src/Pure/sign.ML
author wenzelm
Tue Nov 27 16:48:38 2007 +0100 (2007-11-27)
changeset 25476 03da46cfab9e
parent 25458 ba8f5e4fa336
child 26268 80aaf4d034be
permissions -rw-r--r--
standard_parse_term: check ambiguous results without changing the result yet;
     1 (*  Title:      Pure/sign.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson and Markus Wenzel
     4 
     5 Logical signature content: naming conventions, concrete syntax, type
     6 signature, polymorphic constants.
     7 *)
     8 
     9 signature SIGN_THEORY =
    10 sig
    11   val add_defsort: string -> theory -> theory
    12   val add_defsort_i: sort -> theory -> theory
    13   val add_types: (bstring * int * mixfix) list -> theory -> theory
    14   val add_nonterminals: bstring list -> theory -> theory
    15   val add_tyabbrs: (bstring * string list * string * mixfix) list -> theory -> theory
    16   val add_tyabbrs_i: (bstring * string list * typ * mixfix) list -> theory -> theory
    17   val add_syntax: (bstring * string * mixfix) list -> theory -> theory
    18   val add_syntax_i: (bstring * typ * mixfix) list -> theory -> theory
    19   val add_modesyntax: Syntax.mode -> (bstring * string * mixfix) list -> theory -> theory
    20   val add_modesyntax_i: Syntax.mode -> (bstring * typ * mixfix) list -> theory -> theory
    21   val del_modesyntax: Syntax.mode -> (bstring * string * mixfix) list -> theory -> theory
    22   val del_modesyntax_i: Syntax.mode -> (bstring * typ * mixfix) list -> theory -> theory
    23   val add_consts: (bstring * string * mixfix) list -> theory -> theory
    24   val add_consts_i: (bstring * typ * mixfix) list -> theory -> theory
    25   val add_trfuns:
    26     (string * (ast list -> ast)) list *
    27     (string * (term list -> term)) list *
    28     (string * (term list -> term)) list *
    29     (string * (ast list -> ast)) list -> theory -> theory
    30   val add_trfunsT:
    31     (string * (bool -> typ -> term list -> term)) list -> theory -> theory
    32   val add_advanced_trfuns:
    33     (string * (Proof.context -> ast list -> ast)) list *
    34     (string * (Proof.context -> term list -> term)) list *
    35     (string * (Proof.context -> term list -> term)) list *
    36     (string * (Proof.context -> ast list -> ast)) list -> theory -> theory
    37   val add_advanced_trfunsT:
    38     (string * (Proof.context -> bool -> typ -> term list -> term)) list -> theory -> theory
    39   val add_tokentrfuns:
    40     (string * string * (string -> output * int)) list -> theory -> theory
    41   val add_mode_tokentrfuns: string -> (string * (string -> output * int)) list
    42     -> theory -> theory
    43   val add_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
    44   val del_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
    45   val add_trrules_i: ast Syntax.trrule list -> theory -> theory
    46   val del_trrules_i: ast Syntax.trrule list -> theory -> theory
    47   val add_path: string -> theory -> theory
    48   val parent_path: theory -> theory
    49   val root_path: theory -> theory
    50   val absolute_path: theory -> theory
    51   val local_path: theory -> theory
    52   val no_base_names: theory -> theory
    53   val qualified_names: theory -> theory
    54   val sticky_prefix: string -> theory -> theory
    55   val restore_naming: theory -> theory -> theory
    56 end
    57 
    58 signature SIGN =
    59 sig
    60   val rep_sg: theory ->
    61    {naming: NameSpace.naming,
    62     syn: Syntax.syntax,
    63     tsig: Type.tsig,
    64     consts: Consts.T}
    65   val naming_of: theory -> NameSpace.naming
    66   val base_name: string -> bstring
    67   val full_name: theory -> bstring -> string
    68   val full_name_path: theory -> string -> bstring -> string
    69   val declare_name: theory -> string -> NameSpace.T -> NameSpace.T
    70   val syn_of: theory -> Syntax.syntax
    71   val tsig_of: theory -> Type.tsig
    72   val classes_of: theory -> Sorts.algebra
    73   val all_classes: theory -> class list
    74   val super_classes: theory -> class -> class list
    75   val minimize_sort: theory -> sort -> sort
    76   val complete_sort: theory -> sort -> sort
    77   val defaultS: theory -> sort
    78   val subsort: theory -> sort * sort -> bool
    79   val of_sort: theory -> typ * sort -> bool
    80   val witness_sorts: theory -> sort list -> sort list -> (typ * sort) list
    81   val universal_witness: theory -> (typ * sort) option
    82   val all_sorts_nonempty: theory -> bool
    83   val is_logtype: theory -> string -> bool
    84   val typ_instance: theory -> typ * typ -> bool
    85   val typ_equiv: theory -> typ * typ -> bool
    86   val typ_match: theory -> typ * typ -> Type.tyenv -> Type.tyenv
    87   val typ_unify: theory -> typ * typ -> Type.tyenv * int -> Type.tyenv * int
    88   val consts_of: theory -> Consts.T
    89   val the_const_constraint: theory -> string -> typ
    90   val const_type: theory -> string -> typ option
    91   val the_const_type: theory -> string -> typ
    92   val declared_tyname: theory -> string -> bool
    93   val declared_const: theory -> string -> bool
    94   val const_monomorphic: theory -> string -> bool
    95   val const_syntax_name: theory -> string -> string
    96   val const_typargs: theory -> string * typ -> typ list
    97   val const_instance: theory -> string * typ list -> typ
    98   val class_space: theory -> NameSpace.T
    99   val type_space: theory -> NameSpace.T
   100   val const_space: theory -> NameSpace.T
   101   val intern_class: theory -> xstring -> string
   102   val extern_class: theory -> string -> xstring
   103   val intern_type: theory -> xstring -> string
   104   val extern_type: theory -> string -> xstring
   105   val intern_const: theory -> xstring -> string
   106   val extern_const: theory -> string -> xstring
   107   val intern_sort: theory -> sort -> sort
   108   val extern_sort: theory -> sort -> sort
   109   val intern_typ: theory -> typ -> typ
   110   val extern_typ: theory -> typ -> typ
   111   val intern_term: theory -> term -> term
   112   val extern_term: (string -> xstring) -> theory -> term -> term
   113   val intern_tycons: theory -> typ -> typ
   114   val pretty_term: theory -> term -> Pretty.T
   115   val pretty_typ: theory -> typ -> Pretty.T
   116   val pretty_sort: theory -> sort -> Pretty.T
   117   val string_of_term: theory -> term -> string
   118   val string_of_typ: theory -> typ -> string
   119   val string_of_sort: theory -> sort -> string
   120   val pp: theory -> Pretty.pp
   121   val arity_number: theory -> string -> int
   122   val arity_sorts: theory -> string -> sort -> sort list
   123   val certify_class: theory -> class -> class
   124   val certify_sort: theory -> sort -> sort
   125   val certify_typ: theory -> typ -> typ
   126   val certify_typ_mode: Type.mode -> theory -> typ -> typ
   127   val certify': bool -> Pretty.pp -> bool -> Consts.T -> theory -> term -> term * typ * int
   128   val certify_term: theory -> term -> term * typ * int
   129   val certify_prop: theory -> term -> term * typ * int
   130   val cert_term: theory -> term -> term
   131   val cert_prop: theory -> term -> term
   132   val no_frees: Pretty.pp -> term -> term
   133   val no_vars: Pretty.pp -> term -> term
   134   val cert_def: Proof.context -> term -> (string * typ) * term
   135   val read_class: theory -> xstring -> class
   136   val read_arity: theory -> xstring * string list * string -> arity
   137   val cert_arity: theory -> arity -> arity
   138   val get_sort: theory ->
   139     (indexname -> sort option) -> (indexname * sort) list -> indexname -> sort
   140   val read_def_typ: theory * (indexname -> sort option) -> string -> typ
   141   val read_typ: theory -> string -> typ
   142   val read_typ_syntax: theory -> string -> typ
   143   val read_typ_abbrev: theory -> string -> typ
   144   val read_def_terms:
   145     theory * (indexname -> typ option) * (indexname -> sort option) ->
   146     string list -> bool -> (string * typ) list -> term list * (indexname * typ) list
   147   val simple_read_term: theory -> typ -> string -> term
   148   val read_term: theory -> string -> term
   149   val read_prop: theory -> string -> term
   150   val declare_const: Markup.property list -> bstring * typ * mixfix -> theory -> term * theory
   151   val notation: bool -> Syntax.mode -> (term * mixfix) list -> theory -> theory
   152   val add_abbrev: string -> Markup.property list ->
   153     bstring * term -> theory -> (term * term) * theory
   154   val revert_abbrev: string -> string -> theory -> theory
   155   include SIGN_THEORY
   156   val add_const_constraint: string * typ option -> theory -> theory
   157   val primitive_class: string * class list -> theory -> theory
   158   val primitive_classrel: class * class -> theory -> theory
   159   val primitive_arity: arity -> theory -> theory
   160   val hide_classes: bool -> xstring list -> theory -> theory
   161   val hide_classes_i: bool -> string list -> theory -> theory
   162   val hide_types: bool -> xstring list -> theory -> theory
   163   val hide_types_i: bool -> string list -> theory -> theory
   164   val hide_consts: bool -> xstring list -> theory -> theory
   165   val hide_consts_i: bool -> string list -> theory -> theory
   166   val hide_names: bool -> string * xstring list -> theory -> theory
   167   val hide_names_i: bool -> string * string list -> theory -> theory
   168 end
   169 
   170 structure Sign: SIGN =
   171 struct
   172 
   173 (** datatype sign **)
   174 
   175 datatype sign = Sign of
   176  {naming: NameSpace.naming,     (*common naming conventions*)
   177   syn: Syntax.syntax,           (*concrete syntax for terms, types, sorts*)
   178   tsig: Type.tsig,              (*order-sorted signature of types*)
   179   consts: Consts.T};            (*polymorphic constants*)
   180 
   181 fun make_sign (naming, syn, tsig, consts) =
   182   Sign {naming = naming, syn = syn, tsig = tsig, consts = consts};
   183 
   184 structure SignData = TheoryDataFun
   185 (
   186   type T = sign;
   187   val copy = I;
   188   fun extend (Sign {syn, tsig, consts, ...}) =
   189     make_sign (NameSpace.default_naming, syn, tsig, consts);
   190 
   191   val empty =
   192     make_sign (NameSpace.default_naming, Syntax.basic_syn, Type.empty_tsig, Consts.empty);
   193 
   194   fun merge pp (sign1, sign2) =
   195     let
   196       val Sign {naming = _, syn = syn1, tsig = tsig1, consts = consts1} = sign1;
   197       val Sign {naming = _, syn = syn2, tsig = tsig2, consts = consts2} = sign2;
   198 
   199       val naming = NameSpace.default_naming;
   200       val syn = Syntax.merge_syntaxes syn1 syn2;
   201       val tsig = Type.merge_tsigs pp (tsig1, tsig2);
   202       val consts = Consts.merge (consts1, consts2);
   203     in make_sign (naming, syn, tsig, consts) end;
   204 );
   205 
   206 fun rep_sg thy = SignData.get thy |> (fn Sign args => args);
   207 
   208 fun map_sign f = SignData.map (fn Sign {naming, syn, tsig, consts} =>
   209   make_sign (f (naming, syn, tsig, consts)));
   210 
   211 fun map_naming f = map_sign (fn (naming, syn, tsig, consts) => (f naming, syn, tsig, consts));
   212 fun map_syn f = map_sign (fn (naming, syn, tsig, consts) => (naming, f syn, tsig, consts));
   213 fun map_tsig f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, f tsig, consts));
   214 fun map_consts f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, tsig, f consts));
   215 
   216 
   217 (* naming *)
   218 
   219 val naming_of = #naming o rep_sg;
   220 val base_name = NameSpace.base;
   221 val full_name = NameSpace.full o naming_of;
   222 fun full_name_path thy elems = NameSpace.full (NameSpace.add_path elems (naming_of thy));
   223 val declare_name = NameSpace.declare o naming_of;
   224 
   225 
   226 (* syntax *)
   227 
   228 val syn_of = #syn o rep_sg;
   229 
   230 
   231 (* type signature *)
   232 
   233 val tsig_of = #tsig o rep_sg;
   234 
   235 val classes_of = #2 o #classes o Type.rep_tsig o tsig_of;
   236 val all_classes = Sorts.all_classes o classes_of;
   237 val minimal_classes = Sorts.minimal_classes o classes_of;
   238 val super_classes = Sorts.super_classes o classes_of;
   239 val minimize_sort = Sorts.minimize_sort o classes_of;
   240 val complete_sort = Sorts.complete_sort o classes_of;
   241 
   242 val defaultS = Type.defaultS o tsig_of;
   243 val subsort = Type.subsort o tsig_of;
   244 val of_sort = Type.of_sort o tsig_of;
   245 val witness_sorts = Type.witness_sorts o tsig_of;
   246 val universal_witness = Type.universal_witness o tsig_of;
   247 val all_sorts_nonempty = is_some o universal_witness;
   248 val is_logtype = member (op =) o Type.logical_types o tsig_of;
   249 
   250 val typ_instance = Type.typ_instance o tsig_of;
   251 fun typ_equiv thy (T, U) = typ_instance thy (T, U) andalso typ_instance thy (U, T);
   252 val typ_match = Type.typ_match o tsig_of;
   253 val typ_unify = Type.unify o tsig_of;
   254 
   255 
   256 (* polymorphic constants *)
   257 
   258 val consts_of = #consts o rep_sg;
   259 val the_const_constraint = Consts.the_constraint o consts_of;
   260 val the_const_type = Consts.the_type o consts_of;
   261 val const_type = try o the_const_type;
   262 val const_monomorphic = Consts.is_monomorphic o consts_of;
   263 val const_syntax_name = Consts.syntax_name o consts_of;
   264 val const_typargs = Consts.typargs o consts_of;
   265 val const_instance = Consts.instance o consts_of;
   266 
   267 val declared_tyname = Symtab.defined o #2 o #types o Type.rep_tsig o tsig_of;
   268 val declared_const = can o the_const_constraint;
   269 
   270 
   271 
   272 (** intern / extern names **)
   273 
   274 val class_space = #1 o #classes o Type.rep_tsig o tsig_of;
   275 val type_space = #1 o #types o Type.rep_tsig o tsig_of;
   276 val const_space = Consts.space_of o consts_of;
   277 
   278 val intern_class = NameSpace.intern o class_space;
   279 val extern_class = NameSpace.extern o class_space;
   280 val intern_type = NameSpace.intern o type_space;
   281 val extern_type = NameSpace.extern o type_space;
   282 val intern_const = NameSpace.intern o const_space;
   283 val extern_const = NameSpace.extern o const_space;
   284 
   285 val intern_sort = map o intern_class;
   286 val extern_sort = map o extern_class;
   287 
   288 local
   289 
   290 fun map_typ f g (Type (c, Ts)) = Type (g c, map (map_typ f g) Ts)
   291   | map_typ f _ (TFree (x, S)) = TFree (x, map f S)
   292   | map_typ f _ (TVar (xi, S)) = TVar (xi, map f S);
   293 
   294 fun map_term f g h (Const (c, T)) = Const (h c, map_typ f g T)
   295   | map_term f g _ (Free (x, T)) = Free (x, map_typ f g T)
   296   | map_term f g _ (Var (xi, T)) = Var (xi, map_typ f g T)
   297   | map_term _ _ _ (t as Bound _) = t
   298   | map_term f g h (Abs (x, T, t)) = Abs (x, map_typ f g T, map_term f g h t)
   299   | map_term f g h (t $ u) = map_term f g h t $ map_term f g h u;
   300 
   301 val add_classesT = Term.fold_atyps
   302   (fn TFree (_, S) => fold (insert (op =)) S
   303     | TVar (_, S) => fold (insert (op =)) S
   304     | _ => I);
   305 
   306 fun add_tyconsT (Type (c, Ts)) = insert (op =) c #> fold add_tyconsT Ts
   307   | add_tyconsT _ = I;
   308 
   309 val add_consts = Term.fold_aterms (fn Const (c, _) => insert (op =) c | _ => I);
   310 
   311 fun mapping add_names f t =
   312   let
   313     fun f' (x: string) = let val y = f x in if x = y then NONE else SOME (x, y) end;
   314     val tab = map_filter f' (add_names t []);
   315     fun get x = the_default x (AList.lookup (op =) tab x);
   316   in get end;
   317 
   318 fun typ_mapping f g thy T =
   319   T |> map_typ
   320     (mapping add_classesT (f thy) T)
   321     (mapping add_tyconsT (g thy) T);
   322 
   323 fun term_mapping f g h thy t =
   324   t |> map_term
   325     (mapping (Term.fold_types add_classesT) (f thy) t)
   326     (mapping (Term.fold_types add_tyconsT) (g thy) t)
   327     (mapping add_consts (h thy) t);
   328 
   329 in
   330 
   331 val intern_typ = typ_mapping intern_class intern_type;
   332 val extern_typ = typ_mapping extern_class extern_type;
   333 val intern_term = term_mapping intern_class intern_type intern_const;
   334 fun extern_term h = term_mapping extern_class extern_type (K h);
   335 val intern_tycons = typ_mapping (K I) intern_type;
   336 
   337 end;
   338 
   339 
   340 
   341 (** pretty printing of terms, types etc. **)
   342 
   343 val pretty_term = Syntax.pretty_term o ProofContext.init;
   344 val pretty_typ = Syntax.pretty_typ o ProofContext.init;
   345 val pretty_sort = Syntax.pretty_sort o ProofContext.init;
   346 
   347 val string_of_term = Syntax.string_of_term o ProofContext.init;
   348 val string_of_typ = Syntax.string_of_typ o ProofContext.init;
   349 val string_of_sort = Syntax.string_of_sort o ProofContext.init;
   350 
   351 (*pp operations -- deferred evaluation*)
   352 fun pp thy = Pretty.pp
   353  (fn x => pretty_term thy x,
   354   fn x => pretty_typ thy x,
   355   fn x => pretty_sort thy x,
   356   fn x => Syntax.pretty_classrel (ProofContext.init thy) x,
   357   fn x => Syntax.pretty_arity (ProofContext.init thy) x);
   358 
   359 
   360 
   361 (** certify entities **)    (*exception TYPE*)
   362 
   363 (* certify wrt. type signature *)
   364 
   365 val arity_number = Type.arity_number o tsig_of;
   366 fun arity_sorts thy = Type.arity_sorts (pp thy) (tsig_of thy);
   367 
   368 val certify_class         = Type.cert_class o tsig_of;
   369 val certify_sort          = Type.cert_sort o tsig_of;
   370 val certify_typ           = Type.cert_typ o tsig_of;
   371 fun certify_typ_mode mode = Type.cert_typ_mode mode o tsig_of;
   372 
   373 
   374 (* certify term/prop *)
   375 
   376 local
   377 
   378 fun type_check pp tm =
   379   let
   380     fun err_appl why bs t T u U =
   381       let
   382         val xs = map Free bs;           (*we do not rename here*)
   383         val t' = subst_bounds (xs, t);
   384         val u' = subst_bounds (xs, u);
   385         val msg = cat_lines
   386           (TypeInfer.appl_error (Syntax.pp_show_brackets pp) why t' T u' U);
   387       in raise TYPE (msg, [T, U], [t', u']) end;
   388 
   389     fun typ_of (_, Const (_, T)) = T
   390       | typ_of (_, Free  (_, T)) = T
   391       | typ_of (_, Var (_, T)) = T
   392       | typ_of (bs, Bound i) = snd (List.nth (bs, i) handle Subscript =>
   393           raise TYPE ("Loose bound variable: B." ^ string_of_int i, [], [Bound i]))
   394       | typ_of (bs, Abs (x, T, body)) = T --> typ_of ((x, T) :: bs, body)
   395       | typ_of (bs, t $ u) =
   396           let val T = typ_of (bs, t) and U = typ_of (bs, u) in
   397             (case T of
   398               Type ("fun", [T1, T2]) =>
   399                 if T1 = U then T2 else err_appl "Incompatible operand type" bs t T u U
   400             | _ => err_appl "Operator not of function type" bs t T u U)
   401           end;
   402   in typ_of ([], tm) end;
   403 
   404 fun err msg = raise TYPE (msg, [], []);
   405 
   406 fun check_vars (t $ u) = (check_vars t; check_vars u)
   407   | check_vars (Abs (_, _, t)) = check_vars t
   408   | check_vars (Var (xi as (_, i), _)) =
   409       if i < 0 then err ("Malformed variable: " ^ quote (Term.string_of_vname xi)) else ()
   410   | check_vars _ = ();
   411 
   412 in
   413 
   414 fun certify' prop pp do_expand consts thy tm =
   415   let
   416     val _ = check_vars tm;
   417     val tm' = Term.map_types (certify_typ thy) tm;
   418     val T = type_check pp tm';
   419     val _ = if prop andalso T <> propT then err "Term not of type prop" else ();
   420     val tm'' = Consts.certify pp (tsig_of thy) do_expand consts tm';
   421   in (if tm = tm'' then tm else tm'', T, Term.maxidx_of_term tm'') end;
   422 
   423 fun certify_term thy = certify' false (pp thy) true (consts_of thy) thy;
   424 fun certify_prop thy = certify' true (pp thy) true (consts_of thy) thy;
   425 
   426 fun cert_term_abbrev thy = #1 o certify' false (pp thy) false (consts_of thy) thy;
   427 val cert_term = #1 oo certify_term;
   428 val cert_prop = #1 oo certify_prop;
   429 
   430 end;
   431 
   432 
   433 (* specifications *)
   434 
   435 fun no_variables kind add addT mk mkT pp tm =
   436   (case (add tm [], addT tm []) of
   437     ([], []) => tm
   438   | (frees, tfrees) => error (Pretty.string_of (Pretty.block
   439       (Pretty.str ("Illegal " ^ kind ^ " variable(s) in term:") :: Pretty.brk 1 ::
   440        Pretty.commas (map (Pretty.term pp o mk) frees @ map (Pretty.typ pp o mkT) tfrees)))));
   441 
   442 val no_frees = no_variables "free" Term.add_frees Term.add_tfrees Free TFree;
   443 val no_vars = no_variables "schematic" Term.add_vars Term.add_tvars Var TVar;
   444 
   445 fun cert_def ctxt tm =
   446   let val ((lhs, rhs), _) = tm
   447     |> no_vars (Syntax.pp ctxt)
   448     |> Logic.strip_imp_concl
   449     |> PrimitiveDefs.dest_def ctxt Term.is_Const (K false) (K false)
   450   in (Term.dest_Const (Term.head_of lhs), rhs) end
   451   handle TERM (msg, _) => error msg;
   452 
   453 
   454 
   455 (** read and certify entities **)    (*exception ERROR*)
   456 
   457 (* classes *)
   458 
   459 fun read_class thy c = certify_class thy (intern_class thy c)
   460   handle TYPE (msg, _, _) => error msg;
   461 
   462 
   463 (* type arities *)
   464 
   465 fun prep_arity prep_tycon prep_sort thy (t, Ss, S) =
   466   let val arity = (prep_tycon thy t, map (prep_sort thy) Ss, prep_sort thy S)
   467   in Type.add_arity (pp thy) arity (tsig_of thy); arity end;
   468 
   469 val read_arity = prep_arity intern_type Syntax.read_sort_global;
   470 val cert_arity = prep_arity (K I) certify_sort;
   471 
   472 
   473 (* types *)
   474 
   475 fun get_sort thy def_sort raw_env =
   476   let
   477     val tsig = tsig_of thy;
   478 
   479     fun eq ((xi, S), (xi', S')) =
   480       Term.eq_ix (xi, xi') andalso Type.eq_sort tsig (S, S');
   481     val env = distinct eq raw_env;
   482     val _ = (case duplicates (eq_fst (op =)) env of [] => ()
   483       | dups => error ("Inconsistent sort constraints for type variable(s) "
   484           ^ commas_quote (map (Term.string_of_vname' o fst) dups)));
   485 
   486     fun get xi =
   487       (case (AList.lookup (op =) env xi, def_sort xi) of
   488         (NONE, NONE) => Type.defaultS tsig
   489       | (NONE, SOME S) => S
   490       | (SOME S, NONE) => S
   491       | (SOME S, SOME S') =>
   492           if Type.eq_sort tsig (S, S') then S'
   493           else error ("Sort constraint inconsistent with default for type variable " ^
   494             quote (Term.string_of_vname' xi)));
   495   in get end;
   496 
   497 local
   498 
   499 fun gen_read_typ mode (thy, def_sort) str =
   500   let
   501     val ctxt = ProofContext.init thy;
   502     val syn = syn_of thy;
   503     val T = intern_tycons thy
   504       (Syntax.standard_parse_typ ctxt syn (get_sort thy def_sort) (intern_sort thy) str);
   505   in certify_typ_mode mode thy T handle TYPE (msg, _, _) => error msg end
   506   handle ERROR msg => cat_error msg ("The error(s) above occurred in type " ^ quote str);
   507 
   508 in
   509 
   510 fun no_def_sort thy = (thy: theory, K NONE);
   511 
   512 val read_def_typ     = gen_read_typ Type.mode_default;
   513 val read_typ         = gen_read_typ Type.mode_default o no_def_sort;
   514 val read_typ_syntax  = gen_read_typ Type.mode_syntax o no_def_sort;
   515 val read_typ_abbrev  = gen_read_typ Type.mode_abbrev o no_def_sort;
   516 
   517 end;
   518 
   519 
   520 (* read_def_terms -- read terms and infer types *)    (*exception ERROR*)
   521 
   522 (*
   523   def_type: partial map from indexnames to types (constrains Frees and Vars)
   524   def_sort: partial map from indexnames to sorts (constrains TFrees and TVars)
   525   used: context of already used type variables
   526   freeze: if true then generated parameters are turned into TFrees, else TVars
   527 *)
   528 
   529 fun read_def_terms'
   530     pp is_logtype syn consts map_free ctxt (def_type, def_sort) used freeze raw_args =
   531   let
   532     val thy = ProofContext.theory_of ctxt;
   533     fun check_typs Ts = map (certify_typ thy) Ts
   534       handle TYPE (msg, _, _) => error msg;
   535 
   536     fun infer args = TypeInfer.infer_types pp (tsig_of thy) check_typs
   537         (try (Consts.the_constraint consts)) def_type used ~1 (SOME freeze) args |>> map fst
   538       handle TYPE (msg, _, _) => error msg;
   539 
   540     fun check T t = (singleton (fst o infer) (t, T); NONE) handle ERROR msg => SOME msg;
   541     val map_const = try (#1 o Term.dest_Const o Consts.read_const consts);
   542     fun read T = Syntax.standard_parse_term pp (check T) (get_sort thy def_sort) map_const map_free
   543         (intern_tycons thy) (intern_sort thy) ctxt is_logtype syn T;
   544   in
   545     raw_args
   546     |> map (fn (s, raw_T) =>
   547       let val T = certify_typ thy raw_T handle TYPE (msg, _, _) => error msg
   548       in (read (#1 (TypeInfer.paramify_dummies T 0)) s, T) end)
   549     |> infer
   550   end;
   551 
   552 fun read_def_terms (thy, types, sorts) used freeze sTs =
   553   let
   554     val pp = pp thy;
   555     val consts = consts_of thy;
   556     val cert_consts = Consts.certify pp (tsig_of thy) true consts;
   557     fun map_free x = if is_some (types (x, ~1)) then SOME x else NONE;
   558     val (ts, inst) =
   559       read_def_terms' pp (is_logtype thy) (syn_of thy) consts map_free
   560         (ProofContext.init thy) (types, sorts) (Name.make_context used) freeze sTs;
   561   in (map cert_consts ts, inst) end;
   562 
   563 fun simple_read_term thy T s =
   564   let val ([t], _) = read_def_terms (thy, K NONE, K NONE) [] true [(s, T)]
   565   in t end handle ERROR msg => cat_error msg ("The error(s) above occurred for term " ^ s);
   566 
   567 fun read_term thy = simple_read_term thy dummyT;
   568 fun read_prop thy = simple_read_term thy propT;
   569 
   570 
   571 
   572 (** signature extension functions **)  (*exception ERROR/TYPE*)
   573 
   574 (* add default sort *)
   575 
   576 fun gen_add_defsort prep_sort s thy =
   577   thy |> map_tsig (Type.set_defsort (prep_sort thy s));
   578 
   579 val add_defsort = gen_add_defsort Syntax.read_sort_global;
   580 val add_defsort_i = gen_add_defsort certify_sort;
   581 
   582 
   583 (* add type constructors *)
   584 
   585 fun add_types types thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   586   let
   587     val syn' = Syntax.update_type_gram types syn;
   588     val decls = map (fn (a, n, mx) => (Syntax.type_name a mx, n)) types;
   589     val tsig' = Type.add_types naming decls tsig;
   590   in (naming, syn', tsig', consts) end);
   591 
   592 
   593 (* add nonterminals *)
   594 
   595 fun add_nonterminals ns thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   596   let
   597     val syn' = Syntax.update_consts ns syn;
   598     val tsig' = Type.add_nonterminals naming ns tsig;
   599   in (naming, syn', tsig', consts) end);
   600 
   601 
   602 (* add type abbreviations *)
   603 
   604 fun gen_add_tyabbr parse_typ (a, vs, rhs, mx) thy =
   605   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   606     let
   607       val ctxt = ProofContext.init thy;
   608       val syn' = Syntax.update_type_gram [(a, length vs, mx)] syn;
   609       val a' = Syntax.type_name a mx;
   610       val abbr = (a', vs, certify_typ_mode Type.mode_syntax thy (parse_typ ctxt rhs))
   611         handle ERROR msg => cat_error msg ("in type abbreviation " ^ quote a');
   612       val tsig' = Type.add_abbrevs naming [abbr] tsig;
   613     in (naming, syn', tsig', consts) end);
   614 
   615 val add_tyabbrs = fold (gen_add_tyabbr Syntax.parse_typ);
   616 val add_tyabbrs_i = fold (gen_add_tyabbr (K I));
   617 
   618 
   619 (* modify syntax *)
   620 
   621 fun gen_syntax change_gram parse_typ mode args thy =
   622   let
   623     val ctxt = ProofContext.init thy;
   624     fun prep (c, T, mx) = (c, certify_typ_mode Type.mode_syntax thy (parse_typ ctxt T), mx)
   625       handle ERROR msg =>
   626         cat_error msg ("in syntax declaration " ^ quote (Syntax.const_name c mx));
   627   in thy |> map_syn (change_gram (is_logtype thy) mode (map prep args)) end;
   628 
   629 fun gen_add_syntax x = gen_syntax Syntax.update_const_gram x;
   630 
   631 val add_modesyntax = gen_add_syntax Syntax.parse_typ;
   632 val add_modesyntax_i = gen_add_syntax (K I);
   633 val add_syntax = add_modesyntax Syntax.mode_default;
   634 val add_syntax_i = add_modesyntax_i Syntax.mode_default;
   635 val del_modesyntax = gen_syntax Syntax.remove_const_gram Syntax.parse_typ;
   636 val del_modesyntax_i = gen_syntax Syntax.remove_const_gram (K I);
   637 
   638 fun notation add mode args thy =
   639   let
   640     val change_gram = if add then Syntax.update_const_gram else Syntax.remove_const_gram;
   641     fun const_syntax (Const (c, _), mx) = try (Consts.syntax (consts_of thy)) (c, mx)
   642       | const_syntax _ = NONE;
   643   in gen_syntax change_gram (K I) mode (map_filter const_syntax args) thy end;
   644 
   645 
   646 (* add constants *)
   647 
   648 local
   649 
   650 fun gen_add_consts parse_typ authentic tags raw_args thy =
   651   let
   652     val ctxt = ProofContext.init thy;
   653     val prepT = Type.no_tvars o Term.no_dummyT o certify_typ thy o parse_typ ctxt;
   654     fun prep (raw_c, raw_T, raw_mx) =
   655       let
   656         val (c, mx) = Syntax.const_mixfix raw_c raw_mx;
   657         val full_c = full_name thy c;
   658         val c' = if authentic then Syntax.constN ^ full_c else c;
   659         val T = (prepT raw_T handle TYPE (msg, _, _) => error msg) handle ERROR msg =>
   660           cat_error msg ("in declaration of constant " ^ quote c);
   661         val T' = Compress.typ thy (Logic.varifyT T);
   662       in ((c, T'), (c', T', mx), Const (full_c, T)) end;
   663     val args = map prep raw_args;
   664   in
   665     thy
   666     |> map_consts (fold (Consts.declare authentic (naming_of thy) tags o #1) args)
   667     |> add_syntax_i (map #2 args)
   668     |> pair (map #3 args)
   669   end;
   670 
   671 in
   672 
   673 val add_consts = snd oo gen_add_consts Syntax.parse_typ false [];
   674 val add_consts_i = snd oo gen_add_consts (K I) false [];
   675 
   676 fun declare_const tags arg = gen_add_consts (K I) true tags [arg] #>> the_single;
   677 
   678 end;
   679 
   680 
   681 (* abbreviations *)
   682 
   683 fun add_abbrev mode tags (c, raw_t) thy =
   684   let
   685     val pp = pp thy;
   686     val prep_tm = Compress.term thy o no_frees pp o Term.no_dummy_patterns o cert_term_abbrev thy;
   687     val t = (prep_tm raw_t handle TYPE (msg, _, _) => error msg | TERM (msg, _) => error msg)
   688       handle ERROR msg => cat_error msg ("in constant abbreviation " ^ quote c);
   689     val (res, consts') = consts_of thy
   690       |> Consts.abbreviate pp (tsig_of thy) (naming_of thy) mode tags (c, t);
   691   in (res, thy |> map_consts (K consts')) end;
   692 
   693 fun revert_abbrev mode c = map_consts (Consts.revert_abbrev mode c);
   694 
   695 
   696 (* add constraints *)
   697 
   698 fun add_const_constraint (c, opt_T) thy =
   699   let
   700     fun prepT raw_T =
   701       let val T = Logic.varifyT (Type.no_tvars (Term.no_dummyT (certify_typ thy raw_T)))
   702       in cert_term thy (Const (c, T)); T end
   703       handle TYPE (msg, _, _) => error msg;
   704   in thy |> map_consts (Consts.constrain (c, Option.map prepT opt_T)) end;
   705 
   706 
   707 (* primitive classes and arities *)
   708 
   709 fun primitive_class (bclass, classes) thy =
   710   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   711     let
   712       val syn' = Syntax.update_consts [bclass] syn;
   713       val tsig' = Type.add_class (pp thy) naming (bclass, classes) tsig;
   714     in (naming, syn', tsig', consts) end)
   715   |> add_consts_i [(Logic.const_of_class bclass, Term.a_itselfT --> propT, NoSyn)];
   716 
   717 fun primitive_classrel arg thy = thy |> map_tsig (Type.add_classrel (pp thy) arg);
   718 fun primitive_arity arg thy = thy |> map_tsig (Type.add_arity (pp thy) arg);
   719 
   720 
   721 (* add translation functions *)
   722 
   723 local
   724 
   725 fun mk trs = map Syntax.mk_trfun trs;
   726 
   727 fun gen_add_trfuns ext non_typed (atrs, trs, tr's, atr's) =
   728   map_syn (ext (mk atrs, mk trs, mk (map (apsnd non_typed) tr's), mk atr's));
   729 
   730 fun gen_add_trfunsT ext tr's = map_syn (ext ([], [], mk tr's, []));
   731 
   732 in
   733 
   734 val add_trfuns = gen_add_trfuns Syntax.update_trfuns Syntax.non_typed_tr';
   735 val add_trfunsT = gen_add_trfunsT Syntax.update_trfuns;
   736 val add_advanced_trfuns = gen_add_trfuns Syntax.update_advanced_trfuns Syntax.non_typed_tr'';
   737 val add_advanced_trfunsT = gen_add_trfunsT Syntax.update_advanced_trfuns;
   738 
   739 end;
   740 
   741 val add_tokentrfuns = map_syn o Syntax.extend_tokentrfuns;
   742 fun add_mode_tokentrfuns m = add_tokentrfuns o map (fn (s, f) => (m, s, f));
   743 
   744 
   745 (* translation rules *)
   746 
   747 fun gen_trrules f args thy = thy |> map_syn (fn syn =>
   748   let val rules = map (Syntax.map_trrule (apfst (intern_type thy))) args
   749   in f (ProofContext.init thy) (is_logtype thy) syn rules syn end);
   750 
   751 val add_trrules = gen_trrules Syntax.update_trrules;
   752 val del_trrules = gen_trrules Syntax.remove_trrules;
   753 val add_trrules_i = map_syn o Syntax.update_trrules_i;
   754 val del_trrules_i = map_syn o Syntax.remove_trrules_i;
   755 
   756 
   757 (* modify naming *)
   758 
   759 val add_path        = map_naming o NameSpace.add_path;
   760 val no_base_names   = map_naming NameSpace.no_base_names;
   761 val qualified_names = map_naming NameSpace.qualified_names;
   762 val sticky_prefix   = map_naming o NameSpace.sticky_prefix;
   763 val restore_naming  = map_naming o K o naming_of;
   764 
   765 val parent_path   = add_path "..";
   766 val root_path     = add_path "/";
   767 val absolute_path = add_path "//";
   768 
   769 fun local_path thy = thy |> root_path |> add_path (Context.theory_name thy);
   770 
   771 
   772 (* hide names *)
   773 
   774 fun hide_classes b xs thy = thy |> map_tsig (Type.hide_classes b (map (intern_class thy) xs));
   775 val hide_classes_i = map_tsig oo Type.hide_classes;
   776 fun hide_types b xs thy = thy |> map_tsig (Type.hide_types b (map (intern_type thy) xs));
   777 val hide_types_i = map_tsig oo Type.hide_types;
   778 fun hide_consts b xs thy = thy |> map_consts (fold (Consts.hide b o intern_const thy) xs);
   779 val hide_consts_i = map_consts oo (fold o Consts.hide);
   780 
   781 local
   782 
   783 val kinds =
   784  [("class", (intern_class, can o certify_class, hide_classes_i)),
   785   ("type", (intern_type, declared_tyname, hide_types_i)),
   786   ("const", (intern_const, declared_const, hide_consts_i))];
   787 
   788 fun gen_hide int b (kind, xnames) thy =
   789   (case AList.lookup (op =) kinds kind of
   790     SOME (intern, check, hide) =>
   791       let
   792         val names = if int then map (intern thy) xnames else xnames;
   793         val bads = filter_out (check thy) names;
   794       in
   795         if null bads then hide b names thy
   796         else error ("Attempt to hide undeclared item(s): " ^ commas_quote bads)
   797       end
   798   | NONE => error ("Bad name space specification: " ^ quote kind));
   799 
   800 in
   801 
   802 val hide_names = gen_hide true;
   803 val hide_names_i = gen_hide false;
   804 
   805 end;
   806 
   807 end;