src/HOL/Library/Polynomial.thy
author haftmann
Tue Nov 19 10:05:53 2013 +0100 (2013-11-19)
changeset 54489 03ff4d1e6784
parent 54230 b1d955791529
child 54855 d700d054d022
permissions -rw-r--r--
eliminiated neg_numeral in favour of - (numeral _)
     1 (*  Title:      HOL/Library/Polynomial.thy
     2     Author:     Brian Huffman
     3     Author:     Clemens Ballarin
     4     Author:     Florian Haftmann
     5 *)
     6 
     7 header {* Polynomials as type over a ring structure *}
     8 
     9 theory Polynomial
    10 imports Main GCD
    11 begin
    12 
    13 subsection {* Auxiliary: operations for lists (later) representing coefficients *}
    14 
    15 definition strip_while :: "('a \<Rightarrow> bool) \<Rightarrow> 'a list \<Rightarrow> 'a list"
    16 where
    17   "strip_while P = rev \<circ> dropWhile P \<circ> rev"
    18 
    19 lemma strip_while_Nil [simp]:
    20   "strip_while P [] = []"
    21   by (simp add: strip_while_def)
    22 
    23 lemma strip_while_append [simp]:
    24   "\<not> P x \<Longrightarrow> strip_while P (xs @ [x]) = xs @ [x]"
    25   by (simp add: strip_while_def)
    26 
    27 lemma strip_while_append_rec [simp]:
    28   "P x \<Longrightarrow> strip_while P (xs @ [x]) = strip_while P xs"
    29   by (simp add: strip_while_def)
    30 
    31 lemma strip_while_Cons [simp]:
    32   "\<not> P x \<Longrightarrow> strip_while P (x # xs) = x # strip_while P xs"
    33   by (induct xs rule: rev_induct) (simp_all add: strip_while_def)
    34 
    35 lemma strip_while_eq_Nil [simp]:
    36   "strip_while P xs = [] \<longleftrightarrow> (\<forall>x\<in>set xs. P x)"
    37   by (simp add: strip_while_def)
    38 
    39 lemma strip_while_eq_Cons_rec:
    40   "strip_while P (x # xs) = x # strip_while P xs \<longleftrightarrow> \<not> (P x \<and> (\<forall>x\<in>set xs. P x))"
    41   by (induct xs rule: rev_induct) (simp_all add: strip_while_def)
    42 
    43 lemma strip_while_not_last [simp]:
    44   "\<not> P (last xs) \<Longrightarrow> strip_while P xs = xs"
    45   by (cases xs rule: rev_cases) simp_all
    46 
    47 lemma split_strip_while_append:
    48   fixes xs :: "'a list"
    49   obtains ys zs :: "'a list"
    50   where "strip_while P xs = ys" and "\<forall>x\<in>set zs. P x" and "xs = ys @ zs"
    51 proof (rule that)
    52   show "strip_while P xs = strip_while P xs" ..
    53   show "\<forall>x\<in>set (rev (takeWhile P (rev xs))). P x" by (simp add: takeWhile_eq_all_conv [symmetric])
    54   have "rev xs = rev (strip_while P xs @ rev (takeWhile P (rev xs)))"
    55     by (simp add: strip_while_def)
    56   then show "xs = strip_while P xs @ rev (takeWhile P (rev xs))"
    57     by (simp only: rev_is_rev_conv)
    58 qed
    59 
    60 
    61 definition nth_default :: "'a \<Rightarrow> 'a list \<Rightarrow> nat \<Rightarrow> 'a"
    62 where
    63   "nth_default x xs n = (if n < length xs then xs ! n else x)"
    64 
    65 lemma nth_default_Nil [simp]:
    66   "nth_default y [] n = y"
    67   by (simp add: nth_default_def)
    68 
    69 lemma nth_default_Cons_0 [simp]:
    70   "nth_default y (x # xs) 0 = x"
    71   by (simp add: nth_default_def)
    72 
    73 lemma nth_default_Cons_Suc [simp]:
    74   "nth_default y (x # xs) (Suc n) = nth_default y xs n"
    75   by (simp add: nth_default_def)
    76 
    77 lemma nth_default_map_eq:
    78   "f y = x \<Longrightarrow> nth_default x (map f xs) n = f (nth_default y xs n)"
    79   by (simp add: nth_default_def)
    80 
    81 lemma nth_default_strip_while_eq [simp]:
    82   "nth_default x (strip_while (HOL.eq x) xs) n = nth_default x xs n"
    83 proof -
    84   from split_strip_while_append obtain ys zs
    85     where "strip_while (HOL.eq x) xs = ys" and "\<forall>z\<in>set zs. x = z" and "xs = ys @ zs" by blast
    86   then show ?thesis by (simp add: nth_default_def not_less nth_append)
    87 qed
    88 
    89 
    90 definition cCons :: "'a::zero \<Rightarrow> 'a list \<Rightarrow> 'a list"  (infixr "##" 65)
    91 where
    92   "x ## xs = (if xs = [] \<and> x = 0 then [] else x # xs)"
    93 
    94 lemma cCons_0_Nil_eq [simp]:
    95   "0 ## [] = []"
    96   by (simp add: cCons_def)
    97 
    98 lemma cCons_Cons_eq [simp]:
    99   "x ## y # ys = x # y # ys"
   100   by (simp add: cCons_def)
   101 
   102 lemma cCons_append_Cons_eq [simp]:
   103   "x ## xs @ y # ys = x # xs @ y # ys"
   104   by (simp add: cCons_def)
   105 
   106 lemma cCons_not_0_eq [simp]:
   107   "x \<noteq> 0 \<Longrightarrow> x ## xs = x # xs"
   108   by (simp add: cCons_def)
   109 
   110 lemma strip_while_not_0_Cons_eq [simp]:
   111   "strip_while (\<lambda>x. x = 0) (x # xs) = x ## strip_while (\<lambda>x. x = 0) xs"
   112 proof (cases "x = 0")
   113   case False then show ?thesis by simp
   114 next
   115   case True show ?thesis
   116   proof (induct xs rule: rev_induct)
   117     case Nil with True show ?case by simp
   118   next
   119     case (snoc y ys) then show ?case
   120       by (cases "y = 0") (simp_all add: append_Cons [symmetric] del: append_Cons)
   121   qed
   122 qed
   123 
   124 lemma tl_cCons [simp]:
   125   "tl (x ## xs) = xs"
   126   by (simp add: cCons_def)
   127 
   128 
   129 subsection {* Almost everywhere zero functions *}
   130 
   131 definition almost_everywhere_zero :: "(nat \<Rightarrow> 'a::zero) \<Rightarrow> bool"
   132 where
   133   "almost_everywhere_zero f \<longleftrightarrow> (\<exists>n. \<forall>i>n. f i = 0)"
   134 
   135 lemma almost_everywhere_zeroI:
   136   "(\<And>i. i > n \<Longrightarrow> f i = 0) \<Longrightarrow> almost_everywhere_zero f"
   137   by (auto simp add: almost_everywhere_zero_def)
   138 
   139 lemma almost_everywhere_zeroE:
   140   assumes "almost_everywhere_zero f"
   141   obtains n where "\<And>i. i > n \<Longrightarrow> f i = 0"
   142 proof -
   143   from assms have "\<exists>n. \<forall>i>n. f i = 0" by (simp add: almost_everywhere_zero_def)
   144   then obtain n where "\<And>i. i > n \<Longrightarrow> f i = 0" by blast
   145   with that show thesis .
   146 qed
   147 
   148 lemma almost_everywhere_zero_nat_case:
   149   assumes "almost_everywhere_zero f"
   150   shows "almost_everywhere_zero (nat_case a f)"
   151   using assms
   152   by (auto intro!: almost_everywhere_zeroI elim!: almost_everywhere_zeroE split: nat.split)
   153     blast
   154 
   155 lemma almost_everywhere_zero_Suc:
   156   assumes "almost_everywhere_zero f"
   157   shows "almost_everywhere_zero (\<lambda>n. f (Suc n))"
   158 proof -
   159   from assms obtain n where "\<And>i. i > n \<Longrightarrow> f i = 0" by (erule almost_everywhere_zeroE)
   160   then have "\<And>i. i > n \<Longrightarrow> f (Suc i) = 0" by auto
   161   then show ?thesis by (rule almost_everywhere_zeroI)
   162 qed
   163 
   164 
   165 subsection {* Definition of type @{text poly} *}
   166 
   167 typedef 'a poly = "{f :: nat \<Rightarrow> 'a::zero. almost_everywhere_zero f}"
   168   morphisms coeff Abs_poly
   169   unfolding almost_everywhere_zero_def by auto
   170 
   171 setup_lifting (no_code) type_definition_poly
   172 
   173 lemma poly_eq_iff: "p = q \<longleftrightarrow> (\<forall>n. coeff p n = coeff q n)"
   174   by (simp add: coeff_inject [symmetric] fun_eq_iff)
   175 
   176 lemma poly_eqI: "(\<And>n. coeff p n = coeff q n) \<Longrightarrow> p = q"
   177   by (simp add: poly_eq_iff)
   178 
   179 lemma coeff_almost_everywhere_zero:
   180   "almost_everywhere_zero (coeff p)"
   181   using coeff [of p] by simp
   182 
   183 
   184 subsection {* Degree of a polynomial *}
   185 
   186 definition degree :: "'a::zero poly \<Rightarrow> nat"
   187 where
   188   "degree p = (LEAST n. \<forall>i>n. coeff p i = 0)"
   189 
   190 lemma coeff_eq_0:
   191   assumes "degree p < n"
   192   shows "coeff p n = 0"
   193 proof -
   194   from coeff_almost_everywhere_zero
   195   have "\<exists>n. \<forall>i>n. coeff p i = 0" by (blast intro: almost_everywhere_zeroE)
   196   then have "\<forall>i>degree p. coeff p i = 0"
   197     unfolding degree_def by (rule LeastI_ex)
   198   with assms show ?thesis by simp
   199 qed
   200 
   201 lemma le_degree: "coeff p n \<noteq> 0 \<Longrightarrow> n \<le> degree p"
   202   by (erule contrapos_np, rule coeff_eq_0, simp)
   203 
   204 lemma degree_le: "\<forall>i>n. coeff p i = 0 \<Longrightarrow> degree p \<le> n"
   205   unfolding degree_def by (erule Least_le)
   206 
   207 lemma less_degree_imp: "n < degree p \<Longrightarrow> \<exists>i>n. coeff p i \<noteq> 0"
   208   unfolding degree_def by (drule not_less_Least, simp)
   209 
   210 
   211 subsection {* The zero polynomial *}
   212 
   213 instantiation poly :: (zero) zero
   214 begin
   215 
   216 lift_definition zero_poly :: "'a poly"
   217   is "\<lambda>_. 0" by (rule almost_everywhere_zeroI) simp
   218 
   219 instance ..
   220 
   221 end
   222 
   223 lemma coeff_0 [simp]:
   224   "coeff 0 n = 0"
   225   by transfer rule
   226 
   227 lemma degree_0 [simp]:
   228   "degree 0 = 0"
   229   by (rule order_antisym [OF degree_le le0]) simp
   230 
   231 lemma leading_coeff_neq_0:
   232   assumes "p \<noteq> 0"
   233   shows "coeff p (degree p) \<noteq> 0"
   234 proof (cases "degree p")
   235   case 0
   236   from `p \<noteq> 0` have "\<exists>n. coeff p n \<noteq> 0"
   237     by (simp add: poly_eq_iff)
   238   then obtain n where "coeff p n \<noteq> 0" ..
   239   hence "n \<le> degree p" by (rule le_degree)
   240   with `coeff p n \<noteq> 0` and `degree p = 0`
   241   show "coeff p (degree p) \<noteq> 0" by simp
   242 next
   243   case (Suc n)
   244   from `degree p = Suc n` have "n < degree p" by simp
   245   hence "\<exists>i>n. coeff p i \<noteq> 0" by (rule less_degree_imp)
   246   then obtain i where "n < i" and "coeff p i \<noteq> 0" by fast
   247   from `degree p = Suc n` and `n < i` have "degree p \<le> i" by simp
   248   also from `coeff p i \<noteq> 0` have "i \<le> degree p" by (rule le_degree)
   249   finally have "degree p = i" .
   250   with `coeff p i \<noteq> 0` show "coeff p (degree p) \<noteq> 0" by simp
   251 qed
   252 
   253 lemma leading_coeff_0_iff [simp]:
   254   "coeff p (degree p) = 0 \<longleftrightarrow> p = 0"
   255   by (cases "p = 0", simp, simp add: leading_coeff_neq_0)
   256 
   257 
   258 subsection {* List-style constructor for polynomials *}
   259 
   260 lift_definition pCons :: "'a::zero \<Rightarrow> 'a poly \<Rightarrow> 'a poly"
   261   is "\<lambda>a p. nat_case a (coeff p)"
   262   using coeff_almost_everywhere_zero by (rule almost_everywhere_zero_nat_case)
   263 
   264 lemmas coeff_pCons = pCons.rep_eq
   265 
   266 lemma coeff_pCons_0 [simp]:
   267   "coeff (pCons a p) 0 = a"
   268   by transfer simp
   269 
   270 lemma coeff_pCons_Suc [simp]:
   271   "coeff (pCons a p) (Suc n) = coeff p n"
   272   by (simp add: coeff_pCons)
   273 
   274 lemma degree_pCons_le:
   275   "degree (pCons a p) \<le> Suc (degree p)"
   276   by (rule degree_le) (simp add: coeff_eq_0 coeff_pCons split: nat.split)
   277 
   278 lemma degree_pCons_eq:
   279   "p \<noteq> 0 \<Longrightarrow> degree (pCons a p) = Suc (degree p)"
   280   apply (rule order_antisym [OF degree_pCons_le])
   281   apply (rule le_degree, simp)
   282   done
   283 
   284 lemma degree_pCons_0:
   285   "degree (pCons a 0) = 0"
   286   apply (rule order_antisym [OF _ le0])
   287   apply (rule degree_le, simp add: coeff_pCons split: nat.split)
   288   done
   289 
   290 lemma degree_pCons_eq_if [simp]:
   291   "degree (pCons a p) = (if p = 0 then 0 else Suc (degree p))"
   292   apply (cases "p = 0", simp_all)
   293   apply (rule order_antisym [OF _ le0])
   294   apply (rule degree_le, simp add: coeff_pCons split: nat.split)
   295   apply (rule order_antisym [OF degree_pCons_le])
   296   apply (rule le_degree, simp)
   297   done
   298 
   299 lemma pCons_0_0 [simp]:
   300   "pCons 0 0 = 0"
   301   by (rule poly_eqI) (simp add: coeff_pCons split: nat.split)
   302 
   303 lemma pCons_eq_iff [simp]:
   304   "pCons a p = pCons b q \<longleftrightarrow> a = b \<and> p = q"
   305 proof safe
   306   assume "pCons a p = pCons b q"
   307   then have "coeff (pCons a p) 0 = coeff (pCons b q) 0" by simp
   308   then show "a = b" by simp
   309 next
   310   assume "pCons a p = pCons b q"
   311   then have "\<forall>n. coeff (pCons a p) (Suc n) =
   312                  coeff (pCons b q) (Suc n)" by simp
   313   then show "p = q" by (simp add: poly_eq_iff)
   314 qed
   315 
   316 lemma pCons_eq_0_iff [simp]:
   317   "pCons a p = 0 \<longleftrightarrow> a = 0 \<and> p = 0"
   318   using pCons_eq_iff [of a p 0 0] by simp
   319 
   320 lemma pCons_cases [cases type: poly]:
   321   obtains (pCons) a q where "p = pCons a q"
   322 proof
   323   show "p = pCons (coeff p 0) (Abs_poly (\<lambda>n. coeff p (Suc n)))"
   324     by transfer
   325       (simp add: Abs_poly_inverse almost_everywhere_zero_Suc fun_eq_iff split: nat.split)
   326 qed
   327 
   328 lemma pCons_induct [case_names 0 pCons, induct type: poly]:
   329   assumes zero: "P 0"
   330   assumes pCons: "\<And>a p. P p \<Longrightarrow> P (pCons a p)"
   331   shows "P p"
   332 proof (induct p rule: measure_induct_rule [where f=degree])
   333   case (less p)
   334   obtain a q where "p = pCons a q" by (rule pCons_cases)
   335   have "P q"
   336   proof (cases "q = 0")
   337     case True
   338     then show "P q" by (simp add: zero)
   339   next
   340     case False
   341     then have "degree (pCons a q) = Suc (degree q)"
   342       by (rule degree_pCons_eq)
   343     then have "degree q < degree p"
   344       using `p = pCons a q` by simp
   345     then show "P q"
   346       by (rule less.hyps)
   347   qed
   348   then have "P (pCons a q)"
   349     by (rule pCons)
   350   then show ?case
   351     using `p = pCons a q` by simp
   352 qed
   353 
   354 
   355 subsection {* List-style syntax for polynomials *}
   356 
   357 syntax
   358   "_poly" :: "args \<Rightarrow> 'a poly"  ("[:(_):]")
   359 
   360 translations
   361   "[:x, xs:]" == "CONST pCons x [:xs:]"
   362   "[:x:]" == "CONST pCons x 0"
   363   "[:x:]" <= "CONST pCons x (_constrain 0 t)"
   364 
   365 
   366 subsection {* Representation of polynomials by lists of coefficients *}
   367 
   368 primrec Poly :: "'a::zero list \<Rightarrow> 'a poly"
   369 where
   370   "Poly [] = 0"
   371 | "Poly (a # as) = pCons a (Poly as)"
   372 
   373 lemma Poly_replicate_0 [simp]:
   374   "Poly (replicate n 0) = 0"
   375   by (induct n) simp_all
   376 
   377 lemma Poly_eq_0:
   378   "Poly as = 0 \<longleftrightarrow> (\<exists>n. as = replicate n 0)"
   379   by (induct as) (auto simp add: Cons_replicate_eq)
   380 
   381 definition coeffs :: "'a poly \<Rightarrow> 'a::zero list"
   382 where
   383   "coeffs p = (if p = 0 then [] else map (\<lambda>i. coeff p i) [0 ..< Suc (degree p)])"
   384 
   385 lemma coeffs_eq_Nil [simp]:
   386   "coeffs p = [] \<longleftrightarrow> p = 0"
   387   by (simp add: coeffs_def)
   388 
   389 lemma not_0_coeffs_not_Nil:
   390   "p \<noteq> 0 \<Longrightarrow> coeffs p \<noteq> []"
   391   by simp
   392 
   393 lemma coeffs_0_eq_Nil [simp]:
   394   "coeffs 0 = []"
   395   by simp
   396 
   397 lemma coeffs_pCons_eq_cCons [simp]:
   398   "coeffs (pCons a p) = a ## coeffs p"
   399 proof -
   400   { fix ms :: "nat list" and f :: "nat \<Rightarrow> 'a" and x :: "'a"
   401     assume "\<forall>m\<in>set ms. m > 0"
   402     then have "map (nat_case x f) ms = map f (map (\<lambda>n. n - 1) ms)"
   403       by (induct ms) (auto, metis Suc_pred' nat_case_Suc) }
   404   note * = this
   405   show ?thesis
   406     by (simp add: coeffs_def * upt_conv_Cons coeff_pCons map_decr_upt One_nat_def del: upt_Suc)
   407 qed
   408 
   409 lemma not_0_cCons_eq [simp]:
   410   "p \<noteq> 0 \<Longrightarrow> a ## coeffs p = a # coeffs p"
   411   by (simp add: cCons_def)
   412 
   413 lemma Poly_coeffs [simp, code abstype]:
   414   "Poly (coeffs p) = p"
   415   by (induct p) (simp_all add: cCons_def)
   416 
   417 lemma coeffs_Poly [simp]:
   418   "coeffs (Poly as) = strip_while (HOL.eq 0) as"
   419 proof (induct as)
   420   case Nil then show ?case by simp
   421 next
   422   case (Cons a as)
   423   have "(\<forall>n. as \<noteq> replicate n 0) \<longleftrightarrow> (\<exists>a\<in>set as. a \<noteq> 0)"
   424     using replicate_length_same [of as 0] by (auto dest: sym [of _ as])
   425   with Cons show ?case by auto
   426 qed
   427 
   428 lemma last_coeffs_not_0:
   429   "p \<noteq> 0 \<Longrightarrow> last (coeffs p) \<noteq> 0"
   430   by (induct p) (auto simp add: cCons_def)
   431 
   432 lemma strip_while_coeffs [simp]:
   433   "strip_while (HOL.eq 0) (coeffs p) = coeffs p"
   434   by (cases "p = 0") (auto dest: last_coeffs_not_0 intro: strip_while_not_last)
   435 
   436 lemma coeffs_eq_iff:
   437   "p = q \<longleftrightarrow> coeffs p = coeffs q" (is "?P \<longleftrightarrow> ?Q")
   438 proof
   439   assume ?P then show ?Q by simp
   440 next
   441   assume ?Q
   442   then have "Poly (coeffs p) = Poly (coeffs q)" by simp
   443   then show ?P by simp
   444 qed
   445 
   446 lemma coeff_Poly_eq:
   447   "coeff (Poly xs) n = nth_default 0 xs n"
   448   apply (induct xs arbitrary: n) apply simp_all
   449   by (metis nat_case_0 nat_case_Suc not0_implies_Suc nth_default_Cons_0 nth_default_Cons_Suc pCons.rep_eq)
   450 
   451 lemma nth_default_coeffs_eq:
   452   "nth_default 0 (coeffs p) = coeff p"
   453   by (simp add: fun_eq_iff coeff_Poly_eq [symmetric])
   454 
   455 lemma [code]:
   456   "coeff p = nth_default 0 (coeffs p)"
   457   by (simp add: nth_default_coeffs_eq)
   458 
   459 lemma coeffs_eqI:
   460   assumes coeff: "\<And>n. coeff p n = nth_default 0 xs n"
   461   assumes zero: "xs \<noteq> [] \<Longrightarrow> last xs \<noteq> 0"
   462   shows "coeffs p = xs"
   463 proof -
   464   from coeff have "p = Poly xs" by (simp add: poly_eq_iff coeff_Poly_eq)
   465   with zero show ?thesis by simp (cases xs, simp_all)
   466 qed
   467 
   468 lemma degree_eq_length_coeffs [code]:
   469   "degree p = length (coeffs p) - 1"
   470   by (simp add: coeffs_def)
   471 
   472 lemma length_coeffs_degree:
   473   "p \<noteq> 0 \<Longrightarrow> length (coeffs p) = Suc (degree p)"
   474   by (induct p) (auto simp add: cCons_def)
   475 
   476 lemma [code abstract]:
   477   "coeffs 0 = []"
   478   by (fact coeffs_0_eq_Nil)
   479 
   480 lemma [code abstract]:
   481   "coeffs (pCons a p) = a ## coeffs p"
   482   by (fact coeffs_pCons_eq_cCons)
   483 
   484 instantiation poly :: ("{zero, equal}") equal
   485 begin
   486 
   487 definition
   488   [code]: "HOL.equal (p::'a poly) q \<longleftrightarrow> HOL.equal (coeffs p) (coeffs q)"
   489 
   490 instance proof
   491 qed (simp add: equal equal_poly_def coeffs_eq_iff)
   492 
   493 end
   494 
   495 lemma [code nbe]:
   496   "HOL.equal (p :: _ poly) p \<longleftrightarrow> True"
   497   by (fact equal_refl)
   498 
   499 definition is_zero :: "'a::zero poly \<Rightarrow> bool"
   500 where
   501   [code]: "is_zero p \<longleftrightarrow> List.null (coeffs p)"
   502 
   503 lemma is_zero_null [code_abbrev]:
   504   "is_zero p \<longleftrightarrow> p = 0"
   505   by (simp add: is_zero_def null_def)
   506 
   507 
   508 subsection {* Fold combinator for polynomials *}
   509 
   510 definition fold_coeffs :: "('a::zero \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'a poly \<Rightarrow> 'b \<Rightarrow> 'b"
   511 where
   512   "fold_coeffs f p = foldr f (coeffs p)"
   513 
   514 lemma fold_coeffs_0_eq [simp]:
   515   "fold_coeffs f 0 = id"
   516   by (simp add: fold_coeffs_def)
   517 
   518 lemma fold_coeffs_pCons_eq [simp]:
   519   "f 0 = id \<Longrightarrow> fold_coeffs f (pCons a p) = f a \<circ> fold_coeffs f p"
   520   by (simp add: fold_coeffs_def cCons_def fun_eq_iff)
   521 
   522 lemma fold_coeffs_pCons_0_0_eq [simp]:
   523   "fold_coeffs f (pCons 0 0) = id"
   524   by (simp add: fold_coeffs_def)
   525 
   526 lemma fold_coeffs_pCons_coeff_not_0_eq [simp]:
   527   "a \<noteq> 0 \<Longrightarrow> fold_coeffs f (pCons a p) = f a \<circ> fold_coeffs f p"
   528   by (simp add: fold_coeffs_def)
   529 
   530 lemma fold_coeffs_pCons_not_0_0_eq [simp]:
   531   "p \<noteq> 0 \<Longrightarrow> fold_coeffs f (pCons a p) = f a \<circ> fold_coeffs f p"
   532   by (simp add: fold_coeffs_def)
   533 
   534 
   535 subsection {* Canonical morphism on polynomials -- evaluation *}
   536 
   537 definition poly :: "'a::comm_semiring_0 poly \<Rightarrow> 'a \<Rightarrow> 'a"
   538 where
   539   "poly p = fold_coeffs (\<lambda>a f x. a + x * f x) p (\<lambda>x. 0)" -- {* The Horner Schema *}
   540 
   541 lemma poly_0 [simp]:
   542   "poly 0 x = 0"
   543   by (simp add: poly_def)
   544 
   545 lemma poly_pCons [simp]:
   546   "poly (pCons a p) x = a + x * poly p x"
   547   by (cases "p = 0 \<and> a = 0") (auto simp add: poly_def)
   548 
   549 
   550 subsection {* Monomials *}
   551 
   552 lift_definition monom :: "'a \<Rightarrow> nat \<Rightarrow> 'a::zero poly"
   553   is "\<lambda>a m n. if m = n then a else 0"
   554   by (auto intro!: almost_everywhere_zeroI)
   555 
   556 lemma coeff_monom [simp]:
   557   "coeff (monom a m) n = (if m = n then a else 0)"
   558   by transfer rule
   559 
   560 lemma monom_0:
   561   "monom a 0 = pCons a 0"
   562   by (rule poly_eqI) (simp add: coeff_pCons split: nat.split)
   563 
   564 lemma monom_Suc:
   565   "monom a (Suc n) = pCons 0 (monom a n)"
   566   by (rule poly_eqI) (simp add: coeff_pCons split: nat.split)
   567 
   568 lemma monom_eq_0 [simp]: "monom 0 n = 0"
   569   by (rule poly_eqI) simp
   570 
   571 lemma monom_eq_0_iff [simp]: "monom a n = 0 \<longleftrightarrow> a = 0"
   572   by (simp add: poly_eq_iff)
   573 
   574 lemma monom_eq_iff [simp]: "monom a n = monom b n \<longleftrightarrow> a = b"
   575   by (simp add: poly_eq_iff)
   576 
   577 lemma degree_monom_le: "degree (monom a n) \<le> n"
   578   by (rule degree_le, simp)
   579 
   580 lemma degree_monom_eq: "a \<noteq> 0 \<Longrightarrow> degree (monom a n) = n"
   581   apply (rule order_antisym [OF degree_monom_le])
   582   apply (rule le_degree, simp)
   583   done
   584 
   585 lemma coeffs_monom [code abstract]:
   586   "coeffs (monom a n) = (if a = 0 then [] else replicate n 0 @ [a])"
   587   by (induct n) (simp_all add: monom_0 monom_Suc)
   588 
   589 lemma fold_coeffs_monom [simp]:
   590   "a \<noteq> 0 \<Longrightarrow> fold_coeffs f (monom a n) = f 0 ^^ n \<circ> f a"
   591   by (simp add: fold_coeffs_def coeffs_monom fun_eq_iff)
   592 
   593 lemma poly_monom:
   594   fixes a x :: "'a::{comm_semiring_1}"
   595   shows "poly (monom a n) x = a * x ^ n"
   596   by (cases "a = 0", simp_all)
   597     (induct n, simp_all add: mult.left_commute poly_def)
   598 
   599 
   600 subsection {* Addition and subtraction *}
   601 
   602 instantiation poly :: (comm_monoid_add) comm_monoid_add
   603 begin
   604 
   605 lift_definition plus_poly :: "'a poly \<Rightarrow> 'a poly \<Rightarrow> 'a poly"
   606   is "\<lambda>p q n. coeff p n + coeff q n"
   607 proof (rule almost_everywhere_zeroI) 
   608   fix q p :: "'a poly" and i
   609   assume "max (degree q) (degree p) < i"
   610   then show "coeff p i + coeff q i = 0"
   611     by (simp add: coeff_eq_0)
   612 qed
   613 
   614 lemma coeff_add [simp]:
   615   "coeff (p + q) n = coeff p n + coeff q n"
   616   by (simp add: plus_poly.rep_eq)
   617 
   618 instance proof
   619   fix p q r :: "'a poly"
   620   show "(p + q) + r = p + (q + r)"
   621     by (simp add: poly_eq_iff add_assoc)
   622   show "p + q = q + p"
   623     by (simp add: poly_eq_iff add_commute)
   624   show "0 + p = p"
   625     by (simp add: poly_eq_iff)
   626 qed
   627 
   628 end
   629 
   630 instance poly :: (cancel_comm_monoid_add) cancel_comm_monoid_add
   631 proof
   632   fix p q r :: "'a poly"
   633   assume "p + q = p + r" thus "q = r"
   634     by (simp add: poly_eq_iff)
   635 qed
   636 
   637 instantiation poly :: (ab_group_add) ab_group_add
   638 begin
   639 
   640 lift_definition uminus_poly :: "'a poly \<Rightarrow> 'a poly"
   641   is "\<lambda>p n. - coeff p n"
   642 proof (rule almost_everywhere_zeroI)
   643   fix p :: "'a poly" and i
   644   assume "degree p < i"
   645   then show "- coeff p i = 0"
   646     by (simp add: coeff_eq_0)
   647 qed
   648 
   649 lift_definition minus_poly :: "'a poly \<Rightarrow> 'a poly \<Rightarrow> 'a poly"
   650   is "\<lambda>p q n. coeff p n - coeff q n"
   651 proof (rule almost_everywhere_zeroI) 
   652   fix q p :: "'a poly" and i
   653   assume "max (degree q) (degree p) < i"
   654   then show "coeff p i - coeff q i = 0"
   655     by (simp add: coeff_eq_0)
   656 qed
   657 
   658 lemma coeff_minus [simp]: "coeff (- p) n = - coeff p n"
   659   by (simp add: uminus_poly.rep_eq)
   660 
   661 lemma coeff_diff [simp]:
   662   "coeff (p - q) n = coeff p n - coeff q n"
   663   by (simp add: minus_poly.rep_eq)
   664 
   665 instance proof
   666   fix p q :: "'a poly"
   667   show "- p + p = 0"
   668     by (simp add: poly_eq_iff)
   669   show "p - q = p + - q"
   670     by (simp add: poly_eq_iff)
   671 qed
   672 
   673 end
   674 
   675 lemma add_pCons [simp]:
   676   "pCons a p + pCons b q = pCons (a + b) (p + q)"
   677   by (rule poly_eqI, simp add: coeff_pCons split: nat.split)
   678 
   679 lemma minus_pCons [simp]:
   680   "- pCons a p = pCons (- a) (- p)"
   681   by (rule poly_eqI, simp add: coeff_pCons split: nat.split)
   682 
   683 lemma diff_pCons [simp]:
   684   "pCons a p - pCons b q = pCons (a - b) (p - q)"
   685   by (rule poly_eqI, simp add: coeff_pCons split: nat.split)
   686 
   687 lemma degree_add_le_max: "degree (p + q) \<le> max (degree p) (degree q)"
   688   by (rule degree_le, auto simp add: coeff_eq_0)
   689 
   690 lemma degree_add_le:
   691   "\<lbrakk>degree p \<le> n; degree q \<le> n\<rbrakk> \<Longrightarrow> degree (p + q) \<le> n"
   692   by (auto intro: order_trans degree_add_le_max)
   693 
   694 lemma degree_add_less:
   695   "\<lbrakk>degree p < n; degree q < n\<rbrakk> \<Longrightarrow> degree (p + q) < n"
   696   by (auto intro: le_less_trans degree_add_le_max)
   697 
   698 lemma degree_add_eq_right:
   699   "degree p < degree q \<Longrightarrow> degree (p + q) = degree q"
   700   apply (cases "q = 0", simp)
   701   apply (rule order_antisym)
   702   apply (simp add: degree_add_le)
   703   apply (rule le_degree)
   704   apply (simp add: coeff_eq_0)
   705   done
   706 
   707 lemma degree_add_eq_left:
   708   "degree q < degree p \<Longrightarrow> degree (p + q) = degree p"
   709   using degree_add_eq_right [of q p]
   710   by (simp add: add_commute)
   711 
   712 lemma degree_minus [simp]: "degree (- p) = degree p"
   713   unfolding degree_def by simp
   714 
   715 lemma degree_diff_le_max: "degree (p - q) \<le> max (degree p) (degree q)"
   716   using degree_add_le [where p=p and q="-q"]
   717   by simp
   718 
   719 lemma degree_diff_le:
   720   "\<lbrakk>degree p \<le> n; degree q \<le> n\<rbrakk> \<Longrightarrow> degree (p - q) \<le> n"
   721   using degree_add_le [of p n "- q"] by simp
   722 
   723 lemma degree_diff_less:
   724   "\<lbrakk>degree p < n; degree q < n\<rbrakk> \<Longrightarrow> degree (p - q) < n"
   725   using degree_add_less [of p n "- q"] by simp
   726 
   727 lemma add_monom: "monom a n + monom b n = monom (a + b) n"
   728   by (rule poly_eqI) simp
   729 
   730 lemma diff_monom: "monom a n - monom b n = monom (a - b) n"
   731   by (rule poly_eqI) simp
   732 
   733 lemma minus_monom: "- monom a n = monom (-a) n"
   734   by (rule poly_eqI) simp
   735 
   736 lemma coeff_setsum: "coeff (\<Sum>x\<in>A. p x) i = (\<Sum>x\<in>A. coeff (p x) i)"
   737   by (cases "finite A", induct set: finite, simp_all)
   738 
   739 lemma monom_setsum: "monom (\<Sum>x\<in>A. a x) n = (\<Sum>x\<in>A. monom (a x) n)"
   740   by (rule poly_eqI) (simp add: coeff_setsum)
   741 
   742 fun plus_coeffs :: "'a::comm_monoid_add list \<Rightarrow> 'a list \<Rightarrow> 'a list"
   743 where
   744   "plus_coeffs xs [] = xs"
   745 | "plus_coeffs [] ys = ys"
   746 | "plus_coeffs (x # xs) (y # ys) = (x + y) ## plus_coeffs xs ys"
   747 
   748 lemma coeffs_plus_eq_plus_coeffs [code abstract]:
   749   "coeffs (p + q) = plus_coeffs (coeffs p) (coeffs q)"
   750 proof -
   751   { fix xs ys :: "'a list" and n
   752     have "nth_default 0 (plus_coeffs xs ys) n = nth_default 0 xs n + nth_default 0 ys n"
   753     proof (induct xs ys arbitrary: n rule: plus_coeffs.induct)
   754       case (3 x xs y ys n) then show ?case by (cases n) (auto simp add: cCons_def)
   755     qed simp_all }
   756   note * = this
   757   { fix xs ys :: "'a list"
   758     assume "xs \<noteq> [] \<Longrightarrow> last xs \<noteq> 0" and "ys \<noteq> [] \<Longrightarrow> last ys \<noteq> 0"
   759     moreover assume "plus_coeffs xs ys \<noteq> []"
   760     ultimately have "last (plus_coeffs xs ys) \<noteq> 0"
   761     proof (induct xs ys rule: plus_coeffs.induct)
   762       case (3 x xs y ys) then show ?case by (auto simp add: cCons_def) metis
   763     qed simp_all }
   764   note ** = this
   765   show ?thesis
   766     apply (rule coeffs_eqI)
   767     apply (simp add: * nth_default_coeffs_eq)
   768     apply (rule **)
   769     apply (auto dest: last_coeffs_not_0)
   770     done
   771 qed
   772 
   773 lemma coeffs_uminus [code abstract]:
   774   "coeffs (- p) = map (\<lambda>a. - a) (coeffs p)"
   775   by (rule coeffs_eqI)
   776     (simp_all add: not_0_coeffs_not_Nil last_map last_coeffs_not_0 nth_default_map_eq nth_default_coeffs_eq)
   777 
   778 lemma [code]:
   779   fixes p q :: "'a::ab_group_add poly"
   780   shows "p - q = p + - q"
   781   by simp
   782 
   783 lemma poly_add [simp]: "poly (p + q) x = poly p x + poly q x"
   784   apply (induct p arbitrary: q, simp)
   785   apply (case_tac q, simp, simp add: algebra_simps)
   786   done
   787 
   788 lemma poly_minus [simp]:
   789   fixes x :: "'a::comm_ring"
   790   shows "poly (- p) x = - poly p x"
   791   by (induct p) simp_all
   792 
   793 lemma poly_diff [simp]:
   794   fixes x :: "'a::comm_ring"
   795   shows "poly (p - q) x = poly p x - poly q x"
   796   using poly_add [of p "- q" x] by simp
   797 
   798 lemma poly_setsum: "poly (\<Sum>k\<in>A. p k) x = (\<Sum>k\<in>A. poly (p k) x)"
   799   by (induct A rule: infinite_finite_induct) simp_all
   800 
   801 
   802 subsection {* Multiplication by a constant, polynomial multiplication and the unit polynomial *}
   803 
   804 lift_definition smult :: "'a::comm_semiring_0 \<Rightarrow> 'a poly \<Rightarrow> 'a poly"
   805   is "\<lambda>a p n. a * coeff p n"
   806 proof (rule almost_everywhere_zeroI)
   807   fix a :: 'a and p :: "'a poly" and i
   808   assume "degree p < i"
   809   then show "a * coeff p i = 0"
   810     by (simp add: coeff_eq_0)
   811 qed
   812 
   813 lemma coeff_smult [simp]:
   814   "coeff (smult a p) n = a * coeff p n"
   815   by (simp add: smult.rep_eq)
   816 
   817 lemma degree_smult_le: "degree (smult a p) \<le> degree p"
   818   by (rule degree_le, simp add: coeff_eq_0)
   819 
   820 lemma smult_smult [simp]: "smult a (smult b p) = smult (a * b) p"
   821   by (rule poly_eqI, simp add: mult_assoc)
   822 
   823 lemma smult_0_right [simp]: "smult a 0 = 0"
   824   by (rule poly_eqI, simp)
   825 
   826 lemma smult_0_left [simp]: "smult 0 p = 0"
   827   by (rule poly_eqI, simp)
   828 
   829 lemma smult_1_left [simp]: "smult (1::'a::comm_semiring_1) p = p"
   830   by (rule poly_eqI, simp)
   831 
   832 lemma smult_add_right:
   833   "smult a (p + q) = smult a p + smult a q"
   834   by (rule poly_eqI, simp add: algebra_simps)
   835 
   836 lemma smult_add_left:
   837   "smult (a + b) p = smult a p + smult b p"
   838   by (rule poly_eqI, simp add: algebra_simps)
   839 
   840 lemma smult_minus_right [simp]:
   841   "smult (a::'a::comm_ring) (- p) = - smult a p"
   842   by (rule poly_eqI, simp)
   843 
   844 lemma smult_minus_left [simp]:
   845   "smult (- a::'a::comm_ring) p = - smult a p"
   846   by (rule poly_eqI, simp)
   847 
   848 lemma smult_diff_right:
   849   "smult (a::'a::comm_ring) (p - q) = smult a p - smult a q"
   850   by (rule poly_eqI, simp add: algebra_simps)
   851 
   852 lemma smult_diff_left:
   853   "smult (a - b::'a::comm_ring) p = smult a p - smult b p"
   854   by (rule poly_eqI, simp add: algebra_simps)
   855 
   856 lemmas smult_distribs =
   857   smult_add_left smult_add_right
   858   smult_diff_left smult_diff_right
   859 
   860 lemma smult_pCons [simp]:
   861   "smult a (pCons b p) = pCons (a * b) (smult a p)"
   862   by (rule poly_eqI, simp add: coeff_pCons split: nat.split)
   863 
   864 lemma smult_monom: "smult a (monom b n) = monom (a * b) n"
   865   by (induct n, simp add: monom_0, simp add: monom_Suc)
   866 
   867 lemma degree_smult_eq [simp]:
   868   fixes a :: "'a::idom"
   869   shows "degree (smult a p) = (if a = 0 then 0 else degree p)"
   870   by (cases "a = 0", simp, simp add: degree_def)
   871 
   872 lemma smult_eq_0_iff [simp]:
   873   fixes a :: "'a::idom"
   874   shows "smult a p = 0 \<longleftrightarrow> a = 0 \<or> p = 0"
   875   by (simp add: poly_eq_iff)
   876 
   877 lemma coeffs_smult [code abstract]:
   878   fixes p :: "'a::idom poly"
   879   shows "coeffs (smult a p) = (if a = 0 then [] else map (Groups.times a) (coeffs p))"
   880   by (rule coeffs_eqI)
   881     (auto simp add: not_0_coeffs_not_Nil last_map last_coeffs_not_0 nth_default_map_eq nth_default_coeffs_eq)
   882 
   883 instantiation poly :: (comm_semiring_0) comm_semiring_0
   884 begin
   885 
   886 definition
   887   "p * q = fold_coeffs (\<lambda>a p. smult a q + pCons 0 p) p 0"
   888 
   889 lemma mult_poly_0_left: "(0::'a poly) * q = 0"
   890   by (simp add: times_poly_def)
   891 
   892 lemma mult_pCons_left [simp]:
   893   "pCons a p * q = smult a q + pCons 0 (p * q)"
   894   by (cases "p = 0 \<and> a = 0") (auto simp add: times_poly_def)
   895 
   896 lemma mult_poly_0_right: "p * (0::'a poly) = 0"
   897   by (induct p) (simp add: mult_poly_0_left, simp)
   898 
   899 lemma mult_pCons_right [simp]:
   900   "p * pCons a q = smult a p + pCons 0 (p * q)"
   901   by (induct p) (simp add: mult_poly_0_left, simp add: algebra_simps)
   902 
   903 lemmas mult_poly_0 = mult_poly_0_left mult_poly_0_right
   904 
   905 lemma mult_smult_left [simp]:
   906   "smult a p * q = smult a (p * q)"
   907   by (induct p) (simp add: mult_poly_0, simp add: smult_add_right)
   908 
   909 lemma mult_smult_right [simp]:
   910   "p * smult a q = smult a (p * q)"
   911   by (induct q) (simp add: mult_poly_0, simp add: smult_add_right)
   912 
   913 lemma mult_poly_add_left:
   914   fixes p q r :: "'a poly"
   915   shows "(p + q) * r = p * r + q * r"
   916   by (induct r) (simp add: mult_poly_0, simp add: smult_distribs algebra_simps)
   917 
   918 instance proof
   919   fix p q r :: "'a poly"
   920   show 0: "0 * p = 0"
   921     by (rule mult_poly_0_left)
   922   show "p * 0 = 0"
   923     by (rule mult_poly_0_right)
   924   show "(p + q) * r = p * r + q * r"
   925     by (rule mult_poly_add_left)
   926   show "(p * q) * r = p * (q * r)"
   927     by (induct p, simp add: mult_poly_0, simp add: mult_poly_add_left)
   928   show "p * q = q * p"
   929     by (induct p, simp add: mult_poly_0, simp)
   930 qed
   931 
   932 end
   933 
   934 instance poly :: (comm_semiring_0_cancel) comm_semiring_0_cancel ..
   935 
   936 lemma coeff_mult:
   937   "coeff (p * q) n = (\<Sum>i\<le>n. coeff p i * coeff q (n-i))"
   938 proof (induct p arbitrary: n)
   939   case 0 show ?case by simp
   940 next
   941   case (pCons a p n) thus ?case
   942     by (cases n, simp, simp add: setsum_atMost_Suc_shift
   943                             del: setsum_atMost_Suc)
   944 qed
   945 
   946 lemma degree_mult_le: "degree (p * q) \<le> degree p + degree q"
   947 apply (rule degree_le)
   948 apply (induct p)
   949 apply simp
   950 apply (simp add: coeff_eq_0 coeff_pCons split: nat.split)
   951 done
   952 
   953 lemma mult_monom: "monom a m * monom b n = monom (a * b) (m + n)"
   954   by (induct m, simp add: monom_0 smult_monom, simp add: monom_Suc)
   955 
   956 instantiation poly :: (comm_semiring_1) comm_semiring_1
   957 begin
   958 
   959 definition one_poly_def:
   960   "1 = pCons 1 0"
   961 
   962 instance proof
   963   fix p :: "'a poly" show "1 * p = p"
   964     unfolding one_poly_def by simp
   965 next
   966   show "0 \<noteq> (1::'a poly)"
   967     unfolding one_poly_def by simp
   968 qed
   969 
   970 end
   971 
   972 instance poly :: (comm_semiring_1_cancel) comm_semiring_1_cancel ..
   973 
   974 instance poly :: (comm_ring) comm_ring ..
   975 
   976 instance poly :: (comm_ring_1) comm_ring_1 ..
   977 
   978 lemma coeff_1 [simp]: "coeff 1 n = (if n = 0 then 1 else 0)"
   979   unfolding one_poly_def
   980   by (simp add: coeff_pCons split: nat.split)
   981 
   982 lemma degree_1 [simp]: "degree 1 = 0"
   983   unfolding one_poly_def
   984   by (rule degree_pCons_0)
   985 
   986 lemma coeffs_1_eq [simp, code abstract]:
   987   "coeffs 1 = [1]"
   988   by (simp add: one_poly_def)
   989 
   990 lemma degree_power_le:
   991   "degree (p ^ n) \<le> degree p * n"
   992   by (induct n) (auto intro: order_trans degree_mult_le)
   993 
   994 lemma poly_smult [simp]:
   995   "poly (smult a p) x = a * poly p x"
   996   by (induct p, simp, simp add: algebra_simps)
   997 
   998 lemma poly_mult [simp]:
   999   "poly (p * q) x = poly p x * poly q x"
  1000   by (induct p, simp_all, simp add: algebra_simps)
  1001 
  1002 lemma poly_1 [simp]:
  1003   "poly 1 x = 1"
  1004   by (simp add: one_poly_def)
  1005 
  1006 lemma poly_power [simp]:
  1007   fixes p :: "'a::{comm_semiring_1} poly"
  1008   shows "poly (p ^ n) x = poly p x ^ n"
  1009   by (induct n) simp_all
  1010 
  1011 
  1012 subsection {* Lemmas about divisibility *}
  1013 
  1014 lemma dvd_smult: "p dvd q \<Longrightarrow> p dvd smult a q"
  1015 proof -
  1016   assume "p dvd q"
  1017   then obtain k where "q = p * k" ..
  1018   then have "smult a q = p * smult a k" by simp
  1019   then show "p dvd smult a q" ..
  1020 qed
  1021 
  1022 lemma dvd_smult_cancel:
  1023   fixes a :: "'a::field"
  1024   shows "p dvd smult a q \<Longrightarrow> a \<noteq> 0 \<Longrightarrow> p dvd q"
  1025   by (drule dvd_smult [where a="inverse a"]) simp
  1026 
  1027 lemma dvd_smult_iff:
  1028   fixes a :: "'a::field"
  1029   shows "a \<noteq> 0 \<Longrightarrow> p dvd smult a q \<longleftrightarrow> p dvd q"
  1030   by (safe elim!: dvd_smult dvd_smult_cancel)
  1031 
  1032 lemma smult_dvd_cancel:
  1033   "smult a p dvd q \<Longrightarrow> p dvd q"
  1034 proof -
  1035   assume "smult a p dvd q"
  1036   then obtain k where "q = smult a p * k" ..
  1037   then have "q = p * smult a k" by simp
  1038   then show "p dvd q" ..
  1039 qed
  1040 
  1041 lemma smult_dvd:
  1042   fixes a :: "'a::field"
  1043   shows "p dvd q \<Longrightarrow> a \<noteq> 0 \<Longrightarrow> smult a p dvd q"
  1044   by (rule smult_dvd_cancel [where a="inverse a"]) simp
  1045 
  1046 lemma smult_dvd_iff:
  1047   fixes a :: "'a::field"
  1048   shows "smult a p dvd q \<longleftrightarrow> (if a = 0 then q = 0 else p dvd q)"
  1049   by (auto elim: smult_dvd smult_dvd_cancel)
  1050 
  1051 
  1052 subsection {* Polynomials form an integral domain *}
  1053 
  1054 lemma coeff_mult_degree_sum:
  1055   "coeff (p * q) (degree p + degree q) =
  1056    coeff p (degree p) * coeff q (degree q)"
  1057   by (induct p, simp, simp add: coeff_eq_0)
  1058 
  1059 instance poly :: (idom) idom
  1060 proof
  1061   fix p q :: "'a poly"
  1062   assume "p \<noteq> 0" and "q \<noteq> 0"
  1063   have "coeff (p * q) (degree p + degree q) =
  1064         coeff p (degree p) * coeff q (degree q)"
  1065     by (rule coeff_mult_degree_sum)
  1066   also have "coeff p (degree p) * coeff q (degree q) \<noteq> 0"
  1067     using `p \<noteq> 0` and `q \<noteq> 0` by simp
  1068   finally have "\<exists>n. coeff (p * q) n \<noteq> 0" ..
  1069   thus "p * q \<noteq> 0" by (simp add: poly_eq_iff)
  1070 qed
  1071 
  1072 lemma degree_mult_eq:
  1073   fixes p q :: "'a::idom poly"
  1074   shows "\<lbrakk>p \<noteq> 0; q \<noteq> 0\<rbrakk> \<Longrightarrow> degree (p * q) = degree p + degree q"
  1075 apply (rule order_antisym [OF degree_mult_le le_degree])
  1076 apply (simp add: coeff_mult_degree_sum)
  1077 done
  1078 
  1079 lemma dvd_imp_degree_le:
  1080   fixes p q :: "'a::idom poly"
  1081   shows "\<lbrakk>p dvd q; q \<noteq> 0\<rbrakk> \<Longrightarrow> degree p \<le> degree q"
  1082   by (erule dvdE, simp add: degree_mult_eq)
  1083 
  1084 
  1085 subsection {* Polynomials form an ordered integral domain *}
  1086 
  1087 definition pos_poly :: "'a::linordered_idom poly \<Rightarrow> bool"
  1088 where
  1089   "pos_poly p \<longleftrightarrow> 0 < coeff p (degree p)"
  1090 
  1091 lemma pos_poly_pCons:
  1092   "pos_poly (pCons a p) \<longleftrightarrow> pos_poly p \<or> (p = 0 \<and> 0 < a)"
  1093   unfolding pos_poly_def by simp
  1094 
  1095 lemma not_pos_poly_0 [simp]: "\<not> pos_poly 0"
  1096   unfolding pos_poly_def by simp
  1097 
  1098 lemma pos_poly_add: "\<lbrakk>pos_poly p; pos_poly q\<rbrakk> \<Longrightarrow> pos_poly (p + q)"
  1099   apply (induct p arbitrary: q, simp)
  1100   apply (case_tac q, force simp add: pos_poly_pCons add_pos_pos)
  1101   done
  1102 
  1103 lemma pos_poly_mult: "\<lbrakk>pos_poly p; pos_poly q\<rbrakk> \<Longrightarrow> pos_poly (p * q)"
  1104   unfolding pos_poly_def
  1105   apply (subgoal_tac "p \<noteq> 0 \<and> q \<noteq> 0")
  1106   apply (simp add: degree_mult_eq coeff_mult_degree_sum mult_pos_pos)
  1107   apply auto
  1108   done
  1109 
  1110 lemma pos_poly_total: "p = 0 \<or> pos_poly p \<or> pos_poly (- p)"
  1111 by (induct p) (auto simp add: pos_poly_pCons)
  1112 
  1113 lemma last_coeffs_eq_coeff_degree:
  1114   "p \<noteq> 0 \<Longrightarrow> last (coeffs p) = coeff p (degree p)"
  1115   by (simp add: coeffs_def)
  1116 
  1117 lemma pos_poly_coeffs [code]:
  1118   "pos_poly p \<longleftrightarrow> (let as = coeffs p in as \<noteq> [] \<and> last as > 0)" (is "?P \<longleftrightarrow> ?Q")
  1119 proof
  1120   assume ?Q then show ?P by (auto simp add: pos_poly_def last_coeffs_eq_coeff_degree)
  1121 next
  1122   assume ?P then have *: "0 < coeff p (degree p)" by (simp add: pos_poly_def)
  1123   then have "p \<noteq> 0" by auto
  1124   with * show ?Q by (simp add: last_coeffs_eq_coeff_degree)
  1125 qed
  1126 
  1127 instantiation poly :: (linordered_idom) linordered_idom
  1128 begin
  1129 
  1130 definition
  1131   "x < y \<longleftrightarrow> pos_poly (y - x)"
  1132 
  1133 definition
  1134   "x \<le> y \<longleftrightarrow> x = y \<or> pos_poly (y - x)"
  1135 
  1136 definition
  1137   "abs (x::'a poly) = (if x < 0 then - x else x)"
  1138 
  1139 definition
  1140   "sgn (x::'a poly) = (if x = 0 then 0 else if 0 < x then 1 else - 1)"
  1141 
  1142 instance proof
  1143   fix x y :: "'a poly"
  1144   show "x < y \<longleftrightarrow> x \<le> y \<and> \<not> y \<le> x"
  1145     unfolding less_eq_poly_def less_poly_def
  1146     apply safe
  1147     apply simp
  1148     apply (drule (1) pos_poly_add)
  1149     apply simp
  1150     done
  1151 next
  1152   fix x :: "'a poly" show "x \<le> x"
  1153     unfolding less_eq_poly_def by simp
  1154 next
  1155   fix x y z :: "'a poly"
  1156   assume "x \<le> y" and "y \<le> z" thus "x \<le> z"
  1157     unfolding less_eq_poly_def
  1158     apply safe
  1159     apply (drule (1) pos_poly_add)
  1160     apply (simp add: algebra_simps)
  1161     done
  1162 next
  1163   fix x y :: "'a poly"
  1164   assume "x \<le> y" and "y \<le> x" thus "x = y"
  1165     unfolding less_eq_poly_def
  1166     apply safe
  1167     apply (drule (1) pos_poly_add)
  1168     apply simp
  1169     done
  1170 next
  1171   fix x y z :: "'a poly"
  1172   assume "x \<le> y" thus "z + x \<le> z + y"
  1173     unfolding less_eq_poly_def
  1174     apply safe
  1175     apply (simp add: algebra_simps)
  1176     done
  1177 next
  1178   fix x y :: "'a poly"
  1179   show "x \<le> y \<or> y \<le> x"
  1180     unfolding less_eq_poly_def
  1181     using pos_poly_total [of "x - y"]
  1182     by auto
  1183 next
  1184   fix x y z :: "'a poly"
  1185   assume "x < y" and "0 < z"
  1186   thus "z * x < z * y"
  1187     unfolding less_poly_def
  1188     by (simp add: right_diff_distrib [symmetric] pos_poly_mult)
  1189 next
  1190   fix x :: "'a poly"
  1191   show "\<bar>x\<bar> = (if x < 0 then - x else x)"
  1192     by (rule abs_poly_def)
  1193 next
  1194   fix x :: "'a poly"
  1195   show "sgn x = (if x = 0 then 0 else if 0 < x then 1 else - 1)"
  1196     by (rule sgn_poly_def)
  1197 qed
  1198 
  1199 end
  1200 
  1201 text {* TODO: Simplification rules for comparisons *}
  1202 
  1203 
  1204 subsection {* Synthetic division and polynomial roots *}
  1205 
  1206 text {*
  1207   Synthetic division is simply division by the linear polynomial @{term "x - c"}.
  1208 *}
  1209 
  1210 definition synthetic_divmod :: "'a::comm_semiring_0 poly \<Rightarrow> 'a \<Rightarrow> 'a poly \<times> 'a"
  1211 where
  1212   "synthetic_divmod p c = fold_coeffs (\<lambda>a (q, r). (pCons r q, a + c * r)) p (0, 0)"
  1213 
  1214 definition synthetic_div :: "'a::comm_semiring_0 poly \<Rightarrow> 'a \<Rightarrow> 'a poly"
  1215 where
  1216   "synthetic_div p c = fst (synthetic_divmod p c)"
  1217 
  1218 lemma synthetic_divmod_0 [simp]:
  1219   "synthetic_divmod 0 c = (0, 0)"
  1220   by (simp add: synthetic_divmod_def)
  1221 
  1222 lemma synthetic_divmod_pCons [simp]:
  1223   "synthetic_divmod (pCons a p) c = (\<lambda>(q, r). (pCons r q, a + c * r)) (synthetic_divmod p c)"
  1224   by (cases "p = 0 \<and> a = 0") (auto simp add: synthetic_divmod_def)
  1225 
  1226 lemma synthetic_div_0 [simp]:
  1227   "synthetic_div 0 c = 0"
  1228   unfolding synthetic_div_def by simp
  1229 
  1230 lemma synthetic_div_unique_lemma: "smult c p = pCons a p \<Longrightarrow> p = 0"
  1231 by (induct p arbitrary: a) simp_all
  1232 
  1233 lemma snd_synthetic_divmod:
  1234   "snd (synthetic_divmod p c) = poly p c"
  1235   by (induct p, simp, simp add: split_def)
  1236 
  1237 lemma synthetic_div_pCons [simp]:
  1238   "synthetic_div (pCons a p) c = pCons (poly p c) (synthetic_div p c)"
  1239   unfolding synthetic_div_def
  1240   by (simp add: split_def snd_synthetic_divmod)
  1241 
  1242 lemma synthetic_div_eq_0_iff:
  1243   "synthetic_div p c = 0 \<longleftrightarrow> degree p = 0"
  1244   by (induct p, simp, case_tac p, simp)
  1245 
  1246 lemma degree_synthetic_div:
  1247   "degree (synthetic_div p c) = degree p - 1"
  1248   by (induct p, simp, simp add: synthetic_div_eq_0_iff)
  1249 
  1250 lemma synthetic_div_correct:
  1251   "p + smult c (synthetic_div p c) = pCons (poly p c) (synthetic_div p c)"
  1252   by (induct p) simp_all
  1253 
  1254 lemma synthetic_div_unique:
  1255   "p + smult c q = pCons r q \<Longrightarrow> r = poly p c \<and> q = synthetic_div p c"
  1256 apply (induct p arbitrary: q r)
  1257 apply (simp, frule synthetic_div_unique_lemma, simp)
  1258 apply (case_tac q, force)
  1259 done
  1260 
  1261 lemma synthetic_div_correct':
  1262   fixes c :: "'a::comm_ring_1"
  1263   shows "[:-c, 1:] * synthetic_div p c + [:poly p c:] = p"
  1264   using synthetic_div_correct [of p c]
  1265   by (simp add: algebra_simps)
  1266 
  1267 lemma poly_eq_0_iff_dvd:
  1268   fixes c :: "'a::idom"
  1269   shows "poly p c = 0 \<longleftrightarrow> [:-c, 1:] dvd p"
  1270 proof
  1271   assume "poly p c = 0"
  1272   with synthetic_div_correct' [of c p]
  1273   have "p = [:-c, 1:] * synthetic_div p c" by simp
  1274   then show "[:-c, 1:] dvd p" ..
  1275 next
  1276   assume "[:-c, 1:] dvd p"
  1277   then obtain k where "p = [:-c, 1:] * k" by (rule dvdE)
  1278   then show "poly p c = 0" by simp
  1279 qed
  1280 
  1281 lemma dvd_iff_poly_eq_0:
  1282   fixes c :: "'a::idom"
  1283   shows "[:c, 1:] dvd p \<longleftrightarrow> poly p (-c) = 0"
  1284   by (simp add: poly_eq_0_iff_dvd)
  1285 
  1286 lemma poly_roots_finite:
  1287   fixes p :: "'a::idom poly"
  1288   shows "p \<noteq> 0 \<Longrightarrow> finite {x. poly p x = 0}"
  1289 proof (induct n \<equiv> "degree p" arbitrary: p)
  1290   case (0 p)
  1291   then obtain a where "a \<noteq> 0" and "p = [:a:]"
  1292     by (cases p, simp split: if_splits)
  1293   then show "finite {x. poly p x = 0}" by simp
  1294 next
  1295   case (Suc n p)
  1296   show "finite {x. poly p x = 0}"
  1297   proof (cases "\<exists>x. poly p x = 0")
  1298     case False
  1299     then show "finite {x. poly p x = 0}" by simp
  1300   next
  1301     case True
  1302     then obtain a where "poly p a = 0" ..
  1303     then have "[:-a, 1:] dvd p" by (simp only: poly_eq_0_iff_dvd)
  1304     then obtain k where k: "p = [:-a, 1:] * k" ..
  1305     with `p \<noteq> 0` have "k \<noteq> 0" by auto
  1306     with k have "degree p = Suc (degree k)"
  1307       by (simp add: degree_mult_eq del: mult_pCons_left)
  1308     with `Suc n = degree p` have "n = degree k" by simp
  1309     then have "finite {x. poly k x = 0}" using `k \<noteq> 0` by (rule Suc.hyps)
  1310     then have "finite (insert a {x. poly k x = 0})" by simp
  1311     then show "finite {x. poly p x = 0}"
  1312       by (simp add: k uminus_add_conv_diff Collect_disj_eq
  1313                del: mult_pCons_left)
  1314   qed
  1315 qed
  1316 
  1317 lemma poly_eq_poly_eq_iff:
  1318   fixes p q :: "'a::{idom,ring_char_0} poly"
  1319   shows "poly p = poly q \<longleftrightarrow> p = q" (is "?P \<longleftrightarrow> ?Q")
  1320 proof
  1321   assume ?Q then show ?P by simp
  1322 next
  1323   { fix p :: "'a::{idom,ring_char_0} poly"
  1324     have "poly p = poly 0 \<longleftrightarrow> p = 0"
  1325       apply (cases "p = 0", simp_all)
  1326       apply (drule poly_roots_finite)
  1327       apply (auto simp add: infinite_UNIV_char_0)
  1328       done
  1329   } note this [of "p - q"]
  1330   moreover assume ?P
  1331   ultimately show ?Q by auto
  1332 qed
  1333 
  1334 lemma poly_all_0_iff_0:
  1335   fixes p :: "'a::{ring_char_0, idom} poly"
  1336   shows "(\<forall>x. poly p x = 0) \<longleftrightarrow> p = 0"
  1337   by (auto simp add: poly_eq_poly_eq_iff [symmetric])
  1338 
  1339 
  1340 subsection {* Long division of polynomials *}
  1341 
  1342 definition pdivmod_rel :: "'a::field poly \<Rightarrow> 'a poly \<Rightarrow> 'a poly \<Rightarrow> 'a poly \<Rightarrow> bool"
  1343 where
  1344   "pdivmod_rel x y q r \<longleftrightarrow>
  1345     x = q * y + r \<and> (if y = 0 then q = 0 else r = 0 \<or> degree r < degree y)"
  1346 
  1347 lemma pdivmod_rel_0:
  1348   "pdivmod_rel 0 y 0 0"
  1349   unfolding pdivmod_rel_def by simp
  1350 
  1351 lemma pdivmod_rel_by_0:
  1352   "pdivmod_rel x 0 0 x"
  1353   unfolding pdivmod_rel_def by simp
  1354 
  1355 lemma eq_zero_or_degree_less:
  1356   assumes "degree p \<le> n" and "coeff p n = 0"
  1357   shows "p = 0 \<or> degree p < n"
  1358 proof (cases n)
  1359   case 0
  1360   with `degree p \<le> n` and `coeff p n = 0`
  1361   have "coeff p (degree p) = 0" by simp
  1362   then have "p = 0" by simp
  1363   then show ?thesis ..
  1364 next
  1365   case (Suc m)
  1366   have "\<forall>i>n. coeff p i = 0"
  1367     using `degree p \<le> n` by (simp add: coeff_eq_0)
  1368   then have "\<forall>i\<ge>n. coeff p i = 0"
  1369     using `coeff p n = 0` by (simp add: le_less)
  1370   then have "\<forall>i>m. coeff p i = 0"
  1371     using `n = Suc m` by (simp add: less_eq_Suc_le)
  1372   then have "degree p \<le> m"
  1373     by (rule degree_le)
  1374   then have "degree p < n"
  1375     using `n = Suc m` by (simp add: less_Suc_eq_le)
  1376   then show ?thesis ..
  1377 qed
  1378 
  1379 lemma pdivmod_rel_pCons:
  1380   assumes rel: "pdivmod_rel x y q r"
  1381   assumes y: "y \<noteq> 0"
  1382   assumes b: "b = coeff (pCons a r) (degree y) / coeff y (degree y)"
  1383   shows "pdivmod_rel (pCons a x) y (pCons b q) (pCons a r - smult b y)"
  1384     (is "pdivmod_rel ?x y ?q ?r")
  1385 proof -
  1386   have x: "x = q * y + r" and r: "r = 0 \<or> degree r < degree y"
  1387     using assms unfolding pdivmod_rel_def by simp_all
  1388 
  1389   have 1: "?x = ?q * y + ?r"
  1390     using b x by simp
  1391 
  1392   have 2: "?r = 0 \<or> degree ?r < degree y"
  1393   proof (rule eq_zero_or_degree_less)
  1394     show "degree ?r \<le> degree y"
  1395     proof (rule degree_diff_le)
  1396       show "degree (pCons a r) \<le> degree y"
  1397         using r by auto
  1398       show "degree (smult b y) \<le> degree y"
  1399         by (rule degree_smult_le)
  1400     qed
  1401   next
  1402     show "coeff ?r (degree y) = 0"
  1403       using `y \<noteq> 0` unfolding b by simp
  1404   qed
  1405 
  1406   from 1 2 show ?thesis
  1407     unfolding pdivmod_rel_def
  1408     using `y \<noteq> 0` by simp
  1409 qed
  1410 
  1411 lemma pdivmod_rel_exists: "\<exists>q r. pdivmod_rel x y q r"
  1412 apply (cases "y = 0")
  1413 apply (fast intro!: pdivmod_rel_by_0)
  1414 apply (induct x)
  1415 apply (fast intro!: pdivmod_rel_0)
  1416 apply (fast intro!: pdivmod_rel_pCons)
  1417 done
  1418 
  1419 lemma pdivmod_rel_unique:
  1420   assumes 1: "pdivmod_rel x y q1 r1"
  1421   assumes 2: "pdivmod_rel x y q2 r2"
  1422   shows "q1 = q2 \<and> r1 = r2"
  1423 proof (cases "y = 0")
  1424   assume "y = 0" with assms show ?thesis
  1425     by (simp add: pdivmod_rel_def)
  1426 next
  1427   assume [simp]: "y \<noteq> 0"
  1428   from 1 have q1: "x = q1 * y + r1" and r1: "r1 = 0 \<or> degree r1 < degree y"
  1429     unfolding pdivmod_rel_def by simp_all
  1430   from 2 have q2: "x = q2 * y + r2" and r2: "r2 = 0 \<or> degree r2 < degree y"
  1431     unfolding pdivmod_rel_def by simp_all
  1432   from q1 q2 have q3: "(q1 - q2) * y = r2 - r1"
  1433     by (simp add: algebra_simps)
  1434   from r1 r2 have r3: "(r2 - r1) = 0 \<or> degree (r2 - r1) < degree y"
  1435     by (auto intro: degree_diff_less)
  1436 
  1437   show "q1 = q2 \<and> r1 = r2"
  1438   proof (rule ccontr)
  1439     assume "\<not> (q1 = q2 \<and> r1 = r2)"
  1440     with q3 have "q1 \<noteq> q2" and "r1 \<noteq> r2" by auto
  1441     with r3 have "degree (r2 - r1) < degree y" by simp
  1442     also have "degree y \<le> degree (q1 - q2) + degree y" by simp
  1443     also have "\<dots> = degree ((q1 - q2) * y)"
  1444       using `q1 \<noteq> q2` by (simp add: degree_mult_eq)
  1445     also have "\<dots> = degree (r2 - r1)"
  1446       using q3 by simp
  1447     finally have "degree (r2 - r1) < degree (r2 - r1)" .
  1448     then show "False" by simp
  1449   qed
  1450 qed
  1451 
  1452 lemma pdivmod_rel_0_iff: "pdivmod_rel 0 y q r \<longleftrightarrow> q = 0 \<and> r = 0"
  1453 by (auto dest: pdivmod_rel_unique intro: pdivmod_rel_0)
  1454 
  1455 lemma pdivmod_rel_by_0_iff: "pdivmod_rel x 0 q r \<longleftrightarrow> q = 0 \<and> r = x"
  1456 by (auto dest: pdivmod_rel_unique intro: pdivmod_rel_by_0)
  1457 
  1458 lemmas pdivmod_rel_unique_div = pdivmod_rel_unique [THEN conjunct1]
  1459 
  1460 lemmas pdivmod_rel_unique_mod = pdivmod_rel_unique [THEN conjunct2]
  1461 
  1462 instantiation poly :: (field) ring_div
  1463 begin
  1464 
  1465 definition div_poly where
  1466   "x div y = (THE q. \<exists>r. pdivmod_rel x y q r)"
  1467 
  1468 definition mod_poly where
  1469   "x mod y = (THE r. \<exists>q. pdivmod_rel x y q r)"
  1470 
  1471 lemma div_poly_eq:
  1472   "pdivmod_rel x y q r \<Longrightarrow> x div y = q"
  1473 unfolding div_poly_def
  1474 by (fast elim: pdivmod_rel_unique_div)
  1475 
  1476 lemma mod_poly_eq:
  1477   "pdivmod_rel x y q r \<Longrightarrow> x mod y = r"
  1478 unfolding mod_poly_def
  1479 by (fast elim: pdivmod_rel_unique_mod)
  1480 
  1481 lemma pdivmod_rel:
  1482   "pdivmod_rel x y (x div y) (x mod y)"
  1483 proof -
  1484   from pdivmod_rel_exists
  1485     obtain q r where "pdivmod_rel x y q r" by fast
  1486   thus ?thesis
  1487     by (simp add: div_poly_eq mod_poly_eq)
  1488 qed
  1489 
  1490 instance proof
  1491   fix x y :: "'a poly"
  1492   show "x div y * y + x mod y = x"
  1493     using pdivmod_rel [of x y]
  1494     by (simp add: pdivmod_rel_def)
  1495 next
  1496   fix x :: "'a poly"
  1497   have "pdivmod_rel x 0 0 x"
  1498     by (rule pdivmod_rel_by_0)
  1499   thus "x div 0 = 0"
  1500     by (rule div_poly_eq)
  1501 next
  1502   fix y :: "'a poly"
  1503   have "pdivmod_rel 0 y 0 0"
  1504     by (rule pdivmod_rel_0)
  1505   thus "0 div y = 0"
  1506     by (rule div_poly_eq)
  1507 next
  1508   fix x y z :: "'a poly"
  1509   assume "y \<noteq> 0"
  1510   hence "pdivmod_rel (x + z * y) y (z + x div y) (x mod y)"
  1511     using pdivmod_rel [of x y]
  1512     by (simp add: pdivmod_rel_def distrib_right)
  1513   thus "(x + z * y) div y = z + x div y"
  1514     by (rule div_poly_eq)
  1515 next
  1516   fix x y z :: "'a poly"
  1517   assume "x \<noteq> 0"
  1518   show "(x * y) div (x * z) = y div z"
  1519   proof (cases "y \<noteq> 0 \<and> z \<noteq> 0")
  1520     have "\<And>x::'a poly. pdivmod_rel x 0 0 x"
  1521       by (rule pdivmod_rel_by_0)
  1522     then have [simp]: "\<And>x::'a poly. x div 0 = 0"
  1523       by (rule div_poly_eq)
  1524     have "\<And>x::'a poly. pdivmod_rel 0 x 0 0"
  1525       by (rule pdivmod_rel_0)
  1526     then have [simp]: "\<And>x::'a poly. 0 div x = 0"
  1527       by (rule div_poly_eq)
  1528     case False then show ?thesis by auto
  1529   next
  1530     case True then have "y \<noteq> 0" and "z \<noteq> 0" by auto
  1531     with `x \<noteq> 0`
  1532     have "\<And>q r. pdivmod_rel y z q r \<Longrightarrow> pdivmod_rel (x * y) (x * z) q (x * r)"
  1533       by (auto simp add: pdivmod_rel_def algebra_simps)
  1534         (rule classical, simp add: degree_mult_eq)
  1535     moreover from pdivmod_rel have "pdivmod_rel y z (y div z) (y mod z)" .
  1536     ultimately have "pdivmod_rel (x * y) (x * z) (y div z) (x * (y mod z))" .
  1537     then show ?thesis by (simp add: div_poly_eq)
  1538   qed
  1539 qed
  1540 
  1541 end
  1542 
  1543 lemma degree_mod_less:
  1544   "y \<noteq> 0 \<Longrightarrow> x mod y = 0 \<or> degree (x mod y) < degree y"
  1545   using pdivmod_rel [of x y]
  1546   unfolding pdivmod_rel_def by simp
  1547 
  1548 lemma div_poly_less: "degree x < degree y \<Longrightarrow> x div y = 0"
  1549 proof -
  1550   assume "degree x < degree y"
  1551   hence "pdivmod_rel x y 0 x"
  1552     by (simp add: pdivmod_rel_def)
  1553   thus "x div y = 0" by (rule div_poly_eq)
  1554 qed
  1555 
  1556 lemma mod_poly_less: "degree x < degree y \<Longrightarrow> x mod y = x"
  1557 proof -
  1558   assume "degree x < degree y"
  1559   hence "pdivmod_rel x y 0 x"
  1560     by (simp add: pdivmod_rel_def)
  1561   thus "x mod y = x" by (rule mod_poly_eq)
  1562 qed
  1563 
  1564 lemma pdivmod_rel_smult_left:
  1565   "pdivmod_rel x y q r
  1566     \<Longrightarrow> pdivmod_rel (smult a x) y (smult a q) (smult a r)"
  1567   unfolding pdivmod_rel_def by (simp add: smult_add_right)
  1568 
  1569 lemma div_smult_left: "(smult a x) div y = smult a (x div y)"
  1570   by (rule div_poly_eq, rule pdivmod_rel_smult_left, rule pdivmod_rel)
  1571 
  1572 lemma mod_smult_left: "(smult a x) mod y = smult a (x mod y)"
  1573   by (rule mod_poly_eq, rule pdivmod_rel_smult_left, rule pdivmod_rel)
  1574 
  1575 lemma poly_div_minus_left [simp]:
  1576   fixes x y :: "'a::field poly"
  1577   shows "(- x) div y = - (x div y)"
  1578   using div_smult_left [of "- 1::'a"] by simp
  1579 
  1580 lemma poly_mod_minus_left [simp]:
  1581   fixes x y :: "'a::field poly"
  1582   shows "(- x) mod y = - (x mod y)"
  1583   using mod_smult_left [of "- 1::'a"] by simp
  1584 
  1585 lemma pdivmod_rel_smult_right:
  1586   "\<lbrakk>a \<noteq> 0; pdivmod_rel x y q r\<rbrakk>
  1587     \<Longrightarrow> pdivmod_rel x (smult a y) (smult (inverse a) q) r"
  1588   unfolding pdivmod_rel_def by simp
  1589 
  1590 lemma div_smult_right:
  1591   "a \<noteq> 0 \<Longrightarrow> x div (smult a y) = smult (inverse a) (x div y)"
  1592   by (rule div_poly_eq, erule pdivmod_rel_smult_right, rule pdivmod_rel)
  1593 
  1594 lemma mod_smult_right: "a \<noteq> 0 \<Longrightarrow> x mod (smult a y) = x mod y"
  1595   by (rule mod_poly_eq, erule pdivmod_rel_smult_right, rule pdivmod_rel)
  1596 
  1597 lemma poly_div_minus_right [simp]:
  1598   fixes x y :: "'a::field poly"
  1599   shows "x div (- y) = - (x div y)"
  1600   using div_smult_right [of "- 1::'a"] by (simp add: nonzero_inverse_minus_eq)
  1601 
  1602 lemma poly_mod_minus_right [simp]:
  1603   fixes x y :: "'a::field poly"
  1604   shows "x mod (- y) = x mod y"
  1605   using mod_smult_right [of "- 1::'a"] by simp
  1606 
  1607 lemma pdivmod_rel_mult:
  1608   "\<lbrakk>pdivmod_rel x y q r; pdivmod_rel q z q' r'\<rbrakk>
  1609     \<Longrightarrow> pdivmod_rel x (y * z) q' (y * r' + r)"
  1610 apply (cases "z = 0", simp add: pdivmod_rel_def)
  1611 apply (cases "y = 0", simp add: pdivmod_rel_by_0_iff pdivmod_rel_0_iff)
  1612 apply (cases "r = 0")
  1613 apply (cases "r' = 0")
  1614 apply (simp add: pdivmod_rel_def)
  1615 apply (simp add: pdivmod_rel_def field_simps degree_mult_eq)
  1616 apply (cases "r' = 0")
  1617 apply (simp add: pdivmod_rel_def degree_mult_eq)
  1618 apply (simp add: pdivmod_rel_def field_simps)
  1619 apply (simp add: degree_mult_eq degree_add_less)
  1620 done
  1621 
  1622 lemma poly_div_mult_right:
  1623   fixes x y z :: "'a::field poly"
  1624   shows "x div (y * z) = (x div y) div z"
  1625   by (rule div_poly_eq, rule pdivmod_rel_mult, (rule pdivmod_rel)+)
  1626 
  1627 lemma poly_mod_mult_right:
  1628   fixes x y z :: "'a::field poly"
  1629   shows "x mod (y * z) = y * (x div y mod z) + x mod y"
  1630   by (rule mod_poly_eq, rule pdivmod_rel_mult, (rule pdivmod_rel)+)
  1631 
  1632 lemma mod_pCons:
  1633   fixes a and x
  1634   assumes y: "y \<noteq> 0"
  1635   defines b: "b \<equiv> coeff (pCons a (x mod y)) (degree y) / coeff y (degree y)"
  1636   shows "(pCons a x) mod y = (pCons a (x mod y) - smult b y)"
  1637 unfolding b
  1638 apply (rule mod_poly_eq)
  1639 apply (rule pdivmod_rel_pCons [OF pdivmod_rel y refl])
  1640 done
  1641 
  1642 definition pdivmod :: "'a::field poly \<Rightarrow> 'a poly \<Rightarrow> 'a poly \<times> 'a poly"
  1643 where
  1644   "pdivmod p q = (p div q, p mod q)"
  1645 
  1646 lemma div_poly_code [code]: 
  1647   "p div q = fst (pdivmod p q)"
  1648   by (simp add: pdivmod_def)
  1649 
  1650 lemma mod_poly_code [code]:
  1651   "p mod q = snd (pdivmod p q)"
  1652   by (simp add: pdivmod_def)
  1653 
  1654 lemma pdivmod_0:
  1655   "pdivmod 0 q = (0, 0)"
  1656   by (simp add: pdivmod_def)
  1657 
  1658 lemma pdivmod_pCons:
  1659   "pdivmod (pCons a p) q =
  1660     (if q = 0 then (0, pCons a p) else
  1661       (let (s, r) = pdivmod p q;
  1662            b = coeff (pCons a r) (degree q) / coeff q (degree q)
  1663         in (pCons b s, pCons a r - smult b q)))"
  1664   apply (simp add: pdivmod_def Let_def, safe)
  1665   apply (rule div_poly_eq)
  1666   apply (erule pdivmod_rel_pCons [OF pdivmod_rel _ refl])
  1667   apply (rule mod_poly_eq)
  1668   apply (erule pdivmod_rel_pCons [OF pdivmod_rel _ refl])
  1669   done
  1670 
  1671 lemma pdivmod_fold_coeffs [code]:
  1672   "pdivmod p q = (if q = 0 then (0, p)
  1673     else fold_coeffs (\<lambda>a (s, r).
  1674       let b = coeff (pCons a r) (degree q) / coeff q (degree q)
  1675       in (pCons b s, pCons a r - smult b q)
  1676    ) p (0, 0))"
  1677   apply (cases "q = 0")
  1678   apply (simp add: pdivmod_def)
  1679   apply (rule sym)
  1680   apply (induct p)
  1681   apply (simp_all add: pdivmod_0 pdivmod_pCons)
  1682   apply (case_tac "a = 0 \<and> p = 0")
  1683   apply (auto simp add: pdivmod_def)
  1684   done
  1685 
  1686 
  1687 subsection {* Order of polynomial roots *}
  1688 
  1689 definition order :: "'a::idom \<Rightarrow> 'a poly \<Rightarrow> nat"
  1690 where
  1691   "order a p = (LEAST n. \<not> [:-a, 1:] ^ Suc n dvd p)"
  1692 
  1693 lemma coeff_linear_power:
  1694   fixes a :: "'a::comm_semiring_1"
  1695   shows "coeff ([:a, 1:] ^ n) n = 1"
  1696 apply (induct n, simp_all)
  1697 apply (subst coeff_eq_0)
  1698 apply (auto intro: le_less_trans degree_power_le)
  1699 done
  1700 
  1701 lemma degree_linear_power:
  1702   fixes a :: "'a::comm_semiring_1"
  1703   shows "degree ([:a, 1:] ^ n) = n"
  1704 apply (rule order_antisym)
  1705 apply (rule ord_le_eq_trans [OF degree_power_le], simp)
  1706 apply (rule le_degree, simp add: coeff_linear_power)
  1707 done
  1708 
  1709 lemma order_1: "[:-a, 1:] ^ order a p dvd p"
  1710 apply (cases "p = 0", simp)
  1711 apply (cases "order a p", simp)
  1712 apply (subgoal_tac "nat < (LEAST n. \<not> [:-a, 1:] ^ Suc n dvd p)")
  1713 apply (drule not_less_Least, simp)
  1714 apply (fold order_def, simp)
  1715 done
  1716 
  1717 lemma order_2: "p \<noteq> 0 \<Longrightarrow> \<not> [:-a, 1:] ^ Suc (order a p) dvd p"
  1718 unfolding order_def
  1719 apply (rule LeastI_ex)
  1720 apply (rule_tac x="degree p" in exI)
  1721 apply (rule notI)
  1722 apply (drule (1) dvd_imp_degree_le)
  1723 apply (simp only: degree_linear_power)
  1724 done
  1725 
  1726 lemma order:
  1727   "p \<noteq> 0 \<Longrightarrow> [:-a, 1:] ^ order a p dvd p \<and> \<not> [:-a, 1:] ^ Suc (order a p) dvd p"
  1728 by (rule conjI [OF order_1 order_2])
  1729 
  1730 lemma order_degree:
  1731   assumes p: "p \<noteq> 0"
  1732   shows "order a p \<le> degree p"
  1733 proof -
  1734   have "order a p = degree ([:-a, 1:] ^ order a p)"
  1735     by (simp only: degree_linear_power)
  1736   also have "\<dots> \<le> degree p"
  1737     using order_1 p by (rule dvd_imp_degree_le)
  1738   finally show ?thesis .
  1739 qed
  1740 
  1741 lemma order_root: "poly p a = 0 \<longleftrightarrow> p = 0 \<or> order a p \<noteq> 0"
  1742 apply (cases "p = 0", simp_all)
  1743 apply (rule iffI)
  1744 apply (rule ccontr, simp)
  1745 apply (frule order_2 [where a=a], simp)
  1746 apply (simp add: poly_eq_0_iff_dvd)
  1747 apply (simp add: poly_eq_0_iff_dvd)
  1748 apply (simp only: order_def)
  1749 apply (drule not_less_Least, simp)
  1750 done
  1751 
  1752 
  1753 subsection {* GCD of polynomials *}
  1754 
  1755 instantiation poly :: (field) gcd
  1756 begin
  1757 
  1758 function gcd_poly :: "'a::field poly \<Rightarrow> 'a poly \<Rightarrow> 'a poly"
  1759 where
  1760   "gcd (x::'a poly) 0 = smult (inverse (coeff x (degree x))) x"
  1761 | "y \<noteq> 0 \<Longrightarrow> gcd (x::'a poly) y = gcd y (x mod y)"
  1762 by auto
  1763 
  1764 termination "gcd :: _ poly \<Rightarrow> _"
  1765 by (relation "measure (\<lambda>(x, y). if y = 0 then 0 else Suc (degree y))")
  1766    (auto dest: degree_mod_less)
  1767 
  1768 declare gcd_poly.simps [simp del]
  1769 
  1770 instance ..
  1771 
  1772 end
  1773 
  1774 lemma
  1775   fixes x y :: "_ poly"
  1776   shows poly_gcd_dvd1 [iff]: "gcd x y dvd x"
  1777     and poly_gcd_dvd2 [iff]: "gcd x y dvd y"
  1778   apply (induct x y rule: gcd_poly.induct)
  1779   apply (simp_all add: gcd_poly.simps)
  1780   apply (fastforce simp add: smult_dvd_iff dest: inverse_zero_imp_zero)
  1781   apply (blast dest: dvd_mod_imp_dvd)
  1782   done
  1783 
  1784 lemma poly_gcd_greatest:
  1785   fixes k x y :: "_ poly"
  1786   shows "k dvd x \<Longrightarrow> k dvd y \<Longrightarrow> k dvd gcd x y"
  1787   by (induct x y rule: gcd_poly.induct)
  1788      (simp_all add: gcd_poly.simps dvd_mod dvd_smult)
  1789 
  1790 lemma dvd_poly_gcd_iff [iff]:
  1791   fixes k x y :: "_ poly"
  1792   shows "k dvd gcd x y \<longleftrightarrow> k dvd x \<and> k dvd y"
  1793   by (blast intro!: poly_gcd_greatest intro: dvd_trans)
  1794 
  1795 lemma poly_gcd_monic:
  1796   fixes x y :: "_ poly"
  1797   shows "coeff (gcd x y) (degree (gcd x y)) =
  1798     (if x = 0 \<and> y = 0 then 0 else 1)"
  1799   by (induct x y rule: gcd_poly.induct)
  1800      (simp_all add: gcd_poly.simps nonzero_imp_inverse_nonzero)
  1801 
  1802 lemma poly_gcd_zero_iff [simp]:
  1803   fixes x y :: "_ poly"
  1804   shows "gcd x y = 0 \<longleftrightarrow> x = 0 \<and> y = 0"
  1805   by (simp only: dvd_0_left_iff [symmetric] dvd_poly_gcd_iff)
  1806 
  1807 lemma poly_gcd_0_0 [simp]:
  1808   "gcd (0::_ poly) 0 = 0"
  1809   by simp
  1810 
  1811 lemma poly_dvd_antisym:
  1812   fixes p q :: "'a::idom poly"
  1813   assumes coeff: "coeff p (degree p) = coeff q (degree q)"
  1814   assumes dvd1: "p dvd q" and dvd2: "q dvd p" shows "p = q"
  1815 proof (cases "p = 0")
  1816   case True with coeff show "p = q" by simp
  1817 next
  1818   case False with coeff have "q \<noteq> 0" by auto
  1819   have degree: "degree p = degree q"
  1820     using `p dvd q` `q dvd p` `p \<noteq> 0` `q \<noteq> 0`
  1821     by (intro order_antisym dvd_imp_degree_le)
  1822 
  1823   from `p dvd q` obtain a where a: "q = p * a" ..
  1824   with `q \<noteq> 0` have "a \<noteq> 0" by auto
  1825   with degree a `p \<noteq> 0` have "degree a = 0"
  1826     by (simp add: degree_mult_eq)
  1827   with coeff a show "p = q"
  1828     by (cases a, auto split: if_splits)
  1829 qed
  1830 
  1831 lemma poly_gcd_unique:
  1832   fixes d x y :: "_ poly"
  1833   assumes dvd1: "d dvd x" and dvd2: "d dvd y"
  1834     and greatest: "\<And>k. k dvd x \<Longrightarrow> k dvd y \<Longrightarrow> k dvd d"
  1835     and monic: "coeff d (degree d) = (if x = 0 \<and> y = 0 then 0 else 1)"
  1836   shows "gcd x y = d"
  1837 proof -
  1838   have "coeff (gcd x y) (degree (gcd x y)) = coeff d (degree d)"
  1839     by (simp_all add: poly_gcd_monic monic)
  1840   moreover have "gcd x y dvd d"
  1841     using poly_gcd_dvd1 poly_gcd_dvd2 by (rule greatest)
  1842   moreover have "d dvd gcd x y"
  1843     using dvd1 dvd2 by (rule poly_gcd_greatest)
  1844   ultimately show ?thesis
  1845     by (rule poly_dvd_antisym)
  1846 qed
  1847 
  1848 interpretation gcd_poly!: abel_semigroup "gcd :: _ poly \<Rightarrow> _"
  1849 proof
  1850   fix x y z :: "'a poly"
  1851   show "gcd (gcd x y) z = gcd x (gcd y z)"
  1852     by (rule poly_gcd_unique) (auto intro: dvd_trans simp add: poly_gcd_monic)
  1853   show "gcd x y = gcd y x"
  1854     by (rule poly_gcd_unique) (simp_all add: poly_gcd_monic)
  1855 qed
  1856 
  1857 lemmas poly_gcd_assoc = gcd_poly.assoc
  1858 lemmas poly_gcd_commute = gcd_poly.commute
  1859 lemmas poly_gcd_left_commute = gcd_poly.left_commute
  1860 
  1861 lemmas poly_gcd_ac = poly_gcd_assoc poly_gcd_commute poly_gcd_left_commute
  1862 
  1863 lemma poly_gcd_1_left [simp]: "gcd 1 y = (1 :: _ poly)"
  1864 by (rule poly_gcd_unique) simp_all
  1865 
  1866 lemma poly_gcd_1_right [simp]: "gcd x 1 = (1 :: _ poly)"
  1867 by (rule poly_gcd_unique) simp_all
  1868 
  1869 lemma poly_gcd_minus_left [simp]: "gcd (- x) y = gcd x (y :: _ poly)"
  1870 by (rule poly_gcd_unique) (simp_all add: poly_gcd_monic)
  1871 
  1872 lemma poly_gcd_minus_right [simp]: "gcd x (- y) = gcd x (y :: _ poly)"
  1873 by (rule poly_gcd_unique) (simp_all add: poly_gcd_monic)
  1874 
  1875 lemma poly_gcd_code [code]:
  1876   "gcd x y = (if y = 0 then smult (inverse (coeff x (degree x))) x else gcd y (x mod (y :: _ poly)))"
  1877   by (simp add: gcd_poly.simps)
  1878 
  1879 
  1880 subsection {* Composition of polynomials *}
  1881 
  1882 definition pcompose :: "'a::comm_semiring_0 poly \<Rightarrow> 'a poly \<Rightarrow> 'a poly"
  1883 where
  1884   "pcompose p q = fold_coeffs (\<lambda>a c. [:a:] + q * c) p 0"
  1885 
  1886 lemma pcompose_0 [simp]:
  1887   "pcompose 0 q = 0"
  1888   by (simp add: pcompose_def)
  1889 
  1890 lemma pcompose_pCons:
  1891   "pcompose (pCons a p) q = [:a:] + q * pcompose p q"
  1892   by (cases "p = 0 \<and> a = 0") (auto simp add: pcompose_def)
  1893 
  1894 lemma poly_pcompose:
  1895   "poly (pcompose p q) x = poly p (poly q x)"
  1896   by (induct p) (simp_all add: pcompose_pCons)
  1897 
  1898 lemma degree_pcompose_le:
  1899   "degree (pcompose p q) \<le> degree p * degree q"
  1900 apply (induct p, simp)
  1901 apply (simp add: pcompose_pCons, clarify)
  1902 apply (rule degree_add_le, simp)
  1903 apply (rule order_trans [OF degree_mult_le], simp)
  1904 done
  1905 
  1906 
  1907 no_notation cCons (infixr "##" 65)
  1908 
  1909 end
  1910