# Theory Sqrt_Script

theory Sqrt_Script
imports Complex_Main Primes
```(*  Title:      HOL/ex/Sqrt_Script.thy
Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
*)

section ‹Square roots of primes are irrational (script version)›

theory Sqrt_Script
imports Complex_Main "HOL-Computational_Algebra.Primes"
begin

text ‹
\medskip Contrast this linear Isabelle/Isar script with Markus
Wenzel's more mathematical version.
›

subsection ‹Preliminaries›

lemma prime_nonzero:  "prime (p::nat) ⟹ p ≠ 0"

lemma prime_dvd_other_side:
"(n::nat) * n = p * (k * k) ⟹ prime p ⟹ p dvd n"
apply (subgoal_tac "p dvd n * n", blast dest: prime_dvd_mult_nat)
apply auto
done

lemma reduction: "prime (p::nat) ⟹
0 < k ⟹ k * k = p * (j * j) ⟹ k < p * j ∧ 0 < j"
apply (rule ccontr)
apply (erule disjE)
apply (frule mult_le_mono, assumption)
apply auto
done

lemma rearrange: "(j::nat) * (p * j) = k * k ⟹ k * k = p * (j * j)"

lemma prime_not_square:
"prime (p::nat) ⟹ (⋀k. 0 < k ⟹ m * m ≠ p * (k * k))"
apply (induct m rule: nat_less_induct)
apply clarify
apply (frule prime_dvd_other_side, assumption)
apply (erule dvdE)
apply (blast dest: rearrange reduction)
done

subsection ‹Main theorem›

text ‹
The square root of any prime number (including ‹2›) is
irrational.
›

theorem prime_sqrt_irrational:
"prime (p::nat) ⟹ x * x = real p ⟹ 0 ≤ x ⟹ x ∉ ℚ"
apply (rule notI)
apply (erule Rats_abs_nat_div_natE)
apply (simp del: of_nat_mult
add: abs_if divide_eq_eq prime_not_square of_nat_mult [symmetric])
done

lemmas two_sqrt_irrational =
prime_sqrt_irrational [OF two_is_prime_nat]

end
```