src/HOL/Tools/Sledgehammer/sledgehammer_util.ML
author wenzelm
Mon May 17 23:54:15 2010 +0200 (2010-05-17)
changeset 36960 01594f816e3a
parent 36555 8ff45c2076da
child 37321 9d7cfae95b30
permissions -rw-r--r--
prefer structure Keyword, Parse, Parse_Spec, Outer_Syntax;
eliminated old-style structure aliases K = Keyword, P = Parse;
     1 (*  Title:      HOL/Tools/Sledgehammer/sledgehammer_util.ML
     2     Author:     Jasmin Blanchette, TU Muenchen
     3 
     4 General-purpose functions used by the Sledgehammer modules.
     5 *)
     6 
     7 signature SLEDGEHAMMER_UTIL =
     8 sig
     9   val is_new_spass_version : bool
    10   val pairf : ('a -> 'b) -> ('a -> 'c) -> 'a -> 'b * 'c
    11   val plural_s : int -> string
    12   val serial_commas : string -> string list -> string list
    13   val replace_all : string -> string -> string -> string
    14   val remove_all : string -> string -> string
    15   val timestamp : unit -> string
    16   val parse_bool_option : bool -> string -> string -> bool option
    17   val parse_time_option : string -> string -> Time.time option
    18   val nat_subscript : int -> string
    19   val unyxml : string -> string
    20   val maybe_quote : string -> string
    21   val monomorphic_term : Type.tyenv -> term -> term
    22   val specialize_type : theory -> (string * typ) -> term -> term
    23 end;
    24  
    25 structure Sledgehammer_Util : SLEDGEHAMMER_UTIL =
    26 struct
    27 
    28 val is_new_spass_version =
    29   case getenv "SPASS_VERSION" of
    30     "" => (case getenv "SPASS_HOME" of
    31              "" => false
    32            | s =>
    33              (* Hack: Preliminary versions of the SPASS 3.7 package don't set
    34                 "SPASS_VERSION". *)
    35              String.isSubstring "/spass-3.7/" s)
    36   | s => (case s |> space_explode "." |> map Int.fromString of
    37             SOME m :: SOME n :: _ => m > 3 orelse (m = 3 andalso n >= 5)
    38           | _ => false)
    39 
    40 fun pairf f g x = (f x, g x)
    41 
    42 fun plural_s n = if n = 1 then "" else "s"
    43 
    44 fun serial_commas _ [] = ["??"]
    45   | serial_commas _ [s] = [s]
    46   | serial_commas conj [s1, s2] = [s1, conj, s2]
    47   | serial_commas conj [s1, s2, s3] = [s1 ^ ",", s2 ^ ",", conj, s3]
    48   | serial_commas conj (s :: ss) = s ^ "," :: serial_commas conj ss
    49 
    50 fun replace_all bef aft =
    51   let
    52     fun aux seen "" = String.implode (rev seen)
    53       | aux seen s =
    54         if String.isPrefix bef s then
    55           aux seen "" ^ aft ^ aux [] (unprefix bef s)
    56         else
    57           aux (String.sub (s, 0) :: seen) (String.extract (s, 1, NONE))
    58   in aux [] end
    59 fun remove_all bef = replace_all bef ""
    60 
    61 val timestamp = Date.fmt "%Y-%m-%d %H:%M:%S" o Date.fromTimeLocal o Time.now
    62 
    63 fun parse_bool_option option name s =
    64   (case s of
    65      "smart" => if option then NONE else raise Option
    66    | "false" => SOME false
    67    | "true" => SOME true
    68    | "" => SOME true
    69    | _ => raise Option)
    70   handle Option.Option =>
    71          let val ss = map quote ((option ? cons "smart") ["true", "false"]) in
    72            error ("Parameter " ^ quote name ^ " must be assigned " ^
    73                   space_implode " " (serial_commas "or" ss) ^ ".")
    74          end
    75 
    76 fun parse_time_option _ "none" = NONE
    77   | parse_time_option name s =
    78     let
    79       val msecs =
    80         case space_explode " " s of
    81           [s1, "min"] => 60000 * the (Int.fromString s1)
    82         | [s1, "s"] => 1000 * the (Int.fromString s1)
    83         | [s1, "ms"] => the (Int.fromString s1)
    84         | _ => 0
    85     in
    86       if msecs <= 0 then
    87         error ("Parameter " ^ quote name ^ " must be assigned a positive time \
    88                \value (e.g., \"60 s\", \"200 ms\") or \"none\".")
    89       else
    90         SOME (Time.fromMilliseconds msecs)
    91     end
    92 
    93 val subscript = implode o map (prefix "\<^isub>") o explode
    94 val nat_subscript = subscript o string_of_int
    95 
    96 fun plain_string_from_xml_tree t =
    97   Buffer.empty |> XML.add_content t |> Buffer.content
    98 val unyxml = plain_string_from_xml_tree o YXML.parse
    99 
   100 val is_long_identifier = forall Syntax.is_identifier o space_explode "."
   101 fun maybe_quote y =
   102   let val s = unyxml y in
   103     y |> ((not (is_long_identifier (perhaps (try (unprefix "'")) s)) andalso
   104            not (is_long_identifier (perhaps (try (unprefix "?")) s))) orelse
   105            Keyword.is_keyword s) ? quote
   106   end
   107 
   108 fun monomorphic_term subst t =
   109   map_types (map_type_tvar (fn v =>
   110       case Type.lookup subst v of
   111         SOME typ => typ
   112       | NONE => raise TERM ("monomorphic_term: uninstanitated schematic type \
   113                             \variable", [t]))) t
   114 
   115 fun specialize_type thy (s, T) t =
   116   let
   117     fun subst_for (Const (s', T')) =
   118       if s = s' then
   119         SOME (Sign.typ_match thy (T', T) Vartab.empty)
   120         handle Type.TYPE_MATCH => NONE
   121       else
   122         NONE
   123     | subst_for (t1 $ t2) =
   124       (case subst_for t1 of SOME x => SOME x | NONE => subst_for t2)
   125     | subst_for (Abs (_, _, t')) = subst_for t'
   126     | subst_for _ = NONE
   127   in
   128     case subst_for t of
   129       SOME subst => monomorphic_term subst t
   130     | NONE => raise Type.TYPE_MATCH
   131   end
   132 
   133 
   134 end;