src/HOL/Tools/Meson/meson_clausify.ML
author blanchet
Thu May 12 15:29:19 2011 +0200 (2011-05-12)
changeset 42739 017e5dac8642
parent 42361 23f352990944
child 42747 f132d13fcf75
permissions -rw-r--r--
added unfold set constant functionality to Meson/Metis -- disabled by default for now
     1 (*  Title:      HOL/Tools/Meson/meson_clausify.ML
     2     Author:     Jia Meng, Cambridge University Computer Laboratory and NICTA
     3     Author:     Jasmin Blanchette, TU Muenchen
     4 
     5 Transformation of HOL theorems into CNF forms.
     6 *)
     7 
     8 signature MESON_CLAUSIFY =
     9 sig
    10   val new_skolem_var_prefix : string
    11   val new_nonskolem_var_prefix : string
    12   val is_zapped_var_name : string -> bool
    13   val extensionalize_theorem : thm -> thm
    14   val introduce_combinators_in_cterm : cterm -> thm
    15   val introduce_combinators_in_theorem : thm -> thm
    16   val cluster_of_zapped_var_name : string -> (int * (int * int)) * bool
    17   val ss_only : thm list -> simpset
    18   val cnf_axiom :
    19     Proof.context -> bool -> int -> thm -> (thm * term) option * thm list
    20 end;
    21 
    22 structure Meson_Clausify : MESON_CLAUSIFY =
    23 struct
    24 
    25 open Meson
    26 
    27 (* the extra "Meson" helps prevent clashes (FIXME) *)
    28 val new_skolem_var_prefix = "MesonSK"
    29 val new_nonskolem_var_prefix = "MesonV"
    30 
    31 fun is_zapped_var_name s =
    32   exists (fn prefix => String.isPrefix prefix s)
    33          [new_skolem_var_prefix, new_nonskolem_var_prefix]
    34 
    35 (**** Transformation of Elimination Rules into First-Order Formulas****)
    36 
    37 val cfalse = cterm_of @{theory HOL} HOLogic.false_const;
    38 val ctp_false = cterm_of @{theory HOL} (HOLogic.mk_Trueprop HOLogic.false_const);
    39 
    40 (* Converts an elim-rule into an equivalent theorem that does not have the
    41    predicate variable. Leaves other theorems unchanged. We simply instantiate
    42    the conclusion variable to False. (Cf. "transform_elim_term" in
    43    "Sledgehammer_Util".) *)
    44 fun transform_elim_theorem th =
    45   case concl_of th of    (*conclusion variable*)
    46        @{const Trueprop} $ (v as Var (_, @{typ bool})) =>
    47            Thm.instantiate ([], [(cterm_of @{theory HOL} v, cfalse)]) th
    48     | v as Var(_, @{typ prop}) =>
    49            Thm.instantiate ([], [(cterm_of @{theory HOL} v, ctp_false)]) th
    50     | _ => th
    51 
    52 
    53 (**** SKOLEMIZATION BY INFERENCE (lcp) ****)
    54 
    55 fun mk_old_skolem_term_wrapper t =
    56   let val T = fastype_of t in
    57     Const (@{const_name Meson.skolem}, T --> T) $ t
    58   end
    59 
    60 fun beta_eta_in_abs_body (Abs (s, T, t')) = Abs (s, T, beta_eta_in_abs_body t')
    61   | beta_eta_in_abs_body t = Envir.beta_eta_contract t
    62 
    63 (*Traverse a theorem, accumulating Skolem function definitions.*)
    64 fun old_skolem_defs th =
    65   let
    66     fun dec_sko (Const (@{const_name Ex}, _) $ (body as Abs (_, T, p))) rhss =
    67         (*Existential: declare a Skolem function, then insert into body and continue*)
    68         let
    69           val args = OldTerm.term_frees body
    70           (* Forms a lambda-abstraction over the formal parameters *)
    71           val rhs =
    72             list_abs_free (map dest_Free args,
    73                            HOLogic.choice_const T $ beta_eta_in_abs_body body)
    74             |> mk_old_skolem_term_wrapper
    75           val comb = list_comb (rhs, args)
    76         in dec_sko (subst_bound (comb, p)) (rhs :: rhss) end
    77       | dec_sko (Const (@{const_name All},_) $ Abs (a, T, p)) rhss =
    78         (*Universal quant: insert a free variable into body and continue*)
    79         let val fname = Name.variant (OldTerm.add_term_names (p,[])) a
    80         in dec_sko (subst_bound (Free(fname,T), p)) rhss end
    81       | dec_sko (@{const conj} $ p $ q) rhss = rhss |> dec_sko p |> dec_sko q
    82       | dec_sko (@{const disj} $ p $ q) rhss = rhss |> dec_sko p |> dec_sko q
    83       | dec_sko (@{const Trueprop} $ p) rhss = dec_sko p rhss
    84       | dec_sko _ rhss = rhss
    85   in  dec_sko (prop_of th) []  end;
    86 
    87 
    88 (**** REPLACING ABSTRACTIONS BY COMBINATORS ****)
    89 
    90 val fun_cong_all = @{thm fun_eq_iff [THEN iffD1]}
    91 
    92 (* Removes the lambdas from an equation of the form "t = (%x. u)".
    93    (Cf. "extensionalize_term" in "Sledgehammer_Translate".) *)
    94 fun extensionalize_theorem th =
    95   case prop_of th of
    96     _ $ (Const (@{const_name HOL.eq}, Type (_, [Type (@{type_name fun}, _), _]))
    97          $ _ $ Abs _) => extensionalize_theorem (th RS fun_cong_all)
    98   | _ => th
    99 
   100 fun is_quasi_lambda_free (Const (@{const_name Meson.skolem}, _) $ _) = true
   101   | is_quasi_lambda_free (t1 $ t2) =
   102     is_quasi_lambda_free t1 andalso is_quasi_lambda_free t2
   103   | is_quasi_lambda_free (Abs _) = false
   104   | is_quasi_lambda_free _ = true
   105 
   106 val [f_B,g_B] = map (cterm_of @{theory}) (OldTerm.term_vars (prop_of @{thm abs_B}));
   107 val [g_C,f_C] = map (cterm_of @{theory}) (OldTerm.term_vars (prop_of @{thm abs_C}));
   108 val [f_S,g_S] = map (cterm_of @{theory}) (OldTerm.term_vars (prop_of @{thm abs_S}));
   109 
   110 (* FIXME: Requires more use of cterm constructors. *)
   111 fun abstract ct =
   112   let
   113       val thy = theory_of_cterm ct
   114       val Abs(x,_,body) = term_of ct
   115       val Type(@{type_name fun}, [xT,bodyT]) = typ_of (ctyp_of_term ct)
   116       val cxT = ctyp_of thy xT
   117       val cbodyT = ctyp_of thy bodyT
   118       fun makeK () =
   119         instantiate' [SOME cxT, SOME cbodyT] [SOME (cterm_of thy body)]
   120                      @{thm abs_K}
   121   in
   122       case body of
   123           Const _ => makeK()
   124         | Free _ => makeK()
   125         | Var _ => makeK()  (*though Var isn't expected*)
   126         | Bound 0 => instantiate' [SOME cxT] [] @{thm abs_I} (*identity: I*)
   127         | rator$rand =>
   128             if Term.is_dependent rator then (*C or S*)
   129                if Term.is_dependent rand then (*S*)
   130                  let val crator = cterm_of thy (Abs(x,xT,rator))
   131                      val crand = cterm_of thy (Abs(x,xT,rand))
   132                      val abs_S' = cterm_instantiate [(f_S,crator),(g_S,crand)] @{thm abs_S}
   133                      val (_,rhs) = Thm.dest_equals (cprop_of abs_S')
   134                  in
   135                    Thm.transitive abs_S' (Conv.binop_conv abstract rhs)
   136                  end
   137                else (*C*)
   138                  let val crator = cterm_of thy (Abs(x,xT,rator))
   139                      val abs_C' = cterm_instantiate [(f_C,crator),(g_C,cterm_of thy rand)] @{thm abs_C}
   140                      val (_,rhs) = Thm.dest_equals (cprop_of abs_C')
   141                  in
   142                    Thm.transitive abs_C' (Conv.fun_conv (Conv.arg_conv abstract) rhs)
   143                  end
   144             else if Term.is_dependent rand then (*B or eta*)
   145                if rand = Bound 0 then Thm.eta_conversion ct
   146                else (*B*)
   147                  let val crand = cterm_of thy (Abs(x,xT,rand))
   148                      val crator = cterm_of thy rator
   149                      val abs_B' = cterm_instantiate [(f_B,crator),(g_B,crand)] @{thm abs_B}
   150                      val (_,rhs) = Thm.dest_equals (cprop_of abs_B')
   151                  in Thm.transitive abs_B' (Conv.arg_conv abstract rhs) end
   152             else makeK()
   153         | _ => raise Fail "abstract: Bad term"
   154   end;
   155 
   156 (* Traverse a theorem, remplacing lambda-abstractions with combinators. *)
   157 fun introduce_combinators_in_cterm ct =
   158   if is_quasi_lambda_free (term_of ct) then
   159     Thm.reflexive ct
   160   else case term_of ct of
   161     Abs _ =>
   162     let
   163       val (cv, cta) = Thm.dest_abs NONE ct
   164       val (v, _) = dest_Free (term_of cv)
   165       val u_th = introduce_combinators_in_cterm cta
   166       val cu = Thm.rhs_of u_th
   167       val comb_eq = abstract (Thm.cabs cv cu)
   168     in Thm.transitive (Thm.abstract_rule v cv u_th) comb_eq end
   169   | _ $ _ =>
   170     let val (ct1, ct2) = Thm.dest_comb ct in
   171         Thm.combination (introduce_combinators_in_cterm ct1)
   172                         (introduce_combinators_in_cterm ct2)
   173     end
   174 
   175 fun introduce_combinators_in_theorem th =
   176   if is_quasi_lambda_free (prop_of th) then
   177     th
   178   else
   179     let
   180       val th = Drule.eta_contraction_rule th
   181       val eqth = introduce_combinators_in_cterm (cprop_of th)
   182     in Thm.equal_elim eqth th end
   183     handle THM (msg, _, _) =>
   184            (warning ("Error in the combinator translation of " ^
   185                      Display.string_of_thm_without_context th ^
   186                      "\nException message: " ^ msg ^ ".");
   187             (* A type variable of sort "{}" will make abstraction fail. *)
   188             TrueI)
   189 
   190 (*cterms are used throughout for efficiency*)
   191 val cTrueprop = cterm_of @{theory HOL} HOLogic.Trueprop;
   192 
   193 (*Given an abstraction over n variables, replace the bound variables by free
   194   ones. Return the body, along with the list of free variables.*)
   195 fun c_variant_abs_multi (ct0, vars) =
   196       let val (cv,ct) = Thm.dest_abs NONE ct0
   197       in  c_variant_abs_multi (ct, cv::vars)  end
   198       handle CTERM _ => (ct0, rev vars);
   199 
   200 val skolem_def_raw = @{thms skolem_def_raw}
   201 
   202 (* Given the definition of a Skolem function, return a theorem to replace
   203    an existential formula by a use of that function.
   204    Example: "EX x. x : A & x ~: B ==> sko A B : A & sko A B ~: B"  [.] *)
   205 fun old_skolem_theorem_from_def thy rhs0 =
   206   let
   207     val rhs = rhs0 |> Type.legacy_freeze_thaw |> #1 |> cterm_of thy
   208     val rhs' = rhs |> Thm.dest_comb |> snd
   209     val (ch, frees) = c_variant_abs_multi (rhs', [])
   210     val (hilbert, cabs) = ch |> Thm.dest_comb |>> term_of
   211     val T =
   212       case hilbert of
   213         Const (_, Type (@{type_name fun}, [_, T])) => T
   214       | _ => raise TERM ("old_skolem_theorem_from_def: expected \"Eps\"",
   215                          [hilbert])
   216     val cex = cterm_of thy (HOLogic.exists_const T)
   217     val ex_tm = Thm.capply cTrueprop (Thm.capply cex cabs)
   218     val conc =
   219       Drule.list_comb (rhs, frees)
   220       |> Drule.beta_conv cabs |> Thm.capply cTrueprop
   221     fun tacf [prem] =
   222       rewrite_goals_tac skolem_def_raw
   223       THEN rtac ((prem |> rewrite_rule skolem_def_raw)
   224                  RS Global_Theory.get_thm thy "Hilbert_Choice.someI_ex") 1
   225   in
   226     Goal.prove_internal [ex_tm] conc tacf
   227     |> forall_intr_list frees
   228     |> Thm.forall_elim_vars 0  (*Introduce Vars, but don't discharge defs.*)
   229     |> Thm.varifyT_global
   230   end
   231 
   232 fun to_definitional_cnf_with_quantifiers ctxt th =
   233   let
   234     val eqth = cnf.make_cnfx_thm ctxt (HOLogic.dest_Trueprop (prop_of th))
   235     val eqth = eqth RS @{thm eq_reflection}
   236     val eqth = eqth RS @{thm TruepropI}
   237   in Thm.equal_elim eqth th end
   238 
   239 fun zapped_var_name ((ax_no, cluster_no), skolem) index_no s =
   240   (if skolem then new_skolem_var_prefix else new_nonskolem_var_prefix) ^
   241   "_" ^ string_of_int ax_no ^ "_" ^ string_of_int cluster_no ^ "_" ^
   242   string_of_int index_no ^ "_" ^ Name.desymbolize false s
   243 
   244 fun cluster_of_zapped_var_name s =
   245   let val get_int = the o Int.fromString o nth (space_explode "_" s) in
   246     ((get_int 1, (get_int 2, get_int 3)),
   247      String.isPrefix new_skolem_var_prefix s)
   248   end
   249 
   250 fun rename_bound_vars_to_be_zapped ax_no =
   251   let
   252     fun aux (cluster as (cluster_no, cluster_skolem)) index_no pos t =
   253       case t of
   254         (t1 as Const (s, _)) $ Abs (s', T, t') =>
   255         if s = @{const_name all} orelse s = @{const_name All} orelse
   256            s = @{const_name Ex} then
   257           let
   258             val skolem = (pos = (s = @{const_name Ex}))
   259             val (cluster, index_no) =
   260               if skolem = cluster_skolem then (cluster, index_no)
   261               else ((cluster_no ||> cluster_skolem ? Integer.add 1, skolem), 0)
   262             val s' = zapped_var_name cluster index_no s'
   263           in t1 $ Abs (s', T, aux cluster (index_no + 1) pos t') end
   264         else
   265           t
   266       | (t1 as Const (s, _)) $ t2 $ t3 =>
   267         if s = @{const_name "==>"} orelse s = @{const_name HOL.implies} then
   268           t1 $ aux cluster index_no (not pos) t2 $ aux cluster index_no pos t3
   269         else if s = @{const_name HOL.conj} orelse
   270                 s = @{const_name HOL.disj} then
   271           t1 $ aux cluster index_no pos t2 $ aux cluster index_no pos t3
   272         else
   273           t
   274       | (t1 as Const (s, _)) $ t2 =>
   275         if s = @{const_name Trueprop} then
   276           t1 $ aux cluster index_no pos t2
   277         else if s = @{const_name Not} then
   278           t1 $ aux cluster index_no (not pos) t2
   279         else
   280           t
   281       | _ => t
   282   in aux ((ax_no, 0), true) 0 true end
   283 
   284 fun zap pos ct =
   285   ct
   286   |> (case term_of ct of
   287         Const (s, _) $ Abs (s', _, _) =>
   288         if s = @{const_name all} orelse s = @{const_name All} orelse
   289            s = @{const_name Ex} then
   290           Thm.dest_comb #> snd #> Thm.dest_abs (SOME s') #> snd #> zap pos
   291         else
   292           Conv.all_conv
   293       | Const (s, _) $ _ $ _ =>
   294         if s = @{const_name "==>"} orelse s = @{const_name implies} then
   295           Conv.combination_conv (Conv.arg_conv (zap (not pos))) (zap pos)
   296         else if s = @{const_name conj} orelse s = @{const_name disj} then
   297           Conv.combination_conv (Conv.arg_conv (zap pos)) (zap pos)
   298         else
   299           Conv.all_conv
   300       | Const (s, _) $ _ =>
   301         if s = @{const_name Trueprop} then Conv.arg_conv (zap pos)
   302         else if s = @{const_name Not} then Conv.arg_conv (zap (not pos))
   303         else Conv.all_conv
   304       | _ => Conv.all_conv)
   305 
   306 fun ss_only ths = Simplifier.clear_ss HOL_basic_ss addsimps ths
   307 
   308 val cheat_choice =
   309   @{prop "ALL x. EX y. Q x y ==> EX f. ALL x. Q x (f x)"}
   310   |> Logic.varify_global
   311   |> Skip_Proof.make_thm @{theory}
   312 
   313 (* Converts an Isabelle theorem into NNF. *)
   314 fun nnf_axiom choice_ths new_skolemizer ax_no th ctxt =
   315   let
   316     val thy = Proof_Context.theory_of ctxt
   317     val th =
   318       th |> transform_elim_theorem
   319          |> zero_var_indexes
   320          |> new_skolemizer ? forall_intr_vars
   321     val (th, ctxt) = Variable.import true [th] ctxt |>> snd |>> the_single
   322     val th = th |> Conv.fconv_rule Object_Logic.atomize
   323                 |> Raw_Simplifier.rewrite_rule (unfold_set_const_simps ctxt)
   324                 |> extensionalize_theorem
   325                 |> make_nnf ctxt
   326   in
   327     if new_skolemizer then
   328       let
   329         fun skolemize choice_ths =
   330           skolemize_with_choice_theorems ctxt choice_ths
   331           #> simplify (ss_only @{thms all_simps[symmetric]})
   332         val no_choice = null choice_ths
   333         val pull_out =
   334           if no_choice then
   335             simplify (ss_only @{thms all_simps[symmetric] ex_simps[symmetric]})
   336           else
   337             skolemize choice_ths
   338         val discharger_th = th |> pull_out
   339         val discharger_th =
   340           discharger_th |> has_too_many_clauses ctxt (concl_of discharger_th)
   341                            ? (to_definitional_cnf_with_quantifiers ctxt
   342                               #> pull_out)
   343         val zapped_th =
   344           discharger_th |> prop_of |> rename_bound_vars_to_be_zapped ax_no
   345           |> (if no_choice then
   346                 Skip_Proof.make_thm thy #> skolemize [cheat_choice] #> cprop_of
   347               else
   348                 cterm_of thy)
   349           |> zap true
   350         val fixes =
   351           [] |> Term.add_free_names (prop_of zapped_th)
   352              |> filter is_zapped_var_name
   353         val ctxt' = ctxt |> Variable.add_fixes_direct fixes
   354         val fully_skolemized_t =
   355           zapped_th |> singleton (Variable.export ctxt' ctxt)
   356                     |> cprop_of |> Thm.dest_equals |> snd |> term_of
   357       in
   358         if exists_subterm (fn Var ((s, _), _) =>
   359                               String.isPrefix new_skolem_var_prefix s
   360                             | _ => false) fully_skolemized_t then
   361           let
   362             val (fully_skolemized_ct, ctxt) =
   363               Variable.import_terms true [fully_skolemized_t] ctxt
   364               |>> the_single |>> cterm_of thy
   365           in
   366             (SOME (discharger_th, fully_skolemized_ct),
   367              (Thm.assume fully_skolemized_ct, ctxt))
   368           end
   369        else
   370          (NONE, (th, ctxt))
   371       end
   372     else
   373       (NONE, (th |> has_too_many_clauses ctxt (concl_of th)
   374                     ? to_definitional_cnf_with_quantifiers ctxt, ctxt))
   375   end
   376 
   377 (* Convert a theorem to CNF, with additional premises due to skolemization. *)
   378 fun cnf_axiom ctxt0 new_skolemizer ax_no th =
   379   let
   380     val thy = Proof_Context.theory_of ctxt0
   381     val choice_ths = choice_theorems thy
   382     val (opt, (nnf_th, ctxt)) =
   383       nnf_axiom choice_ths new_skolemizer ax_no th ctxt0
   384     fun clausify th =
   385       make_cnf (if new_skolemizer orelse null choice_ths then []
   386                 else map (old_skolem_theorem_from_def thy) (old_skolem_defs th))
   387                th ctxt
   388     val (cnf_ths, ctxt) = clausify nnf_th
   389     fun intr_imp ct th =
   390       Thm.instantiate ([], map (pairself (cterm_of thy))
   391                                [(Var (("i", 0), @{typ nat}),
   392                                  HOLogic.mk_nat ax_no)])
   393                       (zero_var_indexes @{thm skolem_COMBK_D})
   394       RS Thm.implies_intr ct th
   395   in
   396     (opt |> Option.map (I #>> singleton (Variable.export ctxt ctxt0)
   397                         ##> (term_of #> HOLogic.dest_Trueprop
   398                              #> singleton (Variable.export_terms ctxt ctxt0))),
   399      cnf_ths |> map (introduce_combinators_in_theorem
   400                      #> (case opt of SOME (_, ct) => intr_imp ct | NONE => I))
   401              |> Variable.export ctxt ctxt0
   402              |> finish_cnf
   403              |> map Thm.close_derivation)
   404   end
   405   handle THM _ => (NONE, [])
   406 
   407 end;