src/Pure/sign.ML
author wenzelm
Fri Dec 21 23:17:12 2001 +0100 (2001-12-21)
changeset 12588 0361fd72f1a7
parent 12313 e2cb7e8bb037
child 12785 27debaf2112d
permissions -rw-r--r--
hide: flag for full/base name;
     1 (*  Title:      Pure/sign.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson and Markus Wenzel
     4 
     5 The abstract type "sg" of signatures.
     6 *)
     7 
     8 (*base names*)
     9 type bstring = string;
    10 type bclass = class;
    11 (*external forms -- partially qualified names*)
    12 type xstring = string;
    13 type xclass = class;
    14 type xsort = sort;
    15 type xtyp = typ;
    16 type xterm = term;
    17 
    18 signature SIGN =
    19 sig
    20   type sg
    21   type sg_ref
    22   type data
    23   val rep_sg: sg ->
    24    {self: sg_ref,
    25     tsig: Type.type_sig,
    26     const_tab: typ Symtab.table,
    27     syn: Syntax.syntax,
    28     path: string list option,
    29     spaces: (string * NameSpace.T) list,
    30     data: data}
    31   val name_of: sg -> string
    32   val stamp_names_of: sg -> string list
    33   val exists_stamp: string -> sg -> bool
    34   val tsig_of: sg -> Type.type_sig
    35   val deref: sg_ref -> sg
    36   val self_ref: sg -> sg_ref
    37   val subsig: sg * sg -> bool
    38   val joinable: sg * sg -> bool
    39   val eq_sg: sg * sg -> bool
    40   val same_sg: sg * sg -> bool
    41   val is_draft: sg -> bool
    42   val is_stale: sg -> bool
    43   val const_type: sg -> string -> typ option
    44   val classes: sg -> class list
    45   val defaultS: sg -> sort
    46   val subsort: sg -> sort * sort -> bool
    47   val nodup_vars: term -> term
    48   val norm_sort: sg -> sort -> sort
    49   val of_sort: sg -> typ * sort -> bool
    50   val witness_sorts: sg -> sort list -> sort list -> (typ * sort) list
    51   val univ_witness: sg -> (typ * sort) option
    52   val typ_instance: sg -> typ * typ -> bool
    53   val classK: string
    54   val typeK: string
    55   val constK: string
    56   val full_name: sg -> bstring -> string
    57   val full_name_path: sg -> string -> bstring -> string
    58   val base_name: string -> bstring
    59   val intern: sg -> string -> xstring -> string
    60   val extern: sg -> string -> string -> xstring
    61   val cond_extern: sg -> string -> string -> xstring
    62   val cond_extern_table: sg -> string -> 'a Symtab.table -> (xstring * 'a) list
    63   val intern_class: sg -> xclass -> class
    64   val intern_tycon: sg -> xstring -> string
    65   val intern_const: sg -> xstring -> string
    66   val intern_sort: sg -> xsort -> sort
    67   val intern_typ: sg -> xtyp -> typ
    68   val intern_term: sg -> xterm -> term
    69   val intern_tycons: sg -> xtyp -> typ
    70   val pretty_sg: sg -> Pretty.T
    71   val str_of_sg: sg -> string
    72   val pprint_sg: sg -> pprint_args -> unit
    73   val pretty_term: sg -> term -> Pretty.T
    74   val pretty_term': Syntax.syntax -> sg -> term -> Pretty.T
    75   val pretty_typ: sg -> typ -> Pretty.T
    76   val pretty_sort: sg -> sort -> Pretty.T
    77   val pretty_classrel: sg -> class * class -> Pretty.T
    78   val pretty_arity: sg -> string * sort list * sort -> Pretty.T
    79   val string_of_term: sg -> term -> string
    80   val string_of_typ: sg -> typ -> string
    81   val string_of_sort: sg -> sort -> string
    82   val str_of_sort: sg -> sort -> string
    83   val str_of_classrel: sg -> class * class -> string
    84   val str_of_arity: sg -> string * sort list * sort -> string
    85   val pprint_term: sg -> term -> pprint_args -> unit
    86   val pprint_typ: sg -> typ -> pprint_args -> unit
    87   val certify_class: sg -> class -> class
    88   val certify_sort: sg -> sort -> sort
    89   val certify_typ: sg -> typ -> typ
    90   val certify_typ_no_norm: sg -> typ -> typ
    91   val certify_tycon: sg -> string -> string
    92   val certify_tyabbr: sg -> string -> string
    93   val certify_tyname: sg -> string -> string
    94   val certify_const: sg -> string -> string
    95   val certify_term: sg -> term -> term * typ * int
    96   val read_sort: sg -> string -> sort
    97   val read_raw_typ: sg * (indexname -> sort option) -> string -> typ
    98   val read_typ: sg * (indexname -> sort option) -> string -> typ
    99   val read_typ': Syntax.syntax -> sg * (indexname -> sort option) -> string -> typ
   100   val read_typ_no_norm': Syntax.syntax -> sg * (indexname -> sort option) -> string -> typ
   101   val infer_types: sg -> (indexname -> typ option) ->
   102     (indexname -> sort option) -> string list -> bool
   103     -> xterm list * typ -> term * (indexname * typ) list
   104   val infer_types_simult: sg -> (indexname -> typ option) ->
   105     (indexname -> sort option) -> string list -> bool
   106     -> (xterm list * typ) list -> term list * (indexname * typ) list
   107   val read_def_terms':
   108     Syntax.syntax -> sg * (indexname -> typ option) * (indexname -> sort option) ->
   109     string list -> bool -> (string * typ) list -> term list * (indexname * typ) list
   110   val read_def_terms:
   111     sg * (indexname -> typ option) * (indexname -> sort option) ->
   112     string list -> bool -> (string * typ) list -> term list * (indexname * typ) list
   113   val simple_read_term: sg -> typ -> string -> term
   114   val add_classes: (bclass * xclass list) list -> sg -> sg
   115   val add_classes_i: (bclass * class list) list -> sg -> sg
   116   val add_classrel: (xclass * xclass) list -> sg -> sg
   117   val add_classrel_i: (class * class) list -> sg -> sg
   118   val add_defsort: string -> sg -> sg
   119   val add_defsort_i: sort -> sg -> sg
   120   val add_types: (bstring * int * mixfix) list -> sg -> sg
   121   val add_nonterminals: bstring list -> sg -> sg
   122   val add_tyabbrs: (bstring * string list * string * mixfix) list -> sg -> sg
   123   val add_tyabbrs_i: (bstring * string list * typ * mixfix) list -> sg -> sg
   124   val add_arities: (xstring * string list * string) list -> sg -> sg
   125   val add_arities_i: (string * sort list * sort) list -> sg -> sg
   126   val add_consts: (bstring * string * mixfix) list -> sg -> sg
   127   val add_consts_i: (bstring * typ * mixfix) list -> sg -> sg
   128   val add_syntax: (bstring * string * mixfix) list -> sg -> sg
   129   val add_syntax_i: (bstring * typ * mixfix) list -> sg -> sg
   130   val add_modesyntax: (string * bool) * (bstring * string * mixfix) list -> sg -> sg
   131   val add_modesyntax_i: (string * bool) * (bstring * typ * mixfix) list -> sg -> sg
   132   val add_trfuns:
   133     (string * (ast list -> ast)) list *
   134     (string * (term list -> term)) list *
   135     (string * (term list -> term)) list *
   136     (string * (ast list -> ast)) list -> sg -> sg
   137   val add_trfunsT:
   138     (string * (bool -> typ -> term list -> term)) list -> sg -> sg
   139   val add_tokentrfuns:
   140     (string * string * (string -> string * real)) list -> sg -> sg
   141   val add_trrules: (xstring * string) Syntax.trrule list -> sg -> sg
   142   val add_trrules_i: ast Syntax.trrule list -> sg -> sg
   143   val add_path: string -> sg -> sg
   144   val add_space: string * string list -> sg -> sg
   145   val hide_space: bool -> string * string list -> sg -> sg
   146   val hide_space_i: bool -> string * string list -> sg -> sg
   147   val add_name: string -> sg -> sg
   148   val data_kinds: data -> string list
   149   val merge_refs: sg_ref * sg_ref -> sg_ref
   150   val merge: sg * sg -> sg
   151   val copy: sg -> sg
   152   val prep_ext: sg -> sg
   153   val PureN: string
   154   val CPureN: string
   155   val nontriv_merge: sg * sg -> sg
   156   val pre_pure: sg
   157   val const_of_class: class -> string
   158   val class_of_const: string -> class
   159 end;
   160 
   161 signature PRIVATE_SIGN =
   162 sig
   163   include SIGN
   164   val init_data: Object.kind * (Object.T * (Object.T -> Object.T) * (Object.T -> Object.T) *
   165     (Object.T * Object.T -> Object.T) * (sg -> Object.T -> unit)) -> sg -> sg
   166   val get_data: Object.kind -> (Object.T -> 'a) -> sg -> 'a
   167   val put_data: Object.kind -> ('a -> Object.T) -> 'a -> sg -> sg
   168   val print_data: Object.kind -> sg -> unit
   169 end;
   170 
   171 structure Sign: PRIVATE_SIGN =
   172 struct
   173 
   174 
   175 (** datatype sg **)
   176 
   177 (* types sg, data, sg_ref *)
   178 
   179 datatype sg =
   180   Sg of
   181    {id: string ref,                             (*id*)
   182     stamps: string ref list} *                  (*unique theory indentifier*)
   183    {self: sg_ref,                               (*mutable self reference*)
   184     tsig: Type.type_sig,                        (*order-sorted signature of types*)
   185     const_tab: typ Symtab.table,                (*type schemes of constants*)
   186     syn: Syntax.syntax,                         (*syntax for parsing and printing*)
   187     path: string list option,                   (*current name space entry prefix*)
   188     spaces: (string * NameSpace.T) list,        (*name spaces for consts, types etc.*)
   189     data: data}                                 (*anytype data*)
   190 and data =
   191   Data of
   192     (Object.kind *                              (*kind (for authorization)*)
   193       (Object.T *                               (*value*)
   194         ((Object.T -> Object.T) *               (*copy method*)
   195           (Object.T -> Object.T) *              (*prepare extend method*)
   196           (Object.T * Object.T -> Object.T) *   (*merge and prepare extend method*)
   197           (sg -> Object.T -> unit))))           (*print method*)
   198     Symtab.table
   199 and sg_ref =
   200   SgRef of sg ref option;
   201 
   202 (*make signature*)
   203 fun make_sign (id, self, tsig, const_tab, syn, path, spaces, data, stamps) =
   204   Sg ({id = id, stamps = stamps}, {self = self, tsig = tsig, const_tab = const_tab,
   205     syn = syn, path = path, spaces = spaces, data = data});
   206 
   207 
   208 (* basic operations *)
   209 
   210 fun rep_sg (Sg (_, args)) = args;
   211 
   212 (*show stamps*)
   213 fun stamp_names_of (Sg ({stamps, ...}, _)) = rev (map ! stamps);
   214 fun exists_stamp name (Sg ({stamps, ...}, _)) = exists (equal name o !) stamps;
   215 fun pretty_sg sg = Pretty.str_list "{" "}" (stamp_names_of sg);
   216 val str_of_sg = Pretty.str_of o pretty_sg;
   217 val pprint_sg = Pretty.pprint o pretty_sg;
   218 
   219 val tsig_of = #tsig o rep_sg;
   220 val syn_of = #syn o rep_sg;
   221 
   222 fun const_type (Sg (_, {const_tab, ...})) c = Symtab.lookup (const_tab, c);
   223 
   224 
   225 (* id and self *)
   226 
   227 fun check_stale (sg as Sg ({id, ...},
   228         {self = SgRef (Some (ref (Sg ({id = id', ...}, _)))), ...})) =
   229       if id = id' then sg
   230       else raise TERM ("Stale signature: " ^ str_of_sg sg, [])
   231   | check_stale _ = sys_error "Sign.check_stale";
   232 
   233 fun is_stale sg = (check_stale sg; false) handle TERM _ => true;
   234 
   235 fun self_ref (sg as Sg (_, {self, ...})) = (check_stale sg; self);
   236 
   237 fun deref (SgRef (Some (ref sg))) = sg
   238   | deref (SgRef None) = sys_error "Sign.deref";
   239 
   240 fun name_of (sg as Sg ({id = ref name, ...}, _)) =
   241   if name = "" orelse ord name = ord "#" then
   242     raise TERM ("Nameless signature " ^ str_of_sg sg, [])
   243   else name;
   244 
   245 
   246 (* inclusion and equality *)
   247 
   248 local
   249   (*avoiding polymorphic equality: factor 10 speedup*)
   250   fun mem_stamp (_:string ref, []) = false
   251     | mem_stamp (x, y :: ys) = x = y orelse mem_stamp (x, ys);
   252 
   253   fun subset_stamp ([], ys) = true
   254     | subset_stamp (x :: xs, ys) =
   255         mem_stamp (x, ys) andalso subset_stamp (xs, ys);
   256 
   257   (*fast partial test*)
   258   fun fast_sub ([]: string ref list, _) = true
   259     | fast_sub (_, []) = false
   260     | fast_sub (x :: xs, y :: ys) =
   261         if x = y then fast_sub (xs, ys)
   262         else fast_sub (x :: xs, ys);
   263 in
   264   fun eq_sg (sg1 as Sg ({id = id1, ...}, _), sg2 as Sg ({id = id2, ...}, _)) =
   265     (check_stale sg1; check_stale sg2; id1 = id2);
   266 
   267   fun subsig (sg1 as Sg ({stamps = s1, ...}, _), sg2 as Sg ({stamps = s2, ...}, _)) =
   268     eq_sg (sg1, sg2) orelse subset_stamp (s1, s2);
   269 
   270   fun fast_subsig (sg1 as Sg ({stamps = s1, ...}, _), sg2 as Sg ({stamps = s2, ...}, _)) =
   271     eq_sg (sg1, sg2) orelse fast_sub (s1, s2);
   272 end;
   273 
   274 
   275 fun joinable (sg1, sg2) = subsig (sg1, sg2) orelse subsig (sg2, sg1);
   276 
   277 (*test if same theory names are contained in signatures' stamps,
   278   i.e. if signatures belong to same theory but not necessarily to the
   279   same version of it*)
   280 fun same_sg (sg1 as Sg ({stamps = s1, ...}, _), sg2 as Sg ({stamps = s2, ...}, _)) =
   281   eq_sg (sg1, sg2) orelse eq_set_string (pairself (map (op !)) (s1, s2));
   282 
   283 (*test for drafts*)
   284 fun is_draft (Sg ({stamps = ref name :: _, ...}, _)) = name = "" orelse ord name = ord "#";
   285 
   286 
   287 (* classes and sorts *)
   288 
   289 val classes = Type.classes o tsig_of;
   290 val defaultS = Type.defaultS o tsig_of;
   291 val subsort = Type.subsort o tsig_of;
   292 val norm_sort = Type.norm_sort o tsig_of;
   293 val of_sort = Type.of_sort o tsig_of;
   294 val witness_sorts = Type.witness_sorts o tsig_of;
   295 val univ_witness = Type.univ_witness o tsig_of;
   296 fun typ_instance sg (T, U) = Type.typ_instance (tsig_of sg, T, U);
   297 
   298 
   299 (** signature data **)
   300 
   301 (* errors *)
   302 
   303 fun of_theory sg = "\nof theory " ^ str_of_sg sg;
   304 
   305 fun err_inconsistent kinds =
   306   error ("Attempt to merge different versions of " ^ commas_quote kinds ^ " data");
   307 
   308 fun err_method name kind e =
   309   (writeln ("Error while invoking " ^ quote kind ^ " " ^ name ^ " method"); raise e);
   310 
   311 fun err_dup_init sg kind =
   312   error ("Duplicate initialization of " ^ quote kind ^ " data" ^ of_theory sg);
   313 
   314 fun err_uninit sg kind =
   315   error ("Tried to access uninitialized " ^ quote kind ^ " data" ^
   316          of_theory sg);
   317 
   318 (*Trying to access theory data using get / put operations from a different
   319   instance of the TheoryDataFun result.  Typical cure: re-load all files*)
   320 fun err_access sg kind =
   321   error ("Unauthorized access to " ^ quote kind ^ " data" ^ of_theory sg);
   322 
   323 
   324 (* prepare data *)
   325 
   326 val empty_data = Data Symtab.empty;
   327 
   328 fun merge_data (Data tab1, Data tab2) =
   329   let
   330     val data1 = map snd (Symtab.dest tab1);
   331     val data2 = map snd (Symtab.dest tab2);
   332     val all_data = data1 @ data2;
   333     val kinds = gen_distinct Object.eq_kind (map fst all_data);
   334 
   335    fun entry data kind =
   336      (case gen_assoc Object.eq_kind (data, kind) of
   337        None => []
   338      | Some x => [(kind, x)]);
   339 
   340     fun merge_entries [(kind, (e, mths as (_, ext, _, _)))] =
   341           (kind, (ext e handle exn => err_method "prep_ext" (Object.name_of_kind kind) exn, mths))
   342       | merge_entries [(kind, (e1, mths as (_, _, mrg, _))), (_, (e2, _))] =
   343           (kind, (mrg (e1, e2)
   344             handle exn => err_method "merge" (Object.name_of_kind kind) exn, mths))
   345       | merge_entries _ = sys_error "merge_entries";
   346 
   347     val data = map (fn k => merge_entries (entry data1 k @ entry data2 k)) kinds;
   348     val data_idx = map (fn (k, x) => (Object.name_of_kind k, (k, x))) data;
   349   in
   350     Data (Symtab.make data_idx)
   351       handle Symtab.DUPS dups => err_inconsistent dups
   352   end;
   353 
   354 fun prep_ext_data data = merge_data (data, empty_data);
   355 
   356 fun init_data_sg sg (Data tab) kind e cp ext mrg prt =
   357   let val name = Object.name_of_kind kind in
   358     Data (Symtab.update_new ((name, (kind, (e, (cp, ext, mrg, prt)))), tab))
   359       handle Symtab.DUP _ => err_dup_init sg name
   360   end;
   361 
   362 
   363 (* access data *)
   364 
   365 fun data_kinds (Data tab) = map fst (Symtab.dest tab);
   366 
   367 fun lookup_data sg tab kind =
   368   let val name = Object.name_of_kind kind in
   369     (case Symtab.lookup (tab, name) of
   370       Some (k, x) =>
   371         if Object.eq_kind (kind, k) then x
   372         else err_access sg name
   373     | None => err_uninit sg name)
   374   end;
   375 
   376 fun get_data kind f (sg as Sg (_, {data = Data tab, ...})) =
   377   let val x = fst (lookup_data sg tab kind)
   378   in f x handle Match => Object.kind_error kind end;
   379 
   380 fun print_data kind (sg as Sg (_, {data = Data tab, ...})) =
   381   let val (e, (_, _, _, prt)) = lookup_data sg tab kind
   382   in prt sg e handle exn => err_method ("print" ^ of_theory sg) (Object.name_of_kind kind) exn end;
   383 
   384 fun put_data_sg sg (Data tab) kind f x =
   385   Data (Symtab.update ((Object.name_of_kind kind,
   386     (kind, (f x, snd (lookup_data sg tab kind)))), tab));
   387 
   388 
   389 
   390 (** build signatures **)
   391 
   392 fun ext_stamps stamps (id as ref name) =
   393   let val stmps = (case stamps of ref "#" :: ss => ss | ss => ss) in
   394     if exists (equal name o !) stmps then
   395       error ("Theory already contains a " ^ quote name ^ " component")
   396     else id :: stmps
   397   end;
   398 
   399 fun create_sign self stamps name (syn, tsig, ctab, (path, spaces), data) =
   400   let
   401     val id = ref name;
   402     val sign =
   403       make_sign (id, self, tsig, ctab, syn, path, spaces, data, ext_stamps stamps id);
   404   in
   405     (case self of
   406       SgRef (Some r) => r := sign
   407     | _ => sys_error "Sign.create_sign");
   408     sign
   409   end;
   410 
   411 fun extend_sign keep extfun name decls
   412     (sg as Sg ({id = _, stamps}, {self, tsig, const_tab, syn, path, spaces, data})) =
   413   let
   414     val _ = check_stale sg;
   415     val (self', data') =
   416       if is_draft sg andalso keep then (self, data)
   417       else (SgRef (Some (ref sg)), prep_ext_data data);
   418   in
   419     create_sign self' stamps name
   420       (extfun (syn, tsig, const_tab, (path, spaces), data') decls)
   421   end;
   422 
   423 
   424 
   425 (** name spaces **)
   426 
   427 (* kinds *)
   428 
   429 val classK = "class";
   430 val typeK = "type";
   431 val constK = "const";
   432 
   433 
   434 (* declare and retrieve names *)
   435 
   436 fun space_of spaces kind =
   437   if_none (assoc (spaces, kind)) NameSpace.empty;
   438 
   439 (*input and output of qualified names*)
   440 fun intrn spaces kind = NameSpace.intern (space_of spaces kind);
   441 fun extrn spaces kind = NameSpace.extern (space_of spaces kind);
   442 fun cond_extrn spaces kind = NameSpace.cond_extern (space_of spaces kind);
   443 fun cond_extrn_table spaces kind tab = NameSpace.cond_extern_table (space_of spaces kind) tab;
   444 
   445 (*add / hide names*)
   446 fun change_space f spaces kind x = overwrite (spaces, (kind, f (space_of spaces kind, x)));
   447 fun add_names x = change_space NameSpace.extend x;
   448 fun hide_names b x = change_space (NameSpace.hide b) x;
   449 
   450 (*make full names*)
   451 fun full _ "" = error "Attempt to declare empty name \"\""
   452   | full None name = name
   453   | full (Some path) name =
   454       if NameSpace.is_qualified name then
   455         error ("Attempt to declare qualified name " ^ quote name)
   456       else NameSpace.pack (path @ [name]);
   457 
   458 (*base name*)
   459 val base_name = NameSpace.base;
   460 
   461 
   462 (* intern / extern names *)
   463 
   464 local
   465   (*prepare mapping of names*)
   466   fun mapping f add_xs t =
   467     let
   468       fun f' x = let val y = f x in if x = y then None else Some (x, y) end;
   469       val table = mapfilter f' (add_xs (t, []));
   470       fun lookup x = if_none (assoc (table, x)) x;
   471     in lookup end;
   472 
   473   (*intern / extern typ*)
   474   fun trn_typ trn T =
   475     T |> map_typ
   476       (mapping (trn classK) add_typ_classes T)
   477       (mapping (trn typeK) add_typ_tycons T);
   478 
   479   (*intern / extern term*)
   480   fun trn_term trn t =
   481     t |> map_term
   482       (mapping (trn classK) add_term_classes t)
   483       (mapping (trn typeK) add_term_tycons t)
   484       (mapping (trn constK) add_term_consts t);
   485 
   486   val spaces_of = #spaces o rep_sg;
   487 in
   488   fun intrn_class spaces = intrn spaces classK;
   489   fun extrn_class spaces = extrn spaces classK;
   490 
   491   val intrn_sort = map o intrn_class;
   492   val intrn_typ = trn_typ o intrn;
   493   val intrn_term = trn_term o intrn;
   494 
   495   val extrn_sort = map o extrn_class;
   496   val extrn_typ = trn_typ o extrn;
   497   val extrn_term = trn_term o extrn;
   498 
   499   fun intrn_tycons spaces T =
   500     map_typ I (mapping (intrn spaces typeK) add_typ_tycons T) T;
   501 
   502   val intern = intrn o spaces_of;
   503   val extern = extrn o spaces_of;
   504   val cond_extern = cond_extrn o spaces_of;
   505   fun cond_extern_table sg = cond_extrn_table (spaces_of sg);
   506 
   507   val intern_class = intrn_class o spaces_of;
   508   val intern_sort = intrn_sort o spaces_of;
   509   val intern_typ = intrn_typ o spaces_of;
   510   val intern_term = intrn_term o spaces_of;
   511 
   512   fun intern_tycon sg = intrn (spaces_of sg) typeK;
   513   fun intern_const sg = intrn (spaces_of sg) constK;
   514 
   515   val intern_tycons = intrn_tycons o spaces_of;
   516 
   517   val full_name = full o #path o rep_sg;
   518 
   519   fun full_name_path sg elems =
   520     full (Some (if_none (#path (rep_sg sg)) [] @ NameSpace.unpack elems));
   521 
   522 end;
   523 
   524 
   525 
   526 (** pretty printing of terms, types etc. **)
   527 
   528 fun pretty_term' syn (sg as Sg ({stamps, ...}, {spaces, ...})) t =
   529   Syntax.pretty_term syn
   530     (exists (equal "CPure" o !) stamps)
   531     (if ! NameSpace.long_names then t else extrn_term spaces t);
   532 
   533 fun pretty_term sg = pretty_term' (syn_of sg) sg;
   534 
   535 fun pretty_typ (Sg (_, {syn, spaces, ...})) T =
   536   Syntax.pretty_typ syn
   537     (if ! NameSpace.long_names then T else extrn_typ spaces T);
   538 
   539 fun pretty_sort (Sg (_, {syn, spaces, ...})) S =
   540   Syntax.pretty_sort syn
   541     (if ! NameSpace.long_names then S else extrn_sort spaces S);
   542 
   543 fun pretty_classrel sg (c1, c2) = Pretty.block
   544   [pretty_sort sg [c1], Pretty.str " <", Pretty.brk 1, pretty_sort sg [c2]];
   545 
   546 fun pretty_arity sg (t, Ss, S) =
   547   let
   548     val t' = cond_extern sg typeK t;
   549     val dom =
   550       if null Ss then []
   551       else [Pretty.list "(" ")" (map (pretty_sort sg) Ss), Pretty.brk 1];
   552   in
   553     Pretty.block
   554       ([Pretty.str (t' ^ " ::"), Pretty.brk 1] @ dom @ [pretty_sort sg S])
   555   end;
   556 
   557 fun string_of_term sg t = Pretty.string_of (pretty_term sg t);
   558 fun string_of_typ sg T = Pretty.string_of (pretty_typ sg T);
   559 fun string_of_sort sg S = Pretty.string_of (pretty_sort sg S);
   560 
   561 fun str_of_sort sg S = Pretty.str_of (pretty_sort sg S);
   562 fun str_of_classrel sg c1_c2 = Pretty.str_of (pretty_classrel sg c1_c2);
   563 fun str_of_arity sg ar = Pretty.str_of (pretty_arity sg ar);
   564 
   565 fun pprint_term sg = Pretty.pprint o Pretty.quote o (pretty_term sg);
   566 fun pprint_typ sg = Pretty.pprint o Pretty.quote o (pretty_typ sg);
   567 
   568 
   569 
   570 (** read sorts **)  (*exception ERROR*)
   571 
   572 fun err_in_sort s =
   573   error ("The error(s) above occurred in sort " ^ quote s);
   574 
   575 fun rd_sort syn tsig spaces str =
   576   let val S = intrn_sort spaces (Syntax.read_sort syn str handle ERROR => err_in_sort str)
   577   in Type.cert_sort tsig S handle TYPE (msg, _, _) => (error_msg msg; err_in_sort str) end;
   578 
   579 (*read and certify sort wrt a signature*)
   580 fun read_sort (sg as Sg (_, {tsig, syn, spaces, ...})) str =
   581   (check_stale sg; rd_sort syn tsig spaces str);
   582 
   583 fun cert_sort _ tsig _ = Type.cert_sort tsig;
   584 
   585 
   586 
   587 (** read types **)  (*exception ERROR*)
   588 
   589 fun err_in_type s =
   590   error ("The error(s) above occurred in type " ^ quote s);
   591 
   592 fun rd_raw_typ syn tsig spaces def_sort str =
   593   intrn_tycons spaces
   594     (Syntax.read_typ syn (Type.get_sort tsig def_sort (intrn_sort spaces)) (intrn_sort spaces) str
   595       handle ERROR => err_in_type str);
   596 
   597 fun read_raw_typ' syn (sg as Sg (_, {tsig, spaces, ...}), def_sort) str =
   598   (check_stale sg; rd_raw_typ syn tsig spaces def_sort str);
   599 
   600 fun read_raw_typ (sg, def_sort) = read_raw_typ' (syn_of sg) (sg, def_sort);
   601 
   602 (*read and certify typ wrt a signature*)
   603 local
   604   fun read_typ_aux rd cert (sg, def_sort) str =
   605     (cert (tsig_of sg) (rd (sg, def_sort) str)
   606       handle TYPE (msg, _, _) => (error_msg msg; err_in_type str));
   607 in
   608   val read_typ              = read_typ_aux read_raw_typ Type.cert_typ;
   609   val read_typ_no_norm      = read_typ_aux read_raw_typ Type.cert_typ_no_norm;
   610   fun read_typ' syn         = read_typ_aux (read_raw_typ' syn) Type.cert_typ;
   611   fun read_typ_no_norm' syn = read_typ_aux (read_raw_typ' syn) Type.cert_typ_no_norm;
   612 end;
   613 
   614 
   615 
   616 (** certify classes, sorts, types and terms **)   (*exception TYPE*)
   617 
   618 val certify_class = Type.cert_class o tsig_of;
   619 val certify_sort = Type.cert_sort o tsig_of;
   620 val certify_typ = Type.cert_typ o tsig_of;
   621 val certify_typ_no_norm = Type.cert_typ_no_norm o tsig_of;
   622 
   623 fun certify_tycon sg c =
   624   if is_some (Symtab.lookup (#tycons (Type.rep_tsig (tsig_of sg)), c)) then c
   625   else raise TYPE ("Undeclared type constructor " ^ quote c, [], []);
   626 
   627 fun certify_tyabbr sg c =
   628   if is_some (Symtab.lookup (#abbrs (Type.rep_tsig (tsig_of sg)), c)) then c
   629   else raise TYPE ("Unknown type abbreviation " ^ quote c, [], []);
   630 
   631 fun certify_tyname sg c =
   632   certify_tycon sg c handle TYPE _ => certify_tyabbr sg c handle TYPE _ =>
   633     raise TYPE ("Unknown type name " ^ quote c, [], []);
   634 
   635 fun certify_const sg c =
   636   if is_some (const_type sg c) then c else raise TYPE ("Undeclared constant " ^ quote c, [], []);
   637 
   638 
   639 (* certify_term *)
   640 
   641 (*check for duplicate occurrences of TFree/TVar with distinct sorts*)
   642 fun nodup_tvars (env, Type (_, Ts)) = nodup_tvars_list (env, Ts)
   643   | nodup_tvars (env as (tfrees, tvars), T as TFree (v as (a, S))) =
   644       (case assoc_string (tfrees, a) of
   645         Some S' =>
   646           if S = S' then env
   647           else raise TYPE ("Type variable " ^ quote a ^
   648             " has two distinct sorts", [TFree (a, S'), T], [])
   649       | None => (v :: tfrees, tvars))
   650   | nodup_tvars (env as (tfrees, tvars), T as TVar (v as (a, S))) =
   651       (case assoc_string_int (tvars, a) of
   652         Some S' =>
   653           if S = S' then env
   654           else raise TYPE ("Type variable " ^ quote (Syntax.string_of_vname a) ^
   655             " has two distinct sorts", [TVar (a, S'), T], [])
   656       | None => (tfrees, v :: tvars))
   657 (*equivalent to foldl nodup_tvars_list, but 3X faster under Poly/ML*)
   658 and nodup_tvars_list (env, []) = env
   659   | nodup_tvars_list (env, T :: Ts) = nodup_tvars_list (nodup_tvars (env, T), Ts);
   660 
   661 (*check for duplicate occurrences of Free/Var with distinct types*)
   662 fun nodup_vars tm =
   663   let
   664     fun nodups (envs as (env as (frees, vars), envT)) tm =
   665       (case tm of
   666         Const (c, T) => (env, nodup_tvars (envT, T))
   667       | Free (v as (a, T)) =>
   668           (case assoc_string (frees, a) of
   669             Some T' =>
   670               if T = T' then (env, nodup_tvars (envT, T))
   671               else raise TYPE ("Variable " ^ quote a ^
   672                 " has two distinct types", [T', T], [])
   673           | None => ((v :: frees, vars), nodup_tvars (envT, T)))
   674       | Var (v as (ixn, T)) =>
   675           (case assoc_string_int (vars, ixn) of
   676             Some T' =>
   677               if T = T' then (env, nodup_tvars (envT, T))
   678               else raise TYPE ("Variable " ^ quote (Syntax.string_of_vname ixn) ^
   679                 " has two distinct types", [T', T], [])
   680           | None => ((frees, v :: vars), nodup_tvars (envT, T)))
   681       | Bound _ => envs
   682       | Abs (_, T, t) => nodups (env, nodup_tvars (envT, T)) t
   683       | s $ t => nodups (nodups envs s) t)
   684   in nodups (([], []), ([], [])) tm; tm end;
   685 
   686 (*compute and check type of the term*)
   687 fun type_check sg tm =
   688   let
   689     val prt = setmp Syntax.show_brackets true (pretty_term sg);
   690     val prT = pretty_typ sg;
   691 
   692     fun err_appl why bs t T u U =
   693       let
   694         val xs = map Free bs;           (*we do not rename here*)
   695         val t' = subst_bounds (xs, t);
   696         val u' = subst_bounds (xs, u);
   697         val text = cat_lines (TypeInfer.appl_error prt prT why t' T u' U);
   698       in raise TYPE (text, [T, U], [t', u']) end;
   699 
   700     fun typ_of (_, Const (_, T)) = T
   701       | typ_of (_, Free  (_, T)) = T
   702       | typ_of (_, Var (_, T)) = T
   703       | typ_of (bs, Bound i) = snd (nth_elem (i, bs) handle LIST _ =>
   704           raise TYPE ("Loose bound variable: B." ^ string_of_int i, [], [Bound i]))
   705       | typ_of (bs, Abs (x, T, body)) = T --> typ_of ((x, T) :: bs, body)
   706       | typ_of (bs, t $ u) =
   707           let val T = typ_of (bs, t) and U = typ_of (bs, u) in
   708             (case T of
   709               Type ("fun", [T1, T2]) =>
   710                 if T1 = U then T2 else err_appl "Incompatible operand type." bs t T u U
   711             | _ => err_appl "Operator not of function type." bs t T u U)
   712           end;
   713 
   714   in typ_of ([], tm) end;
   715 
   716 
   717 fun certify_term sg tm =
   718   let
   719     val _ = check_stale sg;
   720     val tsig = tsig_of sg;
   721 
   722     fun show_const a T = quote a ^ " :: " ^ quote (string_of_typ sg T);
   723 
   724     fun atom_err (errs, Const (a, T)) =
   725         (case const_type sg a of
   726           None => ("Undeclared constant " ^ show_const a T) :: errs
   727         | Some U =>
   728             if typ_instance sg (T, U) then errs
   729             else ("Illegal type for constant " ^ show_const a T) :: errs)
   730       | atom_err (errs, Var ((x, i), _)) =
   731           if i < 0 then ("Negative index for Var " ^ quote x) :: errs else errs
   732       | atom_err (errs, _) = errs;
   733 
   734     val norm_tm =
   735       (case it_term_types (Type.typ_errors tsig) (tm, []) of
   736         [] => Type.norm_term tsig tm
   737       | errs => raise TYPE (cat_lines errs, [], [tm]));
   738     val _ = nodup_vars norm_tm;
   739   in
   740     (case foldl_aterms atom_err ([], norm_tm) of
   741       [] => (norm_tm, type_check sg norm_tm, maxidx_of_term norm_tm)
   742     | errs => raise TYPE (cat_lines errs, [], [norm_tm]))
   743   end;
   744 
   745 
   746 (** infer_types **)         (*exception ERROR*)
   747 
   748 (*
   749   def_type: partial map from indexnames to types (constrains Frees, Vars)
   750   def_sort: partial map from indexnames to sorts (constrains TFrees, TVars)
   751   used: list of already used type variables
   752   freeze: if true then generated parameters are turned into TFrees, else TVars
   753 
   754   termss: lists of alternative parses (only one combination should be type-correct)
   755   typs: expected types
   756 *)
   757 
   758 fun infer_types_simult sg def_type def_sort used freeze args =
   759   let
   760     val tsig = tsig_of sg;
   761     val prt = setmp Syntax.show_brackets true (pretty_term sg);
   762     val prT = pretty_typ sg;
   763 
   764     val termss = foldr multiply (map fst args, [[]]);
   765     val typs =
   766       map (fn (_, T) => certify_typ sg T handle TYPE (msg, _, _) => error msg) args;
   767 
   768     fun infer ts = OK
   769       (Type.infer_types prt prT tsig (const_type sg) def_type def_sort
   770         (intern_const sg) (intern_tycons sg) (intern_sort sg) used freeze typs ts)
   771       handle TYPE (msg, _, _) => Error msg;
   772 
   773     val err_results = map infer termss;
   774     val errs = mapfilter get_error err_results;
   775     val results = mapfilter get_ok err_results;
   776 
   777     val ambiguity = length termss;      (* FIXME !? *)
   778     (* FIXME to syntax.ML!? *)
   779     fun ambig_msg () =
   780       if ambiguity > 1 andalso ambiguity <= ! Syntax.ambiguity_level
   781       then
   782         error_msg "Got more than one parse tree.\n\
   783           \Retry with smaller Syntax.ambiguity_level for more information."
   784       else ();
   785   in
   786     if null results then (ambig_msg (); error (cat_lines errs))
   787     else if length results = 1 then
   788       (if ambiguity > ! Syntax.ambiguity_level then
   789         warning "Fortunately, only one parse tree is type correct.\n\
   790           \You may still want to disambiguate your grammar or your input."
   791       else (); hd results)
   792     else (ambig_msg (); error ("More than one term is type correct:\n" ^
   793       (cat_lines (map (Pretty.string_of o prt) (flat (map fst results))))))
   794   end;
   795 
   796 
   797 fun infer_types sg def_type def_sort used freeze tsT =
   798   apfst hd (infer_types_simult sg def_type def_sort used freeze [tsT]);
   799 
   800 
   801 (** read_def_terms **)
   802 
   803 (*read terms, infer types*)
   804 fun read_def_terms' syn (sign, types, sorts) used freeze sTs =
   805   let
   806     fun read (s, T) =
   807       let val T' = certify_typ sign T handle TYPE (msg, _, _) => error msg
   808       in (Syntax.read syn T' s, T') end;
   809     val tsTs = map read sTs;
   810   in infer_types_simult sign types sorts used freeze tsTs end;
   811 
   812 fun read_def_terms (sign, types, sorts) = read_def_terms' (syn_of sign) (sign, types, sorts);
   813 
   814 fun simple_read_term sign T s =
   815   (read_def_terms (sign, K None, K None) [] true [(s, T)]
   816     handle ERROR => error ("The error(s) above occurred for " ^ s)) |> #1 |> hd;
   817 
   818 
   819 
   820 (** extend signature **)    (*exception ERROR*)
   821 
   822 (** signature extension functions **)  (*exception ERROR*)
   823 
   824 fun decls_of path name_of mfixs =
   825   map (fn (x, y, mx) => (full path (name_of x mx), y)) mfixs;
   826 
   827 fun no_read _ _ _ decl = decl;
   828 
   829 
   830 (* add default sort *)
   831 
   832 fun ext_defS prep_sort (syn, tsig, ctab, (path, spaces), data) S =
   833   (syn, Type.ext_tsig_defsort tsig (prep_sort syn tsig spaces S), ctab, (path, spaces), data);
   834 
   835 fun ext_defsort arg   = ext_defS rd_sort arg;
   836 fun ext_defsort_i arg = ext_defS cert_sort arg;
   837 
   838 
   839 (* add type constructors *)
   840 
   841 fun ext_types (syn, tsig, ctab, (path, spaces), data) types =
   842   let val decls = decls_of path Syntax.type_name types in
   843     (Syntax.extend_type_gram types syn,
   844       Type.ext_tsig_types tsig decls, ctab,
   845       (path, add_names spaces typeK (map fst decls)), data)
   846   end;
   847 
   848 fun ext_nonterminals sg nonterms =
   849   ext_types sg (map (fn n => (n, 0, Syntax.NoSyn)) nonterms);
   850 
   851 
   852 (* add type abbreviations *)
   853 
   854 fun read_abbr syn tsig spaces (t, vs, rhs_src) =
   855   (t, vs, rd_raw_typ syn tsig spaces (K None) rhs_src)
   856     handle ERROR => error ("in type abbreviation " ^ t);
   857 
   858 fun ext_abbrs rd_abbr (syn, tsig, ctab, (path, spaces), data) abbrs =
   859   let
   860     fun mfix_of (t, vs, _, mx) = (t, length vs, mx);
   861     val syn' = Syntax.extend_type_gram (map mfix_of abbrs) syn;
   862 
   863     val abbrs' =
   864       map (fn (t, vs, rhs, mx) =>
   865         (full path (Syntax.type_name t mx), vs, rhs)) abbrs;
   866     val spaces' = add_names spaces typeK (map #1 abbrs');
   867     val decls = map (rd_abbr syn' tsig spaces') abbrs';
   868   in
   869     (syn', Type.ext_tsig_abbrs tsig decls, ctab, (path, spaces'), data)
   870   end;
   871 
   872 fun ext_tyabbrs abbrs = ext_abbrs read_abbr abbrs;
   873 fun ext_tyabbrs_i abbrs = ext_abbrs no_read abbrs;
   874 
   875 
   876 (* add type arities *)
   877 
   878 fun ext_ars int prep_sort (syn, tsig, ctab, (path, spaces), data) arities =
   879   let
   880     val prepS = prep_sort syn tsig spaces;
   881     fun prep_arity (c, Ss, S) =
   882       (if int then intrn spaces typeK c else c, map prepS Ss, prepS S);
   883     val tsig' = Type.ext_tsig_arities tsig (map prep_arity arities);
   884     val log_types = Type.logical_types tsig';
   885   in
   886     (Syntax.extend_log_types log_types syn, tsig', ctab, (path, spaces), data)
   887   end;
   888 
   889 fun ext_arities arg   = ext_ars true rd_sort arg;
   890 fun ext_arities_i arg = ext_ars false cert_sort arg;
   891 
   892 
   893 (* add term constants and syntax *)
   894 
   895 fun const_name path c mx =
   896   full path (Syntax.const_name c mx);
   897 
   898 fun err_in_const c =
   899   error ("in declaration of constant " ^ quote c);
   900 
   901 fun err_dup_consts cs =
   902   error ("Duplicate declaration of constant(s) " ^ commas_quote cs);
   903 
   904 
   905 fun read_const syn tsig (path, spaces) (c, ty_src, mx) =
   906   (c, rd_raw_typ syn tsig spaces (K None) ty_src, mx)
   907     handle ERROR => err_in_const (const_name path c mx);
   908 
   909 fun ext_cnsts rd_const syn_only prmode (syn, tsig, ctab, (path, spaces), data) raw_consts =
   910   let
   911     fun prep_const (c, ty, mx) =
   912       (c, compress_type (Type.varifyT (Type.cert_typ tsig (Type.no_tvars ty))), mx)
   913         handle TYPE (msg, _, _) =>
   914           (error_msg msg; err_in_const (const_name path c mx));
   915 
   916     val consts = map (prep_const o rd_const syn tsig (path, spaces)) raw_consts;
   917     val decls =
   918       if syn_only then []
   919       else decls_of path Syntax.const_name consts;
   920   in
   921     (Syntax.extend_const_gram prmode consts syn, tsig,
   922       Symtab.extend (ctab, decls)
   923         handle Symtab.DUPS cs => err_dup_consts cs,
   924       (path, add_names spaces constK (map fst decls)), data)
   925   end;
   926 
   927 fun ext_consts_i sg = ext_cnsts no_read false ("", true) sg;
   928 fun ext_consts sg = ext_cnsts read_const false ("", true) sg;
   929 fun ext_syntax_i sg = ext_cnsts no_read true ("", true) sg;
   930 fun ext_syntax sg = ext_cnsts read_const true ("", true) sg;
   931 fun ext_modesyntax_i sg (prmode, consts) = ext_cnsts no_read true prmode sg consts;
   932 fun ext_modesyntax sg (prmode, consts) = ext_cnsts read_const true prmode sg consts;
   933 
   934 
   935 (* add type classes *)
   936 
   937 fun const_of_class c = c ^ "_class";
   938 
   939 fun class_of_const c_class =
   940   let
   941     val c = implode (take (size c_class - size "_class", explode c_class));
   942   in
   943     if const_of_class c = c_class then c
   944     else raise TERM ("class_of_const: bad name " ^ quote c_class, [])
   945   end;
   946 
   947 
   948 fun ext_classes int (syn, tsig, ctab, (path, spaces), data) classes =
   949   let
   950     val names = map fst classes;
   951     val consts =
   952       map (fn c => (const_of_class c, a_itselfT --> propT, NoSyn)) names;
   953 
   954     val full_names = map (full path) names;
   955     val spaces' = add_names spaces classK full_names;
   956     val intrn = if int then map (intrn_class spaces') else I;
   957     val classes' =
   958       ListPair.map (fn (c, (_, cs)) => (c, intrn cs)) (full_names, classes);
   959   in
   960     ext_consts_i
   961       (Syntax.extend_consts names syn,
   962         Type.ext_tsig_classes tsig classes', ctab, (path, spaces'), data)
   963     consts
   964   end;
   965 
   966 
   967 (* add to classrel *)
   968 
   969 fun ext_classrel int (syn, tsig, ctab, (path, spaces), data) pairs =
   970   let val intrn = if int then map (pairself (intrn_class spaces)) else I in
   971     (syn, Type.ext_tsig_classrel tsig (intrn pairs), ctab, (path, spaces), data)
   972   end;
   973 
   974 
   975 (* add translation rules *)
   976 
   977 fun ext_trrules (syn, tsig, ctab, (path, spaces), data) args =
   978   (syn |> Syntax.extend_trrules
   979     (map (Syntax.map_trrule (fn (root, str) => (intrn spaces typeK root, str))) args),
   980       tsig, ctab, (path, spaces), data);
   981 
   982 
   983 (* add to syntax *)
   984 
   985 fun ext_syn extfun (syn, tsig, ctab, names, data) args =
   986   (extfun args syn, tsig, ctab, names, data);
   987 
   988 
   989 (* add to path *)
   990 
   991 fun ext_path (syn, tsig, ctab, (path, spaces), data) elems =
   992   let
   993     val path' =
   994       if elems = "//" then None
   995       else if elems = "/" then Some []
   996       else if elems = ".." andalso is_some path andalso path <> Some [] then
   997         Some (fst (split_last (the path)))
   998       else Some (if_none path [] @ NameSpace.unpack elems);
   999   in
  1000     (syn, tsig, ctab, (path', spaces), data)
  1001   end;
  1002 
  1003 
  1004 (* change name space *)
  1005 
  1006 fun ext_add_space (syn, tsig, ctab, (path, spaces), data) (kind, names) =
  1007   (syn, tsig, ctab, (path, add_names spaces kind names), data);
  1008 
  1009 fun ext_hide_space (syn, tsig, ctab, (path, spaces), data) (b, (kind, xnames)) =
  1010   (syn, tsig, ctab, (path, hide_names b spaces kind (map (intrn spaces kind) xnames)), data);
  1011 
  1012 fun ext_hide_space_i (syn, tsig, ctab, (path, spaces), data) (b, (kind, names)) =
  1013   (syn, tsig, ctab, (path, hide_names b spaces kind names), data);
  1014 
  1015 
  1016 (* signature data *)
  1017 
  1018 fun ext_init_data sg (syn, tsig, ctab, names, data) (kind, (e, cp, ext, mrg, prt)) =
  1019   (syn, tsig, ctab, names, init_data_sg sg data kind e cp ext mrg prt);
  1020 
  1021 fun ext_put_data sg (syn, tsig, ctab, names, data) (kind, f, x) =
  1022   (syn, tsig, ctab, names, put_data_sg sg data kind f x);
  1023 
  1024 
  1025 fun copy_data (k, (e, mths as (cp, _, _, _))) =
  1026   (k, (cp e handle exn => err_method "copy" (Object.name_of_kind k) exn, mths));
  1027 
  1028 fun copy (sg as Sg ({id = _, stamps}, {self, tsig, const_tab, syn, path, spaces, data})) =
  1029   let
  1030     val _ = check_stale sg;
  1031     val self' = SgRef (Some (ref sg));
  1032     val Data tab = data;
  1033     val data' = Data (Symtab.map copy_data tab);
  1034   in create_sign self' stamps "#" (syn, tsig, const_tab, (path, spaces), data') end;
  1035 
  1036 
  1037 (* the external interfaces *)
  1038 
  1039 val add_classes       = extend_sign true (ext_classes true) "#";
  1040 val add_classes_i     = extend_sign true (ext_classes false) "#";
  1041 val add_classrel      = extend_sign true (ext_classrel true) "#";
  1042 val add_classrel_i    = extend_sign true (ext_classrel false) "#";
  1043 val add_defsort       = extend_sign true ext_defsort "#";
  1044 val add_defsort_i     = extend_sign true ext_defsort_i "#";
  1045 val add_types         = extend_sign true ext_types "#";
  1046 val add_nonterminals  = extend_sign true ext_nonterminals "#";
  1047 val add_tyabbrs       = extend_sign true ext_tyabbrs "#";
  1048 val add_tyabbrs_i     = extend_sign true ext_tyabbrs_i "#";
  1049 val add_arities       = extend_sign true ext_arities "#";
  1050 val add_arities_i     = extend_sign true ext_arities_i "#";
  1051 val add_consts        = extend_sign true ext_consts "#";
  1052 val add_consts_i      = extend_sign true ext_consts_i "#";
  1053 val add_syntax        = extend_sign true ext_syntax "#";
  1054 val add_syntax_i      = extend_sign true ext_syntax_i "#";
  1055 val add_modesyntax    = extend_sign true ext_modesyntax "#";
  1056 val add_modesyntax_i  = extend_sign true ext_modesyntax_i "#";
  1057 val add_trfuns        = extend_sign true (ext_syn Syntax.extend_trfuns) "#";
  1058 val add_trfunsT       = extend_sign true (ext_syn Syntax.extend_trfunsT) "#";
  1059 val add_tokentrfuns   = extend_sign true (ext_syn Syntax.extend_tokentrfuns) "#";
  1060 val add_trrules       = extend_sign true ext_trrules "#";
  1061 val add_trrules_i     = extend_sign true (ext_syn Syntax.extend_trrules_i) "#";
  1062 val add_path          = extend_sign true ext_path "#";
  1063 val add_space         = extend_sign true ext_add_space "#";
  1064 val hide_space        = curry (extend_sign true ext_hide_space "#");
  1065 val hide_space_i      = curry (extend_sign true ext_hide_space_i "#");
  1066 fun init_data arg sg  = extend_sign true (ext_init_data sg) "#" arg sg;
  1067 fun put_data k f x sg = extend_sign true (ext_put_data sg) "#" (k, f, x) sg;
  1068 fun add_name name sg  = extend_sign true K name () sg;
  1069 fun prep_ext sg       = extend_sign false K "#" () sg;
  1070 
  1071 
  1072 
  1073 (** merge signatures **)        (*exception TERM*)
  1074 
  1075 (* merge_stamps *)
  1076 
  1077 fun merge_stamps stamps1 stamps2 =
  1078   let val stamps = merge_lists' stamps1 stamps2 in
  1079     (case duplicates (map ! stamps) of
  1080       [] => stamps
  1081     | dups => raise TERM ("Attempt to merge different versions of theories "
  1082         ^ commas_quote dups, []))
  1083   end;
  1084 
  1085 
  1086 (* implicit merge -- trivial only *)
  1087 
  1088 fun merge_refs (sgr1 as SgRef (Some (ref (sg1 as Sg ({stamps = s1, ...}, _)))),
  1089         sgr2 as SgRef (Some (ref (sg2 as Sg ({stamps = s2, ...}, _))))) =
  1090       if fast_subsig (sg2, sg1) then sgr1
  1091       else if fast_subsig (sg1, sg2) then sgr2
  1092       else if subsig (sg2, sg1) then sgr1
  1093       else if subsig (sg1, sg2) then sgr2
  1094       else (merge_stamps s1 s2; (*check for different versions*)
  1095         raise TERM ("Attempt to do non-trivial merge of signatures", []))
  1096   | merge_refs _ = sys_error "Sign.merge_refs";
  1097 
  1098 val merge = deref o merge_refs o pairself self_ref;
  1099 
  1100 
  1101 (* proper merge *)              (*exception TERM/ERROR*)
  1102 
  1103 val PureN = "Pure";
  1104 val CPureN = "CPure";
  1105 
  1106 fun nontriv_merge (sg1, sg2) =
  1107   if subsig (sg2, sg1) then sg1
  1108   else if subsig (sg1, sg2) then sg2
  1109   else if is_draft sg1 orelse is_draft sg2 then
  1110     raise TERM ("Attempt to merge draft signatures", [])
  1111   else if exists_stamp PureN sg1 andalso exists_stamp CPureN sg2 orelse
  1112       exists_stamp CPureN sg1 andalso exists_stamp PureN sg2 then
  1113     raise TERM ("Cannot merge Pure and CPure signatures", [])
  1114   else
  1115     (*neither is union already; must form union*)
  1116     let
  1117       val Sg ({id = _, stamps = stamps1}, {self = _, tsig = tsig1, const_tab = const_tab1,
  1118         syn = syn1, path = _, spaces = spaces1, data = data1}) = sg1;
  1119       val Sg ({id = _, stamps = stamps2}, {self = _, tsig = tsig2, const_tab = const_tab2,
  1120         syn = syn2, path = _, spaces = spaces2, data = data2}) = sg2;
  1121 
  1122       val id = ref "";
  1123       val self_ref = ref sg1;                   (*dummy value*)
  1124       val self = SgRef (Some self_ref);
  1125 
  1126       val stamps = merge_stamps stamps1 stamps2;
  1127       val tsig = Type.merge_tsigs (tsig1, tsig2);
  1128       val const_tab = Symtab.merge (op =) (const_tab1, const_tab2)
  1129         handle Symtab.DUPS cs =>
  1130           raise TERM ("Incompatible types for constant(s) " ^ commas_quote cs, []);
  1131       val syn = Syntax.merge_syntaxes syn1 syn2;
  1132 
  1133       val path = Some [];
  1134       val kinds = distinct (map fst (spaces1 @ spaces2));
  1135       val spaces =
  1136         kinds ~~
  1137           ListPair.map NameSpace.merge
  1138             (map (space_of spaces1) kinds, map (space_of spaces2) kinds);
  1139 
  1140       val data = merge_data (data1, data2);
  1141 
  1142       val sign = make_sign (id, self, tsig, const_tab, syn, path, spaces, data, stamps);
  1143     in
  1144       self_ref := sign; sign
  1145     end;
  1146 
  1147 
  1148 
  1149 (** partial Pure signature **)
  1150 
  1151 val dummy_sg = make_sign (ref "", SgRef None, Type.tsig0,
  1152   Symtab.empty, Syntax.pure_syn, Some [], [], empty_data, []);
  1153 
  1154 val pre_pure =
  1155   create_sign (SgRef (Some (ref dummy_sg))) [] "#"
  1156     (Syntax.pure_syn, Type.tsig0, Symtab.empty, (Some [], []), empty_data);
  1157 
  1158 
  1159 end;