src/HOL/OrderedGroup.thy
author haftmann
Fri Feb 15 16:09:10 2008 +0100 (2008-02-15)
changeset 26071 046fe7ddfc4b
parent 26015 ad2756de580e
child 26480 544cef16045b
permissions -rw-r--r--
moved *_reorient lemmas here
     1 (*  Title:   HOL/OrderedGroup.thy
     2     ID:      $Id$
     3     Author:  Gertrud Bauer, Steven Obua, Lawrence C Paulson, and Markus Wenzel,
     4              with contributions by Jeremy Avigad
     5 *)
     6 
     7 header {* Ordered Groups *}
     8 
     9 theory OrderedGroup
    10 imports Lattices
    11 uses "~~/src/Provers/Arith/abel_cancel.ML"
    12 begin
    13 
    14 text {*
    15   The theory of partially ordered groups is taken from the books:
    16   \begin{itemize}
    17   \item \emph{Lattice Theory} by Garret Birkhoff, American Mathematical Society 1979 
    18   \item \emph{Partially Ordered Algebraic Systems}, Pergamon Press 1963
    19   \end{itemize}
    20   Most of the used notions can also be looked up in 
    21   \begin{itemize}
    22   \item \url{http://www.mathworld.com} by Eric Weisstein et. al.
    23   \item \emph{Algebra I} by van der Waerden, Springer.
    24   \end{itemize}
    25 *}
    26 
    27 subsection {* Semigroups and Monoids *}
    28 
    29 class semigroup_add = plus +
    30   assumes add_assoc: "(a + b) + c = a + (b + c)"
    31 
    32 class ab_semigroup_add = semigroup_add +
    33   assumes add_commute: "a + b = b + a"
    34 begin
    35 
    36 lemma add_left_commute: "a + (b + c) = b + (a + c)"
    37   by (rule mk_left_commute [of "plus", OF add_assoc add_commute])
    38 
    39 theorems add_ac = add_assoc add_commute add_left_commute
    40 
    41 end
    42 
    43 theorems add_ac = add_assoc add_commute add_left_commute
    44 
    45 class semigroup_mult = times +
    46   assumes mult_assoc: "(a * b) * c = a * (b * c)"
    47 
    48 class ab_semigroup_mult = semigroup_mult +
    49   assumes mult_commute: "a * b = b * a"
    50 begin
    51 
    52 lemma mult_left_commute: "a * (b * c) = b * (a * c)"
    53   by (rule mk_left_commute [of "times", OF mult_assoc mult_commute])
    54 
    55 theorems mult_ac = mult_assoc mult_commute mult_left_commute
    56 
    57 end
    58 
    59 theorems mult_ac = mult_assoc mult_commute mult_left_commute
    60 
    61 class ab_semigroup_idem_mult = ab_semigroup_mult +
    62   assumes mult_idem: "x * x = x"
    63 begin
    64 
    65 lemma mult_left_idem: "x * (x * y) = x * y"
    66   unfolding mult_assoc [symmetric, of x] mult_idem ..
    67 
    68 lemmas mult_ac_idem = mult_ac mult_idem mult_left_idem
    69 
    70 end
    71 
    72 lemmas mult_ac_idem = mult_ac mult_idem mult_left_idem
    73 
    74 class monoid_add = zero + semigroup_add +
    75   assumes add_0_left [simp]: "0 + a = a"
    76     and add_0_right [simp]: "a + 0 = a"
    77 
    78 lemma zero_reorient: "0 = x \<longleftrightarrow> x = 0"
    79   by (rule eq_commute)
    80 
    81 class comm_monoid_add = zero + ab_semigroup_add +
    82   assumes add_0: "0 + a = a"
    83 begin
    84 
    85 subclass monoid_add
    86   by unfold_locales (insert add_0, simp_all add: add_commute)
    87 
    88 end
    89 
    90 class monoid_mult = one + semigroup_mult +
    91   assumes mult_1_left [simp]: "1 * a  = a"
    92   assumes mult_1_right [simp]: "a * 1 = a"
    93 
    94 lemma one_reorient: "1 = x \<longleftrightarrow> x = 1"
    95   by (rule eq_commute)
    96 
    97 class comm_monoid_mult = one + ab_semigroup_mult +
    98   assumes mult_1: "1 * a = a"
    99 begin
   100 
   101 subclass monoid_mult
   102   by unfold_locales (insert mult_1, simp_all add: mult_commute)
   103 
   104 end
   105 
   106 class cancel_semigroup_add = semigroup_add +
   107   assumes add_left_imp_eq: "a + b = a + c \<Longrightarrow> b = c"
   108   assumes add_right_imp_eq: "b + a = c + a \<Longrightarrow> b = c"
   109 
   110 class cancel_ab_semigroup_add = ab_semigroup_add +
   111   assumes add_imp_eq: "a + b = a + c \<Longrightarrow> b = c"
   112 begin
   113 
   114 subclass cancel_semigroup_add
   115 proof unfold_locales
   116   fix a b c :: 'a
   117   assume "a + b = a + c" 
   118   then show "b = c" by (rule add_imp_eq)
   119 next
   120   fix a b c :: 'a
   121   assume "b + a = c + a"
   122   then have "a + b = a + c" by (simp only: add_commute)
   123   then show "b = c" by (rule add_imp_eq)
   124 qed
   125 
   126 end
   127 
   128 context cancel_ab_semigroup_add
   129 begin
   130 
   131 lemma add_left_cancel [simp]:
   132   "a + b = a + c \<longleftrightarrow> b = c"
   133   by (blast dest: add_left_imp_eq)
   134 
   135 lemma add_right_cancel [simp]:
   136   "b + a = c + a \<longleftrightarrow> b = c"
   137   by (blast dest: add_right_imp_eq)
   138 
   139 end
   140 
   141 subsection {* Groups *}
   142 
   143 class group_add = minus + uminus + monoid_add +
   144   assumes left_minus [simp]: "- a + a = 0"
   145   assumes diff_minus: "a - b = a + (- b)"
   146 begin
   147 
   148 lemma minus_add_cancel: "- a + (a + b) = b"
   149   by (simp add: add_assoc[symmetric])
   150 
   151 lemma minus_zero [simp]: "- 0 = 0"
   152 proof -
   153   have "- 0 = - 0 + (0 + 0)" by (simp only: add_0_right)
   154   also have "\<dots> = 0" by (rule minus_add_cancel)
   155   finally show ?thesis .
   156 qed
   157 
   158 lemma minus_minus [simp]: "- (- a) = a"
   159 proof -
   160   have "- (- a) = - (- a) + (- a + a)" by simp
   161   also have "\<dots> = a" by (rule minus_add_cancel)
   162   finally show ?thesis .
   163 qed
   164 
   165 lemma right_minus [simp]: "a + - a = 0"
   166 proof -
   167   have "a + - a = - (- a) + - a" by simp
   168   also have "\<dots> = 0" by (rule left_minus)
   169   finally show ?thesis .
   170 qed
   171 
   172 lemma right_minus_eq: "a - b = 0 \<longleftrightarrow> a = b"
   173 proof
   174   assume "a - b = 0"
   175   have "a = (a - b) + b" by (simp add:diff_minus add_assoc)
   176   also have "\<dots> = b" using `a - b = 0` by simp
   177   finally show "a = b" .
   178 next
   179   assume "a = b" thus "a - b = 0" by (simp add: diff_minus)
   180 qed
   181 
   182 lemma equals_zero_I:
   183   assumes "a + b = 0"
   184   shows "- a = b"
   185 proof -
   186   have "- a = - a + (a + b)" using assms by simp
   187   also have "\<dots> = b" by (simp add: add_assoc[symmetric])
   188   finally show ?thesis .
   189 qed
   190 
   191 lemma diff_self [simp]: "a - a = 0"
   192   by (simp add: diff_minus)
   193 
   194 lemma diff_0 [simp]: "0 - a = - a"
   195   by (simp add: diff_minus)
   196 
   197 lemma diff_0_right [simp]: "a - 0 = a" 
   198   by (simp add: diff_minus)
   199 
   200 lemma diff_minus_eq_add [simp]: "a - - b = a + b"
   201   by (simp add: diff_minus)
   202 
   203 lemma neg_equal_iff_equal [simp]:
   204   "- a = - b \<longleftrightarrow> a = b" 
   205 proof 
   206   assume "- a = - b"
   207   hence "- (- a) = - (- b)"
   208     by simp
   209   thus "a = b" by simp
   210 next
   211   assume "a = b"
   212   thus "- a = - b" by simp
   213 qed
   214 
   215 lemma neg_equal_0_iff_equal [simp]:
   216   "- a = 0 \<longleftrightarrow> a = 0"
   217   by (subst neg_equal_iff_equal [symmetric], simp)
   218 
   219 lemma neg_0_equal_iff_equal [simp]:
   220   "0 = - a \<longleftrightarrow> 0 = a"
   221   by (subst neg_equal_iff_equal [symmetric], simp)
   222 
   223 text{*The next two equations can make the simplifier loop!*}
   224 
   225 lemma equation_minus_iff:
   226   "a = - b \<longleftrightarrow> b = - a"
   227 proof -
   228   have "- (- a) = - b \<longleftrightarrow> - a = b" by (rule neg_equal_iff_equal)
   229   thus ?thesis by (simp add: eq_commute)
   230 qed
   231 
   232 lemma minus_equation_iff:
   233   "- a = b \<longleftrightarrow> - b = a"
   234 proof -
   235   have "- a = - (- b) \<longleftrightarrow> a = -b" by (rule neg_equal_iff_equal)
   236   thus ?thesis by (simp add: eq_commute)
   237 qed
   238 
   239 end
   240 
   241 class ab_group_add = minus + uminus + comm_monoid_add +
   242   assumes ab_left_minus: "- a + a = 0"
   243   assumes ab_diff_minus: "a - b = a + (- b)"
   244 begin
   245 
   246 subclass group_add
   247   by unfold_locales (simp_all add: ab_left_minus ab_diff_minus)
   248 
   249 subclass cancel_ab_semigroup_add
   250 proof unfold_locales
   251   fix a b c :: 'a
   252   assume "a + b = a + c"
   253   then have "- a + a + b = - a + a + c"
   254     unfolding add_assoc by simp
   255   then show "b = c" by simp
   256 qed
   257 
   258 lemma uminus_add_conv_diff:
   259   "- a + b = b - a"
   260   by (simp add:diff_minus add_commute)
   261 
   262 lemma minus_add_distrib [simp]:
   263   "- (a + b) = - a + - b"
   264   by (rule equals_zero_I) (simp add: add_ac)
   265 
   266 lemma minus_diff_eq [simp]:
   267   "- (a - b) = b - a"
   268   by (simp add: diff_minus add_commute)
   269 
   270 lemma add_diff_eq: "a + (b - c) = (a + b) - c"
   271   by (simp add: diff_minus add_ac)
   272 
   273 lemma diff_add_eq: "(a - b) + c = (a + c) - b"
   274   by (simp add: diff_minus add_ac)
   275 
   276 lemma diff_eq_eq: "a - b = c \<longleftrightarrow> a = c + b"
   277   by (auto simp add: diff_minus add_assoc)
   278 
   279 lemma eq_diff_eq: "a = c - b \<longleftrightarrow> a + b = c"
   280   by (auto simp add: diff_minus add_assoc)
   281 
   282 lemma diff_diff_eq: "(a - b) - c = a - (b + c)"
   283   by (simp add: diff_minus add_ac)
   284 
   285 lemma diff_diff_eq2: "a - (b - c) = (a + c) - b"
   286   by (simp add: diff_minus add_ac)
   287 
   288 lemma diff_add_cancel: "a - b + b = a"
   289   by (simp add: diff_minus add_ac)
   290 
   291 lemma add_diff_cancel: "a + b - b = a"
   292   by (simp add: diff_minus add_ac)
   293 
   294 lemmas compare_rls =
   295        diff_minus [symmetric]
   296        add_diff_eq diff_add_eq diff_diff_eq diff_diff_eq2
   297        diff_eq_eq eq_diff_eq
   298 
   299 lemma eq_iff_diff_eq_0: "a = b \<longleftrightarrow> a - b = 0"
   300   by (simp add: compare_rls)
   301 
   302 end
   303 
   304 subsection {* (Partially) Ordered Groups *} 
   305 
   306 class pordered_ab_semigroup_add = order + ab_semigroup_add +
   307   assumes add_left_mono: "a \<le> b \<Longrightarrow> c + a \<le> c + b"
   308 begin
   309 
   310 lemma add_right_mono:
   311   "a \<le> b \<Longrightarrow> a + c \<le> b + c"
   312   by (simp add: add_commute [of _ c] add_left_mono)
   313 
   314 text {* non-strict, in both arguments *}
   315 lemma add_mono:
   316   "a \<le> b \<Longrightarrow> c \<le> d \<Longrightarrow> a + c \<le> b + d"
   317   apply (erule add_right_mono [THEN order_trans])
   318   apply (simp add: add_commute add_left_mono)
   319   done
   320 
   321 end
   322 
   323 class pordered_cancel_ab_semigroup_add =
   324   pordered_ab_semigroup_add + cancel_ab_semigroup_add
   325 begin
   326 
   327 lemma add_strict_left_mono:
   328   "a < b \<Longrightarrow> c + a < c + b"
   329   by (auto simp add: less_le add_left_mono)
   330 
   331 lemma add_strict_right_mono:
   332   "a < b \<Longrightarrow> a + c < b + c"
   333   by (simp add: add_commute [of _ c] add_strict_left_mono)
   334 
   335 text{*Strict monotonicity in both arguments*}
   336 lemma add_strict_mono:
   337   "a < b \<Longrightarrow> c < d \<Longrightarrow> a + c < b + d"
   338 apply (erule add_strict_right_mono [THEN less_trans])
   339 apply (erule add_strict_left_mono)
   340 done
   341 
   342 lemma add_less_le_mono:
   343   "a < b \<Longrightarrow> c \<le> d \<Longrightarrow> a + c < b + d"
   344 apply (erule add_strict_right_mono [THEN less_le_trans])
   345 apply (erule add_left_mono)
   346 done
   347 
   348 lemma add_le_less_mono:
   349   "a \<le> b \<Longrightarrow> c < d \<Longrightarrow> a + c < b + d"
   350 apply (erule add_right_mono [THEN le_less_trans])
   351 apply (erule add_strict_left_mono) 
   352 done
   353 
   354 end
   355 
   356 class pordered_ab_semigroup_add_imp_le =
   357   pordered_cancel_ab_semigroup_add +
   358   assumes add_le_imp_le_left: "c + a \<le> c + b \<Longrightarrow> a \<le> b"
   359 begin
   360 
   361 lemma add_less_imp_less_left:
   362    assumes less: "c + a < c + b"
   363    shows "a < b"
   364 proof -
   365   from less have le: "c + a <= c + b" by (simp add: order_le_less)
   366   have "a <= b" 
   367     apply (insert le)
   368     apply (drule add_le_imp_le_left)
   369     by (insert le, drule add_le_imp_le_left, assumption)
   370   moreover have "a \<noteq> b"
   371   proof (rule ccontr)
   372     assume "~(a \<noteq> b)"
   373     then have "a = b" by simp
   374     then have "c + a = c + b" by simp
   375     with less show "False"by simp
   376   qed
   377   ultimately show "a < b" by (simp add: order_le_less)
   378 qed
   379 
   380 lemma add_less_imp_less_right:
   381   "a + c < b + c \<Longrightarrow> a < b"
   382 apply (rule add_less_imp_less_left [of c])
   383 apply (simp add: add_commute)  
   384 done
   385 
   386 lemma add_less_cancel_left [simp]:
   387   "c + a < c + b \<longleftrightarrow> a < b"
   388   by (blast intro: add_less_imp_less_left add_strict_left_mono) 
   389 
   390 lemma add_less_cancel_right [simp]:
   391   "a + c < b + c \<longleftrightarrow> a < b"
   392   by (blast intro: add_less_imp_less_right add_strict_right_mono)
   393 
   394 lemma add_le_cancel_left [simp]:
   395   "c + a \<le> c + b \<longleftrightarrow> a \<le> b"
   396   by (auto, drule add_le_imp_le_left, simp_all add: add_left_mono) 
   397 
   398 lemma add_le_cancel_right [simp]:
   399   "a + c \<le> b + c \<longleftrightarrow> a \<le> b"
   400   by (simp add: add_commute [of a c] add_commute [of b c])
   401 
   402 lemma add_le_imp_le_right:
   403   "a + c \<le> b + c \<Longrightarrow> a \<le> b"
   404   by simp
   405 
   406 lemma max_add_distrib_left:
   407   "max x y + z = max (x + z) (y + z)"
   408   unfolding max_def by auto
   409 
   410 lemma min_add_distrib_left:
   411   "min x y + z = min (x + z) (y + z)"
   412   unfolding min_def by auto
   413 
   414 end
   415 
   416 subsection {* Support for reasoning about signs *}
   417 
   418 class pordered_comm_monoid_add =
   419   pordered_cancel_ab_semigroup_add + comm_monoid_add
   420 begin
   421 
   422 lemma add_pos_nonneg:
   423   assumes "0 < a" and "0 \<le> b"
   424     shows "0 < a + b"
   425 proof -
   426   have "0 + 0 < a + b" 
   427     using assms by (rule add_less_le_mono)
   428   then show ?thesis by simp
   429 qed
   430 
   431 lemma add_pos_pos:
   432   assumes "0 < a" and "0 < b"
   433     shows "0 < a + b"
   434   by (rule add_pos_nonneg) (insert assms, auto)
   435 
   436 lemma add_nonneg_pos:
   437   assumes "0 \<le> a" and "0 < b"
   438     shows "0 < a + b"
   439 proof -
   440   have "0 + 0 < a + b" 
   441     using assms by (rule add_le_less_mono)
   442   then show ?thesis by simp
   443 qed
   444 
   445 lemma add_nonneg_nonneg:
   446   assumes "0 \<le> a" and "0 \<le> b"
   447     shows "0 \<le> a + b"
   448 proof -
   449   have "0 + 0 \<le> a + b" 
   450     using assms by (rule add_mono)
   451   then show ?thesis by simp
   452 qed
   453 
   454 lemma add_neg_nonpos: 
   455   assumes "a < 0" and "b \<le> 0"
   456   shows "a + b < 0"
   457 proof -
   458   have "a + b < 0 + 0"
   459     using assms by (rule add_less_le_mono)
   460   then show ?thesis by simp
   461 qed
   462 
   463 lemma add_neg_neg: 
   464   assumes "a < 0" and "b < 0"
   465   shows "a + b < 0"
   466   by (rule add_neg_nonpos) (insert assms, auto)
   467 
   468 lemma add_nonpos_neg:
   469   assumes "a \<le> 0" and "b < 0"
   470   shows "a + b < 0"
   471 proof -
   472   have "a + b < 0 + 0"
   473     using assms by (rule add_le_less_mono)
   474   then show ?thesis by simp
   475 qed
   476 
   477 lemma add_nonpos_nonpos:
   478   assumes "a \<le> 0" and "b \<le> 0"
   479   shows "a + b \<le> 0"
   480 proof -
   481   have "a + b \<le> 0 + 0"
   482     using assms by (rule add_mono)
   483   then show ?thesis by simp
   484 qed
   485 
   486 end
   487 
   488 class pordered_ab_group_add =
   489   ab_group_add + pordered_ab_semigroup_add
   490 begin
   491 
   492 subclass pordered_cancel_ab_semigroup_add
   493   by intro_locales
   494 
   495 subclass pordered_ab_semigroup_add_imp_le
   496 proof unfold_locales
   497   fix a b c :: 'a
   498   assume "c + a \<le> c + b"
   499   hence "(-c) + (c + a) \<le> (-c) + (c + b)" by (rule add_left_mono)
   500   hence "((-c) + c) + a \<le> ((-c) + c) + b" by (simp only: add_assoc)
   501   thus "a \<le> b" by simp
   502 qed
   503 
   504 subclass pordered_comm_monoid_add
   505   by intro_locales
   506 
   507 lemma max_diff_distrib_left:
   508   shows "max x y - z = max (x - z) (y - z)"
   509   by (simp add: diff_minus, rule max_add_distrib_left) 
   510 
   511 lemma min_diff_distrib_left:
   512   shows "min x y - z = min (x - z) (y - z)"
   513   by (simp add: diff_minus, rule min_add_distrib_left) 
   514 
   515 lemma le_imp_neg_le:
   516   assumes "a \<le> b"
   517   shows "-b \<le> -a"
   518 proof -
   519   have "-a+a \<le> -a+b"
   520     using `a \<le> b` by (rule add_left_mono) 
   521   hence "0 \<le> -a+b"
   522     by simp
   523   hence "0 + (-b) \<le> (-a + b) + (-b)"
   524     by (rule add_right_mono) 
   525   thus ?thesis
   526     by (simp add: add_assoc)
   527 qed
   528 
   529 lemma neg_le_iff_le [simp]: "- b \<le> - a \<longleftrightarrow> a \<le> b"
   530 proof 
   531   assume "- b \<le> - a"
   532   hence "- (- a) \<le> - (- b)"
   533     by (rule le_imp_neg_le)
   534   thus "a\<le>b" by simp
   535 next
   536   assume "a\<le>b"
   537   thus "-b \<le> -a" by (rule le_imp_neg_le)
   538 qed
   539 
   540 lemma neg_le_0_iff_le [simp]: "- a \<le> 0 \<longleftrightarrow> 0 \<le> a"
   541   by (subst neg_le_iff_le [symmetric], simp)
   542 
   543 lemma neg_0_le_iff_le [simp]: "0 \<le> - a \<longleftrightarrow> a \<le> 0"
   544   by (subst neg_le_iff_le [symmetric], simp)
   545 
   546 lemma neg_less_iff_less [simp]: "- b < - a \<longleftrightarrow> a < b"
   547   by (force simp add: less_le) 
   548 
   549 lemma neg_less_0_iff_less [simp]: "- a < 0 \<longleftrightarrow> 0 < a"
   550   by (subst neg_less_iff_less [symmetric], simp)
   551 
   552 lemma neg_0_less_iff_less [simp]: "0 < - a \<longleftrightarrow> a < 0"
   553   by (subst neg_less_iff_less [symmetric], simp)
   554 
   555 text{*The next several equations can make the simplifier loop!*}
   556 
   557 lemma less_minus_iff: "a < - b \<longleftrightarrow> b < - a"
   558 proof -
   559   have "(- (-a) < - b) = (b < - a)" by (rule neg_less_iff_less)
   560   thus ?thesis by simp
   561 qed
   562 
   563 lemma minus_less_iff: "- a < b \<longleftrightarrow> - b < a"
   564 proof -
   565   have "(- a < - (-b)) = (- b < a)" by (rule neg_less_iff_less)
   566   thus ?thesis by simp
   567 qed
   568 
   569 lemma le_minus_iff: "a \<le> - b \<longleftrightarrow> b \<le> - a"
   570 proof -
   571   have mm: "!! a (b::'a). (-(-a)) < -b \<Longrightarrow> -(-b) < -a" by (simp only: minus_less_iff)
   572   have "(- (- a) <= -b) = (b <= - a)" 
   573     apply (auto simp only: le_less)
   574     apply (drule mm)
   575     apply (simp_all)
   576     apply (drule mm[simplified], assumption)
   577     done
   578   then show ?thesis by simp
   579 qed
   580 
   581 lemma minus_le_iff: "- a \<le> b \<longleftrightarrow> - b \<le> a"
   582   by (auto simp add: le_less minus_less_iff)
   583 
   584 lemma less_iff_diff_less_0: "a < b \<longleftrightarrow> a - b < 0"
   585 proof -
   586   have  "(a < b) = (a + (- b) < b + (-b))"  
   587     by (simp only: add_less_cancel_right)
   588   also have "... =  (a - b < 0)" by (simp add: diff_minus)
   589   finally show ?thesis .
   590 qed
   591 
   592 lemma diff_less_eq: "a - b < c \<longleftrightarrow> a < c + b"
   593 apply (subst less_iff_diff_less_0 [of a])
   594 apply (rule less_iff_diff_less_0 [of _ c, THEN ssubst])
   595 apply (simp add: diff_minus add_ac)
   596 done
   597 
   598 lemma less_diff_eq: "a < c - b \<longleftrightarrow> a + b < c"
   599 apply (subst less_iff_diff_less_0 [of "plus a b"])
   600 apply (subst less_iff_diff_less_0 [of a])
   601 apply (simp add: diff_minus add_ac)
   602 done
   603 
   604 lemma diff_le_eq: "a - b \<le> c \<longleftrightarrow> a \<le> c + b"
   605   by (auto simp add: le_less diff_less_eq diff_add_cancel add_diff_cancel)
   606 
   607 lemma le_diff_eq: "a \<le> c - b \<longleftrightarrow> a + b \<le> c"
   608   by (auto simp add: le_less less_diff_eq diff_add_cancel add_diff_cancel)
   609 
   610 lemmas compare_rls =
   611        diff_minus [symmetric]
   612        add_diff_eq diff_add_eq diff_diff_eq diff_diff_eq2
   613        diff_less_eq less_diff_eq diff_le_eq le_diff_eq
   614        diff_eq_eq eq_diff_eq
   615 
   616 text{*This list of rewrites simplifies (in)equalities by bringing subtractions
   617   to the top and then moving negative terms to the other side.
   618   Use with @{text add_ac}*}
   619 lemmas (in -) compare_rls =
   620        diff_minus [symmetric]
   621        add_diff_eq diff_add_eq diff_diff_eq diff_diff_eq2
   622        diff_less_eq less_diff_eq diff_le_eq le_diff_eq
   623        diff_eq_eq eq_diff_eq
   624 
   625 lemma le_iff_diff_le_0: "a \<le> b \<longleftrightarrow> a - b \<le> 0"
   626   by (simp add: compare_rls)
   627 
   628 lemmas group_simps =
   629   add_ac
   630   add_diff_eq diff_add_eq diff_diff_eq diff_diff_eq2
   631   diff_eq_eq eq_diff_eq diff_minus [symmetric] uminus_add_conv_diff
   632   diff_less_eq less_diff_eq diff_le_eq le_diff_eq
   633 
   634 end
   635 
   636 lemmas group_simps =
   637   mult_ac
   638   add_ac
   639   add_diff_eq diff_add_eq diff_diff_eq diff_diff_eq2
   640   diff_eq_eq eq_diff_eq diff_minus [symmetric] uminus_add_conv_diff
   641   diff_less_eq less_diff_eq diff_le_eq le_diff_eq
   642 
   643 class ordered_ab_semigroup_add =
   644   linorder + pordered_ab_semigroup_add
   645 
   646 class ordered_cancel_ab_semigroup_add =
   647   linorder + pordered_cancel_ab_semigroup_add
   648 begin
   649 
   650 subclass ordered_ab_semigroup_add
   651   by intro_locales
   652 
   653 subclass pordered_ab_semigroup_add_imp_le
   654 proof unfold_locales
   655   fix a b c :: 'a
   656   assume le: "c + a <= c + b"  
   657   show "a <= b"
   658   proof (rule ccontr)
   659     assume w: "~ a \<le> b"
   660     hence "b <= a" by (simp add: linorder_not_le)
   661     hence le2: "c + b <= c + a" by (rule add_left_mono)
   662     have "a = b" 
   663       apply (insert le)
   664       apply (insert le2)
   665       apply (drule antisym, simp_all)
   666       done
   667     with w show False 
   668       by (simp add: linorder_not_le [symmetric])
   669   qed
   670 qed
   671 
   672 end
   673 
   674 class ordered_ab_group_add =
   675   linorder + pordered_ab_group_add
   676 begin
   677 
   678 subclass ordered_cancel_ab_semigroup_add 
   679   by intro_locales
   680 
   681 lemma neg_less_eq_nonneg:
   682   "- a \<le> a \<longleftrightarrow> 0 \<le> a"
   683 proof
   684   assume A: "- a \<le> a" show "0 \<le> a"
   685   proof (rule classical)
   686     assume "\<not> 0 \<le> a"
   687     then have "a < 0" by auto
   688     with A have "- a < 0" by (rule le_less_trans)
   689     then show ?thesis by auto
   690   qed
   691 next
   692   assume A: "0 \<le> a" show "- a \<le> a"
   693   proof (rule order_trans)
   694     show "- a \<le> 0" using A by (simp add: minus_le_iff)
   695   next
   696     show "0 \<le> a" using A .
   697   qed
   698 qed
   699   
   700 lemma less_eq_neg_nonpos:
   701   "a \<le> - a \<longleftrightarrow> a \<le> 0"
   702 proof
   703   assume A: "a \<le> - a" show "a \<le> 0"
   704   proof (rule classical)
   705     assume "\<not> a \<le> 0"
   706     then have "0 < a" by auto
   707     then have "0 < - a" using A by (rule less_le_trans)
   708     then show ?thesis by auto
   709   qed
   710 next
   711   assume A: "a \<le> 0" show "a \<le> - a"
   712   proof (rule order_trans)
   713     show "0 \<le> - a" using A by (simp add: minus_le_iff)
   714   next
   715     show "a \<le> 0" using A .
   716   qed
   717 qed
   718 
   719 lemma equal_neg_zero:
   720   "a = - a \<longleftrightarrow> a = 0"
   721 proof
   722   assume "a = 0" then show "a = - a" by simp
   723 next
   724   assume A: "a = - a" show "a = 0"
   725   proof (cases "0 \<le> a")
   726     case True with A have "0 \<le> - a" by auto
   727     with le_minus_iff have "a \<le> 0" by simp
   728     with True show ?thesis by (auto intro: order_trans)
   729   next
   730     case False then have B: "a \<le> 0" by auto
   731     with A have "- a \<le> 0" by auto
   732     with B show ?thesis by (auto intro: order_trans)
   733   qed
   734 qed
   735 
   736 lemma neg_equal_zero:
   737   "- a = a \<longleftrightarrow> a = 0"
   738   unfolding equal_neg_zero [symmetric] by auto
   739 
   740 end
   741 
   742 -- {* FIXME localize the following *}
   743 
   744 lemma add_increasing:
   745   fixes c :: "'a::{pordered_ab_semigroup_add_imp_le, comm_monoid_add}"
   746   shows  "[|0\<le>a; b\<le>c|] ==> b \<le> a + c"
   747 by (insert add_mono [of 0 a b c], simp)
   748 
   749 lemma add_increasing2:
   750   fixes c :: "'a::{pordered_ab_semigroup_add_imp_le, comm_monoid_add}"
   751   shows  "[|0\<le>c; b\<le>a|] ==> b \<le> a + c"
   752 by (simp add:add_increasing add_commute[of a])
   753 
   754 lemma add_strict_increasing:
   755   fixes c :: "'a::{pordered_ab_semigroup_add_imp_le, comm_monoid_add}"
   756   shows "[|0<a; b\<le>c|] ==> b < a + c"
   757 by (insert add_less_le_mono [of 0 a b c], simp)
   758 
   759 lemma add_strict_increasing2:
   760   fixes c :: "'a::{pordered_ab_semigroup_add_imp_le, comm_monoid_add}"
   761   shows "[|0\<le>a; b<c|] ==> b < a + c"
   762 by (insert add_le_less_mono [of 0 a b c], simp)
   763 
   764 
   765 class pordered_ab_group_add_abs = pordered_ab_group_add + abs +
   766   assumes abs_ge_zero [simp]: "\<bar>a\<bar> \<ge> 0"
   767     and abs_ge_self: "a \<le> \<bar>a\<bar>"
   768     and abs_leI: "a \<le> b \<Longrightarrow> - a \<le> b \<Longrightarrow> \<bar>a\<bar> \<le> b"
   769     and abs_minus_cancel [simp]: "\<bar>-a\<bar> = \<bar>a\<bar>"
   770     and abs_triangle_ineq: "\<bar>a + b\<bar> \<le> \<bar>a\<bar> + \<bar>b\<bar>"
   771 begin
   772 
   773 lemma abs_minus_le_zero: "- \<bar>a\<bar> \<le> 0"
   774   unfolding neg_le_0_iff_le by simp
   775 
   776 lemma abs_of_nonneg [simp]:
   777   assumes nonneg: "0 \<le> a"
   778   shows "\<bar>a\<bar> = a"
   779 proof (rule antisym)
   780   from nonneg le_imp_neg_le have "- a \<le> 0" by simp
   781   from this nonneg have "- a \<le> a" by (rule order_trans)
   782   then show "\<bar>a\<bar> \<le> a" by (auto intro: abs_leI)
   783 qed (rule abs_ge_self)
   784 
   785 lemma abs_idempotent [simp]: "\<bar>\<bar>a\<bar>\<bar> = \<bar>a\<bar>"
   786   by (rule antisym)
   787     (auto intro!: abs_ge_self abs_leI order_trans [of "uminus (abs a)" zero "abs a"])
   788 
   789 lemma abs_eq_0 [simp]: "\<bar>a\<bar> = 0 \<longleftrightarrow> a = 0"
   790 proof -
   791   have "\<bar>a\<bar> = 0 \<Longrightarrow> a = 0"
   792   proof (rule antisym)
   793     assume zero: "\<bar>a\<bar> = 0"
   794     with abs_ge_self show "a \<le> 0" by auto
   795     from zero have "\<bar>-a\<bar> = 0" by simp
   796     with abs_ge_self [of "uminus a"] have "- a \<le> 0" by auto
   797     with neg_le_0_iff_le show "0 \<le> a" by auto
   798   qed
   799   then show ?thesis by auto
   800 qed
   801 
   802 lemma abs_zero [simp]: "\<bar>0\<bar> = 0"
   803   by simp
   804 
   805 lemma abs_0_eq [simp, noatp]: "0 = \<bar>a\<bar> \<longleftrightarrow> a = 0"
   806 proof -
   807   have "0 = \<bar>a\<bar> \<longleftrightarrow> \<bar>a\<bar> = 0" by (simp only: eq_ac)
   808   thus ?thesis by simp
   809 qed
   810 
   811 lemma abs_le_zero_iff [simp]: "\<bar>a\<bar> \<le> 0 \<longleftrightarrow> a = 0" 
   812 proof
   813   assume "\<bar>a\<bar> \<le> 0"
   814   then have "\<bar>a\<bar> = 0" by (rule antisym) simp
   815   thus "a = 0" by simp
   816 next
   817   assume "a = 0"
   818   thus "\<bar>a\<bar> \<le> 0" by simp
   819 qed
   820 
   821 lemma zero_less_abs_iff [simp]: "0 < \<bar>a\<bar> \<longleftrightarrow> a \<noteq> 0"
   822   by (simp add: less_le)
   823 
   824 lemma abs_not_less_zero [simp]: "\<not> \<bar>a\<bar> < 0"
   825 proof -
   826   have a: "\<And>x y. x \<le> y \<Longrightarrow> \<not> y < x" by auto
   827   show ?thesis by (simp add: a)
   828 qed
   829 
   830 lemma abs_ge_minus_self: "- a \<le> \<bar>a\<bar>"
   831 proof -
   832   have "- a \<le> \<bar>-a\<bar>" by (rule abs_ge_self)
   833   then show ?thesis by simp
   834 qed
   835 
   836 lemma abs_minus_commute: 
   837   "\<bar>a - b\<bar> = \<bar>b - a\<bar>"
   838 proof -
   839   have "\<bar>a - b\<bar> = \<bar>- (a - b)\<bar>" by (simp only: abs_minus_cancel)
   840   also have "... = \<bar>b - a\<bar>" by simp
   841   finally show ?thesis .
   842 qed
   843 
   844 lemma abs_of_pos: "0 < a \<Longrightarrow> \<bar>a\<bar> = a"
   845   by (rule abs_of_nonneg, rule less_imp_le)
   846 
   847 lemma abs_of_nonpos [simp]:
   848   assumes "a \<le> 0"
   849   shows "\<bar>a\<bar> = - a"
   850 proof -
   851   let ?b = "- a"
   852   have "- ?b \<le> 0 \<Longrightarrow> \<bar>- ?b\<bar> = - (- ?b)"
   853   unfolding abs_minus_cancel [of "?b"]
   854   unfolding neg_le_0_iff_le [of "?b"]
   855   unfolding minus_minus by (erule abs_of_nonneg)
   856   then show ?thesis using assms by auto
   857 qed
   858   
   859 lemma abs_of_neg: "a < 0 \<Longrightarrow> \<bar>a\<bar> = - a"
   860   by (rule abs_of_nonpos, rule less_imp_le)
   861 
   862 lemma abs_le_D1: "\<bar>a\<bar> \<le> b \<Longrightarrow> a \<le> b"
   863   by (insert abs_ge_self, blast intro: order_trans)
   864 
   865 lemma abs_le_D2: "\<bar>a\<bar> \<le> b \<Longrightarrow> - a \<le> b"
   866   by (insert abs_le_D1 [of "uminus a"], simp)
   867 
   868 lemma abs_le_iff: "\<bar>a\<bar> \<le> b \<longleftrightarrow> a \<le> b \<and> - a \<le> b"
   869   by (blast intro: abs_leI dest: abs_le_D1 abs_le_D2)
   870 
   871 lemma abs_triangle_ineq2: "\<bar>a\<bar> - \<bar>b\<bar> \<le> \<bar>a - b\<bar>"
   872   apply (simp add: compare_rls)
   873   apply (subgoal_tac "abs a = abs (plus (minus a b) b)")
   874   apply (erule ssubst)
   875   apply (rule abs_triangle_ineq)
   876   apply (rule arg_cong) back
   877   apply (simp add: compare_rls)
   878 done
   879 
   880 lemma abs_triangle_ineq3: "\<bar>\<bar>a\<bar> - \<bar>b\<bar>\<bar> \<le> \<bar>a - b\<bar>"
   881   apply (subst abs_le_iff)
   882   apply auto
   883   apply (rule abs_triangle_ineq2)
   884   apply (subst abs_minus_commute)
   885   apply (rule abs_triangle_ineq2)
   886 done
   887 
   888 lemma abs_triangle_ineq4: "\<bar>a - b\<bar> \<le> \<bar>a\<bar> + \<bar>b\<bar>"
   889 proof -
   890   have "abs(a - b) = abs(a + - b)"
   891     by (subst diff_minus, rule refl)
   892   also have "... <= abs a + abs (- b)"
   893     by (rule abs_triangle_ineq)
   894   finally show ?thesis
   895     by simp
   896 qed
   897 
   898 lemma abs_diff_triangle_ineq: "\<bar>a + b - (c + d)\<bar> \<le> \<bar>a - c\<bar> + \<bar>b - d\<bar>"
   899 proof -
   900   have "\<bar>a + b - (c+d)\<bar> = \<bar>(a-c) + (b-d)\<bar>" by (simp add: diff_minus add_ac)
   901   also have "... \<le> \<bar>a-c\<bar> + \<bar>b-d\<bar>" by (rule abs_triangle_ineq)
   902   finally show ?thesis .
   903 qed
   904 
   905 lemma abs_add_abs [simp]:
   906   "\<bar>\<bar>a\<bar> + \<bar>b\<bar>\<bar> = \<bar>a\<bar> + \<bar>b\<bar>" (is "?L = ?R")
   907 proof (rule antisym)
   908   show "?L \<ge> ?R" by(rule abs_ge_self)
   909 next
   910   have "?L \<le> \<bar>\<bar>a\<bar>\<bar> + \<bar>\<bar>b\<bar>\<bar>" by(rule abs_triangle_ineq)
   911   also have "\<dots> = ?R" by simp
   912   finally show "?L \<le> ?R" .
   913 qed
   914 
   915 end
   916 
   917 
   918 subsection {* Lattice Ordered (Abelian) Groups *}
   919 
   920 class lordered_ab_group_add_meet = pordered_ab_group_add + lower_semilattice
   921 begin
   922 
   923 lemma add_inf_distrib_left:
   924   "a + inf b c = inf (a + b) (a + c)"
   925 apply (rule antisym)
   926 apply (simp_all add: le_infI)
   927 apply (rule add_le_imp_le_left [of "uminus a"])
   928 apply (simp only: add_assoc [symmetric], simp)
   929 apply rule
   930 apply (rule add_le_imp_le_left[of "a"], simp only: add_assoc[symmetric], simp)+
   931 done
   932 
   933 lemma add_inf_distrib_right:
   934   "inf a b + c = inf (a + c) (b + c)"
   935 proof -
   936   have "c + inf a b = inf (c+a) (c+b)" by (simp add: add_inf_distrib_left)
   937   thus ?thesis by (simp add: add_commute)
   938 qed
   939 
   940 end
   941 
   942 class lordered_ab_group_add_join = pordered_ab_group_add + upper_semilattice
   943 begin
   944 
   945 lemma add_sup_distrib_left:
   946   "a + sup b c = sup (a + b) (a + c)" 
   947 apply (rule antisym)
   948 apply (rule add_le_imp_le_left [of "uminus a"])
   949 apply (simp only: add_assoc[symmetric], simp)
   950 apply rule
   951 apply (rule add_le_imp_le_left [of "a"], simp only: add_assoc[symmetric], simp)+
   952 apply (rule le_supI)
   953 apply (simp_all)
   954 done
   955 
   956 lemma add_sup_distrib_right:
   957   "sup a b + c = sup (a+c) (b+c)"
   958 proof -
   959   have "c + sup a b = sup (c+a) (c+b)" by (simp add: add_sup_distrib_left)
   960   thus ?thesis by (simp add: add_commute)
   961 qed
   962 
   963 end
   964 
   965 class lordered_ab_group_add = pordered_ab_group_add + lattice
   966 begin
   967 
   968 subclass lordered_ab_group_add_meet by intro_locales
   969 subclass lordered_ab_group_add_join by intro_locales
   970 
   971 lemmas add_sup_inf_distribs = add_inf_distrib_right add_inf_distrib_left add_sup_distrib_right add_sup_distrib_left
   972 
   973 lemma inf_eq_neg_sup: "inf a b = - sup (-a) (-b)"
   974 proof (rule inf_unique)
   975   fix a b :: 'a
   976   show "- sup (-a) (-b) \<le> a"
   977     by (rule add_le_imp_le_right [of _ "sup (uminus a) (uminus b)"])
   978       (simp, simp add: add_sup_distrib_left)
   979 next
   980   fix a b :: 'a
   981   show "- sup (-a) (-b) \<le> b"
   982     by (rule add_le_imp_le_right [of _ "sup (uminus a) (uminus b)"])
   983       (simp, simp add: add_sup_distrib_left)
   984 next
   985   fix a b c :: 'a
   986   assume "a \<le> b" "a \<le> c"
   987   then show "a \<le> - sup (-b) (-c)" by (subst neg_le_iff_le [symmetric])
   988     (simp add: le_supI)
   989 qed
   990   
   991 lemma sup_eq_neg_inf: "sup a b = - inf (-a) (-b)"
   992 proof (rule sup_unique)
   993   fix a b :: 'a
   994   show "a \<le> - inf (-a) (-b)"
   995     by (rule add_le_imp_le_right [of _ "inf (uminus a) (uminus b)"])
   996       (simp, simp add: add_inf_distrib_left)
   997 next
   998   fix a b :: 'a
   999   show "b \<le> - inf (-a) (-b)"
  1000     by (rule add_le_imp_le_right [of _ "inf (uminus a) (uminus b)"])
  1001       (simp, simp add: add_inf_distrib_left)
  1002 next
  1003   fix a b c :: 'a
  1004   assume "a \<le> c" "b \<le> c"
  1005   then show "- inf (-a) (-b) \<le> c" by (subst neg_le_iff_le [symmetric])
  1006     (simp add: le_infI)
  1007 qed
  1008 
  1009 lemma neg_inf_eq_sup: "- inf a b = sup (-a) (-b)"
  1010   by (simp add: inf_eq_neg_sup)
  1011 
  1012 lemma neg_sup_eq_inf: "- sup a b = inf (-a) (-b)"
  1013   by (simp add: sup_eq_neg_inf)
  1014 
  1015 lemma add_eq_inf_sup: "a + b = sup a b + inf a b"
  1016 proof -
  1017   have "0 = - inf 0 (a-b) + inf (a-b) 0" by (simp add: inf_commute)
  1018   hence "0 = sup 0 (b-a) + inf (a-b) 0" by (simp add: inf_eq_neg_sup)
  1019   hence "0 = (-a + sup a b) + (inf a b + (-b))"
  1020     apply (simp add: add_sup_distrib_left add_inf_distrib_right)
  1021     by (simp add: diff_minus add_commute)
  1022   thus ?thesis
  1023     apply (simp add: compare_rls)
  1024     apply (subst add_left_cancel [symmetric, of "plus a b" "plus (sup a b) (inf a b)" "uminus a"])
  1025     apply (simp only: add_assoc, simp add: add_assoc[symmetric])
  1026     done
  1027 qed
  1028 
  1029 subsection {* Positive Part, Negative Part, Absolute Value *}
  1030 
  1031 definition
  1032   nprt :: "'a \<Rightarrow> 'a" where
  1033   "nprt x = inf x 0"
  1034 
  1035 definition
  1036   pprt :: "'a \<Rightarrow> 'a" where
  1037   "pprt x = sup x 0"
  1038 
  1039 lemma pprt_neg: "pprt (- x) = - nprt x"
  1040 proof -
  1041   have "sup (- x) 0 = sup (- x) (- 0)" unfolding minus_zero ..
  1042   also have "\<dots> = - inf x 0" unfolding neg_inf_eq_sup ..
  1043   finally have "sup (- x) 0 = - inf x 0" .
  1044   then show ?thesis unfolding pprt_def nprt_def .
  1045 qed
  1046 
  1047 lemma nprt_neg: "nprt (- x) = - pprt x"
  1048 proof -
  1049   from pprt_neg have "pprt (- (- x)) = - nprt (- x)" .
  1050   then have "pprt x = - nprt (- x)" by simp
  1051   then show ?thesis by simp
  1052 qed
  1053 
  1054 lemma prts: "a = pprt a + nprt a"
  1055   by (simp add: pprt_def nprt_def add_eq_inf_sup[symmetric])
  1056 
  1057 lemma zero_le_pprt[simp]: "0 \<le> pprt a"
  1058   by (simp add: pprt_def)
  1059 
  1060 lemma nprt_le_zero[simp]: "nprt a \<le> 0"
  1061   by (simp add: nprt_def)
  1062 
  1063 lemma le_eq_neg: "a \<le> - b \<longleftrightarrow> a + b \<le> 0" (is "?l = ?r")
  1064 proof -
  1065   have a: "?l \<longrightarrow> ?r"
  1066     apply (auto)
  1067     apply (rule add_le_imp_le_right[of _ "uminus b" _])
  1068     apply (simp add: add_assoc)
  1069     done
  1070   have b: "?r \<longrightarrow> ?l"
  1071     apply (auto)
  1072     apply (rule add_le_imp_le_right[of _ "b" _])
  1073     apply (simp)
  1074     done
  1075   from a b show ?thesis by blast
  1076 qed
  1077 
  1078 lemma pprt_0[simp]: "pprt 0 = 0" by (simp add: pprt_def)
  1079 lemma nprt_0[simp]: "nprt 0 = 0" by (simp add: nprt_def)
  1080 
  1081 lemma pprt_eq_id [simp, noatp]: "0 \<le> x \<Longrightarrow> pprt x = x"
  1082   by (simp add: pprt_def le_iff_sup sup_ACI)
  1083 
  1084 lemma nprt_eq_id [simp, noatp]: "x \<le> 0 \<Longrightarrow> nprt x = x"
  1085   by (simp add: nprt_def le_iff_inf inf_ACI)
  1086 
  1087 lemma pprt_eq_0 [simp, noatp]: "x \<le> 0 \<Longrightarrow> pprt x = 0"
  1088   by (simp add: pprt_def le_iff_sup sup_ACI)
  1089 
  1090 lemma nprt_eq_0 [simp, noatp]: "0 \<le> x \<Longrightarrow> nprt x = 0"
  1091   by (simp add: nprt_def le_iff_inf inf_ACI)
  1092 
  1093 lemma sup_0_imp_0: "sup a (- a) = 0 \<Longrightarrow> a = 0"
  1094 proof -
  1095   {
  1096     fix a::'a
  1097     assume hyp: "sup a (-a) = 0"
  1098     hence "sup a (-a) + a = a" by (simp)
  1099     hence "sup (a+a) 0 = a" by (simp add: add_sup_distrib_right) 
  1100     hence "sup (a+a) 0 <= a" by (simp)
  1101     hence "0 <= a" by (blast intro: order_trans inf_sup_ord)
  1102   }
  1103   note p = this
  1104   assume hyp:"sup a (-a) = 0"
  1105   hence hyp2:"sup (-a) (-(-a)) = 0" by (simp add: sup_commute)
  1106   from p[OF hyp] p[OF hyp2] show "a = 0" by simp
  1107 qed
  1108 
  1109 lemma inf_0_imp_0: "inf a (-a) = 0 \<Longrightarrow> a = 0"
  1110 apply (simp add: inf_eq_neg_sup)
  1111 apply (simp add: sup_commute)
  1112 apply (erule sup_0_imp_0)
  1113 done
  1114 
  1115 lemma inf_0_eq_0 [simp, noatp]: "inf a (- a) = 0 \<longleftrightarrow> a = 0"
  1116   by (rule, erule inf_0_imp_0) simp
  1117 
  1118 lemma sup_0_eq_0 [simp, noatp]: "sup a (- a) = 0 \<longleftrightarrow> a = 0"
  1119   by (rule, erule sup_0_imp_0) simp
  1120 
  1121 lemma zero_le_double_add_iff_zero_le_single_add [simp]:
  1122   "0 \<le> a + a \<longleftrightarrow> 0 \<le> a"
  1123 proof
  1124   assume "0 <= a + a"
  1125   hence a:"inf (a+a) 0 = 0" by (simp add: le_iff_inf inf_commute)
  1126   have "(inf a 0)+(inf a 0) = inf (inf (a+a) 0) a" (is "?l=_")
  1127     by (simp add: add_sup_inf_distribs inf_ACI)
  1128   hence "?l = 0 + inf a 0" by (simp add: a, simp add: inf_commute)
  1129   hence "inf a 0 = 0" by (simp only: add_right_cancel)
  1130   then show "0 <= a" by (simp add: le_iff_inf inf_commute)    
  1131 next  
  1132   assume a: "0 <= a"
  1133   show "0 <= a + a" by (simp add: add_mono[OF a a, simplified])
  1134 qed
  1135 
  1136 lemma double_zero: "a + a = 0 \<longleftrightarrow> a = 0"
  1137 proof
  1138   assume assm: "a + a = 0"
  1139   then have "a + a + - a = - a" by simp
  1140   then have "a + (a + - a) = - a" by (simp only: add_assoc)
  1141   then have a: "- a = a" by simp (*FIXME tune proof*)
  1142   show "a = 0" apply (rule antisym)
  1143   apply (unfold neg_le_iff_le [symmetric, of a])
  1144   unfolding a apply simp
  1145   unfolding zero_le_double_add_iff_zero_le_single_add [symmetric, of a]
  1146   unfolding assm unfolding le_less apply simp_all done
  1147 next
  1148   assume "a = 0" then show "a + a = 0" by simp
  1149 qed
  1150 
  1151 lemma zero_less_double_add_iff_zero_less_single_add:
  1152   "0 < a + a \<longleftrightarrow> 0 < a"
  1153 proof (cases "a = 0")
  1154   case True then show ?thesis by auto
  1155 next
  1156   case False then show ?thesis (*FIXME tune proof*)
  1157   unfolding less_le apply simp apply rule
  1158   apply clarify
  1159   apply rule
  1160   apply assumption
  1161   apply (rule notI)
  1162   unfolding double_zero [symmetric, of a] apply simp
  1163   done
  1164 qed
  1165 
  1166 lemma double_add_le_zero_iff_single_add_le_zero [simp]:
  1167   "a + a \<le> 0 \<longleftrightarrow> a \<le> 0" 
  1168 proof -
  1169   have "a + a \<le> 0 \<longleftrightarrow> 0 \<le> - (a + a)" by (subst le_minus_iff, simp)
  1170   moreover have "\<dots> \<longleftrightarrow> a \<le> 0" by (simp add: zero_le_double_add_iff_zero_le_single_add)
  1171   ultimately show ?thesis by blast
  1172 qed
  1173 
  1174 lemma double_add_less_zero_iff_single_less_zero [simp]:
  1175   "a + a < 0 \<longleftrightarrow> a < 0"
  1176 proof -
  1177   have "a + a < 0 \<longleftrightarrow> 0 < - (a + a)" by (subst less_minus_iff, simp)
  1178   moreover have "\<dots> \<longleftrightarrow> a < 0" by (simp add: zero_less_double_add_iff_zero_less_single_add)
  1179   ultimately show ?thesis by blast
  1180 qed
  1181 
  1182 declare neg_inf_eq_sup [simp] neg_sup_eq_inf [simp]
  1183 
  1184 lemma le_minus_self_iff: "a \<le> - a \<longleftrightarrow> a \<le> 0"
  1185 proof -
  1186   from add_le_cancel_left [of "uminus a" "plus a a" zero]
  1187   have "(a <= -a) = (a+a <= 0)" 
  1188     by (simp add: add_assoc[symmetric])
  1189   thus ?thesis by simp
  1190 qed
  1191 
  1192 lemma minus_le_self_iff: "- a \<le> a \<longleftrightarrow> 0 \<le> a"
  1193 proof -
  1194   from add_le_cancel_left [of "uminus a" zero "plus a a"]
  1195   have "(-a <= a) = (0 <= a+a)" 
  1196     by (simp add: add_assoc[symmetric])
  1197   thus ?thesis by simp
  1198 qed
  1199 
  1200 lemma zero_le_iff_zero_nprt: "0 \<le> a \<longleftrightarrow> nprt a = 0"
  1201   by (simp add: le_iff_inf nprt_def inf_commute)
  1202 
  1203 lemma le_zero_iff_zero_pprt: "a \<le> 0 \<longleftrightarrow> pprt a = 0"
  1204   by (simp add: le_iff_sup pprt_def sup_commute)
  1205 
  1206 lemma le_zero_iff_pprt_id: "0 \<le> a \<longleftrightarrow> pprt a = a"
  1207   by (simp add: le_iff_sup pprt_def sup_commute)
  1208 
  1209 lemma zero_le_iff_nprt_id: "a \<le> 0 \<longleftrightarrow> nprt a = a"
  1210   by (simp add: le_iff_inf nprt_def inf_commute)
  1211 
  1212 lemma pprt_mono [simp, noatp]: "a \<le> b \<Longrightarrow> pprt a \<le> pprt b"
  1213   by (simp add: le_iff_sup pprt_def sup_ACI sup_assoc [symmetric, of a])
  1214 
  1215 lemma nprt_mono [simp, noatp]: "a \<le> b \<Longrightarrow> nprt a \<le> nprt b"
  1216   by (simp add: le_iff_inf nprt_def inf_ACI inf_assoc [symmetric, of a])
  1217 
  1218 end
  1219 
  1220 lemmas add_sup_inf_distribs = add_inf_distrib_right add_inf_distrib_left add_sup_distrib_right add_sup_distrib_left
  1221 
  1222 
  1223 class lordered_ab_group_add_abs = lordered_ab_group_add + abs +
  1224   assumes abs_lattice: "\<bar>a\<bar> = sup a (- a)"
  1225 begin
  1226 
  1227 lemma abs_prts: "\<bar>a\<bar> = pprt a - nprt a"
  1228 proof -
  1229   have "0 \<le> \<bar>a\<bar>"
  1230   proof -
  1231     have a: "a \<le> \<bar>a\<bar>" and b: "- a \<le> \<bar>a\<bar>" by (auto simp add: abs_lattice)
  1232     show ?thesis by (rule add_mono [OF a b, simplified])
  1233   qed
  1234   then have "0 \<le> sup a (- a)" unfolding abs_lattice .
  1235   then have "sup (sup a (- a)) 0 = sup a (- a)" by (rule sup_absorb1)
  1236   then show ?thesis
  1237     by (simp add: add_sup_inf_distribs sup_ACI
  1238       pprt_def nprt_def diff_minus abs_lattice)
  1239 qed
  1240 
  1241 subclass pordered_ab_group_add_abs
  1242 proof -
  1243   have abs_ge_zero [simp]: "\<And>a. 0 \<le> \<bar>a\<bar>"
  1244   proof -
  1245     fix a b
  1246     have a: "a \<le> \<bar>a\<bar>" and b: "- a \<le> \<bar>a\<bar>" by (auto simp add: abs_lattice)
  1247     show "0 \<le> \<bar>a\<bar>" by (rule add_mono [OF a b, simplified])
  1248   qed
  1249   have abs_leI: "\<And>a b. a \<le> b \<Longrightarrow> - a \<le> b \<Longrightarrow> \<bar>a\<bar> \<le> b"
  1250     by (simp add: abs_lattice le_supI)
  1251   show ?thesis
  1252   proof unfold_locales
  1253     fix a
  1254     show "0 \<le> \<bar>a\<bar>" by simp
  1255   next
  1256     fix a
  1257     show "a \<le> \<bar>a\<bar>"
  1258       by (auto simp add: abs_lattice)
  1259   next
  1260     fix a
  1261     show "\<bar>-a\<bar> = \<bar>a\<bar>"
  1262       by (simp add: abs_lattice sup_commute)
  1263   next
  1264     fix a b
  1265     show "a \<le> b \<Longrightarrow> - a \<le> b \<Longrightarrow> \<bar>a\<bar> \<le> b" by (erule abs_leI)
  1266   next
  1267     fix a b
  1268     show "\<bar>a + b\<bar> \<le> \<bar>a\<bar> + \<bar>b\<bar>"
  1269     proof -
  1270       have g:"abs a + abs b = sup (a+b) (sup (-a-b) (sup (-a+b) (a + (-b))))" (is "_=sup ?m ?n")
  1271         by (simp add: abs_lattice add_sup_inf_distribs sup_ACI diff_minus)
  1272       have a:"a+b <= sup ?m ?n" by (simp)
  1273       have b:"-a-b <= ?n" by (simp) 
  1274       have c:"?n <= sup ?m ?n" by (simp)
  1275       from b c have d: "-a-b <= sup ?m ?n" by(rule order_trans)
  1276       have e:"-a-b = -(a+b)" by (simp add: diff_minus)
  1277       from a d e have "abs(a+b) <= sup ?m ?n" 
  1278         by (drule_tac abs_leI, auto)
  1279       with g[symmetric] show ?thesis by simp
  1280     qed
  1281   qed auto
  1282 qed
  1283 
  1284 end
  1285 
  1286 lemma sup_eq_if:
  1287   fixes a :: "'a\<Colon>{lordered_ab_group_add, linorder}"
  1288   shows "sup a (- a) = (if a < 0 then - a else a)"
  1289 proof -
  1290   note add_le_cancel_right [of a a "- a", symmetric, simplified]
  1291   moreover note add_le_cancel_right [of "-a" a a, symmetric, simplified]
  1292   then show ?thesis by (auto simp: sup_max max_def)
  1293 qed
  1294 
  1295 lemma abs_if_lattice:
  1296   fixes a :: "'a\<Colon>{lordered_ab_group_add_abs, linorder}"
  1297   shows "\<bar>a\<bar> = (if a < 0 then - a else a)"
  1298   by auto
  1299 
  1300 
  1301 text {* Needed for abelian cancellation simprocs: *}
  1302 
  1303 lemma add_cancel_21: "((x::'a::ab_group_add) + (y + z) = y + u) = (x + z = u)"
  1304 apply (subst add_left_commute)
  1305 apply (subst add_left_cancel)
  1306 apply simp
  1307 done
  1308 
  1309 lemma add_cancel_end: "(x + (y + z) = y) = (x = - (z::'a::ab_group_add))"
  1310 apply (subst add_cancel_21[of _ _ _ 0, simplified])
  1311 apply (simp add: add_right_cancel[symmetric, of "x" "-z" "z", simplified])
  1312 done
  1313 
  1314 lemma less_eqI: "(x::'a::pordered_ab_group_add) - y = x' - y' \<Longrightarrow> (x < y) = (x' < y')"
  1315 by (simp add: less_iff_diff_less_0[of x y] less_iff_diff_less_0[of x' y'])
  1316 
  1317 lemma le_eqI: "(x::'a::pordered_ab_group_add) - y = x' - y' \<Longrightarrow> (y <= x) = (y' <= x')"
  1318 apply (simp add: le_iff_diff_le_0[of y x] le_iff_diff_le_0[of  y' x'])
  1319 apply (simp add: neg_le_iff_le[symmetric, of "y-x" 0] neg_le_iff_le[symmetric, of "y'-x'" 0])
  1320 done
  1321 
  1322 lemma eq_eqI: "(x::'a::ab_group_add) - y = x' - y' \<Longrightarrow> (x = y) = (x' = y')"
  1323 by (simp add: eq_iff_diff_eq_0[of x y] eq_iff_diff_eq_0[of x' y'])
  1324 
  1325 lemma diff_def: "(x::'a::ab_group_add) - y == x + (-y)"
  1326 by (simp add: diff_minus)
  1327 
  1328 lemma add_minus_cancel: "(a::'a::ab_group_add) + (-a + b) = b"
  1329 by (simp add: add_assoc[symmetric])
  1330 
  1331 lemma le_add_right_mono: 
  1332   assumes 
  1333   "a <= b + (c::'a::pordered_ab_group_add)"
  1334   "c <= d"    
  1335   shows "a <= b + d"
  1336   apply (rule_tac order_trans[where y = "b+c"])
  1337   apply (simp_all add: prems)
  1338   done
  1339 
  1340 lemma estimate_by_abs:
  1341   "a + b <= (c::'a::lordered_ab_group_add_abs) \<Longrightarrow> a <= c + abs b" 
  1342 proof -
  1343   assume "a+b <= c"
  1344   hence 2: "a <= c+(-b)" by (simp add: group_simps)
  1345   have 3: "(-b) <= abs b" by (rule abs_ge_minus_self)
  1346   show ?thesis by (rule le_add_right_mono[OF 2 3])
  1347 qed
  1348 
  1349 subsection {* Tools setup *}
  1350 
  1351 lemma add_mono_thms_ordered_semiring [noatp]:
  1352   fixes i j k :: "'a\<Colon>pordered_ab_semigroup_add"
  1353   shows "i \<le> j \<and> k \<le> l \<Longrightarrow> i + k \<le> j + l"
  1354     and "i = j \<and> k \<le> l \<Longrightarrow> i + k \<le> j + l"
  1355     and "i \<le> j \<and> k = l \<Longrightarrow> i + k \<le> j + l"
  1356     and "i = j \<and> k = l \<Longrightarrow> i + k = j + l"
  1357 by (rule add_mono, clarify+)+
  1358 
  1359 lemma add_mono_thms_ordered_field [noatp]:
  1360   fixes i j k :: "'a\<Colon>pordered_cancel_ab_semigroup_add"
  1361   shows "i < j \<and> k = l \<Longrightarrow> i + k < j + l"
  1362     and "i = j \<and> k < l \<Longrightarrow> i + k < j + l"
  1363     and "i < j \<and> k \<le> l \<Longrightarrow> i + k < j + l"
  1364     and "i \<le> j \<and> k < l \<Longrightarrow> i + k < j + l"
  1365     and "i < j \<and> k < l \<Longrightarrow> i + k < j + l"
  1366 by (auto intro: add_strict_right_mono add_strict_left_mono
  1367   add_less_le_mono add_le_less_mono add_strict_mono)
  1368 
  1369 text{*Simplification of @{term "x-y < 0"}, etc.*}
  1370 lemmas diff_less_0_iff_less [simp] = less_iff_diff_less_0 [symmetric]
  1371 lemmas diff_eq_0_iff_eq [simp, noatp] = eq_iff_diff_eq_0 [symmetric]
  1372 lemmas diff_le_0_iff_le [simp] = le_iff_diff_le_0 [symmetric]
  1373 
  1374 ML {*
  1375 structure ab_group_add_cancel = Abel_Cancel(
  1376 struct
  1377 
  1378 (* term order for abelian groups *)
  1379 
  1380 fun agrp_ord (Const (a, _)) = find_index (fn a' => a = a')
  1381       [@{const_name HOL.zero}, @{const_name HOL.plus},
  1382         @{const_name HOL.uminus}, @{const_name HOL.minus}]
  1383   | agrp_ord _ = ~1;
  1384 
  1385 fun termless_agrp (a, b) = (Term.term_lpo agrp_ord (a, b) = LESS);
  1386 
  1387 local
  1388   val ac1 = mk_meta_eq @{thm add_assoc};
  1389   val ac2 = mk_meta_eq @{thm add_commute};
  1390   val ac3 = mk_meta_eq @{thm add_left_commute};
  1391   fun solve_add_ac thy _ (_ $ (Const (@{const_name HOL.plus},_) $ _ $ _) $ _) =
  1392         SOME ac1
  1393     | solve_add_ac thy _ (_ $ x $ (Const (@{const_name HOL.plus},_) $ y $ z)) =
  1394         if termless_agrp (y, x) then SOME ac3 else NONE
  1395     | solve_add_ac thy _ (_ $ x $ y) =
  1396         if termless_agrp (y, x) then SOME ac2 else NONE
  1397     | solve_add_ac thy _ _ = NONE
  1398 in
  1399   val add_ac_proc = Simplifier.simproc @{theory}
  1400     "add_ac_proc" ["x + y::'a::ab_semigroup_add"] solve_add_ac;
  1401 end;
  1402 
  1403 val cancel_ss = HOL_basic_ss settermless termless_agrp
  1404   addsimprocs [add_ac_proc] addsimps
  1405   [@{thm add_0_left}, @{thm add_0_right}, @{thm diff_def},
  1406    @{thm minus_add_distrib}, @{thm minus_minus}, @{thm minus_zero},
  1407    @{thm right_minus}, @{thm left_minus}, @{thm add_minus_cancel},
  1408    @{thm minus_add_cancel}];
  1409   
  1410 val eq_reflection = @{thm eq_reflection};
  1411   
  1412 val thy_ref = Theory.check_thy @{theory};
  1413 
  1414 val T = @{typ "'a\<Colon>ab_group_add"};
  1415 
  1416 val eqI_rules = [@{thm less_eqI}, @{thm le_eqI}, @{thm eq_eqI}];
  1417 
  1418 val dest_eqI = 
  1419   fst o HOLogic.dest_bin "op =" HOLogic.boolT o HOLogic.dest_Trueprop o concl_of;
  1420 
  1421 end);
  1422 *}
  1423 
  1424 ML_setup {*
  1425   Addsimprocs [ab_group_add_cancel.sum_conv, ab_group_add_cancel.rel_conv];
  1426 *}
  1427 
  1428 end