src/HOL/Number_Theory/Fib.thy
author haftmann
Sat Nov 11 18:41:08 2017 +0000 (19 months ago)
changeset 67051 e7e54a0b9197
parent 65393 079a6f850c02
child 69597 ff784d5a5bfb
permissions -rw-r--r--
dedicated definition for coprimality
wenzelm@41959
     1
(*  Title:      HOL/Number_Theory/Fib.thy
wenzelm@41959
     2
    Author:     Lawrence C. Paulson
wenzelm@41959
     3
    Author:     Jeremy Avigad
eberlm@64317
     4
    Author:     Manuel Eberl
nipkow@31719
     5
*)
nipkow@31719
     6
wenzelm@60527
     7
section \<open>The fibonacci function\<close>
nipkow@31719
     8
nipkow@31719
     9
theory Fib
eberlm@64317
    10
  imports Complex_Main
nipkow@31719
    11
begin
nipkow@31719
    12
nipkow@31719
    13
wenzelm@60526
    14
subsection \<open>Fibonacci numbers\<close>
nipkow@31719
    15
paulson@54713
    16
fun fib :: "nat \<Rightarrow> nat"
wenzelm@65393
    17
  where
wenzelm@65393
    18
    fib0: "fib 0 = 0"
wenzelm@65393
    19
  | fib1: "fib (Suc 0) = 1"
wenzelm@65393
    20
  | fib2: "fib (Suc (Suc n)) = fib (Suc n) + fib n"
wenzelm@60527
    21
nipkow@31719
    22
wenzelm@60526
    23
subsection \<open>Basic Properties\<close>
nipkow@31719
    24
wenzelm@65393
    25
lemma fib_1 [simp]: "fib 1 = 1"
paulson@54713
    26
  by (metis One_nat_def fib1)
nipkow@31719
    27
wenzelm@65393
    28
lemma fib_2 [simp]: "fib 2 = 1"
wenzelm@65393
    29
  using fib.simps(3) [of 0] by (simp add: numeral_2_eq_2)
nipkow@31719
    30
paulson@54713
    31
lemma fib_plus_2: "fib (n + 2) = fib (n + 1) + fib n"
paulson@54713
    32
  by (metis Suc_eq_plus1 add_2_eq_Suc' fib.simps(3))
nipkow@31719
    33
wenzelm@65393
    34
lemma fib_add: "fib (Suc (n + k)) = fib (Suc k) * fib (Suc n) + fib k * fib n"
paulson@54713
    35
  by (induct n rule: fib.induct) (auto simp add: field_simps)
nipkow@31719
    36
paulson@54713
    37
lemma fib_neq_0_nat: "n > 0 \<Longrightarrow> fib n > 0"
wenzelm@65393
    38
  by (induct n rule: fib.induct) auto
nipkow@31719
    39
wenzelm@60527
    40
eberlm@64317
    41
subsection \<open>More efficient code\<close>
eberlm@64317
    42
eberlm@64317
    43
text \<open>
eberlm@64317
    44
  The naive approach is very inefficient since the branching recursion leads to many
eberlm@64317
    45
  values of @{term fib} being computed multiple times. We can avoid this by ``remembering''
eberlm@64317
    46
  the last two values in the sequence, yielding a tail-recursive version.
wenzelm@65393
    47
  This is far from optimal (it takes roughly $O(n\cdot M(n))$ time where $M(n)$ is the
eberlm@64317
    48
  time required to multiply two $n$-bit integers), but much better than the naive version,
eberlm@64317
    49
  which is exponential.
eberlm@64317
    50
\<close>
eberlm@64317
    51
wenzelm@65393
    52
fun gen_fib :: "nat \<Rightarrow> nat \<Rightarrow> nat \<Rightarrow> nat"
wenzelm@65393
    53
  where
wenzelm@65393
    54
    "gen_fib a b 0 = a"
wenzelm@65393
    55
  | "gen_fib a b (Suc 0) = b"
wenzelm@65393
    56
  | "gen_fib a b (Suc (Suc n)) = gen_fib b (a + b) (Suc n)"
eberlm@64317
    57
eberlm@64317
    58
lemma gen_fib_recurrence: "gen_fib a b (Suc (Suc n)) = gen_fib a b n + gen_fib a b (Suc n)"
wenzelm@65393
    59
  by (induct a b n rule: gen_fib.induct) simp_all
wenzelm@65393
    60
eberlm@64317
    61
lemma gen_fib_fib: "gen_fib (fib n) (fib (Suc n)) m = fib (n + m)"
wenzelm@65393
    62
  by (induct m rule: fib.induct) (simp_all del: gen_fib.simps(3) add: gen_fib_recurrence)
eberlm@64317
    63
eberlm@64317
    64
lemma fib_conv_gen_fib: "fib n = gen_fib 0 1 n"
eberlm@64317
    65
  using gen_fib_fib[of 0 n] by simp
eberlm@64317
    66
eberlm@64317
    67
declare fib_conv_gen_fib [code]
eberlm@64317
    68
eberlm@64317
    69
wenzelm@60526
    70
subsection \<open>A Few Elementary Results\<close>
lp15@60141
    71
wenzelm@60526
    72
text \<open>
wenzelm@65393
    73
  \<^medskip> Concrete Mathematics, page 278: Cassini's identity.  The proof is
nipkow@31719
    74
  much easier using integers, not natural numbers!
wenzelm@60526
    75
\<close>
nipkow@31719
    76
paulson@54713
    77
lemma fib_Cassini_int: "int (fib (Suc (Suc n)) * fib n) - int((fib (Suc n))\<^sup>2) = - ((-1)^n)"
wenzelm@65393
    78
  by (induct n rule: fib.induct) (auto simp add: field_simps power2_eq_square power_add)
nipkow@31719
    79
paulson@54713
    80
lemma fib_Cassini_nat:
wenzelm@60527
    81
  "fib (Suc (Suc n)) * fib n =
wenzelm@60527
    82
     (if even n then (fib (Suc n))\<^sup>2 - 1 else (fib (Suc n))\<^sup>2 + 1)"
wenzelm@65393
    83
  using fib_Cassini_int [of n] by (auto simp del: of_nat_mult of_nat_power)
nipkow@31719
    84
nipkow@31719
    85
wenzelm@60526
    86
subsection \<open>Law 6.111 of Concrete Mathematics\<close>
nipkow@31719
    87
wenzelm@65393
    88
lemma coprime_fib_Suc_nat: "coprime (fib n) (fib (Suc n))"
paulson@54713
    89
  apply (induct n rule: fib.induct)
haftmann@67051
    90
    apply (simp_all add: coprime_iff_gcd_eq_1 algebra_simps)
haftmann@67051
    91
  apply (simp add: add.assoc [symmetric])
wenzelm@44872
    92
  done
nipkow@31719
    93
haftmann@67051
    94
lemma gcd_fib_add:
haftmann@67051
    95
  "gcd (fib m) (fib (n + m)) = gcd (fib m) (fib n)"
haftmann@67051
    96
proof (cases m)
haftmann@67051
    97
  case 0
haftmann@67051
    98
  then show ?thesis
haftmann@67051
    99
    by simp
haftmann@67051
   100
next
haftmann@67051
   101
  case (Suc q)
haftmann@67051
   102
  from coprime_fib_Suc_nat [of q]
haftmann@67051
   103
  have "coprime (fib (Suc q)) (fib q)"
haftmann@67051
   104
    by (simp add: ac_simps)
haftmann@67051
   105
  have "gcd (fib q) (fib (Suc q)) = Suc 0"
haftmann@67051
   106
    using coprime_fib_Suc_nat [of q] by simp
haftmann@67051
   107
  then have *: "gcd (fib n * fib q) (fib n * fib (Suc q)) = fib n"
haftmann@67051
   108
    by (simp add: gcd_mult_distrib_nat [symmetric])
haftmann@67051
   109
  moreover have "gcd (fib (Suc q)) (fib n * fib q + fib (Suc n) * fib (Suc q)) =
haftmann@67051
   110
    gcd (fib (Suc q)) (fib n * fib q)"
haftmann@67051
   111
    using gcd_add_mult [of "fib (Suc q)"] by (simp add: ac_simps)
haftmann@67051
   112
  moreover have "gcd (fib (Suc q)) (fib n * fib (Suc q)) = fib (Suc q)"
haftmann@67051
   113
    by simp
haftmann@67051
   114
  ultimately show ?thesis
haftmann@67051
   115
    using Suc \<open>coprime (fib (Suc q)) (fib q)\<close>
haftmann@67051
   116
    by (auto simp add: fib_add algebra_simps gcd_mult_right_right_cancel)
haftmann@67051
   117
qed
nipkow@31719
   118
wenzelm@60527
   119
lemma gcd_fib_diff: "m \<le> n \<Longrightarrow> gcd (fib m) (fib (n - m)) = gcd (fib m) (fib n)"
paulson@54713
   120
  by (simp add: gcd_fib_add [symmetric, of _ "n-m"])
nipkow@31719
   121
wenzelm@60527
   122
lemma gcd_fib_mod: "0 < m \<Longrightarrow> gcd (fib m) (fib (n mod m)) = gcd (fib m) (fib n)"
nipkow@31719
   123
proof (induct n rule: less_induct)
nipkow@31719
   124
  case (less n)
nipkow@31719
   125
  show "gcd (fib m) (fib (n mod m)) = gcd (fib m) (fib n)"
nipkow@31719
   126
  proof (cases "m < n")
wenzelm@44872
   127
    case True
wenzelm@44872
   128
    then have "m \<le> n" by auto
wenzelm@65393
   129
    with \<open>0 < m\<close> have "0 < n" by auto
wenzelm@65393
   130
    with \<open>0 < m\<close> \<open>m < n\<close> have *: "n - m < n" by auto
nipkow@31719
   131
    have "gcd (fib m) (fib (n mod m)) = gcd (fib m) (fib ((n - m) mod m))"
wenzelm@65393
   132
      by (simp add: mod_if [of n]) (use \<open>m < n\<close> in auto)
wenzelm@44872
   133
    also have "\<dots> = gcd (fib m)  (fib (n - m))"
wenzelm@65393
   134
      by (simp add: less.hyps * \<open>0 < m\<close>)
wenzelm@44872
   135
    also have "\<dots> = gcd (fib m) (fib n)"
wenzelm@60526
   136
      by (simp add: gcd_fib_diff \<open>m \<le> n\<close>)
nipkow@31719
   137
    finally show "gcd (fib m) (fib (n mod m)) = gcd (fib m) (fib n)" .
nipkow@31719
   138
  next
wenzelm@44872
   139
    case False
wenzelm@44872
   140
    then show "gcd (fib m) (fib (n mod m)) = gcd (fib m) (fib n)"
wenzelm@44872
   141
      by (cases "m = n") auto
nipkow@31719
   142
  qed
nipkow@31719
   143
qed
nipkow@31719
   144
wenzelm@65393
   145
lemma fib_gcd: "fib (gcd m n) = gcd (fib m) (fib n)"  \<comment> \<open>Law 6.111\<close>
haftmann@62348
   146
  by (induct m n rule: gcd_nat_induct) (simp_all add: gcd_non_0_nat gcd.commute gcd_fib_mod)
nipkow@31719
   147
nipkow@64267
   148
theorem fib_mult_eq_sum_nat: "fib (Suc n) * fib n = (\<Sum>k \<in> {..n}. fib k * fib k)"
paulson@54713
   149
  by (induct n rule: nat.induct) (auto simp add:  field_simps)
nipkow@31719
   150
wenzelm@60527
   151
eberlm@64317
   152
subsection \<open>Closed form\<close>
eberlm@64317
   153
eberlm@64317
   154
lemma fib_closed_form:
wenzelm@65393
   155
  fixes \<phi> \<psi> :: real
wenzelm@65393
   156
  defines "\<phi> \<equiv> (1 + sqrt 5) / 2"
wenzelm@65393
   157
    and "\<psi> \<equiv> (1 - sqrt 5) / 2"
wenzelm@65393
   158
  shows "of_nat (fib n) = (\<phi> ^ n - \<psi> ^ n) / sqrt 5"
wenzelm@65393
   159
proof (induct n rule: fib.induct)
eberlm@64317
   160
  fix n :: nat
eberlm@64317
   161
  assume IH1: "of_nat (fib n) = (\<phi> ^ n - \<psi> ^ n) / sqrt 5"
eberlm@64317
   162
  assume IH2: "of_nat (fib (Suc n)) = (\<phi> ^ Suc n - \<psi> ^ Suc n) / sqrt 5"
eberlm@64317
   163
  have "of_nat (fib (Suc (Suc n))) = of_nat (fib (Suc n)) + of_nat (fib n)" by simp
wenzelm@65393
   164
  also have "\<dots> = (\<phi>^n * (\<phi> + 1) - \<psi>^n * (\<psi> + 1)) / sqrt 5"
eberlm@64317
   165
    by (simp add: IH1 IH2 field_simps)
eberlm@64317
   166
  also have "\<phi> + 1 = \<phi>\<^sup>2" by (simp add: \<phi>_def field_simps power2_eq_square)
eberlm@64317
   167
  also have "\<psi> + 1 = \<psi>\<^sup>2" by (simp add: \<psi>_def field_simps power2_eq_square)
wenzelm@65393
   168
  also have "\<phi>^n * \<phi>\<^sup>2 - \<psi>^n * \<psi>\<^sup>2 = \<phi> ^ Suc (Suc n) - \<psi> ^ Suc (Suc n)"
eberlm@64317
   169
    by (simp add: power2_eq_square)
eberlm@64317
   170
  finally show "of_nat (fib (Suc (Suc n))) = (\<phi> ^ Suc (Suc n) - \<psi> ^ Suc (Suc n)) / sqrt 5" .
eberlm@64317
   171
qed (simp_all add: \<phi>_def \<psi>_def field_simps)
eberlm@64317
   172
eberlm@64317
   173
lemma fib_closed_form':
wenzelm@65393
   174
  fixes \<phi> \<psi> :: real
wenzelm@65393
   175
  defines "\<phi> \<equiv> (1 + sqrt 5) / 2"
wenzelm@65393
   176
    and "\<psi> \<equiv> (1 - sqrt 5) / 2"
eberlm@64317
   177
  assumes "n > 0"
wenzelm@65393
   178
  shows "fib n = round (\<phi> ^ n / sqrt 5)"
eberlm@64317
   179
proof (rule sym, rule round_unique')
eberlm@64317
   180
  have "\<bar>\<phi> ^ n / sqrt 5 - of_int (int (fib n))\<bar> = \<bar>\<psi>\<bar> ^ n / sqrt 5"
eberlm@64317
   181
    by (simp add: fib_closed_form[folded \<phi>_def \<psi>_def] field_simps power_abs)
eberlm@64317
   182
  also {
eberlm@64317
   183
    from assms have "\<bar>\<psi>\<bar>^n \<le> \<bar>\<psi>\<bar>^1"
eberlm@64317
   184
      by (intro power_decreasing) (simp_all add: algebra_simps real_le_lsqrt)
wenzelm@65393
   185
    also have "\<dots> < sqrt 5 / 2" by (simp add: \<psi>_def field_simps)
eberlm@64317
   186
    finally have "\<bar>\<psi>\<bar>^n / sqrt 5 < 1/2" by (simp add: field_simps)
eberlm@64317
   187
  }
eberlm@64317
   188
  finally show "\<bar>\<phi> ^ n / sqrt 5 - of_int (int (fib n))\<bar> < 1/2" .
eberlm@64317
   189
qed
eberlm@64317
   190
eberlm@64317
   191
lemma fib_asymptotics:
wenzelm@65393
   192
  fixes \<phi> :: real
wenzelm@65393
   193
  defines "\<phi> \<equiv> (1 + sqrt 5) / 2"
wenzelm@65393
   194
  shows "(\<lambda>n. real (fib n) / (\<phi> ^ n / sqrt 5)) \<longlonglongrightarrow> 1"
eberlm@64317
   195
proof -
wenzelm@65393
   196
  define \<psi> :: real where "\<psi> \<equiv> (1 - sqrt 5) / 2"
eberlm@64317
   197
  have "\<phi> > 1" by (simp add: \<phi>_def)
wenzelm@65393
   198
  then have *: "\<phi> \<noteq> 0" by auto
eberlm@64317
   199
  have "(\<lambda>n. (\<psi> / \<phi>) ^ n) \<longlonglongrightarrow> 0"
eberlm@64317
   200
    by (rule LIMSEQ_power_zero) (simp_all add: \<phi>_def \<psi>_def field_simps add_pos_pos)
wenzelm@65393
   201
  then have "(\<lambda>n. 1 - (\<psi> / \<phi>) ^ n) \<longlonglongrightarrow> 1 - 0"
wenzelm@65393
   202
    by (intro tendsto_diff tendsto_const)
wenzelm@65393
   203
  with * show ?thesis
eberlm@64317
   204
    by (simp add: divide_simps fib_closed_form [folded \<phi>_def \<psi>_def])
eberlm@64317
   205
qed
eberlm@64317
   206
eberlm@64317
   207
eberlm@64317
   208
subsection \<open>Divide-and-Conquer recurrence\<close>
eberlm@64317
   209
eberlm@64317
   210
text \<open>
wenzelm@65393
   211
  The following divide-and-conquer recurrence allows for a more efficient computation
wenzelm@65393
   212
  of Fibonacci numbers; however, it requires memoisation of values to be reasonably
eberlm@64317
   213
  efficient, cutting the number of values to be computed to logarithmically many instead of
wenzelm@65393
   214
  linearly many. The vast majority of the computation time is then actually spent on the
eberlm@64317
   215
  multiplication, since the output number is exponential in the input number.
eberlm@64317
   216
\<close>
eberlm@64317
   217
eberlm@64317
   218
lemma fib_rec_odd:
wenzelm@65393
   219
  fixes \<phi> \<psi> :: real
wenzelm@65393
   220
  defines "\<phi> \<equiv> (1 + sqrt 5) / 2"
wenzelm@65393
   221
    and "\<psi> \<equiv> (1 - sqrt 5) / 2"
wenzelm@65393
   222
  shows "fib (Suc (2 * n)) = fib n^2 + fib (Suc n)^2"
eberlm@64317
   223
proof -
eberlm@64317
   224
  have "of_nat (fib n^2 + fib (Suc n)^2) = ((\<phi> ^ n - \<psi> ^ n)\<^sup>2 + (\<phi> * \<phi> ^ n - \<psi> * \<psi> ^ n)\<^sup>2)/5"
eberlm@64317
   225
    by (simp add: fib_closed_form[folded \<phi>_def \<psi>_def] field_simps power2_eq_square)
wenzelm@65393
   226
  also
wenzelm@65393
   227
  let ?A = "\<phi>^(2 * n) + \<psi>^(2 * n) - 2*(\<phi> * \<psi>)^n + \<phi>^(2 * n + 2) + \<psi>^(2 * n + 2) - 2*(\<phi> * \<psi>)^(n + 1)"
wenzelm@65393
   228
  have "(\<phi> ^ n - \<psi> ^ n)\<^sup>2 + (\<phi> * \<phi> ^ n - \<psi> * \<psi> ^ n)\<^sup>2 = ?A"
wenzelm@65393
   229
    by (simp add: power2_eq_square algebra_simps power_mult power_mult_distrib)
wenzelm@65393
   230
  also have "\<phi> * \<psi> = -1"
wenzelm@65393
   231
    by (simp add: \<phi>_def \<psi>_def field_simps)
wenzelm@65393
   232
  then have "?A = \<phi>^(2 * n + 1) * (\<phi> + inverse \<phi>) + \<psi>^(2 * n + 1) * (\<psi> + inverse \<psi>)"
eberlm@64317
   233
    by (auto simp: field_simps power2_eq_square)
wenzelm@65393
   234
  also have "1 + sqrt 5 > 0"
wenzelm@65393
   235
    by (auto intro: add_pos_pos)
wenzelm@65393
   236
  then have "\<phi> + inverse \<phi> = sqrt 5"
wenzelm@65393
   237
    by (simp add: \<phi>_def field_simps)
wenzelm@65393
   238
  also have "\<psi> + inverse \<psi> = -sqrt 5"
wenzelm@65393
   239
    by (simp add: \<psi>_def field_simps)
wenzelm@65393
   240
  also have "(\<phi> ^ (2 * n + 1) * sqrt 5 + \<psi> ^ (2 * n + 1) * - sqrt 5) / 5 =
wenzelm@65393
   241
    (\<phi> ^ (2 * n + 1) - \<psi> ^ (2 * n + 1)) * (sqrt 5 / 5)"
wenzelm@65393
   242
    by (simp add: field_simps)
wenzelm@65393
   243
  also have "sqrt 5 / 5 = inverse (sqrt 5)"
wenzelm@65393
   244
    by (simp add: field_simps)
wenzelm@65393
   245
  also have "(\<phi> ^ (2 * n + 1) - \<psi> ^ (2 * n + 1)) * \<dots> = of_nat (fib (Suc (2 * n)))"
eberlm@64317
   246
    by (simp add: fib_closed_form[folded \<phi>_def \<psi>_def] divide_inverse)
wenzelm@65393
   247
  finally show ?thesis
wenzelm@65393
   248
    by (simp only: of_nat_eq_iff)
eberlm@64317
   249
qed
eberlm@64317
   250
wenzelm@65393
   251
lemma fib_rec_even: "fib (2 * n) = (fib (n - 1) + fib (n + 1)) * fib n"
wenzelm@65393
   252
proof (induct n)
wenzelm@65393
   253
  case 0
wenzelm@65393
   254
  then show ?case by simp
wenzelm@65393
   255
next
eberlm@64317
   256
  case (Suc n)
eberlm@64317
   257
  let ?rfib = "\<lambda>x. real (fib x)"
wenzelm@65393
   258
  have "2 * (Suc n) = Suc (Suc (2 * n))" by simp
wenzelm@65393
   259
  also have "real (fib \<dots>) = ?rfib n^2 + ?rfib (Suc n)^2 + (?rfib (n - 1) + ?rfib (n + 1)) * ?rfib n"
eberlm@64317
   260
    by (simp add: fib_rec_odd Suc)
eberlm@64317
   261
  also have "(?rfib (n - 1) + ?rfib (n + 1)) * ?rfib n = (2 * ?rfib (n + 1) - ?rfib n) * ?rfib n"
eberlm@64317
   262
    by (cases n) simp_all
wenzelm@65393
   263
  also have "?rfib n^2 + ?rfib (Suc n)^2 + \<dots> = (?rfib (Suc n) + 2 * ?rfib n) * ?rfib (Suc n)"
eberlm@64317
   264
    by (simp add: algebra_simps power2_eq_square)
wenzelm@65393
   265
  also have "\<dots> = real ((fib (Suc n - 1) + fib (Suc n + 1)) * fib (Suc n))" by simp
eberlm@64317
   266
  finally show ?case by (simp only: of_nat_eq_iff)
wenzelm@65393
   267
qed
eberlm@64317
   268
wenzelm@65393
   269
lemma fib_rec_even': "fib (2 * n) = (2 * fib (n - 1) + fib n) * fib n"
eberlm@64317
   270
  by (subst fib_rec_even, cases n) simp_all
eberlm@64317
   271
eberlm@64317
   272
lemma fib_rec:
wenzelm@65393
   273
  "fib n =
wenzelm@65393
   274
    (if n = 0 then 0 else if n = 1 then 1
wenzelm@65393
   275
     else if even n then let n' = n div 2; fn = fib n' in (2 * fib (n' - 1) + fn) * fn
wenzelm@65393
   276
     else let n' = n div 2 in fib n' ^ 2 + fib (Suc n') ^ 2)"
eberlm@64317
   277
  by (auto elim: evenE oddE simp: fib_rec_odd fib_rec_even' Let_def)
eberlm@64317
   278
eberlm@64317
   279
wenzelm@60526
   280
subsection \<open>Fibonacci and Binomial Coefficients\<close>
lp15@60141
   281
nipkow@64267
   282
lemma sum_drop_zero: "(\<Sum>k = 0..Suc n. if 0<k then (f (k - 1)) else 0) = (\<Sum>j = 0..n. f j)"
lp15@60141
   283
  by (induct n) auto
lp15@60141
   284
nipkow@64267
   285
lemma sum_choose_drop_zero:
wenzelm@65393
   286
  "(\<Sum>k = 0..Suc n. if k = 0 then 0 else (Suc n - k) choose (k - 1)) =
wenzelm@65393
   287
    (\<Sum>j = 0..n. (n-j) choose j)"
nipkow@64267
   288
  by (rule trans [OF sum.cong sum_drop_zero]) auto
lp15@60141
   289
wenzelm@60527
   290
lemma ne_diagonal_fib: "(\<Sum>k = 0..n. (n-k) choose k) = fib (Suc n)"
lp15@60141
   291
proof (induct n rule: fib.induct)
wenzelm@60527
   292
  case 1
wenzelm@60527
   293
  show ?case by simp
lp15@60141
   294
next
wenzelm@60527
   295
  case 2
wenzelm@60527
   296
  show ?case by simp
lp15@60141
   297
next
lp15@60141
   298
  case (3 n)
lp15@60141
   299
  have "(\<Sum>k = 0..Suc n. Suc (Suc n) - k choose k) =
wenzelm@65393
   300
     (\<Sum>k = 0..Suc n. (Suc n - k choose k) + (if k = 0 then 0 else (Suc n - k choose (k - 1))))"
nipkow@64267
   301
    by (rule sum.cong) (simp_all add: choose_reduce_nat)
wenzelm@65393
   302
  also have "\<dots> =
wenzelm@65393
   303
    (\<Sum>k = 0..Suc n. Suc n - k choose k) +
wenzelm@65393
   304
    (\<Sum>k = 0..Suc n. if k=0 then 0 else (Suc n - k choose (k - 1)))"
nipkow@64267
   305
    by (simp add: sum.distrib)
wenzelm@65393
   306
  also have "\<dots> = (\<Sum>k = 0..Suc n. Suc n - k choose k) + (\<Sum>j = 0..n. n - j choose j)"
nipkow@64267
   307
    by (metis sum_choose_drop_zero)
lp15@60141
   308
  finally show ?case using 3
lp15@60141
   309
    by simp
lp15@60141
   310
qed
lp15@60141
   311
nipkow@31719
   312
end