src/HOL/Set.ML
author paulson
Fri Jun 06 10:20:38 1997 +0200 (1997-06-06)
changeset 3420 02dc9c5b035f
parent 3222 726a9b069947
child 3469 61d927bd57ec
permissions -rw-r--r--
New miniscoping rules ball_triv and bex_triv
     1 (*  Title:      HOL/set
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1991  University of Cambridge
     5 
     6 Set theory for higher-order logic.  A set is simply a predicate.
     7 *)
     8 
     9 open Set;
    10 
    11 section "Relating predicates and sets";
    12 
    13 AddIffs [mem_Collect_eq];
    14 
    15 goal Set.thy "!!a. P(a) ==> a : {x.P(x)}";
    16 by (Asm_simp_tac 1);
    17 qed "CollectI";
    18 
    19 val prems = goal Set.thy "!!a. a : {x.P(x)} ==> P(a)";
    20 by (Asm_full_simp_tac 1);
    21 qed "CollectD";
    22 
    23 val [prem] = goal Set.thy "[| !!x. (x:A) = (x:B) |] ==> A = B";
    24 by (rtac (prem RS ext RS arg_cong RS box_equals) 1);
    25 by (rtac Collect_mem_eq 1);
    26 by (rtac Collect_mem_eq 1);
    27 qed "set_ext";
    28 
    29 val [prem] = goal Set.thy "[| !!x. P(x)=Q(x) |] ==> {x. P(x)} = {x. Q(x)}";
    30 by (rtac (prem RS ext RS arg_cong) 1);
    31 qed "Collect_cong";
    32 
    33 val CollectE = make_elim CollectD;
    34 
    35 AddSIs [CollectI];
    36 AddSEs [CollectE];
    37 
    38 
    39 section "Bounded quantifiers";
    40 
    41 val prems = goalw Set.thy [Ball_def]
    42     "[| !!x. x:A ==> P(x) |] ==> ! x:A. P(x)";
    43 by (REPEAT (ares_tac (prems @ [allI,impI]) 1));
    44 qed "ballI";
    45 
    46 val [major,minor] = goalw Set.thy [Ball_def]
    47     "[| ! x:A. P(x);  x:A |] ==> P(x)";
    48 by (rtac (minor RS (major RS spec RS mp)) 1);
    49 qed "bspec";
    50 
    51 val major::prems = goalw Set.thy [Ball_def]
    52     "[| ! x:A. P(x);  P(x) ==> Q;  x~:A ==> Q |] ==> Q";
    53 by (rtac (major RS spec RS impCE) 1);
    54 by (REPEAT (eresolve_tac prems 1));
    55 qed "ballE";
    56 
    57 (*Takes assumptions ! x:A.P(x) and a:A; creates assumption P(a)*)
    58 fun ball_tac i = etac ballE i THEN contr_tac (i+1);
    59 
    60 AddSIs [ballI];
    61 AddEs  [ballE];
    62 
    63 val prems = goalw Set.thy [Bex_def]
    64     "[| P(x);  x:A |] ==> ? x:A. P(x)";
    65 by (REPEAT (ares_tac (prems @ [exI,conjI]) 1));
    66 qed "bexI";
    67 
    68 qed_goal "bexCI" Set.thy 
    69    "[| ! x:A. ~P(x) ==> P(a);  a:A |] ==> ? x:A.P(x)"
    70  (fn prems=>
    71   [ (rtac classical 1),
    72     (REPEAT (ares_tac (prems@[bexI,ballI,notI,notE]) 1))  ]);
    73 
    74 val major::prems = goalw Set.thy [Bex_def]
    75     "[| ? x:A. P(x);  !!x. [| x:A; P(x) |] ==> Q  |] ==> Q";
    76 by (rtac (major RS exE) 1);
    77 by (REPEAT (eresolve_tac (prems @ [asm_rl,conjE]) 1));
    78 qed "bexE";
    79 
    80 AddIs  [bexI];
    81 AddSEs [bexE];
    82 
    83 (*Trival rewrite rule*)
    84 goal Set.thy "(! x:A.P) = ((? x. x:A) --> P)";
    85 by (simp_tac (!simpset addsimps [Ball_def]) 1);
    86 qed "ball_triv";
    87 
    88 (*Dual form for existentials*)
    89 goal Set.thy "(? x:A.P) = ((? x. x:A) & P)";
    90 by (simp_tac (!simpset addsimps [Bex_def]) 1);
    91 qed "bex_triv";
    92 
    93 Addsimps [ball_triv, bex_triv];
    94 
    95 (** Congruence rules **)
    96 
    97 val prems = goal Set.thy
    98     "[| A=B;  !!x. x:B ==> P(x) = Q(x) |] ==> \
    99 \    (! x:A. P(x)) = (! x:B. Q(x))";
   100 by (resolve_tac (prems RL [ssubst]) 1);
   101 by (REPEAT (ares_tac [ballI,iffI] 1
   102      ORELSE eresolve_tac ([make_elim bspec, mp] @ (prems RL [iffE])) 1));
   103 qed "ball_cong";
   104 
   105 val prems = goal Set.thy
   106     "[| A=B;  !!x. x:B ==> P(x) = Q(x) |] ==> \
   107 \    (? x:A. P(x)) = (? x:B. Q(x))";
   108 by (resolve_tac (prems RL [ssubst]) 1);
   109 by (REPEAT (etac bexE 1
   110      ORELSE ares_tac ([bexI,iffI] @ (prems RL [iffD1,iffD2])) 1));
   111 qed "bex_cong";
   112 
   113 section "Subsets";
   114 
   115 val prems = goalw Set.thy [subset_def] "(!!x.x:A ==> x:B) ==> A <= B";
   116 by (REPEAT (ares_tac (prems @ [ballI]) 1));
   117 qed "subsetI";
   118 
   119 Blast.declConsts (["op <="], [subsetI]);	(*overloading of <=*)
   120 
   121 (*Rule in Modus Ponens style*)
   122 val major::prems = goalw Set.thy [subset_def] "[| A <= B;  c:A |] ==> c:B";
   123 by (rtac (major RS bspec) 1);
   124 by (resolve_tac prems 1);
   125 qed "subsetD";
   126 
   127 (*The same, with reversed premises for use with etac -- cf rev_mp*)
   128 qed_goal "rev_subsetD" Set.thy "[| c:A;  A <= B |] ==> c:B"
   129  (fn prems=>  [ (REPEAT (resolve_tac (prems@[subsetD]) 1)) ]);
   130 
   131 (*Converts A<=B to x:A ==> x:B*)
   132 fun impOfSubs th = th RSN (2, rev_subsetD);
   133 
   134 qed_goal "contra_subsetD" Set.thy "!!c. [| A <= B; c ~: B |] ==> c ~: A"
   135  (fn prems=>  [ (REPEAT (eresolve_tac [asm_rl, contrapos, subsetD] 1)) ]);
   136 
   137 qed_goal "rev_contra_subsetD" Set.thy "!!c. [| c ~: B;  A <= B |] ==> c ~: A"
   138  (fn prems=>  [ (REPEAT (eresolve_tac [asm_rl, contrapos, subsetD] 1)) ]);
   139 
   140 (*Classical elimination rule*)
   141 val major::prems = goalw Set.thy [subset_def] 
   142     "[| A <= B;  c~:A ==> P;  c:B ==> P |] ==> P";
   143 by (rtac (major RS ballE) 1);
   144 by (REPEAT (eresolve_tac prems 1));
   145 qed "subsetCE";
   146 
   147 (*Takes assumptions A<=B; c:A and creates the assumption c:B *)
   148 fun set_mp_tac i = etac subsetCE i  THEN  mp_tac i;
   149 
   150 AddSIs [subsetI];
   151 AddEs  [subsetD, subsetCE];
   152 
   153 qed_goal "subset_refl" Set.thy "A <= (A::'a set)"
   154  (fn _=> [Blast_tac 1]);
   155 
   156 val prems = goal Set.thy "!!B. [| A<=B;  B<=C |] ==> A<=(C::'a set)";
   157 by (Blast_tac 1);
   158 qed "subset_trans";
   159 
   160 
   161 section "Equality";
   162 
   163 (*Anti-symmetry of the subset relation*)
   164 val prems = goal Set.thy "[| A <= B;  B <= A |] ==> A = (B::'a set)";
   165 by (rtac (iffI RS set_ext) 1);
   166 by (REPEAT (ares_tac (prems RL [subsetD]) 1));
   167 qed "subset_antisym";
   168 val equalityI = subset_antisym;
   169 
   170 Blast.declConsts (["op ="], [equalityI]);	(*overloading of equality*)
   171 AddSIs [equalityI];
   172 
   173 (* Equality rules from ZF set theory -- are they appropriate here? *)
   174 val prems = goal Set.thy "A = B ==> A<=(B::'a set)";
   175 by (resolve_tac (prems RL [subst]) 1);
   176 by (rtac subset_refl 1);
   177 qed "equalityD1";
   178 
   179 val prems = goal Set.thy "A = B ==> B<=(A::'a set)";
   180 by (resolve_tac (prems RL [subst]) 1);
   181 by (rtac subset_refl 1);
   182 qed "equalityD2";
   183 
   184 val prems = goal Set.thy
   185     "[| A = B;  [| A<=B; B<=(A::'a set) |] ==> P |]  ==>  P";
   186 by (resolve_tac prems 1);
   187 by (REPEAT (resolve_tac (prems RL [equalityD1,equalityD2]) 1));
   188 qed "equalityE";
   189 
   190 val major::prems = goal Set.thy
   191     "[| A = B;  [| c:A; c:B |] ==> P;  [| c~:A; c~:B |] ==> P |]  ==>  P";
   192 by (rtac (major RS equalityE) 1);
   193 by (REPEAT (contr_tac 1 ORELSE eresolve_tac ([asm_rl,subsetCE]@prems) 1));
   194 qed "equalityCE";
   195 
   196 (*Lemma for creating induction formulae -- for "pattern matching" on p
   197   To make the induction hypotheses usable, apply "spec" or "bspec" to
   198   put universal quantifiers over the free variables in p. *)
   199 val prems = goal Set.thy 
   200     "[| p:A;  !!z. z:A ==> p=z --> R |] ==> R";
   201 by (rtac mp 1);
   202 by (REPEAT (resolve_tac (refl::prems) 1));
   203 qed "setup_induction";
   204 
   205 
   206 section "The empty set -- {}";
   207 
   208 qed_goalw "empty_iff" Set.thy [empty_def] "(c : {}) = False"
   209  (fn _ => [ (Blast_tac 1) ]);
   210 
   211 Addsimps [empty_iff];
   212 
   213 qed_goal "emptyE" Set.thy "!!a. a:{} ==> P"
   214  (fn _ => [Full_simp_tac 1]);
   215 
   216 AddSEs [emptyE];
   217 
   218 qed_goal "empty_subsetI" Set.thy "{} <= A"
   219  (fn _ => [ (Blast_tac 1) ]);
   220 
   221 qed_goal "equals0I" Set.thy "[| !!y. y:A ==> False |] ==> A={}"
   222  (fn [prem]=>
   223   [ (blast_tac (!claset addIs [prem RS FalseE]) 1) ]);
   224 
   225 qed_goal "equals0D" Set.thy "!!a. [| A={};  a:A |] ==> P"
   226  (fn _ => [ (Blast_tac 1) ]);
   227 
   228 goal Set.thy "Ball {} P = True";
   229 by (simp_tac (HOL_ss addsimps [mem_Collect_eq, Ball_def, empty_def]) 1);
   230 qed "ball_empty";
   231 
   232 goal Set.thy "Bex {} P = False";
   233 by (simp_tac (HOL_ss addsimps [mem_Collect_eq, Bex_def, empty_def]) 1);
   234 qed "bex_empty";
   235 Addsimps [ball_empty, bex_empty];
   236 
   237 
   238 section "The Powerset operator -- Pow";
   239 
   240 qed_goalw "Pow_iff" Set.thy [Pow_def] "(A : Pow(B)) = (A <= B)"
   241  (fn _ => [ (Asm_simp_tac 1) ]);
   242 
   243 AddIffs [Pow_iff]; 
   244 
   245 qed_goalw "PowI" Set.thy [Pow_def] "!!A B. A <= B ==> A : Pow(B)"
   246  (fn _ => [ (etac CollectI 1) ]);
   247 
   248 qed_goalw "PowD" Set.thy [Pow_def] "!!A B. A : Pow(B)  ==>  A<=B"
   249  (fn _=> [ (etac CollectD 1) ]);
   250 
   251 val Pow_bottom = empty_subsetI RS PowI;        (* {}: Pow(B) *)
   252 val Pow_top = subset_refl RS PowI;             (* A : Pow(A) *)
   253 
   254 
   255 section "Set complement -- Compl";
   256 
   257 qed_goalw "Compl_iff" Set.thy [Compl_def] "(c : Compl(A)) = (c~:A)"
   258  (fn _ => [ (Blast_tac 1) ]);
   259 
   260 Addsimps [Compl_iff];
   261 
   262 val prems = goalw Set.thy [Compl_def]
   263     "[| c:A ==> False |] ==> c : Compl(A)";
   264 by (REPEAT (ares_tac (prems @ [CollectI,notI]) 1));
   265 qed "ComplI";
   266 
   267 (*This form, with negated conclusion, works well with the Classical prover.
   268   Negated assumptions behave like formulae on the right side of the notional
   269   turnstile...*)
   270 val major::prems = goalw Set.thy [Compl_def]
   271     "c : Compl(A) ==> c~:A";
   272 by (rtac (major RS CollectD) 1);
   273 qed "ComplD";
   274 
   275 val ComplE = make_elim ComplD;
   276 
   277 AddSIs [ComplI];
   278 AddSEs [ComplE];
   279 
   280 
   281 section "Binary union -- Un";
   282 
   283 qed_goalw "Un_iff" Set.thy [Un_def] "(c : A Un B) = (c:A | c:B)"
   284  (fn _ => [ Blast_tac 1 ]);
   285 
   286 Addsimps [Un_iff];
   287 
   288 goal Set.thy "!!c. c:A ==> c : A Un B";
   289 by (Asm_simp_tac 1);
   290 qed "UnI1";
   291 
   292 goal Set.thy "!!c. c:B ==> c : A Un B";
   293 by (Asm_simp_tac 1);
   294 qed "UnI2";
   295 
   296 (*Classical introduction rule: no commitment to A vs B*)
   297 qed_goal "UnCI" Set.thy "(c~:B ==> c:A) ==> c : A Un B"
   298  (fn prems=>
   299   [ (Simp_tac 1),
   300     (REPEAT (ares_tac (prems@[disjCI]) 1)) ]);
   301 
   302 val major::prems = goalw Set.thy [Un_def]
   303     "[| c : A Un B;  c:A ==> P;  c:B ==> P |] ==> P";
   304 by (rtac (major RS CollectD RS disjE) 1);
   305 by (REPEAT (eresolve_tac prems 1));
   306 qed "UnE";
   307 
   308 AddSIs [UnCI];
   309 AddSEs [UnE];
   310 
   311 
   312 section "Binary intersection -- Int";
   313 
   314 qed_goalw "Int_iff" Set.thy [Int_def] "(c : A Int B) = (c:A & c:B)"
   315  (fn _ => [ (Blast_tac 1) ]);
   316 
   317 Addsimps [Int_iff];
   318 
   319 goal Set.thy "!!c. [| c:A;  c:B |] ==> c : A Int B";
   320 by (Asm_simp_tac 1);
   321 qed "IntI";
   322 
   323 goal Set.thy "!!c. c : A Int B ==> c:A";
   324 by (Asm_full_simp_tac 1);
   325 qed "IntD1";
   326 
   327 goal Set.thy "!!c. c : A Int B ==> c:B";
   328 by (Asm_full_simp_tac 1);
   329 qed "IntD2";
   330 
   331 val [major,minor] = goal Set.thy
   332     "[| c : A Int B;  [| c:A; c:B |] ==> P |] ==> P";
   333 by (rtac minor 1);
   334 by (rtac (major RS IntD1) 1);
   335 by (rtac (major RS IntD2) 1);
   336 qed "IntE";
   337 
   338 AddSIs [IntI];
   339 AddSEs [IntE];
   340 
   341 section "Set difference";
   342 
   343 qed_goalw "Diff_iff" Set.thy [set_diff_def] "(c : A-B) = (c:A & c~:B)"
   344  (fn _ => [ (Blast_tac 1) ]);
   345 
   346 Addsimps [Diff_iff];
   347 
   348 qed_goal "DiffI" Set.thy "!!c. [| c : A;  c ~: B |] ==> c : A - B"
   349  (fn _=> [ Asm_simp_tac 1 ]);
   350 
   351 qed_goal "DiffD1" Set.thy "!!c. c : A - B ==> c : A"
   352  (fn _=> [ (Asm_full_simp_tac 1) ]);
   353 
   354 qed_goal "DiffD2" Set.thy "!!c. [| c : A - B;  c : B |] ==> P"
   355  (fn _=> [ (Asm_full_simp_tac 1) ]);
   356 
   357 qed_goal "DiffE" Set.thy "[| c : A - B;  [| c:A; c~:B |] ==> P |] ==> P"
   358  (fn prems=>
   359   [ (resolve_tac prems 1),
   360     (REPEAT (ares_tac (prems RL [DiffD1, DiffD2 RS notI]) 1)) ]);
   361 
   362 AddSIs [DiffI];
   363 AddSEs [DiffE];
   364 
   365 
   366 section "Augmenting a set -- insert";
   367 
   368 qed_goalw "insert_iff" Set.thy [insert_def] "a : insert b A = (a=b | a:A)"
   369  (fn _ => [Blast_tac 1]);
   370 
   371 Addsimps [insert_iff];
   372 
   373 qed_goal "insertI1" Set.thy "a : insert a B"
   374  (fn _ => [Simp_tac 1]);
   375 
   376 qed_goal "insertI2" Set.thy "!!a. a : B ==> a : insert b B"
   377  (fn _=> [Asm_simp_tac 1]);
   378 
   379 qed_goalw "insertE" Set.thy [insert_def]
   380     "[| a : insert b A;  a=b ==> P;  a:A ==> P |] ==> P"
   381  (fn major::prems=>
   382   [ (rtac (major RS UnE) 1),
   383     (REPEAT (eresolve_tac (prems @ [CollectE]) 1)) ]);
   384 
   385 (*Classical introduction rule*)
   386 qed_goal "insertCI" Set.thy "(a~:B ==> a=b) ==> a: insert b B"
   387  (fn prems=>
   388   [ (Simp_tac 1),
   389     (REPEAT (ares_tac (prems@[disjCI]) 1)) ]);
   390 
   391 AddSIs [insertCI]; 
   392 AddSEs [insertE];
   393 
   394 section "Singletons, using insert";
   395 
   396 qed_goal "singletonI" Set.thy "a : {a}"
   397  (fn _=> [ (rtac insertI1 1) ]);
   398 
   399 goal Set.thy "!!a. b : {a} ==> b=a";
   400 by (Blast_tac 1);
   401 qed "singletonD";
   402 
   403 bind_thm ("singletonE", make_elim singletonD);
   404 
   405 qed_goal "singleton_iff" thy "(b : {a}) = (b=a)" 
   406 (fn _ => [Blast_tac 1]);
   407 
   408 goal Set.thy "!!a b. {a}={b} ==> a=b";
   409 by (blast_tac (!claset addEs [equalityE]) 1);
   410 qed "singleton_inject";
   411 
   412 (*Redundant? But unlike insertCI, it proves the subgoal immediately!*)
   413 AddSIs [singletonI];   
   414     
   415 AddSDs [singleton_inject];
   416 
   417 
   418 section "The universal set -- UNIV";
   419 
   420 qed_goal "UNIV_I" Set.thy "x : UNIV"
   421   (fn _ => [rtac ComplI 1, etac emptyE 1]);
   422 
   423 qed_goal "subset_UNIV" Set.thy "A <= UNIV"
   424   (fn _ => [rtac subsetI 1, rtac UNIV_I 1]);
   425 
   426 
   427 section "Unions of families -- UNION x:A. B(x) is Union(B``A)";
   428 
   429 goalw Set.thy [UNION_def] "(b: (UN x:A. B(x))) = (EX x:A. b: B(x))";
   430 by (Blast_tac 1);
   431 qed "UN_iff";
   432 
   433 Addsimps [UN_iff];
   434 
   435 (*The order of the premises presupposes that A is rigid; b may be flexible*)
   436 goal Set.thy "!!b. [| a:A;  b: B(a) |] ==> b: (UN x:A. B(x))";
   437 by (Auto_tac());
   438 qed "UN_I";
   439 
   440 val major::prems = goalw Set.thy [UNION_def]
   441     "[| b : (UN x:A. B(x));  !!x.[| x:A;  b: B(x) |] ==> R |] ==> R";
   442 by (rtac (major RS CollectD RS bexE) 1);
   443 by (REPEAT (ares_tac prems 1));
   444 qed "UN_E";
   445 
   446 AddIs  [UN_I];
   447 AddSEs [UN_E];
   448 
   449 val prems = goal Set.thy
   450     "[| A=B;  !!x. x:B ==> C(x) = D(x) |] ==> \
   451 \    (UN x:A. C(x)) = (UN x:B. D(x))";
   452 by (REPEAT (etac UN_E 1
   453      ORELSE ares_tac ([UN_I,equalityI,subsetI] @ 
   454                       (prems RL [equalityD1,equalityD2] RL [subsetD])) 1));
   455 qed "UN_cong";
   456 
   457 
   458 section "Intersections of families -- INTER x:A. B(x) is Inter(B``A)";
   459 
   460 goalw Set.thy [INTER_def] "(b: (INT x:A. B(x))) = (ALL x:A. b: B(x))";
   461 by (Auto_tac());
   462 qed "INT_iff";
   463 
   464 Addsimps [INT_iff];
   465 
   466 val prems = goalw Set.thy [INTER_def]
   467     "(!!x. x:A ==> b: B(x)) ==> b : (INT x:A. B(x))";
   468 by (REPEAT (ares_tac ([CollectI,ballI] @ prems) 1));
   469 qed "INT_I";
   470 
   471 goal Set.thy "!!b. [| b : (INT x:A. B(x));  a:A |] ==> b: B(a)";
   472 by (Auto_tac());
   473 qed "INT_D";
   474 
   475 (*"Classical" elimination -- by the Excluded Middle on a:A *)
   476 val major::prems = goalw Set.thy [INTER_def]
   477     "[| b : (INT x:A. B(x));  b: B(a) ==> R;  a~:A ==> R |] ==> R";
   478 by (rtac (major RS CollectD RS ballE) 1);
   479 by (REPEAT (eresolve_tac prems 1));
   480 qed "INT_E";
   481 
   482 AddSIs [INT_I];
   483 AddEs  [INT_D, INT_E];
   484 
   485 val prems = goal Set.thy
   486     "[| A=B;  !!x. x:B ==> C(x) = D(x) |] ==> \
   487 \    (INT x:A. C(x)) = (INT x:B. D(x))";
   488 by (REPEAT_FIRST (resolve_tac [INT_I,equalityI,subsetI]));
   489 by (REPEAT (dtac INT_D 1
   490      ORELSE ares_tac (prems RL [equalityD1,equalityD2] RL [subsetD]) 1));
   491 qed "INT_cong";
   492 
   493 
   494 section "Unions over a type; UNION1(B) = Union(range(B))";
   495 
   496 goalw Set.thy [UNION1_def] "(b: (UN x. B(x))) = (EX x. b: B(x))";
   497 by (Simp_tac 1);
   498 by (Blast_tac 1);
   499 qed "UN1_iff";
   500 
   501 Addsimps [UN1_iff];
   502 
   503 (*The order of the premises presupposes that A is rigid; b may be flexible*)
   504 goal Set.thy "!!b. b: B(x) ==> b: (UN x. B(x))";
   505 by (Auto_tac());
   506 qed "UN1_I";
   507 
   508 val major::prems = goalw Set.thy [UNION1_def]
   509     "[| b : (UN x. B(x));  !!x. b: B(x) ==> R |] ==> R";
   510 by (rtac (major RS UN_E) 1);
   511 by (REPEAT (ares_tac prems 1));
   512 qed "UN1_E";
   513 
   514 AddIs  [UN1_I];
   515 AddSEs [UN1_E];
   516 
   517 
   518 section "Intersections over a type; INTER1(B) = Inter(range(B))";
   519 
   520 goalw Set.thy [INTER1_def] "(b: (INT x. B(x))) = (ALL x. b: B(x))";
   521 by (Simp_tac 1);
   522 by (Blast_tac 1);
   523 qed "INT1_iff";
   524 
   525 Addsimps [INT1_iff];
   526 
   527 val prems = goalw Set.thy [INTER1_def]
   528     "(!!x. b: B(x)) ==> b : (INT x. B(x))";
   529 by (REPEAT (ares_tac (INT_I::prems) 1));
   530 qed "INT1_I";
   531 
   532 goal Set.thy "!!b. b : (INT x. B(x)) ==> b: B(a)";
   533 by (Asm_full_simp_tac 1);
   534 qed "INT1_D";
   535 
   536 AddSIs [INT1_I]; 
   537 AddDs  [INT1_D];
   538 
   539 
   540 section "Union";
   541 
   542 goalw Set.thy [Union_def] "(A : Union(C)) = (EX X:C. A:X)";
   543 by (Blast_tac 1);
   544 qed "Union_iff";
   545 
   546 Addsimps [Union_iff];
   547 
   548 (*The order of the premises presupposes that C is rigid; A may be flexible*)
   549 goal Set.thy "!!X. [| X:C;  A:X |] ==> A : Union(C)";
   550 by (Auto_tac());
   551 qed "UnionI";
   552 
   553 val major::prems = goalw Set.thy [Union_def]
   554     "[| A : Union(C);  !!X.[| A:X;  X:C |] ==> R |] ==> R";
   555 by (rtac (major RS UN_E) 1);
   556 by (REPEAT (ares_tac prems 1));
   557 qed "UnionE";
   558 
   559 AddIs  [UnionI];
   560 AddSEs [UnionE];
   561 
   562 
   563 section "Inter";
   564 
   565 goalw Set.thy [Inter_def] "(A : Inter(C)) = (ALL X:C. A:X)";
   566 by (Blast_tac 1);
   567 qed "Inter_iff";
   568 
   569 Addsimps [Inter_iff];
   570 
   571 val prems = goalw Set.thy [Inter_def]
   572     "[| !!X. X:C ==> A:X |] ==> A : Inter(C)";
   573 by (REPEAT (ares_tac ([INT_I] @ prems) 1));
   574 qed "InterI";
   575 
   576 (*A "destruct" rule -- every X in C contains A as an element, but
   577   A:X can hold when X:C does not!  This rule is analogous to "spec". *)
   578 goal Set.thy "!!X. [| A : Inter(C);  X:C |] ==> A:X";
   579 by (Auto_tac());
   580 qed "InterD";
   581 
   582 (*"Classical" elimination rule -- does not require proving X:C *)
   583 val major::prems = goalw Set.thy [Inter_def]
   584     "[| A : Inter(C);  X~:C ==> R;  A:X ==> R |] ==> R";
   585 by (rtac (major RS INT_E) 1);
   586 by (REPEAT (eresolve_tac prems 1));
   587 qed "InterE";
   588 
   589 AddSIs [InterI];
   590 AddEs  [InterD, InterE];
   591 
   592 
   593 (*** Image of a set under a function ***)
   594 
   595 (*Frequently b does not have the syntactic form of f(x).*)
   596 val prems = goalw thy [image_def] "[| b=f(x);  x:A |] ==> b : f``A";
   597 by (REPEAT (resolve_tac (prems @ [CollectI,bexI,prem]) 1));
   598 qed "image_eqI";
   599 
   600 bind_thm ("imageI", refl RS image_eqI);
   601 
   602 (*The eta-expansion gives variable-name preservation.*)
   603 val major::prems = goalw thy [image_def]
   604     "[| b : (%x.f(x))``A;  !!x.[| b=f(x);  x:A |] ==> P |] ==> P"; 
   605 by (rtac (major RS CollectD RS bexE) 1);
   606 by (REPEAT (ares_tac prems 1));
   607 qed "imageE";
   608 
   609 AddIs  [image_eqI];
   610 AddSEs [imageE]; 
   611 
   612 goalw thy [o_def] "(f o g)``r = f``(g``r)";
   613 by (Blast_tac 1);
   614 qed "image_compose";
   615 
   616 goal thy "f``(A Un B) = f``A Un f``B";
   617 by (Blast_tac 1);
   618 qed "image_Un";
   619 
   620 
   621 (*** Range of a function -- just a translation for image! ***)
   622 
   623 goal thy "!!b. b=f(x) ==> b : range(f)";
   624 by (EVERY1 [etac image_eqI, rtac UNIV_I]);
   625 bind_thm ("range_eqI", UNIV_I RSN (2,image_eqI));
   626 
   627 bind_thm ("rangeI", UNIV_I RS imageI);
   628 
   629 val [major,minor] = goal thy 
   630     "[| b : range(%x.f(x));  !!x. b=f(x) ==> P |] ==> P"; 
   631 by (rtac (major RS imageE) 1);
   632 by (etac minor 1);
   633 qed "rangeE";
   634 
   635 AddIs  [rangeI]; 
   636 AddSEs [rangeE]; 
   637 
   638 
   639 (*** Set reasoning tools ***)
   640 
   641 
   642 (*Each of these has ALREADY been added to !simpset above.*)
   643 val mem_simps = [insert_iff, empty_iff, Un_iff, Int_iff, Compl_iff, Diff_iff, 
   644                  mem_Collect_eq, 
   645 		 UN_iff, UN1_iff, Union_iff, 
   646 		 INT_iff, INT1_iff, Inter_iff];
   647 
   648 (*Not for Addsimps -- it can cause goals to blow up!*)
   649 goal Set.thy "(a : (if Q then x else y)) = ((Q --> a:x) & (~Q --> a : y))";
   650 by (simp_tac (!simpset setloop split_tac [expand_if]) 1);
   651 qed "mem_if";
   652 
   653 val mksimps_pairs = ("Ball",[bspec]) :: mksimps_pairs;
   654 
   655 simpset := !simpset addcongs [ball_cong,bex_cong]
   656                     setmksimps (mksimps mksimps_pairs);
   657 
   658 Addsimps[subset_UNIV, empty_subsetI, subset_refl];
   659 
   660 
   661 (*** < ***)
   662 
   663 goalw Set.thy [psubset_def] "!!A::'a set. [| A <= B; A ~= B |] ==> A<B";
   664 by (Blast_tac 1);
   665 qed "psubsetI";
   666 
   667 goalw Set.thy [psubset_def]
   668     "!!x. A < insert x B ==> (x ~: A) & A<=B | x:A & A-{x}<B";
   669 by (Auto_tac());
   670 qed "psubset_insertD";