src/HOL/Analysis/Complex_Analysis_Basics.thy
author paulson <lp15@cam.ac.uk>
Mon May 21 22:52:16 2018 +0100 (12 months ago)
changeset 68255 009f783d1bac
parent 68239 0764ee22a4d1
child 68296 69d680e94961
permissions -rw-r--r--
small clean-up of Complex_Analysis_Basics
     1 (*  Author: John Harrison, Marco Maggesi, Graziano Gentili, Gianni Ciolli, Valentina Bruno
     2     Ported from "hol_light/Multivariate/canal.ml" by L C Paulson (2014)
     3 *)
     4 
     5 section \<open>Complex Analysis Basics\<close>
     6 
     7 theory Complex_Analysis_Basics
     8 imports Equivalence_Lebesgue_Henstock_Integration "HOL-Library.Nonpos_Ints"
     9 begin
    10 
    11 
    12 subsection\<open>General lemmas\<close>
    13 
    14 lemma nonneg_Reals_cmod_eq_Re: "z \<in> \<real>\<^sub>\<ge>\<^sub>0 \<Longrightarrow> norm z = Re z"
    15   by (simp add: complex_nonneg_Reals_iff cmod_eq_Re)
    16 
    17 lemma has_derivative_mult_right:
    18   fixes c:: "'a :: real_normed_algebra"
    19   shows "((( * ) c) has_derivative (( * ) c)) F"
    20 by (rule has_derivative_mult_right [OF has_derivative_ident])
    21 
    22 lemma has_derivative_of_real[derivative_intros, simp]:
    23   "(f has_derivative f') F \<Longrightarrow> ((\<lambda>x. of_real (f x)) has_derivative (\<lambda>x. of_real (f' x))) F"
    24   using bounded_linear.has_derivative[OF bounded_linear_of_real] .
    25 
    26 lemma has_vector_derivative_real_field:
    27   "DERIV f (of_real a) :> f' \<Longrightarrow> ((\<lambda>x. f (of_real x)) has_vector_derivative f') (at a within s)"
    28   using has_derivative_compose[of of_real of_real a _ f "( * ) f'"]
    29   by (simp add: scaleR_conv_of_real ac_simps has_vector_derivative_def has_field_derivative_def)
    30 lemmas has_vector_derivative_real_complex = has_vector_derivative_real_field
    31 
    32 lemma fact_cancel:
    33   fixes c :: "'a::real_field"
    34   shows "of_nat (Suc n) * c / (fact (Suc n)) = c / (fact n)"
    35   using of_nat_neq_0 by force
    36 
    37 lemma bilinear_times:
    38   fixes c::"'a::real_algebra" shows "bilinear (\<lambda>x y::'a. x*y)"
    39   by (auto simp: bilinear_def distrib_left distrib_right intro!: linearI)
    40 
    41 lemma linear_cnj: "linear cnj"
    42   using bounded_linear.linear[OF bounded_linear_cnj] .
    43 
    44 lemma lambda_zero: "(\<lambda>h::'a::mult_zero. 0) = ( * ) 0"
    45   by auto
    46 
    47 lemma lambda_one: "(\<lambda>x::'a::monoid_mult. x) = ( * ) 1"
    48   by auto
    49 
    50 lemma continuous_mult_left:
    51   fixes c::"'a::real_normed_algebra"
    52   shows "continuous F f \<Longrightarrow> continuous F (\<lambda>x. c * f x)"
    53 by (rule continuous_mult [OF continuous_const])
    54 
    55 lemma continuous_mult_right:
    56   fixes c::"'a::real_normed_algebra"
    57   shows "continuous F f \<Longrightarrow> continuous F (\<lambda>x. f x * c)"
    58 by (rule continuous_mult [OF _ continuous_const])
    59 
    60 lemma continuous_on_mult_left:
    61   fixes c::"'a::real_normed_algebra"
    62   shows "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. c * f x)"
    63 by (rule continuous_on_mult [OF continuous_on_const])
    64 
    65 lemma continuous_on_mult_right:
    66   fixes c::"'a::real_normed_algebra"
    67   shows "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. f x * c)"
    68 by (rule continuous_on_mult [OF _ continuous_on_const])
    69 
    70 lemma uniformly_continuous_on_cmul_right [continuous_intros]:
    71   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::real_normed_algebra"
    72   shows "uniformly_continuous_on s f \<Longrightarrow> uniformly_continuous_on s (\<lambda>x. f x * c)"
    73   using bounded_linear.uniformly_continuous_on[OF bounded_linear_mult_left] .
    74 
    75 lemma uniformly_continuous_on_cmul_left[continuous_intros]:
    76   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::real_normed_algebra"
    77   assumes "uniformly_continuous_on s f"
    78     shows "uniformly_continuous_on s (\<lambda>x. c * f x)"
    79 by (metis assms bounded_linear.uniformly_continuous_on bounded_linear_mult_right)
    80 
    81 lemma continuous_within_norm_id [continuous_intros]: "continuous (at x within S) norm"
    82   by (rule continuous_norm [OF continuous_ident])
    83 
    84 lemma continuous_on_norm_id [continuous_intros]: "continuous_on S norm"
    85   by (intro continuous_on_id continuous_on_norm)
    86 
    87 subsection\<open>DERIV stuff\<close>
    88 
    89 lemma DERIV_zero_connected_constant:
    90   fixes f :: "'a::{real_normed_field,euclidean_space} \<Rightarrow> 'a"
    91   assumes "connected S"
    92       and "open S"
    93       and "finite K"
    94       and "continuous_on S f"
    95       and "\<forall>x\<in>(S - K). DERIV f x :> 0"
    96     obtains c where "\<And>x. x \<in> S \<Longrightarrow> f(x) = c"
    97 using has_derivative_zero_connected_constant [OF assms(1-4)] assms
    98 by (metis DERIV_const has_derivative_const Diff_iff at_within_open frechet_derivative_at has_field_derivative_def)
    99 
   100 lemmas DERIV_zero_constant = has_field_derivative_zero_constant
   101 
   102 lemma DERIV_zero_unique:
   103   assumes "convex S"
   104       and d0: "\<And>x. x\<in>S \<Longrightarrow> (f has_field_derivative 0) (at x within S)"
   105       and "a \<in> S"
   106       and "x \<in> S"
   107     shows "f x = f a"
   108   by (rule has_derivative_zero_unique [OF assms(1) _ assms(4,3)])
   109      (metis d0 has_field_derivative_imp_has_derivative lambda_zero)
   110 
   111 lemma DERIV_zero_connected_unique:
   112   assumes "connected S"
   113       and "open S"
   114       and d0: "\<And>x. x\<in>S \<Longrightarrow> DERIV f x :> 0"
   115       and "a \<in> S"
   116       and "x \<in> S"
   117     shows "f x = f a"
   118     by (rule has_derivative_zero_unique_connected [OF assms(2,1) _ assms(5,4)])
   119        (metis has_field_derivative_def lambda_zero d0)
   120 
   121 lemma DERIV_transform_within:
   122   assumes "(f has_field_derivative f') (at a within S)"
   123       and "0 < d" "a \<in> S"
   124       and "\<And>x. x\<in>S \<Longrightarrow> dist x a < d \<Longrightarrow> f x = g x"
   125     shows "(g has_field_derivative f') (at a within S)"
   126   using assms unfolding has_field_derivative_def
   127   by (blast intro: has_derivative_transform_within)
   128 
   129 lemma DERIV_transform_within_open:
   130   assumes "DERIV f a :> f'"
   131       and "open S" "a \<in> S"
   132       and "\<And>x. x\<in>S \<Longrightarrow> f x = g x"
   133     shows "DERIV g a :> f'"
   134   using assms unfolding has_field_derivative_def
   135 by (metis has_derivative_transform_within_open)
   136 
   137 lemma DERIV_transform_at:
   138   assumes "DERIV f a :> f'"
   139       and "0 < d"
   140       and "\<And>x. dist x a < d \<Longrightarrow> f x = g x"
   141     shows "DERIV g a :> f'"
   142   by (blast intro: assms DERIV_transform_within)
   143 
   144 (*generalising DERIV_isconst_all, which requires type real (using the ordering)*)
   145 lemma DERIV_zero_UNIV_unique:
   146   "(\<And>x. DERIV f x :> 0) \<Longrightarrow> f x = f a"
   147   by (metis DERIV_zero_unique UNIV_I convex_UNIV)
   148 
   149 subsection \<open>Some limit theorems about real part of real series etc\<close>
   150 
   151 (*MOVE? But not to Finite_Cartesian_Product*)
   152 lemma sums_vec_nth :
   153   assumes "f sums a"
   154   shows "(\<lambda>x. f x $ i) sums a $ i"
   155 using assms unfolding sums_def
   156 by (auto dest: tendsto_vec_nth [where i=i])
   157 
   158 lemma summable_vec_nth :
   159   assumes "summable f"
   160   shows "summable (\<lambda>x. f x $ i)"
   161 using assms unfolding summable_def
   162 by (blast intro: sums_vec_nth)
   163 
   164 subsection \<open>Complex number lemmas\<close>
   165 
   166 lemma
   167   shows open_halfspace_Re_lt: "open {z. Re(z) < b}"
   168     and open_halfspace_Re_gt: "open {z. Re(z) > b}"
   169     and closed_halfspace_Re_ge: "closed {z. Re(z) \<ge> b}"
   170     and closed_halfspace_Re_le: "closed {z. Re(z) \<le> b}"
   171     and closed_halfspace_Re_eq: "closed {z. Re(z) = b}"
   172     and open_halfspace_Im_lt: "open {z. Im(z) < b}"
   173     and open_halfspace_Im_gt: "open {z. Im(z) > b}"
   174     and closed_halfspace_Im_ge: "closed {z. Im(z) \<ge> b}"
   175     and closed_halfspace_Im_le: "closed {z. Im(z) \<le> b}"
   176     and closed_halfspace_Im_eq: "closed {z. Im(z) = b}"
   177   by (intro open_Collect_less closed_Collect_le closed_Collect_eq continuous_on_Re
   178             continuous_on_Im continuous_on_id continuous_on_const)+
   179 
   180 lemma closed_complex_Reals: "closed (\<real> :: complex set)"
   181 proof -
   182   have "(\<real> :: complex set) = {z. Im z = 0}"
   183     by (auto simp: complex_is_Real_iff)
   184   then show ?thesis
   185     by (metis closed_halfspace_Im_eq)
   186 qed
   187 
   188 lemma closed_Real_halfspace_Re_le: "closed (\<real> \<inter> {w. Re w \<le> x})"
   189   by (simp add: closed_Int closed_complex_Reals closed_halfspace_Re_le)
   190 
   191 corollary closed_nonpos_Reals_complex [simp]: "closed (\<real>\<^sub>\<le>\<^sub>0 :: complex set)"
   192 proof -
   193   have "\<real>\<^sub>\<le>\<^sub>0 = \<real> \<inter> {z. Re(z) \<le> 0}"
   194     using complex_nonpos_Reals_iff complex_is_Real_iff by auto
   195   then show ?thesis
   196     by (metis closed_Real_halfspace_Re_le)
   197 qed
   198 
   199 lemma closed_Real_halfspace_Re_ge: "closed (\<real> \<inter> {w. x \<le> Re(w)})"
   200   using closed_halfspace_Re_ge
   201   by (simp add: closed_Int closed_complex_Reals)
   202 
   203 corollary closed_nonneg_Reals_complex [simp]: "closed (\<real>\<^sub>\<ge>\<^sub>0 :: complex set)"
   204 proof -
   205   have "\<real>\<^sub>\<ge>\<^sub>0 = \<real> \<inter> {z. Re(z) \<ge> 0}"
   206     using complex_nonneg_Reals_iff complex_is_Real_iff by auto
   207   then show ?thesis
   208     by (metis closed_Real_halfspace_Re_ge)
   209 qed
   210 
   211 lemma closed_real_abs_le: "closed {w \<in> \<real>. \<bar>Re w\<bar> \<le> r}"
   212 proof -
   213   have "{w \<in> \<real>. \<bar>Re w\<bar> \<le> r} = (\<real> \<inter> {w. Re w \<le> r}) \<inter> (\<real> \<inter> {w. Re w \<ge> -r})"
   214     by auto
   215   then show "closed {w \<in> \<real>. \<bar>Re w\<bar> \<le> r}"
   216     by (simp add: closed_Int closed_Real_halfspace_Re_ge closed_Real_halfspace_Re_le)
   217 qed
   218 
   219 lemma real_lim:
   220   fixes l::complex
   221   assumes "(f \<longlongrightarrow> l) F" and "~(trivial_limit F)" and "eventually P F" and "\<And>a. P a \<Longrightarrow> f a \<in> \<real>"
   222   shows  "l \<in> \<real>"
   223 proof (rule Lim_in_closed_set[OF closed_complex_Reals _ assms(2,1)])
   224   show "eventually (\<lambda>x. f x \<in> \<real>) F"
   225     using assms(3, 4) by (auto intro: eventually_mono)
   226 qed
   227 
   228 lemma real_lim_sequentially:
   229   fixes l::complex
   230   shows "(f \<longlongrightarrow> l) sequentially \<Longrightarrow> (\<exists>N. \<forall>n\<ge>N. f n \<in> \<real>) \<Longrightarrow> l \<in> \<real>"
   231 by (rule real_lim [where F=sequentially]) (auto simp: eventually_sequentially)
   232 
   233 lemma real_series:
   234   fixes l::complex
   235   shows "f sums l \<Longrightarrow> (\<And>n. f n \<in> \<real>) \<Longrightarrow> l \<in> \<real>"
   236 unfolding sums_def
   237 by (metis real_lim_sequentially sum_in_Reals)
   238 
   239 lemma Lim_null_comparison_Re:
   240   assumes "eventually (\<lambda>x. norm(f x) \<le> Re(g x)) F" "(g \<longlongrightarrow> 0) F" shows "(f \<longlongrightarrow> 0) F"
   241   by (rule Lim_null_comparison[OF assms(1)] tendsto_eq_intros assms(2))+ simp
   242 
   243 subsection\<open>Holomorphic functions\<close>
   244 
   245 definition holomorphic_on :: "[complex \<Rightarrow> complex, complex set] \<Rightarrow> bool"
   246            (infixl "(holomorphic'_on)" 50)
   247   where "f holomorphic_on s \<equiv> \<forall>x\<in>s. f field_differentiable (at x within s)"
   248 
   249 named_theorems holomorphic_intros "structural introduction rules for holomorphic_on"
   250 
   251 lemma holomorphic_onI [intro?]: "(\<And>x. x \<in> s \<Longrightarrow> f field_differentiable (at x within s)) \<Longrightarrow> f holomorphic_on s"
   252   by (simp add: holomorphic_on_def)
   253 
   254 lemma holomorphic_onD [dest?]: "\<lbrakk>f holomorphic_on s; x \<in> s\<rbrakk> \<Longrightarrow> f field_differentiable (at x within s)"
   255   by (simp add: holomorphic_on_def)
   256 
   257 lemma holomorphic_on_imp_differentiable_on:
   258     "f holomorphic_on s \<Longrightarrow> f differentiable_on s"
   259   unfolding holomorphic_on_def differentiable_on_def
   260   by (simp add: field_differentiable_imp_differentiable)
   261 
   262 lemma holomorphic_on_imp_differentiable_at:
   263    "\<lbrakk>f holomorphic_on s; open s; x \<in> s\<rbrakk> \<Longrightarrow> f field_differentiable (at x)"
   264 using at_within_open holomorphic_on_def by fastforce
   265 
   266 lemma holomorphic_on_empty [holomorphic_intros]: "f holomorphic_on {}"
   267   by (simp add: holomorphic_on_def)
   268 
   269 lemma holomorphic_on_open:
   270     "open s \<Longrightarrow> f holomorphic_on s \<longleftrightarrow> (\<forall>x \<in> s. \<exists>f'. DERIV f x :> f')"
   271   by (auto simp: holomorphic_on_def field_differentiable_def has_field_derivative_def at_within_open [of _ s])
   272 
   273 lemma holomorphic_on_imp_continuous_on:
   274     "f holomorphic_on s \<Longrightarrow> continuous_on s f"
   275   by (metis field_differentiable_imp_continuous_at continuous_on_eq_continuous_within holomorphic_on_def)
   276 
   277 lemma holomorphic_on_subset [elim]:
   278     "f holomorphic_on s \<Longrightarrow> t \<subseteq> s \<Longrightarrow> f holomorphic_on t"
   279   unfolding holomorphic_on_def
   280   by (metis field_differentiable_within_subset subsetD)
   281 
   282 lemma holomorphic_transform: "\<lbrakk>f holomorphic_on s; \<And>x. x \<in> s \<Longrightarrow> f x = g x\<rbrakk> \<Longrightarrow> g holomorphic_on s"
   283   by (metis field_differentiable_transform_within linordered_field_no_ub holomorphic_on_def)
   284 
   285 lemma holomorphic_cong: "s = t ==> (\<And>x. x \<in> s \<Longrightarrow> f x = g x) \<Longrightarrow> f holomorphic_on s \<longleftrightarrow> g holomorphic_on t"
   286   by (metis holomorphic_transform)
   287 
   288 lemma holomorphic_on_linear [simp, holomorphic_intros]: "(( * ) c) holomorphic_on s"
   289   unfolding holomorphic_on_def by (metis field_differentiable_linear)
   290 
   291 lemma holomorphic_on_const [simp, holomorphic_intros]: "(\<lambda>z. c) holomorphic_on s"
   292   unfolding holomorphic_on_def by (metis field_differentiable_const)
   293 
   294 lemma holomorphic_on_ident [simp, holomorphic_intros]: "(\<lambda>x. x) holomorphic_on s"
   295   unfolding holomorphic_on_def by (metis field_differentiable_ident)
   296 
   297 lemma holomorphic_on_id [simp, holomorphic_intros]: "id holomorphic_on s"
   298   unfolding id_def by (rule holomorphic_on_ident)
   299 
   300 lemma holomorphic_on_compose:
   301   "f holomorphic_on s \<Longrightarrow> g holomorphic_on (f ` s) \<Longrightarrow> (g o f) holomorphic_on s"
   302   using field_differentiable_compose_within[of f _ s g]
   303   by (auto simp: holomorphic_on_def)
   304 
   305 lemma holomorphic_on_compose_gen:
   306   "f holomorphic_on s \<Longrightarrow> g holomorphic_on t \<Longrightarrow> f ` s \<subseteq> t \<Longrightarrow> (g o f) holomorphic_on s"
   307   by (metis holomorphic_on_compose holomorphic_on_subset)
   308 
   309 lemma holomorphic_on_minus [holomorphic_intros]: "f holomorphic_on s \<Longrightarrow> (\<lambda>z. -(f z)) holomorphic_on s"
   310   by (metis field_differentiable_minus holomorphic_on_def)
   311 
   312 lemma holomorphic_on_add [holomorphic_intros]:
   313   "\<lbrakk>f holomorphic_on s; g holomorphic_on s\<rbrakk> \<Longrightarrow> (\<lambda>z. f z + g z) holomorphic_on s"
   314   unfolding holomorphic_on_def by (metis field_differentiable_add)
   315 
   316 lemma holomorphic_on_diff [holomorphic_intros]:
   317   "\<lbrakk>f holomorphic_on s; g holomorphic_on s\<rbrakk> \<Longrightarrow> (\<lambda>z. f z - g z) holomorphic_on s"
   318   unfolding holomorphic_on_def by (metis field_differentiable_diff)
   319 
   320 lemma holomorphic_on_mult [holomorphic_intros]:
   321   "\<lbrakk>f holomorphic_on s; g holomorphic_on s\<rbrakk> \<Longrightarrow> (\<lambda>z. f z * g z) holomorphic_on s"
   322   unfolding holomorphic_on_def by (metis field_differentiable_mult)
   323 
   324 lemma holomorphic_on_inverse [holomorphic_intros]:
   325   "\<lbrakk>f holomorphic_on s; \<And>z. z \<in> s \<Longrightarrow> f z \<noteq> 0\<rbrakk> \<Longrightarrow> (\<lambda>z. inverse (f z)) holomorphic_on s"
   326   unfolding holomorphic_on_def by (metis field_differentiable_inverse)
   327 
   328 lemma holomorphic_on_divide [holomorphic_intros]:
   329   "\<lbrakk>f holomorphic_on s; g holomorphic_on s; \<And>z. z \<in> s \<Longrightarrow> g z \<noteq> 0\<rbrakk> \<Longrightarrow> (\<lambda>z. f z / g z) holomorphic_on s"
   330   unfolding holomorphic_on_def by (metis field_differentiable_divide)
   331 
   332 lemma holomorphic_on_power [holomorphic_intros]:
   333   "f holomorphic_on s \<Longrightarrow> (\<lambda>z. (f z)^n) holomorphic_on s"
   334   unfolding holomorphic_on_def by (metis field_differentiable_power)
   335 
   336 lemma holomorphic_on_sum [holomorphic_intros]:
   337   "(\<And>i. i \<in> I \<Longrightarrow> (f i) holomorphic_on s) \<Longrightarrow> (\<lambda>x. sum (\<lambda>i. f i x) I) holomorphic_on s"
   338   unfolding holomorphic_on_def by (metis field_differentiable_sum)
   339 
   340 lemma holomorphic_on_prod [holomorphic_intros]:
   341   "(\<And>i. i \<in> I \<Longrightarrow> (f i) holomorphic_on s) \<Longrightarrow> (\<lambda>x. prod (\<lambda>i. f i x) I) holomorphic_on s"
   342   by (induction I rule: infinite_finite_induct) (auto intro: holomorphic_intros)
   343 
   344 lemma holomorphic_pochhammer [holomorphic_intros]:
   345   "f holomorphic_on A \<Longrightarrow> (\<lambda>s. pochhammer (f s) n) holomorphic_on A"
   346   by (induction n) (auto intro!: holomorphic_intros simp: pochhammer_Suc)
   347 
   348 lemma holomorphic_on_scaleR [holomorphic_intros]:
   349   "f holomorphic_on A \<Longrightarrow> (\<lambda>x. c *\<^sub>R f x) holomorphic_on A"
   350   by (auto simp: scaleR_conv_of_real intro!: holomorphic_intros)
   351 
   352 lemma holomorphic_on_Un [holomorphic_intros]:
   353   assumes "f holomorphic_on A" "f holomorphic_on B" "open A" "open B"
   354   shows   "f holomorphic_on (A \<union> B)"
   355   using assms by (auto simp: holomorphic_on_def  at_within_open[of _ A]
   356                              at_within_open[of _ B]  at_within_open[of _ "A \<union> B"] open_Un)
   357 
   358 lemma holomorphic_on_If_Un [holomorphic_intros]:
   359   assumes "f holomorphic_on A" "g holomorphic_on B" "open A" "open B"
   360   assumes "\<And>z. z \<in> A \<Longrightarrow> z \<in> B \<Longrightarrow> f z = g z"
   361   shows   "(\<lambda>z. if z \<in> A then f z else g z) holomorphic_on (A \<union> B)" (is "?h holomorphic_on _")
   362 proof (intro holomorphic_on_Un)
   363   note \<open>f holomorphic_on A\<close>
   364   also have "f holomorphic_on A \<longleftrightarrow> ?h holomorphic_on A"
   365     by (intro holomorphic_cong) auto
   366   finally show \<dots> .
   367 next
   368   note \<open>g holomorphic_on B\<close>
   369   also have "g holomorphic_on B \<longleftrightarrow> ?h holomorphic_on B"
   370     using assms by (intro holomorphic_cong) auto
   371   finally show \<dots> .
   372 qed (insert assms, auto)
   373 
   374 lemma leibniz_rule_holomorphic:
   375   fixes f::"complex \<Rightarrow> 'b::euclidean_space \<Rightarrow> complex"
   376   assumes "\<And>x t. x \<in> U \<Longrightarrow> t \<in> cbox a b \<Longrightarrow> ((\<lambda>x. f x t) has_field_derivative fx x t) (at x within U)"
   377   assumes "\<And>x. x \<in> U \<Longrightarrow> (f x) integrable_on cbox a b"
   378   assumes "continuous_on (U \<times> (cbox a b)) (\<lambda>(x, t). fx x t)"
   379   assumes "convex U"
   380   shows "(\<lambda>x. integral (cbox a b) (f x)) holomorphic_on U"
   381   using leibniz_rule_field_differentiable[OF assms(1-3) _ assms(4)]
   382   by (auto simp: holomorphic_on_def)
   383 
   384 lemma DERIV_deriv_iff_field_differentiable:
   385   "DERIV f x :> deriv f x \<longleftrightarrow> f field_differentiable at x"
   386   unfolding field_differentiable_def by (metis DERIV_imp_deriv)
   387 
   388 lemma holomorphic_derivI:
   389      "\<lbrakk>f holomorphic_on S; open S; x \<in> S\<rbrakk>
   390       \<Longrightarrow> (f has_field_derivative deriv f x) (at x within T)"
   391 by (metis DERIV_deriv_iff_field_differentiable at_within_open  holomorphic_on_def has_field_derivative_at_within)
   392 
   393 lemma complex_derivative_chain:
   394   "f field_differentiable at x \<Longrightarrow> g field_differentiable at (f x)
   395     \<Longrightarrow> deriv (g o f) x = deriv g (f x) * deriv f x"
   396   by (metis DERIV_deriv_iff_field_differentiable DERIV_chain DERIV_imp_deriv)
   397 
   398 lemma deriv_linear [simp]: "deriv (\<lambda>w. c * w) = (\<lambda>z. c)"
   399   by (metis DERIV_imp_deriv DERIV_cmult_Id)
   400 
   401 lemma deriv_ident [simp]: "deriv (\<lambda>w. w) = (\<lambda>z. 1)"
   402   by (metis DERIV_imp_deriv DERIV_ident)
   403 
   404 lemma deriv_id [simp]: "deriv id = (\<lambda>z. 1)"
   405   by (simp add: id_def)
   406 
   407 lemma deriv_const [simp]: "deriv (\<lambda>w. c) = (\<lambda>z. 0)"
   408   by (metis DERIV_imp_deriv DERIV_const)
   409 
   410 lemma deriv_add [simp]:
   411   "\<lbrakk>f field_differentiable at z; g field_differentiable at z\<rbrakk>
   412    \<Longrightarrow> deriv (\<lambda>w. f w + g w) z = deriv f z + deriv g z"
   413   unfolding DERIV_deriv_iff_field_differentiable[symmetric]
   414   by (auto intro!: DERIV_imp_deriv derivative_intros)
   415 
   416 lemma deriv_diff [simp]:
   417   "\<lbrakk>f field_differentiable at z; g field_differentiable at z\<rbrakk>
   418    \<Longrightarrow> deriv (\<lambda>w. f w - g w) z = deriv f z - deriv g z"
   419   unfolding DERIV_deriv_iff_field_differentiable[symmetric]
   420   by (auto intro!: DERIV_imp_deriv derivative_intros)
   421 
   422 lemma deriv_mult [simp]:
   423   "\<lbrakk>f field_differentiable at z; g field_differentiable at z\<rbrakk>
   424    \<Longrightarrow> deriv (\<lambda>w. f w * g w) z = f z * deriv g z + deriv f z * g z"
   425   unfolding DERIV_deriv_iff_field_differentiable[symmetric]
   426   by (auto intro!: DERIV_imp_deriv derivative_eq_intros)
   427 
   428 lemma deriv_cmult:
   429   "f field_differentiable at z \<Longrightarrow> deriv (\<lambda>w. c * f w) z = c * deriv f z"
   430   by simp
   431 
   432 lemma deriv_cmult_right:
   433   "f field_differentiable at z \<Longrightarrow> deriv (\<lambda>w. f w * c) z = deriv f z * c"
   434   by simp
   435 
   436 lemma deriv_inverse [simp]:
   437   "\<lbrakk>f field_differentiable at z; f z \<noteq> 0\<rbrakk>
   438    \<Longrightarrow> deriv (\<lambda>w. inverse (f w)) z = - deriv f z / f z ^ 2"
   439   unfolding DERIV_deriv_iff_field_differentiable[symmetric]
   440   by (safe intro!: DERIV_imp_deriv derivative_eq_intros) (auto simp: divide_simps power2_eq_square)
   441 
   442 lemma deriv_divide [simp]:
   443   "\<lbrakk>f field_differentiable at z; g field_differentiable at z; g z \<noteq> 0\<rbrakk>
   444    \<Longrightarrow> deriv (\<lambda>w. f w / g w) z = (deriv f z * g z - f z * deriv g z) / g z ^ 2"
   445   by (simp add: field_class.field_divide_inverse field_differentiable_inverse)
   446      (simp add: divide_simps power2_eq_square)
   447 
   448 lemma deriv_cdivide_right:
   449   "f field_differentiable at z \<Longrightarrow> deriv (\<lambda>w. f w / c) z = deriv f z / c"
   450   by (simp add: field_class.field_divide_inverse)
   451 
   452 lemma complex_derivative_transform_within_open:
   453   "\<lbrakk>f holomorphic_on s; g holomorphic_on s; open s; z \<in> s; \<And>w. w \<in> s \<Longrightarrow> f w = g w\<rbrakk>
   454    \<Longrightarrow> deriv f z = deriv g z"
   455   unfolding holomorphic_on_def
   456   by (rule DERIV_imp_deriv)
   457      (metis DERIV_deriv_iff_field_differentiable DERIV_transform_within_open at_within_open)
   458 
   459 lemma deriv_compose_linear:
   460   "f field_differentiable at (c * z) \<Longrightarrow> deriv (\<lambda>w. f (c * w)) z = c * deriv f (c * z)"
   461 apply (rule DERIV_imp_deriv)
   462   unfolding DERIV_deriv_iff_field_differentiable [symmetric]
   463   by (metis (full_types) DERIV_chain2 DERIV_cmult_Id mult.commute)
   464 
   465 
   466 lemma nonzero_deriv_nonconstant:
   467   assumes df: "DERIV f \<xi> :> df" and S: "open S" "\<xi> \<in> S" and "df \<noteq> 0"
   468     shows "\<not> f constant_on S"
   469 unfolding constant_on_def
   470 by (metis \<open>df \<noteq> 0\<close> DERIV_transform_within_open [OF df S] DERIV_const DERIV_unique)
   471 
   472 lemma holomorphic_nonconstant:
   473   assumes holf: "f holomorphic_on S" and "open S" "\<xi> \<in> S" "deriv f \<xi> \<noteq> 0"
   474     shows "\<not> f constant_on S"
   475   by (rule nonzero_deriv_nonconstant [of f "deriv f \<xi>" \<xi> S])
   476     (use assms in \<open>auto simp: holomorphic_derivI\<close>)
   477 
   478 subsection\<open>Caratheodory characterization\<close>
   479 
   480 lemma field_differentiable_caratheodory_at:
   481   "f field_differentiable (at z) \<longleftrightarrow>
   482          (\<exists>g. (\<forall>w. f(w) - f(z) = g(w) * (w - z)) \<and> continuous (at z) g)"
   483   using CARAT_DERIV [of f]
   484   by (simp add: field_differentiable_def has_field_derivative_def)
   485 
   486 lemma field_differentiable_caratheodory_within:
   487   "f field_differentiable (at z within s) \<longleftrightarrow>
   488          (\<exists>g. (\<forall>w. f(w) - f(z) = g(w) * (w - z)) \<and> continuous (at z within s) g)"
   489   using DERIV_caratheodory_within [of f]
   490   by (simp add: field_differentiable_def has_field_derivative_def)
   491 
   492 subsection\<open>Analyticity on a set\<close>
   493 
   494 definition analytic_on (infixl "(analytic'_on)" 50)
   495   where "f analytic_on S \<equiv> \<forall>x \<in> S. \<exists>e. 0 < e \<and> f holomorphic_on (ball x e)"
   496 
   497 named_theorems analytic_intros "introduction rules for proving analyticity"
   498 
   499 lemma analytic_imp_holomorphic: "f analytic_on S \<Longrightarrow> f holomorphic_on S"
   500   by (simp add: at_within_open [OF _ open_ball] analytic_on_def holomorphic_on_def)
   501      (metis centre_in_ball field_differentiable_at_within)
   502 
   503 lemma analytic_on_open: "open S \<Longrightarrow> f analytic_on S \<longleftrightarrow> f holomorphic_on S"
   504 apply (auto simp: analytic_imp_holomorphic)
   505 apply (auto simp: analytic_on_def holomorphic_on_def)
   506 by (metis holomorphic_on_def holomorphic_on_subset open_contains_ball)
   507 
   508 lemma analytic_on_imp_differentiable_at:
   509   "f analytic_on S \<Longrightarrow> x \<in> S \<Longrightarrow> f field_differentiable (at x)"
   510  apply (auto simp: analytic_on_def holomorphic_on_def)
   511 by (metis open_ball centre_in_ball field_differentiable_within_open)
   512 
   513 lemma analytic_on_subset: "f analytic_on S \<Longrightarrow> T \<subseteq> S \<Longrightarrow> f analytic_on T"
   514   by (auto simp: analytic_on_def)
   515 
   516 lemma analytic_on_Un: "f analytic_on (S \<union> T) \<longleftrightarrow> f analytic_on S \<and> f analytic_on T"
   517   by (auto simp: analytic_on_def)
   518 
   519 lemma analytic_on_Union: "f analytic_on (\<Union>\<T>) \<longleftrightarrow> (\<forall>T \<in> \<T>. f analytic_on T)"
   520   by (auto simp: analytic_on_def)
   521 
   522 lemma analytic_on_UN: "f analytic_on (\<Union>i\<in>I. S i) \<longleftrightarrow> (\<forall>i\<in>I. f analytic_on (S i))"
   523   by (auto simp: analytic_on_def)
   524 
   525 lemma analytic_on_holomorphic:
   526   "f analytic_on S \<longleftrightarrow> (\<exists>T. open T \<and> S \<subseteq> T \<and> f holomorphic_on T)"
   527   (is "?lhs = ?rhs")
   528 proof -
   529   have "?lhs \<longleftrightarrow> (\<exists>T. open T \<and> S \<subseteq> T \<and> f analytic_on T)"
   530   proof safe
   531     assume "f analytic_on S"
   532     then show "\<exists>T. open T \<and> S \<subseteq> T \<and> f analytic_on T"
   533       apply (simp add: analytic_on_def)
   534       apply (rule exI [where x="\<Union>{U. open U \<and> f analytic_on U}"], auto)
   535       apply (metis open_ball analytic_on_open centre_in_ball)
   536       by (metis analytic_on_def)
   537   next
   538     fix T
   539     assume "open T" "S \<subseteq> T" "f analytic_on T"
   540     then show "f analytic_on S"
   541         by (metis analytic_on_subset)
   542   qed
   543   also have "... \<longleftrightarrow> ?rhs"
   544     by (auto simp: analytic_on_open)
   545   finally show ?thesis .
   546 qed
   547 
   548 lemma analytic_on_linear [analytic_intros,simp]: "(( * ) c) analytic_on S"
   549   by (auto simp add: analytic_on_holomorphic)
   550 
   551 lemma analytic_on_const [analytic_intros,simp]: "(\<lambda>z. c) analytic_on S"
   552   by (metis analytic_on_def holomorphic_on_const zero_less_one)
   553 
   554 lemma analytic_on_ident [analytic_intros,simp]: "(\<lambda>x. x) analytic_on S"
   555   by (simp add: analytic_on_def gt_ex)
   556 
   557 lemma analytic_on_id [analytic_intros]: "id analytic_on S"
   558   unfolding id_def by (rule analytic_on_ident)
   559 
   560 lemma analytic_on_compose:
   561   assumes f: "f analytic_on S"
   562       and g: "g analytic_on (f ` S)"
   563     shows "(g o f) analytic_on S"
   564 unfolding analytic_on_def
   565 proof (intro ballI)
   566   fix x
   567   assume x: "x \<in> S"
   568   then obtain e where e: "0 < e" and fh: "f holomorphic_on ball x e" using f
   569     by (metis analytic_on_def)
   570   obtain e' where e': "0 < e'" and gh: "g holomorphic_on ball (f x) e'" using g
   571     by (metis analytic_on_def g image_eqI x)
   572   have "isCont f x"
   573     by (metis analytic_on_imp_differentiable_at field_differentiable_imp_continuous_at f x)
   574   with e' obtain d where d: "0 < d" and fd: "f ` ball x d \<subseteq> ball (f x) e'"
   575      by (auto simp: continuous_at_ball)
   576   have "g \<circ> f holomorphic_on ball x (min d e)"
   577     apply (rule holomorphic_on_compose)
   578     apply (metis fh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   579     by (metis fd gh holomorphic_on_subset image_mono min.cobounded1 subset_ball)
   580   then show "\<exists>e>0. g \<circ> f holomorphic_on ball x e"
   581     by (metis d e min_less_iff_conj)
   582 qed
   583 
   584 lemma analytic_on_compose_gen:
   585   "f analytic_on S \<Longrightarrow> g analytic_on T \<Longrightarrow> (\<And>z. z \<in> S \<Longrightarrow> f z \<in> T)
   586              \<Longrightarrow> g o f analytic_on S"
   587 by (metis analytic_on_compose analytic_on_subset image_subset_iff)
   588 
   589 lemma analytic_on_neg [analytic_intros]:
   590   "f analytic_on S \<Longrightarrow> (\<lambda>z. -(f z)) analytic_on S"
   591 by (metis analytic_on_holomorphic holomorphic_on_minus)
   592 
   593 lemma analytic_on_add [analytic_intros]:
   594   assumes f: "f analytic_on S"
   595       and g: "g analytic_on S"
   596     shows "(\<lambda>z. f z + g z) analytic_on S"
   597 unfolding analytic_on_def
   598 proof (intro ballI)
   599   fix z
   600   assume z: "z \<in> S"
   601   then obtain e where e: "0 < e" and fh: "f holomorphic_on ball z e" using f
   602     by (metis analytic_on_def)
   603   obtain e' where e': "0 < e'" and gh: "g holomorphic_on ball z e'" using g
   604     by (metis analytic_on_def g z)
   605   have "(\<lambda>z. f z + g z) holomorphic_on ball z (min e e')"
   606     apply (rule holomorphic_on_add)
   607     apply (metis fh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   608     by (metis gh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   609   then show "\<exists>e>0. (\<lambda>z. f z + g z) holomorphic_on ball z e"
   610     by (metis e e' min_less_iff_conj)
   611 qed
   612 
   613 lemma analytic_on_diff [analytic_intros]:
   614   assumes f: "f analytic_on S"
   615       and g: "g analytic_on S"
   616     shows "(\<lambda>z. f z - g z) analytic_on S"
   617 unfolding analytic_on_def
   618 proof (intro ballI)
   619   fix z
   620   assume z: "z \<in> S"
   621   then obtain e where e: "0 < e" and fh: "f holomorphic_on ball z e" using f
   622     by (metis analytic_on_def)
   623   obtain e' where e': "0 < e'" and gh: "g holomorphic_on ball z e'" using g
   624     by (metis analytic_on_def g z)
   625   have "(\<lambda>z. f z - g z) holomorphic_on ball z (min e e')"
   626     apply (rule holomorphic_on_diff)
   627     apply (metis fh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   628     by (metis gh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   629   then show "\<exists>e>0. (\<lambda>z. f z - g z) holomorphic_on ball z e"
   630     by (metis e e' min_less_iff_conj)
   631 qed
   632 
   633 lemma analytic_on_mult [analytic_intros]:
   634   assumes f: "f analytic_on S"
   635       and g: "g analytic_on S"
   636     shows "(\<lambda>z. f z * g z) analytic_on S"
   637 unfolding analytic_on_def
   638 proof (intro ballI)
   639   fix z
   640   assume z: "z \<in> S"
   641   then obtain e where e: "0 < e" and fh: "f holomorphic_on ball z e" using f
   642     by (metis analytic_on_def)
   643   obtain e' where e': "0 < e'" and gh: "g holomorphic_on ball z e'" using g
   644     by (metis analytic_on_def g z)
   645   have "(\<lambda>z. f z * g z) holomorphic_on ball z (min e e')"
   646     apply (rule holomorphic_on_mult)
   647     apply (metis fh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   648     by (metis gh holomorphic_on_subset min.bounded_iff order_refl subset_ball)
   649   then show "\<exists>e>0. (\<lambda>z. f z * g z) holomorphic_on ball z e"
   650     by (metis e e' min_less_iff_conj)
   651 qed
   652 
   653 lemma analytic_on_inverse [analytic_intros]:
   654   assumes f: "f analytic_on S"
   655       and nz: "(\<And>z. z \<in> S \<Longrightarrow> f z \<noteq> 0)"
   656     shows "(\<lambda>z. inverse (f z)) analytic_on S"
   657 unfolding analytic_on_def
   658 proof (intro ballI)
   659   fix z
   660   assume z: "z \<in> S"
   661   then obtain e where e: "0 < e" and fh: "f holomorphic_on ball z e" using f
   662     by (metis analytic_on_def)
   663   have "continuous_on (ball z e) f"
   664     by (metis fh holomorphic_on_imp_continuous_on)
   665   then obtain e' where e': "0 < e'" and nz': "\<And>y. dist z y < e' \<Longrightarrow> f y \<noteq> 0"
   666     by (metis open_ball centre_in_ball continuous_on_open_avoid e z nz)
   667   have "(\<lambda>z. inverse (f z)) holomorphic_on ball z (min e e')"
   668     apply (rule holomorphic_on_inverse)
   669     apply (metis fh holomorphic_on_subset min.cobounded2 min.commute subset_ball)
   670     by (metis nz' mem_ball min_less_iff_conj)
   671   then show "\<exists>e>0. (\<lambda>z. inverse (f z)) holomorphic_on ball z e"
   672     by (metis e e' min_less_iff_conj)
   673 qed
   674 
   675 lemma analytic_on_divide [analytic_intros]:
   676   assumes f: "f analytic_on S"
   677       and g: "g analytic_on S"
   678       and nz: "(\<And>z. z \<in> S \<Longrightarrow> g z \<noteq> 0)"
   679     shows "(\<lambda>z. f z / g z) analytic_on S"
   680 unfolding divide_inverse
   681 by (metis analytic_on_inverse analytic_on_mult f g nz)
   682 
   683 lemma analytic_on_power [analytic_intros]:
   684   "f analytic_on S \<Longrightarrow> (\<lambda>z. (f z) ^ n) analytic_on S"
   685 by (induct n) (auto simp: analytic_on_mult)
   686 
   687 lemma analytic_on_sum [analytic_intros]:
   688   "(\<And>i. i \<in> I \<Longrightarrow> (f i) analytic_on S) \<Longrightarrow> (\<lambda>x. sum (\<lambda>i. f i x) I) analytic_on S"
   689   by (induct I rule: infinite_finite_induct) (auto simp: analytic_on_const analytic_on_add)
   690 
   691 lemma deriv_left_inverse:
   692   assumes "f holomorphic_on S" and "g holomorphic_on T"
   693       and "open S" and "open T"
   694       and "f ` S \<subseteq> T"
   695       and [simp]: "\<And>z. z \<in> S \<Longrightarrow> g (f z) = z"
   696       and "w \<in> S"
   697     shows "deriv f w * deriv g (f w) = 1"
   698 proof -
   699   have "deriv f w * deriv g (f w) = deriv g (f w) * deriv f w"
   700     by (simp add: algebra_simps)
   701   also have "... = deriv (g o f) w"
   702     using assms
   703     by (metis analytic_on_imp_differentiable_at analytic_on_open complex_derivative_chain image_subset_iff)
   704   also have "... = deriv id w"
   705   proof (rule complex_derivative_transform_within_open [where s=S])
   706     show "g \<circ> f holomorphic_on S"
   707       by (rule assms holomorphic_on_compose_gen holomorphic_intros)+
   708   qed (use assms in auto)
   709   also have "... = 1"
   710     by simp
   711   finally show ?thesis .
   712 qed
   713 
   714 subsection\<open>analyticity at a point\<close>
   715 
   716 lemma analytic_at_ball:
   717   "f analytic_on {z} \<longleftrightarrow> (\<exists>e. 0<e \<and> f holomorphic_on ball z e)"
   718 by (metis analytic_on_def singleton_iff)
   719 
   720 lemma analytic_at:
   721     "f analytic_on {z} \<longleftrightarrow> (\<exists>s. open s \<and> z \<in> s \<and> f holomorphic_on s)"
   722 by (metis analytic_on_holomorphic empty_subsetI insert_subset)
   723 
   724 lemma analytic_on_analytic_at:
   725     "f analytic_on s \<longleftrightarrow> (\<forall>z \<in> s. f analytic_on {z})"
   726 by (metis analytic_at_ball analytic_on_def)
   727 
   728 lemma analytic_at_two:
   729   "f analytic_on {z} \<and> g analytic_on {z} \<longleftrightarrow>
   730    (\<exists>s. open s \<and> z \<in> s \<and> f holomorphic_on s \<and> g holomorphic_on s)"
   731   (is "?lhs = ?rhs")
   732 proof
   733   assume ?lhs
   734   then obtain s t
   735     where st: "open s" "z \<in> s" "f holomorphic_on s"
   736               "open t" "z \<in> t" "g holomorphic_on t"
   737     by (auto simp: analytic_at)
   738   show ?rhs
   739     apply (rule_tac x="s \<inter> t" in exI)
   740     using st
   741     apply (auto simp: Diff_subset holomorphic_on_subset)
   742     done
   743 next
   744   assume ?rhs
   745   then show ?lhs
   746     by (force simp add: analytic_at)
   747 qed
   748 
   749 subsection\<open>Combining theorems for derivative with ``analytic at'' hypotheses\<close>
   750 
   751 lemma
   752   assumes "f analytic_on {z}" "g analytic_on {z}"
   753   shows complex_derivative_add_at: "deriv (\<lambda>w. f w + g w) z = deriv f z + deriv g z"
   754     and complex_derivative_diff_at: "deriv (\<lambda>w. f w - g w) z = deriv f z - deriv g z"
   755     and complex_derivative_mult_at: "deriv (\<lambda>w. f w * g w) z =
   756            f z * deriv g z + deriv f z * g z"
   757 proof -
   758   obtain s where s: "open s" "z \<in> s" "f holomorphic_on s" "g holomorphic_on s"
   759     using assms by (metis analytic_at_two)
   760   show "deriv (\<lambda>w. f w + g w) z = deriv f z + deriv g z"
   761     apply (rule DERIV_imp_deriv [OF DERIV_add])
   762     using s
   763     apply (auto simp: holomorphic_on_open field_differentiable_def DERIV_deriv_iff_field_differentiable)
   764     done
   765   show "deriv (\<lambda>w. f w - g w) z = deriv f z - deriv g z"
   766     apply (rule DERIV_imp_deriv [OF DERIV_diff])
   767     using s
   768     apply (auto simp: holomorphic_on_open field_differentiable_def DERIV_deriv_iff_field_differentiable)
   769     done
   770   show "deriv (\<lambda>w. f w * g w) z = f z * deriv g z + deriv f z * g z"
   771     apply (rule DERIV_imp_deriv [OF DERIV_mult'])
   772     using s
   773     apply (auto simp: holomorphic_on_open field_differentiable_def DERIV_deriv_iff_field_differentiable)
   774     done
   775 qed
   776 
   777 lemma deriv_cmult_at:
   778   "f analytic_on {z} \<Longrightarrow>  deriv (\<lambda>w. c * f w) z = c * deriv f z"
   779 by (auto simp: complex_derivative_mult_at deriv_const analytic_on_const)
   780 
   781 lemma deriv_cmult_right_at:
   782   "f analytic_on {z} \<Longrightarrow>  deriv (\<lambda>w. f w * c) z = deriv f z * c"
   783 by (auto simp: complex_derivative_mult_at deriv_const analytic_on_const)
   784 
   785 subsection\<open>Complex differentiation of sequences and series\<close>
   786 
   787 (* TODO: Could probably be simplified using Uniform_Limit *)
   788 lemma has_complex_derivative_sequence:
   789   fixes S :: "complex set"
   790   assumes cvs: "convex S"
   791       and df:  "\<And>n x. x \<in> S \<Longrightarrow> (f n has_field_derivative f' n x) (at x within S)"
   792       and conv: "\<And>e. 0 < e \<Longrightarrow> \<exists>N. \<forall>n x. n \<ge> N \<longrightarrow> x \<in> S \<longrightarrow> norm (f' n x - g' x) \<le> e"
   793       and "\<exists>x l. x \<in> S \<and> ((\<lambda>n. f n x) \<longlongrightarrow> l) sequentially"
   794     shows "\<exists>g. \<forall>x \<in> S. ((\<lambda>n. f n x) \<longlongrightarrow> g x) sequentially \<and>
   795                        (g has_field_derivative (g' x)) (at x within S)"
   796 proof -
   797   from assms obtain x l where x: "x \<in> S" and tf: "((\<lambda>n. f n x) \<longlongrightarrow> l) sequentially"
   798     by blast
   799   { fix e::real assume e: "e > 0"
   800     then obtain N where N: "\<forall>n\<ge>N. \<forall>x. x \<in> S \<longrightarrow> cmod (f' n x - g' x) \<le> e"
   801       by (metis conv)
   802     have "\<exists>N. \<forall>n\<ge>N. \<forall>x\<in>S. \<forall>h. cmod (f' n x * h - g' x * h) \<le> e * cmod h"
   803     proof (rule exI [of _ N], clarify)
   804       fix n y h
   805       assume "N \<le> n" "y \<in> S"
   806       then have "cmod (f' n y - g' y) \<le> e"
   807         by (metis N)
   808       then have "cmod h * cmod (f' n y - g' y) \<le> cmod h * e"
   809         by (auto simp: antisym_conv2 mult_le_cancel_left norm_triangle_ineq2)
   810       then show "cmod (f' n y * h - g' y * h) \<le> e * cmod h"
   811         by (simp add: norm_mult [symmetric] field_simps)
   812     qed
   813   } note ** = this
   814   show ?thesis
   815     unfolding has_field_derivative_def
   816   proof (rule has_derivative_sequence [OF cvs _ _ x])
   817     show "(\<lambda>n. f n x) \<longlonglongrightarrow> l"
   818       by (rule tf)
   819   next show "\<And>e. e > 0 \<Longrightarrow> \<forall>\<^sub>F n in sequentially. \<forall>x\<in>S. \<forall>h. cmod (f' n x * h - g' x * h) \<le> e * cmod h"
   820       unfolding eventually_sequentially by (blast intro: **)
   821   qed (metis has_field_derivative_def df)
   822 qed
   823 
   824 lemma has_complex_derivative_series:
   825   fixes S :: "complex set"
   826   assumes cvs: "convex S"
   827       and df:  "\<And>n x. x \<in> S \<Longrightarrow> (f n has_field_derivative f' n x) (at x within S)"
   828       and conv: "\<And>e. 0 < e \<Longrightarrow> \<exists>N. \<forall>n x. n \<ge> N \<longrightarrow> x \<in> S
   829                 \<longrightarrow> cmod ((\<Sum>i<n. f' i x) - g' x) \<le> e"
   830       and "\<exists>x l. x \<in> S \<and> ((\<lambda>n. f n x) sums l)"
   831     shows "\<exists>g. \<forall>x \<in> S. ((\<lambda>n. f n x) sums g x) \<and> ((g has_field_derivative g' x) (at x within S))"
   832 proof -
   833   from assms obtain x l where x: "x \<in> S" and sf: "((\<lambda>n. f n x) sums l)"
   834     by blast
   835   { fix e::real assume e: "e > 0"
   836     then obtain N where N: "\<forall>n x. n \<ge> N \<longrightarrow> x \<in> S
   837             \<longrightarrow> cmod ((\<Sum>i<n. f' i x) - g' x) \<le> e"
   838       by (metis conv)
   839     have "\<exists>N. \<forall>n\<ge>N. \<forall>x\<in>S. \<forall>h. cmod ((\<Sum>i<n. h * f' i x) - g' x * h) \<le> e * cmod h"
   840     proof (rule exI [of _ N], clarify)
   841       fix n y h
   842       assume "N \<le> n" "y \<in> S"
   843       then have "cmod ((\<Sum>i<n. f' i y) - g' y) \<le> e"
   844         by (metis N)
   845       then have "cmod h * cmod ((\<Sum>i<n. f' i y) - g' y) \<le> cmod h * e"
   846         by (auto simp: antisym_conv2 mult_le_cancel_left norm_triangle_ineq2)
   847       then show "cmod ((\<Sum>i<n. h * f' i y) - g' y * h) \<le> e * cmod h"
   848         by (simp add: norm_mult [symmetric] field_simps sum_distrib_left)
   849     qed
   850   } note ** = this
   851   show ?thesis
   852   unfolding has_field_derivative_def
   853   proof (rule has_derivative_series [OF cvs _ _ x])
   854     fix n x
   855     assume "x \<in> S"
   856     then show "((f n) has_derivative (\<lambda>z. z * f' n x)) (at x within S)"
   857       by (metis df has_field_derivative_def mult_commute_abs)
   858   next show " ((\<lambda>n. f n x) sums l)"
   859     by (rule sf)
   860   next show "\<And>e. e>0 \<Longrightarrow> \<forall>\<^sub>F n in sequentially. \<forall>x\<in>S. \<forall>h. cmod ((\<Sum>i<n. h * f' i x) - g' x * h) \<le> e * cmod h"
   861       unfolding eventually_sequentially by (blast intro: **)
   862   qed
   863 qed
   864 
   865 
   866 lemma field_differentiable_series:
   867   fixes f :: "nat \<Rightarrow> 'a::{real_normed_field,banach} \<Rightarrow> 'a"
   868   assumes "convex S" "open S"
   869   assumes "\<And>n x. x \<in> S \<Longrightarrow> (f n has_field_derivative f' n x) (at x)"
   870   assumes "uniformly_convergent_on S (\<lambda>n x. \<Sum>i<n. f' i x)"
   871   assumes "x0 \<in> S" "summable (\<lambda>n. f n x0)" and x: "x \<in> S"
   872   shows  "(\<lambda>x. \<Sum>n. f n x) field_differentiable (at x)"
   873 proof -
   874   from assms(4) obtain g' where A: "uniform_limit S (\<lambda>n x. \<Sum>i<n. f' i x) g' sequentially"
   875     unfolding uniformly_convergent_on_def by blast
   876   from x and \<open>open S\<close> have S: "at x within S = at x" by (rule at_within_open)
   877   have "\<exists>g. \<forall>x\<in>S. (\<lambda>n. f n x) sums g x \<and> (g has_field_derivative g' x) (at x within S)"
   878     by (intro has_field_derivative_series[of S f f' g' x0] assms A has_field_derivative_at_within)
   879   then obtain g where g: "\<And>x. x \<in> S \<Longrightarrow> (\<lambda>n. f n x) sums g x"
   880     "\<And>x. x \<in> S \<Longrightarrow> (g has_field_derivative g' x) (at x within S)" by blast
   881   from g(2)[OF x] have g': "(g has_derivative ( * ) (g' x)) (at x)"
   882     by (simp add: has_field_derivative_def S)
   883   have "((\<lambda>x. \<Sum>n. f n x) has_derivative ( * ) (g' x)) (at x)"
   884     by (rule has_derivative_transform_within_open[OF g' \<open>open S\<close> x])
   885        (insert g, auto simp: sums_iff)
   886   thus "(\<lambda>x. \<Sum>n. f n x) field_differentiable (at x)" unfolding differentiable_def
   887     by (auto simp: summable_def field_differentiable_def has_field_derivative_def)
   888 qed
   889 
   890 subsection\<open>Bound theorem\<close>
   891 
   892 lemma field_differentiable_bound:
   893   fixes S :: "'a::real_normed_field set"
   894   assumes cvs: "convex S"
   895       and df:  "\<And>z. z \<in> S \<Longrightarrow> (f has_field_derivative f' z) (at z within S)"
   896       and dn:  "\<And>z. z \<in> S \<Longrightarrow> norm (f' z) \<le> B"
   897       and "x \<in> S"  "y \<in> S"
   898     shows "norm(f x - f y) \<le> B * norm(x - y)"
   899   apply (rule differentiable_bound [OF cvs])
   900   apply (erule df [unfolded has_field_derivative_def])
   901   apply (rule onorm_le, simp_all add: norm_mult mult_right_mono assms)
   902   done
   903 
   904 subsection\<open>Inverse function theorem for complex derivatives\<close>
   905 
   906 lemma has_field_derivative_inverse_basic:
   907   shows "DERIV f (g y) :> f' \<Longrightarrow>
   908         f' \<noteq> 0 \<Longrightarrow>
   909         continuous (at y) g \<Longrightarrow>
   910         open t \<Longrightarrow>
   911         y \<in> t \<Longrightarrow>
   912         (\<And>z. z \<in> t \<Longrightarrow> f (g z) = z)
   913         \<Longrightarrow> DERIV g y :> inverse (f')"
   914   unfolding has_field_derivative_def
   915   apply (rule has_derivative_inverse_basic)
   916   apply (auto simp:  bounded_linear_mult_right)
   917   done
   918 
   919 lemma has_field_derivative_inverse_strong:
   920   fixes f :: "'a::{euclidean_space,real_normed_field} \<Rightarrow> 'a"
   921   shows "DERIV f x :> f' \<Longrightarrow>
   922          f' \<noteq> 0 \<Longrightarrow>
   923          open S \<Longrightarrow>
   924          x \<in> S \<Longrightarrow>
   925          continuous_on S f \<Longrightarrow>
   926          (\<And>z. z \<in> S \<Longrightarrow> g (f z) = z)
   927          \<Longrightarrow> DERIV g (f x) :> inverse (f')"
   928   unfolding has_field_derivative_def
   929   apply (rule has_derivative_inverse_strong [of S x f g ])
   930   by auto
   931 
   932 lemma has_field_derivative_inverse_strong_x:
   933   fixes f :: "'a::{euclidean_space,real_normed_field} \<Rightarrow> 'a"
   934   shows  "DERIV f (g y) :> f' \<Longrightarrow>
   935           f' \<noteq> 0 \<Longrightarrow>
   936           open S \<Longrightarrow>
   937           continuous_on S f \<Longrightarrow>
   938           g y \<in> S \<Longrightarrow> f(g y) = y \<Longrightarrow>
   939           (\<And>z. z \<in> S \<Longrightarrow> g (f z) = z)
   940           \<Longrightarrow> DERIV g y :> inverse (f')"
   941   unfolding has_field_derivative_def
   942   apply (rule has_derivative_inverse_strong_x [of S g y f])
   943   by auto
   944 
   945 subsection \<open>Taylor on Complex Numbers\<close>
   946 
   947 lemma sum_Suc_reindex:
   948   fixes f :: "nat \<Rightarrow> 'a::ab_group_add"
   949     shows  "sum f {0..n} = f 0 - f (Suc n) + sum (\<lambda>i. f (Suc i)) {0..n}"
   950 by (induct n) auto
   951 
   952 lemma field_taylor:
   953   assumes S: "convex S"
   954       and f: "\<And>i x. x \<in> S \<Longrightarrow> i \<le> n \<Longrightarrow> (f i has_field_derivative f (Suc i) x) (at x within S)"
   955       and B: "\<And>x. x \<in> S \<Longrightarrow> norm (f (Suc n) x) \<le> B"
   956       and w: "w \<in> S"
   957       and z: "z \<in> S"
   958     shows "norm(f 0 z - (\<Sum>i\<le>n. f i w * (z-w) ^ i / (fact i)))
   959           \<le> B * norm(z - w)^(Suc n) / fact n"
   960 proof -
   961   have wzs: "closed_segment w z \<subseteq> S" using assms
   962     by (metis convex_contains_segment)
   963   { fix u
   964     assume "u \<in> closed_segment w z"
   965     then have "u \<in> S"
   966       by (metis wzs subsetD)
   967     have "(\<Sum>i\<le>n. f i u * (- of_nat i * (z-u)^(i - 1)) / (fact i) +
   968                       f (Suc i) u * (z-u)^i / (fact i)) =
   969               f (Suc n) u * (z-u) ^ n / (fact n)"
   970     proof (induction n)
   971       case 0 show ?case by simp
   972     next
   973       case (Suc n)
   974       have "(\<Sum>i\<le>Suc n. f i u * (- of_nat i * (z-u) ^ (i - 1)) / (fact i) +
   975                              f (Suc i) u * (z-u) ^ i / (fact i)) =
   976            f (Suc n) u * (z-u) ^ n / (fact n) +
   977            f (Suc (Suc n)) u * ((z-u) * (z-u) ^ n) / (fact (Suc n)) -
   978            f (Suc n) u * ((1 + of_nat n) * (z-u) ^ n) / (fact (Suc n))"
   979         using Suc by simp
   980       also have "... = f (Suc (Suc n)) u * (z-u) ^ Suc n / (fact (Suc n))"
   981       proof -
   982         have "(fact(Suc n)) *
   983              (f(Suc n) u *(z-u) ^ n / (fact n) +
   984                f(Suc(Suc n)) u *((z-u) *(z-u) ^ n) / (fact(Suc n)) -
   985                f(Suc n) u *((1 + of_nat n) *(z-u) ^ n) / (fact(Suc n))) =
   986             ((fact(Suc n)) *(f(Suc n) u *(z-u) ^ n)) / (fact n) +
   987             ((fact(Suc n)) *(f(Suc(Suc n)) u *((z-u) *(z-u) ^ n)) / (fact(Suc n))) -
   988             ((fact(Suc n)) *(f(Suc n) u *(of_nat(Suc n) *(z-u) ^ n))) / (fact(Suc n))"
   989           by (simp add: algebra_simps del: fact_Suc)
   990         also have "... = ((fact (Suc n)) * (f (Suc n) u * (z-u) ^ n)) / (fact n) +
   991                          (f (Suc (Suc n)) u * ((z-u) * (z-u) ^ n)) -
   992                          (f (Suc n) u * ((1 + of_nat n) * (z-u) ^ n))"
   993           by (simp del: fact_Suc)
   994         also have "... = (of_nat (Suc n) * (f (Suc n) u * (z-u) ^ n)) +
   995                          (f (Suc (Suc n)) u * ((z-u) * (z-u) ^ n)) -
   996                          (f (Suc n) u * ((1 + of_nat n) * (z-u) ^ n))"
   997           by (simp only: fact_Suc of_nat_mult ac_simps) simp
   998         also have "... = f (Suc (Suc n)) u * ((z-u) * (z-u) ^ n)"
   999           by (simp add: algebra_simps)
  1000         finally show ?thesis
  1001         by (simp add: mult_left_cancel [where c = "(fact (Suc n))", THEN iffD1] del: fact_Suc)
  1002       qed
  1003       finally show ?case .
  1004     qed
  1005     then have "((\<lambda>v. (\<Sum>i\<le>n. f i v * (z - v)^i / (fact i)))
  1006                 has_field_derivative f (Suc n) u * (z-u) ^ n / (fact n))
  1007                (at u within S)"
  1008       apply (intro derivative_eq_intros)
  1009       apply (blast intro: assms \<open>u \<in> S\<close>)
  1010       apply (rule refl)+
  1011       apply (auto simp: field_simps)
  1012       done
  1013   } note sum_deriv = this
  1014   { fix u
  1015     assume u: "u \<in> closed_segment w z"
  1016     then have us: "u \<in> S"
  1017       by (metis wzs subsetD)
  1018     have "norm (f (Suc n) u) * norm (z - u) ^ n \<le> norm (f (Suc n) u) * norm (u - z) ^ n"
  1019       by (metis norm_minus_commute order_refl)
  1020     also have "... \<le> norm (f (Suc n) u) * norm (z - w) ^ n"
  1021       by (metis mult_left_mono norm_ge_zero power_mono segment_bound [OF u])
  1022     also have "... \<le> B * norm (z - w) ^ n"
  1023       by (metis norm_ge_zero zero_le_power mult_right_mono  B [OF us])
  1024     finally have "norm (f (Suc n) u) * norm (z - u) ^ n \<le> B * norm (z - w) ^ n" .
  1025   } note cmod_bound = this
  1026   have "(\<Sum>i\<le>n. f i z * (z - z) ^ i / (fact i)) = (\<Sum>i\<le>n. (f i z / (fact i)) * 0 ^ i)"
  1027     by simp
  1028   also have "\<dots> = f 0 z / (fact 0)"
  1029     by (subst sum_zero_power) simp
  1030   finally have "norm (f 0 z - (\<Sum>i\<le>n. f i w * (z - w) ^ i / (fact i)))
  1031                 \<le> norm ((\<Sum>i\<le>n. f i w * (z - w) ^ i / (fact i)) -
  1032                         (\<Sum>i\<le>n. f i z * (z - z) ^ i / (fact i)))"
  1033     by (simp add: norm_minus_commute)
  1034   also have "... \<le> B * norm (z - w) ^ n / (fact n) * norm (w - z)"
  1035     apply (rule field_differentiable_bound
  1036       [where f' = "\<lambda>w. f (Suc n) w * (z - w)^n / (fact n)"
  1037          and S = "closed_segment w z", OF convex_closed_segment])
  1038     apply (auto simp: ends_in_segment DERIV_subset [OF sum_deriv wzs]
  1039                   norm_divide norm_mult norm_power divide_le_cancel cmod_bound)
  1040     done
  1041   also have "...  \<le> B * norm (z - w) ^ Suc n / (fact n)"
  1042     by (simp add: algebra_simps norm_minus_commute)
  1043   finally show ?thesis .
  1044 qed
  1045 
  1046 lemma complex_taylor:
  1047   assumes S: "convex S"
  1048       and f: "\<And>i x. x \<in> S \<Longrightarrow> i \<le> n \<Longrightarrow> (f i has_field_derivative f (Suc i) x) (at x within S)"
  1049       and B: "\<And>x. x \<in> S \<Longrightarrow> cmod (f (Suc n) x) \<le> B"
  1050       and w: "w \<in> S"
  1051       and z: "z \<in> S"
  1052     shows "cmod(f 0 z - (\<Sum>i\<le>n. f i w * (z-w) ^ i / (fact i)))
  1053           \<le> B * cmod(z - w)^(Suc n) / fact n"
  1054   using assms by (rule field_taylor)
  1055 
  1056 
  1057 text\<open>Something more like the traditional MVT for real components\<close>
  1058 
  1059 lemma complex_mvt_line:
  1060   assumes "\<And>u. u \<in> closed_segment w z \<Longrightarrow> (f has_field_derivative f'(u)) (at u)"
  1061     shows "\<exists>u. u \<in> closed_segment w z \<and> Re(f z) - Re(f w) = Re(f'(u) * (z - w))"
  1062 proof -
  1063   have twz: "\<And>t. (1 - t) *\<^sub>R w + t *\<^sub>R z = w + t *\<^sub>R (z - w)"
  1064     by (simp add: real_vector.scale_left_diff_distrib real_vector.scale_right_diff_distrib)
  1065   note assms[unfolded has_field_derivative_def, derivative_intros]
  1066   show ?thesis
  1067     apply (cut_tac mvt_simple
  1068                      [of 0 1 "Re o f o (\<lambda>t. (1 - t) *\<^sub>R w +  t *\<^sub>R z)"
  1069                       "\<lambda>u. Re o (\<lambda>h. f'((1 - u) *\<^sub>R w + u *\<^sub>R z) * h) o (\<lambda>t. t *\<^sub>R (z - w))"])
  1070     apply auto
  1071     apply (rule_tac x="(1 - x) *\<^sub>R w + x *\<^sub>R z" in exI)
  1072     apply (auto simp: closed_segment_def twz) []
  1073     apply (intro derivative_eq_intros has_derivative_at_withinI, simp_all)
  1074     apply (simp add: fun_eq_iff real_vector.scale_right_diff_distrib)
  1075     apply (force simp: twz closed_segment_def)
  1076     done
  1077 qed
  1078 
  1079 lemma complex_taylor_mvt:
  1080   assumes "\<And>i x. \<lbrakk>x \<in> closed_segment w z; i \<le> n\<rbrakk> \<Longrightarrow> ((f i) has_field_derivative f (Suc i) x) (at x)"
  1081     shows "\<exists>u. u \<in> closed_segment w z \<and>
  1082             Re (f 0 z) =
  1083             Re ((\<Sum>i = 0..n. f i w * (z - w) ^ i / (fact i)) +
  1084                 (f (Suc n) u * (z-u)^n / (fact n)) * (z - w))"
  1085 proof -
  1086   { fix u
  1087     assume u: "u \<in> closed_segment w z"
  1088     have "(\<Sum>i = 0..n.
  1089                (f (Suc i) u * (z-u) ^ i - of_nat i * (f i u * (z-u) ^ (i - Suc 0))) /
  1090                (fact i)) =
  1091           f (Suc 0) u -
  1092              (f (Suc (Suc n)) u * ((z-u) ^ Suc n) - (of_nat (Suc n)) * (z-u) ^ n * f (Suc n) u) /
  1093              (fact (Suc n)) +
  1094              (\<Sum>i = 0..n.
  1095                  (f (Suc (Suc i)) u * ((z-u) ^ Suc i) - of_nat (Suc i) * (f (Suc i) u * (z-u) ^ i)) /
  1096                  (fact (Suc i)))"
  1097        by (subst sum_Suc_reindex) simp
  1098     also have "... = f (Suc 0) u -
  1099              (f (Suc (Suc n)) u * ((z-u) ^ Suc n) - (of_nat (Suc n)) * (z-u) ^ n * f (Suc n) u) /
  1100              (fact (Suc n)) +
  1101              (\<Sum>i = 0..n.
  1102                  f (Suc (Suc i)) u * ((z-u) ^ Suc i) / (fact (Suc i))  -
  1103                  f (Suc i) u * (z-u) ^ i / (fact i))"
  1104       by (simp only: diff_divide_distrib fact_cancel ac_simps)
  1105     also have "... = f (Suc 0) u -
  1106              (f (Suc (Suc n)) u * (z-u) ^ Suc n - of_nat (Suc n) * (z-u) ^ n * f (Suc n) u) /
  1107              (fact (Suc n)) +
  1108              f (Suc (Suc n)) u * (z-u) ^ Suc n / (fact (Suc n)) - f (Suc 0) u"
  1109       by (subst sum_Suc_diff) auto
  1110     also have "... = f (Suc n) u * (z-u) ^ n / (fact n)"
  1111       by (simp only: algebra_simps diff_divide_distrib fact_cancel)
  1112     finally have "(\<Sum>i = 0..n. (f (Suc i) u * (z - u) ^ i
  1113                              - of_nat i * (f i u * (z-u) ^ (i - Suc 0))) / (fact i)) =
  1114                   f (Suc n) u * (z - u) ^ n / (fact n)" .
  1115     then have "((\<lambda>u. \<Sum>i = 0..n. f i u * (z - u) ^ i / (fact i)) has_field_derivative
  1116                 f (Suc n) u * (z - u) ^ n / (fact n))  (at u)"
  1117       apply (intro derivative_eq_intros)+
  1118       apply (force intro: u assms)
  1119       apply (rule refl)+
  1120       apply (auto simp: ac_simps)
  1121       done
  1122   }
  1123   then show ?thesis
  1124     apply (cut_tac complex_mvt_line [of w z "\<lambda>u. \<Sum>i = 0..n. f i u * (z-u) ^ i / (fact i)"
  1125                "\<lambda>u. (f (Suc n) u * (z-u)^n / (fact n))"])
  1126     apply (auto simp add: intro: open_closed_segment)
  1127     done
  1128 qed
  1129 
  1130 
  1131 subsection \<open>Polynomal function extremal theorem, from HOL Light\<close>
  1132 
  1133 lemma polyfun_extremal_lemma: (*COMPLEX_POLYFUN_EXTREMAL_LEMMA in HOL Light*)
  1134     fixes c :: "nat \<Rightarrow> 'a::real_normed_div_algebra"
  1135   assumes "0 < e"
  1136     shows "\<exists>M. \<forall>z. M \<le> norm(z) \<longrightarrow> norm (\<Sum>i\<le>n. c(i) * z^i) \<le> e * norm(z) ^ (Suc n)"
  1137 proof (induct n)
  1138   case 0 with assms
  1139   show ?case
  1140     apply (rule_tac x="norm (c 0) / e" in exI)
  1141     apply (auto simp: field_simps)
  1142     done
  1143 next
  1144   case (Suc n)
  1145   obtain M where M: "\<And>z. M \<le> norm z \<Longrightarrow> norm (\<Sum>i\<le>n. c i * z^i) \<le> e * norm z ^ Suc n"
  1146     using Suc assms by blast
  1147   show ?case
  1148   proof (rule exI [where x= "max M (1 + norm(c(Suc n)) / e)"], clarsimp simp del: power_Suc)
  1149     fix z::'a
  1150     assume z1: "M \<le> norm z" and "1 + norm (c (Suc n)) / e \<le> norm z"
  1151     then have z2: "e + norm (c (Suc n)) \<le> e * norm z"
  1152       using assms by (simp add: field_simps)
  1153     have "norm (\<Sum>i\<le>n. c i * z^i) \<le> e * norm z ^ Suc n"
  1154       using M [OF z1] by simp
  1155     then have "norm (\<Sum>i\<le>n. c i * z^i) + norm (c (Suc n) * z ^ Suc n) \<le> e * norm z ^ Suc n + norm (c (Suc n) * z ^ Suc n)"
  1156       by simp
  1157     then have "norm ((\<Sum>i\<le>n. c i * z^i) + c (Suc n) * z ^ Suc n) \<le> e * norm z ^ Suc n + norm (c (Suc n) * z ^ Suc n)"
  1158       by (blast intro: norm_triangle_le elim: )
  1159     also have "... \<le> (e + norm (c (Suc n))) * norm z ^ Suc n"
  1160       by (simp add: norm_power norm_mult algebra_simps)
  1161     also have "... \<le> (e * norm z) * norm z ^ Suc n"
  1162       by (metis z2 mult.commute mult_left_mono norm_ge_zero norm_power)
  1163     finally show "norm ((\<Sum>i\<le>n. c i * z^i) + c (Suc n) * z ^ Suc n) \<le> e * norm z ^ Suc (Suc n)"
  1164       by simp
  1165   qed
  1166 qed
  1167 
  1168 lemma polyfun_extremal: (*COMPLEX_POLYFUN_EXTREMAL in HOL Light*)
  1169     fixes c :: "nat \<Rightarrow> 'a::real_normed_div_algebra"
  1170   assumes k: "c k \<noteq> 0" "1\<le>k" and kn: "k\<le>n"
  1171     shows "eventually (\<lambda>z. norm (\<Sum>i\<le>n. c(i) * z^i) \<ge> B) at_infinity"
  1172 using kn
  1173 proof (induction n)
  1174   case 0
  1175   then show ?case
  1176     using k  by simp
  1177 next
  1178   case (Suc m)
  1179   let ?even = ?case
  1180   show ?even
  1181   proof (cases "c (Suc m) = 0")
  1182     case True
  1183     then show ?even using Suc k
  1184       by auto (metis antisym_conv less_eq_Suc_le not_le)
  1185   next
  1186     case False
  1187     then obtain M where M:
  1188           "\<And>z. M \<le> norm z \<Longrightarrow> norm (\<Sum>i\<le>m. c i * z^i) \<le> norm (c (Suc m)) / 2 * norm z ^ Suc m"
  1189       using polyfun_extremal_lemma [of "norm(c (Suc m)) / 2" c m] Suc
  1190       by auto
  1191     have "\<exists>b. \<forall>z. b \<le> norm z \<longrightarrow> B \<le> norm (\<Sum>i\<le>Suc m. c i * z^i)"
  1192     proof (rule exI [where x="max M (max 1 (\<bar>B\<bar> / (norm(c (Suc m)) / 2)))"], clarsimp simp del: power_Suc)
  1193       fix z::'a
  1194       assume z1: "M \<le> norm z" "1 \<le> norm z"
  1195          and "\<bar>B\<bar> * 2 / norm (c (Suc m)) \<le> norm z"
  1196       then have z2: "\<bar>B\<bar> \<le> norm (c (Suc m)) * norm z / 2"
  1197         using False by (simp add: field_simps)
  1198       have nz: "norm z \<le> norm z ^ Suc m"
  1199         by (metis \<open>1 \<le> norm z\<close> One_nat_def less_eq_Suc_le power_increasing power_one_right zero_less_Suc)
  1200       have *: "\<And>y x. norm (c (Suc m)) * norm z / 2 \<le> norm y - norm x \<Longrightarrow> B \<le> norm (x + y)"
  1201         by (metis abs_le_iff add.commute norm_diff_ineq order_trans z2)
  1202       have "norm z * norm (c (Suc m)) + 2 * norm (\<Sum>i\<le>m. c i * z^i)
  1203             \<le> norm (c (Suc m)) * norm z + norm (c (Suc m)) * norm z ^ Suc m"
  1204         using M [of z] Suc z1  by auto
  1205       also have "... \<le> 2 * (norm (c (Suc m)) * norm z ^ Suc m)"
  1206         using nz by (simp add: mult_mono del: power_Suc)
  1207       finally show "B \<le> norm ((\<Sum>i\<le>m. c i * z^i) + c (Suc m) * z ^ Suc m)"
  1208         using Suc.IH
  1209         apply (auto simp: eventually_at_infinity)
  1210         apply (rule *)
  1211         apply (simp add: field_simps norm_mult norm_power)
  1212         done
  1213     qed
  1214     then show ?even
  1215       by (simp add: eventually_at_infinity)
  1216   qed
  1217 qed
  1218 
  1219 end