Theory Path_Connected

theory Path_Connected
imports Continuous_Extension Continuum_Not_Denumerable
(*  Title:      HOL/Analysis/Path_Connected.thy
    Authors:    LC Paulson and Robert Himmelmann (TU Muenchen), based on material from HOL Light
*)

section ‹Continuous paths and path-connected sets›

theory Path_Connected
imports Continuous_Extension Continuum_Not_Denumerable
begin

subsection ‹Paths and Arcs›

definition%important path :: "(real ⇒ 'a::topological_space) ⇒ bool"
  where "path g ⟷ continuous_on {0..1} g"

definition%important pathstart :: "(real ⇒ 'a::topological_space) ⇒ 'a"
  where "pathstart g = g 0"

definition%important pathfinish :: "(real ⇒ 'a::topological_space) ⇒ 'a"
  where "pathfinish g = g 1"

definition%important path_image :: "(real ⇒ 'a::topological_space) ⇒ 'a set"
  where "path_image g = g ` {0 .. 1}"

definition%important reversepath :: "(real ⇒ 'a::topological_space) ⇒ real ⇒ 'a"
  where "reversepath g = (λx. g(1 - x))"

definition%important joinpaths :: "(real ⇒ 'a::topological_space) ⇒ (real ⇒ 'a) ⇒ real ⇒ 'a"
    (infixr "+++" 75)
  where "g1 +++ g2 = (λx. if x ≤ 1/2 then g1 (2 * x) else g2 (2 * x - 1))"

definition%important simple_path :: "(real ⇒ 'a::topological_space) ⇒ bool"
  where "simple_path g ⟷
     path g ∧ (∀x∈{0..1}. ∀y∈{0..1}. g x = g y ⟶ x = y ∨ x = 0 ∧ y = 1 ∨ x = 1 ∧ y = 0)"

definition%important arc :: "(real ⇒ 'a :: topological_space) ⇒ bool"
  where "arc g ⟷ path g ∧ inj_on g {0..1}"


subsection%unimportant‹Invariance theorems›

lemma path_eq: "path p ⟹ (⋀t. t ∈ {0..1} ⟹ p t = q t) ⟹ path q"
  using continuous_on_eq path_def by blast

lemma path_continuous_image: "path g ⟹ continuous_on (path_image g) f ⟹ path(f ∘ g)"
  unfolding path_def path_image_def
  using continuous_on_compose by blast

lemma path_translation_eq:
  fixes g :: "real ⇒ 'a :: real_normed_vector"
  shows "path((λx. a + x) ∘ g) = path g"
proof -
  have g: "g = (λx. -a + x) ∘ ((λx. a + x) ∘ g)"
    by (rule ext) simp
  show ?thesis
    unfolding path_def
    apply safe
    apply (subst g)
    apply (rule continuous_on_compose)
    apply (auto intro: continuous_intros)
    done
qed

lemma path_linear_image_eq:
  fixes f :: "'a::euclidean_space ⇒ 'b::euclidean_space"
   assumes "linear f" "inj f"
     shows "path(f ∘ g) = path g"
proof -
  from linear_injective_left_inverse [OF assms]
  obtain h where h: "linear h" "h ∘ f = id"
    by blast
  then have g: "g = h ∘ (f ∘ g)"
    by (metis comp_assoc id_comp)
  show ?thesis
    unfolding path_def
    using h assms
    by (metis g continuous_on_compose linear_continuous_on linear_conv_bounded_linear)
qed

lemma pathstart_translation: "pathstart((λx. a + x) ∘ g) = a + pathstart g"
  by (simp add: pathstart_def)

lemma pathstart_linear_image_eq: "linear f ⟹ pathstart(f ∘ g) = f(pathstart g)"
  by (simp add: pathstart_def)

lemma pathfinish_translation: "pathfinish((λx. a + x) ∘ g) = a + pathfinish g"
  by (simp add: pathfinish_def)

lemma pathfinish_linear_image: "linear f ⟹ pathfinish(f ∘ g) = f(pathfinish g)"
  by (simp add: pathfinish_def)

lemma path_image_translation: "path_image((λx. a + x) ∘ g) = (λx. a + x) ` (path_image g)"
  by (simp add: image_comp path_image_def)

lemma path_image_linear_image: "linear f ⟹ path_image(f ∘ g) = f ` (path_image g)"
  by (simp add: image_comp path_image_def)

lemma reversepath_translation: "reversepath((λx. a + x) ∘ g) = (λx. a + x) ∘ reversepath g"
  by (rule ext) (simp add: reversepath_def)

lemma reversepath_linear_image: "linear f ⟹ reversepath(f ∘ g) = f ∘ reversepath g"
  by (rule ext) (simp add: reversepath_def)

lemma joinpaths_translation:
    "((λx. a + x) ∘ g1) +++ ((λx. a + x) ∘ g2) = (λx. a + x) ∘ (g1 +++ g2)"
  by (rule ext) (simp add: joinpaths_def)

lemma joinpaths_linear_image: "linear f ⟹ (f ∘ g1) +++ (f ∘ g2) = f ∘ (g1 +++ g2)"
  by (rule ext) (simp add: joinpaths_def)

lemma simple_path_translation_eq:
  fixes g :: "real ⇒ 'a::euclidean_space"
  shows "simple_path((λx. a + x) ∘ g) = simple_path g"
  by (simp add: simple_path_def path_translation_eq)

lemma simple_path_linear_image_eq:
  fixes f :: "'a::euclidean_space ⇒ 'b::euclidean_space"
  assumes "linear f" "inj f"
    shows "simple_path(f ∘ g) = simple_path g"
  using assms inj_on_eq_iff [of f]
  by (auto simp: path_linear_image_eq simple_path_def path_translation_eq)

lemma arc_translation_eq:
  fixes g :: "real ⇒ 'a::euclidean_space"
  shows "arc((λx. a + x) ∘ g) = arc g"
  by (auto simp: arc_def inj_on_def path_translation_eq)

lemma arc_linear_image_eq:
  fixes f :: "'a::euclidean_space ⇒ 'b::euclidean_space"
   assumes "linear f" "inj f"
     shows  "arc(f ∘ g) = arc g"
  using assms inj_on_eq_iff [of f]
  by (auto simp: arc_def inj_on_def path_linear_image_eq)

subsection%unimportant‹Basic lemmas about paths›

lemma continuous_on_path: "path f ⟹ t ⊆ {0..1} ⟹ continuous_on t f"
  using continuous_on_subset path_def by blast

lemma arc_imp_simple_path: "arc g ⟹ simple_path g"
  by (simp add: arc_def inj_on_def simple_path_def)

lemma arc_imp_path: "arc g ⟹ path g"
  using arc_def by blast

lemma arc_imp_inj_on: "arc g ⟹ inj_on g {0..1}"
  by (auto simp: arc_def)

lemma simple_path_imp_path: "simple_path g ⟹ path g"
  using simple_path_def by blast

lemma simple_path_cases: "simple_path g ⟹ arc g ∨ pathfinish g = pathstart g"
  unfolding simple_path_def arc_def inj_on_def pathfinish_def pathstart_def
  by force

lemma simple_path_imp_arc: "simple_path g ⟹ pathfinish g ≠ pathstart g ⟹ arc g"
  using simple_path_cases by auto

lemma arc_distinct_ends: "arc g ⟹ pathfinish g ≠ pathstart g"
  unfolding arc_def inj_on_def pathfinish_def pathstart_def
  by fastforce

lemma arc_simple_path: "arc g ⟷ simple_path g ∧ pathfinish g ≠ pathstart g"
  using arc_distinct_ends arc_imp_simple_path simple_path_cases by blast

lemma simple_path_eq_arc: "pathfinish g ≠ pathstart g ⟹ (simple_path g = arc g)"
  by (simp add: arc_simple_path)

lemma path_image_const [simp]: "path_image (λt. a) = {a}"
  by (force simp: path_image_def)

lemma path_image_nonempty [simp]: "path_image g ≠ {}"
  unfolding path_image_def image_is_empty box_eq_empty
  by auto

lemma pathstart_in_path_image[intro]: "pathstart g ∈ path_image g"
  unfolding pathstart_def path_image_def
  by auto

lemma pathfinish_in_path_image[intro]: "pathfinish g ∈ path_image g"
  unfolding pathfinish_def path_image_def
  by auto

lemma connected_path_image[intro]: "path g ⟹ connected (path_image g)"
  unfolding path_def path_image_def
  using connected_continuous_image connected_Icc by blast

lemma compact_path_image[intro]: "path g ⟹ compact (path_image g)"
  unfolding path_def path_image_def
  using compact_continuous_image connected_Icc by blast

lemma reversepath_reversepath[simp]: "reversepath (reversepath g) = g"
  unfolding reversepath_def
  by auto

lemma pathstart_reversepath[simp]: "pathstart (reversepath g) = pathfinish g"
  unfolding pathstart_def reversepath_def pathfinish_def
  by auto

lemma pathfinish_reversepath[simp]: "pathfinish (reversepath g) = pathstart g"
  unfolding pathstart_def reversepath_def pathfinish_def
  by auto

lemma pathstart_join[simp]: "pathstart (g1 +++ g2) = pathstart g1"
  unfolding pathstart_def joinpaths_def pathfinish_def
  by auto

lemma pathfinish_join[simp]: "pathfinish (g1 +++ g2) = pathfinish g2"
  unfolding pathstart_def joinpaths_def pathfinish_def
  by auto

lemma path_image_reversepath[simp]: "path_image (reversepath g) = path_image g"
proof -
  have *: "⋀g. path_image (reversepath g) ⊆ path_image g"
    unfolding path_image_def subset_eq reversepath_def Ball_def image_iff
    by force
  show ?thesis
    using *[of g] *[of "reversepath g"]
    unfolding reversepath_reversepath
    by auto
qed

lemma path_reversepath [simp]: "path (reversepath g) ⟷ path g"
proof -
  have *: "⋀g. path g ⟹ path (reversepath g)"
    unfolding path_def reversepath_def
    apply (rule continuous_on_compose[unfolded o_def, of _ "λx. 1 - x"])
    apply (auto intro: continuous_intros continuous_on_subset[of "{0..1}"])
    done
  show ?thesis
    using *[of "reversepath g"] *[of g]
    unfolding reversepath_reversepath
    by (rule iffI)
qed

lemma arc_reversepath:
  assumes "arc g" shows "arc(reversepath g)"
proof -
  have injg: "inj_on g {0..1}"
    using assms
    by (simp add: arc_def)
  have **: "⋀x y::real. 1-x = 1-y ⟹ x = y"
    by simp
  show ?thesis
    using assms  by (clarsimp simp: arc_def intro!: inj_onI) (simp add: inj_onD reversepath_def **)
qed

lemma simple_path_reversepath: "simple_path g ⟹ simple_path (reversepath g)"
  apply (simp add: simple_path_def)
  apply (force simp: reversepath_def)
  done

lemmas reversepath_simps =
  path_reversepath path_image_reversepath pathstart_reversepath pathfinish_reversepath

lemma path_join[simp]:
  assumes "pathfinish g1 = pathstart g2"
  shows "path (g1 +++ g2) ⟷ path g1 ∧ path g2"
  unfolding path_def pathfinish_def pathstart_def
proof safe
  assume cont: "continuous_on {0..1} (g1 +++ g2)"
  have g1: "continuous_on {0..1} g1 ⟷ continuous_on {0..1} ((g1 +++ g2) ∘ (λx. x / 2))"
    by (intro continuous_on_cong refl) (auto simp: joinpaths_def)
  have g2: "continuous_on {0..1} g2 ⟷ continuous_on {0..1} ((g1 +++ g2) ∘ (λx. x / 2 + 1/2))"
    using assms
    by (intro continuous_on_cong refl) (auto simp: joinpaths_def pathfinish_def pathstart_def)
  show "continuous_on {0..1} g1" and "continuous_on {0..1} g2"
    unfolding g1 g2
    by (auto intro!: continuous_intros continuous_on_subset[OF cont] simp del: o_apply)
next
  assume g1g2: "continuous_on {0..1} g1" "continuous_on {0..1} g2"
  have 01: "{0 .. 1} = {0..1/2} ∪ {1/2 .. 1::real}"
    by auto
  {
    fix x :: real
    assume "0 ≤ x" and "x ≤ 1"
    then have "x ∈ (λx. x * 2) ` {0..1 / 2}"
      by (intro image_eqI[where x="x/2"]) auto
  }
  note 1 = this
  {
    fix x :: real
    assume "0 ≤ x" and "x ≤ 1"
    then have "x ∈ (λx. x * 2 - 1) ` {1 / 2..1}"
      by (intro image_eqI[where x="x/2 + 1/2"]) auto
  }
  note 2 = this
  show "continuous_on {0..1} (g1 +++ g2)"
    using assms
    unfolding joinpaths_def 01
    apply (intro continuous_on_cases closed_atLeastAtMost g1g2[THEN continuous_on_compose2] continuous_intros)
    apply (auto simp: field_simps pathfinish_def pathstart_def intro!: 1 2)
    done
qed

section%unimportant ‹Path Images›

lemma bounded_path_image: "path g ⟹ bounded(path_image g)"
  by (simp add: compact_imp_bounded compact_path_image)

lemma closed_path_image:
  fixes g :: "real ⇒ 'a::t2_space"
  shows "path g ⟹ closed(path_image g)"
  by (metis compact_path_image compact_imp_closed)

lemma connected_simple_path_image: "simple_path g ⟹ connected(path_image g)"
  by (metis connected_path_image simple_path_imp_path)

lemma compact_simple_path_image: "simple_path g ⟹ compact(path_image g)"
  by (metis compact_path_image simple_path_imp_path)

lemma bounded_simple_path_image: "simple_path g ⟹ bounded(path_image g)"
  by (metis bounded_path_image simple_path_imp_path)

lemma closed_simple_path_image:
  fixes g :: "real ⇒ 'a::t2_space"
  shows "simple_path g ⟹ closed(path_image g)"
  by (metis closed_path_image simple_path_imp_path)

lemma connected_arc_image: "arc g ⟹ connected(path_image g)"
  by (metis connected_path_image arc_imp_path)

lemma compact_arc_image: "arc g ⟹ compact(path_image g)"
  by (metis compact_path_image arc_imp_path)

lemma bounded_arc_image: "arc g ⟹ bounded(path_image g)"
  by (metis bounded_path_image arc_imp_path)

lemma closed_arc_image:
  fixes g :: "real ⇒ 'a::t2_space"
  shows "arc g ⟹ closed(path_image g)"
  by (metis closed_path_image arc_imp_path)

lemma path_image_join_subset: "path_image (g1 +++ g2) ⊆ path_image g1 ∪ path_image g2"
  unfolding path_image_def joinpaths_def
  by auto

lemma subset_path_image_join:
  assumes "path_image g1 ⊆ s"
    and "path_image g2 ⊆ s"
  shows "path_image (g1 +++ g2) ⊆ s"
  using path_image_join_subset[of g1 g2] and assms
  by auto

lemma path_image_join:
    "pathfinish g1 = pathstart g2 ⟹ path_image(g1 +++ g2) = path_image g1 ∪ path_image g2"
  apply (rule subset_antisym [OF path_image_join_subset])
  apply (auto simp: pathfinish_def pathstart_def path_image_def joinpaths_def image_def)
  apply (drule sym)
  apply (rule_tac x="xa/2" in bexI, auto)
  apply (rule ccontr)
  apply (drule_tac x="(xa+1)/2" in bspec)
  apply (auto simp: field_simps)
  apply (drule_tac x="1/2" in bspec, auto)
  done

lemma not_in_path_image_join:
  assumes "x ∉ path_image g1"
    and "x ∉ path_image g2"
  shows "x ∉ path_image (g1 +++ g2)"
  using assms and path_image_join_subset[of g1 g2]
  by auto

lemma pathstart_compose: "pathstart(f ∘ p) = f(pathstart p)"
  by (simp add: pathstart_def)

lemma pathfinish_compose: "pathfinish(f ∘ p) = f(pathfinish p)"
  by (simp add: pathfinish_def)

lemma path_image_compose: "path_image (f ∘ p) = f ` (path_image p)"
  by (simp add: image_comp path_image_def)

lemma path_compose_join: "f ∘ (p +++ q) = (f ∘ p) +++ (f ∘ q)"
  by (rule ext) (simp add: joinpaths_def)

lemma path_compose_reversepath: "f ∘ reversepath p = reversepath(f ∘ p)"
  by (rule ext) (simp add: reversepath_def)

lemma joinpaths_eq:
  "(⋀t. t ∈ {0..1} ⟹ p t = p' t) ⟹
   (⋀t. t ∈ {0..1} ⟹ q t = q' t)
   ⟹  t ∈ {0..1} ⟹ (p +++ q) t = (p' +++ q') t"
  by (auto simp: joinpaths_def)

lemma simple_path_inj_on: "simple_path g ⟹ inj_on g {0<..<1}"
  by (auto simp: simple_path_def path_image_def inj_on_def less_eq_real_def Ball_def)


subsection%unimportant‹Simple paths with the endpoints removed›

lemma simple_path_endless:
    "simple_path c ⟹ path_image c - {pathstart c,pathfinish c} = c ` {0<..<1}"
  apply (auto simp: simple_path_def path_image_def pathstart_def pathfinish_def Ball_def Bex_def image_def)
  apply (metis eq_iff le_less_linear)
  apply (metis leD linear)
  using less_eq_real_def zero_le_one apply blast
  using less_eq_real_def zero_le_one apply blast
  done

lemma connected_simple_path_endless:
    "simple_path c ⟹ connected(path_image c - {pathstart c,pathfinish c})"
apply (simp add: simple_path_endless)
apply (rule connected_continuous_image)
apply (meson continuous_on_subset greaterThanLessThan_subseteq_atLeastAtMost_iff le_numeral_extra(3) le_numeral_extra(4) path_def simple_path_imp_path)
by auto

lemma nonempty_simple_path_endless:
    "simple_path c ⟹ path_image c - {pathstart c,pathfinish c} ≠ {}"
  by (simp add: simple_path_endless)


subsection%unimportant‹The operations on paths›

lemma path_image_subset_reversepath: "path_image(reversepath g) ≤ path_image g"
  by (auto simp: path_image_def reversepath_def)

lemma path_imp_reversepath: "path g ⟹ path(reversepath g)"
  apply (auto simp: path_def reversepath_def)
  using continuous_on_compose [of "{0..1}" "λx. 1 - x" g]
  apply (auto simp: continuous_on_op_minus)
  done

lemma half_bounded_equal: "1 ≤ x * 2 ⟹ x * 2 ≤ 1 ⟷ x = (1/2::real)"
  by simp

lemma continuous_on_joinpaths:
  assumes "continuous_on {0..1} g1" "continuous_on {0..1} g2" "pathfinish g1 = pathstart g2"
    shows "continuous_on {0..1} (g1 +++ g2)"
proof -
  have *: "{0..1::real} = {0..1/2} ∪ {1/2..1}"
    by auto
  have gg: "g2 0 = g1 1"
    by (metis assms(3) pathfinish_def pathstart_def)
  have 1: "continuous_on {0..1/2} (g1 +++ g2)"
    apply (rule continuous_on_eq [of _ "g1 ∘ (λx. 2*x)"])
    apply (rule continuous_intros | simp add: joinpaths_def assms)+
    done
  have "continuous_on {1/2..1} (g2 ∘ (λx. 2*x-1))"
    apply (rule continuous_on_subset [of "{1/2..1}"])
    apply (rule continuous_intros | simp add: image_affinity_atLeastAtMost_diff assms)+
    done
  then have 2: "continuous_on {1/2..1} (g1 +++ g2)"
    apply (rule continuous_on_eq [of "{1/2..1}" "g2 ∘ (λx. 2*x-1)"])
    apply (rule assms continuous_intros | simp add: joinpaths_def mult.commute half_bounded_equal gg)+
    done
  show ?thesis
    apply (subst *)
    apply (rule continuous_on_closed_Un)
    using 1 2
    apply auto
    done
qed

lemma path_join_imp: "⟦path g1; path g2; pathfinish g1 = pathstart g2⟧ ⟹ path(g1 +++ g2)"
  by (simp add: path_join)

lemma simple_path_join_loop:
  assumes "arc g1" "arc g2"
          "pathfinish g1 = pathstart g2"  "pathfinish g2 = pathstart g1"
          "path_image g1 ∩ path_image g2 ⊆ {pathstart g1, pathstart g2}"
  shows "simple_path(g1 +++ g2)"
proof -
  have injg1: "inj_on g1 {0..1}"
    using assms
    by (simp add: arc_def)
  have injg2: "inj_on g2 {0..1}"
    using assms
    by (simp add: arc_def)
  have g12: "g1 1 = g2 0"
   and g21: "g2 1 = g1 0"
   and sb:  "g1 ` {0..1} ∩ g2 ` {0..1} ⊆ {g1 0, g2 0}"
    using assms
    by (simp_all add: arc_def pathfinish_def pathstart_def path_image_def)
  { fix x and y::real
    assume xyI: "x = 1 ⟶ y ≠ 0"
       and xy: "x ≤ 1" "0 ≤ y" " y * 2 ≤ 1" "¬ x * 2 ≤ 1" "g2 (2 * x - 1) = g1 (2 * y)"
    have g1im: "g1 (2 * y) ∈ g1 ` {0..1} ∩ g2 ` {0..1}"
      using xy
      apply simp
      apply (rule_tac x="2 * x - 1" in image_eqI, auto)
      done
    have False
      using subsetD [OF sb g1im] xy
      apply auto
      apply (drule inj_onD [OF injg1])
      using g21 [symmetric] xyI
      apply (auto dest: inj_onD [OF injg2])
      done
   } note * = this
  { fix x and y::real
    assume xy: "y ≤ 1" "0 ≤ x" "¬ y * 2 ≤ 1" "x * 2 ≤ 1" "g1 (2 * x) = g2 (2 * y - 1)"
    have g1im: "g1 (2 * x) ∈ g1 ` {0..1} ∩ g2 ` {0..1}"
      using xy
      apply simp
      apply (rule_tac x="2 * x" in image_eqI, auto)
      done
    have "x = 0 ∧ y = 1"
      using subsetD [OF sb g1im] xy
      apply auto
      apply (force dest: inj_onD [OF injg1])
      using  g21 [symmetric]
      apply (auto dest: inj_onD [OF injg2])
      done
   } note ** = this
  show ?thesis
    using assms
    apply (simp add: arc_def simple_path_def path_join, clarify)
    apply (simp add: joinpaths_def split: if_split_asm)
    apply (force dest: inj_onD [OF injg1])
    apply (metis *)
    apply (metis **)
    apply (force dest: inj_onD [OF injg2])
    done
qed

lemma arc_join:
  assumes "arc g1" "arc g2"
          "pathfinish g1 = pathstart g2"
          "path_image g1 ∩ path_image g2 ⊆ {pathstart g2}"
    shows "arc(g1 +++ g2)"
proof -
  have injg1: "inj_on g1 {0..1}"
    using assms
    by (simp add: arc_def)
  have injg2: "inj_on g2 {0..1}"
    using assms
    by (simp add: arc_def)
  have g11: "g1 1 = g2 0"
   and sb:  "g1 ` {0..1} ∩ g2 ` {0..1} ⊆ {g2 0}"
    using assms
    by (simp_all add: arc_def pathfinish_def pathstart_def path_image_def)
  { fix x and y::real
    assume xy: "x ≤ 1" "0 ≤ y" " y * 2 ≤ 1" "¬ x * 2 ≤ 1" "g2 (2 * x - 1) = g1 (2 * y)"
    have g1im: "g1 (2 * y) ∈ g1 ` {0..1} ∩ g2 ` {0..1}"
      using xy
      apply simp
      apply (rule_tac x="2 * x - 1" in image_eqI, auto)
      done
    have False
      using subsetD [OF sb g1im] xy
      by (auto dest: inj_onD [OF injg2])
   } note * = this
  show ?thesis
    apply (simp add: arc_def inj_on_def)
    apply (clarsimp simp add: arc_imp_path assms path_join)
    apply (simp add: joinpaths_def split: if_split_asm)
    apply (force dest: inj_onD [OF injg1])
    apply (metis *)
    apply (metis *)
    apply (force dest: inj_onD [OF injg2])
    done
qed

lemma reversepath_joinpaths:
    "pathfinish g1 = pathstart g2 ⟹ reversepath(g1 +++ g2) = reversepath g2 +++ reversepath g1"
  unfolding reversepath_def pathfinish_def pathstart_def joinpaths_def
  by (rule ext) (auto simp: mult.commute)


subsection%unimportant‹Some reversed and "if and only if" versions of joining theorems›

lemma path_join_path_ends:
  fixes g1 :: "real ⇒ 'a::metric_space"
  assumes "path(g1 +++ g2)" "path g2"
    shows "pathfinish g1 = pathstart g2"
proof (rule ccontr)
  define e where "e = dist (g1 1) (g2 0)"
  assume Neg: "pathfinish g1 ≠ pathstart g2"
  then have "0 < dist (pathfinish g1) (pathstart g2)"
    by auto
  then have "e > 0"
    by (metis e_def pathfinish_def pathstart_def)
  then obtain d1 where "d1 > 0"
       and d1: "⋀x'. ⟦x'∈{0..1}; norm x' < d1⟧ ⟹ dist (g2 x') (g2 0) < e/2"
    using assms(2) unfolding path_def continuous_on_iff
    apply (drule_tac x=0 in bspec, simp)
    by (metis half_gt_zero_iff norm_conv_dist)
  obtain d2 where "d2 > 0"
       and d2: "⋀x'. ⟦x'∈{0..1}; dist x' (1/2) < d2⟧
                      ⟹ dist ((g1 +++ g2) x') (g1 1) < e/2"
    using assms(1) ‹e > 0› unfolding path_def continuous_on_iff
    apply (drule_tac x="1/2" in bspec, simp)
    apply (drule_tac x="e/2" in spec)
    apply (force simp: joinpaths_def)
    done
  have int01_1: "min (1/2) (min d1 d2) / 2 ∈ {0..1}"
    using ‹d1 > 0› ‹d2 > 0› by (simp add: min_def)
  have dist1: "norm (min (1 / 2) (min d1 d2) / 2) < d1"
    using ‹d1 > 0› ‹d2 > 0› by (simp add: min_def dist_norm)
  have int01_2: "1/2 + min (1/2) (min d1 d2) / 4 ∈ {0..1}"
    using ‹d1 > 0› ‹d2 > 0› by (simp add: min_def)
  have dist2: "dist (1 / 2 + min (1 / 2) (min d1 d2) / 4) (1 / 2) < d2"
    using ‹d1 > 0› ‹d2 > 0› by (simp add: min_def dist_norm)
  have [simp]: "~ min (1 / 2) (min d1 d2) ≤ 0"
    using ‹d1 > 0› ‹d2 > 0› by (simp add: min_def)
  have "dist (g2 (min (1 / 2) (min d1 d2) / 2)) (g1 1) < e/2"
       "dist (g2 (min (1 / 2) (min d1 d2) / 2)) (g2 0) < e/2"
    using d1 [OF int01_1 dist1] d2 [OF int01_2 dist2] by (simp_all add: joinpaths_def)
  then have "dist (g1 1) (g2 0) < e/2 + e/2"
    using dist_triangle_half_r e_def by blast
  then show False
    by (simp add: e_def [symmetric])
qed

lemma path_join_eq [simp]:
  fixes g1 :: "real ⇒ 'a::metric_space"
  assumes "path g1" "path g2"
    shows "path(g1 +++ g2) ⟷ pathfinish g1 = pathstart g2"
  using assms by (metis path_join_path_ends path_join_imp)

lemma simple_path_joinE:
  assumes "simple_path(g1 +++ g2)" and "pathfinish g1 = pathstart g2"
  obtains "arc g1" "arc g2"
          "path_image g1 ∩ path_image g2 ⊆ {pathstart g1, pathstart g2}"
proof -
  have *: "⋀x y. ⟦0 ≤ x; x ≤ 1; 0 ≤ y; y ≤ 1; (g1 +++ g2) x = (g1 +++ g2) y⟧
               ⟹ x = y ∨ x = 0 ∧ y = 1 ∨ x = 1 ∧ y = 0"
    using assms by (simp add: simple_path_def)
  have "path g1"
    using assms path_join simple_path_imp_path by blast
  moreover have "inj_on g1 {0..1}"
  proof (clarsimp simp: inj_on_def)
    fix x y
    assume "g1 x = g1 y" "0 ≤ x" "x ≤ 1" "0 ≤ y" "y ≤ 1"
    then show "x = y"
      using * [of "x/2" "y/2"] by (simp add: joinpaths_def split_ifs)
  qed
  ultimately have "arc g1"
    using assms  by (simp add: arc_def)
  have [simp]: "g2 0 = g1 1"
    using assms by (metis pathfinish_def pathstart_def)
  have "path g2"
    using assms path_join simple_path_imp_path by blast
  moreover have "inj_on g2 {0..1}"
  proof (clarsimp simp: inj_on_def)
    fix x y
    assume "g2 x = g2 y" "0 ≤ x" "x ≤ 1" "0 ≤ y" "y ≤ 1"
    then show "x = y"
      using * [of "(x + 1) / 2" "(y + 1) / 2"]
      by (force simp: joinpaths_def split_ifs divide_simps)
  qed
  ultimately have "arc g2"
    using assms  by (simp add: arc_def)
  have "g2 y = g1 0 ∨ g2 y = g1 1"
       if "g1 x = g2 y" "0 ≤ x" "x ≤ 1" "0 ≤ y" "y ≤ 1" for x y
      using * [of "x / 2" "(y + 1) / 2"] that
      by (auto simp: joinpaths_def split_ifs divide_simps)
  then have "path_image g1 ∩ path_image g2 ⊆ {pathstart g1, pathstart g2}"
    by (fastforce simp: pathstart_def pathfinish_def path_image_def)
  with ‹arc g1› ‹arc g2› show ?thesis using that by blast
qed

lemma simple_path_join_loop_eq:
  assumes "pathfinish g2 = pathstart g1" "pathfinish g1 = pathstart g2"
    shows "simple_path(g1 +++ g2) ⟷
             arc g1 ∧ arc g2 ∧ path_image g1 ∩ path_image g2 ⊆ {pathstart g1, pathstart g2}"
by (metis assms simple_path_joinE simple_path_join_loop)

lemma arc_join_eq:
  assumes "pathfinish g1 = pathstart g2"
    shows "arc(g1 +++ g2) ⟷
           arc g1 ∧ arc g2 ∧ path_image g1 ∩ path_image g2 ⊆ {pathstart g2}"
           (is "?lhs = ?rhs")
proof
  assume ?lhs
  then have "simple_path(g1 +++ g2)" by (rule arc_imp_simple_path)
  then have *: "⋀x y. ⟦0 ≤ x; x ≤ 1; 0 ≤ y; y ≤ 1; (g1 +++ g2) x = (g1 +++ g2) y⟧
               ⟹ x = y ∨ x = 0 ∧ y = 1 ∨ x = 1 ∧ y = 0"
    using assms by (simp add: simple_path_def)
  have False if "g1 0 = g2 u" "0 ≤ u" "u ≤ 1" for u
    using * [of 0 "(u + 1) / 2"] that assms arc_distinct_ends [OF ‹?lhs›]
    by (auto simp: joinpaths_def pathstart_def pathfinish_def split_ifs divide_simps)
  then have n1: "~ (pathstart g1 ∈ path_image g2)"
    unfolding pathstart_def path_image_def
    using atLeastAtMost_iff by blast
  show ?rhs using ‹?lhs›
    apply (rule simple_path_joinE [OF arc_imp_simple_path assms])
    using n1 by force
next
  assume ?rhs then show ?lhs
    using assms
    by (fastforce simp: pathfinish_def pathstart_def intro!: arc_join)
qed

lemma arc_join_eq_alt:
        "pathfinish g1 = pathstart g2
        ⟹ (arc(g1 +++ g2) ⟷
             arc g1 ∧ arc g2 ∧
             path_image g1 ∩ path_image g2 = {pathstart g2})"
using pathfinish_in_path_image by (fastforce simp: arc_join_eq)


subsection%unimportant‹The joining of paths is associative›

lemma path_assoc:
    "⟦pathfinish p = pathstart q; pathfinish q = pathstart r⟧
     ⟹ path(p +++ (q +++ r)) ⟷ path((p +++ q) +++ r)"
by simp

lemma simple_path_assoc:
  assumes "pathfinish p = pathstart q" "pathfinish q = pathstart r"
    shows "simple_path (p +++ (q +++ r)) ⟷ simple_path ((p +++ q) +++ r)"
proof (cases "pathstart p = pathfinish r")
  case True show ?thesis
  proof
    assume "simple_path (p +++ q +++ r)"
    with assms True show "simple_path ((p +++ q) +++ r)"
      by (fastforce simp add: simple_path_join_loop_eq arc_join_eq path_image_join
                    dest: arc_distinct_ends [of r])
  next
    assume 0: "simple_path ((p +++ q) +++ r)"
    with assms True have q: "pathfinish r ∉ path_image q"
      using arc_distinct_ends
      by (fastforce simp add: simple_path_join_loop_eq arc_join_eq path_image_join)
    have "pathstart r ∉ path_image p"
      using assms
      by (metis 0 IntI arc_distinct_ends arc_join_eq_alt empty_iff insert_iff
              pathfinish_in_path_image pathfinish_join simple_path_joinE)
    with assms 0 q True show "simple_path (p +++ q +++ r)"
      by (auto simp: simple_path_join_loop_eq arc_join_eq path_image_join
               dest!: subsetD [OF _ IntI])
  qed
next
  case False
  { fix x :: 'a
    assume a: "path_image p ∩ path_image q ⊆ {pathstart q}"
              "(path_image p ∪ path_image q) ∩ path_image r ⊆ {pathstart r}"
              "x ∈ path_image p" "x ∈ path_image r"
    have "pathstart r ∈ path_image q"
      by (metis assms(2) pathfinish_in_path_image)
    with a have "x = pathstart q"
      by blast
  }
  with False assms show ?thesis
    by (auto simp: simple_path_eq_arc simple_path_join_loop_eq arc_join_eq path_image_join)
qed

lemma arc_assoc:
     "⟦pathfinish p = pathstart q; pathfinish q = pathstart r⟧
      ⟹ arc(p +++ (q +++ r)) ⟷ arc((p +++ q) +++ r)"
by (simp add: arc_simple_path simple_path_assoc)

subsubsection%unimportant‹Symmetry and loops›

lemma path_sym:
    "⟦pathfinish p = pathstart q; pathfinish q = pathstart p⟧ ⟹ path(p +++ q) ⟷ path(q +++ p)"
  by auto

lemma simple_path_sym:
    "⟦pathfinish p = pathstart q; pathfinish q = pathstart p⟧
     ⟹ simple_path(p +++ q) ⟷ simple_path(q +++ p)"
by (metis (full_types) inf_commute insert_commute simple_path_joinE simple_path_join_loop)

lemma path_image_sym:
    "⟦pathfinish p = pathstart q; pathfinish q = pathstart p⟧
     ⟹ path_image(p +++ q) = path_image(q +++ p)"
by (simp add: path_image_join sup_commute)


section‹Choosing a subpath of an existing path›

definition%important subpath :: "real ⇒ real ⇒ (real ⇒ 'a) ⇒ real ⇒ 'a::real_normed_vector"
  where "subpath a b g ≡ λx. g((b - a) * x + a)"

lemma path_image_subpath_gen:
  fixes g :: "_ ⇒ 'a::real_normed_vector"
  shows "path_image(subpath u v g) = g ` (closed_segment u v)"
  apply (simp add: closed_segment_real_eq path_image_def subpath_def)
  apply (subst o_def [of g, symmetric])
  apply (simp add: image_comp [symmetric])
  done

lemma path_image_subpath:
  fixes g :: "real ⇒ 'a::real_normed_vector"
  shows "path_image(subpath u v g) = (if u ≤ v then g ` {u..v} else g ` {v..u})"
  by (simp add: path_image_subpath_gen closed_segment_eq_real_ivl)

lemma path_image_subpath_commute:
  fixes g :: "real ⇒ 'a::real_normed_vector"
  shows "path_image(subpath u v g) = path_image(subpath v u g)"
  by (simp add: path_image_subpath_gen closed_segment_eq_real_ivl)

lemma path_subpath [simp]:
  fixes g :: "real ⇒ 'a::real_normed_vector"
  assumes "path g" "u ∈ {0..1}" "v ∈ {0..1}"
    shows "path(subpath u v g)"
proof -
  have "continuous_on {0..1} (g ∘ (λx. ((v-u) * x+ u)))"
    apply (rule continuous_intros | simp)+
    apply (simp add: image_affinity_atLeastAtMost [where c=u])
    using assms
    apply (auto simp: path_def continuous_on_subset)
    done
  then show ?thesis
    by (simp add: path_def subpath_def)
qed

lemma pathstart_subpath [simp]: "pathstart(subpath u v g) = g(u)"
  by (simp add: pathstart_def subpath_def)

lemma pathfinish_subpath [simp]: "pathfinish(subpath u v g) = g(v)"
  by (simp add: pathfinish_def subpath_def)

lemma subpath_trivial [simp]: "subpath 0 1 g = g"
  by (simp add: subpath_def)

lemma subpath_reversepath: "subpath 1 0 g = reversepath g"
  by (simp add: reversepath_def subpath_def)

lemma reversepath_subpath: "reversepath(subpath u v g) = subpath v u g"
  by (simp add: reversepath_def subpath_def algebra_simps)

lemma subpath_translation: "subpath u v ((λx. a + x) ∘ g) = (λx. a + x) ∘ subpath u v g"
  by (rule ext) (simp add: subpath_def)

lemma subpath_linear_image: "linear f ⟹ subpath u v (f ∘ g) = f ∘ subpath u v g"
  by (rule ext) (simp add: subpath_def)

lemma affine_ineq:
  fixes x :: "'a::linordered_idom"
  assumes "x ≤ 1" "v ≤ u"
    shows "v + x * u ≤ u + x * v"
proof -
  have "(1-x)*(u-v) ≥ 0"
    using assms by auto
  then show ?thesis
    by (simp add: algebra_simps)
qed

lemma sum_le_prod1:
  fixes a::real shows "⟦a ≤ 1; b ≤ 1⟧ ⟹ a + b ≤ 1 + a * b"
by (metis add.commute affine_ineq less_eq_real_def mult.right_neutral)

lemma simple_path_subpath_eq:
  "simple_path(subpath u v g) ⟷
     path(subpath u v g) ∧ u≠v ∧
     (∀x y. x ∈ closed_segment u v ∧ y ∈ closed_segment u v ∧ g x = g y
                ⟶ x = y ∨ x = u ∧ y = v ∨ x = v ∧ y = u)"
    (is "?lhs = ?rhs")
proof (rule iffI)
  assume ?lhs
  then have p: "path (λx. g ((v - u) * x + u))"
        and sim: "(⋀x y. ⟦x∈{0..1}; y∈{0..1}; g ((v - u) * x + u) = g ((v - u) * y + u)⟧
                  ⟹ x = y ∨ x = 0 ∧ y = 1 ∨ x = 1 ∧ y = 0)"
    by (auto simp: simple_path_def subpath_def)
  { fix x y
    assume "x ∈ closed_segment u v" "y ∈ closed_segment u v" "g x = g y"
    then have "x = y ∨ x = u ∧ y = v ∨ x = v ∧ y = u"
    using sim [of "(x-u)/(v-u)" "(y-u)/(v-u)"] p
    by (auto simp: closed_segment_real_eq image_affinity_atLeastAtMost divide_simps
       split: if_split_asm)
  } moreover
  have "path(subpath u v g) ∧ u≠v"
    using sim [of "1/3" "2/3"] p
    by (auto simp: subpath_def)
  ultimately show ?rhs
    by metis
next
  assume ?rhs
  then
  have d1: "⋀x y. ⟦g x = g y; u ≤ x; x ≤ v; u ≤ y; y ≤ v⟧ ⟹ x = y ∨ x = u ∧ y = v ∨ x = v ∧ y = u"
   and d2: "⋀x y. ⟦g x = g y; v ≤ x; x ≤ u; v ≤ y; y ≤ u⟧ ⟹ x = y ∨ x = u ∧ y = v ∨ x = v ∧ y = u"
   and ne: "u < v ∨ v < u"
   and psp: "path (subpath u v g)"
    by (auto simp: closed_segment_real_eq image_affinity_atLeastAtMost)
  have [simp]: "⋀x. u + x * v = v + x * u ⟷ u=v ∨ x=1"
    by algebra
  show ?lhs using psp ne
    unfolding simple_path_def subpath_def
    by (fastforce simp add: algebra_simps affine_ineq mult_left_mono crossproduct_eq dest: d1 d2)
qed

lemma arc_subpath_eq:
  "arc(subpath u v g) ⟷ path(subpath u v g) ∧ u≠v ∧ inj_on g (closed_segment u v)"
    (is "?lhs = ?rhs")
proof (rule iffI)
  assume ?lhs
  then have p: "path (λx. g ((v - u) * x + u))"
        and sim: "(⋀x y. ⟦x∈{0..1}; y∈{0..1}; g ((v - u) * x + u) = g ((v - u) * y + u)⟧
                  ⟹ x = y)"
    by (auto simp: arc_def inj_on_def subpath_def)
  { fix x y
    assume "x ∈ closed_segment u v" "y ∈ closed_segment u v" "g x = g y"
    then have "x = y"
    using sim [of "(x-u)/(v-u)" "(y-u)/(v-u)"] p
    by (force simp: inj_on_def closed_segment_real_eq image_affinity_atLeastAtMost divide_simps
       split: if_split_asm)
  } moreover
  have "path(subpath u v g) ∧ u≠v"
    using sim [of "1/3" "2/3"] p
    by (auto simp: subpath_def)
  ultimately show ?rhs
    unfolding inj_on_def
    by metis
next
  assume ?rhs
  then
  have d1: "⋀x y. ⟦g x = g y; u ≤ x; x ≤ v; u ≤ y; y ≤ v⟧ ⟹ x = y"
   and d2: "⋀x y. ⟦g x = g y; v ≤ x; x ≤ u; v ≤ y; y ≤ u⟧ ⟹ x = y"
   and ne: "u < v ∨ v < u"
   and psp: "path (subpath u v g)"
    by (auto simp: inj_on_def closed_segment_real_eq image_affinity_atLeastAtMost)
  show ?lhs using psp ne
    unfolding arc_def subpath_def inj_on_def
    by (auto simp: algebra_simps affine_ineq mult_left_mono crossproduct_eq dest: d1 d2)
qed


lemma simple_path_subpath:
  assumes "simple_path g" "u ∈ {0..1}" "v ∈ {0..1}" "u ≠ v"
  shows "simple_path(subpath u v g)"
  using assms
  apply (simp add: simple_path_subpath_eq simple_path_imp_path)
  apply (simp add: simple_path_def closed_segment_real_eq image_affinity_atLeastAtMost, fastforce)
  done

lemma arc_simple_path_subpath:
    "⟦simple_path g; u ∈ {0..1}; v ∈ {0..1}; g u ≠ g v⟧ ⟹ arc(subpath u v g)"
  by (force intro: simple_path_subpath simple_path_imp_arc)

lemma arc_subpath_arc:
    "⟦arc g; u ∈ {0..1}; v ∈ {0..1}; u ≠ v⟧ ⟹ arc(subpath u v g)"
  by (meson arc_def arc_imp_simple_path arc_simple_path_subpath inj_onD)

lemma arc_simple_path_subpath_interior:
    "⟦simple_path g; u ∈ {0..1}; v ∈ {0..1}; u ≠ v; ¦u-v¦ < 1⟧ ⟹ arc(subpath u v g)"
    apply (rule arc_simple_path_subpath)
    apply (force simp: simple_path_def)+
    done

lemma path_image_subpath_subset:
    "⟦u ∈ {0..1}; v ∈ {0..1}⟧ ⟹ path_image(subpath u v g) ⊆ path_image g"
  apply (simp add: closed_segment_real_eq image_affinity_atLeastAtMost path_image_subpath)
  apply (auto simp: path_image_def)
  done  

lemma join_subpaths_middle: "subpath (0) ((1 / 2)) p +++ subpath ((1 / 2)) 1 p = p"
  by (rule ext) (simp add: joinpaths_def subpath_def divide_simps)

subsection%unimportant‹There is a subpath to the frontier›

lemma subpath_to_frontier_explicit:
    fixes S :: "'a::metric_space set"
    assumes g: "path g" and "pathfinish g ∉ S"
    obtains u where "0 ≤ u" "u ≤ 1"
                "⋀x. 0 ≤ x ∧ x < u ⟹ g x ∈ interior S"
                "(g u ∉ interior S)" "(u = 0 ∨ g u ∈ closure S)"
proof -
  have gcon: "continuous_on {0..1} g"     using g by (simp add: path_def)
  then have com: "compact ({0..1} ∩ {u. g u ∈ closure (- S)})"
    apply (simp add: Int_commute [of "{0..1}"] compact_eq_bounded_closed closed_vimage_Int [unfolded vimage_def])
    using compact_eq_bounded_closed apply fastforce
    done
  have "1 ∈ {u. g u ∈ closure (- S)}"
    using assms by (simp add: pathfinish_def closure_def)
  then have dis: "{0..1} ∩ {u. g u ∈ closure (- S)} ≠ {}"
    using atLeastAtMost_iff zero_le_one by blast
  then obtain u where "0 ≤ u" "u ≤ 1" and gu: "g u ∈ closure (- S)"
                  and umin: "⋀t. ⟦0 ≤ t; t ≤ 1; g t ∈ closure (- S)⟧ ⟹ u ≤ t"
    using compact_attains_inf [OF com dis] by fastforce
  then have umin': "⋀t. ⟦0 ≤ t; t ≤ 1; t < u⟧ ⟹  g t ∈ S"
    using closure_def by fastforce
  { assume "u ≠ 0"
    then have "u > 0" using ‹0 ≤ u› by auto
    { fix e::real assume "e > 0"
      obtain d where "d>0" and d: "⋀x'. ⟦x' ∈ {0..1}; dist x' u ≤ d⟧ ⟹ dist (g x') (g u) < e"
        using continuous_onE [OF gcon _ ‹e > 0›] ‹0 ≤ _› ‹_ ≤ 1› atLeastAtMost_iff by auto
      have *: "dist (max 0 (u - d / 2)) u ≤ d"
        using ‹0 ≤ u› ‹u ≤ 1› ‹d > 0› by (simp add: dist_real_def)
      have "∃y∈S. dist y (g u) < e"
        using ‹0 < u› ‹u ≤ 1› ‹d > 0›
        by (force intro: d [OF _ *] umin')
    }
    then have "g u ∈ closure S"
      by (simp add: frontier_def closure_approachable)
  }
  then show ?thesis
    apply (rule_tac u=u in that)
    apply (auto simp: ‹0 ≤ u› ‹u ≤ 1› gu interior_closure umin)
    using ‹_ ≤ 1› interior_closure umin apply fastforce
    done
qed

lemma subpath_to_frontier_strong:
    assumes g: "path g" and "pathfinish g ∉ S"
    obtains u where "0 ≤ u" "u ≤ 1" "g u ∉ interior S"
                    "u = 0 ∨ (∀x. 0 ≤ x ∧ x < 1 ⟶ subpath 0 u g x ∈ interior S)  ∧  g u ∈ closure S"
proof -
  obtain u where "0 ≤ u" "u ≤ 1"
             and gxin: "⋀x. 0 ≤ x ∧ x < u ⟹ g x ∈ interior S"
             and gunot: "(g u ∉ interior S)" and u0: "(u = 0 ∨ g u ∈ closure S)"
    using subpath_to_frontier_explicit [OF assms] by blast
  show ?thesis
    apply (rule that [OF ‹0 ≤ u› ‹u ≤ 1›])
    apply (simp add: gunot)
    using ‹0 ≤ u› u0 by (force simp: subpath_def gxin)
qed

lemma subpath_to_frontier:
    assumes g: "path g" and g0: "pathstart g ∈ closure S" and g1: "pathfinish g ∉ S"
    obtains u where "0 ≤ u" "u ≤ 1" "g u ∈ frontier S" "(path_image(subpath 0 u g) - {g u}) ⊆ interior S"
proof -
  obtain u where "0 ≤ u" "u ≤ 1"
             and notin: "g u ∉ interior S"
             and disj: "u = 0 ∨
                        (∀x. 0 ≤ x ∧ x < 1 ⟶ subpath 0 u g x ∈ interior S) ∧ g u ∈ closure S"
    using subpath_to_frontier_strong [OF g g1] by blast
  show ?thesis
    apply (rule that [OF ‹0 ≤ u› ‹u ≤ 1›])
    apply (metis DiffI disj frontier_def g0 notin pathstart_def)
    using ‹0 ≤ u› g0 disj
    apply (simp add: path_image_subpath_gen)
    apply (auto simp: closed_segment_eq_real_ivl pathstart_def pathfinish_def subpath_def)
    apply (rename_tac y)
    apply (drule_tac x="y/u" in spec)
    apply (auto split: if_split_asm)
    done
qed

lemma exists_path_subpath_to_frontier:
    fixes S :: "'a::real_normed_vector set"
    assumes "path g" "pathstart g ∈ closure S" "pathfinish g ∉ S"
    obtains h where "path h" "pathstart h = pathstart g" "path_image h ⊆ path_image g"
                    "path_image h - {pathfinish h} ⊆ interior S"
                    "pathfinish h ∈ frontier S"
proof -
  obtain u where u: "0 ≤ u" "u ≤ 1" "g u ∈ frontier S" "(path_image(subpath 0 u g) - {g u}) ⊆ interior S"
    using subpath_to_frontier [OF assms] by blast
  show ?thesis
    apply (rule that [of "subpath 0 u g"])
    using assms u
    apply (simp_all add: path_image_subpath)
    apply (simp add: pathstart_def)
    apply (force simp: closed_segment_eq_real_ivl path_image_def)
    done
qed

lemma exists_path_subpath_to_frontier_closed:
    fixes S :: "'a::real_normed_vector set"
    assumes S: "closed S" and g: "path g" and g0: "pathstart g ∈ S" and g1: "pathfinish g ∉ S"
    obtains h where "path h" "pathstart h = pathstart g" "path_image h ⊆ path_image g ∩ S"
                    "pathfinish h ∈ frontier S"
proof -
  obtain h where h: "path h" "pathstart h = pathstart g" "path_image h ⊆ path_image g"
                    "path_image h - {pathfinish h} ⊆ interior S"
                    "pathfinish h ∈ frontier S"
    using exists_path_subpath_to_frontier [OF g _ g1] closure_closed [OF S] g0 by auto
  show ?thesis
    apply (rule that [OF ‹path h›])
    using assms h
    apply auto
    apply (metis Diff_single_insert frontier_subset_eq insert_iff interior_subset subset_iff)
    done
qed

subsection ‹shiftpath: Reparametrizing a closed curve to start at some chosen point›

definition%important shiftpath :: "real ⇒ (real ⇒ 'a::topological_space) ⇒ real ⇒ 'a"
  where "shiftpath a f = (λx. if (a + x) ≤ 1 then f (a + x) else f (a + x - 1))"

lemma pathstart_shiftpath: "a ≤ 1 ⟹ pathstart (shiftpath a g) = g a"
  unfolding pathstart_def shiftpath_def by auto

lemma pathfinish_shiftpath:
  assumes "0 ≤ a"
    and "pathfinish g = pathstart g"
  shows "pathfinish (shiftpath a g) = g a"
  using assms
  unfolding pathstart_def pathfinish_def shiftpath_def
  by auto

lemma endpoints_shiftpath:
  assumes "pathfinish g = pathstart g"
    and "a ∈ {0 .. 1}"
  shows "pathfinish (shiftpath a g) = g a"
    and "pathstart (shiftpath a g) = g a"
  using assms
  by (auto intro!: pathfinish_shiftpath pathstart_shiftpath)

lemma closed_shiftpath:
  assumes "pathfinish g = pathstart g"
    and "a ∈ {0..1}"
  shows "pathfinish (shiftpath a g) = pathstart (shiftpath a g)"
  using endpoints_shiftpath[OF assms]
  by auto

lemma path_shiftpath:
  assumes "path g"
    and "pathfinish g = pathstart g"
    and "a ∈ {0..1}"
  shows "path (shiftpath a g)"
proof -
  have *: "{0 .. 1} = {0 .. 1-a} ∪ {1-a .. 1}"
    using assms(3) by auto
  have **: "⋀x. x + a = 1 ⟹ g (x + a - 1) = g (x + a)"
    using assms(2)[unfolded pathfinish_def pathstart_def]
    by auto
  show ?thesis
    unfolding path_def shiftpath_def *
  proof (rule continuous_on_closed_Un)
    have contg: "continuous_on {0..1} g"
      using ‹path g› path_def by blast
    show "continuous_on {0..1-a} (λx. if a + x ≤ 1 then g (a + x) else g (a + x - 1))"
    proof (rule continuous_on_eq)
      show "continuous_on {0..1-a} (g ∘ (+) a)"
        by (intro continuous_intros continuous_on_subset [OF contg]) (use ‹a ∈ {0..1}› in auto)
    qed auto
    show "continuous_on {1-a..1} (λx. if a + x ≤ 1 then g (a + x) else g (a + x - 1))"
    proof (rule continuous_on_eq)
      show "continuous_on {1-a..1} (g ∘ (+) (a - 1))"
        by (intro continuous_intros continuous_on_subset [OF contg]) (use ‹a ∈ {0..1}› in auto)
    qed (auto simp:  "**" add.commute add_diff_eq)
  qed auto
qed

lemma shiftpath_shiftpath:
  assumes "pathfinish g = pathstart g"
    and "a ∈ {0..1}"
    and "x ∈ {0..1}"
  shows "shiftpath (1 - a) (shiftpath a g) x = g x"
  using assms
  unfolding pathfinish_def pathstart_def shiftpath_def
  by auto

lemma path_image_shiftpath:
  assumes a: "a ∈ {0..1}"
    and "pathfinish g = pathstart g"
  shows "path_image (shiftpath a g) = path_image g"
proof -
  { fix x
    assume g: "g 1 = g 0" "x ∈ {0..1::real}" and gne: "⋀y. y∈{0..1} ∩ {x. ¬ a + x ≤ 1} ⟹ g x ≠ g (a + y - 1)"
    then have "∃y∈{0..1} ∩ {x. a + x ≤ 1}. g x = g (a + y)"
    proof (cases "a ≤ x")
      case False
      then show ?thesis
        apply (rule_tac x="1 + x - a" in bexI)
        using g gne[of "1 + x - a"] a
        apply (force simp: field_simps)+
        done
    next
      case True
      then show ?thesis
        using g a  by (rule_tac x="x - a" in bexI) (auto simp: field_simps)
    qed
  }
  then show ?thesis
    using assms
    unfolding shiftpath_def path_image_def pathfinish_def pathstart_def
    by (auto simp: image_iff)
qed

lemma simple_path_shiftpath:
  assumes "simple_path g" "pathfinish g = pathstart g" and a: "0 ≤ a" "a ≤ 1"
    shows "simple_path (shiftpath a g)"
  unfolding simple_path_def
proof (intro conjI impI ballI)
  show "path (shiftpath a g)"
    by (simp add: assms path_shiftpath simple_path_imp_path)
  have *: "⋀x y. ⟦g x = g y; x ∈ {0..1}; y ∈ {0..1}⟧ ⟹ x = y ∨ x = 0 ∧ y = 1 ∨ x = 1 ∧ y = 0"
    using assms by (simp add:  simple_path_def)
  show "x = y ∨ x = 0 ∧ y = 1 ∨ x = 1 ∧ y = 0"
    if "x ∈ {0..1}" "y ∈ {0..1}" "shiftpath a g x = shiftpath a g y" for x y
    using that a unfolding shiftpath_def
    by (force split: if_split_asm dest!: *)
qed

subsection ‹Special case of straight-line paths›

definition%important linepath :: "'a::real_normed_vector ⇒ 'a ⇒ real ⇒ 'a"
  where "linepath a b = (λx. (1 - x) *R a + x *R b)"

lemma pathstart_linepath[simp]: "pathstart (linepath a b) = a"
  unfolding pathstart_def linepath_def
  by auto

lemma pathfinish_linepath[simp]: "pathfinish (linepath a b) = b"
  unfolding pathfinish_def linepath_def
  by auto

lemma continuous_linepath_at[intro]: "continuous (at x) (linepath a b)"
  unfolding linepath_def
  by (intro continuous_intros)

lemma continuous_on_linepath [intro,continuous_intros]: "continuous_on s (linepath a b)"
  using continuous_linepath_at
  by (auto intro!: continuous_at_imp_continuous_on)

lemma path_linepath[iff]: "path (linepath a b)"
  unfolding path_def
  by (rule continuous_on_linepath)

lemma path_image_linepath[simp]: "path_image (linepath a b) = closed_segment a b"
  unfolding path_image_def segment linepath_def
  by auto

lemma reversepath_linepath[simp]: "reversepath (linepath a b) = linepath b a"
  unfolding reversepath_def linepath_def
  by auto

lemma linepath_0 [simp]: "linepath 0 b x = x *R b"
  by (simp add: linepath_def)

lemma arc_linepath:
  assumes "a ≠ b" shows [simp]: "arc (linepath a b)"
proof -
  {
    fix x y :: "real"
    assume "x *R b + y *R a = x *R a + y *R b"
    then have "(x - y) *R a = (x - y) *R b"
      by (simp add: algebra_simps)
    with assms have "x = y"
      by simp
  }
  then show ?thesis
    unfolding arc_def inj_on_def
    by (fastforce simp: algebra_simps linepath_def)
qed

lemma simple_path_linepath[intro]: "a ≠ b ⟹ simple_path (linepath a b)"
  by (simp add: arc_imp_simple_path)

lemma linepath_trivial [simp]: "linepath a a x = a"
  by (simp add: linepath_def real_vector.scale_left_diff_distrib)

lemma linepath_refl: "linepath a a = (λx. a)"
  by auto

lemma subpath_refl: "subpath a a g = linepath (g a) (g a)"
  by (simp add: subpath_def linepath_def algebra_simps)

lemma linepath_of_real: "(linepath (of_real a) (of_real b) x) = of_real ((1 - x)*a + x*b)"
  by (simp add: scaleR_conv_of_real linepath_def)

lemma of_real_linepath: "of_real (linepath a b x) = linepath (of_real a) (of_real b) x"
  by (metis linepath_of_real mult.right_neutral of_real_def real_scaleR_def)

lemma inj_on_linepath:
  assumes "a ≠ b" shows "inj_on (linepath a b) {0..1}"
proof (clarsimp simp: inj_on_def linepath_def)
  fix x y
  assume "(1 - x) *R a + x *R b = (1 - y) *R a + y *R b" "0 ≤ x" "x ≤ 1" "0 ≤ y" "y ≤ 1"
  then have "x *R (a - b) = y *R (a - b)"
    by (auto simp: algebra_simps)
  then show "x=y"
    using assms by auto
qed


subsection%unimportant‹Segments via convex hulls›

lemma segments_subset_convex_hull:
    "closed_segment a b ⊆ (convex hull {a,b,c})"
    "closed_segment a c ⊆ (convex hull {a,b,c})"
    "closed_segment b c ⊆ (convex hull {a,b,c})"
    "closed_segment b a ⊆ (convex hull {a,b,c})"
    "closed_segment c a ⊆ (convex hull {a,b,c})"
    "closed_segment c b ⊆ (convex hull {a,b,c})"
by (auto simp: segment_convex_hull linepath_of_real  elim!: rev_subsetD [OF _ hull_mono])

lemma midpoints_in_convex_hull:
  assumes "x ∈ convex hull s" "y ∈ convex hull s"
    shows "midpoint x y ∈ convex hull s"
proof -
  have "(1 - inverse(2)) *R x + inverse(2) *R y ∈ convex hull s"
    by (rule convexD_alt) (use assms in auto)
  then show ?thesis
    by (simp add: midpoint_def algebra_simps)
qed

lemma not_in_interior_convex_hull_3:
  fixes a :: "complex"
  shows "a ∉ interior(convex hull {a,b,c})"
        "b ∉ interior(convex hull {a,b,c})"
        "c ∉ interior(convex hull {a,b,c})"
  by (auto simp: card_insert_le_m1 not_in_interior_convex_hull)

lemma midpoint_in_closed_segment [simp]: "midpoint a b ∈ closed_segment a b"
  using midpoints_in_convex_hull segment_convex_hull by blast

lemma midpoint_in_open_segment [simp]: "midpoint a b ∈ open_segment a b ⟷ a ≠ b"
  by (simp add: open_segment_def)

lemma continuous_IVT_local_extremum:
  fixes f :: "'a::euclidean_space ⇒ real"
  assumes contf: "continuous_on (closed_segment a b) f"
      and "a ≠ b" "f a = f b"
  obtains z where "z ∈ open_segment a b"
                  "(∀w ∈ closed_segment a b. (f w) ≤ (f z)) ∨
                   (∀w ∈ closed_segment a b. (f z) ≤ (f w))"
proof -
  obtain c where "c ∈ closed_segment a b" and c: "⋀y. y ∈ closed_segment a b ⟹ f y ≤ f c"
    using continuous_attains_sup [of "closed_segment a b" f] contf by auto
  obtain d where "d ∈ closed_segment a b" and d: "⋀y. y ∈ closed_segment a b ⟹ f d ≤ f y"
    using continuous_attains_inf [of "closed_segment a b" f] contf by auto
  show ?thesis
  proof (cases "c ∈ open_segment a b ∨ d ∈ open_segment a b")
    case True
    then show ?thesis
      using c d that by blast
  next
    case False
    then have "(c = a ∨ c = b) ∧ (d = a ∨ d = b)"
      by (simp add: ‹c ∈ closed_segment a b› ‹d ∈ closed_segment a b› open_segment_def)
    with ‹a ≠ b› ‹f a = f b› c d show ?thesis
      by (rule_tac z = "midpoint a b" in that) (fastforce+)
  qed
qed

text‹An injective map into R is also an open map w.r.T. the universe, and conversely. ›
proposition injective_eq_1d_open_map_UNIV:
  fixes f :: "real ⇒ real"
  assumes contf: "continuous_on S f" and S: "is_interval S"
    shows "inj_on f S ⟷ (∀T. open T ∧ T ⊆ S ⟶ open(f ` T))"
          (is "?lhs = ?rhs")
proof safe
  fix T
  assume injf: ?lhs and "open T" and "T ⊆ S"
  have "∃U. open U ∧ f x ∈ U ∧ U ⊆ f ` T" if "x ∈ T" for x
  proof -
    obtain δ where "δ > 0" and δ: "cball x δ ⊆ T"
      using ‹open T› ‹x ∈ T› open_contains_cball_eq by blast
    show ?thesis
    proof (intro exI conjI)
      have "closed_segment (x-δ) (x+δ) = {x-δ..x+δ}"
        using ‹0 < δ› by (auto simp: closed_segment_eq_real_ivl)
      also have "… ⊆ S"
        using δ ‹T ⊆ S› by (auto simp: dist_norm subset_eq)
      finally have "f ` (open_segment (x-δ) (x+δ)) = open_segment (f (x-δ)) (f (x+δ))"
        using continuous_injective_image_open_segment_1
        by (metis continuous_on_subset [OF contf] inj_on_subset [OF injf])
      then show "open (f ` {x-δ<..<x+δ})"
        using ‹0 < δ› by (simp add: open_segment_eq_real_ivl)
      show "f x ∈ f ` {x - δ<..<x + δ}"
        by (auto simp: ‹δ > 0›)
      show "f ` {x - δ<..<x + δ} ⊆ f ` T"
        using δ by (auto simp: dist_norm subset_iff)
    qed
  qed
  with open_subopen show "open (f ` T)"
    by blast
next
  assume R: ?rhs
  have False if xy: "x ∈ S" "y ∈ S" and "f x = f y" "x ≠ y" for x y
  proof -
    have "open (f ` open_segment x y)"
      using R
      by (metis S convex_contains_open_segment is_interval_convex open_greaterThanLessThan open_segment_eq_real_ivl xy)
    moreover
    have "continuous_on (closed_segment x y) f"
      by (meson S closed_segment_subset contf continuous_on_subset is_interval_convex that)
    then obtain ξ where "ξ ∈ open_segment x y"
                    and ξ: "(∀w ∈ closed_segment x y. (f w) ≤ (f ξ)) ∨
                            (∀w ∈ closed_segment x y. (f ξ) ≤ (f w))"
      using continuous_IVT_local_extremum [of x y f] ‹f x = f y› ‹x ≠ y› by blast
    ultimately obtain e where "e>0" and e: "⋀u. dist u (f ξ) < e ⟹ u ∈ f ` open_segment x y"
      using open_dist by (metis image_eqI)
    have fin: "f ξ + (e/2) ∈ f ` open_segment x y" "f ξ - (e/2) ∈ f ` open_segment x y"
      using e [of "f ξ + (e/2)"] e [of "f ξ - (e/2)"] ‹e > 0› by (auto simp: dist_norm)
    show ?thesis
      using ξ ‹0 < e› fin open_closed_segment by fastforce
  qed
  then show ?lhs
    by (force simp: inj_on_def)
qed

subsection%unimportant ‹Bounding a point away from a path›

lemma not_on_path_ball:
  fixes g :: "real ⇒ 'a::heine_borel"
  assumes "path g"
    and z: "z ∉ path_image g"
  shows "∃e > 0. ball z e ∩ path_image g = {}"
proof -
  have "closed (path_image g)"
    by (simp add: ‹path g› closed_path_image)
  then obtain a where "a ∈ path_image g" "∀y ∈ path_image g. dist z a ≤ dist z y"
    by (auto intro: distance_attains_inf[OF _ path_image_nonempty, of g z])
  then show ?thesis
    by (rule_tac x="dist z a" in exI) (use dist_commute z in auto)
qed

lemma not_on_path_cball:
  fixes g :: "real ⇒ 'a::heine_borel"
  assumes "path g"
    and "z ∉ path_image g"
  shows "∃e>0. cball z e ∩ (path_image g) = {}"
proof -
  obtain e where "ball z e ∩ path_image g = {}" "e > 0"
    using not_on_path_ball[OF assms] by auto
  moreover have "cball z (e/2) ⊆ ball z e"
    using ‹e > 0› by auto
  ultimately show ?thesis
    by (rule_tac x="e/2" in exI) auto
qed


section ‹Path component, considered as a "joinability" relation (from Tom Hales)›

definition%important "path_component s x y ⟷
  (∃g. path g ∧ path_image g ⊆ s ∧ pathstart g = x ∧ pathfinish g = y)"

abbreviation%important
   "path_component_set s x ≡ Collect (path_component s x)"

lemmas path_defs = path_def pathstart_def pathfinish_def path_image_def path_component_def

lemma path_component_mem:
  assumes "path_component s x y"
  shows "x ∈ s" and "y ∈ s"
  using assms
  unfolding path_defs
  by auto

lemma path_component_refl:
  assumes "x ∈ s"
  shows "path_component s x x"
  unfolding path_defs
  apply (rule_tac x="λu. x" in exI)
  using assms
  apply (auto intro!: continuous_intros)
  done

lemma path_component_refl_eq: "path_component s x x ⟷ x ∈ s"
  by (auto intro!: path_component_mem path_component_refl)

lemma path_component_sym: "path_component s x y ⟹ path_component s y x"
  unfolding path_component_def
  apply (erule exE)
  apply (rule_tac x="reversepath g" in exI, auto)
  done

lemma path_component_trans:
  assumes "path_component s x y" and "path_component s y z"
  shows "path_component s x z"
  using assms
  unfolding path_component_def
  apply (elim exE)
  apply (rule_tac x="g +++ ga" in exI)
  apply (auto simp: path_image_join)
  done

lemma path_component_of_subset: "s ⊆ t ⟹ path_component s x y ⟹ path_component t x y"
  unfolding path_component_def by auto

lemma path_connected_linepath:
    fixes s :: "'a::real_normed_vector set"
    shows "closed_segment a b ⊆ s ⟹ path_component s a b"
  unfolding path_component_def
  by (rule_tac x="linepath a b" in exI, auto)


subsubsection%unimportant ‹Path components as sets›

lemma path_component_set:
  "path_component_set s x =
    {y. (∃g. path g ∧ path_image g ⊆ s ∧ pathstart g = x ∧ pathfinish g = y)}"
  by (auto simp: path_component_def)

lemma path_component_subset: "path_component_set s x ⊆ s"
  by (auto simp: path_component_mem(2))

lemma path_component_eq_empty: "path_component_set s x = {} ⟷ x ∉ s"
  using path_component_mem path_component_refl_eq
    by fastforce

lemma path_component_mono:
     "s ⊆ t ⟹ (path_component_set s x) ⊆ (path_component_set t x)"
  by (simp add: Collect_mono path_component_of_subset)

lemma path_component_eq:
   "y ∈ path_component_set s x ⟹ path_component_set s y = path_component_set s x"
by (metis (no_types, lifting) Collect_cong mem_Collect_eq path_component_sym path_component_trans)

subsection ‹Path connectedness of a space›

definition%important "path_connected s ⟷
  (∀x∈s. ∀y∈s. ∃g. path g ∧ path_image g ⊆ s ∧ pathstart g = x ∧ pathfinish g = y)"

lemma path_connected_component: "path_connected s ⟷ (∀x∈s. ∀y∈s. path_component s x y)"
  unfolding path_connected_def path_component_def by auto

lemma path_connected_component_set: "path_connected s ⟷ (∀x∈s. path_component_set s x = s)"
  unfolding path_connected_component path_component_subset
  using path_component_mem by blast

lemma path_component_maximal:
     "⟦x ∈ t; path_connected t; t ⊆ s⟧ ⟹ t ⊆ (path_component_set s x)"
  by (metis path_component_mono path_connected_component_set)

lemma convex_imp_path_connected:
  fixes s :: "'a::real_normed_vector set"
  assumes "convex s"
  shows "path_connected s"
  unfolding path_connected_def
  using assms convex_contains_segment by fastforce

lemma path_connected_UNIV [iff]: "path_connected (UNIV :: 'a::real_normed_vector set)"
  by (simp add: convex_imp_path_connected)

lemma path_component_UNIV: "path_component_set UNIV x = (UNIV :: 'a::real_normed_vector set)"
  using path_connected_component_set by auto

lemma path_connected_imp_connected:
  assumes "path_connected S"
  shows "connected S"
proof (rule connectedI)
  fix e1 e2
  assume as: "open e1" "open e2" "S ⊆ e1 ∪ e2" "e1 ∩ e2 ∩ S = {}" "e1 ∩ S ≠ {}" "e2 ∩ S ≠ {}"
  then obtain x1 x2 where obt:"x1 ∈ e1 ∩ S" "x2 ∈ e2 ∩ S"
    by auto
  then obtain g where g: "path g" "path_image g ⊆ S" "pathstart g = x1" "pathfinish g = x2"
    using assms[unfolded path_connected_def,rule_format,of x1 x2] by auto
  have *: "connected {0..1::real}"
    by (auto intro!: convex_connected convex_real_interval)
  have "{0..1} ⊆ {x ∈ {0..1}. g x ∈ e1} ∪ {x ∈ {0..1}. g x ∈ e2}"
    using as(3) g(2)[unfolded path_defs] by blast
  moreover have "{x ∈ {0..1}. g x ∈ e1} ∩ {x ∈ {0..1}. g x ∈ e2} = {}"
    using as(4) g(2)[unfolded path_defs]
    unfolding subset_eq
    by auto
  moreover have "{x ∈ {0..1}. g x ∈ e1} ≠ {} ∧ {x ∈ {0..1}. g x ∈ e2} ≠ {}"
    using g(3,4)[unfolded path_defs]
    using obt
    by (simp add: ex_in_conv [symmetric], metis zero_le_one order_refl)
  ultimately show False
    using *[unfolded connected_local not_ex, rule_format,
      of "{0..1} ∩ g -` e1" "{0..1} ∩ g -` e2"]
    using continuous_openin_preimage_gen[OF g(1)[unfolded path_def] as(1)]
    using continuous_openin_preimage_gen[OF g(1)[unfolded path_def] as(2)]
    by auto
qed

lemma open_path_component:
  fixes S :: "'a::real_normed_vector set"
  assumes "open S"
  shows "open (path_component_set S x)"
  unfolding open_contains_ball
proof
  fix y
  assume as: "y ∈ path_component_set S x"
  then have "y ∈ S"
    by (simp add: path_component_mem(2))
  then obtain e where e: "e > 0" "ball y e ⊆ S"
    using assms[unfolded open_contains_ball]
    by auto
have "⋀u. dist y u < e ⟹ path_component S x u"
      by (metis (full_types) as centre_in_ball convex_ball convex_imp_path_connected e mem_Collect_eq mem_ball path_component_eq path_component_of_subset path_connected_component)
  then show "∃e > 0. ball y e ⊆ path_component_set S x"
    using ‹e>0› by auto
qed

lemma open_non_path_component:
  fixes S :: "'a::real_normed_vector set"
  assumes "open S"
  shows "open (S - path_component_set S x)"
  unfolding open_contains_ball
proof
  fix y
  assume y: "y ∈ S - path_component_set S x"
  then obtain e where e: "e > 0" "ball y e ⊆ S"
    using assms openE by auto
  show "∃e>0. ball y e ⊆ S - path_component_set S x"
  proof (intro exI conjI subsetI DiffI notI)
    show "⋀x. x ∈ ball y e ⟹ x ∈ S"
      using e by blast
    show False if "z ∈ ball y e" "z ∈ path_component_set S x" for z
    proof -
      have "y ∈ path_component_set S z"
        by (meson assms convex_ball convex_imp_path_connected e open_contains_ball_eq open_path_component path_component_maximal that(1))
      then have "y ∈ path_component_set S x"
        using path_component_eq that(2) by blast
      then show False
        using y by blast
    qed
  qed (use e in auto)
qed

lemma connected_open_path_connected:
  fixes S :: "'a::real_normed_vector set"
  assumes "open S"
    and "connected S"
  shows "path_connected S"
  unfolding path_connected_component_set
proof (rule, rule, rule path_component_subset, rule)
  fix x y
  assume "x ∈ S" and "y ∈ S"
  show "y ∈ path_component_set S x"
  proof (rule ccontr)
    assume "¬ ?thesis"
    moreover have "path_component_set S x ∩ S ≠ {}"
      using ‹x ∈ S› path_component_eq_empty path_component_subset[of S x]
      by auto
    ultimately
    show False
      using ‹y ∈ S› open_non_path_component[OF assms(1)] open_path_component[OF assms(1)]
      using assms(2)[unfolded connected_def not_ex, rule_format,
        of "path_component_set S x" "S - path_component_set S x"]
      by auto
  qed
qed

lemma path_connected_continuous_image:
  assumes "continuous_on S f"
    and "path_connected S"
  shows "path_connected (f ` S)"
  unfolding path_connected_def
proof (rule, rule)
  fix x' y'
  assume "x' ∈ f ` S" "y' ∈ f ` S"
  then obtain x y where x: "x ∈ S" and y: "y ∈ S" and x': "x' = f x" and y': "y' = f y"
    by auto
  from x y obtain g where "path g ∧ path_image g ⊆ S ∧ pathstart g = x ∧ pathfinish g = y"
    using assms(2)[unfolded path_connected_def] by fast
  then show "∃g. path g ∧ path_image g ⊆ f ` S ∧ pathstart g = x' ∧ pathfinish g = y'"
    unfolding x' y'
    apply (rule_tac x="f ∘ g" in exI)
    unfolding path_defs
    apply (intro conjI continuous_on_compose continuous_on_subset[OF assms(1)])
    apply auto
    done
qed

lemma path_connected_translationI:
  fixes a :: "'a :: topological_group_add"
  assumes "path_connected S" shows "path_connected ((λx. a + x) ` S)"
  by (intro path_connected_continuous_image assms continuous_intros)

lemma path_connected_translation:
  fixes a :: "'a :: topological_group_add"
  shows "path_connected ((λx. a + x) ` S) = path_connected S"
proof -
  have "∀x y. (+) (x::'a) ` (+) (0 - x) ` y = y"
    by (simp add: image_image)
  then show ?thesis
    by (metis (no_types) path_connected_translationI)
qed

lemma path_connected_segment [simp]:
    fixes a :: "'a::real_normed_vector"
    shows "path_connected (closed_segment a b)"
  by (simp add: convex_imp_path_connected)

lemma path_connected_open_segment [simp]:
    fixes a :: "'a::real_normed_vector"
    shows "path_connected (open_segment a b)"
  by (simp add: convex_imp_path_connected)

lemma homeomorphic_path_connectedness:
  "S homeomorphic T ⟹ path_connected S ⟷ path_connected T"
  unfolding homeomorphic_def homeomorphism_def by (metis path_connected_continuous_image)

lemma path_connected_empty [simp]: "path_connected {}"
  unfolding path_connected_def by auto

lemma path_connected_singleton [simp]: "path_connected {a}"
  unfolding path_connected_def pathstart_def pathfinish_def path_image_def
  apply clarify
  apply (rule_tac x="λx. a" in exI)
  apply (simp add: image_constant_conv)
  apply (simp add: path_def continuous_on_const)
  done

lemma path_connected_Un:
  assumes "path_connected S"
    and "path_connected T"
    and "S ∩ T ≠ {}"
  shows "path_connected (S ∪ T)"
  unfolding path_connected_component
proof (intro ballI)
  fix x y
  assume x: "x ∈ S ∪ T" and y: "y ∈ S ∪ T"
  from assms obtain z where z: "z ∈ S" "z ∈ T"
    by auto
  show "path_component (S ∪ T) x y"
    using x y
  proof safe
    assume "x ∈ S" "y ∈ S"
    then show "path_component (S ∪ T) x y"
      by (meson Un_upper1 ‹path_connected S› path_component_of_subset path_connected_component)
  next
    assume "x ∈ S" "y ∈ T"
    then show "path_component (S ∪ T) x y"
      by (metis z assms(1-2) le_sup_iff order_refl path_component_of_subset path_component_trans path_connected_component)
  next
  assume "x ∈ T" "y ∈ S"
    then show "path_component (S ∪ T) x y"
      by (metis z assms(1-2) le_sup_iff order_refl path_component_of_subset path_component_trans path_connected_component)
  next
    assume "x ∈ T" "y ∈ T"
    then show "path_component (S ∪ T) x y"
      by (metis Un_upper1 assms(2) path_component_of_subset path_connected_component sup_commute)
  qed
qed

lemma path_connected_UNION:
  assumes "⋀i. i ∈ A ⟹ path_connected (S i)"
    and "⋀i. i ∈ A ⟹ z ∈ S i"
  shows "path_connected (⋃i∈A. S i)"
  unfolding path_connected_component
proof clarify
  fix x i y j
  assume *: "i ∈ A" "x ∈ S i" "j ∈ A" "y ∈ S j"
  then have "path_component (S i) x z" and "path_component (S j) z y"
    using assms by (simp_all add: path_connected_component)
  then have "path_component (⋃i∈A. S i) x z" and "path_component (⋃i∈A. S i) z y"
    using *(1,3) by (auto elim!: path_component_of_subset [rotated])
  then show "path_component (⋃i∈A. S i) x y"
    by (rule path_component_trans)
qed

lemma path_component_path_image_pathstart:
  assumes p: "path p" and x: "x ∈ path_image p"
  shows "path_component (path_image p) (pathstart p) x"
proof -
  obtain y where x: "x = p y" and y: "0 ≤ y" "y ≤ 1"
    using x by (auto simp: path_image_def)
  show ?thesis
    unfolding path_component_def 
  proof (intro exI conjI)
    have "continuous_on {0..1} (p ∘ (( *) y))"
      apply (rule continuous_intros)+
      using p [unfolded path_def] y
      apply (auto simp: mult_le_one intro: continuous_on_subset [of _ p])
      done
    then show "path (λu. p (y * u))"
      by (simp add: path_def)
    show "path_image (λu. p (y * u)) ⊆ path_image p"
      using y mult_le_one by (fastforce simp: path_image_def image_iff)
  qed (auto simp: pathstart_def pathfinish_def x)
qed

lemma path_connected_path_image: "path p ⟹ path_connected(path_image p)"
  unfolding path_connected_component
  by (meson path_component_path_image_pathstart path_component_sym path_component_trans)

lemma path_connected_path_component [simp]:
   "path_connected (path_component_set s x)"
proof -
  { fix y z
    assume pa: "path_component s x y" "path_component s x z"
    then have pae: "path_component_set s x = path_component_set s y"
      using path_component_eq by auto
    have yz: "path_component s y z"
      using pa path_component_sym path_component_trans by blast
    then have "∃g. path g ∧ path_image g ⊆ path_component_set s x ∧ pathstart g = y ∧ pathfinish g = z"
      apply (simp add: path_component_def, clarify)
      apply (rule_tac x=g in exI)
      by (simp add: pae path_component_maximal path_connected_path_image pathstart_in_path_image)
  }
  then show ?thesis
    by (simp add: path_connected_def)
qed

lemma path_component: "path_component S x y ⟷ (∃t. path_connected t ∧ t ⊆ S ∧ x ∈ t ∧ y ∈ t)"
  apply (intro iffI)
  apply (metis path_connected_path_image path_defs(5) pathfinish_in_path_image pathstart_in_path_image)
  using path_component_of_subset path_connected_component by blast

lemma path_component_path_component [simp]:
   "path_component_set (path_component_set S x) x = path_component_set S x"
proof (cases "x ∈ S")
  case True show ?thesis
    apply (rule subset_antisym)
    apply (simp add: path_component_subset)
    by (simp add: True path_component_maximal path_component_refl path_connected_path_component)
next
  case False then show ?thesis
    by (metis False empty_iff path_component_eq_empty)
qed

lemma path_component_subset_connected_component:
   "(path_component_set S x) ⊆ (connected_component_set S x)"
proof (cases "x ∈ S")
  case True show ?thesis
    apply (rule connected_component_maximal)
    apply (auto simp: True path_component_subset path_component_refl path_connected_imp_connected)
    done
next
  case False then show ?thesis
    using path_component_eq_empty by auto
qed

subsection%unimportant‹Lemmas about path-connectedness›

lemma path_connected_linear_image:
  fixes f :: "'a::real_normed_vector ⇒ 'b::real_normed_vector"
  assumes "path_connected S" "bounded_linear f"
    shows "path_connected(f ` S)"
by (auto simp: linear_continuous_on assms path_connected_continuous_image)

lemma is_interval_path_connected: "is_interval S ⟹ path_connected S"
  by (simp add: convex_imp_path_connected is_interval_convex)

lemma linear_homeomorphism_image:
  fixes f :: "'a::euclidean_space ⇒ 'b::euclidean_space"
  assumes "linear f" "inj f"
    obtains g where "homeomorphism (f ` S) S g f"
using linear_injective_left_inverse [OF assms]
apply clarify
apply (rule_tac g=g in that)
using assms
apply (auto simp: homeomorphism_def eq_id_iff [symmetric] image_comp comp_def linear_conv_bounded_linear linear_continuous_on)
done

lemma linear_homeomorphic_image:
  fixes f :: "'a::euclidean_space ⇒ 'b::euclidean_space"
  assumes "linear f" "inj f"
    shows "S homeomorphic f ` S"
by (meson homeomorphic_def homeomorphic_sym linear_homeomorphism_image [OF assms])

lemma path_connected_Times:
  assumes "path_connected s" "path_connected t"
    shows "path_connected (s × t)"
proof (simp add: path_connected_def Sigma_def, clarify)
  fix x1 y1 x2 y2
  assume "x1 ∈ s" "y1 ∈ t" "x2 ∈ s" "y2 ∈ t"
  obtain g where "path g" and g: "path_image g ⊆ s" and gs: "pathstart g = x1" and gf: "pathfinish g = x2"
    using ‹x1 ∈ s› ‹x2 ∈ s› assms by (force simp: path_connected_def)
  obtain h where "path h" and h: "path_image h ⊆ t" and hs: "pathstart h = y1" and hf: "pathfinish h = y2"
    using ‹y1 ∈ t› ‹y2 ∈ t› assms by (force simp: path_connected_def)
  have "path (λz. (x1, h z))"
    using ‹path h›
    apply (simp add: path_def)
    apply (rule continuous_on_compose2 [where f = h])
    apply (rule continuous_intros | force)+
    done
  moreover have "path (λz. (g z, y2))"
    using ‹path g›
    apply (simp add: path_def)
    apply (rule continuous_on_compose2 [where f = g])
    apply (rule continuous_intros | force)+
    done
  ultimately have 1: "path ((λz. (x1, h z)) +++ (λz. (g z, y2)))"
    by (metis hf gs path_join_imp pathstart_def pathfinish_def)
  have "path_image ((λz. (x1, h z)) +++ (λz. (g z, y2))) ⊆ path_image (λz. (x1, h z)) ∪ path_image (λz. (g z, y2))"
    by (rule Path_Connected.path_image_join_subset)
  also have "… ⊆ (⋃x∈s. ⋃x1∈t. {(x, x1)})"
    using g h ‹x1 ∈ s› ‹y2 ∈ t› by (force simp: path_image_def)
  finally have 2: "path_image ((λz. (x1, h z)) +++ (λz. (g z, y2))) ⊆ (⋃x∈s. ⋃x1∈t. {(x, x1)})" .
  show "∃g. path g ∧ path_image g ⊆ (⋃x∈s. ⋃x1∈t. {(x, x1)}) ∧
            pathstart g = (x1, y1) ∧ pathfinish g = (x2, y2)"
    apply (intro exI conjI)
       apply (rule 1)
      apply (rule 2)
     apply (metis hs pathstart_def pathstart_join)
    by (metis gf pathfinish_def pathfinish_join)
qed

lemma is_interval_path_connected_1:
  fixes s :: "real set"
  shows "is_interval s ⟷ path_connected s"
using is_interval_connected_1 is_interval_path_connected path_connected_imp_connected by blast


subsection%unimportant‹Path components›

lemma Union_path_component [simp]:
   "Union {path_component_set S x |x. x ∈ S} = S"
apply (rule subset_antisym)
using path_component_subset apply force
using path_component_refl by auto

lemma path_component_disjoint:
   "disjnt (path_component_set S a) (path_component_set S b) ⟷
    (a ∉ path_component_set S b)"
apply (auto simp: disjnt_def)
using path_component_eq apply fastforce
using path_component_sym path_component_trans by blast

lemma path_component_eq_eq:
   "path_component S x = path_component S y ⟷
        (x ∉ S) ∧ (y ∉ S) ∨ x ∈ S ∧ y ∈ S ∧ path_component S x y"
apply (rule iffI, metis (no_types) path_component_mem(1) path_component_refl)
apply (erule disjE, metis Collect_empty_eq_bot path_component_eq_empty)
apply (rule ext)
apply (metis path_component_trans path_component_sym)
done

lemma path_component_unique:
  assumes "x ∈ c" "c ⊆ S" "path_connected c"
          "⋀c'. ⟦x ∈ c'; c' ⊆ S; path_connected c'⟧ ⟹ c' ⊆ c"
   shows "path_component_set S x = c"
apply (rule subset_antisym)
using assms
apply (metis mem_Collect_eq subsetCE path_component_eq_eq path_component_subset path_connected_path_component)
by (simp add: assms path_component_maximal)

lemma path_component_intermediate_subset:
   "path_component_set u a ⊆ t ∧ t ⊆ u
        ⟹ path_component_set t a = path_component_set u a"
by (metis (no_types) path_component_mono path_component_path_component subset_antisym)

lemma complement_path_component_Union:
  fixes x :: "'a :: topological_space"
  shows "S - path_component_set S x =
         ⋃({path_component_set S y| y. y ∈ S} - {path_component_set S x})"
proof -
  have *: "(⋀x. x ∈ S - {a} ⟹ disjnt a x) ⟹ ⋃S - a = ⋃(S - {a})"
    for a::"'a set" and S
    by (auto simp: disjnt_def)
  have "⋀y. y ∈ {path_component_set S x |x. x ∈ S} - {path_component_set S x}
            ⟹ disjnt (path_component_set S x) y"
    using path_component_disjoint path_component_eq by fastforce
  then have "⋃{path_component_set S x |x. x ∈ S} - path_component_set S x =
             ⋃({path_component_set S y |y. y ∈ S} - {path_component_set S x})"
    by (meson *)
  then show ?thesis by simp
qed


subsection ‹Sphere is path-connected›

lemma path_connected_punctured_universe:
  assumes "2 ≤ DIM('a::euclidean_space)"
  shows "path_connected (- {a::'a})"
proof -
  let ?A = "{x::'a. ∃i∈Basis. x ∙ i < a ∙ i}"
  let ?B = "{x::'a. ∃i∈Basis. a ∙ i < x ∙ i}"

  have A: "path_connected ?A"
    unfolding Collect_bex_eq
  proof (rule path_connected_UNION)
    fix i :: 'a
    assume "i ∈ Basis"
    then show "(∑i∈Basis. (a ∙ i - 1)*R i) ∈ {x::'a. x ∙ i < a ∙ i}"
      by simp
    show "path_connected {x. x ∙ i < a ∙ i}"
      using convex_imp_path_connected [OF convex_halfspace_lt, of i "a ∙ i"]
      by (simp add: inner_commute)
  qed
  have B: "path_connected ?B"
    unfolding Collect_bex_eq
  proof (rule path_connected_UNION)
    fix i :: 'a
    assume "i ∈ Basis"
    then show "(∑i∈Basis. (a ∙ i + 1) *R i) ∈ {x::'a. a ∙ i < x ∙ i}"
      by simp
    show "path_connected {x. a ∙ i < x ∙ i}"
      using convex_imp_path_connected [OF convex_halfspace_gt, of "a ∙ i" i]
      by (simp add: inner_commute)
  qed
  obtain S :: "'a set" where "S ⊆ Basis" and "card S = Suc (Suc 0)"
    using ex_card[OF assms]
    by auto
  then obtain b0 b1 :: 'a where "b0 ∈ Basis" and "b1 ∈ Basis" and "b0 ≠ b1"
    unfolding card_Suc_eq by auto
  then have "a + b0 - b1 ∈ ?A ∩ ?B"
    by (auto simp: inner_simps inner_Basis)
  then have "?A ∩ ?B ≠ {}"
    by fast
  with A B have "path_connected (?A ∪ ?B)"
    by (rule path_connected_Un)
  also have "?A ∪ ?B = {x. ∃i∈Basis. x ∙ i ≠ a ∙ i}"
    unfolding neq_iff bex_disj_distrib Collect_disj_eq ..
  also have "… = {x. x ≠ a}"
    unfolding euclidean_eq_iff [where 'a='a]
    by (simp add: Bex_def)
  also have "… = - {a}"
    by auto
  finally show ?thesis .
qed

corollary connected_punctured_universe:
  "2 ≤ DIM('N::euclidean_space) ⟹ connected(- {a::'N})"
  by (simp add: path_connected_punctured_universe path_connected_imp_connected)

proposition path_connected_sphere:
  fixes a :: "'a :: euclidean_space"
  assumes "2 ≤ DIM('a)"
  shows "path_connected(sphere a r)"
proof (cases r "0::real" rule: linorder_cases)
  case less
  then show ?thesis
    by (simp add: path_connected_empty)
next
  case equal
  then show ?thesis
    by (simp add: path_connected_singleton)
next
  case greater
  then have eq: "(sphere (0::'a) r) = (λx. (r / norm x) *R x) ` (- {0::'a})"
    by (force simp: image_iff split: if_split_asm)
  have "continuous_on (- {0::'a}) (λx. (r / norm x) *R x)"
    by (intro continuous_intros) auto
  then have "path_connected ((λx. (r / norm x) *R x) ` (- {0::'a}))"
    by (intro path_connected_continuous_image path_connected_punctured_universe assms)
  with eq have "path_connected (sphere (0::'a) r)"
    by auto
  then have "path_connected((+) a ` (sphere (0::'a) r))"
    by (simp add: path_connected_translation)
  then show ?thesis
    by (metis add.right_neutral sphere_translation)
qed

lemma connected_sphere:
    fixes a :: "'a :: euclidean_space"
    assumes "2 ≤ DIM('a)"
      shows "connected(sphere a r)"
  using path_connected_sphere [OF assms]
  by (simp add: path_connected_imp_connected)


corollary path_connected_complement_bounded_convex:
    fixes s :: "'a :: euclidean_space set"
    assumes "bounded s" "convex s" and 2: "2 ≤ DIM('a)"
    shows "path_connected (- s)"
proof (cases "s = {}")
  case True then show ?thesis
    using convex_imp_path_connected by auto
next
  case False
  then obtain a where "a ∈ s" by auto
  { fix x y assume "x ∉ s" "y ∉ s"
    then have "x ≠ a" "y ≠ a" using ‹a ∈ s› by auto
    then have bxy: "bounded(insert x (insert y s))"
      by (simp add: ‹bounded s›)
    then obtain B::real where B: "0 < B" and Bx: "norm (a - x) < B" and By: "norm (a - y) < B"
                          and "s ⊆ ball a B"
      using bounded_subset_ballD [OF bxy, of a] by (auto simp: dist_norm)
    define C where "C = B / norm(x - a)"
    { fix u
      assume u: "(1 - u) *R x + u *R (a + C *R (x - a)) ∈ s" and "0 ≤ u" "u ≤ 1"
      have CC: "1 ≤ 1 + (C - 1) * u"
        using ‹x ≠ a› ‹0 ≤ u›
        apply (simp add: C_def divide_simps norm_minus_commute)
        using Bx by auto
      have *: "⋀v. (1 - u) *R x + u *R (a + v *R (x - a)) = a + (1 + (v - 1) * u) *R (x - a)"
        by (simp add: algebra_simps)
      have "a + ((1 / (1 + C * u - u)) *R x + ((u / (1 + C * u - u)) *R a + (C * u / (1 + C * u - u)) *R x)) =
            (1 + (u / (1 + C * u - u))) *R a + ((1 / (1 + C * u - u)) + (C * u / (1 + C * u - u))) *R x"
        by (simp add: algebra_simps)
      also have "… = (1 + (u / (1 + C * u - u))) *R a + (1 + (u / (1 + C * u - u))) *R x"
        using CC by (simp add: field_simps)
      also have "… = x + (1 + (u / (1 + C * u - u))) *R a + (u / (1 + C * u - u)) *R x"
        by (simp add: algebra_simps)
      also have "… = x + ((1 / (1 + C * u - u)) *R a +
              ((u / (1 + C * u - u)) *R x + (C * u / (1 + C * u - u)) *R a))"
        using CC by (simp add: field_simps) (simp add: add_divide_distrib scaleR_add_left)
      finally have xeq: "(1 - 1 / (1 + (C - 1) * u)) *R a + (1 / (1 + (C - 1) * u)) *R (a + (1 + (C - 1) * u) *R (x - a)) = x"
        by (simp add: algebra_simps)
      have False
        using ‹convex s›
        apply (simp add: convex_alt)
        apply (drule_tac x=a in bspec)
         apply (rule  ‹a ∈ s›)
        apply (drule_tac x="a + (1 + (C - 1) * u) *R (x - a)" in bspec)
         using u apply (simp add: *)
        apply (drule_tac x="1 / (1 + (C - 1) * u)" in spec)
        using ‹x ≠ a› ‹x ∉ s› ‹0 ≤ u› CC
        apply (auto simp: xeq)
        done
    }
    then have pcx: "path_component (- s) x (a + C *R (x - a))"
      by (force simp: closed_segment_def intro!: path_connected_linepath)
    define D where "D = B / norm(y - a)"  ― ‹massive duplication with the proof above›
    { fix u
      assume u: "(1 - u) *R y + u *R (a + D *R (y - a)) ∈ s" and "0 ≤ u" "u ≤ 1"
      have DD: "1 ≤ 1 + (D - 1) * u"
        using ‹y ≠ a› ‹0 ≤ u›
        apply (simp add: D_def divide_simps norm_minus_commute)
        using By by auto
      have *: "⋀v. (1 - u) *R y + u *R (a + v *R (y - a)) = a + (1 + (v - 1) * u) *R (y - a)"
        by (simp add: algebra_simps)
      have "a + ((1 / (1 + D * u - u)) *R y + ((u / (1 + D * u - u)) *R a + (D * u / (1 + D * u - u)) *R y)) =
            (1 + (u / (1 + D * u - u))) *R a + ((1 / (1 + D * u - u)) + (D * u / (1 + D * u - u))) *R y"
        by (simp add: algebra_simps)
      also have "… = (1 + (u / (1 + D * u - u))) *R a + (1 + (u / (1 + D * u - u))) *R y"
        using DD by (simp add: field_simps)
      also have "… = y + (1 + (u / (1 + D * u - u))) *R a + (u / (1 + D * u - u)) *R y"
        by (simp add: algebra_simps)
      also have "… = y + ((1 / (1 + D * u - u)) *R a +
              ((u / (1 + D * u - u)) *R y + (D * u / (1 + D * u - u)) *R a))"
        using DD by (simp add: field_simps) (simp add: add_divide_distrib scaleR_add_left)
      finally have xeq: "(1 - 1 / (1 + (D - 1) * u)) *R a + (1 / (1 + (D - 1) * u)) *R (a + (1 + (D - 1) * u) *R (y - a)) = y"
        by (simp add: algebra_simps)
      have False
        using ‹convex s›
        apply (simp add: convex_alt)
        apply (drule_tac x=a in bspec)
         apply (rule  ‹a ∈ s›)
        apply (drule_tac x="a + (1 + (D - 1) * u) *R (y - a)" in bspec)
         using u apply (simp add: *)
        apply (drule_tac x="1 / (1 + (D - 1) * u)" in spec)
        using ‹y ≠ a› ‹y ∉ s› ‹0 ≤ u› DD
        apply (auto simp: xeq)
        done
    }
    then have pdy: "path_component (- s) y (a + D *R (y - a))"
      by (force simp: closed_segment_def intro!: path_connected_linepath)
    have pyx: "path_component (- s) (a + D *R (y - a)) (a + C *R (x - a))"
      apply (rule path_component_of_subset [of "sphere a B"])
       using ‹s ⊆ ball a B›
       apply (force simp: ball_def dist_norm norm_minus_commute)
      apply (rule path_connected_sphere [OF 2, of a B, simplified path_connected_component, rule_format])
       using ‹x ≠ a›  using ‹y ≠ a›  B apply (auto simp: dist_norm C_def D_def)
      done
    have "path_component (- s) x y"
      by (metis path_component_trans path_component_sym pcx pdy pyx)
  }
  then show ?thesis
    by (auto simp: path_connected_component)
qed

lemma connected_complement_bounded_convex:
    fixes s :: "'a :: euclidean_space set"
    assumes "bounded s" "convex s" "2 ≤ DIM('a)"
      shows  "connected (- s)"
  using path_connected_complement_bounded_convex [OF assms] path_connected_imp_connected by blast

lemma connected_diff_ball:
    fixes s :: "'a :: euclidean_space set"
    assumes "connected s" "cball a r ⊆ s" "2 ≤ DIM('a)"
      shows "connected (s - ball a r)"
  apply (rule connected_diff_open_from_closed [OF ball_subset_cball])
  using assms connected_sphere
  apply (auto simp: cball_diff_eq_sphere dist_norm)
  done

proposition connected_open_delete:
  assumes "open S" "connected S" and 2: "2 ≤ DIM('N::euclidean_space)"
    shows "connected(S - {a::'N})"
proof (cases "a ∈ S")
  case True
  with ‹open S› obtain ε where "ε > 0" and ε: "cball a ε ⊆ S"
    using open_contains_cball_eq by blast
  have "dist a (a + ε *R (SOME i. i ∈ Basis)) = ε"
    by (simp add: dist_norm SOME_Basis ‹0 < ε› less_imp_le)
  with ε have "⋂{S - ball a r |r. 0 < r ∧ r < ε} ⊆ {} ⟹ False"
    apply (drule_tac c="a + scaleR (ε) ((SOME i. i ∈ Basis))" in subsetD)
    by auto
  then have nonemp: "(⋂{S - ball a r |r. 0 < r ∧ r < ε}) = {} ⟹ False"
    by auto
  have con: "⋀r. r < ε ⟹ connected (S - ball a r)"
    using ε by (force intro: connected_diff_ball [OF ‹connected S› _ 2])
  have "x ∈ ⋃{S - ball a r |r. 0 < r ∧ r < ε}" if "x ∈ S - {a}" for x
    apply (rule UnionI [of "S - ball a (min ε (dist a x) / 2)"])
     using that ‹0 < ε› apply simp_all
    apply (rule_tac x="min ε (dist a x) / 2" in exI)
    apply auto
    done
  then have "S - {a} = ⋃{S - ball a r | r. 0 < r ∧ r < ε}"
    by auto
  then show ?thesis
    by (auto intro: connected_Union con dest!: nonemp)
next
  case False then show ?thesis
    by (simp add: ‹connected S›)
qed

corollary path_connected_open_delete:
  assumes "open S" "connected S" and 2: "2 ≤ DIM('N::euclidean_space)"
    shows "path_connected(S - {a::'N})"
by (simp add: assms connected_open_delete connected_open_path_connected open_delete)

corollary path_connected_punctured_ball:
   "2 ≤ DIM('N::euclidean_space) ⟹ path_connected(ball a r - {a::'N})"
by (simp add: path_connected_open_delete)

corollary connected_punctured_ball:
   "2 ≤ DIM('N::euclidean_space) ⟹ connected(ball a r - {a::'N})"
by (simp add: connected_open_delete)

corollary connected_open_delete_finite:
  fixes S T::"'a::euclidean_space set"
  assumes S: "open S" "connected S" and 2: "2 ≤ DIM('a)" and "finite T"
  shows "connected(S - T)"
  using ‹finite T› S
proof (induct T)
  case empty
  show ?case using ‹connected S› by simp
next
  case (insert x F)
  then have "connected (S-F)" by auto
  moreover have "open (S - F)" using finite_imp_closed[OF ‹finite F›] ‹open S› by auto
  ultimately have "connected (S - F - {x})" using connected_open_delete[OF _ _ 2] by auto
  thus ?case by (metis Diff_insert)
qed

lemma sphere_1D_doubleton_zero:
  assumes 1: "DIM('a) = 1" and "r > 0"
  obtains x y::"'a::euclidean_space"
    where "sphere 0 r = {x,y} ∧ dist x y = 2*r"
proof -
  obtain b::'a where b: "Basis = {b}"
    using 1 card_1_singletonE by blast
  show ?thesis
  proof (intro that conjI)
    have "x = norm x *R b ∨ x = - norm x *R b" if "r = norm x" for x
    proof -
      have xb: "(x ∙ b) *R b = x"
        using euclidean_representation [of x, unfolded b] by force
      then have "norm ((x ∙ b) *R b) = norm x"
        by simp
      with b have "¦x ∙ b¦ = norm x"
        using norm_Basis by (simp add: b)
      with xb show ?thesis
        apply (simp add: abs_if split: if_split_asm)
        apply (metis add.inverse_inverse real_vector.scale_minus_left xb)
        done
    qed
    with ‹r > 0› b show "sphere 0 r = {r *R b, - r *R b}"
      by (force simp: sphere_def dist_norm)
    have "dist (r *R b) (- r *R b) = norm (r *R b + r *R b)"
      by (simp add: dist_norm)
    also have "… = norm ((2*r) *R b)"
      by (metis mult_2 scaleR_add_left)
    also have "… = 2*r"
      using ‹r > 0› b norm_Basis by fastforce
    finally show "dist (r *R b) (- r *R b) = 2*r" .
  qed
qed

lemma sphere_1D_doubleton:
  fixes a :: "'a :: euclidean_space"
  assumes "DIM('a) = 1" and "r > 0"
  obtains x y where "sphere a r = {x,y} ∧ dist x y = 2*r"
proof -
  have "sphere a r = (+) a ` sphere 0 r"
    by (metis add.right_neutral sphere_translation)
  then show ?thesis
    using sphere_1D_doubleton_zero [OF assms]
    by (metis (mono_tags, lifting) dist_add_cancel image_empty image_insert that)
qed

lemma psubset_sphere_Compl_connected:
  fixes S :: "'a::euclidean_space set"
  assumes S: "S ⊂ sphere a r" and "0 < r" and 2: "2 ≤ DIM('a)"
  shows "connected(- S)"
proof -
  have "S ⊆ sphere a r"
    using S by blast
  obtain b where "dist a b = r" and "b ∉ S"
    using S mem_sphere by blast
  have CS: "- S = {x. dist a x ≤ r ∧ (x ∉ S)} ∪ {x. r ≤ dist a x ∧ (x ∉ S)}"
    by auto
  have "{x. dist a x ≤ r ∧ x ∉ S} ∩ {x. r ≤ dist a x ∧ x ∉ S} ≠ {}"
    using ‹b ∉ S› ‹dist a b = r› by blast
  moreover have "connected {x. dist a x ≤ r ∧ x ∉ S}"
    apply (rule connected_intermediate_closure [of "ball a r"])
    using assms by auto
  moreover
  have "connected {x. r ≤ dist a x ∧ x ∉ S}"
    apply (rule connected_intermediate_closure [of "- cball a r"])
    using assms apply (auto intro: connected_complement_bounded_convex)
    apply (metis ComplI interior_cball interior_closure mem_ball not_less)
    done
  ultimately show ?thesis
    by (simp add: CS connected_Un)
qed


subsection‹Every annulus is a connected set›

lemma path_connected_2DIM_I:
  fixes a :: "'N::euclidean_space"
  assumes 2: "2 ≤ DIM('N)" and pc: "path_connected {r. 0 ≤ r ∧ P r}"
  shows "path_connected {x. P(norm(x - a))}"
proof -
  have "{x. P(norm(x - a))} = (+) a ` {x. P(norm x)}"
    by force
  moreover have "path_connected {x::'N. P(norm x)}"
  proof -
    let ?D = "{x. 0 ≤ x ∧ P x} × sphere (0::'N) 1"
    have "x ∈ (λz. fst z *R snd z) ` ?D"
      if "P (norm x)" for x::'N
    proof (cases "x=0")
      case True
      with that show ?thesis
        apply (simp add: image_iff)
        apply (rule_tac x=0 in exI, simp)
        using vector_choose_size zero_le_one by blast
    next
      case False
      with that show ?thesis
        by (rule_tac x="(norm x, x /R norm x)" in image_eqI) auto
    qed
    then have *: "{x::'N. P(norm x)} =  (λz. fst z *R snd z) ` ?D"
      by auto
    have "continuous_on ?D (λz:: real×'N. fst z *R snd z)"
      by (intro continuous_intros)
    moreover have "path_connected ?D"
      by (metis path_connected_Times [OF pc] path_connected_sphere 2)
    ultimately show ?thesis
      apply (subst *)
      apply (rule path_connected_continuous_image, auto)
      done
  qed
  ultimately show ?thesis
    using path_connected_translation by metis
qed

proposition path_connected_annulus:
  fixes a :: "'N::euclidean_space"
  assumes "2 ≤ DIM('N)"
  shows "path_connected {x. r1 < norm(x - a) ∧ norm(x - a) < r2}"
        "path_connected {x. r1 < norm(x - a) ∧ norm(x - a) ≤ r2}"
        "path_connected {x. r1 ≤ norm(x - a) ∧ norm(x - a) < r2}"
        "path_connected {x. r1 ≤ norm(x - a) ∧ norm(x - a) ≤ r2}"
  by (auto simp: is_interval_def intro!: is_interval_convex convex_imp_path_connected path_connected_2DIM_I [OF assms])

proposition connected_annulus:
  fixes a :: "'N::euclidean_space"
  assumes "2 ≤ DIM('N::euclidean_space)"
  shows "connected {x. r1 < norm(x - a) ∧ norm(x - a) < r2}"
        "connected {x. r1 < norm(x - a) ∧ norm(x - a) ≤ r2}"
        "connected {x. r1 ≤ norm(x - a) ∧ norm(x - a) < r2}"
        "connected {x. r1 ≤ norm(x - a) ∧ norm(x - a) ≤ r2}"
  by (auto simp: path_connected_annulus [OF assms] path_connected_imp_connected)


subsection%unimportant‹Relations between components and path components›

lemma open_connected_component:
  fixes s :: "'a::real_normed_vector set"
  shows "open s ⟹ open (connected_component_set s x)"
    apply (simp add: open_contains_ball, clarify)
    apply (rename_tac y)
    apply (drule_tac x=y in bspec)
     apply (simp add: connected_component_in, clarify)
    apply (rule_tac x=e in exI)
    by (metis mem_Collect_eq connected_component_eq connected_component_maximal centre_in_ball connected_ball)

corollary open_components:
    fixes s :: "'a::real_normed_vector set"
    shows "⟦open u; s ∈ components u⟧ ⟹ open s"
  by (simp add: components_iff) (metis open_connected_component)

lemma in_closure_connected_component:
  fixes s :: "'a::real_normed_vector set"
  assumes x: "x ∈ s" and s: "open s"
  shows "x ∈ closure (connected_component_set s y) ⟷  x ∈ connected_component_set s y"
proof -
  { assume "x ∈ closure (connected_component_set s y)"
    moreover have "x ∈ connected_component_set s x"
      using x by simp
    ultimately have "x ∈ connected_component_set s y"
      using s by (meson Compl_disjoint closure_iff_nhds_not_empty connected_component_disjoint disjoint_eq_subset_Compl open_connected_component)
  }
  then show ?thesis
    by (auto simp: closure_def)
qed

lemma connected_disjoint_Union_open_pick:
  assumes "pairwise disjnt B"
          "⋀S. S ∈ A ⟹ connected S ∧ S ≠ {}"
          "⋀S. S ∈ B ⟹ open S"
          "⋃A ⊆ ⋃B"
          "S ∈ A"
  obtains T where "T ∈ B" "S ⊆ T" "S ∩ ⋃(B - {T}) = {}"
proof -
  have "S ⊆ ⋃B" "connected S" "S ≠ {}"
    using assms ‹S ∈ A› by blast+
  then obtain T where "T ∈ B" "S ∩ T ≠ {}"
    by (metis Sup_inf_eq_bot_iff inf.absorb_iff2 inf_commute)
  have 1: "open T" by (simp add: ‹T ∈ B› assms)
  have 2: "open (⋃(B-{T}))" using assms by blast
  have 3: "S ⊆ T ∪ ⋃(B - {T})" using ‹S ⊆ ⋃B› by blast
  have "T ∩ ⋃(B - {T}) = {}" using ‹T ∈ B› ‹pairwise disjnt B›
    by (auto simp: pairwise_def disjnt_def)
  then have 4: "T ∩ ⋃(B - {T}) ∩ S = {}" by auto
  from connectedD [OF ‹connected S› 1 2 3 4]
  have "S ∩ ⋃(B-{T}) = {}"
    by (auto simp: Int_commute ‹S ∩ T ≠ {}›)
  with ‹T ∈ B› have "S ⊆ T"
    using "3" by auto
  show ?thesis
    using ‹S ∩ ⋃(B - {T}) = {}› ‹S ⊆ T› ‹T ∈ B› that by auto
qed

lemma connected_disjoint_Union_open_subset:
  assumes A: "pairwise disjnt A" and B: "pairwise disjnt B"
      and SA: "⋀S. S ∈ A ⟹ open S ∧ connected S ∧ S ≠ {}"
      and SB: "⋀S. S ∈ B ⟹ open S ∧ connected S ∧ S ≠ {}"
      and eq [simp]: "⋃A = ⋃B"
    shows "A ⊆ B"
proof
  fix S
  assume "S ∈ A"
  obtain T where "T ∈ B" "S ⊆ T" "S ∩ ⋃(B - {T}) = {}"
      apply (rule connected_disjoint_Union_open_pick [OF B, of A])
      using SA SB ‹S ∈ A› by auto
  moreover obtain S' where "S' ∈ A" "T ⊆ S'" "T ∩ ⋃(A - {S'}) = {}"
      apply (rule connected_disjoint_Union_open_pick [OF A, of B])
      using SA SB ‹T ∈ B› by auto
  ultimately have "S' = S"
    by (metis A Int_subset_iff SA ‹S ∈ A› disjnt_def inf.orderE pairwise_def)
  with ‹T ⊆ S'› have "T ⊆ S" by simp
  with ‹S ⊆ T› have "S = T" by blast
  with ‹T ∈ B› show "S ∈ B" by simp
qed

lemma connected_disjoint_Union_open_unique:
  assumes A: "pairwise disjnt A" and B: "pairwise disjnt B"
      and SA: "⋀S. S ∈ A ⟹ open S ∧ connected S ∧ S ≠ {}"
      and SB: "⋀S. S ∈ B ⟹ open S ∧ connected S ∧ S ≠ {}"
      and eq [simp]: "⋃A = ⋃B"
    shows "A = B"
by (rule subset_antisym; metis connected_disjoint_Union_open_subset assms)

proposition components_open_unique:
 fixes S :: "'a::real_normed_vector set"
  assumes "pairwise disjnt A" "⋃A = S"
          "⋀X. X ∈ A ⟹ open X ∧ connected X ∧ X ≠ {}"
    shows "components S = A"
proof -
  have "open S" using assms by blast
  show ?thesis
    apply (rule connected_disjoint_Union_open_unique)
    apply (simp add: components_eq disjnt_def pairwise_def)
    using ‹open S›
    apply (simp_all add: assms open_components in_components_connected in_components_nonempty)
    done
qed


subsection%unimportant‹Existence of unbounded components›

lemma cobounded_unbounded_component:
    fixes s :: "'a :: euclidean_space set"
    assumes "bounded (-s)"
      shows "∃x. x ∈ s ∧ ~ bounded (connected_component_set s x)"
proof -
  obtain i::'a where i: "i ∈ Basis"
    using nonempty_Basis by blast
  obtain B where B: "B>0" "-s ⊆ ball 0 B"
    using bounded_subset_ballD [OF assms, of 0] by auto
  then have *: "⋀x. B ≤ norm x ⟹ x ∈ s"
    by (force simp: ball_def dist_norm)
  have unbounded_inner: "~ bounded {x. inner i x ≥ B}"
    apply (auto simp: bounded_def dist_norm)
    apply (rule_tac x="x + (max B e + 1 + ¦i ∙ x¦) *R i" in exI)
    apply simp
    using i
    apply (auto simp: algebra_simps)
    done
  have **: "{x. B ≤ i ∙ x} ⊆ connected_component_set s (B *R i)"
    apply (rule connected_component_maximal)
    apply (auto simp: i intro: convex_connected convex_halfspace_ge [of B])
    apply (rule *)
    apply (rule order_trans [OF _ Basis_le_norm [OF i]])
    by (simp add: inner_commute)
  have "B *R i ∈ s"
    by (rule *) (simp add: norm_Basis [OF i])
  then show ?thesis
    apply (rule_tac x="B *R i" in exI, clarify)
    apply (frule bounded_subset [of _ "{x. B ≤ i ∙ x}", OF _ **])
    using unbounded_inner apply blast
    done
qed

lemma cobounded_unique_unbounded_component:
    fixes s :: "'a :: euclidean_space set"
    assumes bs: "bounded (-s)" and "2 ≤ DIM('a)"
        and bo: "~ bounded(connected_component_set s x)"
                "~ bounded(connected_component_set s y)"
      shows "connected_component_set s x = connected_component_set s y"
proof -
  obtain i::'a where i: "i ∈ Basis"
    using nonempty_Basis by blast
  obtain B where B: "B>0" "-s ⊆ ball 0 B"
    using bounded_subset_ballD [OF bs, of 0] by auto
  then have *: "⋀x. B ≤ norm x ⟹ x ∈ s"
    by (force simp: ball_def dist_norm)
  have ccb: "connected (- ball 0 B :: 'a set)"
    using assms by (auto intro: connected_complement_bounded_convex)
  obtain x' where x': "connected_component s x x'" "norm x' > B"
    using bo [unfolded bounded_def dist_norm, simplified, rule_format]
    by (metis diff_zero norm_minus_commute not_less)
  obtain y' where y': "connected_component s y y'" "norm y' > B"
    using bo [unfolded bounded_def dist_norm, simplified, rule_format]
    by (metis diff_zero norm_minus_commute not_less)
  have x'y': "connected_component s x' y'"
    apply (simp add: connected_component_def)
    apply (rule_tac x="- ball 0 B" in exI)
    using x' y'
    apply (auto simp: ccb dist_norm *)
    done
  show ?thesis
    apply (rule connected_component_eq)
    using x' y' x'y'
    by (metis (no_types, lifting) connected_component_eq_empty connected_component_eq_eq connected_component_idemp connected_component_in)
qed

lemma cobounded_unbounded_components:
    fixes s :: "'a :: euclidean_space set"
    shows "bounded (-s) ⟹ ∃c. c ∈ components s ∧ ~bounded c"
  by (metis cobounded_unbounded_component components_def imageI)

lemma cobounded_unique_unbounded_components:
    fixes s :: "'a :: euclidean_space set"
    shows  "⟦bounded (- s); c ∈ components s; ¬ bounded c; c' ∈ components s; ¬ bounded c'; 2 ≤ DIM('a)⟧ ⟹ c' = c"
  unfolding components_iff
  by (metis cobounded_unique_unbounded_component)

lemma cobounded_has_bounded_component:
  fixes S :: "'a :: euclidean_space set"
  assumes "bounded (- S)" "¬ connected S" "2 ≤ DIM('a)"
  obtains C where "C ∈ components S" "bounded C"
  by (meson cobounded_unique_unbounded_components connected_eq_connected_components_eq assms)


section‹The "inside" and "outside" of a set›

text%important‹The inside comprises the points in a bounded connected component of the set's complement.
  The outside comprises the points in unbounded connected component of the complement.›

definition%important inside where
  "inside S ≡ {x. (x ∉ S) ∧ bounded(connected_component_set ( - S) x)}"

definition%important outside where
  "outside S ≡ -S ∩ {x. ~ bounded(connected_component_set (- S) x)}"

lemma outside: "outside S = {x. ~ bounded(connected_component_set (- S) x)}"
  by (auto simp: outside_def) (metis Compl_iff bounded_empty connected_component_eq_empty)

lemma inside_no_overlap [simp]: "inside S ∩ S = {}"
  by (auto simp: inside_def)

lemma outside_no_overlap [simp]:
   "outside S ∩ S = {}"
  by (auto simp: outside_def)

lemma inside_Int_outside [simp]: "inside S ∩ outside S = {}"
  by (auto simp: inside_def outside_def)

lemma inside_Un_outside [simp]: "inside S ∪ outside S = (- S)"
  by (auto simp: inside_def outside_def)

lemma inside_eq_outside:
   "inside S = outside S ⟷ S = UNIV"
  by (auto simp: inside_def outside_def)

lemma inside_outside: "inside S = (- (S ∪ outside S))"
  by (force simp: inside_def outside)

lemma outside_inside: "outside S = (- (S ∪ inside S))"
  by (auto simp: inside_outside) (metis IntI equals0D outside_no_overlap)

lemma union_with_inside: "S ∪ inside S = - outside S"
  by (auto simp: inside_outside) (simp add: outside_inside)

lemma union_with_outside: "S ∪ outside S = - inside S"
  by (simp add: inside_outside)

lemma outside_mono: "S ⊆ T ⟹ outside T ⊆ outside S"
  by (auto simp: outside bounded_subset connected_component_mono)

lemma inside_mono: "S ⊆ T ⟹ inside S - T ⊆ inside T"
  by (auto simp: inside_def bounded_subset connected_component_mono)

lemma segment_bound_lemma:
  fixes u::real
  assumes "x ≥ B" "y ≥ B" "0 ≤ u" "u ≤ 1"
  shows "(1 - u) * x + u * y ≥ B"
proof -
  obtain dx dy where "dx ≥ 0" "dy ≥ 0" "x = B + dx" "y = B + dy"
    using assms by auto (metis add.commute diff_add_cancel)
  with ‹0 ≤ u› ‹u ≤ 1› show ?thesis
    by (simp add: add_increasing2 mult_left_le field_simps)
qed

lemma cobounded_outside:
  fixes S :: "'a :: real_normed_vector set"
  assumes "bounded S" shows "bounded (- outside S)"
proof -
  obtain B where B: "B>0" "S ⊆ ball 0 B"
    using bounded_subset_ballD [OF assms, of 0] by auto
  { fix x::'a and C::real
    assume Bno: "B ≤ norm x" and C: "0 < C"
    have "∃y. connected_component (- S) x y ∧ norm y > C"
    proof (cases "x = 0")
      case True with B Bno show ?thesis by force
    next
      case False 
      with B C
      have "closed_segment x (((B + C) / norm x) *R x) ⊆ - ball 0 B"
        apply (clarsimp simp add: closed_segment_def ball_def dist_norm real_vector_class.scaleR_add_left [symmetric] divide_simps)
        using segment_bound_lemma [of B "norm x" "B+C" ] Bno
        by (meson le_add_same_cancel1 less_eq_real_def not_le)
      also have "... ⊆ -S"
        by (simp add: B)
      finally have "∃T. connected T ∧ T ⊆ - S ∧ x ∈ T ∧ ((B + C) / norm x) *R x ∈ T"
        by (rule_tac x="closed_segment x (((B+C)/norm x) *R x)" in exI) simp
      with False B
      show ?thesis
        by (rule_tac x="((B+C)/norm x) *R x" in exI) (simp add: connected_component_def)
    qed
  }
  then show ?thesis
    apply (simp add: outside_def assms)
    apply (rule bounded_subset [OF bounded_ball [of 0 B]])
    apply (force simp: dist_norm not_less bounded_pos)
    done
qed

lemma unbounded_outside:
    fixes S :: "'a::{real_normed_vector, perfect_space} set"
    shows "bounded S ⟹ ~ bounded(outside S)"
  using cobounded_imp_unbounded cobounded_outside by blast

lemma bounded_inside:
    fixes S :: "'a::{real_normed_vector, perfect_space} set"
    shows "bounded S ⟹ bounded(inside S)"
  by (simp add: bounded_Int cobounded_outside inside_outside)

lemma connected_outside:
    fixes S :: "'a::euclidean_space set"
    assumes "bounded S" "2 ≤ DIM('a)"
      shows "connected(outside S)"
  apply (clarsimp simp add: connected_iff_connected_component outside)
  apply (rule_tac s="connected_component_set (- S) x" in connected_component_of_subset)
  apply (metis (no_types) assms cobounded_unbounded_component cobounded_unique_unbounded_component connected_component_eq_eq connected_component_idemp double_complement mem_Collect_eq)
  apply clarify
  apply (metis connected_component_eq_eq connected_component_in)
  done

lemma outside_connected_component_lt:
    "outside S = {x. ∀B. ∃y. B < norm(y) ∧ connected_component (- S) x y}"
apply (auto simp: outside bounded_def dist_norm)
apply (metis diff_0 norm_minus_cancel not_less)
by (metis less_diff_eq norm_minus_commute norm_triangle_ineq2 order.trans pinf(6))

lemma outside_connected_component_le:
   "outside S =
            {x. ∀B. ∃y. B ≤ norm(y) ∧
                         connected_component (- S) x y}"
apply (simp add: outside_connected_component_lt)
apply (simp add: Set.set_eq_iff)
by (meson gt_ex leD le_less_linear less_imp_le order.trans)

lemma not_outside_connected_component_lt:
    fixes S :: "'a::euclidean_space set"
    assumes S: "bounded S" and "2 ≤ DIM('a)"
      shows "- (outside S) = {x. ∀B. ∃y. B < norm(y) ∧ ~ (connected_component (- S) x y)}"
proof -
  obtain B::real where B: "0 < B" and Bno: "⋀x. x ∈ S ⟹ norm x ≤ B"
    using S [simplified bounded_pos] by auto
  { fix y::'a and z::'a
    assume yz: "B < norm z" "B < norm y"
    have "connected_component (- cball 0 B) y z"
      apply (rule connected_componentI [OF _ subset_refl])
      apply (rule connected_complement_bounded_convex)
      using assms yz
      by (auto simp: dist_norm)
    then have "connected_component (- S) y z"
      apply (rule connected_component_of_subset)
      apply (metis Bno Compl_anti_mono mem_cball_0 subset_iff)
      done
  } note cyz = this
  show ?thesis
    apply (auto simp: outside)
    apply (metis Compl_iff bounded_iff cobounded_imp_unbounded mem_Collect_eq not_le)
    apply (simp add: bounded_pos)
    by (metis B connected_component_trans cyz not_le)
qed

lemma not_outside_connected_component_le:
    fixes S :: "'a::euclidean_space set"
    assumes S: "bounded S"  "2 ≤ DIM('a)"
      shows "- (outside S) = {x. ∀B. ∃y. B ≤ norm(y) ∧ ~ (connected_component (- S) x y)}"
apply (auto intro: less_imp_le simp: not_outside_connected_component_lt [OF assms])
by (meson gt_ex less_le_trans)

lemma inside_connected_component_lt:
    fixes S :: "'a::euclidean_space set"
    assumes S: "bounded S"  "2 ≤ DIM('a)"
      shows "inside S = {x. (x ∉ S) ∧ (∀B. ∃y. B < norm(y) ∧ ~(connected_component (- S) x y))}"
  by (auto simp: inside_outside not_outside_connected_component_lt [OF assms])

lemma inside_connected_component_le:
    fixes S :: "'a::euclidean_space set"
    assumes S: "bounded S"  "2 ≤ DIM('a)"
      shows "inside S = {x. (x ∉ S) ∧ (∀B. ∃y. B ≤ norm(y) ∧ ~(connected_component (- S) x y))}"
  by (auto simp: inside_outside not_outside_connected_component_le [OF assms])

lemma inside_subset:
  assumes "connected U" and "~bounded U" and "T ∪ U = - S"
  shows "inside S ⊆ T"
apply (auto simp: inside_def)
by (metis bounded_subset [of "connected_component_set (- S) _"] connected_component_maximal
       Compl_iff Un_iff assms subsetI)

lemma frontier_not_empty:
  fixes S :: "'a :: real_normed_vector set"
  shows "⟦S ≠ {}; S ≠ UNIV⟧ ⟹ frontier S ≠ {}"
    using connected_Int_frontier [of UNIV S] by auto

lemma frontier_eq_empty:
  fixes S :: "'a :: real_normed_vector set"
  shows "frontier S = {} ⟷ S = {} ∨ S = UNIV"
using frontier_UNIV frontier_empty frontier_not_empty by blast

lemma frontier_of_connected_component_subset:
  fixes S :: "'a::real_normed_vector set"
  shows "frontier(connected_component_set S x) ⊆ frontier S"
proof -
  { fix y
    assume y1: "y ∈ closure (connected_component_set S x)"
       and y2: "y ∉ interior (connected_component_set S x)"
    have "y ∈ closure S"
      using y1 closure_mono connected_component_subset by blast
    moreover have "z ∈ interior (connected_component_set S x)"
          if "0 < e" "ball y e ⊆ interior S" "dist y z < e" for e z
    proof -
      have "ball y e ⊆ connected_component_set S y"
        apply (rule connected_component_maximal)
        using that interior_subset mem_ball apply auto
        done
      then show ?thesis
        using y1 apply (simp add: closure_approachable open_contains_ball_eq [OF open_interior])
        by (metis connected_component_eq dist_commute mem_Collect_eq mem_ball mem_interior subsetD ‹0 < e› y2)
    qed
    then have "y ∉ interior S"
      using y2 by (force simp: open_contains_ball_eq [OF open_interior])
    ultimately have "y ∈ frontier S"
      by (auto simp: frontier_def)
  }
  then show ?thesis by (auto simp: frontier_def)
qed

lemma frontier_Union_subset_closure:
  fixes F :: "'a::real_normed_vector set set"
  shows "frontier(⋃F) ⊆ closure(⋃t ∈ F. frontier t)"
proof -
  have "∃y∈F. ∃y∈frontier y. dist y x < e"
       if "T ∈ F" "y ∈ T" "dist y x < e"
          "x ∉ interior (⋃F)" "0 < e" for x y e T
  proof (cases "x ∈ T")
    case True with that show ?thesis
      by (metis Diff_iff Sup_upper closure_subset contra_subsetD dist_self frontier_def interior_mono)
  next
    case False
    have 1: "closed_segment x y ∩ T ≠ {}" using ‹y ∈ T› by blast
    have 2: "closed_segment x y - T ≠ {}"
      using False by blast
    obtain c where "c ∈ closed_segment x y" "c ∈ frontier T"
       using False connected_Int_frontier [OF connected_segment 1 2] by auto
    then show ?thesis
    proof -
      have "norm (y - x) < e"
        by (metis dist_norm ‹dist y x < e›)
      moreover have "norm (c - x) ≤ norm (y - x)"
        by (simp add: ‹c ∈ closed_segment x y› segment_bound(1))
      ultimately have "norm (c - x) < e"
        by linarith
      then show ?thesis
        by (metis (no_types) ‹c ∈ frontier T› dist_norm that(1))
    qed
  qed
  then show ?thesis
    by (fastforce simp add: frontier_def closure_approachable)
qed

lemma frontier_Union_subset:
  fixes F :: "'a::real_normed_vector set set"
  shows "finite F ⟹ frontier(⋃F) ⊆ (⋃t ∈ F. frontier t)"
by (rule order_trans [OF frontier_Union_subset_closure])
   (auto simp: closure_subset_eq)

lemma frontier_of_components_subset:
  fixes S :: "'a::real_normed_vector set"
  shows "C ∈ components S ⟹ frontier C ⊆ frontier S"
  by (metis Path_Connected.frontier_of_connected_component_subset components_iff)

lemma frontier_of_components_closed_complement:
  fixes S :: "'a::real_normed_vector set"
  shows "⟦closed S; C ∈ components (- S)⟧ ⟹ frontier C ⊆ S"
  using frontier_complement frontier_of_components_subset frontier_subset_eq by blast

lemma frontier_minimal_separating_closed:
  fixes S :: "'a::real_normed_vector set"
  assumes "closed S"
      and nconn: "~ connected(- S)"
      and C: "C ∈ components (- S)"
      and conn: "⋀T. ⟦closed T; T ⊂ S⟧ ⟹ connected(- T)"
    shows "frontier C = S"
proof (rule ccontr)
  assume "frontier C ≠ S"
  then have "frontier C ⊂ S"
    using frontier_of_components_closed_complement [OF ‹closed S› C] by blast
  then have "connected(- (frontier C))"
    by (simp add: conn)
  have "¬ connected(- (frontier C))"
    unfolding connected_def not_not
  proof (intro exI conjI)
    show "open C"
      using C ‹closed S› open_components by blast
    show "open (- closure C)"
      by blast
    show "C ∩ - closure C ∩ - frontier C = {}"
      using closure_subset by blast
    show "C ∩ - frontier C ≠ {}"
      using C ‹open C› components_eq frontier_disjoint_eq by fastforce
    show "- frontier C ⊆ C ∪ - closure C"
      by (simp add: ‹open C› closed_Compl frontier_closures)
    then show "- closure C ∩ - frontier C ≠ {}"
      by (metis (no_types, lifting) C Compl_subset_Compl_iff ‹frontier C ⊂ S› compl_sup frontier_closures in_components_subset psubsetE sup.absorb_iff2 sup.boundedE sup_bot.right_neutral sup_inf_absorb)
  qed
  then show False
    using ‹connected (- frontier C)› by blast
qed

lemma connected_component_UNIV [simp]:
    fixes x :: "'a::real_normed_vector"
    shows "connected_component_set UNIV x = UNIV"
using connected_iff_eq_connected_component_set [of "UNIV::'a set"] connected_UNIV
by auto

lemma connected_component_eq_UNIV:
    fixes x :: "'a::real_normed_vector"
    shows "connected_component_set s x = UNIV ⟷ s = UNIV"
  using connected_component_in connected_component_UNIV by blast

lemma components_UNIV [simp]: "components UNIV = {UNIV :: 'a::real_normed_vector set}"
  by (auto simp: components_eq_sing_iff)

lemma interior_inside_frontier:
    fixes s :: "'a::real_normed_vector set"
    assumes "bounded s"
      shows "interior s ⊆ inside (frontier s)"
proof -
  { fix x y
    assume x: "x ∈ interior s" and y: "y ∉ s"
       and cc: "connected_component (- frontier s) x y"
    have "connected_component_set (- frontier s) x ∩ frontier s ≠ {}"
      apply (rule connected_Int_frontier, simp)
      apply (metis IntI cc connected_component_in connected_component_refl empty_iff interiorE mem_Collect_eq set_rev_mp x)
      using  y cc
      by blast
    then have "bounded (connected_component_set (- frontier s) x)"
      using connected_component_in by auto
  }
  then show ?thesis
    apply (auto simp: inside_def frontier_def)
    apply (rule classical)
    apply (rule bounded_subset [OF assms], blast)
    done
qed

lemma inside_empty [simp]: "inside {} = ({} :: 'a :: {real_normed_vector, perfect_space} set)"
  by (simp add: inside_def connected_component_UNIV)

lemma outside_empty [simp]: "outside {} = (UNIV :: 'a :: {real_normed_vector, perfect_space} set)"
using inside_empty inside_Un_outside by blast

lemma inside_same_component:
   "⟦connected_component (- s) x y; x ∈ inside s⟧ ⟹ y ∈ inside s"
  using connected_component_eq connected_component_in
  by (fastforce simp add: inside_def)

lemma outside_same_component:
   "⟦connected_component (- s) x y; x ∈ outside s⟧ ⟹ y ∈ outside s"
  using connected_component_eq connected_component_in
  by (fastforce simp add: outside_def)

lemma convex_in_outside:
  fixes s :: "'a :: {real_normed_vector, perfect_space} set"
  assumes s: "convex s" and z: "z ∉ s"
    shows "z ∈ outside s"
proof (cases "s={}")
  case True then show ?thesis by simp
next
  case False then obtain a where "a ∈ s" by blast
  with z have zna: "z ≠ a" by auto
  { assume "bounded (connected_component_set (- s) z)"
    with bounded_pos_less obtain B where "B>0" and B: "⋀x. connected_component (- s) z x ⟹ norm x < B"
      by (metis mem_Collect_eq)
    define C where "C = (B + 1 + norm z) / norm (z-a)"
    have "C > 0"
      using ‹0 < B› zna by (simp add: C_def divide_simps add_strict_increasing)
    have "¦norm (z + C *R (z-a)) - norm (C *R (z-a))¦ ≤ norm z"
      by (metis add_diff_cancel norm_triangle_ineq3)
    moreover have "norm (C *R (z-a)) > norm z + B"
      using zna ‹B>0› by (simp add: C_def le_max_iff_disj field_simps)
    ultimately have C: "norm (z + C *R (z-a)) > B" by linarith
    { fix u::real
      assume u: "0≤u" "u≤1" and ins: "(1 - u) *R z + u *R (z + C *R (z - a)) ∈ s"
      then have Cpos: "1 + u * C > 0"
        by (meson ‹0 < C› add_pos_nonneg less_eq_real_def zero_le_mult_iff zero_less_one)
      then have *: "(1 / (1 + u * C)) *R z + (u * C / (1 + u * C)) *R z = z"
        by (simp add: scaleR_add_left [symmetric] divide_simps)
      then have False
        using convexD_alt [OF s ‹a ∈ s› ins, of "1/(u*C + 1)"] ‹C>0› ‹z ∉ s› Cpos u
        by (simp add: * divide_simps algebra_simps)
    } note contra = this
    have "connected_component (- s) z (z + C *R (z-a))"
      apply (rule connected_componentI [OF connected_segment [of z "z + C *R (z-a)"]])
      apply (simp add: closed_segment_def)
      using contra
      apply auto
      done
    then have False
      using zna B [of "z + C *R (z-a)"] C
      by (auto simp: divide_simps max_mult_distrib_right)
  }
  then show ?thesis
    by (auto simp: outside_def z)
qed

lemma outside_convex:
  fixes s :: "'a :: {real_normed_vector, perfect_space} set"
  assumes "convex s"
    shows "outside s = - s"
  by (metis ComplD assms convex_in_outside equalityI inside_Un_outside subsetI sup.cobounded2)

lemma outside_singleton [simp]:
  fixes x :: "'a :: {real_normed_vector, perfect_space}"
  shows "outside {x} = -{x}"
  by (auto simp: outside_convex)

lemma inside_convex:
  fixes s :: "'a :: {real_normed_vector, perfect_space} set"
  shows "convex s ⟹ inside s = {}"
  by (simp add: inside_outside outside_convex)

lemma inside_singleton [simp]:
  fixes x :: "'a :: {real_normed_vector, perfect_space}"
  shows "inside {x} = {}"
  by (auto simp: inside_convex)

lemma outside_subset_convex:
  fixes s :: "'a :: {real_normed_vector, perfect_space} set"
  shows "⟦convex t; s ⊆ t⟧ ⟹ - t ⊆ outside s"
  using outside_convex outside_mono by blast

lemma outside_Un_outside_Un:
  fixes S :: "'a::real_normed_vector set"
  assumes "S ∩ outside(T ∪ U) = {}"
  shows "outside(T ∪ U) ⊆ outside(T ∪ S)"
proof
  fix x
  assume x: "x ∈ outside (T ∪ U)"
  have "Y ⊆ - S" if "connected Y" "Y ⊆ - T" "Y ⊆ - U" "x ∈ Y" "u ∈ Y" for u Y
  proof -
    have "Y ⊆ connected_component_set (- (T ∪ U)) x"
      by (simp add: connected_component_maximal that)
    also have "… ⊆ outside(T ∪ U)"
      by (metis (mono_tags, lifting) Collect_mono mem_Collect_eq outside outside_same_component x)
    finally have "Y ⊆ outside(T ∪ U)" .
    with assms show ?thesis by auto
  qed
  with x show "x ∈ outside (T ∪ S)"
    by (simp add: outside_connected_component_lt connected_component_def) meson
qed

lemma outside_frontier_misses_closure:
    fixes s :: "'a::real_normed_vector set"
    assumes "bounded s"
    shows  "outside(frontier s) ⊆ - closure s"
  unfolding outside_inside Lattices.boolean_algebra_class.compl_le_compl_iff
proof -
  { assume "interior s ⊆ inside (frontier s)"
    hence "interior s ∪ inside (frontier s) = inside (frontier s)"
      by (simp add: subset_Un_eq)
    then have "closure s ⊆ frontier s ∪ inside (frontier s)"
      using frontier_def by auto
  }
  then show "closure s ⊆ frontier s ∪ inside (frontier s)"
    using interior_inside_frontier [OF assms] by blast
qed

lemma outside_frontier_eq_complement_closure:
  fixes s :: "'a :: {real_normed_vector, perfect_space} set"
    assumes "bounded s" "convex s"
      shows "outside(frontier s) = - closure s"
by (metis Diff_subset assms convex_closure frontier_def outside_frontier_misses_closure
          outside_subset_convex subset_antisym)

lemma inside_frontier_eq_interior:
     fixes s :: "'a :: {real_normed_vector, perfect_space} set"
     shows "⟦bounded s; convex s⟧ ⟹ inside(frontier s) = interior s"
  apply (simp add: inside_outside outside_frontier_eq_complement_closure)
  using closure_subset interior_subset
  apply (auto simp: frontier_def)
  done

lemma open_inside:
    fixes s :: "'a::real_normed_vector set"
    assumes "closed s"
      shows "open (inside s)"
proof -
  { fix x assume x: "x ∈ inside s"
    have "open (connected_component_set (- s) x)"
      using assms open_connected_component by blast
    then obtain e where e: "e>0" and e: "⋀y. dist y x < e ⟶ connected_component (- s) x y"
      using dist_not_less_zero
      apply (simp add: open_dist)
      by (metis (no_types, lifting) Compl_iff connected_component_refl_eq inside_def mem_Collect_eq x)
    then have "∃e>0. ball x e ⊆ inside s"
      by (metis e dist_commute inside_same_component mem_ball subsetI x)
  }
  then show ?thesis
    by (simp add: open_contains_ball)
qed

lemma open_outside:
    fixes s :: "'a::real_normed_vector set"
    assumes "closed s"
      shows "open (outside s)"
proof -
  { fix x assume x: "x ∈ outside s"
    have "open (connected_component_set (- s) x)"
      using assms open_connected_component by blast
    then obtain e where e: "e>0" and e: "⋀y. dist y x < e ⟶ connected_component (- s) x y"
      using dist_not_less_zero
      apply (simp add: open_dist)
      by (metis Int_iff outside_def connected_component_refl_eq  x)
    then have "∃e>0. ball x e ⊆ outside s"
      by (metis e dist_commute outside_same_component mem_ball subsetI x)
  }
  then show ?thesis
    by (simp add: open_contains_ball)
qed

lemma closure_inside_subset:
    fixes s :: "'a::real_normed_vector set"
    assumes "closed s"
      shows "closure(inside s) ⊆ s ∪ inside s"
by (metis assms closure_minimal open_closed open_outside sup.cobounded2 union_with_inside)

lemma frontier_inside_subset:
    fixes s :: "'a::real_normed_vector set"
    assumes "closed s"
      shows "frontier(inside s) ⊆ s"
proof -
  have "closure (inside s) ∩ - inside s = closure (inside s) - interior (inside s)"
    by (metis (no_types) Diff_Compl assms closure_closed interior_closure open_closed open_inside)
  moreover have "- inside s ∩ - outside s = s"
    by (metis (no_types) compl_sup double_compl inside_Un_outside)
  moreover have "closure (inside s) ⊆ - outside s"
    by (metis (no_types) assms closure_inside_subset union_with_inside)
  ultimately have "closure (inside s) - interior (inside s) ⊆ s"
    by blast
  then show ?thesis
    by (simp add: frontier_def open_inside interior_open)
qed

lemma closure_outside_subset:
    fixes s :: "'a::real_normed_vector set"
    assumes "closed s"
      shows "closure(outside s) ⊆ s ∪ outside s"
  apply (rule closure_minimal, simp)
  by (metis assms closed_open inside_outside open_inside)

lemma frontier_outside_subset:
    fixes s :: "'a::real_normed_vector set"
    assumes "closed s"
      shows "frontier(outside s) ⊆ s"
  apply (simp add: frontier_def open_outside interior_open)
  by (metis Diff_subset_conv assms closure_outside_subset interior_eq open_outside sup.commute)

lemma inside_complement_unbounded_connected_empty:
     "⟦connected (- s); ¬ bounded (- s)⟧ ⟹ inside s = {}"
  apply (simp add: inside_def)
  by (meson Compl_iff bounded_subset connected_component_maximal order_refl)

lemma inside_bounded_complement_connected_empty:
    fixes s :: "'a::{real_normed_vector, perfect_space} set"
    shows "⟦connected (- s); bounded s⟧ ⟹ inside s = {}"
  by (metis inside_complement_unbounded_connected_empty cobounded_imp_unbounded)

lemma inside_inside:
    assumes "s ⊆ inside t"
    shows "inside s - t ⊆ inside t"
unfolding inside_def
proof clarify
  fix x
  assume x: "x ∉ t" "x ∉ s" and bo: "bounded (connected_component_set (- s) x)"
  show "bounded (connected_component_set (- t) x)"
  proof (cases "s ∩ connected_component_set (- t) x = {}")
    case True show ?thesis
      apply (rule bounded_subset [OF bo])
      apply (rule connected_component_maximal)
      using x True apply auto
      done
  next
    case False then show ?thesis
      using assms [unfolded inside_def] x
      apply (simp add: disjoint_iff_not_equal, clarify)
      apply (drule subsetD, assumption, auto)
      by (metis (no_types, hide_lams) ComplI connected_component_eq_eq)
  qed
qed

lemma inside_inside_subset: "inside(inside s) ⊆ s"
  using inside_inside union_with_outside by fastforce

lemma inside_outside_intersect_connected:
      "⟦connected t; inside s ∩ t ≠ {}; outside s ∩ t ≠ {}⟧ ⟹ s ∩ t ≠ {}"
  apply (simp add: inside_def outside_def ex_in_conv [symmetric] disjoint_eq_subset_Compl, clarify)
  by (metis (no_types, hide_lams) Compl_anti_mono connected_component_eq connected_component_maximal contra_subsetD double_compl)

lemma outside_bounded_nonempty:
  fixes s :: "'a :: {real_normed_vector, perfect_space} set"
    assumes "bounded s" shows "outside s ≠ {}"
  by (metis (no_types, lifting) Collect_empty_eq Collect_mem_eq Compl_eq_Diff_UNIV Diff_cancel
                   Diff_disjoint UNIV_I assms ball_eq_empty bounded_diff cobounded_outside convex_ball
                   double_complement order_refl outside_convex outside_def)

lemma outside_compact_in_open:
    fixes s :: "'a :: {real_normed_vector,perfect_space} set"
    assumes s: "compact s" and t: "open t" and "s ⊆ t" "t ≠ {}"
      shows "outside s ∩ t ≠ {}"
proof -
  have "outside s ≠ {}"
    by (simp add: compact_imp_bounded outside_bounded_nonempty s)
  with assms obtain a b where a: "a ∈ outside s" and b: "b ∈ t" by auto
  show ?thesis
  proof (cases "a ∈ t")
    case True with a show ?thesis by blast
  next
    case False
      have front: "frontier t ⊆ - s"
        using ‹s ⊆ t› frontier_disjoint_eq t by auto
      { fix γ
        assume "path γ" and pimg_sbs: "path_image γ - {pathfinish γ} ⊆ interior (- t)"
           and pf: "pathfinish γ ∈ frontier t" and ps: "pathstart γ = a"
        define c where "c = pathfinish γ"
        have "c ∈ -s" unfolding c_def using front pf by blast
        moreover have "open (-s)" using s compact_imp_closed by blast
        ultimately obtain ε::real where "ε > 0" and ε: "cball c ε ⊆ -s"
          using open_contains_cball[of "-s"] s by blast
        then obtain d where "d ∈ t" and d: "dist d c < ε"
          using closure_approachable [of c t] pf unfolding c_def
          by (metis Diff_iff frontier_def)
        then have "d ∈ -s" using ε
          using dist_commute by (metis contra_subsetD mem_cball not_le not_less_iff_gr_or_eq)
        have pimg_sbs_cos: "path_image γ ⊆ -s"
          using pimg_sbs apply (auto simp: path_image_def)
          apply (drule subsetD)
          using ‹c ∈ - s› ‹s ⊆ t› interior_subset apply (auto simp: c_def)
          done
        have "closed_segment c d ≤ cball c ε"
          apply (simp add: segment_convex_hull)
          apply (rule hull_minimal)
          using  ‹ε > 0› d apply (auto simp: dist_commute)
          done
        with ε have "closed_segment c d ⊆ -s" by blast
        moreover have con_gcd: "connected (path_image γ ∪ closed_segment c d)"
          by (rule connected_Un) (auto simp: c_def ‹path γ› connected_path_image)
        ultimately have "connected_component (- s) a d"
          unfolding connected_component_def using pimg_sbs_cos ps by blast
        then have "outside s ∩ t ≠ {}"
          using outside_same_component [OF _ a]  by (metis IntI ‹d ∈ t› empty_iff)
      } note * = this
      have pal: "pathstart (linepath a b) ∈ closure (- t)"
        by (auto simp: False closure_def)
      show ?thesis
        by (rule exists_path_subpath_to_frontier [OF path_linepath pal _ *]) (auto simp: b)
  qed
qed

lemma inside_inside_compact_connected:
    fixes s :: "'a :: euclidean_space set"
    assumes s: "closed s" and t: "compact t" and "connected t" "s ⊆ inside t"
      shows "inside s ⊆ inside t"
proof (cases "inside t = {}")
  case True with assms show ?thesis by auto
next
  case False
  consider "DIM('a) = 1" | "DIM('a) ≥ 2"
    using antisym not_less_eq_eq by fastforce
  then show ?thesis
  proof cases
    case 1 then show ?thesis
             using connected_convex_1_gen assms False inside_convex by blast
  next
    case 2
    have coms: "compact s"
      using assms apply (simp add: s compact_eq_bounded_closed)
       by (meson bounded_inside bounded_subset compact_imp_bounded)
    then have bst: "bounded (s ∪ t)"
      by (simp add: compact_imp_bounded t)
    then obtain r where "0 < r" and r: "s ∪ t ⊆ ball 0 r"
      using bounded_subset_ballD by blast
    have outst: "outside s ∩ outside t ≠ {}"
    proof -
      have "- ball 0 r ⊆ outside s"
        apply (rule outside_subset_convex)
        using r by auto
      moreover have "- ball 0 r ⊆ outside t"
        apply (rule outside_subset_convex)
        using r by auto
      ultimately show ?thesis
        by (metis Compl_subset_Compl_iff Int_subset_iff bounded_ball inf.orderE outside_bounded_nonempty outside_no_overlap)
    qed
    have "s ∩ t = {}" using assms
      by (metis disjoint_iff_not_equal inside_no_overlap subsetCE)
    moreover have "outside s ∩ inside t ≠ {}"
      by (meson False assms(4) compact_eq_bounded_closed coms open_inside outside_compact_in_open t)
    ultimately have "inside s ∩ t = {}"
      using inside_outside_intersect_connected [OF ‹connected t›, of s]
      by (metis "2" compact_eq_bounded_closed coms connected_outside inf.commute inside_outside_intersect_connected outst)
    then show ?thesis
      using inside_inside [OF ‹s ⊆ inside t›] by blast
  qed
qed

lemma connected_with_inside:
    fixes s :: "'a :: real_normed_vector set"
    assumes s: "closed s" and cons: "connected s"
      shows "connected(s ∪ inside s)"
proof (cases "s ∪ inside s = UNIV")
  case True with assms show ?thesis by auto
next
  case False
  then obtain b where b: "b ∉ s" "b ∉ inside s" by blast
  have *: "∃y t. y ∈ s ∧ connected t ∧ a ∈ t ∧ y ∈ t ∧ t ⊆ (s ∪ inside s)" if "a ∈ (s ∪ inside s)" for a
  using that proof
    assume "a ∈ s" then show ?thesis
      apply (rule_tac x=a in exI)
      apply (rule_tac x="{a}" in exI, simp)
      done
  next
    assume a: "a ∈ inside s"
    show ?thesis
      apply (rule exists_path_subpath_to_frontier [OF path_linepath [of a b], of "inside s"])
      using a apply (simp add: closure_def)
      apply (simp add: b)
      apply (rule_tac x="pathfinish h" in exI)
      apply (rule_tac x="path_image h" in exI)
      apply (simp add: pathfinish_in_path_image connected_path_image, auto)
      using frontier_inside_subset s apply fastforce
      by (metis (no_types, lifting) frontier_inside_subset insertE insert_Diff interior_eq open_inside pathfinish_in_path_image s subsetCE)
  qed
  show ?thesis
    apply (simp add: connected_iff_connected_component)
    apply (simp add: connected_component_def)
    apply (clarify dest!: *)
    apply (rename_tac u u' t t')
    apply (rule_tac x="(s ∪ t ∪ t')" in exI)
    apply (auto simp: intro!: connected_Un cons)
    done
qed

text‹The proof is virtually the same as that above.›
lemma connected_with_outside:
    fixes s :: "'a :: real_normed_vector set"
    assumes s: "closed s" and cons: "connected s"
      shows "connected(s ∪ outside s)"
proof (cases "s ∪ outside s = UNIV")
  case True with assms show ?thesis by auto
next
  case False
  then obtain b where b: "b ∉ s" "b ∉ outside s" by blast
  have *: "∃y t. y ∈ s ∧ connected t ∧ a ∈ t ∧ y ∈ t ∧ t ⊆ (s ∪ outside s)" if "a ∈ (s ∪ outside s)" for a
  using that proof
    assume "a ∈ s" then show ?thesis
      apply (rule_tac x=a in exI)
      apply (rule_tac x="{a}" in exI, simp)
      done
  next
    assume a: "a ∈ outside s"
    show ?thesis
      apply (rule exists_path_subpath_to_frontier [OF path_linepath [of a b], of "outside s"])
      using a apply (simp add: closure_def)
      apply (simp add: b)
      apply (rule_tac x="pathfinish h" in exI)
      apply (rule_tac x="path_image h" in exI)
      apply (simp add: pathfinish_in_path_image connected_path_image, auto)
      using frontier_outside_subset s apply fastforce
      by (metis (no_types, lifting) frontier_outside_subset insertE insert_Diff interior_eq open_outside pathfinish_in_path_image s subsetCE)
  qed
  show ?thesis
    apply (simp add: connected_iff_connected_component)
    apply (simp add: connected_component_def)
    apply (clarify dest!: *)
    apply (rename_tac u u' t t')
    apply (rule_tac x="(s ∪ t ∪ t')" in exI)
    apply (auto simp: intro!: connected_Un cons)
    done
qed

lemma inside_inside_eq_empty [simp]:
    fixes s :: "'a :: {real_normed_vector, perfect_space} set"
    assumes s: "closed s" and cons: "connected s"
      shows "inside (inside s) = {}"
  by (metis (no_types) unbounded_outside connected_with_outside [OF assms] bounded_Un
           inside_complement_unbounded_connected_empty unbounded_outside union_with_outside)

lemma inside_in_components:
     "inside s ∈ components (- s) ⟷ connected(inside s) ∧ inside s ≠ {}"
  apply (simp add: in_components_maximal)
  apply (auto intro: inside_same_component connected_componentI)
  apply (metis IntI empty_iff inside_no_overlap)
  done

text‹The proof is virtually the same as that above.›
lemma outside_in_components:
     "outside s ∈ components (- s) ⟷ connected(outside s) ∧ outside s ≠ {}"
  apply (simp add: in_components_maximal)
  apply (auto intro: outside_same_component connected_componentI)
  apply (metis IntI empty_iff outside_no_overlap)
  done

lemma bounded_unique_outside:
    fixes s :: "'a :: euclidean_space set"
    shows "⟦bounded s; DIM('a) ≥ 2⟧ ⟹ (c ∈ components (- s) ∧ ~bounded c ⟷ c = outside s)"
  apply (rule iffI)
  apply (metis cobounded_unique_unbounded_components connected_outside double_compl outside_bounded_nonempty outside_in_components unbounded_outside)
  by (simp add: connected_outside outside_bounded_nonempty outside_in_components unbounded_outside)

subsection‹Condition for an open map's image to contain a ball›

proposition ball_subset_open_map_image:
  fixes f :: "'a::heine_borel ⇒ 'b :: {real_normed_vector,heine_borel}"
  assumes contf: "continuous_on (closure S) f"
      and oint: "open (f ` interior S)"
      and le_no: "⋀z. z ∈ frontier S ⟹ r ≤ norm(f z - f a)"
      and "bounded S" "a ∈ S" "0 < r"
    shows "ball (f a) r ⊆ f ` S"
proof (cases "f ` S = UNIV")
  case True then show ?thesis by simp
next
  case False
    obtain w where w: "w ∈ frontier (f ` S)"
               and dw_le: "⋀y. y ∈ frontier (f ` S) ⟹ norm (f a - w) ≤ norm (f a - y)"
      apply (rule distance_attains_inf [of "frontier(f ` S)" "f a"])
      using ‹a ∈ S› by (auto simp: frontier_eq_empty dist_norm False)
    then obtain ξ where ξ: "⋀n. ξ n ∈ f ` S" and tendsw: "ξ ⇢ w"
      by (metis Diff_iff frontier_def closure_sequential)
    then have "⋀n. ∃x ∈ S. ξ n = f x" by force
    then obtain z where zs: "⋀n. z n ∈ S" and fz: "⋀n. ξ n = f (z n)"
      by metis
    then obtain y K where y: "y ∈ closure S" and "strict_mono (K :: nat ⇒ nat)" 
                      and Klim: "(z ∘ K) ⇢ y"
      using ‹bounded S›
      apply (simp add: compact_closure [symmetric] compact_def)
      apply (drule_tac x=z in spec)
      using closure_subset apply force
      done
    then have ftendsw: "((λn. f (z n)) ∘ K) ⇢ w"
      by (metis LIMSEQ_subseq_LIMSEQ fun.map_cong0 fz tendsw)
    have zKs: "⋀n. (z ∘ K) n ∈ S" by (simp add: zs)
    have fz: "f ∘ z = ξ"  "(λn. f (z n)) = ξ"
      using fz by auto
    then have "(ξ ∘ K) ⇢ f y"
      by (metis (no_types) Klim zKs y contf comp_assoc continuous_on_closure_sequentially)
    with fz have wy: "w = f y" using fz LIMSEQ_unique ftendsw by auto
    have rle: "r ≤ norm (f y - f a)"
      apply (rule le_no)
      using w wy oint
      by (force simp: imageI image_mono interiorI interior_subset frontier_def y)
    have **: "(~(b ∩ (- S) = {}) ∧ ~(b - (- S) = {}) ⟹ (b ∩ f ≠ {}))
              ⟹ (b ∩ S ≠ {}) ⟹ b ∩ f = {} ⟹
              b ⊆ S" for b f and S :: "'b set"
      by blast
    show ?thesis
      apply (rule **)   (*such a horrible mess*)
      apply (rule connected_Int_frontier [where t = "f`S", OF connected_ball])
      using ‹a ∈ S› ‹0 < r›
      apply (auto simp: disjoint_iff_not_equal  dist_norm)
      by (metis dw_le norm_minus_commute not_less order_trans rle wy)
qed

section‹ Homotopy of maps p,q : X=>Y with property P of all intermediate maps›

text%important‹ We often just want to require that it fixes some subset, but to take in
  the case of a loop homotopy, it's convenient to have a general property P.›

definition%important homotopic_with ::
  "[('a::topological_space ⇒ 'b::topological_space) ⇒ bool, 'a set, 'b set, 'a ⇒ 'b, 'a ⇒ 'b] ⇒ bool"
where
 "homotopic_with P X Y p q ≡
   (∃h:: real × 'a ⇒ 'b.
       continuous_on ({0..1} × X) h ∧
       h ` ({0..1} × X) ⊆ Y ∧
       (∀x. h(0, x) = p x) ∧
       (∀x. h(1, x) = q x) ∧
       (∀t ∈ {0..1}. P(λx. h(t, x))))"


text‹ We often want to just localize the ending function equality or whatever.›
proposition homotopic_with:
  fixes X :: "'a::topological_space set" and Y :: "'b::topological_space set"
  assumes "⋀h k. (⋀x. x ∈ X ⟹ h x = k x) ⟹ (P h ⟷ P k)"
  shows "homotopic_with P X Y p q ⟷
           (∃h :: real × 'a ⇒ 'b.
              continuous_on ({0..1} × X) h ∧
              h ` ({0..1} × X) ⊆ Y ∧
              (∀x ∈ X. h(0,x) = p x) ∧
              (∀x ∈ X. h(1,x) = q x) ∧
              (∀t ∈ {0..1}. P(λx. h(t, x))))"
  unfolding homotopic_with_def
  apply (rule iffI, blast, clarify)
  apply (rule_tac x="λ(u,v). if v ∈ X then h(u,v) else if u = 0 then p v else q v" in exI)
  apply auto
  apply (force elim: continuous_on_eq)
  apply (drule_tac x=t in bspec, force)
  apply (subst assms; simp)
  done

proposition homotopic_with_eq:
   assumes h: "homotopic_with P X Y f g"
       and f': "⋀x. x ∈ X ⟹ f' x = f x"
       and g': "⋀x. x ∈ X ⟹ g' x = g x"
       and P:  "(⋀h k. (⋀x. x ∈ X ⟹ h x = k x) ⟹ (P h ⟷ P k))"
   shows "homotopic_with P X Y f' g'"
  using h unfolding homotopic_with_def
  apply safe
  apply (rule_tac x="λ(u,v). if v ∈ X then h(u,v) else if u = 0 then f' v else g' v" in exI)
  apply (simp add: f' g', safe)
  apply (fastforce intro: continuous_on_eq, fastforce)
  apply (subst P; fastforce)
  done

proposition homotopic_with_equal:
   assumes contf: "continuous_on X f" and fXY: "f ` X ⊆ Y"
       and gf: "⋀x. x ∈ X ⟹ g x = f x"
       and P:  "P f" "P g"
   shows "homotopic_with P X Y f g"
  unfolding homotopic_with_def
  apply (rule_tac x="λ(u,v). if u = 1 then g v else f v" in exI)
  using assms
  apply (intro conjI)
  apply (rule continuous_on_eq [where f = "f ∘ snd"])
  apply (rule continuous_intros | force)+
  apply clarify
  apply (case_tac "t=1"; force)
  done


lemma image_Pair_const: "(λx. (x, c)) ` A = A × {c}"
  by auto

lemma homotopic_constant_maps:
   "homotopic_with (λx. True) s t (λx. a) (λx. b) ⟷ s = {} ∨ path_component t a b"
proof (cases "s = {} ∨ t = {}")
  case True with continuous_on_const show ?thesis
    by (auto simp: homotopic_with path_component_def)
next
  case False
  then obtain c where "c ∈ s" by blast
  show ?thesis
  proof
    assume "homotopic_with (λx. True) s t (λx. a) (λx. b)"
    then obtain h :: "real × 'a ⇒ 'b"
        where conth: "continuous_on ({0..1} × s) h"
          and h: "h ` ({0..1} × s) ⊆ t" "(∀x∈s. h (0, x) = a)" "(∀x∈s. h (1, x) = b)"
      by (auto simp: homotopic_with)
    have "continuous_on {0..1} (h ∘ (λt. (t, c)))"
      apply (rule continuous_intros conth | simp add: image_Pair_const)+
      apply (blast intro:  ‹c ∈ s› continuous_on_subset [OF conth])
      done
    with ‹c ∈ s› h show "s = {} ∨ path_component t a b"
      apply (simp_all add: homotopic_with path_component_def, auto)
      apply (drule_tac x="h ∘ (λt. (t, c))" in spec)
      apply (auto simp: pathstart_def pathfinish_def path_image_def path_def)
      done
  next
    assume "s = {} ∨ path_component t a b"
    with False show "homotopic_with (λx. True) s t (λx. a) (λx. b)"
      apply (clarsimp simp: homotopic_with path_component_def pathstart_def pathfinish_def path_image_def path_def)
      apply (rule_tac x="g ∘ fst" in exI)
      apply (rule conjI continuous_intros | force)+
      done
  qed
qed


subsection%unimportant‹Trivial properties›

lemma homotopic_with_imp_property: "homotopic_with P X Y f g ⟹ P f ∧ P g"
  unfolding homotopic_with_def Ball_def
  apply clarify
  apply (frule_tac x=0 in spec)
  apply (drule_tac x=1 in spec, auto)
  done

lemma continuous_on_o_Pair: "⟦continuous_on (T × X) h; t ∈ T⟧ ⟹ continuous_on X (h ∘ Pair t)"
  by (fast intro: continuous_intros elim!: continuous_on_subset)

lemma homotopic_with_imp_continuous:
    assumes "homotopic_with P X Y f g"
    shows "continuous_on X f ∧ continuous_on X g"
proof -
  obtain h :: "real × 'a ⇒ 'b"
    where conth: "continuous_on ({0..1} × X) h"
      and h: "∀x. h (0, x) = f x" "∀x. h (1, x) = g x"
    using assms by (auto simp: homotopic_with_def)
  have *: "t ∈ {0..1} ⟹ continuous_on X (h ∘ (λx. (t,x)))" for t
    by (rule continuous_intros continuous_on_subset [OF conth] | force)+
  show ?thesis
    using h *[of 0] *[of 1] by auto
qed

proposition homotopic_with_imp_subset1:
     "homotopic_with P X Y f g ⟹ f ` X ⊆ Y"
  by (simp add: homotopic_with_def image_subset_iff) (metis atLeastAtMost_iff order_refl zero_le_one)

proposition homotopic_with_imp_subset2:
     "homotopic_with P X Y f g ⟹ g ` X ⊆ Y"
  by (simp add: homotopic_with_def image_subset_iff) (metis atLeastAtMost_iff order_refl zero_le_one)

proposition homotopic_with_mono:
    assumes hom: "homotopic_with P X Y f g"
        and Q: "⋀h. ⟦continuous_on X h; image h X ⊆ Y ∧ P h⟧ ⟹ Q h"
      shows "homotopic_with Q X Y f g"
  using hom
  apply (simp add: homotopic_with_def)
  apply (erule ex_forward)
  apply (force simp: intro!: Q dest: continuous_on_o_Pair)
  done

proposition homotopic_with_subset_left:
     "⟦homotopic_with P X Y f g; Z ⊆ X⟧ ⟹ homotopic_with P Z Y f g"
  apply (simp add: homotopic_with_def)
  apply (fast elim!: continuous_on_subset ex_forward)
  done

proposition homotopic_with_subset_right:
     "⟦homotopic_with P X Y f g; Y ⊆ Z⟧ ⟹ homotopic_with P X Z f g"
  apply (simp add: homotopic_with_def)
  apply (fast elim!: continuous_on_subset ex_forward)
  done

proposition homotopic_with_compose_continuous_right:
    "⟦homotopic_with (λf. p (f ∘ h)) X Y f g; continuous_on W h; h ` W ⊆ X⟧
     ⟹ homotopic_with p W Y (f ∘ h) (g ∘ h)"
  apply (clarsimp simp add: homotopic_with_def)
  apply (rename_tac k)
  apply (rule_tac x="k ∘ (λy. (fst y, h (snd y)))" in exI)
  apply (rule conjI continuous_intros continuous_on_compose [where f=snd and g=h, unfolded o_def] | simp)+
  apply (erule continuous_on_subset)
  apply (fastforce simp: o_def)+
  done

proposition homotopic_compose_continuous_right:
     "⟦homotopic_with (λf. True) X Y f g; continuous_on W h; h ` W ⊆ X⟧
      ⟹ homotopic_with (λf. True) W Y (f ∘ h) (g ∘ h)"
  using homotopic_with_compose_continuous_right by fastforce

proposition homotopic_with_compose_continuous_left:
     "⟦homotopic_with (λf. p (h ∘ f)) X Y f g; continuous_on Y h; h ` Y ⊆ Z⟧
      ⟹ homotopic_with p X Z (h ∘ f) (h ∘ g)"
  apply (clarsimp simp add: homotopic_with_def)
  apply (rename_tac k)
  apply (rule_tac x="h ∘ k" in exI)
  apply (rule conjI continuous_intros continuous_on_compose [where f=snd and g=h, unfolded o_def] | simp)+
  apply (erule continuous_on_subset)
  apply (fastforce simp: o_def)+
  done

proposition homotopic_compose_continuous_left:
   "⟦homotopic_with (λ_. True) X Y f g;
     continuous_on Y h; h ` Y ⊆ Z⟧
    ⟹ homotopic_with (λf. True) X Z (h ∘ f) (h ∘ g)"
  using homotopic_with_compose_continuous_left by fastforce

proposition homotopic_with_Pair:
   assumes hom: "homotopic_with p s t f g" "homotopic_with p' s' t' f' g'"
       and q: "⋀f g. ⟦p f; p' g⟧ ⟹ q(λ(x,y). (f x, g y))"
     shows "homotopic_with q (s × s') (t × t')
                  (λ(x,y). (f x, f' y)) (λ(x,y). (g x, g' y))"
  using hom
  apply (clarsimp simp add: homotopic_with_def)
  apply (rename_tac k k')
  apply (rule_tac x="λz. ((k ∘ (λx. (fst x, fst (snd x)))) z, (k' ∘ (λx. (fst x, snd (snd x)))) z)" in exI)
  apply (rule conjI continuous_intros | erule continuous_on_subset | clarsimp)+
  apply (auto intro!: q [unfolded case_prod_unfold])
  done

lemma homotopic_on_empty [simp]: "homotopic_with (λx. True) {} t f g"
  by (metis continuous_on_def empty_iff homotopic_with_equal image_subset_iff)


text‹Homotopy with P is an equivalence relation (on continuous functions mapping X into Y that satisfy P,
     though this only affects reflexivity.›


proposition homotopic_with_refl:
   "homotopic_with P X Y f f ⟷ continuous_on X f ∧ image f X ⊆ Y ∧ P f"
  apply (rule iffI)
  using homotopic_with_imp_continuous homotopic_with_imp_property homotopic_with_imp_subset2 apply blast
  apply (simp add: homotopic_with_def)
  apply (rule_tac x="f ∘ snd" in exI)
  apply (rule conjI continuous_intros | force)+
  done

lemma homotopic_with_symD:
  fixes X :: "'a::real_normed_vector set"
    assumes "homotopic_with P X Y f g"
      shows "homotopic_with P X Y g f"
  using assms
  apply (clarsimp simp add: homotopic_with_def)
  apply (rename_tac h)
  apply (rule_tac x="h ∘ (λy. (1 - fst y, snd y))" in exI)
  apply (rule conjI continuous_intros | erule continuous_on_subset | force simp: image_subset_iff)+
  done

proposition homotopic_with_sym:
    fixes X :: "'a::real_normed_vector set"
    shows "homotopic_with P X Y f g ⟷ homotopic_with P X Y g f"
  using homotopic_with_symD by blast

lemma split_01: "{0..1::real} = {0..1/2} ∪ {1/2..1}"
  by force

lemma split_01_prod: "{0..1::real} × X = ({0..1/2} × X) ∪ ({1/2..1} × X)"
  by force

proposition homotopic_with_trans:
    fixes X :: "'a::real_normed_vector set"
    assumes "homotopic_with P X Y f g" and "homotopic_with P X Y g h"
      shows "homotopic_with P X Y f h"
proof -
  have clo1: "closedin (subtopology euclidean ({0..1/2} × X ∪ {1/2..1} × X)) ({0..1/2::real} × X)"
    apply (simp add: closedin_closed split_01_prod [symmetric])
    apply (rule_tac x="{0..1/2} × UNIV" in exI)
    apply (force simp: closed_Times)
    done
  have clo2: "closedin (subtopology euclidean ({0..1/2} × X ∪ {1/2..1} × X)) ({1/2..1::real} × X)"
    apply (simp add: closedin_closed split_01_prod [symmetric])
    apply (rule_tac x="{1/2..1} × UNIV" in exI)
    apply (force simp: closed_Times)
    done
  { fix k1 k2:: "real × 'a ⇒ 'b"
    assume cont: "continuous_on ({0..1} × X) k1" "continuous_on ({0..1} × X) k2"
       and Y: "k1 ` ({0..1} × X) ⊆ Y" "k2 ` ({0..1} × X) ⊆ Y"
       and geq: "∀x. k1 (1, x) = g x" "∀x. k2 (0, x) = g x"
       and k12: "∀x. k1 (0, x) = f x" "∀x. k2 (1, x) = h x"
       and P:   "∀t∈{0..1}. P (λx. k1 (t, x))" "∀t∈{0..1}. P (λx. k2 (t, x))"
    define k where "k y =
      (if fst y ≤ 1 / 2
       then (k1 ∘ (λx. (2 *R fst x, snd x))) y
       else (k2 ∘ (λx. (2 *R fst x -1, snd x))) y)" for y
    have keq: "k1 (2 * u, v) = k2 (2 * u - 1, v)" if "u = 1/2"  for u v
      by (simp add: geq that)
    have "continuous_on ({0..1} × X) k"
      using cont
      apply (simp add: split_01_prod k_def)
      apply (rule clo1 clo2 continuous_on_cases_local continuous_intros | erule continuous_on_subset | simp add: linear image_subset_iff)+
      apply (force simp: keq)
      done
    moreover have "k ` ({0..1} × X) ⊆ Y"
      using Y by (force simp: k_def)
    moreover have "∀x. k (0, x) = f x"
      by (simp add: k_def k12)
    moreover have "(∀x. k (1, x) = h x)"
      by (simp add: k_def k12)
    moreover have "∀t∈{0..1}. P (λx. k (t, x))"
      using P
      apply (clarsimp simp add: k_def)
      apply (case_tac "t ≤ 1/2", auto)
      done
    ultimately have *: "∃k :: real × 'a ⇒ 'b.
                       continuous_on ({0..1} × X) k ∧ k ` ({0..1} × X) ⊆ Y ∧
                       (∀x. k (0, x) = f x) ∧ (∀x. k (1, x) = h x) ∧ (∀t∈{0..1}. P (λx. k (t, x)))"
      by blast
  } note * = this
  show ?thesis
    using assms by (auto intro: * simp add: homotopic_with_def)
qed

proposition homotopic_compose:
      fixes s :: "'a::real_normed_vector set"
      shows "⟦homotopic_with (λx. True) s t f f'; homotopic_with (λx. True) t u g g'⟧
             ⟹ homotopic_with (λx. True) s u (g ∘ f) (g' ∘ f')"
  apply (rule homotopic_with_trans [where g = "g ∘ f'"])
  apply (metis homotopic_compose_continuous_left homotopic_with_imp_continuous homotopic_with_imp_subset1)
  by (metis homotopic_compose_continuous_right homotopic_with_imp_continuous homotopic_with_imp_subset2)


text‹Homotopic triviality implicitly incorporates path-connectedness.›
lemma homotopic_triviality:
  fixes S :: "'a::real_normed_vector set"
  shows  "(∀f g. continuous_on S f ∧ f ` S ⊆ T ∧
                 continuous_on S g ∧ g ` S ⊆ T
                 ⟶ homotopic_with (λx. True) S T f g) ⟷
          (S = {} ∨ path_connected T) ∧
          (∀f. continuous_on S f ∧ f ` S ⊆ T ⟶ (∃c. homotopic_with (λx. True) S T f (λx. c)))"
          (is "?lhs = ?rhs")
proof (cases "S = {} ∨ T = {}")
  case True then show ?thesis by auto
next
  case False show ?thesis
  proof
    assume LHS [rule_format]: ?lhs
    have pab: "path_component T a b" if "a ∈ T" "b ∈ T" for a b
    proof -
      have "homotopic_with (λx. True) S T (λx. a) (λx. b)"
        by (simp add: LHS continuous_on_const image_subset_iff that)
      then show ?thesis
        using False homotopic_constant_maps by blast
    qed
      moreover
    have "∃c. homotopic_with (λx. True) S T f (λx. c)" if "continuous_on S f" "f ` S ⊆ T" for f
      by (metis (full_types) False LHS equals0I homotopic_constant_maps homotopic_with_imp_continuous homotopic_with_imp_subset2 pab that)
    ultimately show ?rhs
      by (simp add: path_connected_component)
  next
    assume RHS: ?rhs
    with False have T: "path_connected T"
      by blast
    show ?lhs
    proof clarify
      fix f g
      assume "continuous_on S f" "f ` S ⊆ T" "continuous_on S g" "g ` S ⊆ T"
      obtain c d where c: "homotopic_with (λx. True) S T f (λx. c)" and d: "homotopic_with (λx. True) S T g (λx. d)"
        using False ‹continuous_on S f› ‹f ` S ⊆ T›  RHS ‹continuous_on S g› ‹g ` S ⊆ T› by blast
      then have "c ∈ T" "d ∈ T"
        using False homotopic_with_imp_subset2 by fastforce+
      with T have "path_component T c d"
        using path_connected_component by blast
      then have "homotopic_with (λx. True) S T (λx. c) (λx. d)"
        by (simp add: homotopic_constant_maps)
      with c d show "homotopic_with (λx. True) S T f g"
        by (meson homotopic_with_symD homotopic_with_trans)
    qed
  qed
qed


subsection‹Homotopy of paths, maintaining the same endpoints›


definition%important homotopic_paths :: "['a set, real ⇒ 'a, real ⇒ 'a::topological_space] ⇒ bool"
  where
     "homotopic_paths s p q ≡
       homotopic_with (λr. pathstart r = pathstart p ∧ pathfinish r = pathfinish p) {0..1} s p q"

lemma homotopic_paths:
   "homotopic_paths s p q ⟷
      (∃h. continuous_on ({0..1} × {0..1}) h ∧
          h ` ({0..1} × {0..1}) ⊆ s ∧
          (∀x ∈ {0..1}. h(0,x) = p x) ∧
          (∀x ∈ {0..1}. h(1,x) = q x) ∧
          (∀t ∈ {0..1::real}. pathstart(h ∘ Pair t) = pathstart p ∧
                        pathfinish(h ∘ Pair t) = pathfinish p))"
  by (auto simp: homotopic_paths_def homotopic_with pathstart_def pathfinish_def)

proposition homotopic_paths_imp_pathstart:
     "homotopic_paths s p q ⟹ pathstart p = pathstart q"
  by (metis (mono_tags, lifting) homotopic_paths_def homotopic_with_imp_property)

proposition homotopic_paths_imp_pathfinish:
     "homotopic_paths s p q ⟹ pathfinish p = pathfinish q"
  by (metis (mono_tags, lifting) homotopic_paths_def homotopic_with_imp_property)

lemma homotopic_paths_imp_path:
     "homotopic_paths s p q ⟹ path p ∧ path q"
  using homotopic_paths_def homotopic_with_imp_continuous path_def by blast

lemma homotopic_paths_imp_subset:
     "homotopic_paths s p q ⟹ path_image p ⊆ s ∧ path_image q ⊆ s"
  by (simp add: homotopic_paths_def homotopic_with_imp_subset1 homotopic_with_imp_subset2 path_image_def)

proposition homotopic_paths_refl [simp]: "homotopic_paths s p p ⟷ path p ∧ path_image p ⊆ s"
by (simp add: homotopic_paths_def homotopic_with_refl path_def path_image_def)

proposition homotopic_paths_sym: "homotopic_paths s p q ⟹ homotopic_paths s q p"
  by (metis (mono_tags) homotopic_paths_def homotopic_paths_imp_pathfinish homotopic_paths_imp_pathstart homotopic_with_symD)

proposition homotopic_paths_sym_eq: "homotopic_paths s p q ⟷ homotopic_paths s q p"
  by (metis homotopic_paths_sym)

proposition homotopic_paths_trans [trans]:
     "⟦homotopic_paths s p q; homotopic_paths s q r⟧ ⟹ homotopic_paths s p r"
  apply (simp add: homotopic_paths_def)
  apply (rule homotopic_with_trans, assumption)
  by (metis (mono_tags, lifting) homotopic_with_imp_property homotopic_with_mono)

proposition homotopic_paths_eq:
     "⟦path p; path_image p ⊆ s; ⋀t. t ∈ {0..1} ⟹ p t = q t⟧ ⟹ homotopic_paths s p q"
  apply (simp add: homotopic_paths_def)
  apply (rule homotopic_with_eq)
  apply (auto simp: path_def homotopic_with_refl pathstart_def pathfinish_def path_image_def elim: continuous_on_eq)
  done

proposition homotopic_paths_reparametrize:
  assumes "path p"
      and pips: "path_image p ⊆ s"
      and contf: "continuous_on {0..1} f"
      and f01:"f ` {0..1} ⊆ {0..1}"
      and [simp]: "f(0) = 0" "f(1) = 1"
      and q: "⋀t. t ∈ {0..1} ⟹ q(t) = p(f t)"
    shows "homotopic_paths s p q"
proof -
  have contp: "continuous_on {0..1} p"
    by (metis ‹path p› path_def)
  then have "continuous_on {0..1} (p ∘ f)"
    using contf continuous_on_compose continuous_on_subset f01 by blast
  then have "path q"
    by (simp add: path_def) (metis q continuous_on_cong)
  have piqs: "path_image q ⊆ s"
    by (metis (no_types, hide_lams) pips f01 image_subset_iff path_image_def q)
  have fb0: "⋀a b. ⟦0 ≤ a; a ≤ 1; 0 ≤ b; b ≤ 1⟧ ⟹ 0 ≤ (1 - a) * f b + a * b"
    using f01 by force
  have fb1: "⟦0 ≤ a; a ≤ 1; 0 ≤ b; b ≤ 1⟧ ⟹ (1 - a) * f b + a * b ≤ 1" for a b
    using f01 [THEN subsetD, of "f b"] by (simp add: convex_bound_le)
  have "homotopic_paths s q p"
  proof (rule homotopic_paths_trans)
    show "homotopic_paths s q (p ∘ f)"
      using q by (force intro: homotopic_paths_eq [OF  ‹path q› piqs])
  next
    show "homotopic_paths s (p ∘ f) p"
      apply (simp add: homotopic_paths_def homotopic_with_def)
      apply (rule_tac x="p ∘ (λy. (1 - (fst y)) *R ((f ∘ snd) y) + (fst y) *R snd y)"  in exI)
      apply (rule conjI contf continuous_intros continuous_on_subset [OF contp] | simp)+
      using pips [unfolded path_image_def]
      apply (auto simp: fb0 fb1 pathstart_def pathfinish_def)
      done
  qed
  then show ?thesis
    by (simp add: homotopic_paths_sym)
qed

lemma homotopic_paths_subset: "⟦homotopic_paths s p q; s ⊆ t⟧ ⟹ homotopic_paths t p q"
  using homotopic_paths_def homotopic_with_subset_right by blast


text‹ A slightly ad-hoc but useful lemma in constructing homotopies.›
lemma homotopic_join_lemma:
  fixes q :: "[real,real] ⇒ 'a::topological_space"
  assumes p: "continuous_on ({0..1} × {0..1}) (λy. p (fst y) (snd y))"
      and q: "continuous_on ({0..1} × {0..1}) (λy. q (fst y) (snd y))"
      and pf: "⋀t. t ∈ {0..1} ⟹ pathfinish(p t) = pathstart(q t)"
    shows "continuous_on ({0..1} × {0..1}) (λy. (p(fst y) +++ q(fst y)) (snd y))"
proof -
  have 1: "(λy. p (fst y) (2 * snd y)) = (λy. p (fst y) (snd y)) ∘ (λy. (fst y, 2 * snd y))"
    by (rule ext) (simp)
  have 2: "(λy. q (fst y) (2 * snd y - 1)) = (λy. q (fst y) (snd y)) ∘ (λy. (fst y, 2 * snd y - 1))"
    by (rule ext) (simp)
  show ?thesis
    apply (simp add: joinpaths_def)
    apply (rule continuous_on_cases_le)
    apply (simp_all only: 1 2)
    apply (rule continuous_intros continuous_on_subset [OF p] continuous_on_subset [OF q] | force)+
    using pf
    apply (auto simp: mult.commute pathstart_def pathfinish_def)
    done
qed

text‹ Congruence properties of homotopy w.r.t. path-combining operations.›

lemma homotopic_paths_reversepath_D:
      assumes "homotopic_paths s p q"
      shows   "homotopic_paths s (reversepath p) (reversepath q)"
  using assms
  apply (simp add: homotopic_paths_def homotopic_with_def, clarify)
  apply (rule_tac x="h ∘ (λx. (fst x, 1 - snd x))" in exI)
  apply (rule conjI continuous_intros)+
  apply (auto simp: reversepath_def pathstart_def pathfinish_def elim!: continuous_on_subset)
  done

proposition homotopic_paths_reversepath:
     "homotopic_paths s (reversepath p) (reversepath q) ⟷ homotopic_paths s p q"
  using homotopic_paths_reversepath_D by force


proposition homotopic_paths_join:
    "⟦homotopic_paths s p p'; homotopic_paths s q q'; pathfinish p = pathstart q⟧ ⟹ homotopic_paths s (p +++ q) (p' +++ q')"
  apply (simp add: homotopic_paths_def homotopic_with_def, clarify)
  apply (rename_tac k1 k2)
  apply (rule_tac x="(λy. ((k1 ∘ Pair (fst y)) +++ (k2 ∘ Pair (fst y))) (snd y))" in exI)
  apply (rule conjI continuous_intros homotopic_join_lemma)+
  apply (auto simp: joinpaths_def pathstart_def pathfinish_def path_image_def)
  done

proposition homotopic_paths_continuous_image:
    "⟦homotopic_paths s f g; continuous_on s h; h ` s ⊆ t⟧ ⟹ homotopic_paths t (h ∘ f) (h ∘ g)"
  unfolding homotopic_paths_def
  apply (rule homotopic_with_compose_continuous_left [of _ _ _ s])
  apply (auto simp: pathstart_def pathfinish_def elim!: homotopic_with_mono)
  done

subsection‹Group properties for homotopy of paths›

text%important‹So taking equivalence classes under homotopy would give the fundamental group›

proposition homotopic_paths_rid:
    "⟦path p; path_image p ⊆ s⟧ ⟹ homotopic_paths s (p +++ linepath (pathfinish p) (pathfinish p)) p"
  apply (subst homotopic_paths_sym)
  apply (rule homotopic_paths_reparametrize [where f = "λt. if  t ≤ 1 / 2 then 2 *R t else 1"])
  apply (simp_all del: le_divide_eq_numeral1)
  apply (subst split_01)
  apply (rule continuous_on_cases continuous_intros | force simp: pathfinish_def joinpaths_def)+
  done

proposition homotopic_paths_lid:
   "⟦path p; path_image p ⊆ s⟧ ⟹ homotopic_paths s (linepath (pathstart p) (pathstart p) +++ p) p"
  using homotopic_paths_rid [of "reversepath p" s]
  by (metis homotopic_paths_reversepath path_image_reversepath path_reversepath pathfinish_linepath
        pathfinish_reversepath reversepath_joinpaths reversepath_linepath)

proposition homotopic_paths_assoc:
   "⟦path p; path_image p ⊆ s; path q; path_image q ⊆ s; path r; path_image r ⊆ s; pathfinish p = pathstart q;
     pathfinish q = pathstart r⟧
    ⟹ homotopic_paths s (p +++ (q +++ r)) ((p +++ q) +++ r)"
  apply (subst homotopic_paths_sym)
  apply (rule homotopic_paths_reparametrize
           [where f = "λt. if  t ≤ 1 / 2 then inverse 2 *R t
                           else if  t ≤ 3 / 4 then t - (1 / 4)
                           else 2 *R t - 1"])
  apply (simp_all del: le_divide_eq_numeral1)
  apply (simp add: subset_path_image_join)
  apply (rule continuous_on_cases_1 continuous_intros)+
  apply (auto simp: joinpaths_def)
  done

proposition homotopic_paths_rinv:
  assumes "path p" "path_image p ⊆ s"
    shows "homotopic_paths s (p +++ reversepath p) (linepath (pathstart p) (pathstart p))"
proof -
  have "continuous_on ({0..1} × {0..1}) (λx. (subpath 0 (fst x) p +++ reversepath (subpath 0 (fst x) p)) (snd x))"
    using assms
    apply (simp add: joinpaths_def subpath_def reversepath_def path_def del: le_divide_eq_numeral1)
    apply (rule continuous_on_cases_le)
    apply (rule_tac [2] continuous_on_compose [of _ _ p, unfolded o_def])
    apply (rule continuous_on_compose [of _ _ p, unfolded o_def])
    apply (auto intro!: continuous_intros simp del: eq_divide_eq_numeral1)
    apply (force elim!: continuous_on_subset simp add: mult_le_one)+
    done
  then show ?thesis
    using assms
    apply (subst homotopic_paths_sym_eq)
    unfolding homotopic_paths_def homotopic_with_def
    apply (rule_tac x="(λy. (subpath 0 (fst y) p +++ reversepath(subpath 0 (fst y) p)) (snd y))" in exI)
    apply (simp add: path_defs joinpaths_def subpath_def reversepath_def)
    apply (force simp: mult_le_one)
    done
qed

proposition homotopic_paths_linv:
  assumes "path p" "path_image p ⊆ s"
    shows "homotopic_paths s (reversepath p +++ p) (linepath (pathfinish p) (pathfinish p))"
  using homotopic_paths_rinv [of "reversepath p" s] assms by simp


subsection