src/HOL/Complex.thy
author hoelzl
Tue Mar 26 12:20:58 2013 +0100 (2013-03-26)
changeset 51526 155263089e7b
parent 51002 496013a6eb38
child 53015 a1119cf551e8
permissions -rw-r--r--
move SEQ.thy and Lim.thy to Limits.thy
wenzelm@41959
     1
(*  Title:       HOL/Complex.thy
paulson@13957
     2
    Author:      Jacques D. Fleuriot
paulson@13957
     3
    Copyright:   2001 University of Edinburgh
paulson@14387
     4
    Conversion to Isar and new proofs by Lawrence C Paulson, 2003/4
paulson@13957
     5
*)
paulson@13957
     6
paulson@14377
     7
header {* Complex Numbers: Rectangular and Polar Representations *}
paulson@14373
     8
nipkow@15131
     9
theory Complex
haftmann@28952
    10
imports Transcendental
nipkow@15131
    11
begin
paulson@13957
    12
paulson@14373
    13
datatype complex = Complex real real
paulson@13957
    14
huffman@44724
    15
primrec Re :: "complex \<Rightarrow> real"
huffman@44724
    16
  where Re: "Re (Complex x y) = x"
paulson@14373
    17
huffman@44724
    18
primrec Im :: "complex \<Rightarrow> real"
huffman@44724
    19
  where Im: "Im (Complex x y) = y"
paulson@14373
    20
paulson@14373
    21
lemma complex_surj [simp]: "Complex (Re z) (Im z) = z"
paulson@14373
    22
  by (induct z) simp
paulson@13957
    23
huffman@44065
    24
lemma complex_eqI [intro?]: "\<lbrakk>Re x = Re y; Im x = Im y\<rbrakk> \<Longrightarrow> x = y"
haftmann@25712
    25
  by (induct x, induct y) simp
huffman@23125
    26
huffman@44065
    27
lemma complex_eq_iff: "x = y \<longleftrightarrow> Re x = Re y \<and> Im x = Im y"
haftmann@25712
    28
  by (induct x, induct y) simp
huffman@23125
    29
huffman@23125
    30
huffman@23125
    31
subsection {* Addition and Subtraction *}
huffman@23125
    32
haftmann@25599
    33
instantiation complex :: ab_group_add
haftmann@25571
    34
begin
haftmann@25571
    35
huffman@44724
    36
definition complex_zero_def:
huffman@44724
    37
  "0 = Complex 0 0"
haftmann@25571
    38
huffman@44724
    39
definition complex_add_def:
huffman@44724
    40
  "x + y = Complex (Re x + Re y) (Im x + Im y)"
huffman@23124
    41
huffman@44724
    42
definition complex_minus_def:
huffman@44724
    43
  "- x = Complex (- Re x) (- Im x)"
paulson@14323
    44
huffman@44724
    45
definition complex_diff_def:
huffman@44724
    46
  "x - (y\<Colon>complex) = x + - y"
haftmann@25571
    47
haftmann@25599
    48
lemma Complex_eq_0 [simp]: "Complex a b = 0 \<longleftrightarrow> a = 0 \<and> b = 0"
haftmann@25599
    49
  by (simp add: complex_zero_def)
paulson@14323
    50
paulson@14374
    51
lemma complex_Re_zero [simp]: "Re 0 = 0"
haftmann@25599
    52
  by (simp add: complex_zero_def)
paulson@14374
    53
paulson@14374
    54
lemma complex_Im_zero [simp]: "Im 0 = 0"
haftmann@25599
    55
  by (simp add: complex_zero_def)
haftmann@25599
    56
haftmann@25712
    57
lemma complex_add [simp]:
haftmann@25712
    58
  "Complex a b + Complex c d = Complex (a + c) (b + d)"
haftmann@25712
    59
  by (simp add: complex_add_def)
haftmann@25712
    60
haftmann@25599
    61
lemma complex_Re_add [simp]: "Re (x + y) = Re x + Re y"
haftmann@25599
    62
  by (simp add: complex_add_def)
haftmann@25599
    63
haftmann@25599
    64
lemma complex_Im_add [simp]: "Im (x + y) = Im x + Im y"
haftmann@25599
    65
  by (simp add: complex_add_def)
paulson@14323
    66
haftmann@25712
    67
lemma complex_minus [simp]:
haftmann@25712
    68
  "- (Complex a b) = Complex (- a) (- b)"
haftmann@25599
    69
  by (simp add: complex_minus_def)
huffman@23125
    70
huffman@23125
    71
lemma complex_Re_minus [simp]: "Re (- x) = - Re x"
haftmann@25599
    72
  by (simp add: complex_minus_def)
huffman@23125
    73
huffman@23125
    74
lemma complex_Im_minus [simp]: "Im (- x) = - Im x"
haftmann@25599
    75
  by (simp add: complex_minus_def)
huffman@23125
    76
huffman@23275
    77
lemma complex_diff [simp]:
huffman@23125
    78
  "Complex a b - Complex c d = Complex (a - c) (b - d)"
haftmann@25599
    79
  by (simp add: complex_diff_def)
huffman@23125
    80
huffman@23125
    81
lemma complex_Re_diff [simp]: "Re (x - y) = Re x - Re y"
haftmann@25599
    82
  by (simp add: complex_diff_def)
huffman@23125
    83
huffman@23125
    84
lemma complex_Im_diff [simp]: "Im (x - y) = Im x - Im y"
haftmann@25599
    85
  by (simp add: complex_diff_def)
huffman@23125
    86
haftmann@25712
    87
instance
haftmann@25712
    88
  by intro_classes (simp_all add: complex_add_def complex_diff_def)
haftmann@25712
    89
haftmann@25712
    90
end
haftmann@25712
    91
haftmann@25712
    92
huffman@23125
    93
subsection {* Multiplication and Division *}
huffman@23125
    94
haftmann@36409
    95
instantiation complex :: field_inverse_zero
haftmann@25571
    96
begin
haftmann@25571
    97
huffman@44724
    98
definition complex_one_def:
huffman@44724
    99
  "1 = Complex 1 0"
haftmann@25571
   100
huffman@44724
   101
definition complex_mult_def:
huffman@44724
   102
  "x * y = Complex (Re x * Re y - Im x * Im y) (Re x * Im y + Im x * Re y)"
huffman@23125
   103
huffman@44724
   104
definition complex_inverse_def:
huffman@44724
   105
  "inverse x =
haftmann@25571
   106
    Complex (Re x / ((Re x)\<twosuperior> + (Im x)\<twosuperior>)) (- Im x / ((Re x)\<twosuperior> + (Im x)\<twosuperior>))"
huffman@23125
   107
huffman@44724
   108
definition complex_divide_def:
huffman@44724
   109
  "x / (y\<Colon>complex) = x * inverse y"
haftmann@25571
   110
huffman@23125
   111
lemma Complex_eq_1 [simp]: "(Complex a b = 1) = (a = 1 \<and> b = 0)"
haftmann@25712
   112
  by (simp add: complex_one_def)
huffman@22861
   113
paulson@14374
   114
lemma complex_Re_one [simp]: "Re 1 = 1"
haftmann@25712
   115
  by (simp add: complex_one_def)
paulson@14323
   116
paulson@14374
   117
lemma complex_Im_one [simp]: "Im 1 = 0"
haftmann@25712
   118
  by (simp add: complex_one_def)
paulson@14323
   119
huffman@23125
   120
lemma complex_mult [simp]:
huffman@23125
   121
  "Complex a b * Complex c d = Complex (a * c - b * d) (a * d + b * c)"
haftmann@25712
   122
  by (simp add: complex_mult_def)
paulson@14323
   123
huffman@23125
   124
lemma complex_Re_mult [simp]: "Re (x * y) = Re x * Re y - Im x * Im y"
haftmann@25712
   125
  by (simp add: complex_mult_def)
paulson@14323
   126
huffman@23125
   127
lemma complex_Im_mult [simp]: "Im (x * y) = Re x * Im y + Im x * Re y"
haftmann@25712
   128
  by (simp add: complex_mult_def)
paulson@14323
   129
paulson@14377
   130
lemma complex_inverse [simp]:
huffman@23125
   131
  "inverse (Complex a b) = Complex (a / (a\<twosuperior> + b\<twosuperior>)) (- b / (a\<twosuperior> + b\<twosuperior>))"
haftmann@25712
   132
  by (simp add: complex_inverse_def)
paulson@14335
   133
huffman@23125
   134
lemma complex_Re_inverse:
huffman@23125
   135
  "Re (inverse x) = Re x / ((Re x)\<twosuperior> + (Im x)\<twosuperior>)"
haftmann@25712
   136
  by (simp add: complex_inverse_def)
paulson@14323
   137
huffman@23125
   138
lemma complex_Im_inverse:
huffman@23125
   139
  "Im (inverse x) = - Im x / ((Re x)\<twosuperior> + (Im x)\<twosuperior>)"
haftmann@25712
   140
  by (simp add: complex_inverse_def)
paulson@14335
   141
haftmann@25712
   142
instance
haftmann@25712
   143
  by intro_classes (simp_all add: complex_mult_def
webertj@49962
   144
    distrib_left distrib_right right_diff_distrib left_diff_distrib
huffman@44724
   145
    complex_inverse_def complex_divide_def
huffman@44724
   146
    power2_eq_square add_divide_distrib [symmetric]
huffman@44724
   147
    complex_eq_iff)
paulson@14335
   148
haftmann@25712
   149
end
huffman@23125
   150
huffman@23125
   151
huffman@23125
   152
subsection {* Numerals and Arithmetic *}
huffman@23125
   153
huffman@23125
   154
lemma complex_Re_of_nat [simp]: "Re (of_nat n) = of_nat n"
huffman@44724
   155
  by (induct n) simp_all
huffman@20556
   156
huffman@23125
   157
lemma complex_Im_of_nat [simp]: "Im (of_nat n) = 0"
huffman@44724
   158
  by (induct n) simp_all
huffman@23125
   159
huffman@23125
   160
lemma complex_Re_of_int [simp]: "Re (of_int z) = of_int z"
huffman@44724
   161
  by (cases z rule: int_diff_cases) simp
huffman@23125
   162
huffman@23125
   163
lemma complex_Im_of_int [simp]: "Im (of_int z) = 0"
huffman@44724
   164
  by (cases z rule: int_diff_cases) simp
huffman@23125
   165
huffman@47108
   166
lemma complex_Re_numeral [simp]: "Re (numeral v) = numeral v"
huffman@47108
   167
  using complex_Re_of_int [of "numeral v"] by simp
huffman@47108
   168
huffman@47108
   169
lemma complex_Re_neg_numeral [simp]: "Re (neg_numeral v) = neg_numeral v"
huffman@47108
   170
  using complex_Re_of_int [of "neg_numeral v"] by simp
huffman@47108
   171
huffman@47108
   172
lemma complex_Im_numeral [simp]: "Im (numeral v) = 0"
huffman@47108
   173
  using complex_Im_of_int [of "numeral v"] by simp
huffman@20556
   174
huffman@47108
   175
lemma complex_Im_neg_numeral [simp]: "Im (neg_numeral v) = 0"
huffman@47108
   176
  using complex_Im_of_int [of "neg_numeral v"] by simp
huffman@23125
   177
huffman@47108
   178
lemma Complex_eq_numeral [simp]:
huffman@47108
   179
  "(Complex a b = numeral w) = (a = numeral w \<and> b = 0)"
huffman@47108
   180
  by (simp add: complex_eq_iff)
huffman@47108
   181
huffman@47108
   182
lemma Complex_eq_neg_numeral [simp]:
huffman@47108
   183
  "(Complex a b = neg_numeral w) = (a = neg_numeral w \<and> b = 0)"
huffman@44724
   184
  by (simp add: complex_eq_iff)
huffman@23125
   185
huffman@23125
   186
huffman@23125
   187
subsection {* Scalar Multiplication *}
huffman@20556
   188
haftmann@25712
   189
instantiation complex :: real_field
haftmann@25571
   190
begin
haftmann@25571
   191
huffman@44724
   192
definition complex_scaleR_def:
huffman@44724
   193
  "scaleR r x = Complex (r * Re x) (r * Im x)"
haftmann@25571
   194
huffman@23125
   195
lemma complex_scaleR [simp]:
huffman@23125
   196
  "scaleR r (Complex a b) = Complex (r * a) (r * b)"
haftmann@25712
   197
  unfolding complex_scaleR_def by simp
huffman@23125
   198
huffman@23125
   199
lemma complex_Re_scaleR [simp]: "Re (scaleR r x) = r * Re x"
haftmann@25712
   200
  unfolding complex_scaleR_def by simp
huffman@23125
   201
huffman@23125
   202
lemma complex_Im_scaleR [simp]: "Im (scaleR r x) = r * Im x"
haftmann@25712
   203
  unfolding complex_scaleR_def by simp
huffman@22972
   204
haftmann@25712
   205
instance
huffman@20556
   206
proof
huffman@23125
   207
  fix a b :: real and x y :: complex
huffman@23125
   208
  show "scaleR a (x + y) = scaleR a x + scaleR a y"
webertj@49962
   209
    by (simp add: complex_eq_iff distrib_left)
huffman@23125
   210
  show "scaleR (a + b) x = scaleR a x + scaleR b x"
webertj@49962
   211
    by (simp add: complex_eq_iff distrib_right)
huffman@23125
   212
  show "scaleR a (scaleR b x) = scaleR (a * b) x"
huffman@44065
   213
    by (simp add: complex_eq_iff mult_assoc)
huffman@23125
   214
  show "scaleR 1 x = x"
huffman@44065
   215
    by (simp add: complex_eq_iff)
huffman@23125
   216
  show "scaleR a x * y = scaleR a (x * y)"
huffman@44065
   217
    by (simp add: complex_eq_iff algebra_simps)
huffman@23125
   218
  show "x * scaleR a y = scaleR a (x * y)"
huffman@44065
   219
    by (simp add: complex_eq_iff algebra_simps)
huffman@20556
   220
qed
huffman@20556
   221
haftmann@25712
   222
end
haftmann@25712
   223
huffman@20556
   224
huffman@23125
   225
subsection{* Properties of Embedding from Reals *}
paulson@14323
   226
huffman@44724
   227
abbreviation complex_of_real :: "real \<Rightarrow> complex"
huffman@44724
   228
  where "complex_of_real \<equiv> of_real"
huffman@20557
   229
huffman@20557
   230
lemma complex_of_real_def: "complex_of_real r = Complex r 0"
huffman@44724
   231
  by (simp add: of_real_def complex_scaleR_def)
huffman@20557
   232
huffman@20557
   233
lemma Re_complex_of_real [simp]: "Re (complex_of_real z) = z"
huffman@44724
   234
  by (simp add: complex_of_real_def)
huffman@20557
   235
huffman@20557
   236
lemma Im_complex_of_real [simp]: "Im (complex_of_real z) = 0"
huffman@44724
   237
  by (simp add: complex_of_real_def)
huffman@20557
   238
paulson@14377
   239
lemma Complex_add_complex_of_real [simp]:
huffman@44724
   240
  shows "Complex x y + complex_of_real r = Complex (x+r) y"
huffman@44724
   241
  by (simp add: complex_of_real_def)
paulson@14377
   242
paulson@14377
   243
lemma complex_of_real_add_Complex [simp]:
huffman@44724
   244
  shows "complex_of_real r + Complex x y = Complex (r+x) y"
huffman@44724
   245
  by (simp add: complex_of_real_def)
paulson@14377
   246
paulson@14377
   247
lemma Complex_mult_complex_of_real:
huffman@44724
   248
  shows "Complex x y * complex_of_real r = Complex (x*r) (y*r)"
huffman@44724
   249
  by (simp add: complex_of_real_def)
paulson@14377
   250
paulson@14377
   251
lemma complex_of_real_mult_Complex:
huffman@44724
   252
  shows "complex_of_real r * Complex x y = Complex (r*x) (r*y)"
huffman@44724
   253
  by (simp add: complex_of_real_def)
huffman@20557
   254
huffman@44841
   255
lemma complex_eq_cancel_iff2 [simp]:
huffman@44841
   256
  shows "(Complex x y = complex_of_real xa) = (x = xa & y = 0)"
huffman@44841
   257
  by (simp add: complex_of_real_def)
huffman@44841
   258
huffman@44827
   259
lemma complex_split_polar:
huffman@44827
   260
     "\<exists>r a. z = complex_of_real r * (Complex (cos a) (sin a))"
huffman@44827
   261
  by (simp add: complex_eq_iff polar_Ex)
huffman@44827
   262
paulson@14377
   263
huffman@23125
   264
subsection {* Vector Norm *}
paulson@14323
   265
haftmann@25712
   266
instantiation complex :: real_normed_field
haftmann@25571
   267
begin
haftmann@25571
   268
huffman@31413
   269
definition complex_norm_def:
huffman@31413
   270
  "norm z = sqrt ((Re z)\<twosuperior> + (Im z)\<twosuperior>)"
haftmann@25571
   271
huffman@44724
   272
abbreviation cmod :: "complex \<Rightarrow> real"
huffman@44724
   273
  where "cmod \<equiv> norm"
haftmann@25571
   274
huffman@31413
   275
definition complex_sgn_def:
huffman@31413
   276
  "sgn x = x /\<^sub>R cmod x"
haftmann@25571
   277
huffman@31413
   278
definition dist_complex_def:
huffman@31413
   279
  "dist x y = cmod (x - y)"
huffman@31413
   280
haftmann@37767
   281
definition open_complex_def:
huffman@31492
   282
  "open (S :: complex set) \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"
huffman@31292
   283
huffman@20557
   284
lemmas cmod_def = complex_norm_def
huffman@20557
   285
huffman@23125
   286
lemma complex_norm [simp]: "cmod (Complex x y) = sqrt (x\<twosuperior> + y\<twosuperior>)"
haftmann@25712
   287
  by (simp add: complex_norm_def)
huffman@22852
   288
huffman@31413
   289
instance proof
huffman@31492
   290
  fix r :: real and x y :: complex and S :: "complex set"
huffman@23125
   291
  show "(norm x = 0) = (x = 0)"
huffman@22861
   292
    by (induct x) simp
huffman@23125
   293
  show "norm (x + y) \<le> norm x + norm y"
huffman@23125
   294
    by (induct x, induct y)
huffman@23125
   295
       (simp add: real_sqrt_sum_squares_triangle_ineq)
huffman@23125
   296
  show "norm (scaleR r x) = \<bar>r\<bar> * norm x"
huffman@23125
   297
    by (induct x)
webertj@49962
   298
       (simp add: power_mult_distrib distrib_left [symmetric] real_sqrt_mult)
huffman@23125
   299
  show "norm (x * y) = norm x * norm y"
huffman@23125
   300
    by (induct x, induct y)
nipkow@29667
   301
       (simp add: real_sqrt_mult [symmetric] power2_eq_square algebra_simps)
huffman@31292
   302
  show "sgn x = x /\<^sub>R cmod x"
huffman@31292
   303
    by (rule complex_sgn_def)
huffman@31292
   304
  show "dist x y = cmod (x - y)"
huffman@31292
   305
    by (rule dist_complex_def)
huffman@31492
   306
  show "open S \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"
huffman@31492
   307
    by (rule open_complex_def)
huffman@24520
   308
qed
huffman@20557
   309
haftmann@25712
   310
end
haftmann@25712
   311
huffman@44761
   312
lemma cmod_unit_one: "cmod (Complex (cos a) (sin a)) = 1"
huffman@44724
   313
  by simp
paulson@14323
   314
huffman@44761
   315
lemma cmod_complex_polar:
huffman@44724
   316
  "cmod (complex_of_real r * Complex (cos a) (sin a)) = abs r"
huffman@44724
   317
  by (simp add: norm_mult)
huffman@22861
   318
huffman@22861
   319
lemma complex_Re_le_cmod: "Re x \<le> cmod x"
huffman@44724
   320
  unfolding complex_norm_def
huffman@44724
   321
  by (rule real_sqrt_sum_squares_ge1)
huffman@22861
   322
huffman@44761
   323
lemma complex_mod_minus_le_complex_mod: "- cmod x \<le> cmod x"
huffman@44724
   324
  by (rule order_trans [OF _ norm_ge_zero], simp)
huffman@22861
   325
huffman@44761
   326
lemma complex_mod_triangle_ineq2: "cmod(b + a) - cmod b \<le> cmod a"
huffman@44724
   327
  by (rule ord_le_eq_trans [OF norm_triangle_ineq2], simp)
paulson@14323
   328
chaieb@26117
   329
lemma abs_Re_le_cmod: "\<bar>Re x\<bar> \<le> cmod x"
huffman@44724
   330
  by (cases x) simp
chaieb@26117
   331
chaieb@26117
   332
lemma abs_Im_le_cmod: "\<bar>Im x\<bar> \<le> cmod x"
huffman@44724
   333
  by (cases x) simp
huffman@44724
   334
huffman@44843
   335
text {* Properties of complex signum. *}
huffman@44843
   336
huffman@44843
   337
lemma sgn_eq: "sgn z = z / complex_of_real (cmod z)"
huffman@44843
   338
  by (simp add: sgn_div_norm divide_inverse scaleR_conv_of_real mult_commute)
huffman@44843
   339
huffman@44843
   340
lemma Re_sgn [simp]: "Re(sgn z) = Re(z)/cmod z"
huffman@44843
   341
  by (simp add: complex_sgn_def divide_inverse)
huffman@44843
   342
huffman@44843
   343
lemma Im_sgn [simp]: "Im(sgn z) = Im(z)/cmod z"
huffman@44843
   344
  by (simp add: complex_sgn_def divide_inverse)
huffman@44843
   345
paulson@14354
   346
huffman@23123
   347
subsection {* Completeness of the Complexes *}
huffman@23123
   348
huffman@44290
   349
lemma bounded_linear_Re: "bounded_linear Re"
huffman@44290
   350
  by (rule bounded_linear_intro [where K=1], simp_all add: complex_norm_def)
huffman@44290
   351
huffman@44290
   352
lemma bounded_linear_Im: "bounded_linear Im"
huffman@44127
   353
  by (rule bounded_linear_intro [where K=1], simp_all add: complex_norm_def)
huffman@23123
   354
huffman@44290
   355
lemmas tendsto_Re [tendsto_intros] =
huffman@44290
   356
  bounded_linear.tendsto [OF bounded_linear_Re]
huffman@44290
   357
huffman@44290
   358
lemmas tendsto_Im [tendsto_intros] =
huffman@44290
   359
  bounded_linear.tendsto [OF bounded_linear_Im]
huffman@44290
   360
huffman@44290
   361
lemmas isCont_Re [simp] = bounded_linear.isCont [OF bounded_linear_Re]
huffman@44290
   362
lemmas isCont_Im [simp] = bounded_linear.isCont [OF bounded_linear_Im]
huffman@44290
   363
lemmas Cauchy_Re = bounded_linear.Cauchy [OF bounded_linear_Re]
huffman@44290
   364
lemmas Cauchy_Im = bounded_linear.Cauchy [OF bounded_linear_Im]
huffman@23123
   365
huffman@36825
   366
lemma tendsto_Complex [tendsto_intros]:
huffman@44724
   367
  assumes "(f ---> a) F" and "(g ---> b) F"
huffman@44724
   368
  shows "((\<lambda>x. Complex (f x) (g x)) ---> Complex a b) F"
huffman@36825
   369
proof (rule tendstoI)
huffman@36825
   370
  fix r :: real assume "0 < r"
huffman@36825
   371
  hence "0 < r / sqrt 2" by (simp add: divide_pos_pos)
huffman@44724
   372
  have "eventually (\<lambda>x. dist (f x) a < r / sqrt 2) F"
huffman@44724
   373
    using `(f ---> a) F` and `0 < r / sqrt 2` by (rule tendstoD)
huffman@36825
   374
  moreover
huffman@44724
   375
  have "eventually (\<lambda>x. dist (g x) b < r / sqrt 2) F"
huffman@44724
   376
    using `(g ---> b) F` and `0 < r / sqrt 2` by (rule tendstoD)
huffman@36825
   377
  ultimately
huffman@44724
   378
  show "eventually (\<lambda>x. dist (Complex (f x) (g x)) (Complex a b) < r) F"
huffman@36825
   379
    by (rule eventually_elim2)
huffman@36825
   380
       (simp add: dist_norm real_sqrt_sum_squares_less)
huffman@36825
   381
qed
huffman@36825
   382
huffman@23123
   383
instance complex :: banach
huffman@23123
   384
proof
huffman@23123
   385
  fix X :: "nat \<Rightarrow> complex"
huffman@23123
   386
  assume X: "Cauchy X"
huffman@44290
   387
  from Cauchy_Re [OF X] have 1: "(\<lambda>n. Re (X n)) ----> lim (\<lambda>n. Re (X n))"
huffman@23123
   388
    by (simp add: Cauchy_convergent_iff convergent_LIMSEQ_iff)
huffman@44290
   389
  from Cauchy_Im [OF X] have 2: "(\<lambda>n. Im (X n)) ----> lim (\<lambda>n. Im (X n))"
huffman@23123
   390
    by (simp add: Cauchy_convergent_iff convergent_LIMSEQ_iff)
huffman@23123
   391
  have "X ----> Complex (lim (\<lambda>n. Re (X n))) (lim (\<lambda>n. Im (X n)))"
huffman@44748
   392
    using tendsto_Complex [OF 1 2] by simp
huffman@23123
   393
  thus "convergent X"
huffman@23123
   394
    by (rule convergentI)
huffman@23123
   395
qed
huffman@23123
   396
huffman@23123
   397
huffman@44827
   398
subsection {* The Complex Number $i$ *}
huffman@23125
   399
huffman@44724
   400
definition "ii" :: complex  ("\<i>")
huffman@44724
   401
  where i_def: "ii \<equiv> Complex 0 1"
huffman@23125
   402
huffman@23125
   403
lemma complex_Re_i [simp]: "Re ii = 0"
huffman@44724
   404
  by (simp add: i_def)
paulson@14354
   405
huffman@23125
   406
lemma complex_Im_i [simp]: "Im ii = 1"
huffman@44724
   407
  by (simp add: i_def)
huffman@23125
   408
huffman@23125
   409
lemma Complex_eq_i [simp]: "(Complex x y = ii) = (x = 0 \<and> y = 1)"
huffman@44724
   410
  by (simp add: i_def)
huffman@23125
   411
huffman@44902
   412
lemma norm_ii [simp]: "norm ii = 1"
huffman@44902
   413
  by (simp add: i_def)
huffman@44902
   414
huffman@23125
   415
lemma complex_i_not_zero [simp]: "ii \<noteq> 0"
huffman@44724
   416
  by (simp add: complex_eq_iff)
huffman@23125
   417
huffman@23125
   418
lemma complex_i_not_one [simp]: "ii \<noteq> 1"
huffman@44724
   419
  by (simp add: complex_eq_iff)
huffman@23124
   420
huffman@47108
   421
lemma complex_i_not_numeral [simp]: "ii \<noteq> numeral w"
huffman@47108
   422
  by (simp add: complex_eq_iff)
huffman@47108
   423
huffman@47108
   424
lemma complex_i_not_neg_numeral [simp]: "ii \<noteq> neg_numeral w"
huffman@44724
   425
  by (simp add: complex_eq_iff)
huffman@23125
   426
huffman@23125
   427
lemma i_mult_Complex [simp]: "ii * Complex a b = Complex (- b) a"
huffman@44724
   428
  by (simp add: complex_eq_iff)
huffman@23125
   429
huffman@23125
   430
lemma Complex_mult_i [simp]: "Complex a b * ii = Complex (- b) a"
huffman@44724
   431
  by (simp add: complex_eq_iff)
huffman@23125
   432
huffman@23125
   433
lemma i_complex_of_real [simp]: "ii * complex_of_real r = Complex 0 r"
huffman@44724
   434
  by (simp add: i_def complex_of_real_def)
huffman@23125
   435
huffman@23125
   436
lemma complex_of_real_i [simp]: "complex_of_real r * ii = Complex 0 r"
huffman@44724
   437
  by (simp add: i_def complex_of_real_def)
huffman@23125
   438
huffman@23125
   439
lemma i_squared [simp]: "ii * ii = -1"
huffman@44724
   440
  by (simp add: i_def)
huffman@23125
   441
huffman@23125
   442
lemma power2_i [simp]: "ii\<twosuperior> = -1"
huffman@44724
   443
  by (simp add: power2_eq_square)
huffman@23125
   444
huffman@23125
   445
lemma inverse_i [simp]: "inverse ii = - ii"
huffman@44724
   446
  by (rule inverse_unique, simp)
paulson@14354
   447
huffman@44827
   448
lemma complex_i_mult_minus [simp]: "ii * (ii * x) = - x"
huffman@44827
   449
  by (simp add: mult_assoc [symmetric])
huffman@44827
   450
paulson@14354
   451
huffman@23125
   452
subsection {* Complex Conjugation *}
huffman@23125
   453
huffman@44724
   454
definition cnj :: "complex \<Rightarrow> complex" where
huffman@23125
   455
  "cnj z = Complex (Re z) (- Im z)"
huffman@23125
   456
huffman@23125
   457
lemma complex_cnj [simp]: "cnj (Complex a b) = Complex a (- b)"
huffman@44724
   458
  by (simp add: cnj_def)
huffman@23125
   459
huffman@23125
   460
lemma complex_Re_cnj [simp]: "Re (cnj x) = Re x"
huffman@44724
   461
  by (simp add: cnj_def)
huffman@23125
   462
huffman@23125
   463
lemma complex_Im_cnj [simp]: "Im (cnj x) = - Im x"
huffman@44724
   464
  by (simp add: cnj_def)
huffman@23125
   465
huffman@23125
   466
lemma complex_cnj_cancel_iff [simp]: "(cnj x = cnj y) = (x = y)"
huffman@44724
   467
  by (simp add: complex_eq_iff)
huffman@23125
   468
huffman@23125
   469
lemma complex_cnj_cnj [simp]: "cnj (cnj z) = z"
huffman@44724
   470
  by (simp add: cnj_def)
huffman@23125
   471
huffman@23125
   472
lemma complex_cnj_zero [simp]: "cnj 0 = 0"
huffman@44724
   473
  by (simp add: complex_eq_iff)
huffman@23125
   474
huffman@23125
   475
lemma complex_cnj_zero_iff [iff]: "(cnj z = 0) = (z = 0)"
huffman@44724
   476
  by (simp add: complex_eq_iff)
huffman@23125
   477
huffman@23125
   478
lemma complex_cnj_add: "cnj (x + y) = cnj x + cnj y"
huffman@44724
   479
  by (simp add: complex_eq_iff)
huffman@23125
   480
huffman@23125
   481
lemma complex_cnj_diff: "cnj (x - y) = cnj x - cnj y"
huffman@44724
   482
  by (simp add: complex_eq_iff)
huffman@23125
   483
huffman@23125
   484
lemma complex_cnj_minus: "cnj (- x) = - cnj x"
huffman@44724
   485
  by (simp add: complex_eq_iff)
huffman@23125
   486
huffman@23125
   487
lemma complex_cnj_one [simp]: "cnj 1 = 1"
huffman@44724
   488
  by (simp add: complex_eq_iff)
huffman@23125
   489
huffman@23125
   490
lemma complex_cnj_mult: "cnj (x * y) = cnj x * cnj y"
huffman@44724
   491
  by (simp add: complex_eq_iff)
huffman@23125
   492
huffman@23125
   493
lemma complex_cnj_inverse: "cnj (inverse x) = inverse (cnj x)"
huffman@44724
   494
  by (simp add: complex_inverse_def)
paulson@14323
   495
huffman@23125
   496
lemma complex_cnj_divide: "cnj (x / y) = cnj x / cnj y"
huffman@44724
   497
  by (simp add: complex_divide_def complex_cnj_mult complex_cnj_inverse)
huffman@23125
   498
huffman@23125
   499
lemma complex_cnj_power: "cnj (x ^ n) = cnj x ^ n"
huffman@44724
   500
  by (induct n, simp_all add: complex_cnj_mult)
huffman@23125
   501
huffman@23125
   502
lemma complex_cnj_of_nat [simp]: "cnj (of_nat n) = of_nat n"
huffman@44724
   503
  by (simp add: complex_eq_iff)
huffman@23125
   504
huffman@23125
   505
lemma complex_cnj_of_int [simp]: "cnj (of_int z) = of_int z"
huffman@44724
   506
  by (simp add: complex_eq_iff)
huffman@23125
   507
huffman@47108
   508
lemma complex_cnj_numeral [simp]: "cnj (numeral w) = numeral w"
huffman@47108
   509
  by (simp add: complex_eq_iff)
huffman@47108
   510
huffman@47108
   511
lemma complex_cnj_neg_numeral [simp]: "cnj (neg_numeral w) = neg_numeral w"
huffman@44724
   512
  by (simp add: complex_eq_iff)
huffman@23125
   513
huffman@23125
   514
lemma complex_cnj_scaleR: "cnj (scaleR r x) = scaleR r (cnj x)"
huffman@44724
   515
  by (simp add: complex_eq_iff)
huffman@23125
   516
huffman@23125
   517
lemma complex_mod_cnj [simp]: "cmod (cnj z) = cmod z"
huffman@44724
   518
  by (simp add: complex_norm_def)
paulson@14323
   519
huffman@23125
   520
lemma complex_cnj_complex_of_real [simp]: "cnj (of_real x) = of_real x"
huffman@44724
   521
  by (simp add: complex_eq_iff)
huffman@23125
   522
huffman@23125
   523
lemma complex_cnj_i [simp]: "cnj ii = - ii"
huffman@44724
   524
  by (simp add: complex_eq_iff)
huffman@23125
   525
huffman@23125
   526
lemma complex_add_cnj: "z + cnj z = complex_of_real (2 * Re z)"
huffman@44724
   527
  by (simp add: complex_eq_iff)
huffman@23125
   528
huffman@23125
   529
lemma complex_diff_cnj: "z - cnj z = complex_of_real (2 * Im z) * ii"
huffman@44724
   530
  by (simp add: complex_eq_iff)
paulson@14354
   531
huffman@23125
   532
lemma complex_mult_cnj: "z * cnj z = complex_of_real ((Re z)\<twosuperior> + (Im z)\<twosuperior>)"
huffman@44724
   533
  by (simp add: complex_eq_iff power2_eq_square)
huffman@23125
   534
huffman@23125
   535
lemma complex_mod_mult_cnj: "cmod (z * cnj z) = (cmod z)\<twosuperior>"
huffman@44724
   536
  by (simp add: norm_mult power2_eq_square)
huffman@23125
   537
huffman@44827
   538
lemma complex_mod_sqrt_Re_mult_cnj: "cmod z = sqrt (Re (z * cnj z))"
huffman@44827
   539
  by (simp add: cmod_def power2_eq_square)
huffman@44827
   540
huffman@44827
   541
lemma complex_In_mult_cnj_zero [simp]: "Im (z * cnj z) = 0"
huffman@44827
   542
  by simp
huffman@44827
   543
huffman@44290
   544
lemma bounded_linear_cnj: "bounded_linear cnj"
huffman@44127
   545
  using complex_cnj_add complex_cnj_scaleR
huffman@44127
   546
  by (rule bounded_linear_intro [where K=1], simp)
paulson@14354
   547
huffman@44290
   548
lemmas tendsto_cnj [tendsto_intros] =
huffman@44290
   549
  bounded_linear.tendsto [OF bounded_linear_cnj]
huffman@44290
   550
huffman@44290
   551
lemmas isCont_cnj [simp] =
huffman@44290
   552
  bounded_linear.isCont [OF bounded_linear_cnj]
huffman@44290
   553
paulson@14354
   554
paulson@14323
   555
subsection{*Finally! Polar Form for Complex Numbers*}
paulson@14323
   556
huffman@44827
   557
subsubsection {* $\cos \theta + i \sin \theta$ *}
huffman@20557
   558
huffman@44715
   559
definition cis :: "real \<Rightarrow> complex" where
huffman@20557
   560
  "cis a = Complex (cos a) (sin a)"
huffman@20557
   561
huffman@44827
   562
lemma Re_cis [simp]: "Re (cis a) = cos a"
huffman@44827
   563
  by (simp add: cis_def)
huffman@44827
   564
huffman@44827
   565
lemma Im_cis [simp]: "Im (cis a) = sin a"
huffman@44827
   566
  by (simp add: cis_def)
huffman@44827
   567
huffman@44827
   568
lemma cis_zero [simp]: "cis 0 = 1"
huffman@44827
   569
  by (simp add: cis_def)
huffman@44827
   570
huffman@44828
   571
lemma norm_cis [simp]: "norm (cis a) = 1"
huffman@44828
   572
  by (simp add: cis_def)
huffman@44828
   573
huffman@44828
   574
lemma sgn_cis [simp]: "sgn (cis a) = cis a"
huffman@44828
   575
  by (simp add: sgn_div_norm)
huffman@44828
   576
huffman@44828
   577
lemma cis_neq_zero [simp]: "cis a \<noteq> 0"
huffman@44828
   578
  by (metis norm_cis norm_zero zero_neq_one)
huffman@44828
   579
huffman@44827
   580
lemma cis_mult: "cis a * cis b = cis (a + b)"
huffman@44827
   581
  by (simp add: cis_def cos_add sin_add)
huffman@44827
   582
huffman@44827
   583
lemma DeMoivre: "(cis a) ^ n = cis (real n * a)"
huffman@44827
   584
  by (induct n, simp_all add: real_of_nat_Suc algebra_simps cis_mult)
huffman@44827
   585
huffman@44827
   586
lemma cis_inverse [simp]: "inverse(cis a) = cis (-a)"
huffman@44827
   587
  by (simp add: cis_def)
huffman@44827
   588
huffman@44827
   589
lemma cis_divide: "cis a / cis b = cis (a - b)"
huffman@44827
   590
  by (simp add: complex_divide_def cis_mult diff_minus)
huffman@44827
   591
huffman@44827
   592
lemma cos_n_Re_cis_pow_n: "cos (real n * a) = Re(cis a ^ n)"
huffman@44827
   593
  by (auto simp add: DeMoivre)
huffman@44827
   594
huffman@44827
   595
lemma sin_n_Im_cis_pow_n: "sin (real n * a) = Im(cis a ^ n)"
huffman@44827
   596
  by (auto simp add: DeMoivre)
huffman@44827
   597
huffman@44827
   598
subsubsection {* $r(\cos \theta + i \sin \theta)$ *}
huffman@44715
   599
huffman@44715
   600
definition rcis :: "[real, real] \<Rightarrow> complex" where
huffman@20557
   601
  "rcis r a = complex_of_real r * cis a"
huffman@20557
   602
huffman@44827
   603
lemma Re_rcis [simp]: "Re(rcis r a) = r * cos a"
huffman@44828
   604
  by (simp add: rcis_def)
huffman@44827
   605
huffman@44827
   606
lemma Im_rcis [simp]: "Im(rcis r a) = r * sin a"
huffman@44828
   607
  by (simp add: rcis_def)
huffman@44827
   608
huffman@44827
   609
lemma rcis_Ex: "\<exists>r a. z = rcis r a"
huffman@44828
   610
  by (simp add: complex_eq_iff polar_Ex)
huffman@44827
   611
huffman@44827
   612
lemma complex_mod_rcis [simp]: "cmod(rcis r a) = abs r"
huffman@44828
   613
  by (simp add: rcis_def norm_mult)
huffman@44827
   614
huffman@44827
   615
lemma cis_rcis_eq: "cis a = rcis 1 a"
huffman@44827
   616
  by (simp add: rcis_def)
huffman@44827
   617
huffman@44827
   618
lemma rcis_mult: "rcis r1 a * rcis r2 b = rcis (r1*r2) (a + b)"
huffman@44828
   619
  by (simp add: rcis_def cis_mult)
huffman@44827
   620
huffman@44827
   621
lemma rcis_zero_mod [simp]: "rcis 0 a = 0"
huffman@44827
   622
  by (simp add: rcis_def)
huffman@44827
   623
huffman@44827
   624
lemma rcis_zero_arg [simp]: "rcis r 0 = complex_of_real r"
huffman@44827
   625
  by (simp add: rcis_def)
huffman@44827
   626
huffman@44828
   627
lemma rcis_eq_zero_iff [simp]: "rcis r a = 0 \<longleftrightarrow> r = 0"
huffman@44828
   628
  by (simp add: rcis_def)
huffman@44828
   629
huffman@44827
   630
lemma DeMoivre2: "(rcis r a) ^ n = rcis (r ^ n) (real n * a)"
huffman@44827
   631
  by (simp add: rcis_def power_mult_distrib DeMoivre)
huffman@44827
   632
huffman@44827
   633
lemma rcis_inverse: "inverse(rcis r a) = rcis (1/r) (-a)"
huffman@44827
   634
  by (simp add: divide_inverse rcis_def)
huffman@44827
   635
huffman@44827
   636
lemma rcis_divide: "rcis r1 a / rcis r2 b = rcis (r1/r2) (a - b)"
huffman@44828
   637
  by (simp add: rcis_def cis_divide [symmetric])
huffman@44827
   638
huffman@44827
   639
subsubsection {* Complex exponential *}
huffman@44827
   640
huffman@44291
   641
abbreviation expi :: "complex \<Rightarrow> complex"
huffman@44291
   642
  where "expi \<equiv> exp"
huffman@44291
   643
huffman@44712
   644
lemma cis_conv_exp: "cis b = exp (Complex 0 b)"
huffman@44291
   645
proof (rule complex_eqI)
huffman@44291
   646
  { fix n have "Complex 0 b ^ n =
huffman@44291
   647
    real (fact n) *\<^sub>R Complex (cos_coeff n * b ^ n) (sin_coeff n * b ^ n)"
huffman@44291
   648
      apply (induct n)
huffman@44291
   649
      apply (simp add: cos_coeff_def sin_coeff_def)
huffman@44291
   650
      apply (simp add: sin_coeff_Suc cos_coeff_Suc del: mult_Suc)
huffman@44291
   651
      done } note * = this
huffman@44712
   652
  show "Re (cis b) = Re (exp (Complex 0 b))"
huffman@44291
   653
    unfolding exp_def cis_def cos_def
huffman@44291
   654
    by (subst bounded_linear.suminf[OF bounded_linear_Re summable_exp_generic],
huffman@44291
   655
      simp add: * mult_assoc [symmetric])
huffman@44712
   656
  show "Im (cis b) = Im (exp (Complex 0 b))"
huffman@44291
   657
    unfolding exp_def cis_def sin_def
huffman@44291
   658
    by (subst bounded_linear.suminf[OF bounded_linear_Im summable_exp_generic],
huffman@44291
   659
      simp add: * mult_assoc [symmetric])
huffman@44291
   660
qed
huffman@44291
   661
huffman@44291
   662
lemma expi_def: "expi z = complex_of_real (exp (Re z)) * cis (Im z)"
huffman@44712
   663
  unfolding cis_conv_exp exp_of_real [symmetric] mult_exp_exp by simp
huffman@20557
   664
huffman@44828
   665
lemma Re_exp: "Re (exp z) = exp (Re z) * cos (Im z)"
huffman@44828
   666
  unfolding expi_def by simp
huffman@44828
   667
huffman@44828
   668
lemma Im_exp: "Im (exp z) = exp (Re z) * sin (Im z)"
huffman@44828
   669
  unfolding expi_def by simp
huffman@44828
   670
paulson@14374
   671
lemma complex_expi_Ex: "\<exists>a r. z = complex_of_real r * expi a"
paulson@14373
   672
apply (insert rcis_Ex [of z])
huffman@23125
   673
apply (auto simp add: expi_def rcis_def mult_assoc [symmetric])
paulson@14334
   674
apply (rule_tac x = "ii * complex_of_real a" in exI, auto)
paulson@14323
   675
done
paulson@14323
   676
paulson@14387
   677
lemma expi_two_pi_i [simp]: "expi((2::complex) * complex_of_real pi * ii) = 1"
huffman@44724
   678
  by (simp add: expi_def cis_def)
paulson@14387
   679
huffman@44844
   680
subsubsection {* Complex argument *}
huffman@44844
   681
huffman@44844
   682
definition arg :: "complex \<Rightarrow> real" where
huffman@44844
   683
  "arg z = (if z = 0 then 0 else (SOME a. sgn z = cis a \<and> -pi < a \<and> a \<le> pi))"
huffman@44844
   684
huffman@44844
   685
lemma arg_zero: "arg 0 = 0"
huffman@44844
   686
  by (simp add: arg_def)
huffman@44844
   687
huffman@44844
   688
lemma of_nat_less_of_int_iff: (* TODO: move *)
huffman@44844
   689
  "(of_nat n :: 'a::linordered_idom) < of_int x \<longleftrightarrow> int n < x"
huffman@44844
   690
  by (metis of_int_of_nat_eq of_int_less_iff)
huffman@44844
   691
huffman@47108
   692
lemma real_of_nat_less_numeral_iff [simp]: (* TODO: move *)
huffman@47108
   693
  "real (n::nat) < numeral w \<longleftrightarrow> n < numeral w"
huffman@47108
   694
  using of_nat_less_of_int_iff [of n "numeral w", where 'a=real]
huffman@47108
   695
  by (simp add: real_of_nat_def zless_nat_eq_int_zless [symmetric])
huffman@44844
   696
huffman@44844
   697
lemma arg_unique:
huffman@44844
   698
  assumes "sgn z = cis x" and "-pi < x" and "x \<le> pi"
huffman@44844
   699
  shows "arg z = x"
huffman@44844
   700
proof -
huffman@44844
   701
  from assms have "z \<noteq> 0" by auto
huffman@44844
   702
  have "(SOME a. sgn z = cis a \<and> -pi < a \<and> a \<le> pi) = x"
huffman@44844
   703
  proof
huffman@44844
   704
    fix a def d \<equiv> "a - x"
huffman@44844
   705
    assume a: "sgn z = cis a \<and> - pi < a \<and> a \<le> pi"
huffman@44844
   706
    from a assms have "- (2*pi) < d \<and> d < 2*pi"
huffman@44844
   707
      unfolding d_def by simp
huffman@44844
   708
    moreover from a assms have "cos a = cos x" and "sin a = sin x"
huffman@44844
   709
      by (simp_all add: complex_eq_iff)
huffman@44844
   710
    hence "cos d = 1" unfolding d_def cos_diff by simp
huffman@44844
   711
    moreover hence "sin d = 0" by (rule cos_one_sin_zero)
huffman@44844
   712
    ultimately have "d = 0"
huffman@44844
   713
      unfolding sin_zero_iff even_mult_two_ex
huffman@44844
   714
      by (safe, auto simp add: numeral_2_eq_2 less_Suc_eq)
huffman@44844
   715
    thus "a = x" unfolding d_def by simp
huffman@44844
   716
  qed (simp add: assms del: Re_sgn Im_sgn)
huffman@44844
   717
  with `z \<noteq> 0` show "arg z = x"
huffman@44844
   718
    unfolding arg_def by simp
huffman@44844
   719
qed
huffman@44844
   720
huffman@44844
   721
lemma arg_correct:
huffman@44844
   722
  assumes "z \<noteq> 0" shows "sgn z = cis (arg z) \<and> -pi < arg z \<and> arg z \<le> pi"
huffman@44844
   723
proof (simp add: arg_def assms, rule someI_ex)
huffman@44844
   724
  obtain r a where z: "z = rcis r a" using rcis_Ex by fast
huffman@44844
   725
  with assms have "r \<noteq> 0" by auto
huffman@44844
   726
  def b \<equiv> "if 0 < r then a else a + pi"
huffman@44844
   727
  have b: "sgn z = cis b"
huffman@44844
   728
    unfolding z b_def rcis_def using `r \<noteq> 0`
huffman@44844
   729
    by (simp add: of_real_def sgn_scaleR sgn_if, simp add: cis_def)
huffman@44844
   730
  have cis_2pi_nat: "\<And>n. cis (2 * pi * real_of_nat n) = 1"
webertj@49962
   731
    by (induct_tac n, simp_all add: distrib_left cis_mult [symmetric],
huffman@44844
   732
      simp add: cis_def)
huffman@44844
   733
  have cis_2pi_int: "\<And>x. cis (2 * pi * real_of_int x) = 1"
huffman@44844
   734
    by (case_tac x rule: int_diff_cases,
huffman@44844
   735
      simp add: right_diff_distrib cis_divide [symmetric] cis_2pi_nat)
huffman@44844
   736
  def c \<equiv> "b - 2*pi * of_int \<lceil>(b - pi) / (2*pi)\<rceil>"
huffman@44844
   737
  have "sgn z = cis c"
huffman@44844
   738
    unfolding b c_def
huffman@44844
   739
    by (simp add: cis_divide [symmetric] cis_2pi_int)
huffman@44844
   740
  moreover have "- pi < c \<and> c \<le> pi"
huffman@44844
   741
    using ceiling_correct [of "(b - pi) / (2*pi)"]
huffman@44844
   742
    by (simp add: c_def less_divide_eq divide_le_eq algebra_simps)
huffman@44844
   743
  ultimately show "\<exists>a. sgn z = cis a \<and> -pi < a \<and> a \<le> pi" by fast
huffman@44844
   744
qed
huffman@44844
   745
huffman@44844
   746
lemma arg_bounded: "- pi < arg z \<and> arg z \<le> pi"
huffman@44844
   747
  by (cases "z = 0", simp_all add: arg_zero arg_correct)
huffman@44844
   748
huffman@44844
   749
lemma cis_arg: "z \<noteq> 0 \<Longrightarrow> cis (arg z) = sgn z"
huffman@44844
   750
  by (simp add: arg_correct)
huffman@44844
   751
huffman@44844
   752
lemma rcis_cmod_arg: "rcis (cmod z) (arg z) = z"
huffman@44844
   753
  by (cases "z = 0", simp_all add: rcis_def cis_arg sgn_div_norm of_real_def)
huffman@44844
   754
huffman@44844
   755
lemma cos_arg_i_mult_zero [simp]:
huffman@44844
   756
     "y \<noteq> 0 ==> cos (arg(Complex 0 y)) = 0"
huffman@44844
   757
  using cis_arg [of "Complex 0 y"] by (simp add: complex_eq_iff)
huffman@44844
   758
huffman@44065
   759
text {* Legacy theorem names *}
huffman@44065
   760
huffman@44065
   761
lemmas expand_complex_eq = complex_eq_iff
huffman@44065
   762
lemmas complex_Re_Im_cancel_iff = complex_eq_iff
huffman@44065
   763
lemmas complex_equality = complex_eqI
huffman@44065
   764
paulson@13957
   765
end