src/HOL/Map.thy
author krauss
Mon Jul 27 22:50:01 2009 +0200 (2009-07-27)
changeset 32236 0203e1006f1b
parent 31380 f25536c0bb80
child 33635 dcaada178c6f
permissions -rw-r--r--
some lemmas about maps (contributed by Peter Lammich)
     1 (*  Title:      HOL/Map.thy
     2     Author:     Tobias Nipkow, based on a theory by David von Oheimb
     3     Copyright   1997-2003 TU Muenchen
     4 
     5 The datatype of `maps' (written ~=>); strongly resembles maps in VDM.
     6 *)
     7 
     8 header {* Maps *}
     9 
    10 theory Map
    11 imports List
    12 begin
    13 
    14 types ('a,'b) "~=>" = "'a => 'b option"  (infixr "~=>" 0)
    15 translations (type) "a ~=> b " <= (type) "a => b option"
    16 
    17 syntax (xsymbols)
    18   "~=>" :: "[type, type] => type"  (infixr "\<rightharpoonup>" 0)
    19 
    20 abbreviation
    21   empty :: "'a ~=> 'b" where
    22   "empty == %x. None"
    23 
    24 definition
    25   map_comp :: "('b ~=> 'c) => ('a ~=> 'b) => ('a ~=> 'c)"  (infixl "o'_m" 55) where
    26   "f o_m g = (\<lambda>k. case g k of None \<Rightarrow> None | Some v \<Rightarrow> f v)"
    27 
    28 notation (xsymbols)
    29   map_comp  (infixl "\<circ>\<^sub>m" 55)
    30 
    31 definition
    32   map_add :: "('a ~=> 'b) => ('a ~=> 'b) => ('a ~=> 'b)"  (infixl "++" 100) where
    33   "m1 ++ m2 = (\<lambda>x. case m2 x of None => m1 x | Some y => Some y)"
    34 
    35 definition
    36   restrict_map :: "('a ~=> 'b) => 'a set => ('a ~=> 'b)"  (infixl "|`"  110) where
    37   "m|`A = (\<lambda>x. if x : A then m x else None)"
    38 
    39 notation (latex output)
    40   restrict_map  ("_\<restriction>\<^bsub>_\<^esub>" [111,110] 110)
    41 
    42 definition
    43   dom :: "('a ~=> 'b) => 'a set" where
    44   "dom m = {a. m a ~= None}"
    45 
    46 definition
    47   ran :: "('a ~=> 'b) => 'b set" where
    48   "ran m = {b. EX a. m a = Some b}"
    49 
    50 definition
    51   map_le :: "('a ~=> 'b) => ('a ~=> 'b) => bool"  (infix "\<subseteq>\<^sub>m" 50) where
    52   "(m\<^isub>1 \<subseteq>\<^sub>m m\<^isub>2) = (\<forall>a \<in> dom m\<^isub>1. m\<^isub>1 a = m\<^isub>2 a)"
    53 
    54 consts
    55   map_of :: "('a * 'b) list => 'a ~=> 'b"
    56   map_upds :: "('a ~=> 'b) => 'a list => 'b list => ('a ~=> 'b)"
    57 
    58 nonterminals
    59   maplets maplet
    60 
    61 syntax
    62   "_maplet"  :: "['a, 'a] => maplet"             ("_ /|->/ _")
    63   "_maplets" :: "['a, 'a] => maplet"             ("_ /[|->]/ _")
    64   ""         :: "maplet => maplets"             ("_")
    65   "_Maplets" :: "[maplet, maplets] => maplets" ("_,/ _")
    66   "_MapUpd"  :: "['a ~=> 'b, maplets] => 'a ~=> 'b" ("_/'(_')" [900,0]900)
    67   "_Map"     :: "maplets => 'a ~=> 'b"            ("(1[_])")
    68 
    69 syntax (xsymbols)
    70   "_maplet"  :: "['a, 'a] => maplet"             ("_ /\<mapsto>/ _")
    71   "_maplets" :: "['a, 'a] => maplet"             ("_ /[\<mapsto>]/ _")
    72 
    73 translations
    74   "_MapUpd m (_Maplets xy ms)"  == "_MapUpd (_MapUpd m xy) ms"
    75   "_MapUpd m (_maplet  x y)"    == "m(x:=Some y)"
    76   "_MapUpd m (_maplets x y)"    == "map_upds m x y"
    77   "_Map ms"                     == "_MapUpd (CONST empty) ms"
    78   "_Map (_Maplets ms1 ms2)"     <= "_MapUpd (_Map ms1) ms2"
    79   "_Maplets ms1 (_Maplets ms2 ms3)" <= "_Maplets (_Maplets ms1 ms2) ms3"
    80 
    81 primrec
    82   "map_of [] = empty"
    83   "map_of (p#ps) = (map_of ps)(fst p |-> snd p)"
    84 
    85 declare map_of.simps [code del]
    86 
    87 lemma map_of_Cons_code [code]: 
    88   "map_of [] k = None"
    89   "map_of ((l, v) # ps) k = (if l = k then Some v else map_of ps k)"
    90   by simp_all
    91 
    92 defs
    93   map_upds_def [code]: "m(xs [|->] ys) == m ++ map_of (rev(zip xs ys))"
    94 
    95 
    96 subsection {* @{term [source] empty} *}
    97 
    98 lemma empty_upd_none [simp]: "empty(x := None) = empty"
    99 by (rule ext) simp
   100 
   101 
   102 subsection {* @{term [source] map_upd} *}
   103 
   104 lemma map_upd_triv: "t k = Some x ==> t(k|->x) = t"
   105 by (rule ext) simp
   106 
   107 lemma map_upd_nonempty [simp]: "t(k|->x) ~= empty"
   108 proof
   109   assume "t(k \<mapsto> x) = empty"
   110   then have "(t(k \<mapsto> x)) k = None" by simp
   111   then show False by simp
   112 qed
   113 
   114 lemma map_upd_eqD1:
   115   assumes "m(a\<mapsto>x) = n(a\<mapsto>y)"
   116   shows "x = y"
   117 proof -
   118   from prems have "(m(a\<mapsto>x)) a = (n(a\<mapsto>y)) a" by simp
   119   then show ?thesis by simp
   120 qed
   121 
   122 lemma map_upd_Some_unfold:
   123   "((m(a|->b)) x = Some y) = (x = a \<and> b = y \<or> x \<noteq> a \<and> m x = Some y)"
   124 by auto
   125 
   126 lemma image_map_upd [simp]: "x \<notin> A \<Longrightarrow> m(x \<mapsto> y) ` A = m ` A"
   127 by auto
   128 
   129 lemma finite_range_updI: "finite (range f) ==> finite (range (f(a|->b)))"
   130 unfolding image_def
   131 apply (simp (no_asm_use) add:full_SetCompr_eq)
   132 apply (rule finite_subset)
   133  prefer 2 apply assumption
   134 apply (auto)
   135 done
   136 
   137 
   138 subsection {* @{term [source] map_of} *}
   139 
   140 lemma map_of_eq_None_iff:
   141   "(map_of xys x = None) = (x \<notin> fst ` (set xys))"
   142 by (induct xys) simp_all
   143 
   144 lemma map_of_is_SomeD: "map_of xys x = Some y \<Longrightarrow> (x,y) \<in> set xys"
   145 apply (induct xys)
   146  apply simp
   147 apply (clarsimp split: if_splits)
   148 done
   149 
   150 lemma map_of_eq_Some_iff [simp]:
   151   "distinct(map fst xys) \<Longrightarrow> (map_of xys x = Some y) = ((x,y) \<in> set xys)"
   152 apply (induct xys)
   153  apply simp
   154 apply (auto simp: map_of_eq_None_iff [symmetric])
   155 done
   156 
   157 lemma Some_eq_map_of_iff [simp]:
   158   "distinct(map fst xys) \<Longrightarrow> (Some y = map_of xys x) = ((x,y) \<in> set xys)"
   159 by (auto simp del:map_of_eq_Some_iff simp add: map_of_eq_Some_iff [symmetric])
   160 
   161 lemma map_of_is_SomeI [simp]: "\<lbrakk> distinct(map fst xys); (x,y) \<in> set xys \<rbrakk>
   162     \<Longrightarrow> map_of xys x = Some y"
   163 apply (induct xys)
   164  apply simp
   165 apply force
   166 done
   167 
   168 lemma map_of_zip_is_None [simp]:
   169   "length xs = length ys \<Longrightarrow> (map_of (zip xs ys) x = None) = (x \<notin> set xs)"
   170 by (induct rule: list_induct2) simp_all
   171 
   172 lemma map_of_zip_is_Some:
   173   assumes "length xs = length ys"
   174   shows "x \<in> set xs \<longleftrightarrow> (\<exists>y. map_of (zip xs ys) x = Some y)"
   175 using assms by (induct rule: list_induct2) simp_all
   176 
   177 lemma map_of_zip_upd:
   178   fixes x :: 'a and xs :: "'a list" and ys zs :: "'b list"
   179   assumes "length ys = length xs"
   180     and "length zs = length xs"
   181     and "x \<notin> set xs"
   182     and "map_of (zip xs ys)(x \<mapsto> y) = map_of (zip xs zs)(x \<mapsto> z)"
   183   shows "map_of (zip xs ys) = map_of (zip xs zs)"
   184 proof
   185   fix x' :: 'a
   186   show "map_of (zip xs ys) x' = map_of (zip xs zs) x'"
   187   proof (cases "x = x'")
   188     case True
   189     from assms True map_of_zip_is_None [of xs ys x']
   190       have "map_of (zip xs ys) x' = None" by simp
   191     moreover from assms True map_of_zip_is_None [of xs zs x']
   192       have "map_of (zip xs zs) x' = None" by simp
   193     ultimately show ?thesis by simp
   194   next
   195     case False from assms
   196       have "(map_of (zip xs ys)(x \<mapsto> y)) x' = (map_of (zip xs zs)(x \<mapsto> z)) x'" by auto
   197     with False show ?thesis by simp
   198   qed
   199 qed
   200 
   201 lemma map_of_zip_inject:
   202   assumes "length ys = length xs"
   203     and "length zs = length xs"
   204     and dist: "distinct xs"
   205     and map_of: "map_of (zip xs ys) = map_of (zip xs zs)"
   206   shows "ys = zs"
   207 using assms(1) assms(2)[symmetric] using dist map_of proof (induct ys xs zs rule: list_induct3)
   208   case Nil show ?case by simp
   209 next
   210   case (Cons y ys x xs z zs)
   211   from `map_of (zip (x#xs) (y#ys)) = map_of (zip (x#xs) (z#zs))`
   212     have map_of: "map_of (zip xs ys)(x \<mapsto> y) = map_of (zip xs zs)(x \<mapsto> z)" by simp
   213   from Cons have "length ys = length xs" and "length zs = length xs"
   214     and "x \<notin> set xs" by simp_all
   215   then have "map_of (zip xs ys) = map_of (zip xs zs)" using map_of by (rule map_of_zip_upd)
   216   with Cons.hyps `distinct (x # xs)` have "ys = zs" by simp
   217   moreover from map_of have "y = z" by (rule map_upd_eqD1)
   218   ultimately show ?case by simp
   219 qed
   220 
   221 lemma finite_range_map_of: "finite (range (map_of xys))"
   222 apply (induct xys)
   223  apply (simp_all add: image_constant)
   224 apply (rule finite_subset)
   225  prefer 2 apply assumption
   226 apply auto
   227 done
   228 
   229 lemma map_of_SomeD: "map_of xs k = Some y \<Longrightarrow> (k, y) \<in> set xs"
   230 by (induct xs) (simp, atomize (full), auto)
   231 
   232 lemma map_of_mapk_SomeI:
   233   "inj f ==> map_of t k = Some x ==>
   234    map_of (map (split (%k. Pair (f k))) t) (f k) = Some x"
   235 by (induct t) (auto simp add: inj_eq)
   236 
   237 lemma weak_map_of_SomeI: "(k, x) : set l ==> \<exists>x. map_of l k = Some x"
   238 by (induct l) auto
   239 
   240 lemma map_of_filter_in:
   241   "map_of xs k = Some z \<Longrightarrow> P k z \<Longrightarrow> map_of (filter (split P) xs) k = Some z"
   242 by (induct xs) auto
   243 
   244 lemma map_of_map: "map_of (map (%(a,b). (a,f b)) xs) x = Option.map f (map_of xs x)"
   245 by (induct xs) auto
   246 
   247 
   248 subsection {* @{const Option.map} related *}
   249 
   250 lemma option_map_o_empty [simp]: "Option.map f o empty = empty"
   251 by (rule ext) simp
   252 
   253 lemma option_map_o_map_upd [simp]:
   254   "Option.map f o m(a|->b) = (Option.map f o m)(a|->f b)"
   255 by (rule ext) simp
   256 
   257 
   258 subsection {* @{term [source] map_comp} related *}
   259 
   260 lemma map_comp_empty [simp]:
   261   "m \<circ>\<^sub>m empty = empty"
   262   "empty \<circ>\<^sub>m m = empty"
   263 by (auto simp add: map_comp_def intro: ext split: option.splits)
   264 
   265 lemma map_comp_simps [simp]:
   266   "m2 k = None \<Longrightarrow> (m1 \<circ>\<^sub>m m2) k = None"
   267   "m2 k = Some k' \<Longrightarrow> (m1 \<circ>\<^sub>m m2) k = m1 k'"
   268 by (auto simp add: map_comp_def)
   269 
   270 lemma map_comp_Some_iff:
   271   "((m1 \<circ>\<^sub>m m2) k = Some v) = (\<exists>k'. m2 k = Some k' \<and> m1 k' = Some v)"
   272 by (auto simp add: map_comp_def split: option.splits)
   273 
   274 lemma map_comp_None_iff:
   275   "((m1 \<circ>\<^sub>m m2) k = None) = (m2 k = None \<or> (\<exists>k'. m2 k = Some k' \<and> m1 k' = None)) "
   276 by (auto simp add: map_comp_def split: option.splits)
   277 
   278 
   279 subsection {* @{text "++"} *}
   280 
   281 lemma map_add_empty[simp]: "m ++ empty = m"
   282 by(simp add: map_add_def)
   283 
   284 lemma empty_map_add[simp]: "empty ++ m = m"
   285 by (rule ext) (simp add: map_add_def split: option.split)
   286 
   287 lemma map_add_assoc[simp]: "m1 ++ (m2 ++ m3) = (m1 ++ m2) ++ m3"
   288 by (rule ext) (simp add: map_add_def split: option.split)
   289 
   290 lemma map_add_Some_iff:
   291   "((m ++ n) k = Some x) = (n k = Some x | n k = None & m k = Some x)"
   292 by (simp add: map_add_def split: option.split)
   293 
   294 lemma map_add_SomeD [dest!]:
   295   "(m ++ n) k = Some x \<Longrightarrow> n k = Some x \<or> n k = None \<and> m k = Some x"
   296 by (rule map_add_Some_iff [THEN iffD1])
   297 
   298 lemma map_add_find_right [simp]: "!!xx. n k = Some xx ==> (m ++ n) k = Some xx"
   299 by (subst map_add_Some_iff) fast
   300 
   301 lemma map_add_None [iff]: "((m ++ n) k = None) = (n k = None & m k = None)"
   302 by (simp add: map_add_def split: option.split)
   303 
   304 lemma map_add_upd[simp]: "f ++ g(x|->y) = (f ++ g)(x|->y)"
   305 by (rule ext) (simp add: map_add_def)
   306 
   307 lemma map_add_upds[simp]: "m1 ++ (m2(xs[\<mapsto>]ys)) = (m1++m2)(xs[\<mapsto>]ys)"
   308 by (simp add: map_upds_def)
   309 
   310 lemma map_add_upd_left: "m\<notin>dom e2 \<Longrightarrow> e1(m \<mapsto> u1) ++ e2 = (e1 ++ e2)(m \<mapsto> u1)"
   311 by (rule ext) (auto simp: map_add_def dom_def split: option.split)
   312 
   313 lemma map_of_append[simp]: "map_of (xs @ ys) = map_of ys ++ map_of xs"
   314 unfolding map_add_def
   315 apply (induct xs)
   316  apply simp
   317 apply (rule ext)
   318 apply (simp split add: option.split)
   319 done
   320 
   321 lemma finite_range_map_of_map_add:
   322   "finite (range f) ==> finite (range (f ++ map_of l))"
   323 apply (induct l)
   324  apply (auto simp del: fun_upd_apply)
   325 apply (erule finite_range_updI)
   326 done
   327 
   328 lemma inj_on_map_add_dom [iff]:
   329   "inj_on (m ++ m') (dom m') = inj_on m' (dom m')"
   330 by (fastsimp simp: map_add_def dom_def inj_on_def split: option.splits)
   331 
   332 
   333 subsection {* @{term [source] restrict_map} *}
   334 
   335 lemma restrict_map_to_empty [simp]: "m|`{} = empty"
   336 by (simp add: restrict_map_def)
   337 
   338 lemma restrict_map_insert: "f |` (insert a A) = (f |` A)(a := f a)"
   339 by (auto simp add: restrict_map_def intro: ext)
   340 
   341 lemma restrict_map_empty [simp]: "empty|`D = empty"
   342 by (simp add: restrict_map_def)
   343 
   344 lemma restrict_in [simp]: "x \<in> A \<Longrightarrow> (m|`A) x = m x"
   345 by (simp add: restrict_map_def)
   346 
   347 lemma restrict_out [simp]: "x \<notin> A \<Longrightarrow> (m|`A) x = None"
   348 by (simp add: restrict_map_def)
   349 
   350 lemma ran_restrictD: "y \<in> ran (m|`A) \<Longrightarrow> \<exists>x\<in>A. m x = Some y"
   351 by (auto simp: restrict_map_def ran_def split: split_if_asm)
   352 
   353 lemma dom_restrict [simp]: "dom (m|`A) = dom m \<inter> A"
   354 by (auto simp: restrict_map_def dom_def split: split_if_asm)
   355 
   356 lemma restrict_upd_same [simp]: "m(x\<mapsto>y)|`(-{x}) = m|`(-{x})"
   357 by (rule ext) (auto simp: restrict_map_def)
   358 
   359 lemma restrict_restrict [simp]: "m|`A|`B = m|`(A\<inter>B)"
   360 by (rule ext) (auto simp: restrict_map_def)
   361 
   362 lemma restrict_fun_upd [simp]:
   363   "m(x := y)|`D = (if x \<in> D then (m|`(D-{x}))(x := y) else m|`D)"
   364 by (simp add: restrict_map_def expand_fun_eq)
   365 
   366 lemma fun_upd_None_restrict [simp]:
   367   "(m|`D)(x := None) = (if x:D then m|`(D - {x}) else m|`D)"
   368 by (simp add: restrict_map_def expand_fun_eq)
   369 
   370 lemma fun_upd_restrict: "(m|`D)(x := y) = (m|`(D-{x}))(x := y)"
   371 by (simp add: restrict_map_def expand_fun_eq)
   372 
   373 lemma fun_upd_restrict_conv [simp]:
   374   "x \<in> D \<Longrightarrow> (m|`D)(x := y) = (m|`(D-{x}))(x := y)"
   375 by (simp add: restrict_map_def expand_fun_eq)
   376 
   377 
   378 subsection {* @{term [source] map_upds} *}
   379 
   380 lemma map_upds_Nil1 [simp]: "m([] [|->] bs) = m"
   381 by (simp add: map_upds_def)
   382 
   383 lemma map_upds_Nil2 [simp]: "m(as [|->] []) = m"
   384 by (simp add:map_upds_def)
   385 
   386 lemma map_upds_Cons [simp]: "m(a#as [|->] b#bs) = (m(a|->b))(as[|->]bs)"
   387 by (simp add:map_upds_def)
   388 
   389 lemma map_upds_append1 [simp]: "\<And>ys m. size xs < size ys \<Longrightarrow>
   390   m(xs@[x] [\<mapsto>] ys) = m(xs [\<mapsto>] ys)(x \<mapsto> ys!size xs)"
   391 apply(induct xs)
   392  apply (clarsimp simp add: neq_Nil_conv)
   393 apply (case_tac ys)
   394  apply simp
   395 apply simp
   396 done
   397 
   398 lemma map_upds_list_update2_drop [simp]:
   399   "\<lbrakk>size xs \<le> i; i < size ys\<rbrakk>
   400     \<Longrightarrow> m(xs[\<mapsto>]ys[i:=y]) = m(xs[\<mapsto>]ys)"
   401 apply (induct xs arbitrary: m ys i)
   402  apply simp
   403 apply (case_tac ys)
   404  apply simp
   405 apply (simp split: nat.split)
   406 done
   407 
   408 lemma map_upd_upds_conv_if:
   409   "(f(x|->y))(xs [|->] ys) =
   410    (if x : set(take (length ys) xs) then f(xs [|->] ys)
   411                                     else (f(xs [|->] ys))(x|->y))"
   412 apply (induct xs arbitrary: x y ys f)
   413  apply simp
   414 apply (case_tac ys)
   415  apply (auto split: split_if simp: fun_upd_twist)
   416 done
   417 
   418 lemma map_upds_twist [simp]:
   419   "a ~: set as ==> m(a|->b)(as[|->]bs) = m(as[|->]bs)(a|->b)"
   420 using set_take_subset by (fastsimp simp add: map_upd_upds_conv_if)
   421 
   422 lemma map_upds_apply_nontin [simp]:
   423   "x ~: set xs ==> (f(xs[|->]ys)) x = f x"
   424 apply (induct xs arbitrary: ys)
   425  apply simp
   426 apply (case_tac ys)
   427  apply (auto simp: map_upd_upds_conv_if)
   428 done
   429 
   430 lemma fun_upds_append_drop [simp]:
   431   "size xs = size ys \<Longrightarrow> m(xs@zs[\<mapsto>]ys) = m(xs[\<mapsto>]ys)"
   432 apply (induct xs arbitrary: m ys)
   433  apply simp
   434 apply (case_tac ys)
   435  apply simp_all
   436 done
   437 
   438 lemma fun_upds_append2_drop [simp]:
   439   "size xs = size ys \<Longrightarrow> m(xs[\<mapsto>]ys@zs) = m(xs[\<mapsto>]ys)"
   440 apply (induct xs arbitrary: m ys)
   441  apply simp
   442 apply (case_tac ys)
   443  apply simp_all
   444 done
   445 
   446 
   447 lemma restrict_map_upds[simp]:
   448   "\<lbrakk> length xs = length ys; set xs \<subseteq> D \<rbrakk>
   449     \<Longrightarrow> m(xs [\<mapsto>] ys)|`D = (m|`(D - set xs))(xs [\<mapsto>] ys)"
   450 apply (induct xs arbitrary: m ys)
   451  apply simp
   452 apply (case_tac ys)
   453  apply simp
   454 apply (simp add: Diff_insert [symmetric] insert_absorb)
   455 apply (simp add: map_upd_upds_conv_if)
   456 done
   457 
   458 
   459 subsection {* @{term [source] dom} *}
   460 
   461 lemma dom_eq_empty_conv [simp]: "dom f = {} \<longleftrightarrow> f = empty"
   462 by(auto intro!:ext simp: dom_def)
   463 
   464 lemma domI: "m a = Some b ==> a : dom m"
   465 by(simp add:dom_def)
   466 (* declare domI [intro]? *)
   467 
   468 lemma domD: "a : dom m ==> \<exists>b. m a = Some b"
   469 by (cases "m a") (auto simp add: dom_def)
   470 
   471 lemma domIff [iff, simp del]: "(a : dom m) = (m a ~= None)"
   472 by(simp add:dom_def)
   473 
   474 lemma dom_empty [simp]: "dom empty = {}"
   475 by(simp add:dom_def)
   476 
   477 lemma dom_fun_upd [simp]:
   478   "dom(f(x := y)) = (if y=None then dom f - {x} else insert x (dom f))"
   479 by(auto simp add:dom_def)
   480 
   481 lemma dom_map_of: "dom(map_of xys) = {x. \<exists>y. (x,y) : set xys}"
   482 by (induct xys) (auto simp del: fun_upd_apply)
   483 
   484 lemma dom_map_of_conv_image_fst:
   485   "dom(map_of xys) = fst ` (set xys)"
   486 by(force simp: dom_map_of)
   487 
   488 lemma dom_map_of_zip [simp]: "[| length xs = length ys; distinct xs |] ==>
   489   dom(map_of(zip xs ys)) = set xs"
   490 by (induct rule: list_induct2) simp_all
   491 
   492 lemma finite_dom_map_of: "finite (dom (map_of l))"
   493 by (induct l) (auto simp add: dom_def insert_Collect [symmetric])
   494 
   495 lemma dom_map_upds [simp]:
   496   "dom(m(xs[|->]ys)) = set(take (length ys) xs) Un dom m"
   497 apply (induct xs arbitrary: m ys)
   498  apply simp
   499 apply (case_tac ys)
   500  apply auto
   501 done
   502 
   503 lemma dom_map_add [simp]: "dom(m++n) = dom n Un dom m"
   504 by(auto simp:dom_def)
   505 
   506 lemma dom_override_on [simp]:
   507   "dom(override_on f g A) =
   508     (dom f  - {a. a : A - dom g}) Un {a. a : A Int dom g}"
   509 by(auto simp: dom_def override_on_def)
   510 
   511 lemma map_add_comm: "dom m1 \<inter> dom m2 = {} \<Longrightarrow> m1++m2 = m2++m1"
   512 by (rule ext) (force simp: map_add_def dom_def split: option.split)
   513 
   514 lemma map_add_dom_app_simps:
   515   "\<lbrakk> m\<in>dom l2 \<rbrakk> \<Longrightarrow> (l1++l2) m = l2 m"
   516   "\<lbrakk> m\<notin>dom l1 \<rbrakk> \<Longrightarrow> (l1++l2) m = l2 m"
   517   "\<lbrakk> m\<notin>dom l2 \<rbrakk> \<Longrightarrow> (l1++l2) m = l1 m"
   518 by (auto simp add: map_add_def split: option.split_asm)
   519 
   520 lemma dom_const [simp]:
   521   "dom (\<lambda>x. Some y) = UNIV"
   522   by auto
   523 
   524 lemma dom_if:
   525   "dom (\<lambda>x. if P x then f x else g x) = dom f \<inter> {x. P x} \<union> dom g \<inter> {x. \<not> P x}"
   526   by (auto split: if_splits)
   527 
   528 
   529 (* Due to John Matthews - could be rephrased with dom *)
   530 lemma finite_map_freshness:
   531   "finite (dom (f :: 'a \<rightharpoonup> 'b)) \<Longrightarrow> \<not> finite (UNIV :: 'a set) \<Longrightarrow>
   532    \<exists>x. f x = None"
   533 by(bestsimp dest:ex_new_if_finite)
   534 
   535 lemma dom_minus:
   536   "f x = None \<Longrightarrow> dom f - insert x A = dom f - A"
   537   unfolding dom_def by simp
   538 
   539 lemma insert_dom:
   540   "f x = Some y \<Longrightarrow> insert x (dom f) = dom f"
   541   unfolding dom_def by auto
   542 
   543 
   544 subsection {* @{term [source] ran} *}
   545 
   546 lemma ranI: "m a = Some b ==> b : ran m"
   547 by(auto simp: ran_def)
   548 (* declare ranI [intro]? *)
   549 
   550 lemma ran_empty [simp]: "ran empty = {}"
   551 by(auto simp: ran_def)
   552 
   553 lemma ran_map_upd [simp]: "m a = None ==> ran(m(a|->b)) = insert b (ran m)"
   554 unfolding ran_def
   555 apply auto
   556 apply (subgoal_tac "aa ~= a")
   557  apply auto
   558 done
   559 
   560 
   561 subsection {* @{text "map_le"} *}
   562 
   563 lemma map_le_empty [simp]: "empty \<subseteq>\<^sub>m g"
   564 by (simp add: map_le_def)
   565 
   566 lemma upd_None_map_le [simp]: "f(x := None) \<subseteq>\<^sub>m f"
   567 by (force simp add: map_le_def)
   568 
   569 lemma map_le_upd[simp]: "f \<subseteq>\<^sub>m g ==> f(a := b) \<subseteq>\<^sub>m g(a := b)"
   570 by (fastsimp simp add: map_le_def)
   571 
   572 lemma map_le_imp_upd_le [simp]: "m1 \<subseteq>\<^sub>m m2 \<Longrightarrow> m1(x := None) \<subseteq>\<^sub>m m2(x \<mapsto> y)"
   573 by (force simp add: map_le_def)
   574 
   575 lemma map_le_upds [simp]:
   576   "f \<subseteq>\<^sub>m g ==> f(as [|->] bs) \<subseteq>\<^sub>m g(as [|->] bs)"
   577 apply (induct as arbitrary: f g bs)
   578  apply simp
   579 apply (case_tac bs)
   580  apply auto
   581 done
   582 
   583 lemma map_le_implies_dom_le: "(f \<subseteq>\<^sub>m g) \<Longrightarrow> (dom f \<subseteq> dom g)"
   584 by (fastsimp simp add: map_le_def dom_def)
   585 
   586 lemma map_le_refl [simp]: "f \<subseteq>\<^sub>m f"
   587 by (simp add: map_le_def)
   588 
   589 lemma map_le_trans[trans]: "\<lbrakk> m1 \<subseteq>\<^sub>m m2; m2 \<subseteq>\<^sub>m m3\<rbrakk> \<Longrightarrow> m1 \<subseteq>\<^sub>m m3"
   590 by (auto simp add: map_le_def dom_def)
   591 
   592 lemma map_le_antisym: "\<lbrakk> f \<subseteq>\<^sub>m g; g \<subseteq>\<^sub>m f \<rbrakk> \<Longrightarrow> f = g"
   593 unfolding map_le_def
   594 apply (rule ext)
   595 apply (case_tac "x \<in> dom f", simp)
   596 apply (case_tac "x \<in> dom g", simp, fastsimp)
   597 done
   598 
   599 lemma map_le_map_add [simp]: "f \<subseteq>\<^sub>m (g ++ f)"
   600 by (fastsimp simp add: map_le_def)
   601 
   602 lemma map_le_iff_map_add_commute: "(f \<subseteq>\<^sub>m f ++ g) = (f++g = g++f)"
   603 by(fastsimp simp: map_add_def map_le_def expand_fun_eq split: option.splits)
   604 
   605 lemma map_add_le_mapE: "f++g \<subseteq>\<^sub>m h \<Longrightarrow> g \<subseteq>\<^sub>m h"
   606 by (fastsimp simp add: map_le_def map_add_def dom_def)
   607 
   608 lemma map_add_le_mapI: "\<lbrakk> f \<subseteq>\<^sub>m h; g \<subseteq>\<^sub>m h; f \<subseteq>\<^sub>m f++g \<rbrakk> \<Longrightarrow> f++g \<subseteq>\<^sub>m h"
   609 by (clarsimp simp add: map_le_def map_add_def dom_def split: option.splits)
   610 
   611 
   612 lemma dom_eq_singleton_conv: "dom f = {x} \<longleftrightarrow> (\<exists>v. f = [x \<mapsto> v])"
   613 proof(rule iffI)
   614   assume "\<exists>v. f = [x \<mapsto> v]"
   615   thus "dom f = {x}" by(auto split: split_if_asm)
   616 next
   617   assume "dom f = {x}"
   618   then obtain v where "f x = Some v" by auto
   619   hence "[x \<mapsto> v] \<subseteq>\<^sub>m f" by(auto simp add: map_le_def)
   620   moreover have "f \<subseteq>\<^sub>m [x \<mapsto> v]" using `dom f = {x}` `f x = Some v`
   621     by(auto simp add: map_le_def)
   622   ultimately have "f = [x \<mapsto> v]" by-(rule map_le_antisym)
   623   thus "\<exists>v. f = [x \<mapsto> v]" by blast
   624 qed
   625 
   626 end