src/HOL/Int.thy
author paulson <lp15@cam.ac.uk>
Tue Sep 22 16:55:07 2015 +0100 (2015-09-22)
changeset 61234 a9e6052188fa
parent 61204 3e491e34a62e
child 61524 f2e51e704a96
permissions -rw-r--r--
New lemmas
wenzelm@41959
     1
(*  Title:      HOL/Int.thy
haftmann@25919
     2
    Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
wenzelm@41959
     3
    Author:     Tobias Nipkow, Florian Haftmann, TU Muenchen
haftmann@25919
     4
*)
haftmann@25919
     5
wenzelm@60758
     6
section \<open>The Integers as Equivalence Classes over Pairs of Natural Numbers\<close>
haftmann@25919
     7
haftmann@25919
     8
theory Int
blanchet@55404
     9
imports Equiv_Relations Power Quotient Fun_Def
haftmann@25919
    10
begin
haftmann@25919
    11
wenzelm@60758
    12
subsection \<open>Definition of integers as a quotient type\<close>
haftmann@25919
    13
huffman@48045
    14
definition intrel :: "(nat \<times> nat) \<Rightarrow> (nat \<times> nat) \<Rightarrow> bool" where
huffman@48045
    15
  "intrel = (\<lambda>(x, y) (u, v). x + v = u + y)"
huffman@48045
    16
huffman@48045
    17
lemma intrel_iff [simp]: "intrel (x, y) (u, v) \<longleftrightarrow> x + v = u + y"
huffman@48045
    18
  by (simp add: intrel_def)
haftmann@25919
    19
huffman@48045
    20
quotient_type int = "nat \<times> nat" / "intrel"
wenzelm@45694
    21
  morphisms Rep_Integ Abs_Integ
huffman@48045
    22
proof (rule equivpI)
huffman@48045
    23
  show "reflp intrel"
huffman@48045
    24
    unfolding reflp_def by auto
huffman@48045
    25
  show "symp intrel"
huffman@48045
    26
    unfolding symp_def by auto
huffman@48045
    27
  show "transp intrel"
huffman@48045
    28
    unfolding transp_def by auto
huffman@48045
    29
qed
haftmann@25919
    30
huffman@48045
    31
lemma eq_Abs_Integ [case_names Abs_Integ, cases type: int]:
huffman@48045
    32
     "(!!x y. z = Abs_Integ (x, y) ==> P) ==> P"
huffman@48045
    33
by (induct z) auto
huffman@48045
    34
wenzelm@60758
    35
subsection \<open>Integers form a commutative ring\<close>
huffman@48045
    36
huffman@48045
    37
instantiation int :: comm_ring_1
haftmann@25919
    38
begin
haftmann@25919
    39
kuncar@51994
    40
lift_definition zero_int :: "int" is "(0, 0)" .
haftmann@25919
    41
kuncar@51994
    42
lift_definition one_int :: "int" is "(1, 0)" .
haftmann@25919
    43
huffman@48045
    44
lift_definition plus_int :: "int \<Rightarrow> int \<Rightarrow> int"
huffman@48045
    45
  is "\<lambda>(x, y) (u, v). (x + u, y + v)"
huffman@48045
    46
  by clarsimp
haftmann@25919
    47
huffman@48045
    48
lift_definition uminus_int :: "int \<Rightarrow> int"
huffman@48045
    49
  is "\<lambda>(x, y). (y, x)"
huffman@48045
    50
  by clarsimp
haftmann@25919
    51
huffman@48045
    52
lift_definition minus_int :: "int \<Rightarrow> int \<Rightarrow> int"
huffman@48045
    53
  is "\<lambda>(x, y) (u, v). (x + v, y + u)"
huffman@48045
    54
  by clarsimp
haftmann@25919
    55
huffman@48045
    56
lift_definition times_int :: "int \<Rightarrow> int \<Rightarrow> int"
huffman@48045
    57
  is "\<lambda>(x, y) (u, v). (x*u + y*v, x*v + y*u)"
huffman@48045
    58
proof (clarsimp)
huffman@48045
    59
  fix s t u v w x y z :: nat
huffman@48045
    60
  assume "s + v = u + t" and "w + z = y + x"
huffman@48045
    61
  hence "(s + v) * w + (u + t) * x + u * (w + z) + v * (y + x)
huffman@48045
    62
       = (u + t) * w + (s + v) * x + u * (y + x) + v * (w + z)"
huffman@48045
    63
    by simp
huffman@48045
    64
  thus "(s * w + t * x) + (u * z + v * y) = (u * y + v * z) + (s * x + t * w)"
huffman@48045
    65
    by (simp add: algebra_simps)
huffman@48045
    66
qed
haftmann@25919
    67
huffman@48045
    68
instance
wenzelm@61169
    69
  by standard (transfer, clarsimp simp: algebra_simps)+
haftmann@25919
    70
haftmann@25919
    71
end
haftmann@25919
    72
huffman@44709
    73
abbreviation int :: "nat \<Rightarrow> int" where
huffman@44709
    74
  "int \<equiv> of_nat"
huffman@44709
    75
huffman@48045
    76
lemma int_def: "int n = Abs_Integ (n, 0)"
huffman@48045
    77
  by (induct n, simp add: zero_int.abs_eq,
huffman@48045
    78
    simp add: one_int.abs_eq plus_int.abs_eq)
haftmann@25919
    79
huffman@48045
    80
lemma int_transfer [transfer_rule]:
kuncar@56525
    81
  "(rel_fun (op =) pcr_int) (\<lambda>n. (n, 0)) int"
kuncar@56525
    82
  unfolding rel_fun_def int.pcr_cr_eq cr_int_def int_def by simp
haftmann@25919
    83
huffman@48045
    84
lemma int_diff_cases:
huffman@48045
    85
  obtains (diff) m n where "z = int m - int n"
huffman@48045
    86
  by transfer clarsimp
huffman@48045
    87
wenzelm@60758
    88
subsection \<open>Integers are totally ordered\<close>
haftmann@25919
    89
huffman@48045
    90
instantiation int :: linorder
huffman@48045
    91
begin
huffman@48045
    92
huffman@48045
    93
lift_definition less_eq_int :: "int \<Rightarrow> int \<Rightarrow> bool"
huffman@48045
    94
  is "\<lambda>(x, y) (u, v). x + v \<le> u + y"
huffman@48045
    95
  by auto
huffman@48045
    96
huffman@48045
    97
lift_definition less_int :: "int \<Rightarrow> int \<Rightarrow> bool"
huffman@48045
    98
  is "\<lambda>(x, y) (u, v). x + v < u + y"
huffman@48045
    99
  by auto
huffman@48045
   100
huffman@48045
   101
instance
wenzelm@61169
   102
  by standard (transfer, force)+
huffman@48045
   103
huffman@48045
   104
end
haftmann@25919
   105
haftmann@25919
   106
instantiation int :: distrib_lattice
haftmann@25919
   107
begin
haftmann@25919
   108
haftmann@25919
   109
definition
wenzelm@61076
   110
  "(inf :: int \<Rightarrow> int \<Rightarrow> int) = min"
haftmann@25919
   111
haftmann@25919
   112
definition
wenzelm@61076
   113
  "(sup :: int \<Rightarrow> int \<Rightarrow> int) = max"
haftmann@25919
   114
haftmann@25919
   115
instance
haftmann@25919
   116
  by intro_classes
haftmann@54863
   117
    (auto simp add: inf_int_def sup_int_def max_min_distrib2)
haftmann@25919
   118
haftmann@25919
   119
end
haftmann@25919
   120
wenzelm@60758
   121
subsection \<open>Ordering properties of arithmetic operations\<close>
huffman@48045
   122
haftmann@35028
   123
instance int :: ordered_cancel_ab_semigroup_add
haftmann@25919
   124
proof
haftmann@25919
   125
  fix i j k :: int
haftmann@25919
   126
  show "i \<le> j \<Longrightarrow> k + i \<le> k + j"
huffman@48045
   127
    by transfer clarsimp
haftmann@25919
   128
qed
haftmann@25919
   129
wenzelm@60758
   130
text\<open>Strict Monotonicity of Multiplication\<close>
haftmann@25919
   131
wenzelm@60758
   132
text\<open>strict, in 1st argument; proof is by induction on k>0\<close>
haftmann@25919
   133
lemma zmult_zless_mono2_lemma:
huffman@44709
   134
     "(i::int)<j ==> 0<k ==> int k * i < int k * j"
wenzelm@42676
   135
apply (induct k)
wenzelm@42676
   136
apply simp
webertj@49962
   137
apply (simp add: distrib_right)
haftmann@25919
   138
apply (case_tac "k=0")
haftmann@25919
   139
apply (simp_all add: add_strict_mono)
haftmann@25919
   140
done
haftmann@25919
   141
huffman@44709
   142
lemma zero_le_imp_eq_int: "(0::int) \<le> k ==> \<exists>n. k = int n"
huffman@48045
   143
apply transfer
huffman@48045
   144
apply clarsimp
huffman@48045
   145
apply (rule_tac x="a - b" in exI, simp)
haftmann@25919
   146
done
haftmann@25919
   147
huffman@44709
   148
lemma zero_less_imp_eq_int: "(0::int) < k ==> \<exists>n>0. k = int n"
huffman@48045
   149
apply transfer
huffman@48045
   150
apply clarsimp
huffman@48045
   151
apply (rule_tac x="a - b" in exI, simp)
haftmann@25919
   152
done
haftmann@25919
   153
haftmann@25919
   154
lemma zmult_zless_mono2: "[| i<j;  (0::int) < k |] ==> k*i < k*j"
haftmann@25919
   155
apply (drule zero_less_imp_eq_int)
haftmann@25919
   156
apply (auto simp add: zmult_zless_mono2_lemma)
haftmann@25919
   157
done
haftmann@25919
   158
wenzelm@60758
   159
text\<open>The integers form an ordered integral domain\<close>
huffman@48045
   160
instantiation int :: linordered_idom
huffman@48045
   161
begin
huffman@48045
   162
huffman@48045
   163
definition
wenzelm@61076
   164
  zabs_def: "\<bar>i::int\<bar> = (if i < 0 then - i else i)"
huffman@48045
   165
huffman@48045
   166
definition
wenzelm@61076
   167
  zsgn_def: "sgn (i::int) = (if i=0 then 0 else if 0<i then 1 else - 1)"
huffman@48045
   168
huffman@48045
   169
instance proof
haftmann@25919
   170
  fix i j k :: int
haftmann@25919
   171
  show "i < j \<Longrightarrow> 0 < k \<Longrightarrow> k * i < k * j"
haftmann@25919
   172
    by (rule zmult_zless_mono2)
haftmann@25919
   173
  show "\<bar>i\<bar> = (if i < 0 then -i else i)"
haftmann@25919
   174
    by (simp only: zabs_def)
wenzelm@61076
   175
  show "sgn (i::int) = (if i=0 then 0 else if 0<i then 1 else - 1)"
haftmann@25919
   176
    by (simp only: zsgn_def)
haftmann@25919
   177
qed
haftmann@25919
   178
huffman@48045
   179
end
huffman@48045
   180
wenzelm@61076
   181
lemma zless_imp_add1_zle: "w < z \<Longrightarrow> w + (1::int) \<le> z"
huffman@48045
   182
  by transfer clarsimp
haftmann@25919
   183
haftmann@25919
   184
lemma zless_iff_Suc_zadd:
wenzelm@61076
   185
  "(w :: int) < z \<longleftrightarrow> (\<exists>n. z = w + int (Suc n))"
huffman@48045
   186
apply transfer
huffman@48045
   187
apply auto
huffman@48045
   188
apply (rename_tac a b c d)
huffman@48045
   189
apply (rule_tac x="c+b - Suc(a+d)" in exI)
haftmann@25919
   190
apply arith
haftmann@25919
   191
done
haftmann@25919
   192
haftmann@25919
   193
lemmas int_distrib =
webertj@49962
   194
  distrib_right [of z1 z2 w]
webertj@49962
   195
  distrib_left [of w z1 z2]
wenzelm@45607
   196
  left_diff_distrib [of z1 z2 w]
wenzelm@45607
   197
  right_diff_distrib [of w z1 z2]
wenzelm@45607
   198
  for z1 z2 w :: int
haftmann@25919
   199
haftmann@25919
   200
wenzelm@60758
   201
subsection \<open>Embedding of the Integers into any @{text ring_1}: @{text of_int}\<close>
haftmann@25919
   202
haftmann@25919
   203
context ring_1
haftmann@25919
   204
begin
haftmann@25919
   205
huffman@48045
   206
lift_definition of_int :: "int \<Rightarrow> 'a" is "\<lambda>(i, j). of_nat i - of_nat j"
huffman@48045
   207
  by (clarsimp simp add: diff_eq_eq eq_diff_eq diff_add_eq
huffman@48045
   208
    of_nat_add [symmetric] simp del: of_nat_add)
haftmann@25919
   209
haftmann@25919
   210
lemma of_int_0 [simp]: "of_int 0 = 0"
huffman@48066
   211
  by transfer simp
haftmann@25919
   212
haftmann@25919
   213
lemma of_int_1 [simp]: "of_int 1 = 1"
huffman@48066
   214
  by transfer simp
haftmann@25919
   215
haftmann@25919
   216
lemma of_int_add [simp]: "of_int (w+z) = of_int w + of_int z"
huffman@48066
   217
  by transfer (clarsimp simp add: algebra_simps)
haftmann@25919
   218
haftmann@25919
   219
lemma of_int_minus [simp]: "of_int (-z) = - (of_int z)"
huffman@48066
   220
  by (transfer fixing: uminus) clarsimp
haftmann@25919
   221
haftmann@25919
   222
lemma of_int_diff [simp]: "of_int (w - z) = of_int w - of_int z"
haftmann@54230
   223
  using of_int_add [of w "- z"] by simp
haftmann@25919
   224
haftmann@25919
   225
lemma of_int_mult [simp]: "of_int (w*z) = of_int w * of_int z"
huffman@48066
   226
  by (transfer fixing: times) (clarsimp simp add: algebra_simps of_nat_mult)
haftmann@25919
   227
wenzelm@60758
   228
text\<open>Collapse nested embeddings\<close>
huffman@44709
   229
lemma of_int_of_nat_eq [simp]: "of_int (int n) = of_nat n"
nipkow@29667
   230
by (induct n) auto
haftmann@25919
   231
huffman@47108
   232
lemma of_int_numeral [simp, code_post]: "of_int (numeral k) = numeral k"
huffman@47108
   233
  by (simp add: of_nat_numeral [symmetric] of_int_of_nat_eq [symmetric])
huffman@47108
   234
haftmann@54489
   235
lemma of_int_neg_numeral [code_post]: "of_int (- numeral k) = - numeral k"
haftmann@54489
   236
  by simp
huffman@47108
   237
haftmann@31015
   238
lemma of_int_power:
haftmann@31015
   239
  "of_int (z ^ n) = of_int z ^ n"
haftmann@31015
   240
  by (induct n) simp_all
haftmann@31015
   241
haftmann@25919
   242
end
haftmann@25919
   243
huffman@47108
   244
context ring_char_0
haftmann@25919
   245
begin
haftmann@25919
   246
haftmann@25919
   247
lemma of_int_eq_iff [simp]:
haftmann@25919
   248
   "of_int w = of_int z \<longleftrightarrow> w = z"
huffman@48066
   249
  by transfer (clarsimp simp add: algebra_simps
huffman@48066
   250
    of_nat_add [symmetric] simp del: of_nat_add)
haftmann@25919
   251
wenzelm@60758
   252
text\<open>Special cases where either operand is zero\<close>
haftmann@36424
   253
lemma of_int_eq_0_iff [simp]:
haftmann@36424
   254
  "of_int z = 0 \<longleftrightarrow> z = 0"
haftmann@36424
   255
  using of_int_eq_iff [of z 0] by simp
haftmann@36424
   256
haftmann@36424
   257
lemma of_int_0_eq_iff [simp]:
haftmann@36424
   258
  "0 = of_int z \<longleftrightarrow> z = 0"
haftmann@36424
   259
  using of_int_eq_iff [of 0 z] by simp
haftmann@25919
   260
lp15@61234
   261
lemma of_int_eq_1_iff [iff]:
lp15@61234
   262
   "of_int z = 1 \<longleftrightarrow> z = 1"
lp15@61234
   263
  using of_int_eq_iff [of z 1] by simp
lp15@61234
   264
haftmann@25919
   265
end
haftmann@25919
   266
haftmann@36424
   267
context linordered_idom
haftmann@36424
   268
begin
haftmann@36424
   269
wenzelm@60758
   270
text\<open>Every @{text linordered_idom} has characteristic zero.\<close>
haftmann@36424
   271
subclass ring_char_0 ..
haftmann@36424
   272
haftmann@36424
   273
lemma of_int_le_iff [simp]:
haftmann@36424
   274
  "of_int w \<le> of_int z \<longleftrightarrow> w \<le> z"
huffman@48066
   275
  by (transfer fixing: less_eq) (clarsimp simp add: algebra_simps
huffman@48066
   276
    of_nat_add [symmetric] simp del: of_nat_add)
haftmann@36424
   277
haftmann@36424
   278
lemma of_int_less_iff [simp]:
haftmann@36424
   279
  "of_int w < of_int z \<longleftrightarrow> w < z"
haftmann@36424
   280
  by (simp add: less_le order_less_le)
haftmann@36424
   281
haftmann@36424
   282
lemma of_int_0_le_iff [simp]:
haftmann@36424
   283
  "0 \<le> of_int z \<longleftrightarrow> 0 \<le> z"
haftmann@36424
   284
  using of_int_le_iff [of 0 z] by simp
haftmann@36424
   285
haftmann@36424
   286
lemma of_int_le_0_iff [simp]:
haftmann@36424
   287
  "of_int z \<le> 0 \<longleftrightarrow> z \<le> 0"
haftmann@36424
   288
  using of_int_le_iff [of z 0] by simp
haftmann@36424
   289
haftmann@36424
   290
lemma of_int_0_less_iff [simp]:
haftmann@36424
   291
  "0 < of_int z \<longleftrightarrow> 0 < z"
haftmann@36424
   292
  using of_int_less_iff [of 0 z] by simp
haftmann@36424
   293
haftmann@36424
   294
lemma of_int_less_0_iff [simp]:
haftmann@36424
   295
  "of_int z < 0 \<longleftrightarrow> z < 0"
haftmann@36424
   296
  using of_int_less_iff [of z 0] by simp
haftmann@36424
   297
lp15@61234
   298
lemma of_int_1_le_iff [simp]:
lp15@61234
   299
  "1 \<le> of_int z \<longleftrightarrow> 1 \<le> z"
lp15@61234
   300
  using of_int_le_iff [of 1 z] by simp
lp15@61234
   301
lp15@61234
   302
lemma of_int_le_1_iff [simp]:
lp15@61234
   303
  "of_int z \<le> 1 \<longleftrightarrow> z \<le> 1"
lp15@61234
   304
  using of_int_le_iff [of z 1] by simp
lp15@61234
   305
lp15@61234
   306
lemma of_int_1_less_iff [simp]:
lp15@61234
   307
  "1 < of_int z \<longleftrightarrow> 1 < z"
lp15@61234
   308
  using of_int_less_iff [of 1 z] by simp
lp15@61234
   309
lp15@61234
   310
lemma of_int_less_1_iff [simp]:
lp15@61234
   311
  "of_int z < 1 \<longleftrightarrow> z < 1"
lp15@61234
   312
  using of_int_less_iff [of z 1] by simp
lp15@61234
   313
haftmann@36424
   314
end
haftmann@25919
   315
lp15@61234
   316
text \<open>Comparisons involving @{term of_int}.\<close>
lp15@61234
   317
lp15@61234
   318
lemma of_int_eq_numeral_iff [iff]:
lp15@61234
   319
   "of_int z = (numeral n :: 'a::ring_char_0) 
lp15@61234
   320
   \<longleftrightarrow> z = numeral n"
lp15@61234
   321
  using of_int_eq_iff by fastforce
lp15@61234
   322
lp15@61234
   323
lemma of_int_le_numeral_iff [simp]:           
lp15@61234
   324
   "of_int z \<le> (numeral n :: 'a::linordered_idom) 
lp15@61234
   325
   \<longleftrightarrow> z \<le> numeral n"
lp15@61234
   326
  using of_int_le_iff [of z "numeral n"] by simp
lp15@61234
   327
lp15@61234
   328
lemma of_int_numeral_le_iff [simp]:  
lp15@61234
   329
   "(numeral n :: 'a::linordered_idom) \<le> of_int z \<longleftrightarrow> numeral n \<le> z"
lp15@61234
   330
  using of_int_le_iff [of "numeral n"] by simp
lp15@61234
   331
lp15@61234
   332
lemma of_int_less_numeral_iff [simp]:           
lp15@61234
   333
   "of_int z < (numeral n :: 'a::linordered_idom) 
lp15@61234
   334
   \<longleftrightarrow> z < numeral n"
lp15@61234
   335
  using of_int_less_iff [of z "numeral n"] by simp
lp15@61234
   336
lp15@61234
   337
lemma of_int_numeral_less_iff [simp]:           
lp15@61234
   338
   "(numeral n :: 'a::linordered_idom) < of_int z \<longleftrightarrow> numeral n < z"
lp15@61234
   339
  using of_int_less_iff [of "numeral n" z] by simp
lp15@61234
   340
hoelzl@56889
   341
lemma of_nat_less_of_int_iff:
hoelzl@56889
   342
  "(of_nat n::'a::linordered_idom) < of_int x \<longleftrightarrow> int n < x"
hoelzl@56889
   343
  by (metis of_int_of_nat_eq of_int_less_iff)
hoelzl@56889
   344
haftmann@25919
   345
lemma of_int_eq_id [simp]: "of_int = id"
haftmann@25919
   346
proof
haftmann@25919
   347
  fix z show "of_int z = id z"
huffman@48045
   348
    by (cases z rule: int_diff_cases, simp)
haftmann@25919
   349
qed
haftmann@25919
   350
haftmann@25919
   351
hoelzl@51329
   352
instance int :: no_top
wenzelm@61169
   353
  apply standard
hoelzl@51329
   354
  apply (rule_tac x="x + 1" in exI)
hoelzl@51329
   355
  apply simp
hoelzl@51329
   356
  done
hoelzl@51329
   357
hoelzl@51329
   358
instance int :: no_bot
wenzelm@61169
   359
  apply standard
hoelzl@51329
   360
  apply (rule_tac x="x - 1" in exI)
hoelzl@51329
   361
  apply simp
hoelzl@51329
   362
  done
hoelzl@51329
   363
wenzelm@60758
   364
subsection \<open>Magnitude of an Integer, as a Natural Number: @{text nat}\<close>
haftmann@25919
   365
huffman@48045
   366
lift_definition nat :: "int \<Rightarrow> nat" is "\<lambda>(x, y). x - y"
huffman@48045
   367
  by auto
haftmann@25919
   368
huffman@44709
   369
lemma nat_int [simp]: "nat (int n) = n"
huffman@48045
   370
  by transfer simp
haftmann@25919
   371
huffman@44709
   372
lemma int_nat_eq [simp]: "int (nat z) = (if 0 \<le> z then z else 0)"
huffman@48045
   373
  by transfer clarsimp
haftmann@25919
   374
huffman@44709
   375
corollary nat_0_le: "0 \<le> z ==> int (nat z) = z"
haftmann@25919
   376
by simp
haftmann@25919
   377
haftmann@25919
   378
lemma nat_le_0 [simp]: "z \<le> 0 ==> nat z = 0"
huffman@48045
   379
  by transfer clarsimp
haftmann@25919
   380
haftmann@25919
   381
lemma nat_le_eq_zle: "0 < w | 0 \<le> z ==> (nat w \<le> nat z) = (w\<le>z)"
huffman@48045
   382
  by transfer (clarsimp, arith)
haftmann@25919
   383
wenzelm@60758
   384
text\<open>An alternative condition is @{term "0 \<le> w"}\<close>
haftmann@25919
   385
corollary nat_mono_iff: "0 < z ==> (nat w < nat z) = (w < z)"
lp15@60162
   386
by (simp add: nat_le_eq_zle linorder_not_le [symmetric])
haftmann@25919
   387
haftmann@25919
   388
corollary nat_less_eq_zless: "0 \<le> w ==> (nat w < nat z) = (w<z)"
lp15@60162
   389
by (simp add: nat_le_eq_zle linorder_not_le [symmetric])
haftmann@25919
   390
haftmann@25919
   391
lemma zless_nat_conj [simp]: "(nat w < nat z) = (0 < z & w < z)"
huffman@48045
   392
  by transfer (clarsimp, arith)
haftmann@25919
   393
haftmann@25919
   394
lemma nonneg_eq_int:
haftmann@25919
   395
  fixes z :: int
huffman@44709
   396
  assumes "0 \<le> z" and "\<And>m. z = int m \<Longrightarrow> P"
haftmann@25919
   397
  shows P
haftmann@25919
   398
  using assms by (blast dest: nat_0_le sym)
haftmann@25919
   399
haftmann@54223
   400
lemma nat_eq_iff:
haftmann@54223
   401
  "nat w = m \<longleftrightarrow> (if 0 \<le> w then w = int m else m = 0)"
huffman@48045
   402
  by transfer (clarsimp simp add: le_imp_diff_is_add)
lp15@60162
   403
haftmann@54223
   404
corollary nat_eq_iff2:
haftmann@54223
   405
  "m = nat w \<longleftrightarrow> (if 0 \<le> w then w = int m else m = 0)"
haftmann@54223
   406
  using nat_eq_iff [of w m] by auto
haftmann@54223
   407
haftmann@54223
   408
lemma nat_0 [simp]:
haftmann@54223
   409
  "nat 0 = 0"
haftmann@54223
   410
  by (simp add: nat_eq_iff)
haftmann@25919
   411
haftmann@54223
   412
lemma nat_1 [simp]:
haftmann@54223
   413
  "nat 1 = Suc 0"
haftmann@54223
   414
  by (simp add: nat_eq_iff)
haftmann@54223
   415
haftmann@54223
   416
lemma nat_numeral [simp]:
haftmann@54223
   417
  "nat (numeral k) = numeral k"
haftmann@54223
   418
  by (simp add: nat_eq_iff)
haftmann@25919
   419
haftmann@54223
   420
lemma nat_neg_numeral [simp]:
haftmann@54489
   421
  "nat (- numeral k) = 0"
haftmann@54223
   422
  by simp
haftmann@54223
   423
haftmann@54223
   424
lemma nat_2: "nat 2 = Suc (Suc 0)"
haftmann@54223
   425
  by simp
lp15@60162
   426
haftmann@25919
   427
lemma nat_less_iff: "0 \<le> w ==> (nat w < m) = (w < of_nat m)"
huffman@48045
   428
  by transfer (clarsimp, arith)
haftmann@25919
   429
huffman@44709
   430
lemma nat_le_iff: "nat x \<le> n \<longleftrightarrow> x \<le> int n"
huffman@48045
   431
  by transfer (clarsimp simp add: le_diff_conv)
huffman@44707
   432
huffman@44707
   433
lemma nat_mono: "x \<le> y \<Longrightarrow> nat x \<le> nat y"
huffman@48045
   434
  by transfer auto
huffman@44707
   435
nipkow@29700
   436
lemma nat_0_iff[simp]: "nat(i::int) = 0 \<longleftrightarrow> i\<le>0"
huffman@48045
   437
  by transfer clarsimp
nipkow@29700
   438
haftmann@25919
   439
lemma int_eq_iff: "(of_nat m = z) = (m = nat z & 0 \<le> z)"
haftmann@25919
   440
by (auto simp add: nat_eq_iff2)
haftmann@25919
   441
haftmann@25919
   442
lemma zero_less_nat_eq [simp]: "(0 < nat z) = (0 < z)"
haftmann@25919
   443
by (insert zless_nat_conj [of 0], auto)
haftmann@25919
   444
haftmann@25919
   445
lemma nat_add_distrib:
haftmann@54223
   446
  "0 \<le> z \<Longrightarrow> 0 \<le> z' \<Longrightarrow> nat (z + z') = nat z + nat z'"
huffman@48045
   447
  by transfer clarsimp
haftmann@25919
   448
haftmann@54223
   449
lemma nat_diff_distrib':
haftmann@54223
   450
  "0 \<le> x \<Longrightarrow> 0 \<le> y \<Longrightarrow> nat (x - y) = nat x - nat y"
haftmann@54223
   451
  by transfer clarsimp
lp15@60162
   452
haftmann@25919
   453
lemma nat_diff_distrib:
haftmann@54223
   454
  "0 \<le> z' \<Longrightarrow> z' \<le> z \<Longrightarrow> nat (z - z') = nat z - nat z'"
haftmann@54223
   455
  by (rule nat_diff_distrib') auto
haftmann@25919
   456
huffman@44709
   457
lemma nat_zminus_int [simp]: "nat (- int n) = 0"
huffman@48045
   458
  by transfer simp
haftmann@25919
   459
haftmann@53065
   460
lemma le_nat_iff:
haftmann@53065
   461
  "k \<ge> 0 \<Longrightarrow> n \<le> nat k \<longleftrightarrow> int n \<le> k"
haftmann@53065
   462
  by transfer auto
lp15@60162
   463
huffman@44709
   464
lemma zless_nat_eq_int_zless: "(m < nat z) = (int m < z)"
huffman@48045
   465
  by transfer (clarsimp simp add: less_diff_conv)
haftmann@25919
   466
haftmann@25919
   467
context ring_1
haftmann@25919
   468
begin
haftmann@25919
   469
haftmann@25919
   470
lemma of_nat_nat: "0 \<le> z \<Longrightarrow> of_nat (nat z) = of_int z"
huffman@48066
   471
  by transfer (clarsimp simp add: of_nat_diff)
haftmann@25919
   472
haftmann@25919
   473
end
haftmann@25919
   474
lp15@60162
   475
lemma diff_nat_numeral [simp]:
haftmann@54249
   476
  "(numeral v :: nat) - numeral v' = nat (numeral v - numeral v')"
haftmann@54249
   477
  by (simp only: nat_diff_distrib' zero_le_numeral nat_numeral)
haftmann@54249
   478
haftmann@54249
   479
wenzelm@60758
   480
text \<open>For termination proofs:\<close>
krauss@29779
   481
lemma measure_function_int[measure_function]: "is_measure (nat o abs)" ..
krauss@29779
   482
haftmann@25919
   483
wenzelm@60758
   484
subsection\<open>Lemmas about the Function @{term of_nat} and Orderings\<close>
haftmann@25919
   485
wenzelm@61076
   486
lemma negative_zless_0: "- (int (Suc n)) < (0 :: int)"
haftmann@25919
   487
by (simp add: order_less_le del: of_nat_Suc)
haftmann@25919
   488
huffman@44709
   489
lemma negative_zless [iff]: "- (int (Suc n)) < int m"
haftmann@25919
   490
by (rule negative_zless_0 [THEN order_less_le_trans], simp)
haftmann@25919
   491
huffman@44709
   492
lemma negative_zle_0: "- int n \<le> 0"
haftmann@25919
   493
by (simp add: minus_le_iff)
haftmann@25919
   494
huffman@44709
   495
lemma negative_zle [iff]: "- int n \<le> int m"
haftmann@25919
   496
by (rule order_trans [OF negative_zle_0 of_nat_0_le_iff])
haftmann@25919
   497
huffman@44709
   498
lemma not_zle_0_negative [simp]: "~ (0 \<le> - (int (Suc n)))"
haftmann@25919
   499
by (subst le_minus_iff, simp del: of_nat_Suc)
haftmann@25919
   500
huffman@44709
   501
lemma int_zle_neg: "(int n \<le> - int m) = (n = 0 & m = 0)"
huffman@48045
   502
  by transfer simp
haftmann@25919
   503
huffman@44709
   504
lemma not_int_zless_negative [simp]: "~ (int n < - int m)"
haftmann@25919
   505
by (simp add: linorder_not_less)
haftmann@25919
   506
huffman@44709
   507
lemma negative_eq_positive [simp]: "(- int n = of_nat m) = (n = 0 & m = 0)"
haftmann@25919
   508
by (force simp add: order_eq_iff [of "- of_nat n"] int_zle_neg)
haftmann@25919
   509
huffman@44709
   510
lemma zle_iff_zadd: "w \<le> z \<longleftrightarrow> (\<exists>n. z = w + int n)"
haftmann@25919
   511
proof -
haftmann@25919
   512
  have "(w \<le> z) = (0 \<le> z - w)"
haftmann@25919
   513
    by (simp only: le_diff_eq add_0_left)
haftmann@25919
   514
  also have "\<dots> = (\<exists>n. z - w = of_nat n)"
haftmann@25919
   515
    by (auto elim: zero_le_imp_eq_int)
haftmann@25919
   516
  also have "\<dots> = (\<exists>n. z = w + of_nat n)"
nipkow@29667
   517
    by (simp only: algebra_simps)
haftmann@25919
   518
  finally show ?thesis .
haftmann@25919
   519
qed
haftmann@25919
   520
huffman@44709
   521
lemma zadd_int_left: "int m + (int n + z) = int (m + n) + z"
haftmann@25919
   522
by simp
haftmann@25919
   523
huffman@44709
   524
lemma int_Suc0_eq_1: "int (Suc 0) = 1"
haftmann@25919
   525
by simp
haftmann@25919
   526
wenzelm@60758
   527
text\<open>This version is proved for all ordered rings, not just integers!
haftmann@25919
   528
      It is proved here because attribute @{text arith_split} is not available
haftmann@35050
   529
      in theory @{text Rings}.
wenzelm@60758
   530
      But is it really better than just rewriting with @{text abs_if}?\<close>
blanchet@54147
   531
lemma abs_split [arith_split, no_atp]:
haftmann@35028
   532
     "P(abs(a::'a::linordered_idom)) = ((0 \<le> a --> P a) & (a < 0 --> P(-a)))"
haftmann@25919
   533
by (force dest: order_less_le_trans simp add: abs_if linorder_not_less)
haftmann@25919
   534
huffman@44709
   535
lemma negD: "x < 0 \<Longrightarrow> \<exists>n. x = - (int (Suc n))"
huffman@48045
   536
apply transfer
huffman@48045
   537
apply clarsimp
huffman@48045
   538
apply (rule_tac x="b - Suc a" in exI, arith)
haftmann@25919
   539
done
haftmann@25919
   540
wenzelm@60758
   541
subsection \<open>Cases and induction\<close>
haftmann@25919
   542
wenzelm@60758
   543
text\<open>Now we replace the case analysis rule by a more conventional one:
wenzelm@60758
   544
whether an integer is negative or not.\<close>
haftmann@25919
   545
wenzelm@60758
   546
text\<open>This version is symmetric in the two subgoals.\<close>
lp15@59613
   547
theorem int_cases2 [case_names nonneg nonpos, cases type: int]:
lp15@59613
   548
  "\<lbrakk>!! n. z = int n \<Longrightarrow> P;  !! n. z = - (int n) \<Longrightarrow> P\<rbrakk> \<Longrightarrow> P"
lp15@59613
   549
apply (cases "z < 0")
lp15@59613
   550
apply (auto simp add: linorder_not_less dest!: negD nat_0_le [THEN sym])
lp15@59613
   551
done
lp15@59613
   552
wenzelm@60758
   553
text\<open>This is the default, with a negative case.\<close>
wenzelm@42676
   554
theorem int_cases [case_names nonneg neg, cases type: int]:
lp15@59613
   555
  "[|!! n. z = int n ==> P;  !! n. z = - (int (Suc n)) ==> P |] ==> P"
wenzelm@42676
   556
apply (cases "z < 0")
wenzelm@42676
   557
apply (blast dest!: negD)
haftmann@25919
   558
apply (simp add: linorder_not_less del: of_nat_Suc)
haftmann@25919
   559
apply auto
haftmann@25919
   560
apply (blast dest: nat_0_le [THEN sym])
haftmann@25919
   561
done
haftmann@25919
   562
haftmann@60868
   563
lemma int_cases3 [case_names zero pos neg]:
haftmann@60868
   564
  fixes k :: int
haftmann@60868
   565
  assumes "k = 0 \<Longrightarrow> P" and "\<And>n. k = int n \<Longrightarrow> n > 0 \<Longrightarrow> P"
paulson@61204
   566
    and "\<And>n. k = - int n \<Longrightarrow> n > 0 \<Longrightarrow> P"
haftmann@60868
   567
  shows "P"
haftmann@60868
   568
proof (cases k "0::int" rule: linorder_cases)
haftmann@60868
   569
  case equal with assms(1) show P by simp
haftmann@60868
   570
next
haftmann@60868
   571
  case greater
haftmann@60868
   572
  then have "nat k > 0" by simp
haftmann@60868
   573
  moreover from this have "k = int (nat k)" by auto
haftmann@60868
   574
  ultimately show P using assms(2) by blast
haftmann@60868
   575
next
haftmann@60868
   576
  case less
haftmann@60868
   577
  then have "nat (- k) > 0" by simp
haftmann@60868
   578
  moreover from this have "k = - int (nat (- k))" by auto
haftmann@60868
   579
  ultimately show P using assms(3) by blast
haftmann@60868
   580
qed
haftmann@60868
   581
wenzelm@42676
   582
theorem int_of_nat_induct [case_names nonneg neg, induct type: int]:
huffman@44709
   583
     "[|!! n. P (int n);  !!n. P (- (int (Suc n))) |] ==> P z"
wenzelm@42676
   584
  by (cases z) auto
haftmann@25919
   585
huffman@47207
   586
lemma nonneg_int_cases:
huffman@47207
   587
  assumes "0 \<le> k" obtains n where "k = int n"
haftmann@54489
   588
  using assms by (rule nonneg_eq_int)
huffman@47207
   589
huffman@47108
   590
lemma Let_numeral [simp]: "Let (numeral v) f = f (numeral v)"
wenzelm@60758
   591
  -- \<open>Unfold all @{text let}s involving constants\<close>
wenzelm@60758
   592
  by (fact Let_numeral) -- \<open>FIXME drop\<close>
haftmann@37767
   593
haftmann@54489
   594
lemma Let_neg_numeral [simp]: "Let (- numeral v) f = f (- numeral v)"
wenzelm@60758
   595
  -- \<open>Unfold all @{text let}s involving constants\<close>
wenzelm@60758
   596
  by (fact Let_neg_numeral) -- \<open>FIXME drop\<close>
haftmann@25919
   597
wenzelm@60758
   598
text \<open>Unfold @{text min} and @{text max} on numerals.\<close>
huffman@28958
   599
huffman@47108
   600
lemmas max_number_of [simp] =
huffman@47108
   601
  max_def [of "numeral u" "numeral v"]
haftmann@54489
   602
  max_def [of "numeral u" "- numeral v"]
haftmann@54489
   603
  max_def [of "- numeral u" "numeral v"]
haftmann@54489
   604
  max_def [of "- numeral u" "- numeral v"] for u v
huffman@28958
   605
huffman@47108
   606
lemmas min_number_of [simp] =
huffman@47108
   607
  min_def [of "numeral u" "numeral v"]
haftmann@54489
   608
  min_def [of "numeral u" "- numeral v"]
haftmann@54489
   609
  min_def [of "- numeral u" "numeral v"]
haftmann@54489
   610
  min_def [of "- numeral u" "- numeral v"] for u v
huffman@26075
   611
haftmann@25919
   612
wenzelm@60758
   613
subsubsection \<open>Binary comparisons\<close>
huffman@28958
   614
wenzelm@60758
   615
text \<open>Preliminaries\<close>
huffman@28958
   616
lp15@60162
   617
lemma le_imp_0_less:
huffman@28958
   618
  assumes le: "0 \<le> z"
huffman@28958
   619
  shows "(0::int) < 1 + z"
huffman@28958
   620
proof -
huffman@28958
   621
  have "0 \<le> z" by fact
huffman@47108
   622
  also have "... < z + 1" by (rule less_add_one)
haftmann@57514
   623
  also have "... = 1 + z" by (simp add: ac_simps)
huffman@28958
   624
  finally show "0 < 1 + z" .
huffman@28958
   625
qed
huffman@28958
   626
huffman@28958
   627
lemma odd_less_0_iff:
huffman@28958
   628
  "(1 + z + z < 0) = (z < (0::int))"
wenzelm@42676
   629
proof (cases z)
huffman@28958
   630
  case (nonneg n)
haftmann@57512
   631
  thus ?thesis by (simp add: linorder_not_less add.assoc add_increasing
lp15@60162
   632
                             le_imp_0_less [THEN order_less_imp_le])
huffman@28958
   633
next
huffman@28958
   634
  case (neg n)
huffman@30079
   635
  thus ?thesis by (simp del: of_nat_Suc of_nat_add of_nat_1
huffman@30079
   636
    add: algebra_simps of_nat_1 [where 'a=int, symmetric] of_nat_add [symmetric])
huffman@28958
   637
qed
huffman@28958
   638
wenzelm@60758
   639
subsubsection \<open>Comparisons, for Ordered Rings\<close>
haftmann@25919
   640
haftmann@25919
   641
lemmas double_eq_0_iff = double_zero
haftmann@25919
   642
haftmann@25919
   643
lemma odd_nonzero:
haftmann@33296
   644
  "1 + z + z \<noteq> (0::int)"
wenzelm@42676
   645
proof (cases z)
haftmann@25919
   646
  case (nonneg n)
lp15@60162
   647
  have le: "0 \<le> z+z" by (simp add: nonneg add_increasing)
haftmann@25919
   648
  thus ?thesis using  le_imp_0_less [OF le]
lp15@60162
   649
    by (auto simp add: add.assoc)
haftmann@25919
   650
next
haftmann@25919
   651
  case (neg n)
haftmann@25919
   652
  show ?thesis
haftmann@25919
   653
  proof
haftmann@25919
   654
    assume eq: "1 + z + z = 0"
huffman@44709
   655
    have "(0::int) < 1 + (int n + int n)"
lp15@60162
   656
      by (simp add: le_imp_0_less add_increasing)
lp15@60162
   657
    also have "... = - (1 + z + z)"
lp15@60162
   658
      by (simp add: neg add.assoc [symmetric])
lp15@60162
   659
    also have "... = 0" by (simp add: eq)
haftmann@25919
   660
    finally have "0<0" ..
haftmann@25919
   661
    thus False by blast
haftmann@25919
   662
  qed
haftmann@25919
   663
qed
haftmann@25919
   664
haftmann@30652
   665
wenzelm@60758
   666
subsection \<open>The Set of Integers\<close>
haftmann@25919
   667
haftmann@25919
   668
context ring_1
haftmann@25919
   669
begin
haftmann@25919
   670
wenzelm@61070
   671
definition Ints :: "'a set"  ("\<int>")
wenzelm@61070
   672
  where "\<int> = range of_int"
haftmann@25919
   673
huffman@35634
   674
lemma Ints_of_int [simp]: "of_int z \<in> \<int>"
huffman@35634
   675
  by (simp add: Ints_def)
huffman@35634
   676
huffman@35634
   677
lemma Ints_of_nat [simp]: "of_nat n \<in> \<int>"
huffman@45533
   678
  using Ints_of_int [of "of_nat n"] by simp
huffman@35634
   679
haftmann@25919
   680
lemma Ints_0 [simp]: "0 \<in> \<int>"
huffman@45533
   681
  using Ints_of_int [of "0"] by simp
haftmann@25919
   682
haftmann@25919
   683
lemma Ints_1 [simp]: "1 \<in> \<int>"
huffman@45533
   684
  using Ints_of_int [of "1"] by simp
haftmann@25919
   685
haftmann@25919
   686
lemma Ints_add [simp]: "a \<in> \<int> \<Longrightarrow> b \<in> \<int> \<Longrightarrow> a + b \<in> \<int>"
haftmann@25919
   687
apply (auto simp add: Ints_def)
haftmann@25919
   688
apply (rule range_eqI)
haftmann@25919
   689
apply (rule of_int_add [symmetric])
haftmann@25919
   690
done
haftmann@25919
   691
haftmann@25919
   692
lemma Ints_minus [simp]: "a \<in> \<int> \<Longrightarrow> -a \<in> \<int>"
haftmann@25919
   693
apply (auto simp add: Ints_def)
haftmann@25919
   694
apply (rule range_eqI)
haftmann@25919
   695
apply (rule of_int_minus [symmetric])
haftmann@25919
   696
done
haftmann@25919
   697
huffman@35634
   698
lemma Ints_diff [simp]: "a \<in> \<int> \<Longrightarrow> b \<in> \<int> \<Longrightarrow> a - b \<in> \<int>"
huffman@35634
   699
apply (auto simp add: Ints_def)
huffman@35634
   700
apply (rule range_eqI)
huffman@35634
   701
apply (rule of_int_diff [symmetric])
huffman@35634
   702
done
huffman@35634
   703
haftmann@25919
   704
lemma Ints_mult [simp]: "a \<in> \<int> \<Longrightarrow> b \<in> \<int> \<Longrightarrow> a * b \<in> \<int>"
haftmann@25919
   705
apply (auto simp add: Ints_def)
haftmann@25919
   706
apply (rule range_eqI)
haftmann@25919
   707
apply (rule of_int_mult [symmetric])
haftmann@25919
   708
done
haftmann@25919
   709
huffman@35634
   710
lemma Ints_power [simp]: "a \<in> \<int> \<Longrightarrow> a ^ n \<in> \<int>"
huffman@35634
   711
by (induct n) simp_all
huffman@35634
   712
haftmann@25919
   713
lemma Ints_cases [cases set: Ints]:
haftmann@25919
   714
  assumes "q \<in> \<int>"
haftmann@25919
   715
  obtains (of_int) z where "q = of_int z"
haftmann@25919
   716
  unfolding Ints_def
haftmann@25919
   717
proof -
wenzelm@60758
   718
  from \<open>q \<in> \<int>\<close> have "q \<in> range of_int" unfolding Ints_def .
haftmann@25919
   719
  then obtain z where "q = of_int z" ..
haftmann@25919
   720
  then show thesis ..
haftmann@25919
   721
qed
haftmann@25919
   722
haftmann@25919
   723
lemma Ints_induct [case_names of_int, induct set: Ints]:
haftmann@25919
   724
  "q \<in> \<int> \<Longrightarrow> (\<And>z. P (of_int z)) \<Longrightarrow> P q"
haftmann@25919
   725
  by (rule Ints_cases) auto
haftmann@25919
   726
haftmann@25919
   727
end
haftmann@25919
   728
wenzelm@60758
   729
text \<open>The premise involving @{term Ints} prevents @{term "a = 1/2"}.\<close>
haftmann@25919
   730
haftmann@25919
   731
lemma Ints_double_eq_0_iff:
wenzelm@61070
   732
  assumes in_Ints: "a \<in> \<int>"
haftmann@25919
   733
  shows "(a + a = 0) = (a = (0::'a::ring_char_0))"
haftmann@25919
   734
proof -
haftmann@25919
   735
  from in_Ints have "a \<in> range of_int" unfolding Ints_def [symmetric] .
haftmann@25919
   736
  then obtain z where a: "a = of_int z" ..
haftmann@25919
   737
  show ?thesis
haftmann@25919
   738
  proof
haftmann@25919
   739
    assume "a = 0"
haftmann@25919
   740
    thus "a + a = 0" by simp
haftmann@25919
   741
  next
haftmann@25919
   742
    assume eq: "a + a = 0"
haftmann@25919
   743
    hence "of_int (z + z) = (of_int 0 :: 'a)" by (simp add: a)
haftmann@25919
   744
    hence "z + z = 0" by (simp only: of_int_eq_iff)
haftmann@25919
   745
    hence "z = 0" by (simp only: double_eq_0_iff)
haftmann@25919
   746
    thus "a = 0" by (simp add: a)
haftmann@25919
   747
  qed
haftmann@25919
   748
qed
haftmann@25919
   749
haftmann@25919
   750
lemma Ints_odd_nonzero:
wenzelm@61070
   751
  assumes in_Ints: "a \<in> \<int>"
haftmann@25919
   752
  shows "1 + a + a \<noteq> (0::'a::ring_char_0)"
haftmann@25919
   753
proof -
haftmann@25919
   754
  from in_Ints have "a \<in> range of_int" unfolding Ints_def [symmetric] .
haftmann@25919
   755
  then obtain z where a: "a = of_int z" ..
haftmann@25919
   756
  show ?thesis
haftmann@25919
   757
  proof
haftmann@25919
   758
    assume eq: "1 + a + a = 0"
haftmann@25919
   759
    hence "of_int (1 + z + z) = (of_int 0 :: 'a)" by (simp add: a)
haftmann@25919
   760
    hence "1 + z + z = 0" by (simp only: of_int_eq_iff)
haftmann@25919
   761
    with odd_nonzero show False by blast
haftmann@25919
   762
  qed
lp15@60162
   763
qed
haftmann@25919
   764
wenzelm@61070
   765
lemma Nats_numeral [simp]: "numeral w \<in> \<nat>"
huffman@47108
   766
  using of_nat_in_Nats [of "numeral w"] by simp
huffman@35634
   767
lp15@60162
   768
lemma Ints_odd_less_0:
wenzelm@61070
   769
  assumes in_Ints: "a \<in> \<int>"
haftmann@35028
   770
  shows "(1 + a + a < 0) = (a < (0::'a::linordered_idom))"
haftmann@25919
   771
proof -
haftmann@25919
   772
  from in_Ints have "a \<in> range of_int" unfolding Ints_def [symmetric] .
haftmann@25919
   773
  then obtain z where a: "a = of_int z" ..
haftmann@25919
   774
  hence "((1::'a) + a + a < 0) = (of_int (1 + z + z) < (of_int 0 :: 'a))"
haftmann@25919
   775
    by (simp add: a)
huffman@45532
   776
  also have "... = (z < 0)" by (simp only: of_int_less_iff odd_less_0_iff)
haftmann@25919
   777
  also have "... = (a < 0)" by (simp add: a)
haftmann@25919
   778
  finally show ?thesis .
haftmann@25919
   779
qed
haftmann@25919
   780
haftmann@25919
   781
wenzelm@60758
   782
subsection \<open>@{term setsum} and @{term setprod}\<close>
haftmann@25919
   783
haftmann@25919
   784
lemma of_nat_setsum: "of_nat (setsum f A) = (\<Sum>x\<in>A. of_nat(f x))"
haftmann@25919
   785
  apply (cases "finite A")
haftmann@25919
   786
  apply (erule finite_induct, auto)
haftmann@25919
   787
  done
haftmann@25919
   788
haftmann@25919
   789
lemma of_int_setsum: "of_int (setsum f A) = (\<Sum>x\<in>A. of_int(f x))"
haftmann@25919
   790
  apply (cases "finite A")
haftmann@25919
   791
  apply (erule finite_induct, auto)
haftmann@25919
   792
  done
haftmann@25919
   793
haftmann@25919
   794
lemma of_nat_setprod: "of_nat (setprod f A) = (\<Prod>x\<in>A. of_nat(f x))"
haftmann@25919
   795
  apply (cases "finite A")
haftmann@25919
   796
  apply (erule finite_induct, auto simp add: of_nat_mult)
haftmann@25919
   797
  done
haftmann@25919
   798
haftmann@25919
   799
lemma of_int_setprod: "of_int (setprod f A) = (\<Prod>x\<in>A. of_int(f x))"
haftmann@25919
   800
  apply (cases "finite A")
haftmann@25919
   801
  apply (erule finite_induct, auto)
haftmann@25919
   802
  done
haftmann@25919
   803
haftmann@25919
   804
lemmas int_setsum = of_nat_setsum [where 'a=int]
haftmann@25919
   805
lemmas int_setprod = of_nat_setprod [where 'a=int]
haftmann@25919
   806
haftmann@25919
   807
wenzelm@60758
   808
text \<open>Legacy theorems\<close>
haftmann@25919
   809
haftmann@25919
   810
lemmas zle_int = of_nat_le_iff [where 'a=int]
haftmann@25919
   811
lemmas int_int_eq = of_nat_eq_iff [where 'a=int]
huffman@47108
   812
lemmas numeral_1_eq_1 = numeral_One
haftmann@25919
   813
wenzelm@60758
   814
subsection \<open>Setting up simplification procedures\<close>
huffman@30802
   815
haftmann@54249
   816
lemmas of_int_simps =
haftmann@54249
   817
  of_int_0 of_int_1 of_int_add of_int_mult
haftmann@54249
   818
wenzelm@48891
   819
ML_file "Tools/int_arith.ML"
wenzelm@60758
   820
declaration \<open>K Int_Arith.setup\<close>
haftmann@25919
   821
huffman@47108
   822
simproc_setup fast_arith ("(m::'a::linordered_idom) < n" |
wenzelm@61144
   823
  "(m::'a::linordered_idom) \<le> n" |
huffman@47108
   824
  "(m::'a::linordered_idom) = n") =
wenzelm@61144
   825
  \<open>K Lin_Arith.simproc\<close>
wenzelm@43595
   826
haftmann@25919
   827
wenzelm@60758
   828
subsection\<open>More Inequality Reasoning\<close>
haftmann@25919
   829
haftmann@25919
   830
lemma zless_add1_eq: "(w < z + (1::int)) = (w<z | w=z)"
haftmann@25919
   831
by arith
haftmann@25919
   832
haftmann@25919
   833
lemma add1_zle_eq: "(w + (1::int) \<le> z) = (w<z)"
haftmann@25919
   834
by arith
haftmann@25919
   835
haftmann@25919
   836
lemma zle_diff1_eq [simp]: "(w \<le> z - (1::int)) = (w<z)"
haftmann@25919
   837
by arith
haftmann@25919
   838
haftmann@25919
   839
lemma zle_add1_eq_le [simp]: "(w < z + (1::int)) = (w\<le>z)"
haftmann@25919
   840
by arith
haftmann@25919
   841
haftmann@25919
   842
lemma int_one_le_iff_zero_less: "((1::int) \<le> z) = (0 < z)"
haftmann@25919
   843
by arith
haftmann@25919
   844
haftmann@25919
   845
wenzelm@60758
   846
subsection\<open>The functions @{term nat} and @{term int}\<close>
haftmann@25919
   847
wenzelm@60758
   848
text\<open>Simplify the term @{term "w + - z"}\<close>
haftmann@25919
   849
haftmann@25919
   850
lemma one_less_nat_eq [simp]: "(Suc 0 < nat z) = (1 < z)"
lp15@60162
   851
  using zless_nat_conj [of 1 z] by auto
haftmann@25919
   852
wenzelm@60758
   853
text\<open>This simplifies expressions of the form @{term "int n = z"} where
wenzelm@60758
   854
      z is an integer literal.\<close>
huffman@47108
   855
lemmas int_eq_iff_numeral [simp] = int_eq_iff [of _ "numeral v"] for v
haftmann@25919
   856
haftmann@25919
   857
lemma split_nat [arith_split]:
huffman@44709
   858
  "P(nat(i::int)) = ((\<forall>n. i = int n \<longrightarrow> P n) & (i < 0 \<longrightarrow> P 0))"
haftmann@25919
   859
  (is "?P = (?L & ?R)")
haftmann@25919
   860
proof (cases "i < 0")
haftmann@25919
   861
  case True thus ?thesis by auto
haftmann@25919
   862
next
haftmann@25919
   863
  case False
haftmann@25919
   864
  have "?P = ?L"
haftmann@25919
   865
  proof
haftmann@25919
   866
    assume ?P thus ?L using False by clarsimp
haftmann@25919
   867
  next
haftmann@25919
   868
    assume ?L thus ?P using False by simp
haftmann@25919
   869
  qed
haftmann@25919
   870
  with False show ?thesis by simp
haftmann@25919
   871
qed
haftmann@25919
   872
hoelzl@59000
   873
lemma nat_abs_int_diff: "nat \<bar>int a - int b\<bar> = (if a \<le> b then b - a else a - b)"
hoelzl@59000
   874
  by auto
hoelzl@59000
   875
hoelzl@59000
   876
lemma nat_int_add: "nat (int a + int b) = a + b"
hoelzl@59000
   877
  by auto
hoelzl@59000
   878
haftmann@25919
   879
context ring_1
haftmann@25919
   880
begin
haftmann@25919
   881
blanchet@33056
   882
lemma of_int_of_nat [nitpick_simp]:
haftmann@25919
   883
  "of_int k = (if k < 0 then - of_nat (nat (- k)) else of_nat (nat k))"
haftmann@25919
   884
proof (cases "k < 0")
haftmann@25919
   885
  case True then have "0 \<le> - k" by simp
haftmann@25919
   886
  then have "of_nat (nat (- k)) = of_int (- k)" by (rule of_nat_nat)
haftmann@25919
   887
  with True show ?thesis by simp
haftmann@25919
   888
next
haftmann@25919
   889
  case False then show ?thesis by (simp add: not_less of_nat_nat)
haftmann@25919
   890
qed
haftmann@25919
   891
haftmann@25919
   892
end
haftmann@25919
   893
haftmann@25919
   894
lemma nat_mult_distrib:
haftmann@25919
   895
  fixes z z' :: int
haftmann@25919
   896
  assumes "0 \<le> z"
haftmann@25919
   897
  shows "nat (z * z') = nat z * nat z'"
haftmann@25919
   898
proof (cases "0 \<le> z'")
haftmann@25919
   899
  case False with assms have "z * z' \<le> 0"
haftmann@25919
   900
    by (simp add: not_le mult_le_0_iff)
haftmann@25919
   901
  then have "nat (z * z') = 0" by simp
haftmann@25919
   902
  moreover from False have "nat z' = 0" by simp
haftmann@25919
   903
  ultimately show ?thesis by simp
haftmann@25919
   904
next
haftmann@25919
   905
  case True with assms have ge_0: "z * z' \<ge> 0" by (simp add: zero_le_mult_iff)
haftmann@25919
   906
  show ?thesis
haftmann@25919
   907
    by (rule injD [of "of_nat :: nat \<Rightarrow> int", OF inj_of_nat])
haftmann@25919
   908
      (simp only: of_nat_mult of_nat_nat [OF True]
haftmann@25919
   909
         of_nat_nat [OF assms] of_nat_nat [OF ge_0], simp)
haftmann@25919
   910
qed
haftmann@25919
   911
haftmann@25919
   912
lemma nat_mult_distrib_neg: "z \<le> (0::int) ==> nat(z*z') = nat(-z) * nat(-z')"
haftmann@25919
   913
apply (rule trans)
haftmann@25919
   914
apply (rule_tac [2] nat_mult_distrib, auto)
haftmann@25919
   915
done
haftmann@25919
   916
haftmann@25919
   917
lemma nat_abs_mult_distrib: "nat (abs (w * z)) = nat (abs w) * nat (abs z)"
haftmann@25919
   918
apply (cases "z=0 | w=0")
lp15@60162
   919
apply (auto simp add: abs_if nat_mult_distrib [symmetric]
haftmann@25919
   920
                      nat_mult_distrib_neg [symmetric] mult_less_0_iff)
haftmann@25919
   921
done
haftmann@25919
   922
haftmann@60570
   923
lemma int_in_range_abs [simp]:
haftmann@60570
   924
  "int n \<in> range abs"
haftmann@60570
   925
proof (rule range_eqI)
haftmann@60570
   926
  show "int n = \<bar>int n\<bar>"
haftmann@60570
   927
    by simp
haftmann@60570
   928
qed
haftmann@60570
   929
haftmann@60570
   930
lemma range_abs_Nats [simp]:
haftmann@60570
   931
  "range abs = (\<nat> :: int set)"
haftmann@60570
   932
proof -
haftmann@60570
   933
  have "\<bar>k\<bar> \<in> \<nat>" for k :: int
haftmann@60570
   934
    by (cases k) simp_all
haftmann@60570
   935
  moreover have "k \<in> range abs" if "k \<in> \<nat>" for k :: int
haftmann@60570
   936
    using that by induct simp
haftmann@60570
   937
  ultimately show ?thesis by blast
paulson@61204
   938
qed
haftmann@60570
   939
huffman@47207
   940
lemma Suc_nat_eq_nat_zadd1: "(0::int) <= z ==> Suc (nat z) = nat (1 + z)"
huffman@47207
   941
apply (rule sym)
huffman@47207
   942
apply (simp add: nat_eq_iff)
huffman@47207
   943
done
huffman@47207
   944
huffman@47207
   945
lemma diff_nat_eq_if:
lp15@60162
   946
     "nat z - nat z' =
lp15@60162
   947
        (if z' < 0 then nat z
lp15@60162
   948
         else let d = z-z' in
huffman@47207
   949
              if d < 0 then 0 else nat d)"
huffman@47207
   950
by (simp add: Let_def nat_diff_distrib [symmetric])
huffman@47207
   951
huffman@47207
   952
lemma nat_numeral_diff_1 [simp]:
huffman@47207
   953
  "numeral v - (1::nat) = nat (numeral v - 1)"
huffman@47207
   954
  using diff_nat_numeral [of v Num.One] by simp
huffman@47207
   955
haftmann@25919
   956
haftmann@25919
   957
subsection "Induction principles for int"
haftmann@25919
   958
wenzelm@60758
   959
text\<open>Well-founded segments of the integers\<close>
haftmann@25919
   960
haftmann@25919
   961
definition
haftmann@25919
   962
  int_ge_less_than  ::  "int => (int * int) set"
haftmann@25919
   963
where
haftmann@25919
   964
  "int_ge_less_than d = {(z',z). d \<le> z' & z' < z}"
haftmann@25919
   965
haftmann@25919
   966
theorem wf_int_ge_less_than: "wf (int_ge_less_than d)"
haftmann@25919
   967
proof -
haftmann@25919
   968
  have "int_ge_less_than d \<subseteq> measure (%z. nat (z-d))"
haftmann@25919
   969
    by (auto simp add: int_ge_less_than_def)
lp15@60162
   970
  thus ?thesis
lp15@60162
   971
    by (rule wf_subset [OF wf_measure])
haftmann@25919
   972
qed
haftmann@25919
   973
wenzelm@60758
   974
text\<open>This variant looks odd, but is typical of the relations suggested
wenzelm@60758
   975
by RankFinder.\<close>
haftmann@25919
   976
haftmann@25919
   977
definition
haftmann@25919
   978
  int_ge_less_than2 ::  "int => (int * int) set"
haftmann@25919
   979
where
haftmann@25919
   980
  "int_ge_less_than2 d = {(z',z). d \<le> z & z' < z}"
haftmann@25919
   981
haftmann@25919
   982
theorem wf_int_ge_less_than2: "wf (int_ge_less_than2 d)"
haftmann@25919
   983
proof -
lp15@60162
   984
  have "int_ge_less_than2 d \<subseteq> measure (%z. nat (1+z-d))"
haftmann@25919
   985
    by (auto simp add: int_ge_less_than2_def)
lp15@60162
   986
  thus ?thesis
lp15@60162
   987
    by (rule wf_subset [OF wf_measure])
haftmann@25919
   988
qed
haftmann@25919
   989
haftmann@25919
   990
(* `set:int': dummy construction *)
haftmann@25919
   991
theorem int_ge_induct [case_names base step, induct set: int]:
haftmann@25919
   992
  fixes i :: int
haftmann@25919
   993
  assumes ge: "k \<le> i" and
haftmann@25919
   994
    base: "P k" and
haftmann@25919
   995
    step: "\<And>i. k \<le> i \<Longrightarrow> P i \<Longrightarrow> P (i + 1)"
haftmann@25919
   996
  shows "P i"
haftmann@25919
   997
proof -
wenzelm@42676
   998
  { fix n
wenzelm@42676
   999
    have "\<And>i::int. n = nat (i - k) \<Longrightarrow> k \<le> i \<Longrightarrow> P i"
haftmann@25919
  1000
    proof (induct n)
haftmann@25919
  1001
      case 0
haftmann@25919
  1002
      hence "i = k" by arith
haftmann@25919
  1003
      thus "P i" using base by simp
haftmann@25919
  1004
    next
haftmann@25919
  1005
      case (Suc n)
haftmann@25919
  1006
      then have "n = nat((i - 1) - k)" by arith
haftmann@25919
  1007
      moreover
haftmann@25919
  1008
      have ki1: "k \<le> i - 1" using Suc.prems by arith
haftmann@25919
  1009
      ultimately
wenzelm@42676
  1010
      have "P (i - 1)" by (rule Suc.hyps)
wenzelm@42676
  1011
      from step [OF ki1 this] show ?case by simp
haftmann@25919
  1012
    qed
haftmann@25919
  1013
  }
haftmann@25919
  1014
  with ge show ?thesis by fast
haftmann@25919
  1015
qed
haftmann@25919
  1016
haftmann@25928
  1017
(* `set:int': dummy construction *)
haftmann@25928
  1018
theorem int_gr_induct [case_names base step, induct set: int]:
haftmann@25919
  1019
  assumes gr: "k < (i::int)" and
haftmann@25919
  1020
        base: "P(k+1)" and
haftmann@25919
  1021
        step: "\<And>i. \<lbrakk>k < i; P i\<rbrakk> \<Longrightarrow> P(i+1)"
haftmann@25919
  1022
  shows "P i"
haftmann@25919
  1023
apply(rule int_ge_induct[of "k + 1"])
haftmann@25919
  1024
  using gr apply arith
haftmann@25919
  1025
 apply(rule base)
haftmann@25919
  1026
apply (rule step, simp+)
haftmann@25919
  1027
done
haftmann@25919
  1028
wenzelm@42676
  1029
theorem int_le_induct [consumes 1, case_names base step]:
haftmann@25919
  1030
  assumes le: "i \<le> (k::int)" and
haftmann@25919
  1031
        base: "P(k)" and
haftmann@25919
  1032
        step: "\<And>i. \<lbrakk>i \<le> k; P i\<rbrakk> \<Longrightarrow> P(i - 1)"
haftmann@25919
  1033
  shows "P i"
haftmann@25919
  1034
proof -
wenzelm@42676
  1035
  { fix n
wenzelm@42676
  1036
    have "\<And>i::int. n = nat(k-i) \<Longrightarrow> i \<le> k \<Longrightarrow> P i"
haftmann@25919
  1037
    proof (induct n)
haftmann@25919
  1038
      case 0
haftmann@25919
  1039
      hence "i = k" by arith
haftmann@25919
  1040
      thus "P i" using base by simp
haftmann@25919
  1041
    next
haftmann@25919
  1042
      case (Suc n)
wenzelm@42676
  1043
      hence "n = nat (k - (i + 1))" by arith
haftmann@25919
  1044
      moreover
haftmann@25919
  1045
      have ki1: "i + 1 \<le> k" using Suc.prems by arith
haftmann@25919
  1046
      ultimately
wenzelm@42676
  1047
      have "P (i + 1)" by(rule Suc.hyps)
haftmann@25919
  1048
      from step[OF ki1 this] show ?case by simp
haftmann@25919
  1049
    qed
haftmann@25919
  1050
  }
haftmann@25919
  1051
  with le show ?thesis by fast
haftmann@25919
  1052
qed
haftmann@25919
  1053
wenzelm@42676
  1054
theorem int_less_induct [consumes 1, case_names base step]:
haftmann@25919
  1055
  assumes less: "(i::int) < k" and
haftmann@25919
  1056
        base: "P(k - 1)" and
haftmann@25919
  1057
        step: "\<And>i. \<lbrakk>i < k; P i\<rbrakk> \<Longrightarrow> P(i - 1)"
haftmann@25919
  1058
  shows "P i"
haftmann@25919
  1059
apply(rule int_le_induct[of _ "k - 1"])
haftmann@25919
  1060
  using less apply arith
haftmann@25919
  1061
 apply(rule base)
haftmann@25919
  1062
apply (rule step, simp+)
haftmann@25919
  1063
done
haftmann@25919
  1064
haftmann@36811
  1065
theorem int_induct [case_names base step1 step2]:
haftmann@36801
  1066
  fixes k :: int
haftmann@36801
  1067
  assumes base: "P k"
haftmann@36801
  1068
    and step1: "\<And>i. k \<le> i \<Longrightarrow> P i \<Longrightarrow> P (i + 1)"
haftmann@36801
  1069
    and step2: "\<And>i. k \<ge> i \<Longrightarrow> P i \<Longrightarrow> P (i - 1)"
haftmann@36801
  1070
  shows "P i"
haftmann@36801
  1071
proof -
haftmann@36801
  1072
  have "i \<le> k \<or> i \<ge> k" by arith
wenzelm@42676
  1073
  then show ?thesis
wenzelm@42676
  1074
  proof
wenzelm@42676
  1075
    assume "i \<ge> k"
wenzelm@42676
  1076
    then show ?thesis using base
haftmann@36801
  1077
      by (rule int_ge_induct) (fact step1)
haftmann@36801
  1078
  next
wenzelm@42676
  1079
    assume "i \<le> k"
wenzelm@42676
  1080
    then show ?thesis using base
haftmann@36801
  1081
      by (rule int_le_induct) (fact step2)
haftmann@36801
  1082
  qed
haftmann@36801
  1083
qed
haftmann@36801
  1084
wenzelm@60758
  1085
subsection\<open>Intermediate value theorems\<close>
haftmann@25919
  1086
haftmann@25919
  1087
lemma int_val_lemma:
lp15@60162
  1088
     "(\<forall>i<n::nat. abs(f(i+1) - f i) \<le> 1) -->
haftmann@25919
  1089
      f 0 \<le> k --> k \<le> f n --> (\<exists>i \<le> n. f i = (k::int))"
huffman@30079
  1090
unfolding One_nat_def
wenzelm@42676
  1091
apply (induct n)
wenzelm@42676
  1092
apply simp
haftmann@25919
  1093
apply (intro strip)
haftmann@25919
  1094
apply (erule impE, simp)
haftmann@25919
  1095
apply (erule_tac x = n in allE, simp)
huffman@30079
  1096
apply (case_tac "k = f (Suc n)")
haftmann@27106
  1097
apply force
haftmann@25919
  1098
apply (erule impE)
haftmann@25919
  1099
 apply (simp add: abs_if split add: split_if_asm)
haftmann@25919
  1100
apply (blast intro: le_SucI)
haftmann@25919
  1101
done
haftmann@25919
  1102
haftmann@25919
  1103
lemmas nat0_intermed_int_val = int_val_lemma [rule_format (no_asm)]
haftmann@25919
  1104
haftmann@25919
  1105
lemma nat_intermed_int_val:
lp15@60162
  1106
     "[| \<forall>i. m \<le> i & i < n --> abs(f(i + 1::nat) - f i) \<le> 1; m < n;
haftmann@25919
  1107
         f m \<le> k; k \<le> f n |] ==> ? i. m \<le> i & i \<le> n & f i = (k::int)"
lp15@60162
  1108
apply (cut_tac n = "n-m" and f = "%i. f (i+m) " and k = k
haftmann@25919
  1109
       in int_val_lemma)
huffman@30079
  1110
unfolding One_nat_def
haftmann@25919
  1111
apply simp
haftmann@25919
  1112
apply (erule exE)
haftmann@25919
  1113
apply (rule_tac x = "i+m" in exI, arith)
haftmann@25919
  1114
done
haftmann@25919
  1115
haftmann@25919
  1116
wenzelm@60758
  1117
subsection\<open>Products and 1, by T. M. Rasmussen\<close>
haftmann@25919
  1118
haftmann@25919
  1119
lemma zabs_less_one_iff [simp]: "(\<bar>z\<bar> < 1) = (z = (0::int))"
haftmann@25919
  1120
by arith
haftmann@25919
  1121
paulson@34055
  1122
lemma abs_zmult_eq_1:
paulson@34055
  1123
  assumes mn: "\<bar>m * n\<bar> = 1"
paulson@34055
  1124
  shows "\<bar>m\<bar> = (1::int)"
paulson@34055
  1125
proof -
paulson@34055
  1126
  have 0: "m \<noteq> 0 & n \<noteq> 0" using mn
paulson@34055
  1127
    by auto
paulson@34055
  1128
  have "~ (2 \<le> \<bar>m\<bar>)"
paulson@34055
  1129
  proof
paulson@34055
  1130
    assume "2 \<le> \<bar>m\<bar>"
paulson@34055
  1131
    hence "2*\<bar>n\<bar> \<le> \<bar>m\<bar>*\<bar>n\<bar>"
lp15@60162
  1132
      by (simp add: mult_mono 0)
lp15@60162
  1133
    also have "... = \<bar>m*n\<bar>"
paulson@34055
  1134
      by (simp add: abs_mult)
paulson@34055
  1135
    also have "... = 1"
paulson@34055
  1136
      by (simp add: mn)
paulson@34055
  1137
    finally have "2*\<bar>n\<bar> \<le> 1" .
paulson@34055
  1138
    thus "False" using 0
huffman@47108
  1139
      by arith
paulson@34055
  1140
  qed
paulson@34055
  1141
  thus ?thesis using 0
paulson@34055
  1142
    by auto
paulson@34055
  1143
qed
haftmann@25919
  1144
haftmann@25919
  1145
lemma pos_zmult_eq_1_iff_lemma: "(m * n = 1) ==> m = (1::int) | m = -1"
haftmann@25919
  1146
by (insert abs_zmult_eq_1 [of m n], arith)
haftmann@25919
  1147
boehmes@35815
  1148
lemma pos_zmult_eq_1_iff:
boehmes@35815
  1149
  assumes "0 < (m::int)" shows "(m * n = 1) = (m = 1 & n = 1)"
boehmes@35815
  1150
proof -
boehmes@35815
  1151
  from assms have "m * n = 1 ==> m = 1" by (auto dest: pos_zmult_eq_1_iff_lemma)
boehmes@35815
  1152
  thus ?thesis by (auto dest: pos_zmult_eq_1_iff_lemma)
boehmes@35815
  1153
qed
haftmann@25919
  1154
haftmann@25919
  1155
lemma zmult_eq_1_iff: "(m*n = (1::int)) = ((m = 1 & n = 1) | (m = -1 & n = -1))"
lp15@60162
  1156
apply (rule iffI)
haftmann@25919
  1157
 apply (frule pos_zmult_eq_1_iff_lemma)
lp15@60162
  1158
 apply (simp add: mult.commute [of m])
lp15@60162
  1159
 apply (frule pos_zmult_eq_1_iff_lemma, auto)
haftmann@25919
  1160
done
haftmann@25919
  1161
haftmann@33296
  1162
lemma infinite_UNIV_int: "\<not> finite (UNIV::int set)"
haftmann@25919
  1163
proof
haftmann@33296
  1164
  assume "finite (UNIV::int set)"
wenzelm@61076
  1165
  moreover have "inj (\<lambda>i::int. 2 * i)"
haftmann@33296
  1166
    by (rule injI) simp
wenzelm@61076
  1167
  ultimately have "surj (\<lambda>i::int. 2 * i)"
haftmann@33296
  1168
    by (rule finite_UNIV_inj_surj)
haftmann@33296
  1169
  then obtain i :: int where "1 = 2 * i" by (rule surjE)
haftmann@33296
  1170
  then show False by (simp add: pos_zmult_eq_1_iff)
haftmann@25919
  1171
qed
haftmann@25919
  1172
haftmann@25919
  1173
wenzelm@60758
  1174
subsection \<open>Further theorems on numerals\<close>
haftmann@30652
  1175
wenzelm@60758
  1176
subsubsection\<open>Special Simplification for Constants\<close>
haftmann@30652
  1177
wenzelm@60758
  1178
text\<open>These distributive laws move literals inside sums and differences.\<close>
haftmann@30652
  1179
webertj@49962
  1180
lemmas distrib_right_numeral [simp] = distrib_right [of _ _ "numeral v"] for v
webertj@49962
  1181
lemmas distrib_left_numeral [simp] = distrib_left [of "numeral v"] for v
huffman@47108
  1182
lemmas left_diff_distrib_numeral [simp] = left_diff_distrib [of _ _ "numeral v"] for v
huffman@47108
  1183
lemmas right_diff_distrib_numeral [simp] = right_diff_distrib [of "numeral v"] for v
haftmann@30652
  1184
wenzelm@60758
  1185
text\<open>These are actually for fields, like real: but where else to put them?\<close>
haftmann@30652
  1186
huffman@47108
  1187
lemmas zero_less_divide_iff_numeral [simp, no_atp] = zero_less_divide_iff [of "numeral w"] for w
huffman@47108
  1188
lemmas divide_less_0_iff_numeral [simp, no_atp] = divide_less_0_iff [of "numeral w"] for w
huffman@47108
  1189
lemmas zero_le_divide_iff_numeral [simp, no_atp] = zero_le_divide_iff [of "numeral w"] for w
huffman@47108
  1190
lemmas divide_le_0_iff_numeral [simp, no_atp] = divide_le_0_iff [of "numeral w"] for w
haftmann@30652
  1191
haftmann@30652
  1192
wenzelm@60758
  1193
text \<open>Replaces @{text "inverse #nn"} by @{text "1/#nn"}.  It looks
wenzelm@60758
  1194
  strange, but then other simprocs simplify the quotient.\<close>
haftmann@30652
  1195
huffman@47108
  1196
lemmas inverse_eq_divide_numeral [simp] =
huffman@47108
  1197
  inverse_eq_divide [of "numeral w"] for w
huffman@47108
  1198
huffman@47108
  1199
lemmas inverse_eq_divide_neg_numeral [simp] =
haftmann@54489
  1200
  inverse_eq_divide [of "- numeral w"] for w
haftmann@30652
  1201
wenzelm@60758
  1202
text \<open>These laws simplify inequalities, moving unary minus from a term
wenzelm@60758
  1203
into the literal.\<close>
haftmann@30652
  1204
haftmann@54489
  1205
lemmas equation_minus_iff_numeral [no_atp] =
haftmann@54489
  1206
  equation_minus_iff [of "numeral v"] for v
huffman@47108
  1207
haftmann@54489
  1208
lemmas minus_equation_iff_numeral [no_atp] =
haftmann@54489
  1209
  minus_equation_iff [of _ "numeral v"] for v
huffman@47108
  1210
haftmann@54489
  1211
lemmas le_minus_iff_numeral [no_atp] =
haftmann@54489
  1212
  le_minus_iff [of "numeral v"] for v
haftmann@30652
  1213
haftmann@54489
  1214
lemmas minus_le_iff_numeral [no_atp] =
haftmann@54489
  1215
  minus_le_iff [of _ "numeral v"] for v
haftmann@30652
  1216
haftmann@54489
  1217
lemmas less_minus_iff_numeral [no_atp] =
haftmann@54489
  1218
  less_minus_iff [of "numeral v"] for v
haftmann@30652
  1219
haftmann@54489
  1220
lemmas minus_less_iff_numeral [no_atp] =
haftmann@54489
  1221
  minus_less_iff [of _ "numeral v"] for v
haftmann@30652
  1222
wenzelm@60758
  1223
-- \<open>FIXME maybe simproc\<close>
haftmann@30652
  1224
haftmann@30652
  1225
wenzelm@60758
  1226
text \<open>Cancellation of constant factors in comparisons (@{text "<"} and @{text "\<le>"})\<close>
haftmann@30652
  1227
huffman@47108
  1228
lemmas mult_less_cancel_left_numeral [simp, no_atp] = mult_less_cancel_left [of "numeral v"] for v
huffman@47108
  1229
lemmas mult_less_cancel_right_numeral [simp, no_atp] = mult_less_cancel_right [of _ "numeral v"] for v
huffman@47108
  1230
lemmas mult_le_cancel_left_numeral [simp, no_atp] = mult_le_cancel_left [of "numeral v"] for v
huffman@47108
  1231
lemmas mult_le_cancel_right_numeral [simp, no_atp] = mult_le_cancel_right [of _ "numeral v"] for v
haftmann@30652
  1232
haftmann@30652
  1233
wenzelm@60758
  1234
text \<open>Multiplying out constant divisors in comparisons (@{text "<"}, @{text "\<le>"} and @{text "="})\<close>
haftmann@30652
  1235
huffman@47108
  1236
lemmas le_divide_eq_numeral1 [simp] =
huffman@47108
  1237
  pos_le_divide_eq [of "numeral w", OF zero_less_numeral]
haftmann@54489
  1238
  neg_le_divide_eq [of "- numeral w", OF neg_numeral_less_zero] for w
huffman@47108
  1239
huffman@47108
  1240
lemmas divide_le_eq_numeral1 [simp] =
huffman@47108
  1241
  pos_divide_le_eq [of "numeral w", OF zero_less_numeral]
haftmann@54489
  1242
  neg_divide_le_eq [of "- numeral w", OF neg_numeral_less_zero] for w
huffman@47108
  1243
huffman@47108
  1244
lemmas less_divide_eq_numeral1 [simp] =
huffman@47108
  1245
  pos_less_divide_eq [of "numeral w", OF zero_less_numeral]
haftmann@54489
  1246
  neg_less_divide_eq [of "- numeral w", OF neg_numeral_less_zero] for w
haftmann@30652
  1247
huffman@47108
  1248
lemmas divide_less_eq_numeral1 [simp] =
huffman@47108
  1249
  pos_divide_less_eq [of "numeral w", OF zero_less_numeral]
haftmann@54489
  1250
  neg_divide_less_eq [of "- numeral w", OF neg_numeral_less_zero] for w
huffman@47108
  1251
huffman@47108
  1252
lemmas eq_divide_eq_numeral1 [simp] =
huffman@47108
  1253
  eq_divide_eq [of _ _ "numeral w"]
haftmann@54489
  1254
  eq_divide_eq [of _ _ "- numeral w"] for w
huffman@47108
  1255
huffman@47108
  1256
lemmas divide_eq_eq_numeral1 [simp] =
huffman@47108
  1257
  divide_eq_eq [of _ "numeral w"]
haftmann@54489
  1258
  divide_eq_eq [of _ "- numeral w"] for w
haftmann@54489
  1259
haftmann@30652
  1260
wenzelm@60758
  1261
subsubsection\<open>Optional Simplification Rules Involving Constants\<close>
haftmann@30652
  1262
wenzelm@60758
  1263
text\<open>Simplify quotients that are compared with a literal constant.\<close>
haftmann@30652
  1264
huffman@47108
  1265
lemmas le_divide_eq_numeral =
huffman@47108
  1266
  le_divide_eq [of "numeral w"]
haftmann@54489
  1267
  le_divide_eq [of "- numeral w"] for w
huffman@47108
  1268
huffman@47108
  1269
lemmas divide_le_eq_numeral =
huffman@47108
  1270
  divide_le_eq [of _ _ "numeral w"]
haftmann@54489
  1271
  divide_le_eq [of _ _ "- numeral w"] for w
huffman@47108
  1272
huffman@47108
  1273
lemmas less_divide_eq_numeral =
huffman@47108
  1274
  less_divide_eq [of "numeral w"]
haftmann@54489
  1275
  less_divide_eq [of "- numeral w"] for w
huffman@47108
  1276
huffman@47108
  1277
lemmas divide_less_eq_numeral =
huffman@47108
  1278
  divide_less_eq [of _ _ "numeral w"]
haftmann@54489
  1279
  divide_less_eq [of _ _ "- numeral w"] for w
huffman@47108
  1280
huffman@47108
  1281
lemmas eq_divide_eq_numeral =
huffman@47108
  1282
  eq_divide_eq [of "numeral w"]
haftmann@54489
  1283
  eq_divide_eq [of "- numeral w"] for w
huffman@47108
  1284
huffman@47108
  1285
lemmas divide_eq_eq_numeral =
huffman@47108
  1286
  divide_eq_eq [of _ _ "numeral w"]
haftmann@54489
  1287
  divide_eq_eq [of _ _ "- numeral w"] for w
haftmann@30652
  1288
haftmann@30652
  1289
wenzelm@60758
  1290
text\<open>Not good as automatic simprules because they cause case splits.\<close>
haftmann@30652
  1291
lemmas divide_const_simps =
huffman@47108
  1292
  le_divide_eq_numeral divide_le_eq_numeral less_divide_eq_numeral
huffman@47108
  1293
  divide_less_eq_numeral eq_divide_eq_numeral divide_eq_eq_numeral
haftmann@30652
  1294
  le_divide_eq_1 divide_le_eq_1 less_divide_eq_1 divide_less_eq_1
haftmann@30652
  1295
haftmann@30652
  1296
wenzelm@60758
  1297
subsection \<open>The divides relation\<close>
haftmann@33320
  1298
nipkow@33657
  1299
lemma zdvd_antisym_nonneg:
nipkow@33657
  1300
    "0 <= m ==> 0 <= n ==> m dvd n ==> n dvd m ==> m = (n::int)"
haftmann@33320
  1301
  apply (simp add: dvd_def, auto)
haftmann@57512
  1302
  apply (auto simp add: mult.assoc zero_le_mult_iff zmult_eq_1_iff)
haftmann@33320
  1303
  done
haftmann@33320
  1304
lp15@60162
  1305
lemma zdvd_antisym_abs: assumes "(a::int) dvd b" and "b dvd a"
haftmann@33320
  1306
  shows "\<bar>a\<bar> = \<bar>b\<bar>"
nipkow@33657
  1307
proof cases
nipkow@33657
  1308
  assume "a = 0" with assms show ?thesis by simp
nipkow@33657
  1309
next
nipkow@33657
  1310
  assume "a \<noteq> 0"
wenzelm@60758
  1311
  from \<open>a dvd b\<close> obtain k where k:"b = a*k" unfolding dvd_def by blast
wenzelm@60758
  1312
  from \<open>b dvd a\<close> obtain k' where k':"a = b*k'" unfolding dvd_def by blast
haftmann@33320
  1313
  from k k' have "a = a*k*k'" by simp
haftmann@33320
  1314
  with mult_cancel_left1[where c="a" and b="k*k'"]
wenzelm@60758
  1315
  have kk':"k*k' = 1" using \<open>a\<noteq>0\<close> by (simp add: mult.assoc)
haftmann@33320
  1316
  hence "k = 1 \<and> k' = 1 \<or> k = -1 \<and> k' = -1" by (simp add: zmult_eq_1_iff)
haftmann@33320
  1317
  thus ?thesis using k k' by auto
haftmann@33320
  1318
qed
haftmann@33320
  1319
haftmann@33320
  1320
lemma zdvd_zdiffD: "k dvd m - n ==> k dvd n ==> k dvd (m::int)"
lp15@60162
  1321
  using dvd_add_right_iff [of k "- n" m] by simp
haftmann@33320
  1322
haftmann@33320
  1323
lemma zdvd_reduce: "(k dvd n + k * m) = (k dvd (n::int))"
haftmann@58649
  1324
  using dvd_add_times_triv_right_iff [of k n m] by (simp add: ac_simps)
haftmann@33320
  1325
haftmann@33320
  1326
lemma dvd_imp_le_int:
haftmann@33320
  1327
  fixes d i :: int
haftmann@33320
  1328
  assumes "i \<noteq> 0" and "d dvd i"
haftmann@33320
  1329
  shows "\<bar>d\<bar> \<le> \<bar>i\<bar>"
haftmann@33320
  1330
proof -
wenzelm@60758
  1331
  from \<open>d dvd i\<close> obtain k where "i = d * k" ..
wenzelm@60758
  1332
  with \<open>i \<noteq> 0\<close> have "k \<noteq> 0" by auto
haftmann@33320
  1333
  then have "1 \<le> \<bar>k\<bar>" and "0 \<le> \<bar>d\<bar>" by auto
haftmann@33320
  1334
  then have "\<bar>d\<bar> * 1 \<le> \<bar>d\<bar> * \<bar>k\<bar>" by (rule mult_left_mono)
wenzelm@60758
  1335
  with \<open>i = d * k\<close> show ?thesis by (simp add: abs_mult)
haftmann@33320
  1336
qed
haftmann@33320
  1337
haftmann@33320
  1338
lemma zdvd_not_zless:
haftmann@33320
  1339
  fixes m n :: int
haftmann@33320
  1340
  assumes "0 < m" and "m < n"
haftmann@33320
  1341
  shows "\<not> n dvd m"
haftmann@33320
  1342
proof
haftmann@33320
  1343
  from assms have "0 < n" by auto
haftmann@33320
  1344
  assume "n dvd m" then obtain k where k: "m = n * k" ..
wenzelm@60758
  1345
  with \<open>0 < m\<close> have "0 < n * k" by auto
wenzelm@60758
  1346
  with \<open>0 < n\<close> have "0 < k" by (simp add: zero_less_mult_iff)
wenzelm@60758
  1347
  with k \<open>0 < n\<close> \<open>m < n\<close> have "n * k < n * 1" by simp
wenzelm@60758
  1348
  with \<open>0 < n\<close> \<open>0 < k\<close> show False unfolding mult_less_cancel_left by auto
haftmann@33320
  1349
qed
haftmann@33320
  1350
haftmann@33320
  1351
lemma zdvd_mult_cancel: assumes d:"k * m dvd k * n" and kz:"k \<noteq> (0::int)"
haftmann@33320
  1352
  shows "m dvd n"
haftmann@33320
  1353
proof-
haftmann@33320
  1354
  from d obtain h where h: "k*n = k*m * h" unfolding dvd_def by blast
haftmann@33320
  1355
  {assume "n \<noteq> m*h" hence "k* n \<noteq> k* (m*h)" using kz by simp
haftmann@57512
  1356
    with h have False by (simp add: mult.assoc)}
haftmann@33320
  1357
  hence "n = m * h" by blast
haftmann@33320
  1358
  thus ?thesis by simp
haftmann@33320
  1359
qed
haftmann@33320
  1360
haftmann@33320
  1361
theorem zdvd_int: "(x dvd y) = (int x dvd int y)"
haftmann@33320
  1362
proof -
haftmann@33320
  1363
  have "\<And>k. int y = int x * k \<Longrightarrow> x dvd y"
haftmann@33320
  1364
  proof -
haftmann@33320
  1365
    fix k
haftmann@33320
  1366
    assume A: "int y = int x * k"
wenzelm@42676
  1367
    then show "x dvd y"
wenzelm@42676
  1368
    proof (cases k)
wenzelm@42676
  1369
      case (nonneg n)
wenzelm@42676
  1370
      with A have "y = x * n" by (simp add: of_nat_mult [symmetric])
haftmann@33320
  1371
      then show ?thesis ..
haftmann@33320
  1372
    next
wenzelm@42676
  1373
      case (neg n)
wenzelm@42676
  1374
      with A have "int y = int x * (- int (Suc n))" by simp
haftmann@33320
  1375
      also have "\<dots> = - (int x * int (Suc n))" by (simp only: mult_minus_right)
haftmann@33320
  1376
      also have "\<dots> = - int (x * Suc n)" by (simp only: of_nat_mult [symmetric])
haftmann@33320
  1377
      finally have "- int (x * Suc n) = int y" ..
haftmann@33320
  1378
      then show ?thesis by (simp only: negative_eq_positive) auto
haftmann@33320
  1379
    qed
haftmann@33320
  1380
  qed
haftmann@33320
  1381
  then show ?thesis by (auto elim!: dvdE simp only: dvd_triv_left of_nat_mult)
haftmann@33320
  1382
qed
haftmann@33320
  1383
wenzelm@42676
  1384
lemma zdvd1_eq[simp]: "(x::int) dvd 1 = (\<bar>x\<bar> = 1)"
haftmann@33320
  1385
proof
haftmann@33320
  1386
  assume d: "x dvd 1" hence "int (nat \<bar>x\<bar>) dvd int (nat 1)" by simp
haftmann@33320
  1387
  hence "nat \<bar>x\<bar> dvd 1" by (simp add: zdvd_int)
haftmann@33320
  1388
  hence "nat \<bar>x\<bar> = 1"  by simp
wenzelm@42676
  1389
  thus "\<bar>x\<bar> = 1" by (cases "x < 0") auto
haftmann@33320
  1390
next
haftmann@33320
  1391
  assume "\<bar>x\<bar>=1"
haftmann@33320
  1392
  then have "x = 1 \<or> x = -1" by auto
haftmann@33320
  1393
  then show "x dvd 1" by (auto intro: dvdI)
haftmann@33320
  1394
qed
haftmann@33320
  1395
lp15@60162
  1396
lemma zdvd_mult_cancel1:
haftmann@33320
  1397
  assumes mp:"m \<noteq>(0::int)" shows "(m * n dvd m) = (\<bar>n\<bar> = 1)"
haftmann@33320
  1398
proof
lp15@60162
  1399
  assume n1: "\<bar>n\<bar> = 1" thus "m * n dvd m"
wenzelm@42676
  1400
    by (cases "n >0") (auto simp add: minus_equation_iff)
haftmann@33320
  1401
next
haftmann@33320
  1402
  assume H: "m * n dvd m" hence H2: "m * n dvd m * 1" by simp
haftmann@33320
  1403
  from zdvd_mult_cancel[OF H2 mp] show "\<bar>n\<bar> = 1" by (simp only: zdvd1_eq)
haftmann@33320
  1404
qed
haftmann@33320
  1405
haftmann@33320
  1406
lemma int_dvd_iff: "(int m dvd z) = (m dvd nat (abs z))"
haftmann@33320
  1407
  unfolding zdvd_int by (cases "z \<ge> 0") simp_all
haftmann@33320
  1408
haftmann@33320
  1409
lemma dvd_int_iff: "(z dvd int m) = (nat (abs z) dvd m)"
haftmann@33320
  1410
  unfolding zdvd_int by (cases "z \<ge> 0") simp_all
haftmann@33320
  1411
haftmann@58650
  1412
lemma dvd_int_unfold_dvd_nat:
haftmann@58650
  1413
  "k dvd l \<longleftrightarrow> nat \<bar>k\<bar> dvd nat \<bar>l\<bar>"
haftmann@58650
  1414
  unfolding dvd_int_iff [symmetric] by simp
haftmann@58650
  1415
haftmann@33320
  1416
lemma nat_dvd_iff: "(nat z dvd m) = (if 0 \<le> z then (z dvd int m) else m = 0)"
haftmann@33320
  1417
  by (auto simp add: dvd_int_iff)
haftmann@33320
  1418
haftmann@33341
  1419
lemma eq_nat_nat_iff:
haftmann@33341
  1420
  "0 \<le> z \<Longrightarrow> 0 \<le> z' \<Longrightarrow> nat z = nat z' \<longleftrightarrow> z = z'"
haftmann@33341
  1421
  by (auto elim!: nonneg_eq_int)
haftmann@33341
  1422
haftmann@33341
  1423
lemma nat_power_eq:
haftmann@33341
  1424
  "0 \<le> z \<Longrightarrow> nat (z ^ n) = nat z ^ n"
haftmann@33341
  1425
  by (induct n) (simp_all add: nat_mult_distrib)
haftmann@33341
  1426
haftmann@33320
  1427
lemma zdvd_imp_le: "[| z dvd n; 0 < n |] ==> z \<le> (n::int)"
wenzelm@42676
  1428
  apply (cases n)
haftmann@33320
  1429
  apply (auto simp add: dvd_int_iff)
wenzelm@42676
  1430
  apply (cases z)
haftmann@33320
  1431
  apply (auto simp add: dvd_imp_le)
haftmann@33320
  1432
  done
haftmann@33320
  1433
haftmann@36749
  1434
lemma zdvd_period:
haftmann@36749
  1435
  fixes a d :: int
haftmann@36749
  1436
  assumes "a dvd d"
haftmann@36749
  1437
  shows "a dvd (x + t) \<longleftrightarrow> a dvd ((x + c * d) + t)"
haftmann@36749
  1438
proof -
haftmann@36749
  1439
  from assms obtain k where "d = a * k" by (rule dvdE)
wenzelm@42676
  1440
  show ?thesis
wenzelm@42676
  1441
  proof
haftmann@36749
  1442
    assume "a dvd (x + t)"
haftmann@36749
  1443
    then obtain l where "x + t = a * l" by (rule dvdE)
haftmann@36749
  1444
    then have "x = a * l - t" by simp
wenzelm@60758
  1445
    with \<open>d = a * k\<close> show "a dvd x + c * d + t" by simp
haftmann@36749
  1446
  next
haftmann@36749
  1447
    assume "a dvd x + c * d + t"
haftmann@36749
  1448
    then obtain l where "x + c * d + t = a * l" by (rule dvdE)
haftmann@36749
  1449
    then have "x = a * l - c * d - t" by simp
wenzelm@60758
  1450
    with \<open>d = a * k\<close> show "a dvd (x + t)" by simp
haftmann@36749
  1451
  qed
haftmann@36749
  1452
qed
haftmann@36749
  1453
haftmann@33320
  1454
wenzelm@60758
  1455
subsection \<open>Finiteness of intervals\<close>
bulwahn@46756
  1456
bulwahn@46756
  1457
lemma finite_interval_int1 [iff]: "finite {i :: int. a <= i & i <= b}"
bulwahn@46756
  1458
proof (cases "a <= b")
bulwahn@46756
  1459
  case True
bulwahn@46756
  1460
  from this show ?thesis
bulwahn@46756
  1461
  proof (induct b rule: int_ge_induct)
bulwahn@46756
  1462
    case base
bulwahn@46756
  1463
    have "{i. a <= i & i <= a} = {a}" by auto
bulwahn@46756
  1464
    from this show ?case by simp
bulwahn@46756
  1465
  next
bulwahn@46756
  1466
    case (step b)
bulwahn@46756
  1467
    from this have "{i. a <= i & i <= b + 1} = {i. a <= i & i <= b} \<union> {b + 1}" by auto
bulwahn@46756
  1468
    from this step show ?case by simp
bulwahn@46756
  1469
  qed
bulwahn@46756
  1470
next
bulwahn@46756
  1471
  case False from this show ?thesis
bulwahn@46756
  1472
    by (metis (lifting, no_types) Collect_empty_eq finite.emptyI order_trans)
bulwahn@46756
  1473
qed
bulwahn@46756
  1474
bulwahn@46756
  1475
lemma finite_interval_int2 [iff]: "finite {i :: int. a <= i & i < b}"
bulwahn@46756
  1476
by (rule rev_finite_subset[OF finite_interval_int1[of "a" "b"]]) auto
bulwahn@46756
  1477
bulwahn@46756
  1478
lemma finite_interval_int3 [iff]: "finite {i :: int. a < i & i <= b}"
bulwahn@46756
  1479
by (rule rev_finite_subset[OF finite_interval_int1[of "a" "b"]]) auto
bulwahn@46756
  1480
bulwahn@46756
  1481
lemma finite_interval_int4 [iff]: "finite {i :: int. a < i & i < b}"
bulwahn@46756
  1482
by (rule rev_finite_subset[OF finite_interval_int1[of "a" "b"]]) auto
bulwahn@46756
  1483
bulwahn@46756
  1484
wenzelm@60758
  1485
subsection \<open>Configuration of the code generator\<close>
haftmann@25919
  1486
wenzelm@60758
  1487
text \<open>Constructors\<close>
huffman@47108
  1488
huffman@47108
  1489
definition Pos :: "num \<Rightarrow> int" where
huffman@47108
  1490
  [simp, code_abbrev]: "Pos = numeral"
huffman@47108
  1491
huffman@47108
  1492
definition Neg :: "num \<Rightarrow> int" where
haftmann@54489
  1493
  [simp, code_abbrev]: "Neg n = - (Pos n)"
huffman@47108
  1494
huffman@47108
  1495
code_datatype "0::int" Pos Neg
huffman@47108
  1496
huffman@47108
  1497
wenzelm@60758
  1498
text \<open>Auxiliary operations\<close>
huffman@47108
  1499
huffman@47108
  1500
definition dup :: "int \<Rightarrow> int" where
huffman@47108
  1501
  [simp]: "dup k = k + k"
haftmann@26507
  1502
huffman@47108
  1503
lemma dup_code [code]:
huffman@47108
  1504
  "dup 0 = 0"
huffman@47108
  1505
  "dup (Pos n) = Pos (Num.Bit0 n)"
huffman@47108
  1506
  "dup (Neg n) = Neg (Num.Bit0 n)"
haftmann@54489
  1507
  unfolding Pos_def Neg_def
huffman@47108
  1508
  by (simp_all add: numeral_Bit0)
huffman@47108
  1509
huffman@47108
  1510
definition sub :: "num \<Rightarrow> num \<Rightarrow> int" where
huffman@47108
  1511
  [simp]: "sub m n = numeral m - numeral n"
haftmann@26507
  1512
huffman@47108
  1513
lemma sub_code [code]:
huffman@47108
  1514
  "sub Num.One Num.One = 0"
huffman@47108
  1515
  "sub (Num.Bit0 m) Num.One = Pos (Num.BitM m)"
huffman@47108
  1516
  "sub (Num.Bit1 m) Num.One = Pos (Num.Bit0 m)"
huffman@47108
  1517
  "sub Num.One (Num.Bit0 n) = Neg (Num.BitM n)"
huffman@47108
  1518
  "sub Num.One (Num.Bit1 n) = Neg (Num.Bit0 n)"
huffman@47108
  1519
  "sub (Num.Bit0 m) (Num.Bit0 n) = dup (sub m n)"
huffman@47108
  1520
  "sub (Num.Bit1 m) (Num.Bit1 n) = dup (sub m n)"
huffman@47108
  1521
  "sub (Num.Bit1 m) (Num.Bit0 n) = dup (sub m n) + 1"
huffman@47108
  1522
  "sub (Num.Bit0 m) (Num.Bit1 n) = dup (sub m n) - 1"
haftmann@54489
  1523
  apply (simp_all only: sub_def dup_def numeral.simps Pos_def Neg_def numeral_BitM)
haftmann@54230
  1524
  apply (simp_all only: algebra_simps minus_diff_eq)
haftmann@54230
  1525
  apply (simp_all only: add.commute [of _ "- (numeral n + numeral n)"])
haftmann@54230
  1526
  apply (simp_all only: minus_add add.assoc left_minus)
haftmann@54230
  1527
  done
huffman@47108
  1528
wenzelm@60758
  1529
text \<open>Implementations\<close>
huffman@47108
  1530
huffman@47108
  1531
lemma one_int_code [code, code_unfold]:
huffman@47108
  1532
  "1 = Pos Num.One"
huffman@47108
  1533
  by simp
huffman@47108
  1534
huffman@47108
  1535
lemma plus_int_code [code]:
huffman@47108
  1536
  "k + 0 = (k::int)"
huffman@47108
  1537
  "0 + l = (l::int)"
huffman@47108
  1538
  "Pos m + Pos n = Pos (m + n)"
huffman@47108
  1539
  "Pos m + Neg n = sub m n"
huffman@47108
  1540
  "Neg m + Pos n = sub n m"
huffman@47108
  1541
  "Neg m + Neg n = Neg (m + n)"
huffman@47108
  1542
  by simp_all
haftmann@26507
  1543
huffman@47108
  1544
lemma uminus_int_code [code]:
huffman@47108
  1545
  "uminus 0 = (0::int)"
huffman@47108
  1546
  "uminus (Pos m) = Neg m"
huffman@47108
  1547
  "uminus (Neg m) = Pos m"
huffman@47108
  1548
  by simp_all
huffman@47108
  1549
huffman@47108
  1550
lemma minus_int_code [code]:
huffman@47108
  1551
  "k - 0 = (k::int)"
huffman@47108
  1552
  "0 - l = uminus (l::int)"
huffman@47108
  1553
  "Pos m - Pos n = sub m n"
huffman@47108
  1554
  "Pos m - Neg n = Pos (m + n)"
huffman@47108
  1555
  "Neg m - Pos n = Neg (m + n)"
huffman@47108
  1556
  "Neg m - Neg n = sub n m"
huffman@47108
  1557
  by simp_all
huffman@47108
  1558
huffman@47108
  1559
lemma times_int_code [code]:
huffman@47108
  1560
  "k * 0 = (0::int)"
huffman@47108
  1561
  "0 * l = (0::int)"
huffman@47108
  1562
  "Pos m * Pos n = Pos (m * n)"
huffman@47108
  1563
  "Pos m * Neg n = Neg (m * n)"
huffman@47108
  1564
  "Neg m * Pos n = Neg (m * n)"
huffman@47108
  1565
  "Neg m * Neg n = Pos (m * n)"
huffman@47108
  1566
  by simp_all
haftmann@26507
  1567
haftmann@38857
  1568
instantiation int :: equal
haftmann@26507
  1569
begin
haftmann@26507
  1570
haftmann@37767
  1571
definition
huffman@47108
  1572
  "HOL.equal k l \<longleftrightarrow> k = (l::int)"
haftmann@38857
  1573
wenzelm@61169
  1574
instance
wenzelm@61169
  1575
  by standard (rule equal_int_def)
haftmann@26507
  1576
haftmann@26507
  1577
end
haftmann@26507
  1578
huffman@47108
  1579
lemma equal_int_code [code]:
huffman@47108
  1580
  "HOL.equal 0 (0::int) \<longleftrightarrow> True"
huffman@47108
  1581
  "HOL.equal 0 (Pos l) \<longleftrightarrow> False"
huffman@47108
  1582
  "HOL.equal 0 (Neg l) \<longleftrightarrow> False"
huffman@47108
  1583
  "HOL.equal (Pos k) 0 \<longleftrightarrow> False"
huffman@47108
  1584
  "HOL.equal (Pos k) (Pos l) \<longleftrightarrow> HOL.equal k l"
huffman@47108
  1585
  "HOL.equal (Pos k) (Neg l) \<longleftrightarrow> False"
huffman@47108
  1586
  "HOL.equal (Neg k) 0 \<longleftrightarrow> False"
huffman@47108
  1587
  "HOL.equal (Neg k) (Pos l) \<longleftrightarrow> False"
huffman@47108
  1588
  "HOL.equal (Neg k) (Neg l) \<longleftrightarrow> HOL.equal k l"
huffman@47108
  1589
  by (auto simp add: equal)
haftmann@26507
  1590
huffman@47108
  1591
lemma equal_int_refl [code nbe]:
haftmann@38857
  1592
  "HOL.equal (k::int) k \<longleftrightarrow> True"
huffman@47108
  1593
  by (fact equal_refl)
haftmann@26507
  1594
haftmann@28562
  1595
lemma less_eq_int_code [code]:
huffman@47108
  1596
  "0 \<le> (0::int) \<longleftrightarrow> True"
huffman@47108
  1597
  "0 \<le> Pos l \<longleftrightarrow> True"
huffman@47108
  1598
  "0 \<le> Neg l \<longleftrightarrow> False"
huffman@47108
  1599
  "Pos k \<le> 0 \<longleftrightarrow> False"
huffman@47108
  1600
  "Pos k \<le> Pos l \<longleftrightarrow> k \<le> l"
huffman@47108
  1601
  "Pos k \<le> Neg l \<longleftrightarrow> False"
huffman@47108
  1602
  "Neg k \<le> 0 \<longleftrightarrow> True"
huffman@47108
  1603
  "Neg k \<le> Pos l \<longleftrightarrow> True"
huffman@47108
  1604
  "Neg k \<le> Neg l \<longleftrightarrow> l \<le> k"
huffman@28958
  1605
  by simp_all
haftmann@26507
  1606
haftmann@28562
  1607
lemma less_int_code [code]:
huffman@47108
  1608
  "0 < (0::int) \<longleftrightarrow> False"
huffman@47108
  1609
  "0 < Pos l \<longleftrightarrow> True"
huffman@47108
  1610
  "0 < Neg l \<longleftrightarrow> False"
huffman@47108
  1611
  "Pos k < 0 \<longleftrightarrow> False"
huffman@47108
  1612
  "Pos k < Pos l \<longleftrightarrow> k < l"
huffman@47108
  1613
  "Pos k < Neg l \<longleftrightarrow> False"
huffman@47108
  1614
  "Neg k < 0 \<longleftrightarrow> True"
huffman@47108
  1615
  "Neg k < Pos l \<longleftrightarrow> True"
huffman@47108
  1616
  "Neg k < Neg l \<longleftrightarrow> l < k"
huffman@28958
  1617
  by simp_all
haftmann@25919
  1618
huffman@47108
  1619
lemma nat_code [code]:
huffman@47108
  1620
  "nat (Int.Neg k) = 0"
huffman@47108
  1621
  "nat 0 = 0"
huffman@47108
  1622
  "nat (Int.Pos k) = nat_of_num k"
haftmann@54489
  1623
  by (simp_all add: nat_of_num_numeral)
haftmann@25928
  1624
huffman@47108
  1625
lemma (in ring_1) of_int_code [code]:
haftmann@54489
  1626
  "of_int (Int.Neg k) = - numeral k"
huffman@47108
  1627
  "of_int 0 = 0"
huffman@47108
  1628
  "of_int (Int.Pos k) = numeral k"
huffman@47108
  1629
  by simp_all
haftmann@25919
  1630
huffman@47108
  1631
wenzelm@60758
  1632
text \<open>Serializer setup\<close>
haftmann@25919
  1633
haftmann@52435
  1634
code_identifier
haftmann@52435
  1635
  code_module Int \<rightharpoonup> (SML) Arith and (OCaml) Arith and (Haskell) Arith
haftmann@25919
  1636
haftmann@25919
  1637
quickcheck_params [default_type = int]
haftmann@25919
  1638
huffman@47108
  1639
hide_const (open) Pos Neg sub dup
haftmann@25919
  1640
haftmann@25919
  1641
wenzelm@60758
  1642
subsection \<open>Legacy theorems\<close>
haftmann@25919
  1643
haftmann@25919
  1644
lemmas inj_int = inj_of_nat [where 'a=int]
haftmann@25919
  1645
lemmas zadd_int = of_nat_add [where 'a=int, symmetric]
haftmann@25919
  1646
lemmas int_mult = of_nat_mult [where 'a=int]
haftmann@25919
  1647
lemmas zmult_int = of_nat_mult [where 'a=int, symmetric]
wenzelm@45607
  1648
lemmas int_eq_0_conv = of_nat_eq_0_iff [where 'a=int and m="n"] for n
haftmann@25919
  1649
lemmas zless_int = of_nat_less_iff [where 'a=int]
wenzelm@45607
  1650
lemmas int_less_0_conv = of_nat_less_0_iff [where 'a=int and m="k"] for k
haftmann@25919
  1651
lemmas zero_less_int_conv = of_nat_0_less_iff [where 'a=int]
haftmann@25919
  1652
lemmas zero_zle_int = of_nat_0_le_iff [where 'a=int]
wenzelm@45607
  1653
lemmas int_le_0_conv = of_nat_le_0_iff [where 'a=int and m="n"] for n
haftmann@25919
  1654
lemmas int_0 = of_nat_0 [where 'a=int]
haftmann@25919
  1655
lemmas int_1 = of_nat_1 [where 'a=int]
haftmann@25919
  1656
lemmas int_Suc = of_nat_Suc [where 'a=int]
huffman@47207
  1657
lemmas int_numeral = of_nat_numeral [where 'a=int]
wenzelm@45607
  1658
lemmas abs_int_eq = abs_of_nat [where 'a=int and n="m"] for m
haftmann@25919
  1659
lemmas of_int_int_eq = of_int_of_nat_eq [where 'a=int]
haftmann@25919
  1660
lemmas zdiff_int = of_nat_diff [where 'a=int, symmetric]
huffman@47255
  1661
lemmas zpower_numeral_even = power_numeral_even [where 'a=int]
huffman@47255
  1662
lemmas zpower_numeral_odd = power_numeral_odd [where 'a=int]
haftmann@30960
  1663
haftmann@31015
  1664
lemma zpower_zpower:
haftmann@31015
  1665
  "(x ^ y) ^ z = (x ^ (y * z)::int)"
haftmann@31015
  1666
  by (rule power_mult [symmetric])
haftmann@31015
  1667
haftmann@31015
  1668
lemma int_power:
haftmann@31015
  1669
  "int (m ^ n) = int m ^ n"
haftmann@54489
  1670
  by (fact of_nat_power)
haftmann@31015
  1671
haftmann@31015
  1672
lemmas zpower_int = int_power [symmetric]
haftmann@31015
  1673
wenzelm@60758
  1674
text \<open>De-register @{text "int"} as a quotient type:\<close>
huffman@48045
  1675
kuncar@53652
  1676
lifting_update int.lifting
kuncar@53652
  1677
lifting_forget int.lifting
huffman@48045
  1678
wenzelm@60758
  1679
text\<open>Also the class for fields with characteristic zero.\<close>
lp15@59667
  1680
class field_char_0 = field + ring_char_0
lp15@59667
  1681
subclass (in linordered_field) field_char_0 ..
lp15@59667
  1682
haftmann@25919
  1683
end