src/Pure/theory.ML
author wenzelm
Wed Apr 04 23:29:40 2007 +0200 (2007-04-04)
changeset 22600 043232f8dde2
parent 22578 b0eb5652f210
child 22684 a614c5f506ea
permissions -rw-r--r--
removed unused dep_graph;
     1 (*  Title:      Pure/theory.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson and Markus Wenzel
     4 
     5 Logical theory content: axioms, definitions, oracles.
     6 *)
     7 
     8 signature BASIC_THEORY =
     9 sig
    10   val rep_theory: theory ->
    11    {axioms: term NameSpace.table,
    12     defs: Defs.T,
    13     oracles: ((theory * Object.T -> term) * stamp) NameSpace.table}
    14   val parents_of: theory -> theory list
    15   val ancestors_of: theory -> theory list
    16   val eq_thy: theory * theory -> bool
    17   val subthy: theory * theory -> bool
    18   val cert_axm: theory -> string * term -> string * term
    19   val read_def_axm: theory * (indexname -> typ option) * (indexname -> sort option) ->
    20     string list -> string * string -> string * term
    21   val read_axm: theory -> string * string -> string * term
    22   val inferT_axm: theory -> string * term -> string * term
    23 end
    24 
    25 signature THEORY =
    26 sig
    27   include BASIC_THEORY
    28   include SIGN_THEORY
    29   val begin_theory: string -> theory list -> theory
    30   val end_theory: theory -> theory
    31   val checkpoint: theory -> theory
    32   val copy: theory -> theory
    33   val init_data: theory -> theory
    34   val axiom_space: theory -> NameSpace.T
    35   val oracle_space: theory -> NameSpace.T
    36   val axioms_of: theory -> (string * term) list
    37   val all_axioms_of: theory -> (string * term) list
    38   val defs_of : theory -> Defs.T
    39   val self_ref: theory -> theory_ref
    40   val deref: theory_ref -> theory
    41   val merge: theory * theory -> theory                     (*exception TERM*)
    42   val merge_refs: theory_ref * theory_ref -> theory_ref    (*exception TERM*)
    43   val merge_list: theory list -> theory                    (*exception TERM*)
    44   val requires: theory -> string -> string -> unit
    45   val assert_super: theory -> theory -> theory
    46   val add_axioms: (bstring * string) list -> theory -> theory
    47   val add_axioms_i: (bstring * term) list -> theory -> theory
    48   val add_deps: string -> string * typ -> (string * typ) list -> theory -> theory
    49   val add_defs: bool -> bool -> (bstring * string) list -> theory -> theory
    50   val add_defs_i: bool -> bool -> (bstring * term) list -> theory -> theory
    51   val add_finals: bool -> string list -> theory -> theory
    52   val add_finals_i: bool -> term list -> theory -> theory
    53   val add_oracle: bstring * (theory * Object.T -> term) -> theory -> theory
    54 end
    55 
    56 structure Theory: THEORY =
    57 struct
    58 
    59 
    60 (** type theory **)
    61 
    62 (* context operations *)
    63 
    64 val eq_thy = Context.eq_thy;
    65 val subthy = Context.subthy;
    66 
    67 val parents_of = Context.parents_of;
    68 val ancestors_of = Context.ancestors_of;
    69 
    70 val self_ref = Context.self_ref;
    71 val deref = Context.deref;
    72 val merge = Context.merge;
    73 val merge_refs = Context.merge_refs;
    74 
    75 fun merge_list [] = raise TERM ("Empty merge of theories", [])
    76   | merge_list (thy :: thys) = Library.foldl merge (thy, thys);
    77 
    78 val begin_theory = Sign.local_path oo Context.begin_thy Sign.pp;
    79 val end_theory = Context.finish_thy;
    80 val checkpoint = Context.checkpoint_thy;
    81 val copy = Context.copy_thy;
    82 
    83 
    84 (* signature operations *)
    85 
    86 structure SignTheory: SIGN_THEORY = Sign;
    87 open SignTheory;
    88 
    89 
    90 
    91 (** datatype thy **)
    92 
    93 datatype thy = Thy of
    94  {axioms: term NameSpace.table,
    95   defs: Defs.T,
    96   oracles: ((theory * Object.T -> term) * stamp) NameSpace.table};
    97 
    98 fun make_thy (axioms, defs, oracles) =
    99   Thy {axioms = axioms, defs = defs, oracles = oracles};
   100 
   101 fun err_dup_axms dups = error ("Duplicate axiom(s): " ^ commas_quote dups);
   102 fun err_dup_oras dups = error ("Duplicate oracle(s): " ^ commas_quote dups);
   103 
   104 structure ThyData = TheoryDataFun
   105 (struct
   106   val name = "Pure/theory";
   107   type T = thy;
   108   val empty = make_thy (NameSpace.empty_table, Defs.empty, NameSpace.empty_table);
   109   val copy = I;
   110 
   111   fun extend (Thy {axioms, defs, oracles}) = make_thy (NameSpace.empty_table, defs, oracles);
   112 
   113   fun merge pp (thy1, thy2) =
   114     let
   115       val Thy {axioms = _, defs = defs1, oracles = oracles1} = thy1;
   116       val Thy {axioms = _, defs = defs2, oracles = oracles2} = thy2;
   117 
   118       val axioms = NameSpace.empty_table;
   119       val defs = Defs.merge pp (defs1, defs2);
   120       val oracles = NameSpace.merge_tables (eq_snd (op =)) (oracles1, oracles2)
   121         handle Symtab.DUPS dups => err_dup_oras dups;
   122     in make_thy (axioms, defs, oracles) end;
   123 
   124   fun print _ _ = ();
   125 end);
   126 
   127 val init_data = ThyData.init;
   128 
   129 fun rep_theory thy = ThyData.get thy |> (fn Thy args => args);
   130 
   131 fun map_thy f = ThyData.map (fn (Thy {axioms, defs, oracles}) =>
   132   make_thy (f (axioms, defs, oracles)));
   133 
   134 fun map_axioms f = map_thy (fn (axioms, defs, oracles) => (f axioms, defs, oracles));
   135 fun map_defs f = map_thy (fn (axioms, defs, oracles) => (axioms, f defs, oracles));
   136 fun map_oracles f = map_thy (fn (axioms, defs, oracles) => (axioms, defs, f oracles));
   137 
   138 
   139 (* basic operations *)
   140 
   141 val axiom_space = #1 o #axioms o rep_theory;
   142 val oracle_space = #1 o #oracles o rep_theory;
   143 
   144 val axioms_of = Symtab.dest o #2 o #axioms o rep_theory;
   145 fun all_axioms_of thy = maps axioms_of (thy :: ancestors_of thy);
   146 
   147 val defs_of = #defs o rep_theory;
   148 
   149 fun requires thy name what =
   150   if Context.exists_name name thy then ()
   151   else error ("Require theory " ^ quote name ^ " as an ancestor for " ^ what);
   152 
   153 fun assert_super thy1 thy2 =
   154   if subthy (thy1, thy2) then thy2
   155   else raise THEORY ("Not a super theory", [thy1, thy2]);
   156 
   157 
   158 
   159 (** add axioms **)
   160 
   161 (* prepare axioms *)
   162 
   163 fun err_in_axm msg name =
   164   cat_error msg ("The error(s) above occurred in axiom " ^ quote name);
   165 
   166 fun cert_axm thy (name, raw_tm) =
   167   let
   168     val (t, T, _) = Sign.certify_prop thy raw_tm
   169       handle TYPE (msg, _, _) => error msg
   170         | TERM (msg, _) => error msg;
   171   in
   172     Term.no_dummy_patterns t handle TERM (msg, _) => error msg;
   173     (name, Sign.no_vars (Sign.pp thy) t)
   174   end;
   175 
   176 fun read_def_axm (thy, types, sorts) used (name, str) =
   177   let
   178     val ts = Syntax.read (ProofContext.init thy) (Sign.is_logtype thy) (Sign.syn_of thy) propT str;
   179     val (t, _) =
   180       Sign.infer_types (Sign.pp thy) thy (Sign.consts_of thy)
   181         types sorts (Name.make_context used) true (ts, propT);
   182   in cert_axm thy (name, t) end
   183   handle ERROR msg => err_in_axm msg name;
   184 
   185 fun read_axm thy name_str = read_def_axm (thy, K NONE, K NONE) [] name_str;
   186 
   187 fun inferT_axm thy (name, pre_tm) =
   188   let
   189     val pp = Sign.pp thy;
   190     val (t, _) =
   191       Sign.infer_types pp thy (Sign.consts_of thy)
   192         (K NONE) (K NONE) Name.context true ([pre_tm], propT);
   193   in (name, Sign.no_vars pp t) end
   194   handle ERROR msg => err_in_axm msg name;
   195 
   196 
   197 (* add_axioms(_i) *)
   198 
   199 local
   200 
   201 fun gen_add_axioms prep_axm raw_axms thy = thy |> map_axioms (fn axioms =>
   202   let
   203     val axms = map (apsnd (Compress.term thy o Logic.varify) o prep_axm thy) raw_axms;
   204     val axioms' = NameSpace.extend_table (Sign.naming_of thy) (axioms, axms)
   205       handle Symtab.DUPS dups => err_dup_axms dups;
   206   in axioms' end);
   207 
   208 in
   209 
   210 val add_axioms = gen_add_axioms read_axm;
   211 val add_axioms_i = gen_add_axioms cert_axm;
   212 
   213 end;
   214 
   215 
   216 
   217 (** add constant definitions **)
   218 
   219 (* dependencies *)
   220 
   221 fun dependencies thy unchecked is_def name lhs rhs =
   222   let
   223     val pp = Sign.pp thy;
   224     val consts = Sign.consts_of thy;
   225     fun prep const =
   226       let val Const (c, T) = Sign.no_vars pp (Const const)
   227       in (c, Consts.typargs consts (c, Compress.typ thy (Logic.varifyT T))) end;
   228 
   229     val lhs_vars = Term.add_tfreesT (#2 lhs) [];
   230     val rhs_extras = fold (#2 #> Term.fold_atyps (fn TFree v =>
   231       if member (op =) lhs_vars v then I else insert (op =) v | _ => I)) rhs [];
   232     val _ =
   233       if null rhs_extras then ()
   234       else error ("Specification depends on extra type variables: " ^
   235         commas_quote (map (Pretty.string_of_typ pp o TFree) rhs_extras) ^
   236         "\nThe error(s) above occurred in " ^ quote name);
   237   in Defs.define pp unchecked is_def (Context.theory_name thy) name (prep lhs) (map prep rhs) end;
   238 
   239 fun add_deps a raw_lhs raw_rhs thy =
   240   let
   241     val lhs :: rhs = map (dest_Const o Sign.cert_term thy o Const) (raw_lhs :: raw_rhs);
   242     val name = if a = "" then (#1 lhs ^ " axiom") else a;
   243   in thy |> map_defs (dependencies thy false false name lhs rhs) end;
   244 
   245 
   246 (* check_overloading *)
   247 
   248 fun check_overloading thy overloaded (c, T) =
   249   let
   250     val declT =
   251       (case Sign.const_constraint thy c of
   252         NONE => error ("Undeclared constant " ^ quote c)
   253       | SOME declT => declT);
   254     val T' = Logic.varifyT T;
   255 
   256     fun message txt =
   257       [Pretty.block [Pretty.str "Specification of constant ",
   258         Pretty.str c, Pretty.str " ::", Pretty.brk 1, Pretty.quote (Sign.pretty_typ thy T)],
   259         Pretty.str txt] |> Pretty.chunks |> Pretty.string_of;
   260   in
   261     if Sign.typ_instance thy (declT, T') then ()
   262     else if Type.raw_instance (declT, T') then
   263       error (Library.setmp show_sorts true
   264         message "imposes additional sort constraints on the constant declaration")
   265     else if overloaded then ()
   266     else warning (message "is strictly less general than the declared type");
   267     (c, T)
   268   end;
   269 
   270 
   271 (* check_def *)
   272 
   273 fun check_def thy unchecked overloaded (bname, tm) defs =
   274   let
   275     val name = Sign.full_name thy bname;
   276     val (lhs_const, rhs) = Sign.cert_def (Sign.pp thy) tm;
   277     val rhs_consts = fold_aterms (fn Const const => insert (op =) const | _ => I) rhs [];
   278     val _ = check_overloading thy overloaded lhs_const;
   279   in defs |> dependencies thy unchecked true name lhs_const rhs_consts end
   280   handle ERROR msg => cat_error msg (Pretty.string_of (Pretty.block
   281    [Pretty.str ("The error(s) above occurred in definition " ^ quote bname ^ ":"),
   282     Pretty.fbrk, Pretty.quote (Sign.pretty_term thy tm)]));
   283 
   284 
   285 (* add_defs(_i) *)
   286 
   287 local
   288 
   289 fun gen_add_defs prep_axm unchecked overloaded raw_axms thy =
   290   let val axms = map (prep_axm thy) raw_axms in
   291     thy
   292     |> map_defs (fold (check_def thy unchecked overloaded) axms)
   293     |> add_axioms_i axms
   294   end;
   295 
   296 in
   297 
   298 val add_defs_i = gen_add_defs cert_axm;
   299 val add_defs = gen_add_defs read_axm;
   300 
   301 end;
   302 
   303 
   304 (* add_finals(_i) *)
   305 
   306 local
   307 
   308 fun gen_add_finals prep_term overloaded args thy =
   309   let
   310     fun const_of (Const const) = const
   311       | const_of (Free _) = error "Attempt to finalize variable (or undeclared constant)"
   312       | const_of _ = error "Attempt to finalize non-constant term";
   313     fun specify (c, T) = dependencies thy false false (c ^ " axiom") (c, T) [];
   314     val finalize = specify o check_overloading thy overloaded o const_of o prep_term thy;
   315   in thy |> map_defs (fold finalize args) end;
   316 
   317 in
   318 
   319 val add_finals = gen_add_finals Sign.read_term;
   320 val add_finals_i = gen_add_finals Sign.cert_term;
   321 
   322 end;
   323 
   324 
   325 
   326 (** add oracle **)
   327 
   328 fun add_oracle (bname, oracle) thy = thy |> map_oracles (fn oracles =>
   329   NameSpace.extend_table (Sign.naming_of thy) (oracles, [(bname, (oracle, stamp ()))])
   330     handle Symtab.DUPS dups => err_dup_oras dups);
   331 
   332 end;
   333 
   334 structure BasicTheory: BASIC_THEORY = Theory;
   335 open BasicTheory;