src/Pure/library.ML
author haftmann
Tue Dec 06 16:07:10 2005 +0100 (2005-12-06)
changeset 18359 02a830bab542
parent 18333 b356f7837921
child 18376 2ef0183fa20b
permissions -rw-r--r--
added 'dig' combinator
     1 (*  Title:      Pure/library.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Author:     Markus Wenzel, TU Muenchen
     5 
     6 Basic library: functions, options, pairs, booleans, lists, integers,
     7 strings, lists as sets, association lists, generic
     8 tables, balanced trees, orders, current directory, misc.
     9 *)
    10 
    11 infix 1 |> |-> ||> ||>> |>> |>>> #> #->;
    12 infix 2 ?;
    13 infix 3 o oo ooo oooo;
    14 
    15 infix 4 ~~ upto downto;
    16 infix orf andf prefix \ \\ ins ins_string ins_int mem mem_int mem_string union union_int
    17   union_string inter inter_int inter_string subset subset_int subset_string;
    18 
    19 signature BASIC_LIBRARY =
    20 sig
    21   (*functions*)
    22   val I: 'a -> 'a
    23   val K: 'a -> 'b -> 'a
    24   val curry: ('a * 'b -> 'c) -> 'a -> 'b -> 'c
    25   val uncurry: ('a -> 'b -> 'c) -> 'a * 'b -> 'c
    26   val |> : 'a * ('a -> 'b) -> 'b
    27   val |-> : ('c * 'a) * ('c -> 'a -> 'b) -> 'b
    28   val ||> : ('c * 'a) * ('a -> 'b) -> 'c * 'b
    29   val ||>> : ('c * 'a) * ('a -> 'd * 'b) -> ('c * 'd) * 'b
    30   val |>> : ('a * 'c) * ('a -> 'b) -> 'b * 'c
    31   val |>>> : ('a * 'c) * ('a -> 'b * 'd) -> 'b * ('c * 'd)
    32   val #> : ('a -> 'b) * ('b -> 'c) -> 'a -> 'c
    33   val #-> : ('a -> 'c * 'b) * ('c -> 'b -> 'd) -> 'a -> 'd
    34   val ? : ('a -> bool) * ('a -> 'a) -> 'a -> 'a
    35   val ` : ('b -> 'a) -> 'b -> 'a * 'b
    36   val tap: ('b -> 'a) -> 'b -> 'b
    37   val oo: ('a -> 'b) * ('c -> 'd -> 'a) -> 'c -> 'd -> 'b
    38   val ooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'a) -> 'c -> 'd -> 'e -> 'b
    39   val oooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'f -> 'a) -> 'c -> 'd -> 'e -> 'f -> 'b
    40   val funpow: int -> ('a -> 'a) -> 'a -> 'a
    41 
    42   (*old options -- invalidated*)
    43   datatype invalid = None of invalid
    44   exception OPTION of invalid
    45 
    46   (*options*)
    47   val the: 'a option -> 'a
    48   val these: 'a list option -> 'a list
    49   val the_default: 'a -> 'a option -> 'a
    50   val the_list: 'a option -> 'a list
    51   val if_none: 'a option -> 'a -> 'a
    52   val is_some: 'a option -> bool
    53   val is_none: 'a option -> bool
    54   val perhaps: ('a -> 'a option) -> 'a -> 'a
    55 
    56   exception EXCEPTION of exn * string
    57   exception ERROR
    58   val try: ('a -> 'b) -> 'a -> 'b option
    59   val can: ('a -> 'b) -> 'a -> bool
    60   datatype 'a result = Result of 'a | Exn of exn
    61   val capture: ('a -> 'b) -> 'a -> 'b result
    62   val release: 'a result -> 'a
    63   val get_result: 'a result -> 'a option
    64   val get_exn: 'a result -> exn option
    65 
    66   (*pairs*)
    67   val pair: 'a -> 'b -> 'a * 'b
    68   val rpair: 'a -> 'b -> 'b * 'a
    69   val fst: 'a * 'b -> 'a
    70   val snd: 'a * 'b -> 'b
    71   val eq_fst: ('a * 'c -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    72   val eq_snd: ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    73   val swap: 'a * 'b -> 'b * 'a
    74   val apfst: ('a -> 'b) -> 'a * 'c -> 'b * 'c
    75   val apsnd: ('a -> 'b) -> 'c * 'a -> 'c * 'b
    76   val pairself: ('a -> 'b) -> 'a * 'a -> 'b * 'b
    77 
    78   (*booleans*)
    79   val equal: ''a -> ''a -> bool
    80   val not_equal: ''a -> ''a -> bool
    81   val orf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    82   val andf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    83   val exists: ('a -> bool) -> 'a list -> bool
    84   val forall: ('a -> bool) -> 'a list -> bool
    85   val set: bool ref -> bool
    86   val reset: bool ref -> bool
    87   val toggle: bool ref -> bool
    88   val change: 'a ref -> ('a -> 'a) -> unit
    89   val setmp: 'a ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    90   val conditional: bool -> (unit -> unit) -> unit
    91 
    92   (*lists*)
    93   exception UnequalLengths
    94   val cons: 'a -> 'a list -> 'a list
    95   val single: 'a -> 'a list
    96   val append: 'a list -> 'a list -> 'a list
    97   val apply: ('a -> 'a) list -> 'a -> 'a
    98   val fold: ('a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    99   val fold_rev: ('a -> 'b -> 'b) -> 'a list -> 'b -> 'b
   100   val fold_map: ('a -> 'b -> 'c * 'b) -> 'a list -> 'b -> 'c list * 'b
   101   val fold_index: (int * 'a -> 'b -> 'b) -> 'a list -> 'b -> 'b
   102   val foldr1: ('a * 'a -> 'a) -> 'a list -> 'a
   103   val foldl_map: ('a * 'b -> 'a * 'c) -> 'a * 'b list -> 'a * 'c list
   104   val dig: ('a list -> 'a list) -> 'a list list -> 'a list list
   105   val unflat: 'a list list -> 'b list -> 'b list list
   106   val splitAt: int * 'a list -> 'a list * 'a list
   107   val dropwhile: ('a -> bool) -> 'a list -> 'a list
   108   val nth: 'a list -> int -> 'a
   109   val nth_update: int * 'a -> 'a list -> 'a list
   110   val nth_map: int -> ('a -> 'a) -> 'a list -> 'a list
   111   val nth_list: 'a list list -> int -> 'a list
   112   val split_last: 'a list -> 'a list * 'a
   113   val find_index: ('a -> bool) -> 'a list -> int
   114   val find_index_eq: ''a -> ''a list -> int
   115   val find_first: ('a -> bool) -> 'a list -> 'a option
   116   val get_first: ('a -> 'b option) -> 'a list -> 'b option
   117   val map2: ('a -> 'b -> 'c) -> 'a list -> 'b list -> 'c list
   118   val fold2: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
   119   val ~~ : 'a list * 'b list -> ('a * 'b) list
   120   val split_list: ('a * 'b) list -> 'a list * 'b list
   121   val separate: 'a -> 'a list -> 'a list
   122   val replicate: int -> 'a -> 'a list
   123   val multiply: 'a list -> 'a list list -> 'a list list
   124   val product: 'a list -> 'b list -> ('a * 'b) list
   125   val filter: ('a -> bool) -> 'a list -> 'a list
   126   val filter_out: ('a -> bool) -> 'a list -> 'a list
   127   val equal_lists: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   128   val prefix: ''a list * ''a list -> bool
   129   val take_prefix: ('a -> bool) -> 'a list -> 'a list * 'a list
   130   val take_suffix: ('a -> bool) -> 'a list -> 'a list * 'a list
   131   val prefixes1: 'a list -> 'a list list
   132   val suffixes1: 'a list -> 'a list list
   133 
   134   (*integers*)
   135   val gcd: IntInf.int * IntInf.int -> IntInf.int
   136   val lcm: IntInf.int * IntInf.int -> IntInf.int
   137   val inc: int ref -> int
   138   val dec: int ref -> int
   139   val upto: int * int -> int list
   140   val downto: int * int -> int list
   141   val downto0: int list * int -> bool
   142   val radixpand: int * int -> int list
   143   val radixstring: int * string * int -> string
   144   val string_of_int: int -> string
   145   val string_of_indexname: string * int -> string
   146   val read_radixint: int * string list -> int * string list
   147   val read_int: string list -> int * string list
   148   val oct_char: string -> string
   149 
   150   (*strings*)
   151   val nth_string: string -> int -> string
   152   val fold_string: (string -> 'a -> 'a) -> string -> 'a -> 'a
   153   val exists_string: (string -> bool) -> string -> bool
   154   val forall_string: (string -> bool) -> string -> bool
   155   val enclose: string -> string -> string -> string
   156   val unenclose: string -> string
   157   val quote: string -> string
   158   val space_implode: string -> string list -> string
   159   val commas: string list -> string
   160   val commas_quote: string list -> string
   161   val cat_lines: string list -> string
   162   val space_explode: string -> string -> string list
   163   val split_lines: string -> string list
   164   val prefix_lines: string -> string -> string
   165   val untabify: string list -> string list
   166   val suffix: string -> string -> string
   167   val unsuffix: string -> string -> string
   168   val unprefix: string -> string -> string
   169   val replicate_string: int -> string -> string
   170   val translate_string: (string -> string) -> string -> string
   171 
   172   (*lists as sets -- see also Pure/General/ord_list.ML*)
   173   val mem: ''a * ''a list -> bool
   174   val mem_int: int * int list -> bool
   175   val mem_string: string * string list -> bool
   176   val gen_mem: ('a * 'b -> bool) -> 'a * 'b list -> bool
   177   val ins: ''a * ''a list -> ''a list
   178   val ins_int: int * int list -> int list
   179   val ins_string: string * string list -> string list
   180   val gen_ins: ('a * 'a -> bool) -> 'a * 'a list -> 'a list
   181   val member: ('b * 'a -> bool) -> 'a list -> 'b -> bool
   182   val insert: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   183   val remove: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   184   val union: ''a list * ''a list -> ''a list
   185   val union_int: int list * int list -> int list
   186   val union_string: string list * string list -> string list
   187   val gen_union: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   188   val gen_inter: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   189   val inter: ''a list * ''a list -> ''a list
   190   val inter_int: int list * int list -> int list
   191   val inter_string: string list * string list -> string list
   192   val subset: ''a list * ''a list -> bool
   193   val subset_int: int list * int list -> bool
   194   val subset_string: string list * string list -> bool
   195   val eq_set: ''a list * ''a list -> bool
   196   val eq_set_string: string list * string list -> bool
   197   val gen_subset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   198   val \ : ''a list * ''a -> ''a list
   199   val \\ : ''a list * ''a list -> ''a list
   200   val gen_rem: ('a * 'b -> bool) -> 'a list * 'b -> 'a list
   201   val gen_rems: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   202   val gen_distinct: ('a * 'a -> bool) -> 'a list -> 'a list
   203   val distinct: ''a list -> ''a list
   204   val findrep: ''a list -> ''a list
   205   val gen_duplicates: ('a * 'a -> bool) -> 'a list -> 'a list
   206   val duplicates: ''a list -> ''a list
   207   val has_duplicates: ('a * 'a -> bool) -> 'a list -> bool
   208 
   209   (*lists as tables -- see also Pure/General/alist.ML*)
   210   val gen_merge_lists: ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   211   val gen_merge_lists': ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   212   val merge_lists: ''a list -> ''a list -> ''a list
   213   val merge_lists': ''a list -> ''a list -> ''a list
   214   val merge_alists: (''a * 'b) list -> (''a * 'b) list -> (''a * 'b) list
   215   val merge_alists': (''a * 'b) list -> (''a * 'b) list -> (''a * 'b) list
   216 
   217   (*balanced trees*)
   218   exception Balance
   219   val fold_bal: ('a * 'a -> 'a) -> 'a list -> 'a
   220   val access_bal: ('a -> 'a) * ('a -> 'a) * 'a -> int -> int -> 'a
   221   val accesses_bal: ('a -> 'a) * ('a -> 'a) * 'a -> int -> 'a list
   222 
   223   (*orders*)
   224   val rev_order: order -> order
   225   val make_ord: ('a * 'a -> bool) -> 'a * 'a -> order
   226   val int_ord: int * int -> order
   227   val string_ord: string * string -> order
   228   val fast_string_ord: string * string -> order
   229   val option_ord: ('a * 'b -> order) -> 'a option * 'b option -> order
   230   val prod_ord: ('a * 'b -> order) -> ('c * 'd -> order) -> ('a * 'c) * ('b * 'd) -> order
   231   val dict_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   232   val list_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   233   val sort: ('a * 'a -> order) -> 'a list -> 'a list
   234   val sort_strings: string list -> string list
   235   val sort_wrt: ('a -> string) -> 'a list -> 'a list
   236   val unique_strings: string list -> string list
   237 
   238   (*random numbers*)
   239   exception RANDOM
   240   val random: unit -> real
   241   val random_range: int -> int -> int
   242   val one_of: 'a list -> 'a
   243   val frequency: (int * 'a) list -> 'a
   244 
   245   (*current directory*)
   246   val cd: string -> unit
   247   val pwd: unit -> string
   248 
   249   (*misc*)
   250   val partition_eq: ('a * 'a -> bool) -> 'a list -> 'a list list
   251   val partition_list: (int -> 'a -> bool) -> int -> int -> 'a list -> 'a list list
   252   val gensym: string -> string
   253   val scanwords: (string -> bool) -> string list -> string list
   254   type stamp
   255   val stamp: unit -> stamp
   256   type serial
   257   val serial: unit -> serial
   258   structure Object: sig type T end
   259 end;
   260 
   261 signature LIBRARY =
   262 sig
   263   include BASIC_LIBRARY
   264   val foldl: ('a * 'b -> 'a) -> 'a * 'b list -> 'a
   265   val foldr: ('a * 'b -> 'b) -> 'a list * 'b -> 'b
   266   val take: int * 'a list -> 'a list
   267   val drop: int * 'a list -> 'a list
   268   val last_elem: 'a list -> 'a
   269   val flat: 'a list list -> 'a list
   270   val seq: ('a -> unit) -> 'a list -> unit
   271   val partition: ('a -> bool) -> 'a list -> 'a list * 'a list
   272   val mapfilter: ('a -> 'b option) -> 'a list -> 'b list
   273 end;
   274 
   275 structure Library: LIBRARY =
   276 struct
   277 
   278 
   279 (** functions **)
   280 
   281 fun I x = x;
   282 fun K x = fn _ => x;
   283 fun curry f x y = f (x, y);
   284 fun uncurry f (x, y) = f x y;
   285 
   286 (*reverse application and structured results*)
   287 fun x |> f = f x;
   288 fun (x, y) |-> f = f x y;
   289 fun (x, y) |>> f = (f x, y);
   290 fun (x, y) ||> f = (x, f y);
   291 fun (x, y) |>>> f = let val (x', z) = f x in (x', (y, z)) end;
   292 fun (x, y) ||>> f = let val (z, y') = f y in ((x, z), y') end;
   293 
   294 (*reverse composition*)
   295 fun f #> g = g o f;
   296 fun f #-> g = uncurry g o f;
   297 
   298 (*conditional application*)
   299 fun b ? f = fn x => if b x then f x else x;
   300 
   301 (*view results*)
   302 fun `f = fn x => (f x, x);
   303 fun tap f = fn x => (f x; x);
   304 
   305 (*composition with multiple args*)
   306 fun (f oo g) x y = f (g x y);
   307 fun (f ooo g) x y z = f (g x y z);
   308 fun (f oooo g) x y z w = f (g x y z w);
   309 
   310 (*function exponentiation: f(...(f x)...) with n applications of f*)
   311 fun funpow n f x =
   312   let fun rep (0, x) = x
   313         | rep (n, x) = rep (n - 1, f x)
   314   in rep (n, x) end;
   315 
   316 
   317 (** options **)
   318 
   319 (*invalidate former constructors to prevent accidental use as match-all patterns!*)
   320 datatype invalid = None of invalid;
   321 exception OPTION of invalid;
   322 
   323 val the = Option.valOf;
   324 
   325 fun these (SOME x) = x
   326   | these _ = [];
   327 
   328 fun the_default x (SOME y) = y
   329   | the_default x _ = x;
   330 
   331 fun the_list (SOME x) = [x]
   332   | the_list _ = []
   333 
   334 (*strict!*)
   335 fun if_none NONE y = y
   336   | if_none (SOME x) _ = x;
   337 
   338 fun is_some (SOME _) = true
   339   | is_some NONE = false;
   340 
   341 fun is_none (SOME _) = false
   342   | is_none NONE = true;
   343 
   344 fun perhaps f x =
   345   case f x
   346    of NONE => x
   347     | SOME x' => x';
   348 
   349 (* exceptions *)
   350 
   351 exception EXCEPTION of exn * string;
   352 
   353 exception ERROR;
   354 
   355 fun try f x = SOME (f x)
   356   handle Interrupt => raise Interrupt | ERROR => raise ERROR | _ => NONE;
   357 
   358 fun can f x = is_some (try f x);
   359 
   360 
   361 datatype 'a result =
   362   Result of 'a |
   363   Exn of exn;
   364 
   365 fun capture f x = Result (f x) handle e => Exn e;
   366 
   367 fun release (Result y) = y
   368   | release (Exn e) = raise e;
   369 
   370 fun get_result (Result x) = SOME x
   371   | get_result _ = NONE;
   372 
   373 fun get_exn (Exn exn) = SOME exn
   374   | get_exn _ = NONE;
   375 
   376 
   377 
   378 (** pairs **)
   379 
   380 fun pair x y = (x, y);
   381 fun rpair x y = (y, x);
   382 
   383 fun fst (x, y) = x;
   384 fun snd (x, y) = y;
   385 
   386 fun eq_fst eq ((x1, _), (x2, _)) = eq (x1, x2);
   387 fun eq_snd eq ((_, y1), (_, y2)) = eq (y1, y2);
   388 
   389 fun swap (x, y) = (y, x);
   390 
   391 (*apply function to components*)
   392 fun apfst f (x, y) = (f x, y);
   393 fun apsnd f (x, y) = (x, f y);
   394 fun pairself f (x, y) = (f x, f y);
   395 
   396 
   397 
   398 (** booleans **)
   399 
   400 (* equality *)
   401 
   402 fun equal x y = x = y;
   403 fun not_equal x y = x <> y;
   404 
   405 
   406 (* operators for combining predicates *)
   407 
   408 fun p orf q = fn x => p x orelse q x;
   409 fun p andf q = fn x => p x andalso q x;
   410 
   411 
   412 (* predicates on lists *)
   413 
   414 (*exists pred [x1, ..., xn] ===> pred x1 orelse ... orelse pred xn*)
   415 fun exists (pred: 'a -> bool) : 'a list -> bool =
   416   let fun boolf [] = false
   417         | boolf (x :: xs) = pred x orelse boolf xs
   418   in boolf end;
   419 
   420 (*forall pred [x1, ..., xn] ===> pred x1 andalso ... andalso pred xn*)
   421 fun forall (pred: 'a -> bool) : 'a list -> bool =
   422   let fun boolf [] = true
   423         | boolf (x :: xs) = pred x andalso boolf xs
   424   in boolf end;
   425 
   426 
   427 (* flags *)
   428 
   429 fun set flag = (flag := true; true);
   430 fun reset flag = (flag := false; false);
   431 fun toggle flag = (flag := not (! flag); ! flag);
   432 
   433 fun change r f = r := f (! r);
   434 
   435 (*temporarily set flag, handling exceptions*)
   436 fun setmp flag value f x =
   437   let
   438     val orig_value = ! flag;
   439     fun return y = (flag := orig_value; y);
   440   in
   441     flag := value;
   442     return (f x handle exn => (return (); raise exn))
   443   end;
   444 
   445 
   446 (* conditional execution *)
   447 
   448 fun conditional b f = if b then f () else ();
   449 
   450 
   451 
   452 (** lists **)
   453 
   454 exception UnequalLengths;
   455 
   456 fun cons x xs = x :: xs;
   457 fun single x = [x];
   458 
   459 fun append xs ys = xs @ ys;
   460 
   461 fun apply [] x = x
   462   | apply (f :: fs) x = apply fs (f x);
   463 
   464 
   465 (* fold *)
   466 
   467 fun fold f =
   468   let
   469     fun fold_aux [] y = y
   470       | fold_aux (x :: xs) y = fold_aux xs (f x y);
   471   in fold_aux end;
   472 
   473 fun fold_rev f =
   474   let
   475     fun fold_aux [] y = y
   476       | fold_aux (x :: xs) y = f x (fold_aux xs y);
   477   in fold_aux end;
   478 
   479 fun fold_map f =
   480   let
   481     fun fold_aux [] y = ([], y)
   482       | fold_aux (x :: xs) y =
   483           let
   484             val (x', y') = f x y;
   485             val (xs', y'') = fold_aux xs y';
   486           in (x' :: xs', y'') end;
   487   in fold_aux end;
   488 
   489 (*the following versions of fold are designed to fit nicely with infixes*)
   490 
   491 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   492     for operators that associate to the left (TAIL RECURSIVE)*)
   493 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   494   let fun itl (e, [])  = e
   495         | itl (e, a::l) = itl (f(e, a), l)
   496   in  itl end;
   497 
   498 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   499     for operators that associate to the right (not tail recursive)*)
   500 fun foldr f (l, e) =
   501   let fun itr [] = e
   502         | itr (a::l) = f(a, itr l)
   503   in  itr l  end;
   504 
   505 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   506     for n > 0, operators that associate to the right (not tail recursive)*)
   507 fun foldr1 f l =
   508   let fun itr [x] = x
   509         | itr (x::l) = f(x, itr l)
   510   in  itr l  end;
   511 
   512 fun fold_index f =
   513   let
   514     fun fold_aux _  [] y = y
   515       | fold_aux i (x :: xs) y = fold_aux (i+1) xs (f (i, x) y);
   516   in fold_aux 0 end;
   517 
   518 fun foldl_map f =
   519   let
   520     fun fold_aux (x, []) = (x, [])
   521       | fold_aux (x, y :: ys) =
   522           let
   523             val (x', y') = f (x, y);
   524             val (x'', ys') = fold_aux (x', ys);
   525           in (x'', y' :: ys') end;
   526   in fold_aux end;
   527 
   528 
   529 (* basic list functions *)
   530 
   531 (*take the first n elements from a list*)
   532 fun take (n, []) = []
   533   | take (n, x :: xs) =
   534       if n > 0 then x :: take (n - 1, xs) else [];
   535 
   536 (*drop the first n elements from a list*)
   537 fun drop (n, []) = []
   538   | drop (n, x :: xs) =
   539       if n > 0 then drop (n - 1, xs) else x :: xs;
   540 
   541 fun splitAt(n,[]) = ([],[])
   542   | splitAt(n,xs as x::ys) =
   543       if n>0 then let val (ps,qs) = splitAt(n-1,ys) in (x::ps,qs) end
   544       else ([],xs)
   545 
   546 fun dropwhile P [] = []
   547   | dropwhile P (ys as x::xs) = if P x then dropwhile P xs else ys;
   548 
   549 (*return nth element of a list, where 0 designates the first element;
   550   raise EXCEPTION if list too short*)
   551 fun nth xs i = List.nth (xs, i);
   552 
   553 (*update nth element*)
   554 fun nth_update (n, x) xs =
   555     (case splitAt (n, xs) of
   556       (_, []) => raise Subscript
   557     | (prfx, _ :: sffx') => prfx @ (x :: sffx'))
   558 
   559 fun nth_map 0 f (x :: xs) = f x :: xs
   560   | nth_map n f (x :: xs) = x :: nth_map (n - 1) f xs
   561   | nth_map _ _ [] = raise Subscript;
   562 
   563 fun nth_list xss i = nth xss i handle Subscript => [];
   564 
   565 val last_elem = List.last;
   566 
   567 (*rear decomposition*)
   568 fun split_last [] = raise Empty
   569   | split_last [x] = ([], x)
   570   | split_last (x :: xs) = apfst (cons x) (split_last xs);
   571 
   572 (*find the position of an element in a list*)
   573 fun find_index pred =
   574   let fun find _ [] = ~1
   575         | find n (x :: xs) = if pred x then n else find (n + 1) xs;
   576   in find 0 end;
   577 
   578 fun find_index_eq x = find_index (equal x);
   579 
   580 (*find first element satisfying predicate*)
   581 fun find_first _ [] = NONE
   582   | find_first pred (x :: xs) =
   583       if pred x then SOME x else find_first pred xs;
   584 
   585 (*get first element by lookup function*)
   586 fun get_first _ [] = NONE
   587   | get_first f (x :: xs) =
   588       (case f x of
   589         NONE => get_first f xs
   590       | some => some);
   591 
   592 (*flatten a list of lists to a list*)
   593 val flat = List.concat;
   594 
   595 fun unflat (xs :: xss) ys =
   596       let val (ps,qs) = splitAt(length xs,ys)
   597       in ps :: unflat xss qs end
   598   | unflat [] [] = []
   599   | unflat _ _ = raise UnequalLengths;
   600 
   601 fun dig f xss =
   602   unflat xss ((f o flat) xss);
   603 
   604 
   605 (*like Lisp's MAPC -- seq proc [x1, ..., xn] evaluates
   606   (proc x1; ...; proc xn) for side effects*)
   607 val seq = List.app;
   608 
   609 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   610 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   611   | separate _ xs = xs;
   612 
   613 (*make the list [x, x, ..., x] of length n*)
   614 fun replicate n (x: 'a) : 'a list =
   615   let fun rep (0, xs) = xs
   616         | rep (n, xs) = rep (n - 1, x :: xs)
   617   in
   618     if n < 0 then raise Subscript
   619     else rep (n, [])
   620   end;
   621 
   622 fun translate_string f = String.translate (f o String.str);
   623 
   624 (*multiply [a, b, c, ...] * [xs, ys, zs, ...]*)
   625 fun multiply [] _ = []
   626   | multiply (x :: xs) yss = map (cons x) yss @ multiply xs yss;
   627 
   628 (*direct product*)
   629 fun product _ [] = []
   630   | product [] _ = []
   631   | product (x :: xs) ys = map (pair x) ys @ product xs ys;
   632 
   633 
   634 (* filter *)
   635 
   636 (*copy the list preserving elements that satisfy the predicate*)
   637 val filter = List.filter;
   638 fun filter_out f = filter (not o f);
   639 val mapfilter = List.mapPartial;
   640 
   641 
   642 (* lists of pairs *)
   643 
   644 exception UnequalLengths;
   645 
   646 fun map2 _ [] [] = []
   647   | map2 f (x :: xs) (y :: ys) = f x y :: map2 f xs ys
   648   | map2 _ _ _ = raise UnequalLengths;
   649 
   650 fun fold2 f =
   651   let
   652     fun fold_aux [] [] z = z
   653       | fold_aux (x :: xs) (y :: ys) z = fold_aux xs ys (f x y z)
   654       | fold_aux _ _ _ = raise UnequalLengths;
   655   in fold_aux end;
   656 
   657 
   658 (*combine two lists forming a list of pairs:
   659   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   660 fun [] ~~ [] = []
   661   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   662   | _ ~~ _ = raise UnequalLengths;
   663 
   664 (*inverse of ~~; the old 'split':
   665   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   666 val split_list = ListPair.unzip;
   667 
   668 fun equal_lists eq (xs, ys) =
   669   let
   670     fun eq' [] [] = true
   671       | eq' (x :: xs) (y :: ys) = eq (x, y) andalso eq' xs ys
   672   in length xs = length ys andalso eq' xs ys end;
   673 
   674 
   675 (* prefixes, suffixes *)
   676 
   677 fun [] prefix _ = true
   678   | (x :: xs) prefix (y :: ys) = x = y andalso (xs prefix ys)
   679   | _ prefix _ = false;
   680 
   681 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   682    where xi is the first element that does not satisfy the predicate*)
   683 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   684   let fun take (rxs, []) = (rev rxs, [])
   685         | take (rxs, x :: xs) =
   686             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   687   in  take([], xs)  end;
   688 
   689 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   690    where xi is the last element that does not satisfy the predicate*)
   691 fun take_suffix _ [] = ([], [])
   692   | take_suffix pred (x :: xs) =
   693       (case take_suffix pred xs of
   694         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   695       | (prfx, sffx) => (x :: prfx, sffx));
   696 
   697 fun prefixes1 [] = []
   698   | prefixes1 (x :: xs) = map (cons x) ([] :: prefixes1 xs);
   699 
   700 fun suffixes1 xs = map rev (prefixes1 (rev xs));
   701 
   702 
   703 
   704 (** integers **)
   705 
   706 fun gcd (x, y) =
   707   let fun gxd x y : IntInf.int =
   708     if y = 0 then x else gxd y (x mod y)
   709   in if x < y then gxd y x else gxd x y end;
   710 
   711 fun lcm (x, y) = (x * y) div gcd (x, y);
   712 
   713 fun inc i = (i := ! i + 1; ! i);
   714 fun dec i = (i := ! i - 1; ! i);
   715 
   716 
   717 (* lists of integers *)
   718 
   719 (*make the list [from, from + 1, ..., to]*)
   720 fun (from upto to) =
   721   if from > to then [] else from :: ((from + 1) upto to);
   722 
   723 (*make the list [from, from - 1, ..., to]*)
   724 fun (from downto to) =
   725   if from < to then [] else from :: ((from - 1) downto to);
   726 
   727 (*predicate: downto0 (is, n) <=> is = [n, n - 1, ..., 0]*)
   728 fun downto0 (i :: is, n) = i = n andalso downto0 (is, n - 1)
   729   | downto0 ([], n) = n = ~1;
   730 
   731 
   732 (* convert integers to strings *)
   733 
   734 (*expand the number in the given base;
   735   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   736 fun radixpand (base, num) : int list =
   737   let
   738     fun radix (n, tail) =
   739       if n < base then n :: tail
   740       else radix (n div base, (n mod base) :: tail)
   741   in radix (num, []) end;
   742 
   743 (*expands a number into a string of characters starting from "zerochar";
   744   example: radixstring (2, "0", 8) gives "1000"*)
   745 fun radixstring (base, zerochar, num) =
   746   let val offset = ord zerochar;
   747       fun chrof n = chr (offset + n)
   748   in implode (map chrof (radixpand (base, num))) end;
   749 
   750 
   751 val string_of_int = Int.toString;
   752 
   753 fun string_of_indexname (a,0) = a
   754   | string_of_indexname (a,i) = a ^ "_" ^ Int.toString i;
   755 
   756 
   757 (* read integers *)
   758 
   759 fun read_radixint (radix: int, cs) : int * string list =
   760   let val zero = ord"0"
   761       val limit = zero+radix
   762       fun scan (num,[]) = (num,[])
   763         | scan (num, c::cs) =
   764               if  zero <= ord c  andalso  ord c < limit
   765               then scan(radix*num + ord c - zero, cs)
   766               else (num, c::cs)
   767   in  scan(0,cs)  end;
   768 
   769 fun read_int cs = read_radixint (10, cs);
   770 
   771 fun oct_char s = chr (#1 (read_radixint (8, explode s)));
   772 
   773 
   774 
   775 (** strings **)
   776 
   777 (* functions tuned for strings, avoiding explode *)
   778 
   779 fun nth_string str i =
   780   (case try String.substring (str, i, 1) of
   781     SOME s => s
   782   | NONE => raise Subscript);
   783 
   784 fun fold_string f str x0 =
   785   let
   786     val n = size str;
   787     fun iter (x, i) =
   788       if i < n then iter (f (String.substring (str, i, 1)) x, i + 1) else x;
   789   in iter (x0, 0) end;
   790 
   791 fun exists_string pred str =
   792   let
   793     val n = size str;
   794     fun ex i = i < n andalso (pred (String.substring (str, i, 1)) orelse ex (i + 1));
   795   in ex 0 end;
   796 
   797 fun forall_string pred = not o exists_string (not o pred);
   798 
   799 (*enclose in brackets*)
   800 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   801 fun unenclose str = String.substring (str, 1, size str - 2);
   802 
   803 (*simple quoting (does not escape special chars)*)
   804 val quote = enclose "\"" "\"";
   805 
   806 (*space_implode "..." (explode "hello") = "h...e...l...l...o"*)
   807 fun space_implode a bs = implode (separate a bs);
   808 
   809 val commas = space_implode ", ";
   810 val commas_quote = commas o map quote;
   811 
   812 (*concatenate messages, one per line, into a string*)
   813 val cat_lines = space_implode "\n";
   814 
   815 (*space_explode "." "h.e..l.lo" = ["h", "e", "", "l", "lo"]*)
   816 fun space_explode _ "" = []
   817   | space_explode sep str =
   818       let
   819         fun expl chs =
   820           (case take_prefix (not_equal sep) chs of
   821             (cs, []) => [implode cs]
   822           | (cs, _ :: cs') => implode cs :: expl cs');
   823       in expl (explode str) end;
   824 
   825 val split_lines = space_explode "\n";
   826 
   827 fun prefix_lines "" txt = txt
   828   | prefix_lines prfx txt = txt |> split_lines |> map (fn s => prfx ^ s) |> cat_lines;
   829 
   830 fun untabify chs =
   831   let
   832     val tab_width = 8;
   833 
   834     fun untab (_, "\n") = (0, ["\n"])
   835       | untab (pos, "\t") =
   836           let val d = tab_width - (pos mod tab_width) in (pos + d, replicate d " ") end
   837       | untab (pos, c) = (pos + 1, [c]);
   838   in
   839     if not (exists (equal "\t") chs) then chs
   840     else flat (#2 (foldl_map untab (0, chs)))
   841   end;
   842 
   843 fun suffix sffx s = s ^ sffx;
   844 
   845 fun unsuffix sffx s =
   846   if String.isSuffix sffx s then String.substring (s, 0, size s - size sffx)
   847   else raise Fail "unsuffix";
   848 
   849 fun unprefix prfx s =
   850   if String.isPrefix prfx s then String.substring (s, size prfx, size s - size prfx)
   851   else raise Fail "unprefix";
   852 
   853 fun replicate_string 0 _ = ""
   854   | replicate_string 1 a = a
   855   | replicate_string k a =
   856       if k mod 2 = 0 then replicate_string (k div 2) (a ^ a)
   857       else replicate_string (k div 2) (a ^ a) ^ a;
   858 
   859 
   860 
   861 (** lists as sets -- see also Pure/General/ord_list.ML **)
   862 
   863 (*membership in a list*)
   864 fun x mem [] = false
   865   | x mem (y :: ys) = x = y orelse x mem ys;
   866 
   867 (*membership in a list, optimized version for ints*)
   868 fun (x:int) mem_int [] = false
   869   | x mem_int (y :: ys) = x = y orelse x mem_int ys;
   870 
   871 (*membership in a list, optimized version for strings*)
   872 fun (x:string) mem_string [] = false
   873   | x mem_string (y :: ys) = x = y orelse x mem_string ys;
   874 
   875 (*generalized membership test*)
   876 fun gen_mem eq (x, []) = false
   877   | gen_mem eq (x, y :: ys) = eq (x, y) orelse gen_mem eq (x, ys);
   878 
   879 (*member, insert, and remove -- with canonical argument order*)
   880 fun member eq xs x = gen_mem eq (x, xs);
   881 fun insert eq x xs = if gen_mem eq (x, xs) then xs else x :: xs;
   882 fun remove eq x xs = if gen_mem eq (x, xs) then filter_out (fn y => eq (x, y)) xs else xs;
   883 
   884 (*insertion into list if not already there*)
   885 fun (x ins xs) = if x mem xs then xs else x :: xs;
   886 
   887 (*insertion into list, optimized version for ints*)
   888 fun (x ins_int xs) = if x mem_int xs then xs else x :: xs;
   889 
   890 (*insertion into list, optimized version for strings*)
   891 fun (x ins_string xs) = if x mem_string xs then xs else x :: xs;
   892 
   893 (*generalized insertion*)
   894 fun gen_ins eq (x, xs) = insert eq x xs;
   895 
   896 (*union of sets represented as lists: no repetitions*)
   897 fun xs union [] = xs
   898   | [] union ys = ys
   899   | (x :: xs) union ys = xs union (x ins ys);
   900 
   901 (*union of sets, optimized version for ints*)
   902 fun (xs:int list) union_int [] = xs
   903   | [] union_int ys = ys
   904   | (x :: xs) union_int ys = xs union_int (x ins_int ys);
   905 
   906 (*union of sets, optimized version for strings*)
   907 fun (xs:string list) union_string [] = xs
   908   | [] union_string ys = ys
   909   | (x :: xs) union_string ys = xs union_string (x ins_string ys);
   910 
   911 (*generalized union*)
   912 fun gen_union eq (xs, []) = xs
   913   | gen_union eq ([], ys) = ys
   914   | gen_union eq (x :: xs, ys) = gen_union eq (xs, gen_ins eq (x, ys));
   915 
   916 
   917 (*intersection*)
   918 fun [] inter ys = []
   919   | (x :: xs) inter ys =
   920       if x mem ys then x :: (xs inter ys) else xs inter ys;
   921 
   922 (*intersection, optimized version for ints*)
   923 fun ([]:int list) inter_int ys = []
   924   | (x :: xs) inter_int ys =
   925       if x mem_int ys then x :: (xs inter_int ys) else xs inter_int ys;
   926 
   927 (*intersection, optimized version for strings *)
   928 fun ([]:string list) inter_string ys = []
   929   | (x :: xs) inter_string ys =
   930       if x mem_string ys then x :: (xs inter_string ys) else xs inter_string ys;
   931 
   932 (*generalized intersection*)
   933 fun gen_inter eq ([], ys) = []
   934   | gen_inter eq (x::xs, ys) =
   935       if gen_mem eq (x,ys) then x :: gen_inter eq (xs, ys)
   936                            else      gen_inter eq (xs, ys);
   937 
   938 
   939 (*subset*)
   940 fun [] subset ys = true
   941   | (x :: xs) subset ys = x mem ys andalso xs subset ys;
   942 
   943 (*subset, optimized version for ints*)
   944 fun ([]: int list) subset_int ys = true
   945   | (x :: xs) subset_int ys = x mem_int ys andalso xs subset_int ys;
   946 
   947 (*subset, optimized version for strings*)
   948 fun ([]: string list) subset_string ys = true
   949   | (x :: xs) subset_string ys = x mem_string ys andalso xs subset_string ys;
   950 
   951 (*set equality*)
   952 fun eq_set (xs, ys) =
   953   xs = ys orelse (xs subset ys andalso ys subset xs);
   954 
   955 (*set equality for strings*)
   956 fun eq_set_string ((xs: string list), ys) =
   957   xs = ys orelse (xs subset_string ys andalso ys subset_string xs);
   958 
   959 fun gen_subset eq (xs, ys) = forall (fn x => gen_mem eq (x, ys)) xs;
   960 
   961 
   962 (*removing an element from a list WITHOUT duplicates*)
   963 fun (y :: ys) \ x = if x = y then ys else y :: (ys \ x)
   964   | [] \ x = [];
   965 
   966 fun ys \\ xs = foldl (op \) (ys,xs);
   967 
   968 (*removing an element from a list -- possibly WITH duplicates*)
   969 fun gen_rem eq (xs, y) = filter_out (fn x => eq (x, y)) xs;
   970 fun gen_rems eq (xs, ys) = filter_out (fn x => gen_mem eq (x, ys)) xs;
   971 
   972 (*makes a list of the distinct members of the input; preserves order, takes
   973   first of equal elements*)
   974 fun gen_distinct eq lst =
   975   let
   976     val memb = gen_mem eq;
   977 
   978     fun dist (rev_seen, []) = rev rev_seen
   979       | dist (rev_seen, x :: xs) =
   980           if memb (x, rev_seen) then dist (rev_seen, xs)
   981           else dist (x :: rev_seen, xs);
   982   in
   983     dist ([], lst)
   984   end;
   985 
   986 fun distinct l = gen_distinct (op =) l;
   987 
   988 (*returns the tail beginning with the first repeated element, or []*)
   989 fun findrep [] = []
   990   | findrep (x :: xs) = if x mem xs then x :: xs else findrep xs;
   991 
   992 
   993 (*returns a list containing all repeated elements exactly once; preserves
   994   order, takes first of equal elements*)
   995 fun gen_duplicates eq lst =
   996   let
   997     val memb = gen_mem eq;
   998 
   999     fun dups (rev_dups, []) = rev rev_dups
  1000       | dups (rev_dups, x :: xs) =
  1001           if memb (x, rev_dups) orelse not (memb (x, xs)) then
  1002             dups (rev_dups, xs)
  1003           else dups (x :: rev_dups, xs);
  1004   in
  1005     dups ([], lst)
  1006   end;
  1007 
  1008 fun duplicates l = gen_duplicates (op =) l;
  1009 
  1010 fun has_duplicates eq =
  1011   let
  1012     fun dups [] = false
  1013       | dups (x :: xs) = member eq xs x orelse dups xs;
  1014   in dups end;
  1015 
  1016 
  1017 
  1018 (** association lists **)
  1019 
  1020 (* lists as tables *)
  1021 
  1022 fun gen_merge_lists _ xs [] = xs
  1023   | gen_merge_lists _ [] ys = ys
  1024   | gen_merge_lists eq xs ys = xs @ gen_rems eq (ys, xs);
  1025 
  1026 fun gen_merge_lists' _ xs [] = xs
  1027   | gen_merge_lists' _ [] ys = ys
  1028   | gen_merge_lists' eq xs ys = gen_rems eq (ys, xs) @ xs;
  1029 
  1030 fun merge_lists xs ys = gen_merge_lists (op =) xs ys;
  1031 fun merge_lists' xs ys = gen_merge_lists' (op =) xs ys;
  1032 fun merge_alists al = gen_merge_lists (eq_fst (op =)) al;
  1033 fun merge_alists' al = gen_merge_lists' (eq_fst (op =)) al;
  1034 
  1035 
  1036 
  1037 (** balanced trees **)
  1038 
  1039 exception Balance;      (*indicates non-positive argument to balancing fun*)
  1040 
  1041 (*balanced folding; avoids deep nesting*)
  1042 fun fold_bal f [x] = x
  1043   | fold_bal f [] = raise Balance
  1044   | fold_bal f xs =
  1045       let val (ps,qs) = splitAt(length xs div 2, xs)
  1046       in  f (fold_bal f ps, fold_bal f qs)  end;
  1047 
  1048 (*construct something of the form f(...g(...(x)...)) for balanced access*)
  1049 fun access_bal (f, g, x) n i =
  1050   let fun acc n i =     (*1<=i<=n*)
  1051           if n=1 then x else
  1052           let val n2 = n div 2
  1053           in  if i<=n2 then f (acc n2 i)
  1054                        else g (acc (n-n2) (i-n2))
  1055           end
  1056   in  if 1<=i andalso i<=n then acc n i else raise Balance  end;
  1057 
  1058 (*construct ALL such accesses; could try harder to share recursive calls!*)
  1059 fun accesses_bal (f, g, x) n =
  1060   let fun acc n =
  1061           if n=1 then [x] else
  1062           let val n2 = n div 2
  1063               val acc2 = acc n2
  1064           in  if n-n2=n2 then map f acc2 @ map g acc2
  1065                          else map f acc2 @ map g (acc (n-n2)) end
  1066   in  if 1<=n then acc n else raise Balance  end;
  1067 
  1068 
  1069 
  1070 (** orders **)
  1071 
  1072 fun rev_order LESS = GREATER
  1073   | rev_order EQUAL = EQUAL
  1074   | rev_order GREATER = LESS;
  1075 
  1076 (*assume rel is a linear strict order*)
  1077 fun make_ord rel (x, y) =
  1078   if rel (x, y) then LESS
  1079   else if rel (y, x) then GREATER
  1080   else EQUAL;
  1081 
  1082 val int_ord = Int.compare;
  1083 val string_ord = String.compare;
  1084 
  1085 fun fast_string_ord (s1, s2) =
  1086   (case int_ord (size s1, size s2) of EQUAL => string_ord (s1, s2) | ord => ord);
  1087 
  1088 fun option_ord ord (SOME x, SOME y) = ord (x, y)
  1089   | option_ord _ (NONE, NONE) = EQUAL
  1090   | option_ord _ (NONE, SOME _) = LESS
  1091   | option_ord _ (SOME _, NONE) = GREATER;
  1092 
  1093 (*lexicographic product*)
  1094 fun prod_ord a_ord b_ord ((x, y), (x', y')) =
  1095   (case a_ord (x, x') of EQUAL => b_ord (y, y') | ord => ord);
  1096 
  1097 (*dictionary order -- in general NOT well-founded!*)
  1098 fun dict_ord elem_ord (x :: xs, y :: ys) =
  1099       (case elem_ord (x, y) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord)
  1100   | dict_ord _ ([], []) = EQUAL
  1101   | dict_ord _ ([], _ :: _) = LESS
  1102   | dict_ord _ (_ :: _, []) = GREATER;
  1103 
  1104 (*lexicographic product of lists*)
  1105 fun list_ord elem_ord (xs, ys) =
  1106   (case int_ord (length xs, length ys) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
  1107 
  1108 
  1109 (* sorting *)
  1110 
  1111 (*quicksort (stable, i.e. does not reorder equal elements)*)
  1112 fun sort ord =
  1113   let
  1114     fun qsort [] = []
  1115       | qsort (xs as [_]) = xs
  1116       | qsort (xs as [x, y]) = if ord (x, y) = GREATER then [y, x] else xs
  1117       | qsort xs =
  1118           let val (lts, eqs, gts) = part (nth xs (length xs div 2)) xs
  1119           in qsort lts @ eqs @ qsort gts end
  1120     and part _ [] = ([], [], [])
  1121       | part pivot (x :: xs) = add (ord (x, pivot)) x (part pivot xs)
  1122     and add LESS x (lts, eqs, gts) = (x :: lts, eqs, gts)
  1123       | add EQUAL x (lts, eqs, gts) = (lts, x :: eqs, gts)
  1124       | add GREATER x (lts, eqs, gts) = (lts, eqs, x :: gts);
  1125   in qsort end;
  1126 
  1127 (*sort strings*)
  1128 val sort_strings = sort string_ord;
  1129 fun sort_wrt sel xs = sort (string_ord o pairself sel) xs;
  1130 
  1131 fun unique_strings ([]: string list) = []
  1132   | unique_strings [x] = [x]
  1133   | unique_strings (x :: y :: ys) =
  1134       if x = y then unique_strings (y :: ys)
  1135       else x :: unique_strings (y :: ys);
  1136 
  1137 
  1138 (** random numbers **)
  1139 
  1140 exception RANDOM;
  1141 
  1142 fun rmod x y = x - y * Real.realFloor (x / y);
  1143 
  1144 local
  1145   val a = 16807.0;
  1146   val m = 2147483647.0;
  1147   val random_seed = ref 1.0;
  1148 in
  1149 
  1150 fun random () =
  1151   let val r = rmod (a * !random_seed) m
  1152   in (random_seed := r; r) end;
  1153 
  1154 end;
  1155 
  1156 fun random_range l h =
  1157   if h < l orelse l < 0 then raise RANDOM
  1158   else l + Real.floor (rmod (random ()) (real (h - l + 1)));
  1159 
  1160 fun one_of xs = nth xs (random_range 0 (length xs - 1));
  1161 
  1162 fun frequency xs =
  1163   let
  1164     val sum = foldl op + (0, map fst xs);
  1165     fun pick n ((k: int, x) :: xs) =
  1166       if n <= k then x else pick (n - k) xs
  1167   in pick (random_range 1 sum) xs end;
  1168 
  1169 
  1170 (** current directory **)
  1171 
  1172 val cd = OS.FileSys.chDir;
  1173 val pwd = OS.FileSys.getDir;
  1174 
  1175 
  1176 (** misc **)
  1177 
  1178 (*Partition list into elements that satisfy predicate and those that don't.
  1179   Preserves order of elements in both lists.*)
  1180 val partition = List.partition;
  1181 
  1182 fun partition_eq (eq:'a * 'a -> bool) =
  1183   let
  1184     fun part [] = []
  1185       | part (x :: ys) =
  1186           let val (xs, xs') = partition (fn y => eq (x, y)) ys
  1187           in (x::xs)::(part xs') end
  1188   in part end;
  1189 
  1190 
  1191 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
  1192    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
  1193 fun partition_list p i j =
  1194   let fun part k xs =
  1195             if k>j then
  1196               (case xs of [] => []
  1197                          | _ => raise Fail "partition_list")
  1198             else
  1199             let val (ns, rest) = partition (p k) xs;
  1200             in  ns :: part(k+1)rest  end
  1201   in  part i end;
  1202 
  1203 
  1204 (* generating identifiers *)
  1205 
  1206 (** Freshly generated identifiers; supplied prefix MUST start with a letter **)
  1207 local
  1208 (*Maps 0-63 to A-Z, a-z, 0-9 or _ or ' for generating random identifiers*)
  1209 fun char i =      if i<26 then chr (ord "A" + i)
  1210              else if i<52 then chr (ord "a" + i - 26)
  1211              else if i<62 then chr (ord"0" + i - 52)
  1212              else if i=62 then "_"
  1213              else  (*i=63*)    "'";
  1214 
  1215 val charVec = Vector.tabulate (64, char);
  1216 
  1217 fun newid n =
  1218   let
  1219   in  implode (map (fn i => Vector.sub(charVec,i)) (radixpand (64,n)))  end;
  1220 
  1221 val seedr = ref 0;
  1222 
  1223 in
  1224 
  1225 fun gensym pre = pre ^ (#1(newid (!seedr), inc seedr));
  1226 
  1227 end;
  1228 
  1229 
  1230 (* lexical scanning *)
  1231 
  1232 (*scan a list of characters into "words" composed of "letters" (recognized by
  1233   is_let) and separated by any number of non-"letters"*)
  1234 fun scanwords is_let cs =
  1235   let fun scan1 [] = []
  1236         | scan1 cs =
  1237             let val (lets, rest) = take_prefix is_let cs
  1238             in implode lets :: scanwords is_let rest end;
  1239   in scan1 (#2 (take_prefix (not o is_let) cs)) end;
  1240 
  1241 
  1242 (* stamps and serial numbers *)
  1243 
  1244 type stamp = unit ref;
  1245 val stamp: unit -> stamp = ref;
  1246 
  1247 type serial = int;
  1248 local val count = ref 0
  1249 in fun serial () = inc count end;
  1250 
  1251 
  1252 (* generic objects *)
  1253 
  1254 (*note that the builtin exception datatype may be extended by new
  1255   constructors at any time*)
  1256 structure Object = struct type T = exn end;
  1257 
  1258 end;
  1259 
  1260 structure BasicLibrary: BASIC_LIBRARY = Library;
  1261 open BasicLibrary;