src/HOL/Nat.thy
author blanchet
Wed Feb 12 08:37:06 2014 +0100 (2014-02-12)
changeset 55417 01fbfb60c33e
parent 55415 05f5fdb8d093
child 55423 07dea66779f3
permissions -rw-r--r--
adapted to 'xxx_{case,rec}' renaming, to new theorem names, and to new variable names in theorems
* * *
more transition of 'xxx_rec' to 'rec_xxx' and same for case
* * *
compile
* * *
'rename_tac's to avoid referring to generated names
* * *
more robust scripts with 'rename_tac'
* * *
'where' -> 'of'
* * *
'where' -> 'of'
* * *
renamed 'xxx_rec' to 'rec_xxx'
     1 (*  Title:      HOL/Nat.thy
     2     Author:     Tobias Nipkow and Lawrence C Paulson and Markus Wenzel
     3 
     4 Type "nat" is a linear order, and a datatype; arithmetic operators + -
     5 and * (for div and mod, see theory Divides).
     6 *)
     7 
     8 header {* Natural numbers *}
     9 
    10 theory Nat
    11 imports Inductive Typedef Fun Fields
    12 begin
    13 
    14 ML_file "~~/src/Tools/rat.ML"
    15 ML_file "Tools/arith_data.ML"
    16 ML_file "~~/src/Provers/Arith/fast_lin_arith.ML"
    17 
    18 
    19 subsection {* Type @{text ind} *}
    20 
    21 typedecl ind
    22 
    23 axiomatization Zero_Rep :: ind and Suc_Rep :: "ind => ind" where
    24   -- {* the axiom of infinity in 2 parts *}
    25   Suc_Rep_inject:       "Suc_Rep x = Suc_Rep y ==> x = y" and
    26   Suc_Rep_not_Zero_Rep: "Suc_Rep x \<noteq> Zero_Rep"
    27 
    28 subsection {* Type nat *}
    29 
    30 text {* Type definition *}
    31 
    32 inductive Nat :: "ind \<Rightarrow> bool" where
    33   Zero_RepI: "Nat Zero_Rep"
    34 | Suc_RepI: "Nat i \<Longrightarrow> Nat (Suc_Rep i)"
    35 
    36 typedef nat = "{n. Nat n}"
    37   morphisms Rep_Nat Abs_Nat
    38   using Nat.Zero_RepI by auto
    39 
    40 lemma Nat_Rep_Nat:
    41   "Nat (Rep_Nat n)"
    42   using Rep_Nat by simp
    43 
    44 lemma Nat_Abs_Nat_inverse:
    45   "Nat n \<Longrightarrow> Rep_Nat (Abs_Nat n) = n"
    46   using Abs_Nat_inverse by simp
    47 
    48 lemma Nat_Abs_Nat_inject:
    49   "Nat n \<Longrightarrow> Nat m \<Longrightarrow> Abs_Nat n = Abs_Nat m \<longleftrightarrow> n = m"
    50   using Abs_Nat_inject by simp
    51 
    52 instantiation nat :: zero
    53 begin
    54 
    55 definition Zero_nat_def:
    56   "0 = Abs_Nat Zero_Rep"
    57 
    58 instance ..
    59 
    60 end
    61 
    62 definition Suc :: "nat \<Rightarrow> nat" where
    63   "Suc n = Abs_Nat (Suc_Rep (Rep_Nat n))"
    64 
    65 lemma Suc_not_Zero: "Suc m \<noteq> 0"
    66   by (simp add: Zero_nat_def Suc_def Suc_RepI Zero_RepI Nat_Abs_Nat_inject Suc_Rep_not_Zero_Rep Nat_Rep_Nat)
    67 
    68 lemma Zero_not_Suc: "0 \<noteq> Suc m"
    69   by (rule not_sym, rule Suc_not_Zero not_sym)
    70 
    71 lemma Suc_Rep_inject': "Suc_Rep x = Suc_Rep y \<longleftrightarrow> x = y"
    72   by (rule iffI, rule Suc_Rep_inject) simp_all
    73 
    74 lemma nat_induct0:
    75   fixes n
    76   assumes "P 0" and "\<And>n. P n \<Longrightarrow> P (Suc n)"
    77   shows "P n"
    78 using assms
    79 apply (unfold Zero_nat_def Suc_def)
    80 apply (rule Rep_Nat_inverse [THEN subst]) -- {* types force good instantiation *}
    81 apply (erule Nat_Rep_Nat [THEN Nat.induct])
    82 apply (iprover elim: Nat_Abs_Nat_inverse [THEN subst])
    83 done
    84 
    85 wrap_free_constructors ["0 \<Colon> nat", Suc] case_nat [=] [[], [pred]]
    86   apply atomize_elim
    87   apply (rename_tac n, induct_tac n rule: nat_induct0, auto)
    88  apply (simp add: Suc_def Nat_Abs_Nat_inject Nat_Rep_Nat Suc_RepI
    89    Suc_Rep_inject' Rep_Nat_inject)
    90 apply (simp only: Suc_not_Zero)
    91 done
    92 
    93 -- {* Avoid name clashes by prefixing the output of @{text rep_datatype} with @{text old}. *}
    94 setup {* Sign.mandatory_path "old" *}
    95 
    96 rep_datatype "0 \<Colon> nat" Suc
    97   apply (erule nat_induct0, assumption)
    98  apply (rule nat.inject)
    99 apply (rule nat.distinct(1))
   100 done
   101 
   102 setup {* Sign.parent_path *}
   103 
   104 -- {* But erase the prefix for properties that are not generated by @{text wrap_free_constructors}. *}
   105 setup {* Sign.mandatory_path "nat" *}
   106 
   107 declare
   108   old.nat.inject[iff del]
   109   old.nat.distinct(1)[simp del, induct_simp del]
   110 
   111 lemmas induct = old.nat.induct
   112 lemmas inducts = old.nat.inducts
   113 lemmas recs = old.nat.recs
   114 lemmas cases = nat.case
   115 lemmas simps = nat.inject nat.distinct nat.case old.nat.recs
   116 
   117 setup {* Sign.parent_path *}
   118 
   119 abbreviation rec_nat :: "'a \<Rightarrow> (nat \<Rightarrow> 'a \<Rightarrow> 'a) \<Rightarrow> nat \<Rightarrow> 'a" where
   120   "rec_nat \<equiv> old.rec_nat"
   121 
   122 hide_const Nat.pred -- {* hide everything related to the selector *}
   123 hide_fact
   124   nat.case_eq_if
   125   nat.collapse
   126   nat.expand
   127   nat.sel
   128   nat.sel_exhaust
   129   nat.sel_split
   130   nat.sel_split_asm
   131 
   132 lemma nat_exhaust [case_names 0 Suc, cases type: nat]:
   133   -- {* for backward compatibility -- names of variables differ *}
   134   "(y = 0 \<Longrightarrow> P) \<Longrightarrow> (\<And>nat. y = Suc nat \<Longrightarrow> P) \<Longrightarrow> P"
   135 by (rule nat.exhaust)
   136 
   137 lemma nat_induct [case_names 0 Suc, induct type: nat]:
   138   -- {* for backward compatibility -- names of variables differ *}
   139   fixes n
   140   assumes "P 0" and "\<And>n. P n \<Longrightarrow> P (Suc n)"
   141   shows "P n"
   142 using assms by (rule nat.induct)
   143 
   144 hide_fact
   145   nat_exhaust
   146   nat_induct0
   147 
   148 text {* Injectiveness and distinctness lemmas *}
   149 
   150 lemma inj_Suc[simp]: "inj_on Suc N"
   151   by (simp add: inj_on_def)
   152 
   153 lemma Suc_neq_Zero: "Suc m = 0 \<Longrightarrow> R"
   154 by (rule notE, rule Suc_not_Zero)
   155 
   156 lemma Zero_neq_Suc: "0 = Suc m \<Longrightarrow> R"
   157 by (rule Suc_neq_Zero, erule sym)
   158 
   159 lemma Suc_inject: "Suc x = Suc y \<Longrightarrow> x = y"
   160 by (rule inj_Suc [THEN injD])
   161 
   162 lemma n_not_Suc_n: "n \<noteq> Suc n"
   163 by (induct n) simp_all
   164 
   165 lemma Suc_n_not_n: "Suc n \<noteq> n"
   166 by (rule not_sym, rule n_not_Suc_n)
   167 
   168 text {* A special form of induction for reasoning
   169   about @{term "m < n"} and @{term "m - n"} *}
   170 
   171 lemma diff_induct: "(!!x. P x 0) ==> (!!y. P 0 (Suc y)) ==>
   172     (!!x y. P x y ==> P (Suc x) (Suc y)) ==> P m n"
   173   apply (rule_tac x = m in spec)
   174   apply (induct n)
   175   prefer 2
   176   apply (rule allI)
   177   apply (induct_tac x, iprover+)
   178   done
   179 
   180 
   181 subsection {* Arithmetic operators *}
   182 
   183 instantiation nat :: comm_monoid_diff
   184 begin
   185 
   186 primrec plus_nat where
   187   add_0:      "0 + n = (n\<Colon>nat)"
   188 | add_Suc:  "Suc m + n = Suc (m + n)"
   189 
   190 lemma add_0_right [simp]: "m + 0 = (m::nat)"
   191   by (induct m) simp_all
   192 
   193 lemma add_Suc_right [simp]: "m + Suc n = Suc (m + n)"
   194   by (induct m) simp_all
   195 
   196 declare add_0 [code]
   197 
   198 lemma add_Suc_shift [code]: "Suc m + n = m + Suc n"
   199   by simp
   200 
   201 primrec minus_nat where
   202   diff_0 [code]: "m - 0 = (m\<Colon>nat)"
   203 | diff_Suc: "m - Suc n = (case m - n of 0 => 0 | Suc k => k)"
   204 
   205 declare diff_Suc [simp del]
   206 
   207 lemma diff_0_eq_0 [simp, code]: "0 - n = (0::nat)"
   208   by (induct n) (simp_all add: diff_Suc)
   209 
   210 lemma diff_Suc_Suc [simp, code]: "Suc m - Suc n = m - n"
   211   by (induct n) (simp_all add: diff_Suc)
   212 
   213 instance proof
   214   fix n m q :: nat
   215   show "(n + m) + q = n + (m + q)" by (induct n) simp_all
   216   show "n + m = m + n" by (induct n) simp_all
   217   show "0 + n = n" by simp
   218   show "n - 0 = n" by simp
   219   show "0 - n = 0" by simp
   220   show "(q + n) - (q + m) = n - m" by (induct q) simp_all
   221   show "n - m - q = n - (m + q)" by (induct q) (simp_all add: diff_Suc)
   222 qed
   223 
   224 end
   225 
   226 hide_fact (open) add_0 add_0_right diff_0
   227 
   228 instantiation nat :: comm_semiring_1_cancel
   229 begin
   230 
   231 definition
   232   One_nat_def [simp]: "1 = Suc 0"
   233 
   234 primrec times_nat where
   235   mult_0:     "0 * n = (0\<Colon>nat)"
   236 | mult_Suc: "Suc m * n = n + (m * n)"
   237 
   238 lemma mult_0_right [simp]: "(m::nat) * 0 = 0"
   239   by (induct m) simp_all
   240 
   241 lemma mult_Suc_right [simp]: "m * Suc n = m + (m * n)"
   242   by (induct m) (simp_all add: add_left_commute)
   243 
   244 lemma add_mult_distrib: "(m + n) * k = (m * k) + ((n * k)::nat)"
   245   by (induct m) (simp_all add: add_assoc)
   246 
   247 instance proof
   248   fix n m q :: nat
   249   show "0 \<noteq> (1::nat)" unfolding One_nat_def by simp
   250   show "1 * n = n" unfolding One_nat_def by simp
   251   show "n * m = m * n" by (induct n) simp_all
   252   show "(n * m) * q = n * (m * q)" by (induct n) (simp_all add: add_mult_distrib)
   253   show "(n + m) * q = n * q + m * q" by (rule add_mult_distrib)
   254   assume "n + m = n + q" thus "m = q" by (induct n) simp_all
   255 qed
   256 
   257 end
   258 
   259 subsubsection {* Addition *}
   260 
   261 lemma nat_add_assoc: "(m + n) + k = m + ((n + k)::nat)"
   262   by (rule add_assoc)
   263 
   264 lemma nat_add_commute: "m + n = n + (m::nat)"
   265   by (rule add_commute)
   266 
   267 lemma nat_add_left_commute: "x + (y + z) = y + ((x + z)::nat)"
   268   by (rule add_left_commute)
   269 
   270 lemma nat_add_left_cancel [simp]: "(k + m = k + n) = (m = (n::nat))"
   271   by (rule add_left_cancel)
   272 
   273 lemma nat_add_right_cancel [simp]: "(m + k = n + k) = (m=(n::nat))"
   274   by (rule add_right_cancel)
   275 
   276 text {* Reasoning about @{text "m + 0 = 0"}, etc. *}
   277 
   278 lemma add_is_0 [iff]:
   279   fixes m n :: nat
   280   shows "(m + n = 0) = (m = 0 & n = 0)"
   281   by (cases m) simp_all
   282 
   283 lemma add_is_1:
   284   "(m+n= Suc 0) = (m= Suc 0 & n=0 | m=0 & n= Suc 0)"
   285   by (cases m) simp_all
   286 
   287 lemma one_is_add:
   288   "(Suc 0 = m + n) = (m = Suc 0 & n = 0 | m = 0 & n = Suc 0)"
   289   by (rule trans, rule eq_commute, rule add_is_1)
   290 
   291 lemma add_eq_self_zero:
   292   fixes m n :: nat
   293   shows "m + n = m \<Longrightarrow> n = 0"
   294   by (induct m) simp_all
   295 
   296 lemma inj_on_add_nat[simp]: "inj_on (%n::nat. n+k) N"
   297   apply (induct k)
   298    apply simp
   299   apply(drule comp_inj_on[OF _ inj_Suc])
   300   apply (simp add:o_def)
   301   done
   302 
   303 lemma Suc_eq_plus1: "Suc n = n + 1"
   304   unfolding One_nat_def by simp
   305 
   306 lemma Suc_eq_plus1_left: "Suc n = 1 + n"
   307   unfolding One_nat_def by simp
   308 
   309 
   310 subsubsection {* Difference *}
   311 
   312 lemma diff_self_eq_0 [simp]: "(m\<Colon>nat) - m = 0"
   313   by (induct m) simp_all
   314 
   315 lemma diff_diff_left: "(i::nat) - j - k = i - (j + k)"
   316   by (induct i j rule: diff_induct) simp_all
   317 
   318 lemma Suc_diff_diff [simp]: "(Suc m - n) - Suc k = m - n - k"
   319   by (simp add: diff_diff_left)
   320 
   321 lemma diff_commute: "(i::nat) - j - k = i - k - j"
   322   by (simp add: diff_diff_left add_commute)
   323 
   324 lemma diff_add_inverse: "(n + m) - n = (m::nat)"
   325   by (induct n) simp_all
   326 
   327 lemma diff_add_inverse2: "(m + n) - n = (m::nat)"
   328   by (simp add: diff_add_inverse add_commute [of m n])
   329 
   330 lemma diff_cancel: "(k + m) - (k + n) = m - (n::nat)"
   331   by (induct k) simp_all
   332 
   333 lemma diff_cancel2: "(m + k) - (n + k) = m - (n::nat)"
   334   by (simp add: diff_cancel add_commute)
   335 
   336 lemma diff_add_0: "n - (n + m) = (0::nat)"
   337   by (induct n) simp_all
   338 
   339 lemma diff_Suc_1 [simp]: "Suc n - 1 = n"
   340   unfolding One_nat_def by simp
   341 
   342 text {* Difference distributes over multiplication *}
   343 
   344 lemma diff_mult_distrib: "((m::nat) - n) * k = (m * k) - (n * k)"
   345 by (induct m n rule: diff_induct) (simp_all add: diff_cancel)
   346 
   347 lemma diff_mult_distrib2: "k * ((m::nat) - n) = (k * m) - (k * n)"
   348 by (simp add: diff_mult_distrib mult_commute [of k])
   349   -- {* NOT added as rewrites, since sometimes they are used from right-to-left *}
   350 
   351 
   352 subsubsection {* Multiplication *}
   353 
   354 lemma nat_mult_assoc: "(m * n) * k = m * ((n * k)::nat)"
   355   by (rule mult_assoc)
   356 
   357 lemma nat_mult_commute: "m * n = n * (m::nat)"
   358   by (rule mult_commute)
   359 
   360 lemma add_mult_distrib2: "k * (m + n) = (k * m) + ((k * n)::nat)"
   361   by (rule distrib_left)
   362 
   363 lemma mult_is_0 [simp]: "((m::nat) * n = 0) = (m=0 | n=0)"
   364   by (induct m) auto
   365 
   366 lemmas nat_distrib =
   367   add_mult_distrib add_mult_distrib2 diff_mult_distrib diff_mult_distrib2
   368 
   369 lemma mult_eq_1_iff [simp]: "(m * n = Suc 0) = (m = Suc 0 & n = Suc 0)"
   370   apply (induct m)
   371    apply simp
   372   apply (induct n)
   373    apply auto
   374   done
   375 
   376 lemma one_eq_mult_iff [simp]: "(Suc 0 = m * n) = (m = Suc 0 & n = Suc 0)"
   377   apply (rule trans)
   378   apply (rule_tac [2] mult_eq_1_iff, fastforce)
   379   done
   380 
   381 lemma nat_mult_eq_1_iff [simp]: "m * n = (1::nat) \<longleftrightarrow> m = 1 \<and> n = 1"
   382   unfolding One_nat_def by (rule mult_eq_1_iff)
   383 
   384 lemma nat_1_eq_mult_iff [simp]: "(1::nat) = m * n \<longleftrightarrow> m = 1 \<and> n = 1"
   385   unfolding One_nat_def by (rule one_eq_mult_iff)
   386 
   387 lemma mult_cancel1 [simp]: "(k * m = k * n) = (m = n | (k = (0::nat)))"
   388 proof -
   389   have "k \<noteq> 0 \<Longrightarrow> k * m = k * n \<Longrightarrow> m = n"
   390   proof (induct n arbitrary: m)
   391     case 0 then show "m = 0" by simp
   392   next
   393     case (Suc n) then show "m = Suc n"
   394       by (cases m) (simp_all add: eq_commute [of "0"])
   395   qed
   396   then show ?thesis by auto
   397 qed
   398 
   399 lemma mult_cancel2 [simp]: "(m * k = n * k) = (m = n | (k = (0::nat)))"
   400   by (simp add: mult_commute)
   401 
   402 lemma Suc_mult_cancel1: "(Suc k * m = Suc k * n) = (m = n)"
   403   by (subst mult_cancel1) simp
   404 
   405 
   406 subsection {* Orders on @{typ nat} *}
   407 
   408 subsubsection {* Operation definition *}
   409 
   410 instantiation nat :: linorder
   411 begin
   412 
   413 primrec less_eq_nat where
   414   "(0\<Colon>nat) \<le> n \<longleftrightarrow> True"
   415 | "Suc m \<le> n \<longleftrightarrow> (case n of 0 \<Rightarrow> False | Suc n \<Rightarrow> m \<le> n)"
   416 
   417 declare less_eq_nat.simps [simp del]
   418 lemma le0 [iff]: "0 \<le> (n\<Colon>nat)" by (simp add: less_eq_nat.simps)
   419 lemma [code]: "(0\<Colon>nat) \<le> n \<longleftrightarrow> True" by simp
   420 
   421 definition less_nat where
   422   less_eq_Suc_le: "n < m \<longleftrightarrow> Suc n \<le> m"
   423 
   424 lemma Suc_le_mono [iff]: "Suc n \<le> Suc m \<longleftrightarrow> n \<le> m"
   425   by (simp add: less_eq_nat.simps(2))
   426 
   427 lemma Suc_le_eq [code]: "Suc m \<le> n \<longleftrightarrow> m < n"
   428   unfolding less_eq_Suc_le ..
   429 
   430 lemma le_0_eq [iff]: "(n\<Colon>nat) \<le> 0 \<longleftrightarrow> n = 0"
   431   by (induct n) (simp_all add: less_eq_nat.simps(2))
   432 
   433 lemma not_less0 [iff]: "\<not> n < (0\<Colon>nat)"
   434   by (simp add: less_eq_Suc_le)
   435 
   436 lemma less_nat_zero_code [code]: "n < (0\<Colon>nat) \<longleftrightarrow> False"
   437   by simp
   438 
   439 lemma Suc_less_eq [iff]: "Suc m < Suc n \<longleftrightarrow> m < n"
   440   by (simp add: less_eq_Suc_le)
   441 
   442 lemma less_Suc_eq_le [code]: "m < Suc n \<longleftrightarrow> m \<le> n"
   443   by (simp add: less_eq_Suc_le)
   444 
   445 lemma le_SucI: "m \<le> n \<Longrightarrow> m \<le> Suc n"
   446   by (induct m arbitrary: n)
   447     (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   448 
   449 lemma Suc_leD: "Suc m \<le> n \<Longrightarrow> m \<le> n"
   450   by (cases n) (auto intro: le_SucI)
   451 
   452 lemma less_SucI: "m < n \<Longrightarrow> m < Suc n"
   453   by (simp add: less_eq_Suc_le) (erule Suc_leD)
   454 
   455 lemma Suc_lessD: "Suc m < n \<Longrightarrow> m < n"
   456   by (simp add: less_eq_Suc_le) (erule Suc_leD)
   457 
   458 instance
   459 proof
   460   fix n m :: nat
   461   show "n < m \<longleftrightarrow> n \<le> m \<and> \<not> m \<le> n" 
   462   proof (induct n arbitrary: m)
   463     case 0 then show ?case by (cases m) (simp_all add: less_eq_Suc_le)
   464   next
   465     case (Suc n) then show ?case by (cases m) (simp_all add: less_eq_Suc_le)
   466   qed
   467 next
   468   fix n :: nat show "n \<le> n" by (induct n) simp_all
   469 next
   470   fix n m :: nat assume "n \<le> m" and "m \<le> n"
   471   then show "n = m"
   472     by (induct n arbitrary: m)
   473       (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   474 next
   475   fix n m q :: nat assume "n \<le> m" and "m \<le> q"
   476   then show "n \<le> q"
   477   proof (induct n arbitrary: m q)
   478     case 0 show ?case by simp
   479   next
   480     case (Suc n) then show ?case
   481       by (simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits, clarify,
   482         simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits, clarify,
   483         simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits)
   484   qed
   485 next
   486   fix n m :: nat show "n \<le> m \<or> m \<le> n"
   487     by (induct n arbitrary: m)
   488       (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   489 qed
   490 
   491 end
   492 
   493 instantiation nat :: order_bot
   494 begin
   495 
   496 definition bot_nat :: nat where
   497   "bot_nat = 0"
   498 
   499 instance proof
   500 qed (simp add: bot_nat_def)
   501 
   502 end
   503 
   504 instance nat :: no_top
   505   by default (auto intro: less_Suc_eq_le [THEN iffD2])
   506 
   507 
   508 subsubsection {* Introduction properties *}
   509 
   510 lemma lessI [iff]: "n < Suc n"
   511   by (simp add: less_Suc_eq_le)
   512 
   513 lemma zero_less_Suc [iff]: "0 < Suc n"
   514   by (simp add: less_Suc_eq_le)
   515 
   516 
   517 subsubsection {* Elimination properties *}
   518 
   519 lemma less_not_refl: "~ n < (n::nat)"
   520   by (rule order_less_irrefl)
   521 
   522 lemma less_not_refl2: "n < m ==> m \<noteq> (n::nat)"
   523   by (rule not_sym) (rule less_imp_neq) 
   524 
   525 lemma less_not_refl3: "(s::nat) < t ==> s \<noteq> t"
   526   by (rule less_imp_neq)
   527 
   528 lemma less_irrefl_nat: "(n::nat) < n ==> R"
   529   by (rule notE, rule less_not_refl)
   530 
   531 lemma less_zeroE: "(n::nat) < 0 ==> R"
   532   by (rule notE) (rule not_less0)
   533 
   534 lemma less_Suc_eq: "(m < Suc n) = (m < n | m = n)"
   535   unfolding less_Suc_eq_le le_less ..
   536 
   537 lemma less_Suc0 [iff]: "(n < Suc 0) = (n = 0)"
   538   by (simp add: less_Suc_eq)
   539 
   540 lemma less_one [iff]: "(n < (1::nat)) = (n = 0)"
   541   unfolding One_nat_def by (rule less_Suc0)
   542 
   543 lemma Suc_mono: "m < n ==> Suc m < Suc n"
   544   by simp
   545 
   546 text {* "Less than" is antisymmetric, sort of *}
   547 lemma less_antisym: "\<lbrakk> \<not> n < m; n < Suc m \<rbrakk> \<Longrightarrow> m = n"
   548   unfolding not_less less_Suc_eq_le by (rule antisym)
   549 
   550 lemma nat_neq_iff: "((m::nat) \<noteq> n) = (m < n | n < m)"
   551   by (rule linorder_neq_iff)
   552 
   553 lemma nat_less_cases: assumes major: "(m::nat) < n ==> P n m"
   554   and eqCase: "m = n ==> P n m" and lessCase: "n<m ==> P n m"
   555   shows "P n m"
   556   apply (rule less_linear [THEN disjE])
   557   apply (erule_tac [2] disjE)
   558   apply (erule lessCase)
   559   apply (erule sym [THEN eqCase])
   560   apply (erule major)
   561   done
   562 
   563 
   564 subsubsection {* Inductive (?) properties *}
   565 
   566 lemma Suc_lessI: "m < n ==> Suc m \<noteq> n ==> Suc m < n"
   567   unfolding less_eq_Suc_le [of m] le_less by simp 
   568 
   569 lemma lessE:
   570   assumes major: "i < k"
   571   and p1: "k = Suc i ==> P" and p2: "!!j. i < j ==> k = Suc j ==> P"
   572   shows P
   573 proof -
   574   from major have "\<exists>j. i \<le> j \<and> k = Suc j"
   575     unfolding less_eq_Suc_le by (induct k) simp_all
   576   then have "(\<exists>j. i < j \<and> k = Suc j) \<or> k = Suc i"
   577     by (clarsimp simp add: less_le)
   578   with p1 p2 show P by auto
   579 qed
   580 
   581 lemma less_SucE: assumes major: "m < Suc n"
   582   and less: "m < n ==> P" and eq: "m = n ==> P" shows P
   583   apply (rule major [THEN lessE])
   584   apply (rule eq, blast)
   585   apply (rule less, blast)
   586   done
   587 
   588 lemma Suc_lessE: assumes major: "Suc i < k"
   589   and minor: "!!j. i < j ==> k = Suc j ==> P" shows P
   590   apply (rule major [THEN lessE])
   591   apply (erule lessI [THEN minor])
   592   apply (erule Suc_lessD [THEN minor], assumption)
   593   done
   594 
   595 lemma Suc_less_SucD: "Suc m < Suc n ==> m < n"
   596   by simp
   597 
   598 lemma less_trans_Suc:
   599   assumes le: "i < j" shows "j < k ==> Suc i < k"
   600   apply (induct k, simp_all)
   601   apply (insert le)
   602   apply (simp add: less_Suc_eq)
   603   apply (blast dest: Suc_lessD)
   604   done
   605 
   606 text {* Can be used with @{text less_Suc_eq} to get @{term "n = m | n < m"} *}
   607 lemma not_less_eq: "\<not> m < n \<longleftrightarrow> n < Suc m"
   608   unfolding not_less less_Suc_eq_le ..
   609 
   610 lemma not_less_eq_eq: "\<not> m \<le> n \<longleftrightarrow> Suc n \<le> m"
   611   unfolding not_le Suc_le_eq ..
   612 
   613 text {* Properties of "less than or equal" *}
   614 
   615 lemma le_imp_less_Suc: "m \<le> n ==> m < Suc n"
   616   unfolding less_Suc_eq_le .
   617 
   618 lemma Suc_n_not_le_n: "~ Suc n \<le> n"
   619   unfolding not_le less_Suc_eq_le ..
   620 
   621 lemma le_Suc_eq: "(m \<le> Suc n) = (m \<le> n | m = Suc n)"
   622   by (simp add: less_Suc_eq_le [symmetric] less_Suc_eq)
   623 
   624 lemma le_SucE: "m \<le> Suc n ==> (m \<le> n ==> R) ==> (m = Suc n ==> R) ==> R"
   625   by (drule le_Suc_eq [THEN iffD1], iprover+)
   626 
   627 lemma Suc_leI: "m < n ==> Suc(m) \<le> n"
   628   unfolding Suc_le_eq .
   629 
   630 text {* Stronger version of @{text Suc_leD} *}
   631 lemma Suc_le_lessD: "Suc m \<le> n ==> m < n"
   632   unfolding Suc_le_eq .
   633 
   634 lemma less_imp_le_nat: "m < n ==> m \<le> (n::nat)"
   635   unfolding less_eq_Suc_le by (rule Suc_leD)
   636 
   637 text {* For instance, @{text "(Suc m < Suc n) = (Suc m \<le> n) = (m < n)"} *}
   638 lemmas le_simps = less_imp_le_nat less_Suc_eq_le Suc_le_eq
   639 
   640 
   641 text {* Equivalence of @{term "m \<le> n"} and @{term "m < n | m = n"} *}
   642 
   643 lemma less_or_eq_imp_le: "m < n | m = n ==> m \<le> (n::nat)"
   644   unfolding le_less .
   645 
   646 lemma le_eq_less_or_eq: "(m \<le> (n::nat)) = (m < n | m=n)"
   647   by (rule le_less)
   648 
   649 text {* Useful with @{text blast}. *}
   650 lemma eq_imp_le: "(m::nat) = n ==> m \<le> n"
   651   by auto
   652 
   653 lemma le_refl: "n \<le> (n::nat)"
   654   by simp
   655 
   656 lemma le_trans: "[| i \<le> j; j \<le> k |] ==> i \<le> (k::nat)"
   657   by (rule order_trans)
   658 
   659 lemma le_antisym: "[| m \<le> n; n \<le> m |] ==> m = (n::nat)"
   660   by (rule antisym)
   661 
   662 lemma nat_less_le: "((m::nat) < n) = (m \<le> n & m \<noteq> n)"
   663   by (rule less_le)
   664 
   665 lemma le_neq_implies_less: "(m::nat) \<le> n ==> m \<noteq> n ==> m < n"
   666   unfolding less_le ..
   667 
   668 lemma nat_le_linear: "(m::nat) \<le> n | n \<le> m"
   669   by (rule linear)
   670 
   671 lemmas linorder_neqE_nat = linorder_neqE [where 'a = nat]
   672 
   673 lemma le_less_Suc_eq: "m \<le> n ==> (n < Suc m) = (n = m)"
   674   unfolding less_Suc_eq_le by auto
   675 
   676 lemma not_less_less_Suc_eq: "~ n < m ==> (n < Suc m) = (n = m)"
   677   unfolding not_less by (rule le_less_Suc_eq)
   678 
   679 lemmas not_less_simps = not_less_less_Suc_eq le_less_Suc_eq
   680 
   681 lemma not0_implies_Suc: "n \<noteq> 0 ==> \<exists>m. n = Suc m"
   682 by (cases n) simp_all
   683 
   684 lemma gr0_implies_Suc: "n > 0 ==> \<exists>m. n = Suc m"
   685 by (cases n) simp_all
   686 
   687 lemma gr_implies_not0: fixes n :: nat shows "m<n ==> n \<noteq> 0"
   688 by (cases n) simp_all
   689 
   690 lemma neq0_conv[iff]: fixes n :: nat shows "(n \<noteq> 0) = (0 < n)"
   691 by (cases n) simp_all
   692 
   693 text {* This theorem is useful with @{text blast} *}
   694 lemma gr0I: "((n::nat) = 0 ==> False) ==> 0 < n"
   695 by (rule neq0_conv[THEN iffD1], iprover)
   696 
   697 lemma gr0_conv_Suc: "(0 < n) = (\<exists>m. n = Suc m)"
   698 by (fast intro: not0_implies_Suc)
   699 
   700 lemma not_gr0 [iff]: "!!n::nat. (~ (0 < n)) = (n = 0)"
   701 using neq0_conv by blast
   702 
   703 lemma Suc_le_D: "(Suc n \<le> m') ==> (? m. m' = Suc m)"
   704 by (induct m') simp_all
   705 
   706 text {* Useful in certain inductive arguments *}
   707 lemma less_Suc_eq_0_disj: "(m < Suc n) = (m = 0 | (\<exists>j. m = Suc j & j < n))"
   708 by (cases m) simp_all
   709 
   710 
   711 subsubsection {* Monotonicity of Addition *}
   712 
   713 lemma Suc_pred [simp]: "n>0 ==> Suc (n - Suc 0) = n"
   714 by (simp add: diff_Suc split: nat.split)
   715 
   716 lemma Suc_diff_1 [simp]: "0 < n ==> Suc (n - 1) = n"
   717 unfolding One_nat_def by (rule Suc_pred)
   718 
   719 lemma nat_add_left_cancel_le [simp]: "(k + m \<le> k + n) = (m\<le>(n::nat))"
   720 by (induct k) simp_all
   721 
   722 lemma nat_add_left_cancel_less [simp]: "(k + m < k + n) = (m<(n::nat))"
   723 by (induct k) simp_all
   724 
   725 lemma add_gr_0 [iff]: "!!m::nat. (m + n > 0) = (m>0 | n>0)"
   726 by(auto dest:gr0_implies_Suc)
   727 
   728 text {* strict, in 1st argument *}
   729 lemma add_less_mono1: "i < j ==> i + k < j + (k::nat)"
   730 by (induct k) simp_all
   731 
   732 text {* strict, in both arguments *}
   733 lemma add_less_mono: "[|i < j; k < l|] ==> i + k < j + (l::nat)"
   734   apply (rule add_less_mono1 [THEN less_trans], assumption+)
   735   apply (induct j, simp_all)
   736   done
   737 
   738 text {* Deleted @{text less_natE}; use @{text "less_imp_Suc_add RS exE"} *}
   739 lemma less_imp_Suc_add: "m < n ==> (\<exists>k. n = Suc (m + k))"
   740   apply (induct n)
   741   apply (simp_all add: order_le_less)
   742   apply (blast elim!: less_SucE
   743                intro!: Nat.add_0_right [symmetric] add_Suc_right [symmetric])
   744   done
   745 
   746 text {* strict, in 1st argument; proof is by induction on @{text "k > 0"} *}
   747 lemma mult_less_mono2: "(i::nat) < j ==> 0<k ==> k * i < k * j"
   748 apply(auto simp: gr0_conv_Suc)
   749 apply (induct_tac m)
   750 apply (simp_all add: add_less_mono)
   751 done
   752 
   753 text{*The naturals form an ordered @{text comm_semiring_1_cancel}*}
   754 instance nat :: linordered_semidom
   755 proof
   756   show "0 < (1::nat)" by simp
   757   show "\<And>m n q :: nat. m \<le> n \<Longrightarrow> q + m \<le> q + n" by simp
   758   show "\<And>m n q :: nat. m < n \<Longrightarrow> 0 < q \<Longrightarrow> q * m < q * n" by (simp add: mult_less_mono2)
   759 qed
   760 
   761 instance nat :: no_zero_divisors
   762 proof
   763   fix a::nat and b::nat show "a ~= 0 \<Longrightarrow> b ~= 0 \<Longrightarrow> a * b ~= 0" by auto
   764 qed
   765 
   766 
   767 subsubsection {* @{term min} and @{term max} *}
   768 
   769 lemma mono_Suc: "mono Suc"
   770 by (rule monoI) simp
   771 
   772 lemma min_0L [simp]: "min 0 n = (0::nat)"
   773 by (rule min_absorb1) simp
   774 
   775 lemma min_0R [simp]: "min n 0 = (0::nat)"
   776 by (rule min_absorb2) simp
   777 
   778 lemma min_Suc_Suc [simp]: "min (Suc m) (Suc n) = Suc (min m n)"
   779 by (simp add: mono_Suc min_of_mono)
   780 
   781 lemma min_Suc1:
   782    "min (Suc n) m = (case m of 0 => 0 | Suc m' => Suc(min n m'))"
   783 by (simp split: nat.split)
   784 
   785 lemma min_Suc2:
   786    "min m (Suc n) = (case m of 0 => 0 | Suc m' => Suc(min m' n))"
   787 by (simp split: nat.split)
   788 
   789 lemma max_0L [simp]: "max 0 n = (n::nat)"
   790 by (rule max_absorb2) simp
   791 
   792 lemma max_0R [simp]: "max n 0 = (n::nat)"
   793 by (rule max_absorb1) simp
   794 
   795 lemma max_Suc_Suc [simp]: "max (Suc m) (Suc n) = Suc(max m n)"
   796 by (simp add: mono_Suc max_of_mono)
   797 
   798 lemma max_Suc1:
   799    "max (Suc n) m = (case m of 0 => Suc n | Suc m' => Suc(max n m'))"
   800 by (simp split: nat.split)
   801 
   802 lemma max_Suc2:
   803    "max m (Suc n) = (case m of 0 => Suc n | Suc m' => Suc(max m' n))"
   804 by (simp split: nat.split)
   805 
   806 lemma nat_mult_min_left:
   807   fixes m n q :: nat
   808   shows "min m n * q = min (m * q) (n * q)"
   809   by (simp add: min_def not_le) (auto dest: mult_right_le_imp_le mult_right_less_imp_less le_less_trans)
   810 
   811 lemma nat_mult_min_right:
   812   fixes m n q :: nat
   813   shows "m * min n q = min (m * n) (m * q)"
   814   by (simp add: min_def not_le) (auto dest: mult_left_le_imp_le mult_left_less_imp_less le_less_trans)
   815 
   816 lemma nat_add_max_left:
   817   fixes m n q :: nat
   818   shows "max m n + q = max (m + q) (n + q)"
   819   by (simp add: max_def)
   820 
   821 lemma nat_add_max_right:
   822   fixes m n q :: nat
   823   shows "m + max n q = max (m + n) (m + q)"
   824   by (simp add: max_def)
   825 
   826 lemma nat_mult_max_left:
   827   fixes m n q :: nat
   828   shows "max m n * q = max (m * q) (n * q)"
   829   by (simp add: max_def not_le) (auto dest: mult_right_le_imp_le mult_right_less_imp_less le_less_trans)
   830 
   831 lemma nat_mult_max_right:
   832   fixes m n q :: nat
   833   shows "m * max n q = max (m * n) (m * q)"
   834   by (simp add: max_def not_le) (auto dest: mult_left_le_imp_le mult_left_less_imp_less le_less_trans)
   835 
   836 
   837 subsubsection {* Additional theorems about @{term "op \<le>"} *}
   838 
   839 text {* Complete induction, aka course-of-values induction *}
   840 
   841 instance nat :: wellorder proof
   842   fix P and n :: nat
   843   assume step: "\<And>n::nat. (\<And>m. m < n \<Longrightarrow> P m) \<Longrightarrow> P n"
   844   have "\<And>q. q \<le> n \<Longrightarrow> P q"
   845   proof (induct n)
   846     case (0 n)
   847     have "P 0" by (rule step) auto
   848     thus ?case using 0 by auto
   849   next
   850     case (Suc m n)
   851     then have "n \<le> m \<or> n = Suc m" by (simp add: le_Suc_eq)
   852     thus ?case
   853     proof
   854       assume "n \<le> m" thus "P n" by (rule Suc(1))
   855     next
   856       assume n: "n = Suc m"
   857       show "P n"
   858         by (rule step) (rule Suc(1), simp add: n le_simps)
   859     qed
   860   qed
   861   then show "P n" by auto
   862 qed
   863 
   864 lemma Least_Suc:
   865      "[| P n; ~ P 0 |] ==> (LEAST n. P n) = Suc (LEAST m. P(Suc m))"
   866   apply (cases n, auto)
   867   apply (frule LeastI)
   868   apply (drule_tac P = "%x. P (Suc x) " in LeastI)
   869   apply (subgoal_tac " (LEAST x. P x) \<le> Suc (LEAST x. P (Suc x))")
   870   apply (erule_tac [2] Least_le)
   871   apply (cases "LEAST x. P x", auto)
   872   apply (drule_tac P = "%x. P (Suc x) " in Least_le)
   873   apply (blast intro: order_antisym)
   874   done
   875 
   876 lemma Least_Suc2:
   877    "[|P n; Q m; ~P 0; !k. P (Suc k) = Q k|] ==> Least P = Suc (Least Q)"
   878   apply (erule (1) Least_Suc [THEN ssubst])
   879   apply simp
   880   done
   881 
   882 lemma ex_least_nat_le: "\<not>P(0) \<Longrightarrow> P(n::nat) \<Longrightarrow> \<exists>k\<le>n. (\<forall>i<k. \<not>P i) & P(k)"
   883   apply (cases n)
   884    apply blast
   885   apply (rule_tac x="LEAST k. P(k)" in exI)
   886   apply (blast intro: Least_le dest: not_less_Least intro: LeastI_ex)
   887   done
   888 
   889 lemma ex_least_nat_less: "\<not>P(0) \<Longrightarrow> P(n::nat) \<Longrightarrow> \<exists>k<n. (\<forall>i\<le>k. \<not>P i) & P(k+1)"
   890   unfolding One_nat_def
   891   apply (cases n)
   892    apply blast
   893   apply (frule (1) ex_least_nat_le)
   894   apply (erule exE)
   895   apply (case_tac k)
   896    apply simp
   897   apply (rename_tac k1)
   898   apply (rule_tac x=k1 in exI)
   899   apply (auto simp add: less_eq_Suc_le)
   900   done
   901 
   902 lemma nat_less_induct:
   903   assumes "!!n. \<forall>m::nat. m < n --> P m ==> P n" shows "P n"
   904   using assms less_induct by blast
   905 
   906 lemma measure_induct_rule [case_names less]:
   907   fixes f :: "'a \<Rightarrow> nat"
   908   assumes step: "\<And>x. (\<And>y. f y < f x \<Longrightarrow> P y) \<Longrightarrow> P x"
   909   shows "P a"
   910 by (induct m\<equiv>"f a" arbitrary: a rule: less_induct) (auto intro: step)
   911 
   912 text {* old style induction rules: *}
   913 lemma measure_induct:
   914   fixes f :: "'a \<Rightarrow> nat"
   915   shows "(\<And>x. \<forall>y. f y < f x \<longrightarrow> P y \<Longrightarrow> P x) \<Longrightarrow> P a"
   916   by (rule measure_induct_rule [of f P a]) iprover
   917 
   918 lemma full_nat_induct:
   919   assumes step: "(!!n. (ALL m. Suc m <= n --> P m) ==> P n)"
   920   shows "P n"
   921   by (rule less_induct) (auto intro: step simp:le_simps)
   922 
   923 text{*An induction rule for estabilishing binary relations*}
   924 lemma less_Suc_induct:
   925   assumes less:  "i < j"
   926      and  step:  "!!i. P i (Suc i)"
   927      and  trans: "!!i j k. i < j ==> j < k ==>  P i j ==> P j k ==> P i k"
   928   shows "P i j"
   929 proof -
   930   from less obtain k where j: "j = Suc (i + k)" by (auto dest: less_imp_Suc_add)
   931   have "P i (Suc (i + k))"
   932   proof (induct k)
   933     case 0
   934     show ?case by (simp add: step)
   935   next
   936     case (Suc k)
   937     have "0 + i < Suc k + i" by (rule add_less_mono1) simp
   938     hence "i < Suc (i + k)" by (simp add: add_commute)
   939     from trans[OF this lessI Suc step]
   940     show ?case by simp
   941   qed
   942   thus "P i j" by (simp add: j)
   943 qed
   944 
   945 text {* The method of infinite descent, frequently used in number theory.
   946 Provided by Roelof Oosterhuis.
   947 $P(n)$ is true for all $n\in\mathbb{N}$ if
   948 \begin{itemize}
   949   \item case ``0'': given $n=0$ prove $P(n)$,
   950   \item case ``smaller'': given $n>0$ and $\neg P(n)$ prove there exists
   951         a smaller integer $m$ such that $\neg P(m)$.
   952 \end{itemize} *}
   953 
   954 text{* A compact version without explicit base case: *}
   955 lemma infinite_descent:
   956   "\<lbrakk> !!n::nat. \<not> P n \<Longrightarrow>  \<exists>m<n. \<not>  P m \<rbrakk> \<Longrightarrow>  P n"
   957 by (induct n rule: less_induct) auto
   958 
   959 lemma infinite_descent0[case_names 0 smaller]: 
   960   "\<lbrakk> P 0; !!n. n>0 \<Longrightarrow> \<not> P n \<Longrightarrow> (\<exists>m::nat. m < n \<and> \<not>P m) \<rbrakk> \<Longrightarrow> P n"
   961 by (rule infinite_descent) (case_tac "n>0", auto)
   962 
   963 text {*
   964 Infinite descent using a mapping to $\mathbb{N}$:
   965 $P(x)$ is true for all $x\in D$ if there exists a $V: D \to \mathbb{N}$ and
   966 \begin{itemize}
   967 \item case ``0'': given $V(x)=0$ prove $P(x)$,
   968 \item case ``smaller'': given $V(x)>0$ and $\neg P(x)$ prove there exists a $y \in D$ such that $V(y)<V(x)$ and $~\neg P(y)$.
   969 \end{itemize}
   970 NB: the proof also shows how to use the previous lemma. *}
   971 
   972 corollary infinite_descent0_measure [case_names 0 smaller]:
   973   assumes A0: "!!x. V x = (0::nat) \<Longrightarrow> P x"
   974     and   A1: "!!x. V x > 0 \<Longrightarrow> \<not>P x \<Longrightarrow> (\<exists>y. V y < V x \<and> \<not>P y)"
   975   shows "P x"
   976 proof -
   977   obtain n where "n = V x" by auto
   978   moreover have "\<And>x. V x = n \<Longrightarrow> P x"
   979   proof (induct n rule: infinite_descent0)
   980     case 0 -- "i.e. $V(x) = 0$"
   981     with A0 show "P x" by auto
   982   next -- "now $n>0$ and $P(x)$ does not hold for some $x$ with $V(x)=n$"
   983     case (smaller n)
   984     then obtain x where vxn: "V x = n " and "V x > 0 \<and> \<not> P x" by auto
   985     with A1 obtain y where "V y < V x \<and> \<not> P y" by auto
   986     with vxn obtain m where "m = V y \<and> m<n \<and> \<not> P y" by auto
   987     then show ?case by auto
   988   qed
   989   ultimately show "P x" by auto
   990 qed
   991 
   992 text{* Again, without explicit base case: *}
   993 lemma infinite_descent_measure:
   994 assumes "!!x. \<not> P x \<Longrightarrow> \<exists>y. (V::'a\<Rightarrow>nat) y < V x \<and> \<not> P y" shows "P x"
   995 proof -
   996   from assms obtain n where "n = V x" by auto
   997   moreover have "!!x. V x = n \<Longrightarrow> P x"
   998   proof (induct n rule: infinite_descent, auto)
   999     fix x assume "\<not> P x"
  1000     with assms show "\<exists>m < V x. \<exists>y. V y = m \<and> \<not> P y" by auto
  1001   qed
  1002   ultimately show "P x" by auto
  1003 qed
  1004 
  1005 text {* A [clumsy] way of lifting @{text "<"}
  1006   monotonicity to @{text "\<le>"} monotonicity *}
  1007 lemma less_mono_imp_le_mono:
  1008   "\<lbrakk> !!i j::nat. i < j \<Longrightarrow> f i < f j; i \<le> j \<rbrakk> \<Longrightarrow> f i \<le> ((f j)::nat)"
  1009 by (simp add: order_le_less) (blast)
  1010 
  1011 
  1012 text {* non-strict, in 1st argument *}
  1013 lemma add_le_mono1: "i \<le> j ==> i + k \<le> j + (k::nat)"
  1014 by (rule add_right_mono)
  1015 
  1016 text {* non-strict, in both arguments *}
  1017 lemma add_le_mono: "[| i \<le> j;  k \<le> l |] ==> i + k \<le> j + (l::nat)"
  1018 by (rule add_mono)
  1019 
  1020 lemma le_add2: "n \<le> ((m + n)::nat)"
  1021 by (insert add_right_mono [of 0 m n], simp)
  1022 
  1023 lemma le_add1: "n \<le> ((n + m)::nat)"
  1024 by (simp add: add_commute, rule le_add2)
  1025 
  1026 lemma less_add_Suc1: "i < Suc (i + m)"
  1027 by (rule le_less_trans, rule le_add1, rule lessI)
  1028 
  1029 lemma less_add_Suc2: "i < Suc (m + i)"
  1030 by (rule le_less_trans, rule le_add2, rule lessI)
  1031 
  1032 lemma less_iff_Suc_add: "(m < n) = (\<exists>k. n = Suc (m + k))"
  1033 by (iprover intro!: less_add_Suc1 less_imp_Suc_add)
  1034 
  1035 lemma trans_le_add1: "(i::nat) \<le> j ==> i \<le> j + m"
  1036 by (rule le_trans, assumption, rule le_add1)
  1037 
  1038 lemma trans_le_add2: "(i::nat) \<le> j ==> i \<le> m + j"
  1039 by (rule le_trans, assumption, rule le_add2)
  1040 
  1041 lemma trans_less_add1: "(i::nat) < j ==> i < j + m"
  1042 by (rule less_le_trans, assumption, rule le_add1)
  1043 
  1044 lemma trans_less_add2: "(i::nat) < j ==> i < m + j"
  1045 by (rule less_le_trans, assumption, rule le_add2)
  1046 
  1047 lemma add_lessD1: "i + j < (k::nat) ==> i < k"
  1048 apply (rule le_less_trans [of _ "i+j"])
  1049 apply (simp_all add: le_add1)
  1050 done
  1051 
  1052 lemma not_add_less1 [iff]: "~ (i + j < (i::nat))"
  1053 apply (rule notI)
  1054 apply (drule add_lessD1)
  1055 apply (erule less_irrefl [THEN notE])
  1056 done
  1057 
  1058 lemma not_add_less2 [iff]: "~ (j + i < (i::nat))"
  1059 by (simp add: add_commute)
  1060 
  1061 lemma add_leD1: "m + k \<le> n ==> m \<le> (n::nat)"
  1062 apply (rule order_trans [of _ "m+k"])
  1063 apply (simp_all add: le_add1)
  1064 done
  1065 
  1066 lemma add_leD2: "m + k \<le> n ==> k \<le> (n::nat)"
  1067 apply (simp add: add_commute)
  1068 apply (erule add_leD1)
  1069 done
  1070 
  1071 lemma add_leE: "(m::nat) + k \<le> n ==> (m \<le> n ==> k \<le> n ==> R) ==> R"
  1072 by (blast dest: add_leD1 add_leD2)
  1073 
  1074 text {* needs @{text "!!k"} for @{text add_ac} to work *}
  1075 lemma less_add_eq_less: "!!k::nat. k < l ==> m + l = k + n ==> m < n"
  1076 by (force simp del: add_Suc_right
  1077     simp add: less_iff_Suc_add add_Suc_right [symmetric] add_ac)
  1078 
  1079 
  1080 subsubsection {* More results about difference *}
  1081 
  1082 text {* Addition is the inverse of subtraction:
  1083   if @{term "n \<le> m"} then @{term "n + (m - n) = m"}. *}
  1084 lemma add_diff_inverse: "~  m < n ==> n + (m - n) = (m::nat)"
  1085 by (induct m n rule: diff_induct) simp_all
  1086 
  1087 lemma le_add_diff_inverse [simp]: "n \<le> m ==> n + (m - n) = (m::nat)"
  1088 by (simp add: add_diff_inverse linorder_not_less)
  1089 
  1090 lemma le_add_diff_inverse2 [simp]: "n \<le> m ==> (m - n) + n = (m::nat)"
  1091 by (simp add: add_commute)
  1092 
  1093 lemma Suc_diff_le: "n \<le> m ==> Suc m - n = Suc (m - n)"
  1094 by (induct m n rule: diff_induct) simp_all
  1095 
  1096 lemma diff_less_Suc: "m - n < Suc m"
  1097 apply (induct m n rule: diff_induct)
  1098 apply (erule_tac [3] less_SucE)
  1099 apply (simp_all add: less_Suc_eq)
  1100 done
  1101 
  1102 lemma diff_le_self [simp]: "m - n \<le> (m::nat)"
  1103 by (induct m n rule: diff_induct) (simp_all add: le_SucI)
  1104 
  1105 lemma le_iff_add: "(m::nat) \<le> n = (\<exists>k. n = m + k)"
  1106   by (auto simp: le_add1 dest!: le_add_diff_inverse sym [of _ n])
  1107 
  1108 instance nat :: ordered_cancel_comm_monoid_diff
  1109 proof
  1110   show "\<And>m n :: nat. m \<le> n \<longleftrightarrow> (\<exists>q. n = m + q)" by (fact le_iff_add)
  1111 qed
  1112 
  1113 lemma less_imp_diff_less: "(j::nat) < k ==> j - n < k"
  1114 by (rule le_less_trans, rule diff_le_self)
  1115 
  1116 lemma diff_Suc_less [simp]: "0<n ==> n - Suc i < n"
  1117 by (cases n) (auto simp add: le_simps)
  1118 
  1119 lemma diff_add_assoc: "k \<le> (j::nat) ==> (i + j) - k = i + (j - k)"
  1120 by (induct j k rule: diff_induct) simp_all
  1121 
  1122 lemma diff_add_assoc2: "k \<le> (j::nat) ==> (j + i) - k = (j - k) + i"
  1123 by (simp add: add_commute diff_add_assoc)
  1124 
  1125 lemma le_imp_diff_is_add: "i \<le> (j::nat) ==> (j - i = k) = (j = k + i)"
  1126 by (auto simp add: diff_add_inverse2)
  1127 
  1128 lemma diff_is_0_eq [simp]: "((m::nat) - n = 0) = (m \<le> n)"
  1129 by (induct m n rule: diff_induct) simp_all
  1130 
  1131 lemma diff_is_0_eq' [simp]: "m \<le> n ==> (m::nat) - n = 0"
  1132 by (rule iffD2, rule diff_is_0_eq)
  1133 
  1134 lemma zero_less_diff [simp]: "(0 < n - (m::nat)) = (m < n)"
  1135 by (induct m n rule: diff_induct) simp_all
  1136 
  1137 lemma less_imp_add_positive:
  1138   assumes "i < j"
  1139   shows "\<exists>k::nat. 0 < k & i + k = j"
  1140 proof
  1141   from assms show "0 < j - i & i + (j - i) = j"
  1142     by (simp add: order_less_imp_le)
  1143 qed
  1144 
  1145 text {* a nice rewrite for bounded subtraction *}
  1146 lemma nat_minus_add_max:
  1147   fixes n m :: nat
  1148   shows "n - m + m = max n m"
  1149     by (simp add: max_def not_le order_less_imp_le)
  1150 
  1151 lemma nat_diff_split:
  1152   "P(a - b::nat) = ((a<b --> P 0) & (ALL d. a = b + d --> P d))"
  1153     -- {* elimination of @{text -} on @{text nat} *}
  1154 by (cases "a < b")
  1155   (auto simp add: diff_is_0_eq [THEN iffD2] diff_add_inverse
  1156     not_less le_less dest!: sym [of a] sym [of b] add_eq_self_zero)
  1157 
  1158 lemma nat_diff_split_asm:
  1159   "P(a - b::nat) = (~ (a < b & ~ P 0 | (EX d. a = b + d & ~ P d)))"
  1160     -- {* elimination of @{text -} on @{text nat} in assumptions *}
  1161 by (auto split: nat_diff_split)
  1162 
  1163 lemma Suc_pred': "0 < n ==> n = Suc(n - 1)"
  1164   by simp
  1165 
  1166 lemma add_eq_if: "(m::nat) + n = (if m=0 then n else Suc ((m - 1) + n))"
  1167   unfolding One_nat_def by (cases m) simp_all
  1168 
  1169 lemma mult_eq_if: "(m::nat) * n = (if m=0 then 0 else n + ((m - 1) * n))"
  1170   unfolding One_nat_def by (cases m) simp_all
  1171 
  1172 lemma Suc_diff_eq_diff_pred: "0 < n ==> Suc m - n = m - (n - 1)"
  1173   unfolding One_nat_def by (cases n) simp_all
  1174 
  1175 lemma diff_Suc_eq_diff_pred: "m - Suc n = (m - 1) - n"
  1176   unfolding One_nat_def by (cases m) simp_all
  1177 
  1178 lemma Let_Suc [simp]: "Let (Suc n) f == f (Suc n)"
  1179   by (fact Let_def)
  1180 
  1181 
  1182 subsubsection {* Monotonicity of Multiplication *}
  1183 
  1184 lemma mult_le_mono1: "i \<le> (j::nat) ==> i * k \<le> j * k"
  1185 by (simp add: mult_right_mono)
  1186 
  1187 lemma mult_le_mono2: "i \<le> (j::nat) ==> k * i \<le> k * j"
  1188 by (simp add: mult_left_mono)
  1189 
  1190 text {* @{text "\<le>"} monotonicity, BOTH arguments *}
  1191 lemma mult_le_mono: "i \<le> (j::nat) ==> k \<le> l ==> i * k \<le> j * l"
  1192 by (simp add: mult_mono)
  1193 
  1194 lemma mult_less_mono1: "(i::nat) < j ==> 0 < k ==> i * k < j * k"
  1195 by (simp add: mult_strict_right_mono)
  1196 
  1197 text{*Differs from the standard @{text zero_less_mult_iff} in that
  1198       there are no negative numbers.*}
  1199 lemma nat_0_less_mult_iff [simp]: "(0 < (m::nat) * n) = (0 < m & 0 < n)"
  1200   apply (induct m)
  1201    apply simp
  1202   apply (case_tac n)
  1203    apply simp_all
  1204   done
  1205 
  1206 lemma one_le_mult_iff [simp]: "(Suc 0 \<le> m * n) = (Suc 0 \<le> m & Suc 0 \<le> n)"
  1207   apply (induct m)
  1208    apply simp
  1209   apply (case_tac n)
  1210    apply simp_all
  1211   done
  1212 
  1213 lemma mult_less_cancel2 [simp]: "((m::nat) * k < n * k) = (0 < k & m < n)"
  1214   apply (safe intro!: mult_less_mono1)
  1215   apply (cases k, auto)
  1216   apply (simp del: le_0_eq add: linorder_not_le [symmetric])
  1217   apply (blast intro: mult_le_mono1)
  1218   done
  1219 
  1220 lemma mult_less_cancel1 [simp]: "(k * (m::nat) < k * n) = (0 < k & m < n)"
  1221 by (simp add: mult_commute [of k])
  1222 
  1223 lemma mult_le_cancel1 [simp]: "(k * (m::nat) \<le> k * n) = (0 < k --> m \<le> n)"
  1224 by (simp add: linorder_not_less [symmetric], auto)
  1225 
  1226 lemma mult_le_cancel2 [simp]: "((m::nat) * k \<le> n * k) = (0 < k --> m \<le> n)"
  1227 by (simp add: linorder_not_less [symmetric], auto)
  1228 
  1229 lemma Suc_mult_less_cancel1: "(Suc k * m < Suc k * n) = (m < n)"
  1230 by (subst mult_less_cancel1) simp
  1231 
  1232 lemma Suc_mult_le_cancel1: "(Suc k * m \<le> Suc k * n) = (m \<le> n)"
  1233 by (subst mult_le_cancel1) simp
  1234 
  1235 lemma le_square: "m \<le> m * (m::nat)"
  1236   by (cases m) (auto intro: le_add1)
  1237 
  1238 lemma le_cube: "(m::nat) \<le> m * (m * m)"
  1239   by (cases m) (auto intro: le_add1)
  1240 
  1241 text {* Lemma for @{text gcd} *}
  1242 lemma mult_eq_self_implies_10: "(m::nat) = m * n ==> n = 1 | m = 0"
  1243   apply (drule sym)
  1244   apply (rule disjCI)
  1245   apply (rule nat_less_cases, erule_tac [2] _)
  1246    apply (drule_tac [2] mult_less_mono2)
  1247     apply (auto)
  1248   done
  1249 
  1250 lemma mono_times_nat:
  1251   fixes n :: nat
  1252   assumes "n > 0"
  1253   shows "mono (times n)"
  1254 proof
  1255   fix m q :: nat
  1256   assume "m \<le> q"
  1257   with assms show "n * m \<le> n * q" by simp
  1258 qed
  1259 
  1260 text {* the lattice order on @{typ nat} *}
  1261 
  1262 instantiation nat :: distrib_lattice
  1263 begin
  1264 
  1265 definition
  1266   "(inf \<Colon> nat \<Rightarrow> nat \<Rightarrow> nat) = min"
  1267 
  1268 definition
  1269   "(sup \<Colon> nat \<Rightarrow> nat \<Rightarrow> nat) = max"
  1270 
  1271 instance by intro_classes
  1272   (auto simp add: inf_nat_def sup_nat_def max_def not_le min_def
  1273     intro: order_less_imp_le antisym elim!: order_trans order_less_trans)
  1274 
  1275 end
  1276 
  1277 
  1278 subsection {* Natural operation of natural numbers on functions *}
  1279 
  1280 text {*
  1281   We use the same logical constant for the power operations on
  1282   functions and relations, in order to share the same syntax.
  1283 *}
  1284 
  1285 consts compow :: "nat \<Rightarrow> 'a \<Rightarrow> 'a"
  1286 
  1287 abbreviation compower :: "'a \<Rightarrow> nat \<Rightarrow> 'a" (infixr "^^" 80) where
  1288   "f ^^ n \<equiv> compow n f"
  1289 
  1290 notation (latex output)
  1291   compower ("(_\<^bsup>_\<^esup>)" [1000] 1000)
  1292 
  1293 notation (HTML output)
  1294   compower ("(_\<^bsup>_\<^esup>)" [1000] 1000)
  1295 
  1296 text {* @{text "f ^^ n = f o ... o f"}, the n-fold composition of @{text f} *}
  1297 
  1298 overloading
  1299   funpow == "compow :: nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> ('a \<Rightarrow> 'a)"
  1300 begin
  1301 
  1302 primrec funpow :: "nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'a" where
  1303   "funpow 0 f = id"
  1304 | "funpow (Suc n) f = f o funpow n f"
  1305 
  1306 end
  1307 
  1308 lemma funpow_Suc_right:
  1309   "f ^^ Suc n = f ^^ n \<circ> f"
  1310 proof (induct n)
  1311   case 0 then show ?case by simp
  1312 next
  1313   fix n
  1314   assume "f ^^ Suc n = f ^^ n \<circ> f"
  1315   then show "f ^^ Suc (Suc n) = f ^^ Suc n \<circ> f"
  1316     by (simp add: o_assoc)
  1317 qed
  1318 
  1319 lemmas funpow_simps_right = funpow.simps(1) funpow_Suc_right
  1320 
  1321 text {* for code generation *}
  1322 
  1323 definition funpow :: "nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'a" where
  1324   funpow_code_def [code_abbrev]: "funpow = compow"
  1325 
  1326 lemma [code]:
  1327   "funpow (Suc n) f = f o funpow n f"
  1328   "funpow 0 f = id"
  1329   by (simp_all add: funpow_code_def)
  1330 
  1331 hide_const (open) funpow
  1332 
  1333 lemma funpow_add:
  1334   "f ^^ (m + n) = f ^^ m \<circ> f ^^ n"
  1335   by (induct m) simp_all
  1336 
  1337 lemma funpow_mult:
  1338   fixes f :: "'a \<Rightarrow> 'a"
  1339   shows "(f ^^ m) ^^ n = f ^^ (m * n)"
  1340   by (induct n) (simp_all add: funpow_add)
  1341 
  1342 lemma funpow_swap1:
  1343   "f ((f ^^ n) x) = (f ^^ n) (f x)"
  1344 proof -
  1345   have "f ((f ^^ n) x) = (f ^^ (n + 1)) x" by simp
  1346   also have "\<dots>  = (f ^^ n o f ^^ 1) x" by (simp only: funpow_add)
  1347   also have "\<dots> = (f ^^ n) (f x)" by simp
  1348   finally show ?thesis .
  1349 qed
  1350 
  1351 lemma comp_funpow:
  1352   fixes f :: "'a \<Rightarrow> 'a"
  1353   shows "comp f ^^ n = comp (f ^^ n)"
  1354   by (induct n) simp_all
  1355 
  1356 lemma Suc_funpow[simp]: "Suc ^^ n = (op + n)"
  1357   by (induct n) simp_all
  1358 
  1359 lemma id_funpow[simp]: "id ^^ n = id"
  1360   by (induct n) simp_all
  1361 
  1362 subsection {* Kleene iteration *}
  1363 
  1364 lemma Kleene_iter_lpfp:
  1365 assumes "mono f" and "f p \<le> p" shows "(f^^k) (bot::'a::order_bot) \<le> p"
  1366 proof(induction k)
  1367   case 0 show ?case by simp
  1368 next
  1369   case Suc
  1370   from monoD[OF assms(1) Suc] assms(2)
  1371   show ?case by simp
  1372 qed
  1373 
  1374 lemma lfp_Kleene_iter: assumes "mono f" and "(f^^Suc k) bot = (f^^k) bot"
  1375 shows "lfp f = (f^^k) bot"
  1376 proof(rule antisym)
  1377   show "lfp f \<le> (f^^k) bot"
  1378   proof(rule lfp_lowerbound)
  1379     show "f ((f^^k) bot) \<le> (f^^k) bot" using assms(2) by simp
  1380   qed
  1381 next
  1382   show "(f^^k) bot \<le> lfp f"
  1383     using Kleene_iter_lpfp[OF assms(1)] lfp_unfold[OF assms(1)] by simp
  1384 qed
  1385 
  1386 
  1387 subsection {* Embedding of the Naturals into any @{text semiring_1}: @{term of_nat} *}
  1388 
  1389 context semiring_1
  1390 begin
  1391 
  1392 definition of_nat :: "nat \<Rightarrow> 'a" where
  1393   "of_nat n = (plus 1 ^^ n) 0"
  1394 
  1395 lemma of_nat_simps [simp]:
  1396   shows of_nat_0: "of_nat 0 = 0"
  1397     and of_nat_Suc: "of_nat (Suc m) = 1 + of_nat m"
  1398   by (simp_all add: of_nat_def)
  1399 
  1400 lemma of_nat_1 [simp]: "of_nat 1 = 1"
  1401   by (simp add: of_nat_def)
  1402 
  1403 lemma of_nat_add [simp]: "of_nat (m + n) = of_nat m + of_nat n"
  1404   by (induct m) (simp_all add: add_ac)
  1405 
  1406 lemma of_nat_mult: "of_nat (m * n) = of_nat m * of_nat n"
  1407   by (induct m) (simp_all add: add_ac distrib_right)
  1408 
  1409 primrec of_nat_aux :: "('a \<Rightarrow> 'a) \<Rightarrow> nat \<Rightarrow> 'a \<Rightarrow> 'a" where
  1410   "of_nat_aux inc 0 i = i"
  1411 | "of_nat_aux inc (Suc n) i = of_nat_aux inc n (inc i)" -- {* tail recursive *}
  1412 
  1413 lemma of_nat_code:
  1414   "of_nat n = of_nat_aux (\<lambda>i. i + 1) n 0"
  1415 proof (induct n)
  1416   case 0 then show ?case by simp
  1417 next
  1418   case (Suc n)
  1419   have "\<And>i. of_nat_aux (\<lambda>i. i + 1) n (i + 1) = of_nat_aux (\<lambda>i. i + 1) n i + 1"
  1420     by (induct n) simp_all
  1421   from this [of 0] have "of_nat_aux (\<lambda>i. i + 1) n 1 = of_nat_aux (\<lambda>i. i + 1) n 0 + 1"
  1422     by simp
  1423   with Suc show ?case by (simp add: add_commute)
  1424 qed
  1425 
  1426 end
  1427 
  1428 declare of_nat_code [code]
  1429 
  1430 text{*Class for unital semirings with characteristic zero.
  1431  Includes non-ordered rings like the complex numbers.*}
  1432 
  1433 class semiring_char_0 = semiring_1 +
  1434   assumes inj_of_nat: "inj of_nat"
  1435 begin
  1436 
  1437 lemma of_nat_eq_iff [simp]: "of_nat m = of_nat n \<longleftrightarrow> m = n"
  1438   by (auto intro: inj_of_nat injD)
  1439 
  1440 text{*Special cases where either operand is zero*}
  1441 
  1442 lemma of_nat_0_eq_iff [simp]: "0 = of_nat n \<longleftrightarrow> 0 = n"
  1443   by (fact of_nat_eq_iff [of 0 n, unfolded of_nat_0])
  1444 
  1445 lemma of_nat_eq_0_iff [simp]: "of_nat m = 0 \<longleftrightarrow> m = 0"
  1446   by (fact of_nat_eq_iff [of m 0, unfolded of_nat_0])
  1447 
  1448 end
  1449 
  1450 context linordered_semidom
  1451 begin
  1452 
  1453 lemma of_nat_0_le_iff [simp]: "0 \<le> of_nat n"
  1454   by (induct n) simp_all
  1455 
  1456 lemma of_nat_less_0_iff [simp]: "\<not> of_nat m < 0"
  1457   by (simp add: not_less)
  1458 
  1459 lemma of_nat_less_iff [simp]: "of_nat m < of_nat n \<longleftrightarrow> m < n"
  1460   by (induct m n rule: diff_induct, simp_all add: add_pos_nonneg)
  1461 
  1462 lemma of_nat_le_iff [simp]: "of_nat m \<le> of_nat n \<longleftrightarrow> m \<le> n"
  1463   by (simp add: not_less [symmetric] linorder_not_less [symmetric])
  1464 
  1465 lemma less_imp_of_nat_less: "m < n \<Longrightarrow> of_nat m < of_nat n"
  1466   by simp
  1467 
  1468 lemma of_nat_less_imp_less: "of_nat m < of_nat n \<Longrightarrow> m < n"
  1469   by simp
  1470 
  1471 text{*Every @{text linordered_semidom} has characteristic zero.*}
  1472 
  1473 subclass semiring_char_0 proof
  1474 qed (auto intro!: injI simp add: eq_iff)
  1475 
  1476 text{*Special cases where either operand is zero*}
  1477 
  1478 lemma of_nat_le_0_iff [simp]: "of_nat m \<le> 0 \<longleftrightarrow> m = 0"
  1479   by (rule of_nat_le_iff [of _ 0, simplified])
  1480 
  1481 lemma of_nat_0_less_iff [simp]: "0 < of_nat n \<longleftrightarrow> 0 < n"
  1482   by (rule of_nat_less_iff [of 0, simplified])
  1483 
  1484 end
  1485 
  1486 context ring_1
  1487 begin
  1488 
  1489 lemma of_nat_diff: "n \<le> m \<Longrightarrow> of_nat (m - n) = of_nat m - of_nat n"
  1490 by (simp add: algebra_simps of_nat_add [symmetric])
  1491 
  1492 end
  1493 
  1494 context linordered_idom
  1495 begin
  1496 
  1497 lemma abs_of_nat [simp]: "\<bar>of_nat n\<bar> = of_nat n"
  1498   unfolding abs_if by auto
  1499 
  1500 end
  1501 
  1502 lemma of_nat_id [simp]: "of_nat n = n"
  1503   by (induct n) simp_all
  1504 
  1505 lemma of_nat_eq_id [simp]: "of_nat = id"
  1506   by (auto simp add: fun_eq_iff)
  1507 
  1508 
  1509 subsection {* The Set of Natural Numbers *}
  1510 
  1511 context semiring_1
  1512 begin
  1513 
  1514 definition Nats  :: "'a set" where
  1515   "Nats = range of_nat"
  1516 
  1517 notation (xsymbols)
  1518   Nats  ("\<nat>")
  1519 
  1520 lemma of_nat_in_Nats [simp]: "of_nat n \<in> \<nat>"
  1521   by (simp add: Nats_def)
  1522 
  1523 lemma Nats_0 [simp]: "0 \<in> \<nat>"
  1524 apply (simp add: Nats_def)
  1525 apply (rule range_eqI)
  1526 apply (rule of_nat_0 [symmetric])
  1527 done
  1528 
  1529 lemma Nats_1 [simp]: "1 \<in> \<nat>"
  1530 apply (simp add: Nats_def)
  1531 apply (rule range_eqI)
  1532 apply (rule of_nat_1 [symmetric])
  1533 done
  1534 
  1535 lemma Nats_add [simp]: "a \<in> \<nat> \<Longrightarrow> b \<in> \<nat> \<Longrightarrow> a + b \<in> \<nat>"
  1536 apply (auto simp add: Nats_def)
  1537 apply (rule range_eqI)
  1538 apply (rule of_nat_add [symmetric])
  1539 done
  1540 
  1541 lemma Nats_mult [simp]: "a \<in> \<nat> \<Longrightarrow> b \<in> \<nat> \<Longrightarrow> a * b \<in> \<nat>"
  1542 apply (auto simp add: Nats_def)
  1543 apply (rule range_eqI)
  1544 apply (rule of_nat_mult [symmetric])
  1545 done
  1546 
  1547 lemma Nats_cases [cases set: Nats]:
  1548   assumes "x \<in> \<nat>"
  1549   obtains (of_nat) n where "x = of_nat n"
  1550   unfolding Nats_def
  1551 proof -
  1552   from `x \<in> \<nat>` have "x \<in> range of_nat" unfolding Nats_def .
  1553   then obtain n where "x = of_nat n" ..
  1554   then show thesis ..
  1555 qed
  1556 
  1557 lemma Nats_induct [case_names of_nat, induct set: Nats]:
  1558   "x \<in> \<nat> \<Longrightarrow> (\<And>n. P (of_nat n)) \<Longrightarrow> P x"
  1559   by (rule Nats_cases) auto
  1560 
  1561 end
  1562 
  1563 
  1564 subsection {* Further Arithmetic Facts Concerning the Natural Numbers *}
  1565 
  1566 lemma subst_equals:
  1567   assumes 1: "t = s" and 2: "u = t"
  1568   shows "u = s"
  1569   using 2 1 by (rule trans)
  1570 
  1571 setup Arith_Data.setup
  1572 
  1573 ML_file "Tools/nat_arith.ML"
  1574 
  1575 simproc_setup nateq_cancel_sums
  1576   ("(l::nat) + m = n" | "(l::nat) = m + n" | "Suc m = n" | "m = Suc n") =
  1577   {* fn phi => try o Nat_Arith.cancel_eq_conv *}
  1578 
  1579 simproc_setup natless_cancel_sums
  1580   ("(l::nat) + m < n" | "(l::nat) < m + n" | "Suc m < n" | "m < Suc n") =
  1581   {* fn phi => try o Nat_Arith.cancel_less_conv *}
  1582 
  1583 simproc_setup natle_cancel_sums
  1584   ("(l::nat) + m \<le> n" | "(l::nat) \<le> m + n" | "Suc m \<le> n" | "m \<le> Suc n") =
  1585   {* fn phi => try o Nat_Arith.cancel_le_conv *}
  1586 
  1587 simproc_setup natdiff_cancel_sums
  1588   ("(l::nat) + m - n" | "(l::nat) - (m + n)" | "Suc m - n" | "m - Suc n") =
  1589   {* fn phi => try o Nat_Arith.cancel_diff_conv *}
  1590 
  1591 ML_file "Tools/lin_arith.ML"
  1592 setup {* Lin_Arith.global_setup *}
  1593 declaration {* K Lin_Arith.setup *}
  1594 
  1595 simproc_setup fast_arith_nat ("(m::nat) < n" | "(m::nat) <= n" | "(m::nat) = n") =
  1596   {* fn _ => fn ss => fn ct => Lin_Arith.simproc ss (term_of ct) *}
  1597 (* Because of this simproc, the arithmetic solver is really only
  1598 useful to detect inconsistencies among the premises for subgoals which are
  1599 *not* themselves (in)equalities, because the latter activate
  1600 fast_nat_arith_simproc anyway. However, it seems cheaper to activate the
  1601 solver all the time rather than add the additional check. *)
  1602 
  1603 
  1604 lemmas [arith_split] = nat_diff_split split_min split_max
  1605 
  1606 context order
  1607 begin
  1608 
  1609 lemma lift_Suc_mono_le:
  1610   assumes mono: "\<And>n. f n \<le> f (Suc n)" and "n \<le> n'"
  1611   shows "f n \<le> f n'"
  1612 proof (cases "n < n'")
  1613   case True
  1614   then show ?thesis
  1615     by (induct n n' rule: less_Suc_induct [consumes 1]) (auto intro: mono)
  1616 qed (insert `n \<le> n'`, auto) -- {* trivial for @{prop "n = n'"} *}
  1617 
  1618 lemma lift_Suc_mono_less:
  1619   assumes mono: "\<And>n. f n < f (Suc n)" and "n < n'"
  1620   shows "f n < f n'"
  1621 using `n < n'`
  1622 by (induct n n' rule: less_Suc_induct [consumes 1]) (auto intro: mono)
  1623 
  1624 lemma lift_Suc_mono_less_iff:
  1625   "(\<And>n. f n < f (Suc n)) \<Longrightarrow> f n < f m \<longleftrightarrow> n < m"
  1626   by (blast intro: less_asym' lift_Suc_mono_less [of f]
  1627     dest: linorder_not_less[THEN iffD1] le_eq_less_or_eq [THEN iffD1])
  1628 
  1629 end
  1630 
  1631 lemma mono_iff_le_Suc:
  1632   "mono f \<longleftrightarrow> (\<forall>n. f n \<le> f (Suc n))"
  1633   unfolding mono_def by (auto intro: lift_Suc_mono_le [of f])
  1634 
  1635 lemma mono_nat_linear_lb:
  1636   fixes f :: "nat \<Rightarrow> nat"
  1637   assumes "\<And>m n. m < n \<Longrightarrow> f m < f n"
  1638   shows "f m + k \<le> f (m + k)"
  1639 proof (induct k)
  1640   case 0 then show ?case by simp
  1641 next
  1642   case (Suc k)
  1643   then have "Suc (f m + k) \<le> Suc (f (m + k))" by simp
  1644   also from assms [of "m + k" "Suc (m + k)"] have "Suc (f (m + k)) \<le> f (Suc (m + k))"
  1645     by (simp add: Suc_le_eq)
  1646   finally show ?case by simp
  1647 qed
  1648 
  1649 
  1650 text{*Subtraction laws, mostly by Clemens Ballarin*}
  1651 
  1652 lemma diff_less_mono: "[| a < (b::nat); c \<le> a |] ==> a-c < b-c"
  1653 by arith
  1654 
  1655 lemma less_diff_conv: "(i < j-k) = (i+k < (j::nat))"
  1656 by arith
  1657 
  1658 lemma less_diff_conv2:
  1659   fixes j k i :: nat
  1660   assumes "k \<le> j"
  1661   shows "j - k < i \<longleftrightarrow> j < i + k"
  1662   using assms by arith
  1663 
  1664 lemma le_diff_conv: "(j-k \<le> (i::nat)) = (j \<le> i+k)"
  1665 by arith
  1666 
  1667 lemma le_diff_conv2: "k \<le> j ==> (i \<le> j-k) = (i+k \<le> (j::nat))"
  1668 by arith
  1669 
  1670 lemma diff_diff_cancel [simp]: "i \<le> (n::nat) ==> n - (n - i) = i"
  1671 by arith
  1672 
  1673 lemma le_add_diff: "k \<le> (n::nat) ==> m \<le> n + m - k"
  1674 by arith
  1675 
  1676 (*Replaces the previous diff_less and le_diff_less, which had the stronger
  1677   second premise n\<le>m*)
  1678 lemma diff_less[simp]: "!!m::nat. [| 0<n; 0<m |] ==> m - n < m"
  1679 by arith
  1680 
  1681 text {* Simplification of relational expressions involving subtraction *}
  1682 
  1683 lemma diff_diff_eq: "[| k \<le> m;  k \<le> (n::nat) |] ==> ((m-k) - (n-k)) = (m-n)"
  1684 by (simp split add: nat_diff_split)
  1685 
  1686 hide_fact (open) diff_diff_eq
  1687 
  1688 lemma eq_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k = n-k) = (m=n)"
  1689 by (auto split add: nat_diff_split)
  1690 
  1691 lemma less_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k < n-k) = (m<n)"
  1692 by (auto split add: nat_diff_split)
  1693 
  1694 lemma le_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k \<le> n-k) = (m\<le>n)"
  1695 by (auto split add: nat_diff_split)
  1696 
  1697 text{*(Anti)Monotonicity of subtraction -- by Stephan Merz*}
  1698 
  1699 (* Monotonicity of subtraction in first argument *)
  1700 lemma diff_le_mono: "m \<le> (n::nat) ==> (m-l) \<le> (n-l)"
  1701 by (simp split add: nat_diff_split)
  1702 
  1703 lemma diff_le_mono2: "m \<le> (n::nat) ==> (l-n) \<le> (l-m)"
  1704 by (simp split add: nat_diff_split)
  1705 
  1706 lemma diff_less_mono2: "[| m < (n::nat); m<l |] ==> (l-n) < (l-m)"
  1707 by (simp split add: nat_diff_split)
  1708 
  1709 lemma diffs0_imp_equal: "!!m::nat. [| m-n = 0; n-m = 0 |] ==>  m=n"
  1710 by (simp split add: nat_diff_split)
  1711 
  1712 lemma min_diff: "min (m - (i::nat)) (n - i) = min m n - i"
  1713 by auto
  1714 
  1715 lemma inj_on_diff_nat: 
  1716   assumes k_le_n: "\<forall>n \<in> N. k \<le> (n::nat)"
  1717   shows "inj_on (\<lambda>n. n - k) N"
  1718 proof (rule inj_onI)
  1719   fix x y
  1720   assume a: "x \<in> N" "y \<in> N" "x - k = y - k"
  1721   with k_le_n have "x - k + k = y - k + k" by auto
  1722   with a k_le_n show "x = y" by auto
  1723 qed
  1724 
  1725 text{*Rewriting to pull differences out*}
  1726 
  1727 lemma diff_diff_right [simp]: "k\<le>j --> i - (j - k) = i + (k::nat) - j"
  1728 by arith
  1729 
  1730 lemma diff_Suc_diff_eq1 [simp]: "k \<le> j ==> m - Suc (j - k) = m + k - Suc j"
  1731 by arith
  1732 
  1733 lemma diff_Suc_diff_eq2 [simp]: "k \<le> j ==> Suc (j - k) - m = Suc j - (k + m)"
  1734 by arith
  1735 
  1736 lemma Suc_diff_Suc: "n < m \<Longrightarrow> Suc (m - Suc n) = m - n"
  1737 by simp
  1738 
  1739 (*The others are
  1740       i - j - k = i - (j + k),
  1741       k \<le> j ==> j - k + i = j + i - k,
  1742       k \<le> j ==> i + (j - k) = i + j - k *)
  1743 lemmas add_diff_assoc = diff_add_assoc [symmetric]
  1744 lemmas add_diff_assoc2 = diff_add_assoc2[symmetric]
  1745 declare diff_diff_left [simp]  add_diff_assoc [simp] add_diff_assoc2[simp]
  1746 
  1747 text{*At present we prove no analogue of @{text not_less_Least} or @{text
  1748 Least_Suc}, since there appears to be no need.*}
  1749 
  1750 text{*Lemmas for ex/Factorization*}
  1751 
  1752 lemma one_less_mult: "[| Suc 0 < n; Suc 0 < m |] ==> Suc 0 < m*n"
  1753 by (cases m) auto
  1754 
  1755 lemma n_less_m_mult_n: "[| Suc 0 < n; Suc 0 < m |] ==> n<m*n"
  1756 by (cases m) auto
  1757 
  1758 lemma n_less_n_mult_m: "[| Suc 0 < n; Suc 0 < m |] ==> n<n*m"
  1759 by (cases m) auto
  1760 
  1761 text {* Specialized induction principles that work "backwards": *}
  1762 
  1763 lemma inc_induct[consumes 1, case_names base step]:
  1764   assumes less: "i \<le> j"
  1765   assumes base: "P j"
  1766   assumes step: "\<And>n. i \<le> n \<Longrightarrow> n < j \<Longrightarrow> P (Suc n) \<Longrightarrow> P n"
  1767   shows "P i"
  1768   using less step
  1769 proof (induct d\<equiv>"j - i" arbitrary: i)
  1770   case (0 i)
  1771   hence "i = j" by simp
  1772   with base show ?case by simp
  1773 next
  1774   case (Suc d n)
  1775   hence "n \<le> n" "n < j" "P (Suc n)"
  1776     by simp_all
  1777   then show "P n" by fact
  1778 qed
  1779 
  1780 lemma strict_inc_induct[consumes 1, case_names base step]:
  1781   assumes less: "i < j"
  1782   assumes base: "!!i. j = Suc i ==> P i"
  1783   assumes step: "!!i. [| i < j; P (Suc i) |] ==> P i"
  1784   shows "P i"
  1785   using less
  1786 proof (induct d=="j - i - 1" arbitrary: i)
  1787   case (0 i)
  1788   with `i < j` have "j = Suc i" by simp
  1789   with base show ?case by simp
  1790 next
  1791   case (Suc d i)
  1792   hence "i < j" "P (Suc i)"
  1793     by simp_all
  1794   thus "P i" by (rule step)
  1795 qed
  1796 
  1797 lemma zero_induct_lemma: "P k ==> (!!n. P (Suc n) ==> P n) ==> P (k - i)"
  1798   using inc_induct[of "k - i" k P, simplified] by blast
  1799 
  1800 lemma zero_induct: "P k ==> (!!n. P (Suc n) ==> P n) ==> P 0"
  1801   using inc_induct[of 0 k P] by blast
  1802 
  1803 text {* Further induction rule similar to @{thm inc_induct} *}
  1804 
  1805 lemma dec_induct[consumes 1, case_names base step]:
  1806   "i \<le> j \<Longrightarrow> P i \<Longrightarrow> (\<And>n. i \<le> n \<Longrightarrow> n < j \<Longrightarrow> P n \<Longrightarrow> P (Suc n)) \<Longrightarrow> P j"
  1807   by (induct j arbitrary: i) (auto simp: le_Suc_eq)
  1808  
  1809 subsection {* The divides relation on @{typ nat} *}
  1810 
  1811 lemma dvd_1_left [iff]: "Suc 0 dvd k"
  1812 unfolding dvd_def by simp
  1813 
  1814 lemma dvd_1_iff_1 [simp]: "(m dvd Suc 0) = (m = Suc 0)"
  1815 by (simp add: dvd_def)
  1816 
  1817 lemma nat_dvd_1_iff_1 [simp]: "m dvd (1::nat) \<longleftrightarrow> m = 1"
  1818 by (simp add: dvd_def)
  1819 
  1820 lemma dvd_antisym: "[| m dvd n; n dvd m |] ==> m = (n::nat)"
  1821   unfolding dvd_def
  1822   by (force dest: mult_eq_self_implies_10 simp add: mult_assoc)
  1823 
  1824 text {* @{term "op dvd"} is a partial order *}
  1825 
  1826 interpretation dvd: order "op dvd" "\<lambda>n m \<Colon> nat. n dvd m \<and> \<not> m dvd n"
  1827   proof qed (auto intro: dvd_refl dvd_trans dvd_antisym)
  1828 
  1829 lemma dvd_diff_nat[simp]: "[| k dvd m; k dvd n |] ==> k dvd (m-n :: nat)"
  1830 unfolding dvd_def
  1831 by (blast intro: diff_mult_distrib2 [symmetric])
  1832 
  1833 lemma dvd_diffD: "[| k dvd m-n; k dvd n; n\<le>m |] ==> k dvd (m::nat)"
  1834   apply (erule linorder_not_less [THEN iffD2, THEN add_diff_inverse, THEN subst])
  1835   apply (blast intro: dvd_add)
  1836   done
  1837 
  1838 lemma dvd_diffD1: "[| k dvd m-n; k dvd m; n\<le>m |] ==> k dvd (n::nat)"
  1839 by (drule_tac m = m in dvd_diff_nat, auto)
  1840 
  1841 lemma dvd_reduce: "(k dvd n + k) = (k dvd (n::nat))"
  1842   apply (rule iffI)
  1843    apply (erule_tac [2] dvd_add)
  1844    apply (rule_tac [2] dvd_refl)
  1845   apply (subgoal_tac "n = (n+k) -k")
  1846    prefer 2 apply simp
  1847   apply (erule ssubst)
  1848   apply (erule dvd_diff_nat)
  1849   apply (rule dvd_refl)
  1850   done
  1851 
  1852 lemma dvd_mult_cancel: "!!k::nat. [| k*m dvd k*n; 0<k |] ==> m dvd n"
  1853   unfolding dvd_def
  1854   apply (erule exE)
  1855   apply (simp add: mult_ac)
  1856   done
  1857 
  1858 lemma dvd_mult_cancel1: "0<m ==> (m*n dvd m) = (n = (1::nat))"
  1859   apply auto
  1860    apply (subgoal_tac "m*n dvd m*1")
  1861    apply (drule dvd_mult_cancel, auto)
  1862   done
  1863 
  1864 lemma dvd_mult_cancel2: "0<m ==> (n*m dvd m) = (n = (1::nat))"
  1865   apply (subst mult_commute)
  1866   apply (erule dvd_mult_cancel1)
  1867   done
  1868 
  1869 lemma dvd_imp_le: "[| k dvd n; 0 < n |] ==> k \<le> (n::nat)"
  1870 by (auto elim!: dvdE) (auto simp add: gr0_conv_Suc)
  1871 
  1872 lemma nat_dvd_not_less:
  1873   fixes m n :: nat
  1874   shows "0 < m \<Longrightarrow> m < n \<Longrightarrow> \<not> n dvd m"
  1875 by (auto elim!: dvdE) (auto simp add: gr0_conv_Suc)
  1876 
  1877 lemma dvd_plusE:
  1878   fixes m n q :: nat
  1879   assumes "m dvd n + q" "m dvd n"
  1880   obtains "m dvd q"
  1881 proof (cases "m = 0")
  1882   case True with assms that show thesis by simp
  1883 next
  1884   case False then have "m > 0" by simp
  1885   from assms obtain r s where "n = m * r" and "n + q = m * s" by (blast elim: dvdE)
  1886   then have *: "m * r + q = m * s" by simp
  1887   show thesis proof (cases "r \<le> s")
  1888     case False then have "s < r" by (simp add: not_le)
  1889     with * have "m * r + q - m * s = m * s - m * s" by simp
  1890     then have "m * r + q - m * s = 0" by simp
  1891     with `m > 0` `s < r` have "m * r - m * s + q = 0" by (unfold less_le_not_le) auto
  1892     then have "m * (r - s) + q = 0" by auto
  1893     then have "m * (r - s) = 0" by simp
  1894     then have "m = 0 \<or> r - s = 0" by simp
  1895     with `s < r` have "m = 0" by (simp add: less_le_not_le)
  1896     with `m > 0` show thesis by auto
  1897   next
  1898     case True with * have "m * r + q - m * r = m * s - m * r" by simp
  1899     with `m > 0` `r \<le> s` have "m * r - m * r + q = m * s - m * r" by simp
  1900     then have "q = m * (s - r)" by (simp add: diff_mult_distrib2)
  1901     with assms that show thesis by (auto intro: dvdI)
  1902   qed
  1903 qed
  1904 
  1905 lemma dvd_plus_eq_right:
  1906   fixes m n q :: nat
  1907   assumes "m dvd n"
  1908   shows "m dvd n + q \<longleftrightarrow> m dvd q"
  1909   using assms by (auto elim: dvd_plusE)
  1910 
  1911 lemma dvd_plus_eq_left:
  1912   fixes m n q :: nat
  1913   assumes "m dvd q"
  1914   shows "m dvd n + q \<longleftrightarrow> m dvd n"
  1915   using assms by (simp add: dvd_plus_eq_right add_commute [of n])
  1916 
  1917 lemma less_eq_dvd_minus:
  1918   fixes m n :: nat
  1919   assumes "m \<le> n"
  1920   shows "m dvd n \<longleftrightarrow> m dvd n - m"
  1921 proof -
  1922   from assms have "n = m + (n - m)" by simp
  1923   then obtain q where "n = m + q" ..
  1924   then show ?thesis by (simp add: dvd_reduce add_commute [of m])
  1925 qed
  1926 
  1927 lemma dvd_minus_self:
  1928   fixes m n :: nat
  1929   shows "m dvd n - m \<longleftrightarrow> n < m \<or> m dvd n"
  1930   by (cases "n < m") (auto elim!: dvdE simp add: not_less le_imp_diff_is_add)
  1931 
  1932 lemma dvd_minus_add:
  1933   fixes m n q r :: nat
  1934   assumes "q \<le> n" "q \<le> r * m"
  1935   shows "m dvd n - q \<longleftrightarrow> m dvd n + (r * m - q)"
  1936 proof -
  1937   have "m dvd n - q \<longleftrightarrow> m dvd r * m + (n - q)"
  1938     by (auto elim: dvd_plusE)
  1939   also from assms have "\<dots> \<longleftrightarrow> m dvd r * m + n - q" by simp
  1940   also from assms have "\<dots> \<longleftrightarrow> m dvd (r * m - q) + n" by simp
  1941   also have "\<dots> \<longleftrightarrow> m dvd n + (r * m - q)" by (simp add: add_commute)
  1942   finally show ?thesis .
  1943 qed
  1944 
  1945 
  1946 subsection {* aliasses *}
  1947 
  1948 lemma nat_mult_1: "(1::nat) * n = n"
  1949   by simp
  1950  
  1951 lemma nat_mult_1_right: "n * (1::nat) = n"
  1952   by simp
  1953 
  1954 
  1955 subsection {* size of a datatype value *}
  1956 
  1957 class size =
  1958   fixes size :: "'a \<Rightarrow> nat" -- {* see further theory @{text Wellfounded} *}
  1959 
  1960 
  1961 subsection {* code module namespace *}
  1962 
  1963 code_identifier
  1964   code_module Nat \<rightharpoonup> (SML) Arith and (OCaml) Arith and (Haskell) Arith
  1965 
  1966 hide_const (open) of_nat_aux
  1967 
  1968 end