src/HOL/Multivariate_Analysis/Cartesian_Euclidean_Space.thy
author immler
Tue Mar 18 10:12:57 2014 +0100 (2014-03-18)
changeset 56188 0268784f60da
parent 55522 23d2cbac6dce
child 56189 c4daa97ac57a
permissions -rw-r--r--
use cbox to relax class constraints
     1 header {*Instanciates the finite cartesian product of euclidean spaces as a euclidean space.*}
     2 
     3 theory Cartesian_Euclidean_Space
     4 imports Finite_Cartesian_Product Integration
     5 begin
     6 
     7 lemma delta_mult_idempotent:
     8   "(if k=a then 1 else (0::'a::semiring_1)) * (if k=a then 1 else 0) = (if k=a then 1 else 0)"
     9   by (cases "k=a") auto
    10 
    11 lemma setsum_Plus:
    12   "\<lbrakk>finite A; finite B\<rbrakk> \<Longrightarrow>
    13     (\<Sum>x\<in>A <+> B. g x) = (\<Sum>x\<in>A. g (Inl x)) + (\<Sum>x\<in>B. g (Inr x))"
    14   unfolding Plus_def
    15   by (subst setsum_Un_disjoint, auto simp add: setsum_reindex)
    16 
    17 lemma setsum_UNIV_sum:
    18   fixes g :: "'a::finite + 'b::finite \<Rightarrow> _"
    19   shows "(\<Sum>x\<in>UNIV. g x) = (\<Sum>x\<in>UNIV. g (Inl x)) + (\<Sum>x\<in>UNIV. g (Inr x))"
    20   apply (subst UNIV_Plus_UNIV [symmetric])
    21   apply (rule setsum_Plus [OF finite finite])
    22   done
    23 
    24 lemma setsum_mult_product:
    25   "setsum h {..<A * B :: nat} = (\<Sum>i\<in>{..<A}. \<Sum>j\<in>{..<B}. h (j + i * B))"
    26   unfolding sumr_group[of h B A, unfolded atLeast0LessThan, symmetric]
    27 proof (rule setsum_cong, simp, rule setsum_reindex_cong)
    28   fix i
    29   show "inj_on (\<lambda>j. j + i * B) {..<B}" by (auto intro!: inj_onI)
    30   show "{i * B..<i * B + B} = (\<lambda>j. j + i * B) ` {..<B}"
    31   proof safe
    32     fix j assume "j \<in> {i * B..<i * B + B}"
    33     then show "j \<in> (\<lambda>j. j + i * B) ` {..<B}"
    34       by (auto intro!: image_eqI[of _ _ "j - i * B"])
    35   qed simp
    36 qed simp
    37 
    38 
    39 subsection{* Basic componentwise operations on vectors. *}
    40 
    41 instantiation vec :: (times, finite) times
    42 begin
    43 
    44 definition "op * \<equiv> (\<lambda> x y.  (\<chi> i. (x$i) * (y$i)))"
    45 instance ..
    46 
    47 end
    48 
    49 instantiation vec :: (one, finite) one
    50 begin
    51 
    52 definition "1 \<equiv> (\<chi> i. 1)"
    53 instance ..
    54 
    55 end
    56 
    57 instantiation vec :: (ord, finite) ord
    58 begin
    59 
    60 definition "x \<le> y \<longleftrightarrow> (\<forall>i. x$i \<le> y$i)"
    61 definition "x < (y::'a^'b) \<longleftrightarrow> x \<le> y \<and> \<not> y \<le> x"
    62 instance ..
    63 
    64 end
    65 
    66 text{* The ordering on one-dimensional vectors is linear. *}
    67 
    68 class cart_one =
    69   assumes UNIV_one: "card (UNIV \<Colon> 'a set) = Suc 0"
    70 begin
    71 
    72 subclass finite
    73 proof
    74   from UNIV_one show "finite (UNIV :: 'a set)"
    75     by (auto intro!: card_ge_0_finite)
    76 qed
    77 
    78 end
    79 
    80 instance vec:: (order, finite) order
    81   by default (auto simp: less_eq_vec_def less_vec_def vec_eq_iff
    82       intro: order.trans order.antisym order.strict_implies_order)
    83 
    84 instance vec :: (linorder, cart_one) linorder
    85 proof
    86   obtain a :: 'b where all: "\<And>P. (\<forall>i. P i) \<longleftrightarrow> P a"
    87   proof -
    88     have "card (UNIV :: 'b set) = Suc 0" by (rule UNIV_one)
    89     then obtain b :: 'b where "UNIV = {b}" by (auto iff: card_Suc_eq)
    90     then have "\<And>P. (\<forall>i\<in>UNIV. P i) \<longleftrightarrow> P b" by auto
    91     then show thesis by (auto intro: that)
    92   qed
    93   fix x y :: "'a^'b::cart_one"
    94   note [simp] = less_eq_vec_def less_vec_def all vec_eq_iff field_simps
    95   show "x \<le> y \<or> y \<le> x" by auto
    96 qed
    97 
    98 text{* Constant Vectors *}
    99 
   100 definition "vec x = (\<chi> i. x)"
   101 
   102 lemma interval_cbox_cart: "{a::real^'n..b} = cbox a b"
   103   by (auto simp add: less_eq_vec_def mem_box Basis_vec_def inner_axis)
   104 
   105 text{* Also the scalar-vector multiplication. *}
   106 
   107 definition vector_scalar_mult:: "'a::times \<Rightarrow> 'a ^ 'n \<Rightarrow> 'a ^ 'n" (infixl "*s" 70)
   108   where "c *s x = (\<chi> i. c * (x$i))"
   109 
   110 
   111 subsection {* A naive proof procedure to lift really trivial arithmetic stuff from the basis of the vector space. *}
   112 
   113 method_setup vector = {*
   114 let
   115   val ss1 =
   116     simpset_of (put_simpset HOL_basic_ss @{context}
   117       addsimps [@{thm setsum_addf} RS sym,
   118       @{thm setsum_subtractf} RS sym, @{thm setsum_right_distrib},
   119       @{thm setsum_left_distrib}, @{thm setsum_negf} RS sym])
   120   val ss2 =
   121     simpset_of (@{context} addsimps
   122              [@{thm plus_vec_def}, @{thm times_vec_def},
   123               @{thm minus_vec_def}, @{thm uminus_vec_def},
   124               @{thm one_vec_def}, @{thm zero_vec_def}, @{thm vec_def},
   125               @{thm scaleR_vec_def},
   126               @{thm vec_lambda_beta}, @{thm vector_scalar_mult_def}])
   127   fun vector_arith_tac ctxt ths =
   128     simp_tac (put_simpset ss1 ctxt)
   129     THEN' (fn i => rtac @{thm setsum_cong2} i
   130          ORELSE rtac @{thm setsum_0'} i
   131          ORELSE simp_tac (put_simpset HOL_basic_ss ctxt addsimps [@{thm vec_eq_iff}]) i)
   132     (* THEN' TRY o clarify_tac HOL_cs  THEN' (TRY o rtac @{thm iffI}) *)
   133     THEN' asm_full_simp_tac (put_simpset ss2 ctxt addsimps ths)
   134 in
   135   Attrib.thms >> (fn ths => fn ctxt => SIMPLE_METHOD' (vector_arith_tac ctxt ths))
   136 end
   137 *} "lift trivial vector statements to real arith statements"
   138 
   139 lemma vec_0[simp]: "vec 0 = 0" by (vector zero_vec_def)
   140 lemma vec_1[simp]: "vec 1 = 1" by (vector one_vec_def)
   141 
   142 lemma vec_inj[simp]: "vec x = vec y \<longleftrightarrow> x = y" by vector
   143 
   144 lemma vec_in_image_vec: "vec x \<in> (vec ` S) \<longleftrightarrow> x \<in> S" by auto
   145 
   146 lemma vec_add: "vec(x + y) = vec x + vec y"  by (vector vec_def)
   147 lemma vec_sub: "vec(x - y) = vec x - vec y" by (vector vec_def)
   148 lemma vec_cmul: "vec(c * x) = c *s vec x " by (vector vec_def)
   149 lemma vec_neg: "vec(- x) = - vec x " by (vector vec_def)
   150 
   151 lemma vec_setsum:
   152   assumes "finite S"
   153   shows "vec(setsum f S) = setsum (vec o f) S"
   154   using assms
   155 proof induct
   156   case empty
   157   then show ?case by simp
   158 next
   159   case insert
   160   then show ?case by (auto simp add: vec_add)
   161 qed
   162 
   163 text{* Obvious "component-pushing". *}
   164 
   165 lemma vec_component [simp]: "vec x $ i = x"
   166   by (vector vec_def)
   167 
   168 lemma vector_mult_component [simp]: "(x * y)$i = x$i * y$i"
   169   by vector
   170 
   171 lemma vector_smult_component [simp]: "(c *s y)$i = c * (y$i)"
   172   by vector
   173 
   174 lemma cond_component: "(if b then x else y)$i = (if b then x$i else y$i)" by vector
   175 
   176 lemmas vector_component =
   177   vec_component vector_add_component vector_mult_component
   178   vector_smult_component vector_minus_component vector_uminus_component
   179   vector_scaleR_component cond_component
   180 
   181 
   182 subsection {* Some frequently useful arithmetic lemmas over vectors. *}
   183 
   184 instance vec :: (semigroup_mult, finite) semigroup_mult
   185   by default (vector mult_assoc)
   186 
   187 instance vec :: (monoid_mult, finite) monoid_mult
   188   by default vector+
   189 
   190 instance vec :: (ab_semigroup_mult, finite) ab_semigroup_mult
   191   by default (vector mult_commute)
   192 
   193 instance vec :: (comm_monoid_mult, finite) comm_monoid_mult
   194   by default vector
   195 
   196 instance vec :: (semiring, finite) semiring
   197   by default (vector field_simps)+
   198 
   199 instance vec :: (semiring_0, finite) semiring_0
   200   by default (vector field_simps)+
   201 instance vec :: (semiring_1, finite) semiring_1
   202   by default vector
   203 instance vec :: (comm_semiring, finite) comm_semiring
   204   by default (vector field_simps)+
   205 
   206 instance vec :: (comm_semiring_0, finite) comm_semiring_0 ..
   207 instance vec :: (cancel_comm_monoid_add, finite) cancel_comm_monoid_add ..
   208 instance vec :: (semiring_0_cancel, finite) semiring_0_cancel ..
   209 instance vec :: (comm_semiring_0_cancel, finite) comm_semiring_0_cancel ..
   210 instance vec :: (ring, finite) ring ..
   211 instance vec :: (semiring_1_cancel, finite) semiring_1_cancel ..
   212 instance vec :: (comm_semiring_1, finite) comm_semiring_1 ..
   213 
   214 instance vec :: (ring_1, finite) ring_1 ..
   215 
   216 instance vec :: (real_algebra, finite) real_algebra
   217   by default (simp_all add: vec_eq_iff)
   218 
   219 instance vec :: (real_algebra_1, finite) real_algebra_1 ..
   220 
   221 lemma of_nat_index: "(of_nat n :: 'a::semiring_1 ^'n)$i = of_nat n"
   222 proof (induct n)
   223   case 0
   224   then show ?case by vector
   225 next
   226   case Suc
   227   then show ?case by vector
   228 qed
   229 
   230 lemma one_index [simp]: "(1 :: 'a :: one ^ 'n) $ i = 1"
   231   by vector
   232 
   233 lemma neg_one_index [simp]: "(- 1 :: 'a :: {one, uminus} ^ 'n) $ i = - 1"
   234   by vector
   235 
   236 instance vec :: (semiring_char_0, finite) semiring_char_0
   237 proof
   238   fix m n :: nat
   239   show "inj (of_nat :: nat \<Rightarrow> 'a ^ 'b)"
   240     by (auto intro!: injI simp add: vec_eq_iff of_nat_index)
   241 qed
   242 
   243 instance vec :: (numeral, finite) numeral ..
   244 instance vec :: (semiring_numeral, finite) semiring_numeral ..
   245 
   246 lemma numeral_index [simp]: "numeral w $ i = numeral w"
   247   by (induct w) (simp_all only: numeral.simps vector_add_component one_index)
   248 
   249 lemma neg_numeral_index [simp]: "- numeral w $ i = - numeral w"
   250   by (simp only: vector_uminus_component numeral_index)
   251 
   252 instance vec :: (comm_ring_1, finite) comm_ring_1 ..
   253 instance vec :: (ring_char_0, finite) ring_char_0 ..
   254 
   255 lemma vector_smult_assoc: "a *s (b *s x) = ((a::'a::semigroup_mult) * b) *s x"
   256   by (vector mult_assoc)
   257 lemma vector_sadd_rdistrib: "((a::'a::semiring) + b) *s x = a *s x + b *s x"
   258   by (vector field_simps)
   259 lemma vector_add_ldistrib: "(c::'a::semiring) *s (x + y) = c *s x + c *s y"
   260   by (vector field_simps)
   261 lemma vector_smult_lzero[simp]: "(0::'a::mult_zero) *s x = 0" by vector
   262 lemma vector_smult_lid[simp]: "(1::'a::monoid_mult) *s x = x" by vector
   263 lemma vector_ssub_ldistrib: "(c::'a::ring) *s (x - y) = c *s x - c *s y"
   264   by (vector field_simps)
   265 lemma vector_smult_rneg: "(c::'a::ring) *s -x = -(c *s x)" by vector
   266 lemma vector_smult_lneg: "- (c::'a::ring) *s x = -(c *s x)" by vector
   267 lemma vector_sneg_minus1: "-x = (-1::'a::ring_1) *s x" by vector
   268 lemma vector_smult_rzero[simp]: "c *s 0 = (0::'a::mult_zero ^ 'n)" by vector
   269 lemma vector_sub_rdistrib: "((a::'a::ring) - b) *s x = a *s x - b *s x"
   270   by (vector field_simps)
   271 
   272 lemma vec_eq[simp]: "(vec m = vec n) \<longleftrightarrow> (m = n)"
   273   by (simp add: vec_eq_iff)
   274 
   275 lemma norm_eq_0_imp: "norm x = 0 ==> x = (0::real ^'n)" by (metis norm_eq_zero)
   276 lemma vector_mul_eq_0[simp]: "(a *s x = 0) \<longleftrightarrow> a = (0::'a::idom) \<or> x = 0"
   277   by vector
   278 lemma vector_mul_lcancel[simp]: "a *s x = a *s y \<longleftrightarrow> a = (0::real) \<or> x = y"
   279   by (metis eq_iff_diff_eq_0 vector_mul_eq_0 vector_ssub_ldistrib)
   280 lemma vector_mul_rcancel[simp]: "a *s x = b *s x \<longleftrightarrow> (a::real) = b \<or> x = 0"
   281   by (metis eq_iff_diff_eq_0 vector_mul_eq_0 vector_sub_rdistrib)
   282 lemma vector_mul_lcancel_imp: "a \<noteq> (0::real) ==>  a *s x = a *s y ==> (x = y)"
   283   by (metis vector_mul_lcancel)
   284 lemma vector_mul_rcancel_imp: "x \<noteq> 0 \<Longrightarrow> (a::real) *s x = b *s x ==> a = b"
   285   by (metis vector_mul_rcancel)
   286 
   287 lemma component_le_norm_cart: "\<bar>x$i\<bar> <= norm x"
   288   apply (simp add: norm_vec_def)
   289   apply (rule member_le_setL2, simp_all)
   290   done
   291 
   292 lemma norm_bound_component_le_cart: "norm x <= e ==> \<bar>x$i\<bar> <= e"
   293   by (metis component_le_norm_cart order_trans)
   294 
   295 lemma norm_bound_component_lt_cart: "norm x < e ==> \<bar>x$i\<bar> < e"
   296   by (metis component_le_norm_cart le_less_trans)
   297 
   298 lemma norm_le_l1_cart: "norm x <= setsum(\<lambda>i. \<bar>x$i\<bar>) UNIV"
   299   by (simp add: norm_vec_def setL2_le_setsum)
   300 
   301 lemma scalar_mult_eq_scaleR: "c *s x = c *\<^sub>R x"
   302   unfolding scaleR_vec_def vector_scalar_mult_def by simp
   303 
   304 lemma dist_mul[simp]: "dist (c *s x) (c *s y) = \<bar>c\<bar> * dist x y"
   305   unfolding dist_norm scalar_mult_eq_scaleR
   306   unfolding scaleR_right_diff_distrib[symmetric] by simp
   307 
   308 lemma setsum_component [simp]:
   309   fixes f:: " 'a \<Rightarrow> ('b::comm_monoid_add) ^'n"
   310   shows "(setsum f S)$i = setsum (\<lambda>x. (f x)$i) S"
   311 proof (cases "finite S")
   312   case True
   313   then show ?thesis by induct simp_all
   314 next
   315   case False
   316   then show ?thesis by simp
   317 qed
   318 
   319 lemma setsum_eq: "setsum f S = (\<chi> i. setsum (\<lambda>x. (f x)$i ) S)"
   320   by (simp add: vec_eq_iff)
   321 
   322 lemma setsum_cmul:
   323   fixes f:: "'c \<Rightarrow> ('a::semiring_1)^'n"
   324   shows "setsum (\<lambda>x. c *s f x) S = c *s setsum f S"
   325   by (simp add: vec_eq_iff setsum_right_distrib)
   326 
   327 lemma setsum_norm_allsubsets_bound_cart:
   328   fixes f:: "'a \<Rightarrow> real ^'n"
   329   assumes fP: "finite P" and fPs: "\<And>Q. Q \<subseteq> P \<Longrightarrow> norm (setsum f Q) \<le> e"
   330   shows "setsum (\<lambda>x. norm (f x)) P \<le> 2 * real CARD('n) *  e"
   331   using setsum_norm_allsubsets_bound[OF assms]
   332   by (simp add: DIM_cart Basis_real_def)
   333 
   334 instantiation vec :: (ordered_euclidean_space, finite) ordered_euclidean_space
   335 begin
   336 
   337 definition "inf x y = (\<chi> i. inf (x $ i) (y $ i))"
   338 definition "sup x y = (\<chi> i. sup (x $ i) (y $ i))"
   339 definition "Inf X = (\<chi> i. (INF x:X. x $ i))"
   340 definition "Sup X = (\<chi> i. (SUP x:X. x $ i))"
   341 definition "abs x = (\<chi> i. abs (x $ i))"
   342 
   343 instance
   344   apply default
   345   unfolding euclidean_representation_setsum'
   346   apply (auto simp: less_eq_vec_def inf_vec_def sup_vec_def Inf_vec_def Sup_vec_def inner_axis
   347     Basis_vec_def inner_Basis_inf_left inner_Basis_sup_left inner_Basis_INF_left
   348     inner_Basis_SUP_left eucl_le[where 'a='a] less_le_not_le abs_vec_def abs_inner)
   349   done
   350 
   351 end
   352 
   353 subsection {* Matrix operations *}
   354 
   355 text{* Matrix notation. NB: an MxN matrix is of type @{typ "'a^'n^'m"}, not @{typ "'a^'m^'n"} *}
   356 
   357 definition matrix_matrix_mult :: "('a::semiring_1) ^'n^'m \<Rightarrow> 'a ^'p^'n \<Rightarrow> 'a ^ 'p ^'m"
   358     (infixl "**" 70)
   359   where "m ** m' == (\<chi> i j. setsum (\<lambda>k. ((m$i)$k) * ((m'$k)$j)) (UNIV :: 'n set)) ::'a ^ 'p ^'m"
   360 
   361 definition matrix_vector_mult :: "('a::semiring_1) ^'n^'m \<Rightarrow> 'a ^'n \<Rightarrow> 'a ^ 'm"
   362     (infixl "*v" 70)
   363   where "m *v x \<equiv> (\<chi> i. setsum (\<lambda>j. ((m$i)$j) * (x$j)) (UNIV ::'n set)) :: 'a^'m"
   364 
   365 definition vector_matrix_mult :: "'a ^ 'm \<Rightarrow> ('a::semiring_1) ^'n^'m \<Rightarrow> 'a ^'n "
   366     (infixl "v*" 70)
   367   where "v v* m == (\<chi> j. setsum (\<lambda>i. ((m$i)$j) * (v$i)) (UNIV :: 'm set)) :: 'a^'n"
   368 
   369 definition "(mat::'a::zero => 'a ^'n^'n) k = (\<chi> i j. if i = j then k else 0)"
   370 definition transpose where 
   371   "(transpose::'a^'n^'m \<Rightarrow> 'a^'m^'n) A = (\<chi> i j. ((A$j)$i))"
   372 definition "(row::'m => 'a ^'n^'m \<Rightarrow> 'a ^'n) i A = (\<chi> j. ((A$i)$j))"
   373 definition "(column::'n =>'a^'n^'m =>'a^'m) j A = (\<chi> i. ((A$i)$j))"
   374 definition "rows(A::'a^'n^'m) = { row i A | i. i \<in> (UNIV :: 'm set)}"
   375 definition "columns(A::'a^'n^'m) = { column i A | i. i \<in> (UNIV :: 'n set)}"
   376 
   377 lemma mat_0[simp]: "mat 0 = 0" by (vector mat_def)
   378 lemma matrix_add_ldistrib: "(A ** (B + C)) = (A ** B) + (A ** C)"
   379   by (vector matrix_matrix_mult_def setsum_addf[symmetric] field_simps)
   380 
   381 lemma matrix_mul_lid:
   382   fixes A :: "'a::semiring_1 ^ 'm ^ 'n"
   383   shows "mat 1 ** A = A"
   384   apply (simp add: matrix_matrix_mult_def mat_def)
   385   apply vector
   386   apply (auto simp only: if_distrib cond_application_beta setsum_delta'[OF finite]
   387     mult_1_left mult_zero_left if_True UNIV_I)
   388   done
   389 
   390 
   391 lemma matrix_mul_rid:
   392   fixes A :: "'a::semiring_1 ^ 'm ^ 'n"
   393   shows "A ** mat 1 = A"
   394   apply (simp add: matrix_matrix_mult_def mat_def)
   395   apply vector
   396   apply (auto simp only: if_distrib cond_application_beta setsum_delta[OF finite]
   397     mult_1_right mult_zero_right if_True UNIV_I cong: if_cong)
   398   done
   399 
   400 lemma matrix_mul_assoc: "A ** (B ** C) = (A ** B) ** C"
   401   apply (vector matrix_matrix_mult_def setsum_right_distrib setsum_left_distrib mult_assoc)
   402   apply (subst setsum_commute)
   403   apply simp
   404   done
   405 
   406 lemma matrix_vector_mul_assoc: "A *v (B *v x) = (A ** B) *v x"
   407   apply (vector matrix_matrix_mult_def matrix_vector_mult_def
   408     setsum_right_distrib setsum_left_distrib mult_assoc)
   409   apply (subst setsum_commute)
   410   apply simp
   411   done
   412 
   413 lemma matrix_vector_mul_lid: "mat 1 *v x = (x::'a::semiring_1 ^ 'n)"
   414   apply (vector matrix_vector_mult_def mat_def)
   415   apply (simp add: if_distrib cond_application_beta setsum_delta' cong del: if_weak_cong)
   416   done
   417 
   418 lemma matrix_transpose_mul:
   419     "transpose(A ** B) = transpose B ** transpose (A::'a::comm_semiring_1^_^_)"
   420   by (simp add: matrix_matrix_mult_def transpose_def vec_eq_iff mult_commute)
   421 
   422 lemma matrix_eq:
   423   fixes A B :: "'a::semiring_1 ^ 'n ^ 'm"
   424   shows "A = B \<longleftrightarrow>  (\<forall>x. A *v x = B *v x)" (is "?lhs \<longleftrightarrow> ?rhs")
   425   apply auto
   426   apply (subst vec_eq_iff)
   427   apply clarify
   428   apply (clarsimp simp add: matrix_vector_mult_def if_distrib cond_application_beta vec_eq_iff cong del: if_weak_cong)
   429   apply (erule_tac x="axis ia 1" in allE)
   430   apply (erule_tac x="i" in allE)
   431   apply (auto simp add: if_distrib cond_application_beta axis_def
   432     setsum_delta[OF finite] cong del: if_weak_cong)
   433   done
   434 
   435 lemma matrix_vector_mul_component: "((A::real^_^_) *v x)$k = (A$k) \<bullet> x"
   436   by (simp add: matrix_vector_mult_def inner_vec_def)
   437 
   438 lemma dot_lmul_matrix: "((x::real ^_) v* A) \<bullet> y = x \<bullet> (A *v y)"
   439   apply (simp add: inner_vec_def matrix_vector_mult_def vector_matrix_mult_def setsum_left_distrib setsum_right_distrib mult_ac)
   440   apply (subst setsum_commute)
   441   apply simp
   442   done
   443 
   444 lemma transpose_mat: "transpose (mat n) = mat n"
   445   by (vector transpose_def mat_def)
   446 
   447 lemma transpose_transpose: "transpose(transpose A) = A"
   448   by (vector transpose_def)
   449 
   450 lemma row_transpose:
   451   fixes A:: "'a::semiring_1^_^_"
   452   shows "row i (transpose A) = column i A"
   453   by (simp add: row_def column_def transpose_def vec_eq_iff)
   454 
   455 lemma column_transpose:
   456   fixes A:: "'a::semiring_1^_^_"
   457   shows "column i (transpose A) = row i A"
   458   by (simp add: row_def column_def transpose_def vec_eq_iff)
   459 
   460 lemma rows_transpose: "rows(transpose (A::'a::semiring_1^_^_)) = columns A"
   461   by (auto simp add: rows_def columns_def row_transpose intro: set_eqI)
   462 
   463 lemma columns_transpose: "columns(transpose (A::'a::semiring_1^_^_)) = rows A"
   464   by (metis transpose_transpose rows_transpose)
   465 
   466 text{* Two sometimes fruitful ways of looking at matrix-vector multiplication. *}
   467 
   468 lemma matrix_mult_dot: "A *v x = (\<chi> i. A$i \<bullet> x)"
   469   by (simp add: matrix_vector_mult_def inner_vec_def)
   470 
   471 lemma matrix_mult_vsum:
   472   "(A::'a::comm_semiring_1^'n^'m) *v x = setsum (\<lambda>i. (x$i) *s column i A) (UNIV:: 'n set)"
   473   by (simp add: matrix_vector_mult_def vec_eq_iff column_def mult_commute)
   474 
   475 lemma vector_componentwise:
   476   "(x::'a::ring_1^'n) = (\<chi> j. \<Sum>i\<in>UNIV. (x$i) * (axis i 1 :: 'a^'n) $ j)"
   477   by (simp add: axis_def if_distrib setsum_cases vec_eq_iff)
   478 
   479 lemma basis_expansion: "setsum (\<lambda>i. (x$i) *s axis i 1) UNIV = (x::('a::ring_1) ^'n)"
   480   by (auto simp add: axis_def vec_eq_iff if_distrib setsum_cases cong del: if_weak_cong)
   481 
   482 lemma linear_componentwise:
   483   fixes f:: "real ^'m \<Rightarrow> real ^ _"
   484   assumes lf: "linear f"
   485   shows "(f x)$j = setsum (\<lambda>i. (x$i) * (f (axis i 1)$j)) (UNIV :: 'm set)" (is "?lhs = ?rhs")
   486 proof -
   487   let ?M = "(UNIV :: 'm set)"
   488   let ?N = "(UNIV :: 'n set)"
   489   have fM: "finite ?M" by simp
   490   have "?rhs = (setsum (\<lambda>i.(x$i) *\<^sub>R f (axis i 1) ) ?M)$j"
   491     unfolding setsum_component by simp
   492   then show ?thesis
   493     unfolding linear_setsum_mul[OF lf fM, symmetric]
   494     unfolding scalar_mult_eq_scaleR[symmetric]
   495     unfolding basis_expansion
   496     by simp
   497 qed
   498 
   499 text{* Inverse matrices  (not necessarily square) *}
   500 
   501 definition
   502   "invertible(A::'a::semiring_1^'n^'m) \<longleftrightarrow> (\<exists>A'::'a^'m^'n. A ** A' = mat 1 \<and> A' ** A = mat 1)"
   503 
   504 definition
   505   "matrix_inv(A:: 'a::semiring_1^'n^'m) =
   506     (SOME A'::'a^'m^'n. A ** A' = mat 1 \<and> A' ** A = mat 1)"
   507 
   508 text{* Correspondence between matrices and linear operators. *}
   509 
   510 definition matrix :: "('a::{plus,times, one, zero}^'m \<Rightarrow> 'a ^ 'n) \<Rightarrow> 'a^'m^'n"
   511   where "matrix f = (\<chi> i j. (f(axis j 1))$i)"
   512 
   513 lemma matrix_vector_mul_linear: "linear(\<lambda>x. A *v (x::real ^ _))"
   514   by (simp add: linear_iff matrix_vector_mult_def vec_eq_iff
   515       field_simps setsum_right_distrib setsum_addf)
   516 
   517 lemma matrix_works:
   518   assumes lf: "linear f"
   519   shows "matrix f *v x = f (x::real ^ 'n)"
   520   apply (simp add: matrix_def matrix_vector_mult_def vec_eq_iff mult_commute)
   521   apply clarify
   522   apply (rule linear_componentwise[OF lf, symmetric])
   523   done
   524 
   525 lemma matrix_vector_mul: "linear f ==> f = (\<lambda>x. matrix f *v (x::real ^ 'n))"
   526   by (simp add: ext matrix_works)
   527 
   528 lemma matrix_of_matrix_vector_mul: "matrix(\<lambda>x. A *v (x :: real ^ 'n)) = A"
   529   by (simp add: matrix_eq matrix_vector_mul_linear matrix_works)
   530 
   531 lemma matrix_compose:
   532   assumes lf: "linear (f::real^'n \<Rightarrow> real^'m)"
   533     and lg: "linear (g::real^'m \<Rightarrow> real^_)"
   534   shows "matrix (g o f) = matrix g ** matrix f"
   535   using lf lg linear_compose[OF lf lg] matrix_works[OF linear_compose[OF lf lg]]
   536   by (simp add: matrix_eq matrix_works matrix_vector_mul_assoc[symmetric] o_def)
   537 
   538 lemma matrix_vector_column:
   539   "(A::'a::comm_semiring_1^'n^_) *v x = setsum (\<lambda>i. (x$i) *s ((transpose A)$i)) (UNIV:: 'n set)"
   540   by (simp add: matrix_vector_mult_def transpose_def vec_eq_iff mult_commute)
   541 
   542 lemma adjoint_matrix: "adjoint(\<lambda>x. (A::real^'n^'m) *v x) = (\<lambda>x. transpose A *v x)"
   543   apply (rule adjoint_unique)
   544   apply (simp add: transpose_def inner_vec_def matrix_vector_mult_def
   545     setsum_left_distrib setsum_right_distrib)
   546   apply (subst setsum_commute)
   547   apply (auto simp add: mult_ac)
   548   done
   549 
   550 lemma matrix_adjoint: assumes lf: "linear (f :: real^'n \<Rightarrow> real ^'m)"
   551   shows "matrix(adjoint f) = transpose(matrix f)"
   552   apply (subst matrix_vector_mul[OF lf])
   553   unfolding adjoint_matrix matrix_of_matrix_vector_mul
   554   apply rule
   555   done
   556 
   557 
   558 subsection {* lambda skolemization on cartesian products *}
   559 
   560 (* FIXME: rename do choice_cart *)
   561 
   562 lemma lambda_skolem: "(\<forall>i. \<exists>x. P i x) \<longleftrightarrow>
   563    (\<exists>x::'a ^ 'n. \<forall>i. P i (x $ i))" (is "?lhs \<longleftrightarrow> ?rhs")
   564 proof -
   565   let ?S = "(UNIV :: 'n set)"
   566   { assume H: "?rhs"
   567     then have ?lhs by auto }
   568   moreover
   569   { assume H: "?lhs"
   570     then obtain f where f:"\<forall>i. P i (f i)" unfolding choice_iff by metis
   571     let ?x = "(\<chi> i. (f i)) :: 'a ^ 'n"
   572     { fix i
   573       from f have "P i (f i)" by metis
   574       then have "P i (?x $ i)" by auto
   575     }
   576     hence "\<forall>i. P i (?x$i)" by metis
   577     hence ?rhs by metis }
   578   ultimately show ?thesis by metis
   579 qed
   580 
   581 lemma vector_sub_project_orthogonal_cart: "(b::real^'n) \<bullet> (x - ((b \<bullet> x) / (b \<bullet> b)) *s b) = 0"
   582   unfolding inner_simps scalar_mult_eq_scaleR by auto
   583 
   584 lemma left_invertible_transpose:
   585   "(\<exists>(B). B ** transpose (A) = mat (1::'a::comm_semiring_1)) \<longleftrightarrow> (\<exists>(B). A ** B = mat 1)"
   586   by (metis matrix_transpose_mul transpose_mat transpose_transpose)
   587 
   588 lemma right_invertible_transpose:
   589   "(\<exists>(B). transpose (A) ** B = mat (1::'a::comm_semiring_1)) \<longleftrightarrow> (\<exists>(B). B ** A = mat 1)"
   590   by (metis matrix_transpose_mul transpose_mat transpose_transpose)
   591 
   592 lemma matrix_left_invertible_injective:
   593   "(\<exists>B. (B::real^'m^'n) ** (A::real^'n^'m) = mat 1) \<longleftrightarrow> (\<forall>x y. A *v x = A *v y \<longrightarrow> x = y)"
   594 proof -
   595   { fix B:: "real^'m^'n" and x y assume B: "B ** A = mat 1" and xy: "A *v x = A*v y"
   596     from xy have "B*v (A *v x) = B *v (A*v y)" by simp
   597     hence "x = y"
   598       unfolding matrix_vector_mul_assoc B matrix_vector_mul_lid . }
   599   moreover
   600   { assume A: "\<forall>x y. A *v x = A *v y \<longrightarrow> x = y"
   601     hence i: "inj (op *v A)" unfolding inj_on_def by auto
   602     from linear_injective_left_inverse[OF matrix_vector_mul_linear i]
   603     obtain g where g: "linear g" "g o op *v A = id" by blast
   604     have "matrix g ** A = mat 1"
   605       unfolding matrix_eq matrix_vector_mul_lid matrix_vector_mul_assoc[symmetric] matrix_works[OF g(1)]
   606       using g(2) by (simp add: fun_eq_iff)
   607     then have "\<exists>B. (B::real ^'m^'n) ** A = mat 1" by blast }
   608   ultimately show ?thesis by blast
   609 qed
   610 
   611 lemma matrix_left_invertible_ker:
   612   "(\<exists>B. (B::real ^'m^'n) ** (A::real^'n^'m) = mat 1) \<longleftrightarrow> (\<forall>x. A *v x = 0 \<longrightarrow> x = 0)"
   613   unfolding matrix_left_invertible_injective
   614   using linear_injective_0[OF matrix_vector_mul_linear, of A]
   615   by (simp add: inj_on_def)
   616 
   617 lemma matrix_right_invertible_surjective:
   618   "(\<exists>B. (A::real^'n^'m) ** (B::real^'m^'n) = mat 1) \<longleftrightarrow> surj (\<lambda>x. A *v x)"
   619 proof -
   620   { fix B :: "real ^'m^'n"
   621     assume AB: "A ** B = mat 1"
   622     { fix x :: "real ^ 'm"
   623       have "A *v (B *v x) = x"
   624         by (simp add: matrix_vector_mul_lid matrix_vector_mul_assoc AB) }
   625     hence "surj (op *v A)" unfolding surj_def by metis }
   626   moreover
   627   { assume sf: "surj (op *v A)"
   628     from linear_surjective_right_inverse[OF matrix_vector_mul_linear sf]
   629     obtain g:: "real ^'m \<Rightarrow> real ^'n" where g: "linear g" "op *v A o g = id"
   630       by blast
   631 
   632     have "A ** (matrix g) = mat 1"
   633       unfolding matrix_eq  matrix_vector_mul_lid
   634         matrix_vector_mul_assoc[symmetric] matrix_works[OF g(1)]
   635       using g(2) unfolding o_def fun_eq_iff id_def
   636       .
   637     hence "\<exists>B. A ** (B::real^'m^'n) = mat 1" by blast
   638   }
   639   ultimately show ?thesis unfolding surj_def by blast
   640 qed
   641 
   642 lemma matrix_left_invertible_independent_columns:
   643   fixes A :: "real^'n^'m"
   644   shows "(\<exists>(B::real ^'m^'n). B ** A = mat 1) \<longleftrightarrow>
   645       (\<forall>c. setsum (\<lambda>i. c i *s column i A) (UNIV :: 'n set) = 0 \<longrightarrow> (\<forall>i. c i = 0))"
   646     (is "?lhs \<longleftrightarrow> ?rhs")
   647 proof -
   648   let ?U = "UNIV :: 'n set"
   649   { assume k: "\<forall>x. A *v x = 0 \<longrightarrow> x = 0"
   650     { fix c i
   651       assume c: "setsum (\<lambda>i. c i *s column i A) ?U = 0" and i: "i \<in> ?U"
   652       let ?x = "\<chi> i. c i"
   653       have th0:"A *v ?x = 0"
   654         using c
   655         unfolding matrix_mult_vsum vec_eq_iff
   656         by auto
   657       from k[rule_format, OF th0] i
   658       have "c i = 0" by (vector vec_eq_iff)}
   659     hence ?rhs by blast }
   660   moreover
   661   { assume H: ?rhs
   662     { fix x assume x: "A *v x = 0"
   663       let ?c = "\<lambda>i. ((x$i ):: real)"
   664       from H[rule_format, of ?c, unfolded matrix_mult_vsum[symmetric], OF x]
   665       have "x = 0" by vector }
   666   }
   667   ultimately show ?thesis unfolding matrix_left_invertible_ker by blast
   668 qed
   669 
   670 lemma matrix_right_invertible_independent_rows:
   671   fixes A :: "real^'n^'m"
   672   shows "(\<exists>(B::real^'m^'n). A ** B = mat 1) \<longleftrightarrow>
   673     (\<forall>c. setsum (\<lambda>i. c i *s row i A) (UNIV :: 'm set) = 0 \<longrightarrow> (\<forall>i. c i = 0))"
   674   unfolding left_invertible_transpose[symmetric]
   675     matrix_left_invertible_independent_columns
   676   by (simp add: column_transpose)
   677 
   678 lemma matrix_right_invertible_span_columns:
   679   "(\<exists>(B::real ^'n^'m). (A::real ^'m^'n) ** B = mat 1) \<longleftrightarrow>
   680     span (columns A) = UNIV" (is "?lhs = ?rhs")
   681 proof -
   682   let ?U = "UNIV :: 'm set"
   683   have fU: "finite ?U" by simp
   684   have lhseq: "?lhs \<longleftrightarrow> (\<forall>y. \<exists>(x::real^'m). setsum (\<lambda>i. (x$i) *s column i A) ?U = y)"
   685     unfolding matrix_right_invertible_surjective matrix_mult_vsum surj_def
   686     apply (subst eq_commute)
   687     apply rule
   688     done
   689   have rhseq: "?rhs \<longleftrightarrow> (\<forall>x. x \<in> span (columns A))" by blast
   690   { assume h: ?lhs
   691     { fix x:: "real ^'n"
   692       from h[unfolded lhseq, rule_format, of x] obtain y :: "real ^'m"
   693         where y: "setsum (\<lambda>i. (y$i) *s column i A) ?U = x" by blast
   694       have "x \<in> span (columns A)"
   695         unfolding y[symmetric]
   696         apply (rule span_setsum[OF fU])
   697         apply clarify
   698         unfolding scalar_mult_eq_scaleR
   699         apply (rule span_mul)
   700         apply (rule span_superset)
   701         unfolding columns_def
   702         apply blast
   703         done
   704     }
   705     then have ?rhs unfolding rhseq by blast }
   706   moreover
   707   { assume h:?rhs
   708     let ?P = "\<lambda>(y::real ^'n). \<exists>(x::real^'m). setsum (\<lambda>i. (x$i) *s column i A) ?U = y"
   709     { fix y
   710       have "?P y"
   711       proof (rule span_induct_alt[of ?P "columns A", folded scalar_mult_eq_scaleR])
   712         show "\<exists>x\<Colon>real ^ 'm. setsum (\<lambda>i. (x$i) *s column i A) ?U = 0"
   713           by (rule exI[where x=0], simp)
   714       next
   715         fix c y1 y2
   716         assume y1: "y1 \<in> columns A" and y2: "?P y2"
   717         from y1 obtain i where i: "i \<in> ?U" "y1 = column i A"
   718           unfolding columns_def by blast
   719         from y2 obtain x:: "real ^'m" where
   720           x: "setsum (\<lambda>i. (x$i) *s column i A) ?U = y2" by blast
   721         let ?x = "(\<chi> j. if j = i then c + (x$i) else (x$j))::real^'m"
   722         show "?P (c*s y1 + y2)"
   723         proof (rule exI[where x= "?x"], vector, auto simp add: i x[symmetric] if_distrib distrib_left cond_application_beta cong del: if_weak_cong)
   724           fix j
   725           have th: "\<forall>xa \<in> ?U. (if xa = i then (c + (x$i)) * ((column xa A)$j)
   726               else (x$xa) * ((column xa A$j))) = (if xa = i then c * ((column i A)$j) else 0) + ((x$xa) * ((column xa A)$j))"
   727             using i(1) by (simp add: field_simps)
   728           have "setsum (\<lambda>xa. if xa = i then (c + (x$i)) * ((column xa A)$j)
   729               else (x$xa) * ((column xa A$j))) ?U = setsum (\<lambda>xa. (if xa = i then c * ((column i A)$j) else 0) + ((x$xa) * ((column xa A)$j))) ?U"
   730             apply (rule setsum_cong[OF refl])
   731             using th apply blast
   732             done
   733           also have "\<dots> = setsum (\<lambda>xa. if xa = i then c * ((column i A)$j) else 0) ?U + setsum (\<lambda>xa. ((x$xa) * ((column xa A)$j))) ?U"
   734             by (simp add: setsum_addf)
   735           also have "\<dots> = c * ((column i A)$j) + setsum (\<lambda>xa. ((x$xa) * ((column xa A)$j))) ?U"
   736             unfolding setsum_delta[OF fU]
   737             using i(1) by simp
   738           finally show "setsum (\<lambda>xa. if xa = i then (c + (x$i)) * ((column xa A)$j)
   739             else (x$xa) * ((column xa A$j))) ?U = c * ((column i A)$j) + setsum (\<lambda>xa. ((x$xa) * ((column xa A)$j))) ?U" .
   740         qed
   741       next
   742         show "y \<in> span (columns A)"
   743           unfolding h by blast
   744       qed
   745     }
   746     then have ?lhs unfolding lhseq ..
   747   }
   748   ultimately show ?thesis by blast
   749 qed
   750 
   751 lemma matrix_left_invertible_span_rows:
   752   "(\<exists>(B::real^'m^'n). B ** (A::real^'n^'m) = mat 1) \<longleftrightarrow> span (rows A) = UNIV"
   753   unfolding right_invertible_transpose[symmetric]
   754   unfolding columns_transpose[symmetric]
   755   unfolding matrix_right_invertible_span_columns
   756   ..
   757 
   758 text {* The same result in terms of square matrices. *}
   759 
   760 lemma matrix_left_right_inverse:
   761   fixes A A' :: "real ^'n^'n"
   762   shows "A ** A' = mat 1 \<longleftrightarrow> A' ** A = mat 1"
   763 proof -
   764   { fix A A' :: "real ^'n^'n"
   765     assume AA': "A ** A' = mat 1"
   766     have sA: "surj (op *v A)"
   767       unfolding surj_def
   768       apply clarify
   769       apply (rule_tac x="(A' *v y)" in exI)
   770       apply (simp add: matrix_vector_mul_assoc AA' matrix_vector_mul_lid)
   771       done
   772     from linear_surjective_isomorphism[OF matrix_vector_mul_linear sA]
   773     obtain f' :: "real ^'n \<Rightarrow> real ^'n"
   774       where f': "linear f'" "\<forall>x. f' (A *v x) = x" "\<forall>x. A *v f' x = x" by blast
   775     have th: "matrix f' ** A = mat 1"
   776       by (simp add: matrix_eq matrix_works[OF f'(1)]
   777           matrix_vector_mul_assoc[symmetric] matrix_vector_mul_lid f'(2)[rule_format])
   778     hence "(matrix f' ** A) ** A' = mat 1 ** A'" by simp
   779     hence "matrix f' = A'"
   780       by (simp add: matrix_mul_assoc[symmetric] AA' matrix_mul_rid matrix_mul_lid)
   781     hence "matrix f' ** A = A' ** A" by simp
   782     hence "A' ** A = mat 1" by (simp add: th)
   783   }
   784   then show ?thesis by blast
   785 qed
   786 
   787 text {* Considering an n-element vector as an n-by-1 or 1-by-n matrix. *}
   788 
   789 definition "rowvector v = (\<chi> i j. (v$j))"
   790 
   791 definition "columnvector v = (\<chi> i j. (v$i))"
   792 
   793 lemma transpose_columnvector: "transpose(columnvector v) = rowvector v"
   794   by (simp add: transpose_def rowvector_def columnvector_def vec_eq_iff)
   795 
   796 lemma transpose_rowvector: "transpose(rowvector v) = columnvector v"
   797   by (simp add: transpose_def columnvector_def rowvector_def vec_eq_iff)
   798 
   799 lemma dot_rowvector_columnvector: "columnvector (A *v v) = A ** columnvector v"
   800   by (vector columnvector_def matrix_matrix_mult_def matrix_vector_mult_def)
   801 
   802 lemma dot_matrix_product:
   803   "(x::real^'n) \<bullet> y = (((rowvector x ::real^'n^1) ** (columnvector y :: real^1^'n))$1)$1"
   804   by (vector matrix_matrix_mult_def rowvector_def columnvector_def inner_vec_def)
   805 
   806 lemma dot_matrix_vector_mul:
   807   fixes A B :: "real ^'n ^'n" and x y :: "real ^'n"
   808   shows "(A *v x) \<bullet> (B *v y) =
   809       (((rowvector x :: real^'n^1) ** ((transpose A ** B) ** (columnvector y :: real ^1^'n)))$1)$1"
   810   unfolding dot_matrix_product transpose_columnvector[symmetric]
   811     dot_rowvector_columnvector matrix_transpose_mul matrix_mul_assoc ..
   812 
   813 
   814 lemma infnorm_cart:"infnorm (x::real^'n) = Sup {abs(x$i) |i. i\<in>UNIV}"
   815   by (simp add: infnorm_def inner_axis Basis_vec_def) (metis (lifting) inner_axis real_inner_1_right)
   816 
   817 lemma component_le_infnorm_cart: "\<bar>x$i\<bar> \<le> infnorm (x::real^'n)"
   818   using Basis_le_infnorm[of "axis i 1" x]
   819   by (simp add: Basis_vec_def axis_eq_axis inner_axis)
   820 
   821 lemma continuous_component: "continuous F f \<Longrightarrow> continuous F (\<lambda>x. f x $ i)"
   822   unfolding continuous_def by (rule tendsto_vec_nth)
   823 
   824 lemma continuous_on_component: "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. f x $ i)"
   825   unfolding continuous_on_def by (fast intro: tendsto_vec_nth)
   826 
   827 lemma closed_positive_orthant: "closed {x::real^'n. \<forall>i. 0 \<le>x$i}"
   828   by (simp add: Collect_all_eq closed_INT closed_Collect_le)
   829 
   830 lemma bounded_component_cart: "bounded s \<Longrightarrow> bounded ((\<lambda>x. x $ i) ` s)"
   831   unfolding bounded_def
   832   apply clarify
   833   apply (rule_tac x="x $ i" in exI)
   834   apply (rule_tac x="e" in exI)
   835   apply clarify
   836   apply (rule order_trans [OF dist_vec_nth_le], simp)
   837   done
   838 
   839 lemma compact_lemma_cart:
   840   fixes f :: "nat \<Rightarrow> 'a::heine_borel ^ 'n"
   841   assumes f: "bounded (range f)"
   842   shows "\<forall>d.
   843         \<exists>l r. subseq r \<and>
   844         (\<forall>e>0. eventually (\<lambda>n. \<forall>i\<in>d. dist (f (r n) $ i) (l $ i) < e) sequentially)"
   845 proof
   846   fix d :: "'n set"
   847   have "finite d" by simp
   848   thus "\<exists>l::'a ^ 'n. \<exists>r. subseq r \<and>
   849       (\<forall>e>0. eventually (\<lambda>n. \<forall>i\<in>d. dist (f (r n) $ i) (l $ i) < e) sequentially)"
   850   proof (induct d)
   851     case empty
   852     thus ?case unfolding subseq_def by auto
   853   next
   854     case (insert k d)
   855     obtain l1::"'a^'n" and r1 where r1:"subseq r1"
   856       and lr1:"\<forall>e>0. eventually (\<lambda>n. \<forall>i\<in>d. dist (f (r1 n) $ i) (l1 $ i) < e) sequentially"
   857       using insert(3) by auto
   858     have s': "bounded ((\<lambda>x. x $ k) ` range f)" using `bounded (range f)`
   859       by (auto intro!: bounded_component_cart)
   860     have f': "\<forall>n. f (r1 n) $ k \<in> (\<lambda>x. x $ k) ` range f" by simp
   861     have "bounded (range (\<lambda>i. f (r1 i) $ k))"
   862       by (metis (lifting) bounded_subset image_subsetI f' s')
   863     then obtain l2 r2 where r2: "subseq r2"
   864       and lr2: "((\<lambda>i. f (r1 (r2 i)) $ k) ---> l2) sequentially"
   865       using bounded_imp_convergent_subsequence[of "\<lambda>i. f (r1 i) $ k"] by (auto simp: o_def)
   866     def r \<equiv> "r1 \<circ> r2"
   867     have r: "subseq r"
   868       using r1 and r2 unfolding r_def o_def subseq_def by auto
   869     moreover
   870     def l \<equiv> "(\<chi> i. if i = k then l2 else l1$i)::'a^'n"
   871     { fix e :: real assume "e > 0"
   872       from lr1 `e>0` have N1:"eventually (\<lambda>n. \<forall>i\<in>d. dist (f (r1 n) $ i) (l1 $ i) < e) sequentially"
   873         by blast
   874       from lr2 `e>0` have N2:"eventually (\<lambda>n. dist (f (r1 (r2 n)) $ k) l2 < e) sequentially"
   875         by (rule tendstoD)
   876       from r2 N1 have N1': "eventually (\<lambda>n. \<forall>i\<in>d. dist (f (r1 (r2 n)) $ i) (l1 $ i) < e) sequentially"
   877         by (rule eventually_subseq)
   878       have "eventually (\<lambda>n. \<forall>i\<in>(insert k d). dist (f (r n) $ i) (l $ i) < e) sequentially"
   879         using N1' N2 by (rule eventually_elim2, simp add: l_def r_def)
   880     }
   881     ultimately show ?case by auto
   882   qed
   883 qed
   884 
   885 instance vec :: (heine_borel, finite) heine_borel
   886 proof
   887   fix f :: "nat \<Rightarrow> 'a ^ 'b"
   888   assume f: "bounded (range f)"
   889   then obtain l r where r: "subseq r"
   890       and l: "\<forall>e>0. eventually (\<lambda>n. \<forall>i\<in>UNIV. dist (f (r n) $ i) (l $ i) < e) sequentially"
   891     using compact_lemma_cart [OF f] by blast
   892   let ?d = "UNIV::'b set"
   893   { fix e::real assume "e>0"
   894     hence "0 < e / (real_of_nat (card ?d))"
   895       using zero_less_card_finite divide_pos_pos[of e, of "real_of_nat (card ?d)"] by auto
   896     with l have "eventually (\<lambda>n. \<forall>i. dist (f (r n) $ i) (l $ i) < e / (real_of_nat (card ?d))) sequentially"
   897       by simp
   898     moreover
   899     { fix n
   900       assume n: "\<forall>i. dist (f (r n) $ i) (l $ i) < e / (real_of_nat (card ?d))"
   901       have "dist (f (r n)) l \<le> (\<Sum>i\<in>?d. dist (f (r n) $ i) (l $ i))"
   902         unfolding dist_vec_def using zero_le_dist by (rule setL2_le_setsum)
   903       also have "\<dots> < (\<Sum>i\<in>?d. e / (real_of_nat (card ?d)))"
   904         by (rule setsum_strict_mono) (simp_all add: n)
   905       finally have "dist (f (r n)) l < e" by simp
   906     }
   907     ultimately have "eventually (\<lambda>n. dist (f (r n)) l < e) sequentially"
   908       by (rule eventually_elim1)
   909   }
   910   hence "((f \<circ> r) ---> l) sequentially" unfolding o_def tendsto_iff by simp
   911   with r show "\<exists>l r. subseq r \<and> ((f \<circ> r) ---> l) sequentially" by auto
   912 qed
   913 
   914 lemma interval_cart:
   915   fixes a :: "real^'n"
   916   shows "box a b = {x::real^'n. \<forall>i. a$i < x$i \<and> x$i < b$i}"
   917     and "cbox a b = {x::real^'n. \<forall>i. a$i \<le> x$i \<and> x$i \<le> b$i}"
   918   by (auto simp add: set_eq_iff less_vec_def less_eq_vec_def mem_box Basis_vec_def inner_axis)
   919 
   920 lemma mem_interval_cart:
   921   fixes a :: "real^'n"
   922   shows "x \<in> box a b \<longleftrightarrow> (\<forall>i. a$i < x$i \<and> x$i < b$i)"
   923     and "x \<in> cbox a b \<longleftrightarrow> (\<forall>i. a$i \<le> x$i \<and> x$i \<le> b$i)"
   924   using interval_cart[of a b] by (auto simp add: set_eq_iff less_vec_def less_eq_vec_def)
   925 
   926 lemma interval_eq_empty_cart:
   927   fixes a :: "real^'n"
   928   shows "(box a b = {} \<longleftrightarrow> (\<exists>i. b$i \<le> a$i))" (is ?th1)
   929     and "(cbox a b = {} \<longleftrightarrow> (\<exists>i. b$i < a$i))" (is ?th2)
   930 proof -
   931   { fix i x assume as:"b$i \<le> a$i" and x:"x\<in>box a b"
   932     hence "a $ i < x $ i \<and> x $ i < b $ i" unfolding mem_interval_cart by auto
   933     hence "a$i < b$i" by auto
   934     hence False using as by auto }
   935   moreover
   936   { assume as:"\<forall>i. \<not> (b$i \<le> a$i)"
   937     let ?x = "(1/2) *\<^sub>R (a + b)"
   938     { fix i
   939       have "a$i < b$i" using as[THEN spec[where x=i]] by auto
   940       hence "a$i < ((1/2) *\<^sub>R (a+b)) $ i" "((1/2) *\<^sub>R (a+b)) $ i < b$i"
   941         unfolding vector_smult_component and vector_add_component
   942         by auto }
   943     hence "box a b \<noteq> {}" using mem_interval_cart(1)[of "?x" a b] by auto }
   944   ultimately show ?th1 by blast
   945 
   946   { fix i x assume as:"b$i < a$i" and x:"x\<in>cbox a b"
   947     hence "a $ i \<le> x $ i \<and> x $ i \<le> b $ i" unfolding mem_interval_cart by auto
   948     hence "a$i \<le> b$i" by auto
   949     hence False using as by auto }
   950   moreover
   951   { assume as:"\<forall>i. \<not> (b$i < a$i)"
   952     let ?x = "(1/2) *\<^sub>R (a + b)"
   953     { fix i
   954       have "a$i \<le> b$i" using as[THEN spec[where x=i]] by auto
   955       hence "a$i \<le> ((1/2) *\<^sub>R (a+b)) $ i" "((1/2) *\<^sub>R (a+b)) $ i \<le> b$i"
   956         unfolding vector_smult_component and vector_add_component
   957         by auto }
   958     hence "cbox a b \<noteq> {}" using mem_interval_cart(2)[of "?x" a b] by auto  }
   959   ultimately show ?th2 by blast
   960 qed
   961 
   962 lemma interval_ne_empty_cart:
   963   fixes a :: "real^'n"
   964   shows "cbox a b \<noteq> {} \<longleftrightarrow> (\<forall>i. a$i \<le> b$i)"
   965     and "box a b \<noteq> {} \<longleftrightarrow> (\<forall>i. a$i < b$i)"
   966   unfolding interval_eq_empty_cart[of a b] by (auto simp add: not_less not_le)
   967     (* BH: Why doesn't just "auto" work here? *)
   968 
   969 lemma subset_interval_imp_cart:
   970   fixes a :: "real^'n"
   971   shows "(\<forall>i. a$i \<le> c$i \<and> d$i \<le> b$i) \<Longrightarrow> cbox c d \<subseteq> cbox a b"
   972     and "(\<forall>i. a$i < c$i \<and> d$i < b$i) \<Longrightarrow> cbox c d \<subseteq> box a b"
   973     and "(\<forall>i. a$i \<le> c$i \<and> d$i \<le> b$i) \<Longrightarrow> box c d \<subseteq> cbox a b"
   974     and "(\<forall>i. a$i \<le> c$i \<and> d$i \<le> b$i) \<Longrightarrow> box c d \<subseteq> box a b"
   975   unfolding subset_eq[unfolded Ball_def] unfolding mem_interval_cart
   976   by (auto intro: order_trans less_le_trans le_less_trans less_imp_le) (* BH: Why doesn't just "auto" work here? *)
   977 
   978 lemma interval_sing:
   979   fixes a :: "'a::linorder^'n"
   980   shows "{a .. a} = {a} \<and> {a<..<a} = {}"
   981   apply (auto simp add: set_eq_iff less_vec_def less_eq_vec_def vec_eq_iff)
   982   done
   983 
   984 lemma subset_interval_cart:
   985   fixes a :: "real^'n"
   986   shows "cbox c d \<subseteq> cbox a b \<longleftrightarrow> (\<forall>i. c$i \<le> d$i) --> (\<forall>i. a$i \<le> c$i \<and> d$i \<le> b$i)" (is ?th1)
   987     and "cbox c d \<subseteq> box a b \<longleftrightarrow> (\<forall>i. c$i \<le> d$i) --> (\<forall>i. a$i < c$i \<and> d$i < b$i)" (is ?th2)
   988     and "box c d \<subseteq> cbox a b \<longleftrightarrow> (\<forall>i. c$i < d$i) --> (\<forall>i. a$i \<le> c$i \<and> d$i \<le> b$i)" (is ?th3)
   989     and "box c d \<subseteq> box a b \<longleftrightarrow> (\<forall>i. c$i < d$i) --> (\<forall>i. a$i \<le> c$i \<and> d$i \<le> b$i)" (is ?th4)
   990   using subset_box[of c d a b] by (simp_all add: Basis_vec_def inner_axis)
   991 
   992 lemma disjoint_interval_cart:
   993   fixes a::"real^'n"
   994   shows "cbox a b \<inter> cbox c d = {} \<longleftrightarrow> (\<exists>i. (b$i < a$i \<or> d$i < c$i \<or> b$i < c$i \<or> d$i < a$i))" (is ?th1)
   995     and "cbox a b \<inter> box c d = {} \<longleftrightarrow> (\<exists>i. (b$i < a$i \<or> d$i \<le> c$i \<or> b$i \<le> c$i \<or> d$i \<le> a$i))" (is ?th2)
   996     and "box a b \<inter> cbox c d = {} \<longleftrightarrow> (\<exists>i. (b$i \<le> a$i \<or> d$i < c$i \<or> b$i \<le> c$i \<or> d$i \<le> a$i))" (is ?th3)
   997     and "box a b \<inter> box c d = {} \<longleftrightarrow> (\<exists>i. (b$i \<le> a$i \<or> d$i \<le> c$i \<or> b$i \<le> c$i \<or> d$i \<le> a$i))" (is ?th4)
   998   using disjoint_interval[of a b c d] by (simp_all add: Basis_vec_def inner_axis)
   999 
  1000 lemma inter_interval_cart:
  1001   fixes a :: "real^'n"
  1002   shows "cbox a b \<inter> cbox c d =  {(\<chi> i. max (a$i) (c$i)) .. (\<chi> i. min (b$i) (d$i))}"
  1003   unfolding inter_interval
  1004   by (auto simp: mem_box less_eq_vec_def)
  1005     (auto simp: Basis_vec_def inner_axis)
  1006 
  1007 lemma closed_interval_left_cart:
  1008   fixes b :: "real^'n"
  1009   shows "closed {x::real^'n. \<forall>i. x$i \<le> b$i}"
  1010   by (simp add: Collect_all_eq closed_INT closed_Collect_le)
  1011 
  1012 lemma closed_interval_right_cart:
  1013   fixes a::"real^'n"
  1014   shows "closed {x::real^'n. \<forall>i. a$i \<le> x$i}"
  1015   by (simp add: Collect_all_eq closed_INT closed_Collect_le)
  1016 
  1017 lemma is_interval_cart:
  1018   "is_interval (s::(real^'n) set) \<longleftrightarrow>
  1019     (\<forall>a\<in>s. \<forall>b\<in>s. \<forall>x. (\<forall>i. ((a$i \<le> x$i \<and> x$i \<le> b$i) \<or> (b$i \<le> x$i \<and> x$i \<le> a$i))) \<longrightarrow> x \<in> s)"
  1020   by (simp add: is_interval_def Ball_def Basis_vec_def inner_axis imp_ex)
  1021 
  1022 lemma closed_halfspace_component_le_cart: "closed {x::real^'n. x$i \<le> a}"
  1023   by (simp add: closed_Collect_le)
  1024 
  1025 lemma closed_halfspace_component_ge_cart: "closed {x::real^'n. x$i \<ge> a}"
  1026   by (simp add: closed_Collect_le)
  1027 
  1028 lemma open_halfspace_component_lt_cart: "open {x::real^'n. x$i < a}"
  1029   by (simp add: open_Collect_less)
  1030 
  1031 lemma open_halfspace_component_gt_cart: "open {x::real^'n. x$i  > a}"
  1032   by (simp add: open_Collect_less)
  1033 
  1034 lemma Lim_component_le_cart:
  1035   fixes f :: "'a \<Rightarrow> real^'n"
  1036   assumes "(f ---> l) net" "\<not> (trivial_limit net)"  "eventually (\<lambda>x. f x $i \<le> b) net"
  1037   shows "l$i \<le> b"
  1038   by (rule tendsto_le[OF assms(2) tendsto_const tendsto_vec_nth, OF assms(1, 3)])
  1039 
  1040 lemma Lim_component_ge_cart:
  1041   fixes f :: "'a \<Rightarrow> real^'n"
  1042   assumes "(f ---> l) net"  "\<not> (trivial_limit net)"  "eventually (\<lambda>x. b \<le> (f x)$i) net"
  1043   shows "b \<le> l$i"
  1044   by (rule tendsto_le[OF assms(2) tendsto_vec_nth tendsto_const, OF assms(1, 3)])
  1045 
  1046 lemma Lim_component_eq_cart:
  1047   fixes f :: "'a \<Rightarrow> real^'n"
  1048   assumes net: "(f ---> l) net" "~(trivial_limit net)" and ev:"eventually (\<lambda>x. f(x)$i = b) net"
  1049   shows "l$i = b"
  1050   using ev[unfolded order_eq_iff eventually_conj_iff] and
  1051     Lim_component_ge_cart[OF net, of b i] and
  1052     Lim_component_le_cart[OF net, of i b] by auto
  1053 
  1054 lemma connected_ivt_component_cart:
  1055   fixes x :: "real^'n"
  1056   shows "connected s \<Longrightarrow> x \<in> s \<Longrightarrow> y \<in> s \<Longrightarrow> x$k \<le> a \<Longrightarrow> a \<le> y$k \<Longrightarrow> (\<exists>z\<in>s.  z$k = a)"
  1057   using connected_ivt_hyperplane[of s x y "axis k 1" a]
  1058   by (auto simp add: inner_axis inner_commute)
  1059 
  1060 lemma subspace_substandard_cart: "subspace {x::real^_. (\<forall>i. P i \<longrightarrow> x$i = 0)}"
  1061   unfolding subspace_def by auto
  1062 
  1063 lemma closed_substandard_cart:
  1064   "closed {x::'a::real_normed_vector ^ 'n. \<forall>i. P i \<longrightarrow> x$i = 0}"
  1065 proof -
  1066   { fix i::'n
  1067     have "closed {x::'a ^ 'n. P i \<longrightarrow> x$i = 0}"
  1068       by (cases "P i") (simp_all add: closed_Collect_eq) }
  1069   thus ?thesis
  1070     unfolding Collect_all_eq by (simp add: closed_INT)
  1071 qed
  1072 
  1073 lemma dim_substandard_cart: "dim {x::real^'n. \<forall>i. i \<notin> d \<longrightarrow> x$i = 0} = card d"
  1074   (is "dim ?A = _")
  1075 proof -
  1076   let ?a = "\<lambda>x. axis x 1 :: real^'n"
  1077   have *: "{x. \<forall>i\<in>Basis. i \<notin> ?a ` d \<longrightarrow> x \<bullet> i = 0} = ?A"
  1078     by (auto simp: image_iff Basis_vec_def axis_eq_axis inner_axis)
  1079   have "?a ` d \<subseteq> Basis"
  1080     by (auto simp: Basis_vec_def)
  1081   thus ?thesis
  1082     using dim_substandard[of "?a ` d"] card_image[of ?a d]
  1083     by (auto simp: axis_eq_axis inj_on_def *)
  1084 qed
  1085 
  1086 lemma affinity_inverses:
  1087   assumes m0: "m \<noteq> (0::'a::field)"
  1088   shows "(\<lambda>x. m *s x + c) o (\<lambda>x. inverse(m) *s x + (-(inverse(m) *s c))) = id"
  1089   "(\<lambda>x. inverse(m) *s x + (-(inverse(m) *s c))) o (\<lambda>x. m *s x + c) = id"
  1090   using m0
  1091   apply (auto simp add: fun_eq_iff vector_add_ldistrib diff_conv_add_uminus simp del: add_uminus_conv_diff)
  1092   apply (simp_all add: vector_smult_lneg[symmetric] vector_smult_assoc vector_sneg_minus1 [symmetric])
  1093   done
  1094 
  1095 lemma vector_affinity_eq:
  1096   assumes m0: "(m::'a::field) \<noteq> 0"
  1097   shows "m *s x + c = y \<longleftrightarrow> x = inverse m *s y + -(inverse m *s c)"
  1098 proof
  1099   assume h: "m *s x + c = y"
  1100   hence "m *s x = y - c" by (simp add: field_simps)
  1101   hence "inverse m *s (m *s x) = inverse m *s (y - c)" by simp
  1102   then show "x = inverse m *s y + - (inverse m *s c)"
  1103     using m0 by (simp add: vector_smult_assoc vector_ssub_ldistrib)
  1104 next
  1105   assume h: "x = inverse m *s y + - (inverse m *s c)"
  1106   show "m *s x + c = y" unfolding h
  1107     using m0 by (simp add: vector_smult_assoc vector_ssub_ldistrib)
  1108 qed
  1109 
  1110 lemma vector_eq_affinity:
  1111     "(m::'a::field) \<noteq> 0 ==> (y = m *s x + c \<longleftrightarrow> inverse(m) *s y + -(inverse(m) *s c) = x)"
  1112   using vector_affinity_eq[where m=m and x=x and y=y and c=c]
  1113   by metis
  1114 
  1115 lemma vector_cart:
  1116   fixes f :: "real^'n \<Rightarrow> real"
  1117   shows "(\<chi> i. f (axis i 1)) = (\<Sum>i\<in>Basis. f i *\<^sub>R i)"
  1118   unfolding euclidean_eq_iff[where 'a="real^'n"]
  1119   by simp (simp add: Basis_vec_def inner_axis)
  1120   
  1121 lemma const_vector_cart:"((\<chi> i. d)::real^'n) = (\<Sum>i\<in>Basis. d *\<^sub>R i)"
  1122   by (rule vector_cart)
  1123 
  1124 subsection "Convex Euclidean Space"
  1125 
  1126 lemma Cart_1:"(1::real^'n) = \<Sum>Basis"
  1127   using const_vector_cart[of 1] by (simp add: one_vec_def)
  1128 
  1129 declare vector_add_ldistrib[simp] vector_ssub_ldistrib[simp] vector_smult_assoc[simp] vector_smult_rneg[simp]
  1130 declare vector_sadd_rdistrib[simp] vector_sub_rdistrib[simp]
  1131 
  1132 lemmas vector_component_simps = vector_minus_component vector_smult_component vector_add_component less_eq_vec_def vec_lambda_beta vector_uminus_component
  1133 
  1134 lemma convex_box_cart:
  1135   assumes "\<And>i. convex {x. P i x}"
  1136   shows "convex {x. \<forall>i. P i (x$i)}"
  1137   using assms unfolding convex_def by auto
  1138 
  1139 lemma convex_positive_orthant_cart: "convex {x::real^'n. (\<forall>i. 0 \<le> x$i)}"
  1140   by (rule convex_box_cart) (simp add: atLeast_def[symmetric] convex_real_interval)
  1141 
  1142 lemma unit_interval_convex_hull_cart:
  1143   "cbox (0::real^'n) 1 = convex hull {x. \<forall>i. (x$i = 0) \<or> (x$i = 1)}"
  1144   unfolding Cart_1 unit_interval_convex_hull[where 'a="real^'n"] box_real[symmetric]
  1145   by (rule arg_cong[where f="\<lambda>x. convex hull x"]) (simp add: Basis_vec_def inner_axis)
  1146 
  1147 lemma cube_convex_hull_cart:
  1148   assumes "0 < d"
  1149   obtains s::"(real^'n) set"
  1150     where "finite s" "cbox (x - (\<chi> i. d)) (x + (\<chi> i. d)) = convex hull s"
  1151 proof -
  1152   from assms obtain s where "finite s"
  1153     and "cbox (x - setsum (op *\<^sub>R d) Basis) (x + setsum (op *\<^sub>R d) Basis) = convex hull s"
  1154     by (rule cube_convex_hull)
  1155   with that[of s] show thesis
  1156     by (simp add: const_vector_cart)
  1157 qed
  1158 
  1159 
  1160 subsection "Derivative"
  1161 
  1162 lemma differentiable_at_imp_differentiable_on:
  1163   "(\<forall>x\<in>(s::(real^'n) set). f differentiable at x) \<Longrightarrow> f differentiable_on s"
  1164   by (metis differentiable_at_withinI differentiable_on_def)
  1165 
  1166 definition "jacobian f net = matrix(frechet_derivative f net)"
  1167 
  1168 lemma jacobian_works:
  1169   "(f::(real^'a) \<Rightarrow> (real^'b)) differentiable net \<longleftrightarrow>
  1170     (f has_derivative (\<lambda>h. (jacobian f net) *v h)) net"
  1171   apply rule
  1172   unfolding jacobian_def
  1173   apply (simp only: matrix_works[OF linear_frechet_derivative]) defer
  1174   apply (rule differentiableI)
  1175   apply assumption
  1176   unfolding frechet_derivative_works
  1177   apply assumption
  1178   done
  1179 
  1180 
  1181 subsection {* Component of the differential must be zero if it exists at a local
  1182   maximum or minimum for that corresponding component. *}
  1183 
  1184 lemma differential_zero_maxmin_cart:
  1185   fixes f::"real^'a \<Rightarrow> real^'b"
  1186   assumes "0 < e" "((\<forall>y \<in> ball x e. (f y)$k \<le> (f x)$k) \<or> (\<forall>y\<in>ball x e. (f x)$k \<le> (f y)$k))"
  1187     "f differentiable (at x)"
  1188   shows "jacobian f (at x) $ k = 0"
  1189   using differential_zero_maxmin_component[of "axis k 1" e x f] assms
  1190     vector_cart[of "\<lambda>j. frechet_derivative f (at x) j $ k"]
  1191   by (simp add: Basis_vec_def axis_eq_axis inner_axis jacobian_def matrix_def)
  1192 
  1193 subsection {* Lemmas for working on @{typ "real^1"} *}
  1194 
  1195 lemma forall_1[simp]: "(\<forall>i::1. P i) \<longleftrightarrow> P 1"
  1196   by (metis (full_types) num1_eq_iff)
  1197 
  1198 lemma ex_1[simp]: "(\<exists>x::1. P x) \<longleftrightarrow> P 1"
  1199   by auto (metis (full_types) num1_eq_iff)
  1200 
  1201 lemma exhaust_2:
  1202   fixes x :: 2
  1203   shows "x = 1 \<or> x = 2"
  1204 proof (induct x)
  1205   case (of_int z)
  1206   then have "0 <= z" and "z < 2" by simp_all
  1207   then have "z = 0 | z = 1" by arith
  1208   then show ?case by auto
  1209 qed
  1210 
  1211 lemma forall_2: "(\<forall>i::2. P i) \<longleftrightarrow> P 1 \<and> P 2"
  1212   by (metis exhaust_2)
  1213 
  1214 lemma exhaust_3:
  1215   fixes x :: 3
  1216   shows "x = 1 \<or> x = 2 \<or> x = 3"
  1217 proof (induct x)
  1218   case (of_int z)
  1219   then have "0 <= z" and "z < 3" by simp_all
  1220   then have "z = 0 \<or> z = 1 \<or> z = 2" by arith
  1221   then show ?case by auto
  1222 qed
  1223 
  1224 lemma forall_3: "(\<forall>i::3. P i) \<longleftrightarrow> P 1 \<and> P 2 \<and> P 3"
  1225   by (metis exhaust_3)
  1226 
  1227 lemma UNIV_1 [simp]: "UNIV = {1::1}"
  1228   by (auto simp add: num1_eq_iff)
  1229 
  1230 lemma UNIV_2: "UNIV = {1::2, 2::2}"
  1231   using exhaust_2 by auto
  1232 
  1233 lemma UNIV_3: "UNIV = {1::3, 2::3, 3::3}"
  1234   using exhaust_3 by auto
  1235 
  1236 lemma setsum_1: "setsum f (UNIV::1 set) = f 1"
  1237   unfolding UNIV_1 by simp
  1238 
  1239 lemma setsum_2: "setsum f (UNIV::2 set) = f 1 + f 2"
  1240   unfolding UNIV_2 by simp
  1241 
  1242 lemma setsum_3: "setsum f (UNIV::3 set) = f 1 + f 2 + f 3"
  1243   unfolding UNIV_3 by (simp add: add_ac)
  1244 
  1245 instantiation num1 :: cart_one
  1246 begin
  1247 
  1248 instance
  1249 proof
  1250   show "CARD(1) = Suc 0" by auto
  1251 qed
  1252 
  1253 end
  1254 
  1255 subsection{* The collapse of the general concepts to dimension one. *}
  1256 
  1257 lemma vector_one: "(x::'a ^1) = (\<chi> i. (x$1))"
  1258   by (simp add: vec_eq_iff)
  1259 
  1260 lemma forall_one: "(\<forall>(x::'a ^1). P x) \<longleftrightarrow> (\<forall>x. P(\<chi> i. x))"
  1261   apply auto
  1262   apply (erule_tac x= "x$1" in allE)
  1263   apply (simp only: vector_one[symmetric])
  1264   done
  1265 
  1266 lemma norm_vector_1: "norm (x :: _^1) = norm (x$1)"
  1267   by (simp add: norm_vec_def)
  1268 
  1269 lemma norm_real: "norm(x::real ^ 1) = abs(x$1)"
  1270   by (simp add: norm_vector_1)
  1271 
  1272 lemma dist_real: "dist(x::real ^ 1) y = abs((x$1) - (y$1))"
  1273   by (auto simp add: norm_real dist_norm)
  1274 
  1275 
  1276 subsection{* Explicit vector construction from lists. *}
  1277 
  1278 definition "vector l = (\<chi> i. foldr (\<lambda>x f n. fun_upd (f (n+1)) n x) l (\<lambda>n x. 0) 1 i)"
  1279 
  1280 lemma vector_1: "(vector[x]) $1 = x"
  1281   unfolding vector_def by simp
  1282 
  1283 lemma vector_2:
  1284  "(vector[x,y]) $1 = x"
  1285  "(vector[x,y] :: 'a^2)$2 = (y::'a::zero)"
  1286   unfolding vector_def by simp_all
  1287 
  1288 lemma vector_3:
  1289  "(vector [x,y,z] ::('a::zero)^3)$1 = x"
  1290  "(vector [x,y,z] ::('a::zero)^3)$2 = y"
  1291  "(vector [x,y,z] ::('a::zero)^3)$3 = z"
  1292   unfolding vector_def by simp_all
  1293 
  1294 lemma forall_vector_1: "(\<forall>v::'a::zero^1. P v) \<longleftrightarrow> (\<forall>x. P(vector[x]))"
  1295   apply auto
  1296   apply (erule_tac x="v$1" in allE)
  1297   apply (subgoal_tac "vector [v$1] = v")
  1298   apply simp
  1299   apply (vector vector_def)
  1300   apply simp
  1301   done
  1302 
  1303 lemma forall_vector_2: "(\<forall>v::'a::zero^2. P v) \<longleftrightarrow> (\<forall>x y. P(vector[x, y]))"
  1304   apply auto
  1305   apply (erule_tac x="v$1" in allE)
  1306   apply (erule_tac x="v$2" in allE)
  1307   apply (subgoal_tac "vector [v$1, v$2] = v")
  1308   apply simp
  1309   apply (vector vector_def)
  1310   apply (simp add: forall_2)
  1311   done
  1312 
  1313 lemma forall_vector_3: "(\<forall>v::'a::zero^3. P v) \<longleftrightarrow> (\<forall>x y z. P(vector[x, y, z]))"
  1314   apply auto
  1315   apply (erule_tac x="v$1" in allE)
  1316   apply (erule_tac x="v$2" in allE)
  1317   apply (erule_tac x="v$3" in allE)
  1318   apply (subgoal_tac "vector [v$1, v$2, v$3] = v")
  1319   apply simp
  1320   apply (vector vector_def)
  1321   apply (simp add: forall_3)
  1322   done
  1323 
  1324 lemma bounded_linear_component_cart[intro]: "bounded_linear (\<lambda>x::real^'n. x $ k)"
  1325   apply (rule bounded_linearI[where K=1])
  1326   using component_le_norm_cart[of _ k] unfolding real_norm_def by auto
  1327 
  1328 lemma integral_component_eq_cart[simp]:
  1329   fixes f :: "'n::euclidean_space \<Rightarrow> real^'m"
  1330   assumes "f integrable_on s"
  1331   shows "integral s (\<lambda>x. f x $ k) = integral s f $ k"
  1332   using integral_linear[OF assms(1) bounded_linear_component_cart,unfolded o_def] .
  1333 
  1334 lemma interval_split_cart:
  1335   "{a..b::real^'n} \<inter> {x. x$k \<le> c} = {a .. (\<chi> i. if i = k then min (b$k) c else b$i)}"
  1336   "cbox a b \<inter> {x. x$k \<ge> c} = {(\<chi> i. if i = k then max (a$k) c else a$i) .. b}"
  1337   apply (rule_tac[!] set_eqI)
  1338   unfolding Int_iff mem_interval_cart mem_Collect_eq interval_cbox_cart
  1339   unfolding vec_lambda_beta
  1340   by auto
  1341 
  1342 lemma interval_bij_bij_cart: fixes x::"real^'n" assumes "\<forall>i. a$i < b$i \<and> u$i < v$i" 
  1343   shows "interval_bij (a,b) (u,v) (interval_bij (u,v) (a,b) x) = x"
  1344   using assms by (intro interval_bij_bij) (auto simp: Basis_vec_def inner_axis)
  1345 
  1346 end