src/Pure/library.ML
author wenzelm
Sun Sep 07 22:19:46 2008 +0200 (2008-09-07)
changeset 28157 0435d23deccc
parent 28122 3d099ce624e7
child 28347 3cb64932ac77
permissions -rw-r--r--
added change_result;
     1 (*  Title:      Pure/library.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Author:     Markus Wenzel, TU Muenchen
     5 
     6 Basic library: functions, options, pairs, booleans, lists, integers,
     7 strings, lists as sets, orders, current directory, misc.
     8 
     9 See also General/basics.ML for the most fundamental concepts.
    10 *)
    11 
    12 infix 1 |>>>
    13 infix 2 ?
    14 infix 3 o oo ooo oooo
    15 infix 4 ~~ upto downto
    16 infix orf andf \ \\ mem mem_int mem_string union union_int
    17   union_string inter inter_int inter_string subset subset_int subset_string
    18 
    19 signature BASIC_LIBRARY =
    20 sig
    21   (*functions*)
    22   val undefined: 'a -> 'b
    23   val I: 'a -> 'a
    24   val K: 'a -> 'b -> 'a
    25   val curry: ('a * 'b -> 'c) -> 'a -> 'b -> 'c
    26   val uncurry: ('a -> 'b -> 'c) -> 'a * 'b -> 'c
    27   val |>>> : ('a * 'c) * ('a -> 'b * 'd) -> 'b * ('c * 'd)
    28   val ? : bool * ('a -> 'a) -> 'a -> 'a
    29   val oo: ('a -> 'b) * ('c -> 'd -> 'a) -> 'c -> 'd -> 'b
    30   val ooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'a) -> 'c -> 'd -> 'e -> 'b
    31   val oooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'f -> 'a) -> 'c -> 'd -> 'e -> 'f -> 'b
    32   val funpow: int -> ('a -> 'a) -> 'a -> 'a
    33 
    34   (*errors*)
    35   exception SYS_ERROR of string
    36   val sys_error: string -> 'a
    37   exception ERROR of string
    38   val error: string -> 'a
    39   val cat_error: string -> string -> 'a
    40   val assert_all: ('a -> bool) -> 'a list -> ('a -> string) -> unit
    41 
    42   (*pairs*)
    43   val pair: 'a -> 'b -> 'a * 'b
    44   val rpair: 'a -> 'b -> 'b * 'a
    45   val fst: 'a * 'b -> 'a
    46   val snd: 'a * 'b -> 'b
    47   val eq_fst: ('a * 'c -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    48   val eq_snd: ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    49   val eq_pair: ('a * 'c -> bool) -> ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    50   val swap: 'a * 'b -> 'b * 'a
    51   val apfst: ('a -> 'b) -> 'a * 'c -> 'b * 'c
    52   val apsnd: ('a -> 'b) -> 'c * 'a -> 'c * 'b
    53   val pairself: ('a -> 'b) -> 'a * 'a -> 'b * 'b
    54 
    55   (*booleans*)
    56   val equal: ''a -> ''a -> bool
    57   val not_equal: ''a -> ''a -> bool
    58   val orf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    59   val andf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    60   val exists: ('a -> bool) -> 'a list -> bool
    61   val forall: ('a -> bool) -> 'a list -> bool
    62   val set: bool ref -> bool
    63   val reset: bool ref -> bool
    64   val toggle: bool ref -> bool
    65   val change: 'a ref -> ('a -> 'a) -> unit
    66   val change_result: 'a ref -> ('a -> 'b * 'a) -> 'b
    67   val setmp_noncritical: 'a ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    68   val setmp: 'a ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    69   val setmp_thread_data: 'a Universal.tag -> 'a -> 'a -> ('b -> 'c) -> 'b -> 'c
    70 
    71   (*lists*)
    72   exception UnequalLengths
    73   val single: 'a -> 'a list
    74   val the_single: 'a list -> 'a
    75   val singleton: ('a list -> 'b list) -> 'a -> 'b
    76   val yield_singleton: ('a list -> 'c -> 'b list * 'c) -> 'a -> 'c -> 'b * 'c
    77   val apply: ('a -> 'a) list -> 'a -> 'a
    78   val perhaps_apply: ('a -> 'a option) list -> 'a -> 'a option
    79   val perhaps_loop: ('a -> 'a option) -> 'a -> 'a option
    80   val foldl1: ('a * 'a -> 'a) -> 'a list -> 'a
    81   val foldr1: ('a * 'a -> 'a) -> 'a list -> 'a
    82   val foldl_map: ('a * 'b -> 'a * 'c) -> 'a * 'b list -> 'a * 'c list
    83   val flat: 'a list list -> 'a list
    84   val unflat: 'a list list -> 'b list -> 'b list list
    85   val burrow: ('a list -> 'b list) -> 'a list list -> 'b list list
    86   val burrow_options: ('a list -> 'b list) -> 'a option list -> 'b option list
    87   val fold_burrow: ('a list -> 'c -> 'b list * 'd) -> 'a list list -> 'c -> 'b list list * 'd
    88   val maps: ('a -> 'b list) -> 'a list -> 'b list
    89   val filter: ('a -> bool) -> 'a list -> 'a list
    90   val filter_out: ('a -> bool) -> 'a list -> 'a list
    91   val map_filter: ('a -> 'b option) -> 'a list -> 'b list
    92   val chop: int -> 'a list -> 'a list * 'a list
    93   val dropwhile: ('a -> bool) -> 'a list -> 'a list
    94   val nth: 'a list -> int -> 'a
    95   val nth_map: int -> ('a -> 'a) -> 'a list -> 'a list
    96   val nth_drop: int -> 'a list -> 'a list
    97   val nth_list: 'a list list -> int -> 'a list
    98   val map_index: (int * 'a -> 'b) -> 'a list -> 'b list
    99   val fold_index: (int * 'a -> 'b -> 'b) -> 'a list -> 'b -> 'b
   100   val split_last: 'a list -> 'a list * 'a
   101   val find_index: ('a -> bool) -> 'a list -> int
   102   val find_index_eq: ''a -> ''a list -> int
   103   val find_first: ('a -> bool) -> 'a list -> 'a option
   104   val get_index: ('a -> 'b option) -> 'a list -> (int * 'b) option
   105   val get_first: ('a -> 'b option) -> 'a list -> 'b option
   106   val eq_list: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   107   val map2: ('a -> 'b -> 'c) -> 'a list -> 'b list -> 'c list
   108   val fold2: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
   109   val zip_options: 'a list -> 'b option list -> ('a * 'b) list
   110   val ~~ : 'a list * 'b list -> ('a * 'b) list
   111   val map_split: ('a -> 'b * 'c) -> 'a list -> 'b list * 'c list
   112   val split_list: ('a * 'b) list -> 'a list * 'b list
   113   val map_product: ('a -> 'b -> 'c) -> 'a list -> 'b list -> 'c list
   114   val fold_product: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
   115   val separate: 'a -> 'a list -> 'a list
   116   val surround: 'a -> 'a list -> 'a list
   117   val replicate: int -> 'a -> 'a list
   118   val is_prefix: ('a * 'a -> bool) -> 'a list -> 'a list -> bool
   119   val take_prefix: ('a -> bool) -> 'a list -> 'a list * 'a list
   120   val chop_prefix: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list * ('a list * 'b list)
   121   val take_suffix: ('a -> bool) -> 'a list -> 'a list * 'a list
   122   val prefixes1: 'a list -> 'a list list
   123   val prefixes: 'a list -> 'a list list
   124   val suffixes1: 'a list -> 'a list list
   125   val suffixes: 'a list -> 'a list list
   126 
   127   (*integers*)
   128   val inc: int ref -> int
   129   val dec: int ref -> int
   130   val upto: int * int -> int list
   131   val downto: int * int -> int list
   132   val radixpand: int * int -> int list
   133   val radixstring: int * string * int -> string
   134   val string_of_int: int -> string
   135   val signed_string_of_int: int -> string
   136   val string_of_indexname: string * int -> string
   137   val read_radix_int: int -> string list -> int * string list
   138   val read_int: string list -> int * string list
   139   val oct_char: string -> string
   140 
   141   (*strings*)
   142   val nth_string: string -> int -> string
   143   val fold_string: (string -> 'a -> 'a) -> string -> 'a -> 'a
   144   val exists_string: (string -> bool) -> string -> bool
   145   val forall_string: (string -> bool) -> string -> bool
   146   val first_field: string -> string -> (string * string) option
   147   val enclose: string -> string -> string -> string
   148   val unenclose: string -> string
   149   val quote: string -> string
   150   val space_implode: string -> string list -> string
   151   val commas: string list -> string
   152   val commas_quote: string list -> string
   153   val cat_lines: string list -> string
   154   val space_explode: string -> string -> string list
   155   val split_lines: string -> string list
   156   val prefix_lines: string -> string -> string
   157   val prefix: string -> string -> string
   158   val suffix: string -> string -> string
   159   val unprefix: string -> string -> string
   160   val unsuffix: string -> string -> string
   161   val replicate_string: int -> string -> string
   162   val translate_string: (string -> string) -> string -> string
   163   val multiply: 'a list -> 'a list list -> 'a list list
   164 
   165   (*lists as sets -- see also Pure/General/ord_list.ML*)
   166   val member: ('b * 'a -> bool) -> 'a list -> 'b -> bool
   167   val insert: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   168   val remove: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   169   val update: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   170   val subtract: ('b * 'a -> bool) -> 'b list -> 'a list -> 'a list
   171   val merge: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   172   val mem: ''a * ''a list -> bool
   173   val mem_int: int * int list -> bool
   174   val mem_string: string * string list -> bool
   175   val union: ''a list * ''a list -> ''a list
   176   val union_int: int list * int list -> int list
   177   val union_string: string list * string list -> string list
   178   val gen_union: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   179   val gen_inter: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   180   val inter: ''a list * ''a list -> ''a list
   181   val inter_int: int list * int list -> int list
   182   val inter_string: string list * string list -> string list
   183   val subset: ''a list * ''a list -> bool
   184   val subset_int: int list * int list -> bool
   185   val subset_string: string list * string list -> bool
   186   val eq_set: ''a list * ''a list -> bool
   187   val eq_set_string: string list * string list -> bool
   188   val gen_subset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   189   val gen_eq_set: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   190   val \ : ''a list * ''a -> ''a list
   191   val \\ : ''a list * ''a list -> ''a list
   192   val distinct: ('a * 'a -> bool) -> 'a list -> 'a list
   193   val duplicates: ('a * 'a -> bool) -> 'a list -> 'a list
   194   val has_duplicates: ('a * 'a -> bool) -> 'a list -> bool
   195 
   196   (*lists as multisets*)
   197   val remove1: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   198   val submultiset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   199 
   200   (*orders*)
   201   val is_equal: order -> bool
   202   val rev_order: order -> order
   203   val make_ord: ('a * 'a -> bool) -> 'a * 'a -> order
   204   val bool_ord: bool * bool -> order
   205   val int_ord: int * int -> order
   206   val string_ord: string * string -> order
   207   val fast_string_ord: string * string -> order
   208   val option_ord: ('a * 'b -> order) -> 'a option * 'b option -> order
   209   val prod_ord: ('a * 'b -> order) -> ('c * 'd -> order) -> ('a * 'c) * ('b * 'd) -> order
   210   val dict_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   211   val list_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   212   val sort: ('a * 'a -> order) -> 'a list -> 'a list
   213   val sort_distinct: ('a * 'a -> order) -> 'a list -> 'a list
   214   val sort_strings: string list -> string list
   215   val sort_wrt: ('a -> string) -> 'a list -> 'a list
   216 
   217   (*random numbers*)
   218   exception RANDOM
   219   val random: unit -> real
   220   val random_range: int -> int -> int
   221   val one_of: 'a list -> 'a
   222   val frequency: (int * 'a) list -> 'a
   223 
   224   (*misc*)
   225   val divide_and_conquer: ('a -> 'a list * ('b list -> 'b)) -> 'a -> 'b
   226   val partition_eq: ('a * 'a -> bool) -> 'a list -> 'a list list
   227   val partition_list: (int -> 'a -> bool) -> int -> int -> 'a list -> 'a list list
   228   val gensym: string -> string
   229   type stamp
   230   val stamp: unit -> stamp
   231   type serial
   232   val serial: unit -> serial
   233   val serial_string: unit -> string
   234   structure Object: sig type T end
   235 end;
   236 
   237 signature LIBRARY =
   238 sig
   239   include BASIC_LIBRARY
   240   val foldl: ('a * 'b -> 'a) -> 'a * 'b list -> 'a
   241   val foldr: ('a * 'b -> 'b) -> 'a list * 'b -> 'b
   242   val take: int * 'a list -> 'a list
   243   val drop: int * 'a list -> 'a list
   244   val last_elem: 'a list -> 'a
   245 end;
   246 
   247 structure Library: LIBRARY =
   248 struct
   249 
   250 (* functions *)
   251 
   252 fun undefined _ = raise Match;
   253 
   254 fun I x = x;
   255 fun K x = fn _ => x;
   256 fun curry f x y = f (x, y);
   257 fun uncurry f (x, y) = f x y;
   258 
   259 (*application and structured results -- old version*)
   260 fun (x, y) |>>> f = let val (x', z) = f x in (x', (y, z)) end;
   261 
   262 (*conditional application*)
   263 fun b ? f = fn x => if b then f x else x;
   264 
   265 (*composition with multiple args*)
   266 fun (f oo g) x y = f (g x y);
   267 fun (f ooo g) x y z = f (g x y z);
   268 fun (f oooo g) x y z w = f (g x y z w);
   269 
   270 (*function exponentiation: f(...(f x)...) with n applications of f*)
   271 fun funpow (0: int) _ x = x
   272   | funpow n f x = funpow (n - 1) f (f x);
   273 
   274 
   275 (* errors *)
   276 
   277 exception SYS_ERROR of string;
   278 fun sys_error msg = raise SYS_ERROR msg;
   279 
   280 exception ERROR of string;
   281 fun error msg = raise ERROR msg;
   282 
   283 fun cat_error "" msg = error msg
   284   | cat_error msg1 msg2 = error (msg1 ^ "\n" ^ msg2);
   285 
   286 fun assert_all pred list msg =
   287   let
   288     fun ass [] = ()
   289       | ass (x :: xs) = if pred x then ass xs else error (msg x);
   290   in ass list end;
   291 
   292 
   293 (* pairs *)
   294 
   295 fun pair x y = (x, y);
   296 fun rpair x y = (y, x);
   297 
   298 fun fst (x, y) = x;
   299 fun snd (x, y) = y;
   300 
   301 fun eq_fst eq ((x1, _), (x2, _)) = eq (x1, x2);
   302 fun eq_snd eq ((_, y1), (_, y2)) = eq (y1, y2);
   303 fun eq_pair eqx eqy ((x1, y1), (x2, y2)) = eqx (x1, x2) andalso eqy (y1, y2);
   304 
   305 fun swap (x, y) = (y, x);
   306 
   307 fun apfst f (x, y) = (f x, y);
   308 fun apsnd f (x, y) = (x, f y);
   309 fun pairself f (x, y) = (f x, f y);
   310 
   311 
   312 (* booleans *)
   313 
   314 (*polymorphic equality*)
   315 fun equal x y = x = y;
   316 fun not_equal x y = x <> y;
   317 
   318 (*combining predicates*)
   319 fun p orf q = fn x => p x orelse q x;
   320 fun p andf q = fn x => p x andalso q x;
   321 
   322 val exists = List.exists;
   323 val forall = List.all;
   324 
   325 
   326 (* flags *)
   327 
   328 fun set flag = (flag := true; true);
   329 fun reset flag = (flag := false; false);
   330 fun toggle flag = (flag := not (! flag); ! flag);
   331 
   332 fun change r f = r := f (! r);
   333 fun change_result r f = let val (x, y) = f (! r) in r := y; x end;
   334 
   335 (*temporarily set flag during execution*)
   336 fun setmp_noncritical flag value f x =
   337   uninterruptible (fn restore_attributes => fn () =>
   338     let
   339       val orig_value = ! flag;
   340       val _ = flag := value;
   341       val result = Exn.capture (restore_attributes f) x;
   342       val _ = flag := orig_value;
   343     in Exn.release result end) ();
   344 
   345 fun setmp flag value f x =
   346   NAMED_CRITICAL "setmp" (fn () => setmp_noncritical flag value f x);
   347 
   348 fun setmp_thread_data tag orig_data data f x =
   349   uninterruptible (fn restore_attributes => fn () =>
   350     let
   351       val _ = Thread.setLocal (tag, data);
   352       val result = Exn.capture (restore_attributes f) x;
   353       val _ = Thread.setLocal (tag, orig_data);
   354     in Exn.release result end) ();
   355 
   356 
   357 
   358 (** lists **)
   359 
   360 exception UnequalLengths;
   361 
   362 fun single x = [x];
   363 
   364 fun the_single [x] = x
   365   | the_single _ = raise Empty;
   366 
   367 fun singleton f x = the_single (f [x]);
   368 
   369 fun yield_singleton f x = f [x] #>> the_single;
   370 
   371 fun apply [] x = x
   372   | apply (f :: fs) x = apply fs (f x);
   373 
   374 fun perhaps_apply funs arg =
   375   let
   376     fun app [] res = res
   377       | app (f :: fs) (changed, x) =
   378           (case f x of
   379             NONE => app fs (changed, x)
   380           | SOME x' => app fs (true, x'));
   381   in (case app funs (false, arg) of (false, _) => NONE | (true, arg') => SOME arg') end;
   382 
   383 fun perhaps_loop f arg =
   384   let
   385     fun loop (changed, x) =
   386       (case f x of
   387         NONE => (changed, x)
   388       | SOME x' => loop (true, x'));
   389   in (case loop (false, arg) of (false, _) => NONE | (true, arg') => SOME arg') end;
   390 
   391 
   392 (* fold -- old versions *)
   393 
   394 (*the following versions of fold are designed to fit nicely with infixes*)
   395 
   396 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   397     for operators that associate to the left (TAIL RECURSIVE)*)
   398 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   399   let fun itl (e, [])  = e
   400         | itl (e, a::l) = itl (f(e, a), l)
   401   in  itl end;
   402 
   403 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   404     for operators that associate to the right (not tail recursive)*)
   405 fun foldr f (l, e) =
   406   let fun itr [] = e
   407         | itr (a::l) = f(a, itr l)
   408   in  itr l  end;
   409 
   410 (*  (op @) [x1, ..., xn]  ===>  ((x1 @ x2) @ x3) ... @ xn
   411     for operators that associate to the left (TAIL RECURSIVE)*)
   412 fun foldl1 f [] = raise Empty
   413   | foldl1 f (x :: xs) = foldl f (x, xs);
   414 
   415 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   416     for n > 0, operators that associate to the right (not tail recursive)*)
   417 fun foldr1 f [] = raise Empty
   418   | foldr1 f l =
   419       let fun itr [x] = x
   420             | itr (x::l) = f(x, itr l)
   421       in  itr l  end;
   422 
   423 fun foldl_map f =
   424   let
   425     fun fold_aux (x, []) = (x, [])
   426       | fold_aux (x, y :: ys) =
   427           let
   428             val (x', y') = f (x, y);
   429             val (x'', ys') = fold_aux (x', ys);
   430           in (x'', y' :: ys') end;
   431   in fold_aux end;
   432 
   433 
   434 (* basic list functions *)
   435 
   436 fun eq_list eq (list1, list2) =
   437   let
   438     fun eq_lst (x :: xs, y :: ys) = eq (x, y) andalso eq_lst (xs, ys)
   439       | eq_lst _ = true;
   440   in length list1 = length list2 andalso eq_lst (list1, list2) end;
   441 
   442 fun maps f [] = []
   443   | maps f (x :: xs) = f x @ maps f xs;
   444 
   445 val filter = List.filter;
   446 fun filter_out f = filter (not o f);
   447 val map_filter = List.mapPartial;
   448 
   449 fun chop (0: int) xs = ([], xs)
   450   | chop _ [] = ([], [])
   451   | chop n (x :: xs) = chop (n - 1) xs |>> cons x;
   452 
   453 (*take the first n elements from a list*)
   454 fun take (n: int, []) = []
   455   | take (n, x :: xs) =
   456       if n > 0 then x :: take (n - 1, xs) else [];
   457 
   458 (*drop the first n elements from a list*)
   459 fun drop (n: int, []) = []
   460   | drop (n, x :: xs) =
   461       if n > 0 then drop (n - 1, xs) else x :: xs;
   462 
   463 fun dropwhile P [] = []
   464   | dropwhile P (ys as x::xs) = if P x then dropwhile P xs else ys;
   465 
   466 (*return nth element of a list, where 0 designates the first element;
   467   raise Subscript if list too short*)
   468 fun nth xs i = List.nth (xs, i);
   469 
   470 fun nth_list xss i = nth xss i handle Subscript => [];
   471 
   472 fun nth_map 0 f (x :: xs) = f x :: xs
   473   | nth_map n f (x :: xs) = x :: nth_map (n - 1) f xs
   474   | nth_map (_: int) _ [] = raise Subscript;
   475 
   476 fun nth_drop n xs =
   477   List.take (xs, n) @ List.drop (xs, n + 1);
   478 
   479 fun map_index f =
   480   let
   481     fun mapp (_: int) [] = []
   482       | mapp i (x :: xs) = f (i, x) :: mapp (i + 1) xs
   483   in mapp 0 end;
   484 
   485 fun fold_index f =
   486   let
   487     fun fold_aux (_: int) [] y = y
   488       | fold_aux i (x :: xs) y = fold_aux (i + 1) xs (f (i, x) y);
   489   in fold_aux 0 end;
   490 
   491 val last_elem = List.last;
   492 
   493 (*rear decomposition*)
   494 fun split_last [] = raise Empty
   495   | split_last [x] = ([], x)
   496   | split_last (x :: xs) = apfst (cons x) (split_last xs);
   497 
   498 (*find the position of an element in a list*)
   499 fun find_index pred =
   500   let fun find (_: int) [] = ~1
   501         | find n (x :: xs) = if pred x then n else find (n + 1) xs;
   502   in find 0 end;
   503 
   504 fun find_index_eq x = find_index (equal x);
   505 
   506 (*find first element satisfying predicate*)
   507 val find_first = List.find;
   508 
   509 (*get first element by lookup function*)
   510 fun get_first _ [] = NONE
   511   | get_first f (x :: xs) =
   512       (case f x of
   513         NONE => get_first f xs
   514       | some => some);
   515 
   516 fun get_index f =
   517   let
   518     fun get (_: int) [] = NONE
   519       | get i (x :: xs) =
   520           case f x
   521            of NONE => get (i + 1) xs
   522             | SOME y => SOME (i, y)
   523   in get 0 end;
   524 
   525 val flat = List.concat;
   526 
   527 fun unflat (xs :: xss) ys =
   528       let val (ps, qs) = chop (length xs) ys
   529       in ps :: unflat xss qs end
   530   | unflat [] [] = []
   531   | unflat _ _ = raise UnequalLengths;
   532 
   533 fun burrow f xss = unflat xss (f (flat xss));
   534 
   535 fun burrow_options f os = map (try hd) (burrow f (map the_list os));
   536 
   537 fun fold_burrow f xss s =
   538   apfst (unflat xss) (f (flat xss) s);
   539 
   540 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   541 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   542   | separate _ xs = xs;
   543 
   544 fun surround s (x :: xs) = s :: x :: surround s xs
   545   | surround s [] = [s];
   546 
   547 (*make the list [x, x, ..., x] of length n*)
   548 fun replicate (n: int) x =
   549   let fun rep (0, xs) = xs
   550         | rep (n, xs) = rep (n - 1, x :: xs)
   551   in
   552     if n < 0 then raise Subscript
   553     else rep (n, [])
   554   end;
   555 
   556 fun translate_string f = String.translate (f o String.str);
   557 
   558 (*multiply [a, b, c, ...] * [xs, ys, zs, ...]*)
   559 fun multiply [] _ = []
   560   | multiply (x :: xs) yss = map (cons x) yss @ multiply xs yss;
   561 
   562 
   563 (* direct product *)
   564 
   565 fun map_product f _ [] = []
   566   | map_product f [] _ = []
   567   | map_product f (x :: xs) ys = map (f x) ys @ map_product f xs ys;
   568 
   569 fun fold_product f _ [] z = z
   570   | fold_product f [] _ z = z
   571   | fold_product f (x :: xs) ys z = z |> fold (f x) ys |> fold_product f xs ys;
   572 
   573 
   574 (* lists of pairs *)
   575 
   576 exception UnequalLengths;
   577 
   578 fun map2 _ [] [] = []
   579   | map2 f (x :: xs) (y :: ys) = f x y :: map2 f xs ys
   580   | map2 _ _ _ = raise UnequalLengths;
   581 
   582 fun fold2 f [] [] z = z
   583   | fold2 f (x :: xs) (y :: ys) z = fold2 f xs ys (f x y z)
   584   | fold2 f _ _ _ = raise UnequalLengths;
   585 
   586 fun map_split f [] = ([], [])
   587   | map_split f (x :: xs) =
   588       let
   589         val (y, w) = f x;
   590         val (ys, ws) = map_split f xs;
   591       in (y :: ys, w :: ws) end;
   592 
   593 fun zip_options (x :: xs) (SOME y :: ys) = (x, y) :: zip_options xs ys
   594   | zip_options (_ :: xs) (NONE :: ys) = zip_options xs ys
   595   | zip_options _ [] = []
   596   | zip_options [] _ = raise UnequalLengths;
   597 
   598 (*combine two lists forming a list of pairs:
   599   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   600 fun [] ~~ [] = []
   601   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   602   | _ ~~ _ = raise UnequalLengths;
   603 
   604 (*inverse of ~~; the old 'split':
   605   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   606 val split_list = ListPair.unzip;
   607 
   608 
   609 (* prefixes, suffixes *)
   610 
   611 fun is_prefix _ [] _ = true
   612   | is_prefix eq (x :: xs) (y :: ys) = eq (x, y) andalso is_prefix eq xs ys
   613   | is_prefix eq _ _ = false;
   614 
   615 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   616    where xi is the first element that does not satisfy the predicate*)
   617 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   618   let fun take (rxs, []) = (rev rxs, [])
   619         | take (rxs, x :: xs) =
   620             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   621   in  take([], xs)  end;
   622 
   623 fun chop_prefix eq ([], ys) = ([], ([], ys))
   624   | chop_prefix eq (xs, []) = ([], (xs, []))
   625   | chop_prefix eq (xs as x :: xs', ys as y :: ys') =
   626       if eq (x, y) then
   627         let val (ps', xys'') = chop_prefix eq (xs', ys')
   628         in (x :: ps', xys'') end
   629       else ([], (xs, ys));
   630 
   631 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   632    where xi is the last element that does not satisfy the predicate*)
   633 fun take_suffix _ [] = ([], [])
   634   | take_suffix pred (x :: xs) =
   635       (case take_suffix pred xs of
   636         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   637       | (prfx, sffx) => (x :: prfx, sffx));
   638 
   639 fun prefixes1 [] = []
   640   | prefixes1 (x :: xs) = map (cons x) ([] :: prefixes1 xs);
   641 
   642 fun prefixes xs = [] :: prefixes1 xs;
   643 
   644 fun suffixes1 xs = map rev (prefixes1 (rev xs));
   645 fun suffixes xs = [] :: suffixes1 xs;
   646 
   647 
   648 
   649 (** integers **)
   650 
   651 fun inc i = (i := ! i + (1: int); ! i);
   652 fun dec i = (i := ! i - (1: int); ! i);
   653 
   654 
   655 (* lists of integers *)
   656 
   657 (*make the list [from, from + 1, ..., to]*)
   658 fun ((i: int) upto j) =
   659   if i > j then [] else i :: (i + 1 upto j);
   660 
   661 (*make the list [from, from - 1, ..., to]*)
   662 fun ((i: int) downto j) =
   663   if i < j then [] else i :: (i - 1 downto j);
   664 
   665 
   666 (* convert integers to strings *)
   667 
   668 (*expand the number in the given base;
   669   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   670 fun radixpand (base, num) : int list =
   671   let
   672     fun radix (n, tail) =
   673       if n < base then n :: tail
   674       else radix (n div base, (n mod base) :: tail)
   675   in radix (num, []) end;
   676 
   677 (*expands a number into a string of characters starting from "zerochar";
   678   example: radixstring (2, "0", 8) gives "1000"*)
   679 fun radixstring (base, zerochar, num) =
   680   let val offset = ord zerochar;
   681       fun chrof n = chr (offset + n)
   682   in implode (map chrof (radixpand (base, num))) end;
   683 
   684 
   685 val string_of_int = Int.toString;
   686 
   687 fun signed_string_of_int i =
   688   if i < 0 then "-" ^ string_of_int (~ i) else string_of_int i;
   689 
   690 fun string_of_indexname (a, 0) = a
   691   | string_of_indexname (a, i) = a ^ "_" ^ string_of_int i;
   692 
   693 
   694 (* read integers *)
   695 
   696 fun read_radix_int radix cs =
   697   let
   698     val zero = ord "0";
   699     val limit = zero + radix;
   700     fun scan (num, []) = (num, [])
   701       | scan (num, c :: cs) =
   702         if zero <= ord c andalso ord c < limit then
   703           scan (radix * num + (ord c - zero), cs)
   704         else (num, c :: cs);
   705   in scan (0, cs) end;
   706 
   707 val read_int = read_radix_int 10;
   708 
   709 fun oct_char s = chr (#1 (read_radix_int 8 (explode s)));
   710 
   711 
   712 
   713 (** strings **)
   714 
   715 (* functions tuned for strings, avoiding explode *)
   716 
   717 fun nth_string str i =
   718   (case try String.substring (str, i, 1) of
   719     SOME s => s
   720   | NONE => raise Subscript);
   721 
   722 fun fold_string f str x0 =
   723   let
   724     val n = size str;
   725     fun iter (x, i) =
   726       if i < n then iter (f (String.substring (str, i, 1)) x, i + 1) else x;
   727   in iter (x0, 0) end;
   728 
   729 fun exists_string pred str =
   730   let
   731     val n = size str;
   732     fun ex i = i < n andalso (pred (String.substring (str, i, 1)) orelse ex (i + 1));
   733   in ex 0 end;
   734 
   735 fun forall_string pred = not o exists_string (not o pred);
   736 
   737 fun first_field sep str =
   738   let
   739     val n = size sep;
   740     val len = size str;
   741     fun find i =
   742       if i + n > len then NONE
   743       else if String.substring (str, i, n) = sep then SOME i
   744       else find (i + 1);
   745   in
   746     (case find 0 of
   747       NONE => NONE
   748     | SOME i => SOME (String.substring (str, 0, i), String.extract (str, i + n, NONE)))
   749   end;
   750 
   751 (*enclose in brackets*)
   752 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   753 fun unenclose str = String.substring (str, 1, size str - 2);
   754 
   755 (*simple quoting (does not escape special chars)*)
   756 val quote = enclose "\"" "\"";
   757 
   758 (*space_implode "..." (explode "hello") = "h...e...l...l...o"*)
   759 fun space_implode a bs = implode (separate a bs);
   760 
   761 val commas = space_implode ", ";
   762 val commas_quote = commas o map quote;
   763 
   764 (*concatenate messages, one per line, into a string*)
   765 val cat_lines = space_implode "\n";
   766 
   767 (*space_explode "." "h.e..l.lo" = ["h", "e", "", "l", "lo"]*)
   768 fun space_explode _ "" = []
   769   | space_explode sep s = String.fields (fn c => str c = sep) s;
   770 
   771 val split_lines = space_explode "\n";
   772 
   773 fun prefix_lines "" txt = txt
   774   | prefix_lines prfx txt = txt |> split_lines |> map (fn s => prfx ^ s) |> cat_lines;
   775 
   776 fun prefix prfx s = prfx ^ s;
   777 fun suffix sffx s = s ^ sffx;
   778 
   779 fun unprefix prfx s =
   780   if String.isPrefix prfx s then String.substring (s, size prfx, size s - size prfx)
   781   else raise Fail "unprefix";
   782 
   783 fun unsuffix sffx s =
   784   if String.isSuffix sffx s then String.substring (s, 0, size s - size sffx)
   785   else raise Fail "unsuffix";
   786 
   787 fun replicate_string (0: int) _ = ""
   788   | replicate_string 1 a = a
   789   | replicate_string k a =
   790       if k mod 2 = 0 then replicate_string (k div 2) (a ^ a)
   791       else replicate_string (k div 2) (a ^ a) ^ a;
   792 
   793 
   794 
   795 (** lists as sets -- see also Pure/General/ord_list.ML **)
   796 
   797 (* canonical operations *)
   798 
   799 fun member eq list x =
   800   let
   801     fun memb [] = false
   802       | memb (y :: ys) = eq (x, y) orelse memb ys;
   803   in memb list end;
   804 
   805 fun insert eq x xs = if member eq xs x then xs else x :: xs;
   806 fun remove eq x xs = if member eq xs x then filter_out (fn y => eq (x, y)) xs else xs;
   807 fun update eq x xs = cons x (remove eq x xs);
   808 
   809 fun subtract eq = fold (remove eq);
   810 
   811 fun merge _ ([], ys) = ys
   812   | merge eq (xs, ys) = fold_rev (insert eq) ys xs;
   813 
   814 
   815 (* old-style infixes *)
   816 
   817 fun x mem xs = member (op =) xs x;
   818 fun (x: int) mem_int xs = member (op =) xs x;
   819 fun (x: string) mem_string xs = member (op =) xs x;
   820 
   821 (*union of sets represented as lists: no repetitions*)
   822 fun xs union [] = xs
   823   | [] union ys = ys
   824   | (x :: xs) union ys = xs union (insert (op =) x ys);
   825 
   826 (*union of sets, optimized version for ints*)
   827 fun (xs:int list) union_int [] = xs
   828   | [] union_int ys = ys
   829   | (x :: xs) union_int ys = xs union_int (insert (op =) x ys);
   830 
   831 (*union of sets, optimized version for strings*)
   832 fun (xs:string list) union_string [] = xs
   833   | [] union_string ys = ys
   834   | (x :: xs) union_string ys = xs union_string (insert (op =) x ys);
   835 
   836 (*generalized union*)
   837 fun gen_union eq (xs, []) = xs
   838   | gen_union eq ([], ys) = ys
   839   | gen_union eq (x :: xs, ys) = gen_union eq (xs, insert eq x ys);
   840 
   841 
   842 (*intersection*)
   843 fun [] inter ys = []
   844   | (x :: xs) inter ys =
   845       if x mem ys then x :: (xs inter ys) else xs inter ys;
   846 
   847 (*intersection, optimized version for ints*)
   848 fun ([]:int list) inter_int ys = []
   849   | (x :: xs) inter_int ys =
   850       if x mem_int ys then x :: (xs inter_int ys) else xs inter_int ys;
   851 
   852 (*intersection, optimized version for strings *)
   853 fun ([]:string list) inter_string ys = []
   854   | (x :: xs) inter_string ys =
   855       if x mem_string ys then x :: (xs inter_string ys) else xs inter_string ys;
   856 
   857 (*generalized intersection*)
   858 fun gen_inter eq ([], ys) = []
   859   | gen_inter eq (x::xs, ys) =
   860       if member eq ys x then x :: gen_inter eq (xs, ys)
   861       else gen_inter eq (xs, ys);
   862 
   863 
   864 (*subset*)
   865 fun [] subset ys = true
   866   | (x :: xs) subset ys = x mem ys andalso xs subset ys;
   867 
   868 (*subset, optimized version for ints*)
   869 fun ([]: int list) subset_int ys = true
   870   | (x :: xs) subset_int ys = x mem_int ys andalso xs subset_int ys;
   871 
   872 (*subset, optimized version for strings*)
   873 fun ([]: string list) subset_string ys = true
   874   | (x :: xs) subset_string ys = x mem_string ys andalso xs subset_string ys;
   875 
   876 (*set equality*)
   877 fun eq_set (xs, ys) =
   878   xs = ys orelse (xs subset ys andalso ys subset xs);
   879 
   880 (*set equality for strings*)
   881 fun eq_set_string ((xs: string list), ys) =
   882   xs = ys orelse (xs subset_string ys andalso ys subset_string xs);
   883 
   884 fun gen_subset eq (xs, ys) = forall (member eq ys) xs;
   885 
   886 fun gen_eq_set eq (xs, ys) =
   887   eq_list eq (xs, ys) orelse
   888     (gen_subset eq (xs, ys) andalso gen_subset (eq o swap) (ys, xs));
   889 
   890 
   891 (*removing an element from a list WITHOUT duplicates*)
   892 fun (y :: ys) \ x = if x = y then ys else y :: (ys \ x)
   893   | [] \ x = [];
   894 fun ys \\ xs = foldl (op \) (ys,xs);
   895 
   896 
   897 (*makes a list of the distinct members of the input; preserves order, takes
   898   first of equal elements*)
   899 fun distinct eq lst =
   900   let
   901     fun dist (rev_seen, []) = rev rev_seen
   902       | dist (rev_seen, x :: xs) =
   903           if member eq rev_seen x then dist (rev_seen, xs)
   904           else dist (x :: rev_seen, xs);
   905   in dist ([], lst) end;
   906 
   907 (*returns a list containing all repeated elements exactly once; preserves
   908   order, takes first of equal elements*)
   909 fun duplicates eq lst =
   910   let
   911     fun dups (rev_dups, []) = rev rev_dups
   912       | dups (rev_dups, x :: xs) =
   913           if member eq rev_dups x orelse not (member eq xs x) then
   914             dups (rev_dups, xs)
   915           else dups (x :: rev_dups, xs);
   916   in dups ([], lst) end;
   917 
   918 fun has_duplicates eq =
   919   let
   920     fun dups [] = false
   921       | dups (x :: xs) = member eq xs x orelse dups xs;
   922   in dups end;
   923 
   924 
   925 
   926 (** lists as multisets **)
   927 
   928 fun remove1 _ _ [] = raise Empty
   929   | remove1 eq y (x::xs) = if eq (y, x) then xs else x :: remove1 eq y xs;
   930 
   931 fun submultiset _ ([], _)  = true
   932   | submultiset eq (x :: xs, ys) = member eq ys x andalso submultiset eq (xs, remove1 eq x ys);
   933 
   934 
   935 
   936 (** orders **)
   937 
   938 fun is_equal EQUAL = true
   939   | is_equal _ = false;
   940 
   941 fun rev_order LESS = GREATER
   942   | rev_order EQUAL = EQUAL
   943   | rev_order GREATER = LESS;
   944 
   945 (*assume rel is a linear strict order*)
   946 fun make_ord rel (x, y) =
   947   if rel (x, y) then LESS
   948   else if rel (y, x) then GREATER
   949   else EQUAL;
   950 
   951 fun bool_ord (false, true) = LESS
   952   | bool_ord (true, false) = GREATER
   953   | bool_ord _ = EQUAL;
   954 
   955 val int_ord = Int.compare;
   956 val string_ord = String.compare;
   957 
   958 fun fast_string_ord (s1, s2) =
   959   (case int_ord (size s1, size s2) of EQUAL => string_ord (s1, s2) | ord => ord);
   960 
   961 fun option_ord ord (SOME x, SOME y) = ord (x, y)
   962   | option_ord _ (NONE, NONE) = EQUAL
   963   | option_ord _ (NONE, SOME _) = LESS
   964   | option_ord _ (SOME _, NONE) = GREATER;
   965 
   966 (*lexicographic product*)
   967 fun prod_ord a_ord b_ord ((x, y), (x', y')) =
   968   (case a_ord (x, x') of EQUAL => b_ord (y, y') | ord => ord);
   969 
   970 (*dictionary order -- in general NOT well-founded!*)
   971 fun dict_ord elem_ord (x :: xs, y :: ys) =
   972       (case elem_ord (x, y) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord)
   973   | dict_ord _ ([], []) = EQUAL
   974   | dict_ord _ ([], _ :: _) = LESS
   975   | dict_ord _ (_ :: _, []) = GREATER;
   976 
   977 (*lexicographic product of lists*)
   978 fun list_ord elem_ord (xs, ys) =
   979   (case int_ord (length xs, length ys) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
   980 
   981 
   982 (* sorting *)
   983 
   984 (*quicksort -- stable, i.e. does not reorder equal elements*)
   985 fun quicksort unique ord =
   986   let
   987     fun qsort [] = []
   988       | qsort (xs as [_]) = xs
   989       | qsort (xs as [x, y]) =
   990           (case ord (x, y) of
   991             LESS => xs
   992           | EQUAL => if unique then [x] else xs
   993           | GREATER => [y, x])
   994       | qsort xs =
   995           let val (lts, eqs, gts) = part (nth xs (length xs div 2)) xs
   996           in qsort lts @ eqs @ qsort gts end
   997     and part _ [] = ([], [], [])
   998       | part pivot (x :: xs) = add (ord (x, pivot)) x (part pivot xs)
   999     and add LESS x (lts, eqs, gts) = (x :: lts, eqs, gts)
  1000       | add EQUAL x (lts, [], gts) = (lts, [x], gts)
  1001       | add EQUAL x (res as (lts, eqs, gts)) = if unique then res else (lts, x :: eqs, gts)
  1002       | add GREATER x (lts, eqs, gts) = (lts, eqs, x :: gts);
  1003   in qsort end;
  1004 
  1005 fun sort ord = quicksort false ord;
  1006 fun sort_distinct ord = quicksort true ord;
  1007 
  1008 val sort_strings = sort string_ord;
  1009 fun sort_wrt sel xs = sort (string_ord o pairself sel) xs;
  1010 
  1011 
  1012 
  1013 (** random numbers **)
  1014 
  1015 exception RANDOM;
  1016 
  1017 fun rmod x y = x - y * Real.realFloor (x / y);
  1018 
  1019 local
  1020   val a = 16807.0;
  1021   val m = 2147483647.0;
  1022   val random_seed = ref 1.0;
  1023 in
  1024 
  1025 fun random () = CRITICAL (fn () =>
  1026   let val r = rmod (a * ! random_seed) m
  1027   in (random_seed := r; r) end);
  1028 
  1029 end;
  1030 
  1031 fun random_range l h =
  1032   if h < l orelse l < 0 then raise RANDOM
  1033   else l + Real.floor (rmod (random ()) (real (h - l + 1)));
  1034 
  1035 fun one_of xs = nth xs (random_range 0 (length xs - 1));
  1036 
  1037 fun frequency xs =
  1038   let
  1039     val sum = foldl op + (0, map fst xs);
  1040     fun pick n ((k: int, x) :: xs) =
  1041       if n <= k then x else pick (n - k) xs
  1042   in pick (random_range 1 sum) xs end;
  1043 
  1044 
  1045 
  1046 (** misc **)
  1047 
  1048 fun divide_and_conquer decomp x =
  1049   let val (ys, recomb) = decomp x
  1050   in recomb (map (divide_and_conquer decomp) ys) end;
  1051 
  1052 
  1053 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
  1054    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
  1055 fun partition_list p i j =
  1056   let fun part k xs =
  1057             if k>j then
  1058               (case xs of [] => []
  1059                          | _ => raise Fail "partition_list")
  1060             else
  1061             let val (ns, rest) = List.partition (p k) xs;
  1062             in  ns :: part(k+1)rest  end
  1063   in  part (i: int) end;
  1064 
  1065 fun partition_eq (eq:'a * 'a -> bool) =
  1066   let
  1067     fun part [] = []
  1068       | part (x :: ys) =
  1069           let val (xs, xs') = List.partition (fn y => eq (x, y)) ys
  1070           in (x::xs)::(part xs') end
  1071   in part end;
  1072 
  1073 
  1074 
  1075 (* generating identifiers *)
  1076 
  1077 (** Freshly generated identifiers; supplied prefix MUST start with a letter **)
  1078 local
  1079 (*Maps 0-61 to A-Z, a-z, 0-9; exclude _ or ' to avoid clash with internal/unusual indentifiers*)
  1080 fun gensym_char i =
  1081   if i<26 then chr (ord "A" + i)
  1082   else if i<52 then chr (ord "a" + i - 26)
  1083   else chr (ord "0" + i - 52);
  1084 
  1085 val char_vec = Vector.tabulate (62, gensym_char);
  1086 fun newid n = implode (map (fn i => Vector.sub (char_vec, i)) (radixpand (62, n)));
  1087 
  1088 val gensym_seed = ref (0: int);
  1089 
  1090 in
  1091   fun gensym pre = pre ^ newid (NAMED_CRITICAL "gensym" (fn () => inc gensym_seed));
  1092 end;
  1093 
  1094 
  1095 (* stamps and serial numbers *)
  1096 
  1097 type stamp = unit ref;
  1098 val stamp: unit -> stamp = ref;
  1099 
  1100 type serial = int;
  1101 val serial = Multithreading.serial;
  1102 val serial_string = string_of_int o serial;
  1103 
  1104 
  1105 (* generic objects *)
  1106 
  1107 (*note that the builtin exception datatype may be extended by new
  1108   constructors at any time*)
  1109 structure Object = struct type T = exn end;
  1110 
  1111 end;
  1112 
  1113 structure BasicLibrary: BASIC_LIBRARY = Library;
  1114 open BasicLibrary;