src/Pure/drule.ML
author wenzelm
Wed Mar 26 22:40:03 2008 +0100 (2008-03-26)
changeset 26413 003dd6155870
parent 25470 ba5a2bb7a81a
child 26424 a6cad32a27b0
permissions -rw-r--r--
added thread data (formerly global ref in ML/ml_context.ML);
renamed ML_Context.>> to Context.>> (again);
     1 (*  Title:      Pure/drule.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1993  University of Cambridge
     5 
     6 Derived rules and other operations on theorems.
     7 *)
     8 
     9 infix 0 RS RSN RL RLN MRS MRL OF COMP INCR_COMP COMP_INCR;
    10 
    11 signature BASIC_DRULE =
    12 sig
    13   val mk_implies: cterm * cterm -> cterm
    14   val list_implies: cterm list * cterm -> cterm
    15   val strip_imp_prems: cterm -> cterm list
    16   val strip_imp_concl: cterm -> cterm
    17   val cprems_of: thm -> cterm list
    18   val cterm_fun: (term -> term) -> (cterm -> cterm)
    19   val ctyp_fun: (typ -> typ) -> (ctyp -> ctyp)
    20   val read_insts: theory -> (indexname -> typ option) * (indexname -> sort option) ->
    21     (indexname -> typ option) * (indexname -> sort option) -> string list ->
    22     (indexname * string) list -> (ctyp * ctyp) list * (cterm * cterm) list
    23   val types_sorts: thm -> (indexname-> typ option) * (indexname-> sort option)
    24   val forall_intr_list: cterm list -> thm -> thm
    25   val forall_intr_frees: thm -> thm
    26   val forall_intr_vars: thm -> thm
    27   val forall_elim_list: cterm list -> thm -> thm
    28   val forall_elim_var: int -> thm -> thm
    29   val forall_elim_vars: int -> thm -> thm
    30   val gen_all: thm -> thm
    31   val lift_all: cterm -> thm -> thm
    32   val freeze_thaw: thm -> thm * (thm -> thm)
    33   val freeze_thaw_robust: thm -> thm * (int -> thm -> thm)
    34   val implies_elim_list: thm -> thm list -> thm
    35   val implies_intr_list: cterm list -> thm -> thm
    36   val instantiate: (ctyp * ctyp) list * (cterm * cterm) list -> thm -> thm
    37   val zero_var_indexes_list: thm list -> thm list
    38   val zero_var_indexes: thm -> thm
    39   val implies_intr_hyps: thm -> thm
    40   val standard: thm -> thm
    41   val standard': thm -> thm
    42   val rotate_prems: int -> thm -> thm
    43   val rearrange_prems: int list -> thm -> thm
    44   val RSN: thm * (int * thm) -> thm
    45   val RS: thm * thm -> thm
    46   val RLN: thm list * (int * thm list) -> thm list
    47   val RL: thm list * thm list -> thm list
    48   val MRS: thm list * thm -> thm
    49   val MRL: thm list list * thm list -> thm list
    50   val OF: thm * thm list -> thm
    51   val compose: thm * int * thm -> thm list
    52   val COMP: thm * thm -> thm
    53   val INCR_COMP: thm * thm -> thm
    54   val COMP_INCR: thm * thm -> thm
    55   val read_instantiate_sg: theory -> (string*string)list -> thm -> thm
    56   val read_instantiate: (string*string)list -> thm -> thm
    57   val cterm_instantiate: (cterm*cterm)list -> thm -> thm
    58   val size_of_thm: thm -> int
    59   val reflexive_thm: thm
    60   val symmetric_thm: thm
    61   val transitive_thm: thm
    62   val symmetric_fun: thm -> thm
    63   val extensional: thm -> thm
    64   val equals_cong: thm
    65   val imp_cong: thm
    66   val swap_prems_eq: thm
    67   val asm_rl: thm
    68   val cut_rl: thm
    69   val revcut_rl: thm
    70   val thin_rl: thm
    71   val triv_forall_equality: thm
    72   val distinct_prems_rl: thm
    73   val swap_prems_rl: thm
    74   val equal_intr_rule: thm
    75   val equal_elim_rule1: thm
    76   val equal_elim_rule2: thm
    77   val instantiate': ctyp option list -> cterm option list -> thm -> thm
    78 end;
    79 
    80 signature DRULE =
    81 sig
    82   include BASIC_DRULE
    83   val generalize: string list * string list -> thm -> thm
    84   val list_comb: cterm * cterm list -> cterm
    85   val strip_comb: cterm -> cterm * cterm list
    86   val strip_type: ctyp -> ctyp list * ctyp
    87   val beta_conv: cterm -> cterm -> cterm
    88   val add_used: thm -> string list -> string list
    89   val flexflex_unique: thm -> thm
    90   val close_derivation: thm -> thm
    91   val store_thm: bstring -> thm -> thm
    92   val store_standard_thm: bstring -> thm -> thm
    93   val store_thm_open: bstring -> thm -> thm
    94   val store_standard_thm_open: bstring -> thm -> thm
    95   val compose_single: thm * int * thm -> thm
    96   val imp_cong_rule: thm -> thm -> thm
    97   val arg_cong_rule: cterm -> thm -> thm
    98   val binop_cong_rule: cterm -> thm -> thm -> thm
    99   val fun_cong_rule: thm -> cterm -> thm
   100   val beta_eta_conversion: cterm -> thm
   101   val eta_long_conversion: cterm -> thm
   102   val eta_contraction_rule: thm -> thm
   103   val norm_hhf_eq: thm
   104   val is_norm_hhf: term -> bool
   105   val norm_hhf: theory -> term -> term
   106   val norm_hhf_cterm: cterm -> cterm
   107   val protect: cterm -> cterm
   108   val protectI: thm
   109   val protectD: thm
   110   val protect_cong: thm
   111   val implies_intr_protected: cterm list -> thm -> thm
   112   val termI: thm
   113   val mk_term: cterm -> thm
   114   val dest_term: thm -> cterm
   115   val cterm_rule: (thm -> thm) -> cterm -> cterm
   116   val term_rule: theory -> (thm -> thm) -> term -> term
   117   val dummy_thm: thm
   118   val sort_triv: theory -> typ * sort -> thm list
   119   val unconstrainTs: thm -> thm
   120   val with_subgoal: int -> (thm -> thm) -> thm -> thm
   121   val rename_bvars: (string * string) list -> thm -> thm
   122   val rename_bvars': string option list -> thm -> thm
   123   val incr_type_indexes: int -> thm -> thm
   124   val incr_indexes: thm -> thm -> thm
   125   val incr_indexes2: thm -> thm -> thm -> thm
   126   val remdups_rl: thm
   127   val multi_resolve: thm list -> thm -> thm Seq.seq
   128   val multi_resolves: thm list -> thm list -> thm Seq.seq
   129   val abs_def: thm -> thm
   130   val read_instantiate_sg': theory -> (indexname * string) list -> thm -> thm
   131   val read_instantiate': (indexname * string) list -> thm -> thm
   132 end;
   133 
   134 structure Drule: DRULE =
   135 struct
   136 
   137 
   138 (** some cterm->cterm operations: faster than calling cterm_of! **)
   139 
   140 (* A1==>...An==>B  goes to  [A1,...,An], where B is not an implication *)
   141 fun strip_imp_prems ct =
   142   let val (cA, cB) = Thm.dest_implies ct
   143   in cA :: strip_imp_prems cB end
   144   handle TERM _ => [];
   145 
   146 (* A1==>...An==>B  goes to B, where B is not an implication *)
   147 fun strip_imp_concl ct =
   148   (case Thm.term_of ct of
   149     Const ("==>", _) $ _ $ _ => strip_imp_concl (Thm.dest_arg ct)
   150   | _ => ct);
   151 
   152 (*The premises of a theorem, as a cterm list*)
   153 val cprems_of = strip_imp_prems o cprop_of;
   154 
   155 fun cterm_fun f ct =
   156   let val {t, thy, ...} = Thm.rep_cterm ct
   157   in Thm.cterm_of thy (f t) end;
   158 
   159 fun ctyp_fun f cT =
   160   let val {T, thy, ...} = Thm.rep_ctyp cT
   161   in Thm.ctyp_of thy (f T) end;
   162 
   163 val cert = cterm_of ProtoPure.thy;
   164 
   165 val implies = cert Term.implies;
   166 fun mk_implies (A, B) = Thm.capply (Thm.capply implies A) B;
   167 
   168 (*cterm version of list_implies: [A1,...,An], B  goes to [|A1;==>;An|]==>B *)
   169 fun list_implies([], B) = B
   170   | list_implies(A::AS, B) = mk_implies (A, list_implies(AS,B));
   171 
   172 (*cterm version of list_comb: maps  (f, [t1,...,tn])  to  f(t1,...,tn) *)
   173 fun list_comb (f, []) = f
   174   | list_comb (f, t::ts) = list_comb (Thm.capply f t, ts);
   175 
   176 (*cterm version of strip_comb: maps  f(t1,...,tn)  to  (f, [t1,...,tn]) *)
   177 fun strip_comb ct =
   178   let
   179     fun stripc (p as (ct, cts)) =
   180       let val (ct1, ct2) = Thm.dest_comb ct
   181       in stripc (ct1, ct2 :: cts) end handle CTERM _ => p
   182   in stripc (ct, []) end;
   183 
   184 (* cterm version of strip_type: maps  [T1,...,Tn]--->T  to   ([T1,T2,...,Tn], T) *)
   185 fun strip_type cT = (case Thm.typ_of cT of
   186     Type ("fun", _) =>
   187       let
   188         val [cT1, cT2] = Thm.dest_ctyp cT;
   189         val (cTs, cT') = strip_type cT2
   190       in (cT1 :: cTs, cT') end
   191   | _ => ([], cT));
   192 
   193 (*Beta-conversion for cterms, where x is an abstraction. Simply returns the rhs
   194   of the meta-equality returned by the beta_conversion rule.*)
   195 fun beta_conv x y =
   196   Thm.dest_arg (cprop_of (Thm.beta_conversion false (Thm.capply x y)));
   197 
   198 
   199 
   200 (** reading of instantiations **)
   201 
   202 fun absent ixn =
   203   error("No such variable in term: " ^ Term.string_of_vname ixn);
   204 
   205 fun inst_failure ixn =
   206   error("Instantiation of " ^ Term.string_of_vname ixn ^ " fails");
   207 
   208 fun read_insts thy (rtypes,rsorts) (types,sorts) used insts =
   209 let
   210     fun is_tv ((a, _), _) =
   211       (case Symbol.explode a of "'" :: _ => true | _ => false);
   212     val (tvs, vs) = List.partition is_tv insts;
   213     fun sort_of ixn = case rsorts ixn of SOME S => S | NONE => absent ixn;
   214     fun readT (ixn, st) =
   215         let val S = sort_of ixn;
   216             val T = Sign.read_def_typ (thy,sorts) st;
   217         in if Sign.typ_instance thy (T, TVar(ixn,S)) then (ixn,T)
   218            else inst_failure ixn
   219         end
   220     val tye = map readT tvs;
   221     fun mkty(ixn,st) = (case rtypes ixn of
   222                           SOME T => (ixn,(st,typ_subst_TVars tye T))
   223                         | NONE => absent ixn);
   224     val ixnsTs = map mkty vs;
   225     val ixns = map fst ixnsTs
   226     and sTs  = map snd ixnsTs
   227     val (cts,tye2) = Thm.read_def_cterms(thy,types,sorts) used false sTs;
   228     fun mkcVar(ixn,T) =
   229         let val U = typ_subst_TVars tye2 T
   230         in cterm_of thy (Var(ixn,U)) end
   231     val ixnTs = ListPair.zip(ixns, map snd sTs)
   232 in (map (fn (ixn, T) => (ctyp_of thy (TVar (ixn, sort_of ixn)),
   233       ctyp_of thy T)) (tye2 @ tye),
   234     ListPair.zip(map mkcVar ixnTs,cts))
   235 end;
   236 
   237 
   238 (*** Find the type (sort) associated with a (T)Var or (T)Free in a term
   239      Used for establishing default types (of variables) and sorts (of
   240      type variables) when reading another term.
   241      Index -1 indicates that a (T)Free rather than a (T)Var is wanted.
   242 ***)
   243 
   244 fun types_sorts thm =
   245   let
   246     val vars = Thm.fold_terms Term.add_vars thm [];
   247     val frees = Thm.fold_terms Term.add_frees thm [];
   248     val tvars = Thm.fold_terms Term.add_tvars thm [];
   249     val tfrees = Thm.fold_terms Term.add_tfrees thm [];
   250     fun types (a, i) =
   251       if i < 0 then AList.lookup (op =) frees a else AList.lookup (op =) vars (a, i);
   252     fun sorts (a, i) =
   253       if i < 0 then AList.lookup (op =) tfrees a else AList.lookup (op =) tvars (a, i);
   254   in (types, sorts) end;
   255 
   256 val add_used =
   257   (Thm.fold_terms o fold_types o fold_atyps)
   258     (fn TFree (a, _) => insert (op =) a
   259       | TVar ((a, _), _) => insert (op =) a
   260       | _ => I);
   261 
   262 
   263 
   264 (** Standardization of rules **)
   265 
   266 (* type classes and sorts *)
   267 
   268 fun sort_triv thy (T, S) =
   269   let
   270     val certT = Thm.ctyp_of thy;
   271     val cT = certT T;
   272     fun class_triv c =
   273       Thm.class_triv thy c
   274       |> Thm.instantiate ([(certT (TVar ((Name.aT, 0), [c])), cT)], []);
   275   in map class_triv S end;
   276 
   277 fun unconstrainTs th =
   278   fold (Thm.unconstrainT o Thm.ctyp_of (Thm.theory_of_thm th) o TVar)
   279     (Thm.fold_terms Term.add_tvars th []) th;
   280 
   281 (*Generalization over a list of variables*)
   282 val forall_intr_list = fold_rev forall_intr;
   283 
   284 (*Generalization over all suitable Free variables*)
   285 fun forall_intr_frees th =
   286     let
   287       val {prop, hyps, tpairs, thy,...} = rep_thm th;
   288       val fixed = fold Term.add_frees (Thm.terms_of_tpairs tpairs @ hyps) [];
   289       val frees = Term.fold_aterms (fn Free v =>
   290         if member (op =) fixed v then I else insert (op =) v | _ => I) prop [];
   291     in fold (forall_intr o cterm_of thy o Free) frees th end;
   292 
   293 (*Generalization over Vars -- canonical order*)
   294 fun forall_intr_vars th =
   295   fold forall_intr
   296     (map (Thm.cterm_of (Thm.theory_of_thm th) o Var) (Thm.fold_terms Term.add_vars th [])) th;
   297 
   298 val forall_elim_var = PureThy.forall_elim_var;
   299 val forall_elim_vars = PureThy.forall_elim_vars;
   300 
   301 fun outer_params t =
   302   let val vs = Term.strip_all_vars t
   303   in Name.variant_list [] (map (Name.clean o #1) vs) ~~ map #2 vs end;
   304 
   305 (*generalize outermost parameters*)
   306 fun gen_all th =
   307   let
   308     val {thy, prop, maxidx, ...} = Thm.rep_thm th;
   309     val cert = Thm.cterm_of thy;
   310     fun elim (x, T) = Thm.forall_elim (cert (Var ((x, maxidx + 1), T)));
   311   in fold elim (outer_params prop) th end;
   312 
   313 (*lift vars wrt. outermost goal parameters
   314   -- reverses the effect of gen_all modulo higher-order unification*)
   315 fun lift_all goal th =
   316   let
   317     val thy = Theory.merge (Thm.theory_of_cterm goal, Thm.theory_of_thm th);
   318     val cert = Thm.cterm_of thy;
   319     val maxidx = Thm.maxidx_of th;
   320     val ps = outer_params (Thm.term_of goal)
   321       |> map (fn (x, T) => Var ((x, maxidx + 1), Logic.incr_tvar (maxidx + 1) T));
   322     val Ts = map Term.fastype_of ps;
   323     val inst = Thm.fold_terms Term.add_vars th [] |> map (fn (xi, T) =>
   324       (cert (Var (xi, T)), cert (Term.list_comb (Var (xi, Ts ---> T), ps))));
   325   in
   326     th |> Thm.instantiate ([], inst)
   327     |> fold_rev (Thm.forall_intr o cert) ps
   328   end;
   329 
   330 (*direct generalization*)
   331 fun generalize names th = Thm.generalize names (Thm.maxidx_of th + 1) th;
   332 
   333 (*specialization over a list of cterms*)
   334 val forall_elim_list = fold forall_elim;
   335 
   336 (*maps A1,...,An |- B  to  [| A1;...;An |] ==> B*)
   337 val implies_intr_list = fold_rev implies_intr;
   338 
   339 (*maps [| A1;...;An |] ==> B and [A1,...,An]  to  B*)
   340 fun implies_elim_list impth ths = fold Thm.elim_implies ths impth;
   341 
   342 (*Reset Var indexes to zero, renaming to preserve distinctness*)
   343 fun zero_var_indexes_list [] = []
   344   | zero_var_indexes_list ths =
   345       let
   346         val thy = Theory.merge_list (map Thm.theory_of_thm ths);
   347         val certT = Thm.ctyp_of thy and cert = Thm.cterm_of thy;
   348         val (instT, inst) = TermSubst.zero_var_indexes_inst (map Thm.full_prop_of ths);
   349         val cinstT = map (fn (v, T) => (certT (TVar v), certT T)) instT;
   350         val cinst = map (fn (v, t) => (cert (Var v), cert t)) inst;
   351       in map (Thm.adjust_maxidx_thm ~1 o Thm.instantiate (cinstT, cinst)) ths end;
   352 
   353 val zero_var_indexes = singleton zero_var_indexes_list;
   354 
   355 
   356 (** Standard form of object-rule: no hypotheses, flexflex constraints,
   357     Frees, or outer quantifiers; all generality expressed by Vars of index 0.**)
   358 
   359 (*Discharge all hypotheses.*)
   360 fun implies_intr_hyps th =
   361   fold Thm.implies_intr (#hyps (Thm.crep_thm th)) th;
   362 
   363 (*Squash a theorem's flexflex constraints provided it can be done uniquely.
   364   This step can lose information.*)
   365 fun flexflex_unique th =
   366   if null (tpairs_of th) then th else
   367     case distinct Thm.eq_thm (Seq.list_of (flexflex_rule th)) of
   368       [th] => th
   369     | []   => raise THM("flexflex_unique: impossible constraints", 0, [th])
   370     |  _   => raise THM("flexflex_unique: multiple unifiers", 0, [th]);
   371 
   372 fun close_derivation thm =
   373   if Thm.get_name thm = "" then Thm.put_name "" thm
   374   else thm;
   375 
   376 
   377 (* legacy standard operations *)
   378 
   379 val standard' =
   380   implies_intr_hyps
   381   #> forall_intr_frees
   382   #> `Thm.maxidx_of
   383   #-> (fn maxidx =>
   384     forall_elim_vars (maxidx + 1)
   385     #> Thm.strip_shyps
   386     #> zero_var_indexes
   387     #> Thm.varifyT
   388     #> Thm.compress);
   389 
   390 val standard =
   391   flexflex_unique
   392   #> standard'
   393   #> close_derivation;
   394 
   395 
   396 (*Convert all Vars in a theorem to Frees.  Also return a function for
   397   reversing that operation.  DOES NOT WORK FOR TYPE VARIABLES.
   398   Similar code in type/freeze_thaw*)
   399 
   400 fun freeze_thaw_robust th =
   401  let val fth = Thm.freezeT th
   402      val {prop, tpairs, thy, ...} = rep_thm fth
   403  in
   404    case List.foldr add_term_vars [] (prop :: Thm.terms_of_tpairs tpairs) of
   405        [] => (fth, fn i => fn x => x)   (*No vars: nothing to do!*)
   406      | vars =>
   407          let fun newName (Var(ix,_)) = (ix, gensym (string_of_indexname ix))
   408              val alist = map newName vars
   409              fun mk_inst (Var(v,T)) =
   410                  (cterm_of thy (Var(v,T)),
   411                   cterm_of thy (Free(((the o AList.lookup (op =) alist) v), T)))
   412              val insts = map mk_inst vars
   413              fun thaw i th' = (*i is non-negative increment for Var indexes*)
   414                  th' |> forall_intr_list (map #2 insts)
   415                      |> forall_elim_list (map (Thm.incr_indexes_cterm i o #1) insts)
   416          in  (Thm.instantiate ([],insts) fth, thaw)  end
   417  end;
   418 
   419 (*Basic version of the function above. No option to rename Vars apart in thaw.
   420   The Frees created from Vars have nice names. FIXME: does not check for
   421   clashes with variables in the assumptions, so delete and use freeze_thaw_robust instead?*)
   422 fun freeze_thaw th =
   423  let val fth = Thm.freezeT th
   424      val {prop, tpairs, thy, ...} = rep_thm fth
   425  in
   426    case List.foldr add_term_vars [] (prop :: Thm.terms_of_tpairs tpairs) of
   427        [] => (fth, fn x => x)
   428      | vars =>
   429          let fun newName (Var(ix,_), (pairs,used)) =
   430                    let val v = Name.variant used (string_of_indexname ix)
   431                    in  ((ix,v)::pairs, v::used)  end;
   432              val (alist, _) = List.foldr newName ([], Library.foldr add_term_names
   433                (prop :: Thm.terms_of_tpairs tpairs, [])) vars
   434              fun mk_inst (Var(v,T)) =
   435                  (cterm_of thy (Var(v,T)),
   436                   cterm_of thy (Free(((the o AList.lookup (op =) alist) v), T)))
   437              val insts = map mk_inst vars
   438              fun thaw th' =
   439                  th' |> forall_intr_list (map #2 insts)
   440                      |> forall_elim_list (map #1 insts)
   441          in  (Thm.instantiate ([],insts) fth, thaw)  end
   442  end;
   443 
   444 (*Rotates a rule's premises to the left by k*)
   445 fun rotate_prems 0 = I
   446   | rotate_prems k = permute_prems 0 k;
   447 
   448 fun with_subgoal i f = rotate_prems (i - 1) #> f #> rotate_prems (1 - i);
   449 
   450 (* permute prems, where the i-th position in the argument list (counting from 0)
   451    gives the position within the original thm to be transferred to position i.
   452    Any remaining trailing positions are left unchanged. *)
   453 val rearrange_prems = let
   454   fun rearr new []      thm = thm
   455   |   rearr new (p::ps) thm = rearr (new+1)
   456      (map (fn q => if new<=q andalso q<p then q+1 else q) ps)
   457      (permute_prems (new+1) (new-p) (permute_prems new (p-new) thm))
   458   in rearr 0 end;
   459 
   460 (*Resolution: exactly one resolvent must be produced.*)
   461 fun tha RSN (i,thb) =
   462   case Seq.chop 2 (biresolution false [(false,tha)] i thb) of
   463       ([th],_) => th
   464     | ([],_)   => raise THM("RSN: no unifiers", i, [tha,thb])
   465     |      _   => raise THM("RSN: multiple unifiers", i, [tha,thb]);
   466 
   467 (*resolution: P==>Q, Q==>R gives P==>R. *)
   468 fun tha RS thb = tha RSN (1,thb);
   469 
   470 (*For joining lists of rules*)
   471 fun thas RLN (i,thbs) =
   472   let val resolve = biresolution false (map (pair false) thas) i
   473       fun resb thb = Seq.list_of (resolve thb) handle THM _ => []
   474   in maps resb thbs end;
   475 
   476 fun thas RL thbs = thas RLN (1,thbs);
   477 
   478 (*Resolve a list of rules against bottom_rl from right to left;
   479   makes proof trees*)
   480 fun rls MRS bottom_rl =
   481   let fun rs_aux i [] = bottom_rl
   482         | rs_aux i (rl::rls) = rl RSN (i, rs_aux (i+1) rls)
   483   in  rs_aux 1 rls  end;
   484 
   485 (*As above, but for rule lists*)
   486 fun rlss MRL bottom_rls =
   487   let fun rs_aux i [] = bottom_rls
   488         | rs_aux i (rls::rlss) = rls RLN (i, rs_aux (i+1) rlss)
   489   in  rs_aux 1 rlss  end;
   490 
   491 (*A version of MRS with more appropriate argument order*)
   492 fun bottom_rl OF rls = rls MRS bottom_rl;
   493 
   494 (*compose Q and [...,Qi,Q(i+1),...]==>R to [...,Q(i+1),...]==>R
   495   with no lifting or renaming!  Q may contain ==> or meta-quants
   496   ALWAYS deletes premise i *)
   497 fun compose(tha,i,thb) =
   498     distinct Thm.eq_thm (Seq.list_of (bicompose false (false,tha,0) i thb));
   499 
   500 fun compose_single (tha,i,thb) =
   501   case compose (tha,i,thb) of
   502     [th] => th
   503   | _ => raise THM ("compose: unique result expected", i, [tha,thb]);
   504 
   505 (*compose Q and [Q1,Q2,...,Qk]==>R to [Q2,...,Qk]==>R getting unique result*)
   506 fun tha COMP thb =
   507     case compose(tha,1,thb) of
   508         [th] => th
   509       | _ =>   raise THM("COMP", 1, [tha,thb]);
   510 
   511 
   512 (** theorem equality **)
   513 
   514 (*Useful "distance" function for BEST_FIRST*)
   515 val size_of_thm = size_of_term o Thm.full_prop_of;
   516 
   517 
   518 
   519 (*** Meta-Rewriting Rules ***)
   520 
   521 val read_prop = Thm.cterm_of ProtoPure.thy o SimpleSyntax.read_prop;
   522 
   523 fun store_thm name thm = hd (PureThy.smart_store_thms (name, [thm]));
   524 fun store_standard_thm name thm = store_thm name (standard thm);
   525 fun store_thm_open name thm = hd (PureThy.smart_store_thms_open (name, [thm]));
   526 fun store_standard_thm_open name thm = store_thm_open name (standard' thm);
   527 
   528 val reflexive_thm =
   529   let val cx = cert (Var(("x",0),TVar(("'a",0),[])))
   530   in store_standard_thm_open "reflexive" (Thm.reflexive cx) end;
   531 
   532 val symmetric_thm =
   533   let val xy = read_prop "x::'a == y::'a"
   534   in store_standard_thm_open "symmetric" (Thm.implies_intr xy (Thm.symmetric (Thm.assume xy))) end;
   535 
   536 val transitive_thm =
   537   let val xy = read_prop "x::'a == y::'a"
   538       val yz = read_prop "y::'a == z::'a"
   539       val xythm = Thm.assume xy and yzthm = Thm.assume yz
   540   in store_standard_thm_open "transitive" (Thm.implies_intr yz (Thm.transitive xythm yzthm)) end;
   541 
   542 fun symmetric_fun thm = thm RS symmetric_thm;
   543 
   544 fun extensional eq =
   545   let val eq' =
   546     abstract_rule "x" (Thm.dest_arg (fst (Thm.dest_equals (cprop_of eq)))) eq
   547   in equal_elim (eta_conversion (cprop_of eq')) eq' end;
   548 
   549 val equals_cong =
   550   store_standard_thm_open "equals_cong" (Thm.reflexive (read_prop "x::'a == y::'a"));
   551 
   552 val imp_cong =
   553   let
   554     val ABC = read_prop "A ==> B::prop == C::prop"
   555     val AB = read_prop "A ==> B"
   556     val AC = read_prop "A ==> C"
   557     val A = read_prop "A"
   558   in
   559     store_standard_thm_open "imp_cong" (implies_intr ABC (equal_intr
   560       (implies_intr AB (implies_intr A
   561         (equal_elim (implies_elim (assume ABC) (assume A))
   562           (implies_elim (assume AB) (assume A)))))
   563       (implies_intr AC (implies_intr A
   564         (equal_elim (symmetric (implies_elim (assume ABC) (assume A)))
   565           (implies_elim (assume AC) (assume A)))))))
   566   end;
   567 
   568 val swap_prems_eq =
   569   let
   570     val ABC = read_prop "A ==> B ==> C"
   571     val BAC = read_prop "B ==> A ==> C"
   572     val A = read_prop "A"
   573     val B = read_prop "B"
   574   in
   575     store_standard_thm_open "swap_prems_eq" (equal_intr
   576       (implies_intr ABC (implies_intr B (implies_intr A
   577         (implies_elim (implies_elim (assume ABC) (assume A)) (assume B)))))
   578       (implies_intr BAC (implies_intr A (implies_intr B
   579         (implies_elim (implies_elim (assume BAC) (assume B)) (assume A))))))
   580   end;
   581 
   582 val imp_cong_rule = Thm.combination o Thm.combination (Thm.reflexive implies);
   583 
   584 fun arg_cong_rule ct th = Thm.combination (Thm.reflexive ct) th;    (*AP_TERM in LCF/HOL*)
   585 fun fun_cong_rule th ct = Thm.combination th (Thm.reflexive ct);    (*AP_THM in LCF/HOL*)
   586 fun binop_cong_rule ct th1 th2 = Thm.combination (arg_cong_rule ct th1) th2;
   587 
   588 local
   589   val dest_eq = Thm.dest_equals o cprop_of
   590   val rhs_of = snd o dest_eq
   591 in
   592 fun beta_eta_conversion t =
   593   let val thm = beta_conversion true t
   594   in transitive thm (eta_conversion (rhs_of thm)) end
   595 end;
   596 
   597 fun eta_long_conversion ct = transitive (beta_eta_conversion ct)
   598   (symmetric (beta_eta_conversion (cterm_fun (Pattern.eta_long []) ct)));
   599 
   600 (*Contract all eta-redexes in the theorem, lest they give rise to needless abstractions*)
   601 fun eta_contraction_rule th =
   602   equal_elim (eta_conversion (cprop_of th)) th;
   603 
   604 
   605 (* abs_def *)
   606 
   607 (*
   608    f ?x1 ... ?xn == u
   609   --------------------
   610    f == %x1 ... xn. u
   611 *)
   612 
   613 local
   614 
   615 fun contract_lhs th =
   616   Thm.transitive (Thm.symmetric (beta_eta_conversion
   617     (fst (Thm.dest_equals (cprop_of th))))) th;
   618 
   619 fun var_args ct =
   620   (case try Thm.dest_comb ct of
   621     SOME (f, arg) =>
   622       (case Thm.term_of arg of
   623         Var ((x, _), _) => update (eq_snd (op aconvc)) (x, arg) (var_args f)
   624       | _ => [])
   625   | NONE => []);
   626 
   627 in
   628 
   629 fun abs_def th =
   630   let
   631     val th' = contract_lhs th;
   632     val args = var_args (Thm.lhs_of th');
   633   in contract_lhs (fold (uncurry Thm.abstract_rule) args th') end;
   634 
   635 end;
   636 
   637 
   638 
   639 (*** Some useful meta-theorems ***)
   640 
   641 (*The rule V/V, obtains assumption solving for eresolve_tac*)
   642 val asm_rl = store_standard_thm_open "asm_rl" (Thm.trivial (read_prop "?psi"));
   643 val _ = store_thm "_" asm_rl;
   644 
   645 (*Meta-level cut rule: [| V==>W; V |] ==> W *)
   646 val cut_rl =
   647   store_standard_thm_open "cut_rl"
   648     (Thm.trivial (read_prop "?psi ==> ?theta"));
   649 
   650 (*Generalized elim rule for one conclusion; cut_rl with reversed premises:
   651      [| PROP V;  PROP V ==> PROP W |] ==> PROP W *)
   652 val revcut_rl =
   653   let val V = read_prop "V"
   654       and VW = read_prop "V ==> W";
   655   in
   656     store_standard_thm_open "revcut_rl"
   657       (implies_intr V (implies_intr VW (implies_elim (assume VW) (assume V))))
   658   end;
   659 
   660 (*for deleting an unwanted assumption*)
   661 val thin_rl =
   662   let val V = read_prop "V"
   663       and W = read_prop "W";
   664   in store_standard_thm_open "thin_rl" (implies_intr V (implies_intr W (assume W))) end;
   665 
   666 (* (!!x. PROP ?V) == PROP ?V       Allows removal of redundant parameters*)
   667 val triv_forall_equality =
   668   let val V  = read_prop "V"
   669       and QV = read_prop "!!x::'a. V"
   670       and x  = cert (Free ("x", Term.aT []));
   671   in
   672     store_standard_thm_open "triv_forall_equality"
   673       (equal_intr (implies_intr QV (forall_elim x (assume QV)))
   674         (implies_intr V  (forall_intr x (assume V))))
   675   end;
   676 
   677 (* (PROP ?Phi ==> PROP ?Phi ==> PROP ?Psi) ==>
   678    (PROP ?Phi ==> PROP ?Psi)
   679 *)
   680 val distinct_prems_rl =
   681   let
   682     val AAB = read_prop "Phi ==> Phi ==> Psi"
   683     val A = read_prop "Phi";
   684   in
   685     store_standard_thm_open "distinct_prems_rl"
   686       (implies_intr_list [AAB, A] (implies_elim_list (assume AAB) [assume A, assume A]))
   687   end;
   688 
   689 (* (PROP ?PhiA ==> PROP ?PhiB ==> PROP ?Psi) ==>
   690    (PROP ?PhiB ==> PROP ?PhiA ==> PROP ?Psi)
   691    `thm COMP swap_prems_rl' swaps the first two premises of `thm'
   692 *)
   693 val swap_prems_rl =
   694   let val cmajor = read_prop "PhiA ==> PhiB ==> Psi";
   695       val major = assume cmajor;
   696       val cminor1 = read_prop "PhiA";
   697       val minor1 = assume cminor1;
   698       val cminor2 = read_prop "PhiB";
   699       val minor2 = assume cminor2;
   700   in store_standard_thm_open "swap_prems_rl"
   701        (implies_intr cmajor (implies_intr cminor2 (implies_intr cminor1
   702          (implies_elim (implies_elim major minor1) minor2))))
   703   end;
   704 
   705 (* [| PROP ?phi ==> PROP ?psi; PROP ?psi ==> PROP ?phi |]
   706    ==> PROP ?phi == PROP ?psi
   707    Introduction rule for == as a meta-theorem.
   708 *)
   709 val equal_intr_rule =
   710   let val PQ = read_prop "phi ==> psi"
   711       and QP = read_prop "psi ==> phi"
   712   in
   713     store_standard_thm_open "equal_intr_rule"
   714       (implies_intr PQ (implies_intr QP (equal_intr (assume PQ) (assume QP))))
   715   end;
   716 
   717 (* PROP ?phi == PROP ?psi ==> PROP ?phi ==> PROP ?psi *)
   718 val equal_elim_rule1 =
   719   let val eq = read_prop "phi::prop == psi::prop"
   720       and P = read_prop "phi"
   721   in store_standard_thm_open "equal_elim_rule1"
   722     (Thm.equal_elim (assume eq) (assume P) |> implies_intr_list [eq, P])
   723   end;
   724 
   725 (* PROP ?psi == PROP ?phi ==> PROP ?phi ==> PROP ?psi *)
   726 val equal_elim_rule2 =
   727   store_standard_thm_open "equal_elim_rule2" (symmetric_thm RS equal_elim_rule1);
   728 
   729 (* "[| PROP ?phi; PROP ?phi; PROP ?psi |] ==> PROP ?psi" *)
   730 val remdups_rl =
   731   let val P = read_prop "phi" and Q = read_prop "psi";
   732   in store_standard_thm_open "remdups_rl" (implies_intr_list [P, P, Q] (Thm.assume Q)) end;
   733 
   734 
   735 (*(PROP ?phi ==> (!!x. PROP ?psi(x))) == (!!x. PROP ?phi ==> PROP ?psi(x))
   736   Rewrite rule for HHF normalization.*)
   737 
   738 val norm_hhf_eq =
   739   let
   740     val aT = TFree ("'a", []);
   741     val all = Term.all aT;
   742     val x = Free ("x", aT);
   743     val phi = Free ("phi", propT);
   744     val psi = Free ("psi", aT --> propT);
   745 
   746     val cx = cert x;
   747     val cphi = cert phi;
   748     val lhs = cert (Logic.mk_implies (phi, all $ Abs ("x", aT, psi $ Bound 0)));
   749     val rhs = cert (all $ Abs ("x", aT, Logic.mk_implies (phi, psi $ Bound 0)));
   750   in
   751     Thm.equal_intr
   752       (Thm.implies_elim (Thm.assume lhs) (Thm.assume cphi)
   753         |> Thm.forall_elim cx
   754         |> Thm.implies_intr cphi
   755         |> Thm.forall_intr cx
   756         |> Thm.implies_intr lhs)
   757       (Thm.implies_elim
   758           (Thm.assume rhs |> Thm.forall_elim cx) (Thm.assume cphi)
   759         |> Thm.forall_intr cx
   760         |> Thm.implies_intr cphi
   761         |> Thm.implies_intr rhs)
   762     |> store_standard_thm_open "norm_hhf_eq"
   763   end;
   764 
   765 val norm_hhf_prop = Logic.dest_equals (Thm.prop_of norm_hhf_eq);
   766 
   767 fun is_norm_hhf tm =
   768   let
   769     fun is_norm (Const ("==>", _) $ _ $ (Const ("all", _) $ _)) = false
   770       | is_norm (t $ u) = is_norm t andalso is_norm u
   771       | is_norm (Abs (_, _, t)) = is_norm t
   772       | is_norm _ = true;
   773   in is_norm (Envir.beta_eta_contract tm) end;
   774 
   775 fun norm_hhf thy t =
   776   if is_norm_hhf t then t
   777   else Pattern.rewrite_term thy [norm_hhf_prop] [] t;
   778 
   779 fun norm_hhf_cterm ct =
   780   if is_norm_hhf (Thm.term_of ct) then ct
   781   else cterm_fun (Pattern.rewrite_term (Thm.theory_of_cterm ct) [norm_hhf_prop] []) ct;
   782 
   783 
   784 (* var indexes *)
   785 
   786 (*Increment the indexes of only the type variables*)
   787 fun incr_type_indexes inc th =
   788   let val tvs = term_tvars (prop_of th)
   789       and thy = theory_of_thm th
   790       fun inc_tvar ((a,i),s) = pairself (ctyp_of thy) (TVar ((a,i),s), TVar ((a,i+inc),s))
   791   in Thm.instantiate (map inc_tvar tvs, []) th end;
   792 
   793 fun incr_indexes th = Thm.incr_indexes (Thm.maxidx_of th + 1);
   794 
   795 fun incr_indexes2 th1 th2 =
   796   Thm.incr_indexes (Int.max (Thm.maxidx_of th1, Thm.maxidx_of th2) + 1);
   797 
   798 fun th1 INCR_COMP th2 = incr_indexes th2 th1 COMP th2;
   799 fun th1 COMP_INCR th2 = th1 COMP incr_indexes th1 th2;
   800 
   801 
   802 (*** Instantiate theorem th, reading instantiations in theory thy ****)
   803 
   804 (*Version that normalizes the result: Thm.instantiate no longer does that*)
   805 fun instantiate instpair th =
   806   Thm.adjust_maxidx_thm ~1 (Thm.instantiate instpair th COMP_INCR asm_rl);
   807 
   808 fun read_instantiate_sg' thy sinsts th =
   809     let val ts = types_sorts th;
   810         val used = add_used th [];
   811     in  instantiate (read_insts thy ts ts used sinsts) th  end;
   812 
   813 fun read_instantiate_sg thy sinsts th =
   814   read_instantiate_sg' thy (map (apfst Syntax.read_indexname) sinsts) th;
   815 
   816 (*Instantiate theorem th, reading instantiations under theory of th*)
   817 fun read_instantiate sinsts th =
   818     read_instantiate_sg (Thm.theory_of_thm th) sinsts th;
   819 
   820 fun read_instantiate' sinsts th =
   821     read_instantiate_sg' (Thm.theory_of_thm th) sinsts th;
   822 
   823 
   824 (*Left-to-right replacements: tpairs = [...,(vi,ti),...].
   825   Instantiates distinct Vars by terms, inferring type instantiations. *)
   826 local
   827   fun add_types ((ct,cu), (thy,tye,maxidx)) =
   828     let val {thy=thyt, t=t, T= T, maxidx=maxt,...} = rep_cterm ct
   829         and {thy=thyu, t=u, T= U, maxidx=maxu,...} = rep_cterm cu;
   830         val maxi = Int.max(maxidx, Int.max(maxt, maxu));
   831         val thy' = Theory.merge(thy, Theory.merge(thyt, thyu))
   832         val (tye',maxi') = Sign.typ_unify thy' (T, U) (tye, maxi)
   833           handle Type.TUNIFY => raise TYPE ("Ill-typed instantiation:\nType\n" ^
   834             Sign.string_of_typ thy' (Envir.norm_type tye T) ^
   835             "\nof variable " ^
   836             Sign.string_of_term thy' (Term.map_types (Envir.norm_type tye) t) ^
   837             "\ncannot be unified with type\n" ^
   838             Sign.string_of_typ thy' (Envir.norm_type tye U) ^ "\nof term " ^
   839             Sign.string_of_term thy' (Term.map_types (Envir.norm_type tye) u),
   840             [T, U], [t, u])
   841     in  (thy', tye', maxi')  end;
   842 in
   843 fun cterm_instantiate [] th = th
   844   | cterm_instantiate ctpairs0 th =
   845   let val (thy,tye,_) = List.foldr add_types (Thm.theory_of_thm th, Vartab.empty, 0) ctpairs0
   846       fun instT(ct,cu) =
   847         let val inst = cterm_of thy o Term.map_types (Envir.norm_type tye) o term_of
   848         in (inst ct, inst cu) end
   849       fun ctyp2 (ixn, (S, T)) = (ctyp_of thy (TVar (ixn, S)), ctyp_of thy (Envir.norm_type tye T))
   850   in  instantiate (map ctyp2 (Vartab.dest tye), map instT ctpairs0) th  end
   851   handle TERM _ =>
   852            raise THM("cterm_instantiate: incompatible theories",0,[th])
   853        | TYPE (msg, _, _) => raise THM(msg, 0, [th])
   854 end;
   855 
   856 
   857 (** protected propositions and embedded terms **)
   858 
   859 local
   860   val A = cert (Free ("A", propT));
   861   val prop_def = Thm.unvarify ProtoPure.prop_def;
   862   val term_def = Thm.unvarify ProtoPure.term_def;
   863 in
   864   val protect = Thm.capply (cert Logic.protectC);
   865   val protectI = store_thm "protectI" (PureThy.kind_rule Thm.internalK (standard
   866       (Thm.equal_elim (Thm.symmetric prop_def) (Thm.assume A))));
   867   val protectD = store_thm "protectD" (PureThy.kind_rule Thm.internalK (standard
   868       (Thm.equal_elim prop_def (Thm.assume (protect A)))));
   869   val protect_cong = store_standard_thm_open "protect_cong" (Thm.reflexive (protect A));
   870 
   871   val termI = store_thm "termI" (PureThy.kind_rule Thm.internalK (standard
   872       (Thm.equal_elim (Thm.symmetric term_def) (Thm.forall_intr A (Thm.trivial A)))));
   873 end;
   874 
   875 fun implies_intr_protected asms th =
   876   let val asms' = map protect asms in
   877     implies_elim_list
   878       (implies_intr_list asms th)
   879       (map (fn asm' => Thm.assume asm' RS protectD) asms')
   880     |> implies_intr_list asms'
   881   end;
   882 
   883 fun mk_term ct =
   884   let
   885     val {thy, T, ...} = Thm.rep_cterm ct;
   886     val cert = Thm.cterm_of thy;
   887     val certT = Thm.ctyp_of thy;
   888     val a = certT (TVar (("'a", 0), []));
   889     val x = cert (Var (("x", 0), T));
   890   in Thm.instantiate ([(a, certT T)], [(x, ct)]) termI end;
   891 
   892 fun dest_term th =
   893   let val cprop = strip_imp_concl (Thm.cprop_of th) in
   894     if can Logic.dest_term (Thm.term_of cprop) then
   895       Thm.dest_arg cprop
   896     else raise THM ("dest_term", 0, [th])
   897   end;
   898 
   899 fun cterm_rule f = dest_term o f o mk_term;
   900 fun term_rule thy f t = Thm.term_of (cterm_rule f (Thm.cterm_of thy t));
   901 
   902 val dummy_thm = mk_term (Thm.cterm_of ProtoPure.thy (Term.dummy_pattern propT));
   903 
   904 
   905 
   906 (** variations on instantiate **)
   907 
   908 (* instantiate by left-to-right occurrence of variables *)
   909 
   910 fun instantiate' cTs cts thm =
   911   let
   912     fun err msg =
   913       raise TYPE ("instantiate': " ^ msg,
   914         map_filter (Option.map Thm.typ_of) cTs,
   915         map_filter (Option.map Thm.term_of) cts);
   916 
   917     fun inst_of (v, ct) =
   918       (Thm.cterm_of (Thm.theory_of_cterm ct) (Var v), ct)
   919         handle TYPE (msg, _, _) => err msg;
   920 
   921     fun tyinst_of (v, cT) =
   922       (Thm.ctyp_of (Thm.theory_of_ctyp cT) (TVar v), cT)
   923         handle TYPE (msg, _, _) => err msg;
   924 
   925     fun zip_vars xs ys =
   926       zip_options xs ys handle Library.UnequalLengths =>
   927         err "more instantiations than variables in thm";
   928 
   929     (*instantiate types first!*)
   930     val thm' =
   931       if forall is_none cTs then thm
   932       else Thm.instantiate
   933         (map tyinst_of (zip_vars (rev (Thm.fold_terms Term.add_tvars thm [])) cTs), []) thm;
   934     val thm'' =
   935       if forall is_none cts then thm'
   936       else Thm.instantiate
   937         ([], map inst_of (zip_vars (rev (Thm.fold_terms Term.add_vars thm' [])) cts)) thm';
   938     in thm'' end;
   939 
   940 
   941 
   942 (** renaming of bound variables **)
   943 
   944 (* replace bound variables x_i in thm by y_i *)
   945 (* where vs = [(x_1, y_1), ..., (x_n, y_n)]  *)
   946 
   947 fun rename_bvars [] thm = thm
   948   | rename_bvars vs thm =
   949     let
   950       val {thy, prop, ...} = rep_thm thm;
   951       fun ren (Abs (x, T, t)) = Abs (AList.lookup (op =) vs x |> the_default x, T, ren t)
   952         | ren (t $ u) = ren t $ ren u
   953         | ren t = t;
   954     in equal_elim (reflexive (cterm_of thy (ren prop))) thm end;
   955 
   956 
   957 (* renaming in left-to-right order *)
   958 
   959 fun rename_bvars' xs thm =
   960   let
   961     val {thy, prop, ...} = rep_thm thm;
   962     fun rename [] t = ([], t)
   963       | rename (x' :: xs) (Abs (x, T, t)) =
   964           let val (xs', t') = rename xs t
   965           in (xs', Abs (the_default x x', T, t')) end
   966       | rename xs (t $ u) =
   967           let
   968             val (xs', t') = rename xs t;
   969             val (xs'', u') = rename xs' u
   970           in (xs'', t' $ u') end
   971       | rename xs t = (xs, t);
   972   in case rename xs prop of
   973       ([], prop') => equal_elim (reflexive (cterm_of thy prop')) thm
   974     | _ => error "More names than abstractions in theorem"
   975   end;
   976 
   977 
   978 
   979 (** multi_resolve **)
   980 
   981 local
   982 
   983 fun res th i rule =
   984   Thm.biresolution false [(false, th)] i rule handle THM _ => Seq.empty;
   985 
   986 fun multi_res _ [] rule = Seq.single rule
   987   | multi_res i (th :: ths) rule = Seq.maps (res th i) (multi_res (i + 1) ths rule);
   988 
   989 in
   990 
   991 val multi_resolve = multi_res 1;
   992 fun multi_resolves facts rules = Seq.maps (multi_resolve facts) (Seq.of_list rules);
   993 
   994 end;
   995 
   996 end;
   997 
   998 structure BasicDrule: BASIC_DRULE = Drule;
   999 open BasicDrule;