src/HOL/RealVector.thy
author haftmann
Wed Jan 21 23:40:23 2009 +0100 (2009-01-21)
changeset 29608 564ea783ace8
parent 29252 ea97aa6aeba2
child 30069 e2fe62de0925
child 30240 5b25fee0362c
permissions -rw-r--r--
no base sort in class import
haftmann@29197
     1
(*  Title:      HOL/RealVector.thy
haftmann@27552
     2
    Author:     Brian Huffman
huffman@20504
     3
*)
huffman@20504
     4
huffman@20504
     5
header {* Vector Spaces and Algebras over the Reals *}
huffman@20504
     6
huffman@20504
     7
theory RealVector
haftmann@29197
     8
imports RealPow
huffman@20504
     9
begin
huffman@20504
    10
huffman@20504
    11
subsection {* Locale for additive functions *}
huffman@20504
    12
huffman@20504
    13
locale additive =
huffman@20504
    14
  fixes f :: "'a::ab_group_add \<Rightarrow> 'b::ab_group_add"
huffman@20504
    15
  assumes add: "f (x + y) = f x + f y"
huffman@27443
    16
begin
huffman@20504
    17
huffman@27443
    18
lemma zero: "f 0 = 0"
huffman@20504
    19
proof -
huffman@20504
    20
  have "f 0 = f (0 + 0)" by simp
huffman@20504
    21
  also have "\<dots> = f 0 + f 0" by (rule add)
huffman@20504
    22
  finally show "f 0 = 0" by simp
huffman@20504
    23
qed
huffman@20504
    24
huffman@27443
    25
lemma minus: "f (- x) = - f x"
huffman@20504
    26
proof -
huffman@20504
    27
  have "f (- x) + f x = f (- x + x)" by (rule add [symmetric])
huffman@20504
    28
  also have "\<dots> = - f x + f x" by (simp add: zero)
huffman@20504
    29
  finally show "f (- x) = - f x" by (rule add_right_imp_eq)
huffman@20504
    30
qed
huffman@20504
    31
huffman@27443
    32
lemma diff: "f (x - y) = f x - f y"
huffman@20504
    33
by (simp add: diff_def add minus)
huffman@20504
    34
huffman@27443
    35
lemma setsum: "f (setsum g A) = (\<Sum>x\<in>A. f (g x))"
huffman@22942
    36
apply (cases "finite A")
huffman@22942
    37
apply (induct set: finite)
huffman@22942
    38
apply (simp add: zero)
huffman@22942
    39
apply (simp add: add)
huffman@22942
    40
apply (simp add: zero)
huffman@22942
    41
done
huffman@22942
    42
huffman@27443
    43
end
huffman@20504
    44
huffman@28029
    45
subsection {* Vector spaces *}
huffman@28029
    46
huffman@28029
    47
locale vector_space =
huffman@28029
    48
  fixes scale :: "'a::field \<Rightarrow> 'b::ab_group_add \<Rightarrow> 'b"
huffman@28029
    49
  assumes scale_right_distrib: "scale a (x + y) = scale a x + scale a y"
huffman@28029
    50
  and scale_left_distrib: "scale (a + b) x = scale a x + scale b x"
huffman@28029
    51
  and scale_scale [simp]: "scale a (scale b x) = scale (a * b) x"
huffman@28029
    52
  and scale_one [simp]: "scale 1 x = x"
huffman@28029
    53
begin
huffman@28029
    54
huffman@28029
    55
lemma scale_left_commute:
huffman@28029
    56
  "scale a (scale b x) = scale b (scale a x)"
huffman@28029
    57
by (simp add: mult_commute)
huffman@28029
    58
huffman@28029
    59
lemma scale_zero_left [simp]: "scale 0 x = 0"
huffman@28029
    60
  and scale_minus_left [simp]: "scale (- a) x = - (scale a x)"
huffman@28029
    61
  and scale_left_diff_distrib: "scale (a - b) x = scale a x - scale b x"
huffman@28029
    62
proof -
ballarin@29229
    63
  interpret s: additive "\<lambda>a. scale a x"
haftmann@28823
    64
    proof qed (rule scale_left_distrib)
huffman@28029
    65
  show "scale 0 x = 0" by (rule s.zero)
huffman@28029
    66
  show "scale (- a) x = - (scale a x)" by (rule s.minus)
huffman@28029
    67
  show "scale (a - b) x = scale a x - scale b x" by (rule s.diff)
huffman@28029
    68
qed
huffman@28029
    69
huffman@28029
    70
lemma scale_zero_right [simp]: "scale a 0 = 0"
huffman@28029
    71
  and scale_minus_right [simp]: "scale a (- x) = - (scale a x)"
huffman@28029
    72
  and scale_right_diff_distrib: "scale a (x - y) = scale a x - scale a y"
huffman@28029
    73
proof -
ballarin@29229
    74
  interpret s: additive "\<lambda>x. scale a x"
haftmann@28823
    75
    proof qed (rule scale_right_distrib)
huffman@28029
    76
  show "scale a 0 = 0" by (rule s.zero)
huffman@28029
    77
  show "scale a (- x) = - (scale a x)" by (rule s.minus)
huffman@28029
    78
  show "scale a (x - y) = scale a x - scale a y" by (rule s.diff)
huffman@28029
    79
qed
huffman@28029
    80
huffman@28029
    81
lemma scale_eq_0_iff [simp]:
huffman@28029
    82
  "scale a x = 0 \<longleftrightarrow> a = 0 \<or> x = 0"
huffman@28029
    83
proof cases
huffman@28029
    84
  assume "a = 0" thus ?thesis by simp
huffman@28029
    85
next
huffman@28029
    86
  assume anz [simp]: "a \<noteq> 0"
huffman@28029
    87
  { assume "scale a x = 0"
huffman@28029
    88
    hence "scale (inverse a) (scale a x) = 0" by simp
huffman@28029
    89
    hence "x = 0" by simp }
huffman@28029
    90
  thus ?thesis by force
huffman@28029
    91
qed
huffman@28029
    92
huffman@28029
    93
lemma scale_left_imp_eq:
huffman@28029
    94
  "\<lbrakk>a \<noteq> 0; scale a x = scale a y\<rbrakk> \<Longrightarrow> x = y"
huffman@28029
    95
proof -
huffman@28029
    96
  assume nonzero: "a \<noteq> 0"
huffman@28029
    97
  assume "scale a x = scale a y"
huffman@28029
    98
  hence "scale a (x - y) = 0"
huffman@28029
    99
     by (simp add: scale_right_diff_distrib)
huffman@28029
   100
  hence "x - y = 0" by (simp add: nonzero)
huffman@28029
   101
  thus "x = y" by (simp only: right_minus_eq)
huffman@28029
   102
qed
huffman@28029
   103
huffman@28029
   104
lemma scale_right_imp_eq:
huffman@28029
   105
  "\<lbrakk>x \<noteq> 0; scale a x = scale b x\<rbrakk> \<Longrightarrow> a = b"
huffman@28029
   106
proof -
huffman@28029
   107
  assume nonzero: "x \<noteq> 0"
huffman@28029
   108
  assume "scale a x = scale b x"
huffman@28029
   109
  hence "scale (a - b) x = 0"
huffman@28029
   110
     by (simp add: scale_left_diff_distrib)
huffman@28029
   111
  hence "a - b = 0" by (simp add: nonzero)
huffman@28029
   112
  thus "a = b" by (simp only: right_minus_eq)
huffman@28029
   113
qed
huffman@28029
   114
huffman@28029
   115
lemma scale_cancel_left:
huffman@28029
   116
  "scale a x = scale a y \<longleftrightarrow> x = y \<or> a = 0"
huffman@28029
   117
by (auto intro: scale_left_imp_eq)
huffman@28029
   118
huffman@28029
   119
lemma scale_cancel_right:
huffman@28029
   120
  "scale a x = scale b x \<longleftrightarrow> a = b \<or> x = 0"
huffman@28029
   121
by (auto intro: scale_right_imp_eq)
huffman@28029
   122
huffman@28029
   123
end
huffman@28029
   124
huffman@20504
   125
subsection {* Real vector spaces *}
huffman@20504
   126
haftmann@29608
   127
class scaleR =
haftmann@25062
   128
  fixes scaleR :: "real \<Rightarrow> 'a \<Rightarrow> 'a" (infixr "*\<^sub>R" 75)
haftmann@24748
   129
begin
huffman@20504
   130
huffman@20763
   131
abbreviation
haftmann@25062
   132
  divideR :: "'a \<Rightarrow> real \<Rightarrow> 'a" (infixl "'/\<^sub>R" 70)
haftmann@24748
   133
where
haftmann@25062
   134
  "x /\<^sub>R r == scaleR (inverse r) x"
haftmann@24748
   135
haftmann@24748
   136
end
haftmann@24748
   137
haftmann@25571
   138
instantiation real :: scaleR
haftmann@25571
   139
begin
haftmann@25571
   140
haftmann@25571
   141
definition
haftmann@25571
   142
  real_scaleR_def [simp]: "scaleR a x = a * x"
haftmann@25571
   143
haftmann@25571
   144
instance ..
haftmann@25571
   145
haftmann@25571
   146
end
huffman@20554
   147
haftmann@24588
   148
class real_vector = scaleR + ab_group_add +
haftmann@25062
   149
  assumes scaleR_right_distrib: "scaleR a (x + y) = scaleR a x + scaleR a y"
haftmann@25062
   150
  and scaleR_left_distrib: "scaleR (a + b) x = scaleR a x + scaleR b x"
haftmann@24588
   151
  and scaleR_scaleR [simp]: "scaleR a (scaleR b x) = scaleR (a * b) x"
haftmann@24588
   152
  and scaleR_one [simp]: "scaleR 1 x = x"
huffman@20504
   153
ballarin@29233
   154
interpretation real_vector!:
ballarin@29229
   155
  vector_space "scaleR :: real \<Rightarrow> 'a \<Rightarrow> 'a::real_vector"
huffman@28009
   156
apply unfold_locales
huffman@28009
   157
apply (rule scaleR_right_distrib)
huffman@28009
   158
apply (rule scaleR_left_distrib)
huffman@28009
   159
apply (rule scaleR_scaleR)
huffman@28009
   160
apply (rule scaleR_one)
huffman@28009
   161
done
huffman@28009
   162
huffman@28009
   163
text {* Recover original theorem names *}
huffman@28009
   164
huffman@28009
   165
lemmas scaleR_left_commute = real_vector.scale_left_commute
huffman@28009
   166
lemmas scaleR_zero_left = real_vector.scale_zero_left
huffman@28009
   167
lemmas scaleR_minus_left = real_vector.scale_minus_left
huffman@28009
   168
lemmas scaleR_left_diff_distrib = real_vector.scale_left_diff_distrib
huffman@28009
   169
lemmas scaleR_zero_right = real_vector.scale_zero_right
huffman@28009
   170
lemmas scaleR_minus_right = real_vector.scale_minus_right
huffman@28009
   171
lemmas scaleR_right_diff_distrib = real_vector.scale_right_diff_distrib
huffman@28009
   172
lemmas scaleR_eq_0_iff = real_vector.scale_eq_0_iff
huffman@28009
   173
lemmas scaleR_left_imp_eq = real_vector.scale_left_imp_eq
huffman@28009
   174
lemmas scaleR_right_imp_eq = real_vector.scale_right_imp_eq
huffman@28009
   175
lemmas scaleR_cancel_left = real_vector.scale_cancel_left
huffman@28009
   176
lemmas scaleR_cancel_right = real_vector.scale_cancel_right
huffman@28009
   177
haftmann@24588
   178
class real_algebra = real_vector + ring +
haftmann@25062
   179
  assumes mult_scaleR_left [simp]: "scaleR a x * y = scaleR a (x * y)"
haftmann@25062
   180
  and mult_scaleR_right [simp]: "x * scaleR a y = scaleR a (x * y)"
huffman@20504
   181
haftmann@24588
   182
class real_algebra_1 = real_algebra + ring_1
huffman@20554
   183
haftmann@24588
   184
class real_div_algebra = real_algebra_1 + division_ring
huffman@20584
   185
haftmann@24588
   186
class real_field = real_div_algebra + field
huffman@20584
   187
huffman@20584
   188
instance real :: real_field
huffman@20554
   189
apply (intro_classes, unfold real_scaleR_def)
huffman@20554
   190
apply (rule right_distrib)
huffman@20554
   191
apply (rule left_distrib)
huffman@20763
   192
apply (rule mult_assoc [symmetric])
huffman@20554
   193
apply (rule mult_1_left)
huffman@20554
   194
apply (rule mult_assoc)
huffman@20554
   195
apply (rule mult_left_commute)
huffman@20554
   196
done
huffman@20554
   197
ballarin@29233
   198
interpretation scaleR_left!: additive "(\<lambda>a. scaleR a x::'a::real_vector)"
haftmann@28823
   199
proof qed (rule scaleR_left_distrib)
huffman@20504
   200
ballarin@29233
   201
interpretation scaleR_right!: additive "(\<lambda>x. scaleR a x::'a::real_vector)"
haftmann@28823
   202
proof qed (rule scaleR_right_distrib)
huffman@20504
   203
huffman@20584
   204
lemma nonzero_inverse_scaleR_distrib:
huffman@21809
   205
  fixes x :: "'a::real_div_algebra" shows
huffman@21809
   206
  "\<lbrakk>a \<noteq> 0; x \<noteq> 0\<rbrakk> \<Longrightarrow> inverse (scaleR a x) = scaleR (inverse a) (inverse x)"
huffman@20763
   207
by (rule inverse_unique, simp)
huffman@20584
   208
huffman@20584
   209
lemma inverse_scaleR_distrib:
huffman@20584
   210
  fixes x :: "'a::{real_div_algebra,division_by_zero}"
huffman@21809
   211
  shows "inverse (scaleR a x) = scaleR (inverse a) (inverse x)"
huffman@20584
   212
apply (case_tac "a = 0", simp)
huffman@20584
   213
apply (case_tac "x = 0", simp)
huffman@20584
   214
apply (erule (1) nonzero_inverse_scaleR_distrib)
huffman@20584
   215
done
huffman@20584
   216
huffman@20554
   217
huffman@20554
   218
subsection {* Embedding of the Reals into any @{text real_algebra_1}:
huffman@20554
   219
@{term of_real} *}
huffman@20554
   220
huffman@20554
   221
definition
wenzelm@21404
   222
  of_real :: "real \<Rightarrow> 'a::real_algebra_1" where
huffman@21809
   223
  "of_real r = scaleR r 1"
huffman@20554
   224
huffman@21809
   225
lemma scaleR_conv_of_real: "scaleR r x = of_real r * x"
huffman@20763
   226
by (simp add: of_real_def)
huffman@20763
   227
huffman@20554
   228
lemma of_real_0 [simp]: "of_real 0 = 0"
huffman@20554
   229
by (simp add: of_real_def)
huffman@20554
   230
huffman@20554
   231
lemma of_real_1 [simp]: "of_real 1 = 1"
huffman@20554
   232
by (simp add: of_real_def)
huffman@20554
   233
huffman@20554
   234
lemma of_real_add [simp]: "of_real (x + y) = of_real x + of_real y"
huffman@20554
   235
by (simp add: of_real_def scaleR_left_distrib)
huffman@20554
   236
huffman@20554
   237
lemma of_real_minus [simp]: "of_real (- x) = - of_real x"
huffman@20554
   238
by (simp add: of_real_def)
huffman@20554
   239
huffman@20554
   240
lemma of_real_diff [simp]: "of_real (x - y) = of_real x - of_real y"
huffman@20554
   241
by (simp add: of_real_def scaleR_left_diff_distrib)
huffman@20554
   242
huffman@20554
   243
lemma of_real_mult [simp]: "of_real (x * y) = of_real x * of_real y"
huffman@20763
   244
by (simp add: of_real_def mult_commute)
huffman@20554
   245
huffman@20584
   246
lemma nonzero_of_real_inverse:
huffman@20584
   247
  "x \<noteq> 0 \<Longrightarrow> of_real (inverse x) =
huffman@20584
   248
   inverse (of_real x :: 'a::real_div_algebra)"
huffman@20584
   249
by (simp add: of_real_def nonzero_inverse_scaleR_distrib)
huffman@20584
   250
huffman@20584
   251
lemma of_real_inverse [simp]:
huffman@20584
   252
  "of_real (inverse x) =
huffman@20584
   253
   inverse (of_real x :: 'a::{real_div_algebra,division_by_zero})"
huffman@20584
   254
by (simp add: of_real_def inverse_scaleR_distrib)
huffman@20584
   255
huffman@20584
   256
lemma nonzero_of_real_divide:
huffman@20584
   257
  "y \<noteq> 0 \<Longrightarrow> of_real (x / y) =
huffman@20584
   258
   (of_real x / of_real y :: 'a::real_field)"
huffman@20584
   259
by (simp add: divide_inverse nonzero_of_real_inverse)
huffman@20722
   260
huffman@20722
   261
lemma of_real_divide [simp]:
huffman@20584
   262
  "of_real (x / y) =
huffman@20584
   263
   (of_real x / of_real y :: 'a::{real_field,division_by_zero})"
huffman@20584
   264
by (simp add: divide_inverse)
huffman@20584
   265
huffman@20722
   266
lemma of_real_power [simp]:
huffman@20722
   267
  "of_real (x ^ n) = (of_real x :: 'a::{real_algebra_1,recpower}) ^ n"
wenzelm@20772
   268
by (induct n) (simp_all add: power_Suc)
huffman@20722
   269
huffman@20554
   270
lemma of_real_eq_iff [simp]: "(of_real x = of_real y) = (x = y)"
huffman@20554
   271
by (simp add: of_real_def scaleR_cancel_right)
huffman@20554
   272
huffman@20584
   273
lemmas of_real_eq_0_iff [simp] = of_real_eq_iff [of _ 0, simplified]
huffman@20554
   274
huffman@20554
   275
lemma of_real_eq_id [simp]: "of_real = (id :: real \<Rightarrow> real)"
huffman@20554
   276
proof
huffman@20554
   277
  fix r
huffman@20554
   278
  show "of_real r = id r"
huffman@22973
   279
    by (simp add: of_real_def)
huffman@20554
   280
qed
huffman@20554
   281
huffman@20554
   282
text{*Collapse nested embeddings*}
huffman@20554
   283
lemma of_real_of_nat_eq [simp]: "of_real (of_nat n) = of_nat n"
wenzelm@20772
   284
by (induct n) auto
huffman@20554
   285
huffman@20554
   286
lemma of_real_of_int_eq [simp]: "of_real (of_int z) = of_int z"
huffman@20554
   287
by (cases z rule: int_diff_cases, simp)
huffman@20554
   288
huffman@20554
   289
lemma of_real_number_of_eq:
huffman@20554
   290
  "of_real (number_of w) = (number_of w :: 'a::{number_ring,real_algebra_1})"
huffman@20554
   291
by (simp add: number_of_eq)
huffman@20554
   292
huffman@22912
   293
text{*Every real algebra has characteristic zero*}
huffman@22912
   294
instance real_algebra_1 < ring_char_0
huffman@22912
   295
proof
huffman@23282
   296
  fix m n :: nat
huffman@23282
   297
  have "(of_real (of_nat m) = (of_real (of_nat n)::'a)) = (m = n)"
huffman@23282
   298
    by (simp only: of_real_eq_iff of_nat_eq_iff)
huffman@23282
   299
  thus "(of_nat m = (of_nat n::'a)) = (m = n)"
huffman@23282
   300
    by (simp only: of_real_of_nat_eq)
huffman@22912
   301
qed
huffman@22912
   302
huffman@27553
   303
instance real_field < field_char_0 ..
huffman@27553
   304
huffman@20554
   305
huffman@20554
   306
subsection {* The Set of Real Numbers *}
huffman@20554
   307
wenzelm@20772
   308
definition
wenzelm@21404
   309
  Reals :: "'a::real_algebra_1 set" where
haftmann@28562
   310
  [code del]: "Reals \<equiv> range of_real"
huffman@20554
   311
wenzelm@21210
   312
notation (xsymbols)
huffman@20554
   313
  Reals  ("\<real>")
huffman@20554
   314
huffman@21809
   315
lemma Reals_of_real [simp]: "of_real r \<in> Reals"
huffman@20554
   316
by (simp add: Reals_def)
huffman@20554
   317
huffman@21809
   318
lemma Reals_of_int [simp]: "of_int z \<in> Reals"
huffman@21809
   319
by (subst of_real_of_int_eq [symmetric], rule Reals_of_real)
huffman@20718
   320
huffman@21809
   321
lemma Reals_of_nat [simp]: "of_nat n \<in> Reals"
huffman@21809
   322
by (subst of_real_of_nat_eq [symmetric], rule Reals_of_real)
huffman@21809
   323
huffman@21809
   324
lemma Reals_number_of [simp]:
huffman@21809
   325
  "(number_of w::'a::{number_ring,real_algebra_1}) \<in> Reals"
huffman@21809
   326
by (subst of_real_number_of_eq [symmetric], rule Reals_of_real)
huffman@20718
   327
huffman@20554
   328
lemma Reals_0 [simp]: "0 \<in> Reals"
huffman@20554
   329
apply (unfold Reals_def)
huffman@20554
   330
apply (rule range_eqI)
huffman@20554
   331
apply (rule of_real_0 [symmetric])
huffman@20554
   332
done
huffman@20554
   333
huffman@20554
   334
lemma Reals_1 [simp]: "1 \<in> Reals"
huffman@20554
   335
apply (unfold Reals_def)
huffman@20554
   336
apply (rule range_eqI)
huffman@20554
   337
apply (rule of_real_1 [symmetric])
huffman@20554
   338
done
huffman@20554
   339
huffman@20584
   340
lemma Reals_add [simp]: "\<lbrakk>a \<in> Reals; b \<in> Reals\<rbrakk> \<Longrightarrow> a + b \<in> Reals"
huffman@20554
   341
apply (auto simp add: Reals_def)
huffman@20554
   342
apply (rule range_eqI)
huffman@20554
   343
apply (rule of_real_add [symmetric])
huffman@20554
   344
done
huffman@20554
   345
huffman@20584
   346
lemma Reals_minus [simp]: "a \<in> Reals \<Longrightarrow> - a \<in> Reals"
huffman@20584
   347
apply (auto simp add: Reals_def)
huffman@20584
   348
apply (rule range_eqI)
huffman@20584
   349
apply (rule of_real_minus [symmetric])
huffman@20584
   350
done
huffman@20584
   351
huffman@20584
   352
lemma Reals_diff [simp]: "\<lbrakk>a \<in> Reals; b \<in> Reals\<rbrakk> \<Longrightarrow> a - b \<in> Reals"
huffman@20584
   353
apply (auto simp add: Reals_def)
huffman@20584
   354
apply (rule range_eqI)
huffman@20584
   355
apply (rule of_real_diff [symmetric])
huffman@20584
   356
done
huffman@20584
   357
huffman@20584
   358
lemma Reals_mult [simp]: "\<lbrakk>a \<in> Reals; b \<in> Reals\<rbrakk> \<Longrightarrow> a * b \<in> Reals"
huffman@20554
   359
apply (auto simp add: Reals_def)
huffman@20554
   360
apply (rule range_eqI)
huffman@20554
   361
apply (rule of_real_mult [symmetric])
huffman@20554
   362
done
huffman@20554
   363
huffman@20584
   364
lemma nonzero_Reals_inverse:
huffman@20584
   365
  fixes a :: "'a::real_div_algebra"
huffman@20584
   366
  shows "\<lbrakk>a \<in> Reals; a \<noteq> 0\<rbrakk> \<Longrightarrow> inverse a \<in> Reals"
huffman@20584
   367
apply (auto simp add: Reals_def)
huffman@20584
   368
apply (rule range_eqI)
huffman@20584
   369
apply (erule nonzero_of_real_inverse [symmetric])
huffman@20584
   370
done
huffman@20584
   371
huffman@20584
   372
lemma Reals_inverse [simp]:
huffman@20584
   373
  fixes a :: "'a::{real_div_algebra,division_by_zero}"
huffman@20584
   374
  shows "a \<in> Reals \<Longrightarrow> inverse a \<in> Reals"
huffman@20584
   375
apply (auto simp add: Reals_def)
huffman@20584
   376
apply (rule range_eqI)
huffman@20584
   377
apply (rule of_real_inverse [symmetric])
huffman@20584
   378
done
huffman@20584
   379
huffman@20584
   380
lemma nonzero_Reals_divide:
huffman@20584
   381
  fixes a b :: "'a::real_field"
huffman@20584
   382
  shows "\<lbrakk>a \<in> Reals; b \<in> Reals; b \<noteq> 0\<rbrakk> \<Longrightarrow> a / b \<in> Reals"
huffman@20584
   383
apply (auto simp add: Reals_def)
huffman@20584
   384
apply (rule range_eqI)
huffman@20584
   385
apply (erule nonzero_of_real_divide [symmetric])
huffman@20584
   386
done
huffman@20584
   387
huffman@20584
   388
lemma Reals_divide [simp]:
huffman@20584
   389
  fixes a b :: "'a::{real_field,division_by_zero}"
huffman@20584
   390
  shows "\<lbrakk>a \<in> Reals; b \<in> Reals\<rbrakk> \<Longrightarrow> a / b \<in> Reals"
huffman@20584
   391
apply (auto simp add: Reals_def)
huffman@20584
   392
apply (rule range_eqI)
huffman@20584
   393
apply (rule of_real_divide [symmetric])
huffman@20584
   394
done
huffman@20584
   395
huffman@20722
   396
lemma Reals_power [simp]:
huffman@20722
   397
  fixes a :: "'a::{real_algebra_1,recpower}"
huffman@20722
   398
  shows "a \<in> Reals \<Longrightarrow> a ^ n \<in> Reals"
huffman@20722
   399
apply (auto simp add: Reals_def)
huffman@20722
   400
apply (rule range_eqI)
huffman@20722
   401
apply (rule of_real_power [symmetric])
huffman@20722
   402
done
huffman@20722
   403
huffman@20554
   404
lemma Reals_cases [cases set: Reals]:
huffman@20554
   405
  assumes "q \<in> \<real>"
huffman@20554
   406
  obtains (of_real) r where "q = of_real r"
huffman@20554
   407
  unfolding Reals_def
huffman@20554
   408
proof -
huffman@20554
   409
  from `q \<in> \<real>` have "q \<in> range of_real" unfolding Reals_def .
huffman@20554
   410
  then obtain r where "q = of_real r" ..
huffman@20554
   411
  then show thesis ..
huffman@20554
   412
qed
huffman@20554
   413
huffman@20554
   414
lemma Reals_induct [case_names of_real, induct set: Reals]:
huffman@20554
   415
  "q \<in> \<real> \<Longrightarrow> (\<And>r. P (of_real r)) \<Longrightarrow> P q"
huffman@20554
   416
  by (rule Reals_cases) auto
huffman@20554
   417
huffman@20504
   418
huffman@20504
   419
subsection {* Real normed vector spaces *}
huffman@20504
   420
haftmann@29608
   421
class norm =
huffman@22636
   422
  fixes norm :: "'a \<Rightarrow> real"
huffman@20504
   423
haftmann@25571
   424
instantiation real :: norm
haftmann@25571
   425
begin
haftmann@25571
   426
haftmann@25571
   427
definition
haftmann@25571
   428
  real_norm_def [simp]: "norm r \<equiv> \<bar>r\<bar>"
haftmann@25571
   429
haftmann@25571
   430
instance ..
haftmann@25571
   431
haftmann@25571
   432
end
huffman@20554
   433
huffman@24520
   434
class sgn_div_norm = scaleR + norm + sgn +
haftmann@25062
   435
  assumes sgn_div_norm: "sgn x = x /\<^sub>R norm x"
nipkow@24506
   436
haftmann@24588
   437
class real_normed_vector = real_vector + sgn_div_norm +
haftmann@24588
   438
  assumes norm_ge_zero [simp]: "0 \<le> norm x"
haftmann@25062
   439
  and norm_eq_zero [simp]: "norm x = 0 \<longleftrightarrow> x = 0"
haftmann@25062
   440
  and norm_triangle_ineq: "norm (x + y) \<le> norm x + norm y"
haftmann@24588
   441
  and norm_scaleR: "norm (scaleR a x) = \<bar>a\<bar> * norm x"
huffman@20504
   442
haftmann@24588
   443
class real_normed_algebra = real_algebra + real_normed_vector +
haftmann@25062
   444
  assumes norm_mult_ineq: "norm (x * y) \<le> norm x * norm y"
huffman@20504
   445
haftmann@24588
   446
class real_normed_algebra_1 = real_algebra_1 + real_normed_algebra +
haftmann@25062
   447
  assumes norm_one [simp]: "norm 1 = 1"
huffman@22852
   448
haftmann@24588
   449
class real_normed_div_algebra = real_div_algebra + real_normed_vector +
haftmann@25062
   450
  assumes norm_mult: "norm (x * y) = norm x * norm y"
huffman@20504
   451
haftmann@24588
   452
class real_normed_field = real_field + real_normed_div_algebra
huffman@20584
   453
huffman@22852
   454
instance real_normed_div_algebra < real_normed_algebra_1
huffman@20554
   455
proof
huffman@20554
   456
  fix x y :: 'a
huffman@20554
   457
  show "norm (x * y) \<le> norm x * norm y"
huffman@20554
   458
    by (simp add: norm_mult)
huffman@22852
   459
next
huffman@22852
   460
  have "norm (1 * 1::'a) = norm (1::'a) * norm (1::'a)"
huffman@22852
   461
    by (rule norm_mult)
huffman@22852
   462
  thus "norm (1::'a) = 1" by simp
huffman@20554
   463
qed
huffman@20554
   464
huffman@20584
   465
instance real :: real_normed_field
huffman@22852
   466
apply (intro_classes, unfold real_norm_def real_scaleR_def)
nipkow@24506
   467
apply (simp add: real_sgn_def)
huffman@20554
   468
apply (rule abs_ge_zero)
huffman@20554
   469
apply (rule abs_eq_0)
huffman@20554
   470
apply (rule abs_triangle_ineq)
huffman@22852
   471
apply (rule abs_mult)
huffman@20554
   472
apply (rule abs_mult)
huffman@20554
   473
done
huffman@20504
   474
huffman@22852
   475
lemma norm_zero [simp]: "norm (0::'a::real_normed_vector) = 0"
huffman@20504
   476
by simp
huffman@20504
   477
huffman@22852
   478
lemma zero_less_norm_iff [simp]:
huffman@22852
   479
  fixes x :: "'a::real_normed_vector"
huffman@22852
   480
  shows "(0 < norm x) = (x \<noteq> 0)"
huffman@20504
   481
by (simp add: order_less_le)
huffman@20504
   482
huffman@22852
   483
lemma norm_not_less_zero [simp]:
huffman@22852
   484
  fixes x :: "'a::real_normed_vector"
huffman@22852
   485
  shows "\<not> norm x < 0"
huffman@20828
   486
by (simp add: linorder_not_less)
huffman@20828
   487
huffman@22852
   488
lemma norm_le_zero_iff [simp]:
huffman@22852
   489
  fixes x :: "'a::real_normed_vector"
huffman@22852
   490
  shows "(norm x \<le> 0) = (x = 0)"
huffman@20828
   491
by (simp add: order_le_less)
huffman@20828
   492
huffman@20504
   493
lemma norm_minus_cancel [simp]:
huffman@20584
   494
  fixes x :: "'a::real_normed_vector"
huffman@20584
   495
  shows "norm (- x) = norm x"
huffman@20504
   496
proof -
huffman@21809
   497
  have "norm (- x) = norm (scaleR (- 1) x)"
huffman@20504
   498
    by (simp only: scaleR_minus_left scaleR_one)
huffman@20533
   499
  also have "\<dots> = \<bar>- 1\<bar> * norm x"
huffman@20504
   500
    by (rule norm_scaleR)
huffman@20504
   501
  finally show ?thesis by simp
huffman@20504
   502
qed
huffman@20504
   503
huffman@20504
   504
lemma norm_minus_commute:
huffman@20584
   505
  fixes a b :: "'a::real_normed_vector"
huffman@20584
   506
  shows "norm (a - b) = norm (b - a)"
huffman@20504
   507
proof -
huffman@22898
   508
  have "norm (- (b - a)) = norm (b - a)"
huffman@22898
   509
    by (rule norm_minus_cancel)
huffman@22898
   510
  thus ?thesis by simp
huffman@20504
   511
qed
huffman@20504
   512
huffman@20504
   513
lemma norm_triangle_ineq2:
huffman@20584
   514
  fixes a b :: "'a::real_normed_vector"
huffman@20533
   515
  shows "norm a - norm b \<le> norm (a - b)"
huffman@20504
   516
proof -
huffman@20533
   517
  have "norm (a - b + b) \<le> norm (a - b) + norm b"
huffman@20504
   518
    by (rule norm_triangle_ineq)
huffman@22898
   519
  thus ?thesis by simp
huffman@20504
   520
qed
huffman@20504
   521
huffman@20584
   522
lemma norm_triangle_ineq3:
huffman@20584
   523
  fixes a b :: "'a::real_normed_vector"
huffman@20584
   524
  shows "\<bar>norm a - norm b\<bar> \<le> norm (a - b)"
huffman@20584
   525
apply (subst abs_le_iff)
huffman@20584
   526
apply auto
huffman@20584
   527
apply (rule norm_triangle_ineq2)
huffman@20584
   528
apply (subst norm_minus_commute)
huffman@20584
   529
apply (rule norm_triangle_ineq2)
huffman@20584
   530
done
huffman@20584
   531
huffman@20504
   532
lemma norm_triangle_ineq4:
huffman@20584
   533
  fixes a b :: "'a::real_normed_vector"
huffman@20533
   534
  shows "norm (a - b) \<le> norm a + norm b"
huffman@20504
   535
proof -
huffman@22898
   536
  have "norm (a + - b) \<le> norm a + norm (- b)"
huffman@20504
   537
    by (rule norm_triangle_ineq)
huffman@22898
   538
  thus ?thesis
huffman@22898
   539
    by (simp only: diff_minus norm_minus_cancel)
huffman@22898
   540
qed
huffman@22898
   541
huffman@22898
   542
lemma norm_diff_ineq:
huffman@22898
   543
  fixes a b :: "'a::real_normed_vector"
huffman@22898
   544
  shows "norm a - norm b \<le> norm (a + b)"
huffman@22898
   545
proof -
huffman@22898
   546
  have "norm a - norm (- b) \<le> norm (a - - b)"
huffman@22898
   547
    by (rule norm_triangle_ineq2)
huffman@22898
   548
  thus ?thesis by simp
huffman@20504
   549
qed
huffman@20504
   550
huffman@20551
   551
lemma norm_diff_triangle_ineq:
huffman@20551
   552
  fixes a b c d :: "'a::real_normed_vector"
huffman@20551
   553
  shows "norm ((a + b) - (c + d)) \<le> norm (a - c) + norm (b - d)"
huffman@20551
   554
proof -
huffman@20551
   555
  have "norm ((a + b) - (c + d)) = norm ((a - c) + (b - d))"
huffman@20551
   556
    by (simp add: diff_minus add_ac)
huffman@20551
   557
  also have "\<dots> \<le> norm (a - c) + norm (b - d)"
huffman@20551
   558
    by (rule norm_triangle_ineq)
huffman@20551
   559
  finally show ?thesis .
huffman@20551
   560
qed
huffman@20551
   561
huffman@22857
   562
lemma abs_norm_cancel [simp]:
huffman@22857
   563
  fixes a :: "'a::real_normed_vector"
huffman@22857
   564
  shows "\<bar>norm a\<bar> = norm a"
huffman@22857
   565
by (rule abs_of_nonneg [OF norm_ge_zero])
huffman@22857
   566
huffman@22880
   567
lemma norm_add_less:
huffman@22880
   568
  fixes x y :: "'a::real_normed_vector"
huffman@22880
   569
  shows "\<lbrakk>norm x < r; norm y < s\<rbrakk> \<Longrightarrow> norm (x + y) < r + s"
huffman@22880
   570
by (rule order_le_less_trans [OF norm_triangle_ineq add_strict_mono])
huffman@22880
   571
huffman@22880
   572
lemma norm_mult_less:
huffman@22880
   573
  fixes x y :: "'a::real_normed_algebra"
huffman@22880
   574
  shows "\<lbrakk>norm x < r; norm y < s\<rbrakk> \<Longrightarrow> norm (x * y) < r * s"
huffman@22880
   575
apply (rule order_le_less_trans [OF norm_mult_ineq])
huffman@22880
   576
apply (simp add: mult_strict_mono')
huffman@22880
   577
done
huffman@22880
   578
huffman@22857
   579
lemma norm_of_real [simp]:
huffman@22857
   580
  "norm (of_real r :: 'a::real_normed_algebra_1) = \<bar>r\<bar>"
huffman@22852
   581
unfolding of_real_def by (simp add: norm_scaleR)
huffman@20560
   582
huffman@22876
   583
lemma norm_number_of [simp]:
huffman@22876
   584
  "norm (number_of w::'a::{number_ring,real_normed_algebra_1})
huffman@22876
   585
    = \<bar>number_of w\<bar>"
huffman@22876
   586
by (subst of_real_number_of_eq [symmetric], rule norm_of_real)
huffman@22876
   587
huffman@22876
   588
lemma norm_of_int [simp]:
huffman@22876
   589
  "norm (of_int z::'a::real_normed_algebra_1) = \<bar>of_int z\<bar>"
huffman@22876
   590
by (subst of_real_of_int_eq [symmetric], rule norm_of_real)
huffman@22876
   591
huffman@22876
   592
lemma norm_of_nat [simp]:
huffman@22876
   593
  "norm (of_nat n::'a::real_normed_algebra_1) = of_nat n"
huffman@22876
   594
apply (subst of_real_of_nat_eq [symmetric])
huffman@22876
   595
apply (subst norm_of_real, simp)
huffman@22876
   596
done
huffman@22876
   597
huffman@20504
   598
lemma nonzero_norm_inverse:
huffman@20504
   599
  fixes a :: "'a::real_normed_div_algebra"
huffman@20533
   600
  shows "a \<noteq> 0 \<Longrightarrow> norm (inverse a) = inverse (norm a)"
huffman@20504
   601
apply (rule inverse_unique [symmetric])
huffman@20504
   602
apply (simp add: norm_mult [symmetric])
huffman@20504
   603
done
huffman@20504
   604
huffman@20504
   605
lemma norm_inverse:
huffman@20504
   606
  fixes a :: "'a::{real_normed_div_algebra,division_by_zero}"
huffman@20533
   607
  shows "norm (inverse a) = inverse (norm a)"
huffman@20504
   608
apply (case_tac "a = 0", simp)
huffman@20504
   609
apply (erule nonzero_norm_inverse)
huffman@20504
   610
done
huffman@20504
   611
huffman@20584
   612
lemma nonzero_norm_divide:
huffman@20584
   613
  fixes a b :: "'a::real_normed_field"
huffman@20584
   614
  shows "b \<noteq> 0 \<Longrightarrow> norm (a / b) = norm a / norm b"
huffman@20584
   615
by (simp add: divide_inverse norm_mult nonzero_norm_inverse)
huffman@20584
   616
huffman@20584
   617
lemma norm_divide:
huffman@20584
   618
  fixes a b :: "'a::{real_normed_field,division_by_zero}"
huffman@20584
   619
  shows "norm (a / b) = norm a / norm b"
huffman@20584
   620
by (simp add: divide_inverse norm_mult norm_inverse)
huffman@20584
   621
huffman@22852
   622
lemma norm_power_ineq:
huffman@22852
   623
  fixes x :: "'a::{real_normed_algebra_1,recpower}"
huffman@22852
   624
  shows "norm (x ^ n) \<le> norm x ^ n"
huffman@22852
   625
proof (induct n)
huffman@22852
   626
  case 0 show "norm (x ^ 0) \<le> norm x ^ 0" by simp
huffman@22852
   627
next
huffman@22852
   628
  case (Suc n)
huffman@22852
   629
  have "norm (x * x ^ n) \<le> norm x * norm (x ^ n)"
huffman@22852
   630
    by (rule norm_mult_ineq)
huffman@22852
   631
  also from Suc have "\<dots> \<le> norm x * norm x ^ n"
huffman@22852
   632
    using norm_ge_zero by (rule mult_left_mono)
huffman@22852
   633
  finally show "norm (x ^ Suc n) \<le> norm x ^ Suc n"
huffman@22852
   634
    by (simp add: power_Suc)
huffman@22852
   635
qed
huffman@22852
   636
huffman@20684
   637
lemma norm_power:
huffman@20684
   638
  fixes x :: "'a::{real_normed_div_algebra,recpower}"
huffman@20684
   639
  shows "norm (x ^ n) = norm x ^ n"
wenzelm@20772
   640
by (induct n) (simp_all add: power_Suc norm_mult)
huffman@20684
   641
huffman@22442
   642
huffman@22972
   643
subsection {* Sign function *}
huffman@22972
   644
nipkow@24506
   645
lemma norm_sgn:
nipkow@24506
   646
  "norm (sgn(x::'a::real_normed_vector)) = (if x = 0 then 0 else 1)"
nipkow@24506
   647
by (simp add: sgn_div_norm norm_scaleR)
huffman@22972
   648
nipkow@24506
   649
lemma sgn_zero [simp]: "sgn(0::'a::real_normed_vector) = 0"
nipkow@24506
   650
by (simp add: sgn_div_norm)
huffman@22972
   651
nipkow@24506
   652
lemma sgn_zero_iff: "(sgn(x::'a::real_normed_vector) = 0) = (x = 0)"
nipkow@24506
   653
by (simp add: sgn_div_norm)
huffman@22972
   654
nipkow@24506
   655
lemma sgn_minus: "sgn (- x) = - sgn(x::'a::real_normed_vector)"
nipkow@24506
   656
by (simp add: sgn_div_norm)
huffman@22972
   657
nipkow@24506
   658
lemma sgn_scaleR:
nipkow@24506
   659
  "sgn (scaleR r x) = scaleR (sgn r) (sgn(x::'a::real_normed_vector))"
nipkow@24506
   660
by (simp add: sgn_div_norm norm_scaleR mult_ac)
huffman@22973
   661
huffman@22972
   662
lemma sgn_one [simp]: "sgn (1::'a::real_normed_algebra_1) = 1"
nipkow@24506
   663
by (simp add: sgn_div_norm)
huffman@22972
   664
huffman@22972
   665
lemma sgn_of_real:
huffman@22972
   666
  "sgn (of_real r::'a::real_normed_algebra_1) = of_real (sgn r)"
huffman@22972
   667
unfolding of_real_def by (simp only: sgn_scaleR sgn_one)
huffman@22972
   668
huffman@22973
   669
lemma sgn_mult:
huffman@22973
   670
  fixes x y :: "'a::real_normed_div_algebra"
huffman@22973
   671
  shows "sgn (x * y) = sgn x * sgn y"
nipkow@24506
   672
by (simp add: sgn_div_norm norm_mult mult_commute)
huffman@22973
   673
huffman@22972
   674
lemma real_sgn_eq: "sgn (x::real) = x / \<bar>x\<bar>"
nipkow@24506
   675
by (simp add: sgn_div_norm divide_inverse)
huffman@22972
   676
huffman@22972
   677
lemma real_sgn_pos: "0 < (x::real) \<Longrightarrow> sgn x = 1"
huffman@22972
   678
unfolding real_sgn_eq by simp
huffman@22972
   679
huffman@22972
   680
lemma real_sgn_neg: "(x::real) < 0 \<Longrightarrow> sgn x = -1"
huffman@22972
   681
unfolding real_sgn_eq by simp
huffman@22972
   682
huffman@22972
   683
huffman@22442
   684
subsection {* Bounded Linear and Bilinear Operators *}
huffman@22442
   685
huffman@22442
   686
locale bounded_linear = additive +
huffman@22442
   687
  constrains f :: "'a::real_normed_vector \<Rightarrow> 'b::real_normed_vector"
huffman@22442
   688
  assumes scaleR: "f (scaleR r x) = scaleR r (f x)"
huffman@22442
   689
  assumes bounded: "\<exists>K. \<forall>x. norm (f x) \<le> norm x * K"
huffman@27443
   690
begin
huffman@22442
   691
huffman@27443
   692
lemma pos_bounded:
huffman@22442
   693
  "\<exists>K>0. \<forall>x. norm (f x) \<le> norm x * K"
huffman@22442
   694
proof -
huffman@22442
   695
  obtain K where K: "\<And>x. norm (f x) \<le> norm x * K"
huffman@22442
   696
    using bounded by fast
huffman@22442
   697
  show ?thesis
huffman@22442
   698
  proof (intro exI impI conjI allI)
huffman@22442
   699
    show "0 < max 1 K"
huffman@22442
   700
      by (rule order_less_le_trans [OF zero_less_one le_maxI1])
huffman@22442
   701
  next
huffman@22442
   702
    fix x
huffman@22442
   703
    have "norm (f x) \<le> norm x * K" using K .
huffman@22442
   704
    also have "\<dots> \<le> norm x * max 1 K"
huffman@22442
   705
      by (rule mult_left_mono [OF le_maxI2 norm_ge_zero])
huffman@22442
   706
    finally show "norm (f x) \<le> norm x * max 1 K" .
huffman@22442
   707
  qed
huffman@22442
   708
qed
huffman@22442
   709
huffman@27443
   710
lemma nonneg_bounded:
huffman@22442
   711
  "\<exists>K\<ge>0. \<forall>x. norm (f x) \<le> norm x * K"
huffman@22442
   712
proof -
huffman@22442
   713
  from pos_bounded
huffman@22442
   714
  show ?thesis by (auto intro: order_less_imp_le)
huffman@22442
   715
qed
huffman@22442
   716
huffman@27443
   717
end
huffman@27443
   718
huffman@22442
   719
locale bounded_bilinear =
huffman@22442
   720
  fixes prod :: "['a::real_normed_vector, 'b::real_normed_vector]
huffman@22442
   721
                 \<Rightarrow> 'c::real_normed_vector"
huffman@22442
   722
    (infixl "**" 70)
huffman@22442
   723
  assumes add_left: "prod (a + a') b = prod a b + prod a' b"
huffman@22442
   724
  assumes add_right: "prod a (b + b') = prod a b + prod a b'"
huffman@22442
   725
  assumes scaleR_left: "prod (scaleR r a) b = scaleR r (prod a b)"
huffman@22442
   726
  assumes scaleR_right: "prod a (scaleR r b) = scaleR r (prod a b)"
huffman@22442
   727
  assumes bounded: "\<exists>K. \<forall>a b. norm (prod a b) \<le> norm a * norm b * K"
huffman@27443
   728
begin
huffman@22442
   729
huffman@27443
   730
lemma pos_bounded:
huffman@22442
   731
  "\<exists>K>0. \<forall>a b. norm (a ** b) \<le> norm a * norm b * K"
huffman@22442
   732
apply (cut_tac bounded, erule exE)
huffman@22442
   733
apply (rule_tac x="max 1 K" in exI, safe)
huffman@22442
   734
apply (rule order_less_le_trans [OF zero_less_one le_maxI1])
huffman@22442
   735
apply (drule spec, drule spec, erule order_trans)
huffman@22442
   736
apply (rule mult_left_mono [OF le_maxI2])
huffman@22442
   737
apply (intro mult_nonneg_nonneg norm_ge_zero)
huffman@22442
   738
done
huffman@22442
   739
huffman@27443
   740
lemma nonneg_bounded:
huffman@22442
   741
  "\<exists>K\<ge>0. \<forall>a b. norm (a ** b) \<le> norm a * norm b * K"
huffman@22442
   742
proof -
huffman@22442
   743
  from pos_bounded
huffman@22442
   744
  show ?thesis by (auto intro: order_less_imp_le)
huffman@22442
   745
qed
huffman@22442
   746
huffman@27443
   747
lemma additive_right: "additive (\<lambda>b. prod a b)"
huffman@22442
   748
by (rule additive.intro, rule add_right)
huffman@22442
   749
huffman@27443
   750
lemma additive_left: "additive (\<lambda>a. prod a b)"
huffman@22442
   751
by (rule additive.intro, rule add_left)
huffman@22442
   752
huffman@27443
   753
lemma zero_left: "prod 0 b = 0"
huffman@22442
   754
by (rule additive.zero [OF additive_left])
huffman@22442
   755
huffman@27443
   756
lemma zero_right: "prod a 0 = 0"
huffman@22442
   757
by (rule additive.zero [OF additive_right])
huffman@22442
   758
huffman@27443
   759
lemma minus_left: "prod (- a) b = - prod a b"
huffman@22442
   760
by (rule additive.minus [OF additive_left])
huffman@22442
   761
huffman@27443
   762
lemma minus_right: "prod a (- b) = - prod a b"
huffman@22442
   763
by (rule additive.minus [OF additive_right])
huffman@22442
   764
huffman@27443
   765
lemma diff_left:
huffman@22442
   766
  "prod (a - a') b = prod a b - prod a' b"
huffman@22442
   767
by (rule additive.diff [OF additive_left])
huffman@22442
   768
huffman@27443
   769
lemma diff_right:
huffman@22442
   770
  "prod a (b - b') = prod a b - prod a b'"
huffman@22442
   771
by (rule additive.diff [OF additive_right])
huffman@22442
   772
huffman@27443
   773
lemma bounded_linear_left:
huffman@22442
   774
  "bounded_linear (\<lambda>a. a ** b)"
huffman@22442
   775
apply (unfold_locales)
huffman@22442
   776
apply (rule add_left)
huffman@22442
   777
apply (rule scaleR_left)
huffman@22442
   778
apply (cut_tac bounded, safe)
huffman@22442
   779
apply (rule_tac x="norm b * K" in exI)
huffman@22442
   780
apply (simp add: mult_ac)
huffman@22442
   781
done
huffman@22442
   782
huffman@27443
   783
lemma bounded_linear_right:
huffman@22442
   784
  "bounded_linear (\<lambda>b. a ** b)"
huffman@22442
   785
apply (unfold_locales)
huffman@22442
   786
apply (rule add_right)
huffman@22442
   787
apply (rule scaleR_right)
huffman@22442
   788
apply (cut_tac bounded, safe)
huffman@22442
   789
apply (rule_tac x="norm a * K" in exI)
huffman@22442
   790
apply (simp add: mult_ac)
huffman@22442
   791
done
huffman@22442
   792
huffman@27443
   793
lemma prod_diff_prod:
huffman@22442
   794
  "(x ** y - a ** b) = (x - a) ** (y - b) + (x - a) ** b + a ** (y - b)"
huffman@22442
   795
by (simp add: diff_left diff_right)
huffman@22442
   796
huffman@27443
   797
end
huffman@27443
   798
ballarin@29233
   799
interpretation mult!:
ballarin@29229
   800
  bounded_bilinear "op * :: 'a \<Rightarrow> 'a \<Rightarrow> 'a::real_normed_algebra"
huffman@22442
   801
apply (rule bounded_bilinear.intro)
huffman@22442
   802
apply (rule left_distrib)
huffman@22442
   803
apply (rule right_distrib)
huffman@22442
   804
apply (rule mult_scaleR_left)
huffman@22442
   805
apply (rule mult_scaleR_right)
huffman@22442
   806
apply (rule_tac x="1" in exI)
huffman@22442
   807
apply (simp add: norm_mult_ineq)
huffman@22442
   808
done
huffman@22442
   809
ballarin@29233
   810
interpretation mult_left!:
ballarin@29229
   811
  bounded_linear "(\<lambda>x::'a::real_normed_algebra. x * y)"
huffman@23127
   812
by (rule mult.bounded_linear_left)
huffman@22442
   813
ballarin@29233
   814
interpretation mult_right!:
ballarin@29229
   815
  bounded_linear "(\<lambda>y::'a::real_normed_algebra. x * y)"
huffman@23127
   816
by (rule mult.bounded_linear_right)
huffman@23127
   817
ballarin@29233
   818
interpretation divide!:
ballarin@29229
   819
  bounded_linear "(\<lambda>x::'a::real_normed_field. x / y)"
huffman@23127
   820
unfolding divide_inverse by (rule mult.bounded_linear_left)
huffman@23120
   821
ballarin@29233
   822
interpretation scaleR!: bounded_bilinear "scaleR"
huffman@22442
   823
apply (rule bounded_bilinear.intro)
huffman@22442
   824
apply (rule scaleR_left_distrib)
huffman@22442
   825
apply (rule scaleR_right_distrib)
huffman@22973
   826
apply simp
huffman@22442
   827
apply (rule scaleR_left_commute)
huffman@22442
   828
apply (rule_tac x="1" in exI)
huffman@22442
   829
apply (simp add: norm_scaleR)
huffman@22442
   830
done
huffman@22442
   831
ballarin@29233
   832
interpretation scaleR_left!: bounded_linear "\<lambda>r. scaleR r x"
huffman@23127
   833
by (rule scaleR.bounded_linear_left)
huffman@23127
   834
ballarin@29233
   835
interpretation scaleR_right!: bounded_linear "\<lambda>x. scaleR r x"
huffman@23127
   836
by (rule scaleR.bounded_linear_right)
huffman@23127
   837
ballarin@29233
   838
interpretation of_real!: bounded_linear "\<lambda>r. of_real r"
huffman@23127
   839
unfolding of_real_def by (rule scaleR.bounded_linear_left)
huffman@22625
   840
huffman@20504
   841
end