src/Pure/sign.ML
author wenzelm
Sun Apr 15 14:31:54 2007 +0200 (2007-04-15)
changeset 22696 00fc658c4fe5
parent 22683 0e9a65ddfe9d
child 22709 9ab51bac6287
permissions -rw-r--r--
removed obsolete infer_types(_simult);
read_sort/get_sort, read_def_terms: internal reorganization;
     1 (*  Title:      Pure/sign.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson and Markus Wenzel
     4 
     5 Logical signature content: naming conventions, concrete syntax, type
     6 signature, polymorphic constants.
     7 *)
     8 
     9 signature SIGN_THEORY =
    10 sig
    11   val add_defsort: string -> theory -> theory
    12   val add_defsort_i: sort -> theory -> theory
    13   val add_types: (bstring * int * mixfix) list -> theory -> theory
    14   val add_typedecls: (bstring * string list * mixfix) list -> theory -> theory
    15   val add_nonterminals: bstring list -> theory -> theory
    16   val add_tyabbrs: (bstring * string list * string * mixfix) list -> theory -> theory
    17   val add_tyabbrs_i: (bstring * string list * typ * mixfix) list -> theory -> theory
    18   val add_syntax: (bstring * string * mixfix) list -> theory -> theory
    19   val add_syntax_i: (bstring * typ * mixfix) list -> theory -> theory
    20   val add_modesyntax: Syntax.mode -> (bstring * string * mixfix) list -> theory -> theory
    21   val add_modesyntax_i: Syntax.mode -> (bstring * typ * mixfix) list -> theory -> theory
    22   val del_modesyntax: Syntax.mode -> (bstring * string * mixfix) list -> theory -> theory
    23   val del_modesyntax_i: Syntax.mode -> (bstring * typ * mixfix) list -> theory -> theory
    24   val add_consts: (bstring * string * mixfix) list -> theory -> theory
    25   val add_consts_i: (bstring * typ * mixfix) list -> theory -> theory
    26   val add_const_constraint: xstring * string option -> theory -> theory
    27   val add_const_constraint_i: string * typ option -> theory -> theory
    28   val primitive_class: string * class list -> theory -> theory
    29   val primitive_classrel: class * class -> theory -> theory
    30   val primitive_arity: arity -> theory -> theory
    31   val add_trfuns:
    32     (string * (ast list -> ast)) list *
    33     (string * (term list -> term)) list *
    34     (string * (term list -> term)) list *
    35     (string * (ast list -> ast)) list -> theory -> theory
    36   val add_trfunsT:
    37     (string * (bool -> typ -> term list -> term)) list -> theory -> theory
    38   val add_advanced_trfuns:
    39     (string * (Proof.context -> ast list -> ast)) list *
    40     (string * (Proof.context -> term list -> term)) list *
    41     (string * (Proof.context -> term list -> term)) list *
    42     (string * (Proof.context -> ast list -> ast)) list -> theory -> theory
    43   val add_advanced_trfunsT:
    44     (string * (Proof.context -> bool -> typ -> term list -> term)) list -> theory -> theory
    45   val add_tokentrfuns:
    46     (string * string * (string -> string * real)) list -> theory -> theory
    47   val add_mode_tokentrfuns: string -> (string * (string -> string * real)) list
    48     -> theory -> theory
    49   val add_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
    50   val del_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
    51   val add_trrules_i: ast Syntax.trrule list -> theory -> theory
    52   val del_trrules_i: ast Syntax.trrule list -> theory -> theory
    53   val add_path: string -> theory -> theory
    54   val parent_path: theory -> theory
    55   val root_path: theory -> theory
    56   val absolute_path: theory -> theory
    57   val local_path: theory -> theory
    58   val no_base_names: theory -> theory
    59   val qualified_names: theory -> theory
    60   val sticky_prefix: string -> theory -> theory
    61   val set_policy: (string -> bstring -> string) * (string list -> string list list) ->
    62     theory -> theory
    63   val restore_naming: theory -> theory -> theory
    64   val hide_classes: bool -> xstring list -> theory -> theory
    65   val hide_classes_i: bool -> string list -> theory -> theory
    66   val hide_types: bool -> xstring list -> theory -> theory
    67   val hide_types_i: bool -> string list -> theory -> theory
    68   val hide_consts: bool -> xstring list -> theory -> theory
    69   val hide_consts_i: bool -> string list -> theory -> theory
    70   val hide_names: bool -> string * xstring list -> theory -> theory
    71   val hide_names_i: bool -> string * string list -> theory -> theory
    72 end
    73 
    74 signature SIGN =
    75 sig
    76   val init_data: theory -> theory
    77   val rep_sg: theory ->
    78    {naming: NameSpace.naming,
    79     syn: Syntax.syntax,
    80     tsig: Type.tsig,
    81     consts: Consts.T}
    82   val naming_of: theory -> NameSpace.naming
    83   val base_name: string -> bstring
    84   val full_name: theory -> bstring -> string
    85   val full_name_path: theory -> string -> bstring -> string
    86   val declare_name: theory -> string -> NameSpace.T -> NameSpace.T
    87   val syn_of: theory -> Syntax.syntax
    88   val tsig_of: theory -> Type.tsig
    89   val classes_of: theory -> Sorts.algebra
    90   val all_classes: theory -> class list
    91   val super_classes: theory -> class -> class list
    92   val defaultS: theory -> sort
    93   val subsort: theory -> sort * sort -> bool
    94   val of_sort: theory -> typ * sort -> bool
    95   val witness_sorts: theory -> sort list -> sort list -> (typ * sort) list
    96   val universal_witness: theory -> (typ * sort) option
    97   val all_sorts_nonempty: theory -> bool
    98   val typ_instance: theory -> typ * typ -> bool
    99   val typ_equiv: theory -> typ * typ -> bool
   100   val typ_match: theory -> typ * typ -> Type.tyenv -> Type.tyenv
   101   val typ_unify: theory -> typ * typ -> Type.tyenv * int -> Type.tyenv * int
   102   val is_logtype: theory -> string -> bool
   103   val consts_of: theory -> Consts.T
   104   val const_constraint: theory -> string -> typ option
   105   val the_const_constraint: theory -> string -> typ
   106   val const_type: theory -> string -> typ option
   107   val the_const_type: theory -> string -> typ
   108   val declared_tyname: theory -> string -> bool
   109   val declared_const: theory -> string -> bool
   110   val const_monomorphic: theory -> string -> bool
   111   val const_syntax_name: theory -> string -> string
   112   val const_typargs: theory -> string * typ -> typ list
   113   val const_instance: theory -> string * typ list -> typ
   114   val class_space: theory -> NameSpace.T
   115   val type_space: theory -> NameSpace.T
   116   val const_space: theory -> NameSpace.T
   117   val intern_class: theory -> xstring -> string
   118   val extern_class: theory -> string -> xstring
   119   val intern_type: theory -> xstring -> string
   120   val extern_type: theory -> string -> xstring
   121   val intern_const: theory -> xstring -> string
   122   val extern_const: theory -> string -> xstring
   123   val intern_sort: theory -> sort -> sort
   124   val extern_sort: theory -> sort -> sort
   125   val intern_typ: theory -> typ -> typ
   126   val extern_typ: theory -> typ -> typ
   127   val intern_term: theory -> term -> term
   128   val extern_term: (string -> xstring) -> theory -> term -> term
   129   val intern_tycons: theory -> typ -> typ
   130   val pretty_term': Proof.context -> Syntax.syntax -> (string -> xstring) -> term -> Pretty.T
   131   val pretty_term: theory -> term -> Pretty.T
   132   val pretty_typ: theory -> typ -> Pretty.T
   133   val pretty_sort: theory -> sort -> Pretty.T
   134   val pretty_classrel: theory -> class list -> Pretty.T
   135   val pretty_arity: theory -> arity -> Pretty.T
   136   val string_of_term: theory -> term -> string
   137   val string_of_typ: theory -> typ -> string
   138   val string_of_sort: theory -> sort -> string
   139   val string_of_classrel: theory -> class list -> string
   140   val string_of_arity: theory -> arity -> string
   141   val pp: theory -> Pretty.pp
   142   val arity_number: theory -> string -> int
   143   val arity_sorts: theory -> string -> sort -> sort list
   144   val certify_class: theory -> class -> class
   145   val certify_sort: theory -> sort -> sort
   146   val certify_typ: theory -> typ -> typ
   147   val certify_typ_syntax: theory -> typ -> typ
   148   val certify_typ_abbrev: theory -> typ -> typ
   149   val certify': bool -> bool -> Pretty.pp -> Consts.T -> theory -> term -> term * typ * int
   150   val certify_term: theory -> term -> term * typ * int
   151   val certify_prop: theory -> term -> term * typ * int
   152   val cert_term: theory -> term -> term
   153   val cert_prop: theory -> term -> term
   154   val no_frees: Pretty.pp -> term -> term
   155   val no_vars: Pretty.pp -> term -> term
   156   val cert_def: Pretty.pp -> term -> (string * typ) * term
   157   val read_class: theory -> xstring -> class
   158   val read_sort': Syntax.syntax -> Proof.context -> string -> sort
   159   val read_sort: theory -> string -> sort
   160   val read_arity: theory -> xstring * string list * string -> arity
   161   val cert_arity: theory -> arity -> arity
   162   val read_typ': Syntax.syntax -> Proof.context -> (indexname -> sort option) -> string -> typ
   163   val read_typ_syntax': Syntax.syntax -> Proof.context ->
   164     (indexname -> sort option) -> string -> typ
   165   val read_typ_abbrev': Syntax.syntax -> Proof.context ->
   166     (indexname -> sort option) -> string -> typ
   167   val read_def_typ: theory * (indexname -> sort option) -> string -> typ
   168   val read_typ: theory -> string -> typ
   169   val read_typ_syntax: theory -> string -> typ
   170   val read_typ_abbrev: theory -> string -> typ
   171   val read_tyname: theory -> string -> typ
   172   val read_const: theory -> string -> term
   173   val read_def_terms': Pretty.pp -> (string -> bool) -> Syntax.syntax -> Consts.T ->
   174     (string -> string option) -> Proof.context ->
   175     (indexname -> typ option) * (indexname -> sort option) ->
   176     Name.context -> bool -> (string * typ) list -> term list * (indexname * typ) list
   177   val read_def_terms:
   178     theory * (indexname -> typ option) * (indexname -> sort option) ->
   179     string list -> bool -> (string * typ) list -> term list * (indexname * typ) list
   180   val simple_read_term: theory -> typ -> string -> term
   181   val read_term: theory -> string -> term
   182   val read_prop: theory -> string -> term
   183   val add_consts_authentic: (bstring * typ * mixfix) list -> theory -> theory
   184   val add_notation: Syntax.mode -> (term * mixfix) list -> theory -> theory
   185   val add_abbrev: string -> bstring * term -> theory -> (term * term) * theory
   186   include SIGN_THEORY
   187 end
   188 
   189 structure Sign: SIGN =
   190 struct
   191 
   192 (** datatype sign **)
   193 
   194 datatype sign = Sign of
   195  {naming: NameSpace.naming,     (*common naming conventions*)
   196   syn: Syntax.syntax,           (*concrete syntax for terms, types, sorts*)
   197   tsig: Type.tsig,              (*order-sorted signature of types*)
   198   consts: Consts.T};            (*polymorphic constants*)
   199 
   200 fun make_sign (naming, syn, tsig, consts) =
   201   Sign {naming = naming, syn = syn, tsig = tsig, consts = consts};
   202 
   203 structure SignData = TheoryDataFun
   204 (struct
   205   val name = "Pure/sign";
   206   type T = sign;
   207   val copy = I;
   208   fun extend (Sign {syn, tsig, consts, ...}) =
   209     make_sign (NameSpace.default_naming, syn, tsig, consts);
   210 
   211   val empty =
   212     make_sign (NameSpace.default_naming, Syntax.basic_syn, Type.empty_tsig, Consts.empty);
   213 
   214   fun merge pp (sign1, sign2) =
   215     let
   216       val Sign {naming = _, syn = syn1, tsig = tsig1, consts = consts1} = sign1;
   217       val Sign {naming = _, syn = syn2, tsig = tsig2, consts = consts2} = sign2;
   218 
   219       val naming = NameSpace.default_naming;
   220       val syn = Syntax.merge_syntaxes syn1 syn2;
   221       val tsig = Type.merge_tsigs pp (tsig1, tsig2);
   222       val consts = Consts.merge (consts1, consts2);
   223     in make_sign (naming, syn, tsig, consts) end;
   224 
   225   fun print _ _ = ();
   226 end);
   227 
   228 val init_data = SignData.init;
   229 
   230 fun rep_sg thy = SignData.get thy |> (fn Sign args => args);
   231 
   232 fun map_sign f = SignData.map (fn Sign {naming, syn, tsig, consts} =>
   233   make_sign (f (naming, syn, tsig, consts)));
   234 
   235 fun map_naming f = map_sign (fn (naming, syn, tsig, consts) => (f naming, syn, tsig, consts));
   236 fun map_syn f = map_sign (fn (naming, syn, tsig, consts) => (naming, f syn, tsig, consts));
   237 fun map_tsig f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, f tsig, consts));
   238 fun map_consts f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, tsig, f consts));
   239 
   240 
   241 (* naming *)
   242 
   243 val naming_of = #naming o rep_sg;
   244 val base_name = NameSpace.base;
   245 val full_name = NameSpace.full o naming_of;
   246 fun full_name_path thy elems = NameSpace.full (NameSpace.add_path elems (naming_of thy));
   247 val declare_name = NameSpace.declare o naming_of;
   248 
   249 
   250 (* syntax *)
   251 
   252 val syn_of = #syn o rep_sg;
   253 
   254 
   255 (* type signature *)
   256 
   257 val tsig_of = #tsig o rep_sg;
   258 val classes_of = #2 o #classes o Type.rep_tsig o tsig_of;
   259 val all_classes = Sorts.all_classes o classes_of;
   260 val minimal_classes = Sorts.minimal_classes o classes_of;
   261 val super_classes = Sorts.super_classes o classes_of;
   262 val defaultS = Type.defaultS o tsig_of;
   263 val subsort = Type.subsort o tsig_of;
   264 val of_sort = Type.of_sort o tsig_of;
   265 val witness_sorts = Type.witness_sorts o tsig_of;
   266 val universal_witness = Type.universal_witness o tsig_of;
   267 val all_sorts_nonempty = is_some o universal_witness;
   268 val typ_instance = Type.typ_instance o tsig_of;
   269 fun typ_equiv thy (T, U) = typ_instance thy (T, U) andalso typ_instance thy (U, T);
   270 val typ_match = Type.typ_match o tsig_of;
   271 val typ_unify = Type.unify o tsig_of;
   272 val is_logtype = member (op =) o Type.logical_types o tsig_of;
   273 
   274 
   275 (* polymorphic constants *)
   276 
   277 val consts_of = #consts o rep_sg;
   278 val the_const_constraint = Consts.the_constraint o consts_of;
   279 val const_constraint = try o the_const_constraint;
   280 val the_const_type = Consts.the_declaration o consts_of;
   281 val const_type = try o the_const_type;
   282 val const_monomorphic = Consts.is_monomorphic o consts_of;
   283 val const_syntax_name = Consts.syntax_name o consts_of;
   284 val const_typargs = Consts.typargs o consts_of;
   285 val const_instance = Consts.instance o consts_of;
   286 
   287 val declared_tyname = Symtab.defined o #2 o #types o Type.rep_tsig o tsig_of;
   288 val declared_const = is_some oo const_constraint;
   289 
   290 
   291 
   292 (** intern / extern names **)
   293 
   294 val class_space = #1 o #classes o Type.rep_tsig o tsig_of;
   295 val type_space = #1 o #types o Type.rep_tsig o tsig_of;
   296 val const_space = Consts.space_of o consts_of;
   297 
   298 val intern_class = NameSpace.intern o class_space;
   299 val extern_class = NameSpace.extern o class_space;
   300 val intern_type = NameSpace.intern o type_space;
   301 val extern_type = NameSpace.extern o type_space;
   302 val intern_const = NameSpace.intern o const_space;
   303 val extern_const = NameSpace.extern o const_space;
   304 
   305 val intern_sort = map o intern_class;
   306 val extern_sort = map o extern_class;
   307 
   308 local
   309 
   310 fun map_typ f g (Type (c, Ts)) = Type (g c, map (map_typ f g) Ts)
   311   | map_typ f _ (TFree (x, S)) = TFree (x, map f S)
   312   | map_typ f _ (TVar (xi, S)) = TVar (xi, map f S);
   313 
   314 fun map_term f g h (Const (c, T)) = Const (h c, map_typ f g T)
   315   | map_term f g _ (Free (x, T)) = Free (x, map_typ f g T)
   316   | map_term f g _ (Var (xi, T)) = Var (xi, map_typ f g T)
   317   | map_term _ _ _ (t as Bound _) = t
   318   | map_term f g h (Abs (x, T, t)) = Abs (x, map_typ f g T, map_term f g h t)
   319   | map_term f g h (t $ u) = map_term f g h t $ map_term f g h u;
   320 
   321 val add_classesT = Term.fold_atyps
   322   (fn TFree (_, S) => fold (insert (op =)) S
   323     | TVar (_, S) => fold (insert (op =)) S
   324     | _ => I);
   325 
   326 fun add_tyconsT (Type (c, Ts)) = insert (op =) c #> fold add_tyconsT Ts
   327   | add_tyconsT _ = I;
   328 
   329 val add_consts = Term.fold_aterms (fn Const (c, _) => insert (op =) c | _ => I);
   330 
   331 fun mapping add_names f t =
   332   let
   333     fun f' (x: string) = let val y = f x in if x = y then NONE else SOME (x, y) end;
   334     val tab = map_filter f' (add_names t []);
   335     fun get x = the_default x (AList.lookup (op =) tab x);
   336   in get end;
   337 
   338 fun typ_mapping f g thy T =
   339   T |> map_typ
   340     (mapping add_classesT (f thy) T)
   341     (mapping add_tyconsT (g thy) T);
   342 
   343 fun term_mapping f g h thy t =
   344   t |> map_term
   345     (mapping (Term.fold_types add_classesT) (f thy) t)
   346     (mapping (Term.fold_types add_tyconsT) (g thy) t)
   347     (mapping add_consts (h thy) t);
   348 
   349 in
   350 
   351 val intern_typ = typ_mapping intern_class intern_type;
   352 val extern_typ = typ_mapping extern_class extern_type;
   353 val intern_term = term_mapping intern_class intern_type intern_const;
   354 fun extern_term h = term_mapping extern_class extern_type (K h);
   355 val intern_tycons = typ_mapping (K I) intern_type;
   356 
   357 end;
   358 
   359 
   360 
   361 (** pretty printing of terms, types etc. **)
   362 
   363 fun pretty_term' ctxt syn ext t =
   364   let val curried = Context.exists_name Context.CPureN (ProofContext.theory_of ctxt)
   365   in Syntax.pretty_term ext ctxt syn curried t end;
   366 
   367 fun pretty_term thy t =
   368   pretty_term' (ProofContext.init thy) (syn_of thy) (Consts.extern (consts_of thy))
   369     (extern_term (Consts.extern_early (consts_of thy)) thy t);
   370 
   371 fun pretty_typ thy T =
   372   Syntax.pretty_typ (ProofContext.init thy) (syn_of thy) (extern_typ thy T);
   373 
   374 fun pretty_sort thy S =
   375   Syntax.pretty_sort (ProofContext.init thy) (syn_of thy) (extern_sort thy S);
   376 
   377 fun pretty_classrel thy cs = Pretty.block (flat
   378   (separate [Pretty.str " <", Pretty.brk 1] (map (single o pretty_sort thy o single) cs)));
   379 
   380 fun pretty_arity thy (a, Ss, S) =
   381   let
   382     val a' = extern_type thy a;
   383     val dom =
   384       if null Ss then []
   385       else [Pretty.list "(" ")" (map (pretty_sort thy) Ss), Pretty.brk 1];
   386   in Pretty.block ([Pretty.str (a' ^ " ::"), Pretty.brk 1] @ dom @ [pretty_sort thy S]) end;
   387 
   388 val string_of_term = Pretty.string_of oo pretty_term;
   389 val string_of_typ = Pretty.string_of oo pretty_typ;
   390 val string_of_sort = Pretty.string_of oo pretty_sort;
   391 val string_of_classrel = Pretty.string_of oo pretty_classrel;
   392 val string_of_arity = Pretty.string_of oo pretty_arity;
   393 
   394 fun pp thy = Pretty.pp (pretty_term thy, pretty_typ thy, pretty_sort thy,
   395   pretty_classrel thy, pretty_arity thy);
   396 
   397 
   398 
   399 (** certify entities **)    (*exception TYPE*)
   400 
   401 (* certify wrt. type signature *)
   402 
   403 val arity_number = Type.arity_number o tsig_of;
   404 fun arity_sorts thy = Type.arity_sorts (pp thy) (tsig_of thy);
   405 
   406 fun certify cert = cert o tsig_of o Context.check_thy;
   407 
   408 val certify_class      = certify Type.cert_class;
   409 val certify_sort       = certify Type.cert_sort;
   410 val certify_typ        = certify Type.cert_typ;
   411 val certify_typ_syntax = certify Type.cert_typ_syntax;
   412 val certify_typ_abbrev = certify Type.cert_typ_abbrev;
   413 
   414 
   415 (* certify term/prop *)
   416 
   417 local
   418 
   419 fun type_check pp tm =
   420   let
   421     fun err_appl why bs t T u U =
   422       let
   423         val xs = map Free bs;           (*we do not rename here*)
   424         val t' = subst_bounds (xs, t);
   425         val u' = subst_bounds (xs, u);
   426         val msg = cat_lines
   427           (TypeInfer.appl_error (Syntax.pp_show_brackets pp) why t' T u' U);
   428       in raise TYPE (msg, [T, U], [t', u']) end;
   429 
   430     fun typ_of (_, Const (_, T)) = T
   431       | typ_of (_, Free  (_, T)) = T
   432       | typ_of (_, Var (_, T)) = T
   433       | typ_of (bs, Bound i) = snd (List.nth (bs, i) handle Subscript =>
   434           raise TYPE ("Loose bound variable: B." ^ string_of_int i, [], [Bound i]))
   435       | typ_of (bs, Abs (x, T, body)) = T --> typ_of ((x, T) :: bs, body)
   436       | typ_of (bs, t $ u) =
   437           let val T = typ_of (bs, t) and U = typ_of (bs, u) in
   438             (case T of
   439               Type ("fun", [T1, T2]) =>
   440                 if T1 = U then T2 else err_appl "Incompatible operand type" bs t T u U
   441             | _ => err_appl "Operator not of function type" bs t T u U)
   442           end;
   443   in typ_of ([], tm) end;
   444 
   445 fun err msg = raise TYPE (msg, [], []);
   446 
   447 fun check_vars (t $ u) = (check_vars t; check_vars u)
   448   | check_vars (Abs (_, _, t)) = check_vars t
   449   | check_vars (Var (xi as (_, i), _)) =
   450       if i < 0 then err ("Malformed variable: " ^ quote (Term.string_of_vname xi)) else ()
   451   | check_vars _ = ();
   452 
   453 in
   454 
   455 fun certify' normalize prop pp consts thy tm =
   456   let
   457     val _ = Context.check_thy thy;
   458     val _ = check_vars tm;
   459     val tm' = Term.map_types (certify_typ thy) tm;
   460     val T = type_check pp tm';
   461     val _ = if prop andalso T <> propT then err "Term not of type prop" else ();
   462     val tm'' = Consts.certify pp (tsig_of thy) consts tm';
   463     val tm'' = if normalize then tm'' else tm';
   464   in (if tm = tm'' then tm else tm'', T, Term.maxidx_of_term tm'') end;
   465 
   466 fun certify_term thy = certify' true false (pp thy) (consts_of thy) thy;
   467 fun certify_prop thy = certify' true true (pp thy) (consts_of thy) thy;
   468 
   469 fun cert_term_abbrev thy = #1 o certify' false false (pp thy) (consts_of thy) thy;
   470 val cert_term = #1 oo certify_term;
   471 val cert_prop = #1 oo certify_prop;
   472 
   473 end;
   474 
   475 
   476 (* specifications *)
   477 
   478 fun no_variables kind add addT mk mkT pp tm =
   479   (case (add tm [], addT tm []) of
   480     ([], []) => tm
   481   | (frees, tfrees) => error (Pretty.string_of (Pretty.block (Pretty.breaks
   482       (Pretty.str ("Illegal " ^ kind ^ " variable(s) in term:") ::
   483        map (Pretty.term pp o mk) frees @ map (Pretty.typ pp o mkT) tfrees)))));
   484 
   485 val no_frees = no_variables "free" Term.add_frees Term.add_tfrees Free TFree;
   486 val no_vars = no_variables "schematic" Term.add_vars Term.add_tvars Var TVar;
   487 
   488 fun cert_def pp tm =
   489   let val ((lhs, rhs), _) = tm
   490     |> no_vars pp
   491     |> Logic.strip_imp_concl
   492     |> Logic.dest_def pp Term.is_Const (K false) (K false)
   493   in (Term.dest_Const (Term.head_of lhs), rhs) end
   494   handle TERM (msg, _) => error msg;
   495 
   496 
   497 
   498 (** read and certify entities **)    (*exception ERROR*)
   499 
   500 (* classes and sorts *)
   501 
   502 fun read_class thy c = certify_class thy (intern_class thy c)
   503   handle TYPE (msg, _, _) => error msg;
   504 
   505 fun read_sort' syn ctxt str =
   506   let
   507     val thy = ProofContext.theory_of ctxt;
   508     val _ = Context.check_thy thy;
   509     val S = Syntax.read_sort ctxt syn (intern_sort thy) str;
   510   in certify_sort thy S handle TYPE (msg, _, _) => error msg end;
   511 
   512 fun read_sort thy str = read_sort' (syn_of thy) (ProofContext.init thy) str;
   513 
   514 
   515 (* type arities *)
   516 
   517 fun prep_arity prep_tycon prep_sort thy (t, Ss, S) =
   518   let val arity = (prep_tycon thy t, map (prep_sort thy) Ss, prep_sort thy S)
   519   in Type.add_arity (pp thy) arity (tsig_of thy); arity end;
   520 
   521 val read_arity = prep_arity intern_type read_sort;
   522 val cert_arity = prep_arity (K I) certify_sort;
   523 
   524 
   525 (* types *)
   526 
   527 fun get_sort tsig def_sort raw_env =
   528   let
   529     fun eq ((xi, S), (xi', S')) =
   530       Term.eq_ix (xi, xi') andalso Type.eq_sort tsig (S, S');
   531     val env = distinct eq raw_env;
   532     val _ = (case duplicates (eq_fst (op =)) env of [] => ()
   533       | dups => error ("Inconsistent sort constraints for type variable(s) "
   534           ^ commas_quote (map (Term.string_of_vname' o fst) dups)));
   535 
   536     fun get xi =
   537       (case (AList.lookup (op =) env xi, def_sort xi) of
   538         (NONE, NONE) => Type.defaultS tsig
   539       | (NONE, SOME S) => S
   540       | (SOME S, NONE) => S
   541       | (SOME S, SOME S') =>
   542           if Type.eq_sort tsig (S, S') then S'
   543           else error ("Sort constraint inconsistent with default for type variable " ^
   544             quote (Term.string_of_vname' xi)));
   545   in get end;
   546 
   547 local
   548 
   549 fun gen_read_typ' cert syn ctxt def_sort str =
   550   let
   551     val thy = ProofContext.theory_of ctxt;
   552     val _ = Context.check_thy thy;
   553     val T = intern_tycons thy
   554       (Syntax.read_typ ctxt syn (get_sort (tsig_of thy) def_sort) (intern_sort thy) str);
   555   in cert thy T handle TYPE (msg, _, _) => error msg end
   556   handle ERROR msg => cat_error msg ("The error(s) above occurred in type " ^ quote str);
   557 
   558 fun gen_read_typ cert (thy, def_sort) str =
   559   gen_read_typ' cert (syn_of thy) (ProofContext.init thy) def_sort str;
   560 
   561 in
   562 
   563 fun no_def_sort thy = (thy: theory, K NONE);
   564 
   565 val read_typ'        = gen_read_typ' certify_typ;
   566 val read_typ_syntax' = gen_read_typ' certify_typ_syntax;
   567 val read_typ_abbrev' = gen_read_typ' certify_typ_abbrev;
   568 val read_def_typ     = gen_read_typ certify_typ;
   569 
   570 val read_typ = read_def_typ o no_def_sort;
   571 val read_typ_syntax  = gen_read_typ certify_typ_syntax o no_def_sort;
   572 val read_typ_abbrev  = gen_read_typ certify_typ_abbrev o no_def_sort;
   573 
   574 end;
   575 
   576 
   577 (* type and constant names *)
   578 
   579 fun read_tyname thy raw_c =
   580   let val c = intern_type thy raw_c
   581   in Type (c, replicate (arity_number thy c) dummyT) end;
   582 
   583 val read_const = Consts.read_const o consts_of;
   584 
   585 
   586 
   587 (* read_def_terms -- read terms and infer types *)    (*exception ERROR*)
   588 
   589 (*
   590   def_type: partial map from indexnames to types (constrains Frees and Vars)
   591   def_sort: partial map from indexnames to sorts (constrains TFrees and TVars)
   592   used: context of already used type variables
   593   freeze: if true then generated parameters are turned into TFrees, else TVars
   594 *)
   595 
   596 fun read_def_terms' pp is_logtype syn consts fixed ctxt (def_type, def_sort) used freeze sTs =
   597   let
   598     val thy = ProofContext.theory_of ctxt;
   599     val tsig = tsig_of thy;
   600 
   601     (*read terms -- potentially ambiguous*)
   602     val map_const = try (#1 o Term.dest_Const o Consts.read_const consts);
   603     fun map_free x =
   604       (case fixed x of
   605         NONE => if is_some (def_type (x, ~1)) then SOME x else NONE
   606       | some => some);
   607     val read =
   608       Syntax.read_term (get_sort tsig def_sort) map_const map_free
   609         (intern_tycons thy) (intern_sort thy) ctxt is_logtype syn;
   610 
   611     val args = sTs |> map (fn (s, raw_T) =>
   612       let val T = certify_typ thy raw_T handle TYPE (msg, _, _) => error msg
   613       in (read T s, T) end);
   614 
   615     (*brute-force disambiguation via type-inference*)
   616     val termss = fold_rev (multiply o fst) args [[]];
   617     val typs = map snd args;
   618 
   619     fun infer ts = Result (TypeInfer.infer_types (Syntax.pp_show_brackets pp) tsig
   620         (try (Consts.the_constraint consts)) def_type used freeze (ts ~~ typs) |>> map fst)
   621       handle TYPE (msg, _, _) => Exn (ERROR msg);
   622 
   623     val err_results = map infer termss;
   624     val errs = map_filter (fn Exn (ERROR msg) => SOME msg | _ => NONE) err_results;
   625     val results = map_filter get_result err_results;
   626 
   627     val ambiguity = length termss;
   628     fun ambig_msg () =
   629       if ambiguity > 1 andalso ambiguity <= ! Syntax.ambiguity_level then
   630         "Got more than one parse tree.\n\
   631         \Retry with smaller Syntax.ambiguity_level for more information."
   632       else "";
   633   in
   634     if null results then cat_error (ambig_msg ()) (cat_lines errs)
   635     else if length results = 1 then
   636       (if ambiguity > ! Syntax.ambiguity_level then
   637         warning "Fortunately, only one parse tree is type correct.\n\
   638           \You may still want to disambiguate your grammar or your input."
   639       else (); hd results)
   640     else cat_error (ambig_msg ()) ("More than one term is type correct:\n" ^
   641       cat_lines (map (Pretty.string_of_term pp) (maps fst results)))
   642   end;
   643 
   644 fun read_def_terms (thy, types, sorts) used freeze sTs =
   645   let
   646     val pp = pp thy;
   647     val consts = consts_of thy;
   648     val cert_consts = Consts.certify pp (tsig_of thy) consts;
   649     val (ts, inst) =
   650       read_def_terms' pp (is_logtype thy) (syn_of thy) consts (K NONE)
   651         (ProofContext.init thy) (types, sorts) (Name.make_context used) freeze sTs;
   652   in (map cert_consts ts, inst) end;
   653 
   654 fun simple_read_term thy T s =
   655   let val ([t], _) = read_def_terms (thy, K NONE, K NONE) [] true [(s, T)]
   656   in t end handle ERROR msg => cat_error msg ("The error(s) above occurred for term " ^ s);
   657 
   658 fun read_term thy = simple_read_term thy TypeInfer.logicT;
   659 fun read_prop thy = simple_read_term thy propT;
   660 
   661 
   662 
   663 (** signature extension functions **)  (*exception ERROR/TYPE*)
   664 
   665 (* add default sort *)
   666 
   667 fun gen_add_defsort prep_sort s thy =
   668   thy |> map_tsig (Type.set_defsort (prep_sort thy s));
   669 
   670 val add_defsort = gen_add_defsort read_sort;
   671 val add_defsort_i = gen_add_defsort certify_sort;
   672 
   673 
   674 (* add type constructors *)
   675 
   676 fun add_types types thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   677   let
   678     val syn' = Syntax.extend_type_gram types syn;
   679     val decls = map (fn (a, n, mx) => (Syntax.type_name a mx, n)) types;
   680     val tsig' = Type.add_types naming decls tsig;
   681   in (naming, syn', tsig', consts) end);
   682 
   683 fun add_typedecls decls thy =
   684   let
   685     fun type_of (a, vs: string list, mx) =
   686       if not (has_duplicates (op =) vs) then (a, length vs, mx)
   687       else error ("Duplicate parameters in type declaration: " ^ quote a);
   688   in add_types (map type_of decls) thy end;
   689 
   690 
   691 (* add nonterminals *)
   692 
   693 fun add_nonterminals ns thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   694   let
   695     val syn' = Syntax.extend_consts ns syn;
   696     val tsig' = Type.add_nonterminals naming ns tsig;
   697   in (naming, syn', tsig', consts) end);
   698 
   699 
   700 (* add type abbreviations *)
   701 
   702 fun gen_add_tyabbr prep_typ (a, vs, rhs, mx) thy =
   703   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   704     let
   705       val syn' = Syntax.extend_type_gram [(a, length vs, mx)] syn;
   706       val a' = Syntax.type_name a mx;
   707       val abbr = (a', vs, prep_typ thy rhs)
   708         handle ERROR msg => cat_error msg ("in type abbreviation " ^ quote a');
   709       val tsig' = Type.add_abbrevs naming [abbr] tsig;
   710     in (naming, syn', tsig', consts) end);
   711 
   712 val add_tyabbrs = fold (gen_add_tyabbr read_typ_syntax);
   713 val add_tyabbrs_i = fold (gen_add_tyabbr certify_typ_syntax);
   714 
   715 
   716 (* modify syntax *)
   717 
   718 fun gen_syntax change_gram prep_typ mode args thy =
   719   let
   720     fun prep (c, T, mx) = (c, prep_typ thy T, mx) handle ERROR msg =>
   721       cat_error msg ("in syntax declaration " ^ quote (Syntax.const_name c mx));
   722   in thy |> map_syn (change_gram (is_logtype thy) mode (map prep args)) end;
   723 
   724 fun gen_add_syntax x = gen_syntax Syntax.extend_const_gram x;
   725 
   726 val add_modesyntax = gen_add_syntax read_typ_syntax;
   727 val add_modesyntax_i = gen_add_syntax certify_typ_syntax;
   728 val add_syntax = add_modesyntax Syntax.default_mode;
   729 val add_syntax_i = add_modesyntax_i Syntax.default_mode;
   730 val del_modesyntax = gen_syntax Syntax.remove_const_gram read_typ_syntax;
   731 val del_modesyntax_i = gen_syntax Syntax.remove_const_gram certify_typ_syntax;
   732 
   733 fun const_syntax thy (Const (c, _), mx) = try (Consts.syntax (consts_of thy)) (c, mx)
   734   | const_syntax _ _ = NONE;
   735 
   736 fun add_notation mode args thy =
   737   thy |> add_modesyntax_i mode (map_filter (const_syntax thy) args);
   738 
   739 
   740 (* add constants *)
   741 
   742 local
   743 
   744 fun gen_add_consts prep_typ authentic raw_args thy =
   745   let
   746     val prepT = Compress.typ thy o Logic.varifyT o Type.no_tvars o Term.no_dummyT o prep_typ thy;
   747     fun prep (raw_c, raw_T, raw_mx) =
   748       let
   749         val (c, mx) = Syntax.const_mixfix raw_c raw_mx;
   750         val c' = if authentic then Syntax.constN ^ full_name thy c else c;
   751         val T = (prepT raw_T handle TYPE (msg, _, _) => error msg) handle ERROR msg =>
   752           cat_error msg ("in declaration of constant " ^ quote c);
   753       in (((c, T), authentic), (c', T, mx)) end;
   754     val args = map prep raw_args;
   755   in
   756     thy
   757     |> map_consts (fold (Consts.declare (naming_of thy) o #1) args)
   758     |> add_syntax_i (map #2 args)
   759   end;
   760 
   761 in
   762 
   763 val add_consts = gen_add_consts read_typ false;
   764 val add_consts_i = gen_add_consts certify_typ false;
   765 val add_consts_authentic = gen_add_consts certify_typ true;
   766 
   767 end;
   768 
   769 
   770 (* add abbreviations *)
   771 
   772 fun add_abbrev mode (c, raw_t) thy =
   773   let
   774     val pp = pp thy;
   775     val prep_tm = Compress.term thy o no_frees pp o
   776       map_types Logic.legacy_varifyT (* FIXME tmp *) o
   777       Term.no_dummy_patterns o cert_term_abbrev thy;
   778     val t = (prep_tm raw_t handle TYPE (msg, _, _) => error msg | TERM (msg, _) => error msg)
   779       handle ERROR msg => cat_error msg ("in constant abbreviation " ^ quote c);
   780     val (res, consts') = consts_of thy
   781       |> Consts.abbreviate pp (tsig_of thy) (naming_of thy) mode (c, t);
   782   in (res, thy |> map_consts (K consts')) end;
   783 
   784 
   785 (* add constraints *)
   786 
   787 fun gen_add_constraint int_const prep_typ (raw_c, opt_T) thy =
   788   let
   789     val c = int_const thy raw_c;
   790     fun prepT raw_T =
   791       let val T = Logic.varifyT (Type.no_tvars (Term.no_dummyT (prep_typ thy raw_T)))
   792       in cert_term thy (Const (c, T)); T end
   793       handle TYPE (msg, _, _) => error msg;
   794   in thy |> map_consts (Consts.constrain (c, Option.map prepT opt_T)) end;
   795 
   796 val add_const_constraint = gen_add_constraint intern_const read_typ;
   797 val add_const_constraint_i = gen_add_constraint (K I) certify_typ;
   798 
   799 
   800 (* primitive classes and arities *)
   801 
   802 fun primitive_class (bclass, classes) thy =
   803   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   804     let
   805       val syn' = Syntax.extend_consts [bclass] syn;
   806       val tsig' = Type.add_class (pp thy) naming (bclass, classes) tsig;
   807     in (naming, syn', tsig', consts) end)
   808   |> add_consts_i [(Logic.const_of_class bclass, Term.a_itselfT --> propT, NoSyn)];
   809 
   810 fun primitive_classrel arg thy = thy |> map_tsig (Type.add_classrel (pp thy) arg);
   811 fun primitive_arity arg thy = thy |> map_tsig (Type.add_arity (pp thy) arg);
   812 
   813 
   814 (* add translation functions *)
   815 
   816 local
   817 
   818 fun mk trs = map Syntax.mk_trfun trs;
   819 
   820 fun gen_add_trfuns ext non_typed (atrs, trs, tr's, atr's) =
   821   map_syn (ext (mk atrs, mk trs, mk (map (apsnd non_typed) tr's), mk atr's));
   822 
   823 fun gen_add_trfunsT ext tr's = map_syn (ext ([], [], mk tr's, []));
   824 
   825 in
   826 
   827 val add_trfuns = gen_add_trfuns Syntax.extend_trfuns Syntax.non_typed_tr';
   828 val add_trfunsT = gen_add_trfunsT Syntax.extend_trfuns;
   829 val add_advanced_trfuns = gen_add_trfuns Syntax.extend_advanced_trfuns Syntax.non_typed_tr'';
   830 val add_advanced_trfunsT = gen_add_trfunsT Syntax.extend_advanced_trfuns;
   831 
   832 end;
   833 
   834 val add_tokentrfuns = map_syn o Syntax.extend_tokentrfuns;
   835 fun add_mode_tokentrfuns m = add_tokentrfuns o map (fn (s, f) => (m, s, f));
   836 
   837 
   838 (* translation rules *)
   839 
   840 fun gen_trrules f args thy = thy |> map_syn (fn syn =>
   841   let val rules = map (Syntax.map_trrule (apfst (intern_type thy))) args
   842   in f (ProofContext.init thy) (is_logtype thy) syn rules syn end);
   843 
   844 val add_trrules = gen_trrules Syntax.extend_trrules;
   845 val del_trrules = gen_trrules Syntax.remove_trrules;
   846 val add_trrules_i = map_syn o Syntax.extend_trrules_i;
   847 val del_trrules_i = map_syn o Syntax.remove_trrules_i;
   848 
   849 
   850 (* modify naming *)
   851 
   852 val add_path        = map_naming o NameSpace.add_path;
   853 val no_base_names   = map_naming NameSpace.no_base_names;
   854 val qualified_names = map_naming NameSpace.qualified_names;
   855 val sticky_prefix   = map_naming o NameSpace.sticky_prefix;
   856 val set_policy      = map_naming o NameSpace.set_policy;
   857 val restore_naming  = map_naming o K o naming_of;
   858 
   859 val parent_path   = add_path "..";
   860 val root_path     = add_path "/";
   861 val absolute_path = add_path "//";
   862 
   863 fun local_path thy = thy |> root_path |> add_path (Context.theory_name thy);
   864 
   865 
   866 (* hide names *)
   867 
   868 fun hide_classes b xs thy = thy |> map_tsig (Type.hide_classes b (map (intern_class thy) xs));
   869 val hide_classes_i = map_tsig oo Type.hide_classes;
   870 fun hide_types b xs thy = thy |> map_tsig (Type.hide_types b (map (intern_type thy) xs));
   871 val hide_types_i = map_tsig oo Type.hide_types;
   872 fun hide_consts b xs thy = thy |> map_consts (fold (Consts.hide b o intern_const thy) xs);
   873 val hide_consts_i = map_consts oo (fold o Consts.hide);
   874 
   875 local
   876 
   877 val kinds =
   878  [("class", (intern_class, can o certify_class, hide_classes_i)),
   879   ("type", (intern_type, declared_tyname, hide_types_i)),
   880   ("const", (intern_const, declared_const, hide_consts_i))];
   881 
   882 fun gen_hide int b (kind, xnames) thy =
   883   (case AList.lookup (op =) kinds kind of
   884     SOME (intern, check, hide) =>
   885       let
   886         val names = if int then map (intern thy) xnames else xnames;
   887         val bads = filter_out (check thy) names;
   888       in
   889         if null bads then hide b names thy
   890         else error ("Attempt to hide undeclared item(s): " ^ commas_quote bads)
   891       end
   892   | NONE => error ("Bad name space specification: " ^ quote kind));
   893 
   894 in
   895 
   896 val hide_names = gen_hide true;
   897 val hide_names_i = gen_hide false;
   898 
   899 end;
   900 
   901 end;