src/HOLCF/Cfun.thy
author huffman
Thu Nov 03 01:28:22 2005 +0100 (2005-11-03)
changeset 18079 9d4d70b175fd
parent 18078 20e5a6440790
child 18087 577d57e51f89
permissions -rw-r--r--
add translation for wildcard pattern
huffman@15600
     1
(*  Title:      HOLCF/Cfun.thy
huffman@15576
     2
    ID:         $Id$
huffman@15576
     3
    Author:     Franz Regensburger
huffman@15576
     4
huffman@15576
     5
Definition of the type ->  of continuous functions.
huffman@15576
     6
*)
huffman@15576
     7
huffman@15576
     8
header {* The type of continuous functions *}
huffman@15576
     9
huffman@15577
    10
theory Cfun
huffman@16699
    11
imports Pcpodef
haftmann@16417
    12
uses ("cont_proc.ML")
huffman@15577
    13
begin
huffman@15576
    14
huffman@15576
    15
defaultsort cpo
huffman@15576
    16
huffman@15589
    17
subsection {* Definition of continuous function type *}
huffman@15589
    18
huffman@16699
    19
lemma Ex_cont: "\<exists>f. cont f"
huffman@16699
    20
by (rule exI, rule cont_const)
huffman@16699
    21
huffman@16699
    22
lemma adm_cont: "adm cont"
huffman@16699
    23
by (rule admI, rule cont_lub_fun)
huffman@16699
    24
huffman@17817
    25
cpodef (CFun)  ('a, 'b) "->" (infixr "->" 0) = "{f::'a => 'b. cont f}"
huffman@16699
    26
by (simp add: Ex_cont adm_cont)
huffman@15576
    27
huffman@17816
    28
syntax (xsymbols)
huffman@17816
    29
  "->"     :: "[type, type] => type"      ("(_ \<rightarrow>/ _)" [1,0]0)
huffman@17816
    30
huffman@15576
    31
syntax
huffman@17816
    32
  Rep_CFun :: "('a \<rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b)" ("_$_" [999,1000] 999)
huffman@15576
    33
huffman@15576
    34
syntax (xsymbols)
huffman@17816
    35
  Rep_CFun :: "('a \<rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b)" ("(_\<cdot>_)" [999,1000] 999)
huffman@15576
    36
huffman@15576
    37
syntax (HTML output)
huffman@17816
    38
  Rep_CFun :: "('a \<rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b)" ("(_\<cdot>_)" [999,1000] 999)
huffman@17816
    39
huffman@17832
    40
subsection {* Syntax for continuous lambda abstraction *}
huffman@17832
    41
huffman@18078
    42
syntax "_cabs" :: "'a"
huffman@18078
    43
huffman@18078
    44
parse_translation {*
huffman@18078
    45
(* rewrites (_cabs x t) --> (Abs_CFun (%x. t)) *)
huffman@18078
    46
  [mk_binder_tr ("_cabs", "Abs_CFun")];
huffman@18078
    47
*}
huffman@17816
    48
huffman@17832
    49
text {* To avoid eta-contraction of body: *}
huffman@17816
    50
print_translation {*
huffman@18078
    51
  let
huffman@18078
    52
    fun cabs_tr' [Abs abs] =
huffman@18078
    53
      let val (x,t) = atomic_abs_tr' abs
huffman@18078
    54
      in Syntax.const "_cabs" $ x $ t end
huffman@18078
    55
  in [("Abs_CFun", cabs_tr')] end;
huffman@17816
    56
*}
huffman@17816
    57
huffman@17832
    58
text {* syntax for nested abstractions *}
huffman@17832
    59
huffman@17832
    60
syntax
huffman@18078
    61
  "_Lambda" :: "[cargs, 'a] \<Rightarrow> logic"  ("(3LAM _./ _)" [1000, 10] 10)
huffman@17832
    62
huffman@17832
    63
syntax (xsymbols)
huffman@18078
    64
  "_Lambda" :: "[cargs, 'a] \<Rightarrow> logic" ("(3\<Lambda>_./ _)" [1000, 10] 10)
huffman@17832
    65
huffman@17816
    66
parse_ast_translation {*
huffman@17832
    67
(* rewrites (LAM x y z. t) --> (_cabs x (_cabs y (_cabs z t))) *)
huffman@18078
    68
(* cf. Syntax.lambda_ast_tr from Syntax/syn_trans.ML *)
huffman@18078
    69
  let
huffman@18078
    70
    fun Lambda_ast_tr [pats, body] =
huffman@18078
    71
          Syntax.fold_ast_p "_cabs" (Syntax.unfold_ast "_cargs" pats, body)
huffman@18078
    72
      | Lambda_ast_tr asts = raise Syntax.AST ("Lambda_ast_tr", asts);
huffman@18078
    73
  in [("_Lambda", Lambda_ast_tr)] end;
huffman@17816
    74
*}
huffman@17816
    75
huffman@17816
    76
print_ast_translation {*
huffman@17832
    77
(* rewrites (_cabs x (_cabs y (_cabs z t))) --> (LAM x y z. t) *)
huffman@18078
    78
(* cf. Syntax.abs_ast_tr' from Syntax/syn_trans.ML *)
huffman@18078
    79
  let
huffman@18078
    80
    fun cabs_ast_tr' asts =
huffman@18078
    81
      (case Syntax.unfold_ast_p "_cabs"
huffman@18078
    82
          (Syntax.Appl (Syntax.Constant "_cabs" :: asts)) of
huffman@18078
    83
        ([], _) => raise Syntax.AST ("cabs_ast_tr'", asts)
huffman@18078
    84
      | (xs, body) => Syntax.Appl
huffman@18078
    85
          [Syntax.Constant "_Lambda", Syntax.fold_ast "_cargs" xs, body]);
huffman@18078
    86
  in [("_cabs", cabs_ast_tr')] end;
huffman@17816
    87
*}
huffman@15641
    88
huffman@18079
    89
translations
huffman@18079
    90
  "\<Lambda> _. t" == "Abs_CFun (\<lambda> _. t)"
huffman@18079
    91
huffman@17832
    92
subsection {* Continuous function space is pointed *}
huffman@15589
    93
huffman@16098
    94
lemma UU_CFun: "\<bottom> \<in> CFun"
huffman@16098
    95
by (simp add: CFun_def inst_fun_pcpo cont_const)
huffman@16098
    96
huffman@16098
    97
instance "->" :: (cpo, pcpo) pcpo
huffman@16920
    98
by (rule typedef_pcpo [OF type_definition_CFun less_CFun_def UU_CFun])
huffman@16098
    99
huffman@16209
   100
lemmas Rep_CFun_strict =
huffman@16699
   101
  typedef_Rep_strict [OF type_definition_CFun less_CFun_def UU_CFun]
huffman@16209
   102
huffman@16209
   103
lemmas Abs_CFun_strict =
huffman@16699
   104
  typedef_Abs_strict [OF type_definition_CFun less_CFun_def UU_CFun]
huffman@16098
   105
huffman@17832
   106
text {* function application is strict in its first argument *}
huffman@17832
   107
huffman@17832
   108
lemma Rep_CFun_strict1 [simp]: "\<bottom>\<cdot>x = \<bottom>"
huffman@17832
   109
by (simp add: Rep_CFun_strict)
huffman@17832
   110
huffman@17832
   111
text {* for compatibility with old HOLCF-Version *}
huffman@17832
   112
lemma inst_cfun_pcpo: "\<bottom> = (\<Lambda> x. \<bottom>)"
huffman@17832
   113
by (simp add: inst_fun_pcpo [symmetric] Abs_CFun_strict)
huffman@17832
   114
huffman@17832
   115
subsection {* Basic properties of continuous functions *}
huffman@17832
   116
huffman@17832
   117
text {* Beta-equality for continuous functions *}
huffman@16209
   118
huffman@16209
   119
lemma Abs_CFun_inverse2: "cont f \<Longrightarrow> Rep_CFun (Abs_CFun f) = f"
huffman@16209
   120
by (simp add: Abs_CFun_inverse CFun_def)
huffman@16098
   121
huffman@16209
   122
lemma beta_cfun [simp]: "cont f \<Longrightarrow> (\<Lambda> x. f x)\<cdot>u = f u"
huffman@16209
   123
by (simp add: Abs_CFun_inverse2)
huffman@16209
   124
huffman@16209
   125
text {* Eta-equality for continuous functions *}
huffman@16209
   126
huffman@16209
   127
lemma eta_cfun: "(\<Lambda> x. f\<cdot>x) = f"
huffman@16209
   128
by (rule Rep_CFun_inverse)
huffman@16209
   129
huffman@16209
   130
text {* Extensionality for continuous functions *}
huffman@16209
   131
huffman@17832
   132
lemma expand_cfun_eq: "(f = g) = (\<forall>x. f\<cdot>x = g\<cdot>x)"
huffman@17832
   133
by (simp add: Rep_CFun_inject [symmetric] expand_fun_eq)
huffman@17832
   134
huffman@16209
   135
lemma ext_cfun: "(\<And>x. f\<cdot>x = g\<cdot>x) \<Longrightarrow> f = g"
huffman@17832
   136
by (simp add: expand_cfun_eq)
huffman@17832
   137
huffman@17832
   138
text {* Extensionality wrt. ordering for continuous functions *}
huffman@15576
   139
huffman@17832
   140
lemma expand_cfun_less: "f \<sqsubseteq> g = (\<forall>x. f\<cdot>x \<sqsubseteq> g\<cdot>x)" 
huffman@17832
   141
by (simp add: less_CFun_def expand_fun_less)
huffman@17832
   142
huffman@17832
   143
lemma less_cfun_ext: "(\<And>x. f\<cdot>x \<sqsubseteq> g\<cdot>x) \<Longrightarrow> f \<sqsubseteq> g"
huffman@17832
   144
by (simp add: expand_cfun_less)
huffman@17832
   145
huffman@17832
   146
text {* Congruence for continuous function application *}
huffman@15589
   147
huffman@16209
   148
lemma cfun_cong: "\<lbrakk>f = g; x = y\<rbrakk> \<Longrightarrow> f\<cdot>x = g\<cdot>y"
huffman@15589
   149
by simp
huffman@15589
   150
huffman@16209
   151
lemma cfun_fun_cong: "f = g \<Longrightarrow> f\<cdot>x = g\<cdot>x"
huffman@15589
   152
by simp
huffman@15589
   153
huffman@16209
   154
lemma cfun_arg_cong: "x = y \<Longrightarrow> f\<cdot>x = f\<cdot>y"
huffman@15589
   155
by simp
huffman@15589
   156
huffman@16209
   157
subsection {* Continuity of application *}
huffman@15576
   158
huffman@16209
   159
lemma cont_Rep_CFun1: "cont (\<lambda>f. f\<cdot>x)"
huffman@16209
   160
by (rule cont_Rep_CFun [THEN cont2cont_CF1L])
huffman@15576
   161
huffman@16209
   162
lemma cont_Rep_CFun2: "cont (\<lambda>x. f\<cdot>x)"
huffman@16209
   163
apply (rule_tac P = "cont" in CollectD)
huffman@16209
   164
apply (fold CFun_def)
huffman@16209
   165
apply (rule Rep_CFun)
huffman@15576
   166
done
huffman@15576
   167
huffman@16209
   168
lemmas monofun_Rep_CFun = cont_Rep_CFun [THEN cont2mono]
huffman@16209
   169
lemmas contlub_Rep_CFun = cont_Rep_CFun [THEN cont2contlub]
huffman@15589
   170
huffman@16209
   171
lemmas monofun_Rep_CFun1 = cont_Rep_CFun1 [THEN cont2mono, standard]
huffman@16209
   172
lemmas contlub_Rep_CFun1 = cont_Rep_CFun1 [THEN cont2contlub, standard]
huffman@16209
   173
lemmas monofun_Rep_CFun2 = cont_Rep_CFun2 [THEN cont2mono, standard]
huffman@16209
   174
lemmas contlub_Rep_CFun2 = cont_Rep_CFun2 [THEN cont2contlub, standard]
huffman@16209
   175
huffman@16209
   176
text {* contlub, cont properties of @{term Rep_CFun} in each argument *}
huffman@16209
   177
huffman@16209
   178
lemma contlub_cfun_arg: "chain Y \<Longrightarrow> f\<cdot>(lub (range Y)) = (\<Squnion>i. f\<cdot>(Y i))"
huffman@16209
   179
by (rule contlub_Rep_CFun2 [THEN contlubE])
huffman@15576
   180
huffman@16209
   181
lemma cont_cfun_arg: "chain Y \<Longrightarrow> range (\<lambda>i. f\<cdot>(Y i)) <<| f\<cdot>(lub (range Y))"
huffman@16209
   182
by (rule cont_Rep_CFun2 [THEN contE])
huffman@16209
   183
huffman@16209
   184
lemma contlub_cfun_fun: "chain F \<Longrightarrow> lub (range F)\<cdot>x = (\<Squnion>i. F i\<cdot>x)"
huffman@16209
   185
by (rule contlub_Rep_CFun1 [THEN contlubE])
huffman@15576
   186
huffman@16209
   187
lemma cont_cfun_fun: "chain F \<Longrightarrow> range (\<lambda>i. F i\<cdot>x) <<| lub (range F)\<cdot>x"
huffman@16209
   188
by (rule cont_Rep_CFun1 [THEN contE])
huffman@15576
   189
huffman@16209
   190
text {* monotonicity of application *}
huffman@16209
   191
huffman@16209
   192
lemma monofun_cfun_fun: "f \<sqsubseteq> g \<Longrightarrow> f\<cdot>x \<sqsubseteq> g\<cdot>x"
huffman@17832
   193
by (simp add: expand_cfun_less)
huffman@15576
   194
huffman@16209
   195
lemma monofun_cfun_arg: "x \<sqsubseteq> y \<Longrightarrow> f\<cdot>x \<sqsubseteq> f\<cdot>y"
huffman@16209
   196
by (rule monofun_Rep_CFun2 [THEN monofunE])
huffman@15576
   197
huffman@16209
   198
lemma monofun_cfun: "\<lbrakk>f \<sqsubseteq> g; x \<sqsubseteq> y\<rbrakk> \<Longrightarrow> f\<cdot>x \<sqsubseteq> g\<cdot>y"
huffman@16209
   199
by (rule trans_less [OF monofun_cfun_fun monofun_cfun_arg])
huffman@15576
   200
huffman@16209
   201
text {* ch2ch - rules for the type @{typ "'a -> 'b"} *}
huffman@15576
   202
huffman@16209
   203
lemma chain_monofun: "chain Y \<Longrightarrow> chain (\<lambda>i. f\<cdot>(Y i))"
huffman@16209
   204
by (erule monofun_Rep_CFun2 [THEN ch2ch_monofun])
huffman@16209
   205
huffman@16209
   206
lemma ch2ch_Rep_CFunR: "chain Y \<Longrightarrow> chain (\<lambda>i. f\<cdot>(Y i))"
huffman@16209
   207
by (rule monofun_Rep_CFun2 [THEN ch2ch_monofun])
huffman@15576
   208
huffman@16209
   209
lemma ch2ch_Rep_CFunL: "chain F \<Longrightarrow> chain (\<lambda>i. (F i)\<cdot>x)"
huffman@16209
   210
by (rule monofun_Rep_CFun1 [THEN ch2ch_monofun])
huffman@15576
   211
huffman@18076
   212
lemma ch2ch_Rep_CFun [simp]:
huffman@18076
   213
  "\<lbrakk>chain F; chain Y\<rbrakk> \<Longrightarrow> chain (\<lambda>i. (F i)\<cdot>(Y i))"
huffman@15576
   214
apply (rule chainI)
huffman@16209
   215
apply (rule monofun_cfun)
huffman@16209
   216
apply (erule chainE)
huffman@15576
   217
apply (erule chainE)
huffman@15576
   218
done
huffman@15576
   219
huffman@16209
   220
text {* contlub, cont properties of @{term Rep_CFun} in both arguments *}
huffman@15576
   221
huffman@16209
   222
lemma contlub_cfun: 
huffman@16209
   223
  "\<lbrakk>chain F; chain Y\<rbrakk> \<Longrightarrow> (\<Squnion>i. F i)\<cdot>(\<Squnion>i. Y i) = (\<Squnion>i. F i\<cdot>(Y i))"
huffman@18076
   224
by (simp add: contlub_cfun_fun contlub_cfun_arg diag_lub)
huffman@15576
   225
huffman@16209
   226
lemma cont_cfun: 
huffman@16209
   227
  "\<lbrakk>chain F; chain Y\<rbrakk> \<Longrightarrow> range (\<lambda>i. F i\<cdot>(Y i)) <<| (\<Squnion>i. F i)\<cdot>(\<Squnion>i. Y i)"
huffman@16209
   228
apply (rule thelubE)
huffman@16209
   229
apply (simp only: ch2ch_Rep_CFun)
huffman@16209
   230
apply (simp only: contlub_cfun)
huffman@16209
   231
done
huffman@16209
   232
huffman@16209
   233
text {* strictness *}
huffman@16209
   234
huffman@16209
   235
lemma strictI: "f\<cdot>x = \<bottom> \<Longrightarrow> f\<cdot>\<bottom> = \<bottom>"
huffman@16209
   236
apply (rule UU_I)
huffman@15576
   237
apply (erule subst)
huffman@15576
   238
apply (rule minimal [THEN monofun_cfun_arg])
huffman@15576
   239
done
huffman@15576
   240
huffman@16209
   241
text {* the lub of a chain of continous functions is monotone *}
huffman@15576
   242
huffman@16209
   243
lemma lub_cfun_mono: "chain F \<Longrightarrow> monofun (\<lambda>x. \<Squnion>i. F i\<cdot>x)"
huffman@16209
   244
apply (drule ch2ch_monofun [OF monofun_Rep_CFun])
huffman@16209
   245
apply (simp add: thelub_fun [symmetric])
huffman@16209
   246
apply (erule monofun_lub_fun)
huffman@16209
   247
apply (simp add: monofun_Rep_CFun2)
huffman@15576
   248
done
huffman@15576
   249
huffman@16386
   250
text {* a lemma about the exchange of lubs for type @{typ "'a -> 'b"} *}
huffman@15576
   251
huffman@16699
   252
lemma ex_lub_cfun:
huffman@16699
   253
  "\<lbrakk>chain F; chain Y\<rbrakk> \<Longrightarrow> (\<Squnion>j. \<Squnion>i. F j\<cdot>(Y i)) = (\<Squnion>i. \<Squnion>j. F j\<cdot>(Y i))"
huffman@18076
   254
by (simp add: diag_lub)
huffman@15576
   255
huffman@15589
   256
text {* the lub of a chain of cont. functions is continuous *}
huffman@15576
   257
huffman@16209
   258
lemma cont_lub_cfun: "chain F \<Longrightarrow> cont (\<lambda>x. \<Squnion>i. F i\<cdot>x)"
huffman@16209
   259
apply (rule cont2cont_lub)
huffman@16209
   260
apply (erule monofun_Rep_CFun [THEN ch2ch_monofun])
huffman@16209
   261
apply (rule cont_Rep_CFun2)
huffman@15576
   262
done
huffman@15576
   263
huffman@15589
   264
text {* type @{typ "'a -> 'b"} is chain complete *}
huffman@15576
   265
huffman@16920
   266
lemma lub_cfun: "chain F \<Longrightarrow> range F <<| (\<Lambda> x. \<Squnion>i. F i\<cdot>x)"
huffman@16920
   267
by (simp only: contlub_cfun_fun [symmetric] eta_cfun thelubE)
huffman@15576
   268
huffman@16920
   269
lemma thelub_cfun: "chain F \<Longrightarrow> lub (range F) = (\<Lambda> x. \<Squnion>i. F i\<cdot>x)"
huffman@16920
   270
by (rule lub_cfun [THEN thelubI])
huffman@15576
   271
huffman@17832
   272
subsection {* Continuity simplification procedure *}
huffman@15589
   273
huffman@15589
   274
text {* cont2cont lemma for @{term Rep_CFun} *}
huffman@15576
   275
huffman@16209
   276
lemma cont2cont_Rep_CFun:
huffman@16209
   277
  "\<lbrakk>cont f; cont t\<rbrakk> \<Longrightarrow> cont (\<lambda>x. (f x)\<cdot>(t x))"
huffman@16209
   278
by (best intro: cont2cont_app2 cont_const cont_Rep_CFun cont_Rep_CFun2)
huffman@15576
   279
huffman@15589
   280
text {* cont2mono Lemma for @{term "%x. LAM y. c1(x)(y)"} *}
huffman@15576
   281
huffman@15576
   282
lemma cont2mono_LAM:
huffman@15576
   283
assumes p1: "!!x. cont(c1 x)"
huffman@15576
   284
assumes p2: "!!y. monofun(%x. c1 x y)"
huffman@15576
   285
shows "monofun(%x. LAM y. c1 x y)"
huffman@16209
   286
apply (rule monofunI)
huffman@16209
   287
apply (rule less_cfun_ext)
huffman@16209
   288
apply (simp add: p1)
huffman@16209
   289
apply (erule p2 [THEN monofunE])
huffman@15576
   290
done
huffman@15576
   291
huffman@15589
   292
text {* cont2cont Lemma for @{term "%x. LAM y. c1 x y"} *}
huffman@15576
   293
huffman@15576
   294
lemma cont2cont_LAM:
huffman@15576
   295
assumes p1: "!!x. cont(c1 x)"
huffman@15576
   296
assumes p2: "!!y. cont(%x. c1 x y)"
huffman@15576
   297
shows "cont(%x. LAM y. c1 x y)"
huffman@16098
   298
apply (rule cont_Abs_CFun)
huffman@16098
   299
apply (simp add: p1 CFun_def)
huffman@17832
   300
apply (simp add: p2 cont2cont_lambda)
huffman@15576
   301
done
huffman@15576
   302
huffman@16386
   303
text {* continuity simplification procedure *}
huffman@15576
   304
huffman@16055
   305
lemmas cont_lemmas1 =
huffman@16055
   306
  cont_const cont_id cont_Rep_CFun2 cont2cont_Rep_CFun cont2cont_LAM
huffman@16055
   307
huffman@16386
   308
use "cont_proc.ML";
huffman@16386
   309
setup ContProc.setup;
huffman@15576
   310
huffman@15576
   311
(*val cont_tac = (fn i => (resolve_tac cont_lemmas i));*)
huffman@15576
   312
(*val cont_tacR = (fn i => (REPEAT (cont_tac i)));*)
huffman@15576
   313
huffman@17832
   314
subsection {* Miscellaneous *}
huffman@17832
   315
huffman@17832
   316
text {* Monotonicity of @{term Abs_CFun} *}
huffman@15576
   317
huffman@17832
   318
lemma semi_monofun_Abs_CFun:
huffman@17832
   319
  "\<lbrakk>cont f; cont g; f \<sqsubseteq> g\<rbrakk> \<Longrightarrow> Abs_CFun f \<sqsubseteq> Abs_CFun g"
huffman@17832
   320
by (simp add: less_CFun_def Abs_CFun_inverse2)
huffman@15576
   321
huffman@15589
   322
text {* some lemmata for functions with flat/chfin domain/range types *}
huffman@15576
   323
huffman@15576
   324
lemma chfin_Rep_CFunR: "chain (Y::nat => 'a::cpo->'b::chfin)  
huffman@15576
   325
      ==> !s. ? n. lub(range(Y))$s = Y n$s"
huffman@15576
   326
apply (rule allI)
huffman@15576
   327
apply (subst contlub_cfun_fun)
huffman@15576
   328
apply assumption
huffman@15576
   329
apply (fast intro!: thelubI chfin lub_finch2 chfin2finch ch2ch_Rep_CFunL)
huffman@15576
   330
done
huffman@15576
   331
huffman@16085
   332
subsection {* Continuous injection-retraction pairs *}
huffman@15589
   333
huffman@16085
   334
text {* Continuous retractions are strict. *}
huffman@15576
   335
huffman@16085
   336
lemma retraction_strict:
huffman@16085
   337
  "\<forall>x. f\<cdot>(g\<cdot>x) = x \<Longrightarrow> f\<cdot>\<bottom> = \<bottom>"
huffman@15576
   338
apply (rule UU_I)
huffman@16085
   339
apply (drule_tac x="\<bottom>" in spec)
huffman@16085
   340
apply (erule subst)
huffman@16085
   341
apply (rule monofun_cfun_arg)
huffman@16085
   342
apply (rule minimal)
huffman@15576
   343
done
huffman@15576
   344
huffman@16085
   345
lemma injection_eq:
huffman@16085
   346
  "\<forall>x. f\<cdot>(g\<cdot>x) = x \<Longrightarrow> (g\<cdot>x = g\<cdot>y) = (x = y)"
huffman@16085
   347
apply (rule iffI)
huffman@16085
   348
apply (drule_tac f=f in cfun_arg_cong)
huffman@16085
   349
apply simp
huffman@16085
   350
apply simp
huffman@15576
   351
done
huffman@15576
   352
huffman@16314
   353
lemma injection_less:
huffman@16314
   354
  "\<forall>x. f\<cdot>(g\<cdot>x) = x \<Longrightarrow> (g\<cdot>x \<sqsubseteq> g\<cdot>y) = (x \<sqsubseteq> y)"
huffman@16314
   355
apply (rule iffI)
huffman@16314
   356
apply (drule_tac f=f in monofun_cfun_arg)
huffman@16314
   357
apply simp
huffman@16314
   358
apply (erule monofun_cfun_arg)
huffman@16314
   359
done
huffman@16314
   360
huffman@16085
   361
lemma injection_defined_rev:
huffman@16085
   362
  "\<lbrakk>\<forall>x. f\<cdot>(g\<cdot>x) = x; g\<cdot>z = \<bottom>\<rbrakk> \<Longrightarrow> z = \<bottom>"
huffman@16085
   363
apply (drule_tac f=f in cfun_arg_cong)
huffman@16085
   364
apply (simp add: retraction_strict)
huffman@15576
   365
done
huffman@15576
   366
huffman@16085
   367
lemma injection_defined:
huffman@16085
   368
  "\<lbrakk>\<forall>x. f\<cdot>(g\<cdot>x) = x; z \<noteq> \<bottom>\<rbrakk> \<Longrightarrow> g\<cdot>z \<noteq> \<bottom>"
huffman@16085
   369
by (erule contrapos_nn, rule injection_defined_rev)
huffman@16085
   370
huffman@16085
   371
text {* propagation of flatness and chain-finiteness by retractions *}
huffman@16085
   372
huffman@16085
   373
lemma chfin2chfin:
huffman@16085
   374
  "\<forall>y. (f::'a::chfin \<rightarrow> 'b)\<cdot>(g\<cdot>y) = y
huffman@16085
   375
    \<Longrightarrow> \<forall>Y::nat \<Rightarrow> 'b. chain Y \<longrightarrow> (\<exists>n. max_in_chain n Y)"
huffman@16085
   376
apply clarify
huffman@16085
   377
apply (drule_tac f=g in chain_monofun)
huffman@16085
   378
apply (drule chfin [rule_format])
huffman@16085
   379
apply (unfold max_in_chain_def)
huffman@16085
   380
apply (simp add: injection_eq)
huffman@16085
   381
done
huffman@16085
   382
huffman@16085
   383
lemma flat2flat:
huffman@16085
   384
  "\<forall>y. (f::'a::flat \<rightarrow> 'b::pcpo)\<cdot>(g\<cdot>y) = y
huffman@16085
   385
    \<Longrightarrow> \<forall>x y::'b. x \<sqsubseteq> y \<longrightarrow> x = \<bottom> \<or> x = y"
huffman@16085
   386
apply clarify
huffman@16209
   387
apply (drule_tac f=g in monofun_cfun_arg)
huffman@16085
   388
apply (drule ax_flat [rule_format])
huffman@16085
   389
apply (erule disjE)
huffman@16085
   390
apply (simp add: injection_defined_rev)
huffman@16085
   391
apply (simp add: injection_eq)
huffman@15576
   392
done
huffman@15576
   393
huffman@15589
   394
text {* a result about functions with flat codomain *}
huffman@15576
   395
huffman@16085
   396
lemma flat_eqI: "\<lbrakk>(x::'a::flat) \<sqsubseteq> y; x \<noteq> \<bottom>\<rbrakk> \<Longrightarrow> x = y"
huffman@16085
   397
by (drule ax_flat [rule_format], simp)
huffman@16085
   398
huffman@16085
   399
lemma flat_codom:
huffman@16085
   400
  "f\<cdot>x = (c::'b::flat) \<Longrightarrow> f\<cdot>\<bottom> = \<bottom> \<or> (\<forall>z. f\<cdot>z = c)"
huffman@16085
   401
apply (case_tac "f\<cdot>x = \<bottom>")
huffman@15576
   402
apply (rule disjI1)
huffman@15576
   403
apply (rule UU_I)
huffman@16085
   404
apply (erule_tac t="\<bottom>" in subst)
huffman@15576
   405
apply (rule minimal [THEN monofun_cfun_arg])
huffman@16085
   406
apply clarify
huffman@16085
   407
apply (rule_tac a = "f\<cdot>\<bottom>" in refl [THEN box_equals])
huffman@16085
   408
apply (erule minimal [THEN monofun_cfun_arg, THEN flat_eqI])
huffman@16085
   409
apply (erule minimal [THEN monofun_cfun_arg, THEN flat_eqI])
huffman@15589
   410
done
huffman@15589
   411
huffman@15589
   412
huffman@15589
   413
subsection {* Identity and composition *}
huffman@15589
   414
huffman@15589
   415
consts
huffman@16085
   416
  ID      :: "'a \<rightarrow> 'a"
huffman@16085
   417
  cfcomp  :: "('b \<rightarrow> 'c) \<rightarrow> ('a \<rightarrow> 'b) \<rightarrow> 'a \<rightarrow> 'c"
huffman@15589
   418
huffman@16085
   419
syntax  "@oo" :: "['b \<rightarrow> 'c, 'a \<rightarrow> 'b] \<Rightarrow> 'a \<rightarrow> 'c" (infixr "oo" 100)
huffman@15589
   420
     
huffman@18076
   421
translations  "f oo g" == "cfcomp\<cdot>f\<cdot>g"
huffman@15589
   422
huffman@15589
   423
defs
huffman@16085
   424
  ID_def: "ID \<equiv> (\<Lambda> x. x)"
huffman@16085
   425
  oo_def: "cfcomp \<equiv> (\<Lambda> f g x. f\<cdot>(g\<cdot>x))" 
huffman@15589
   426
huffman@16085
   427
lemma ID1 [simp]: "ID\<cdot>x = x"
huffman@16085
   428
by (simp add: ID_def)
huffman@15576
   429
huffman@16085
   430
lemma cfcomp1: "(f oo g) = (\<Lambda> x. f\<cdot>(g\<cdot>x))"
huffman@15589
   431
by (simp add: oo_def)
huffman@15576
   432
huffman@16085
   433
lemma cfcomp2 [simp]: "(f oo g)\<cdot>x = f\<cdot>(g\<cdot>x)"
huffman@15589
   434
by (simp add: cfcomp1)
huffman@15576
   435
huffman@15589
   436
text {*
huffman@15589
   437
  Show that interpretation of (pcpo,@{text "_->_"}) is a category.
huffman@15589
   438
  The class of objects is interpretation of syntactical class pcpo.
huffman@15589
   439
  The class of arrows  between objects @{typ 'a} and @{typ 'b} is interpret. of @{typ "'a -> 'b"}.
huffman@15589
   440
  The identity arrow is interpretation of @{term ID}.
huffman@15589
   441
  The composition of f and g is interpretation of @{text "oo"}.
huffman@15589
   442
*}
huffman@15576
   443
huffman@16085
   444
lemma ID2 [simp]: "f oo ID = f"
huffman@15589
   445
by (rule ext_cfun, simp)
huffman@15576
   446
huffman@16085
   447
lemma ID3 [simp]: "ID oo f = f"
huffman@15589
   448
by (rule ext_cfun, simp)
huffman@15576
   449
huffman@15576
   450
lemma assoc_oo: "f oo (g oo h) = (f oo g) oo h"
huffman@15589
   451
by (rule ext_cfun, simp)
huffman@15576
   452
huffman@16085
   453
huffman@16085
   454
subsection {* Strictified functions *}
huffman@16085
   455
huffman@16085
   456
defaultsort pcpo
huffman@16085
   457
huffman@17815
   458
constdefs
huffman@16085
   459
  strictify  :: "('a \<rightarrow> 'b) \<rightarrow> 'a \<rightarrow> 'b"
huffman@17815
   460
  "strictify \<equiv> (\<Lambda> f x. if x = \<bottom> then \<bottom> else f\<cdot>x)"
huffman@16085
   461
huffman@16085
   462
text {* results about strictify *}
huffman@16085
   463
huffman@17815
   464
lemma cont_strictify1: "cont (\<lambda>f. if x = \<bottom> then \<bottom> else f\<cdot>x)"
huffman@17815
   465
by (simp add: cont_if)
huffman@16085
   466
huffman@17815
   467
lemma monofun_strictify2: "monofun (\<lambda>x. if x = \<bottom> then \<bottom> else f\<cdot>x)"
huffman@17815
   468
apply (rule monofunI)
huffman@17815
   469
apply (auto simp add: monofun_cfun_arg eq_UU_iff [symmetric])
huffman@16085
   470
done
huffman@16085
   471
huffman@17815
   472
(*FIXME: long proof*)
huffman@17815
   473
lemma contlub_strictify2: "contlub (\<lambda>x. if x = \<bottom> then \<bottom> else f\<cdot>x)"
huffman@16209
   474
apply (rule contlubI)
huffman@16085
   475
apply (case_tac "lub (range Y) = \<bottom>")
huffman@16699
   476
apply (drule (1) chain_UU_I)
huffman@18076
   477
apply simp
huffman@17815
   478
apply (simp del: if_image_distrib)
huffman@17815
   479
apply (simp only: contlub_cfun_arg)
huffman@16085
   480
apply (rule lub_equal2)
huffman@16085
   481
apply (rule chain_mono2 [THEN exE])
huffman@16085
   482
apply (erule chain_UU_I_inverse2)
huffman@16085
   483
apply (assumption)
huffman@17815
   484
apply (rule_tac x=x in exI, clarsimp)
huffman@16085
   485
apply (erule chain_monofun)
huffman@17815
   486
apply (erule monofun_strictify2 [THEN ch2ch_monofun])
huffman@16085
   487
done
huffman@16085
   488
huffman@17815
   489
lemmas cont_strictify2 =
huffman@17815
   490
  monocontlub2cont [OF monofun_strictify2 contlub_strictify2, standard]
huffman@17815
   491
huffman@17815
   492
lemma strictify_conv_if: "strictify\<cdot>f\<cdot>x = (if x = \<bottom> then \<bottom> else f\<cdot>x)"
huffman@17815
   493
by (unfold strictify_def, simp add: cont_strictify1 cont_strictify2)
huffman@16085
   494
huffman@16085
   495
lemma strictify1 [simp]: "strictify\<cdot>f\<cdot>\<bottom> = \<bottom>"
huffman@17815
   496
by (simp add: strictify_conv_if)
huffman@16085
   497
huffman@16085
   498
lemma strictify2 [simp]: "x \<noteq> \<bottom> \<Longrightarrow> strictify\<cdot>f\<cdot>x = f\<cdot>x"
huffman@17815
   499
by (simp add: strictify_conv_if)
huffman@16085
   500
huffman@17816
   501
subsection {* Continuous let-bindings *}
huffman@17816
   502
huffman@17816
   503
constdefs
huffman@17816
   504
  CLet :: "'a \<rightarrow> ('a \<rightarrow> 'b) \<rightarrow> 'b"
huffman@17816
   505
  "CLet \<equiv> \<Lambda> s f. f\<cdot>s"
huffman@17816
   506
huffman@17816
   507
syntax
huffman@17816
   508
  "_CLet" :: "[letbinds, 'a] => 'a" ("(Let (_)/ in (_))" 10)
huffman@17816
   509
huffman@17816
   510
translations
huffman@17816
   511
  "_CLet (_binds b bs) e" == "_CLet b (_CLet bs e)"
huffman@18076
   512
  "Let x = a in e" == "CLet\<cdot>a\<cdot>(\<Lambda> x. e)"
huffman@17816
   513
huffman@15576
   514
end