src/HOL/Complete_Lattice.thy
author haftmann
Sat Jul 16 22:04:02 2011 +0200 (2011-07-16)
changeset 43853 020ddc6a9508
parent 43852 7411fbf0a325
child 43854 f1d23df1adde
permissions -rw-r--r--
consolidated bot and top classes, tuned notation
     1 (*  Author:     Tobias Nipkow, Lawrence C Paulson and Markus Wenzel; Florian Haftmann, TU Muenchen *)
     2 
     3 header {* Complete lattices, with special focus on sets *}
     4 
     5 theory Complete_Lattice
     6 imports Set
     7 begin
     8 
     9 notation
    10   less_eq (infix "\<sqsubseteq>" 50) and
    11   less (infix "\<sqsubset>" 50) and
    12   inf (infixl "\<sqinter>" 70) and
    13   sup (infixl "\<squnion>" 65) and
    14   top ("\<top>") and
    15   bot ("\<bottom>")
    16 
    17 
    18 subsection {* Syntactic infimum and supremum operations *}
    19 
    20 class Inf =
    21   fixes Inf :: "'a set \<Rightarrow> 'a" ("\<Sqinter>_" [900] 900)
    22 
    23 class Sup =
    24   fixes Sup :: "'a set \<Rightarrow> 'a" ("\<Squnion>_" [900] 900)
    25 
    26 subsection {* Abstract complete lattices *}
    27 
    28 class complete_lattice = bounded_lattice + Inf + Sup +
    29   assumes Inf_lower: "x \<in> A \<Longrightarrow> \<Sqinter>A \<sqsubseteq> x"
    30      and Inf_greatest: "(\<And>x. x \<in> A \<Longrightarrow> z \<sqsubseteq> x) \<Longrightarrow> z \<sqsubseteq> \<Sqinter>A"
    31   assumes Sup_upper: "x \<in> A \<Longrightarrow> x \<sqsubseteq> \<Squnion>A"
    32      and Sup_least: "(\<And>x. x \<in> A \<Longrightarrow> x \<sqsubseteq> z) \<Longrightarrow> \<Squnion>A \<sqsubseteq> z"
    33 begin
    34 
    35 lemma dual_complete_lattice:
    36   "class.complete_lattice Sup Inf (op \<ge>) (op >) (op \<squnion>) (op \<sqinter>) \<top> \<bottom>"
    37   by (auto intro!: class.complete_lattice.intro dual_bounded_lattice)
    38     (unfold_locales, (fact bot_least top_greatest
    39         Sup_upper Sup_least Inf_lower Inf_greatest)+)
    40 
    41 lemma Inf_Sup: "\<Sqinter>A = \<Squnion>{b. \<forall>a \<in> A. b \<sqsubseteq> a}"
    42   by (auto intro: antisym Inf_lower Inf_greatest Sup_upper Sup_least)
    43 
    44 lemma Sup_Inf:  "\<Squnion>A = \<Sqinter>{b. \<forall>a \<in> A. a \<sqsubseteq> b}"
    45   by (auto intro: antisym Inf_lower Inf_greatest Sup_upper Sup_least)
    46 
    47 lemma Inf_empty [simp]:
    48   "\<Sqinter>{} = \<top>"
    49   by (auto intro: antisym Inf_greatest)
    50 
    51 lemma Sup_empty [simp]:
    52   "\<Squnion>{} = \<bottom>"
    53   by (auto intro: antisym Sup_least)
    54 
    55 lemma Inf_UNIV [simp]:
    56   "\<Sqinter>UNIV = \<bottom>"
    57   by (simp add: Sup_Inf Sup_empty [symmetric])
    58 
    59 lemma Sup_UNIV [simp]:
    60   "\<Squnion>UNIV = \<top>"
    61   by (simp add: Inf_Sup Inf_empty [symmetric])
    62 
    63 lemma Inf_insert: "\<Sqinter>insert a A = a \<sqinter> \<Sqinter>A"
    64   by (auto intro: le_infI le_infI1 le_infI2 antisym Inf_greatest Inf_lower)
    65 
    66 lemma Sup_insert: "\<Squnion>insert a A = a \<squnion> \<Squnion>A"
    67   by (auto intro: le_supI le_supI1 le_supI2 antisym Sup_least Sup_upper)
    68 
    69 lemma Inf_singleton [simp]:
    70   "\<Sqinter>{a} = a"
    71   by (auto intro: antisym Inf_lower Inf_greatest)
    72 
    73 lemma Sup_singleton [simp]:
    74   "\<Squnion>{a} = a"
    75   by (auto intro: antisym Sup_upper Sup_least)
    76 
    77 lemma Inf_binary:
    78   "\<Sqinter>{a, b} = a \<sqinter> b"
    79   by (simp add: Inf_insert)
    80 
    81 lemma Sup_binary:
    82   "\<Squnion>{a, b} = a \<squnion> b"
    83   by (simp add: Sup_insert)
    84 
    85 lemma le_Inf_iff: "b \<sqsubseteq> \<Sqinter>A \<longleftrightarrow> (\<forall>a\<in>A. b \<sqsubseteq> a)"
    86   by (auto intro: Inf_greatest dest: Inf_lower)
    87 
    88 lemma Sup_le_iff: "\<Squnion>A \<sqsubseteq> b \<longleftrightarrow> (\<forall>a\<in>A. a \<sqsubseteq> b)"
    89   by (auto intro: Sup_least dest: Sup_upper)
    90 
    91 lemma Inf_mono:
    92   assumes "\<And>b. b \<in> B \<Longrightarrow> \<exists>a\<in>A. a \<sqsubseteq> b"
    93   shows "\<Sqinter>A \<sqsubseteq> \<Sqinter>B"
    94 proof (rule Inf_greatest)
    95   fix b assume "b \<in> B"
    96   with assms obtain a where "a \<in> A" and "a \<sqsubseteq> b" by blast
    97   from `a \<in> A` have "\<Sqinter>A \<sqsubseteq> a" by (rule Inf_lower)
    98   with `a \<sqsubseteq> b` show "\<Sqinter>A \<sqsubseteq> b" by auto
    99 qed
   100 
   101 lemma Sup_mono:
   102   assumes "\<And>a. a \<in> A \<Longrightarrow> \<exists>b\<in>B. a \<sqsubseteq> b"
   103   shows "\<Squnion>A \<sqsubseteq> \<Squnion>B"
   104 proof (rule Sup_least)
   105   fix a assume "a \<in> A"
   106   with assms obtain b where "b \<in> B" and "a \<sqsubseteq> b" by blast
   107   from `b \<in> B` have "b \<sqsubseteq> \<Squnion>B" by (rule Sup_upper)
   108   with `a \<sqsubseteq> b` show "a \<sqsubseteq> \<Squnion>B" by auto
   109 qed
   110 
   111 lemma Sup_upper2: "u \<in> A \<Longrightarrow> v \<sqsubseteq> u \<Longrightarrow> v \<sqsubseteq> \<Squnion>A"
   112   using Sup_upper[of u A] by auto
   113 
   114 lemma Inf_lower2: "u \<in> A \<Longrightarrow> u \<sqsubseteq> v \<Longrightarrow> \<Sqinter>A \<sqsubseteq> v"
   115   using Inf_lower[of u A] by auto
   116 
   117 definition INFI :: "'b set \<Rightarrow> ('b \<Rightarrow> 'a) \<Rightarrow> 'a" where
   118   "INFI A f = \<Sqinter> (f ` A)"
   119 
   120 definition SUPR :: "'b set \<Rightarrow> ('b \<Rightarrow> 'a) \<Rightarrow> 'a" where
   121   "SUPR A f = \<Squnion> (f ` A)"
   122 
   123 end
   124 
   125 syntax
   126   "_INF1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3INF _./ _)" [0, 10] 10)
   127   "_INF"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3INF _:_./ _)" [0, 0, 10] 10)
   128   "_SUP1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3SUP _./ _)" [0, 10] 10)
   129   "_SUP"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3SUP _:_./ _)" [0, 0, 10] 10)
   130 
   131 syntax (xsymbols)
   132   "_INF1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3\<Sqinter>_./ _)" [0, 10] 10)
   133   "_INF"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3\<Sqinter>_\<in>_./ _)" [0, 0, 10] 10)
   134   "_SUP1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3\<Squnion>_./ _)" [0, 10] 10)
   135   "_SUP"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3\<Squnion>_\<in>_./ _)" [0, 0, 10] 10)
   136 
   137 translations
   138   "INF x y. B"   == "INF x. INF y. B"
   139   "INF x. B"     == "CONST INFI CONST UNIV (%x. B)"
   140   "INF x. B"     == "INF x:CONST UNIV. B"
   141   "INF x:A. B"   == "CONST INFI A (%x. B)"
   142   "SUP x y. B"   == "SUP x. SUP y. B"
   143   "SUP x. B"     == "CONST SUPR CONST UNIV (%x. B)"
   144   "SUP x. B"     == "SUP x:CONST UNIV. B"
   145   "SUP x:A. B"   == "CONST SUPR A (%x. B)"
   146 
   147 print_translation {*
   148   [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax INFI} @{syntax_const "_INF"},
   149     Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax SUPR} @{syntax_const "_SUP"}]
   150 *} -- {* to avoid eta-contraction of body *}
   151 
   152 context complete_lattice
   153 begin
   154 
   155 lemma SUP_cong: "(\<And>x. x \<in> A \<Longrightarrow> f x = g x) \<Longrightarrow> SUPR A f = SUPR A g"
   156   by (simp add: SUPR_def cong: image_cong)
   157 
   158 lemma INF_cong: "(\<And>x. x \<in> A \<Longrightarrow> f x = g x) \<Longrightarrow> INFI A f = INFI A g"
   159   by (simp add: INFI_def cong: image_cong)
   160 
   161 lemma le_SUPI: "i \<in> A \<Longrightarrow> M i \<sqsubseteq> (\<Squnion>i\<in>A. M i)"
   162   by (auto simp add: SUPR_def intro: Sup_upper)
   163 
   164 lemma le_SUPI2: "i \<in> A \<Longrightarrow> u \<sqsubseteq> M i \<Longrightarrow> u \<sqsubseteq> (\<Squnion>i\<in>A. M i)"
   165   using le_SUPI[of i A M] by auto
   166 
   167 lemma SUP_leI: "(\<And>i. i \<in> A \<Longrightarrow> M i \<sqsubseteq> u) \<Longrightarrow> (\<Squnion>i\<in>A. M i) \<sqsubseteq> u"
   168   by (auto simp add: SUPR_def intro: Sup_least)
   169 
   170 lemma INF_leI: "i \<in> A \<Longrightarrow> (\<Sqinter>i\<in>A. M i) \<sqsubseteq> M i"
   171   by (auto simp add: INFI_def intro: Inf_lower)
   172 
   173 lemma INF_leI2: "i \<in> A \<Longrightarrow> M i \<sqsubseteq> u \<Longrightarrow> (\<Sqinter>i\<in>A. M i) \<sqsubseteq> u"
   174   using INF_leI[of i A M] by auto
   175 
   176 lemma le_INFI: "(\<And>i. i \<in> A \<Longrightarrow> u \<sqsubseteq> M i) \<Longrightarrow> u \<sqsubseteq> (\<Sqinter>i\<in>A. M i)"
   177   by (auto simp add: INFI_def intro: Inf_greatest)
   178 
   179 lemma SUP_le_iff: "(\<Squnion>i\<in>A. M i) \<sqsubseteq> u \<longleftrightarrow> (\<forall>i \<in> A. M i \<sqsubseteq> u)"
   180   unfolding SUPR_def by (auto simp add: Sup_le_iff)
   181 
   182 lemma le_INF_iff: "u \<sqsubseteq> (\<Sqinter>i\<in>A. M i) \<longleftrightarrow> (\<forall>i \<in> A. u \<sqsubseteq> M i)"
   183   unfolding INFI_def by (auto simp add: le_Inf_iff)
   184 
   185 lemma INF_const[simp]: "A \<noteq> {} \<Longrightarrow> (\<Sqinter>i\<in>A. M) = M"
   186   by (auto intro: antisym INF_leI le_INFI)
   187 
   188 lemma SUP_const[simp]: "A \<noteq> {} \<Longrightarrow> (\<Squnion>i\<in>A. M) = M"
   189   by (auto intro: antisym SUP_leI le_SUPI)
   190 
   191 lemma INF_mono:
   192   "(\<And>m. m \<in> B \<Longrightarrow> \<exists>n\<in>A. f n \<sqsubseteq> g m) \<Longrightarrow> (\<Sqinter>n\<in>A. f n) \<sqsubseteq> (\<Sqinter>n\<in>B. g n)"
   193   by (force intro!: Inf_mono simp: INFI_def)
   194 
   195 lemma SUP_mono:
   196   "(\<And>n. n \<in> A \<Longrightarrow> \<exists>m\<in>B. f n \<sqsubseteq> g m) \<Longrightarrow> (\<Squnion>n\<in>A. f n) \<sqsubseteq> (\<Squnion>n\<in>B. g n)"
   197   by (force intro!: Sup_mono simp: SUPR_def)
   198 
   199 lemma INF_subset:  "A \<subseteq> B \<Longrightarrow> INFI B f \<sqsubseteq> INFI A f"
   200   by (intro INF_mono) auto
   201 
   202 lemma SUP_subset:  "A \<subseteq> B \<Longrightarrow> SUPR A f \<sqsubseteq> SUPR B f"
   203   by (intro SUP_mono) auto
   204 
   205 lemma INF_commute: "(\<Sqinter>i\<in>A. \<Sqinter>j\<in>B. f i j) = (\<Sqinter>j\<in>B. \<Sqinter>i\<in>A. f i j)"
   206   by (iprover intro: INF_leI le_INFI order_trans antisym)
   207 
   208 lemma SUP_commute: "(\<Squnion>i\<in>A. \<Squnion>j\<in>B. f i j) = (\<Squnion>j\<in>B. \<Squnion>i\<in>A. f i j)"
   209   by (iprover intro: SUP_leI le_SUPI order_trans antisym)
   210 
   211 end
   212 
   213 lemma Inf_less_iff:
   214   fixes a :: "'a\<Colon>{complete_lattice,linorder}"
   215   shows "\<Sqinter>S \<sqsubset> a \<longleftrightarrow> (\<exists>x\<in>S. x \<sqsubset> a)"
   216   unfolding not_le [symmetric] le_Inf_iff by auto
   217 
   218 lemma less_Sup_iff:
   219   fixes a :: "'a\<Colon>{complete_lattice,linorder}"
   220   shows "a \<sqsubset> \<Squnion>S \<longleftrightarrow> (\<exists>x\<in>S. a \<sqsubset> x)"
   221   unfolding not_le [symmetric] Sup_le_iff by auto
   222 
   223 lemma INF_less_iff:
   224   fixes a :: "'a::{complete_lattice,linorder}"
   225   shows "(\<Sqinter>i\<in>A. f i) \<sqsubset> a \<longleftrightarrow> (\<exists>x\<in>A. f x \<sqsubset> a)"
   226   unfolding INFI_def Inf_less_iff by auto
   227 
   228 lemma less_SUP_iff:
   229   fixes a :: "'a::{complete_lattice,linorder}"
   230   shows "a \<sqsubset> (\<Squnion>i\<in>A. f i) \<longleftrightarrow> (\<exists>x\<in>A. a \<sqsubset> f x)"
   231   unfolding SUPR_def less_Sup_iff by auto
   232 
   233 subsection {* @{typ bool} and @{typ "_ \<Rightarrow> _"} as complete lattice *}
   234 
   235 instantiation bool :: complete_lattice
   236 begin
   237 
   238 definition
   239   "\<Sqinter>A \<longleftrightarrow> (\<forall>x\<in>A. x)"
   240 
   241 definition
   242   "\<Squnion>A \<longleftrightarrow> (\<exists>x\<in>A. x)"
   243 
   244 instance proof
   245 qed (auto simp add: Inf_bool_def Sup_bool_def)
   246 
   247 end
   248 
   249 lemma INFI_bool_eq [simp]:
   250   "INFI = Ball"
   251 proof (rule ext)+
   252   fix A :: "'a set"
   253   fix P :: "'a \<Rightarrow> bool"
   254   show "(\<Sqinter>x\<in>A. P x) \<longleftrightarrow> (\<forall>x\<in>A. P x)"
   255     by (auto simp add: Ball_def INFI_def Inf_bool_def)
   256 qed
   257 
   258 lemma SUPR_bool_eq [simp]:
   259   "SUPR = Bex"
   260 proof (rule ext)+
   261   fix A :: "'a set"
   262   fix P :: "'a \<Rightarrow> bool"
   263   show "(\<Squnion>x\<in>A. P x) \<longleftrightarrow> (\<exists>x\<in>A. P x)"
   264     by (auto simp add: Bex_def SUPR_def Sup_bool_def)
   265 qed
   266 
   267 instantiation "fun" :: (type, complete_lattice) complete_lattice
   268 begin
   269 
   270 definition
   271   "\<Sqinter>A = (\<lambda>x. \<Sqinter>{y. \<exists>f\<in>A. y = f x})"
   272 
   273 lemma Inf_apply:
   274   "(\<Sqinter>A) x = \<Sqinter>{y. \<exists>f\<in>A. y = f x}"
   275   by (simp add: Inf_fun_def)
   276 
   277 definition
   278   "\<Squnion>A = (\<lambda>x. \<Squnion>{y. \<exists>f\<in>A. y = f x})"
   279 
   280 lemma Sup_apply:
   281   "(\<Squnion>A) x = \<Squnion>{y. \<exists>f\<in>A. y = f x}"
   282   by (simp add: Sup_fun_def)
   283 
   284 instance proof
   285 qed (auto simp add: le_fun_def Inf_apply Sup_apply
   286   intro: Inf_lower Sup_upper Inf_greatest Sup_least)
   287 
   288 end
   289 
   290 lemma INFI_apply:
   291   "(\<Sqinter>y\<in>A. f y) x = (\<Sqinter>y\<in>A. f y x)"
   292   by (auto intro: arg_cong [of _ _ Inf] simp add: INFI_def Inf_apply)
   293 
   294 lemma SUPR_apply:
   295   "(\<Squnion>y\<in>A. f y) x = (\<Squnion>y\<in>A. f y x)"
   296   by (auto intro: arg_cong [of _ _ Sup] simp add: SUPR_def Sup_apply)
   297 
   298 
   299 subsection {* Inter *}
   300 
   301 abbreviation Inter :: "'a set set \<Rightarrow> 'a set" where
   302   "Inter S \<equiv> \<Sqinter>S"
   303   
   304 notation (xsymbols)
   305   Inter  ("\<Inter>_" [90] 90)
   306 
   307 lemma Inter_eq:
   308   "\<Inter>A = {x. \<forall>B \<in> A. x \<in> B}"
   309 proof (rule set_eqI)
   310   fix x
   311   have "(\<forall>Q\<in>{P. \<exists>B\<in>A. P \<longleftrightarrow> x \<in> B}. Q) \<longleftrightarrow> (\<forall>B\<in>A. x \<in> B)"
   312     by auto
   313   then show "x \<in> \<Inter>A \<longleftrightarrow> x \<in> {x. \<forall>B \<in> A. x \<in> B}"
   314     by (simp add: Inf_fun_def Inf_bool_def) (simp add: mem_def)
   315 qed
   316 
   317 lemma Inter_iff [simp,no_atp]: "A \<in> \<Inter>C \<longleftrightarrow> (\<forall>X\<in>C. A \<in> X)"
   318   by (unfold Inter_eq) blast
   319 
   320 lemma InterI [intro!]: "(\<And>X. X \<in> C \<Longrightarrow> A \<in> X) \<Longrightarrow> A \<in> \<Inter>C"
   321   by (simp add: Inter_eq)
   322 
   323 text {*
   324   \medskip A ``destruct'' rule -- every @{term X} in @{term C}
   325   contains @{term A} as an element, but @{prop "A \<in> X"} can hold when
   326   @{prop "X \<in> C"} does not!  This rule is analogous to @{text spec}.
   327 *}
   328 
   329 lemma InterD [elim, Pure.elim]: "A \<in> \<Inter>C \<Longrightarrow> X \<in> C \<Longrightarrow> A \<in> X"
   330   by auto
   331 
   332 lemma InterE [elim]: "A \<in> \<Inter>C \<Longrightarrow> (X \<notin> C \<Longrightarrow> R) \<Longrightarrow> (A \<in> X \<Longrightarrow> R) \<Longrightarrow> R"
   333   -- {* ``Classical'' elimination rule -- does not require proving
   334     @{prop "X \<in> C"}. *}
   335   by (unfold Inter_eq) blast
   336 
   337 lemma Inter_lower: "B \<in> A \<Longrightarrow> \<Inter>A \<subseteq> B"
   338   by (fact Inf_lower)
   339 
   340 lemma (in complete_lattice) Inf_less_eq:
   341   assumes "\<And>v. v \<in> A \<Longrightarrow> v \<sqsubseteq> u"
   342     and "A \<noteq> {}"
   343   shows "\<Sqinter>A \<sqsubseteq> u"
   344 proof -
   345   from `A \<noteq> {}` obtain v where "v \<in> A" by blast
   346   moreover with assms have "v \<sqsubseteq> u" by blast
   347   ultimately show ?thesis by (rule Inf_lower2)
   348 qed
   349 
   350 lemma Inter_subset:
   351   "(\<And>X. X \<in> A \<Longrightarrow> X \<subseteq> B) \<Longrightarrow> A \<noteq> {} \<Longrightarrow> \<Inter>A \<subseteq> B"
   352   by (fact Inf_less_eq)
   353 
   354 lemma Inter_greatest: "(\<And>X. X \<in> A \<Longrightarrow> C \<subseteq> X) \<Longrightarrow> C \<subseteq> Inter A"
   355   by (fact Inf_greatest)
   356 
   357 lemma Int_eq_Inter: "A \<inter> B = \<Inter>{A, B}"
   358   by (fact Inf_binary [symmetric])
   359 
   360 lemma Inter_empty [simp]: "\<Inter>{} = UNIV"
   361   by (fact Inf_empty)
   362 
   363 lemma Inter_UNIV [simp]: "\<Inter>UNIV = {}"
   364   by (fact Inf_UNIV)
   365 
   366 lemma Inter_insert [simp]: "\<Inter>(insert a B) = a \<inter> \<Inter>B"
   367   by (fact Inf_insert)
   368 
   369 lemma (in complete_lattice) Inf_inter_less: "\<Sqinter>A \<squnion> \<Sqinter>B \<sqsubseteq> \<Sqinter>(A \<inter> B)"
   370   by (auto intro: Inf_greatest Inf_lower)
   371 
   372 lemma Inter_Un_subset: "\<Inter>A \<union> \<Inter>B \<subseteq> \<Inter>(A \<inter> B)"
   373   by (fact Inf_inter_less)
   374 
   375 lemma (in complete_lattice) Inf_union_distrib: "\<Sqinter>(A \<union> B) = \<Sqinter>A \<sqinter> \<Sqinter>B"
   376   by (rule antisym) (auto intro: Inf_greatest Inf_lower le_infI1 le_infI2)
   377 
   378 lemma Inter_Un_distrib: "\<Inter>(A \<union> B) = \<Inter>A \<inter> \<Inter>B"
   379   by (fact Inf_union_distrib)
   380 
   381 lemma (in complete_lattice) Inf_top_conv [no_atp]:
   382   "\<Sqinter>A = \<top> \<longleftrightarrow> (\<forall>x\<in>A. x = \<top>)"
   383   "\<top> = \<Sqinter>A \<longleftrightarrow> (\<forall>x\<in>A. x = \<top>)"
   384 proof -
   385   show "\<Sqinter>A = \<top> \<longleftrightarrow> (\<forall>x\<in>A. x = \<top>)"
   386   proof
   387     assume "\<forall>x\<in>A. x = \<top>"
   388     then have "A = {} \<or> A = {\<top>}" by auto
   389     then show "\<Sqinter>A = \<top>" by auto
   390   next
   391     assume "\<Sqinter>A = \<top>"
   392     show "\<forall>x\<in>A. x = \<top>"
   393     proof (rule ccontr)
   394       assume "\<not> (\<forall>x\<in>A. x = \<top>)"
   395       then obtain x where "x \<in> A" and "x \<noteq> \<top>" by blast
   396       then obtain B where "A = insert x B" by blast
   397       with `\<Sqinter>A = \<top>` `x \<noteq> \<top>` show False by (simp add: Inf_insert)
   398     qed
   399   qed
   400   then show "\<top> = \<Sqinter>A \<longleftrightarrow> (\<forall>x\<in>A. x = \<top>)" by auto
   401 qed
   402 
   403 lemma Inter_UNIV_conv [simp,no_atp]:
   404   "\<Inter>A = UNIV \<longleftrightarrow> (\<forall>x\<in>A. x = UNIV)"
   405   "UNIV = \<Inter>A \<longleftrightarrow> (\<forall>x\<in>A. x = UNIV)"
   406   by (fact Inf_top_conv)+
   407 
   408 lemma (in complete_lattice) Inf_anti_mono: "B \<subseteq> A \<Longrightarrow> \<Sqinter>A \<sqsubseteq> \<Sqinter>B"
   409   by (auto intro: Inf_greatest Inf_lower)
   410 
   411 lemma Inter_anti_mono: "B \<subseteq> A \<Longrightarrow> \<Inter>A \<subseteq> \<Inter>B"
   412   by (fact Inf_anti_mono)
   413 
   414 
   415 subsection {* Intersections of families *}
   416 
   417 abbreviation INTER :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> 'b set" where
   418   "INTER \<equiv> INFI"
   419 
   420 syntax
   421   "_INTER1"     :: "pttrns => 'b set => 'b set"           ("(3INT _./ _)" [0, 10] 10)
   422   "_INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3INT _:_./ _)" [0, 0, 10] 10)
   423 
   424 syntax (xsymbols)
   425   "_INTER1"     :: "pttrns => 'b set => 'b set"           ("(3\<Inter>_./ _)" [0, 10] 10)
   426   "_INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Inter>_\<in>_./ _)" [0, 0, 10] 10)
   427 
   428 syntax (latex output)
   429   "_INTER1"     :: "pttrns => 'b set => 'b set"           ("(3\<Inter>(00\<^bsub>_\<^esub>)/ _)" [0, 10] 10)
   430   "_INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Inter>(00\<^bsub>_\<in>_\<^esub>)/ _)" [0, 0, 10] 10)
   431 
   432 translations
   433   "INT x y. B"  == "INT x. INT y. B"
   434   "INT x. B"    == "CONST INTER CONST UNIV (%x. B)"
   435   "INT x. B"    == "INT x:CONST UNIV. B"
   436   "INT x:A. B"  == "CONST INTER A (%x. B)"
   437 
   438 print_translation {*
   439   [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax INTER} @{syntax_const "_INTER"}]
   440 *} -- {* to avoid eta-contraction of body *}
   441 
   442 lemma INTER_eq_Inter_image:
   443   "(\<Inter>x\<in>A. B x) = \<Inter>(B`A)"
   444   by (fact INFI_def)
   445   
   446 lemma Inter_def:
   447   "\<Inter>S = (\<Inter>x\<in>S. x)"
   448   by (simp add: INTER_eq_Inter_image image_def)
   449 
   450 lemma INTER_def:
   451   "(\<Inter>x\<in>A. B x) = {y. \<forall>x\<in>A. y \<in> B x}"
   452   by (auto simp add: INTER_eq_Inter_image Inter_eq)
   453 
   454 lemma Inter_image_eq [simp]:
   455   "\<Inter>(B`A) = (\<Inter>x\<in>A. B x)"
   456   by (rule sym) (fact INFI_def)
   457 
   458 lemma INT_iff [simp]: "b \<in> (\<Inter>x\<in>A. B x) \<longleftrightarrow> (\<forall>x\<in>A. b \<in> B x)"
   459   by (unfold INTER_def) blast
   460 
   461 lemma INT_I [intro!]: "(\<And>x. x \<in> A \<Longrightarrow> b \<in> B x) \<Longrightarrow> b \<in> (\<Inter>x\<in>A. B x)"
   462   by (unfold INTER_def) blast
   463 
   464 lemma INT_D [elim, Pure.elim]: "b \<in> (\<Inter>x\<in>A. B x) \<Longrightarrow> a \<in> A \<Longrightarrow> b \<in> B a"
   465   by auto
   466 
   467 lemma INT_E [elim]: "b \<in> (\<Inter>x\<in>A. B x) \<Longrightarrow> (b \<in> B a \<Longrightarrow> R) \<Longrightarrow> (a \<notin> A \<Longrightarrow> R) \<Longrightarrow> R"
   468   -- {* "Classical" elimination -- by the Excluded Middle on @{prop "a\<in>A"}. *}
   469   by (unfold INTER_def) blast
   470 
   471 lemma INT_cong [cong]:
   472     "A = B \<Longrightarrow> (\<And>x. x \<in> B \<Longrightarrow> C x = D x) \<Longrightarrow> (\<Inter>x\<in>A. C x) = (\<Inter>x\<in>B. D x)"
   473   by (simp add: INTER_def)
   474 
   475 lemma Collect_ball_eq: "{x. \<forall>y\<in>A. P x y} = (\<Inter>y\<in>A. {x. P x y})"
   476   by blast
   477 
   478 lemma Collect_all_eq: "{x. \<forall>y. P x y} = (\<Inter>y. {x. P x y})"
   479   by blast
   480 
   481 lemma INT_lower: "a \<in> A \<Longrightarrow> (\<Inter>x\<in>A. B x) \<subseteq> B a"
   482   by (fact INF_leI)
   483 
   484 lemma INT_greatest: "(\<And>x. x \<in> A \<Longrightarrow> C \<subseteq> B x) \<Longrightarrow> C \<subseteq> (\<Inter>x\<in>A. B x)"
   485   by (fact le_INFI)
   486 
   487 lemma INT_empty [simp]: "(\<Inter>x\<in>{}. B x) = UNIV"
   488   by blast
   489 
   490 lemma INT_absorb: "k \<in> I \<Longrightarrow> A k \<inter> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. A i)"
   491   by blast
   492 
   493 lemma INT_subset_iff: "(B \<subseteq> (\<Inter>i\<in>I. A i)) = (\<forall>i\<in>I. B \<subseteq> A i)"
   494   by (fact le_INF_iff)
   495 
   496 lemma INT_insert [simp]: "(\<Inter>x \<in> insert a A. B x) = B a \<inter> INTER A B"
   497   by blast
   498 
   499 lemma INT_Un: "(\<Inter>i \<in> A \<union> B. M i) = (\<Inter>i \<in> A. M i) \<inter> (\<Inter>i\<in>B. M i)"
   500   by blast
   501 
   502 lemma INT_insert_distrib:
   503     "u \<in> A \<Longrightarrow> (\<Inter>x\<in>A. insert a (B x)) = insert a (\<Inter>x\<in>A. B x)"
   504   by blast
   505 
   506 lemma INT_constant [simp]: "(\<Inter>y\<in>A. c) = (if A = {} then UNIV else c)"
   507   by auto
   508 
   509 lemma INT_eq: "(\<Inter>x\<in>A. B x) = \<Inter>({Y. \<exists>x\<in>A. Y = B x})"
   510   -- {* Look: it has an \emph{existential} quantifier *}
   511   by blast
   512 
   513 lemma INTER_UNIV_conv[simp]:
   514  "(UNIV = (\<Inter>x\<in>A. B x)) = (\<forall>x\<in>A. B x = UNIV)"
   515  "((\<Inter>x\<in>A. B x) = UNIV) = (\<forall>x\<in>A. B x = UNIV)"
   516 by blast+
   517 
   518 lemma INT_bool_eq: "(\<Inter>b. A b) = (A True \<inter> A False)"
   519   by (auto intro: bool_induct)
   520 
   521 lemma Pow_INT_eq: "Pow (\<Inter>x\<in>A. B x) = (\<Inter>x\<in>A. Pow (B x))"
   522   by blast
   523 
   524 lemma INT_anti_mono:
   525   "B \<subseteq> A \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> f x \<subseteq> g x) \<Longrightarrow>
   526     (\<Inter>x\<in>A. f x) \<subseteq> (\<Inter>x\<in>A. g x)"
   527   -- {* The last inclusion is POSITIVE! *}
   528   by (blast dest: subsetD)
   529 
   530 lemma vimage_INT: "f -` (\<Inter>x\<in>A. B x) = (\<Inter>x\<in>A. f -` B x)"
   531   by blast
   532 
   533 
   534 subsection {* Union *}
   535 
   536 abbreviation Union :: "'a set set \<Rightarrow> 'a set" where
   537   "Union S \<equiv> \<Squnion>S"
   538 
   539 notation (xsymbols)
   540   Union  ("\<Union>_" [90] 90)
   541 
   542 lemma Union_eq:
   543   "\<Union>A = {x. \<exists>B \<in> A. x \<in> B}"
   544 proof (rule set_eqI)
   545   fix x
   546   have "(\<exists>Q\<in>{P. \<exists>B\<in>A. P \<longleftrightarrow> x \<in> B}. Q) \<longleftrightarrow> (\<exists>B\<in>A. x \<in> B)"
   547     by auto
   548   then show "x \<in> \<Union>A \<longleftrightarrow> x \<in> {x. \<exists>B\<in>A. x \<in> B}"
   549     by (simp add: Sup_fun_def Sup_bool_def) (simp add: mem_def)
   550 qed
   551 
   552 lemma Union_iff [simp, no_atp]:
   553   "A \<in> \<Union>C \<longleftrightarrow> (\<exists>X\<in>C. A\<in>X)"
   554   by (unfold Union_eq) blast
   555 
   556 lemma UnionI [intro]:
   557   "X \<in> C \<Longrightarrow> A \<in> X \<Longrightarrow> A \<in> \<Union>C"
   558   -- {* The order of the premises presupposes that @{term C} is rigid;
   559     @{term A} may be flexible. *}
   560   by auto
   561 
   562 lemma UnionE [elim!]:
   563   "A \<in> \<Union>C \<Longrightarrow> (\<And>X. A \<in> X \<Longrightarrow> X \<in> C \<Longrightarrow> R) \<Longrightarrow> R"
   564   by auto
   565 
   566 lemma Union_upper: "B \<in> A \<Longrightarrow> B \<subseteq> \<Union>A"
   567   by (iprover intro: subsetI UnionI)
   568 
   569 lemma Union_least: "(\<And>X. X \<in> A \<Longrightarrow> X \<subseteq> C) \<Longrightarrow> \<Union>A \<subseteq> C"
   570   by (iprover intro: subsetI elim: UnionE dest: subsetD)
   571 
   572 lemma Un_eq_Union: "A \<union> B = \<Union>{A, B}"
   573   by blast
   574 
   575 lemma Union_empty [simp]: "\<Union>{} = {}"
   576   by blast
   577 
   578 lemma Union_UNIV [simp]: "\<Union>UNIV = UNIV"
   579   by blast
   580 
   581 lemma Union_insert [simp]: "\<Union>insert a B = a \<union> \<Union>B"
   582   by blast
   583 
   584 lemma Union_Un_distrib [simp]: "\<Union>(A \<union> B) = \<Union>A \<union> \<Union>B"
   585   by blast
   586 
   587 lemma Union_Int_subset: "\<Union>(A \<inter> B) \<subseteq> \<Union>A \<inter> \<Union>B"
   588   by blast
   589 
   590 lemma Union_empty_conv [simp,no_atp]: "(\<Union>A = {}) \<longleftrightarrow> (\<forall>x\<in>A. x = {})"
   591   by blast
   592 
   593 lemma empty_Union_conv [simp,no_atp]: "({} = \<Union>A) \<longleftrightarrow> (\<forall>x\<in>A. x = {})"
   594   by blast
   595 
   596 lemma Union_disjoint: "(\<Union>C \<inter> A = {}) \<longleftrightarrow> (\<forall>B\<in>C. B \<inter> A = {})"
   597   by blast
   598 
   599 lemma subset_Pow_Union: "A \<subseteq> Pow (\<Union>A)"
   600   by blast
   601 
   602 lemma Union_Pow_eq [simp]: "\<Union>(Pow A) = A"
   603   by blast
   604 
   605 lemma Union_mono: "A \<subseteq> B \<Longrightarrow> \<Union>A \<subseteq> \<Union>B"
   606   by blast
   607 
   608 
   609 subsection {* Unions of families *}
   610 
   611 abbreviation UNION :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> 'b set" where
   612   "UNION \<equiv> SUPR"
   613 
   614 syntax
   615   "_UNION1"     :: "pttrns => 'b set => 'b set"           ("(3UN _./ _)" [0, 10] 10)
   616   "_UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3UN _:_./ _)" [0, 0, 10] 10)
   617 
   618 syntax (xsymbols)
   619   "_UNION1"     :: "pttrns => 'b set => 'b set"           ("(3\<Union>_./ _)" [0, 10] 10)
   620   "_UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Union>_\<in>_./ _)" [0, 0, 10] 10)
   621 
   622 syntax (latex output)
   623   "_UNION1"     :: "pttrns => 'b set => 'b set"           ("(3\<Union>(00\<^bsub>_\<^esub>)/ _)" [0, 10] 10)
   624   "_UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Union>(00\<^bsub>_\<in>_\<^esub>)/ _)" [0, 0, 10] 10)
   625 
   626 translations
   627   "UN x y. B"   == "UN x. UN y. B"
   628   "UN x. B"     == "CONST UNION CONST UNIV (%x. B)"
   629   "UN x. B"     == "UN x:CONST UNIV. B"
   630   "UN x:A. B"   == "CONST UNION A (%x. B)"
   631 
   632 text {*
   633   Note the difference between ordinary xsymbol syntax of indexed
   634   unions and intersections (e.g.\ @{text"\<Union>a\<^isub>1\<in>A\<^isub>1. B"})
   635   and their \LaTeX\ rendition: @{term"\<Union>a\<^isub>1\<in>A\<^isub>1. B"}. The
   636   former does not make the index expression a subscript of the
   637   union/intersection symbol because this leads to problems with nested
   638   subscripts in Proof General.
   639 *}
   640 
   641 print_translation {*
   642   [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax UNION} @{syntax_const "_UNION"}]
   643 *} -- {* to avoid eta-contraction of body *}
   644 
   645 lemma UNION_eq_Union_image:
   646   "(\<Union>x\<in>A. B x) = \<Union>(B ` A)"
   647   by (fact SUPR_def)
   648 
   649 lemma Union_def:
   650   "\<Union>S = (\<Union>x\<in>S. x)"
   651   by (simp add: UNION_eq_Union_image image_def)
   652 
   653 lemma UNION_def [no_atp]:
   654   "(\<Union>x\<in>A. B x) = {y. \<exists>x\<in>A. y \<in> B x}"
   655   by (auto simp add: UNION_eq_Union_image Union_eq)
   656   
   657 lemma Union_image_eq [simp]:
   658   "\<Union>(B ` A) = (\<Union>x\<in>A. B x)"
   659   by (rule sym) (fact UNION_eq_Union_image)
   660   
   661 lemma UN_iff [simp]: "(b \<in> (\<Union>x\<in>A. B x)) = (\<exists>x\<in>A. b \<in> B x)"
   662   by (unfold UNION_def) blast
   663 
   664 lemma UN_I [intro]: "a \<in> A \<Longrightarrow> b \<in> B a \<Longrightarrow> b \<in> (\<Union>x\<in>A. B x)"
   665   -- {* The order of the premises presupposes that @{term A} is rigid;
   666     @{term b} may be flexible. *}
   667   by auto
   668 
   669 lemma UN_E [elim!]: "b \<in> (\<Union>x\<in>A. B x) \<Longrightarrow> (\<And>x. x\<in>A \<Longrightarrow> b \<in> B x \<Longrightarrow> R) \<Longrightarrow> R"
   670   by (unfold UNION_def) blast
   671 
   672 lemma UN_cong [cong]:
   673     "A = B \<Longrightarrow> (\<And>x. x \<in> B \<Longrightarrow> C x = D x) \<Longrightarrow> (\<Union>x\<in>A. C x) = (\<Union>x\<in>B. D x)"
   674   by (simp add: UNION_def)
   675 
   676 lemma strong_UN_cong:
   677     "A = B \<Longrightarrow> (\<And>x. x \<in> B =simp=> C x = D x) \<Longrightarrow> (\<Union>x\<in>A. C x) = (\<Union>x\<in>B. D x)"
   678   by (simp add: UNION_def simp_implies_def)
   679 
   680 lemma image_eq_UN: "f ` A = (\<Union>x\<in>A. {f x})"
   681   by blast
   682 
   683 lemma UN_upper: "a \<in> A \<Longrightarrow> B a \<subseteq> (\<Union>x\<in>A. B x)"
   684   by (fact le_SUPI)
   685 
   686 lemma UN_least: "(\<And>x. x \<in> A \<Longrightarrow> B x \<subseteq> C) \<Longrightarrow> (\<Union>x\<in>A. B x) \<subseteq> C"
   687   by (iprover intro: subsetI elim: UN_E dest: subsetD)
   688 
   689 lemma Collect_bex_eq [no_atp]: "{x. \<exists>y\<in>A. P x y} = (\<Union>y\<in>A. {x. P x y})"
   690   by blast
   691 
   692 lemma UN_insert_distrib: "u \<in> A \<Longrightarrow> (\<Union>x\<in>A. insert a (B x)) = insert a (\<Union>x\<in>A. B x)"
   693   by blast
   694 
   695 lemma UN_empty [simp,no_atp]: "(\<Union>x\<in>{}. B x) = {}"
   696   by blast
   697 
   698 lemma UN_empty2 [simp]: "(\<Union>x\<in>A. {}) = {}"
   699   by blast
   700 
   701 lemma UN_singleton [simp]: "(\<Union>x\<in>A. {x}) = A"
   702   by blast
   703 
   704 lemma UN_absorb: "k \<in> I \<Longrightarrow> A k \<union> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. A i)"
   705   by auto
   706 
   707 lemma UN_insert [simp]: "(\<Union>x\<in>insert a A. B x) = B a \<union> UNION A B"
   708   by blast
   709 
   710 lemma UN_Un[simp]: "(\<Union>i \<in> A \<union> B. M i) = (\<Union>i\<in>A. M i) \<union> (\<Union>i\<in>B. M i)"
   711   by blast
   712 
   713 lemma UN_UN_flatten: "(\<Union>x \<in> (\<Union>y\<in>A. B y). C x) = (\<Union>y\<in>A. \<Union>x\<in>B y. C x)"
   714   by blast
   715 
   716 lemma UN_subset_iff: "((\<Union>i\<in>I. A i) \<subseteq> B) = (\<forall>i\<in>I. A i \<subseteq> B)"
   717   by (fact SUP_le_iff)
   718 
   719 lemma image_Union: "f ` \<Union>S = (\<Union>x\<in>S. f ` x)"
   720   by blast
   721 
   722 lemma UN_constant [simp]: "(\<Union>y\<in>A. c) = (if A = {} then {} else c)"
   723   by auto
   724 
   725 lemma UN_eq: "(\<Union>x\<in>A. B x) = \<Union>({Y. \<exists>x\<in>A. Y = B x})"
   726   by blast
   727 
   728 lemma UNION_empty_conv[simp]:
   729   "{} = (\<Union>x\<in>A. B x) \<longleftrightarrow> (\<forall>x\<in>A. B x = {})"
   730   "(\<Union>x\<in>A. B x) = {} \<longleftrightarrow> (\<forall>x\<in>A. B x = {})"
   731 by blast+
   732 
   733 lemma Collect_ex_eq [no_atp]: "{x. \<exists>y. P x y} = (\<Union>y. {x. P x y})"
   734   by blast
   735 
   736 lemma ball_UN: "(\<forall>z \<in> UNION A B. P z) = (\<forall>x\<in>A. \<forall>z \<in> B x. P z)"
   737   by blast
   738 
   739 lemma bex_UN: "(\<exists>z \<in> UNION A B. P z) = (\<exists>x\<in>A. \<exists>z\<in>B x. P z)"
   740   by blast
   741 
   742 lemma Un_eq_UN: "A \<union> B = (\<Union>b. if b then A else B)"
   743   by (auto simp add: split_if_mem2)
   744 
   745 lemma UN_bool_eq: "(\<Union>b. A b) = (A True \<union> A False)"
   746   by (auto intro: bool_contrapos)
   747 
   748 lemma UN_Pow_subset: "(\<Union>x\<in>A. Pow (B x)) \<subseteq> Pow (\<Union>x\<in>A. B x)"
   749   by blast
   750 
   751 lemma UN_mono:
   752   "A \<subseteq> B \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> f x \<subseteq> g x) \<Longrightarrow>
   753     (\<Union>x\<in>A. f x) \<subseteq> (\<Union>x\<in>B. g x)"
   754   by (blast dest: subsetD)
   755 
   756 lemma vimage_Union: "f -` (\<Union>A) = (\<Union>X\<in>A. f -` X)"
   757   by blast
   758 
   759 lemma vimage_UN: "f -` (\<Union>x\<in>A. B x) = (\<Union>x\<in>A. f -` B x)"
   760   by blast
   761 
   762 lemma vimage_eq_UN: "f -` B = (\<Union>y\<in>B. f -` {y})"
   763   -- {* NOT suitable for rewriting *}
   764   by blast
   765 
   766 lemma image_UN: "f ` UNION A B = (\<Union>x\<in>A. f ` B x)"
   767   by blast
   768 
   769 
   770 subsection {* Distributive laws *}
   771 
   772 lemma Int_Union: "A \<inter> \<Union>B = (\<Union>C\<in>B. A \<inter> C)"
   773   by blast
   774 
   775 lemma Int_Union2: "\<Union>B \<inter> A = (\<Union>C\<in>B. C \<inter> A)"
   776   by blast
   777 
   778 lemma Un_Union_image: "(\<Union>x\<in>C. A x \<union> B x) = \<Union>(A ` C) \<union> \<Union>(B ` C)"
   779   -- {* Devlin, Fundamentals of Contemporary Set Theory, page 12, exercise 5: *}
   780   -- {* Union of a family of unions *}
   781   by blast
   782 
   783 lemma UN_Un_distrib: "(\<Union>i\<in>I. A i \<union> B i) = (\<Union>i\<in>I. A i) \<union> (\<Union>i\<in>I. B i)"
   784   -- {* Equivalent version *}
   785   by blast
   786 
   787 lemma Un_Inter: "A \<union> \<Inter>B = (\<Inter>C\<in>B. A \<union> C)"
   788   by blast
   789 
   790 lemma Int_Inter_image: "(\<Inter>x\<in>C. A x \<inter> B x) = \<Inter>(A ` C) \<inter> \<Inter>(B ` C)"
   791   by blast
   792 
   793 lemma INT_Int_distrib: "(\<Inter>i\<in>I. A i \<inter> B i) = (\<Inter>i\<in>I. A i) \<inter> (\<Inter>i\<in>I. B i)"
   794   -- {* Equivalent version *}
   795   by blast
   796 
   797 lemma Int_UN_distrib: "B \<inter> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. B \<inter> A i)"
   798   -- {* Halmos, Naive Set Theory, page 35. *}
   799   by blast
   800 
   801 lemma Un_INT_distrib: "B \<union> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. B \<union> A i)"
   802   by blast
   803 
   804 lemma Int_UN_distrib2: "(\<Union>i\<in>I. A i) \<inter> (\<Union>j\<in>J. B j) = (\<Union>i\<in>I. \<Union>j\<in>J. A i \<inter> B j)"
   805   by blast
   806 
   807 lemma Un_INT_distrib2: "(\<Inter>i\<in>I. A i) \<union> (\<Inter>j\<in>J. B j) = (\<Inter>i\<in>I. \<Inter>j\<in>J. A i \<union> B j)"
   808   by blast
   809 
   810 
   811 subsection {* Complement *}
   812 
   813 lemma Compl_UN [simp]: "- (\<Union>x\<in>A. B x) = (\<Inter>x\<in>A. -B x)"
   814   by blast
   815 
   816 lemma Compl_INT [simp]: "- (\<Inter>x\<in>A. B x) = (\<Union>x\<in>A. -B x)"
   817   by blast
   818 
   819 
   820 subsection {* Miniscoping and maxiscoping *}
   821 
   822 text {* \medskip Miniscoping: pushing in quantifiers and big Unions
   823            and Intersections. *}
   824 
   825 lemma UN_simps [simp]:
   826   "\<And>a B C. (\<Union>x\<in>C. insert a (B x)) = (if C={} then {} else insert a (\<Union>x\<in>C. B x))"
   827   "\<And>A B C. (\<Union>x\<in>C. A x \<union>  B) = ((if C={} then {} else (\<Union>x\<in>C. A x) \<union> B))"
   828   "\<And>A B C. (\<Union>x\<in>C. A \<union> B x) = ((if C={} then {} else A \<union> (\<Union>x\<in>C. B x)))"
   829   "\<And>A B C. (\<Union>x\<in>C. A x \<inter> B) = ((\<Union>x\<in>C. A x) \<inter>B)"
   830   "\<And>A B C. (\<Union>x\<in>C. A \<inter> B x) = (A \<inter>(\<Union>x\<in>C. B x))"
   831   "\<And>A B C. (\<Union>x\<in>C. A x - B) = ((\<Union>x\<in>C. A x) - B)"
   832   "\<And>A B C. (\<Union>x\<in>C. A - B x) = (A - (\<Inter>x\<in>C. B x))"
   833   "\<And>A B. (\<Union>x\<in>\<Union>A. B x) = (\<Union>y\<in>A. \<Union>x\<in>y. B x)"
   834   "\<And>A B C. (\<Union>z\<in>UNION A B. C z) = (\<Union>x\<in>A. \<Union>z\<in>B x. C z)"
   835   "\<And>A B f. (\<Union>x\<in>f`A. B x) = (\<Union>a\<in>A. B (f a))"
   836   by auto
   837 
   838 lemma INT_simps [simp]:
   839   "\<And>A B C. (\<Inter>x\<in>C. A x \<inter> B) = (if C={} then UNIV else (\<Inter>x\<in>C. A x) \<inter>B)"
   840   "\<And>A B C. (\<Inter>x\<in>C. A \<inter> B x) = (if C={} then UNIV else A \<inter>(\<Inter>x\<in>C. B x))"
   841   "\<And>A B C. (\<Inter>x\<in>C. A x - B) = (if C={} then UNIV else (\<Inter>x\<in>C. A x) - B)"
   842   "\<And>A B C. (\<Inter>x\<in>C. A - B x) = (if C={} then UNIV else A - (\<Union>x\<in>C. B x))"
   843   "\<And>a B C. (\<Inter>x\<in>C. insert a (B x)) = insert a (\<Inter>x\<in>C. B x)"
   844   "\<And>A B C. (\<Inter>x\<in>C. A x \<union> B) = ((\<Inter>x\<in>C. A x) \<union> B)"
   845   "\<And>A B C. (\<Inter>x\<in>C. A \<union> B x) = (A \<union> (\<Inter>x\<in>C. B x))"
   846   "\<And>A B. (\<Inter>x\<in>\<Union>A. B x) = (\<Inter>y\<in>A. \<Inter>x\<in>y. B x)"
   847   "\<And>A B C. (\<Inter>z\<in>UNION A B. C z) = (\<Inter>x\<in>A. \<Inter>z\<in>B x. C z)"
   848   "\<And>A B f. (\<Inter>x\<in>f`A. B x) = (\<Inter>a\<in>A. B (f a))"
   849   by auto
   850 
   851 lemma ball_simps [simp,no_atp]:
   852   "\<And>A P Q. (\<forall>x\<in>A. P x \<or> Q) \<longleftrightarrow> ((\<forall>x\<in>A. P x) \<or> Q)"
   853   "\<And>A P Q. (\<forall>x\<in>A. P \<or> Q x) \<longleftrightarrow> (P \<or> (\<forall>x\<in>A. Q x))"
   854   "\<And>A P Q. (\<forall>x\<in>A. P \<longrightarrow> Q x) \<longleftrightarrow> (P \<longrightarrow> (\<forall>x\<in>A. Q x))"
   855   "\<And>A P Q. (\<forall>x\<in>A. P x \<longrightarrow> Q) \<longleftrightarrow> ((\<exists>x\<in>A. P x) \<longrightarrow> Q)"
   856   "\<And>P. (\<forall>x\<in>{}. P x) \<longleftrightarrow> True"
   857   "\<And>P. (\<forall>x\<in>UNIV. P x) \<longleftrightarrow> (\<forall>x. P x)"
   858   "\<And>a B P. (\<forall>x\<in>insert a B. P x) \<longleftrightarrow> (P a \<and> (\<forall>x\<in>B. P x))"
   859   "\<And>A P. (\<forall>x\<in>\<Union>A. P x) \<longleftrightarrow> (\<forall>y\<in>A. \<forall>x\<in>y. P x)"
   860   "\<And>A B P. (\<forall>x\<in> UNION A B. P x) = (\<forall>a\<in>A. \<forall>x\<in> B a. P x)"
   861   "\<And>P Q. (\<forall>x\<in>Collect Q. P x) \<longleftrightarrow> (\<forall>x. Q x \<longrightarrow> P x)"
   862   "\<And>A P f. (\<forall>x\<in>f`A. P x) \<longleftrightarrow> (\<forall>x\<in>A. P (f x))"
   863   "\<And>A P. (\<not> (\<forall>x\<in>A. P x)) \<longleftrightarrow> (\<exists>x\<in>A. \<not> P x)"
   864   by auto
   865 
   866 lemma bex_simps [simp,no_atp]:
   867   "\<And>A P Q. (\<exists>x\<in>A. P x \<and> Q) \<longleftrightarrow> ((\<exists>x\<in>A. P x) \<and> Q)"
   868   "\<And>A P Q. (\<exists>x\<in>A. P \<and> Q x) \<longleftrightarrow> (P \<and> (\<exists>x\<in>A. Q x))"
   869   "\<And>P. (\<exists>x\<in>{}. P x) \<longleftrightarrow> False"
   870   "\<And>P. (\<exists>x\<in>UNIV. P x) \<longleftrightarrow> (\<exists>x. P x)"
   871   "\<And>a B P. (\<exists>x\<in>insert a B. P x) \<longleftrightarrow> (P a | (\<exists>x\<in>B. P x))"
   872   "\<And>A P. (\<exists>x\<in>\<Union>A. P x) \<longleftrightarrow> (\<exists>y\<in>A. \<exists>x\<in>y. P x)"
   873   "\<And>A B P. (\<exists>x\<in>UNION A B. P x) \<longleftrightarrow> (\<exists>a\<in>A. \<exists>x\<in>B a. P x)"
   874   "\<And>P Q. (\<exists>x\<in>Collect Q. P x) \<longleftrightarrow> (\<exists>x. Q x \<and> P x)"
   875   "\<And>A P f. (\<exists>x\<in>f`A. P x) \<longleftrightarrow> (\<exists>x\<in>A. P (f x))"
   876   "\<And>A P. (\<not>(\<exists>x\<in>A. P x)) \<longleftrightarrow> (\<forall>x\<in>A. \<not> P x)"
   877   by auto
   878 
   879 text {* \medskip Maxiscoping: pulling out big Unions and Intersections. *}
   880 
   881 lemma UN_extend_simps:
   882   "\<And>a B C. insert a (\<Union>x\<in>C. B x) = (if C={} then {a} else (\<Union>x\<in>C. insert a (B x)))"
   883   "\<And>A B C. (\<Union>x\<in>C. A x) \<union>  B  = (if C={} then B else (\<Union>x\<in>C. A x \<union>  B))"
   884   "\<And>A B C. A \<union> (\<Union>x\<in>C. B x) = (if C={} then A else (\<Union>x\<in>C. A \<union> B x))"
   885   "\<And>A B C. ((\<Union>x\<in>C. A x) \<inter> B) = (\<Union>x\<in>C. A x \<inter> B)"
   886   "\<And>A B C. (A \<inter> (\<Union>x\<in>C. B x)) = (\<Union>x\<in>C. A \<inter> B x)"
   887   "\<And>A B C. ((\<Union>x\<in>C. A x) - B) = (\<Union>x\<in>C. A x - B)"
   888   "\<And>A B C. (A - (\<Inter>x\<in>C. B x)) = (\<Union>x\<in>C. A - B x)"
   889   "\<And>A B. (\<Union>y\<in>A. \<Union>x\<in>y. B x) = (\<Union>x\<in>\<Union>A. B x)"
   890   "\<And>A B C. (\<Union>x\<in>A. \<Union>z\<in>B x. C z) = (\<Union>z\<in>UNION A B. C z)"
   891   "\<And>A B f. (\<Union>a\<in>A. B (f a)) = (\<Union>x\<in>f`A. B x)"
   892   by auto
   893 
   894 lemma INT_extend_simps:
   895   "\<And>A B C. (\<Inter>x\<in>C. A x) \<inter> B = (if C={} then B else (\<Inter>x\<in>C. A x \<inter> B))"
   896   "\<And>A B C. A \<inter> (\<Inter>x\<in>C. B x) = (if C={} then A else (\<Inter>x\<in>C. A \<inter> B x))"
   897   "\<And>A B C. (\<Inter>x\<in>C. A x) - B = (if C={} then UNIV - B else (\<Inter>x\<in>C. A x - B))"
   898   "\<And>A B C. A - (\<Union>x\<in>C. B x) = (if C={} then A else (\<Inter>x\<in>C. A - B x))"
   899   "\<And>a B C. insert a (\<Inter>x\<in>C. B x) = (\<Inter>x\<in>C. insert a (B x))"
   900   "\<And>A B C. ((\<Inter>x\<in>C. A x) \<union> B) = (\<Inter>x\<in>C. A x \<union> B)"
   901   "\<And>A B C. A \<union> (\<Inter>x\<in>C. B x) = (\<Inter>x\<in>C. A \<union> B x)"
   902   "\<And>A B. (\<Inter>y\<in>A. \<Inter>x\<in>y. B x) = (\<Inter>x\<in>\<Union>A. B x)"
   903   "\<And>A B C. (\<Inter>x\<in>A. \<Inter>z\<in>B x. C z) = (\<Inter>z\<in>UNION A B. C z)"
   904   "\<And>A B f. (\<Inter>a\<in>A. B (f a)) = (\<Inter>x\<in>f`A. B x)"
   905   by auto
   906 
   907 
   908 no_notation
   909   less_eq  (infix "\<sqsubseteq>" 50) and
   910   less (infix "\<sqsubset>" 50) and
   911   bot ("\<bottom>") and
   912   top ("\<top>") and
   913   inf  (infixl "\<sqinter>" 70) and
   914   sup  (infixl "\<squnion>" 65) and
   915   Inf  ("\<Sqinter>_" [900] 900) and
   916   Sup  ("\<Squnion>_" [900] 900)
   917 
   918 no_syntax (xsymbols)
   919   "_INF1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3\<Sqinter>_./ _)" [0, 10] 10)
   920   "_INF"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3\<Sqinter>_\<in>_./ _)" [0, 0, 10] 10)
   921   "_SUP1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3\<Squnion>_./ _)" [0, 10] 10)
   922   "_SUP"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3\<Squnion>_\<in>_./ _)" [0, 0, 10] 10)
   923 
   924 lemmas mem_simps =
   925   insert_iff empty_iff Un_iff Int_iff Compl_iff Diff_iff
   926   mem_Collect_eq UN_iff Union_iff INT_iff Inter_iff
   927   -- {* Each of these has ALREADY been added @{text "[simp]"} above. *}
   928 
   929 end