src/Pure/theory.ML
author wenzelm
Wed Mar 26 22:40:03 2008 +0100 (2008-03-26)
changeset 26413 003dd6155870
parent 25059 e6e0ee56a672
child 26631 d6b6c74a8bcf
permissions -rw-r--r--
added thread data (formerly global ref in ML/ml_context.ML);
renamed ML_Context.>> to Context.>> (again);
     1 (*  Title:      Pure/theory.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson and Markus Wenzel
     4 
     5 Logical theory content: axioms, definitions, oracles.
     6 *)
     7 
     8 signature BASIC_THEORY =
     9 sig
    10   val eq_thy: theory * theory -> bool
    11   val subthy: theory * theory -> bool
    12 end
    13 
    14 signature THEORY =
    15 sig
    16   include BASIC_THEORY
    17   include SIGN_THEORY
    18   val assert_super: theory -> theory -> theory
    19   val parents_of: theory -> theory list
    20   val ancestors_of: theory -> theory list
    21   val check_thy: theory -> theory_ref
    22   val deref: theory_ref -> theory
    23   val merge: theory * theory -> theory
    24   val merge_refs: theory_ref * theory_ref -> theory_ref
    25   val merge_list: theory list -> theory
    26   val checkpoint: theory -> theory
    27   val copy: theory -> theory
    28   val requires: theory -> string -> string -> unit
    29   val axiom_space: theory -> NameSpace.T
    30   val axiom_table: theory -> term Symtab.table
    31   val oracle_space: theory -> NameSpace.T
    32   val oracle_table: theory -> ((theory * Object.T -> term) * stamp) Symtab.table
    33   val axioms_of: theory -> (string * term) list
    34   val all_axioms_of: theory -> (string * term) list
    35   val defs_of: theory -> Defs.T
    36   val at_begin: (theory -> theory option) -> theory -> theory
    37   val at_end: (theory -> theory option) -> theory -> theory
    38   val begin_theory: string -> theory list -> theory
    39   val end_theory: theory -> theory
    40   val add_axioms: (bstring * string) list -> theory -> theory
    41   val add_axioms_i: (bstring * term) list -> theory -> theory
    42   val add_deps: string -> string * typ -> (string * typ) list -> theory -> theory
    43   val add_defs: bool -> bool -> (bstring * string) list -> theory -> theory
    44   val add_defs_i: bool -> bool -> (bstring * term) list -> theory -> theory
    45   val add_finals: bool -> string list -> theory -> theory
    46   val add_finals_i: bool -> term list -> theory -> theory
    47   val specify_const: Markup.property list -> bstring * typ * mixfix -> (string * typ) list ->
    48    theory -> term * theory
    49   val add_oracle: bstring * (theory * Object.T -> term) -> theory -> theory
    50 end
    51 
    52 structure Theory: THEORY =
    53 struct
    54 
    55 
    56 (** theory context operations **)
    57 
    58 val eq_thy = Context.eq_thy;
    59 val subthy = Context.subthy;
    60 
    61 fun assert_super thy1 thy2 =
    62   if subthy (thy1, thy2) then thy2
    63   else raise THEORY ("Not a super theory", [thy1, thy2]);
    64 
    65 val parents_of = Context.parents_of;
    66 val ancestors_of = Context.ancestors_of;
    67 
    68 val check_thy = Context.check_thy;
    69 val deref = Context.deref;
    70 
    71 val merge = Context.merge;
    72 val merge_refs = Context.merge_refs;
    73 
    74 fun merge_list [] = raise THEORY ("Empty merge of theories", [])
    75   | merge_list (thy :: thys) = Library.foldl merge (thy, thys);
    76 
    77 val checkpoint = Context.checkpoint_thy;
    78 val copy = Context.copy_thy;
    79 
    80 fun requires thy name what =
    81   if Context.exists_name name thy then ()
    82   else error ("Require theory " ^ quote name ^ " as an ancestor for " ^ what);
    83 
    84 
    85 
    86 (** datatype thy **)
    87 
    88 type wrapper = (theory -> theory option) * stamp;
    89 
    90 fun apply_wrappers (wrappers: wrapper list) =
    91   perhaps (perhaps_loop (perhaps_apply (map fst wrappers)));
    92 
    93 datatype thy = Thy of
    94  {axioms: term NameSpace.table,
    95   defs: Defs.T,
    96   oracles: ((theory * Object.T -> term) * stamp) NameSpace.table,
    97   wrappers: wrapper list * wrapper list};
    98 
    99 fun make_thy (axioms, defs, oracles, wrappers) =
   100   Thy {axioms = axioms, defs = defs, oracles = oracles, wrappers = wrappers};
   101 
   102 fun err_dup_axm dup = error ("Duplicate axiom: " ^ quote dup);
   103 fun err_dup_ora dup = error ("Duplicate oracle: " ^ quote dup);
   104 
   105 structure ThyData = TheoryDataFun
   106 (
   107   type T = thy;
   108   val empty = make_thy (NameSpace.empty_table, Defs.empty, NameSpace.empty_table, ([], []));
   109   val copy = I;
   110 
   111   fun extend (Thy {axioms, defs, oracles, wrappers}) =
   112     make_thy (NameSpace.empty_table, defs, oracles, wrappers);
   113 
   114   fun merge pp (thy1, thy2) =
   115     let
   116       val Thy {axioms = _, defs = defs1, oracles = oracles1, wrappers = (bgs1, ens1)} = thy1;
   117       val Thy {axioms = _, defs = defs2, oracles = oracles2, wrappers = (bgs2, ens2)} = thy2;
   118 
   119       val axioms' = NameSpace.empty_table;
   120       val defs' = Defs.merge pp (defs1, defs2);
   121       val oracles' = NameSpace.merge_tables (eq_snd (op =)) (oracles1, oracles2)
   122         handle Symtab.DUP dup => err_dup_ora dup;
   123       val bgs' = Library.merge (eq_snd op =) (bgs1, bgs2);
   124       val ens' = Library.merge (eq_snd op =) (ens1, ens2);
   125     in make_thy (axioms', defs', oracles', (bgs', ens')) end;
   126 );
   127 
   128 fun rep_theory thy = ThyData.get thy |> (fn Thy args => args);
   129 
   130 fun map_thy f = ThyData.map (fn (Thy {axioms, defs, oracles, wrappers}) =>
   131   make_thy (f (axioms, defs, oracles, wrappers)));
   132 
   133 
   134 fun map_axioms f = map_thy
   135   (fn (axioms, defs, oracles, wrappers) => (f axioms, defs, oracles, wrappers));
   136 
   137 fun map_defs f = map_thy
   138   (fn (axioms, defs, oracles, wrappers) => (axioms, f defs, oracles, wrappers));
   139 
   140 fun map_oracles f = map_thy
   141   (fn (axioms, defs, oracles, wrappers) => (axioms, defs, f oracles, wrappers));
   142 
   143 fun map_wrappers f = map_thy
   144   (fn (axioms, defs, oracles, wrappers) => (axioms, defs, oracles, f wrappers));
   145 
   146 
   147 (* basic operations *)
   148 
   149 val axiom_space = #1 o #axioms o rep_theory;
   150 val axiom_table = #2 o #axioms o rep_theory;
   151 
   152 val oracle_space = #1 o #oracles o rep_theory;
   153 val oracle_table = #2 o #oracles o rep_theory;
   154 
   155 val axioms_of = Symtab.dest o #2 o #axioms o rep_theory;
   156 fun all_axioms_of thy = maps axioms_of (thy :: ancestors_of thy);
   157 
   158 val defs_of = #defs o rep_theory;
   159 
   160 
   161 (* begin/end theory *)
   162 
   163 val begin_wrappers = rev o #1 o #wrappers o rep_theory;
   164 val end_wrappers = rev o #2 o #wrappers o rep_theory;
   165 
   166 fun at_begin f = map_wrappers (apfst (cons (f, stamp ())));
   167 fun at_end f = map_wrappers (apsnd (cons (f, stamp ())));
   168 
   169 fun begin_theory name imports =
   170   let
   171     val thy = Context.begin_thy Sign.pp name imports;
   172     val wrappers = begin_wrappers thy;
   173   in thy |> Sign.local_path |> apply_wrappers wrappers end;
   174 
   175 fun end_theory thy =
   176   thy |> apply_wrappers (end_wrappers thy) |> Context.finish_thy;
   177 
   178 
   179 (* signature operations *)
   180 
   181 structure SignTheory: SIGN_THEORY = Sign;
   182 open SignTheory;
   183 
   184 
   185 
   186 (** add axioms **)
   187 
   188 (* prepare axioms *)
   189 
   190 fun err_in_axm msg name =
   191   cat_error msg ("The error(s) above occurred in axiom " ^ quote name);
   192 
   193 fun cert_axm thy (name, raw_tm) =
   194   let
   195     val (t, T, _) = Sign.certify_prop thy raw_tm
   196       handle TYPE (msg, _, _) => error msg
   197         | TERM (msg, _) => error msg;
   198   in
   199     Term.no_dummy_patterns t handle TERM (msg, _) => error msg;
   200     (name, Sign.no_vars (Sign.pp thy) t)
   201   end;
   202 
   203 fun read_axm thy (name, str) =
   204   cert_axm thy (name, Syntax.read_prop_global thy str)
   205     handle ERROR msg => err_in_axm msg name;
   206 
   207 
   208 (* add_axioms(_i) *)
   209 
   210 local
   211 
   212 fun gen_add_axioms prep_axm raw_axms thy = thy |> map_axioms (fn axioms =>
   213   let
   214     val axms = map (apsnd (Compress.term thy o Logic.varify) o prep_axm thy) raw_axms;
   215     val axioms' = NameSpace.extend_table (Sign.naming_of thy) axms axioms
   216       handle Symtab.DUP dup => err_dup_axm dup;
   217   in axioms' end);
   218 
   219 in
   220 
   221 val add_axioms = gen_add_axioms read_axm;
   222 val add_axioms_i = gen_add_axioms cert_axm;
   223 
   224 end;
   225 
   226 
   227 
   228 (** add constant definitions **)
   229 
   230 (* dependencies *)
   231 
   232 fun dependencies thy unchecked is_def name lhs rhs =
   233   let
   234     val pp = Sign.pp thy;
   235     val consts = Sign.consts_of thy;
   236     fun prep const =
   237       let val Const (c, T) = Sign.no_vars pp (Const const)
   238       in (c, Consts.typargs consts (c, Compress.typ thy (Logic.varifyT T))) end;
   239 
   240     val lhs_vars = Term.add_tfreesT (#2 lhs) [];
   241     val rhs_extras = fold (#2 #> Term.fold_atyps (fn TFree v =>
   242       if member (op =) lhs_vars v then I else insert (op =) v | _ => I)) rhs [];
   243     val _ =
   244       if null rhs_extras then ()
   245       else error ("Specification depends on extra type variables: " ^
   246         commas_quote (map (Pretty.string_of_typ pp o TFree) rhs_extras) ^
   247         "\nThe error(s) above occurred in " ^ quote name);
   248   in Defs.define pp unchecked is_def name (prep lhs) (map prep rhs) end;
   249 
   250 fun add_deps a raw_lhs raw_rhs thy =
   251   let
   252     val lhs :: rhs = map (dest_Const o Sign.cert_term thy o Const) (raw_lhs :: raw_rhs);
   253     val name = if a = "" then (#1 lhs ^ " axiom") else a;
   254   in thy |> map_defs (dependencies thy false false name lhs rhs) end;
   255 
   256 fun specify_const tags decl deps thy =
   257   let val (t as Const const, thy') = Sign.declare_const tags decl thy
   258   in (t, add_deps "" const deps thy') end;
   259 
   260 
   261 (* check_overloading *)
   262 
   263 fun check_overloading thy overloaded (c, T) =
   264   let
   265     val declT = Sign.the_const_constraint thy c
   266       handle TYPE (msg, _, _) => error msg;
   267     val T' = Logic.varifyT T;
   268 
   269     fun message txt =
   270       [Pretty.block [Pretty.str "Specification of constant ",
   271         Pretty.str c, Pretty.str " ::", Pretty.brk 1, Pretty.quote (Sign.pretty_typ thy T)],
   272         Pretty.str txt] |> Pretty.chunks |> Pretty.string_of;
   273   in
   274     if Sign.typ_instance thy (declT, T') then ()
   275     else if Type.raw_instance (declT, T') then
   276       error (Library.setmp show_sorts true
   277         message "imposes additional sort constraints on the constant declaration")
   278     else if overloaded then ()
   279     else warning (message "is strictly less general than the declared type");
   280     (c, T)
   281   end;
   282 
   283 
   284 (* check_def *)
   285 
   286 fun check_def thy unchecked overloaded (bname, tm) defs =
   287   let
   288     val ctxt = ProofContext.init thy;
   289     val name = Sign.full_name thy bname;
   290     val (lhs_const, rhs) = Sign.cert_def ctxt tm;
   291     val rhs_consts = fold_aterms (fn Const const => insert (op =) const | _ => I) rhs [];
   292     val _ = check_overloading thy overloaded lhs_const;
   293   in defs |> dependencies thy unchecked true name lhs_const rhs_consts end
   294   handle ERROR msg => cat_error msg (Pretty.string_of (Pretty.block
   295    [Pretty.str ("The error(s) above occurred in definition " ^ quote bname ^ ":"),
   296     Pretty.fbrk, Pretty.quote (Sign.pretty_term thy tm)]));
   297 
   298 
   299 (* add_defs(_i) *)
   300 
   301 local
   302 
   303 fun gen_add_defs prep_axm unchecked overloaded raw_axms thy =
   304   let val axms = map (prep_axm thy) raw_axms in
   305     thy
   306     |> map_defs (fold (check_def thy unchecked overloaded) axms)
   307     |> add_axioms_i axms
   308   end;
   309 
   310 in
   311 
   312 val add_defs_i = gen_add_defs cert_axm;
   313 val add_defs = gen_add_defs read_axm;
   314 
   315 end;
   316 
   317 
   318 (* add_finals(_i) *)
   319 
   320 local
   321 
   322 fun gen_add_finals prep_term overloaded args thy =
   323   let
   324     fun const_of (Const const) = const
   325       | const_of (Free _) = error "Attempt to finalize variable (or undeclared constant)"
   326       | const_of _ = error "Attempt to finalize non-constant term";
   327     fun specify (c, T) = dependencies thy false false (c ^ " axiom") (c, T) [];
   328     val finalize = specify o check_overloading thy overloaded o const_of o
   329       Sign.cert_term thy o prep_term thy;
   330   in thy |> map_defs (fold finalize args) end;
   331 
   332 in
   333 
   334 val add_finals = gen_add_finals Syntax.read_term_global;
   335 val add_finals_i = gen_add_finals (K I);
   336 
   337 end;
   338 
   339 
   340 
   341 (** add oracle **)
   342 
   343 fun add_oracle (bname, oracle) thy = thy |> map_oracles (fn oracles =>
   344   NameSpace.extend_table (Sign.naming_of thy) [(bname, (oracle, stamp ()))] oracles
   345     handle Symtab.DUP dup => err_dup_ora dup);
   346 
   347 end;
   348 
   349 structure BasicTheory: BASIC_THEORY = Theory;
   350 open BasicTheory;