Up to index of Isabelle/HOL/Decision_Procs
theory Parametric_Ferrante_Rackoff(* Title: HOL/Decision_Procs/Parametric_Ferrante_Rackoff.thy
Author: Amine Chaieb
*)
header{* A formalization of Ferrante and Rackoff's procedure with polynomial parameters, see Paper in CALCULEMUS 2008 *}
theory Parametric_Ferrante_Rackoff
imports Reflected_Multivariate_Polynomial Dense_Linear_Order DP_Library
"~~/src/HOL/Library/Efficient_Nat" "~~/src/HOL/Library/Old_Recdef"
begin
subsection {* Terms *}
datatype tm = CP poly | Bound nat | Add tm tm | Mul poly tm
| Neg tm | Sub tm tm | CNP nat poly tm
(* A size for poly to make inductive proofs simpler*)
primrec tmsize :: "tm => nat" where
"tmsize (CP c) = polysize c"
| "tmsize (Bound n) = 1"
| "tmsize (Neg a) = 1 + tmsize a"
| "tmsize (Add a b) = 1 + tmsize a + tmsize b"
| "tmsize (Sub a b) = 3 + tmsize a + tmsize b"
| "tmsize (Mul c a) = 1 + polysize c + tmsize a"
| "tmsize (CNP n c a) = 3 + polysize c + tmsize a "
(* Semantics of terms tm *)
primrec Itm :: "'a::{field_char_0, field_inverse_zero} list => 'a list => tm => 'a" where
"Itm vs bs (CP c) = (Ipoly vs c)"
| "Itm vs bs (Bound n) = bs!n"
| "Itm vs bs (Neg a) = -(Itm vs bs a)"
| "Itm vs bs (Add a b) = Itm vs bs a + Itm vs bs b"
| "Itm vs bs (Sub a b) = Itm vs bs a - Itm vs bs b"
| "Itm vs bs (Mul c a) = (Ipoly vs c) * Itm vs bs a"
| "Itm vs bs (CNP n c t) = (Ipoly vs c)*(bs!n) + Itm vs bs t"
fun allpolys:: "(poly => bool) => tm => bool" where
"allpolys P (CP c) = P c"
| "allpolys P (CNP n c p) = (P c ∧ allpolys P p)"
| "allpolys P (Mul c p) = (P c ∧ allpolys P p)"
| "allpolys P (Neg p) = allpolys P p"
| "allpolys P (Add p q) = (allpolys P p ∧ allpolys P q)"
| "allpolys P (Sub p q) = (allpolys P p ∧ allpolys P q)"
| "allpolys P p = True"
primrec tmboundslt:: "nat => tm => bool" where
"tmboundslt n (CP c) = True"
| "tmboundslt n (Bound m) = (m < n)"
| "tmboundslt n (CNP m c a) = (m < n ∧ tmboundslt n a)"
| "tmboundslt n (Neg a) = tmboundslt n a"
| "tmboundslt n (Add a b) = (tmboundslt n a ∧ tmboundslt n b)"
| "tmboundslt n (Sub a b) = (tmboundslt n a ∧ tmboundslt n b)"
| "tmboundslt n (Mul i a) = tmboundslt n a"
primrec tmbound0:: "tm => bool" (* a tm is INDEPENDENT of Bound 0 *) where
"tmbound0 (CP c) = True"
| "tmbound0 (Bound n) = (n>0)"
| "tmbound0 (CNP n c a) = (n≠0 ∧ tmbound0 a)"
| "tmbound0 (Neg a) = tmbound0 a"
| "tmbound0 (Add a b) = (tmbound0 a ∧ tmbound0 b)"
| "tmbound0 (Sub a b) = (tmbound0 a ∧ tmbound0 b)"
| "tmbound0 (Mul i a) = tmbound0 a"
lemma tmbound0_I:
assumes nb: "tmbound0 a"
shows "Itm vs (b#bs) a = Itm vs (b'#bs) a"
using nb
by (induct a rule: tm.induct,auto)
primrec tmbound:: "nat => tm => bool" (* a tm is INDEPENDENT of Bound n *) where
"tmbound n (CP c) = True"
| "tmbound n (Bound m) = (n ≠ m)"
| "tmbound n (CNP m c a) = (n≠m ∧ tmbound n a)"
| "tmbound n (Neg a) = tmbound n a"
| "tmbound n (Add a b) = (tmbound n a ∧ tmbound n b)"
| "tmbound n (Sub a b) = (tmbound n a ∧ tmbound n b)"
| "tmbound n (Mul i a) = tmbound n a"
lemma tmbound0_tmbound_iff: "tmbound 0 t = tmbound0 t" by (induct t, auto)
lemma tmbound_I:
assumes bnd: "tmboundslt (length bs) t" and nb: "tmbound n t" and le: "n ≤ length bs"
shows "Itm vs (bs[n:=x]) t = Itm vs bs t"
using nb le bnd
by (induct t rule: tm.induct , auto)
fun decrtm0:: "tm => tm" where
"decrtm0 (Bound n) = Bound (n - 1)"
| "decrtm0 (Neg a) = Neg (decrtm0 a)"
| "decrtm0 (Add a b) = Add (decrtm0 a) (decrtm0 b)"
| "decrtm0 (Sub a b) = Sub (decrtm0 a) (decrtm0 b)"
| "decrtm0 (Mul c a) = Mul c (decrtm0 a)"
| "decrtm0 (CNP n c a) = CNP (n - 1) c (decrtm0 a)"
| "decrtm0 a = a"
fun incrtm0:: "tm => tm" where
"incrtm0 (Bound n) = Bound (n + 1)"
| "incrtm0 (Neg a) = Neg (incrtm0 a)"
| "incrtm0 (Add a b) = Add (incrtm0 a) (incrtm0 b)"
| "incrtm0 (Sub a b) = Sub (incrtm0 a) (incrtm0 b)"
| "incrtm0 (Mul c a) = Mul c (incrtm0 a)"
| "incrtm0 (CNP n c a) = CNP (n + 1) c (incrtm0 a)"
| "incrtm0 a = a"
lemma decrtm0: assumes nb: "tmbound0 t"
shows "Itm vs (x#bs) t = Itm vs bs (decrtm0 t)"
using nb by (induct t rule: decrtm0.induct, simp_all)
lemma incrtm0: "Itm vs (x#bs) (incrtm0 t) = Itm vs bs t"
by (induct t rule: decrtm0.induct, simp_all)
primrec decrtm:: "nat => tm => tm" where
"decrtm m (CP c) = (CP c)"
| "decrtm m (Bound n) = (if n < m then Bound n else Bound (n - 1))"
| "decrtm m (Neg a) = Neg (decrtm m a)"
| "decrtm m (Add a b) = Add (decrtm m a) (decrtm m b)"
| "decrtm m (Sub a b) = Sub (decrtm m a) (decrtm m b)"
| "decrtm m (Mul c a) = Mul c (decrtm m a)"
| "decrtm m (CNP n c a) = (if n < m then CNP n c (decrtm m a) else CNP (n - 1) c (decrtm m a))"
primrec removen:: "nat => 'a list => 'a list" where
"removen n [] = []"
| "removen n (x#xs) = (if n=0 then xs else (x#(removen (n - 1) xs)))"
lemma removen_same: "n ≥ length xs ==> removen n xs = xs"
by (induct xs arbitrary: n, auto)
lemma nth_length_exceeds: "n ≥ length xs ==> xs!n = []!(n - length xs)"
by (induct xs arbitrary: n, auto)
lemma removen_length: "length (removen n xs) = (if n ≥ length xs then length xs else length xs - 1)"
by (induct xs arbitrary: n, auto)
lemma removen_nth: "(removen n xs)!m = (if n ≥ length xs then xs!m
else if m < n then xs!m else if m ≤ length xs then xs!(Suc m) else []!(m - (length xs - 1)))"
proof(induct xs arbitrary: n m)
case Nil thus ?case by simp
next
case (Cons x xs n m)
{assume nxs: "n ≥ length (x#xs)" hence ?case using removen_same[OF nxs] by simp}
moreover
{assume nxs: "¬ (n ≥ length (x#xs))"
{assume mln: "m < n" hence ?case using Cons by (cases m, auto)}
moreover
{assume mln: "¬ (m < n)"
{assume mxs: "m ≤ length (x#xs)" hence ?case using Cons by (cases m, auto)}
moreover
{assume mxs: "¬ (m ≤ length (x#xs))"
have th: "length (removen n (x#xs)) = length xs"
using removen_length[where n="n" and xs="x#xs"] nxs by simp
with mxs have mxs':"m ≥ length (removen n (x#xs))" by auto
hence "(removen n (x#xs))!m = [] ! (m - length xs)"
using th nth_length_exceeds[OF mxs'] by auto
hence th: "(removen n (x#xs))!m = [] ! (m - (length (x#xs) - 1))"
by auto
hence ?case using nxs mln mxs by auto }
ultimately have ?case by blast
}
ultimately have ?case by blast
} ultimately show ?case by blast
qed
lemma decrtm: assumes bnd: "tmboundslt (length bs) t" and nb: "tmbound m t"
and nle: "m ≤ length bs"
shows "Itm vs (removen m bs) (decrtm m t) = Itm vs bs t"
using bnd nb nle by (induct t rule: tm.induct) (auto simp add: removen_nth)
primrec tmsubst0:: "tm => tm => tm" where
"tmsubst0 t (CP c) = CP c"
| "tmsubst0 t (Bound n) = (if n=0 then t else Bound n)"
| "tmsubst0 t (CNP n c a) = (if n=0 then Add (Mul c t) (tmsubst0 t a) else CNP n c (tmsubst0 t a))"
| "tmsubst0 t (Neg a) = Neg (tmsubst0 t a)"
| "tmsubst0 t (Add a b) = Add (tmsubst0 t a) (tmsubst0 t b)"
| "tmsubst0 t (Sub a b) = Sub (tmsubst0 t a) (tmsubst0 t b)"
| "tmsubst0 t (Mul i a) = Mul i (tmsubst0 t a)"
lemma tmsubst0:
shows "Itm vs (x#bs) (tmsubst0 t a) = Itm vs ((Itm vs (x#bs) t)#bs) a"
by (induct a rule: tm.induct) auto
lemma tmsubst0_nb: "tmbound0 t ==> tmbound0 (tmsubst0 t a)"
by (induct a rule: tm.induct) auto
primrec tmsubst:: "nat => tm => tm => tm" where
"tmsubst n t (CP c) = CP c"
| "tmsubst n t (Bound m) = (if n=m then t else Bound m)"
| "tmsubst n t (CNP m c a) = (if n=m then Add (Mul c t) (tmsubst n t a)
else CNP m c (tmsubst n t a))"
| "tmsubst n t (Neg a) = Neg (tmsubst n t a)"
| "tmsubst n t (Add a b) = Add (tmsubst n t a) (tmsubst n t b)"
| "tmsubst n t (Sub a b) = Sub (tmsubst n t a) (tmsubst n t b)"
| "tmsubst n t (Mul i a) = Mul i (tmsubst n t a)"
lemma tmsubst: assumes nb: "tmboundslt (length bs) a" and nlt: "n ≤ length bs"
shows "Itm vs bs (tmsubst n t a) = Itm vs (bs[n:= Itm vs bs t]) a"
using nb nlt
by (induct a rule: tm.induct,auto)
lemma tmsubst_nb0: assumes tnb: "tmbound0 t"
shows "tmbound0 (tmsubst 0 t a)"
using tnb
by (induct a rule: tm.induct, auto)
lemma tmsubst_nb: assumes tnb: "tmbound m t"
shows "tmbound m (tmsubst m t a)"
using tnb
by (induct a rule: tm.induct, auto)
lemma incrtm0_tmbound: "tmbound n t ==> tmbound (Suc n) (incrtm0 t)"
by (induct t, auto)
(* Simplification *)
consts
tmadd:: "tm × tm => tm"
recdef tmadd "measure (λ (t,s). size t + size s)"
"tmadd (CNP n1 c1 r1,CNP n2 c2 r2) =
(if n1=n2 then
(let c = c1 +⇩p c2
in if c = 0⇩p then tmadd(r1,r2) else CNP n1 c (tmadd (r1,r2)))
else if n1 ≤ n2 then (CNP n1 c1 (tmadd (r1,CNP n2 c2 r2)))
else (CNP n2 c2 (tmadd (CNP n1 c1 r1,r2))))"
"tmadd (CNP n1 c1 r1,t) = CNP n1 c1 (tmadd (r1, t))"
"tmadd (t,CNP n2 c2 r2) = CNP n2 c2 (tmadd (t,r2))"
"tmadd (CP b1, CP b2) = CP (b1 +⇩p b2)"
"tmadd (a,b) = Add a b"
lemma tmadd[simp]: "Itm vs bs (tmadd (t,s)) = Itm vs bs (Add t s)"
apply (induct t s rule: tmadd.induct, simp_all add: Let_def)
apply (case_tac "c1 +⇩p c2 = 0⇩p",case_tac "n1 ≤ n2", simp_all)
apply (case_tac "n1 = n2", simp_all add: field_simps)
apply (simp only: right_distrib[symmetric])
by (auto simp del: polyadd simp add: polyadd[symmetric])
lemma tmadd_nb0[simp]: "[| tmbound0 t ; tmbound0 s|] ==> tmbound0 (tmadd (t,s))"
by (induct t s rule: tmadd.induct, auto simp add: Let_def)
lemma tmadd_nb[simp]: "[| tmbound n t ; tmbound n s|] ==> tmbound n (tmadd (t,s))"
by (induct t s rule: tmadd.induct, auto simp add: Let_def)
lemma tmadd_blt[simp]: "[|tmboundslt n t ; tmboundslt n s|] ==> tmboundslt n (tmadd (t,s))"
by (induct t s rule: tmadd.induct, auto simp add: Let_def)
lemma tmadd_allpolys_npoly[simp]: "allpolys isnpoly t ==> allpolys isnpoly s ==> allpolys isnpoly (tmadd(t,s))" by (induct t s rule: tmadd.induct, simp_all add: Let_def polyadd_norm)
fun tmmul:: "tm => poly => tm" where
"tmmul (CP j) = (λ i. CP (i *⇩p j))"
| "tmmul (CNP n c a) = (λ i. CNP n (i *⇩p c) (tmmul a i))"
| "tmmul t = (λ i. Mul i t)"
lemma tmmul[simp]: "Itm vs bs (tmmul t i) = Itm vs bs (Mul i t)"
by (induct t arbitrary: i rule: tmmul.induct, simp_all add: field_simps)
lemma tmmul_nb0[simp]: "tmbound0 t ==> tmbound0 (tmmul t i)"
by (induct t arbitrary: i rule: tmmul.induct, auto )
lemma tmmul_nb[simp]: "tmbound n t ==> tmbound n (tmmul t i)"
by (induct t arbitrary: n rule: tmmul.induct, auto )
lemma tmmul_blt[simp]: "tmboundslt n t ==> tmboundslt n (tmmul t i)"
by (induct t arbitrary: i rule: tmmul.induct, auto simp add: Let_def)
lemma tmmul_allpolys_npoly[simp]:
assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
shows "allpolys isnpoly t ==> isnpoly c ==> allpolys isnpoly (tmmul t c)" by (induct t rule: tmmul.induct, simp_all add: Let_def polymul_norm)
definition tmneg :: "tm => tm" where
"tmneg t ≡ tmmul t (C (- 1,1))"
definition tmsub :: "tm => tm => tm" where
"tmsub s t ≡ (if s = t then CP 0⇩p else tmadd (s,tmneg t))"
lemma tmneg[simp]: "Itm vs bs (tmneg t) = Itm vs bs (Neg t)"
using tmneg_def[of t]
apply simp
apply (subst number_of_Min)
apply (simp only: of_int_minus)
apply simp
done
lemma tmneg_nb0[simp]: "tmbound0 t ==> tmbound0 (tmneg t)"
using tmneg_def by simp
lemma tmneg_nb[simp]: "tmbound n t ==> tmbound n (tmneg t)"
using tmneg_def by simp
lemma tmneg_blt[simp]: "tmboundslt n t ==> tmboundslt n (tmneg t)"
using tmneg_def by simp
lemma [simp]: "isnpoly (C (-1,1))" unfolding isnpoly_def by simp
lemma tmneg_allpolys_npoly[simp]:
assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
shows "allpolys isnpoly t ==> allpolys isnpoly (tmneg t)"
unfolding tmneg_def by auto
lemma tmsub[simp]: "Itm vs bs (tmsub a b) = Itm vs bs (Sub a b)"
using tmsub_def by simp
lemma tmsub_nb0[simp]: "[| tmbound0 t ; tmbound0 s|] ==> tmbound0 (tmsub t s)"
using tmsub_def by simp
lemma tmsub_nb[simp]: "[| tmbound n t ; tmbound n s|] ==> tmbound n (tmsub t s)"
using tmsub_def by simp
lemma tmsub_blt[simp]: "[|tmboundslt n t ; tmboundslt n s|] ==> tmboundslt n (tmsub t s )"
using tmsub_def by simp
lemma tmsub_allpolys_npoly[simp]:
assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
shows "allpolys isnpoly t ==> allpolys isnpoly s ==> allpolys isnpoly (tmsub t s)"
unfolding tmsub_def by (simp add: isnpoly_def)
fun simptm:: "tm => tm" where
"simptm (CP j) = CP (polynate j)"
| "simptm (Bound n) = CNP n 1⇩p (CP 0⇩p)"
| "simptm (Neg t) = tmneg (simptm t)"
| "simptm (Add t s) = tmadd (simptm t,simptm s)"
| "simptm (Sub t s) = tmsub (simptm t) (simptm s)"
| "simptm (Mul i t) = (let i' = polynate i in if i' = 0⇩p then CP 0⇩p else tmmul (simptm t) i')"
| "simptm (CNP n c t) = (let c' = polynate c in if c' = 0⇩p then simptm t else tmadd (CNP n c' (CP 0⇩p ), simptm t))"
lemma polynate_stupid:
assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
shows "polynate t = 0⇩p ==> Ipoly bs t = (0::'a::{field_char_0, field_inverse_zero})"
apply (subst polynate[symmetric])
apply simp
done
lemma simptm_ci[simp]: "Itm vs bs (simptm t) = Itm vs bs t"
by (induct t rule: simptm.induct, auto simp add: tmneg tmadd tmsub tmmul Let_def polynate_stupid)
lemma simptm_tmbound0[simp]:
"tmbound0 t ==> tmbound0 (simptm t)"
by (induct t rule: simptm.induct, auto simp add: Let_def)
lemma simptm_nb[simp]: "tmbound n t ==> tmbound n (simptm t)"
by (induct t rule: simptm.induct, auto simp add: Let_def)
lemma simptm_nlt[simp]: "tmboundslt n t ==> tmboundslt n (simptm t)"
by (induct t rule: simptm.induct, auto simp add: Let_def)
lemma [simp]: "isnpoly 0⇩p" and [simp]: "isnpoly (C(1,1))"
by (simp_all add: isnpoly_def)
lemma simptm_allpolys_npoly[simp]:
assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
shows "allpolys isnpoly (simptm p)"
by (induct p rule: simptm.induct, auto simp add: Let_def)
declare let_cong[fundef_cong del]
fun split0 :: "tm => (poly × tm)" where
"split0 (Bound 0) = (1⇩p, CP 0⇩p)"
| "split0 (CNP 0 c t) = (let (c',t') = split0 t in (c +⇩p c',t'))"
| "split0 (Neg t) = (let (c,t') = split0 t in (~⇩p c,Neg t'))"
| "split0 (CNP n c t) = (let (c',t') = split0 t in (c',CNP n c t'))"
| "split0 (Add s t) = (let (c1,s') = split0 s ; (c2,t') = split0 t in (c1 +⇩p c2, Add s' t'))"
| "split0 (Sub s t) = (let (c1,s') = split0 s ; (c2,t') = split0 t in (c1 -⇩p c2, Sub s' t'))"
| "split0 (Mul c t) = (let (c',t') = split0 t in (c *⇩p c', Mul c t'))"
| "split0 t = (0⇩p, t)"
declare let_cong[fundef_cong]
lemma split0_stupid[simp]: "∃x y. (x,y) = split0 p"
apply (rule exI[where x="fst (split0 p)"])
apply (rule exI[where x="snd (split0 p)"])
by simp
lemma split0:
"tmbound 0 (snd (split0 t)) ∧ (Itm vs bs (CNP 0 (fst (split0 t)) (snd (split0 t))) = Itm vs bs t)"
apply (induct t rule: split0.induct)
apply simp
apply (simp add: Let_def split_def field_simps)
apply (simp add: Let_def split_def field_simps)
apply (simp add: Let_def split_def field_simps)
apply (simp add: Let_def split_def field_simps)
apply (simp add: Let_def split_def field_simps)
apply (simp add: Let_def split_def mult_assoc right_distrib[symmetric])
apply (simp add: Let_def split_def field_simps)
apply (simp add: Let_def split_def field_simps)
done
lemma split0_ci: "split0 t = (c',t') ==> Itm vs bs t = Itm vs bs (CNP 0 c' t')"
proof-
fix c' t'
assume "split0 t = (c', t')" hence "c' = fst (split0 t)" and "t' = snd (split0 t)" by auto
with split0[where t="t" and bs="bs"] show "Itm vs bs t = Itm vs bs (CNP 0 c' t')" by simp
qed
lemma split0_nb0:
assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
shows "split0 t = (c',t') ==> tmbound 0 t'"
proof-
fix c' t'
assume "split0 t = (c', t')" hence "c' = fst (split0 t)" and "t' = snd (split0 t)" by auto
with conjunct1[OF split0[where t="t"]] show "tmbound 0 t'" by simp
qed
lemma split0_nb0'[simp]: assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
shows "tmbound0 (snd (split0 t))"
using split0_nb0[of t "fst (split0 t)" "snd (split0 t)"] by (simp add: tmbound0_tmbound_iff)
lemma split0_nb: assumes nb:"tmbound n t" shows "tmbound n (snd (split0 t))"
using nb by (induct t rule: split0.induct, auto simp add: Let_def split_def split0_stupid)
lemma split0_blt: assumes nb:"tmboundslt n t" shows "tmboundslt n (snd (split0 t))"
using nb by (induct t rule: split0.induct, auto simp add: Let_def split_def split0_stupid)
lemma tmbound_split0: "tmbound 0 t ==> Ipoly vs (fst(split0 t)) = 0"
by (induct t rule: split0.induct, auto simp add: Let_def split_def split0_stupid)
lemma tmboundslt_split0: "tmboundslt n t ==> Ipoly vs (fst(split0 t)) = 0 ∨ n > 0"
by (induct t rule: split0.induct, auto simp add: Let_def split_def split0_stupid)
lemma tmboundslt0_split0: "tmboundslt 0 t ==> Ipoly vs (fst(split0 t)) = 0"
by (induct t rule: split0.induct, auto simp add: Let_def split_def split0_stupid)
lemma allpolys_split0: "allpolys isnpoly p ==> allpolys isnpoly (snd (split0 p))"
by (induct p rule: split0.induct, auto simp add: isnpoly_def Let_def split_def split0_stupid)
lemma isnpoly_fst_split0: assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
shows
"allpolys isnpoly p ==> isnpoly (fst (split0 p))"
by (induct p rule: split0.induct,
auto simp add: polyadd_norm polysub_norm polyneg_norm polymul_norm
Let_def split_def split0_stupid)
subsection{* Formulae *}
datatype fm = T| F| Le tm | Lt tm | Eq tm | NEq tm|
NOT fm| And fm fm| Or fm fm| Imp fm fm| Iff fm fm| E fm| A fm
(* A size for fm *)
fun fmsize :: "fm => nat" where
"fmsize (NOT p) = 1 + fmsize p"
| "fmsize (And p q) = 1 + fmsize p + fmsize q"
| "fmsize (Or p q) = 1 + fmsize p + fmsize q"
| "fmsize (Imp p q) = 3 + fmsize p + fmsize q"
| "fmsize (Iff p q) = 3 + 2*(fmsize p + fmsize q)"
| "fmsize (E p) = 1 + fmsize p"
| "fmsize (A p) = 4+ fmsize p"
| "fmsize p = 1"
(* several lemmas about fmsize *)
lemma fmsize_pos[termination_simp]: "fmsize p > 0"
by (induct p rule: fmsize.induct) simp_all
(* Semantics of formulae (fm) *)
primrec Ifm ::"'a::{linordered_field_inverse_zero} list => 'a list => fm => bool" where
"Ifm vs bs T = True"
| "Ifm vs bs F = False"
| "Ifm vs bs (Lt a) = (Itm vs bs a < 0)"
| "Ifm vs bs (Le a) = (Itm vs bs a ≤ 0)"
| "Ifm vs bs (Eq a) = (Itm vs bs a = 0)"
| "Ifm vs bs (NEq a) = (Itm vs bs a ≠ 0)"
| "Ifm vs bs (NOT p) = (¬ (Ifm vs bs p))"
| "Ifm vs bs (And p q) = (Ifm vs bs p ∧ Ifm vs bs q)"
| "Ifm vs bs (Or p q) = (Ifm vs bs p ∨ Ifm vs bs q)"
| "Ifm vs bs (Imp p q) = ((Ifm vs bs p) --> (Ifm vs bs q))"
| "Ifm vs bs (Iff p q) = (Ifm vs bs p = Ifm vs bs q)"
| "Ifm vs bs (E p) = (∃ x. Ifm vs (x#bs) p)"
| "Ifm vs bs (A p) = (∀ x. Ifm vs (x#bs) p)"
fun not:: "fm => fm" where
"not (NOT (NOT p)) = not p"
| "not (NOT p) = p"
| "not T = F"
| "not F = T"
| "not (Lt t) = Le (tmneg t)"
| "not (Le t) = Lt (tmneg t)"
| "not (Eq t) = NEq t"
| "not (NEq t) = Eq t"
| "not p = NOT p"
lemma not[simp]: "Ifm vs bs (not p) = Ifm vs bs (NOT p)"
by (induct p rule: not.induct) auto
definition conj :: "fm => fm => fm" where
"conj p q ≡ (if (p = F ∨ q=F) then F else if p=T then q else if q=T then p else
if p = q then p else And p q)"
lemma conj[simp]: "Ifm vs bs (conj p q) = Ifm vs bs (And p q)"
by (cases "p=F ∨ q=F",simp_all add: conj_def) (cases p,simp_all)
definition disj :: "fm => fm => fm" where
"disj p q ≡ (if (p = T ∨ q=T) then T else if p=F then q else if q=F then p
else if p=q then p else Or p q)"
lemma disj[simp]: "Ifm vs bs (disj p q) = Ifm vs bs (Or p q)"
by (cases "p=T ∨ q=T",simp_all add: disj_def) (cases p,simp_all)
definition imp :: "fm => fm => fm" where
"imp p q ≡ (if (p = F ∨ q=T ∨ p=q) then T else if p=T then q else if q=F then not p
else Imp p q)"
lemma imp[simp]: "Ifm vs bs (imp p q) = Ifm vs bs (Imp p q)"
by (cases "p=F ∨ q=T",simp_all add: imp_def)
definition iff :: "fm => fm => fm" where
"iff p q ≡ (if (p = q) then T else if (p = NOT q ∨ NOT p = q) then F else
if p=F then not q else if q=F then not p else if p=T then q else if q=T then p else
Iff p q)"
lemma iff[simp]: "Ifm vs bs (iff p q) = Ifm vs bs (Iff p q)"
by (unfold iff_def,cases "p=q", simp,cases "p=NOT q", simp) (cases "NOT p= q", auto)
(* Quantifier freeness *)
fun qfree:: "fm => bool" where
"qfree (E p) = False"
| "qfree (A p) = False"
| "qfree (NOT p) = qfree p"
| "qfree (And p q) = (qfree p ∧ qfree q)"
| "qfree (Or p q) = (qfree p ∧ qfree q)"
| "qfree (Imp p q) = (qfree p ∧ qfree q)"
| "qfree (Iff p q) = (qfree p ∧ qfree q)"
| "qfree p = True"
(* Boundedness and substitution *)
primrec boundslt :: "nat => fm => bool" where
"boundslt n T = True"
| "boundslt n F = True"
| "boundslt n (Lt t) = (tmboundslt n t)"
| "boundslt n (Le t) = (tmboundslt n t)"
| "boundslt n (Eq t) = (tmboundslt n t)"
| "boundslt n (NEq t) = (tmboundslt n t)"
| "boundslt n (NOT p) = boundslt n p"
| "boundslt n (And p q) = (boundslt n p ∧ boundslt n q)"
| "boundslt n (Or p q) = (boundslt n p ∧ boundslt n q)"
| "boundslt n (Imp p q) = ((boundslt n p) ∧ (boundslt n q))"
| "boundslt n (Iff p q) = (boundslt n p ∧ boundslt n q)"
| "boundslt n (E p) = boundslt (Suc n) p"
| "boundslt n (A p) = boundslt (Suc n) p"
fun bound0:: "fm => bool" (* A Formula is independent of Bound 0 *) where
"bound0 T = True"
| "bound0 F = True"
| "bound0 (Lt a) = tmbound0 a"
| "bound0 (Le a) = tmbound0 a"
| "bound0 (Eq a) = tmbound0 a"
| "bound0 (NEq a) = tmbound0 a"
| "bound0 (NOT p) = bound0 p"
| "bound0 (And p q) = (bound0 p ∧ bound0 q)"
| "bound0 (Or p q) = (bound0 p ∧ bound0 q)"
| "bound0 (Imp p q) = ((bound0 p) ∧ (bound0 q))"
| "bound0 (Iff p q) = (bound0 p ∧ bound0 q)"
| "bound0 p = False"
lemma bound0_I:
assumes bp: "bound0 p"
shows "Ifm vs (b#bs) p = Ifm vs (b'#bs) p"
using bp tmbound0_I[where b="b" and bs="bs" and b'="b'"]
by (induct p rule: bound0.induct,auto)
primrec bound:: "nat => fm => bool" (* A Formula is independent of Bound n *) where
"bound m T = True"
| "bound m F = True"
| "bound m (Lt t) = tmbound m t"
| "bound m (Le t) = tmbound m t"
| "bound m (Eq t) = tmbound m t"
| "bound m (NEq t) = tmbound m t"
| "bound m (NOT p) = bound m p"
| "bound m (And p q) = (bound m p ∧ bound m q)"
| "bound m (Or p q) = (bound m p ∧ bound m q)"
| "bound m (Imp p q) = ((bound m p) ∧ (bound m q))"
| "bound m (Iff p q) = (bound m p ∧ bound m q)"
| "bound m (E p) = bound (Suc m) p"
| "bound m (A p) = bound (Suc m) p"
lemma bound_I:
assumes bnd: "boundslt (length bs) p" and nb: "bound n p" and le: "n ≤ length bs"
shows "Ifm vs (bs[n:=x]) p = Ifm vs bs p"
using bnd nb le tmbound_I[where bs=bs and vs = vs]
proof(induct p arbitrary: bs n rule: fm.induct)
case (E p bs n)
{fix y
from E have bnd: "boundslt (length (y#bs)) p"
and nb: "bound (Suc n) p" and le: "Suc n ≤ length (y#bs)" by simp+
from E.hyps[OF bnd nb le tmbound_I] have "Ifm vs ((y#bs)[Suc n:=x]) p = Ifm vs (y#bs) p" . }
thus ?case by simp
next
case (A p bs n) {fix y
from A have bnd: "boundslt (length (y#bs)) p"
and nb: "bound (Suc n) p" and le: "Suc n ≤ length (y#bs)" by simp+
from A.hyps[OF bnd nb le tmbound_I] have "Ifm vs ((y#bs)[Suc n:=x]) p = Ifm vs (y#bs) p" . }
thus ?case by simp
qed auto
fun decr0 :: "fm => fm" where
"decr0 (Lt a) = Lt (decrtm0 a)"
| "decr0 (Le a) = Le (decrtm0 a)"
| "decr0 (Eq a) = Eq (decrtm0 a)"
| "decr0 (NEq a) = NEq (decrtm0 a)"
| "decr0 (NOT p) = NOT (decr0 p)"
| "decr0 (And p q) = conj (decr0 p) (decr0 q)"
| "decr0 (Or p q) = disj (decr0 p) (decr0 q)"
| "decr0 (Imp p q) = imp (decr0 p) (decr0 q)"
| "decr0 (Iff p q) = iff (decr0 p) (decr0 q)"
| "decr0 p = p"
lemma decr0: assumes nb: "bound0 p"
shows "Ifm vs (x#bs) p = Ifm vs bs (decr0 p)"
using nb
by (induct p rule: decr0.induct, simp_all add: decrtm0)
primrec decr :: "nat => fm => fm" where
"decr m T = T"
| "decr m F = F"
| "decr m (Lt t) = (Lt (decrtm m t))"
| "decr m (Le t) = (Le (decrtm m t))"
| "decr m (Eq t) = (Eq (decrtm m t))"
| "decr m (NEq t) = (NEq (decrtm m t))"
| "decr m (NOT p) = NOT (decr m p)"
| "decr m (And p q) = conj (decr m p) (decr m q)"
| "decr m (Or p q) = disj (decr m p) (decr m q)"
| "decr m (Imp p q) = imp (decr m p) (decr m q)"
| "decr m (Iff p q) = iff (decr m p) (decr m q)"
| "decr m (E p) = E (decr (Suc m) p)"
| "decr m (A p) = A (decr (Suc m) p)"
lemma decr: assumes bnd: "boundslt (length bs) p" and nb: "bound m p"
and nle: "m < length bs"
shows "Ifm vs (removen m bs) (decr m p) = Ifm vs bs p"
using bnd nb nle
proof(induct p arbitrary: bs m rule: fm.induct)
case (E p bs m)
{fix x
from E have bnd: "boundslt (length (x#bs)) p" and nb: "bound (Suc m) p"
and nle: "Suc m < length (x#bs)" by auto
from E(1)[OF bnd nb nle] have "Ifm vs (removen (Suc m) (x#bs)) (decr (Suc m) p) = Ifm vs (x#bs) p".
} thus ?case by auto
next
case (A p bs m)
{fix x
from A have bnd: "boundslt (length (x#bs)) p" and nb: "bound (Suc m) p"
and nle: "Suc m < length (x#bs)" by auto
from A(1)[OF bnd nb nle] have "Ifm vs (removen (Suc m) (x#bs)) (decr (Suc m) p) = Ifm vs (x#bs) p".
} thus ?case by auto
qed (auto simp add: decrtm removen_nth)
primrec subst0:: "tm => fm => fm" where
"subst0 t T = T"
| "subst0 t F = F"
| "subst0 t (Lt a) = Lt (tmsubst0 t a)"
| "subst0 t (Le a) = Le (tmsubst0 t a)"
| "subst0 t (Eq a) = Eq (tmsubst0 t a)"
| "subst0 t (NEq a) = NEq (tmsubst0 t a)"
| "subst0 t (NOT p) = NOT (subst0 t p)"
| "subst0 t (And p q) = And (subst0 t p) (subst0 t q)"
| "subst0 t (Or p q) = Or (subst0 t p) (subst0 t q)"
| "subst0 t (Imp p q) = Imp (subst0 t p) (subst0 t q)"
| "subst0 t (Iff p q) = Iff (subst0 t p) (subst0 t q)"
| "subst0 t (E p) = E p"
| "subst0 t (A p) = A p"
lemma subst0: assumes qf: "qfree p"
shows "Ifm vs (x#bs) (subst0 t p) = Ifm vs ((Itm vs (x#bs) t)#bs) p"
using qf tmsubst0[where x="x" and bs="bs" and t="t"]
by (induct p rule: fm.induct, auto)
lemma subst0_nb:
assumes bp: "tmbound0 t" and qf: "qfree p"
shows "bound0 (subst0 t p)"
using qf tmsubst0_nb[OF bp] bp
by (induct p rule: fm.induct, auto)
primrec subst:: "nat => tm => fm => fm" where
"subst n t T = T"
| "subst n t F = F"
| "subst n t (Lt a) = Lt (tmsubst n t a)"
| "subst n t (Le a) = Le (tmsubst n t a)"
| "subst n t (Eq a) = Eq (tmsubst n t a)"
| "subst n t (NEq a) = NEq (tmsubst n t a)"
| "subst n t (NOT p) = NOT (subst n t p)"
| "subst n t (And p q) = And (subst n t p) (subst n t q)"
| "subst n t (Or p q) = Or (subst n t p) (subst n t q)"
| "subst n t (Imp p q) = Imp (subst n t p) (subst n t q)"
| "subst n t (Iff p q) = Iff (subst n t p) (subst n t q)"
| "subst n t (E p) = E (subst (Suc n) (incrtm0 t) p)"
| "subst n t (A p) = A (subst (Suc n) (incrtm0 t) p)"
lemma subst: assumes nb: "boundslt (length bs) p" and nlm: "n ≤ length bs"
shows "Ifm vs bs (subst n t p) = Ifm vs (bs[n:= Itm vs bs t]) p"
using nb nlm
proof (induct p arbitrary: bs n t rule: fm.induct)
case (E p bs n)
{fix x
from E have bn: "boundslt (length (x#bs)) p" by simp
from E have nlm: "Suc n ≤ length (x#bs)" by simp
from E(1)[OF bn nlm] have "Ifm vs (x#bs) (subst (Suc n) (incrtm0 t) p) = Ifm vs ((x#bs)[Suc n:= Itm vs (x#bs) (incrtm0 t)]) p" by simp
hence "Ifm vs (x#bs) (subst (Suc n) (incrtm0 t) p) = Ifm vs (x#bs[n:= Itm vs bs t]) p"
by (simp add: incrtm0[where x="x" and bs="bs" and t="t"]) }
thus ?case by simp
next
case (A p bs n)
{fix x
from A have bn: "boundslt (length (x#bs)) p" by simp
from A have nlm: "Suc n ≤ length (x#bs)" by simp
from A(1)[OF bn nlm] have "Ifm vs (x#bs) (subst (Suc n) (incrtm0 t) p) = Ifm vs ((x#bs)[Suc n:= Itm vs (x#bs) (incrtm0 t)]) p" by simp
hence "Ifm vs (x#bs) (subst (Suc n) (incrtm0 t) p) = Ifm vs (x#bs[n:= Itm vs bs t]) p"
by (simp add: incrtm0[where x="x" and bs="bs" and t="t"]) }
thus ?case by simp
qed(auto simp add: tmsubst)
lemma subst_nb: assumes tnb: "tmbound m t"
shows "bound m (subst m t p)"
using tnb tmsubst_nb incrtm0_tmbound
by (induct p arbitrary: m t rule: fm.induct, auto)
lemma not_qf[simp]: "qfree p ==> qfree (not p)"
by (induct p rule: not.induct, auto)
lemma not_bn0[simp]: "bound0 p ==> bound0 (not p)"
by (induct p rule: not.induct, auto)
lemma not_nb[simp]: "bound n p ==> bound n (not p)"
by (induct p rule: not.induct, auto)
lemma not_blt[simp]: "boundslt n p ==> boundslt n (not p)"
by (induct p rule: not.induct, auto)
lemma conj_qf[simp]: "[|qfree p ; qfree q|] ==> qfree (conj p q)"
using conj_def by auto
lemma conj_nb0[simp]: "[|bound0 p ; bound0 q|] ==> bound0 (conj p q)"
using conj_def by auto
lemma conj_nb[simp]: "[|bound n p ; bound n q|] ==> bound n (conj p q)"
using conj_def by auto
lemma conj_blt[simp]: "boundslt n p ==> boundslt n q ==> boundslt n (conj p q)"
using conj_def by auto
lemma disj_qf[simp]: "[|qfree p ; qfree q|] ==> qfree (disj p q)"
using disj_def by auto
lemma disj_nb0[simp]: "[|bound0 p ; bound0 q|] ==> bound0 (disj p q)"
using disj_def by auto
lemma disj_nb[simp]: "[|bound n p ; bound n q|] ==> bound n (disj p q)"
using disj_def by auto
lemma disj_blt[simp]: "boundslt n p ==> boundslt n q ==> boundslt n (disj p q)"
using disj_def by auto
lemma imp_qf[simp]: "[|qfree p ; qfree q|] ==> qfree (imp p q)"
using imp_def by (cases "p=F ∨ q=T",simp_all add: imp_def)
lemma imp_nb0[simp]: "[|bound0 p ; bound0 q|] ==> bound0 (imp p q)"
using imp_def by (cases "p=F ∨ q=T ∨ p=q",simp_all add: imp_def)
lemma imp_nb[simp]: "[|bound n p ; bound n q|] ==> bound n (imp p q)"
using imp_def by (cases "p=F ∨ q=T ∨ p=q",simp_all add: imp_def)
lemma imp_blt[simp]: "boundslt n p ==> boundslt n q ==> boundslt n (imp p q)"
using imp_def by auto
lemma iff_qf[simp]: "[|qfree p ; qfree q|] ==> qfree (iff p q)"
by (unfold iff_def,cases "p=q", auto)
lemma iff_nb0[simp]: "[|bound0 p ; bound0 q|] ==> bound0 (iff p q)"
using iff_def by (unfold iff_def,cases "p=q", auto)
lemma iff_nb[simp]: "[|bound n p ; bound n q|] ==> bound n (iff p q)"
using iff_def by (unfold iff_def,cases "p=q", auto)
lemma iff_blt[simp]: "boundslt n p ==> boundslt n q ==> boundslt n (iff p q)"
using iff_def by auto
lemma decr0_qf: "bound0 p ==> qfree (decr0 p)"
by (induct p, simp_all)
fun isatom :: "fm => bool" (* test for atomicity *) where
"isatom T = True"
| "isatom F = True"
| "isatom (Lt a) = True"
| "isatom (Le a) = True"
| "isatom (Eq a) = True"
| "isatom (NEq a) = True"
| "isatom p = False"
lemma bound0_qf: "bound0 p ==> qfree p"
by (induct p, simp_all)
definition djf :: "('a => fm) => 'a => fm => fm" where
"djf f p q ≡ (if q=T then T else if q=F then f p else
(let fp = f p in case fp of T => T | F => q | _ => Or (f p) q))"
definition evaldjf :: "('a => fm) => 'a list => fm" where
"evaldjf f ps ≡ foldr (djf f) ps F"
lemma djf_Or: "Ifm vs bs (djf f p q) = Ifm vs bs (Or (f p) q)"
by (cases "q=T", simp add: djf_def,cases "q=F",simp add: djf_def)
(cases "f p", simp_all add: Let_def djf_def)
lemma evaldjf_ex: "Ifm vs bs (evaldjf f ps) = (∃ p ∈ set ps. Ifm vs bs (f p))"
by(induct ps, simp_all add: evaldjf_def djf_Or)
lemma evaldjf_bound0:
assumes nb: "∀ x∈ set xs. bound0 (f x)"
shows "bound0 (evaldjf f xs)"
using nb by (induct xs, auto simp add: evaldjf_def djf_def Let_def) (case_tac "f a", auto)
lemma evaldjf_qf:
assumes nb: "∀ x∈ set xs. qfree (f x)"
shows "qfree (evaldjf f xs)"
using nb by (induct xs, auto simp add: evaldjf_def djf_def Let_def) (case_tac "f a", auto)
fun disjuncts :: "fm => fm list" where
"disjuncts (Or p q) = (disjuncts p) @ (disjuncts q)"
| "disjuncts F = []"
| "disjuncts p = [p]"
lemma disjuncts: "(∃ q∈ set (disjuncts p). Ifm vs bs q) = Ifm vs bs p"
by(induct p rule: disjuncts.induct, auto)
lemma disjuncts_nb: "bound0 p ==> ∀ q∈ set (disjuncts p). bound0 q"
proof-
assume nb: "bound0 p"
hence "list_all bound0 (disjuncts p)" by (induct p rule:disjuncts.induct,auto)
thus ?thesis by (simp only: list_all_iff)
qed
lemma disjuncts_qf: "qfree p ==> ∀ q∈ set (disjuncts p). qfree q"
proof-
assume qf: "qfree p"
hence "list_all qfree (disjuncts p)"
by (induct p rule: disjuncts.induct, auto)
thus ?thesis by (simp only: list_all_iff)
qed
definition DJ :: "(fm => fm) => fm => fm" where
"DJ f p ≡ evaldjf f (disjuncts p)"
lemma DJ: assumes fdj: "∀ p q. Ifm vs bs (f (Or p q)) = Ifm vs bs (Or (f p) (f q))"
and fF: "f F = F"
shows "Ifm vs bs (DJ f p) = Ifm vs bs (f p)"
proof-
have "Ifm vs bs (DJ f p) = (∃ q ∈ set (disjuncts p). Ifm vs bs (f q))"
by (simp add: DJ_def evaldjf_ex)
also have "… = Ifm vs bs (f p)" using fdj fF by (induct p rule: disjuncts.induct, auto)
finally show ?thesis .
qed
lemma DJ_qf: assumes
fqf: "∀ p. qfree p --> qfree (f p)"
shows "∀p. qfree p --> qfree (DJ f p) "
proof(clarify)
fix p assume qf: "qfree p"
have th: "DJ f p = evaldjf f (disjuncts p)" by (simp add: DJ_def)
from disjuncts_qf[OF qf] have "∀ q∈ set (disjuncts p). qfree q" .
with fqf have th':"∀ q∈ set (disjuncts p). qfree (f q)" by blast
from evaldjf_qf[OF th'] th show "qfree (DJ f p)" by simp
qed
lemma DJ_qe: assumes qe: "∀ bs p. qfree p --> qfree (qe p) ∧ (Ifm vs bs (qe p) = Ifm vs bs (E p))"
shows "∀ bs p. qfree p --> qfree (DJ qe p) ∧ (Ifm vs bs ((DJ qe p)) = Ifm vs bs (E p))"
proof(clarify)
fix p::fm and bs
assume qf: "qfree p"
from qe have qth: "∀ p. qfree p --> qfree (qe p)" by blast
from DJ_qf[OF qth] qf have qfth:"qfree (DJ qe p)" by auto
have "Ifm vs bs (DJ qe p) = (∃ q∈ set (disjuncts p). Ifm vs bs (qe q))"
by (simp add: DJ_def evaldjf_ex)
also have "… = (∃ q ∈ set(disjuncts p). Ifm vs bs (E q))" using qe disjuncts_qf[OF qf] by auto
also have "… = Ifm vs bs (E p)" by (induct p rule: disjuncts.induct, auto)
finally show "qfree (DJ qe p) ∧ Ifm vs bs (DJ qe p) = Ifm vs bs (E p)" using qfth by blast
qed
fun conjuncts :: "fm => fm list" where
"conjuncts (And p q) = (conjuncts p) @ (conjuncts q)"
| "conjuncts T = []"
| "conjuncts p = [p]"
definition list_conj :: "fm list => fm" where
"list_conj ps ≡ foldr conj ps T"
definition CJNB :: "(fm => fm) => fm => fm" where
"CJNB f p ≡ (let cjs = conjuncts p ; (yes,no) = partition bound0 cjs
in conj (decr0 (list_conj yes)) (f (list_conj no)))"
lemma conjuncts_qf: "qfree p ==> ∀ q∈ set (conjuncts p). qfree q"
proof-
assume qf: "qfree p"
hence "list_all qfree (conjuncts p)"
by (induct p rule: conjuncts.induct, auto)
thus ?thesis by (simp only: list_all_iff)
qed
lemma conjuncts: "(∀ q∈ set (conjuncts p). Ifm vs bs q) = Ifm vs bs p"
by(induct p rule: conjuncts.induct, auto)
lemma conjuncts_nb: "bound0 p ==> ∀ q∈ set (conjuncts p). bound0 q"
proof-
assume nb: "bound0 p"
hence "list_all bound0 (conjuncts p)" by (induct p rule:conjuncts.induct,auto)
thus ?thesis by (simp only: list_all_iff)
qed
fun islin :: "fm => bool" where
"islin (And p q) = (islin p ∧ islin q ∧ p ≠ T ∧ p ≠ F ∧ q ≠ T ∧ q ≠ F)"
| "islin (Or p q) = (islin p ∧ islin q ∧ p ≠ T ∧ p ≠ F ∧ q ≠ T ∧ q ≠ F)"
| "islin (Eq (CNP 0 c s)) = (isnpoly c ∧ c ≠ 0⇩p ∧ tmbound0 s ∧ allpolys isnpoly s)"
| "islin (NEq (CNP 0 c s)) = (isnpoly c ∧ c ≠ 0⇩p ∧ tmbound0 s ∧ allpolys isnpoly s)"
| "islin (Lt (CNP 0 c s)) = (isnpoly c ∧ c ≠ 0⇩p ∧ tmbound0 s ∧ allpolys isnpoly s)"
| "islin (Le (CNP 0 c s)) = (isnpoly c ∧ c ≠ 0⇩p ∧ tmbound0 s ∧ allpolys isnpoly s)"
| "islin (NOT p) = False"
| "islin (Imp p q) = False"
| "islin (Iff p q) = False"
| "islin p = bound0 p"
lemma islin_stupid: assumes nb: "tmbound0 p"
shows "islin (Lt p)" and "islin (Le p)" and "islin (Eq p)" and "islin (NEq p)"
using nb by (cases p, auto, case_tac nat, auto)+
definition "lt p = (case p of CP (C c) => if 0>⇩N c then T else F| _ => Lt p)"
definition "le p = (case p of CP (C c) => if 0≥⇩N c then T else F | _ => Le p)"
definition eq where "eq p = (case p of CP (C c) => if c = 0⇩N then T else F | _ => Eq p)"
definition "neq p = not (eq p)"
lemma lt: "allpolys isnpoly p ==> Ifm vs bs (lt p) = Ifm vs bs (Lt p)"
apply(simp add: lt_def)
apply(cases p, simp_all)
apply (case_tac poly, simp_all add: isnpoly_def)
done
lemma le: "allpolys isnpoly p ==> Ifm vs bs (le p) = Ifm vs bs (Le p)"
apply(simp add: le_def)
apply(cases p, simp_all)
apply (case_tac poly, simp_all add: isnpoly_def)
done
lemma eq: "allpolys isnpoly p ==> Ifm vs bs (eq p) = Ifm vs bs (Eq p)"
apply(simp add: eq_def)
apply(cases p, simp_all)
apply (case_tac poly, simp_all add: isnpoly_def)
done
lemma neq: "allpolys isnpoly p ==> Ifm vs bs (neq p) = Ifm vs bs (NEq p)"
by(simp add: neq_def eq)
lemma lt_lin: "tmbound0 p ==> islin (lt p)"
apply (simp add: lt_def)
apply (cases p, simp_all)
apply (case_tac poly, simp_all)
apply (case_tac nat, simp_all)
done
lemma le_lin: "tmbound0 p ==> islin (le p)"
apply (simp add: le_def)
apply (cases p, simp_all)
apply (case_tac poly, simp_all)
apply (case_tac nat, simp_all)
done
lemma eq_lin: "tmbound0 p ==> islin (eq p)"
apply (simp add: eq_def)
apply (cases p, simp_all)
apply (case_tac poly, simp_all)
apply (case_tac nat, simp_all)
done
lemma neq_lin: "tmbound0 p ==> islin (neq p)"
apply (simp add: neq_def eq_def)
apply (cases p, simp_all)
apply (case_tac poly, simp_all)
apply (case_tac nat, simp_all)
done
definition "simplt t = (let (c,s) = split0 (simptm t) in if c= 0⇩p then lt s else Lt (CNP 0 c s))"
definition "simple t = (let (c,s) = split0 (simptm t) in if c= 0⇩p then le s else Le (CNP 0 c s))"
definition "simpeq t = (let (c,s) = split0 (simptm t) in if c= 0⇩p then eq s else Eq (CNP 0 c s))"
definition "simpneq t = (let (c,s) = split0 (simptm t) in if c= 0⇩p then neq s else NEq (CNP 0 c s))"
lemma simplt_islin[simp]: assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
shows "islin (simplt t)"
unfolding simplt_def
using split0_nb0'
by (auto simp add: lt_lin Let_def split_def isnpoly_fst_split0[OF simptm_allpolys_npoly] islin_stupid allpolys_split0[OF simptm_allpolys_npoly])
lemma simple_islin[simp]: assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
shows "islin (simple t)"
unfolding simple_def
using split0_nb0'
by (auto simp add: Let_def split_def isnpoly_fst_split0[OF simptm_allpolys_npoly] islin_stupid allpolys_split0[OF simptm_allpolys_npoly] le_lin)
lemma simpeq_islin[simp]: assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
shows "islin (simpeq t)"
unfolding simpeq_def
using split0_nb0'
by (auto simp add: Let_def split_def isnpoly_fst_split0[OF simptm_allpolys_npoly] islin_stupid allpolys_split0[OF simptm_allpolys_npoly] eq_lin)
lemma simpneq_islin[simp]: assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
shows "islin (simpneq t)"
unfolding simpneq_def
using split0_nb0'
by (auto simp add: Let_def split_def isnpoly_fst_split0[OF simptm_allpolys_npoly] islin_stupid allpolys_split0[OF simptm_allpolys_npoly] neq_lin)
lemma really_stupid: "¬ (∀c1 s'. (c1, s') ≠ split0 s)"
by (cases "split0 s", auto)
lemma split0_npoly: assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
and n: "allpolys isnpoly t"
shows "isnpoly (fst (split0 t))" and "allpolys isnpoly (snd (split0 t))"
using n
by (induct t rule: split0.induct, auto simp add: Let_def split_def polyadd_norm polymul_norm polyneg_norm polysub_norm really_stupid)
lemma simplt[simp]:
shows "Ifm vs bs (simplt t) = Ifm vs bs (Lt t)"
proof-
have n: "allpolys isnpoly (simptm t)" by simp
let ?t = "simptm t"
{assume "fst (split0 ?t) = 0⇩p" hence ?thesis
using split0[of "simptm t" vs bs] lt[OF split0_npoly(2)[OF n], of vs bs]
by (simp add: simplt_def Let_def split_def lt)}
moreover
{assume "fst (split0 ?t) ≠ 0⇩p"
hence ?thesis using split0[of "simptm t" vs bs] by (simp add: simplt_def Let_def split_def)
}
ultimately show ?thesis by blast
qed
lemma simple[simp]:
shows "Ifm vs bs (simple t) = Ifm vs bs (Le t)"
proof-
have n: "allpolys isnpoly (simptm t)" by simp
let ?t = "simptm t"
{assume "fst (split0 ?t) = 0⇩p" hence ?thesis
using split0[of "simptm t" vs bs] le[OF split0_npoly(2)[OF n], of vs bs]
by (simp add: simple_def Let_def split_def le)}
moreover
{assume "fst (split0 ?t) ≠ 0⇩p"
hence ?thesis using split0[of "simptm t" vs bs] by (simp add: simple_def Let_def split_def)
}
ultimately show ?thesis by blast
qed
lemma simpeq[simp]:
shows "Ifm vs bs (simpeq t) = Ifm vs bs (Eq t)"
proof-
have n: "allpolys isnpoly (simptm t)" by simp
let ?t = "simptm t"
{assume "fst (split0 ?t) = 0⇩p" hence ?thesis
using split0[of "simptm t" vs bs] eq[OF split0_npoly(2)[OF n], of vs bs]
by (simp add: simpeq_def Let_def split_def)}
moreover
{assume "fst (split0 ?t) ≠ 0⇩p"
hence ?thesis using split0[of "simptm t" vs bs] by (simp add: simpeq_def Let_def split_def)
}
ultimately show ?thesis by blast
qed
lemma simpneq[simp]:
shows "Ifm vs bs (simpneq t) = Ifm vs bs (NEq t)"
proof-
have n: "allpolys isnpoly (simptm t)" by simp
let ?t = "simptm t"
{assume "fst (split0 ?t) = 0⇩p" hence ?thesis
using split0[of "simptm t" vs bs] neq[OF split0_npoly(2)[OF n], of vs bs]
by (simp add: simpneq_def Let_def split_def )}
moreover
{assume "fst (split0 ?t) ≠ 0⇩p"
hence ?thesis using split0[of "simptm t" vs bs] by (simp add: simpneq_def Let_def split_def)
}
ultimately show ?thesis by blast
qed
lemma lt_nb: "tmbound0 t ==> bound0 (lt t)"
apply (simp add: lt_def)
apply (cases t, auto)
apply (case_tac poly, auto)
done
lemma le_nb: "tmbound0 t ==> bound0 (le t)"
apply (simp add: le_def)
apply (cases t, auto)
apply (case_tac poly, auto)
done
lemma eq_nb: "tmbound0 t ==> bound0 (eq t)"
apply (simp add: eq_def)
apply (cases t, auto)
apply (case_tac poly, auto)
done
lemma neq_nb: "tmbound0 t ==> bound0 (neq t)"
apply (simp add: neq_def eq_def)
apply (cases t, auto)
apply (case_tac poly, auto)
done
lemma simplt_nb[simp]: assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
shows "tmbound0 t ==> bound0 (simplt t)"
using split0 [of "simptm t" vs bs]
proof(simp add: simplt_def Let_def split_def)
assume nb: "tmbound0 t"
hence nb': "tmbound0 (simptm t)" by simp
let ?c = "fst (split0 (simptm t))"
from tmbound_split0[OF nb'[unfolded tmbound0_tmbound_iff[symmetric]]]
have th: "∀bs. Ipoly bs ?c = Ipoly bs 0⇩p" by auto
from isnpoly_fst_split0[OF simptm_allpolys_npoly[of t]]
have ths: "isnpolyh ?c 0" "isnpolyh 0⇩p 0" by (simp_all add: isnpoly_def)
from iffD1[OF isnpolyh_unique[OF ths] th]
have "fst (split0 (simptm t)) = 0⇩p" .
thus "(fst (split0 (simptm t)) = 0⇩p --> bound0 (lt (snd (split0 (simptm t))))) ∧
fst (split0 (simptm t)) = 0⇩p" by (simp add: simplt_def Let_def split_def lt_nb)
qed
lemma simple_nb[simp]: assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
shows "tmbound0 t ==> bound0 (simple t)"
using split0 [of "simptm t" vs bs]
proof(simp add: simple_def Let_def split_def)
assume nb: "tmbound0 t"
hence nb': "tmbound0 (simptm t)" by simp
let ?c = "fst (split0 (simptm t))"
from tmbound_split0[OF nb'[unfolded tmbound0_tmbound_iff[symmetric]]]
have th: "∀bs. Ipoly bs ?c = Ipoly bs 0⇩p" by auto
from isnpoly_fst_split0[OF simptm_allpolys_npoly[of t]]
have ths: "isnpolyh ?c 0" "isnpolyh 0⇩p 0" by (simp_all add: isnpoly_def)
from iffD1[OF isnpolyh_unique[OF ths] th]
have "fst (split0 (simptm t)) = 0⇩p" .
thus "(fst (split0 (simptm t)) = 0⇩p --> bound0 (le (snd (split0 (simptm t))))) ∧
fst (split0 (simptm t)) = 0⇩p" by (simp add: simplt_def Let_def split_def le_nb)
qed
lemma simpeq_nb[simp]: assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
shows "tmbound0 t ==> bound0 (simpeq t)"
using split0 [of "simptm t" vs bs]
proof(simp add: simpeq_def Let_def split_def)
assume nb: "tmbound0 t"
hence nb': "tmbound0 (simptm t)" by simp
let ?c = "fst (split0 (simptm t))"
from tmbound_split0[OF nb'[unfolded tmbound0_tmbound_iff[symmetric]]]
have th: "∀bs. Ipoly bs ?c = Ipoly bs 0⇩p" by auto
from isnpoly_fst_split0[OF simptm_allpolys_npoly[of t]]
have ths: "isnpolyh ?c 0" "isnpolyh 0⇩p 0" by (simp_all add: isnpoly_def)
from iffD1[OF isnpolyh_unique[OF ths] th]
have "fst (split0 (simptm t)) = 0⇩p" .
thus "(fst (split0 (simptm t)) = 0⇩p --> bound0 (eq (snd (split0 (simptm t))))) ∧
fst (split0 (simptm t)) = 0⇩p" by (simp add: simpeq_def Let_def split_def eq_nb)
qed
lemma simpneq_nb[simp]: assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
shows "tmbound0 t ==> bound0 (simpneq t)"
using split0 [of "simptm t" vs bs]
proof(simp add: simpneq_def Let_def split_def)
assume nb: "tmbound0 t"
hence nb': "tmbound0 (simptm t)" by simp
let ?c = "fst (split0 (simptm t))"
from tmbound_split0[OF nb'[unfolded tmbound0_tmbound_iff[symmetric]]]
have th: "∀bs. Ipoly bs ?c = Ipoly bs 0⇩p" by auto
from isnpoly_fst_split0[OF simptm_allpolys_npoly[of t]]
have ths: "isnpolyh ?c 0" "isnpolyh 0⇩p 0" by (simp_all add: isnpoly_def)
from iffD1[OF isnpolyh_unique[OF ths] th]
have "fst (split0 (simptm t)) = 0⇩p" .
thus "(fst (split0 (simptm t)) = 0⇩p --> bound0 (neq (snd (split0 (simptm t))))) ∧
fst (split0 (simptm t)) = 0⇩p" by (simp add: simpneq_def Let_def split_def neq_nb)
qed
fun conjs :: "fm => fm list" where
"conjs (And p q) = (conjs p)@(conjs q)"
| "conjs T = []"
| "conjs p = [p]"
lemma conjs_ci: "(∀ q ∈ set (conjs p). Ifm vs bs q) = Ifm vs bs p"
by (induct p rule: conjs.induct, auto)
definition list_disj :: "fm list => fm" where
"list_disj ps ≡ foldr disj ps F"
lemma list_conj: "Ifm vs bs (list_conj ps) = (∀p∈ set ps. Ifm vs bs p)"
by (induct ps, auto simp add: list_conj_def)
lemma list_conj_qf: " ∀p∈ set ps. qfree p ==> qfree (list_conj ps)"
by (induct ps, auto simp add: list_conj_def conj_qf)
lemma list_disj: "Ifm vs bs (list_disj ps) = (∃p∈ set ps. Ifm vs bs p)"
by (induct ps, auto simp add: list_disj_def)
lemma conj_boundslt: "boundslt n p ==> boundslt n q ==> boundslt n (conj p q)"
unfolding conj_def by auto
lemma conjs_nb: "bound n p ==> ∀q∈ set (conjs p). bound n q"
apply (induct p rule: conjs.induct)
apply (unfold conjs.simps)
apply (unfold set_append)
apply (unfold ball_Un)
apply (unfold bound.simps)
apply auto
done
lemma conjs_boundslt: "boundslt n p ==> ∀q∈ set (conjs p). boundslt n q"
apply (induct p rule: conjs.induct)
apply (unfold conjs.simps)
apply (unfold set_append)
apply (unfold ball_Un)
apply (unfold boundslt.simps)
apply blast
by simp_all
lemma list_conj_boundslt: " ∀p∈ set ps. boundslt n p ==> boundslt n (list_conj ps)"
unfolding list_conj_def
by (induct ps, auto simp add: conj_boundslt)
lemma list_conj_nb: assumes bnd: "∀p∈ set ps. bound n p"
shows "bound n (list_conj ps)"
using bnd
unfolding list_conj_def
by (induct ps, auto simp add: conj_nb)
lemma list_conj_nb': "∀p∈set ps. bound0 p ==> bound0 (list_conj ps)"
unfolding list_conj_def by (induct ps , auto)
lemma CJNB_qe:
assumes qe: "∀ bs p. qfree p --> qfree (qe p) ∧ (Ifm vs bs (qe p) = Ifm vs bs (E p))"
shows "∀ bs p. qfree p --> qfree (CJNB qe p) ∧ (Ifm vs bs ((CJNB qe p)) = Ifm vs bs (E p))"
proof(clarify)
fix bs p
assume qfp: "qfree p"
let ?cjs = "conjuncts p"
let ?yes = "fst (partition bound0 ?cjs)"
let ?no = "snd (partition bound0 ?cjs)"
let ?cno = "list_conj ?no"
let ?cyes = "list_conj ?yes"
have part: "partition bound0 ?cjs = (?yes,?no)" by simp
from partition_P[OF part] have "∀ q∈ set ?yes. bound0 q" by blast
hence yes_nb: "bound0 ?cyes" by (simp add: list_conj_nb')
hence yes_qf: "qfree (decr0 ?cyes )" by (simp add: decr0_qf)
from conjuncts_qf[OF qfp] partition_set[OF part]
have " ∀q∈ set ?no. qfree q" by auto
hence no_qf: "qfree ?cno"by (simp add: list_conj_qf)
with qe have cno_qf:"qfree (qe ?cno )"
and noE: "Ifm vs bs (qe ?cno) = Ifm vs bs (E ?cno)" by blast+
from cno_qf yes_qf have qf: "qfree (CJNB qe p)"
by (simp add: CJNB_def Let_def conj_qf split_def)
{fix bs
from conjuncts have "Ifm vs bs p = (∀q∈ set ?cjs. Ifm vs bs q)" by blast
also have "… = ((∀q∈ set ?yes. Ifm vs bs q) ∧ (∀q∈ set ?no. Ifm vs bs q))"
using partition_set[OF part] by auto
finally have "Ifm vs bs p = ((Ifm vs bs ?cyes) ∧ (Ifm vs bs ?cno))" using list_conj[of vs bs] by simp}
hence "Ifm vs bs (E p) = (∃x. (Ifm vs (x#bs) ?cyes) ∧ (Ifm vs (x#bs) ?cno))" by simp
also have "… = (∃x. (Ifm vs (y#bs) ?cyes) ∧ (Ifm vs (x#bs) ?cno))"
using bound0_I[OF yes_nb, where bs="bs" and b'="y"] by blast
also have "… = (Ifm vs bs (decr0 ?cyes) ∧ Ifm vs bs (E ?cno))"
by (auto simp add: decr0[OF yes_nb] simp del: partition_filter_conv)
also have "… = (Ifm vs bs (conj (decr0 ?cyes) (qe ?cno)))"
using qe[rule_format, OF no_qf] by auto
finally have "Ifm vs bs (E p) = Ifm vs bs (CJNB qe p)"
by (simp add: Let_def CJNB_def split_def)
with qf show "qfree (CJNB qe p) ∧ Ifm vs bs (CJNB qe p) = Ifm vs bs (E p)" by blast
qed
consts simpfm :: "fm => fm"
recdef simpfm "measure fmsize"
"simpfm (Lt t) = simplt (simptm t)"
"simpfm (Le t) = simple (simptm t)"
"simpfm (Eq t) = simpeq(simptm t)"
"simpfm (NEq t) = simpneq(simptm t)"
"simpfm (And p q) = conj (simpfm p) (simpfm q)"
"simpfm (Or p q) = disj (simpfm p) (simpfm q)"
"simpfm (Imp p q) = disj (simpfm (NOT p)) (simpfm q)"
"simpfm (Iff p q) = disj (conj (simpfm p) (simpfm q)) (conj (simpfm (NOT p)) (simpfm (NOT q)))"
"simpfm (NOT (And p q)) = disj (simpfm (NOT p)) (simpfm (NOT q))"
"simpfm (NOT (Or p q)) = conj (simpfm (NOT p)) (simpfm (NOT q))"
"simpfm (NOT (Imp p q)) = conj (simpfm p) (simpfm (NOT q))"
"simpfm (NOT (Iff p q)) = disj (conj (simpfm p) (simpfm (NOT q))) (conj (simpfm (NOT p)) (simpfm q))"
"simpfm (NOT (Eq t)) = simpneq t"
"simpfm (NOT (NEq t)) = simpeq t"
"simpfm (NOT (Le t)) = simplt (Neg t)"
"simpfm (NOT (Lt t)) = simple (Neg t)"
"simpfm (NOT (NOT p)) = simpfm p"
"simpfm (NOT T) = F"
"simpfm (NOT F) = T"
"simpfm p = p"
lemma simpfm[simp]: "Ifm vs bs (simpfm p) = Ifm vs bs p"
by(induct p arbitrary: bs rule: simpfm.induct, auto)
lemma simpfm_bound0: assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
shows "bound0 p ==> bound0 (simpfm p)"
by (induct p rule: simpfm.induct, auto)
lemma lt_qf[simp]: "qfree (lt t)"
apply (cases t, auto simp add: lt_def)
by (case_tac poly, auto)
lemma le_qf[simp]: "qfree (le t)"
apply (cases t, auto simp add: le_def)
by (case_tac poly, auto)
lemma eq_qf[simp]: "qfree (eq t)"
apply (cases t, auto simp add: eq_def)
by (case_tac poly, auto)
lemma neq_qf[simp]: "qfree (neq t)" by (simp add: neq_def)
lemma simplt_qf[simp]: "qfree (simplt t)" by (simp add: simplt_def Let_def split_def)
lemma simple_qf[simp]: "qfree (simple t)" by (simp add: simple_def Let_def split_def)
lemma simpeq_qf[simp]: "qfree (simpeq t)" by (simp add: simpeq_def Let_def split_def)
lemma simpneq_qf[simp]: "qfree (simpneq t)" by (simp add: simpneq_def Let_def split_def)
lemma simpfm_qf[simp]: "qfree p ==> qfree (simpfm p)"
by (induct p rule: simpfm.induct, auto simp add: disj_qf imp_qf iff_qf conj_qf not_qf Let_def)
lemma disj_lin: "islin p ==> islin q ==> islin (disj p q)" by (simp add: disj_def)
lemma conj_lin: "islin p ==> islin q ==> islin (conj p q)" by (simp add: conj_def)
lemma assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
shows "qfree p ==> islin (simpfm p)"
apply (induct p rule: simpfm.induct)
apply (simp_all add: conj_lin disj_lin)
done
consts prep :: "fm => fm"
recdef prep "measure fmsize"
"prep (E T) = T"
"prep (E F) = F"
"prep (E (Or p q)) = disj (prep (E p)) (prep (E q))"
"prep (E (Imp p q)) = disj (prep (E (NOT p))) (prep (E q))"
"prep (E (Iff p q)) = disj (prep (E (And p q))) (prep (E (And (NOT p) (NOT q))))"
"prep (E (NOT (And p q))) = disj (prep (E (NOT p))) (prep (E(NOT q)))"
"prep (E (NOT (Imp p q))) = prep (E (And p (NOT q)))"
"prep (E (NOT (Iff p q))) = disj (prep (E (And p (NOT q)))) (prep (E(And (NOT p) q)))"
"prep (E p) = E (prep p)"
"prep (A (And p q)) = conj (prep (A p)) (prep (A q))"
"prep (A p) = prep (NOT (E (NOT p)))"
"prep (NOT (NOT p)) = prep p"
"prep (NOT (And p q)) = disj (prep (NOT p)) (prep (NOT q))"
"prep (NOT (A p)) = prep (E (NOT p))"
"prep (NOT (Or p q)) = conj (prep (NOT p)) (prep (NOT q))"
"prep (NOT (Imp p q)) = conj (prep p) (prep (NOT q))"
"prep (NOT (Iff p q)) = disj (prep (And p (NOT q))) (prep (And (NOT p) q))"
"prep (NOT p) = not (prep p)"
"prep (Or p q) = disj (prep p) (prep q)"
"prep (And p q) = conj (prep p) (prep q)"
"prep (Imp p q) = prep (Or (NOT p) q)"
"prep (Iff p q) = disj (prep (And p q)) (prep (And (NOT p) (NOT q)))"
"prep p = p"
(hints simp add: fmsize_pos)
lemma prep: "Ifm vs bs (prep p) = Ifm vs bs p"
by (induct p arbitrary: bs rule: prep.induct, auto)
(* Generic quantifier elimination *)
function (sequential) qelim :: "fm => (fm => fm) => fm" where
"qelim (E p) = (λ qe. DJ (CJNB qe) (qelim p qe))"
| "qelim (A p) = (λ qe. not (qe ((qelim (NOT p) qe))))"
| "qelim (NOT p) = (λ qe. not (qelim p qe))"
| "qelim (And p q) = (λ qe. conj (qelim p qe) (qelim q qe))"
| "qelim (Or p q) = (λ qe. disj (qelim p qe) (qelim q qe))"
| "qelim (Imp p q) = (λ qe. imp (qelim p qe) (qelim q qe))"
| "qelim (Iff p q) = (λ qe. iff (qelim p qe) (qelim q qe))"
| "qelim p = (λ y. simpfm p)"
by pat_completeness simp_all
termination by (relation "measure fmsize") auto
lemma qelim:
assumes qe_inv: "∀ bs p. qfree p --> qfree (qe p) ∧ (Ifm vs bs (qe p) = Ifm vs bs (E p))"
shows "!! bs. qfree (qelim p qe) ∧ (Ifm vs bs (qelim p qe) = Ifm vs bs p)"
using qe_inv DJ_qe[OF CJNB_qe[OF qe_inv]]
by (induct p rule: qelim.induct) auto
subsection{* Core Procedure *}
fun minusinf:: "fm => fm" (* Virtual substitution of -∞*) where
"minusinf (And p q) = conj (minusinf p) (minusinf q)"
| "minusinf (Or p q) = disj (minusinf p) (minusinf q)"
| "minusinf (Eq (CNP 0 c e)) = conj (eq (CP c)) (eq e)"
| "minusinf (NEq (CNP 0 c e)) = disj (not (eq e)) (not (eq (CP c)))"
| "minusinf (Lt (CNP 0 c e)) = disj (conj (eq (CP c)) (lt e)) (lt (CP (~⇩p c)))"
| "minusinf (Le (CNP 0 c e)) = disj (conj (eq (CP c)) (le e)) (lt (CP (~⇩p c)))"
| "minusinf p = p"
fun plusinf:: "fm => fm" (* Virtual substitution of +∞*) where
"plusinf (And p q) = conj (plusinf p) (plusinf q)"
| "plusinf (Or p q) = disj (plusinf p) (plusinf q)"
| "plusinf (Eq (CNP 0 c e)) = conj (eq (CP c)) (eq e)"
| "plusinf (NEq (CNP 0 c e)) = disj (not (eq e)) (not (eq (CP c)))"
| "plusinf (Lt (CNP 0 c e)) = disj (conj (eq (CP c)) (lt e)) (lt (CP c))"
| "plusinf (Le (CNP 0 c e)) = disj (conj (eq (CP c)) (le e)) (lt (CP c))"
| "plusinf p = p"
lemma minusinf_inf: assumes lp:"islin p"
shows "∃z. ∀x < z. Ifm vs (x#bs) (minusinf p) <-> Ifm vs (x#bs) p"
using lp
proof (induct p rule: minusinf.induct)
case 1 thus ?case by (auto,rule_tac x="min z za" in exI, auto)
next
case 2 thus ?case by (auto,rule_tac x="min z za" in exI, auto)
next
case (3 c e) hence nbe: "tmbound0 e" by simp
from 3 have nc: "allpolys isnpoly (CP c)" "allpolys isnpoly e" by simp_all
note eqs = eq[OF nc(1), where ?'a = 'a] eq[OF nc(2), where ?'a = 'a]
let ?c = "Ipoly vs c"
let ?e = "Itm vs (y#bs) e"
have "?c=0 ∨ ?c > 0 ∨ ?c < 0" by arith
moreover {assume "?c = 0" hence ?case
using eq[OF nc(2), of vs] eq[OF nc(1), of vs] by auto}
moreover {assume cp: "?c > 0"
{fix x assume xz: "x < -?e / ?c" hence "?c * x < - ?e"
using pos_less_divide_eq[OF cp, where a="x" and b="-?e"] by (simp add: mult_commute)
hence "?c * x + ?e < 0" by simp
hence "Ifm vs (x#bs) (Eq (CNP 0 c e)) = Ifm vs (x#bs) (minusinf (Eq (CNP 0 c e)))"
using eqs tmbound0_I[OF nbe, where b="y" and b'="x" and vs=vs and bs=bs] by auto} hence ?case by auto}
moreover {assume cp: "?c < 0"
{fix x assume xz: "x < -?e / ?c" hence "?c * x > - ?e"
using neg_less_divide_eq[OF cp, where a="x" and b="-?e"] by (simp add: mult_commute)
hence "?c * x + ?e > 0" by simp
hence "Ifm vs (x#bs) (Eq (CNP 0 c e)) = Ifm vs (x#bs) (minusinf (Eq (CNP 0 c e)))"
using tmbound0_I[OF nbe, where b="y" and b'="x"] eqs by auto} hence ?case by auto}
ultimately show ?case by blast
next
case (4 c e) hence nbe: "tmbound0 e" by simp
from 4 have nc: "allpolys isnpoly (CP c)" "allpolys isnpoly e" by simp_all
note eqs = eq[OF nc(1), where ?'a = 'a] eq[OF nc(2), where ?'a = 'a]
let ?c = "Ipoly vs c"
let ?e = "Itm vs (y#bs) e"
have "?c=0 ∨ ?c > 0 ∨ ?c < 0" by arith
moreover {assume "?c = 0" hence ?case using eqs by auto}
moreover {assume cp: "?c > 0"
{fix x assume xz: "x < -?e / ?c" hence "?c * x < - ?e"
using pos_less_divide_eq[OF cp, where a="x" and b="-?e"] by (simp add: mult_commute)
hence "?c * x + ?e < 0" by simp
hence "Ifm vs (x#bs) (NEq (CNP 0 c e)) = Ifm vs (x#bs) (minusinf (NEq (CNP 0 c e)))"
using eqs tmbound0_I[OF nbe, where b="y" and b'="x"] by auto} hence ?case by auto}
moreover {assume cp: "?c < 0"
{fix x assume xz: "x < -?e / ?c" hence "?c * x > - ?e"
using neg_less_divide_eq[OF cp, where a="x" and b="-?e"] by (simp add: mult_commute)
hence "?c * x + ?e > 0" by simp
hence "Ifm vs (x#bs) (NEq (CNP 0 c e)) = Ifm vs (x#bs) (minusinf (NEq (CNP 0 c e)))"
using eqs tmbound0_I[OF nbe, where b="y" and b'="x"] by auto} hence ?case by auto}
ultimately show ?case by blast
next
case (5 c e) hence nbe: "tmbound0 e" by simp
from 5 have nc: "allpolys isnpoly (CP c)" "allpolys isnpoly e" by simp_all
hence nc': "allpolys isnpoly (CP (~⇩p c))" by (simp add: polyneg_norm)
note eqs = lt[OF nc', where ?'a = 'a] eq [OF nc(1), where ?'a = 'a] lt[OF nc(2), where ?'a = 'a]
let ?c = "Ipoly vs c"
let ?e = "Itm vs (y#bs) e"
have "?c=0 ∨ ?c > 0 ∨ ?c < 0" by arith
moreover {assume "?c = 0" hence ?case using eqs by auto}
moreover {assume cp: "?c > 0"
{fix x assume xz: "x < -?e / ?c" hence "?c * x < - ?e"
using pos_less_divide_eq[OF cp, where a="x" and b="-?e"] by (simp add: mult_commute)
hence "?c * x + ?e < 0" by simp
hence "Ifm vs (x#bs) (Lt (CNP 0 c e)) = Ifm vs (x#bs) (minusinf (Lt (CNP 0 c e)))"
using tmbound0_I[OF nbe, where b="y" and b'="x"] cp eqs by auto} hence ?case by auto}
moreover {assume cp: "?c < 0"
{fix x assume xz: "x < -?e / ?c" hence "?c * x > - ?e"
using neg_less_divide_eq[OF cp, where a="x" and b="-?e"] by (simp add: mult_commute)
hence "?c * x + ?e > 0" by simp
hence "Ifm vs (x#bs) (Lt (CNP 0 c e)) = Ifm vs (x#bs) (minusinf (Lt (CNP 0 c e)))"
using eqs tmbound0_I[OF nbe, where b="y" and b'="x"] cp by auto} hence ?case by auto}
ultimately show ?case by blast
next
case (6 c e) hence nbe: "tmbound0 e" by simp
from 6 have nc: "allpolys isnpoly (CP c)" "allpolys isnpoly e" by simp_all
hence nc': "allpolys isnpoly (CP (~⇩p c))" by (simp add: polyneg_norm)
note eqs = lt[OF nc', where ?'a = 'a] eq [OF nc(1), where ?'a = 'a] le[OF nc(2), where ?'a = 'a]
let ?c = "Ipoly vs c"
let ?e = "Itm vs (y#bs) e"
have "?c=0 ∨ ?c > 0 ∨ ?c < 0" by arith
moreover {assume "?c = 0" hence ?case using eqs by auto}
moreover {assume cp: "?c > 0"
{fix x assume xz: "x < -?e / ?c" hence "?c * x < - ?e"
using pos_less_divide_eq[OF cp, where a="x" and b="-?e"] by (simp add: mult_commute)
hence "?c * x + ?e < 0" by simp
hence "Ifm vs (x#bs) (Le (CNP 0 c e)) = Ifm vs (x#bs) (minusinf (Le (CNP 0 c e)))"
using tmbound0_I[OF nbe, where b="y" and b'="x"] cp eqs by auto} hence ?case by auto}
moreover {assume cp: "?c < 0"
{fix x assume xz: "x < -?e / ?c" hence "?c * x > - ?e"
using neg_less_divide_eq[OF cp, where a="x" and b="-?e"] by (simp add: mult_commute)
hence "?c * x + ?e > 0" by simp
hence "Ifm vs (x#bs) (Le (CNP 0 c e)) = Ifm vs (x#bs) (minusinf (Le (CNP 0 c e)))"
using tmbound0_I[OF nbe, where b="y" and b'="x"] cp eqs by auto} hence ?case by auto}
ultimately show ?case by blast
qed (auto)
lemma plusinf_inf: assumes lp:"islin p"
shows "∃z. ∀x > z. Ifm vs (x#bs) (plusinf p) <-> Ifm vs (x#bs) p"
using lp
proof (induct p rule: plusinf.induct)
case 1 thus ?case by (auto,rule_tac x="max z za" in exI, auto)
next
case 2 thus ?case by (auto,rule_tac x="max z za" in exI, auto)
next
case (3 c e) hence nbe: "tmbound0 e" by simp
from 3 have nc: "allpolys isnpoly (CP c)" "allpolys isnpoly e" by simp_all
note eqs = eq[OF nc(1), where ?'a = 'a] eq[OF nc(2), where ?'a = 'a]
let ?c = "Ipoly vs c"
let ?e = "Itm vs (y#bs) e"
have "?c=0 ∨ ?c > 0 ∨ ?c < 0" by arith
moreover {assume "?c = 0" hence ?case
using eq[OF nc(2), of vs] eq[OF nc(1), of vs] by auto}
moreover {assume cp: "?c > 0"
{fix x assume xz: "x > -?e / ?c" hence "?c * x > - ?e"
using pos_divide_less_eq[OF cp, where a="x" and b="-?e"] by (simp add: mult_commute)
hence "?c * x + ?e > 0" by simp
hence "Ifm vs (x#bs) (Eq (CNP 0 c e)) = Ifm vs (x#bs) (plusinf (Eq (CNP 0 c e)))"
using eqs tmbound0_I[OF nbe, where b="y" and b'="x" and vs=vs and bs=bs] by auto} hence ?case by auto}
moreover {assume cp: "?c < 0"
{fix x assume xz: "x > -?e / ?c" hence "?c * x < - ?e"
using neg_divide_less_eq[OF cp, where a="x" and b="-?e"] by (simp add: mult_commute)
hence "?c * x + ?e < 0" by simp
hence "Ifm vs (x#bs) (Eq (CNP 0 c e)) = Ifm vs (x#bs) (plusinf (Eq (CNP 0 c e)))"
using tmbound0_I[OF nbe, where b="y" and b'="x"] eqs by auto} hence ?case by auto}
ultimately show ?case by blast
next
case (4 c e) hence nbe: "tmbound0 e" by simp
from 4 have nc: "allpolys isnpoly (CP c)" "allpolys isnpoly e" by simp_all
note eqs = eq[OF nc(1), where ?'a = 'a] eq[OF nc(2), where ?'a = 'a]
let ?c = "Ipoly vs c"
let ?e = "Itm vs (y#bs) e"
have "?c=0 ∨ ?c > 0 ∨ ?c < 0" by arith
moreover {assume "?c = 0" hence ?case using eqs by auto}
moreover {assume cp: "?c > 0"
{fix x assume xz: "x > -?e / ?c" hence "?c * x > - ?e"
using pos_divide_less_eq[OF cp, where a="x" and b="-?e"] by (simp add: mult_commute)
hence "?c * x + ?e > 0" by simp
hence "Ifm vs (x#bs) (NEq (CNP 0 c e)) = Ifm vs (x#bs) (plusinf (NEq (CNP 0 c e)))"
using eqs tmbound0_I[OF nbe, where b="y" and b'="x"] by auto} hence ?case by auto}
moreover {assume cp: "?c < 0"
{fix x assume xz: "x > -?e / ?c" hence "?c * x < - ?e"
using neg_divide_less_eq[OF cp, where a="x" and b="-?e"] by (simp add: mult_commute)
hence "?c * x + ?e < 0" by simp
hence "Ifm vs (x#bs) (NEq (CNP 0 c e)) = Ifm vs (x#bs) (plusinf (NEq (CNP 0 c e)))"
using eqs tmbound0_I[OF nbe, where b="y" and b'="x"] by auto} hence ?case by auto}
ultimately show ?case by blast
next
case (5 c e) hence nbe: "tmbound0 e" by simp
from 5 have nc: "allpolys isnpoly (CP c)" "allpolys isnpoly e" by simp_all
hence nc': "allpolys isnpoly (CP (~⇩p c))" by (simp add: polyneg_norm)
note eqs = lt[OF nc(1), where ?'a = 'a] lt[OF nc', where ?'a = 'a] eq [OF nc(1), where ?'a = 'a] lt[OF nc(2), where ?'a = 'a]
let ?c = "Ipoly vs c"
let ?e = "Itm vs (y#bs) e"
have "?c=0 ∨ ?c > 0 ∨ ?c < 0" by arith
moreover {assume "?c = 0" hence ?case using eqs by auto}
moreover {assume cp: "?c > 0"
{fix x assume xz: "x > -?e / ?c" hence "?c * x > - ?e"
using pos_divide_less_eq[OF cp, where a="x" and b="-?e"] by (simp add: mult_commute)
hence "?c * x + ?e > 0" by simp
hence "Ifm vs (x#bs) (Lt (CNP 0 c e)) = Ifm vs (x#bs) (plusinf (Lt (CNP 0 c e)))"
using tmbound0_I[OF nbe, where b="y" and b'="x"] cp eqs by auto} hence ?case by auto}
moreover {assume cp: "?c < 0"
{fix x assume xz: "x > -?e / ?c" hence "?c * x < - ?e"
using neg_divide_less_eq[OF cp, where a="x" and b="-?e"] by (simp add: mult_commute)
hence "?c * x + ?e < 0" by simp
hence "Ifm vs (x#bs) (Lt (CNP 0 c e)) = Ifm vs (x#bs) (plusinf (Lt (CNP 0 c e)))"
using eqs tmbound0_I[OF nbe, where b="y" and b'="x"] cp by auto} hence ?case by auto}
ultimately show ?case by blast
next
case (6 c e) hence nbe: "tmbound0 e" by simp
from 6 have nc: "allpolys isnpoly (CP c)" "allpolys isnpoly e" by simp_all
hence nc': "allpolys isnpoly (CP (~⇩p c))" by (simp add: polyneg_norm)
note eqs = lt[OF nc(1), where ?'a = 'a] eq [OF nc(1), where ?'a = 'a] le[OF nc(2), where ?'a = 'a]
let ?c = "Ipoly vs c"
let ?e = "Itm vs (y#bs) e"
have "?c=0 ∨ ?c > 0 ∨ ?c < 0" by arith
moreover {assume "?c = 0" hence ?case using eqs by auto}
moreover {assume cp: "?c > 0"
{fix x assume xz: "x > -?e / ?c" hence "?c * x > - ?e"
using pos_divide_less_eq[OF cp, where a="x" and b="-?e"] by (simp add: mult_commute)
hence "?c * x + ?e > 0" by simp
hence "Ifm vs (x#bs) (Le (CNP 0 c e)) = Ifm vs (x#bs) (plusinf (Le (CNP 0 c e)))"
using tmbound0_I[OF nbe, where b="y" and b'="x"] cp eqs by auto} hence ?case by auto}
moreover {assume cp: "?c < 0"
{fix x assume xz: "x > -?e / ?c" hence "?c * x < - ?e"
using neg_divide_less_eq[OF cp, where a="x" and b="-?e"] by (simp add: mult_commute)
hence "?c * x + ?e < 0" by simp
hence "Ifm vs (x#bs) (Le (CNP 0 c e)) = Ifm vs (x#bs) (plusinf (Le (CNP 0 c e)))"
using tmbound0_I[OF nbe, where b="y" and b'="x"] cp eqs by auto} hence ?case by auto}
ultimately show ?case by blast
qed (auto)
lemma minusinf_nb: "islin p ==> bound0 (minusinf p)"
by (induct p rule: minusinf.induct, auto simp add: eq_nb lt_nb le_nb)
lemma plusinf_nb: "islin p ==> bound0 (plusinf p)"
by (induct p rule: minusinf.induct, auto simp add: eq_nb lt_nb le_nb)
lemma minusinf_ex: assumes lp: "islin p" and ex: "Ifm vs (x#bs) (minusinf p)"
shows "∃x. Ifm vs (x#bs) p"
proof-
from bound0_I [OF minusinf_nb[OF lp], where b="a" and bs ="bs"] ex
have th: "∀ x. Ifm vs (x#bs) (minusinf p)" by auto
from minusinf_inf[OF lp, where bs="bs"]
obtain z where z_def: "∀x<z. Ifm vs (x # bs) (minusinf p) = Ifm vs (x # bs) p" by blast
from th have "Ifm vs ((z - 1)#bs) (minusinf p)" by simp
moreover have "z - 1 < z" by simp
ultimately show ?thesis using z_def by auto
qed
lemma plusinf_ex: assumes lp: "islin p" and ex: "Ifm vs (x#bs) (plusinf p)"
shows "∃x. Ifm vs (x#bs) p"
proof-
from bound0_I [OF plusinf_nb[OF lp], where b="a" and bs ="bs"] ex
have th: "∀ x. Ifm vs (x#bs) (plusinf p)" by auto
from plusinf_inf[OF lp, where bs="bs"]
obtain z where z_def: "∀x>z. Ifm vs (x # bs) (plusinf p) = Ifm vs (x # bs) p" by blast
from th have "Ifm vs ((z + 1)#bs) (plusinf p)" by simp
moreover have "z + 1 > z" by simp
ultimately show ?thesis using z_def by auto
qed
fun uset :: "fm => (poly × tm) list" where
"uset (And p q) = uset p @ uset q"
| "uset (Or p q) = uset p @ uset q"
| "uset (Eq (CNP 0 a e)) = [(a,e)]"
| "uset (Le (CNP 0 a e)) = [(a,e)]"
| "uset (Lt (CNP 0 a e)) = [(a,e)]"
| "uset (NEq (CNP 0 a e)) = [(a,e)]"
| "uset p = []"
lemma uset_l:
assumes lp: "islin p"
shows "∀ (c,s) ∈ set (uset p). isnpoly c ∧ c ≠ 0⇩p ∧ tmbound0 s ∧ allpolys isnpoly s"
using lp by(induct p rule: uset.induct,auto)
lemma minusinf_uset0:
assumes lp: "islin p"
and nmi: "¬ (Ifm vs (x#bs) (minusinf p))"
and ex: "Ifm vs (x#bs) p" (is "?I x p")
shows "∃ (c,s) ∈ set (uset p). x ≥ - Itm vs (x#bs) s / Ipoly vs c"
proof-
have "∃ (c,s) ∈ set (uset p). (Ipoly vs c < 0 ∧ Ipoly vs c * x ≤ - Itm vs (x#bs) s) ∨ (Ipoly vs c > 0 ∧ Ipoly vs c * x ≥ - Itm vs (x#bs) s)"
using lp nmi ex
apply (induct p rule: minusinf.induct, auto simp add: eq le lt polyneg_norm)
apply (auto simp add: linorder_not_less order_le_less)
done
then obtain c s where csU: "(c,s) ∈ set (uset p)" and x: "(Ipoly vs c < 0 ∧ Ipoly vs c * x ≤ - Itm vs (x#bs) s) ∨ (Ipoly vs c > 0 ∧ Ipoly vs c * x ≥ - Itm vs (x#bs) s)" by blast
hence "x ≥ (- Itm vs (x#bs) s) / Ipoly vs c"
using divide_le_eq[of "- Itm vs (x#bs) s" "Ipoly vs c" x]
by (auto simp add: mult_commute del: divide_minus_left)
thus ?thesis using csU by auto
qed
lemma minusinf_uset:
assumes lp: "islin p"
and nmi: "¬ (Ifm vs (a#bs) (minusinf p))"
and ex: "Ifm vs (x#bs) p" (is "?I x p")
shows "∃ (c,s) ∈ set (uset p). x ≥ - Itm vs (a#bs) s / Ipoly vs c"
proof-
from nmi have nmi': "¬ (Ifm vs (x#bs) (minusinf p))"
by (simp add: bound0_I[OF minusinf_nb[OF lp], where b=x and b'=a])
from minusinf_uset0[OF lp nmi' ex]
obtain c s where csU: "(c,s) ∈ set (uset p)" and th: "x ≥ - Itm vs (x#bs) s / Ipoly vs c" by blast
from uset_l[OF lp, rule_format, OF csU] have nb: "tmbound0 s" by simp
from th tmbound0_I[OF nb, of vs x bs a] csU show ?thesis by auto
qed
lemma plusinf_uset0:
assumes lp: "islin p"
and nmi: "¬ (Ifm vs (x#bs) (plusinf p))"
and ex: "Ifm vs (x#bs) p" (is "?I x p")
shows "∃ (c,s) ∈ set (uset p). x ≤ - Itm vs (x#bs) s / Ipoly vs c"
proof-
have "∃ (c,s) ∈ set (uset p). (Ipoly vs c < 0 ∧ Ipoly vs c * x ≥ - Itm vs (x#bs) s) ∨ (Ipoly vs c > 0 ∧ Ipoly vs c * x ≤ - Itm vs (x#bs) s)"
using lp nmi ex
apply (induct p rule: minusinf.induct, auto simp add: eq le lt polyneg_norm)
apply (auto simp add: linorder_not_less order_le_less)
done
then obtain c s where csU: "(c,s) ∈ set (uset p)" and x: "(Ipoly vs c < 0 ∧ Ipoly vs c * x ≥ - Itm vs (x#bs) s) ∨ (Ipoly vs c > 0 ∧ Ipoly vs c * x ≤ - Itm vs (x#bs) s)" by blast
hence "x ≤ (- Itm vs (x#bs) s) / Ipoly vs c"
using le_divide_eq[of x "- Itm vs (x#bs) s" "Ipoly vs c"]
by (auto simp add: mult_commute del: divide_minus_left)
thus ?thesis using csU by auto
qed
lemma plusinf_uset:
assumes lp: "islin p"
and nmi: "¬ (Ifm vs (a#bs) (plusinf p))"
and ex: "Ifm vs (x#bs) p" (is "?I x p")
shows "∃ (c,s) ∈ set (uset p). x ≤ - Itm vs (a#bs) s / Ipoly vs c"
proof-
from nmi have nmi': "¬ (Ifm vs (x#bs) (plusinf p))"
by (simp add: bound0_I[OF plusinf_nb[OF lp], where b=x and b'=a])
from plusinf_uset0[OF lp nmi' ex]
obtain c s where csU: "(c,s) ∈ set (uset p)" and th: "x ≤ - Itm vs (x#bs) s / Ipoly vs c" by blast
from uset_l[OF lp, rule_format, OF csU] have nb: "tmbound0 s" by simp
from th tmbound0_I[OF nb, of vs x bs a] csU show ?thesis by auto
qed
lemma lin_dense:
assumes lp: "islin p"
and noS: "∀ t. l < t ∧ t< u --> t ∉ (λ (c,t). - Itm vs (x#bs) t / Ipoly vs c) ` set (uset p)"
(is "∀ t. _ ∧ _ --> t ∉ (λ (c,t). - ?Nt x t / ?N c) ` ?U p")
and lx: "l < x" and xu:"x < u" and px:" Ifm vs (x#bs) p"
and ly: "l < y" and yu: "y < u"
shows "Ifm vs (y#bs) p"
using lp px noS
proof (induct p rule: islin.induct)
case (5 c s)
from "5.prems"
have lin: "isnpoly c" "c ≠ 0⇩p" "tmbound0 s" "allpolys isnpoly s"
and px: "Ifm vs (x # bs) (Lt (CNP 0 c s))"
and noS: "∀t. l < t ∧ t < u --> t ≠ - Itm vs (x # bs) s / (|c|)),⇩p⇗vs⇖" by simp_all
from ly yu noS have yne: "y ≠ - ?Nt x s / (|c|)),⇩p⇗vs⇖" by simp
hence ycs: "y < - ?Nt x s / ?N c ∨ y > -?Nt x s / ?N c" by auto
have ccs: "?N c = 0 ∨ ?N c < 0 ∨ ?N c > 0" by dlo
moreover
{assume "?N c = 0" hence ?case using px by (simp add: tmbound0_I[OF lin(3), where bs="bs" and b="x" and b'="y"])}
moreover
{assume c: "?N c > 0"
from px pos_less_divide_eq[OF c, where a="x" and b="-?Nt x s"]
have px': "x < - ?Nt x s / ?N c"
by (auto simp add: not_less field_simps)
{assume y: "y < - ?Nt x s / ?N c"
hence "y * ?N c < - ?Nt x s"
by (simp add: pos_less_divide_eq[OF c, where a="y" and b="-?Nt x s", symmetric])
hence "?N c * y + ?Nt x s < 0" by (simp add: field_simps)
hence ?case using tmbound0_I[OF lin(3), where bs="bs" and b="x" and b'="y"] by simp}
moreover
{assume y: "y > -?Nt x s / ?N c"
with yu have eu: "u > - ?Nt x s / ?N c" by auto
with noS ly yu have th: "- ?Nt x s / ?N c ≤ l" by (cases "- ?Nt x s / ?N c > l", auto)
with lx px' have "False" by simp hence ?case by simp }
ultimately have ?case using ycs by blast
}
moreover
{assume c: "?N c < 0"
from px neg_divide_less_eq[OF c, where a="x" and b="-?Nt x s"]
have px': "x > - ?Nt x s / ?N c"
by (auto simp add: not_less field_simps)
{assume y: "y > - ?Nt x s / ?N c"
hence "y * ?N c < - ?Nt x s"
by (simp add: neg_divide_less_eq[OF c, where a="y" and b="-?Nt x s", symmetric])
hence "?N c * y + ?Nt x s < 0" by (simp add: field_simps)
hence ?case using tmbound0_I[OF lin(3), where bs="bs" and b="x" and b'="y"] by simp}
moreover
{assume y: "y < -?Nt x s / ?N c"
with ly have eu: "l < - ?Nt x s / ?N c" by auto
with noS ly yu have th: "- ?Nt x s / ?N c ≥ u" by (cases "- ?Nt x s / ?N c < u", auto)
with xu px' have "False" by simp hence ?case by simp }
ultimately have ?case using ycs by blast
}
ultimately show ?case by blast
next
case (6 c s)
from "6.prems"
have lin: "isnpoly c" "c ≠ 0⇩p" "tmbound0 s" "allpolys isnpoly s"
and px: "Ifm vs (x # bs) (Le (CNP 0 c s))"
and noS: "∀t. l < t ∧ t < u --> t ≠ - Itm vs (x # bs) s / (|c|)),⇩p⇗vs⇖" by simp_all
from ly yu noS have yne: "y ≠ - ?Nt x s / (|c|)),⇩p⇗vs⇖" by simp
hence ycs: "y < - ?Nt x s / ?N c ∨ y > -?Nt x s / ?N c" by auto
have ccs: "?N c = 0 ∨ ?N c < 0 ∨ ?N c > 0" by dlo
moreover
{assume "?N c = 0" hence ?case using px by (simp add: tmbound0_I[OF lin(3), where bs="bs" and b="x" and b'="y"])}
moreover
{assume c: "?N c > 0"
from px pos_le_divide_eq[OF c, where a="x" and b="-?Nt x s"]
have px': "x <= - ?Nt x s / ?N c" by (simp add: not_less field_simps)
{assume y: "y < - ?Nt x s / ?N c"
hence "y * ?N c < - ?Nt x s"
by (simp add: pos_less_divide_eq[OF c, where a="y" and b="-?Nt x s", symmetric])
hence "?N c * y + ?Nt x s < 0" by (simp add: field_simps)
hence ?case using tmbound0_I[OF lin(3), where bs="bs" and b="x" and b'="y"] by simp}
moreover
{assume y: "y > -?Nt x s / ?N c"
with yu have eu: "u > - ?Nt x s / ?N c" by auto
with noS ly yu have th: "- ?Nt x s / ?N c ≤ l" by (cases "- ?Nt x s / ?N c > l", auto)
with lx px' have "False" by simp hence ?case by simp }
ultimately have ?case using ycs by blast
}
moreover
{assume c: "?N c < 0"
from px neg_divide_le_eq[OF c, where a="x" and b="-?Nt x s"]
have px': "x >= - ?Nt x s / ?N c" by (simp add: field_simps)
{assume y: "y > - ?Nt x s / ?N c"
hence "y * ?N c < - ?Nt x s"
by (simp add: neg_divide_less_eq[OF c, where a="y" and b="-?Nt x s", symmetric])
hence "?N c * y + ?Nt x s < 0" by (simp add: field_simps)
hence ?case using tmbound0_I[OF lin(3), where bs="bs" and b="x" and b'="y"] by simp}
moreover
{assume y: "y < -?Nt x s / ?N c"
with ly have eu: "l < - ?Nt x s / ?N c" by auto
with noS ly yu have th: "- ?Nt x s / ?N c ≥ u" by (cases "- ?Nt x s / ?N c < u", auto)
with xu px' have "False" by simp hence ?case by simp }
ultimately have ?case using ycs by blast
}
ultimately show ?case by blast
next
case (3 c s)
from "3.prems"
have lin: "isnpoly c" "c ≠ 0⇩p" "tmbound0 s" "allpolys isnpoly s"
and px: "Ifm vs (x # bs) (Eq (CNP 0 c s))"
and noS: "∀t. l < t ∧ t < u --> t ≠ - Itm vs (x # bs) s / (|c|)),⇩p⇗vs⇖" by simp_all
from ly yu noS have yne: "y ≠ - ?Nt x s / (|c|)),⇩p⇗vs⇖" by simp
hence ycs: "y < - ?Nt x s / ?N c ∨ y > -?Nt x s / ?N c" by auto
have ccs: "?N c = 0 ∨ ?N c < 0 ∨ ?N c > 0" by dlo
moreover
{assume "?N c = 0" hence ?case using px by (simp add: tmbound0_I[OF lin(3), where bs="bs" and b="x" and b'="y"])}
moreover
{assume c: "?N c > 0" hence cnz: "?N c ≠ 0" by simp
from px eq_divide_eq[of "x" "-?Nt x s" "?N c"] cnz
have px': "x = - ?Nt x s / ?N c" by (simp add: field_simps)
{assume y: "y < -?Nt x s / ?N c"
with ly have eu: "l < - ?Nt x s / ?N c" by auto
with noS ly yu have th: "- ?Nt x s / ?N c ≥ u" by (cases "- ?Nt x s / ?N c < u", auto)
with xu px' have "False" by simp hence ?case by simp }
moreover
{assume y: "y > -?Nt x s / ?N c"
with yu have eu: "u > - ?Nt x s / ?N c" by auto
with noS ly yu have th: "- ?Nt x s / ?N c ≤ l" by (cases "- ?Nt x s / ?N c > l", auto)
with lx px' have "False" by simp hence ?case by simp }
ultimately have ?case using ycs by blast
}
moreover
{assume c: "?N c < 0" hence cnz: "?N c ≠ 0" by simp
from px eq_divide_eq[of "x" "-?Nt x s" "?N c"] cnz
have px': "x = - ?Nt x s / ?N c" by (simp add: field_simps)
{assume y: "y < -?Nt x s / ?N c"
with ly have eu: "l < - ?Nt x s / ?N c" by auto
with noS ly yu have th: "- ?Nt x s / ?N c ≥ u" by (cases "- ?Nt x s / ?N c < u", auto)
with xu px' have "False" by simp hence ?case by simp }
moreover
{assume y: "y > -?Nt x s / ?N c"
with yu have eu: "u > - ?Nt x s / ?N c" by auto
with noS ly yu have th: "- ?Nt x s / ?N c ≤ l" by (cases "- ?Nt x s / ?N c > l", auto)
with lx px' have "False" by simp hence ?case by simp }
ultimately have ?case using ycs by blast
}
ultimately show ?case by blast
next
case (4 c s)
from "4.prems"
have lin: "isnpoly c" "c ≠ 0⇩p" "tmbound0 s" "allpolys isnpoly s"
and px: "Ifm vs (x # bs) (NEq (CNP 0 c s))"
and noS: "∀t. l < t ∧ t < u --> t ≠ - Itm vs (x # bs) s / (|c|)),⇩p⇗vs⇖" by simp_all
from ly yu noS have yne: "y ≠ - ?Nt x s / (|c|)),⇩p⇗vs⇖" by simp
hence ycs: "y < - ?Nt x s / ?N c ∨ y > -?Nt x s / ?N c" by auto
have ccs: "?N c = 0 ∨ ?N c ≠ 0" by dlo
moreover
{assume "?N c = 0" hence ?case using px by (simp add: tmbound0_I[OF lin(3), where bs="bs" and b="x" and b'="y"])}
moreover
{assume c: "?N c ≠ 0"
from yne c eq_divide_eq[of "y" "- ?Nt x s" "?N c"] have ?case
by (simp add: field_simps tmbound0_I[OF lin(3), of vs x bs y] sum_eq[symmetric]) }
ultimately show ?case by blast
qed (auto simp add: tmbound0_I[where vs=vs and bs="bs" and b="y" and b'="x"] bound0_I[where vs=vs and bs="bs" and b="y" and b'="x"])
lemma one_plus_one_pos[simp]: "(1::'a::{linordered_field}) + 1 > 0"
proof-
have op: "(1::'a) > 0" by simp
from add_pos_pos[OF op op] show ?thesis .
qed
lemma one_plus_one_nonzero[simp]: "(1::'a::{linordered_field}) + 1 ≠ 0"
using one_plus_one_pos[where ?'a = 'a] by (simp add: less_le)
lemma half_sum_eq: "(u + u) / (1+1) = (u::'a::{linordered_field})"
proof-
have "(u + u) = (1 + 1) * u" by (simp add: field_simps)
hence "(u + u) / (1+1) = (1 + 1)*u / (1 + 1)" by simp
with nonzero_mult_divide_cancel_left[OF one_plus_one_nonzero, of u] show ?thesis by simp
qed
lemma inf_uset:
assumes lp: "islin p"
and nmi: "¬ (Ifm vs (x#bs) (minusinf p))" (is "¬ (Ifm vs (x#bs) (?M p))")
and npi: "¬ (Ifm vs (x#bs) (plusinf p))" (is "¬ (Ifm vs (x#bs) (?P p))")
and ex: "∃ x. Ifm vs (x#bs) p" (is "∃ x. ?I x p")
shows "∃ (c,t) ∈ set (uset p). ∃ (d,s) ∈ set (uset p). ?I ((- Itm vs (x#bs) t / Ipoly vs c + - Itm vs (x#bs) s / Ipoly vs d) / (1 + 1)) p"
proof-
let ?Nt = "λ x t. Itm vs (x#bs) t"
let ?N = "Ipoly vs"
let ?U = "set (uset p)"
from ex obtain a where pa: "?I a p" by blast
from bound0_I[OF minusinf_nb[OF lp], where bs="bs" and b="x" and b'="a"] nmi
have nmi': "¬ (?I a (?M p))" by simp
from bound0_I[OF plusinf_nb[OF lp], where bs="bs" and b="x" and b'="a"] npi
have npi': "¬ (?I a (?P p))" by simp
have "∃ (c,t) ∈ set (uset p). ∃ (d,s) ∈ set (uset p). ?I ((- ?Nt a t/?N c + - ?Nt a s /?N d) / (1 + 1)) p"
proof-
let ?M = "(λ (c,t). - ?Nt a t / ?N c) ` ?U"
have fM: "finite ?M" by auto
from minusinf_uset[OF lp nmi pa] plusinf_uset[OF lp npi pa]
have "∃ (c,t) ∈ set (uset p). ∃ (d,s) ∈ set (uset p). a ≤ - ?Nt x t / ?N c ∧ a ≥ - ?Nt x s / ?N d" by blast
then obtain "c" "t" "d" "s" where
ctU: "(c,t) ∈ ?U" and dsU: "(d,s) ∈ ?U"
and xs1: "a ≤ - ?Nt x s / ?N d" and tx1: "a ≥ - ?Nt x t / ?N c" by blast
from uset_l[OF lp] ctU dsU tmbound0_I[where bs="bs" and b="x" and b'="a"] xs1 tx1
have xs: "a ≤ - ?Nt a s / ?N d" and tx: "a ≥ - ?Nt a t / ?N c" by auto
from ctU have Mne: "?M ≠ {}" by auto
hence Une: "?U ≠ {}" by simp
let ?l = "Min ?M"
let ?u = "Max ?M"
have linM: "?l ∈ ?M" using fM Mne by simp
have uinM: "?u ∈ ?M" using fM Mne by simp
have ctM: "- ?Nt a t / ?N c ∈ ?M" using ctU by auto
have dsM: "- ?Nt a s / ?N d ∈ ?M" using dsU by auto
have lM: "∀ t∈ ?M. ?l ≤ t" using Mne fM by auto
have Mu: "∀ t∈ ?M. t ≤ ?u" using Mne fM by auto
have "?l ≤ - ?Nt a t / ?N c" using ctM Mne by simp hence lx: "?l ≤ a" using tx by simp
have "- ?Nt a s / ?N d ≤ ?u" using dsM Mne by simp hence xu: "a ≤ ?u" using xs by simp
from finite_set_intervals2[where P="λ x. ?I x p",OF pa lx xu linM uinM fM lM Mu]
have "(∃ s∈ ?M. ?I s p) ∨
(∃ t1∈ ?M. ∃ t2 ∈ ?M. (∀ y. t1 < y ∧ y < t2 --> y ∉ ?M) ∧ t1 < a ∧ a < t2 ∧ ?I a p)" .
moreover {fix u assume um: "u∈ ?M" and pu: "?I u p"
hence "∃ (nu,tu) ∈ ?U. u = - ?Nt a tu / ?N nu" by auto
then obtain "tu" "nu" where tuU: "(nu,tu) ∈ ?U" and tuu:"u= - ?Nt a tu / ?N nu" by blast
from half_sum_eq[of u] pu tuu
have "?I (((- ?Nt a tu / ?N nu) + (- ?Nt a tu / ?N nu)) / (1 + 1)) p" by simp
with tuU have ?thesis by blast}
moreover{
assume "∃ t1∈ ?M. ∃ t2 ∈ ?M. (∀ y. t1 < y ∧ y < t2 --> y ∉ ?M) ∧ t1 < a ∧ a < t2 ∧ ?I a p"
then obtain t1 and t2 where t1M: "t1 ∈ ?M" and t2M: "t2∈ ?M"
and noM: "∀ y. t1 < y ∧ y < t2 --> y ∉ ?M" and t1x: "t1 < a" and xt2: "a < t2" and px: "?I a p"
by blast
from t1M have "∃ (t1n,t1u) ∈ ?U. t1 = - ?Nt a t1u / ?N t1n" by auto
then obtain "t1u" "t1n" where t1uU: "(t1n,t1u) ∈ ?U" and t1u: "t1 = - ?Nt a t1u / ?N t1n" by blast
from t2M have "∃ (t2n,t2u) ∈ ?U. t2 = - ?Nt a t2u / ?N t2n" by auto
then obtain "t2u" "t2n" where t2uU: "(t2n,t2u) ∈ ?U" and t2u: "t2 = - ?Nt a t2u / ?N t2n" by blast
from t1x xt2 have t1t2: "t1 < t2" by simp
let ?u = "(t1 + t2) / (1 + 1)"
from less_half_sum[OF t1t2] gt_half_sum[OF t1t2] have t1lu: "t1 < ?u" and ut2: "?u < t2" by auto
from lin_dense[OF lp noM t1x xt2 px t1lu ut2] have "?I ?u p" .
with t1uU t2uU t1u t2u have ?thesis by blast}
ultimately show ?thesis by blast
qed
then obtain "l" "n" "s" "m" where lnU: "(n,l) ∈ ?U" and smU:"(m,s) ∈ ?U"
and pu: "?I ((- ?Nt a l / ?N n + - ?Nt a s / ?N m) / (1 + 1)) p" by blast
from lnU smU uset_l[OF lp] have nbl: "tmbound0 l" and nbs: "tmbound0 s" by auto
from tmbound0_I[OF nbl, where bs="bs" and b="a" and b'="x"]
tmbound0_I[OF nbs, where bs="bs" and b="a" and b'="x"] pu
have "?I ((- ?Nt x l / ?N n + - ?Nt x s / ?N m) / (1 + 1)) p" by simp
with lnU smU
show ?thesis by auto
qed
(* The Ferrante - Rackoff Theorem *)
theorem fr_eq:
assumes lp: "islin p"
shows "(∃ x. Ifm vs (x#bs) p) = ((Ifm vs (x#bs) (minusinf p)) ∨ (Ifm vs (x#bs) (plusinf p)) ∨ (∃ (n,t) ∈ set (uset p). ∃ (m,s) ∈ set (uset p). Ifm vs (((- Itm vs (x#bs) t / Ipoly vs n + - Itm vs (x#bs) s / Ipoly vs m) /(1 + 1))#bs) p))"
(is "(∃ x. ?I x p) = (?M ∨ ?P ∨ ?F)" is "?E = ?D")
proof
assume px: "∃ x. ?I x p"
have "?M ∨ ?P ∨ (¬ ?M ∧ ¬ ?P)" by blast
moreover {assume "?M ∨ ?P" hence "?D" by blast}
moreover {assume nmi: "¬ ?M" and npi: "¬ ?P"
from inf_uset[OF lp nmi npi] have "?F" using px by blast hence "?D" by blast}
ultimately show "?D" by blast
next
assume "?D"
moreover {assume m:"?M" from minusinf_ex[OF lp m] have "?E" .}
moreover {assume p: "?P" from plusinf_ex[OF lp p] have "?E" . }
moreover {assume f:"?F" hence "?E" by blast}
ultimately show "?E" by blast
qed
section{* First implementation : Naive by encoding all case splits locally *}
definition "msubsteq c t d s a r =
evaldjf (split conj)
[(let cd = c *⇩p d in (NEq (CP cd), Eq (Add (Mul (~⇩p a) (Add (Mul d t) (Mul c s))) (Mul (2⇩p *⇩p cd) r)))),
(conj (Eq (CP c)) (NEq (CP d)) , Eq (Add (Mul (~⇩p a) s) (Mul (2⇩p *⇩p d) r))),
(conj (NEq (CP c)) (Eq (CP d)) , Eq (Add (Mul (~⇩p a) t) (Mul (2⇩p *⇩p c) r))),
(conj (Eq (CP c)) (Eq (CP d)) , Eq r)]"
lemma msubsteq_nb: assumes lp: "islin (Eq (CNP 0 a r))" and t: "tmbound0 t" and s: "tmbound0 s"
shows "bound0 (msubsteq c t d s a r)"
proof-
have th: "∀x∈ set [(let cd = c *⇩p d in (NEq (CP cd), Eq (Add (Mul (~⇩p a) (Add (Mul d t) (Mul c s))) (Mul (2⇩p *⇩p cd) r)))),
(conj (Eq (CP c)) (NEq (CP d)) , Eq (Add (Mul (~⇩p a) s) (Mul (2⇩p *⇩p d) r))),
(conj (NEq (CP c)) (Eq (CP d)) , Eq (Add (Mul (~⇩p a) t) (Mul (2⇩p *⇩p c) r))),
(conj (Eq (CP c)) (Eq (CP d)) , Eq r)]. bound0 (split conj x)"
using lp by (simp add: Let_def t s )
from evaldjf_bound0[OF th] show ?thesis by (simp add: msubsteq_def)
qed
lemma msubsteq: assumes lp: "islin (Eq (CNP 0 a r))"
shows "Ifm vs (x#bs) (msubsteq c t d s a r) = Ifm vs (((- Itm vs (x#bs) t / Ipoly vs c + - Itm vs (x#bs) s / Ipoly vs d) /(1 + 1))#bs) (Eq (CNP 0 a r))" (is "?lhs = ?rhs")
proof-
let ?Nt = "λ(x::'a) t. Itm vs (x#bs) t"
let ?N = "λp. Ipoly vs p"
let ?c = "?N c"
let ?d = "?N d"
let ?t = "?Nt x t"
let ?s = "?Nt x s"
let ?a = "?N a"
let ?r = "?Nt x r"
from lp have lin:"isnpoly a" "a ≠ 0⇩p" "tmbound0 r" "allpolys isnpoly r" by simp_all
note r= tmbound0_I[OF lin(3), of vs _ bs x]
have cd_cs: "?c * ?d ≠ 0 ∨ (?c = 0 ∧ ?d = 0) ∨ (?c = 0 ∧ ?d ≠ 0) ∨ (?c ≠ 0 ∧ ?d = 0)" by auto
moreover
{assume c: "?c = 0" and d: "?d=0"
hence ?thesis by (simp add: r[of 0] msubsteq_def Let_def evaldjf_ex)}
moreover
{assume c: "?c = 0" and d: "?d≠0"
from c have th: "(- ?t / ?c + - ?s / ?d)/(1 + 1) = -?s / ((1 + 1)*?d)" by simp
have "?rhs = Ifm vs (-?s / ((1 + 1)*?d) # bs) (Eq (CNP 0 a r))" by (simp only: th)
also have "… <-> ?a * (-?s / ((1 + 1)*?d)) + ?r = 0" by (simp add: r[of "- (Itm vs (x # bs) s / ((1 + 1) * (|d|)),⇩p⇗vs⇖))"])
also have "… <-> (1 + 1)*?d * (?a * (-?s / ((1 + 1)*?d)) + ?r) = 0"
using d mult_cancel_left[of "(1 + 1)*?d" "(?a * (-?s / ((1 + 1)*?d)) + ?r)" 0] by simp
also have "… <-> (- ?a * ?s) * ((1 + 1)*?d / ((1 + 1)*?d)) + (1 + 1)*?d*?r= 0"
by (simp add: field_simps right_distrib[of "(1 + 1)*?d"] del: right_distrib)
also have "… <-> - (?a * ?s) + (1 + 1)*?d*?r = 0" using d by simp
finally have ?thesis using c d
apply (simp add: r[of "- (Itm vs (x # bs) s / ((1 + 1) * (|d|)),⇩p⇗vs⇖))"] msubsteq_def Let_def evaldjf_ex del: one_add_one_is_two)
apply (simp only: one_add_one_is_two[symmetric] of_int_add)
apply simp
done}
moreover
{assume c: "?c ≠ 0" and d: "?d=0"
from d have th: "(- ?t / ?c + - ?s / ?d)/(1 + 1) = -?t / ((1 + 1)*?c)" by simp
have "?rhs = Ifm vs (-?t / ((1 + 1)*?c) # bs) (Eq (CNP 0 a r))" by (simp only: th)
also have "… <-> ?a * (-?t / ((1 + 1)*?c)) + ?r = 0" by (simp add: r[of "- (?t/ ((1 + 1)* ?c))"])
also have "… <-> (1 + 1)*?c * (?a * (-?t / ((1 + 1)*?c)) + ?r) = 0"
using c mult_cancel_left[of "(1 + 1)*?c" "(?a * (-?t / ((1 + 1)*?c)) + ?r)" 0] by simp
also have "… <-> (?a * -?t)* ((1 + 1)*?c) / ((1 + 1)*?c) + (1 + 1)*?c*?r= 0"
by (simp add: field_simps right_distrib[of "(1 + 1)*?c"] del: right_distrib)
also have "… <-> - (?a * ?t) + (1 + 1)*?c*?r = 0" using c by simp
finally have ?thesis using c d
apply (simp add: r[of "- (?t/ ((1 + 1)*?c))"] msubsteq_def Let_def evaldjf_ex del: one_add_one_is_two)
apply (simp only: one_add_one_is_two[symmetric] of_int_add)
apply simp
done }
moreover
{assume c: "?c ≠ 0" and d: "?d≠0" hence dc: "?c * ?d *(1 + 1) ≠ 0" by simp
from add_frac_eq[OF c d, of "- ?t" "- ?s"]
have th: "(- ?t / ?c + - ?s / ?d)/(1 + 1) = - (?d * ?t + ?c* ?s )/ ((1 + 1)*?c*?d)"
by (simp add: field_simps)
have "?rhs <-> Ifm vs (- (?d * ?t + ?c* ?s )/ ((1 + 1)*?c*?d) # bs) (Eq (CNP 0 a r))" by (simp only: th)
also have "… <-> ?a * (- (?d * ?t + ?c* ?s )/ ((1 + 1)*?c*?d)) + ?r = 0"
by (simp add: r[of "(- (?d * ?t) + - (?c *?s)) / ((1 + 1) * ?c * ?d)"])
also have "… <-> ((1 + 1) * ?c * ?d) * (?a * (- (?d * ?t + ?c* ?s )/ ((1 + 1)*?c*?d)) + ?r) =0 "
using c d mult_cancel_left[of "(1 + 1) * ?c * ?d" "?a * (- (?d * ?t + ?c* ?s)/ ((1 + 1)*?c*?d)) + ?r" 0] by simp
also have "… <-> ?a * (- (?d * ?t + ?c* ?s )) + (1 + 1)*?c*?d*?r =0"
using nonzero_mult_divide_cancel_left [OF dc] c d
by (simp add: algebra_simps diff_divide_distrib del: left_distrib)
finally have ?thesis using c d
apply (simp add: r[of "(- (?d * ?t) + - (?c *?s)) / ((1 + 1) * ?c * ?d)"] msubsteq_def Let_def evaldjf_ex field_simps)
apply (simp only: one_add_one_is_two[symmetric] of_int_add)
apply (simp add: field_simps)
done }
ultimately show ?thesis by blast
qed
definition "msubstneq c t d s a r =
evaldjf (split conj)
[(let cd = c *⇩p d in (NEq (CP cd), NEq (Add (Mul (~⇩p a) (Add (Mul d t) (Mul c s))) (Mul (2⇩p *⇩p cd) r)))),
(conj (Eq (CP c)) (NEq (CP d)) , NEq (Add (Mul (~⇩p a) s) (Mul (2⇩p *⇩p d) r))),
(conj (NEq (CP c)) (Eq (CP d)) , NEq (Add (Mul (~⇩p a) t) (Mul (2⇩p *⇩p c) r))),
(conj (Eq (CP c)) (Eq (CP d)) , NEq r)]"
lemma msubstneq_nb: assumes lp: "islin (NEq (CNP 0 a r))" and t: "tmbound0 t" and s: "tmbound0 s"
shows "bound0 (msubstneq c t d s a r)"
proof-
have th: "∀x∈ set [(let cd = c *⇩p d in (NEq (CP cd), NEq (Add (Mul (~⇩p a) (Add (Mul d t) (Mul c s))) (Mul (2⇩p *⇩p cd) r)))),
(conj (Eq (CP c)) (NEq (CP d)) , NEq (Add (Mul (~⇩p a) s) (Mul (2⇩p *⇩p d) r))),
(conj (NEq (CP c)) (Eq (CP d)) , NEq (Add (Mul (~⇩p a) t) (Mul (2⇩p *⇩p c) r))),
(conj (Eq (CP c)) (Eq (CP d)) , NEq r)]. bound0 (split conj x)"
using lp by (simp add: Let_def t s )
from evaldjf_bound0[OF th] show ?thesis by (simp add: msubstneq_def)
qed
lemma msubstneq: assumes lp: "islin (Eq (CNP 0 a r))"
shows "Ifm vs (x#bs) (msubstneq c t d s a r) = Ifm vs (((- Itm vs (x#bs) t / Ipoly vs c + - Itm vs (x#bs) s / Ipoly vs d) /(1 + 1))#bs) (NEq (CNP 0 a r))" (is "?lhs = ?rhs")
proof-
let ?Nt = "λ(x::'a) t. Itm vs (x#bs) t"
let ?N = "λp. Ipoly vs p"
let ?c = "?N c"
let ?d = "?N d"
let ?t = "?Nt x t"
let ?s = "?Nt x s"
let ?a = "?N a"
let ?r = "?Nt x r"
from lp have lin:"isnpoly a" "a ≠ 0⇩p" "tmbound0 r" "allpolys isnpoly r" by simp_all
note r= tmbound0_I[OF lin(3), of vs _ bs x]
have cd_cs: "?c * ?d ≠ 0 ∨ (?c = 0 ∧ ?d = 0) ∨ (?c = 0 ∧ ?d ≠ 0) ∨ (?c ≠ 0 ∧ ?d = 0)" by auto
moreover
{assume c: "?c = 0" and d: "?d=0"
hence ?thesis by (simp add: r[of 0] msubstneq_def Let_def evaldjf_ex)}
moreover
{assume c: "?c = 0" and d: "?d≠0"
from c have th: "(- ?t / ?c + - ?s / ?d)/(1 + 1) = -?s / ((1 + 1)*?d)" by simp
have "?rhs = Ifm vs (-?s / ((1 + 1)*?d) # bs) (NEq (CNP 0 a r))" by (simp only: th)
also have "… <-> ?a * (-?s / ((1 + 1)*?d)) + ?r ≠ 0" by (simp add: r[of "- (Itm vs (x # bs) s / ((1 + 1) * (|d|)),⇩p⇗vs⇖))"])
also have "… <-> (1 + 1)*?d * (?a * (-?s / ((1 + 1)*?d)) + ?r) ≠ 0"
using d mult_cancel_left[of "(1 + 1)*?d" "(?a * (-?s / ((1 + 1)*?d)) + ?r)" 0] by simp
also have "… <-> (- ?a * ?s) * ((1 + 1)*?d / ((1 + 1)*?d)) + (1 + 1)*?d*?r≠ 0"
by (simp add: field_simps right_distrib[of "(1 + 1)*?d"] del: right_distrib)
also have "… <-> - (?a * ?s) + (1 + 1)*?d*?r ≠ 0" using d by simp
finally have ?thesis using c d
apply (simp add: r[of "- (Itm vs (x # bs) s / ((1 + 1) * (|d|)),⇩p⇗vs⇖))"] msubstneq_def Let_def evaldjf_ex del: one_add_one_is_two)
apply (simp only: one_add_one_is_two[symmetric] of_int_add)
apply simp
done}
moreover
{assume c: "?c ≠ 0" and d: "?d=0"
from d have th: "(- ?t / ?c + - ?s / ?d)/(1 + 1) = -?t / ((1 + 1)*?c)" by simp
have "?rhs = Ifm vs (-?t / ((1 + 1)*?c) # bs) (NEq (CNP 0 a r))" by (simp only: th)
also have "… <-> ?a * (-?t / ((1 + 1)*?c)) + ?r ≠ 0" by (simp add: r[of "- (?t/ ((1 + 1)* ?c))"])
also have "… <-> (1 + 1)*?c * (?a * (-?t / ((1 + 1)*?c)) + ?r) ≠ 0"
using c mult_cancel_left[of "(1 + 1)*?c" "(?a * (-?t / ((1 + 1)*?c)) + ?r)" 0] by simp
also have "… <-> (?a * -?t)* ((1 + 1)*?c) / ((1 + 1)*?c) + (1 + 1)*?c*?r ≠ 0"
by (simp add: field_simps right_distrib[of "(1 + 1)*?c"] del: right_distrib)
also have "… <-> - (?a * ?t) + (1 + 1)*?c*?r ≠ 0" using c by simp
finally have ?thesis using c d
apply (simp add: r[of "- (?t/ ((1 + 1)*?c))"] msubstneq_def Let_def evaldjf_ex del: one_add_one_is_two)
apply (simp only: one_add_one_is_two[symmetric] of_int_add)
apply simp
done }
moreover
{assume c: "?c ≠ 0" and d: "?d≠0" hence dc: "?c * ?d *(1 + 1) ≠ 0" by simp
from add_frac_eq[OF c d, of "- ?t" "- ?s"]
have th: "(- ?t / ?c + - ?s / ?d)/(1 + 1) = - (?d * ?t + ?c* ?s )/ ((1 + 1)*?c*?d)"
by (simp add: field_simps)
have "?rhs <-> Ifm vs (- (?d * ?t + ?c* ?s )/ ((1 + 1)*?c*?d) # bs) (NEq (CNP 0 a r))" by (simp only: th)
also have "… <-> ?a * (- (?d * ?t + ?c* ?s )/ ((1 + 1)*?c*?d)) + ?r ≠ 0"
by (simp add: r[of "(- (?d * ?t) + - (?c *?s)) / ((1 + 1) * ?c * ?d)"])
also have "… <-> ((1 + 1) * ?c * ?d) * (?a * (- (?d * ?t + ?c* ?s )/ ((1 + 1)*?c*?d)) + ?r) ≠ 0 "
using c d mult_cancel_left[of "(1 + 1) * ?c * ?d" "?a * (- (?d * ?t + ?c* ?s)/ ((1 + 1)*?c*?d)) + ?r" 0] by simp
also have "… <-> ?a * (- (?d * ?t + ?c* ?s )) + (1 + 1)*?c*?d*?r ≠ 0"
using nonzero_mult_divide_cancel_left[OF dc] c d
by (simp add: algebra_simps diff_divide_distrib del: left_distrib)
finally have ?thesis using c d
apply (simp add: r[of "(- (?d * ?t) + - (?c *?s)) / ((1 + 1) * ?c * ?d)"] msubstneq_def Let_def evaldjf_ex field_simps)
apply (simp only: one_add_one_is_two[symmetric] of_int_add)
apply (simp add: field_simps)
done }
ultimately show ?thesis by blast
qed
definition "msubstlt c t d s a r =
evaldjf (split conj)
[(let cd = c *⇩p d in (lt (CP (~⇩p cd)), Lt (Add (Mul (~⇩p a) (Add (Mul d t) (Mul c s))) (Mul (2⇩p *⇩p cd) r)))),
(let cd = c *⇩p d in (lt (CP cd), Lt (Sub (Mul a (Add (Mul d t) (Mul c s))) (Mul (2⇩p *⇩p cd) r)))),
(conj (lt (CP (~⇩p c))) (Eq (CP d)) , Lt (Add (Mul (~⇩p a) t) (Mul (2⇩p *⇩p c) r))),
(conj (lt (CP c)) (Eq (CP d)) , Lt (Sub (Mul a t) (Mul (2⇩p *⇩p c) r))),
(conj (lt (CP (~⇩p d))) (Eq (CP c)) , Lt (Add (Mul (~⇩p a) s) (Mul (2⇩p *⇩p d) r))),
(conj (lt (CP d)) (Eq (CP c)) , Lt (Sub (Mul a s) (Mul (2⇩p *⇩p d) r))),
(conj (Eq (CP c)) (Eq (CP d)) , Lt r)]"
lemma msubstlt_nb: assumes lp: "islin (Lt (CNP 0 a r))" and t: "tmbound0 t" and s: "tmbound0 s"
shows "bound0 (msubstlt c t d s a r)"
proof-
have th: "∀x∈ set [(let cd = c *⇩p d in (lt (CP (~⇩p cd)), Lt (Add (Mul (~⇩p a) (Add (Mul d t) (Mul c s))) (Mul (2⇩p *⇩p cd) r)))),
(let cd = c *⇩p d in (lt (CP cd), Lt (Sub (Mul a (Add (Mul d t) (Mul c s))) (Mul (2⇩p *⇩p cd) r)))),
(conj (lt (CP (~⇩p c))) (Eq (CP d)) , Lt (Add (Mul (~⇩p a) t) (Mul (2⇩p *⇩p c) r))),
(conj (lt (CP c)) (Eq (CP d)) , Lt (Sub (Mul a t) (Mul (2⇩p *⇩p c) r))),
(conj (lt (CP (~⇩p d))) (Eq (CP c)) , Lt (Add (Mul (~⇩p a) s) (Mul (2⇩p *⇩p d) r))),
(conj (lt (CP d)) (Eq (CP c)) , Lt (Sub (Mul a s) (Mul (2⇩p *⇩p d) r))),
(conj (Eq (CP c)) (Eq (CP d)) , Lt r)]. bound0 (split conj x)"
using lp by (simp add: Let_def t s lt_nb )
from evaldjf_bound0[OF th] show ?thesis by (simp add: msubstlt_def)
qed
lemma msubstlt: assumes nc: "isnpoly c" and nd: "isnpoly d" and lp: "islin (Lt (CNP 0 a r))"
shows "Ifm vs (x#bs) (msubstlt c t d s a r) <->
Ifm vs (((- Itm vs (x#bs) t / Ipoly vs c + - Itm vs (x#bs) s / Ipoly vs d) /(1 + 1))#bs) (Lt (CNP 0 a r))" (is "?lhs = ?rhs")
proof-
let ?Nt = "λx t. Itm vs (x#bs) t"
let ?N = "λp. Ipoly vs p"
let ?c = "?N c"
let ?d = "?N d"
let ?t = "?Nt x t"
let ?s = "?Nt x s"
let ?a = "?N a"
let ?r = "?Nt x r"
from lp have lin:"isnpoly a" "a ≠ 0⇩p" "tmbound0 r" "allpolys isnpoly r" by simp_all
note r= tmbound0_I[OF lin(3), of vs _ bs x]
have cd_cs: "?c * ?d < 0 ∨ ?c * ?d > 0 ∨ (?c = 0 ∧ ?d = 0) ∨ (?c = 0 ∧ ?d < 0) ∨ (?c = 0 ∧ ?d > 0) ∨ (?c < 0 ∧ ?d = 0) ∨ (?c > 0 ∧ ?d = 0)" by auto
moreover
{assume c: "?c=0" and d: "?d=0"
hence ?thesis using nc nd by (simp add: polyneg_norm lt r[of 0] msubstlt_def Let_def evaldjf_ex)}
moreover
{assume dc: "?c*?d > 0"
from mult_pos_pos[OF one_plus_one_pos dc] have dc': "(1 + 1)*?c *?d > 0" by simp
hence c:"?c ≠ 0" and d: "?d≠ 0" by auto
from dc' have dc'': "¬ (1 + 1)*?c *?d < 0" by simp
from add_frac_eq[OF c d, of "- ?t" "- ?s"]
have th: "(- ?t / ?c + - ?s / ?d)/(1 + 1) = - (?d * ?t + ?c* ?s )/ ((1 + 1)*?c*?d)"
by (simp add: field_simps)
have "?rhs <-> Ifm vs (- (?d * ?t + ?c* ?s )/ ((1 + 1)*?c*?d) # bs) (Lt (CNP 0 a r))" by (simp only: th