src/HOL/Library/Inner_Product.thy
author huffman
Thu Feb 19 09:42:23 2009 -0800 (2009-02-19)
changeset 29993 84b2c432b94a
child 30046 49f603f92c47
permissions -rw-r--r--
new theory of real inner product spaces
huffman@29993
     1
(* Title:      Inner_Product.thy
huffman@29993
     2
   Author:     Brian Huffman
huffman@29993
     3
*)
huffman@29993
     4
huffman@29993
     5
header {* Inner Product Spaces and the Gradient Derivative *}
huffman@29993
     6
huffman@29993
     7
theory Inner_Product
huffman@29993
     8
imports Complex FrechetDeriv
huffman@29993
     9
begin
huffman@29993
    10
huffman@29993
    11
subsection {* Real inner product spaces *}
huffman@29993
    12
huffman@29993
    13
class real_inner = real_vector + sgn_div_norm +
huffman@29993
    14
  fixes inner :: "'a \<Rightarrow> 'a \<Rightarrow> real"
huffman@29993
    15
  assumes inner_commute: "inner x y = inner y x"
huffman@29993
    16
  and inner_left_distrib: "inner (x + y) z = inner x z + inner y z"
huffman@29993
    17
  and inner_scaleR_left: "inner (scaleR r x) y = r * (inner x y)"
huffman@29993
    18
  and inner_ge_zero [simp]: "0 \<le> inner x x"
huffman@29993
    19
  and inner_eq_zero_iff [simp]: "inner x x = 0 \<longleftrightarrow> x = 0"
huffman@29993
    20
  and norm_eq_sqrt_inner: "norm x = sqrt (inner x x)"
huffman@29993
    21
begin
huffman@29993
    22
huffman@29993
    23
lemma inner_zero_left [simp]: "inner 0 x = 0"
huffman@29993
    24
proof -
huffman@29993
    25
  have "inner 0 x = inner (0 + 0) x" by simp
huffman@29993
    26
  also have "\<dots> = inner 0 x + inner 0 x" by (rule inner_left_distrib)
huffman@29993
    27
  finally show "inner 0 x = 0" by simp
huffman@29993
    28
qed
huffman@29993
    29
huffman@29993
    30
lemma inner_minus_left [simp]: "inner (- x) y = - inner x y"
huffman@29993
    31
proof -
huffman@29993
    32
  have "inner (- x) y + inner x y = inner (- x + x) y"
huffman@29993
    33
    by (rule inner_left_distrib [symmetric])
huffman@29993
    34
  also have "\<dots> = - inner x y + inner x y" by simp
huffman@29993
    35
  finally show "inner (- x) y = - inner x y" by simp
huffman@29993
    36
qed
huffman@29993
    37
huffman@29993
    38
lemma inner_diff_left: "inner (x - y) z = inner x z - inner y z"
huffman@29993
    39
  by (simp add: diff_minus inner_left_distrib)
huffman@29993
    40
huffman@29993
    41
text {* Transfer distributivity rules to right argument. *}
huffman@29993
    42
huffman@29993
    43
lemma inner_right_distrib: "inner x (y + z) = inner x y + inner x z"
huffman@29993
    44
  using inner_left_distrib [of y z x] by (simp only: inner_commute)
huffman@29993
    45
huffman@29993
    46
lemma inner_scaleR_right: "inner x (scaleR r y) = r * (inner x y)"
huffman@29993
    47
  using inner_scaleR_left [of r y x] by (simp only: inner_commute)
huffman@29993
    48
huffman@29993
    49
lemma inner_zero_right [simp]: "inner x 0 = 0"
huffman@29993
    50
  using inner_zero_left [of x] by (simp only: inner_commute)
huffman@29993
    51
huffman@29993
    52
lemma inner_minus_right [simp]: "inner x (- y) = - inner x y"
huffman@29993
    53
  using inner_minus_left [of y x] by (simp only: inner_commute)
huffman@29993
    54
huffman@29993
    55
lemma inner_diff_right: "inner x (y - z) = inner x y - inner x z"
huffman@29993
    56
  using inner_diff_left [of y z x] by (simp only: inner_commute)
huffman@29993
    57
huffman@29993
    58
lemmas inner_distrib = inner_left_distrib inner_right_distrib
huffman@29993
    59
lemmas inner_diff = inner_diff_left inner_diff_right
huffman@29993
    60
lemmas inner_scaleR = inner_scaleR_left inner_scaleR_right
huffman@29993
    61
huffman@29993
    62
lemma inner_gt_zero_iff [simp]: "0 < inner x x \<longleftrightarrow> x \<noteq> 0"
huffman@29993
    63
  by (simp add: order_less_le)
huffman@29993
    64
huffman@29993
    65
lemma power2_norm_eq_inner: "(norm x)\<twosuperior> = inner x x"
huffman@29993
    66
  by (simp add: norm_eq_sqrt_inner)
huffman@29993
    67
huffman@29993
    68
lemma Cauchy_Schwartz_ineq:
huffman@29993
    69
  "(inner x y)\<twosuperior> \<le> inner x x * inner y y"
huffman@29993
    70
proof (cases)
huffman@29993
    71
  assume "y = 0"
huffman@29993
    72
  thus ?thesis by simp
huffman@29993
    73
next
huffman@29993
    74
  assume y: "y \<noteq> 0"
huffman@29993
    75
  let ?r = "inner x y / inner y y"
huffman@29993
    76
  have "0 \<le> inner (x - scaleR ?r y) (x - scaleR ?r y)"
huffman@29993
    77
    by (rule inner_ge_zero)
huffman@29993
    78
  also have "\<dots> = inner x x - inner y x * ?r"
huffman@29993
    79
    by (simp add: inner_diff inner_scaleR)
huffman@29993
    80
  also have "\<dots> = inner x x - (inner x y)\<twosuperior> / inner y y"
huffman@29993
    81
    by (simp add: power2_eq_square inner_commute)
huffman@29993
    82
  finally have "0 \<le> inner x x - (inner x y)\<twosuperior> / inner y y" .
huffman@29993
    83
  hence "(inner x y)\<twosuperior> / inner y y \<le> inner x x"
huffman@29993
    84
    by (simp add: le_diff_eq)
huffman@29993
    85
  thus "(inner x y)\<twosuperior> \<le> inner x x * inner y y"
huffman@29993
    86
    by (simp add: pos_divide_le_eq y)
huffman@29993
    87
qed
huffman@29993
    88
huffman@29993
    89
lemma Cauchy_Schwartz_ineq2:
huffman@29993
    90
  "\<bar>inner x y\<bar> \<le> norm x * norm y"
huffman@29993
    91
proof (rule power2_le_imp_le)
huffman@29993
    92
  have "(inner x y)\<twosuperior> \<le> inner x x * inner y y"
huffman@29993
    93
    using Cauchy_Schwartz_ineq .
huffman@29993
    94
  thus "\<bar>inner x y\<bar>\<twosuperior> \<le> (norm x * norm y)\<twosuperior>"
huffman@29993
    95
    by (simp add: power_mult_distrib power2_norm_eq_inner)
huffman@29993
    96
  show "0 \<le> norm x * norm y"
huffman@29993
    97
    unfolding norm_eq_sqrt_inner
huffman@29993
    98
    by (intro mult_nonneg_nonneg real_sqrt_ge_zero inner_ge_zero)
huffman@29993
    99
qed
huffman@29993
   100
huffman@29993
   101
subclass real_normed_vector
huffman@29993
   102
proof
huffman@29993
   103
  fix a :: real and x y :: 'a
huffman@29993
   104
  show "0 \<le> norm x"
huffman@29993
   105
    unfolding norm_eq_sqrt_inner by simp
huffman@29993
   106
  show "norm x = 0 \<longleftrightarrow> x = 0"
huffman@29993
   107
    unfolding norm_eq_sqrt_inner by simp
huffman@29993
   108
  show "norm (x + y) \<le> norm x + norm y"
huffman@29993
   109
    proof (rule power2_le_imp_le)
huffman@29993
   110
      have "inner x y \<le> norm x * norm y"
huffman@29993
   111
        by (rule order_trans [OF abs_ge_self Cauchy_Schwartz_ineq2])
huffman@29993
   112
      thus "(norm (x + y))\<twosuperior> \<le> (norm x + norm y)\<twosuperior>"
huffman@29993
   113
        unfolding power2_sum power2_norm_eq_inner
huffman@29993
   114
        by (simp add: inner_distrib inner_commute)
huffman@29993
   115
      show "0 \<le> norm x + norm y"
huffman@29993
   116
        unfolding norm_eq_sqrt_inner
huffman@29993
   117
        by (simp add: add_nonneg_nonneg)
huffman@29993
   118
    qed
huffman@29993
   119
  have "sqrt (a\<twosuperior> * inner x x) = \<bar>a\<bar> * sqrt (inner x x)"
huffman@29993
   120
    by (simp add: real_sqrt_mult_distrib)
huffman@29993
   121
  then show "norm (a *\<^sub>R x) = \<bar>a\<bar> * norm x"
huffman@29993
   122
    unfolding norm_eq_sqrt_inner
huffman@29993
   123
    by (simp add: inner_scaleR power2_eq_square mult_assoc)
huffman@29993
   124
qed
huffman@29993
   125
huffman@29993
   126
end
huffman@29993
   127
huffman@29993
   128
interpretation inner!:
huffman@29993
   129
  bounded_bilinear "inner::'a::real_inner \<Rightarrow> 'a \<Rightarrow> real"
huffman@29993
   130
proof
huffman@29993
   131
  fix x y z :: 'a and r :: real
huffman@29993
   132
  show "inner (x + y) z = inner x z + inner y z"
huffman@29993
   133
    by (rule inner_left_distrib)
huffman@29993
   134
  show "inner x (y + z) = inner x y + inner x z"
huffman@29993
   135
    by (rule inner_right_distrib)
huffman@29993
   136
  show "inner (scaleR r x) y = scaleR r (inner x y)"
huffman@29993
   137
    unfolding real_scaleR_def by (rule inner_scaleR_left)
huffman@29993
   138
  show "inner x (scaleR r y) = scaleR r (inner x y)"
huffman@29993
   139
    unfolding real_scaleR_def by (rule inner_scaleR_right)
huffman@29993
   140
  show "\<exists>K. \<forall>x y::'a. norm (inner x y) \<le> norm x * norm y * K"
huffman@29993
   141
  proof
huffman@29993
   142
    show "\<forall>x y::'a. norm (inner x y) \<le> norm x * norm y * 1"
huffman@29993
   143
      by (simp add: Cauchy_Schwartz_ineq2)
huffman@29993
   144
  qed
huffman@29993
   145
qed
huffman@29993
   146
huffman@29993
   147
interpretation inner_left!:
huffman@29993
   148
  bounded_linear "\<lambda>x::'a::real_inner. inner x y"
huffman@29993
   149
  by (rule inner.bounded_linear_left)
huffman@29993
   150
huffman@29993
   151
interpretation inner_right!:
huffman@29993
   152
  bounded_linear "\<lambda>y::'a::real_inner. inner x y"
huffman@29993
   153
  by (rule inner.bounded_linear_right)
huffman@29993
   154
huffman@29993
   155
huffman@29993
   156
subsection {* Class instances *}
huffman@29993
   157
huffman@29993
   158
instantiation real :: real_inner
huffman@29993
   159
begin
huffman@29993
   160
huffman@29993
   161
definition inner_real_def [simp]: "inner = op *"
huffman@29993
   162
huffman@29993
   163
instance proof
huffman@29993
   164
  fix x y z r :: real
huffman@29993
   165
  show "inner x y = inner y x"
huffman@29993
   166
    unfolding inner_real_def by (rule mult_commute)
huffman@29993
   167
  show "inner (x + y) z = inner x z + inner y z"
huffman@29993
   168
    unfolding inner_real_def by (rule left_distrib)
huffman@29993
   169
  show "inner (scaleR r x) y = r * inner x y"
huffman@29993
   170
    unfolding inner_real_def real_scaleR_def by (rule mult_assoc)
huffman@29993
   171
  show "0 \<le> inner x x"
huffman@29993
   172
    unfolding inner_real_def by simp
huffman@29993
   173
  show "inner x x = 0 \<longleftrightarrow> x = 0"
huffman@29993
   174
    unfolding inner_real_def by simp
huffman@29993
   175
  show "norm x = sqrt (inner x x)"
huffman@29993
   176
    unfolding inner_real_def by simp
huffman@29993
   177
qed
huffman@29993
   178
huffman@29993
   179
end
huffman@29993
   180
huffman@29993
   181
instantiation complex :: real_inner
huffman@29993
   182
begin
huffman@29993
   183
huffman@29993
   184
definition inner_complex_def:
huffman@29993
   185
  "inner x y = Re x * Re y + Im x * Im y"
huffman@29993
   186
huffman@29993
   187
instance proof
huffman@29993
   188
  fix x y z :: complex and r :: real
huffman@29993
   189
  show "inner x y = inner y x"
huffman@29993
   190
    unfolding inner_complex_def by (simp add: mult_commute)
huffman@29993
   191
  show "inner (x + y) z = inner x z + inner y z"
huffman@29993
   192
    unfolding inner_complex_def by (simp add: left_distrib)
huffman@29993
   193
  show "inner (scaleR r x) y = r * inner x y"
huffman@29993
   194
    unfolding inner_complex_def by (simp add: right_distrib)
huffman@29993
   195
  show "0 \<le> inner x x"
huffman@29993
   196
    unfolding inner_complex_def by (simp add: add_nonneg_nonneg)
huffman@29993
   197
  show "inner x x = 0 \<longleftrightarrow> x = 0"
huffman@29993
   198
    unfolding inner_complex_def
huffman@29993
   199
    by (simp add: add_nonneg_eq_0_iff complex_Re_Im_cancel_iff)
huffman@29993
   200
  show "norm x = sqrt (inner x x)"
huffman@29993
   201
    unfolding inner_complex_def complex_norm_def
huffman@29993
   202
    by (simp add: power2_eq_square)
huffman@29993
   203
qed
huffman@29993
   204
huffman@29993
   205
end
huffman@29993
   206
huffman@29993
   207
huffman@29993
   208
subsection {* Gradient derivative *}
huffman@29993
   209
huffman@29993
   210
definition
huffman@29993
   211
  gderiv ::
huffman@29993
   212
    "['a::real_inner \<Rightarrow> real, 'a, 'a] \<Rightarrow> bool"
huffman@29993
   213
          ("(GDERIV (_)/ (_)/ :> (_))" [1000, 1000, 60] 60)
huffman@29993
   214
where
huffman@29993
   215
  "GDERIV f x :> D \<longleftrightarrow> FDERIV f x :> (\<lambda>h. inner h D)"
huffman@29993
   216
huffman@29993
   217
lemma deriv_fderiv: "DERIV f x :> D \<longleftrightarrow> FDERIV f x :> (\<lambda>h. h * D)"
huffman@29993
   218
  by (simp only: deriv_def field_fderiv_def)
huffman@29993
   219
huffman@29993
   220
lemma gderiv_deriv [simp]: "GDERIV f x :> D \<longleftrightarrow> DERIV f x :> D"
huffman@29993
   221
  by (simp only: gderiv_def deriv_fderiv inner_real_def)
huffman@29993
   222
huffman@29993
   223
lemma GDERIV_DERIV_compose:
huffman@29993
   224
    "\<lbrakk>GDERIV f x :> df; DERIV g (f x) :> dg\<rbrakk>
huffman@29993
   225
     \<Longrightarrow> GDERIV (\<lambda>x. g (f x)) x :> scaleR dg df"
huffman@29993
   226
  unfolding gderiv_def deriv_fderiv
huffman@29993
   227
  apply (drule (1) FDERIV_compose)
huffman@29993
   228
  apply (simp add: inner_scaleR_right mult_ac)
huffman@29993
   229
  done
huffman@29993
   230
huffman@29993
   231
lemma FDERIV_subst: "\<lbrakk>FDERIV f x :> df; df = d\<rbrakk> \<Longrightarrow> FDERIV f x :> d"
huffman@29993
   232
  by simp
huffman@29993
   233
huffman@29993
   234
lemma GDERIV_subst: "\<lbrakk>GDERIV f x :> df; df = d\<rbrakk> \<Longrightarrow> GDERIV f x :> d"
huffman@29993
   235
  by simp
huffman@29993
   236
huffman@29993
   237
lemma GDERIV_const: "GDERIV (\<lambda>x. k) x :> 0"
huffman@29993
   238
  unfolding gderiv_def inner_right.zero by (rule FDERIV_const)
huffman@29993
   239
huffman@29993
   240
lemma GDERIV_add:
huffman@29993
   241
    "\<lbrakk>GDERIV f x :> df; GDERIV g x :> dg\<rbrakk>
huffman@29993
   242
     \<Longrightarrow> GDERIV (\<lambda>x. f x + g x) x :> df + dg"
huffman@29993
   243
  unfolding gderiv_def inner_right.add by (rule FDERIV_add)
huffman@29993
   244
huffman@29993
   245
lemma GDERIV_minus:
huffman@29993
   246
    "GDERIV f x :> df \<Longrightarrow> GDERIV (\<lambda>x. - f x) x :> - df"
huffman@29993
   247
  unfolding gderiv_def inner_right.minus by (rule FDERIV_minus)
huffman@29993
   248
huffman@29993
   249
lemma GDERIV_diff:
huffman@29993
   250
    "\<lbrakk>GDERIV f x :> df; GDERIV g x :> dg\<rbrakk>
huffman@29993
   251
     \<Longrightarrow> GDERIV (\<lambda>x. f x - g x) x :> df - dg"
huffman@29993
   252
  unfolding gderiv_def inner_right.diff by (rule FDERIV_diff)
huffman@29993
   253
huffman@29993
   254
lemma GDERIV_scaleR:
huffman@29993
   255
    "\<lbrakk>DERIV f x :> df; GDERIV g x :> dg\<rbrakk>
huffman@29993
   256
     \<Longrightarrow> GDERIV (\<lambda>x. scaleR (f x) (g x)) x
huffman@29993
   257
      :> (scaleR (f x) dg + scaleR df (g x))"
huffman@29993
   258
  unfolding gderiv_def deriv_fderiv inner_right.add inner_right.scaleR
huffman@29993
   259
  apply (rule FDERIV_subst)
huffman@29993
   260
  apply (erule (1) scaleR.FDERIV)
huffman@29993
   261
  apply (simp add: mult_ac)
huffman@29993
   262
  done
huffman@29993
   263
huffman@29993
   264
lemma GDERIV_mult:
huffman@29993
   265
    "\<lbrakk>GDERIV f x :> df; GDERIV g x :> dg\<rbrakk>
huffman@29993
   266
     \<Longrightarrow> GDERIV (\<lambda>x. f x * g x) x :> scaleR (f x) dg + scaleR (g x) df"
huffman@29993
   267
  unfolding gderiv_def
huffman@29993
   268
  apply (rule FDERIV_subst)
huffman@29993
   269
  apply (erule (1) FDERIV_mult)
huffman@29993
   270
  apply (simp add: inner_distrib inner_scaleR mult_ac)
huffman@29993
   271
  done
huffman@29993
   272
huffman@29993
   273
lemma GDERIV_inverse:
huffman@29993
   274
    "\<lbrakk>GDERIV f x :> df; f x \<noteq> 0\<rbrakk>
huffman@29993
   275
     \<Longrightarrow> GDERIV (\<lambda>x. inverse (f x)) x :> - (inverse (f x))\<twosuperior> *\<^sub>R df"
huffman@29993
   276
  apply (erule GDERIV_DERIV_compose)
huffman@29993
   277
  apply (erule DERIV_inverse [folded numeral_2_eq_2])
huffman@29993
   278
  done
huffman@29993
   279
huffman@29993
   280
lemma GDERIV_norm:
huffman@29993
   281
  assumes "x \<noteq> 0" shows "GDERIV (\<lambda>x. norm x) x :> sgn x"
huffman@29993
   282
proof -
huffman@29993
   283
  have 1: "FDERIV (\<lambda>x. inner x x) x :> (\<lambda>h. inner x h + inner h x)"
huffman@29993
   284
    by (intro inner.FDERIV FDERIV_ident)
huffman@29993
   285
  have 2: "(\<lambda>h. inner x h + inner h x) = (\<lambda>h. inner h (scaleR 2 x))"
huffman@29993
   286
    by (simp add: expand_fun_eq inner_scaleR inner_commute)
huffman@29993
   287
  have "0 < inner x x" using `x \<noteq> 0` by simp
huffman@29993
   288
  then have 3: "DERIV sqrt (inner x x) :> (inverse (sqrt (inner x x)) / 2)"
huffman@29993
   289
    by (rule DERIV_real_sqrt)
huffman@29993
   290
  have 4: "(inverse (sqrt (inner x x)) / 2) *\<^sub>R 2 *\<^sub>R x = sgn x"
huffman@29993
   291
    by (simp add: sgn_div_norm norm_eq_sqrt_inner)
huffman@29993
   292
  show ?thesis
huffman@29993
   293
    unfolding norm_eq_sqrt_inner
huffman@29993
   294
    apply (rule GDERIV_subst [OF _ 4])
huffman@29993
   295
    apply (rule GDERIV_DERIV_compose [where g=sqrt and df="scaleR 2 x"])
huffman@29993
   296
    apply (subst gderiv_def)
huffman@29993
   297
    apply (rule FDERIV_subst [OF _ 2])
huffman@29993
   298
    apply (rule 1)
huffman@29993
   299
    apply (rule 3)
huffman@29993
   300
    done
huffman@29993
   301
qed
huffman@29993
   302
huffman@29993
   303
lemmas FDERIV_norm = GDERIV_norm [unfolded gderiv_def]
huffman@29993
   304
huffman@29993
   305
end