src/HOL/Algebra/Sylow.thy
author nipkow
Wed Jan 10 15:25:09 2018 +0100 (19 months ago)
changeset 67399 eab6ce8368fa
parent 64914 51f015bd4565
child 67613 ce654b0e6d69
permissions -rw-r--r--
ran isabelle update_op on all sources
wenzelm@14706
     1
(*  Title:      HOL/Algebra/Sylow.thy
paulson@13870
     2
    Author:     Florian Kammueller, with new proofs by L C Paulson
paulson@13870
     3
*)
paulson@13870
     4
wenzelm@35849
     5
theory Sylow
wenzelm@64912
     6
  imports Coset Exponent
wenzelm@35849
     7
begin
paulson@13870
     8
wenzelm@64912
     9
text \<open>See also @{cite "Kammueller-Paulson:1999"}.\<close>
wenzelm@64912
    10
wenzelm@64912
    11
text \<open>The combinatorial argument is in theory @{theory Exponent}.\<close>
wenzelm@14706
    12
wenzelm@64912
    13
lemma le_extend_mult: "\<lbrakk>0 < c; a \<le> b\<rbrakk> \<Longrightarrow> a \<le> b * c"
wenzelm@64912
    14
  for c :: nat
wenzelm@64912
    15
  by (metis divisors_zero dvd_triv_left leI less_le_trans nat_dvd_not_less zero_less_iff_neq_zero)
lp15@62410
    16
paulson@14747
    17
locale sylow = group +
paulson@13870
    18
  fixes p and a and m and calM and RelM
wenzelm@64912
    19
  assumes prime_p: "prime p"
wenzelm@64912
    20
    and order_G: "order G = (p^a) * m"
wenzelm@64912
    21
    and finite_G[iff]: "finite (carrier G)"
wenzelm@64912
    22
  defines "calM \<equiv> {s. s \<subseteq> carrier G \<and> card s = p^a}"
wenzelm@64912
    23
    and "RelM \<equiv> {(N1, N2). N1 \<in> calM \<and> N2 \<in> calM \<and> (\<exists>g \<in> carrier G. N1 = N2 #> g)}"
lp15@62410
    24
begin
paulson@13870
    25
lp15@62410
    26
lemma RelM_refl_on: "refl_on calM RelM"
wenzelm@64912
    27
  by (auto simp: refl_on_def RelM_def calM_def) (blast intro!: coset_mult_one [symmetric])
paulson@13870
    28
lp15@62410
    29
lemma RelM_sym: "sym RelM"
paulson@13870
    30
proof (unfold sym_def RelM_def, clarify)
paulson@13870
    31
  fix y g
wenzelm@64912
    32
  assume "y \<in> calM"
paulson@13870
    33
    and g: "g \<in> carrier G"
wenzelm@64912
    34
  then have "y = y #> g #> (inv g)"
wenzelm@64912
    35
    by (simp add: coset_mult_assoc calM_def)
wenzelm@64912
    36
  then show "\<exists>g'\<in>carrier G. y = y #> g #> g'"
wenzelm@64912
    37
    by (blast intro: g)
paulson@13870
    38
qed
paulson@13870
    39
lp15@62410
    40
lemma RelM_trans: "trans RelM"
wenzelm@64912
    41
  by (auto simp add: trans_def RelM_def calM_def coset_mult_assoc)
paulson@13870
    42
lp15@62410
    43
lemma RelM_equiv: "equiv calM RelM"
wenzelm@64912
    44
  unfolding equiv_def by (blast intro: RelM_refl_on RelM_sym RelM_trans)
paulson@13870
    45
wenzelm@64912
    46
lemma M_subset_calM_prep: "M' \<in> calM // RelM  \<Longrightarrow> M' \<subseteq> calM"
wenzelm@64912
    47
  unfolding RelM_def by (blast elim!: quotientE)
paulson@13870
    48
lp15@62410
    49
end
ballarin@20318
    50
wenzelm@64912
    51
subsection \<open>Main Part of the Proof\<close>
paulson@13870
    52
paulson@13870
    53
locale sylow_central = sylow +
paulson@13870
    54
  fixes H and M1 and M
wenzelm@64912
    55
  assumes M_in_quot: "M \<in> calM // RelM"
wenzelm@64912
    56
    and not_dvd_M: "\<not> (p ^ Suc (multiplicity p m) dvd card M)"
wenzelm@64912
    57
    and M1_in_M: "M1 \<in> M"
wenzelm@64912
    58
  defines "H \<equiv> {g. g \<in> carrier G \<and> M1 #> g = M1}"
lp15@62410
    59
begin
paulson@13870
    60
lp15@62410
    61
lemma M_subset_calM: "M \<subseteq> calM"
lp15@62410
    62
  by (rule M_in_quot [THEN M_subset_calM_prep])
paulson@13870
    63
wenzelm@64912
    64
lemma card_M1: "card M1 = p^a"
lp15@62410
    65
  using M1_in_M M_subset_calM calM_def by blast
wenzelm@64912
    66
lp15@62410
    67
lemma exists_x_in_M1: "\<exists>x. x \<in> M1"
wenzelm@64912
    68
  using prime_p [THEN prime_gt_Suc_0_nat] card_M1
wenzelm@64912
    69
  by (metis Suc_lessD card_eq_0_iff empty_subsetI equalityI gr_implies_not0 nat_zero_less_power_iff subsetI)
paulson@13870
    70
lp15@62410
    71
lemma M1_subset_G [simp]: "M1 \<subseteq> carrier G"
wenzelm@64912
    72
  using M1_in_M M_subset_calM calM_def mem_Collect_eq subsetCE by blast
paulson@13870
    73
lp15@62410
    74
lemma M1_inj_H: "\<exists>f \<in> H\<rightarrow>M1. inj_on f H"
lp15@62410
    75
proof -
lp15@62410
    76
  from exists_x_in_M1 obtain m1 where m1M: "m1 \<in> M1"..
wenzelm@64912
    77
  have m1: "m1 \<in> carrier G"
wenzelm@64912
    78
    by (simp add: m1M M1_subset_G [THEN subsetD])
lp15@62410
    79
  show ?thesis
lp15@62410
    80
  proof
lp15@62410
    81
    show "inj_on (\<lambda>z\<in>H. m1 \<otimes> z) H"
wenzelm@64912
    82
      by (simp add: inj_on_def l_cancel [of m1 x y, THEN iffD1] H_def m1)
nipkow@67399
    83
    show "restrict ((\<otimes>) m1) H \<in> H \<rightarrow> M1"
lp15@62410
    84
    proof (rule restrictI)
wenzelm@64912
    85
      fix z
wenzelm@64912
    86
      assume zH: "z \<in> H"
lp15@62410
    87
      show "m1 \<otimes> z \<in> M1"
lp15@62410
    88
      proof -
lp15@62410
    89
        from zH
lp15@62410
    90
        have zG: "z \<in> carrier G" and M1zeq: "M1 #> z = M1"
lp15@62410
    91
          by (auto simp add: H_def)
lp15@62410
    92
        show ?thesis
wenzelm@64912
    93
          by (rule subst [OF M1zeq]) (simp add: m1M zG rcosI)
paulson@13870
    94
      qed
paulson@13870
    95
    qed
paulson@13870
    96
  qed
lp15@62410
    97
qed
paulson@13870
    98
lp15@62410
    99
end
paulson@13870
   100
wenzelm@64912
   101
wenzelm@64912
   102
subsection \<open>Discharging the Assumptions of \<open>sylow_central\<close>\<close>
paulson@13870
   103
lp15@62410
   104
context sylow
lp15@62410
   105
begin
lp15@62410
   106
lp15@62410
   107
lemma EmptyNotInEquivSet: "{} \<notin> calM // RelM"
wenzelm@64912
   108
  by (blast elim!: quotientE dest: RelM_equiv [THEN equiv_class_self])
paulson@13870
   109
wenzelm@64912
   110
lemma existsM1inM: "M \<in> calM // RelM \<Longrightarrow> \<exists>M1. M1 \<in> M"
lp15@62410
   111
  using RelM_equiv equiv_Eps_in by blast
paulson@13870
   112
wenzelm@64912
   113
lemma zero_less_o_G: "0 < order G"
lp15@62410
   114
  by (simp add: order_def card_gt_0_iff carrier_not_empty)
paulson@13870
   115
lp15@62410
   116
lemma zero_less_m: "m > 0"
lp15@62410
   117
  using zero_less_o_G by (simp add: order_G)
paulson@13870
   118
wenzelm@64912
   119
lemma card_calM: "card calM = (p^a) * m choose p^a"
wenzelm@64912
   120
  by (simp add: calM_def n_subsets order_G [symmetric] order_def)
paulson@13870
   121
lp15@62410
   122
lemma zero_less_card_calM: "card calM > 0"
wenzelm@64912
   123
  by (simp add: card_calM zero_less_binomial le_extend_mult zero_less_m)
paulson@13870
   124
wenzelm@64912
   125
lemma max_p_div_calM: "\<not> (p ^ Suc (multiplicity p m) dvd card calM)"
eberlm@63534
   126
proof
eberlm@63534
   127
  assume "p ^ Suc (multiplicity p m) dvd card calM"
wenzelm@64912
   128
  with zero_less_card_calM prime_p
eberlm@63534
   129
  have "Suc (multiplicity p m) \<le> multiplicity p (card calM)"
eberlm@63534
   130
    by (intro multiplicity_geI) auto
wenzelm@64912
   131
  then have "multiplicity p m < multiplicity p (card calM)" by simp
eberlm@63534
   132
  also have "multiplicity p m = multiplicity p (card calM)"
eberlm@63534
   133
    by (simp add: const_p_fac prime_p zero_less_m card_calM)
eberlm@63534
   134
  finally show False by simp
lp15@62410
   135
qed
paulson@13870
   136
lp15@62410
   137
lemma finite_calM: "finite calM"
wenzelm@64912
   138
  unfolding calM_def by (rule finite_subset [where B = "Pow (carrier G)"]) auto
paulson@13870
   139
wenzelm@64912
   140
lemma lemma_A1: "\<exists>M \<in> calM // RelM. \<not> (p ^ Suc (multiplicity p m) dvd card M)"
lp15@62410
   141
  using RelM_equiv equiv_imp_dvd_card finite_calM max_p_div_calM by blast
paulson@13870
   142
lp15@62410
   143
end
paulson@13870
   144
wenzelm@64912
   145
wenzelm@64912
   146
subsubsection \<open>Introduction and Destruct Rules for \<open>H\<close>\<close>
paulson@13870
   147
wenzelm@64914
   148
context sylow_central
wenzelm@64914
   149
begin
paulson@13870
   150
wenzelm@64914
   151
lemma H_I: "\<lbrakk>g \<in> carrier G; M1 #> g = M1\<rbrakk> \<Longrightarrow> g \<in> H"
wenzelm@64912
   152
  by (simp add: H_def)
paulson@13870
   153
wenzelm@64914
   154
lemma H_into_carrier_G: "x \<in> H \<Longrightarrow> x \<in> carrier G"
wenzelm@64912
   155
  by (simp add: H_def)
wenzelm@64912
   156
wenzelm@64914
   157
lemma in_H_imp_eq: "g \<in> H \<Longrightarrow> M1 #> g = M1"
wenzelm@64914
   158
  by (simp add: H_def)
wenzelm@64914
   159
wenzelm@64914
   160
lemma H_m_closed: "\<lbrakk>x \<in> H; y \<in> H\<rbrakk> \<Longrightarrow> x \<otimes> y \<in> H"
wenzelm@64912
   161
  by (simp add: H_def coset_mult_assoc [symmetric])
paulson@13870
   162
wenzelm@64914
   163
lemma H_not_empty: "H \<noteq> {}"
wenzelm@64912
   164
  apply (simp add: H_def)
wenzelm@64912
   165
  apply (rule exI [of _ \<one>])
wenzelm@64912
   166
  apply simp
wenzelm@64912
   167
  done
paulson@13870
   168
wenzelm@64914
   169
lemma H_is_subgroup: "subgroup H G"
wenzelm@64912
   170
  apply (rule subgroupI)
wenzelm@64912
   171
     apply (rule subsetI)
wenzelm@64912
   172
     apply (erule H_into_carrier_G)
wenzelm@64912
   173
    apply (rule H_not_empty)
wenzelm@64912
   174
   apply (simp add: H_def)
wenzelm@64912
   175
   apply clarify
wenzelm@64912
   176
   apply (erule_tac P = "\<lambda>z. lhs z = M1" for lhs in subst)
wenzelm@64912
   177
   apply (simp add: coset_mult_assoc )
wenzelm@64912
   178
  apply (blast intro: H_m_closed)
wenzelm@64912
   179
  done
paulson@13870
   180
paulson@13870
   181
wenzelm@64914
   182
lemma rcosetGM1g_subset_G: "\<lbrakk>g \<in> carrier G; x \<in> M1 #> g\<rbrakk> \<Longrightarrow> x \<in> carrier G"
wenzelm@64912
   183
  by (blast intro: M1_subset_G [THEN r_coset_subset_G, THEN subsetD])
paulson@13870
   184
wenzelm@64914
   185
lemma finite_M1: "finite M1"
wenzelm@64912
   186
  by (rule finite_subset [OF M1_subset_G finite_G])
paulson@13870
   187
wenzelm@64914
   188
lemma finite_rcosetGM1g: "g \<in> carrier G \<Longrightarrow> finite (M1 #> g)"
lp15@62410
   189
  using rcosetGM1g_subset_G finite_G M1_subset_G cosets_finite rcosetsI by blast
paulson@13870
   190
wenzelm@64914
   191
lemma M1_cardeq_rcosetGM1g: "g \<in> carrier G \<Longrightarrow> card (M1 #> g) = card M1"
wenzelm@64912
   192
  by (simp add: card_cosets_equal rcosetsI)
paulson@13870
   193
wenzelm@64914
   194
lemma M1_RelM_rcosetGM1g: "g \<in> carrier G \<Longrightarrow> (M1, M1 #> g) \<in> RelM"
wenzelm@64912
   195
  apply (simp add: RelM_def calM_def card_M1)
wenzelm@64912
   196
  apply (rule conjI)
wenzelm@64912
   197
   apply (blast intro: rcosetGM1g_subset_G)
wenzelm@64912
   198
  apply (simp add: card_M1 M1_cardeq_rcosetGM1g)
wenzelm@64912
   199
  apply (metis M1_subset_G coset_mult_assoc coset_mult_one r_inv_ex)
wenzelm@64912
   200
  done
paulson@13870
   201
wenzelm@64914
   202
end
wenzelm@64914
   203
paulson@13870
   204
wenzelm@64912
   205
subsection \<open>Equal Cardinalities of \<open>M\<close> and the Set of Cosets\<close>
paulson@13870
   206
wenzelm@64912
   207
text \<open>Injections between @{term M} and @{term "rcosets\<^bsub>G\<^esub> H"} show that
wenzelm@61382
   208
 their cardinalities are equal.\<close>
paulson@13870
   209
wenzelm@64912
   210
lemma ElemClassEquiv: "\<lbrakk>equiv A r; C \<in> A // r\<rbrakk> \<Longrightarrow> \<forall>x \<in> C. \<forall>y \<in> C. (x, y) \<in> r"
wenzelm@64912
   211
  unfolding equiv_def quotient_def sym_def trans_def by blast
paulson@13870
   212
wenzelm@64914
   213
context sylow_central
wenzelm@64914
   214
begin
wenzelm@64914
   215
wenzelm@64914
   216
lemma M_elem_map: "M2 \<in> M \<Longrightarrow> \<exists>g. g \<in> carrier G \<and> M1 #> g = M2"
wenzelm@64912
   217
  using M1_in_M M_in_quot [THEN RelM_equiv [THEN ElemClassEquiv]]
wenzelm@64912
   218
  by (simp add: RelM_def) (blast dest!: bspec)
paulson@13870
   219
wenzelm@64914
   220
lemmas M_elem_map_carrier = M_elem_map [THEN someI_ex, THEN conjunct1]
paulson@13870
   221
wenzelm@64914
   222
lemmas M_elem_map_eq = M_elem_map [THEN someI_ex, THEN conjunct2]
paulson@13870
   223
wenzelm@64914
   224
lemma M_funcset_rcosets_H:
wenzelm@64912
   225
  "(\<lambda>x\<in>M. H #> (SOME g. g \<in> carrier G \<and> M1 #> g = x)) \<in> M \<rightarrow> rcosets H"
lp15@55157
   226
  by (metis (lifting) H_is_subgroup M_elem_map_carrier rcosetsI restrictI subgroup_imp_subset)
paulson@13870
   227
wenzelm@64914
   228
lemma inj_M_GmodH: "\<exists>f \<in> M \<rightarrow> rcosets H. inj_on f M"
wenzelm@64912
   229
  apply (rule bexI)
wenzelm@64912
   230
   apply (rule_tac [2] M_funcset_rcosets_H)
wenzelm@64912
   231
  apply (rule inj_onI, simp)
wenzelm@64912
   232
  apply (rule trans [OF _ M_elem_map_eq])
wenzelm@64912
   233
   prefer 2 apply assumption
wenzelm@64912
   234
  apply (rule M_elem_map_eq [symmetric, THEN trans], assumption)
wenzelm@64912
   235
  apply (rule coset_mult_inv1)
wenzelm@64912
   236
     apply (erule_tac [2] M_elem_map_carrier)+
wenzelm@64912
   237
   apply (rule_tac [2] M1_subset_G)
wenzelm@64912
   238
  apply (rule coset_join1 [THEN in_H_imp_eq])
wenzelm@64912
   239
    apply (rule_tac [3] H_is_subgroup)
wenzelm@64912
   240
   prefer 2 apply (blast intro: M_elem_map_carrier)
wenzelm@64912
   241
  apply (simp add: coset_mult_inv2 H_def M_elem_map_carrier subset_eq)
wenzelm@64912
   242
  done
paulson@13870
   243
wenzelm@64914
   244
end
paulson@13870
   245
wenzelm@64914
   246
wenzelm@64914
   247
subsubsection \<open>The Opposite Injection\<close>
paulson@13870
   248
wenzelm@64914
   249
context sylow_central
wenzelm@64914
   250
begin
wenzelm@64914
   251
wenzelm@64914
   252
lemma H_elem_map: "H1 \<in> rcosets H \<Longrightarrow> \<exists>g. g \<in> carrier G \<and> H #> g = H1"
wenzelm@64912
   253
  by (auto simp: RCOSETS_def)
paulson@13870
   254
wenzelm@64914
   255
lemmas H_elem_map_carrier = H_elem_map [THEN someI_ex, THEN conjunct1]
paulson@13870
   256
wenzelm@64914
   257
lemmas H_elem_map_eq = H_elem_map [THEN someI_ex, THEN conjunct2]
paulson@13870
   258
wenzelm@64914
   259
lemma rcosets_H_funcset_M:
paulson@14963
   260
  "(\<lambda>C \<in> rcosets H. M1 #> (@g. g \<in> carrier G \<and> H #> g = C)) \<in> rcosets H \<rightarrow> M"
wenzelm@64912
   261
  apply (simp add: RCOSETS_def)
wenzelm@64912
   262
  apply (fast intro: someI2
wenzelm@64912
   263
      intro!: M1_in_M in_quotient_imp_closed [OF RelM_equiv M_in_quot _  M1_RelM_rcosetGM1g])
wenzelm@64912
   264
  done
paulson@13870
   265
wenzelm@64912
   266
text \<open>Close to a duplicate of \<open>inj_M_GmodH\<close>.\<close>
wenzelm@64914
   267
lemma inj_GmodH_M: "\<exists>g \<in> rcosets H\<rightarrow>M. inj_on g (rcosets H)"
wenzelm@64912
   268
  apply (rule bexI)
wenzelm@64912
   269
   apply (rule_tac [2] rcosets_H_funcset_M)
wenzelm@64912
   270
  apply (rule inj_onI)
wenzelm@64912
   271
  apply (simp)
wenzelm@64912
   272
  apply (rule trans [OF _ H_elem_map_eq])
wenzelm@64912
   273
   prefer 2 apply assumption
wenzelm@64912
   274
  apply (rule H_elem_map_eq [symmetric, THEN trans], assumption)
wenzelm@64912
   275
  apply (rule coset_mult_inv1)
wenzelm@64912
   276
     apply (erule_tac [2] H_elem_map_carrier)+
wenzelm@64912
   277
   apply (rule_tac [2] H_is_subgroup [THEN subgroup.subset])
wenzelm@64912
   278
  apply (rule coset_join2)
wenzelm@64912
   279
    apply (blast intro: H_elem_map_carrier)
wenzelm@64912
   280
   apply (rule H_is_subgroup)
wenzelm@64912
   281
  apply (simp add: H_I coset_mult_inv2 H_elem_map_carrier)
wenzelm@64912
   282
  done
paulson@13870
   283
wenzelm@64914
   284
lemma calM_subset_PowG: "calM \<subseteq> Pow (carrier G)"
wenzelm@64912
   285
  by (auto simp: calM_def)
paulson@13870
   286
paulson@13870
   287
wenzelm@64914
   288
lemma finite_M: "finite M"
wenzelm@64912
   289
  by (metis M_subset_calM finite_calM rev_finite_subset)
paulson@13870
   290
wenzelm@64914
   291
lemma cardMeqIndexH: "card M = card (rcosets H)"
wenzelm@64912
   292
  apply (insert inj_M_GmodH inj_GmodH_M)
wenzelm@64912
   293
  apply (blast intro: card_bij finite_M H_is_subgroup
wenzelm@64912
   294
      rcosets_subset_PowG [THEN finite_subset]
wenzelm@64912
   295
      finite_Pow_iff [THEN iffD2])
wenzelm@64912
   296
  done
paulson@13870
   297
wenzelm@64914
   298
lemma index_lem: "card M * card H = order G"
wenzelm@64912
   299
  by (simp add: cardMeqIndexH lagrange H_is_subgroup)
paulson@13870
   300
wenzelm@64914
   301
lemma lemma_leq1: "p^a \<le> card H"
wenzelm@64912
   302
  apply (rule dvd_imp_le)
wenzelm@64912
   303
   apply (rule div_combine [OF prime_imp_prime_elem[OF prime_p] not_dvd_M])
wenzelm@64912
   304
   prefer 2 apply (blast intro: subgroup.finite_imp_card_positive H_is_subgroup)
wenzelm@64912
   305
  apply (simp add: index_lem order_G power_add mult_dvd_mono multiplicity_dvd zero_less_m)
wenzelm@64912
   306
  done
paulson@13870
   307
wenzelm@64914
   308
lemma lemma_leq2: "card H \<le> p^a"
wenzelm@64912
   309
  apply (subst card_M1 [symmetric])
wenzelm@64912
   310
  apply (cut_tac M1_inj_H)
wenzelm@64912
   311
  apply (blast intro!: M1_subset_G intro: card_inj H_into_carrier_G finite_subset [OF _ finite_G])
wenzelm@64912
   312
  done
paulson@13870
   313
wenzelm@64914
   314
lemma card_H_eq: "card H = p^a"
wenzelm@64912
   315
  by (blast intro: le_antisym lemma_leq1 lemma_leq2)
paulson@13870
   316
wenzelm@64914
   317
end
wenzelm@64914
   318
wenzelm@64912
   319
lemma (in sylow) sylow_thm: "\<exists>H. subgroup H G \<and> card H = p^a"
wenzelm@64912
   320
  using lemma_A1
wenzelm@64912
   321
  apply clarify
wenzelm@64912
   322
  apply (frule existsM1inM, clarify)
wenzelm@64912
   323
  apply (subgoal_tac "sylow_central G p a m M1 M")
wenzelm@64912
   324
   apply (blast dest: sylow_central.H_is_subgroup sylow_central.card_H_eq)
wenzelm@64912
   325
  apply (simp add: sylow_central_def sylow_central_axioms_def sylow_axioms calM_def RelM_def)
wenzelm@64912
   326
  done
paulson@13870
   327
wenzelm@64912
   328
text \<open>Needed because the locale's automatic definition refers to
wenzelm@64912
   329
  @{term "semigroup G"} and @{term "group_axioms G"} rather than
wenzelm@61382
   330
  simply to @{term "group G"}.\<close>
wenzelm@64912
   331
lemma sylow_eq: "sylow G p a m \<longleftrightarrow> group G \<and> sylow_axioms G p a m"
wenzelm@64912
   332
  by (simp add: sylow_def group_def)
paulson@13870
   333
ballarin@20318
   334
wenzelm@61382
   335
subsection \<open>Sylow's Theorem\<close>
ballarin@20318
   336
paulson@13870
   337
theorem sylow_thm:
wenzelm@64912
   338
  "\<lbrakk>prime p; group G; order G = (p^a) * m; finite (carrier G)\<rbrakk>
wenzelm@64912
   339
    \<Longrightarrow> \<exists>H. subgroup H G \<and> card H = p^a"
wenzelm@64912
   340
  by (rule sylow.sylow_thm [of G p a m]) (simp add: sylow_eq sylow_axioms_def)
paulson@13870
   341
paulson@13870
   342
end