src/HOL/Library/FuncSet.thy
author Christian Sternagel
Wed Aug 29 12:23:14 2012 +0900 (2012-08-29)
changeset 49083 01081bca31b6
parent 47761 dfe747e72fa8
child 50104 de19856feb54
permissions -rw-r--r--
dropped ord and bot instance for list prefixes (use locale interpretation instead, which allows users to decide what order to use on lists)
     1 (*  Title:      HOL/Library/FuncSet.thy
     2     Author:     Florian Kammueller and Lawrence C Paulson, Lukas Bulwahn
     3 *)
     4 
     5 header {* Pi and Function Sets *}
     6 
     7 theory FuncSet
     8 imports Hilbert_Choice Main
     9 begin
    10 
    11 definition
    12   Pi :: "['a set, 'a => 'b set] => ('a => 'b) set" where
    13   "Pi A B = {f. \<forall>x. x \<in> A --> f x \<in> B x}"
    14 
    15 definition
    16   extensional :: "'a set => ('a => 'b) set" where
    17   "extensional A = {f. \<forall>x. x~:A --> f x = undefined}"
    18 
    19 definition
    20   "restrict" :: "['a => 'b, 'a set] => ('a => 'b)" where
    21   "restrict f A = (%x. if x \<in> A then f x else undefined)"
    22 
    23 abbreviation
    24   funcset :: "['a set, 'b set] => ('a => 'b) set"
    25     (infixr "->" 60) where
    26   "A -> B == Pi A (%_. B)"
    27 
    28 notation (xsymbols)
    29   funcset  (infixr "\<rightarrow>" 60)
    30 
    31 syntax
    32   "_Pi"  :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3PI _:_./ _)" 10)
    33   "_lam" :: "[pttrn, 'a set, 'a => 'b] => ('a=>'b)"  ("(3%_:_./ _)" [0,0,3] 3)
    34 
    35 syntax (xsymbols)
    36   "_Pi" :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3\<Pi> _\<in>_./ _)"   10)
    37   "_lam" :: "[pttrn, 'a set, 'a => 'b] => ('a=>'b)"  ("(3\<lambda>_\<in>_./ _)" [0,0,3] 3)
    38 
    39 syntax (HTML output)
    40   "_Pi" :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3\<Pi> _\<in>_./ _)"   10)
    41   "_lam" :: "[pttrn, 'a set, 'a => 'b] => ('a=>'b)"  ("(3\<lambda>_\<in>_./ _)" [0,0,3] 3)
    42 
    43 translations
    44   "PI x:A. B" == "CONST Pi A (%x. B)"
    45   "%x:A. f" == "CONST restrict (%x. f) A"
    46 
    47 definition
    48   "compose" :: "['a set, 'b => 'c, 'a => 'b] => ('a => 'c)" where
    49   "compose A g f = (\<lambda>x\<in>A. g (f x))"
    50 
    51 
    52 subsection{*Basic Properties of @{term Pi}*}
    53 
    54 lemma Pi_I[intro!]: "(!!x. x \<in> A ==> f x \<in> B x) ==> f \<in> Pi A B"
    55   by (simp add: Pi_def)
    56 
    57 lemma Pi_I'[simp]: "(!!x. x : A --> f x : B x) ==> f : Pi A B"
    58 by(simp add:Pi_def)
    59 
    60 lemma funcsetI: "(!!x. x \<in> A ==> f x \<in> B) ==> f \<in> A -> B"
    61   by (simp add: Pi_def)
    62 
    63 lemma Pi_mem: "[|f: Pi A B; x \<in> A|] ==> f x \<in> B x"
    64   by (simp add: Pi_def)
    65 
    66 lemma Pi_iff: "f \<in> Pi I X \<longleftrightarrow> (\<forall>i\<in>I. f i \<in> X i)"
    67   unfolding Pi_def by auto
    68 
    69 lemma PiE [elim]:
    70   "f : Pi A B ==> (f x : B x ==> Q) ==> (x ~: A ==> Q) ==> Q"
    71 by(auto simp: Pi_def)
    72 
    73 lemma Pi_cong:
    74   "(\<And> w. w \<in> A \<Longrightarrow> f w = g w) \<Longrightarrow> f \<in> Pi A B \<longleftrightarrow> g \<in> Pi A B"
    75   by (auto simp: Pi_def)
    76 
    77 lemma funcset_id [simp]: "(\<lambda>x. x) \<in> A \<rightarrow> A"
    78   by auto
    79 
    80 lemma funcset_mem: "[|f \<in> A -> B; x \<in> A|] ==> f x \<in> B"
    81   by (simp add: Pi_def)
    82 
    83 lemma funcset_image: "f \<in> A\<rightarrow>B ==> f ` A \<subseteq> B"
    84 by auto
    85 
    86 lemma Pi_eq_empty[simp]: "((PI x: A. B x) = {}) = (\<exists>x\<in>A. B(x) = {})"
    87 apply (simp add: Pi_def, auto)
    88 txt{*Converse direction requires Axiom of Choice to exhibit a function
    89 picking an element from each non-empty @{term "B x"}*}
    90 apply (drule_tac x = "%u. SOME y. y \<in> B u" in spec, auto)
    91 apply (cut_tac P= "%y. y \<in> B x" in some_eq_ex, auto)
    92 done
    93 
    94 lemma Pi_empty [simp]: "Pi {} B = UNIV"
    95 by (simp add: Pi_def)
    96 
    97 lemma Pi_UNIV [simp]: "A -> UNIV = UNIV"
    98 by (simp add: Pi_def)
    99 (*
   100 lemma funcset_id [simp]: "(%x. x): A -> A"
   101   by (simp add: Pi_def)
   102 *)
   103 text{*Covariance of Pi-sets in their second argument*}
   104 lemma Pi_mono: "(!!x. x \<in> A ==> B x <= C x) ==> Pi A B <= Pi A C"
   105 by auto
   106 
   107 text{*Contravariance of Pi-sets in their first argument*}
   108 lemma Pi_anti_mono: "A' <= A ==> Pi A B <= Pi A' B"
   109 by auto
   110 
   111 lemma prod_final:
   112   assumes 1: "fst \<circ> f \<in> Pi A B" and 2: "snd \<circ> f \<in> Pi A C"
   113   shows "f \<in> (\<Pi> z \<in> A. B z \<times> C z)"
   114 proof (rule Pi_I) 
   115   fix z
   116   assume z: "z \<in> A" 
   117   have "f z = (fst (f z), snd (f z))" 
   118     by simp
   119   also have "...  \<in> B z \<times> C z"
   120     by (metis SigmaI PiE o_apply 1 2 z) 
   121   finally show "f z \<in> B z \<times> C z" .
   122 qed
   123 
   124 
   125 subsection{*Composition With a Restricted Domain: @{term compose}*}
   126 
   127 lemma funcset_compose:
   128   "[| f \<in> A -> B; g \<in> B -> C |]==> compose A g f \<in> A -> C"
   129 by (simp add: Pi_def compose_def restrict_def)
   130 
   131 lemma compose_assoc:
   132     "[| f \<in> A -> B; g \<in> B -> C; h \<in> C -> D |]
   133       ==> compose A h (compose A g f) = compose A (compose B h g) f"
   134 by (simp add: fun_eq_iff Pi_def compose_def restrict_def)
   135 
   136 lemma compose_eq: "x \<in> A ==> compose A g f x = g(f(x))"
   137 by (simp add: compose_def restrict_def)
   138 
   139 lemma surj_compose: "[| f ` A = B; g ` B = C |] ==> compose A g f ` A = C"
   140   by (auto simp add: image_def compose_eq)
   141 
   142 
   143 subsection{*Bounded Abstraction: @{term restrict}*}
   144 
   145 lemma restrict_in_funcset: "(!!x. x \<in> A ==> f x \<in> B) ==> (\<lambda>x\<in>A. f x) \<in> A -> B"
   146   by (simp add: Pi_def restrict_def)
   147 
   148 lemma restrictI[intro!]: "(!!x. x \<in> A ==> f x \<in> B x) ==> (\<lambda>x\<in>A. f x) \<in> Pi A B"
   149   by (simp add: Pi_def restrict_def)
   150 
   151 lemma restrict_apply [simp]:
   152     "(\<lambda>y\<in>A. f y) x = (if x \<in> A then f x else undefined)"
   153   by (simp add: restrict_def)
   154 
   155 lemma restrict_ext:
   156     "(!!x. x \<in> A ==> f x = g x) ==> (\<lambda>x\<in>A. f x) = (\<lambda>x\<in>A. g x)"
   157   by (simp add: fun_eq_iff Pi_def restrict_def)
   158 
   159 lemma inj_on_restrict_eq [simp]: "inj_on (restrict f A) A = inj_on f A"
   160   by (simp add: inj_on_def restrict_def)
   161 
   162 lemma Id_compose:
   163     "[|f \<in> A -> B;  f \<in> extensional A|] ==> compose A (\<lambda>y\<in>B. y) f = f"
   164   by (auto simp add: fun_eq_iff compose_def extensional_def Pi_def)
   165 
   166 lemma compose_Id:
   167     "[|g \<in> A -> B;  g \<in> extensional A|] ==> compose A g (\<lambda>x\<in>A. x) = g"
   168   by (auto simp add: fun_eq_iff compose_def extensional_def Pi_def)
   169 
   170 lemma image_restrict_eq [simp]: "(restrict f A) ` A = f ` A"
   171   by (auto simp add: restrict_def)
   172 
   173 
   174 subsection{*Bijections Between Sets*}
   175 
   176 text{*The definition of @{const bij_betw} is in @{text "Fun.thy"}, but most of
   177 the theorems belong here, or need at least @{term Hilbert_Choice}.*}
   178 
   179 lemma bij_betwI:
   180 assumes "f \<in> A \<rightarrow> B" and "g \<in> B \<rightarrow> A"
   181     and g_f: "\<And>x. x\<in>A \<Longrightarrow> g (f x) = x" and f_g: "\<And>y. y\<in>B \<Longrightarrow> f (g y) = y"
   182 shows "bij_betw f A B"
   183 unfolding bij_betw_def
   184 proof
   185   show "inj_on f A" by (metis g_f inj_on_def)
   186 next
   187   have "f ` A \<subseteq> B" using `f \<in> A \<rightarrow> B` by auto
   188   moreover
   189   have "B \<subseteq> f ` A" by auto (metis Pi_mem `g \<in> B \<rightarrow> A` f_g image_iff)
   190   ultimately show "f ` A = B" by blast
   191 qed
   192 
   193 lemma bij_betw_imp_funcset: "bij_betw f A B \<Longrightarrow> f \<in> A \<rightarrow> B"
   194 by (auto simp add: bij_betw_def)
   195 
   196 lemma inj_on_compose:
   197   "[| bij_betw f A B; inj_on g B |] ==> inj_on (compose A g f) A"
   198 by (auto simp add: bij_betw_def inj_on_def compose_eq)
   199 
   200 lemma bij_betw_compose:
   201   "[| bij_betw f A B; bij_betw g B C |] ==> bij_betw (compose A g f) A C"
   202 apply (simp add: bij_betw_def compose_eq inj_on_compose)
   203 apply (auto simp add: compose_def image_def)
   204 done
   205 
   206 lemma bij_betw_restrict_eq [simp]:
   207   "bij_betw (restrict f A) A B = bij_betw f A B"
   208 by (simp add: bij_betw_def)
   209 
   210 
   211 subsection{*Extensionality*}
   212 
   213 lemma extensional_arb: "[|f \<in> extensional A; x\<notin> A|] ==> f x = undefined"
   214 by (simp add: extensional_def)
   215 
   216 lemma restrict_extensional [simp]: "restrict f A \<in> extensional A"
   217 by (simp add: restrict_def extensional_def)
   218 
   219 lemma compose_extensional [simp]: "compose A f g \<in> extensional A"
   220 by (simp add: compose_def)
   221 
   222 lemma extensionalityI:
   223   "[| f \<in> extensional A; g \<in> extensional A;
   224       !!x. x\<in>A ==> f x = g x |] ==> f = g"
   225 by (force simp add: fun_eq_iff extensional_def)
   226 
   227 lemma extensional_restrict:  "f \<in> extensional A \<Longrightarrow> restrict f A = f"
   228 by(rule extensionalityI[OF restrict_extensional]) auto
   229 
   230 lemma inv_into_funcset: "f ` A = B ==> (\<lambda>x\<in>B. inv_into A f x) : B -> A"
   231 by (unfold inv_into_def) (fast intro: someI2)
   232 
   233 lemma compose_inv_into_id:
   234   "bij_betw f A B ==> compose A (\<lambda>y\<in>B. inv_into A f y) f = (\<lambda>x\<in>A. x)"
   235 apply (simp add: bij_betw_def compose_def)
   236 apply (rule restrict_ext, auto)
   237 done
   238 
   239 lemma compose_id_inv_into:
   240   "f ` A = B ==> compose B f (\<lambda>y\<in>B. inv_into A f y) = (\<lambda>x\<in>B. x)"
   241 apply (simp add: compose_def)
   242 apply (rule restrict_ext)
   243 apply (simp add: f_inv_into_f)
   244 done
   245 
   246 
   247 subsection{*Cardinality*}
   248 
   249 lemma card_inj: "[|f \<in> A\<rightarrow>B; inj_on f A; finite B|] ==> card(A) \<le> card(B)"
   250 by (rule card_inj_on_le) auto
   251 
   252 lemma card_bij:
   253   "[|f \<in> A\<rightarrow>B; inj_on f A;
   254      g \<in> B\<rightarrow>A; inj_on g B; finite A; finite B|] ==> card(A) = card(B)"
   255 by (blast intro: card_inj order_antisym)
   256 
   257 subsection {* Extensional Function Spaces *} 
   258 
   259 definition extensional_funcset
   260 where "extensional_funcset S T = (S -> T) \<inter> (extensional S)"
   261 
   262 lemma extensional_empty[simp]: "extensional {} = {%x. undefined}"
   263 unfolding extensional_def by auto
   264 
   265 lemma extensional_funcset_empty_domain: "extensional_funcset {} T = {%x. undefined}"
   266 unfolding extensional_funcset_def by simp
   267 
   268 lemma extensional_funcset_empty_range:
   269   assumes "S \<noteq> {}"
   270   shows "extensional_funcset S {} = {}"
   271 using assms unfolding extensional_funcset_def by auto
   272 
   273 lemma extensional_funcset_arb:
   274   assumes "f \<in> extensional_funcset S T" "x \<notin> S"
   275   shows "f x = undefined"
   276 using assms
   277 unfolding extensional_funcset_def by auto (auto dest!: extensional_arb)
   278 
   279 lemma extensional_funcset_mem: "f \<in> extensional_funcset S T \<Longrightarrow> x \<in> S \<Longrightarrow> f x \<in> T"
   280 unfolding extensional_funcset_def by auto
   281 
   282 lemma extensional_subset: "f : extensional A ==> A <= B ==> f : extensional B"
   283 unfolding extensional_def by auto
   284 
   285 lemma extensional_funcset_extend_domainI: "\<lbrakk> y \<in> T; f \<in> extensional_funcset S T\<rbrakk> \<Longrightarrow> f(x := y) \<in> extensional_funcset (insert x S) T"
   286 unfolding extensional_funcset_def extensional_def by auto
   287 
   288 lemma extensional_funcset_restrict_domain:
   289   "x \<notin> S \<Longrightarrow> f \<in> extensional_funcset (insert x S) T \<Longrightarrow> f(x := undefined) \<in> extensional_funcset S T"
   290 unfolding extensional_funcset_def extensional_def by auto
   291 
   292 lemma extensional_funcset_extend_domain_eq:
   293   assumes "x \<notin> S"
   294   shows
   295     "extensional_funcset (insert x S) T = (\<lambda>(y, g). g(x := y)) ` {(y, g). y \<in> T \<and> g \<in> extensional_funcset S T}"
   296   using assms
   297 proof -
   298   {
   299     fix f
   300     assume "f : extensional_funcset (insert x S) T"
   301     from this assms have "f : (%(y, g). g(x := y)) ` (T <*> extensional_funcset S T)"
   302       unfolding image_iff
   303       apply (rule_tac x="(f x, f(x := undefined))" in bexI)
   304     apply (auto intro: extensional_funcset_extend_domainI extensional_funcset_restrict_domain extensional_funcset_mem) done 
   305   }
   306   moreover
   307   {
   308     fix f
   309     assume "f : (%(y, g). g(x := y)) ` (T <*> extensional_funcset S T)"
   310     from this assms have "f : extensional_funcset (insert x S) T"
   311       by (auto intro: extensional_funcset_extend_domainI)
   312   }
   313   ultimately show ?thesis by auto
   314 qed
   315 
   316 lemma extensional_funcset_fun_upd_restricts_rangeI:  "\<forall> y \<in> S. f x \<noteq> f y ==> f : extensional_funcset (insert x S) T ==> f(x := undefined) : extensional_funcset S (T - {f x})"
   317 unfolding extensional_funcset_def extensional_def
   318 apply auto
   319 apply (case_tac "x = xa")
   320 apply auto done
   321 
   322 lemma extensional_funcset_fun_upd_extends_rangeI:
   323   assumes "a \<in> T" "f : extensional_funcset S (T - {a})"
   324   shows "f(x := a) : extensional_funcset (insert x S) T"
   325   using assms unfolding extensional_funcset_def extensional_def by auto
   326 
   327 subsubsection {* Injective Extensional Function Spaces *}
   328 
   329 lemma extensional_funcset_fun_upd_inj_onI:
   330   assumes "f \<in> extensional_funcset S (T - {a})" "inj_on f S"
   331   shows "inj_on (f(x := a)) S"
   332   using assms unfolding extensional_funcset_def by (auto intro!: inj_on_fun_updI)
   333 
   334 lemma extensional_funcset_extend_domain_inj_on_eq:
   335   assumes "x \<notin> S"
   336   shows"{f. f \<in> extensional_funcset (insert x S) T \<and> inj_on f (insert x S)} =
   337     (%(y, g). g(x:=y)) ` {(y, g). y \<in> T \<and> g \<in> extensional_funcset S (T - {y}) \<and> inj_on g S}"
   338 proof -
   339   from assms show ?thesis
   340     apply auto
   341     apply (auto intro: extensional_funcset_fun_upd_inj_onI extensional_funcset_fun_upd_extends_rangeI)
   342     apply (auto simp add: image_iff inj_on_def)
   343     apply (rule_tac x="xa x" in exI)
   344     apply (auto intro: extensional_funcset_mem)
   345     apply (rule_tac x="xa(x := undefined)" in exI)
   346     apply (auto intro!: extensional_funcset_fun_upd_restricts_rangeI)
   347     apply (auto dest!: extensional_funcset_mem split: split_if_asm)
   348     done
   349 qed
   350 
   351 lemma extensional_funcset_extend_domain_inj_onI:
   352   assumes "x \<notin> S"
   353   shows "inj_on (\<lambda>(y, g). g(x := y)) {(y, g). y \<in> T \<and> g \<in> extensional_funcset S (T - {y}) \<and> inj_on g S}"
   354 proof -
   355   from assms show ?thesis
   356     apply (auto intro!: inj_onI)
   357     apply (metis fun_upd_same)
   358     by (metis assms extensional_funcset_arb fun_upd_triv fun_upd_upd)
   359 qed
   360   
   361 
   362 subsubsection {* Cardinality *}
   363 
   364 lemma card_extensional_funcset:
   365   assumes "finite S"
   366   shows "card (extensional_funcset S T) = (card T) ^ (card S)"
   367 using assms
   368 proof (induct rule: finite_induct)
   369   case empty
   370   show ?case
   371     by (auto simp add: extensional_funcset_empty_domain)
   372 next
   373   case (insert x S)
   374   {
   375     fix g g' y y'
   376     assume assms: "g \<in> extensional_funcset S T"
   377       "g' \<in> extensional_funcset S T"
   378       "y \<in> T" "y' \<in> T"
   379       "g(x := y) = g'(x := y')"
   380     from this have "y = y'"
   381       by (metis fun_upd_same)
   382     have "g = g'"
   383       by (metis assms(1) assms(2) assms(5) extensional_funcset_arb fun_upd_triv fun_upd_upd insert(2))
   384   from `y = y'` `g = g'` have "y = y' & g = g'" by simp
   385   }
   386   from this have "inj_on (\<lambda>(y, g). g (x := y)) (T \<times> extensional_funcset S T)"
   387     by (auto intro: inj_onI)
   388   from this insert.hyps show ?case
   389     by (simp add: extensional_funcset_extend_domain_eq card_image card_cartesian_product)
   390 qed
   391 
   392 lemma finite_extensional_funcset:
   393   assumes "finite S" "finite T"
   394   shows "finite (extensional_funcset S T)"
   395 proof -
   396   from card_extensional_funcset[OF assms(1), of T] assms(2)
   397   have "(card (extensional_funcset S T) \<noteq> 0) \<or> (S \<noteq> {} \<and> T = {})"
   398     by auto
   399   from this show ?thesis
   400   proof
   401     assume "card (extensional_funcset S T) \<noteq> 0"
   402     from this show ?thesis
   403       by (auto intro: card_ge_0_finite)
   404   next
   405     assume "S \<noteq> {} \<and> T = {}"
   406     from this show ?thesis
   407       by (auto simp add: extensional_funcset_empty_range)
   408   qed
   409 qed
   410 
   411 end