src/HOL/Library/List_Prefix.thy
author wenzelm
Thu Feb 11 23:00:22 2010 +0100 (2010-02-11)
changeset 35115 446c5063e4fd
parent 30663 0b6aff7451b2
child 37474 ce943f9edf5e
permissions -rw-r--r--
modernized translations;
formal markup of @{syntax_const} and @{const_syntax};
minor tuning;
wenzelm@10330
     1
(*  Title:      HOL/Library/List_Prefix.thy
wenzelm@10330
     2
    Author:     Tobias Nipkow and Markus Wenzel, TU Muenchen
wenzelm@10330
     3
*)
wenzelm@10330
     4
wenzelm@14706
     5
header {* List prefixes and postfixes *}
wenzelm@10330
     6
nipkow@15131
     7
theory List_Prefix
haftmann@30663
     8
imports List Main
nipkow@15131
     9
begin
wenzelm@10330
    10
wenzelm@10330
    11
subsection {* Prefix order on lists *}
wenzelm@10330
    12
haftmann@25764
    13
instantiation list :: (type) order
haftmann@25764
    14
begin
haftmann@25764
    15
haftmann@25764
    16
definition
haftmann@28562
    17
  prefix_def [code del]: "xs \<le> ys = (\<exists>zs. ys = xs @ zs)"
wenzelm@10330
    18
haftmann@25764
    19
definition
haftmann@28562
    20
  strict_prefix_def [code del]: "xs < ys = (xs \<le> ys \<and> xs \<noteq> (ys::'a list))"
wenzelm@10330
    21
haftmann@25764
    22
instance
wenzelm@10389
    23
  by intro_classes (auto simp add: prefix_def strict_prefix_def)
wenzelm@10330
    24
haftmann@25764
    25
end
haftmann@25764
    26
wenzelm@10389
    27
lemma prefixI [intro?]: "ys = xs @ zs ==> xs \<le> ys"
wenzelm@18730
    28
  unfolding prefix_def by blast
wenzelm@10330
    29
wenzelm@21305
    30
lemma prefixE [elim?]:
wenzelm@21305
    31
  assumes "xs \<le> ys"
wenzelm@21305
    32
  obtains zs where "ys = xs @ zs"
wenzelm@23394
    33
  using assms unfolding prefix_def by blast
wenzelm@10330
    34
wenzelm@10870
    35
lemma strict_prefixI' [intro?]: "ys = xs @ z # zs ==> xs < ys"
wenzelm@18730
    36
  unfolding strict_prefix_def prefix_def by blast
wenzelm@10870
    37
wenzelm@10870
    38
lemma strict_prefixE' [elim?]:
wenzelm@21305
    39
  assumes "xs < ys"
wenzelm@21305
    40
  obtains z zs where "ys = xs @ z # zs"
wenzelm@10870
    41
proof -
wenzelm@21305
    42
  from `xs < ys` obtain us where "ys = xs @ us" and "xs \<noteq> ys"
wenzelm@18730
    43
    unfolding strict_prefix_def prefix_def by blast
wenzelm@21305
    44
  with that show ?thesis by (auto simp add: neq_Nil_conv)
wenzelm@10870
    45
qed
wenzelm@10870
    46
wenzelm@10389
    47
lemma strict_prefixI [intro?]: "xs \<le> ys ==> xs \<noteq> ys ==> xs < (ys::'a list)"
wenzelm@18730
    48
  unfolding strict_prefix_def by blast
wenzelm@10330
    49
wenzelm@10389
    50
lemma strict_prefixE [elim?]:
wenzelm@21305
    51
  fixes xs ys :: "'a list"
wenzelm@21305
    52
  assumes "xs < ys"
wenzelm@21305
    53
  obtains "xs \<le> ys" and "xs \<noteq> ys"
wenzelm@23394
    54
  using assms unfolding strict_prefix_def by blast
wenzelm@10330
    55
wenzelm@10330
    56
wenzelm@10389
    57
subsection {* Basic properties of prefixes *}
wenzelm@10330
    58
wenzelm@10330
    59
theorem Nil_prefix [iff]: "[] \<le> xs"
wenzelm@10389
    60
  by (simp add: prefix_def)
wenzelm@10330
    61
wenzelm@10330
    62
theorem prefix_Nil [simp]: "(xs \<le> []) = (xs = [])"
wenzelm@10389
    63
  by (induct xs) (simp_all add: prefix_def)
wenzelm@10330
    64
wenzelm@10330
    65
lemma prefix_snoc [simp]: "(xs \<le> ys @ [y]) = (xs = ys @ [y] \<or> xs \<le> ys)"
wenzelm@10389
    66
proof
wenzelm@10389
    67
  assume "xs \<le> ys @ [y]"
wenzelm@10389
    68
  then obtain zs where zs: "ys @ [y] = xs @ zs" ..
wenzelm@10389
    69
  show "xs = ys @ [y] \<or> xs \<le> ys"
nipkow@25564
    70
    by (metis append_Nil2 butlast_append butlast_snoc prefixI zs)
wenzelm@10389
    71
next
wenzelm@10389
    72
  assume "xs = ys @ [y] \<or> xs \<le> ys"
wenzelm@23254
    73
  then show "xs \<le> ys @ [y]"
nipkow@25564
    74
    by (metis order_eq_iff strict_prefixE strict_prefixI' xt1(7))
wenzelm@10389
    75
qed
wenzelm@10330
    76
wenzelm@10330
    77
lemma Cons_prefix_Cons [simp]: "(x # xs \<le> y # ys) = (x = y \<and> xs \<le> ys)"
wenzelm@10389
    78
  by (auto simp add: prefix_def)
wenzelm@10330
    79
wenzelm@10330
    80
lemma same_prefix_prefix [simp]: "(xs @ ys \<le> xs @ zs) = (ys \<le> zs)"
wenzelm@10389
    81
  by (induct xs) simp_all
wenzelm@10330
    82
wenzelm@10389
    83
lemma same_prefix_nil [iff]: "(xs @ ys \<le> xs) = (ys = [])"
wenzelm@25692
    84
  by (metis append_Nil2 append_self_conv order_eq_iff prefixI)
nipkow@25665
    85
wenzelm@10330
    86
lemma prefix_prefix [simp]: "xs \<le> ys ==> xs \<le> ys @ zs"
wenzelm@25692
    87
  by (metis order_le_less_trans prefixI strict_prefixE strict_prefixI)
nipkow@25665
    88
nipkow@14300
    89
lemma append_prefixD: "xs @ ys \<le> zs \<Longrightarrow> xs \<le> zs"
wenzelm@17201
    90
  by (auto simp add: prefix_def)
nipkow@14300
    91
wenzelm@10330
    92
theorem prefix_Cons: "(xs \<le> y # ys) = (xs = [] \<or> (\<exists>zs. xs = y # zs \<and> zs \<le> ys))"
wenzelm@10389
    93
  by (cases xs) (auto simp add: prefix_def)
wenzelm@10330
    94
wenzelm@10330
    95
theorem prefix_append:
nipkow@25564
    96
  "(xs \<le> ys @ zs) = (xs \<le> ys \<or> (\<exists>us. xs = ys @ us \<and> us \<le> zs))"
wenzelm@10330
    97
  apply (induct zs rule: rev_induct)
wenzelm@10330
    98
   apply force
wenzelm@10330
    99
  apply (simp del: append_assoc add: append_assoc [symmetric])
nipkow@25564
   100
  apply (metis append_eq_appendI)
wenzelm@10330
   101
  done
wenzelm@10330
   102
wenzelm@10330
   103
lemma append_one_prefix:
nipkow@25564
   104
  "xs \<le> ys ==> length xs < length ys ==> xs @ [ys ! length xs] \<le> ys"
wenzelm@25692
   105
  unfolding prefix_def
wenzelm@25692
   106
  by (metis Cons_eq_appendI append_eq_appendI append_eq_conv_conj
wenzelm@25692
   107
    eq_Nil_appendI nth_drop')
nipkow@25665
   108
wenzelm@10330
   109
theorem prefix_length_le: "xs \<le> ys ==> length xs \<le> length ys"
wenzelm@10389
   110
  by (auto simp add: prefix_def)
wenzelm@10330
   111
nipkow@14300
   112
lemma prefix_same_cases:
nipkow@25564
   113
  "(xs\<^isub>1::'a list) \<le> ys \<Longrightarrow> xs\<^isub>2 \<le> ys \<Longrightarrow> xs\<^isub>1 \<le> xs\<^isub>2 \<or> xs\<^isub>2 \<le> xs\<^isub>1"
wenzelm@25692
   114
  unfolding prefix_def by (metis append_eq_append_conv2)
nipkow@25665
   115
nipkow@25564
   116
lemma set_mono_prefix: "xs \<le> ys \<Longrightarrow> set xs \<subseteq> set ys"
wenzelm@25692
   117
  by (auto simp add: prefix_def)
nipkow@14300
   118
nipkow@25564
   119
lemma take_is_prefix: "take n xs \<le> xs"
wenzelm@25692
   120
  unfolding prefix_def by (metis append_take_drop_id)
nipkow@25665
   121
wenzelm@25692
   122
lemma map_prefixI: "xs \<le> ys \<Longrightarrow> map f xs \<le> map f ys"
wenzelm@25692
   123
  by (auto simp: prefix_def)
kleing@25322
   124
wenzelm@25692
   125
lemma prefix_length_less: "xs < ys \<Longrightarrow> length xs < length ys"
wenzelm@25692
   126
  by (auto simp: strict_prefix_def prefix_def)
nipkow@25665
   127
kleing@25299
   128
lemma strict_prefix_simps [simp]:
wenzelm@25692
   129
    "xs < [] = False"
wenzelm@25692
   130
    "[] < (x # xs) = True"
wenzelm@25692
   131
    "(x # xs) < (y # ys) = (x = y \<and> xs < ys)"
wenzelm@25692
   132
  by (simp_all add: strict_prefix_def cong: conj_cong)
kleing@25299
   133
nipkow@25564
   134
lemma take_strict_prefix: "xs < ys \<Longrightarrow> take n xs < ys"
wenzelm@25692
   135
  apply (induct n arbitrary: xs ys)
wenzelm@25692
   136
   apply (case_tac ys, simp_all)[1]
wenzelm@25692
   137
  apply (metis order_less_trans strict_prefixI take_is_prefix)
wenzelm@25692
   138
  done
kleing@25299
   139
wenzelm@25355
   140
lemma not_prefix_cases:
kleing@25299
   141
  assumes pfx: "\<not> ps \<le> ls"
wenzelm@25356
   142
  obtains
wenzelm@25356
   143
    (c1) "ps \<noteq> []" and "ls = []"
wenzelm@25356
   144
  | (c2) a as x xs where "ps = a#as" and "ls = x#xs" and "x = a" and "\<not> as \<le> xs"
wenzelm@25356
   145
  | (c3) a as x xs where "ps = a#as" and "ls = x#xs" and "x \<noteq> a"
kleing@25299
   146
proof (cases ps)
wenzelm@25692
   147
  case Nil then show ?thesis using pfx by simp
kleing@25299
   148
next
kleing@25299
   149
  case (Cons a as)
wenzelm@25692
   150
  note c = `ps = a#as`
kleing@25299
   151
  show ?thesis
kleing@25299
   152
  proof (cases ls)
wenzelm@25692
   153
    case Nil then show ?thesis by (metis append_Nil2 pfx c1 same_prefix_nil)
kleing@25299
   154
  next
kleing@25299
   155
    case (Cons x xs)
kleing@25299
   156
    show ?thesis
kleing@25299
   157
    proof (cases "x = a")
wenzelm@25355
   158
      case True
wenzelm@25355
   159
      have "\<not> as \<le> xs" using pfx c Cons True by simp
wenzelm@25355
   160
      with c Cons True show ?thesis by (rule c2)
wenzelm@25355
   161
    next
wenzelm@25355
   162
      case False
wenzelm@25355
   163
      with c Cons show ?thesis by (rule c3)
kleing@25299
   164
    qed
kleing@25299
   165
  qed
kleing@25299
   166
qed
kleing@25299
   167
kleing@25299
   168
lemma not_prefix_induct [consumes 1, case_names Nil Neq Eq]:
kleing@25299
   169
  assumes np: "\<not> ps \<le> ls"
wenzelm@25356
   170
    and base: "\<And>x xs. P (x#xs) []"
wenzelm@25356
   171
    and r1: "\<And>x xs y ys. x \<noteq> y \<Longrightarrow> P (x#xs) (y#ys)"
wenzelm@25356
   172
    and r2: "\<And>x xs y ys. \<lbrakk> x = y; \<not> xs \<le> ys; P xs ys \<rbrakk> \<Longrightarrow> P (x#xs) (y#ys)"
wenzelm@25356
   173
  shows "P ps ls" using np
kleing@25299
   174
proof (induct ls arbitrary: ps)
wenzelm@25355
   175
  case Nil then show ?case
kleing@25299
   176
    by (auto simp: neq_Nil_conv elim!: not_prefix_cases intro!: base)
kleing@25299
   177
next
wenzelm@25355
   178
  case (Cons y ys)
wenzelm@25355
   179
  then have npfx: "\<not> ps \<le> (y # ys)" by simp
wenzelm@25355
   180
  then obtain x xs where pv: "ps = x # xs"
kleing@25299
   181
    by (rule not_prefix_cases) auto
nipkow@25564
   182
  show ?case by (metis Cons.hyps Cons_prefix_Cons npfx pv r1 r2)
kleing@25299
   183
qed
nipkow@14300
   184
wenzelm@25356
   185
wenzelm@10389
   186
subsection {* Parallel lists *}
wenzelm@10389
   187
wenzelm@19086
   188
definition
wenzelm@21404
   189
  parallel :: "'a list => 'a list => bool"  (infixl "\<parallel>" 50) where
wenzelm@19086
   190
  "(xs \<parallel> ys) = (\<not> xs \<le> ys \<and> \<not> ys \<le> xs)"
wenzelm@10389
   191
wenzelm@10389
   192
lemma parallelI [intro]: "\<not> xs \<le> ys ==> \<not> ys \<le> xs ==> xs \<parallel> ys"
wenzelm@25692
   193
  unfolding parallel_def by blast
wenzelm@10330
   194
wenzelm@10389
   195
lemma parallelE [elim]:
wenzelm@25692
   196
  assumes "xs \<parallel> ys"
wenzelm@25692
   197
  obtains "\<not> xs \<le> ys \<and> \<not> ys \<le> xs"
wenzelm@25692
   198
  using assms unfolding parallel_def by blast
wenzelm@10330
   199
wenzelm@10389
   200
theorem prefix_cases:
wenzelm@25692
   201
  obtains "xs \<le> ys" | "ys < xs" | "xs \<parallel> ys"
wenzelm@25692
   202
  unfolding parallel_def strict_prefix_def by blast
wenzelm@10330
   203
wenzelm@10389
   204
theorem parallel_decomp:
wenzelm@10389
   205
  "xs \<parallel> ys ==> \<exists>as b bs c cs. b \<noteq> c \<and> xs = as @ b # bs \<and> ys = as @ c # cs"
wenzelm@10408
   206
proof (induct xs rule: rev_induct)
wenzelm@11987
   207
  case Nil
wenzelm@23254
   208
  then have False by auto
wenzelm@23254
   209
  then show ?case ..
wenzelm@10408
   210
next
wenzelm@11987
   211
  case (snoc x xs)
wenzelm@11987
   212
  show ?case
wenzelm@10408
   213
  proof (rule prefix_cases)
wenzelm@10408
   214
    assume le: "xs \<le> ys"
wenzelm@10408
   215
    then obtain ys' where ys: "ys = xs @ ys'" ..
wenzelm@10408
   216
    show ?thesis
wenzelm@10408
   217
    proof (cases ys')
nipkow@25564
   218
      assume "ys' = []"
wenzelm@25692
   219
      then show ?thesis by (metis append_Nil2 parallelE prefixI snoc.prems ys)
wenzelm@10389
   220
    next
wenzelm@10408
   221
      fix c cs assume ys': "ys' = c # cs"
wenzelm@25692
   222
      then show ?thesis
wenzelm@25692
   223
        by (metis Cons_eq_appendI eq_Nil_appendI parallelE prefixI
wenzelm@25692
   224
          same_prefix_prefix snoc.prems ys)
wenzelm@10389
   225
    qed
wenzelm@10408
   226
  next
wenzelm@23254
   227
    assume "ys < xs" then have "ys \<le> xs @ [x]" by (simp add: strict_prefix_def)
wenzelm@11987
   228
    with snoc have False by blast
wenzelm@23254
   229
    then show ?thesis ..
wenzelm@10408
   230
  next
wenzelm@10408
   231
    assume "xs \<parallel> ys"
wenzelm@11987
   232
    with snoc obtain as b bs c cs where neq: "(b::'a) \<noteq> c"
wenzelm@10408
   233
      and xs: "xs = as @ b # bs" and ys: "ys = as @ c # cs"
wenzelm@10408
   234
      by blast
wenzelm@10408
   235
    from xs have "xs @ [x] = as @ b # (bs @ [x])" by simp
wenzelm@10408
   236
    with neq ys show ?thesis by blast
wenzelm@10389
   237
  qed
wenzelm@10389
   238
qed
wenzelm@10330
   239
nipkow@25564
   240
lemma parallel_append: "a \<parallel> b \<Longrightarrow> a @ c \<parallel> b @ d"
wenzelm@25692
   241
  apply (rule parallelI)
wenzelm@25692
   242
    apply (erule parallelE, erule conjE,
wenzelm@25692
   243
      induct rule: not_prefix_induct, simp+)+
wenzelm@25692
   244
  done
kleing@25299
   245
wenzelm@25692
   246
lemma parallel_appendI: "xs \<parallel> ys \<Longrightarrow> x = xs @ xs' \<Longrightarrow> y = ys @ ys' \<Longrightarrow> x \<parallel> y"
wenzelm@25692
   247
  by (simp add: parallel_append)
kleing@25299
   248
wenzelm@25692
   249
lemma parallel_commute: "a \<parallel> b \<longleftrightarrow> b \<parallel> a"
wenzelm@25692
   250
  unfolding parallel_def by auto
oheimb@14538
   251
wenzelm@25356
   252
oheimb@14538
   253
subsection {* Postfix order on lists *}
wenzelm@17201
   254
wenzelm@19086
   255
definition
wenzelm@21404
   256
  postfix :: "'a list => 'a list => bool"  ("(_/ >>= _)" [51, 50] 50) where
wenzelm@19086
   257
  "(xs >>= ys) = (\<exists>zs. xs = zs @ ys)"
oheimb@14538
   258
wenzelm@21305
   259
lemma postfixI [intro?]: "xs = zs @ ys ==> xs >>= ys"
wenzelm@25692
   260
  unfolding postfix_def by blast
wenzelm@21305
   261
wenzelm@21305
   262
lemma postfixE [elim?]:
wenzelm@25692
   263
  assumes "xs >>= ys"
wenzelm@25692
   264
  obtains zs where "xs = zs @ ys"
wenzelm@25692
   265
  using assms unfolding postfix_def by blast
wenzelm@21305
   266
wenzelm@21305
   267
lemma postfix_refl [iff]: "xs >>= xs"
wenzelm@14706
   268
  by (auto simp add: postfix_def)
wenzelm@17201
   269
lemma postfix_trans: "\<lbrakk>xs >>= ys; ys >>= zs\<rbrakk> \<Longrightarrow> xs >>= zs"
wenzelm@14706
   270
  by (auto simp add: postfix_def)
wenzelm@17201
   271
lemma postfix_antisym: "\<lbrakk>xs >>= ys; ys >>= xs\<rbrakk> \<Longrightarrow> xs = ys"
wenzelm@14706
   272
  by (auto simp add: postfix_def)
oheimb@14538
   273
wenzelm@17201
   274
lemma Nil_postfix [iff]: "xs >>= []"
wenzelm@14706
   275
  by (simp add: postfix_def)
wenzelm@17201
   276
lemma postfix_Nil [simp]: "([] >>= xs) = (xs = [])"
wenzelm@21305
   277
  by (auto simp add: postfix_def)
oheimb@14538
   278
wenzelm@17201
   279
lemma postfix_ConsI: "xs >>= ys \<Longrightarrow> x#xs >>= ys"
wenzelm@14706
   280
  by (auto simp add: postfix_def)
wenzelm@17201
   281
lemma postfix_ConsD: "xs >>= y#ys \<Longrightarrow> xs >>= ys"
wenzelm@14706
   282
  by (auto simp add: postfix_def)
oheimb@14538
   283
wenzelm@17201
   284
lemma postfix_appendI: "xs >>= ys \<Longrightarrow> zs @ xs >>= ys"
wenzelm@14706
   285
  by (auto simp add: postfix_def)
wenzelm@17201
   286
lemma postfix_appendD: "xs >>= zs @ ys \<Longrightarrow> xs >>= ys"
wenzelm@21305
   287
  by (auto simp add: postfix_def)
oheimb@14538
   288
wenzelm@21305
   289
lemma postfix_is_subset: "xs >>= ys ==> set ys \<subseteq> set xs"
wenzelm@21305
   290
proof -
wenzelm@21305
   291
  assume "xs >>= ys"
wenzelm@21305
   292
  then obtain zs where "xs = zs @ ys" ..
wenzelm@21305
   293
  then show ?thesis by (induct zs) auto
wenzelm@21305
   294
qed
oheimb@14538
   295
wenzelm@21305
   296
lemma postfix_ConsD2: "x#xs >>= y#ys ==> xs >>= ys"
wenzelm@21305
   297
proof -
wenzelm@21305
   298
  assume "x#xs >>= y#ys"
wenzelm@21305
   299
  then obtain zs where "x#xs = zs @ y#ys" ..
wenzelm@21305
   300
  then show ?thesis
wenzelm@21305
   301
    by (induct zs) (auto intro!: postfix_appendI postfix_ConsI)
wenzelm@21305
   302
qed
oheimb@14538
   303
wenzelm@21305
   304
lemma postfix_to_prefix: "xs >>= ys \<longleftrightarrow> rev ys \<le> rev xs"
wenzelm@21305
   305
proof
wenzelm@21305
   306
  assume "xs >>= ys"
wenzelm@21305
   307
  then obtain zs where "xs = zs @ ys" ..
wenzelm@21305
   308
  then have "rev xs = rev ys @ rev zs" by simp
wenzelm@21305
   309
  then show "rev ys <= rev xs" ..
wenzelm@21305
   310
next
wenzelm@21305
   311
  assume "rev ys <= rev xs"
wenzelm@21305
   312
  then obtain zs where "rev xs = rev ys @ zs" ..
wenzelm@21305
   313
  then have "rev (rev xs) = rev zs @ rev (rev ys)" by simp
wenzelm@21305
   314
  then have "xs = rev zs @ ys" by simp
wenzelm@21305
   315
  then show "xs >>= ys" ..
wenzelm@21305
   316
qed
wenzelm@17201
   317
nipkow@25564
   318
lemma distinct_postfix: "distinct xs \<Longrightarrow> xs >>= ys \<Longrightarrow> distinct ys"
wenzelm@25692
   319
  by (clarsimp elim!: postfixE)
kleing@25299
   320
nipkow@25564
   321
lemma postfix_map: "xs >>= ys \<Longrightarrow> map f xs >>= map f ys"
wenzelm@25692
   322
  by (auto elim!: postfixE intro: postfixI)
kleing@25299
   323
wenzelm@25356
   324
lemma postfix_drop: "as >>= drop n as"
wenzelm@25692
   325
  unfolding postfix_def
wenzelm@25692
   326
  apply (rule exI [where x = "take n as"])
wenzelm@25692
   327
  apply simp
wenzelm@25692
   328
  done
kleing@25299
   329
nipkow@25564
   330
lemma postfix_take: "xs >>= ys \<Longrightarrow> xs = take (length xs - length ys) xs @ ys"
wenzelm@25692
   331
  by (clarsimp elim!: postfixE)
kleing@25299
   332
wenzelm@25356
   333
lemma parallelD1: "x \<parallel> y \<Longrightarrow> \<not> x \<le> y"
wenzelm@25692
   334
  by blast
kleing@25299
   335
wenzelm@25356
   336
lemma parallelD2: "x \<parallel> y \<Longrightarrow> \<not> y \<le> x"
wenzelm@25692
   337
  by blast
wenzelm@25355
   338
wenzelm@25355
   339
lemma parallel_Nil1 [simp]: "\<not> x \<parallel> []"
wenzelm@25692
   340
  unfolding parallel_def by simp
wenzelm@25355
   341
kleing@25299
   342
lemma parallel_Nil2 [simp]: "\<not> [] \<parallel> x"
wenzelm@25692
   343
  unfolding parallel_def by simp
kleing@25299
   344
nipkow@25564
   345
lemma Cons_parallelI1: "a \<noteq> b \<Longrightarrow> a # as \<parallel> b # bs"
wenzelm@25692
   346
  by auto
kleing@25299
   347
nipkow@25564
   348
lemma Cons_parallelI2: "\<lbrakk> a = b; as \<parallel> bs \<rbrakk> \<Longrightarrow> a # as \<parallel> b # bs"
wenzelm@25692
   349
  by (metis Cons_prefix_Cons parallelE parallelI)
nipkow@25665
   350
kleing@25299
   351
lemma not_equal_is_parallel:
kleing@25299
   352
  assumes neq: "xs \<noteq> ys"
wenzelm@25356
   353
    and len: "length xs = length ys"
wenzelm@25356
   354
  shows "xs \<parallel> ys"
kleing@25299
   355
  using len neq
wenzelm@25355
   356
proof (induct rule: list_induct2)
haftmann@26445
   357
  case Nil
wenzelm@25356
   358
  then show ?case by simp
kleing@25299
   359
next
haftmann@26445
   360
  case (Cons a as b bs)
wenzelm@25355
   361
  have ih: "as \<noteq> bs \<Longrightarrow> as \<parallel> bs" by fact
kleing@25299
   362
  show ?case
kleing@25299
   363
  proof (cases "a = b")
wenzelm@25355
   364
    case True
haftmann@26445
   365
    then have "as \<noteq> bs" using Cons by simp
wenzelm@25355
   366
    then show ?thesis by (rule Cons_parallelI2 [OF True ih])
kleing@25299
   367
  next
kleing@25299
   368
    case False
wenzelm@25355
   369
    then show ?thesis by (rule Cons_parallelI1)
kleing@25299
   370
  qed
kleing@25299
   371
qed
haftmann@22178
   372
wenzelm@25355
   373
wenzelm@25356
   374
subsection {* Executable code *}
haftmann@22178
   375
haftmann@28562
   376
lemma less_eq_code [code]:
wenzelm@25356
   377
    "([]\<Colon>'a\<Colon>{eq, ord} list) \<le> xs \<longleftrightarrow> True"
wenzelm@25356
   378
    "(x\<Colon>'a\<Colon>{eq, ord}) # xs \<le> [] \<longleftrightarrow> False"
wenzelm@25356
   379
    "(x\<Colon>'a\<Colon>{eq, ord}) # xs \<le> y # ys \<longleftrightarrow> x = y \<and> xs \<le> ys"
haftmann@22178
   380
  by simp_all
haftmann@22178
   381
haftmann@28562
   382
lemma less_code [code]:
wenzelm@25356
   383
    "xs < ([]\<Colon>'a\<Colon>{eq, ord} list) \<longleftrightarrow> False"
wenzelm@25356
   384
    "[] < (x\<Colon>'a\<Colon>{eq, ord})# xs \<longleftrightarrow> True"
wenzelm@25356
   385
    "(x\<Colon>'a\<Colon>{eq, ord}) # xs < y # ys \<longleftrightarrow> x = y \<and> xs < ys"
haftmann@22178
   386
  unfolding strict_prefix_def by auto
haftmann@22178
   387
haftmann@28562
   388
lemmas [code] = postfix_to_prefix
haftmann@22178
   389
wenzelm@10330
   390
end