src/HOL/Nat.thy
author haftmann
Mon Mar 23 19:05:14 2015 +0100 (2015-03-23)
changeset 59816 034b13f4efae
parent 59815 cce82e360c2f
child 59833 ab828c2c5d67
permissions -rw-r--r--
distributivity of partial minus establishes desired properties of dvd in semirings
     1 (*  Title:      HOL/Nat.thy
     2     Author:     Tobias Nipkow and Lawrence C Paulson and Markus Wenzel
     3 
     4 Type "nat" is a linear order, and a datatype; arithmetic operators + -
     5 and * (for div and mod, see theory Divides).
     6 *)
     7 
     8 section {* Natural numbers *}
     9 
    10 theory Nat
    11 imports Inductive Typedef Fun Fields
    12 begin
    13 
    14 ML_file "~~/src/Tools/rat.ML"
    15 
    16 named_theorems arith "arith facts -- only ground formulas"
    17 ML_file "Tools/arith_data.ML"
    18 ML_file "~~/src/Provers/Arith/fast_lin_arith.ML"
    19 
    20 
    21 subsection {* Type @{text ind} *}
    22 
    23 typedecl ind
    24 
    25 axiomatization Zero_Rep :: ind and Suc_Rep :: "ind => ind" where
    26   -- {* the axiom of infinity in 2 parts *}
    27   Suc_Rep_inject:       "Suc_Rep x = Suc_Rep y ==> x = y" and
    28   Suc_Rep_not_Zero_Rep: "Suc_Rep x \<noteq> Zero_Rep"
    29 
    30 subsection {* Type nat *}
    31 
    32 text {* Type definition *}
    33 
    34 inductive Nat :: "ind \<Rightarrow> bool" where
    35   Zero_RepI: "Nat Zero_Rep"
    36 | Suc_RepI: "Nat i \<Longrightarrow> Nat (Suc_Rep i)"
    37 
    38 typedef nat = "{n. Nat n}"
    39   morphisms Rep_Nat Abs_Nat
    40   using Nat.Zero_RepI by auto
    41 
    42 lemma Nat_Rep_Nat:
    43   "Nat (Rep_Nat n)"
    44   using Rep_Nat by simp
    45 
    46 lemma Nat_Abs_Nat_inverse:
    47   "Nat n \<Longrightarrow> Rep_Nat (Abs_Nat n) = n"
    48   using Abs_Nat_inverse by simp
    49 
    50 lemma Nat_Abs_Nat_inject:
    51   "Nat n \<Longrightarrow> Nat m \<Longrightarrow> Abs_Nat n = Abs_Nat m \<longleftrightarrow> n = m"
    52   using Abs_Nat_inject by simp
    53 
    54 instantiation nat :: zero
    55 begin
    56 
    57 definition Zero_nat_def:
    58   "0 = Abs_Nat Zero_Rep"
    59 
    60 instance ..
    61 
    62 end
    63 
    64 definition Suc :: "nat \<Rightarrow> nat" where
    65   "Suc n = Abs_Nat (Suc_Rep (Rep_Nat n))"
    66 
    67 lemma Suc_not_Zero: "Suc m \<noteq> 0"
    68   by (simp add: Zero_nat_def Suc_def Suc_RepI Zero_RepI Nat_Abs_Nat_inject Suc_Rep_not_Zero_Rep Nat_Rep_Nat)
    69 
    70 lemma Zero_not_Suc: "0 \<noteq> Suc m"
    71   by (rule not_sym, rule Suc_not_Zero not_sym)
    72 
    73 lemma Suc_Rep_inject': "Suc_Rep x = Suc_Rep y \<longleftrightarrow> x = y"
    74   by (rule iffI, rule Suc_Rep_inject) simp_all
    75 
    76 lemma nat_induct0:
    77   fixes n
    78   assumes "P 0" and "\<And>n. P n \<Longrightarrow> P (Suc n)"
    79   shows "P n"
    80 using assms
    81 apply (unfold Zero_nat_def Suc_def)
    82 apply (rule Rep_Nat_inverse [THEN subst]) -- {* types force good instantiation *}
    83 apply (erule Nat_Rep_Nat [THEN Nat.induct])
    84 apply (iprover elim: Nat_Abs_Nat_inverse [THEN subst])
    85 done
    86 
    87 free_constructors case_nat for
    88     "0 \<Colon> nat"
    89   | Suc pred
    90 where
    91   "pred (0 \<Colon> nat) = (0 \<Colon> nat)"
    92     apply atomize_elim
    93     apply (rename_tac n, induct_tac n rule: nat_induct0, auto)
    94    apply (simp add: Suc_def Nat_Abs_Nat_inject Nat_Rep_Nat Suc_RepI Suc_Rep_inject'
    95      Rep_Nat_inject)
    96   apply (simp only: Suc_not_Zero)
    97   done
    98 
    99 -- {* Avoid name clashes by prefixing the output of @{text old_rep_datatype} with @{text old}. *}
   100 setup {* Sign.mandatory_path "old" *}
   101 
   102 old_rep_datatype "0 \<Colon> nat" Suc
   103   apply (erule nat_induct0, assumption)
   104  apply (rule nat.inject)
   105 apply (rule nat.distinct(1))
   106 done
   107 
   108 setup {* Sign.parent_path *}
   109 
   110 -- {* But erase the prefix for properties that are not generated by @{text free_constructors}. *}
   111 setup {* Sign.mandatory_path "nat" *}
   112 
   113 declare
   114   old.nat.inject[iff del]
   115   old.nat.distinct(1)[simp del, induct_simp del]
   116 
   117 lemmas induct = old.nat.induct
   118 lemmas inducts = old.nat.inducts
   119 lemmas rec = old.nat.rec
   120 lemmas simps = nat.inject nat.distinct nat.case nat.rec
   121 
   122 setup {* Sign.parent_path *}
   123 
   124 abbreviation rec_nat :: "'a \<Rightarrow> (nat \<Rightarrow> 'a \<Rightarrow> 'a) \<Rightarrow> nat \<Rightarrow> 'a" where
   125   "rec_nat \<equiv> old.rec_nat"
   126 
   127 declare nat.sel[code del]
   128 
   129 hide_const (open) Nat.pred -- {* hide everything related to the selector *}
   130 hide_fact
   131   nat.case_eq_if
   132   nat.collapse
   133   nat.expand
   134   nat.sel
   135   nat.exhaust_sel
   136   nat.split_sel
   137   nat.split_sel_asm
   138 
   139 lemma nat_exhaust [case_names 0 Suc, cases type: nat]:
   140   -- {* for backward compatibility -- names of variables differ *}
   141   "(y = 0 \<Longrightarrow> P) \<Longrightarrow> (\<And>nat. y = Suc nat \<Longrightarrow> P) \<Longrightarrow> P"
   142 by (rule old.nat.exhaust)
   143 
   144 lemma nat_induct [case_names 0 Suc, induct type: nat]:
   145   -- {* for backward compatibility -- names of variables differ *}
   146   fixes n
   147   assumes "P 0" and "\<And>n. P n \<Longrightarrow> P (Suc n)"
   148   shows "P n"
   149 using assms by (rule nat.induct)
   150 
   151 hide_fact
   152   nat_exhaust
   153   nat_induct0
   154 
   155 ML {*
   156 val nat_basic_lfp_sugar =
   157   let
   158     val ctr_sugar = the (Ctr_Sugar.ctr_sugar_of_global @{theory} @{type_name nat});
   159     val recx = Logic.varify_types_global @{term rec_nat};
   160     val C = body_type (fastype_of recx);
   161   in
   162     {T = HOLogic.natT, fp_res_index = 0, C = C, fun_arg_Tsss = [[], [[HOLogic.natT, C]]],
   163      ctr_sugar = ctr_sugar, recx = recx, rec_thms = @{thms nat.rec}}
   164   end;
   165 *}
   166 
   167 setup {*
   168 let
   169   fun basic_lfp_sugars_of _ [@{typ nat}] _ _ ctxt =
   170       ([], [0], [nat_basic_lfp_sugar], [], [], TrueI (*dummy*), [], false, ctxt)
   171     | basic_lfp_sugars_of bs arg_Ts callers callssss ctxt =
   172       BNF_LFP_Rec_Sugar.default_basic_lfp_sugars_of bs arg_Ts callers callssss ctxt;
   173 in
   174   BNF_LFP_Rec_Sugar.register_lfp_rec_extension
   175     {nested_simps = [], is_new_datatype = K (K true), basic_lfp_sugars_of = basic_lfp_sugars_of,
   176      rewrite_nested_rec_call = NONE}
   177 end
   178 *}
   179 
   180 text {* Injectiveness and distinctness lemmas *}
   181 
   182 lemma inj_Suc[simp]: "inj_on Suc N"
   183   by (simp add: inj_on_def)
   184 
   185 lemma Suc_neq_Zero: "Suc m = 0 \<Longrightarrow> R"
   186 by (rule notE, rule Suc_not_Zero)
   187 
   188 lemma Zero_neq_Suc: "0 = Suc m \<Longrightarrow> R"
   189 by (rule Suc_neq_Zero, erule sym)
   190 
   191 lemma Suc_inject: "Suc x = Suc y \<Longrightarrow> x = y"
   192 by (rule inj_Suc [THEN injD])
   193 
   194 lemma n_not_Suc_n: "n \<noteq> Suc n"
   195 by (induct n) simp_all
   196 
   197 lemma Suc_n_not_n: "Suc n \<noteq> n"
   198 by (rule not_sym, rule n_not_Suc_n)
   199 
   200 text {* A special form of induction for reasoning
   201   about @{term "m < n"} and @{term "m - n"} *}
   202 
   203 lemma diff_induct: "(!!x. P x 0) ==> (!!y. P 0 (Suc y)) ==>
   204     (!!x y. P x y ==> P (Suc x) (Suc y)) ==> P m n"
   205   apply (rule_tac x = m in spec)
   206   apply (induct n)
   207   prefer 2
   208   apply (rule allI)
   209   apply (induct_tac x, iprover+)
   210   done
   211 
   212 
   213 subsection {* Arithmetic operators *}
   214 
   215 instantiation nat :: comm_monoid_diff
   216 begin
   217 
   218 primrec plus_nat where
   219   add_0:      "0 + n = (n\<Colon>nat)"
   220 | add_Suc:  "Suc m + n = Suc (m + n)"
   221 
   222 lemma add_0_right [simp]: "m + 0 = (m::nat)"
   223   by (induct m) simp_all
   224 
   225 lemma add_Suc_right [simp]: "m + Suc n = Suc (m + n)"
   226   by (induct m) simp_all
   227 
   228 declare add_0 [code]
   229 
   230 lemma add_Suc_shift [code]: "Suc m + n = m + Suc n"
   231   by simp
   232 
   233 primrec minus_nat where
   234   diff_0 [code]: "m - 0 = (m\<Colon>nat)"
   235 | diff_Suc: "m - Suc n = (case m - n of 0 => 0 | Suc k => k)"
   236 
   237 declare diff_Suc [simp del]
   238 
   239 lemma diff_0_eq_0 [simp, code]: "0 - n = (0::nat)"
   240   by (induct n) (simp_all add: diff_Suc)
   241 
   242 lemma diff_Suc_Suc [simp, code]: "Suc m - Suc n = m - n"
   243   by (induct n) (simp_all add: diff_Suc)
   244 
   245 instance proof
   246   fix n m q :: nat
   247   show "(n + m) + q = n + (m + q)" by (induct n) simp_all
   248   show "n + m = m + n" by (induct n) simp_all
   249   show "m + n - m = n" by (induct m) simp_all
   250   show "n - m - q = n - (m + q)" by (induct q) (simp_all add: diff_Suc)
   251   show "0 + n = n" by simp
   252   show "0 - n = 0" by simp
   253 qed
   254 
   255 end
   256 
   257 hide_fact (open) add_0 add_0_right diff_0
   258 
   259 instantiation nat :: comm_semiring_1_cancel
   260 begin
   261 
   262 definition
   263   One_nat_def [simp]: "1 = Suc 0"
   264 
   265 primrec times_nat where
   266   mult_0:     "0 * n = (0\<Colon>nat)"
   267 | mult_Suc: "Suc m * n = n + (m * n)"
   268 
   269 lemma mult_0_right [simp]: "(m::nat) * 0 = 0"
   270   by (induct m) simp_all
   271 
   272 lemma mult_Suc_right [simp]: "m * Suc n = m + (m * n)"
   273   by (induct m) (simp_all add: add.left_commute)
   274 
   275 lemma add_mult_distrib: "(m + n) * k = (m * k) + ((n * k)::nat)"
   276   by (induct m) (simp_all add: add.assoc)
   277 
   278 instance proof
   279   fix n m q :: nat
   280   show "0 \<noteq> (1::nat)" unfolding One_nat_def by simp
   281   show "1 * n = n" unfolding One_nat_def by simp
   282   show "n * m = m * n" by (induct n) simp_all
   283   show "(n * m) * q = n * (m * q)" by (induct n) (simp_all add: add_mult_distrib)
   284   show "(n + m) * q = n * q + m * q" by (rule add_mult_distrib)
   285 qed
   286 
   287 end
   288 
   289 subsubsection {* Addition *}
   290 
   291 lemma nat_add_left_cancel:
   292   fixes k m n :: nat
   293   shows "k + m = k + n \<longleftrightarrow> m = n"
   294   by (fact add_left_cancel)
   295 
   296 lemma nat_add_right_cancel:
   297   fixes k m n :: nat
   298   shows "m + k = n + k \<longleftrightarrow> m = n"
   299   by (fact add_right_cancel)
   300 
   301 text {* Reasoning about @{text "m + 0 = 0"}, etc. *}
   302 
   303 lemma add_is_0 [iff]:
   304   fixes m n :: nat
   305   shows "(m + n = 0) = (m = 0 & n = 0)"
   306   by (cases m) simp_all
   307 
   308 lemma add_is_1:
   309   "(m+n= Suc 0) = (m= Suc 0 & n=0 | m=0 & n= Suc 0)"
   310   by (cases m) simp_all
   311 
   312 lemma one_is_add:
   313   "(Suc 0 = m + n) = (m = Suc 0 & n = 0 | m = 0 & n = Suc 0)"
   314   by (rule trans, rule eq_commute, rule add_is_1)
   315 
   316 lemma add_eq_self_zero:
   317   fixes m n :: nat
   318   shows "m + n = m \<Longrightarrow> n = 0"
   319   by (induct m) simp_all
   320 
   321 lemma inj_on_add_nat[simp]: "inj_on (%n::nat. n+k) N"
   322   apply (induct k)
   323    apply simp
   324   apply(drule comp_inj_on[OF _ inj_Suc])
   325   apply (simp add:o_def)
   326   done
   327 
   328 lemma Suc_eq_plus1: "Suc n = n + 1"
   329   unfolding One_nat_def by simp
   330 
   331 lemma Suc_eq_plus1_left: "Suc n = 1 + n"
   332   unfolding One_nat_def by simp
   333 
   334 
   335 subsubsection {* Difference *}
   336 
   337 lemma diff_self_eq_0 [simp]: "(m\<Colon>nat) - m = 0"
   338   by (fact diff_cancel)
   339 
   340 lemma diff_diff_left: "(i::nat) - j - k = i - (j + k)"
   341   by (fact diff_diff_add)
   342 
   343 lemma Suc_diff_diff [simp]: "(Suc m - n) - Suc k = m - n - k"
   344   by (simp add: diff_diff_left)
   345 
   346 lemma diff_commute: "(i::nat) - j - k = i - k - j"
   347   by (fact diff_right_commute)
   348 
   349 lemma diff_add_inverse: "(n + m) - n = (m::nat)"
   350   by (fact add_diff_cancel_left')
   351 
   352 lemma diff_add_inverse2: "(m + n) - n = (m::nat)"
   353   by (fact add_diff_cancel_right')
   354 
   355 lemma diff_cancel: "(k + m) - (k + n) = m - (n::nat)"
   356   by (fact add_diff_cancel_left)
   357 
   358 lemma diff_cancel2: "(m + k) - (n + k) = m - (n::nat)"
   359   by (fact add_diff_cancel_right)
   360 
   361 lemma diff_add_0: "n - (n + m) = (0::nat)"
   362   by (fact diff_add_zero)
   363 
   364 lemma diff_Suc_1 [simp]: "Suc n - 1 = n"
   365   unfolding One_nat_def by simp
   366 
   367 text {* Difference distributes over multiplication *}
   368 
   369 instance nat :: comm_semiring_1_diff_distrib
   370 proof
   371   fix k m n :: nat
   372   show "k * ((m::nat) - n) = (k * m) - (k * n)"
   373     by (induct m n rule: diff_induct) simp_all
   374 qed
   375 
   376 lemma diff_mult_distrib:
   377   "((m::nat) - n) * k = (m * k) - (n * k)"
   378   by (fact left_diff_distrib')
   379   
   380 lemma diff_mult_distrib2:
   381   "k * ((m::nat) - n) = (k * m) - (k * n)"
   382   by (fact right_diff_distrib')
   383 
   384 
   385 subsubsection {* Multiplication *}
   386 
   387 lemma add_mult_distrib2: "k * (m + n) = (k * m) + ((k * n)::nat)"
   388   by (fact distrib_left)
   389 
   390 lemma mult_is_0 [simp]: "((m::nat) * n = 0) = (m=0 | n=0)"
   391   by (induct m) auto
   392 
   393 lemmas nat_distrib =
   394   add_mult_distrib add_mult_distrib2 diff_mult_distrib diff_mult_distrib2
   395 
   396 lemma mult_eq_1_iff [simp]: "(m * n = Suc 0) = (m = Suc 0 & n = Suc 0)"
   397   apply (induct m)
   398    apply simp
   399   apply (induct n)
   400    apply auto
   401   done
   402 
   403 lemma one_eq_mult_iff [simp]: "(Suc 0 = m * n) = (m = Suc 0 & n = Suc 0)"
   404   apply (rule trans)
   405   apply (rule_tac [2] mult_eq_1_iff, fastforce)
   406   done
   407 
   408 lemma nat_mult_eq_1_iff [simp]: "m * n = (1::nat) \<longleftrightarrow> m = 1 \<and> n = 1"
   409   unfolding One_nat_def by (rule mult_eq_1_iff)
   410 
   411 lemma nat_1_eq_mult_iff [simp]: "(1::nat) = m * n \<longleftrightarrow> m = 1 \<and> n = 1"
   412   unfolding One_nat_def by (rule one_eq_mult_iff)
   413 
   414 lemma mult_cancel1 [simp]: "(k * m = k * n) = (m = n | (k = (0::nat)))"
   415 proof -
   416   have "k \<noteq> 0 \<Longrightarrow> k * m = k * n \<Longrightarrow> m = n"
   417   proof (induct n arbitrary: m)
   418     case 0 then show "m = 0" by simp
   419   next
   420     case (Suc n) then show "m = Suc n"
   421       by (cases m) (simp_all add: eq_commute [of "0"])
   422   qed
   423   then show ?thesis by auto
   424 qed
   425 
   426 lemma mult_cancel2 [simp]: "(m * k = n * k) = (m = n | (k = (0::nat)))"
   427   by (simp add: mult.commute)
   428 
   429 lemma Suc_mult_cancel1: "(Suc k * m = Suc k * n) = (m = n)"
   430   by (subst mult_cancel1) simp
   431 
   432 
   433 subsection {* Orders on @{typ nat} *}
   434 
   435 subsubsection {* Operation definition *}
   436 
   437 instantiation nat :: linorder
   438 begin
   439 
   440 primrec less_eq_nat where
   441   "(0\<Colon>nat) \<le> n \<longleftrightarrow> True"
   442 | "Suc m \<le> n \<longleftrightarrow> (case n of 0 \<Rightarrow> False | Suc n \<Rightarrow> m \<le> n)"
   443 
   444 declare less_eq_nat.simps [simp del]
   445 lemma le0 [iff]: "0 \<le> (n\<Colon>nat)" by (simp add: less_eq_nat.simps)
   446 lemma [code]: "(0\<Colon>nat) \<le> n \<longleftrightarrow> True" by simp
   447 
   448 definition less_nat where
   449   less_eq_Suc_le: "n < m \<longleftrightarrow> Suc n \<le> m"
   450 
   451 lemma Suc_le_mono [iff]: "Suc n \<le> Suc m \<longleftrightarrow> n \<le> m"
   452   by (simp add: less_eq_nat.simps(2))
   453 
   454 lemma Suc_le_eq [code]: "Suc m \<le> n \<longleftrightarrow> m < n"
   455   unfolding less_eq_Suc_le ..
   456 
   457 lemma le_0_eq [iff]: "(n\<Colon>nat) \<le> 0 \<longleftrightarrow> n = 0"
   458   by (induct n) (simp_all add: less_eq_nat.simps(2))
   459 
   460 lemma not_less0 [iff]: "\<not> n < (0\<Colon>nat)"
   461   by (simp add: less_eq_Suc_le)
   462 
   463 lemma less_nat_zero_code [code]: "n < (0\<Colon>nat) \<longleftrightarrow> False"
   464   by simp
   465 
   466 lemma Suc_less_eq [iff]: "Suc m < Suc n \<longleftrightarrow> m < n"
   467   by (simp add: less_eq_Suc_le)
   468 
   469 lemma less_Suc_eq_le [code]: "m < Suc n \<longleftrightarrow> m \<le> n"
   470   by (simp add: less_eq_Suc_le)
   471 
   472 lemma Suc_less_eq2: "Suc n < m \<longleftrightarrow> (\<exists>m'. m = Suc m' \<and> n < m')"
   473   by (cases m) auto
   474 
   475 lemma le_SucI: "m \<le> n \<Longrightarrow> m \<le> Suc n"
   476   by (induct m arbitrary: n)
   477     (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   478 
   479 lemma Suc_leD: "Suc m \<le> n \<Longrightarrow> m \<le> n"
   480   by (cases n) (auto intro: le_SucI)
   481 
   482 lemma less_SucI: "m < n \<Longrightarrow> m < Suc n"
   483   by (simp add: less_eq_Suc_le) (erule Suc_leD)
   484 
   485 lemma Suc_lessD: "Suc m < n \<Longrightarrow> m < n"
   486   by (simp add: less_eq_Suc_le) (erule Suc_leD)
   487 
   488 instance
   489 proof
   490   fix n m :: nat
   491   show "n < m \<longleftrightarrow> n \<le> m \<and> \<not> m \<le> n" 
   492   proof (induct n arbitrary: m)
   493     case 0 then show ?case by (cases m) (simp_all add: less_eq_Suc_le)
   494   next
   495     case (Suc n) then show ?case by (cases m) (simp_all add: less_eq_Suc_le)
   496   qed
   497 next
   498   fix n :: nat show "n \<le> n" by (induct n) simp_all
   499 next
   500   fix n m :: nat assume "n \<le> m" and "m \<le> n"
   501   then show "n = m"
   502     by (induct n arbitrary: m)
   503       (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   504 next
   505   fix n m q :: nat assume "n \<le> m" and "m \<le> q"
   506   then show "n \<le> q"
   507   proof (induct n arbitrary: m q)
   508     case 0 show ?case by simp
   509   next
   510     case (Suc n) then show ?case
   511       by (simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits, clarify,
   512         simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits, clarify,
   513         simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits)
   514   qed
   515 next
   516   fix n m :: nat show "n \<le> m \<or> m \<le> n"
   517     by (induct n arbitrary: m)
   518       (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   519 qed
   520 
   521 end
   522 
   523 instantiation nat :: order_bot
   524 begin
   525 
   526 definition bot_nat :: nat where
   527   "bot_nat = 0"
   528 
   529 instance proof
   530 qed (simp add: bot_nat_def)
   531 
   532 end
   533 
   534 instance nat :: no_top
   535   by default (auto intro: less_Suc_eq_le [THEN iffD2])
   536 
   537 
   538 subsubsection {* Introduction properties *}
   539 
   540 lemma lessI [iff]: "n < Suc n"
   541   by (simp add: less_Suc_eq_le)
   542 
   543 lemma zero_less_Suc [iff]: "0 < Suc n"
   544   by (simp add: less_Suc_eq_le)
   545 
   546 
   547 subsubsection {* Elimination properties *}
   548 
   549 lemma less_not_refl: "~ n < (n::nat)"
   550   by (rule order_less_irrefl)
   551 
   552 lemma less_not_refl2: "n < m ==> m \<noteq> (n::nat)"
   553   by (rule not_sym) (rule less_imp_neq) 
   554 
   555 lemma less_not_refl3: "(s::nat) < t ==> s \<noteq> t"
   556   by (rule less_imp_neq)
   557 
   558 lemma less_irrefl_nat: "(n::nat) < n ==> R"
   559   by (rule notE, rule less_not_refl)
   560 
   561 lemma less_zeroE: "(n::nat) < 0 ==> R"
   562   by (rule notE) (rule not_less0)
   563 
   564 lemma less_Suc_eq: "(m < Suc n) = (m < n | m = n)"
   565   unfolding less_Suc_eq_le le_less ..
   566 
   567 lemma less_Suc0 [iff]: "(n < Suc 0) = (n = 0)"
   568   by (simp add: less_Suc_eq)
   569 
   570 lemma less_one [iff]: "(n < (1::nat)) = (n = 0)"
   571   unfolding One_nat_def by (rule less_Suc0)
   572 
   573 lemma Suc_mono: "m < n ==> Suc m < Suc n"
   574   by simp
   575 
   576 text {* "Less than" is antisymmetric, sort of *}
   577 lemma less_antisym: "\<lbrakk> \<not> n < m; n < Suc m \<rbrakk> \<Longrightarrow> m = n"
   578   unfolding not_less less_Suc_eq_le by (rule antisym)
   579 
   580 lemma nat_neq_iff: "((m::nat) \<noteq> n) = (m < n | n < m)"
   581   by (rule linorder_neq_iff)
   582 
   583 lemma nat_less_cases: assumes major: "(m::nat) < n ==> P n m"
   584   and eqCase: "m = n ==> P n m" and lessCase: "n<m ==> P n m"
   585   shows "P n m"
   586   apply (rule less_linear [THEN disjE])
   587   apply (erule_tac [2] disjE)
   588   apply (erule lessCase)
   589   apply (erule sym [THEN eqCase])
   590   apply (erule major)
   591   done
   592 
   593 
   594 subsubsection {* Inductive (?) properties *}
   595 
   596 lemma Suc_lessI: "m < n ==> Suc m \<noteq> n ==> Suc m < n"
   597   unfolding less_eq_Suc_le [of m] le_less by simp 
   598 
   599 lemma lessE:
   600   assumes major: "i < k"
   601   and p1: "k = Suc i ==> P" and p2: "!!j. i < j ==> k = Suc j ==> P"
   602   shows P
   603 proof -
   604   from major have "\<exists>j. i \<le> j \<and> k = Suc j"
   605     unfolding less_eq_Suc_le by (induct k) simp_all
   606   then have "(\<exists>j. i < j \<and> k = Suc j) \<or> k = Suc i"
   607     by (clarsimp simp add: less_le)
   608   with p1 p2 show P by auto
   609 qed
   610 
   611 lemma less_SucE: assumes major: "m < Suc n"
   612   and less: "m < n ==> P" and eq: "m = n ==> P" shows P
   613   apply (rule major [THEN lessE])
   614   apply (rule eq, blast)
   615   apply (rule less, blast)
   616   done
   617 
   618 lemma Suc_lessE: assumes major: "Suc i < k"
   619   and minor: "!!j. i < j ==> k = Suc j ==> P" shows P
   620   apply (rule major [THEN lessE])
   621   apply (erule lessI [THEN minor])
   622   apply (erule Suc_lessD [THEN minor], assumption)
   623   done
   624 
   625 lemma Suc_less_SucD: "Suc m < Suc n ==> m < n"
   626   by simp
   627 
   628 lemma less_trans_Suc:
   629   assumes le: "i < j" shows "j < k ==> Suc i < k"
   630   apply (induct k, simp_all)
   631   apply (insert le)
   632   apply (simp add: less_Suc_eq)
   633   apply (blast dest: Suc_lessD)
   634   done
   635 
   636 text {* Can be used with @{text less_Suc_eq} to get @{term "n = m | n < m"} *}
   637 lemma not_less_eq: "\<not> m < n \<longleftrightarrow> n < Suc m"
   638   unfolding not_less less_Suc_eq_le ..
   639 
   640 lemma not_less_eq_eq: "\<not> m \<le> n \<longleftrightarrow> Suc n \<le> m"
   641   unfolding not_le Suc_le_eq ..
   642 
   643 text {* Properties of "less than or equal" *}
   644 
   645 lemma le_imp_less_Suc: "m \<le> n ==> m < Suc n"
   646   unfolding less_Suc_eq_le .
   647 
   648 lemma Suc_n_not_le_n: "~ Suc n \<le> n"
   649   unfolding not_le less_Suc_eq_le ..
   650 
   651 lemma le_Suc_eq: "(m \<le> Suc n) = (m \<le> n | m = Suc n)"
   652   by (simp add: less_Suc_eq_le [symmetric] less_Suc_eq)
   653 
   654 lemma le_SucE: "m \<le> Suc n ==> (m \<le> n ==> R) ==> (m = Suc n ==> R) ==> R"
   655   by (drule le_Suc_eq [THEN iffD1], iprover+)
   656 
   657 lemma Suc_leI: "m < n ==> Suc(m) \<le> n"
   658   unfolding Suc_le_eq .
   659 
   660 text {* Stronger version of @{text Suc_leD} *}
   661 lemma Suc_le_lessD: "Suc m \<le> n ==> m < n"
   662   unfolding Suc_le_eq .
   663 
   664 lemma less_imp_le_nat: "m < n ==> m \<le> (n::nat)"
   665   unfolding less_eq_Suc_le by (rule Suc_leD)
   666 
   667 text {* For instance, @{text "(Suc m < Suc n) = (Suc m \<le> n) = (m < n)"} *}
   668 lemmas le_simps = less_imp_le_nat less_Suc_eq_le Suc_le_eq
   669 
   670 
   671 text {* Equivalence of @{term "m \<le> n"} and @{term "m < n | m = n"} *}
   672 
   673 lemma less_or_eq_imp_le: "m < n | m = n ==> m \<le> (n::nat)"
   674   unfolding le_less .
   675 
   676 lemma le_eq_less_or_eq: "(m \<le> (n::nat)) = (m < n | m=n)"
   677   by (rule le_less)
   678 
   679 text {* Useful with @{text blast}. *}
   680 lemma eq_imp_le: "(m::nat) = n ==> m \<le> n"
   681   by auto
   682 
   683 lemma le_refl: "n \<le> (n::nat)"
   684   by simp
   685 
   686 lemma le_trans: "[| i \<le> j; j \<le> k |] ==> i \<le> (k::nat)"
   687   by (rule order_trans)
   688 
   689 lemma le_antisym: "[| m \<le> n; n \<le> m |] ==> m = (n::nat)"
   690   by (rule antisym)
   691 
   692 lemma nat_less_le: "((m::nat) < n) = (m \<le> n & m \<noteq> n)"
   693   by (rule less_le)
   694 
   695 lemma le_neq_implies_less: "(m::nat) \<le> n ==> m \<noteq> n ==> m < n"
   696   unfolding less_le ..
   697 
   698 lemma nat_le_linear: "(m::nat) \<le> n | n \<le> m"
   699   by (rule linear)
   700 
   701 lemmas linorder_neqE_nat = linorder_neqE [where 'a = nat]
   702 
   703 lemma le_less_Suc_eq: "m \<le> n ==> (n < Suc m) = (n = m)"
   704   unfolding less_Suc_eq_le by auto
   705 
   706 lemma not_less_less_Suc_eq: "~ n < m ==> (n < Suc m) = (n = m)"
   707   unfolding not_less by (rule le_less_Suc_eq)
   708 
   709 lemmas not_less_simps = not_less_less_Suc_eq le_less_Suc_eq
   710 
   711 lemma not0_implies_Suc: "n \<noteq> 0 ==> \<exists>m. n = Suc m"
   712 by (cases n) simp_all
   713 
   714 lemma gr0_implies_Suc: "n > 0 ==> \<exists>m. n = Suc m"
   715 by (cases n) simp_all
   716 
   717 lemma gr_implies_not0: fixes n :: nat shows "m<n ==> n \<noteq> 0"
   718 by (cases n) simp_all
   719 
   720 lemma neq0_conv[iff]: fixes n :: nat shows "(n \<noteq> 0) = (0 < n)"
   721 by (cases n) simp_all
   722 
   723 text {* This theorem is useful with @{text blast} *}
   724 lemma gr0I: "((n::nat) = 0 ==> False) ==> 0 < n"
   725 by (rule neq0_conv[THEN iffD1], iprover)
   726 
   727 lemma gr0_conv_Suc: "(0 < n) = (\<exists>m. n = Suc m)"
   728 by (fast intro: not0_implies_Suc)
   729 
   730 lemma not_gr0 [iff]: "!!n::nat. (~ (0 < n)) = (n = 0)"
   731 using neq0_conv by blast
   732 
   733 lemma Suc_le_D: "(Suc n \<le> m') ==> (? m. m' = Suc m)"
   734 by (induct m') simp_all
   735 
   736 text {* Useful in certain inductive arguments *}
   737 lemma less_Suc_eq_0_disj: "(m < Suc n) = (m = 0 | (\<exists>j. m = Suc j & j < n))"
   738 by (cases m) simp_all
   739 
   740 
   741 subsubsection {* Monotonicity of Addition *}
   742 
   743 lemma Suc_pred [simp]: "n>0 ==> Suc (n - Suc 0) = n"
   744 by (simp add: diff_Suc split: nat.split)
   745 
   746 lemma Suc_diff_1 [simp]: "0 < n ==> Suc (n - 1) = n"
   747 unfolding One_nat_def by (rule Suc_pred)
   748 
   749 lemma nat_add_left_cancel_le [simp]: "(k + m \<le> k + n) = (m\<le>(n::nat))"
   750 by (induct k) simp_all
   751 
   752 lemma nat_add_left_cancel_less [simp]: "(k + m < k + n) = (m<(n::nat))"
   753 by (induct k) simp_all
   754 
   755 lemma add_gr_0 [iff]: "!!m::nat. (m + n > 0) = (m>0 | n>0)"
   756 by(auto dest:gr0_implies_Suc)
   757 
   758 text {* strict, in 1st argument *}
   759 lemma add_less_mono1: "i < j ==> i + k < j + (k::nat)"
   760 by (induct k) simp_all
   761 
   762 text {* strict, in both arguments *}
   763 lemma add_less_mono: "[|i < j; k < l|] ==> i + k < j + (l::nat)"
   764   apply (rule add_less_mono1 [THEN less_trans], assumption+)
   765   apply (induct j, simp_all)
   766   done
   767 
   768 text {* Deleted @{text less_natE}; use @{text "less_imp_Suc_add RS exE"} *}
   769 lemma less_imp_Suc_add: "m < n ==> (\<exists>k. n = Suc (m + k))"
   770   apply (induct n)
   771   apply (simp_all add: order_le_less)
   772   apply (blast elim!: less_SucE
   773                intro!: Nat.add_0_right [symmetric] add_Suc_right [symmetric])
   774   done
   775 
   776 lemma le_Suc_ex: "(k::nat) \<le> l \<Longrightarrow> (\<exists>n. l = k + n)"
   777   by (auto simp: less_Suc_eq_le[symmetric] dest: less_imp_Suc_add)
   778 
   779 text {* strict, in 1st argument; proof is by induction on @{text "k > 0"} *}
   780 lemma mult_less_mono2: "(i::nat) < j ==> 0<k ==> k * i < k * j"
   781 apply(auto simp: gr0_conv_Suc)
   782 apply (induct_tac m)
   783 apply (simp_all add: add_less_mono)
   784 done
   785 
   786 text{*The naturals form an ordered @{text comm_semiring_1_cancel}*}
   787 instance nat :: linordered_semidom
   788 proof
   789   show "0 < (1::nat)" by simp
   790   show "\<And>m n q :: nat. m \<le> n \<Longrightarrow> q + m \<le> q + n" by simp
   791   show "\<And>m n q :: nat. m < n \<Longrightarrow> 0 < q \<Longrightarrow> q * m < q * n" by (simp add: mult_less_mono2)
   792 qed
   793 
   794 instance nat :: semiring_no_zero_divisors
   795 proof
   796   fix m n :: nat
   797   show "m \<noteq> 0 \<Longrightarrow> n \<noteq> 0 \<Longrightarrow> m * n \<noteq> 0" by simp
   798 qed
   799 
   800 
   801 subsubsection {* @{term min} and @{term max} *}
   802 
   803 lemma mono_Suc: "mono Suc"
   804 by (rule monoI) simp
   805 
   806 lemma min_0L [simp]: "min 0 n = (0::nat)"
   807 by (rule min_absorb1) simp
   808 
   809 lemma min_0R [simp]: "min n 0 = (0::nat)"
   810 by (rule min_absorb2) simp
   811 
   812 lemma min_Suc_Suc [simp]: "min (Suc m) (Suc n) = Suc (min m n)"
   813 by (simp add: mono_Suc min_of_mono)
   814 
   815 lemma min_Suc1:
   816    "min (Suc n) m = (case m of 0 => 0 | Suc m' => Suc(min n m'))"
   817 by (simp split: nat.split)
   818 
   819 lemma min_Suc2:
   820    "min m (Suc n) = (case m of 0 => 0 | Suc m' => Suc(min m' n))"
   821 by (simp split: nat.split)
   822 
   823 lemma max_0L [simp]: "max 0 n = (n::nat)"
   824 by (rule max_absorb2) simp
   825 
   826 lemma max_0R [simp]: "max n 0 = (n::nat)"
   827 by (rule max_absorb1) simp
   828 
   829 lemma max_Suc_Suc [simp]: "max (Suc m) (Suc n) = Suc(max m n)"
   830 by (simp add: mono_Suc max_of_mono)
   831 
   832 lemma max_Suc1:
   833    "max (Suc n) m = (case m of 0 => Suc n | Suc m' => Suc(max n m'))"
   834 by (simp split: nat.split)
   835 
   836 lemma max_Suc2:
   837    "max m (Suc n) = (case m of 0 => Suc n | Suc m' => Suc(max m' n))"
   838 by (simp split: nat.split)
   839 
   840 lemma nat_mult_min_left:
   841   fixes m n q :: nat
   842   shows "min m n * q = min (m * q) (n * q)"
   843   by (simp add: min_def not_le) (auto dest: mult_right_le_imp_le mult_right_less_imp_less le_less_trans)
   844 
   845 lemma nat_mult_min_right:
   846   fixes m n q :: nat
   847   shows "m * min n q = min (m * n) (m * q)"
   848   by (simp add: min_def not_le) (auto dest: mult_left_le_imp_le mult_left_less_imp_less le_less_trans)
   849 
   850 lemma nat_add_max_left:
   851   fixes m n q :: nat
   852   shows "max m n + q = max (m + q) (n + q)"
   853   by (simp add: max_def)
   854 
   855 lemma nat_add_max_right:
   856   fixes m n q :: nat
   857   shows "m + max n q = max (m + n) (m + q)"
   858   by (simp add: max_def)
   859 
   860 lemma nat_mult_max_left:
   861   fixes m n q :: nat
   862   shows "max m n * q = max (m * q) (n * q)"
   863   by (simp add: max_def not_le) (auto dest: mult_right_le_imp_le mult_right_less_imp_less le_less_trans)
   864 
   865 lemma nat_mult_max_right:
   866   fixes m n q :: nat
   867   shows "m * max n q = max (m * n) (m * q)"
   868   by (simp add: max_def not_le) (auto dest: mult_left_le_imp_le mult_left_less_imp_less le_less_trans)
   869 
   870 
   871 subsubsection {* Additional theorems about @{term "op \<le>"} *}
   872 
   873 text {* Complete induction, aka course-of-values induction *}
   874 
   875 instance nat :: wellorder proof
   876   fix P and n :: nat
   877   assume step: "\<And>n::nat. (\<And>m. m < n \<Longrightarrow> P m) \<Longrightarrow> P n"
   878   have "\<And>q. q \<le> n \<Longrightarrow> P q"
   879   proof (induct n)
   880     case (0 n)
   881     have "P 0" by (rule step) auto
   882     thus ?case using 0 by auto
   883   next
   884     case (Suc m n)
   885     then have "n \<le> m \<or> n = Suc m" by (simp add: le_Suc_eq)
   886     thus ?case
   887     proof
   888       assume "n \<le> m" thus "P n" by (rule Suc(1))
   889     next
   890       assume n: "n = Suc m"
   891       show "P n"
   892         by (rule step) (rule Suc(1), simp add: n le_simps)
   893     qed
   894   qed
   895   then show "P n" by auto
   896 qed
   897 
   898 
   899 lemma Least_eq_0[simp]: "P(0::nat) \<Longrightarrow> Least P = 0"
   900 by (rule Least_equality[OF _ le0])
   901 
   902 lemma Least_Suc:
   903      "[| P n; ~ P 0 |] ==> (LEAST n. P n) = Suc (LEAST m. P(Suc m))"
   904   apply (cases n, auto)
   905   apply (frule LeastI)
   906   apply (drule_tac P = "%x. P (Suc x) " in LeastI)
   907   apply (subgoal_tac " (LEAST x. P x) \<le> Suc (LEAST x. P (Suc x))")
   908   apply (erule_tac [2] Least_le)
   909   apply (cases "LEAST x. P x", auto)
   910   apply (drule_tac P = "%x. P (Suc x) " in Least_le)
   911   apply (blast intro: order_antisym)
   912   done
   913 
   914 lemma Least_Suc2:
   915    "[|P n; Q m; ~P 0; !k. P (Suc k) = Q k|] ==> Least P = Suc (Least Q)"
   916   apply (erule (1) Least_Suc [THEN ssubst])
   917   apply simp
   918   done
   919 
   920 lemma ex_least_nat_le: "\<not>P(0) \<Longrightarrow> P(n::nat) \<Longrightarrow> \<exists>k\<le>n. (\<forall>i<k. \<not>P i) & P(k)"
   921   apply (cases n)
   922    apply blast
   923   apply (rule_tac x="LEAST k. P(k)" in exI)
   924   apply (blast intro: Least_le dest: not_less_Least intro: LeastI_ex)
   925   done
   926 
   927 lemma ex_least_nat_less: "\<not>P(0) \<Longrightarrow> P(n::nat) \<Longrightarrow> \<exists>k<n. (\<forall>i\<le>k. \<not>P i) & P(k+1)"
   928   unfolding One_nat_def
   929   apply (cases n)
   930    apply blast
   931   apply (frule (1) ex_least_nat_le)
   932   apply (erule exE)
   933   apply (case_tac k)
   934    apply simp
   935   apply (rename_tac k1)
   936   apply (rule_tac x=k1 in exI)
   937   apply (auto simp add: less_eq_Suc_le)
   938   done
   939 
   940 lemma nat_less_induct:
   941   assumes "!!n. \<forall>m::nat. m < n --> P m ==> P n" shows "P n"
   942   using assms less_induct by blast
   943 
   944 lemma measure_induct_rule [case_names less]:
   945   fixes f :: "'a \<Rightarrow> nat"
   946   assumes step: "\<And>x. (\<And>y. f y < f x \<Longrightarrow> P y) \<Longrightarrow> P x"
   947   shows "P a"
   948 by (induct m\<equiv>"f a" arbitrary: a rule: less_induct) (auto intro: step)
   949 
   950 text {* old style induction rules: *}
   951 lemma measure_induct:
   952   fixes f :: "'a \<Rightarrow> nat"
   953   shows "(\<And>x. \<forall>y. f y < f x \<longrightarrow> P y \<Longrightarrow> P x) \<Longrightarrow> P a"
   954   by (rule measure_induct_rule [of f P a]) iprover
   955 
   956 lemma full_nat_induct:
   957   assumes step: "(!!n. (ALL m. Suc m <= n --> P m) ==> P n)"
   958   shows "P n"
   959   by (rule less_induct) (auto intro: step simp:le_simps)
   960 
   961 text{*An induction rule for estabilishing binary relations*}
   962 lemma less_Suc_induct:
   963   assumes less:  "i < j"
   964      and  step:  "!!i. P i (Suc i)"
   965      and  trans: "!!i j k. i < j ==> j < k ==>  P i j ==> P j k ==> P i k"
   966   shows "P i j"
   967 proof -
   968   from less obtain k where j: "j = Suc (i + k)" by (auto dest: less_imp_Suc_add)
   969   have "P i (Suc (i + k))"
   970   proof (induct k)
   971     case 0
   972     show ?case by (simp add: step)
   973   next
   974     case (Suc k)
   975     have "0 + i < Suc k + i" by (rule add_less_mono1) simp
   976     hence "i < Suc (i + k)" by (simp add: add.commute)
   977     from trans[OF this lessI Suc step]
   978     show ?case by simp
   979   qed
   980   thus "P i j" by (simp add: j)
   981 qed
   982 
   983 text {* The method of infinite descent, frequently used in number theory.
   984 Provided by Roelof Oosterhuis.
   985 $P(n)$ is true for all $n\in\mathbb{N}$ if
   986 \begin{itemize}
   987   \item case ``0'': given $n=0$ prove $P(n)$,
   988   \item case ``smaller'': given $n>0$ and $\neg P(n)$ prove there exists
   989         a smaller integer $m$ such that $\neg P(m)$.
   990 \end{itemize} *}
   991 
   992 text{* A compact version without explicit base case: *}
   993 lemma infinite_descent:
   994   "\<lbrakk> !!n::nat. \<not> P n \<Longrightarrow>  \<exists>m<n. \<not>  P m \<rbrakk> \<Longrightarrow>  P n"
   995 by (induct n rule: less_induct) auto
   996 
   997 lemma infinite_descent0[case_names 0 smaller]: 
   998   "\<lbrakk> P 0; !!n. n>0 \<Longrightarrow> \<not> P n \<Longrightarrow> (\<exists>m::nat. m < n \<and> \<not>P m) \<rbrakk> \<Longrightarrow> P n"
   999 by (rule infinite_descent) (case_tac "n>0", auto)
  1000 
  1001 text {*
  1002 Infinite descent using a mapping to $\mathbb{N}$:
  1003 $P(x)$ is true for all $x\in D$ if there exists a $V: D \to \mathbb{N}$ and
  1004 \begin{itemize}
  1005 \item case ``0'': given $V(x)=0$ prove $P(x)$,
  1006 \item case ``smaller'': given $V(x)>0$ and $\neg P(x)$ prove there exists a $y \in D$ such that $V(y)<V(x)$ and $~\neg P(y)$.
  1007 \end{itemize}
  1008 NB: the proof also shows how to use the previous lemma. *}
  1009 
  1010 corollary infinite_descent0_measure [case_names 0 smaller]:
  1011   assumes A0: "!!x. V x = (0::nat) \<Longrightarrow> P x"
  1012     and   A1: "!!x. V x > 0 \<Longrightarrow> \<not>P x \<Longrightarrow> (\<exists>y. V y < V x \<and> \<not>P y)"
  1013   shows "P x"
  1014 proof -
  1015   obtain n where "n = V x" by auto
  1016   moreover have "\<And>x. V x = n \<Longrightarrow> P x"
  1017   proof (induct n rule: infinite_descent0)
  1018     case 0 -- "i.e. $V(x) = 0$"
  1019     with A0 show "P x" by auto
  1020   next -- "now $n>0$ and $P(x)$ does not hold for some $x$ with $V(x)=n$"
  1021     case (smaller n)
  1022     then obtain x where vxn: "V x = n " and "V x > 0 \<and> \<not> P x" by auto
  1023     with A1 obtain y where "V y < V x \<and> \<not> P y" by auto
  1024     with vxn obtain m where "m = V y \<and> m<n \<and> \<not> P y" by auto
  1025     then show ?case by auto
  1026   qed
  1027   ultimately show "P x" by auto
  1028 qed
  1029 
  1030 text{* Again, without explicit base case: *}
  1031 lemma infinite_descent_measure:
  1032 assumes "!!x. \<not> P x \<Longrightarrow> \<exists>y. (V::'a\<Rightarrow>nat) y < V x \<and> \<not> P y" shows "P x"
  1033 proof -
  1034   from assms obtain n where "n = V x" by auto
  1035   moreover have "!!x. V x = n \<Longrightarrow> P x"
  1036   proof (induct n rule: infinite_descent, auto)
  1037     fix x assume "\<not> P x"
  1038     with assms show "\<exists>m < V x. \<exists>y. V y = m \<and> \<not> P y" by auto
  1039   qed
  1040   ultimately show "P x" by auto
  1041 qed
  1042 
  1043 text {* A [clumsy] way of lifting @{text "<"}
  1044   monotonicity to @{text "\<le>"} monotonicity *}
  1045 lemma less_mono_imp_le_mono:
  1046   "\<lbrakk> !!i j::nat. i < j \<Longrightarrow> f i < f j; i \<le> j \<rbrakk> \<Longrightarrow> f i \<le> ((f j)::nat)"
  1047 by (simp add: order_le_less) (blast)
  1048 
  1049 
  1050 text {* non-strict, in 1st argument *}
  1051 lemma add_le_mono1: "i \<le> j ==> i + k \<le> j + (k::nat)"
  1052 by (rule add_right_mono)
  1053 
  1054 text {* non-strict, in both arguments *}
  1055 lemma add_le_mono: "[| i \<le> j;  k \<le> l |] ==> i + k \<le> j + (l::nat)"
  1056 by (rule add_mono)
  1057 
  1058 lemma le_add2: "n \<le> ((m + n)::nat)"
  1059 by (insert add_right_mono [of 0 m n], simp)
  1060 
  1061 lemma le_add1: "n \<le> ((n + m)::nat)"
  1062 by (simp add: add.commute, rule le_add2)
  1063 
  1064 lemma less_add_Suc1: "i < Suc (i + m)"
  1065 by (rule le_less_trans, rule le_add1, rule lessI)
  1066 
  1067 lemma less_add_Suc2: "i < Suc (m + i)"
  1068 by (rule le_less_trans, rule le_add2, rule lessI)
  1069 
  1070 lemma less_iff_Suc_add: "(m < n) = (\<exists>k. n = Suc (m + k))"
  1071 by (iprover intro!: less_add_Suc1 less_imp_Suc_add)
  1072 
  1073 lemma trans_le_add1: "(i::nat) \<le> j ==> i \<le> j + m"
  1074 by (rule le_trans, assumption, rule le_add1)
  1075 
  1076 lemma trans_le_add2: "(i::nat) \<le> j ==> i \<le> m + j"
  1077 by (rule le_trans, assumption, rule le_add2)
  1078 
  1079 lemma trans_less_add1: "(i::nat) < j ==> i < j + m"
  1080 by (rule less_le_trans, assumption, rule le_add1)
  1081 
  1082 lemma trans_less_add2: "(i::nat) < j ==> i < m + j"
  1083 by (rule less_le_trans, assumption, rule le_add2)
  1084 
  1085 lemma add_lessD1: "i + j < (k::nat) ==> i < k"
  1086 apply (rule le_less_trans [of _ "i+j"])
  1087 apply (simp_all add: le_add1)
  1088 done
  1089 
  1090 lemma not_add_less1 [iff]: "~ (i + j < (i::nat))"
  1091 apply (rule notI)
  1092 apply (drule add_lessD1)
  1093 apply (erule less_irrefl [THEN notE])
  1094 done
  1095 
  1096 lemma not_add_less2 [iff]: "~ (j + i < (i::nat))"
  1097 by (simp add: add.commute)
  1098 
  1099 lemma add_leD1: "m + k \<le> n ==> m \<le> (n::nat)"
  1100 apply (rule order_trans [of _ "m+k"])
  1101 apply (simp_all add: le_add1)
  1102 done
  1103 
  1104 lemma add_leD2: "m + k \<le> n ==> k \<le> (n::nat)"
  1105 apply (simp add: add.commute)
  1106 apply (erule add_leD1)
  1107 done
  1108 
  1109 lemma add_leE: "(m::nat) + k \<le> n ==> (m \<le> n ==> k \<le> n ==> R) ==> R"
  1110 by (blast dest: add_leD1 add_leD2)
  1111 
  1112 text {* needs @{text "!!k"} for @{text ac_simps} to work *}
  1113 lemma less_add_eq_less: "!!k::nat. k < l ==> m + l = k + n ==> m < n"
  1114 by (force simp del: add_Suc_right
  1115     simp add: less_iff_Suc_add add_Suc_right [symmetric] ac_simps)
  1116 
  1117 
  1118 subsubsection {* More results about difference *}
  1119 
  1120 text {* Addition is the inverse of subtraction:
  1121   if @{term "n \<le> m"} then @{term "n + (m - n) = m"}. *}
  1122 lemma add_diff_inverse: "~  m < n ==> n + (m - n) = (m::nat)"
  1123 by (induct m n rule: diff_induct) simp_all
  1124 
  1125 lemma le_add_diff_inverse [simp]: "n \<le> m ==> n + (m - n) = (m::nat)"
  1126 by (simp add: add_diff_inverse linorder_not_less)
  1127 
  1128 lemma le_add_diff_inverse2 [simp]: "n \<le> m ==> (m - n) + n = (m::nat)"
  1129 by (simp add: add.commute)
  1130 
  1131 lemma Suc_diff_le: "n \<le> m ==> Suc m - n = Suc (m - n)"
  1132 by (induct m n rule: diff_induct) simp_all
  1133 
  1134 lemma diff_less_Suc: "m - n < Suc m"
  1135 apply (induct m n rule: diff_induct)
  1136 apply (erule_tac [3] less_SucE)
  1137 apply (simp_all add: less_Suc_eq)
  1138 done
  1139 
  1140 lemma diff_le_self [simp]: "m - n \<le> (m::nat)"
  1141 by (induct m n rule: diff_induct) (simp_all add: le_SucI)
  1142 
  1143 lemma le_iff_add: "(m::nat) \<le> n = (\<exists>k. n = m + k)"
  1144   by (auto simp: le_add1 dest!: le_add_diff_inverse sym [of _ n])
  1145 
  1146 instance nat :: ordered_cancel_comm_monoid_diff
  1147 proof
  1148   show "\<And>m n :: nat. m \<le> n \<longleftrightarrow> (\<exists>q. n = m + q)" by (fact le_iff_add)
  1149 qed
  1150 
  1151 lemma less_imp_diff_less: "(j::nat) < k ==> j - n < k"
  1152 by (rule le_less_trans, rule diff_le_self)
  1153 
  1154 lemma diff_Suc_less [simp]: "0<n ==> n - Suc i < n"
  1155 by (cases n) (auto simp add: le_simps)
  1156 
  1157 lemma diff_add_assoc: "k \<le> (j::nat) ==> (i + j) - k = i + (j - k)"
  1158 by (induct j k rule: diff_induct) simp_all
  1159 
  1160 lemma diff_add_assoc2: "k \<le> (j::nat) ==> (j + i) - k = (j - k) + i"
  1161 by (simp add: add.commute diff_add_assoc)
  1162 
  1163 lemma le_imp_diff_is_add: "i \<le> (j::nat) ==> (j - i = k) = (j = k + i)"
  1164 by (auto simp add: diff_add_inverse2)
  1165 
  1166 lemma diff_is_0_eq [simp]: "((m::nat) - n = 0) = (m \<le> n)"
  1167 by (induct m n rule: diff_induct) simp_all
  1168 
  1169 lemma diff_is_0_eq' [simp]: "m \<le> n ==> (m::nat) - n = 0"
  1170 by (rule iffD2, rule diff_is_0_eq)
  1171 
  1172 lemma zero_less_diff [simp]: "(0 < n - (m::nat)) = (m < n)"
  1173 by (induct m n rule: diff_induct) simp_all
  1174 
  1175 lemma less_imp_add_positive:
  1176   assumes "i < j"
  1177   shows "\<exists>k::nat. 0 < k & i + k = j"
  1178 proof
  1179   from assms show "0 < j - i & i + (j - i) = j"
  1180     by (simp add: order_less_imp_le)
  1181 qed
  1182 
  1183 text {* a nice rewrite for bounded subtraction *}
  1184 lemma nat_minus_add_max:
  1185   fixes n m :: nat
  1186   shows "n - m + m = max n m"
  1187     by (simp add: max_def not_le order_less_imp_le)
  1188 
  1189 lemma nat_diff_split:
  1190   "P(a - b::nat) = ((a<b --> P 0) & (ALL d. a = b + d --> P d))"
  1191     -- {* elimination of @{text -} on @{text nat} *}
  1192 by (cases "a < b")
  1193   (auto simp add: diff_is_0_eq [THEN iffD2] diff_add_inverse
  1194     not_less le_less dest!: add_eq_self_zero add_eq_self_zero[OF sym])
  1195 
  1196 lemma nat_diff_split_asm:
  1197   "P(a - b::nat) = (~ (a < b & ~ P 0 | (EX d. a = b + d & ~ P d)))"
  1198     -- {* elimination of @{text -} on @{text nat} in assumptions *}
  1199 by (auto split: nat_diff_split)
  1200 
  1201 lemma Suc_pred': "0 < n ==> n = Suc(n - 1)"
  1202   by simp
  1203 
  1204 lemma add_eq_if: "(m::nat) + n = (if m=0 then n else Suc ((m - 1) + n))"
  1205   unfolding One_nat_def by (cases m) simp_all
  1206 
  1207 lemma mult_eq_if: "(m::nat) * n = (if m=0 then 0 else n + ((m - 1) * n))"
  1208   unfolding One_nat_def by (cases m) simp_all
  1209 
  1210 lemma Suc_diff_eq_diff_pred: "0 < n ==> Suc m - n = m - (n - 1)"
  1211   unfolding One_nat_def by (cases n) simp_all
  1212 
  1213 lemma diff_Suc_eq_diff_pred: "m - Suc n = (m - 1) - n"
  1214   unfolding One_nat_def by (cases m) simp_all
  1215 
  1216 lemma Let_Suc [simp]: "Let (Suc n) f == f (Suc n)"
  1217   by (fact Let_def)
  1218 
  1219 
  1220 subsubsection {* Monotonicity of multiplication *}
  1221 
  1222 lemma mult_le_mono1: "i \<le> (j::nat) ==> i * k \<le> j * k"
  1223 by (simp add: mult_right_mono)
  1224 
  1225 lemma mult_le_mono2: "i \<le> (j::nat) ==> k * i \<le> k * j"
  1226 by (simp add: mult_left_mono)
  1227 
  1228 text {* @{text "\<le>"} monotonicity, BOTH arguments *}
  1229 lemma mult_le_mono: "i \<le> (j::nat) ==> k \<le> l ==> i * k \<le> j * l"
  1230 by (simp add: mult_mono)
  1231 
  1232 lemma mult_less_mono1: "(i::nat) < j ==> 0 < k ==> i * k < j * k"
  1233 by (simp add: mult_strict_right_mono)
  1234 
  1235 text{*Differs from the standard @{text zero_less_mult_iff} in that
  1236       there are no negative numbers.*}
  1237 lemma nat_0_less_mult_iff [simp]: "(0 < (m::nat) * n) = (0 < m & 0 < n)"
  1238   apply (induct m)
  1239    apply simp
  1240   apply (case_tac n)
  1241    apply simp_all
  1242   done
  1243 
  1244 lemma one_le_mult_iff [simp]: "(Suc 0 \<le> m * n) = (Suc 0 \<le> m & Suc 0 \<le> n)"
  1245   apply (induct m)
  1246    apply simp
  1247   apply (case_tac n)
  1248    apply simp_all
  1249   done
  1250 
  1251 lemma mult_less_cancel2 [simp]: "((m::nat) * k < n * k) = (0 < k & m < n)"
  1252   apply (safe intro!: mult_less_mono1)
  1253   apply (cases k, auto)
  1254   apply (simp del: le_0_eq add: linorder_not_le [symmetric])
  1255   apply (blast intro: mult_le_mono1)
  1256   done
  1257 
  1258 lemma mult_less_cancel1 [simp]: "(k * (m::nat) < k * n) = (0 < k & m < n)"
  1259 by (simp add: mult.commute [of k])
  1260 
  1261 lemma mult_le_cancel1 [simp]: "(k * (m::nat) \<le> k * n) = (0 < k --> m \<le> n)"
  1262 by (simp add: linorder_not_less [symmetric], auto)
  1263 
  1264 lemma mult_le_cancel2 [simp]: "((m::nat) * k \<le> n * k) = (0 < k --> m \<le> n)"
  1265 by (simp add: linorder_not_less [symmetric], auto)
  1266 
  1267 lemma Suc_mult_less_cancel1: "(Suc k * m < Suc k * n) = (m < n)"
  1268 by (subst mult_less_cancel1) simp
  1269 
  1270 lemma Suc_mult_le_cancel1: "(Suc k * m \<le> Suc k * n) = (m \<le> n)"
  1271 by (subst mult_le_cancel1) simp
  1272 
  1273 lemma le_square: "m \<le> m * (m::nat)"
  1274   by (cases m) (auto intro: le_add1)
  1275 
  1276 lemma le_cube: "(m::nat) \<le> m * (m * m)"
  1277   by (cases m) (auto intro: le_add1)
  1278 
  1279 text {* Lemma for @{text gcd} *}
  1280 lemma mult_eq_self_implies_10: "(m::nat) = m * n ==> n = 1 | m = 0"
  1281   apply (drule sym)
  1282   apply (rule disjCI)
  1283   apply (rule nat_less_cases, erule_tac [2] _)
  1284    apply (drule_tac [2] mult_less_mono2)
  1285     apply (auto)
  1286   done
  1287 
  1288 lemma mono_times_nat:
  1289   fixes n :: nat
  1290   assumes "n > 0"
  1291   shows "mono (times n)"
  1292 proof
  1293   fix m q :: nat
  1294   assume "m \<le> q"
  1295   with assms show "n * m \<le> n * q" by simp
  1296 qed
  1297 
  1298 text {* the lattice order on @{typ nat} *}
  1299 
  1300 instantiation nat :: distrib_lattice
  1301 begin
  1302 
  1303 definition
  1304   "(inf \<Colon> nat \<Rightarrow> nat \<Rightarrow> nat) = min"
  1305 
  1306 definition
  1307   "(sup \<Colon> nat \<Rightarrow> nat \<Rightarrow> nat) = max"
  1308 
  1309 instance by intro_classes
  1310   (auto simp add: inf_nat_def sup_nat_def max_def not_le min_def
  1311     intro: order_less_imp_le antisym elim!: order_trans order_less_trans)
  1312 
  1313 end
  1314 
  1315 
  1316 subsection {* Natural operation of natural numbers on functions *}
  1317 
  1318 text {*
  1319   We use the same logical constant for the power operations on
  1320   functions and relations, in order to share the same syntax.
  1321 *}
  1322 
  1323 consts compow :: "nat \<Rightarrow> 'a \<Rightarrow> 'a"
  1324 
  1325 abbreviation compower :: "'a \<Rightarrow> nat \<Rightarrow> 'a" (infixr "^^" 80) where
  1326   "f ^^ n \<equiv> compow n f"
  1327 
  1328 notation (latex output)
  1329   compower ("(_\<^bsup>_\<^esup>)" [1000] 1000)
  1330 
  1331 notation (HTML output)
  1332   compower ("(_\<^bsup>_\<^esup>)" [1000] 1000)
  1333 
  1334 text {* @{text "f ^^ n = f o ... o f"}, the n-fold composition of @{text f} *}
  1335 
  1336 overloading
  1337   funpow == "compow :: nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> ('a \<Rightarrow> 'a)"
  1338 begin
  1339 
  1340 primrec funpow :: "nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'a" where
  1341   "funpow 0 f = id"
  1342 | "funpow (Suc n) f = f o funpow n f"
  1343 
  1344 end
  1345 
  1346 lemma funpow_Suc_right:
  1347   "f ^^ Suc n = f ^^ n \<circ> f"
  1348 proof (induct n)
  1349   case 0 then show ?case by simp
  1350 next
  1351   fix n
  1352   assume "f ^^ Suc n = f ^^ n \<circ> f"
  1353   then show "f ^^ Suc (Suc n) = f ^^ Suc n \<circ> f"
  1354     by (simp add: o_assoc)
  1355 qed
  1356 
  1357 lemmas funpow_simps_right = funpow.simps(1) funpow_Suc_right
  1358 
  1359 text {* for code generation *}
  1360 
  1361 definition funpow :: "nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'a" where
  1362   funpow_code_def [code_abbrev]: "funpow = compow"
  1363 
  1364 lemma [code]:
  1365   "funpow (Suc n) f = f o funpow n f"
  1366   "funpow 0 f = id"
  1367   by (simp_all add: funpow_code_def)
  1368 
  1369 hide_const (open) funpow
  1370 
  1371 lemma funpow_add:
  1372   "f ^^ (m + n) = f ^^ m \<circ> f ^^ n"
  1373   by (induct m) simp_all
  1374 
  1375 lemma funpow_mult:
  1376   fixes f :: "'a \<Rightarrow> 'a"
  1377   shows "(f ^^ m) ^^ n = f ^^ (m * n)"
  1378   by (induct n) (simp_all add: funpow_add)
  1379 
  1380 lemma funpow_swap1:
  1381   "f ((f ^^ n) x) = (f ^^ n) (f x)"
  1382 proof -
  1383   have "f ((f ^^ n) x) = (f ^^ (n + 1)) x" by simp
  1384   also have "\<dots>  = (f ^^ n o f ^^ 1) x" by (simp only: funpow_add)
  1385   also have "\<dots> = (f ^^ n) (f x)" by simp
  1386   finally show ?thesis .
  1387 qed
  1388 
  1389 lemma comp_funpow:
  1390   fixes f :: "'a \<Rightarrow> 'a"
  1391   shows "comp f ^^ n = comp (f ^^ n)"
  1392   by (induct n) simp_all
  1393 
  1394 lemma Suc_funpow[simp]: "Suc ^^ n = (op + n)"
  1395   by (induct n) simp_all
  1396 
  1397 lemma id_funpow[simp]: "id ^^ n = id"
  1398   by (induct n) simp_all
  1399 
  1400 lemma funpow_mono:
  1401   fixes f :: "'a \<Rightarrow> ('a::lattice)"
  1402   shows "mono f \<Longrightarrow> A \<le> B \<Longrightarrow> (f ^^ n) A \<le> (f ^^ n) B"
  1403   by (induct n arbitrary: A B)
  1404      (auto simp del: funpow.simps(2) simp add: funpow_Suc_right mono_def)
  1405 
  1406 subsection {* Kleene iteration *}
  1407 
  1408 lemma Kleene_iter_lpfp:
  1409 assumes "mono f" and "f p \<le> p" shows "(f^^k) (bot::'a::order_bot) \<le> p"
  1410 proof(induction k)
  1411   case 0 show ?case by simp
  1412 next
  1413   case Suc
  1414   from monoD[OF assms(1) Suc] assms(2)
  1415   show ?case by simp
  1416 qed
  1417 
  1418 lemma lfp_Kleene_iter: assumes "mono f" and "(f^^Suc k) bot = (f^^k) bot"
  1419 shows "lfp f = (f^^k) bot"
  1420 proof(rule antisym)
  1421   show "lfp f \<le> (f^^k) bot"
  1422   proof(rule lfp_lowerbound)
  1423     show "f ((f^^k) bot) \<le> (f^^k) bot" using assms(2) by simp
  1424   qed
  1425 next
  1426   show "(f^^k) bot \<le> lfp f"
  1427     using Kleene_iter_lpfp[OF assms(1)] lfp_unfold[OF assms(1)] by simp
  1428 qed
  1429 
  1430 
  1431 subsection {* Embedding of the naturals into any @{text semiring_1}: @{term of_nat} *}
  1432 
  1433 context semiring_1
  1434 begin
  1435 
  1436 definition of_nat :: "nat \<Rightarrow> 'a" where
  1437   "of_nat n = (plus 1 ^^ n) 0"
  1438 
  1439 lemma of_nat_simps [simp]:
  1440   shows of_nat_0: "of_nat 0 = 0"
  1441     and of_nat_Suc: "of_nat (Suc m) = 1 + of_nat m"
  1442   by (simp_all add: of_nat_def)
  1443 
  1444 lemma of_nat_1 [simp]: "of_nat 1 = 1"
  1445   by (simp add: of_nat_def)
  1446 
  1447 lemma of_nat_add [simp]: "of_nat (m + n) = of_nat m + of_nat n"
  1448   by (induct m) (simp_all add: ac_simps)
  1449 
  1450 lemma of_nat_mult: "of_nat (m * n) = of_nat m * of_nat n"
  1451   by (induct m) (simp_all add: ac_simps distrib_right)
  1452 
  1453 primrec of_nat_aux :: "('a \<Rightarrow> 'a) \<Rightarrow> nat \<Rightarrow> 'a \<Rightarrow> 'a" where
  1454   "of_nat_aux inc 0 i = i"
  1455 | "of_nat_aux inc (Suc n) i = of_nat_aux inc n (inc i)" -- {* tail recursive *}
  1456 
  1457 lemma of_nat_code:
  1458   "of_nat n = of_nat_aux (\<lambda>i. i + 1) n 0"
  1459 proof (induct n)
  1460   case 0 then show ?case by simp
  1461 next
  1462   case (Suc n)
  1463   have "\<And>i. of_nat_aux (\<lambda>i. i + 1) n (i + 1) = of_nat_aux (\<lambda>i. i + 1) n i + 1"
  1464     by (induct n) simp_all
  1465   from this [of 0] have "of_nat_aux (\<lambda>i. i + 1) n 1 = of_nat_aux (\<lambda>i. i + 1) n 0 + 1"
  1466     by simp
  1467   with Suc show ?case by (simp add: add.commute)
  1468 qed
  1469 
  1470 end
  1471 
  1472 declare of_nat_code [code]
  1473 
  1474 text{*Class for unital semirings with characteristic zero.
  1475  Includes non-ordered rings like the complex numbers.*}
  1476 
  1477 class semiring_char_0 = semiring_1 +
  1478   assumes inj_of_nat: "inj of_nat"
  1479 begin
  1480 
  1481 lemma of_nat_eq_iff [simp]: "of_nat m = of_nat n \<longleftrightarrow> m = n"
  1482   by (auto intro: inj_of_nat injD)
  1483 
  1484 text{*Special cases where either operand is zero*}
  1485 
  1486 lemma of_nat_0_eq_iff [simp]: "0 = of_nat n \<longleftrightarrow> 0 = n"
  1487   by (fact of_nat_eq_iff [of 0 n, unfolded of_nat_0])
  1488 
  1489 lemma of_nat_eq_0_iff [simp]: "of_nat m = 0 \<longleftrightarrow> m = 0"
  1490   by (fact of_nat_eq_iff [of m 0, unfolded of_nat_0])
  1491 
  1492 end
  1493 
  1494 context linordered_semidom
  1495 begin
  1496 
  1497 lemma of_nat_0_le_iff [simp]: "0 \<le> of_nat n"
  1498   by (induct n) simp_all
  1499 
  1500 lemma of_nat_less_0_iff [simp]: "\<not> of_nat m < 0"
  1501   by (simp add: not_less)
  1502 
  1503 lemma of_nat_less_iff [simp]: "of_nat m < of_nat n \<longleftrightarrow> m < n"
  1504   by (induct m n rule: diff_induct, simp_all add: add_pos_nonneg)
  1505 
  1506 lemma of_nat_le_iff [simp]: "of_nat m \<le> of_nat n \<longleftrightarrow> m \<le> n"
  1507   by (simp add: not_less [symmetric] linorder_not_less [symmetric])
  1508 
  1509 lemma less_imp_of_nat_less: "m < n \<Longrightarrow> of_nat m < of_nat n"
  1510   by simp
  1511 
  1512 lemma of_nat_less_imp_less: "of_nat m < of_nat n \<Longrightarrow> m < n"
  1513   by simp
  1514 
  1515 text{*Every @{text linordered_semidom} has characteristic zero.*}
  1516 
  1517 subclass semiring_char_0 proof
  1518 qed (auto intro!: injI simp add: eq_iff)
  1519 
  1520 text{*Special cases where either operand is zero*}
  1521 
  1522 lemma of_nat_le_0_iff [simp]: "of_nat m \<le> 0 \<longleftrightarrow> m = 0"
  1523   by (rule of_nat_le_iff [of _ 0, simplified])
  1524 
  1525 lemma of_nat_0_less_iff [simp]: "0 < of_nat n \<longleftrightarrow> 0 < n"
  1526   by (rule of_nat_less_iff [of 0, simplified])
  1527 
  1528 end
  1529 
  1530 context ring_1
  1531 begin
  1532 
  1533 lemma of_nat_diff: "n \<le> m \<Longrightarrow> of_nat (m - n) = of_nat m - of_nat n"
  1534 by (simp add: algebra_simps of_nat_add [symmetric])
  1535 
  1536 end
  1537 
  1538 context linordered_idom
  1539 begin
  1540 
  1541 lemma abs_of_nat [simp]: "\<bar>of_nat n\<bar> = of_nat n"
  1542   unfolding abs_if by auto
  1543 
  1544 end
  1545 
  1546 lemma of_nat_id [simp]: "of_nat n = n"
  1547   by (induct n) simp_all
  1548 
  1549 lemma of_nat_eq_id [simp]: "of_nat = id"
  1550   by (auto simp add: fun_eq_iff)
  1551 
  1552 
  1553 subsection {* The set of natural numbers *}
  1554 
  1555 context semiring_1
  1556 begin
  1557 
  1558 definition Nats  :: "'a set" where
  1559   "Nats = range of_nat"
  1560 
  1561 notation (xsymbols)
  1562   Nats  ("\<nat>")
  1563 
  1564 lemma of_nat_in_Nats [simp]: "of_nat n \<in> \<nat>"
  1565   by (simp add: Nats_def)
  1566 
  1567 lemma Nats_0 [simp]: "0 \<in> \<nat>"
  1568 apply (simp add: Nats_def)
  1569 apply (rule range_eqI)
  1570 apply (rule of_nat_0 [symmetric])
  1571 done
  1572 
  1573 lemma Nats_1 [simp]: "1 \<in> \<nat>"
  1574 apply (simp add: Nats_def)
  1575 apply (rule range_eqI)
  1576 apply (rule of_nat_1 [symmetric])
  1577 done
  1578 
  1579 lemma Nats_add [simp]: "a \<in> \<nat> \<Longrightarrow> b \<in> \<nat> \<Longrightarrow> a + b \<in> \<nat>"
  1580 apply (auto simp add: Nats_def)
  1581 apply (rule range_eqI)
  1582 apply (rule of_nat_add [symmetric])
  1583 done
  1584 
  1585 lemma Nats_mult [simp]: "a \<in> \<nat> \<Longrightarrow> b \<in> \<nat> \<Longrightarrow> a * b \<in> \<nat>"
  1586 apply (auto simp add: Nats_def)
  1587 apply (rule range_eqI)
  1588 apply (rule of_nat_mult [symmetric])
  1589 done
  1590 
  1591 lemma Nats_cases [cases set: Nats]:
  1592   assumes "x \<in> \<nat>"
  1593   obtains (of_nat) n where "x = of_nat n"
  1594   unfolding Nats_def
  1595 proof -
  1596   from `x \<in> \<nat>` have "x \<in> range of_nat" unfolding Nats_def .
  1597   then obtain n where "x = of_nat n" ..
  1598   then show thesis ..
  1599 qed
  1600 
  1601 lemma Nats_induct [case_names of_nat, induct set: Nats]:
  1602   "x \<in> \<nat> \<Longrightarrow> (\<And>n. P (of_nat n)) \<Longrightarrow> P x"
  1603   by (rule Nats_cases) auto
  1604 
  1605 end
  1606 
  1607 
  1608 subsection {* Further arithmetic facts concerning the natural numbers *}
  1609 
  1610 lemma subst_equals:
  1611   assumes 1: "t = s" and 2: "u = t"
  1612   shows "u = s"
  1613   using 2 1 by (rule trans)
  1614 
  1615 ML_file "Tools/nat_arith.ML"
  1616 
  1617 simproc_setup nateq_cancel_sums
  1618   ("(l::nat) + m = n" | "(l::nat) = m + n" | "Suc m = n" | "m = Suc n") =
  1619   {* fn phi => try o Nat_Arith.cancel_eq_conv *}
  1620 
  1621 simproc_setup natless_cancel_sums
  1622   ("(l::nat) + m < n" | "(l::nat) < m + n" | "Suc m < n" | "m < Suc n") =
  1623   {* fn phi => try o Nat_Arith.cancel_less_conv *}
  1624 
  1625 simproc_setup natle_cancel_sums
  1626   ("(l::nat) + m \<le> n" | "(l::nat) \<le> m + n" | "Suc m \<le> n" | "m \<le> Suc n") =
  1627   {* fn phi => try o Nat_Arith.cancel_le_conv *}
  1628 
  1629 simproc_setup natdiff_cancel_sums
  1630   ("(l::nat) + m - n" | "(l::nat) - (m + n)" | "Suc m - n" | "m - Suc n") =
  1631   {* fn phi => try o Nat_Arith.cancel_diff_conv *}
  1632 
  1633 ML_file "Tools/lin_arith.ML"
  1634 setup {* Lin_Arith.global_setup *}
  1635 declaration {* K Lin_Arith.setup *}
  1636 
  1637 simproc_setup fast_arith_nat ("(m::nat) < n" | "(m::nat) <= n" | "(m::nat) = n") =
  1638   {* fn _ => fn ss => fn ct => Lin_Arith.simproc ss (Thm.term_of ct) *}
  1639 (* Because of this simproc, the arithmetic solver is really only
  1640 useful to detect inconsistencies among the premises for subgoals which are
  1641 *not* themselves (in)equalities, because the latter activate
  1642 fast_nat_arith_simproc anyway. However, it seems cheaper to activate the
  1643 solver all the time rather than add the additional check. *)
  1644 
  1645 
  1646 lemmas [arith_split] = nat_diff_split split_min split_max
  1647 
  1648 context order
  1649 begin
  1650 
  1651 lemma lift_Suc_mono_le:
  1652   assumes mono: "\<And>n. f n \<le> f (Suc n)" and "n \<le> n'"
  1653   shows "f n \<le> f n'"
  1654 proof (cases "n < n'")
  1655   case True
  1656   then show ?thesis
  1657     by (induct n n' rule: less_Suc_induct [consumes 1]) (auto intro: mono)
  1658 qed (insert `n \<le> n'`, auto) -- {* trivial for @{prop "n = n'"} *}
  1659 
  1660 lemma lift_Suc_antimono_le:
  1661   assumes mono: "\<And>n. f n \<ge> f (Suc n)" and "n \<le> n'"
  1662   shows "f n \<ge> f n'"
  1663 proof (cases "n < n'")
  1664   case True
  1665   then show ?thesis
  1666     by (induct n n' rule: less_Suc_induct [consumes 1]) (auto intro: mono)
  1667 qed (insert `n \<le> n'`, auto) -- {* trivial for @{prop "n = n'"} *}
  1668 
  1669 lemma lift_Suc_mono_less:
  1670   assumes mono: "\<And>n. f n < f (Suc n)" and "n < n'"
  1671   shows "f n < f n'"
  1672 using `n < n'`
  1673 by (induct n n' rule: less_Suc_induct [consumes 1]) (auto intro: mono)
  1674 
  1675 lemma lift_Suc_mono_less_iff:
  1676   "(\<And>n. f n < f (Suc n)) \<Longrightarrow> f n < f m \<longleftrightarrow> n < m"
  1677   by (blast intro: less_asym' lift_Suc_mono_less [of f]
  1678     dest: linorder_not_less[THEN iffD1] le_eq_less_or_eq [THEN iffD1])
  1679 
  1680 end
  1681 
  1682 lemma mono_iff_le_Suc:
  1683   "mono f \<longleftrightarrow> (\<forall>n. f n \<le> f (Suc n))"
  1684   unfolding mono_def by (auto intro: lift_Suc_mono_le [of f])
  1685 
  1686 lemma antimono_iff_le_Suc:
  1687   "antimono f \<longleftrightarrow> (\<forall>n. f (Suc n) \<le> f n)"
  1688   unfolding antimono_def by (auto intro: lift_Suc_antimono_le [of f])
  1689 
  1690 lemma mono_nat_linear_lb:
  1691   fixes f :: "nat \<Rightarrow> nat"
  1692   assumes "\<And>m n. m < n \<Longrightarrow> f m < f n"
  1693   shows "f m + k \<le> f (m + k)"
  1694 proof (induct k)
  1695   case 0 then show ?case by simp
  1696 next
  1697   case (Suc k)
  1698   then have "Suc (f m + k) \<le> Suc (f (m + k))" by simp
  1699   also from assms [of "m + k" "Suc (m + k)"] have "Suc (f (m + k)) \<le> f (Suc (m + k))"
  1700     by (simp add: Suc_le_eq)
  1701   finally show ?case by simp
  1702 qed
  1703 
  1704 
  1705 text{*Subtraction laws, mostly by Clemens Ballarin*}
  1706 
  1707 lemma diff_less_mono: "[| a < (b::nat); c \<le> a |] ==> a-c < b-c"
  1708 by arith
  1709 
  1710 lemma less_diff_conv: "(i < j-k) = (i+k < (j::nat))"
  1711 by arith
  1712 
  1713 lemma less_diff_conv2:
  1714   fixes j k i :: nat
  1715   assumes "k \<le> j"
  1716   shows "j - k < i \<longleftrightarrow> j < i + k"
  1717   using assms by arith
  1718 
  1719 lemma le_diff_conv: "(j-k \<le> (i::nat)) = (j \<le> i+k)"
  1720 by arith
  1721 
  1722 lemma le_diff_conv2: "k \<le> j ==> (i \<le> j-k) = (i+k \<le> (j::nat))"
  1723   by (fact le_diff_conv2) -- {* FIXME delete *}
  1724 
  1725 lemma diff_diff_cancel [simp]: "i \<le> (n::nat) ==> n - (n - i) = i"
  1726 by arith
  1727 
  1728 lemma le_add_diff: "k \<le> (n::nat) ==> m \<le> n + m - k"
  1729   by (fact le_add_diff) -- {* FIXME delete *}
  1730 
  1731 (*Replaces the previous diff_less and le_diff_less, which had the stronger
  1732   second premise n\<le>m*)
  1733 lemma diff_less[simp]: "!!m::nat. [| 0<n; 0<m |] ==> m - n < m"
  1734 by arith
  1735 
  1736 text {* Simplification of relational expressions involving subtraction *}
  1737 
  1738 lemma diff_diff_eq: "[| k \<le> m;  k \<le> (n::nat) |] ==> ((m-k) - (n-k)) = (m-n)"
  1739 by (simp split add: nat_diff_split)
  1740 
  1741 hide_fact (open) diff_diff_eq
  1742 
  1743 lemma eq_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k = n-k) = (m=n)"
  1744 by (auto split add: nat_diff_split)
  1745 
  1746 lemma less_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k < n-k) = (m<n)"
  1747 by (auto split add: nat_diff_split)
  1748 
  1749 lemma le_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k \<le> n-k) = (m\<le>n)"
  1750 by (auto split add: nat_diff_split)
  1751 
  1752 text{*(Anti)Monotonicity of subtraction -- by Stephan Merz*}
  1753 
  1754 (* Monotonicity of subtraction in first argument *)
  1755 lemma diff_le_mono: "m \<le> (n::nat) ==> (m-l) \<le> (n-l)"
  1756 by (simp split add: nat_diff_split)
  1757 
  1758 lemma diff_le_mono2: "m \<le> (n::nat) ==> (l-n) \<le> (l-m)"
  1759 by (simp split add: nat_diff_split)
  1760 
  1761 lemma diff_less_mono2: "[| m < (n::nat); m<l |] ==> (l-n) < (l-m)"
  1762 by (simp split add: nat_diff_split)
  1763 
  1764 lemma diffs0_imp_equal: "!!m::nat. [| m-n = 0; n-m = 0 |] ==>  m=n"
  1765 by (simp split add: nat_diff_split)
  1766 
  1767 lemma min_diff: "min (m - (i::nat)) (n - i) = min m n - i"
  1768 by auto
  1769 
  1770 lemma inj_on_diff_nat: 
  1771   assumes k_le_n: "\<forall>n \<in> N. k \<le> (n::nat)"
  1772   shows "inj_on (\<lambda>n. n - k) N"
  1773 proof (rule inj_onI)
  1774   fix x y
  1775   assume a: "x \<in> N" "y \<in> N" "x - k = y - k"
  1776   with k_le_n have "x - k + k = y - k + k" by auto
  1777   with a k_le_n show "x = y" by auto
  1778 qed
  1779 
  1780 text{*Rewriting to pull differences out*}
  1781 
  1782 lemma diff_diff_right [simp]: "k\<le>j --> i - (j - k) = i + (k::nat) - j"
  1783 by arith
  1784 
  1785 lemma diff_Suc_diff_eq1 [simp]: "k \<le> j ==> m - Suc (j - k) = m + k - Suc j"
  1786 by arith
  1787 
  1788 lemma diff_Suc_diff_eq2 [simp]: "k \<le> j ==> Suc (j - k) - m = Suc j - (k + m)"
  1789 by arith
  1790 
  1791 lemma Suc_diff_Suc: "n < m \<Longrightarrow> Suc (m - Suc n) = m - n"
  1792 by simp
  1793 
  1794 (*The others are
  1795       i - j - k = i - (j + k),
  1796       k \<le> j ==> j - k + i = j + i - k,
  1797       k \<le> j ==> i + (j - k) = i + j - k *)
  1798 lemmas add_diff_assoc = diff_add_assoc [symmetric]
  1799 lemmas add_diff_assoc2 = diff_add_assoc2[symmetric]
  1800 declare diff_diff_left [simp]  add_diff_assoc [simp] add_diff_assoc2[simp]
  1801 
  1802 text{*At present we prove no analogue of @{text not_less_Least} or @{text
  1803 Least_Suc}, since there appears to be no need.*}
  1804 
  1805 text{*Lemmas for ex/Factorization*}
  1806 
  1807 lemma one_less_mult: "[| Suc 0 < n; Suc 0 < m |] ==> Suc 0 < m*n"
  1808 by (cases m) auto
  1809 
  1810 lemma n_less_m_mult_n: "[| Suc 0 < n; Suc 0 < m |] ==> n<m*n"
  1811 by (cases m) auto
  1812 
  1813 lemma n_less_n_mult_m: "[| Suc 0 < n; Suc 0 < m |] ==> n<n*m"
  1814 by (cases m) auto
  1815 
  1816 text {* Specialized induction principles that work "backwards": *}
  1817 
  1818 lemma inc_induct[consumes 1, case_names base step]:
  1819   assumes less: "i \<le> j"
  1820   assumes base: "P j"
  1821   assumes step: "\<And>n. i \<le> n \<Longrightarrow> n < j \<Longrightarrow> P (Suc n) \<Longrightarrow> P n"
  1822   shows "P i"
  1823   using less step
  1824 proof (induct d\<equiv>"j - i" arbitrary: i)
  1825   case (0 i)
  1826   hence "i = j" by simp
  1827   with base show ?case by simp
  1828 next
  1829   case (Suc d n)
  1830   hence "n \<le> n" "n < j" "P (Suc n)"
  1831     by simp_all
  1832   then show "P n" by fact
  1833 qed
  1834 
  1835 lemma strict_inc_induct[consumes 1, case_names base step]:
  1836   assumes less: "i < j"
  1837   assumes base: "!!i. j = Suc i ==> P i"
  1838   assumes step: "!!i. [| i < j; P (Suc i) |] ==> P i"
  1839   shows "P i"
  1840   using less
  1841 proof (induct d=="j - i - 1" arbitrary: i)
  1842   case (0 i)
  1843   with `i < j` have "j = Suc i" by simp
  1844   with base show ?case by simp
  1845 next
  1846   case (Suc d i)
  1847   hence "i < j" "P (Suc i)"
  1848     by simp_all
  1849   thus "P i" by (rule step)
  1850 qed
  1851 
  1852 lemma zero_induct_lemma: "P k ==> (!!n. P (Suc n) ==> P n) ==> P (k - i)"
  1853   using inc_induct[of "k - i" k P, simplified] by blast
  1854 
  1855 lemma zero_induct: "P k ==> (!!n. P (Suc n) ==> P n) ==> P 0"
  1856   using inc_induct[of 0 k P] by blast
  1857 
  1858 text {* Further induction rule similar to @{thm inc_induct} *}
  1859 
  1860 lemma dec_induct[consumes 1, case_names base step]:
  1861   "i \<le> j \<Longrightarrow> P i \<Longrightarrow> (\<And>n. i \<le> n \<Longrightarrow> n < j \<Longrightarrow> P n \<Longrightarrow> P (Suc n)) \<Longrightarrow> P j"
  1862   by (induct j arbitrary: i) (auto simp: le_Suc_eq)
  1863 
  1864 subsection \<open> Monotonicity of funpow \<close>
  1865 
  1866 lemma funpow_increasing:
  1867   fixes f :: "'a \<Rightarrow> ('a::{lattice, order_top})"
  1868   shows "m \<le> n \<Longrightarrow> mono f \<Longrightarrow> (f ^^ n) \<top> \<le> (f ^^ m) \<top>"
  1869   by (induct rule: inc_induct)
  1870      (auto simp del: funpow.simps(2) simp add: funpow_Suc_right
  1871            intro: order_trans[OF _ funpow_mono])
  1872 
  1873 lemma funpow_decreasing:
  1874   fixes f :: "'a \<Rightarrow> ('a::{lattice, order_bot})"
  1875   shows "m \<le> n \<Longrightarrow> mono f \<Longrightarrow> (f ^^ m) \<bottom> \<le> (f ^^ n) \<bottom>"
  1876   by (induct rule: dec_induct)
  1877      (auto simp del: funpow.simps(2) simp add: funpow_Suc_right
  1878            intro: order_trans[OF _ funpow_mono])
  1879 
  1880 lemma mono_funpow:
  1881   fixes Q :: "('i \<Rightarrow> 'a::{lattice, order_bot}) \<Rightarrow> ('i \<Rightarrow> 'a)"
  1882   shows "mono Q \<Longrightarrow> mono (\<lambda>i. (Q ^^ i) \<bottom>)"
  1883   by (auto intro!: funpow_decreasing simp: mono_def)
  1884 
  1885 subsection {* The divides relation on @{typ nat} *}
  1886 
  1887 lemma dvd_1_left [iff]: "Suc 0 dvd k"
  1888 unfolding dvd_def by simp
  1889 
  1890 lemma dvd_1_iff_1 [simp]: "(m dvd Suc 0) = (m = Suc 0)"
  1891 by (simp add: dvd_def)
  1892 
  1893 lemma nat_dvd_1_iff_1 [simp]: "m dvd (1::nat) \<longleftrightarrow> m = 1"
  1894 by (simp add: dvd_def)
  1895 
  1896 lemma dvd_antisym: "[| m dvd n; n dvd m |] ==> m = (n::nat)"
  1897   unfolding dvd_def
  1898   by (force dest: mult_eq_self_implies_10 simp add: mult.assoc)
  1899 
  1900 text {* @{term "op dvd"} is a partial order *}
  1901 
  1902 interpretation dvd: order "op dvd" "\<lambda>n m \<Colon> nat. n dvd m \<and> \<not> m dvd n"
  1903   proof qed (auto intro: dvd_refl dvd_trans dvd_antisym)
  1904 
  1905 lemma dvd_diff_nat[simp]: "[| k dvd m; k dvd n |] ==> k dvd (m-n :: nat)"
  1906 unfolding dvd_def
  1907 by (blast intro: diff_mult_distrib2 [symmetric])
  1908 
  1909 lemma dvd_diffD: "[| k dvd m-n; k dvd n; n\<le>m |] ==> k dvd (m::nat)"
  1910   apply (erule linorder_not_less [THEN iffD2, THEN add_diff_inverse, THEN subst])
  1911   apply (blast intro: dvd_add)
  1912   done
  1913 
  1914 lemma dvd_diffD1: "[| k dvd m-n; k dvd m; n\<le>m |] ==> k dvd (n::nat)"
  1915 by (drule_tac m = m in dvd_diff_nat, auto)
  1916 
  1917 lemma dvd_mult_cancel: "!!k::nat. [| k*m dvd k*n; 0<k |] ==> m dvd n"
  1918   unfolding dvd_def
  1919   apply (erule exE)
  1920   apply (simp add: ac_simps)
  1921   done
  1922 
  1923 lemma dvd_mult_cancel1: "0<m ==> (m*n dvd m) = (n = (1::nat))"
  1924   apply auto
  1925    apply (subgoal_tac "m*n dvd m*1")
  1926    apply (drule dvd_mult_cancel, auto)
  1927   done
  1928 
  1929 lemma dvd_mult_cancel2: "0<m ==> (n*m dvd m) = (n = (1::nat))"
  1930   apply (subst mult.commute)
  1931   apply (erule dvd_mult_cancel1)
  1932   done
  1933 
  1934 lemma dvd_imp_le: "[| k dvd n; 0 < n |] ==> k \<le> (n::nat)"
  1935 by (auto elim!: dvdE) (auto simp add: gr0_conv_Suc)
  1936 
  1937 lemma nat_dvd_not_less:
  1938   fixes m n :: nat
  1939   shows "0 < m \<Longrightarrow> m < n \<Longrightarrow> \<not> n dvd m"
  1940 by (auto elim!: dvdE) (auto simp add: gr0_conv_Suc)
  1941 
  1942 lemma less_eq_dvd_minus:
  1943   fixes m n :: nat
  1944   assumes "m \<le> n"
  1945   shows "m dvd n \<longleftrightarrow> m dvd n - m"
  1946 proof -
  1947   from assms have "n = m + (n - m)" by simp
  1948   then obtain q where "n = m + q" ..
  1949   then show ?thesis by (simp add: add.commute [of m])
  1950 qed
  1951 
  1952 lemma dvd_minus_self:
  1953   fixes m n :: nat
  1954   shows "m dvd n - m \<longleftrightarrow> n < m \<or> m dvd n"
  1955   by (cases "n < m") (auto elim!: dvdE simp add: not_less le_imp_diff_is_add)
  1956 
  1957 lemma dvd_minus_add:
  1958   fixes m n q r :: nat
  1959   assumes "q \<le> n" "q \<le> r * m"
  1960   shows "m dvd n - q \<longleftrightarrow> m dvd n + (r * m - q)"
  1961 proof -
  1962   have "m dvd n - q \<longleftrightarrow> m dvd r * m + (n - q)"
  1963     using dvd_add_times_triv_left_iff [of m r] by simp
  1964   also from assms have "\<dots> \<longleftrightarrow> m dvd r * m + n - q" by simp
  1965   also from assms have "\<dots> \<longleftrightarrow> m dvd (r * m - q) + n" by simp
  1966   also have "\<dots> \<longleftrightarrow> m dvd n + (r * m - q)" by (simp add: add.commute)
  1967   finally show ?thesis .
  1968 qed
  1969 
  1970 
  1971 subsection {* Aliases *}
  1972 
  1973 lemma nat_mult_1: "(1::nat) * n = n"
  1974   by (fact mult_1_left)
  1975  
  1976 lemma nat_mult_1_right: "n * (1::nat) = n"
  1977   by (fact mult_1_right)
  1978 
  1979 
  1980 subsection {* Size of a datatype value *}
  1981 
  1982 class size =
  1983   fixes size :: "'a \<Rightarrow> nat" -- {* see further theory @{text Wellfounded} *}
  1984 
  1985 instantiation nat :: size
  1986 begin
  1987 
  1988 definition size_nat where
  1989   [simp, code]: "size (n \<Colon> nat) = n"
  1990 
  1991 instance ..
  1992 
  1993 end
  1994 
  1995 
  1996 subsection {* Code module namespace *}
  1997 
  1998 code_identifier
  1999   code_module Nat \<rightharpoonup> (SML) Arith and (OCaml) Arith and (Haskell) Arith
  2000 
  2001 hide_const (open) of_nat_aux
  2002 
  2003 end