Theory Series

theory Series
imports Limits Inequalities
(*  Title       : Series.thy
    Author      : Jacques D. Fleuriot
    Copyright   : 1998  University of Cambridge

Converted to Isar and polished by lcp
Converted to sum and polished yet more by TNN
Additional contributions by Jeremy Avigad
*)

section ‹Infinite Series›

theory Series
imports Limits Inequalities
begin

subsection ‹Definition of infinite summability›

definition sums :: "(nat ⇒ 'a::{topological_space, comm_monoid_add}) ⇒ 'a ⇒ bool"
    (infixr "sums" 80)
  where "f sums s ⟷ (λn. ∑i<n. f i) ⇢ s"

definition summable :: "(nat ⇒ 'a::{topological_space, comm_monoid_add}) ⇒ bool"
  where "summable f ⟷ (∃s. f sums s)"

definition suminf :: "(nat ⇒ 'a::{topological_space, comm_monoid_add}) ⇒ 'a"
    (binder "∑" 10)
  where "suminf f = (THE s. f sums s)"

text‹Variants of the definition›
lemma sums_def': "f sums s ⟷ (λn. ∑i = 0..n. f i) ⇢ s"
  apply (simp add: sums_def)
  apply (subst LIMSEQ_Suc_iff [symmetric])
  apply (simp only: lessThan_Suc_atMost atLeast0AtMost)
  done

lemma sums_def_le: "f sums s ⟷ (λn. ∑i≤n. f i) ⇢ s"
  by (simp add: sums_def' atMost_atLeast0)


subsection ‹Infinite summability on topological monoids›

lemma sums_subst[trans]: "f = g ⟹ g sums z ⟹ f sums z"
  by simp

lemma sums_cong: "(⋀n. f n = g n) ⟹ f sums c ⟷ g sums c"
  by (drule ext) simp

lemma sums_summable: "f sums l ⟹ summable f"
  by (simp add: sums_def summable_def, blast)

lemma summable_iff_convergent: "summable f ⟷ convergent (λn. ∑i<n. f i)"
  by (simp add: summable_def sums_def convergent_def)

lemma summable_iff_convergent': "summable f ⟷ convergent (λn. sum f {..n})"
  by (simp_all only: summable_iff_convergent convergent_def
        lessThan_Suc_atMost [symmetric] LIMSEQ_Suc_iff[of "λn. sum f {..<n}"])

lemma suminf_eq_lim: "suminf f = lim (λn. ∑i<n. f i)"
  by (simp add: suminf_def sums_def lim_def)

lemma sums_zero[simp, intro]: "(λn. 0) sums 0"
  unfolding sums_def by simp

lemma summable_zero[simp, intro]: "summable (λn. 0)"
  by (rule sums_zero [THEN sums_summable])

lemma sums_group: "f sums s ⟹ 0 < k ⟹ (λn. sum f {n * k ..< n * k + k}) sums s"
  apply (simp only: sums_def sum_nat_group tendsto_def eventually_sequentially)
  apply safe
  apply (erule_tac x=S in allE)
  apply safe
  apply (rule_tac x="N" in exI, safe)
  apply (drule_tac x="n*k" in spec)
  apply (erule mp)
  apply (erule order_trans)
  apply simp
  done

lemma suminf_cong: "(⋀n. f n = g n) ⟹ suminf f = suminf g"
  by (rule arg_cong[of f g], rule ext) simp

lemma summable_cong:
  fixes f g :: "nat ⇒ 'a::real_normed_vector"
  assumes "eventually (λx. f x = g x) sequentially"
  shows "summable f = summable g"
proof -
  from assms obtain N where N: "∀n≥N. f n = g n"
    by (auto simp: eventually_at_top_linorder)
  define C where "C = (∑k<N. f k - g k)"
  from eventually_ge_at_top[of N]
  have "eventually (λn. sum f {..<n} = C + sum g {..<n}) sequentially"
  proof eventually_elim
    case (elim n)
    then have "{..<n} = {..<N} ∪ {N..<n}"
      by auto
    also have "sum f ... = sum f {..<N} + sum f {N..<n}"
      by (intro sum.union_disjoint) auto
    also from N have "sum f {N..<n} = sum g {N..<n}"
      by (intro sum.cong) simp_all
    also have "sum f {..<N} + sum g {N..<n} = C + (sum g {..<N} + sum g {N..<n})"
      unfolding C_def by (simp add: algebra_simps sum_subtractf)
    also have "sum g {..<N} + sum g {N..<n} = sum g ({..<N} ∪ {N..<n})"
      by (intro sum.union_disjoint [symmetric]) auto
    also from elim have "{..<N} ∪ {N..<n} = {..<n}"
      by auto
    finally show "sum f {..<n} = C + sum g {..<n}" .
  qed
  from convergent_cong[OF this] show ?thesis
    by (simp add: summable_iff_convergent convergent_add_const_iff)
qed

lemma sums_finite:
  assumes [simp]: "finite N"
    and f: "⋀n. n ∉ N ⟹ f n = 0"
  shows "f sums (∑n∈N. f n)"
proof -
  have eq: "sum f {..<n + Suc (Max N)} = sum f N" for n
  proof (cases "N = {}")
    case True
    with f have "f = (λx. 0)" by auto
    then show ?thesis by simp
  next
    case [simp]: False
    show ?thesis
    proof (safe intro!: sum.mono_neutral_right f)
      fix i
      assume "i ∈ N"
      then have "i ≤ Max N" by simp
      then show "i < n + Suc (Max N)" by simp
    qed
  qed
  show ?thesis
    unfolding sums_def
    by (rule LIMSEQ_offset[of _ "Suc (Max N)"])
       (simp add: eq atLeast0LessThan del: add_Suc_right)
qed

corollary sums_0: "(⋀n. f n = 0) ⟹ (f sums 0)"
    by (metis (no_types) finite.emptyI sum.empty sums_finite)

lemma summable_finite: "finite N ⟹ (⋀n. n ∉ N ⟹ f n = 0) ⟹ summable f"
  by (rule sums_summable) (rule sums_finite)

lemma sums_If_finite_set: "finite A ⟹ (λr. if r ∈ A then f r else 0) sums (∑r∈A. f r)"
  using sums_finite[of A "(λr. if r ∈ A then f r else 0)"] by simp

lemma summable_If_finite_set[simp, intro]: "finite A ⟹ summable (λr. if r ∈ A then f r else 0)"
  by (rule sums_summable) (rule sums_If_finite_set)

lemma sums_If_finite: "finite {r. P r} ⟹ (λr. if P r then f r else 0) sums (∑r | P r. f r)"
  using sums_If_finite_set[of "{r. P r}"] by simp

lemma summable_If_finite[simp, intro]: "finite {r. P r} ⟹ summable (λr. if P r then f r else 0)"
  by (rule sums_summable) (rule sums_If_finite)

lemma sums_single: "(λr. if r = i then f r else 0) sums f i"
  using sums_If_finite[of "λr. r = i"] by simp

lemma summable_single[simp, intro]: "summable (λr. if r = i then f r else 0)"
  by (rule sums_summable) (rule sums_single)

context
  fixes f :: "nat ⇒ 'a::{t2_space,comm_monoid_add}"
begin

lemma summable_sums[intro]: "summable f ⟹ f sums (suminf f)"
  by (simp add: summable_def sums_def suminf_def)
     (metis convergent_LIMSEQ_iff convergent_def lim_def)

lemma summable_LIMSEQ: "summable f ⟹ (λn. ∑i<n. f i) ⇢ suminf f"
  by (rule summable_sums [unfolded sums_def])

lemma sums_unique: "f sums s ⟹ s = suminf f"
  by (metis limI suminf_eq_lim sums_def)

lemma sums_iff: "f sums x ⟷ summable f ∧ suminf f = x"
  by (metis summable_sums sums_summable sums_unique)

lemma summable_sums_iff: "summable f ⟷ f sums suminf f"
  by (auto simp: sums_iff summable_sums)

lemma sums_unique2: "f sums a ⟹ f sums b ⟹ a = b"
  for a b :: 'a
  by (simp add: sums_iff)

lemma suminf_finite:
  assumes N: "finite N"
    and f: "⋀n. n ∉ N ⟹ f n = 0"
  shows "suminf f = (∑n∈N. f n)"
  using sums_finite[OF assms, THEN sums_unique] by simp

end

lemma suminf_zero[simp]: "suminf (λn. 0::'a::{t2_space, comm_monoid_add}) = 0"
  by (rule sums_zero [THEN sums_unique, symmetric])


subsection ‹Infinite summability on ordered, topological monoids›

lemma sums_le: "∀n. f n ≤ g n ⟹ f sums s ⟹ g sums t ⟹ s ≤ t"
  for f g :: "nat ⇒ 'a::{ordered_comm_monoid_add,linorder_topology}"
  by (rule LIMSEQ_le) (auto intro: sum_mono simp: sums_def)

context
  fixes f :: "nat ⇒ 'a::{ordered_comm_monoid_add,linorder_topology}"
begin

lemma suminf_le: "∀n. f n ≤ g n ⟹ summable f ⟹ summable g ⟹ suminf f ≤ suminf g"
  by (auto dest: sums_summable intro: sums_le)

lemma sum_le_suminf: "summable f ⟹ ∀m≥n. 0 ≤ f m ⟹ sum f {..<n} ≤ suminf f"
  by (rule sums_le[OF _ sums_If_finite_set summable_sums]) auto

lemma suminf_nonneg: "summable f ⟹ ∀n. 0 ≤ f n ⟹ 0 ≤ suminf f"
  using sum_le_suminf[of 0] by simp

lemma suminf_le_const: "summable f ⟹ (⋀n. sum f {..<n} ≤ x) ⟹ suminf f ≤ x"
  by (metis LIMSEQ_le_const2 summable_LIMSEQ)

lemma suminf_eq_zero_iff: "summable f ⟹ ∀n. 0 ≤ f n ⟹ suminf f = 0 ⟷ (∀n. f n = 0)"
proof
  assume "summable f" "suminf f = 0" and pos: "∀n. 0 ≤ f n"
  then have f: "(λn. ∑i<n. f i) ⇢ 0"
    using summable_LIMSEQ[of f] by simp
  then have "⋀i. (∑n∈{i}. f n) ≤ 0"
  proof (rule LIMSEQ_le_const)
    show "∃N. ∀n≥N. (∑n∈{i}. f n) ≤ sum f {..<n}" for i
      using pos by (intro exI[of _ "Suc i"] allI impI sum_mono2) auto
  qed
  with pos show "∀n. f n = 0"
    by (auto intro!: antisym)
qed (metis suminf_zero fun_eq_iff)

lemma suminf_pos_iff: "summable f ⟹ ∀n. 0 ≤ f n ⟹ 0 < suminf f ⟷ (∃i. 0 < f i)"
  using sum_le_suminf[of 0] suminf_eq_zero_iff by (simp add: less_le)

lemma suminf_pos2:
  assumes "summable f" "∀n. 0 ≤ f n" "0 < f i"
  shows "0 < suminf f"
proof -
  have "0 < (∑n<Suc i. f n)"
    using assms by (intro sum_pos2[where i=i]) auto
  also have "… ≤ suminf f"
    using assms by (intro sum_le_suminf) auto
  finally show ?thesis .
qed

lemma suminf_pos: "summable f ⟹ ∀n. 0 < f n ⟹ 0 < suminf f"
  by (intro suminf_pos2[where i=0]) (auto intro: less_imp_le)

end

context
  fixes f :: "nat ⇒ 'a::{ordered_cancel_comm_monoid_add,linorder_topology}"
begin

lemma sum_less_suminf2:
  "summable f ⟹ ∀m≥n. 0 ≤ f m ⟹ n ≤ i ⟹ 0 < f i ⟹ sum f {..<n} < suminf f"
  using sum_le_suminf[of f "Suc i"]
    and add_strict_increasing[of "f i" "sum f {..<n}" "sum f {..<i}"]
    and sum_mono2[of "{..<i}" "{..<n}" f]
  by (auto simp: less_imp_le ac_simps)

lemma sum_less_suminf: "summable f ⟹ ∀m≥n. 0 < f m ⟹ sum f {..<n} < suminf f"
  using sum_less_suminf2[of n n] by (simp add: less_imp_le)

end

lemma summableI_nonneg_bounded:
  fixes f :: "nat ⇒ 'a::{ordered_comm_monoid_add,linorder_topology,conditionally_complete_linorder}"
  assumes pos[simp]: "⋀n. 0 ≤ f n"
    and le: "⋀n. (∑i<n. f i) ≤ x"
  shows "summable f"
  unfolding summable_def sums_def [abs_def]
proof (rule exI LIMSEQ_incseq_SUP)+
  show "bdd_above (range (λn. sum f {..<n}))"
    using le by (auto simp: bdd_above_def)
  show "incseq (λn. sum f {..<n})"
    by (auto simp: mono_def intro!: sum_mono2)
qed

lemma summableI[intro, simp]: "summable f"
  for f :: "nat ⇒ 'a::{canonically_ordered_monoid_add,linorder_topology,complete_linorder}"
  by (intro summableI_nonneg_bounded[where x=top] zero_le top_greatest)


subsection ‹Infinite summability on topological monoids›

context
  fixes f g :: "nat ⇒ 'a::{t2_space,topological_comm_monoid_add}"
begin

lemma sums_Suc:
  assumes "(λn. f (Suc n)) sums l"
  shows "f sums (l + f 0)"
proof  -
  have "(λn. (∑i<n. f (Suc i)) + f 0) ⇢ l + f 0"
    using assms by (auto intro!: tendsto_add simp: sums_def)
  moreover have "(∑i<n. f (Suc i)) + f 0 = (∑i<Suc n. f i)" for n
    unfolding lessThan_Suc_eq_insert_0
    by (simp add: ac_simps sum_atLeast1_atMost_eq image_Suc_lessThan)
  ultimately show ?thesis
    by (auto simp: sums_def simp del: sum_lessThan_Suc intro: LIMSEQ_Suc_iff[THEN iffD1])
qed

lemma sums_add: "f sums a ⟹ g sums b ⟹ (λn. f n + g n) sums (a + b)"
  unfolding sums_def by (simp add: sum.distrib tendsto_add)

lemma summable_add: "summable f ⟹ summable g ⟹ summable (λn. f n + g n)"
  unfolding summable_def by (auto intro: sums_add)

lemma suminf_add: "summable f ⟹ summable g ⟹ suminf f + suminf g = (∑n. f n + g n)"
  by (intro sums_unique sums_add summable_sums)

end

context
  fixes f :: "'i ⇒ nat ⇒ 'a::{t2_space,topological_comm_monoid_add}"
    and I :: "'i set"
begin

lemma sums_sum: "(⋀i. i ∈ I ⟹ (f i) sums (x i)) ⟹ (λn. ∑i∈I. f i n) sums (∑i∈I. x i)"
  by (induct I rule: infinite_finite_induct) (auto intro!: sums_add)

lemma suminf_sum: "(⋀i. i ∈ I ⟹ summable (f i)) ⟹ (∑n. ∑i∈I. f i n) = (∑i∈I. ∑n. f i n)"
  using sums_unique[OF sums_sum, OF summable_sums] by simp

lemma summable_sum: "(⋀i. i ∈ I ⟹ summable (f i)) ⟹ summable (λn. ∑i∈I. f i n)"
  using sums_summable[OF sums_sum[OF summable_sums]] .

end

subsection ‹Infinite summability on real normed vector spaces›

context
  fixes f :: "nat ⇒ 'a::real_normed_vector"
begin

lemma sums_Suc_iff: "(λn. f (Suc n)) sums s ⟷ f sums (s + f 0)"
proof -
  have "f sums (s + f 0) ⟷ (λi. ∑j<Suc i. f j) ⇢ s + f 0"
    by (subst LIMSEQ_Suc_iff) (simp add: sums_def)
  also have "… ⟷ (λi. (∑j<i. f (Suc j)) + f 0) ⇢ s + f 0"
    by (simp add: ac_simps lessThan_Suc_eq_insert_0 image_Suc_lessThan sum_atLeast1_atMost_eq)
  also have "… ⟷ (λn. f (Suc n)) sums s"
  proof
    assume "(λi. (∑j<i. f (Suc j)) + f 0) ⇢ s + f 0"
    with tendsto_add[OF this tendsto_const, of "- f 0"] show "(λi. f (Suc i)) sums s"
      by (simp add: sums_def)
  qed (auto intro: tendsto_add simp: sums_def)
  finally show ?thesis ..
qed

lemma summable_Suc_iff: "summable (λn. f (Suc n)) = summable f"
proof
  assume "summable f"
  then have "f sums suminf f"
    by (rule summable_sums)
  then have "(λn. f (Suc n)) sums (suminf f - f 0)"
    by (simp add: sums_Suc_iff)
  then show "summable (λn. f (Suc n))"
    unfolding summable_def by blast
qed (auto simp: sums_Suc_iff summable_def)

lemma sums_Suc_imp: "f 0 = 0 ⟹ (λn. f (Suc n)) sums s ⟹ (λn. f n) sums s"
  using sums_Suc_iff by simp

end

context (* Separate contexts are necessary to allow general use of the results above, here. *)
  fixes f :: "nat ⇒ 'a::real_normed_vector"
begin

lemma sums_diff: "f sums a ⟹ g sums b ⟹ (λn. f n - g n) sums (a - b)"
  unfolding sums_def by (simp add: sum_subtractf tendsto_diff)

lemma summable_diff: "summable f ⟹ summable g ⟹ summable (λn. f n - g n)"
  unfolding summable_def by (auto intro: sums_diff)

lemma suminf_diff: "summable f ⟹ summable g ⟹ suminf f - suminf g = (∑n. f n - g n)"
  by (intro sums_unique sums_diff summable_sums)

lemma sums_minus: "f sums a ⟹ (λn. - f n) sums (- a)"
  unfolding sums_def by (simp add: sum_negf tendsto_minus)

lemma summable_minus: "summable f ⟹ summable (λn. - f n)"
  unfolding summable_def by (auto intro: sums_minus)

lemma suminf_minus: "summable f ⟹ (∑n. - f n) = - (∑n. f n)"
  by (intro sums_unique [symmetric] sums_minus summable_sums)

lemma sums_iff_shift: "(λi. f (i + n)) sums s ⟷ f sums (s + (∑i<n. f i))"
proof (induct n arbitrary: s)
  case 0
  then show ?case by simp
next
  case (Suc n)
  then have "(λi. f (Suc i + n)) sums s ⟷ (λi. f (i + n)) sums (s + f n)"
    by (subst sums_Suc_iff) simp
  with Suc show ?case
    by (simp add: ac_simps)
qed

corollary sums_iff_shift': "(λi. f (i + n)) sums (s - (∑i<n. f i)) ⟷ f sums s"
  by (simp add: sums_iff_shift)

lemma sums_zero_iff_shift:
  assumes "⋀i. i < n ⟹ f i = 0"
  shows "(λi. f (i+n)) sums s ⟷ (λi. f i) sums s"
  by (simp add: assms sums_iff_shift)

lemma summable_iff_shift: "summable (λn. f (n + k)) ⟷ summable f"
  by (metis diff_add_cancel summable_def sums_iff_shift [abs_def])

lemma sums_split_initial_segment: "f sums s ⟹ (λi. f (i + n)) sums (s - (∑i<n. f i))"
  by (simp add: sums_iff_shift)

lemma summable_ignore_initial_segment: "summable f ⟹ summable (λn. f(n + k))"
  by (simp add: summable_iff_shift)

lemma suminf_minus_initial_segment: "summable f ⟹ (∑n. f (n + k)) = (∑n. f n) - (∑i<k. f i)"
  by (rule sums_unique[symmetric]) (auto simp: sums_iff_shift)

lemma suminf_split_initial_segment: "summable f ⟹ suminf f = (∑n. f(n + k)) + (∑i<k. f i)"
  by (auto simp add: suminf_minus_initial_segment)

lemma suminf_split_head: "summable f ⟹ (∑n. f (Suc n)) = suminf f - f 0"
  using suminf_split_initial_segment[of 1] by simp

lemma suminf_exist_split:
  fixes r :: real
  assumes "0 < r" and "summable f"
  shows "∃N. ∀n≥N. norm (∑i. f (i + n)) < r"
proof -
  from LIMSEQ_D[OF summable_LIMSEQ[OF ‹summable f›] ‹0 < r›]
  obtain N :: nat where "∀ n ≥ N. norm (sum f {..<n} - suminf f) < r"
    by auto
  then show ?thesis
    by (auto simp: norm_minus_commute suminf_minus_initial_segment[OF ‹summable f›])
qed

lemma summable_LIMSEQ_zero: "summable f ⟹ f ⇢ 0"
  apply (drule summable_iff_convergent [THEN iffD1])
  apply (drule convergent_Cauchy)
  apply (simp only: Cauchy_iff LIMSEQ_iff)
  apply safe
  apply (drule_tac x="r" in spec)
  apply safe
  apply (rule_tac x="M" in exI)
  apply safe
  apply (drule_tac x="Suc n" in spec)
  apply simp
  apply (drule_tac x="n" in spec)
  apply simp
  done

lemma summable_imp_convergent: "summable f ⟹ convergent f"
  by (force dest!: summable_LIMSEQ_zero simp: convergent_def)

lemma summable_imp_Bseq: "summable f ⟹ Bseq f"
  by (simp add: convergent_imp_Bseq summable_imp_convergent)

end

lemma summable_minus_iff: "summable (λn. - f n) ⟷ summable f"
  for f :: "nat ⇒ 'a::real_normed_vector"
  by (auto dest: summable_minus)  (* used two ways, hence must be outside the context above *)

lemma (in bounded_linear) sums: "(λn. X n) sums a ⟹ (λn. f (X n)) sums (f a)"
  unfolding sums_def by (drule tendsto) (simp only: sum)

lemma (in bounded_linear) summable: "summable (λn. X n) ⟹ summable (λn. f (X n))"
  unfolding summable_def by (auto intro: sums)

lemma (in bounded_linear) suminf: "summable (λn. X n) ⟹ f (∑n. X n) = (∑n. f (X n))"
  by (intro sums_unique sums summable_sums)

lemmas sums_of_real = bounded_linear.sums [OF bounded_linear_of_real]
lemmas summable_of_real = bounded_linear.summable [OF bounded_linear_of_real]
lemmas suminf_of_real = bounded_linear.suminf [OF bounded_linear_of_real]

lemmas sums_scaleR_left = bounded_linear.sums[OF bounded_linear_scaleR_left]
lemmas summable_scaleR_left = bounded_linear.summable[OF bounded_linear_scaleR_left]
lemmas suminf_scaleR_left = bounded_linear.suminf[OF bounded_linear_scaleR_left]

lemmas sums_scaleR_right = bounded_linear.sums[OF bounded_linear_scaleR_right]
lemmas summable_scaleR_right = bounded_linear.summable[OF bounded_linear_scaleR_right]
lemmas suminf_scaleR_right = bounded_linear.suminf[OF bounded_linear_scaleR_right]

lemma summable_const_iff: "summable (λ_. c) ⟷ c = 0"
  for c :: "'a::real_normed_vector"
proof -
  have "¬ summable (λ_. c)" if "c ≠ 0"
  proof -
    from that have "filterlim (λn. of_nat n * norm c) at_top sequentially"
      by (subst mult.commute)
        (auto intro!: filterlim_tendsto_pos_mult_at_top filterlim_real_sequentially)
    then have "¬ convergent (λn. norm (∑k<n. c))"
      by (intro filterlim_at_infinity_imp_not_convergent filterlim_at_top_imp_at_infinity)
        (simp_all add: sum_constant_scaleR)
    then show ?thesis
      unfolding summable_iff_convergent using convergent_norm by blast
  qed
  then show ?thesis by auto
qed


subsection ‹Infinite summability on real normed algebras›

context
  fixes f :: "nat ⇒ 'a::real_normed_algebra"
begin

lemma sums_mult: "f sums a ⟹ (λn. c * f n) sums (c * a)"
  by (rule bounded_linear.sums [OF bounded_linear_mult_right])

lemma summable_mult: "summable f ⟹ summable (λn. c * f n)"
  by (rule bounded_linear.summable [OF bounded_linear_mult_right])

lemma suminf_mult: "summable f ⟹ suminf (λn. c * f n) = c * suminf f"
  by (rule bounded_linear.suminf [OF bounded_linear_mult_right, symmetric])

lemma sums_mult2: "f sums a ⟹ (λn. f n * c) sums (a * c)"
  by (rule bounded_linear.sums [OF bounded_linear_mult_left])

lemma summable_mult2: "summable f ⟹ summable (λn. f n * c)"
  by (rule bounded_linear.summable [OF bounded_linear_mult_left])

lemma suminf_mult2: "summable f ⟹ suminf f * c = (∑n. f n * c)"
  by (rule bounded_linear.suminf [OF bounded_linear_mult_left])

end

lemma sums_mult_iff:
  fixes f :: "nat ⇒ 'a::{real_normed_algebra,field}"
  assumes "c ≠ 0"
  shows "(λn. c * f n) sums (c * d) ⟷ f sums d"
  using sums_mult[of f d c] sums_mult[of "λn. c * f n" "c * d" "inverse c"]
  by (force simp: field_simps assms)

lemma sums_mult2_iff:
  fixes f :: "nat ⇒ 'a::{real_normed_algebra,field}"
  assumes "c ≠ 0"
  shows   "(λn. f n * c) sums (d * c) ⟷ f sums d"
  using sums_mult_iff[OF assms, of f d] by (simp add: mult.commute)

lemma sums_of_real_iff:
  "(λn. of_real (f n) :: 'a::real_normed_div_algebra) sums of_real c ⟷ f sums c"
  by (simp add: sums_def of_real_sum[symmetric] tendsto_of_real_iff del: of_real_sum)


subsection ‹Infinite summability on real normed fields›

context
  fixes c :: "'a::real_normed_field"
begin

lemma sums_divide: "f sums a ⟹ (λn. f n / c) sums (a / c)"
  by (rule bounded_linear.sums [OF bounded_linear_divide])

lemma summable_divide: "summable f ⟹ summable (λn. f n / c)"
  by (rule bounded_linear.summable [OF bounded_linear_divide])

lemma suminf_divide: "summable f ⟹ suminf (λn. f n / c) = suminf f / c"
  by (rule bounded_linear.suminf [OF bounded_linear_divide, symmetric])

lemma sums_mult_D: "(λn. c * f n) sums a ⟹ c ≠ 0 ⟹ f sums (a/c)"
  using sums_mult_iff by fastforce

lemma summable_mult_D: "summable (λn. c * f n) ⟹ c ≠ 0 ⟹ summable f"
  by (auto dest: summable_divide)


text ‹Sum of a geometric progression.›

lemma geometric_sums:
  assumes less_1: "norm c < 1"
  shows "(λn. c^n) sums (1 / (1 - c))"
proof -
  from less_1 have neq_1: "c ≠ 1" by auto
  then have neq_0: "c - 1 ≠ 0" by simp
  from less_1 have lim_0: "(λn. c^n) ⇢ 0"
    by (rule LIMSEQ_power_zero)
  then have "(λn. c ^ n / (c - 1) - 1 / (c - 1)) ⇢ 0 / (c - 1) - 1 / (c - 1)"
    using neq_0 by (intro tendsto_intros)
  then have "(λn. (c ^ n - 1) / (c - 1)) ⇢ 1 / (1 - c)"
    by (simp add: nonzero_minus_divide_right [OF neq_0] diff_divide_distrib)
  then show "(λn. c ^ n) sums (1 / (1 - c))"
    by (simp add: sums_def geometric_sum neq_1)
qed

lemma summable_geometric: "norm c < 1 ⟹ summable (λn. c^n)"
  by (rule geometric_sums [THEN sums_summable])

lemma suminf_geometric: "norm c < 1 ⟹ suminf (λn. c^n) = 1 / (1 - c)"
  by (rule sums_unique[symmetric]) (rule geometric_sums)

lemma summable_geometric_iff: "summable (λn. c ^ n) ⟷ norm c < 1"
proof
  assume "summable (λn. c ^ n :: 'a :: real_normed_field)"
  then have "(λn. norm c ^ n) ⇢ 0"
    by (simp add: norm_power [symmetric] tendsto_norm_zero_iff summable_LIMSEQ_zero)
  from order_tendstoD(2)[OF this zero_less_one] obtain n where "norm c ^ n < 1"
    by (auto simp: eventually_at_top_linorder)
  then show "norm c < 1" using one_le_power[of "norm c" n]
    by (cases "norm c ≥ 1") (linarith, simp)
qed (rule summable_geometric)

end

lemma power_half_series: "(λn. (1/2::real)^Suc n) sums 1"
proof -
  have 2: "(λn. (1/2::real)^n) sums 2"
    using geometric_sums [of "1/2::real"] by auto
  have "(λn. (1/2::real)^Suc n) = (λn. (1 / 2) ^ n / 2)"
    by (simp add: mult.commute)
  then show ?thesis
    using sums_divide [OF 2, of 2] by simp
qed


subsection ‹Telescoping›

lemma telescope_sums:
  fixes c :: "'a::real_normed_vector"
  assumes "f ⇢ c"
  shows "(λn. f (Suc n) - f n) sums (c - f 0)"
  unfolding sums_def
proof (subst LIMSEQ_Suc_iff [symmetric])
  have "(λn. ∑k<Suc n. f (Suc k) - f k) = (λn. f (Suc n) - f 0)"
    by (simp add: lessThan_Suc_atMost atLeast0AtMost [symmetric] sum_Suc_diff)
  also have "… ⇢ c - f 0"
    by (intro tendsto_diff LIMSEQ_Suc[OF assms] tendsto_const)
  finally show "(λn. ∑n<Suc n. f (Suc n) - f n) ⇢ c - f 0" .
qed

lemma telescope_sums':
  fixes c :: "'a::real_normed_vector"
  assumes "f ⇢ c"
  shows "(λn. f n - f (Suc n)) sums (f 0 - c)"
  using sums_minus[OF telescope_sums[OF assms]] by (simp add: algebra_simps)

lemma telescope_summable:
  fixes c :: "'a::real_normed_vector"
  assumes "f ⇢ c"
  shows "summable (λn. f (Suc n) - f n)"
  using telescope_sums[OF assms] by (simp add: sums_iff)

lemma telescope_summable':
  fixes c :: "'a::real_normed_vector"
  assumes "f ⇢ c"
  shows "summable (λn. f n - f (Suc n))"
  using summable_minus[OF telescope_summable[OF assms]] by (simp add: algebra_simps)


subsection ‹Infinite summability on Banach spaces›

text ‹Cauchy-type criterion for convergence of series (c.f. Harrison).›

lemma summable_Cauchy: "summable f ⟷ (∀e>0. ∃N. ∀m≥N. ∀n. norm (sum f {m..<n}) < e)"
  for f :: "nat ⇒ 'a::banach"
  apply (simp only: summable_iff_convergent Cauchy_convergent_iff [symmetric] Cauchy_iff)
  apply safe
   apply (drule spec)
   apply (drule (1) mp)
   apply (erule exE)
   apply (rule_tac x="M" in exI)
   apply clarify
   apply (rule_tac x="m" and y="n" in linorder_le_cases)
    apply (frule (1) order_trans)
    apply (drule_tac x="n" in spec)
    apply (drule (1) mp)
    apply (drule_tac x="m" in spec)
    apply (drule (1) mp)
    apply (simp_all add: sum_diff [symmetric])
  apply (drule spec)
  apply (drule (1) mp)
  apply (erule exE)
  apply (rule_tac x="N" in exI)
  apply clarify
  apply (rule_tac x="m" and y="n" in linorder_le_cases)
   apply (subst norm_minus_commute)
   apply (simp_all add: sum_diff [symmetric])
  done

context
  fixes f :: "nat ⇒ 'a::banach"
begin

text ‹Absolute convergence imples normal convergence.›

lemma summable_norm_cancel: "summable (λn. norm (f n)) ⟹ summable f"
  apply (simp only: summable_Cauchy)
  apply safe
  apply (drule_tac x="e" in spec)
  apply safe
  apply (rule_tac x="N" in exI)
  apply safe
  apply (drule_tac x="m" in spec)
  apply safe
  apply (rule order_le_less_trans [OF norm_sum])
  apply (rule order_le_less_trans [OF abs_ge_self])
  apply simp
  done

lemma summable_norm: "summable (λn. norm (f n)) ⟹ norm (suminf f) ≤ (∑n. norm (f n))"
  by (auto intro: LIMSEQ_le tendsto_norm summable_norm_cancel summable_LIMSEQ norm_sum)

text ‹Comparison tests.›

lemma summable_comparison_test: "∃N. ∀n≥N. norm (f n) ≤ g n ⟹ summable g ⟹ summable f"
  apply (simp add: summable_Cauchy)
  apply safe
  apply (drule_tac x="e" in spec)
  apply safe
  apply (rule_tac x = "N + Na" in exI)
  apply safe
  apply (rotate_tac 2)
  apply (drule_tac x = m in spec)
  apply auto
  apply (rotate_tac 2)
  apply (drule_tac x = n in spec)
  apply (rule_tac y = "∑k=m..<n. norm (f k)" in order_le_less_trans)
   apply (rule norm_sum)
  apply (rule_tac y = "sum g {m..<n}" in order_le_less_trans)
   apply (auto intro: sum_mono simp add: abs_less_iff)
  done

lemma summable_comparison_test_ev:
  "eventually (λn. norm (f n) ≤ g n) sequentially ⟹ summable g ⟹ summable f"
  by (rule summable_comparison_test) (auto simp: eventually_at_top_linorder)

text ‹A better argument order.›
lemma summable_comparison_test': "summable g ⟹ (⋀n. n ≥ N ⟹ norm (f n) ≤ g n) ⟹ summable f"
  by (rule summable_comparison_test) auto


subsection ‹The Ratio Test›

lemma summable_ratio_test:
  assumes "c < 1" "⋀n. n ≥ N ⟹ norm (f (Suc n)) ≤ c * norm (f n)"
  shows "summable f"
proof (cases "0 < c")
  case True
  show "summable f"
  proof (rule summable_comparison_test)
    show "∃N'. ∀n≥N'. norm (f n) ≤ (norm (f N) / (c ^ N)) * c ^ n"
    proof (intro exI allI impI)
      fix n
      assume "N ≤ n"
      then show "norm (f n) ≤ (norm (f N) / (c ^ N)) * c ^ n"
      proof (induct rule: inc_induct)
        case base
        with True show ?case by simp
      next
        case (step m)
        have "norm (f (Suc m)) / c ^ Suc m * c ^ n ≤ norm (f m) / c ^ m * c ^ n"
          using ‹0 < c› ‹c < 1› assms(2)[OF ‹N ≤ m›] by (simp add: field_simps)
        with step show ?case by simp
      qed
    qed
    show "summable (λn. norm (f N) / c ^ N * c ^ n)"
      using ‹0 < c› ‹c < 1› by (intro summable_mult summable_geometric) simp
  qed
next
  case False
  have "f (Suc n) = 0" if "n ≥ N" for n
  proof -
    from that have "norm (f (Suc n)) ≤ c * norm (f n)"
      by (rule assms(2))
    also have "… ≤ 0"
      using False by (simp add: not_less mult_nonpos_nonneg)
    finally show ?thesis
      by auto
  qed
  then show "summable f"
    by (intro sums_summable[OF sums_finite, of "{.. Suc N}"]) (auto simp: not_le Suc_less_eq2)
qed

end


text ‹Relations among convergence and absolute convergence for power series.›

lemma Abel_lemma:
  fixes a :: "nat ⇒ 'a::real_normed_vector"
  assumes r: "0 ≤ r"
    and r0: "r < r0"
    and M: "⋀n. norm (a n) * r0^n ≤ M"
  shows "summable (λn. norm (a n) * r^n)"
proof (rule summable_comparison_test')
  show "summable (λn. M * (r / r0) ^ n)"
    using assms
    by (auto simp add: summable_mult summable_geometric)
  show "norm (norm (a n) * r ^ n) ≤ M * (r / r0) ^ n" for n
    using r r0 M [of n]
    apply (auto simp add: abs_mult field_simps)
    apply (cases "r = 0")
     apply simp
     apply (cases n)
      apply auto
    done
qed


text ‹Summability of geometric series for real algebras.›

lemma complete_algebra_summable_geometric:
  fixes x :: "'a::{real_normed_algebra_1,banach}"
  assumes "norm x < 1"
  shows "summable (λn. x ^ n)"
proof (rule summable_comparison_test)
  show "∃N. ∀n≥N. norm (x ^ n) ≤ norm x ^ n"
    by (simp add: norm_power_ineq)
  from assms show "summable (λn. norm x ^ n)"
    by (simp add: summable_geometric)
qed


subsection ‹Cauchy Product Formula›

text ‹
  Proof based on Analysis WebNotes: Chapter 07, Class 41
  🌐‹http://www.math.unl.edu/~webnotes/classes/class41/prp77.htm›
›

lemma Cauchy_product_sums:
  fixes a b :: "nat ⇒ 'a::{real_normed_algebra,banach}"
  assumes a: "summable (λk. norm (a k))"
    and b: "summable (λk. norm (b k))"
  shows "(λk. ∑i≤k. a i * b (k - i)) sums ((∑k. a k) * (∑k. b k))"
proof -
  let ?S1 = "λn::nat. {..<n} × {..<n}"
  let ?S2 = "λn::nat. {(i,j). i + j < n}"
  have S1_mono: "⋀m n. m ≤ n ⟹ ?S1 m ⊆ ?S1 n" by auto
  have S2_le_S1: "⋀n. ?S2 n ⊆ ?S1 n" by auto
  have S1_le_S2: "⋀n. ?S1 (n div 2) ⊆ ?S2 n" by auto
  have finite_S1: "⋀n. finite (?S1 n)" by simp
  with S2_le_S1 have finite_S2: "⋀n. finite (?S2 n)" by (rule finite_subset)

  let ?g = "λ(i,j). a i * b j"
  let ?f = "λ(i,j). norm (a i) * norm (b j)"
  have f_nonneg: "⋀x. 0 ≤ ?f x" by auto
  then have norm_sum_f: "⋀A. norm (sum ?f A) = sum ?f A"
    unfolding real_norm_def
    by (simp only: abs_of_nonneg sum_nonneg [rule_format])

  have "(λn. (∑k<n. a k) * (∑k<n. b k)) ⇢ (∑k. a k) * (∑k. b k)"
    by (intro tendsto_mult summable_LIMSEQ summable_norm_cancel [OF a] summable_norm_cancel [OF b])
  then have 1: "(λn. sum ?g (?S1 n)) ⇢ (∑k. a k) * (∑k. b k)"
    by (simp only: sum_product sum.Sigma [rule_format] finite_lessThan)

  have "(λn. (∑k<n. norm (a k)) * (∑k<n. norm (b k))) ⇢ (∑k. norm (a k)) * (∑k. norm (b k))"
    using a b by (intro tendsto_mult summable_LIMSEQ)
  then have "(λn. sum ?f (?S1 n)) ⇢ (∑k. norm (a k)) * (∑k. norm (b k))"
    by (simp only: sum_product sum.Sigma [rule_format] finite_lessThan)
  then have "convergent (λn. sum ?f (?S1 n))"
    by (rule convergentI)
  then have Cauchy: "Cauchy (λn. sum ?f (?S1 n))"
    by (rule convergent_Cauchy)
  have "Zfun (λn. sum ?f (?S1 n - ?S2 n)) sequentially"
  proof (rule ZfunI, simp only: eventually_sequentially norm_sum_f)
    fix r :: real
    assume r: "0 < r"
    from CauchyD [OF Cauchy r] obtain N
      where "∀m≥N. ∀n≥N. norm (sum ?f (?S1 m) - sum ?f (?S1 n)) < r" ..
    then have "⋀m n. N ≤ n ⟹ n ≤ m ⟹ norm (sum ?f (?S1 m - ?S1 n)) < r"
      by (simp only: sum_diff finite_S1 S1_mono)
    then have N: "⋀m n. N ≤ n ⟹ n ≤ m ⟹ sum ?f (?S1 m - ?S1 n) < r"
      by (simp only: norm_sum_f)
    show "∃N. ∀n≥N. sum ?f (?S1 n - ?S2 n) < r"
    proof (intro exI allI impI)
      fix n
      assume "2 * N ≤ n"
      then have n: "N ≤ n div 2" by simp
      have "sum ?f (?S1 n - ?S2 n) ≤ sum ?f (?S1 n - ?S1 (n div 2))"
        by (intro sum_mono2 finite_Diff finite_S1 f_nonneg Diff_mono subset_refl S1_le_S2)
      also have "… < r"
        using n div_le_dividend by (rule N)
      finally show "sum ?f (?S1 n - ?S2 n) < r" .
    qed
  qed
  then have "Zfun (λn. sum ?g (?S1 n - ?S2 n)) sequentially"
    apply (rule Zfun_le [rule_format])
    apply (simp only: norm_sum_f)
    apply (rule order_trans [OF norm_sum sum_mono])
    apply (auto simp add: norm_mult_ineq)
    done
  then have 2: "(λn. sum ?g (?S1 n) - sum ?g (?S2 n)) ⇢ 0"
    unfolding tendsto_Zfun_iff diff_0_right
    by (simp only: sum_diff finite_S1 S2_le_S1)
  with 1 have "(λn. sum ?g (?S2 n)) ⇢ (∑k. a k) * (∑k. b k)"
    by (rule Lim_transform2)
  then show ?thesis
    by (simp only: sums_def sum_triangle_reindex)
qed

lemma Cauchy_product:
  fixes a b :: "nat ⇒ 'a::{real_normed_algebra,banach}"
  assumes "summable (λk. norm (a k))"
    and "summable (λk. norm (b k))"
  shows "(∑k. a k) * (∑k. b k) = (∑k. ∑i≤k. a i * b (k - i))"
  using assms by (rule Cauchy_product_sums [THEN sums_unique])

lemma summable_Cauchy_product:
  fixes a b :: "nat ⇒ 'a::{real_normed_algebra,banach}"
  assumes "summable (λk. norm (a k))"
    and "summable (λk. norm (b k))"
  shows "summable (λk. ∑i≤k. a i * b (k - i))"
  using Cauchy_product_sums[OF assms] by (simp add: sums_iff)


subsection ‹Series on @{typ real}s›

lemma summable_norm_comparison_test:
  "∃N. ∀n≥N. norm (f n) ≤ g n ⟹ summable g ⟹ summable (λn. norm (f n))"
  by (rule summable_comparison_test) auto

lemma summable_rabs_comparison_test: "∃N. ∀n≥N. ¦f n¦ ≤ g n ⟹ summable g ⟹ summable (λn. ¦f n¦)"
  for f :: "nat ⇒ real"
  by (rule summable_comparison_test) auto

lemma summable_rabs_cancel: "summable (λn. ¦f n¦) ⟹ summable f"
  for f :: "nat ⇒ real"
  by (rule summable_norm_cancel) simp

lemma summable_rabs: "summable (λn. ¦f n¦) ⟹ ¦suminf f¦ ≤ (∑n. ¦f n¦)"
  for f :: "nat ⇒ real"
  by (fold real_norm_def) (rule summable_norm)

lemma summable_zero_power [simp]: "summable (λn. 0 ^ n :: 'a::{comm_ring_1,topological_space})"
proof -
  have "(λn. 0 ^ n :: 'a) = (λn. if n = 0 then 0^0 else 0)"
    by (intro ext) (simp add: zero_power)
  moreover have "summable …" by simp
  ultimately show ?thesis by simp
qed

lemma summable_zero_power' [simp]: "summable (λn. f n * 0 ^ n :: 'a::{ring_1,topological_space})"
proof -
  have "(λn. f n * 0 ^ n :: 'a) = (λn. if n = 0 then f 0 * 0^0 else 0)"
    by (intro ext) (simp add: zero_power)
  moreover have "summable …" by simp
  ultimately show ?thesis by simp
qed

lemma summable_power_series:
  fixes z :: real
  assumes le_1: "⋀i. f i ≤ 1"
    and nonneg: "⋀i. 0 ≤ f i"
    and z: "0 ≤ z" "z < 1"
  shows "summable (λi. f i * z^i)"
proof (rule summable_comparison_test[OF _ summable_geometric])
  show "norm z < 1"
    using z by (auto simp: less_imp_le)
  show "⋀n. ∃N. ∀na≥N. norm (f na * z ^ na) ≤ z ^ na"
    using z
    by (auto intro!: exI[of _ 0] mult_left_le_one_le simp: abs_mult nonneg power_abs less_imp_le le_1)
qed

lemma summable_0_powser: "summable (λn. f n * 0 ^ n :: 'a::real_normed_div_algebra)"
proof -
  have A: "(λn. f n * 0 ^ n) = (λn. if n = 0 then f n else 0)"
    by (intro ext) auto
  then show ?thesis
    by (subst A) simp_all
qed

lemma summable_powser_split_head:
  "summable (λn. f (Suc n) * z ^ n :: 'a::real_normed_div_algebra) = summable (λn. f n * z ^ n)"
proof -
  have "summable (λn. f (Suc n) * z ^ n) ⟷ summable (λn. f (Suc n) * z ^ Suc n)"
    (is "?lhs ⟷ ?rhs")
  proof
    show ?rhs if ?lhs
      using summable_mult2[OF that, of z]
      by (simp add: power_commutes algebra_simps)
    show ?lhs if ?rhs
      using summable_mult2[OF that, of "inverse z"]
      by (cases "z ≠ 0", subst (asm) power_Suc2) (simp_all add: algebra_simps)
  qed
  also have "… ⟷ summable (λn. f n * z ^ n)" by (rule summable_Suc_iff)
  finally show ?thesis .
qed

lemma summable_powser_ignore_initial_segment:
  fixes f :: "nat ⇒ 'a :: real_normed_div_algebra"
  shows "summable (λn. f (n + m) * z ^ n) ⟷ summable (λn. f n * z ^ n)"
proof (induction m)
  case (Suc m)
  have "summable (λn. f (n + Suc m) * z ^ n) = summable (λn. f (Suc n + m) * z ^ n)"
    by simp
  also have "… = summable (λn. f (n + m) * z ^ n)"
    by (rule summable_powser_split_head)
  also have "… = summable (λn. f n * z ^ n)"
    by (rule Suc.IH)
  finally show ?case .
qed simp_all

lemma powser_split_head:
  fixes f :: "nat ⇒ 'a::{real_normed_div_algebra,banach}"
  assumes "summable (λn. f n * z ^ n)"
  shows "suminf (λn. f n * z ^ n) = f 0 + suminf (λn. f (Suc n) * z ^ n) * z"
    and "suminf (λn. f (Suc n) * z ^ n) * z = suminf (λn. f n * z ^ n) - f 0"
    and "summable (λn. f (Suc n) * z ^ n)"
proof -
  from assms show "summable (λn. f (Suc n) * z ^ n)"
    by (subst summable_powser_split_head)
  from suminf_mult2[OF this, of z]
    have "(∑n. f (Suc n) * z ^ n) * z = (∑n. f (Suc n) * z ^ Suc n)"
    by (simp add: power_commutes algebra_simps)
  also from assms have "… = suminf (λn. f n * z ^ n) - f 0"
    by (subst suminf_split_head) simp_all
  finally show "suminf (λn. f n * z ^ n) = f 0 + suminf (λn. f (Suc n) * z ^ n) * z"
    by simp
  then show "suminf (λn. f (Suc n) * z ^ n) * z = suminf (λn. f n * z ^ n) - f 0"
    by simp
qed

lemma summable_partial_sum_bound:
  fixes f :: "nat ⇒ 'a :: banach"
    and e :: real
  assumes summable: "summable f"
    and e: "e > 0"
  obtains N where "⋀m n. m ≥ N ⟹ norm (∑k=m..n. f k) < e"
proof -
  from summable have "Cauchy (λn. ∑k<n. f k)"
    by (simp add: Cauchy_convergent_iff summable_iff_convergent)
  from CauchyD [OF this e] obtain N
    where N: "⋀m n. m ≥ N ⟹ n ≥ N ⟹ norm ((∑k<m. f k) - (∑k<n. f k)) < e"
    by blast
  have "norm (∑k=m..n. f k) < e" if m: "m ≥ N" for m n
  proof (cases "n ≥ m")
    case True
    with m have "norm ((∑k<Suc n. f k) - (∑k<m. f k)) < e"
      by (intro N) simp_all
    also from True have "(∑k<Suc n. f k) - (∑k<m. f k) = (∑k=m..n. f k)"
      by (subst sum_diff [symmetric]) (simp_all add: sum_last_plus)
    finally show ?thesis .
  next
    case False
    with e show ?thesis by simp_all
  qed
  then show ?thesis by (rule that)
qed

lemma powser_sums_if:
  "(λn. (if n = m then (1 :: 'a::{ring_1,topological_space}) else 0) * z^n) sums z^m"
proof -
  have "(λn. (if n = m then 1 else 0) * z^n) = (λn. if n = m then z^n else 0)"
    by (intro ext) auto
  then show ?thesis
    by (simp add: sums_single)
qed

lemma
  fixes f :: "nat ⇒ real"
  assumes "summable f"
    and "inj g"
    and pos: "⋀x. 0 ≤ f x"
  shows summable_reindex: "summable (f ∘ g)"
    and suminf_reindex_mono: "suminf (f ∘ g) ≤ suminf f"
    and suminf_reindex: "(⋀x. x ∉ range g ⟹ f x = 0) ⟹ suminf (f ∘ g) = suminf f"
proof -
  from ‹inj g› have [simp]: "⋀A. inj_on g A"
    by (rule subset_inj_on) simp

  have smaller: "∀n. (∑i<n. (f ∘ g) i) ≤ suminf f"
  proof
    fix n
    have "∀ n' ∈ (g ` {..<n}). n' < Suc (Max (g ` {..<n}))"
      by (metis Max_ge finite_imageI finite_lessThan not_le not_less_eq)
    then obtain m where n: "⋀n'. n' < n ⟹ g n' < m"
      by blast

    have "(∑i<n. f (g i)) = sum f (g ` {..<n})"
      by (simp add: sum.reindex)
    also have "… ≤ (∑i<m. f i)"
      by (rule sum_mono2) (auto simp add: pos n[rule_format])
    also have "… ≤ suminf f"
      using ‹summable f› by (rule sum_le_suminf) (simp add: pos)
    finally show "(∑i<n. (f ∘  g) i) ≤ suminf f"
      by simp
  qed

  have "incseq (λn. ∑i<n. (f ∘ g) i)"
    by (rule incseq_SucI) (auto simp add: pos)
  then obtain  L where L: "(λ n. ∑i<n. (f ∘ g) i) ⇢ L"
    using smaller by(rule incseq_convergent)
  then have "(f ∘ g) sums L"
    by (simp add: sums_def)
  then show "summable (f ∘ g)"
    by (auto simp add: sums_iff)

  then have "(λn. ∑i<n. (f ∘ g) i) ⇢ suminf (f ∘ g)"
    by (rule summable_LIMSEQ)
  then show le: "suminf (f ∘ g) ≤ suminf f"
    by(rule LIMSEQ_le_const2)(blast intro: smaller[rule_format])

  assume f: "⋀x. x ∉ range g ⟹ f x = 0"

  from ‹summable f› have "suminf f ≤ suminf (f ∘ g)"
  proof (rule suminf_le_const)
    fix n
    have "∀ n' ∈ (g -` {..<n}). n' < Suc (Max (g -` {..<n}))"
      by(auto intro: Max_ge simp add: finite_vimageI less_Suc_eq_le)
    then obtain m where n: "⋀n'. g n' < n ⟹ n' < m"
      by blast
    have "(∑i<n. f i) = (∑i∈{..<n} ∩ range g. f i)"
      using f by(auto intro: sum.mono_neutral_cong_right)
    also have "… = (∑i∈g -` {..<n}. (f ∘ g) i)"
      by (rule sum.reindex_cong[where l=g])(auto)
    also have "… ≤ (∑i<m. (f ∘ g) i)"
      by (rule sum_mono2)(auto simp add: pos n)
    also have "… ≤ suminf (f ∘ g)"
      using ‹summable (f ∘ g)› by (rule sum_le_suminf) (simp add: pos)
    finally show "sum f {..<n} ≤ suminf (f ∘ g)" .
  qed
  with le show "suminf (f ∘ g) = suminf f"
    by (rule antisym)
qed

lemma sums_mono_reindex:
  assumes subseq: "strict_mono g"
    and zero: "⋀n. n ∉ range g ⟹ f n = 0"
  shows "(λn. f (g n)) sums c ⟷ f sums c"
  unfolding sums_def
proof
  assume lim: "(λn. ∑k<n. f k) ⇢ c"
  have "(λn. ∑k<n. f (g k)) = (λn. ∑k<g n. f k)"
  proof
    fix n :: nat
    from subseq have "(∑k<n. f (g k)) = (∑k∈g`{..<n}. f k)"
      by (subst sum.reindex) (auto intro: strict_mono_imp_inj_on)
    also from subseq have "… = (∑k<g n. f k)"
      by (intro sum.mono_neutral_left ballI zero)
        (auto simp: strict_mono_less strict_mono_less_eq)
    finally show "(∑k<n. f (g k)) = (∑k<g n. f k)" .
  qed
  also from LIMSEQ_subseq_LIMSEQ[OF lim subseq] have "… ⇢ c"
    by (simp only: o_def)
  finally show "(λn. ∑k<n. f (g k)) ⇢ c" .
next
  assume lim: "(λn. ∑k<n. f (g k)) ⇢ c"
  define g_inv where "g_inv n = (LEAST m. g m ≥ n)" for n
  from filterlim_subseq[OF subseq] have g_inv_ex: "∃m. g m ≥ n" for n
    by (auto simp: filterlim_at_top eventually_at_top_linorder)
  then have g_inv: "g (g_inv n) ≥ n" for n
    unfolding g_inv_def by (rule LeastI_ex)
  have g_inv_least: "m ≥ g_inv n" if "g m ≥ n" for m n
    using that unfolding g_inv_def by (rule Least_le)
  have g_inv_least': "g m < n" if "m < g_inv n" for m n
    using that g_inv_least[of n m] by linarith
  have "(λn. ∑k<n. f k) = (λn. ∑k<g_inv n. f (g k))"
  proof
    fix n :: nat
    {
      fix k
      assume k: "k ∈ {..<n} - g`{..<g_inv n}"
      have "k ∉ range g"
      proof (rule notI, elim imageE)
        fix l
        assume l: "k = g l"
        have "g l < g (g_inv n)"
          by (rule less_le_trans[OF _ g_inv]) (use k l in simp_all)
        with subseq have "l < g_inv n"
          by (simp add: strict_mono_less)
        with k l show False
          by simp
      qed
      then have "f k = 0"
        by (rule zero)
    }
    with g_inv_least' g_inv have "(∑k<n. f k) = (∑k∈g`{..<g_inv n}. f k)"
      by (intro sum.mono_neutral_right) auto
    also from subseq have "… = (∑k<g_inv n. f (g k))"
      using strict_mono_imp_inj_on by (subst sum.reindex) simp_all
    finally show "(∑k<n. f k) = (∑k<g_inv n. f (g k))" .
  qed
  also {
    fix K n :: nat
    assume "g K ≤ n"
    also have "n ≤ g (g_inv n)"
      by (rule g_inv)
    finally have "K ≤ g_inv n"
      using subseq by (simp add: strict_mono_less_eq)
  }
  then have "filterlim g_inv at_top sequentially"
    by (auto simp: filterlim_at_top eventually_at_top_linorder)
  with lim have "(λn. ∑k<g_inv n. f (g k)) ⇢ c"
    by (rule filterlim_compose)
  finally show "(λn. ∑k<n. f k) ⇢ c" .
qed

lemma summable_mono_reindex:
  assumes subseq: "strict_mono g"
    and zero: "⋀n. n ∉ range g ⟹ f n = 0"
  shows "summable (λn. f (g n)) ⟷ summable f"
  using sums_mono_reindex[of g f, OF assms] by (simp add: summable_def)

lemma suminf_mono_reindex:
  fixes f :: "nat ⇒ 'a::{t2_space,comm_monoid_add}"
  assumes "strict_mono g" "⋀n. n ∉ range g ⟹ f n = 0"
  shows   "suminf (λn. f (g n)) = suminf f"
proof (cases "summable f")
  case True
  with sums_mono_reindex [of g f, OF assms]
    and summable_mono_reindex [of g f, OF assms]
  show ?thesis
    by (simp add: sums_iff)
next
  case False
  then have "¬(∃c. f sums c)"
    unfolding summable_def by blast
  then have "suminf f = The (λ_. False)"
    by (simp add: suminf_def)
  moreover from False have "¬ summable (λn. f (g n))"
    using summable_mono_reindex[of g f, OF assms] by simp
  then have "¬(∃c. (λn. f (g n)) sums c)"
    unfolding summable_def by blast
  then have "suminf (λn. f (g n)) = The (λ_. False)"
    by (simp add: suminf_def)
  ultimately show ?thesis by simp
qed

end