src/Pure/library.ML
author wenzelm
Wed Nov 03 11:33:51 2010 +0100 (2010-11-03)
changeset 40318 035b2afbeb2e
parent 40291 012ed4426fda
child 40509 0bc83ae22789
permissions -rw-r--r--
discontinued obsolete function sys_error and exception SYS_ERROR;
     1 (*  Title:      Pure/library.ML
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 Basic library: functions, pairs, booleans, lists, integers,
     6 strings, lists as sets, orders, current directory, misc.
     7 
     8 See also General/basics.ML for the most fundamental concepts.
     9 *)
    10 
    11 infix 2 ?
    12 infix 3 o oo ooo oooo
    13 infix 4 ~~ upto downto
    14 infix orf andf
    15 
    16 signature BASIC_LIBRARY =
    17 sig
    18   (*functions*)
    19   val undefined: 'a -> 'b
    20   val I: 'a -> 'a
    21   val K: 'a -> 'b -> 'a
    22   val curry: ('a * 'b -> 'c) -> 'a -> 'b -> 'c
    23   val uncurry: ('a -> 'b -> 'c) -> 'a * 'b -> 'c
    24   val ? : bool * ('a -> 'a) -> 'a -> 'a
    25   val oo: ('a -> 'b) * ('c -> 'd -> 'a) -> 'c -> 'd -> 'b
    26   val ooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'a) -> 'c -> 'd -> 'e -> 'b
    27   val oooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'f -> 'a) -> 'c -> 'd -> 'e -> 'f -> 'b
    28   val funpow: int -> ('a -> 'a) -> 'a -> 'a
    29   val funpow_yield: int -> ('a -> 'b * 'a) -> 'a -> 'b list * 'a
    30 
    31   (*errors*)
    32   exception ERROR of string
    33   val error: string -> 'a
    34   val cat_error: string -> string -> 'a
    35   val assert_all: ('a -> bool) -> 'a list -> ('a -> string) -> unit
    36 
    37   (*pairs*)
    38   val pair: 'a -> 'b -> 'a * 'b
    39   val rpair: 'a -> 'b -> 'b * 'a
    40   val fst: 'a * 'b -> 'a
    41   val snd: 'a * 'b -> 'b
    42   val eq_fst: ('a * 'c -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    43   val eq_snd: ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    44   val eq_pair: ('a * 'c -> bool) -> ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    45   val swap: 'a * 'b -> 'b * 'a
    46   val apfst: ('a -> 'b) -> 'a * 'c -> 'b * 'c
    47   val apsnd: ('a -> 'b) -> 'c * 'a -> 'c * 'b
    48   val pairself: ('a -> 'b) -> 'a * 'a -> 'b * 'b
    49 
    50   (*booleans*)
    51   val equal: ''a -> ''a -> bool
    52   val not_equal: ''a -> ''a -> bool
    53   val orf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    54   val andf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    55   val exists: ('a -> bool) -> 'a list -> bool
    56   val forall: ('a -> bool) -> 'a list -> bool
    57   val setmp_CRITICAL: 'a Unsynchronized.ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    58   val setmp_thread_data: 'a Universal.tag -> 'a -> 'a -> ('b -> 'c) -> 'b -> 'c
    59 
    60   (*lists*)
    61   exception UnequalLengths
    62   val single: 'a -> 'a list
    63   val the_single: 'a list -> 'a
    64   val singleton: ('a list -> 'b list) -> 'a -> 'b
    65   val yield_singleton: ('a list -> 'c -> 'b list * 'c) -> 'a -> 'c -> 'b * 'c
    66   val apply: ('a -> 'a) list -> 'a -> 'a
    67   val perhaps_apply: ('a -> 'a option) list -> 'a -> 'a option
    68   val perhaps_loop: ('a -> 'a option) -> 'a -> 'a option
    69   val foldl1: ('a * 'a -> 'a) -> 'a list -> 'a
    70   val foldr1: ('a * 'a -> 'a) -> 'a list -> 'a
    71   val flat: 'a list list -> 'a list
    72   val unflat: 'a list list -> 'b list -> 'b list list
    73   val burrow: ('a list -> 'b list) -> 'a list list -> 'b list list
    74   val burrow_options: ('a list -> 'b list) -> 'a option list -> 'b option list
    75   val burrow_fst: ('a list -> 'b list) -> ('a * 'c) list -> ('b * 'c) list
    76   val fold_burrow: ('a list -> 'c -> 'b list * 'd) -> 'a list list -> 'c -> 'b list list * 'd
    77   val maps: ('a -> 'b list) -> 'a list -> 'b list
    78   val filter: ('a -> bool) -> 'a list -> 'a list
    79   val filter_out: ('a -> bool) -> 'a list -> 'a list
    80   val map_filter: ('a -> 'b option) -> 'a list -> 'b list
    81   val take: int -> 'a list -> 'a list
    82   val drop: int -> 'a list -> 'a list
    83   val chop: int -> 'a list -> 'a list * 'a list
    84   val chop_while: ('a -> bool) -> 'a list -> 'a list * 'a list
    85   val nth: 'a list -> int -> 'a
    86   val nth_map: int -> ('a -> 'a) -> 'a list -> 'a list
    87   val nth_drop: int -> 'a list -> 'a list
    88   val nth_list: 'a list list -> int -> 'a list
    89   val map_index: (int * 'a -> 'b) -> 'a list -> 'b list
    90   val fold_index: (int * 'a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    91   val map_range: (int -> 'a) -> int -> 'a list
    92   val split_last: 'a list -> 'a list * 'a
    93   val find_index: ('a -> bool) -> 'a list -> int
    94   val find_first: ('a -> bool) -> 'a list -> 'a option
    95   val get_index: ('a -> 'b option) -> 'a list -> (int * 'b) option
    96   val get_first: ('a -> 'b option) -> 'a list -> 'b option
    97   val eq_list: ('a * 'b -> bool) -> 'a list * 'b list -> bool
    98   val map2: ('a -> 'b -> 'c) -> 'a list -> 'b list -> 'c list
    99   val fold2: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
   100   val zip_options: 'a list -> 'b option list -> ('a * 'b) list
   101   val ~~ : 'a list * 'b list -> ('a * 'b) list
   102   val map_split: ('a -> 'b * 'c) -> 'a list -> 'b list * 'c list
   103   val split_list: ('a * 'b) list -> 'a list * 'b list
   104   val map_product: ('a -> 'b -> 'c) -> 'a list -> 'b list -> 'c list
   105   val fold_product: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
   106   val map_transpose: ('a list -> 'b) -> 'a list list -> 'b list
   107   val separate: 'a -> 'a list -> 'a list
   108   val surround: 'a -> 'a list -> 'a list
   109   val replicate: int -> 'a -> 'a list
   110   val is_prefix: ('a * 'a -> bool) -> 'a list -> 'a list -> bool
   111   val take_prefix: ('a -> bool) -> 'a list -> 'a list * 'a list
   112   val chop_prefix: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list * ('a list * 'b list)
   113   val take_suffix: ('a -> bool) -> 'a list -> 'a list * 'a list
   114   val prefixes1: 'a list -> 'a list list
   115   val prefixes: 'a list -> 'a list list
   116   val suffixes1: 'a list -> 'a list list
   117   val suffixes: 'a list -> 'a list list
   118 
   119   (*integers*)
   120   val upto: int * int -> int list
   121   val downto: int * int -> int list
   122   val radixpand: int * int -> int list
   123   val radixstring: int * string * int -> string
   124   val string_of_int: int -> string
   125   val signed_string_of_int: int -> string
   126   val string_of_indexname: string * int -> string
   127   val read_radix_int: int -> string list -> int * string list
   128   val read_int: string list -> int * string list
   129   val oct_char: string -> string
   130 
   131   (*reals*)
   132   val string_of_real: real -> string
   133   val signed_string_of_real: real -> string
   134 
   135   (*strings*)
   136   val nth_string: string -> int -> string
   137   val fold_string: (string -> 'a -> 'a) -> string -> 'a -> 'a
   138   val exists_string: (string -> bool) -> string -> bool
   139   val forall_string: (string -> bool) -> string -> bool
   140   val first_field: string -> string -> (string * string) option
   141   val enclose: string -> string -> string -> string
   142   val unenclose: string -> string
   143   val quote: string -> string
   144   val space_implode: string -> string list -> string
   145   val commas: string list -> string
   146   val commas_quote: string list -> string
   147   val cat_lines: string list -> string
   148   val space_explode: string -> string -> string list
   149   val split_lines: string -> string list
   150   val prefix_lines: string -> string -> string
   151   val prefix: string -> string -> string
   152   val suffix: string -> string -> string
   153   val unprefix: string -> string -> string
   154   val unsuffix: string -> string -> string
   155   val replicate_string: int -> string -> string
   156   val translate_string: (string -> string) -> string -> string
   157   val match_string: string -> string -> bool
   158 
   159   (*lists as sets -- see also Pure/General/ord_list.ML*)
   160   val member: ('b * 'a -> bool) -> 'a list -> 'b -> bool
   161   val insert: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   162   val remove: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   163   val update: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   164   val union: ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   165   val subtract: ('b * 'a -> bool) -> 'b list -> 'a list -> 'a list
   166   val inter: ('a * 'b -> bool) -> 'b list -> 'a list -> 'a list
   167   val merge: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   168   val subset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   169   val eq_set: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   170   val distinct: ('a * 'a -> bool) -> 'a list -> 'a list
   171   val duplicates: ('a * 'a -> bool) -> 'a list -> 'a list
   172   val has_duplicates: ('a * 'a -> bool) -> 'a list -> bool
   173 
   174   (*lists as multisets*)
   175   val remove1: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   176   val combine: ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   177   val submultiset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   178 
   179   (*orders*)
   180   val is_equal: order -> bool
   181   val rev_order: order -> order
   182   val make_ord: ('a * 'a -> bool) -> 'a * 'a -> order
   183   val bool_ord: bool * bool -> order
   184   val int_ord: int * int -> order
   185   val string_ord: string * string -> order
   186   val fast_string_ord: string * string -> order
   187   val option_ord: ('a * 'b -> order) -> 'a option * 'b option -> order
   188   val prod_ord: ('a * 'b -> order) -> ('c * 'd -> order) -> ('a * 'c) * ('b * 'd) -> order
   189   val dict_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   190   val list_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   191   val sort: ('a * 'a -> order) -> 'a list -> 'a list
   192   val sort_distinct: ('a * 'a -> order) -> 'a list -> 'a list
   193   val sort_strings: string list -> string list
   194   val sort_wrt: ('a -> string) -> 'a list -> 'a list
   195   val tag_list: int -> 'a list -> (int * 'a) list
   196   val untag_list: (int * 'a) list -> 'a list
   197   val order_list: (int * 'a) list -> 'a list
   198 
   199   (*random numbers*)
   200   exception RANDOM
   201   val random: unit -> real
   202   val random_range: int -> int -> int
   203   val one_of: 'a list -> 'a
   204   val frequency: (int * 'a) list -> 'a
   205 
   206   (*misc*)
   207   val divide_and_conquer: ('a -> 'a list * ('b list -> 'b)) -> 'a -> 'b
   208   val divide_and_conquer': ('a -> 'b -> ('a list * ('c list * 'b -> 'c * 'b)) * 'b) ->
   209     'a -> 'b -> 'c * 'b
   210   val partition_eq: ('a * 'a -> bool) -> 'a list -> 'a list list
   211   val partition_list: (int -> 'a -> bool) -> int -> int -> 'a list -> 'a list list
   212   val gensym: string -> string
   213   type stamp
   214   val stamp: unit -> stamp
   215   type serial
   216   val serial: unit -> serial
   217   val serial_string: unit -> string
   218   structure Object: sig type T end
   219 end;
   220 
   221 signature LIBRARY =
   222 sig
   223   include BASIC_LIBRARY
   224   val foldl: ('a * 'b -> 'a) -> 'a * 'b list -> 'a
   225   val foldr: ('a * 'b -> 'b) -> 'a list * 'b -> 'b
   226   val foldl_map: ('a * 'b -> 'a * 'c) -> 'a * 'b list -> 'a * 'c list
   227   val last_elem: 'a list -> 'a
   228 end;
   229 
   230 structure Library: LIBRARY =
   231 struct
   232 
   233 (* functions *)
   234 
   235 fun undefined _ = raise Match;
   236 
   237 fun I x = x;
   238 fun K x = fn _ => x;
   239 fun curry f x y = f (x, y);
   240 fun uncurry f (x, y) = f x y;
   241 
   242 (*conditional application*)
   243 fun b ? f = fn x => if b then f x else x;
   244 
   245 (*composition with multiple args*)
   246 fun (f oo g) x y = f (g x y);
   247 fun (f ooo g) x y z = f (g x y z);
   248 fun (f oooo g) x y z w = f (g x y z w);
   249 
   250 (*function exponentiation: f (... (f x) ...) with n applications of f*)
   251 fun funpow (0 : int) _ = I
   252   | funpow n f = f #> funpow (n - 1) f;
   253 
   254 fun funpow_yield (0 : int) _ x = ([], x)
   255   | funpow_yield n f x = x |> f ||>> funpow_yield (n - 1) f |>> op ::;
   256 
   257 
   258 (* errors *)
   259 
   260 exception ERROR of string;
   261 fun error msg = raise ERROR msg;
   262 
   263 fun cat_error "" msg = error msg
   264   | cat_error msg1 msg2 = error (msg1 ^ "\n" ^ msg2);
   265 
   266 fun assert_all pred list msg =
   267   let
   268     fun ass [] = ()
   269       | ass (x :: xs) = if pred x then ass xs else error (msg x);
   270   in ass list end;
   271 
   272 
   273 (* pairs *)
   274 
   275 fun pair x y = (x, y);
   276 fun rpair x y = (y, x);
   277 
   278 fun fst (x, y) = x;
   279 fun snd (x, y) = y;
   280 
   281 fun eq_fst eq ((x1, _), (x2, _)) = eq (x1, x2);
   282 fun eq_snd eq ((_, y1), (_, y2)) = eq (y1, y2);
   283 fun eq_pair eqx eqy ((x1, y1), (x2, y2)) = eqx (x1, x2) andalso eqy (y1, y2);
   284 
   285 fun swap (x, y) = (y, x);
   286 
   287 fun apfst f (x, y) = (f x, y);
   288 fun apsnd f (x, y) = (x, f y);
   289 fun pairself f (x, y) = (f x, f y);
   290 
   291 
   292 (* booleans *)
   293 
   294 (*polymorphic equality*)
   295 fun equal x y = x = y;
   296 fun not_equal x y = x <> y;
   297 
   298 (*combining predicates*)
   299 fun p orf q = fn x => p x orelse q x;
   300 fun p andf q = fn x => p x andalso q x;
   301 
   302 val exists = List.exists;
   303 val forall = List.all;
   304 
   305 
   306 (* flags *)
   307 
   308 fun setmp_CRITICAL flag value f x =
   309   NAMED_CRITICAL "setmp" (fn () => Unsynchronized.setmp flag value f x);
   310 
   311 fun setmp_thread_data tag orig_data data f x =
   312   uninterruptible (fn restore_attributes => fn () =>
   313     let
   314       val _ = Thread.setLocal (tag, data);
   315       val result = Exn.capture (restore_attributes f) x;
   316       val _ = Thread.setLocal (tag, orig_data);
   317     in Exn.release result end) ();
   318 
   319 
   320 
   321 (** lists **)
   322 
   323 exception UnequalLengths;
   324 
   325 fun single x = [x];
   326 
   327 fun the_single [x] = x
   328   | the_single _ = raise Empty;
   329 
   330 fun singleton f x = the_single (f [x]);
   331 
   332 fun yield_singleton f x = f [x] #>> the_single;
   333 
   334 fun apply [] x = x
   335   | apply (f :: fs) x = apply fs (f x);
   336 
   337 fun perhaps_apply funs arg =
   338   let
   339     fun app [] res = res
   340       | app (f :: fs) (changed, x) =
   341           (case f x of
   342             NONE => app fs (changed, x)
   343           | SOME x' => app fs (true, x'));
   344   in (case app funs (false, arg) of (false, _) => NONE | (true, arg') => SOME arg') end;
   345 
   346 fun perhaps_loop f arg =
   347   let
   348     fun loop (changed, x) =
   349       (case f x of
   350         NONE => (changed, x)
   351       | SOME x' => loop (true, x'));
   352   in (case loop (false, arg) of (false, _) => NONE | (true, arg') => SOME arg') end;
   353 
   354 
   355 (* fold -- old versions *)
   356 
   357 (*the following versions of fold are designed to fit nicely with infixes*)
   358 
   359 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   360     for operators that associate to the left (TAIL RECURSIVE)*)
   361 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   362   let fun itl (e, [])  = e
   363         | itl (e, a::l) = itl (f(e, a), l)
   364   in  itl end;
   365 
   366 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   367     for operators that associate to the right (not tail recursive)*)
   368 fun foldr f (l, e) =
   369   let fun itr [] = e
   370         | itr (a::l) = f(a, itr l)
   371   in  itr l  end;
   372 
   373 (*  (op @) [x1, ..., xn]  ===>  ((x1 @ x2) @ x3) ... @ xn
   374     for operators that associate to the left (TAIL RECURSIVE)*)
   375 fun foldl1 f [] = raise Empty
   376   | foldl1 f (x :: xs) = foldl f (x, xs);
   377 
   378 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   379     for n > 0, operators that associate to the right (not tail recursive)*)
   380 fun foldr1 f [] = raise Empty
   381   | foldr1 f l =
   382       let fun itr [x] = x
   383             | itr (x::l) = f(x, itr l)
   384       in  itr l  end;
   385 
   386 fun foldl_map f =
   387   let
   388     fun fold_aux (x, []) = (x, [])
   389       | fold_aux (x, y :: ys) =
   390           let
   391             val (x', y') = f (x, y);
   392             val (x'', ys') = fold_aux (x', ys);
   393           in (x'', y' :: ys') end;
   394   in fold_aux end;
   395 
   396 
   397 (* basic list functions *)
   398 
   399 fun eq_list eq (list1, list2) =
   400   let
   401     fun eq_lst (x :: xs, y :: ys) = eq (x, y) andalso eq_lst (xs, ys)
   402       | eq_lst _ = true;
   403   in length list1 = length list2 andalso eq_lst (list1, list2) end;
   404 
   405 fun maps f [] = []
   406   | maps f (x :: xs) = f x @ maps f xs;
   407 
   408 val filter = List.filter;
   409 fun filter_out f = filter (not o f);
   410 val map_filter = List.mapPartial;
   411 
   412 fun take (0: int) xs = []
   413   | take _ [] = []
   414   | take n (x :: xs) = x :: take (n - 1) xs;
   415 
   416 fun drop (0: int) xs = xs
   417   | drop _ [] = []
   418   | drop n (x :: xs) = drop (n - 1) xs;
   419 
   420 fun chop (0: int) xs = ([], xs)
   421   | chop _ [] = ([], [])
   422   | chop n (x :: xs) = chop (n - 1) xs |>> cons x;
   423 
   424 fun chop_while P [] = ([], [])
   425   | chop_while P (ys as x :: xs) =
   426       if P x then chop_while P xs |>> cons x else ([], ys);
   427 
   428 (*return nth element of a list, where 0 designates the first element;
   429   raise Subscript if list too short*)
   430 fun nth xs i = List.nth (xs, i);
   431 
   432 fun nth_list xss i = nth xss i handle Subscript => [];
   433 
   434 fun nth_map 0 f (x :: xs) = f x :: xs
   435   | nth_map n f (x :: xs) = x :: nth_map (n - 1) f xs
   436   | nth_map (_: int) _ [] = raise Subscript;
   437 
   438 fun nth_drop n xs =
   439   List.take (xs, n) @ List.drop (xs, n + 1);
   440 
   441 fun map_index f =
   442   let
   443     fun mapp (_: int) [] = []
   444       | mapp i (x :: xs) = f (i, x) :: mapp (i + 1) xs
   445   in mapp 0 end;
   446 
   447 fun fold_index f =
   448   let
   449     fun fold_aux (_: int) [] y = y
   450       | fold_aux i (x :: xs) y = fold_aux (i + 1) xs (f (i, x) y);
   451   in fold_aux 0 end;
   452 
   453 fun map_range f i =
   454   let
   455     fun mapp (k: int) =
   456       if k < i then f k :: mapp (k + 1) else [];
   457   in mapp 0 end;
   458 
   459 val last_elem = List.last;
   460 
   461 (*rear decomposition*)
   462 fun split_last [] = raise Empty
   463   | split_last [x] = ([], x)
   464   | split_last (x :: xs) = apfst (cons x) (split_last xs);
   465 
   466 (*find position of first element satisfying a predicate*)
   467 fun find_index pred =
   468   let fun find (_: int) [] = ~1
   469         | find n (x :: xs) = if pred x then n else find (n + 1) xs;
   470   in find 0 end;
   471 
   472 (*find first element satisfying predicate*)
   473 val find_first = List.find;
   474 
   475 (*get first element by lookup function*)
   476 fun get_first _ [] = NONE
   477   | get_first f (x :: xs) =
   478       (case f x of
   479         NONE => get_first f xs
   480       | some => some);
   481 
   482 fun get_index f =
   483   let
   484     fun get (_: int) [] = NONE
   485       | get i (x :: xs) =
   486           case f x
   487            of NONE => get (i + 1) xs
   488             | SOME y => SOME (i, y)
   489   in get 0 end;
   490 
   491 val flat = List.concat;
   492 
   493 fun unflat (xs :: xss) ys =
   494       let val (ps, qs) = chop (length xs) ys
   495       in ps :: unflat xss qs end
   496   | unflat [] [] = []
   497   | unflat _ _ = raise UnequalLengths;
   498 
   499 fun burrow f xss = unflat xss (f (flat xss));
   500 
   501 fun burrow_options f os = map (try hd) (burrow f (map the_list os));
   502 
   503 fun fold_burrow f xss s =
   504   apfst (unflat xss) (f (flat xss) s);
   505 
   506 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   507 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   508   | separate _ xs = xs;
   509 
   510 fun surround s (x :: xs) = s :: x :: surround s xs
   511   | surround s [] = [s];
   512 
   513 (*make the list [x, x, ..., x] of length n*)
   514 fun replicate (n: int) x =
   515   let fun rep (0, xs) = xs
   516         | rep (n, xs) = rep (n - 1, x :: xs)
   517   in
   518     if n < 0 then raise Subscript
   519     else rep (n, [])
   520   end;
   521 
   522 
   523 (* direct product *)
   524 
   525 fun map_product f _ [] = []
   526   | map_product f [] _ = []
   527   | map_product f (x :: xs) ys = map (f x) ys @ map_product f xs ys;
   528 
   529 fun fold_product f _ [] z = z
   530   | fold_product f [] _ z = z
   531   | fold_product f (x :: xs) ys z = z |> fold (f x) ys |> fold_product f xs ys;
   532 
   533 
   534 (* lists of pairs *)
   535 
   536 exception UnequalLengths;
   537 
   538 fun map2 _ [] [] = []
   539   | map2 f (x :: xs) (y :: ys) = f x y :: map2 f xs ys
   540   | map2 _ _ _ = raise UnequalLengths;
   541 
   542 fun fold2 f [] [] z = z
   543   | fold2 f (x :: xs) (y :: ys) z = fold2 f xs ys (f x y z)
   544   | fold2 f _ _ _ = raise UnequalLengths;
   545 
   546 fun map_split f [] = ([], [])
   547   | map_split f (x :: xs) =
   548       let
   549         val (y, w) = f x;
   550         val (ys, ws) = map_split f xs;
   551       in (y :: ys, w :: ws) end;
   552 
   553 fun zip_options (x :: xs) (SOME y :: ys) = (x, y) :: zip_options xs ys
   554   | zip_options (_ :: xs) (NONE :: ys) = zip_options xs ys
   555   | zip_options _ [] = []
   556   | zip_options [] _ = raise UnequalLengths;
   557 
   558 (*combine two lists forming a list of pairs:
   559   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   560 fun [] ~~ [] = []
   561   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   562   | _ ~~ _ = raise UnequalLengths;
   563 
   564 (*inverse of ~~; the old 'split':
   565   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   566 val split_list = ListPair.unzip;
   567 
   568 fun burrow_fst f xs = split_list xs |>> f |> op ~~;
   569 
   570 
   571 (* prefixes, suffixes *)
   572 
   573 fun is_prefix _ [] _ = true
   574   | is_prefix eq (x :: xs) (y :: ys) = eq (x, y) andalso is_prefix eq xs ys
   575   | is_prefix eq _ _ = false;
   576 
   577 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   578    where xi is the first element that does not satisfy the predicate*)
   579 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   580   let fun take (rxs, []) = (rev rxs, [])
   581         | take (rxs, x :: xs) =
   582             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   583   in  take([], xs)  end;
   584 
   585 fun chop_prefix eq ([], ys) = ([], ([], ys))
   586   | chop_prefix eq (xs, []) = ([], (xs, []))
   587   | chop_prefix eq (xs as x :: xs', ys as y :: ys') =
   588       if eq (x, y) then
   589         let val (ps', xys'') = chop_prefix eq (xs', ys')
   590         in (x :: ps', xys'') end
   591       else ([], (xs, ys));
   592 
   593 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   594    where xi is the last element that does not satisfy the predicate*)
   595 fun take_suffix _ [] = ([], [])
   596   | take_suffix pred (x :: xs) =
   597       (case take_suffix pred xs of
   598         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   599       | (prfx, sffx) => (x :: prfx, sffx));
   600 
   601 fun prefixes1 [] = []
   602   | prefixes1 (x :: xs) = map (cons x) ([] :: prefixes1 xs);
   603 
   604 fun prefixes xs = [] :: prefixes1 xs;
   605 
   606 fun suffixes1 xs = map rev (prefixes1 (rev xs));
   607 fun suffixes xs = [] :: suffixes1 xs;
   608 
   609 
   610 
   611 (** integers **)
   612 
   613 (* lists of integers *)
   614 
   615 (*make the list [from, from + 1, ..., to]*)
   616 fun ((i: int) upto j) =
   617   if i > j then [] else i :: (i + 1 upto j);
   618 
   619 (*make the list [from, from - 1, ..., to]*)
   620 fun ((i: int) downto j) =
   621   if i < j then [] else i :: (i - 1 downto j);
   622 
   623 
   624 (* convert integers to strings *)
   625 
   626 (*expand the number in the given base;
   627   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   628 fun radixpand (base, num) : int list =
   629   let
   630     fun radix (n, tail) =
   631       if n < base then n :: tail
   632       else radix (n div base, (n mod base) :: tail)
   633   in radix (num, []) end;
   634 
   635 (*expands a number into a string of characters starting from "zerochar";
   636   example: radixstring (2, "0", 8) gives "1000"*)
   637 fun radixstring (base, zerochar, num) =
   638   let val offset = ord zerochar;
   639       fun chrof n = chr (offset + n)
   640   in implode (map chrof (radixpand (base, num))) end;
   641 
   642 
   643 val string_of_int = Int.toString;
   644 
   645 fun signed_string_of_int i =
   646   if i < 0 then "-" ^ string_of_int (~ i) else string_of_int i;
   647 
   648 fun string_of_indexname (a, 0) = a
   649   | string_of_indexname (a, i) = a ^ "_" ^ string_of_int i;
   650 
   651 
   652 (* read integers *)
   653 
   654 fun read_radix_int radix cs =
   655   let
   656     val zero = ord "0";
   657     val limit = zero + radix;
   658     fun scan (num, []) = (num, [])
   659       | scan (num, c :: cs) =
   660         if zero <= ord c andalso ord c < limit then
   661           scan (radix * num + (ord c - zero), cs)
   662         else (num, c :: cs);
   663   in scan (0, cs) end;
   664 
   665 val read_int = read_radix_int 10;
   666 
   667 fun oct_char s = chr (#1 (read_radix_int 8 (explode s)));
   668 
   669 
   670 
   671 (** reals **)
   672 
   673 val string_of_real = Real.fmt (StringCvt.GEN NONE);
   674 
   675 fun signed_string_of_real x =
   676   if x < 0.0 then "-" ^ string_of_real (~ x) else string_of_real x;
   677 
   678 
   679 
   680 (** strings **)
   681 
   682 (* functions tuned for strings, avoiding explode *)
   683 
   684 fun nth_string str i =
   685   (case try String.substring (str, i, 1) of
   686     SOME s => s
   687   | NONE => raise Subscript);
   688 
   689 fun fold_string f str x0 =
   690   let
   691     val n = size str;
   692     fun iter (x, i) =
   693       if i < n then iter (f (String.substring (str, i, 1)) x, i + 1) else x;
   694   in iter (x0, 0) end;
   695 
   696 fun exists_string pred str =
   697   let
   698     val n = size str;
   699     fun ex i = i < n andalso (pred (String.substring (str, i, 1)) orelse ex (i + 1));
   700   in ex 0 end;
   701 
   702 fun forall_string pred = not o exists_string (not o pred);
   703 
   704 fun first_field sep str =
   705   let
   706     val n = size sep;
   707     val len = size str;
   708     fun find i =
   709       if i + n > len then NONE
   710       else if String.substring (str, i, n) = sep then SOME i
   711       else find (i + 1);
   712   in
   713     (case find 0 of
   714       NONE => NONE
   715     | SOME i => SOME (String.substring (str, 0, i), String.extract (str, i + n, NONE)))
   716   end;
   717 
   718 (*enclose in brackets*)
   719 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   720 fun unenclose str = String.substring (str, 1, size str - 2);
   721 
   722 (*simple quoting (does not escape special chars)*)
   723 val quote = enclose "\"" "\"";
   724 
   725 (*space_implode "..." (explode "hello") = "h...e...l...l...o"*)
   726 fun space_implode a bs = implode (separate a bs);
   727 
   728 val commas = space_implode ", ";
   729 val commas_quote = commas o map quote;
   730 
   731 (*concatenate messages, one per line, into a string*)
   732 val cat_lines = space_implode "\n";
   733 
   734 (*space_explode "." "h.e..l.lo" = ["h", "e", "", "l", "lo"]*)
   735 fun space_explode _ "" = []
   736   | space_explode sep s = String.fields (fn c => str c = sep) s;
   737 
   738 val split_lines = space_explode "\n";
   739 
   740 fun prefix_lines "" txt = txt
   741   | prefix_lines prfx txt = txt |> split_lines |> map (fn s => prfx ^ s) |> cat_lines;
   742 
   743 fun prefix prfx s = prfx ^ s;
   744 fun suffix sffx s = s ^ sffx;
   745 
   746 fun unprefix prfx s =
   747   if String.isPrefix prfx s then String.substring (s, size prfx, size s - size prfx)
   748   else raise Fail "unprefix";
   749 
   750 fun unsuffix sffx s =
   751   if String.isSuffix sffx s then String.substring (s, 0, size s - size sffx)
   752   else raise Fail "unsuffix";
   753 
   754 fun replicate_string (0: int) _ = ""
   755   | replicate_string 1 a = a
   756   | replicate_string k a =
   757       if k mod 2 = 0 then replicate_string (k div 2) (a ^ a)
   758       else replicate_string (k div 2) (a ^ a) ^ a;
   759 
   760 fun translate_string f = String.translate (f o String.str);
   761 
   762 (*crude matching of str against simple glob pat*)
   763 fun match_string pat str =
   764   let
   765     fun match [] _ = true
   766       | match (p :: ps) s =
   767           size p <= size s andalso
   768             (case try (unprefix p) s of
   769               SOME s' => match ps s'
   770             | NONE => match (p :: ps) (String.substring (s, 1, size s - 1)));
   771   in match (space_explode "*" pat) str end;
   772 
   773 
   774 
   775 (** lists as sets -- see also Pure/General/ord_list.ML **)
   776 
   777 (* canonical operations *)
   778 
   779 fun member eq list x =
   780   let
   781     fun memb [] = false
   782       | memb (y :: ys) = eq (x, y) orelse memb ys;
   783   in memb list end;
   784 
   785 fun insert eq x xs = if member eq xs x then xs else x :: xs;
   786 fun remove eq x xs = if member eq xs x then filter_out (fn y => eq (x, y)) xs else xs;
   787 fun update eq x xs = cons x (remove eq x xs);
   788 
   789 fun inter eq xs = filter (member eq xs);
   790 
   791 fun union eq = fold (insert eq);
   792 fun subtract eq = fold (remove eq);
   793 
   794 fun merge eq (xs, ys) =
   795   if pointer_eq (xs, ys) then xs
   796   else if null xs then ys
   797   else fold_rev (insert eq) ys xs;
   798 
   799 
   800 (* subset and set equality *)
   801 
   802 fun subset eq (xs, ys) = forall (member eq ys) xs;
   803 
   804 fun eq_set eq (xs, ys) =
   805   eq_list eq (xs, ys) orelse
   806     (subset eq (xs, ys) andalso subset (eq o swap) (ys, xs));
   807 
   808 
   809 (*makes a list of the distinct members of the input; preserves order, takes
   810   first of equal elements*)
   811 fun distinct eq lst =
   812   let
   813     fun dist (rev_seen, []) = rev rev_seen
   814       | dist (rev_seen, x :: xs) =
   815           if member eq rev_seen x then dist (rev_seen, xs)
   816           else dist (x :: rev_seen, xs);
   817   in dist ([], lst) end;
   818 
   819 (*returns a list containing all repeated elements exactly once; preserves
   820   order, takes first of equal elements*)
   821 fun duplicates eq lst =
   822   let
   823     fun dups (rev_dups, []) = rev rev_dups
   824       | dups (rev_dups, x :: xs) =
   825           if member eq rev_dups x orelse not (member eq xs x) then
   826             dups (rev_dups, xs)
   827           else dups (x :: rev_dups, xs);
   828   in dups ([], lst) end;
   829 
   830 fun has_duplicates eq =
   831   let
   832     fun dups [] = false
   833       | dups (x :: xs) = member eq xs x orelse dups xs;
   834   in dups end;
   835 
   836 
   837 (* matrices *)
   838 
   839 fun map_transpose f xss =
   840   let
   841     val n = case distinct (op =) (map length xss)
   842      of [] => 0
   843       | [n] => n
   844       | _ => raise UnequalLengths;
   845   in map_range (fn m => f (map (fn xs => nth xs m) xss)) n end;
   846 
   847 
   848 
   849 (** lists as multisets **)
   850 
   851 fun remove1 eq x [] = []
   852   | remove1 eq x (y :: ys) = if eq (x, y) then ys else y :: remove1 eq x ys;
   853 
   854 fun combine eq xs ys = fold (remove1 eq) ys xs @ ys;
   855 
   856 fun submultiset _ ([], _)  = true
   857   | submultiset eq (x :: xs, ys) = member eq ys x andalso submultiset eq (xs, remove1 eq x ys);
   858 
   859 
   860 
   861 (** orders **)
   862 
   863 fun is_equal EQUAL = true
   864   | is_equal _ = false;
   865 
   866 fun rev_order LESS = GREATER
   867   | rev_order EQUAL = EQUAL
   868   | rev_order GREATER = LESS;
   869 
   870 (*assume rel is a linear strict order*)
   871 fun make_ord rel (x, y) =
   872   if rel (x, y) then LESS
   873   else if rel (y, x) then GREATER
   874   else EQUAL;
   875 
   876 fun bool_ord (false, true) = LESS
   877   | bool_ord (true, false) = GREATER
   878   | bool_ord _ = EQUAL;
   879 
   880 val int_ord = Int.compare;
   881 val string_ord = String.compare;
   882 
   883 fun fast_string_ord (s1, s2) =
   884   (case int_ord (size s1, size s2) of EQUAL => string_ord (s1, s2) | ord => ord);
   885 
   886 fun option_ord ord (SOME x, SOME y) = ord (x, y)
   887   | option_ord _ (NONE, NONE) = EQUAL
   888   | option_ord _ (NONE, SOME _) = LESS
   889   | option_ord _ (SOME _, NONE) = GREATER;
   890 
   891 (*lexicographic product*)
   892 fun prod_ord a_ord b_ord ((x, y), (x', y')) =
   893   (case a_ord (x, x') of EQUAL => b_ord (y, y') | ord => ord);
   894 
   895 (*dictionary order -- in general NOT well-founded!*)
   896 fun dict_ord elem_ord (x :: xs, y :: ys) =
   897       (case elem_ord (x, y) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord)
   898   | dict_ord _ ([], []) = EQUAL
   899   | dict_ord _ ([], _ :: _) = LESS
   900   | dict_ord _ (_ :: _, []) = GREATER;
   901 
   902 (*lexicographic product of lists*)
   903 fun list_ord elem_ord (xs, ys) =
   904   (case int_ord (length xs, length ys) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
   905 
   906 
   907 (* sorting *)
   908 
   909 (*quicksort -- stable, i.e. does not reorder equal elements*)
   910 fun quicksort unique ord =
   911   let
   912     fun qsort [] = []
   913       | qsort (xs as [_]) = xs
   914       | qsort (xs as [x, y]) =
   915           (case ord (x, y) of
   916             LESS => xs
   917           | EQUAL => if unique then [x] else xs
   918           | GREATER => [y, x])
   919       | qsort xs =
   920           let val (lts, eqs, gts) = part (nth xs (length xs div 2)) xs
   921           in qsort lts @ eqs @ qsort gts end
   922     and part _ [] = ([], [], [])
   923       | part pivot (x :: xs) = add (ord (x, pivot)) x (part pivot xs)
   924     and add LESS x (lts, eqs, gts) = (x :: lts, eqs, gts)
   925       | add EQUAL x (lts, [], gts) = (lts, [x], gts)
   926       | add EQUAL x (res as (lts, eqs, gts)) = if unique then res else (lts, x :: eqs, gts)
   927       | add GREATER x (lts, eqs, gts) = (lts, eqs, x :: gts);
   928   in qsort end;
   929 
   930 fun sort ord = quicksort false ord;
   931 fun sort_distinct ord = quicksort true ord;
   932 
   933 val sort_strings = sort string_ord;
   934 fun sort_wrt sel xs = sort (string_ord o pairself sel) xs;
   935 
   936 
   937 (* items tagged by integer index *)
   938 
   939 (*insert tags*)
   940 fun tag_list k [] = []
   941   | tag_list k (x :: xs) = (k:int, x) :: tag_list (k + 1) xs;
   942 
   943 (*remove tags and suppress duplicates -- list is assumed sorted!*)
   944 fun untag_list [] = []
   945   | untag_list [(k: int, x)] = [x]
   946   | untag_list ((k, x) :: (rest as (k', x') :: _)) =
   947       if k = k' then untag_list rest
   948       else x :: untag_list rest;
   949 
   950 (*return list elements in original order*)
   951 fun order_list list = untag_list (sort (int_ord o pairself fst) list);
   952 
   953 
   954 
   955 (** random numbers **)
   956 
   957 exception RANDOM;
   958 
   959 fun rmod x y = x - y * Real.realFloor (x / y);
   960 
   961 local
   962   val a = 16807.0;
   963   val m = 2147483647.0;
   964   val random_seed = Unsynchronized.ref 1.0;
   965 in
   966 
   967 fun random () = CRITICAL (fn () =>
   968   let val r = rmod (a * ! random_seed) m
   969   in (random_seed := r; r) end);
   970 
   971 end;
   972 
   973 fun random_range l h =
   974   if h < l orelse l < 0 then raise RANDOM
   975   else l + Real.floor (rmod (random ()) (real (h - l + 1)));
   976 
   977 fun one_of xs = nth xs (random_range 0 (length xs - 1));
   978 
   979 fun frequency xs =
   980   let
   981     val sum = foldl op + (0, map fst xs);
   982     fun pick n ((k: int, x) :: xs) =
   983       if n <= k then x else pick (n - k) xs
   984   in pick (random_range 1 sum) xs end;
   985 
   986 
   987 
   988 (** misc **)
   989 
   990 fun divide_and_conquer decomp x =
   991   let val (ys, recomb) = decomp x
   992   in recomb (map (divide_and_conquer decomp) ys) end;
   993 
   994 fun divide_and_conquer' decomp x s =
   995   let val ((ys, recomb), s') = decomp x s
   996   in recomb (fold_map (divide_and_conquer' decomp) ys s') end;
   997 
   998 
   999 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
  1000    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
  1001 fun partition_list p i j =
  1002   let
  1003     fun part (k: int) xs =
  1004       if k > j then
  1005         (case xs of
  1006           [] => []
  1007         | _ => raise Fail "partition_list")
  1008       else
  1009         let val (ns, rest) = List.partition (p k) xs
  1010         in ns :: part (k + 1) rest end;
  1011   in part (i: int) end;
  1012 
  1013 fun partition_eq (eq: 'a * 'a -> bool) =
  1014   let
  1015     fun part [] = []
  1016       | part (x :: ys) =
  1017           let val (xs, xs') = List.partition (fn y => eq (x, y)) ys
  1018           in (x :: xs) :: part xs' end;
  1019   in part end;
  1020 
  1021 
  1022 
  1023 (* generating identifiers *)
  1024 
  1025 (** Freshly generated identifiers; supplied prefix MUST start with a letter **)
  1026 local
  1027 (*Maps 0-61 to A-Z, a-z, 0-9; exclude _ or ' to avoid clash with internal/unusual indentifiers*)
  1028 fun gensym_char i =
  1029   if i<26 then chr (ord "A" + i)
  1030   else if i<52 then chr (ord "a" + i - 26)
  1031   else chr (ord "0" + i - 52);
  1032 
  1033 val char_vec = Vector.tabulate (62, gensym_char);
  1034 fun newid n = implode (map (fn i => Vector.sub (char_vec, i)) (radixpand (62, n)));
  1035 
  1036 val gensym_seed = Unsynchronized.ref (0: int);
  1037 
  1038 in
  1039   fun gensym pre =
  1040     pre ^ newid (NAMED_CRITICAL "gensym" (fn () => Unsynchronized.inc gensym_seed));
  1041 end;
  1042 
  1043 
  1044 (* stamps and serial numbers *)
  1045 
  1046 type stamp = unit Unsynchronized.ref;
  1047 val stamp: unit -> stamp = Unsynchronized.ref;
  1048 
  1049 type serial = int;
  1050 val serial = Multithreading.serial;
  1051 val serial_string = string_of_int o serial;
  1052 
  1053 
  1054 (* generic objects *)
  1055 
  1056 (*note that the builtin exception datatype may be extended by new
  1057   constructors at any time*)
  1058 structure Object = struct type T = exn end;
  1059 
  1060 end;
  1061 
  1062 structure Basic_Library: BASIC_LIBRARY = Library;
  1063 open Basic_Library;