src/HOL/Real/RealDef.thy
author avigad
Wed Jul 13 19:49:07 2005 +0200 (2005-07-13)
changeset 16819 00d8f9300d13
parent 16417 9bc16273c2d4
child 16888 7cb4bcfa058e
permissions -rw-r--r--
Additions to the Real (and Hyperreal) libraries:
RealDef.thy: lemmas relating nats, ints, and reals
reversed direction of real_of_int_mult, etc. (now they agree with nat versions)
SEQ.thy and Series.thy: various additions
RComplete.thy: lemmas involving floor and ceiling
introduced natfloor and natceiling
Log.thy: various additions
     1 (*  Title       : Real/RealDef.thy
     2     ID          : $Id$
     3     Author      : Jacques D. Fleuriot
     4     Copyright   : 1998  University of Cambridge
     5     Conversion to Isar and new proofs by Lawrence C Paulson, 2003/4
     6     Additional contributions by Jeremy Avigad
     7 *)
     8 
     9 header{*Defining the Reals from the Positive Reals*}
    10 
    11 theory RealDef
    12 imports PReal
    13 uses ("real_arith.ML")
    14 begin
    15 
    16 constdefs
    17   realrel   ::  "((preal * preal) * (preal * preal)) set"
    18   "realrel == {p. \<exists>x1 y1 x2 y2. p = ((x1,y1),(x2,y2)) & x1+y2 = x2+y1}"
    19 
    20 typedef (Real)  real = "UNIV//realrel"
    21   by (auto simp add: quotient_def)
    22 
    23 instance real :: "{ord, zero, one, plus, times, minus, inverse}" ..
    24 
    25 constdefs
    26 
    27   (** these don't use the overloaded "real" function: users don't see them **)
    28 
    29   real_of_preal :: "preal => real"
    30   "real_of_preal m     ==
    31            Abs_Real(realrel``{(m + preal_of_rat 1, preal_of_rat 1)})"
    32 
    33 consts
    34    (*Overloaded constant denoting the Real subset of enclosing
    35      types such as hypreal and complex*)
    36    Reals :: "'a set"
    37 
    38    (*overloaded constant for injecting other types into "real"*)
    39    real :: "'a => real"
    40 
    41 syntax (xsymbols)
    42   Reals     :: "'a set"                   ("\<real>")
    43 
    44 
    45 defs (overloaded)
    46 
    47   real_zero_def:
    48   "0 == Abs_Real(realrel``{(preal_of_rat 1, preal_of_rat 1)})"
    49 
    50   real_one_def:
    51   "1 == Abs_Real(realrel``
    52                {(preal_of_rat 1 + preal_of_rat 1,
    53 		 preal_of_rat 1)})"
    54 
    55   real_minus_def:
    56   "- r ==  contents (\<Union>(x,y) \<in> Rep_Real(r). { Abs_Real(realrel``{(y,x)}) })"
    57 
    58   real_add_def:
    59    "z + w ==
    60        contents (\<Union>(x,y) \<in> Rep_Real(z). \<Union>(u,v) \<in> Rep_Real(w).
    61 		 { Abs_Real(realrel``{(x+u, y+v)}) })"
    62 
    63   real_diff_def:
    64    "r - (s::real) == r + - s"
    65 
    66   real_mult_def:
    67     "z * w ==
    68        contents (\<Union>(x,y) \<in> Rep_Real(z). \<Union>(u,v) \<in> Rep_Real(w).
    69 		 { Abs_Real(realrel``{(x*u + y*v, x*v + y*u)}) })"
    70 
    71   real_inverse_def:
    72   "inverse (R::real) == (SOME S. (R = 0 & S = 0) | S * R = 1)"
    73 
    74   real_divide_def:
    75   "R / (S::real) == R * inverse S"
    76 
    77   real_le_def:
    78    "z \<le> (w::real) == 
    79     \<exists>x y u v. x+v \<le> u+y & (x,y) \<in> Rep_Real z & (u,v) \<in> Rep_Real w"
    80 
    81   real_less_def: "(x < (y::real)) == (x \<le> y & x \<noteq> y)"
    82 
    83   real_abs_def:  "abs (r::real) == (if 0 \<le> r then r else -r)"
    84 
    85 
    86 
    87 subsection{*Proving that realrel is an equivalence relation*}
    88 
    89 lemma preal_trans_lemma:
    90   assumes "x + y1 = x1 + y"
    91       and "x + y2 = x2 + y"
    92   shows "x1 + y2 = x2 + (y1::preal)"
    93 proof -
    94   have "(x1 + y2) + x = (x + y2) + x1" by (simp add: preal_add_ac) 
    95   also have "... = (x2 + y) + x1"  by (simp add: prems)
    96   also have "... = x2 + (x1 + y)"  by (simp add: preal_add_ac)
    97   also have "... = x2 + (x + y1)"  by (simp add: prems)
    98   also have "... = (x2 + y1) + x"  by (simp add: preal_add_ac)
    99   finally have "(x1 + y2) + x = (x2 + y1) + x" .
   100   thus ?thesis by (simp add: preal_add_right_cancel_iff) 
   101 qed
   102 
   103 
   104 lemma realrel_iff [simp]: "(((x1,y1),(x2,y2)) \<in> realrel) = (x1 + y2 = x2 + y1)"
   105 by (simp add: realrel_def)
   106 
   107 lemma equiv_realrel: "equiv UNIV realrel"
   108 apply (auto simp add: equiv_def refl_def sym_def trans_def realrel_def)
   109 apply (blast dest: preal_trans_lemma) 
   110 done
   111 
   112 text{*Reduces equality of equivalence classes to the @{term realrel} relation:
   113   @{term "(realrel `` {x} = realrel `` {y}) = ((x,y) \<in> realrel)"} *}
   114 lemmas equiv_realrel_iff = 
   115        eq_equiv_class_iff [OF equiv_realrel UNIV_I UNIV_I]
   116 
   117 declare equiv_realrel_iff [simp]
   118 
   119 
   120 lemma realrel_in_real [simp]: "realrel``{(x,y)}: Real"
   121 by (simp add: Real_def realrel_def quotient_def, blast)
   122 
   123 
   124 lemma inj_on_Abs_Real: "inj_on Abs_Real Real"
   125 apply (rule inj_on_inverseI)
   126 apply (erule Abs_Real_inverse)
   127 done
   128 
   129 declare inj_on_Abs_Real [THEN inj_on_iff, simp]
   130 declare Abs_Real_inverse [simp]
   131 
   132 
   133 text{*Case analysis on the representation of a real number as an equivalence
   134       class of pairs of positive reals.*}
   135 lemma eq_Abs_Real [case_names Abs_Real, cases type: real]: 
   136      "(!!x y. z = Abs_Real(realrel``{(x,y)}) ==> P) ==> P"
   137 apply (rule Rep_Real [of z, unfolded Real_def, THEN quotientE])
   138 apply (drule arg_cong [where f=Abs_Real])
   139 apply (auto simp add: Rep_Real_inverse)
   140 done
   141 
   142 
   143 subsection{*Congruence property for addition*}
   144 
   145 lemma real_add_congruent2_lemma:
   146      "[|a + ba = aa + b; ab + bc = ac + bb|]
   147       ==> a + ab + (ba + bc) = aa + ac + (b + (bb::preal))"
   148 apply (simp add: preal_add_assoc) 
   149 apply (rule preal_add_left_commute [of ab, THEN ssubst])
   150 apply (simp add: preal_add_assoc [symmetric])
   151 apply (simp add: preal_add_ac)
   152 done
   153 
   154 lemma real_add:
   155      "Abs_Real (realrel``{(x,y)}) + Abs_Real (realrel``{(u,v)}) =
   156       Abs_Real (realrel``{(x+u, y+v)})"
   157 proof -
   158   have "(\<lambda>z w. (\<lambda>(x,y). (\<lambda>(u,v). {Abs_Real (realrel `` {(x+u, y+v)})}) w) z)
   159         respects2 realrel"
   160     by (simp add: congruent2_def, blast intro: real_add_congruent2_lemma) 
   161   thus ?thesis
   162     by (simp add: real_add_def UN_UN_split_split_eq
   163                   UN_equiv_class2 [OF equiv_realrel equiv_realrel])
   164 qed
   165 
   166 lemma real_add_commute: "(z::real) + w = w + z"
   167 by (cases z, cases w, simp add: real_add preal_add_ac)
   168 
   169 lemma real_add_assoc: "((z1::real) + z2) + z3 = z1 + (z2 + z3)"
   170 by (cases z1, cases z2, cases z3, simp add: real_add preal_add_assoc)
   171 
   172 lemma real_add_zero_left: "(0::real) + z = z"
   173 by (cases z, simp add: real_add real_zero_def preal_add_ac)
   174 
   175 instance real :: comm_monoid_add
   176   by (intro_classes,
   177       (assumption | 
   178        rule real_add_commute real_add_assoc real_add_zero_left)+)
   179 
   180 
   181 subsection{*Additive Inverse on real*}
   182 
   183 lemma real_minus: "- Abs_Real(realrel``{(x,y)}) = Abs_Real(realrel `` {(y,x)})"
   184 proof -
   185   have "(\<lambda>(x,y). {Abs_Real (realrel``{(y,x)})}) respects realrel"
   186     by (simp add: congruent_def preal_add_commute) 
   187   thus ?thesis
   188     by (simp add: real_minus_def UN_equiv_class [OF equiv_realrel])
   189 qed
   190 
   191 lemma real_add_minus_left: "(-z) + z = (0::real)"
   192 by (cases z, simp add: real_minus real_add real_zero_def preal_add_commute)
   193 
   194 
   195 subsection{*Congruence property for multiplication*}
   196 
   197 lemma real_mult_congruent2_lemma:
   198      "!!(x1::preal). [| x1 + y2 = x2 + y1 |] ==>
   199           x * x1 + y * y1 + (x * y2 + y * x2) =
   200           x * x2 + y * y2 + (x * y1 + y * x1)"
   201 apply (simp add: preal_add_left_commute preal_add_assoc [symmetric])
   202 apply (simp add: preal_add_assoc preal_add_mult_distrib2 [symmetric])
   203 apply (simp add: preal_add_commute)
   204 done
   205 
   206 lemma real_mult_congruent2:
   207     "(%p1 p2.
   208         (%(x1,y1). (%(x2,y2). 
   209           { Abs_Real (realrel``{(x1*x2 + y1*y2, x1*y2+y1*x2)}) }) p2) p1)
   210      respects2 realrel"
   211 apply (rule congruent2_commuteI [OF equiv_realrel], clarify)
   212 apply (simp add: preal_mult_commute preal_add_commute)
   213 apply (auto simp add: real_mult_congruent2_lemma)
   214 done
   215 
   216 lemma real_mult:
   217       "Abs_Real((realrel``{(x1,y1)})) * Abs_Real((realrel``{(x2,y2)})) =
   218        Abs_Real(realrel `` {(x1*x2+y1*y2,x1*y2+y1*x2)})"
   219 by (simp add: real_mult_def UN_UN_split_split_eq
   220          UN_equiv_class2 [OF equiv_realrel equiv_realrel real_mult_congruent2])
   221 
   222 lemma real_mult_commute: "(z::real) * w = w * z"
   223 by (cases z, cases w, simp add: real_mult preal_add_ac preal_mult_ac)
   224 
   225 lemma real_mult_assoc: "((z1::real) * z2) * z3 = z1 * (z2 * z3)"
   226 apply (cases z1, cases z2, cases z3)
   227 apply (simp add: real_mult preal_add_mult_distrib2 preal_add_ac preal_mult_ac)
   228 done
   229 
   230 lemma real_mult_1: "(1::real) * z = z"
   231 apply (cases z)
   232 apply (simp add: real_mult real_one_def preal_add_mult_distrib2
   233                  preal_mult_1_right preal_mult_ac preal_add_ac)
   234 done
   235 
   236 lemma real_add_mult_distrib: "((z1::real) + z2) * w = (z1 * w) + (z2 * w)"
   237 apply (cases z1, cases z2, cases w)
   238 apply (simp add: real_add real_mult preal_add_mult_distrib2 
   239                  preal_add_ac preal_mult_ac)
   240 done
   241 
   242 text{*one and zero are distinct*}
   243 lemma real_zero_not_eq_one: "0 \<noteq> (1::real)"
   244 proof -
   245   have "preal_of_rat 1 < preal_of_rat 1 + preal_of_rat 1"
   246     by (simp add: preal_self_less_add_left) 
   247   thus ?thesis
   248     by (simp add: real_zero_def real_one_def preal_add_right_cancel_iff)
   249 qed
   250 
   251 subsection{*existence of inverse*}
   252 
   253 lemma real_zero_iff: "Abs_Real (realrel `` {(x, x)}) = 0"
   254 by (simp add: real_zero_def preal_add_commute)
   255 
   256 text{*Instead of using an existential quantifier and constructing the inverse
   257 within the proof, we could define the inverse explicitly.*}
   258 
   259 lemma real_mult_inverse_left_ex: "x \<noteq> 0 ==> \<exists>y. y*x = (1::real)"
   260 apply (simp add: real_zero_def real_one_def, cases x)
   261 apply (cut_tac x = xa and y = y in linorder_less_linear)
   262 apply (auto dest!: less_add_left_Ex simp add: real_zero_iff)
   263 apply (rule_tac
   264         x = "Abs_Real (realrel `` { (preal_of_rat 1, 
   265                             inverse (D) + preal_of_rat 1)}) " 
   266        in exI)
   267 apply (rule_tac [2]
   268         x = "Abs_Real (realrel `` { (inverse (D) + preal_of_rat 1,
   269                    preal_of_rat 1)})" 
   270        in exI)
   271 apply (auto simp add: real_mult preal_mult_1_right
   272               preal_add_mult_distrib2 preal_add_mult_distrib preal_mult_1
   273               preal_mult_inverse_right preal_add_ac preal_mult_ac)
   274 done
   275 
   276 lemma real_mult_inverse_left: "x \<noteq> 0 ==> inverse(x)*x = (1::real)"
   277 apply (simp add: real_inverse_def)
   278 apply (frule real_mult_inverse_left_ex, safe)
   279 apply (rule someI2, auto)
   280 done
   281 
   282 
   283 subsection{*The Real Numbers form a Field*}
   284 
   285 instance real :: field
   286 proof
   287   fix x y z :: real
   288   show "- x + x = 0" by (rule real_add_minus_left)
   289   show "x - y = x + (-y)" by (simp add: real_diff_def)
   290   show "(x * y) * z = x * (y * z)" by (rule real_mult_assoc)
   291   show "x * y = y * x" by (rule real_mult_commute)
   292   show "1 * x = x" by (rule real_mult_1)
   293   show "(x + y) * z = x * z + y * z" by (simp add: real_add_mult_distrib)
   294   show "0 \<noteq> (1::real)" by (rule real_zero_not_eq_one)
   295   show "x \<noteq> 0 ==> inverse x * x = 1" by (rule real_mult_inverse_left)
   296   show "x / y = x * inverse y" by (simp add: real_divide_def)
   297 qed
   298 
   299 
   300 text{*Inverse of zero!  Useful to simplify certain equations*}
   301 
   302 lemma INVERSE_ZERO: "inverse 0 = (0::real)"
   303 by (simp add: real_inverse_def)
   304 
   305 instance real :: division_by_zero
   306 proof
   307   show "inverse 0 = (0::real)" by (rule INVERSE_ZERO)
   308 qed
   309 
   310 
   311 (*Pull negations out*)
   312 declare minus_mult_right [symmetric, simp] 
   313         minus_mult_left [symmetric, simp]
   314 
   315 lemma real_mult_1_right: "z * (1::real) = z"
   316   by (rule OrderedGroup.mult_1_right)
   317 
   318 
   319 subsection{*The @{text "\<le>"} Ordering*}
   320 
   321 lemma real_le_refl: "w \<le> (w::real)"
   322 by (cases w, force simp add: real_le_def)
   323 
   324 text{*The arithmetic decision procedure is not set up for type preal.
   325   This lemma is currently unused, but it could simplify the proofs of the
   326   following two lemmas.*}
   327 lemma preal_eq_le_imp_le:
   328   assumes eq: "a+b = c+d" and le: "c \<le> a"
   329   shows "b \<le> (d::preal)"
   330 proof -
   331   have "c+d \<le> a+d" by (simp add: prems preal_cancels)
   332   hence "a+b \<le> a+d" by (simp add: prems)
   333   thus "b \<le> d" by (simp add: preal_cancels)
   334 qed
   335 
   336 lemma real_le_lemma:
   337   assumes l: "u1 + v2 \<le> u2 + v1"
   338       and "x1 + v1 = u1 + y1"
   339       and "x2 + v2 = u2 + y2"
   340   shows "x1 + y2 \<le> x2 + (y1::preal)"
   341 proof -
   342   have "(x1+v1) + (u2+y2) = (u1+y1) + (x2+v2)" by (simp add: prems)
   343   hence "(x1+y2) + (u2+v1) = (x2+y1) + (u1+v2)" by (simp add: preal_add_ac)
   344   also have "... \<le> (x2+y1) + (u2+v1)"
   345          by (simp add: prems preal_add_le_cancel_left)
   346   finally show ?thesis by (simp add: preal_add_le_cancel_right)
   347 qed						 
   348 
   349 lemma real_le: 
   350      "(Abs_Real(realrel``{(x1,y1)}) \<le> Abs_Real(realrel``{(x2,y2)})) =  
   351       (x1 + y2 \<le> x2 + y1)"
   352 apply (simp add: real_le_def) 
   353 apply (auto intro: real_le_lemma)
   354 done
   355 
   356 lemma real_le_anti_sym: "[| z \<le> w; w \<le> z |] ==> z = (w::real)"
   357 by (cases z, cases w, simp add: real_le)
   358 
   359 lemma real_trans_lemma:
   360   assumes "x + v \<le> u + y"
   361       and "u + v' \<le> u' + v"
   362       and "x2 + v2 = u2 + y2"
   363   shows "x + v' \<le> u' + (y::preal)"
   364 proof -
   365   have "(x+v') + (u+v) = (x+v) + (u+v')" by (simp add: preal_add_ac)
   366   also have "... \<le> (u+y) + (u+v')" 
   367     by (simp add: preal_add_le_cancel_right prems) 
   368   also have "... \<le> (u+y) + (u'+v)" 
   369     by (simp add: preal_add_le_cancel_left prems) 
   370   also have "... = (u'+y) + (u+v)"  by (simp add: preal_add_ac)
   371   finally show ?thesis by (simp add: preal_add_le_cancel_right)
   372 qed
   373 
   374 lemma real_le_trans: "[| i \<le> j; j \<le> k |] ==> i \<le> (k::real)"
   375 apply (cases i, cases j, cases k)
   376 apply (simp add: real_le)
   377 apply (blast intro: real_trans_lemma) 
   378 done
   379 
   380 (* Axiom 'order_less_le' of class 'order': *)
   381 lemma real_less_le: "((w::real) < z) = (w \<le> z & w \<noteq> z)"
   382 by (simp add: real_less_def)
   383 
   384 instance real :: order
   385 proof qed
   386  (assumption |
   387   rule real_le_refl real_le_trans real_le_anti_sym real_less_le)+
   388 
   389 (* Axiom 'linorder_linear' of class 'linorder': *)
   390 lemma real_le_linear: "(z::real) \<le> w | w \<le> z"
   391 apply (cases z, cases w) 
   392 apply (auto simp add: real_le real_zero_def preal_add_ac preal_cancels)
   393 done
   394 
   395 
   396 instance real :: linorder
   397   by (intro_classes, rule real_le_linear)
   398 
   399 
   400 lemma real_le_eq_diff: "(x \<le> y) = (x-y \<le> (0::real))"
   401 apply (cases x, cases y) 
   402 apply (auto simp add: real_le real_zero_def real_diff_def real_add real_minus
   403                       preal_add_ac)
   404 apply (simp_all add: preal_add_assoc [symmetric] preal_cancels)
   405 done
   406 
   407 lemma real_add_left_mono: 
   408   assumes le: "x \<le> y" shows "z + x \<le> z + (y::real)"
   409 proof -
   410   have "z + x - (z + y) = (z + -z) + (x - y)"
   411     by (simp add: diff_minus add_ac) 
   412   with le show ?thesis 
   413     by (simp add: real_le_eq_diff[of x] real_le_eq_diff[of "z+x"] diff_minus)
   414 qed
   415 
   416 lemma real_sum_gt_zero_less: "(0 < S + (-W::real)) ==> (W < S)"
   417 by (simp add: linorder_not_le [symmetric] real_le_eq_diff [of S] diff_minus)
   418 
   419 lemma real_less_sum_gt_zero: "(W < S) ==> (0 < S + (-W::real))"
   420 by (simp add: linorder_not_le [symmetric] real_le_eq_diff [of S] diff_minus)
   421 
   422 lemma real_mult_order: "[| 0 < x; 0 < y |] ==> (0::real) < x * y"
   423 apply (cases x, cases y)
   424 apply (simp add: linorder_not_le [where 'a = real, symmetric] 
   425                  linorder_not_le [where 'a = preal] 
   426                   real_zero_def real_le real_mult)
   427   --{*Reduce to the (simpler) @{text "\<le>"} relation *}
   428 apply (auto  dest!: less_add_left_Ex 
   429      simp add: preal_add_ac preal_mult_ac 
   430           preal_add_mult_distrib2 preal_cancels preal_self_less_add_right)
   431 done
   432 
   433 lemma real_mult_less_mono2: "[| (0::real) < z; x < y |] ==> z * x < z * y"
   434 apply (rule real_sum_gt_zero_less)
   435 apply (drule real_less_sum_gt_zero [of x y])
   436 apply (drule real_mult_order, assumption)
   437 apply (simp add: right_distrib)
   438 done
   439 
   440 text{*lemma for proving @{term "0<(1::real)"}*}
   441 lemma real_zero_le_one: "0 \<le> (1::real)"
   442 by (simp add: real_zero_def real_one_def real_le 
   443                  preal_self_less_add_left order_less_imp_le)
   444 
   445 
   446 subsection{*The Reals Form an Ordered Field*}
   447 
   448 instance real :: ordered_field
   449 proof
   450   fix x y z :: real
   451   show "x \<le> y ==> z + x \<le> z + y" by (rule real_add_left_mono)
   452   show "x < y ==> 0 < z ==> z * x < z * y" by (simp add: real_mult_less_mono2)
   453   show "\<bar>x\<bar> = (if x < 0 then -x else x)"
   454     by (auto dest: order_le_less_trans simp add: real_abs_def linorder_not_le)
   455 qed
   456 
   457 
   458 
   459 text{*The function @{term real_of_preal} requires many proofs, but it seems
   460 to be essential for proving completeness of the reals from that of the
   461 positive reals.*}
   462 
   463 lemma real_of_preal_add:
   464      "real_of_preal ((x::preal) + y) = real_of_preal x + real_of_preal y"
   465 by (simp add: real_of_preal_def real_add preal_add_mult_distrib preal_mult_1 
   466               preal_add_ac)
   467 
   468 lemma real_of_preal_mult:
   469      "real_of_preal ((x::preal) * y) = real_of_preal x* real_of_preal y"
   470 by (simp add: real_of_preal_def real_mult preal_add_mult_distrib2
   471               preal_mult_1 preal_mult_1_right preal_add_ac preal_mult_ac)
   472 
   473 
   474 text{*Gleason prop 9-4.4 p 127*}
   475 lemma real_of_preal_trichotomy:
   476       "\<exists>m. (x::real) = real_of_preal m | x = 0 | x = -(real_of_preal m)"
   477 apply (simp add: real_of_preal_def real_zero_def, cases x)
   478 apply (auto simp add: real_minus preal_add_ac)
   479 apply (cut_tac x = x and y = y in linorder_less_linear)
   480 apply (auto dest!: less_add_left_Ex simp add: preal_add_assoc [symmetric])
   481 apply (auto simp add: preal_add_commute)
   482 done
   483 
   484 lemma real_of_preal_leD:
   485       "real_of_preal m1 \<le> real_of_preal m2 ==> m1 \<le> m2"
   486 by (simp add: real_of_preal_def real_le preal_cancels)
   487 
   488 lemma real_of_preal_lessI: "m1 < m2 ==> real_of_preal m1 < real_of_preal m2"
   489 by (auto simp add: real_of_preal_leD linorder_not_le [symmetric])
   490 
   491 lemma real_of_preal_lessD:
   492       "real_of_preal m1 < real_of_preal m2 ==> m1 < m2"
   493 by (simp add: real_of_preal_def real_le linorder_not_le [symmetric] 
   494               preal_cancels) 
   495 
   496 
   497 lemma real_of_preal_less_iff [simp]:
   498      "(real_of_preal m1 < real_of_preal m2) = (m1 < m2)"
   499 by (blast intro: real_of_preal_lessI real_of_preal_lessD)
   500 
   501 lemma real_of_preal_le_iff:
   502      "(real_of_preal m1 \<le> real_of_preal m2) = (m1 \<le> m2)"
   503 by (simp add: linorder_not_less [symmetric]) 
   504 
   505 lemma real_of_preal_zero_less: "0 < real_of_preal m"
   506 apply (auto simp add: real_zero_def real_of_preal_def real_less_def real_le_def
   507             preal_add_ac preal_cancels)
   508 apply (simp_all add: preal_add_assoc [symmetric] preal_cancels)
   509 apply (blast intro: preal_self_less_add_left order_less_imp_le)
   510 apply (insert preal_not_eq_self [of "preal_of_rat 1" m]) 
   511 apply (simp add: preal_add_ac) 
   512 done
   513 
   514 lemma real_of_preal_minus_less_zero: "- real_of_preal m < 0"
   515 by (simp add: real_of_preal_zero_less)
   516 
   517 lemma real_of_preal_not_minus_gt_zero: "~ 0 < - real_of_preal m"
   518 proof -
   519   from real_of_preal_minus_less_zero
   520   show ?thesis by (blast dest: order_less_trans)
   521 qed
   522 
   523 
   524 subsection{*Theorems About the Ordering*}
   525 
   526 text{*obsolete but used a lot*}
   527 
   528 lemma real_not_refl2: "x < y ==> x \<noteq> (y::real)"
   529 by blast 
   530 
   531 lemma real_le_imp_less_or_eq: "!!(x::real). x \<le> y ==> x < y | x = y"
   532 by (simp add: order_le_less)
   533 
   534 lemma real_gt_zero_preal_Ex: "(0 < x) = (\<exists>y. x = real_of_preal y)"
   535 apply (auto simp add: real_of_preal_zero_less)
   536 apply (cut_tac x = x in real_of_preal_trichotomy)
   537 apply (blast elim!: real_of_preal_not_minus_gt_zero [THEN notE])
   538 done
   539 
   540 lemma real_gt_preal_preal_Ex:
   541      "real_of_preal z < x ==> \<exists>y. x = real_of_preal y"
   542 by (blast dest!: real_of_preal_zero_less [THEN order_less_trans]
   543              intro: real_gt_zero_preal_Ex [THEN iffD1])
   544 
   545 lemma real_ge_preal_preal_Ex:
   546      "real_of_preal z \<le> x ==> \<exists>y. x = real_of_preal y"
   547 by (blast dest: order_le_imp_less_or_eq real_gt_preal_preal_Ex)
   548 
   549 lemma real_less_all_preal: "y \<le> 0 ==> \<forall>x. y < real_of_preal x"
   550 by (auto elim: order_le_imp_less_or_eq [THEN disjE] 
   551             intro: real_of_preal_zero_less [THEN [2] order_less_trans] 
   552             simp add: real_of_preal_zero_less)
   553 
   554 lemma real_less_all_real2: "~ 0 < y ==> \<forall>x. y < real_of_preal x"
   555 by (blast intro!: real_less_all_preal linorder_not_less [THEN iffD1])
   556 
   557 lemma real_add_less_le_mono: "[| w'<w; z'\<le>z |] ==> w' + z' < w + (z::real)"
   558   by (rule OrderedGroup.add_less_le_mono)
   559 
   560 lemma real_add_le_less_mono:
   561      "!!z z'::real. [| w'\<le>w; z'<z |] ==> w' + z' < w + z"
   562   by (rule OrderedGroup.add_le_less_mono)
   563 
   564 lemma real_le_square [simp]: "(0::real) \<le> x*x"
   565  by (rule Ring_and_Field.zero_le_square)
   566 
   567 
   568 subsection{*More Lemmas*}
   569 
   570 lemma real_mult_left_cancel: "(c::real) \<noteq> 0 ==> (c*a=c*b) = (a=b)"
   571 by auto
   572 
   573 lemma real_mult_right_cancel: "(c::real) \<noteq> 0 ==> (a*c=b*c) = (a=b)"
   574 by auto
   575 
   576 text{*The precondition could be weakened to @{term "0\<le>x"}*}
   577 lemma real_mult_less_mono:
   578      "[| u<v;  x<y;  (0::real) < v;  0 < x |] ==> u*x < v* y"
   579  by (simp add: Ring_and_Field.mult_strict_mono order_less_imp_le)
   580 
   581 lemma real_mult_less_iff1 [simp]: "(0::real) < z ==> (x*z < y*z) = (x < y)"
   582   by (force elim: order_less_asym
   583             simp add: Ring_and_Field.mult_less_cancel_right)
   584 
   585 lemma real_mult_le_cancel_iff1 [simp]: "(0::real) < z ==> (x*z \<le> y*z) = (x\<le>y)"
   586 apply (simp add: mult_le_cancel_right)
   587 apply (blast intro: elim: order_less_asym) 
   588 done
   589 
   590 lemma real_mult_le_cancel_iff2 [simp]: "(0::real) < z ==> (z*x \<le> z*y) = (x\<le>y)"
   591 by(simp add:mult_commute)
   592 
   593 text{*Only two uses?*}
   594 lemma real_mult_less_mono':
   595      "[| x < y;  r1 < r2;  (0::real) \<le> r1;  0 \<le> x|] ==> r1 * x < r2 * y"
   596  by (rule Ring_and_Field.mult_strict_mono')
   597 
   598 text{*FIXME: delete or at least combine the next two lemmas*}
   599 lemma real_sum_squares_cancel: "x * x + y * y = 0 ==> x = (0::real)"
   600 apply (drule OrderedGroup.equals_zero_I [THEN sym])
   601 apply (cut_tac x = y in real_le_square) 
   602 apply (auto, drule order_antisym, auto)
   603 done
   604 
   605 lemma real_sum_squares_cancel2: "x * x + y * y = 0 ==> y = (0::real)"
   606 apply (rule_tac y = x in real_sum_squares_cancel)
   607 apply (simp add: add_commute)
   608 done
   609 
   610 lemma real_add_order: "[| 0 < x; 0 < y |] ==> (0::real) < x + y"
   611 by (drule add_strict_mono [of concl: 0 0], assumption, simp)
   612 
   613 lemma real_le_add_order: "[| 0 \<le> x; 0 \<le> y |] ==> (0::real) \<le> x + y"
   614 apply (drule order_le_imp_less_or_eq)+
   615 apply (auto intro: real_add_order order_less_imp_le)
   616 done
   617 
   618 lemma real_inverse_unique: "x*y = (1::real) ==> y = inverse x"
   619 apply (case_tac "x \<noteq> 0")
   620 apply (rule_tac c1 = x in real_mult_left_cancel [THEN iffD1], auto)
   621 done
   622 
   623 lemma real_inverse_gt_one: "[| (0::real) < x; x < 1 |] ==> 1 < inverse x"
   624 by (auto dest: less_imp_inverse_less)
   625 
   626 lemma real_mult_self_sum_ge_zero: "(0::real) \<le> x*x + y*y"
   627 proof -
   628   have "0 + 0 \<le> x*x + y*y" by (blast intro: add_mono zero_le_square)
   629   thus ?thesis by simp
   630 qed
   631 
   632 
   633 subsection{*Embedding the Integers into the Reals*}
   634 
   635 defs (overloaded)
   636   real_of_nat_def: "real z == of_nat z"
   637   real_of_int_def: "real z == of_int z"
   638 
   639 lemma real_eq_of_nat: "real = of_nat"
   640   apply (rule ext)
   641   apply (unfold real_of_nat_def)
   642   apply (rule refl)
   643   done
   644 
   645 lemma real_eq_of_int: "real = of_int"
   646   apply (rule ext)
   647   apply (unfold real_of_int_def)
   648   apply (rule refl)
   649   done
   650 
   651 lemma real_of_int_zero [simp]: "real (0::int) = 0"  
   652 by (simp add: real_of_int_def) 
   653 
   654 lemma real_of_one [simp]: "real (1::int) = (1::real)"
   655 by (simp add: real_of_int_def) 
   656 
   657 lemma real_of_int_add [simp]: "real(x + y) = real (x::int) + real y"
   658 by (simp add: real_of_int_def) 
   659 
   660 lemma real_of_int_minus [simp]: "real(-x) = -real (x::int)"
   661 by (simp add: real_of_int_def) 
   662 
   663 lemma real_of_int_diff [simp]: "real(x - y) = real (x::int) - real y"
   664 by (simp add: real_of_int_def) 
   665 
   666 lemma real_of_int_mult [simp]: "real(x * y) = real (x::int) * real y"
   667 by (simp add: real_of_int_def) 
   668 
   669 lemma real_of_int_setsum [simp]: "real ((SUM x:A. f x)::int) = (SUM x:A. real(f x))"
   670   apply (subst real_eq_of_int)+
   671   apply (rule of_int_setsum)
   672 done
   673 
   674 lemma real_of_int_setprod [simp]: "real ((PROD x:A. f x)::int) = 
   675     (PROD x:A. real(f x))"
   676   apply (subst real_eq_of_int)+
   677   apply (rule of_int_setprod)
   678 done
   679 
   680 lemma real_of_int_zero_cancel [simp]: "(real x = 0) = (x = (0::int))"
   681 by (simp add: real_of_int_def) 
   682 
   683 lemma real_of_int_inject [iff]: "(real (x::int) = real y) = (x = y)"
   684 by (simp add: real_of_int_def) 
   685 
   686 lemma real_of_int_less_iff [iff]: "(real (x::int) < real y) = (x < y)"
   687 by (simp add: real_of_int_def) 
   688 
   689 lemma real_of_int_le_iff [simp]: "(real (x::int) \<le> real y) = (x \<le> y)"
   690 by (simp add: real_of_int_def) 
   691 
   692 lemma real_of_int_gt_zero_cancel_iff [simp]: "(0 < real (n::int)) = (0 < n)"
   693 by (simp add: real_of_int_def) 
   694 
   695 lemma real_of_int_ge_zero_cancel_iff [simp]: "(0 <= real (n::int)) = (0 <= n)"
   696 by (simp add: real_of_int_def) 
   697 
   698 lemma real_of_int_lt_zero_cancel_iff [simp]: "(real (n::int) < 0) = (n < 0)"
   699 by (simp add: real_of_int_def)
   700 
   701 lemma real_of_int_le_zero_cancel_iff [simp]: "(real (n::int) <= 0) = (n <= 0)"
   702 by (simp add: real_of_int_def)
   703 
   704 lemma int_less_real_le: "((n::int) < m) = (real n + 1 <= real m)"
   705   apply (subgoal_tac "real n + 1 = real (n + 1)")
   706   apply (simp del: real_of_int_add)
   707   apply auto
   708 done
   709 
   710 lemma int_le_real_less: "((n::int) <= m) = (real n < real m + 1)"
   711   apply (subgoal_tac "real m + 1 = real (m + 1)")
   712   apply (simp del: real_of_int_add)
   713   apply simp
   714 done
   715 
   716 lemma real_of_int_div_aux: "d ~= 0 ==> (real (x::int)) / (real d) = 
   717     real (x div d) + (real (x mod d)) / (real d)"
   718 proof -
   719   assume "d ~= 0"
   720   have "x = (x div d) * d + x mod d"
   721     by auto
   722   then have "real x = real (x div d) * real d + real(x mod d)"
   723     by (simp only: real_of_int_mult [THEN sym] real_of_int_add [THEN sym])
   724   then have "real x / real d = ... / real d"
   725     by simp
   726   then show ?thesis
   727     by (auto simp add: add_divide_distrib ring_eq_simps prems)
   728 qed
   729 
   730 lemma real_of_int_div: "(d::int) ~= 0 ==> d dvd n ==>
   731     real(n div d) = real n / real d"
   732   apply (frule real_of_int_div_aux [of d n])
   733   apply simp
   734   apply (simp add: zdvd_iff_zmod_eq_0)
   735 done
   736 
   737 lemma real_of_int_div2:
   738   "0 <= real (n::int) / real (x) - real (n div x)"
   739   apply (case_tac "x = 0")
   740   apply simp
   741   apply (case_tac "0 < x")
   742   apply (simp add: compare_rls)
   743   apply (subst real_of_int_div_aux)
   744   apply simp
   745   apply simp
   746   apply (subst zero_le_divide_iff)
   747   apply auto
   748   apply (simp add: compare_rls)
   749   apply (subst real_of_int_div_aux)
   750   apply simp
   751   apply simp
   752   apply (subst zero_le_divide_iff)
   753   apply auto
   754 done
   755 
   756 lemma real_of_int_div3:
   757   "real (n::int) / real (x) - real (n div x) <= 1"
   758   apply(case_tac "x = 0")
   759   apply simp
   760   apply (simp add: compare_rls)
   761   apply (subst real_of_int_div_aux)
   762   apply assumption
   763   apply simp
   764   apply (subst divide_le_eq)
   765   apply clarsimp
   766   apply (rule conjI)
   767   apply (rule impI)
   768   apply (rule order_less_imp_le)
   769   apply simp
   770   apply (rule impI)
   771   apply (rule order_less_imp_le)
   772   apply simp
   773 done
   774 
   775 lemma real_of_int_div4: "real (n div x) <= real (n::int) / real x" 
   776   by (insert real_of_int_div2 [of n x], simp)
   777 
   778 subsection{*Embedding the Naturals into the Reals*}
   779 
   780 lemma real_of_nat_zero [simp]: "real (0::nat) = 0"
   781 by (simp add: real_of_nat_def)
   782 
   783 lemma real_of_nat_one [simp]: "real (Suc 0) = (1::real)"
   784 by (simp add: real_of_nat_def)
   785 
   786 lemma real_of_nat_add [simp]: "real (m + n) = real (m::nat) + real n"
   787 by (simp add: real_of_nat_def)
   788 
   789 (*Not for addsimps: often the LHS is used to represent a positive natural*)
   790 lemma real_of_nat_Suc: "real (Suc n) = real n + (1::real)"
   791 by (simp add: real_of_nat_def)
   792 
   793 lemma real_of_nat_less_iff [iff]: 
   794      "(real (n::nat) < real m) = (n < m)"
   795 by (simp add: real_of_nat_def)
   796 
   797 lemma real_of_nat_le_iff [iff]: "(real (n::nat) \<le> real m) = (n \<le> m)"
   798 by (simp add: real_of_nat_def)
   799 
   800 lemma real_of_nat_ge_zero [iff]: "0 \<le> real (n::nat)"
   801 by (simp add: real_of_nat_def zero_le_imp_of_nat)
   802 
   803 lemma real_of_nat_Suc_gt_zero: "0 < real (Suc n)"
   804 by (simp add: real_of_nat_def del: of_nat_Suc)
   805 
   806 lemma real_of_nat_mult [simp]: "real (m * n) = real (m::nat) * real n"
   807 by (simp add: real_of_nat_def)
   808 
   809 lemma real_of_nat_setsum [simp]: "real ((SUM x:A. f x)::nat) = 
   810     (SUM x:A. real(f x))"
   811   apply (subst real_eq_of_nat)+
   812   apply (rule of_nat_setsum)
   813 done
   814 
   815 lemma real_of_nat_setprod [simp]: "real ((PROD x:A. f x)::nat) = 
   816     (PROD x:A. real(f x))"
   817   apply (subst real_eq_of_nat)+
   818   apply (rule of_nat_setprod)
   819 done
   820 
   821 lemma real_of_card: "real (card A) = setsum (%x.1) A"
   822   apply (subst card_eq_setsum)
   823   apply (subst real_of_nat_setsum)
   824   apply simp
   825 done
   826 
   827 lemma real_of_nat_inject [iff]: "(real (n::nat) = real m) = (n = m)"
   828 by (simp add: real_of_nat_def)
   829 
   830 lemma real_of_nat_zero_iff [iff]: "(real (n::nat) = 0) = (n = 0)"
   831 by (simp add: real_of_nat_def)
   832 
   833 lemma real_of_nat_diff: "n \<le> m ==> real (m - n) = real (m::nat) - real n"
   834 by (simp add: add: real_of_nat_def) 
   835 
   836 lemma real_of_nat_gt_zero_cancel_iff [simp]: "(0 < real (n::nat)) = (0 < n)"
   837 by (simp add: add: real_of_nat_def) 
   838 
   839 lemma real_of_nat_le_zero_cancel_iff [simp]: "(real (n::nat) \<le> 0) = (n = 0)"
   840 by (simp add: add: real_of_nat_def)
   841 
   842 lemma not_real_of_nat_less_zero [simp]: "~ real (n::nat) < 0"
   843 by (simp add: add: real_of_nat_def)
   844 
   845 lemma real_of_nat_ge_zero_cancel_iff [simp]: "(0 \<le> real (n::nat)) = (0 \<le> n)"
   846 by (simp add: add: real_of_nat_def)
   847 
   848 lemma nat_less_real_le: "((n::nat) < m) = (real n + 1 <= real m)"
   849   apply (subgoal_tac "real n + 1 = real (Suc n)")
   850   apply simp
   851   apply (auto simp add: real_of_nat_Suc)
   852 done
   853 
   854 lemma nat_le_real_less: "((n::nat) <= m) = (real n < real m + 1)"
   855   apply (subgoal_tac "real m + 1 = real (Suc m)")
   856   apply (simp add: less_Suc_eq_le)
   857   apply (simp add: real_of_nat_Suc)
   858 done
   859 
   860 lemma real_of_nat_div_aux: "0 < d ==> (real (x::nat)) / (real d) = 
   861     real (x div d) + (real (x mod d)) / (real d)"
   862 proof -
   863   assume "0 < d"
   864   have "x = (x div d) * d + x mod d"
   865     by auto
   866   then have "real x = real (x div d) * real d + real(x mod d)"
   867     by (simp only: real_of_nat_mult [THEN sym] real_of_nat_add [THEN sym])
   868   then have "real x / real d = \<dots> / real d"
   869     by simp
   870   then show ?thesis
   871     by (auto simp add: add_divide_distrib ring_eq_simps prems)
   872 qed
   873 
   874 lemma real_of_nat_div: "0 < (d::nat) ==> d dvd n ==>
   875     real(n div d) = real n / real d"
   876   apply (frule real_of_nat_div_aux [of d n])
   877   apply simp
   878   apply (subst dvd_eq_mod_eq_0 [THEN sym])
   879   apply assumption
   880 done
   881 
   882 lemma real_of_nat_div2:
   883   "0 <= real (n::nat) / real (x) - real (n div x)"
   884   apply(case_tac "x = 0")
   885   apply simp
   886   apply (simp add: compare_rls)
   887   apply (subst real_of_nat_div_aux)
   888   apply assumption
   889   apply simp
   890   apply (subst zero_le_divide_iff)
   891   apply simp
   892 done
   893 
   894 lemma real_of_nat_div3:
   895   "real (n::nat) / real (x) - real (n div x) <= 1"
   896   apply(case_tac "x = 0")
   897   apply simp
   898   apply (simp add: compare_rls)
   899   apply (subst real_of_nat_div_aux)
   900   apply assumption
   901   apply simp
   902 done
   903 
   904 lemma real_of_nat_div4: "real (n div x) <= real (n::nat) / real x" 
   905   by (insert real_of_nat_div2 [of n x], simp)
   906 
   907 lemma real_of_int_real_of_nat: "real (int n) = real n"
   908 by (simp add: real_of_nat_def real_of_int_def int_eq_of_nat)
   909 
   910 lemma real_of_int_of_nat_eq [simp]: "real (of_nat n :: int) = real n"
   911 by (simp add: real_of_int_def real_of_nat_def)
   912 
   913 lemma real_nat_eq_real [simp]: "0 <= x ==> real(nat x) = real x"
   914   apply (subgoal_tac "real(int(nat x)) = real(nat x)")
   915   apply force
   916   apply (simp only: real_of_int_real_of_nat)
   917 done
   918 
   919 subsection{*Numerals and Arithmetic*}
   920 
   921 instance real :: number ..
   922 
   923 defs (overloaded)
   924   real_number_of_def: "(number_of w :: real) == of_int (Rep_Bin w)"
   925     --{*the type constraint is essential!*}
   926 
   927 instance real :: number_ring
   928 by (intro_classes, simp add: real_number_of_def) 
   929 
   930 
   931 text{*Collapse applications of @{term real} to @{term number_of}*}
   932 lemma real_number_of [simp]: "real (number_of v :: int) = number_of v"
   933 by (simp add:  real_of_int_def of_int_number_of_eq)
   934 
   935 lemma real_of_nat_number_of [simp]:
   936      "real (number_of v :: nat) =  
   937         (if neg (number_of v :: int) then 0  
   938          else (number_of v :: real))"
   939 by (simp add: real_of_int_real_of_nat [symmetric] int_nat_number_of)
   940  
   941 
   942 use "real_arith.ML"
   943 
   944 setup real_arith_setup
   945 
   946 subsection{* Simprules combining x+y and 0: ARE THEY NEEDED?*}
   947 
   948 text{*Needed in this non-standard form by Hyperreal/Transcendental*}
   949 lemma real_0_le_divide_iff:
   950      "((0::real) \<le> x/y) = ((x \<le> 0 | 0 \<le> y) & (0 \<le> x | y \<le> 0))"
   951 by (simp add: real_divide_def zero_le_mult_iff, auto)
   952 
   953 lemma real_add_minus_iff [simp]: "(x + - a = (0::real)) = (x=a)" 
   954 by arith
   955 
   956 lemma real_add_eq_0_iff: "(x+y = (0::real)) = (y = -x)"
   957 by auto
   958 
   959 lemma real_add_less_0_iff: "(x+y < (0::real)) = (y < -x)"
   960 by auto
   961 
   962 lemma real_0_less_add_iff: "((0::real) < x+y) = (-x < y)"
   963 by auto
   964 
   965 lemma real_add_le_0_iff: "(x+y \<le> (0::real)) = (y \<le> -x)"
   966 by auto
   967 
   968 lemma real_0_le_add_iff: "((0::real) \<le> x+y) = (-x \<le> y)"
   969 by auto
   970 
   971 
   972 (*
   973 FIXME: we should have this, as for type int, but many proofs would break.
   974 It replaces x+-y by x-y.
   975 declare real_diff_def [symmetric, simp]
   976 *)
   977 
   978 
   979 subsubsection{*Density of the Reals*}
   980 
   981 lemma real_lbound_gt_zero:
   982      "[| (0::real) < d1; 0 < d2 |] ==> \<exists>e. 0 < e & e < d1 & e < d2"
   983 apply (rule_tac x = " (min d1 d2) /2" in exI)
   984 apply (simp add: min_def)
   985 done
   986 
   987 
   988 text{*Similar results are proved in @{text Ring_and_Field}*}
   989 lemma real_less_half_sum: "x < y ==> x < (x+y) / (2::real)"
   990   by auto
   991 
   992 lemma real_gt_half_sum: "x < y ==> (x+y)/(2::real) < y"
   993   by auto
   994 
   995 
   996 subsection{*Absolute Value Function for the Reals*}
   997 
   998 lemma abs_minus_add_cancel: "abs(x + (-y)) = abs (y + (-(x::real)))"
   999 by (simp add: abs_if)
  1000 
  1001 lemma abs_interval_iff: "(abs x < r) = (-r < x & x < (r::real))"
  1002 by (force simp add: Ring_and_Field.abs_less_iff)
  1003 
  1004 lemma abs_le_interval_iff: "(abs x \<le> r) = (-r\<le>x & x\<le>(r::real))"
  1005 by (force simp add: OrderedGroup.abs_le_iff)
  1006 
  1007 (*FIXME: used only once, in SEQ.ML*)
  1008 lemma abs_add_one_gt_zero [simp]: "(0::real) < 1 + abs(x)"
  1009 by (simp add: abs_if)
  1010 
  1011 lemma abs_real_of_nat_cancel [simp]: "abs (real x) = real (x::nat)"
  1012 by (simp add: real_of_nat_ge_zero)
  1013 
  1014 lemma abs_add_one_not_less_self [simp]: "~ abs(x) + (1::real) < x"
  1015 apply (simp add: linorder_not_less)
  1016 apply (auto intro: abs_ge_self [THEN order_trans])
  1017 done
  1018  
  1019 text{*Used only in Hyperreal/Lim.ML*}
  1020 lemma abs_sum_triangle_ineq: "abs ((x::real) + y + (-l + -m)) \<le> abs(x + -l) + abs(y + -m)"
  1021 apply (simp add: real_add_assoc)
  1022 apply (rule_tac a1 = y in add_left_commute [THEN ssubst])
  1023 apply (rule real_add_assoc [THEN subst])
  1024 apply (rule abs_triangle_ineq)
  1025 done
  1026 
  1027 
  1028 
  1029 ML
  1030 {*
  1031 val real_lbound_gt_zero = thm"real_lbound_gt_zero";
  1032 val real_less_half_sum = thm"real_less_half_sum";
  1033 val real_gt_half_sum = thm"real_gt_half_sum";
  1034 
  1035 val abs_interval_iff = thm"abs_interval_iff";
  1036 val abs_le_interval_iff = thm"abs_le_interval_iff";
  1037 val abs_add_one_gt_zero = thm"abs_add_one_gt_zero";
  1038 val abs_add_one_not_less_self = thm"abs_add_one_not_less_self";
  1039 val abs_sum_triangle_ineq = thm"abs_sum_triangle_ineq";
  1040 *}
  1041 
  1042 
  1043 end