src/HOL/Library/Poly_Deriv.thy
author Christian Sternagel
Wed Aug 29 12:23:14 2012 +0900 (2012-08-29)
changeset 49083 01081bca31b6
parent 47108 2a1953f0d20d
child 52380 3cc46b8cca5e
permissions -rw-r--r--
dropped ord and bot instance for list prefixes (use locale interpretation instead, which allows users to decide what order to use on lists)
     1 (*  Title:      HOL/Library/Poly_Deriv.thy
     2     Author:     Amine Chaieb
     3     Author:     Brian Huffman
     4 *)
     5 
     6 header{* Polynomials and Differentiation *}
     7 
     8 theory Poly_Deriv
     9 imports Deriv Polynomial
    10 begin
    11 
    12 subsection {* Derivatives of univariate polynomials *}
    13 
    14 definition
    15   pderiv :: "'a::real_normed_field poly \<Rightarrow> 'a poly" where
    16   "pderiv = poly_rec 0 (\<lambda>a p p'. p + pCons 0 p')"
    17 
    18 lemma pderiv_0 [simp]: "pderiv 0 = 0"
    19   unfolding pderiv_def by (simp add: poly_rec_0)
    20 
    21 lemma pderiv_pCons: "pderiv (pCons a p) = p + pCons 0 (pderiv p)"
    22   unfolding pderiv_def by (simp add: poly_rec_pCons)
    23 
    24 lemma coeff_pderiv: "coeff (pderiv p) n = of_nat (Suc n) * coeff p (Suc n)"
    25   apply (induct p arbitrary: n, simp)
    26   apply (simp add: pderiv_pCons coeff_pCons algebra_simps split: nat.split)
    27   done
    28 
    29 lemma pderiv_eq_0_iff: "pderiv p = 0 \<longleftrightarrow> degree p = 0"
    30   apply (rule iffI)
    31   apply (cases p, simp)
    32   apply (simp add: expand_poly_eq coeff_pderiv del: of_nat_Suc)
    33   apply (simp add: expand_poly_eq coeff_pderiv coeff_eq_0)
    34   done
    35 
    36 lemma degree_pderiv: "degree (pderiv p) = degree p - 1"
    37   apply (rule order_antisym [OF degree_le])
    38   apply (simp add: coeff_pderiv coeff_eq_0)
    39   apply (cases "degree p", simp)
    40   apply (rule le_degree)
    41   apply (simp add: coeff_pderiv del: of_nat_Suc)
    42   apply (rule subst, assumption)
    43   apply (rule leading_coeff_neq_0, clarsimp)
    44   done
    45 
    46 lemma pderiv_singleton [simp]: "pderiv [:a:] = 0"
    47 by (simp add: pderiv_pCons)
    48 
    49 lemma pderiv_add: "pderiv (p + q) = pderiv p + pderiv q"
    50 by (rule poly_ext, simp add: coeff_pderiv algebra_simps)
    51 
    52 lemma pderiv_minus: "pderiv (- p) = - pderiv p"
    53 by (rule poly_ext, simp add: coeff_pderiv)
    54 
    55 lemma pderiv_diff: "pderiv (p - q) = pderiv p - pderiv q"
    56 by (rule poly_ext, simp add: coeff_pderiv algebra_simps)
    57 
    58 lemma pderiv_smult: "pderiv (smult a p) = smult a (pderiv p)"
    59 by (rule poly_ext, simp add: coeff_pderiv algebra_simps)
    60 
    61 lemma pderiv_mult: "pderiv (p * q) = p * pderiv q + q * pderiv p"
    62 apply (induct p)
    63 apply simp
    64 apply (simp add: pderiv_add pderiv_smult pderiv_pCons algebra_simps)
    65 done
    66 
    67 lemma pderiv_power_Suc:
    68   "pderiv (p ^ Suc n) = smult (of_nat (Suc n)) (p ^ n) * pderiv p"
    69 apply (induct n)
    70 apply simp
    71 apply (subst power_Suc)
    72 apply (subst pderiv_mult)
    73 apply (erule ssubst)
    74 apply (simp only: of_nat_Suc smult_add_left smult_1_left)
    75 apply (simp add: algebra_simps) (* FIXME *)
    76 done
    77 
    78 lemma DERIV_cmult2: "DERIV f x :> D ==> DERIV (%x. (f x) * c :: real) x :> D * c"
    79 by (simp add: DERIV_cmult mult_commute [of _ c])
    80 
    81 lemma DERIV_pow2: "DERIV (%x. x ^ Suc n) x :> real (Suc n) * (x ^ n)"
    82 by (rule DERIV_cong, rule DERIV_pow, simp)
    83 declare DERIV_pow2 [simp] DERIV_pow [simp]
    84 
    85 lemma DERIV_add_const: "DERIV f x :> D ==>  DERIV (%x. a + f x :: 'a::real_normed_field) x :> D"
    86 by (rule DERIV_cong, rule DERIV_add, auto)
    87 
    88 lemma poly_DERIV[simp]: "DERIV (%x. poly p x) x :> poly (pderiv p) x"
    89   by (induct p, auto intro!: DERIV_intros simp add: pderiv_pCons)
    90 
    91 text{* Consequences of the derivative theorem above*}
    92 
    93 lemma poly_differentiable[simp]: "(%x. poly p x) differentiable (x::real)"
    94 apply (simp add: differentiable_def)
    95 apply (blast intro: poly_DERIV)
    96 done
    97 
    98 lemma poly_isCont[simp]: "isCont (%x. poly p x) (x::real)"
    99 by (rule poly_DERIV [THEN DERIV_isCont])
   100 
   101 lemma poly_IVT_pos: "[| a < b; poly p (a::real) < 0; 0 < poly p b |]
   102       ==> \<exists>x. a < x & x < b & (poly p x = 0)"
   103 apply (cut_tac f = "%x. poly p x" and a = a and b = b and y = 0 in IVT_objl)
   104 apply (auto simp add: order_le_less)
   105 done
   106 
   107 lemma poly_IVT_neg: "[| (a::real) < b; 0 < poly p a; poly p b < 0 |]
   108       ==> \<exists>x. a < x & x < b & (poly p x = 0)"
   109 by (insert poly_IVT_pos [where p = "- p" ]) simp
   110 
   111 lemma poly_MVT: "(a::real) < b ==>
   112      \<exists>x. a < x & x < b & (poly p b - poly p a = (b - a) * poly (pderiv p) x)"
   113 apply (drule_tac f = "poly p" in MVT, auto)
   114 apply (rule_tac x = z in exI)
   115 apply (auto simp add: real_mult_left_cancel poly_DERIV [THEN DERIV_unique])
   116 done
   117 
   118 text{*Lemmas for Derivatives*}
   119 
   120 lemma order_unique_lemma:
   121   fixes p :: "'a::idom poly"
   122   assumes "[:-a, 1:] ^ n dvd p \<and> \<not> [:-a, 1:] ^ Suc n dvd p"
   123   shows "n = order a p"
   124 unfolding Polynomial.order_def
   125 apply (rule Least_equality [symmetric])
   126 apply (rule assms [THEN conjunct2])
   127 apply (erule contrapos_np)
   128 apply (rule power_le_dvd)
   129 apply (rule assms [THEN conjunct1])
   130 apply simp
   131 done
   132 
   133 lemma lemma_order_pderiv1:
   134   "pderiv ([:- a, 1:] ^ Suc n * q) = [:- a, 1:] ^ Suc n * pderiv q +
   135     smult (of_nat (Suc n)) (q * [:- a, 1:] ^ n)"
   136 apply (simp only: pderiv_mult pderiv_power_Suc)
   137 apply (simp del: power_Suc of_nat_Suc add: pderiv_pCons)
   138 done
   139 
   140 lemma dvd_add_cancel1:
   141   fixes a b c :: "'a::comm_ring_1"
   142   shows "a dvd b + c \<Longrightarrow> a dvd b \<Longrightarrow> a dvd c"
   143   by (drule (1) Rings.dvd_diff, simp)
   144 
   145 lemma lemma_order_pderiv [rule_format]:
   146      "\<forall>p q a. 0 < n &
   147        pderiv p \<noteq> 0 &
   148        p = [:- a, 1:] ^ n * q & ~ [:- a, 1:] dvd q
   149        --> n = Suc (order a (pderiv p))"
   150  apply (cases "n", safe, rename_tac n p q a)
   151  apply (rule order_unique_lemma)
   152  apply (rule conjI)
   153   apply (subst lemma_order_pderiv1)
   154   apply (rule dvd_add)
   155    apply (rule dvd_mult2)
   156    apply (rule le_imp_power_dvd, simp)
   157   apply (rule dvd_smult)
   158   apply (rule dvd_mult)
   159   apply (rule dvd_refl)
   160  apply (subst lemma_order_pderiv1)
   161  apply (erule contrapos_nn) back
   162  apply (subgoal_tac "[:- a, 1:] ^ Suc n dvd q * [:- a, 1:] ^ n")
   163   apply (simp del: mult_pCons_left)
   164  apply (drule dvd_add_cancel1)
   165   apply (simp del: mult_pCons_left)
   166  apply (drule dvd_smult_cancel, simp del: of_nat_Suc)
   167  apply assumption
   168 done
   169 
   170 lemma order_decomp:
   171      "p \<noteq> 0
   172       ==> \<exists>q. p = [:-a, 1:] ^ (order a p) * q &
   173                 ~([:-a, 1:] dvd q)"
   174 apply (drule order [where a=a])
   175 apply (erule conjE)
   176 apply (erule dvdE)
   177 apply (rule exI)
   178 apply (rule conjI, assumption)
   179 apply (erule contrapos_nn)
   180 apply (erule ssubst) back
   181 apply (subst power_Suc2)
   182 apply (erule mult_dvd_mono [OF dvd_refl])
   183 done
   184 
   185 lemma order_pderiv: "[| pderiv p \<noteq> 0; order a p \<noteq> 0 |]
   186       ==> (order a p = Suc (order a (pderiv p)))"
   187 apply (case_tac "p = 0", simp)
   188 apply (drule_tac a = a and p = p in order_decomp)
   189 using neq0_conv
   190 apply (blast intro: lemma_order_pderiv)
   191 done
   192 
   193 lemma order_mult: "p * q \<noteq> 0 \<Longrightarrow> order a (p * q) = order a p + order a q"
   194 proof -
   195   def i \<equiv> "order a p"
   196   def j \<equiv> "order a q"
   197   def t \<equiv> "[:-a, 1:]"
   198   have t_dvd_iff: "\<And>u. t dvd u \<longleftrightarrow> poly u a = 0"
   199     unfolding t_def by (simp add: dvd_iff_poly_eq_0)
   200   assume "p * q \<noteq> 0"
   201   then show "order a (p * q) = i + j"
   202     apply clarsimp
   203     apply (drule order [where a=a and p=p, folded i_def t_def])
   204     apply (drule order [where a=a and p=q, folded j_def t_def])
   205     apply clarify
   206     apply (rule order_unique_lemma [symmetric], fold t_def)
   207     apply (erule dvdE)+
   208     apply (simp add: power_add t_dvd_iff)
   209     done
   210 qed
   211 
   212 text{*Now justify the standard squarefree decomposition, i.e. f / gcd(f,f'). *}
   213 
   214 lemma order_divides: "[:-a, 1:] ^ n dvd p \<longleftrightarrow> p = 0 \<or> n \<le> order a p"
   215 apply (cases "p = 0", auto)
   216 apply (drule order_2 [where a=a and p=p])
   217 apply (erule contrapos_np)
   218 apply (erule power_le_dvd)
   219 apply simp
   220 apply (erule power_le_dvd [OF order_1])
   221 done
   222 
   223 lemma poly_squarefree_decomp_order:
   224   assumes "pderiv p \<noteq> 0"
   225   and p: "p = q * d"
   226   and p': "pderiv p = e * d"
   227   and d: "d = r * p + s * pderiv p"
   228   shows "order a q = (if order a p = 0 then 0 else 1)"
   229 proof (rule classical)
   230   assume 1: "order a q \<noteq> (if order a p = 0 then 0 else 1)"
   231   from `pderiv p \<noteq> 0` have "p \<noteq> 0" by auto
   232   with p have "order a p = order a q + order a d"
   233     by (simp add: order_mult)
   234   with 1 have "order a p \<noteq> 0" by (auto split: if_splits)
   235   have "order a (pderiv p) = order a e + order a d"
   236     using `pderiv p \<noteq> 0` `pderiv p = e * d` by (simp add: order_mult)
   237   have "order a p = Suc (order a (pderiv p))"
   238     using `pderiv p \<noteq> 0` `order a p \<noteq> 0` by (rule order_pderiv)
   239   have "d \<noteq> 0" using `p \<noteq> 0` `p = q * d` by simp
   240   have "([:-a, 1:] ^ (order a (pderiv p))) dvd d"
   241     apply (simp add: d)
   242     apply (rule dvd_add)
   243     apply (rule dvd_mult)
   244     apply (simp add: order_divides `p \<noteq> 0`
   245            `order a p = Suc (order a (pderiv p))`)
   246     apply (rule dvd_mult)
   247     apply (simp add: order_divides)
   248     done
   249   then have "order a (pderiv p) \<le> order a d"
   250     using `d \<noteq> 0` by (simp add: order_divides)
   251   show ?thesis
   252     using `order a p = order a q + order a d`
   253     using `order a (pderiv p) = order a e + order a d`
   254     using `order a p = Suc (order a (pderiv p))`
   255     using `order a (pderiv p) \<le> order a d`
   256     by auto
   257 qed
   258 
   259 lemma poly_squarefree_decomp_order2: "[| pderiv p \<noteq> 0;
   260          p = q * d;
   261          pderiv p = e * d;
   262          d = r * p + s * pderiv p
   263       |] ==> \<forall>a. order a q = (if order a p = 0 then 0 else 1)"
   264 apply (blast intro: poly_squarefree_decomp_order)
   265 done
   266 
   267 lemma order_pderiv2: "[| pderiv p \<noteq> 0; order a p \<noteq> 0 |]
   268       ==> (order a (pderiv p) = n) = (order a p = Suc n)"
   269 apply (auto dest: order_pderiv)
   270 done
   271 
   272 definition
   273   rsquarefree :: "'a::idom poly => bool" where
   274   "rsquarefree p = (p \<noteq> 0 & (\<forall>a. (order a p = 0) | (order a p = 1)))"
   275 
   276 lemma pderiv_iszero: "pderiv p = 0 \<Longrightarrow> \<exists>h. p = [:h:]"
   277 apply (simp add: pderiv_eq_0_iff)
   278 apply (case_tac p, auto split: if_splits)
   279 done
   280 
   281 lemma rsquarefree_roots:
   282   "rsquarefree p = (\<forall>a. ~(poly p a = 0 & poly (pderiv p) a = 0))"
   283 apply (simp add: rsquarefree_def)
   284 apply (case_tac "p = 0", simp, simp)
   285 apply (case_tac "pderiv p = 0")
   286 apply simp
   287 apply (drule pderiv_iszero, clarify)
   288 apply simp
   289 apply (rule allI)
   290 apply (cut_tac p = "[:h:]" and a = a in order_root)
   291 apply simp
   292 apply (auto simp add: order_root order_pderiv2)
   293 apply (erule_tac x="a" in allE, simp)
   294 done
   295 
   296 lemma poly_squarefree_decomp:
   297   assumes "pderiv p \<noteq> 0"
   298     and "p = q * d"
   299     and "pderiv p = e * d"
   300     and "d = r * p + s * pderiv p"
   301   shows "rsquarefree q & (\<forall>a. (poly q a = 0) = (poly p a = 0))"
   302 proof -
   303   from `pderiv p \<noteq> 0` have "p \<noteq> 0" by auto
   304   with `p = q * d` have "q \<noteq> 0" by simp
   305   have "\<forall>a. order a q = (if order a p = 0 then 0 else 1)"
   306     using assms by (rule poly_squarefree_decomp_order2)
   307   with `p \<noteq> 0` `q \<noteq> 0` show ?thesis
   308     by (simp add: rsquarefree_def order_root)
   309 qed
   310 
   311 end