src/Pure/library.ML
author wenzelm
Fri Jun 17 18:33:24 2005 +0200 (2005-06-17)
changeset 16439 0509ef1b1ec3
parent 16188 841342a7c41c
child 16492 fbfd15412f05
permissions -rw-r--r--
added serial numbers;
     1 (*  Title:      Pure/library.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Author:     Markus Wenzel, TU Muenchen
     5 
     6 Basic library: functions, options, pairs, booleans, lists, integers,
     7 rational numbers, strings, lists as sets, association lists, generic
     8 tables, balanced trees, orders, current directory, misc.
     9 *)
    10 
    11 infix |> |>> |>>> ~~ \ \\ ins ins_string ins_int orf andf prefix upto downto
    12   mem mem_int mem_string union union_int union_string inter inter_int
    13   inter_string subset subset_int subset_string;
    14 
    15 infix 3 oo ooo oooo;
    16 
    17 signature BASIC_LIBRARY =
    18 sig
    19   (*functions*)
    20   val curry: ('a * 'b -> 'c) -> 'a -> 'b -> 'c
    21   val uncurry: ('a -> 'b -> 'c) -> 'a * 'b -> 'c
    22   val I: 'a -> 'a
    23   val K: 'a -> 'b -> 'a
    24   val |> : 'a * ('a -> 'b) -> 'b
    25   val |>> : ('a * 'b) * ('a -> 'c) -> 'c * 'b
    26   val |>>> : ('a * 'b) * ('a -> 'c * 'd) -> 'c * ('b * 'd)
    27   val apl: 'a * ('a * 'b -> 'c) -> 'b -> 'c
    28   val apr: ('a * 'b -> 'c) * 'b -> 'a -> 'c
    29   val funpow: int -> ('a -> 'a) -> 'a -> 'a
    30   val oo: ('a -> 'b) * ('c -> 'd -> 'a) -> 'c -> 'd -> 'b
    31   val ooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'a) -> 'c -> 'd -> 'e -> 'b
    32   val oooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'f -> 'a) -> 'c -> 'd -> 'e -> 'f -> 'b
    33 
    34   (*old options -- invalidated*)
    35   datatype invalid = None of invalid
    36   exception OPTION of invalid
    37 
    38   (*options*)
    39   val the: 'a option -> 'a
    40   val if_none: 'a option -> 'a -> 'a
    41   val is_some: 'a option -> bool
    42   val is_none: 'a option -> bool
    43 
    44   exception ERROR
    45   val try: ('a -> 'b) -> 'a -> 'b option
    46   val can: ('a -> 'b) -> 'a -> bool
    47   datatype 'a result = Result of 'a | Exn of exn
    48   val capture: ('a -> 'b) -> 'a -> 'b result
    49   val release: 'a result -> 'a
    50   val get_result: 'a result -> 'a option
    51   val get_exn: 'a result -> exn option
    52 
    53   (*pairs*)
    54   val pair: 'a -> 'b -> 'a * 'b
    55   val rpair: 'a -> 'b -> 'b * 'a
    56   val fst: 'a * 'b -> 'a
    57   val snd: 'a * 'b -> 'b
    58   val eq_fst: (''a * 'b) * (''a * 'c) -> bool
    59   val eq_snd: ('a * ''b) * ('c * ''b) -> bool
    60   val swap: 'a * 'b -> 'b * 'a
    61   val apfst: ('a -> 'b) -> 'a * 'c -> 'b * 'c
    62   val apsnd: ('a -> 'b) -> 'c * 'a -> 'c * 'b
    63   val pairself: ('a -> 'b) -> 'a * 'a -> 'b * 'b
    64 
    65   (*booleans*)
    66   val equal: ''a -> ''a -> bool
    67   val not_equal: ''a -> ''a -> bool
    68   val orf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    69   val andf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    70   val exists: ('a -> bool) -> 'a list -> bool
    71   val forall: ('a -> bool) -> 'a list -> bool
    72   val set: bool ref -> bool
    73   val reset: bool ref -> bool
    74   val toggle: bool ref -> bool
    75   val change: 'a ref -> ('a -> 'a) -> unit
    76   val setmp: 'a ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    77   val conditional: bool -> (unit -> unit) -> unit
    78 
    79   (*lists*)
    80   exception UnequalLengths
    81   val cons: 'a -> 'a list -> 'a list
    82   val single: 'a -> 'a list
    83   val append: 'a list -> 'a list -> 'a list
    84   val apply: ('a -> 'a) list -> 'a -> 'a
    85   val fold: ('a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    86   val fold_rev: ('a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    87   val foldl_map: ('a * 'b -> 'a * 'c) -> 'a * 'b list -> 'a * 'c list
    88   val foldr1: ('a * 'a -> 'a) -> 'a list -> 'a
    89   val foldln: ('a * int -> 'b -> 'b) -> 'a list -> 'b -> 'b
    90   val unflat: 'a list list -> 'b list -> 'b list list
    91   val splitAt: int * 'a list -> 'a list * 'a list
    92   val dropwhile: ('a -> bool) -> 'a list -> 'a list
    93   val map_nth_elem: int -> ('a -> 'a) -> 'a list -> 'a list
    94   val split_last: 'a list -> 'a list * 'a
    95   val nth_update: 'a -> int * 'a list -> 'a list
    96   val find_index: ('a -> bool) -> 'a list -> int
    97   val find_index_eq: ''a -> ''a list -> int
    98   val find_first: ('a -> bool) -> 'a list -> 'a option
    99   val get_first: ('a -> 'b option) -> 'a list -> 'b option
   100   val separate: 'a -> 'a list -> 'a list
   101   val replicate: int -> 'a -> 'a list
   102   val multiply: 'a list * 'a list list -> 'a list list
   103   val product: 'a list -> 'b list -> ('a * 'b) list
   104   val filter: ('a -> bool) -> 'a list -> 'a list
   105   val filter_out: ('a -> bool) -> 'a list -> 'a list
   106   val map2: ('a * 'b -> 'c) -> 'a list * 'b list -> 'c list
   107   val exists2: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   108   val forall2: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   109   val seq2: ('a * 'b -> unit) -> 'a list * 'b list -> unit
   110   val ~~ : 'a list * 'b list -> ('a * 'b) list
   111   val split_list: ('a * 'b) list -> 'a list * 'b list
   112   val equal_lists: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   113   val prefix: ''a list * ''a list -> bool
   114   val take_prefix: ('a -> bool) -> 'a list -> 'a list * 'a list
   115   val take_suffix: ('a -> bool) -> 'a list -> 'a list * 'a list
   116   val prefixes1: 'a list -> 'a list list
   117   val suffixes1: 'a list -> 'a list list
   118 
   119   (*integers*)
   120   val gcd: IntInf.int * IntInf.int -> IntInf.int
   121   val lcm: IntInf.int * IntInf.int -> IntInf.int
   122   val inc: int ref -> int
   123   val dec: int ref -> int
   124   val upto: int * int -> int list
   125   val downto: int * int -> int list
   126   val downto0: int list * int -> bool
   127   val radixpand: int * int -> int list
   128   val radixstring: int * string * int -> string
   129   val string_of_int: int -> string
   130   val string_of_indexname: string * int -> string
   131   val read_radixint: int * string list -> int * string list
   132   val read_int: string list -> int * string list
   133   val oct_char: string -> string
   134 
   135   (*rational numbers*)
   136   type rat
   137   exception RAT of string
   138   val rep_rat: rat -> IntInf.int * IntInf.int
   139   val ratadd: rat * rat -> rat
   140   val ratmul: rat * rat -> rat
   141   val ratinv: rat -> rat
   142   val int_ratdiv: IntInf.int * IntInf.int -> rat
   143   val ratneg: rat -> rat
   144   val rat_of_int: int -> rat
   145   val rat_of_intinf: IntInf.int -> rat
   146 
   147   (*strings*)
   148   val nth_elem_string: int * string -> string
   149   val fold_string: (string -> 'a -> 'a) -> string -> 'a -> 'a
   150   val exists_string: (string -> bool) -> string -> bool
   151   val forall_string: (string -> bool) -> string -> bool
   152   val enclose: string -> string -> string -> string
   153   val unenclose: string -> string
   154   val quote: string -> string
   155   val space_implode: string -> string list -> string
   156   val commas: string list -> string
   157   val commas_quote: string list -> string
   158   val cat_lines: string list -> string
   159   val space_explode: string -> string -> string list
   160   val split_lines: string -> string list
   161   val prefix_lines: string -> string -> string
   162   val untabify: string list -> string list
   163   val suffix: string -> string -> string
   164   val unsuffix: string -> string -> string
   165   val unprefix: string -> string -> string
   166   val replicate_string: int -> string -> string
   167   val translate_string: (string -> string) -> string -> string
   168 
   169   (*lists as sets*)
   170   val mem: ''a * ''a list -> bool
   171   val mem_int: int * int list -> bool
   172   val mem_string: string * string list -> bool
   173   val gen_mem: ('a * 'b -> bool) -> 'a * 'b list -> bool
   174   val ins: ''a * ''a list -> ''a list
   175   val ins_int: int * int list -> int list
   176   val ins_string: string * string list -> string list
   177   val gen_ins: ('a * 'a -> bool) -> 'a * 'a list -> 'a list
   178   val insert: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   179   val remove: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   180   val union: ''a list * ''a list -> ''a list
   181   val union_int: int list * int list -> int list
   182   val union_string: string list * string list -> string list
   183   val gen_union: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   184   val gen_inter: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   185   val inter: ''a list * ''a list -> ''a list
   186   val inter_int: int list * int list -> int list
   187   val inter_string: string list * string list -> string list
   188   val subset: ''a list * ''a list -> bool
   189   val subset_int: int list * int list -> bool
   190   val subset_string: string list * string list -> bool
   191   val eq_set: ''a list * ''a list -> bool
   192   val eq_set_string: string list * string list -> bool
   193   val gen_subset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   194   val \ : ''a list * ''a -> ''a list
   195   val \\ : ''a list * ''a list -> ''a list
   196   val gen_rem: ('a * 'b -> bool) -> 'a list * 'b -> 'a list
   197   val gen_rems: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   198   val gen_distinct: ('a * 'a -> bool) -> 'a list -> 'a list
   199   val distinct: ''a list -> ''a list
   200   val findrep: ''a list -> ''a list
   201   val gen_duplicates: ('a * 'a -> bool) -> 'a list -> 'a list
   202   val duplicates: ''a list -> ''a list
   203 
   204   (*association lists*)
   205   val assoc: (''a * 'b) list * ''a -> 'b option
   206   val assoc_int: (int * 'a) list * int -> 'a option
   207   val assoc_string: (string * 'a) list * string -> 'a option
   208   val assoc_string_int: ((string * int) * 'a) list * (string * int) -> 'a option
   209   val assocs: (''a * 'b list) list -> ''a -> 'b list
   210   val assoc2: (''a * (''b * 'c) list) list * (''a * ''b) -> 'c option
   211   val gen_assoc: ('a * 'b -> bool) -> ('b * 'c) list * 'a -> 'c option
   212   val overwrite: (''a * 'b) list * (''a * 'b) -> (''a * 'b) list
   213   val gen_overwrite: ('a * 'a -> bool) -> ('a * 'b) list * ('a * 'b) -> ('a * 'b) list
   214 
   215   (*lists as tables*)
   216   val gen_merge_lists: ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   217   val gen_merge_lists': ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   218   val merge_lists: ''a list -> ''a list -> ''a list
   219   val merge_lists': ''a list -> ''a list -> ''a list
   220   val merge_alists: (''a * 'b) list -> (''a * 'b) list -> (''a * 'b) list
   221   val merge_alists': (''a * 'b) list -> (''a * 'b) list -> (''a * 'b) list
   222 
   223   (*balanced trees*)
   224   exception Balance
   225   val fold_bal: ('a * 'a -> 'a) -> 'a list -> 'a
   226   val access_bal: ('a -> 'a) * ('a -> 'a) * 'a -> int -> int -> 'a
   227   val accesses_bal: ('a -> 'a) * ('a -> 'a) * 'a -> int -> 'a list
   228 
   229   (*orders*)
   230   val rev_order: order -> order
   231   val make_ord: ('a * 'a -> bool) -> 'a * 'a -> order
   232   val int_ord: int * int -> order
   233   val string_ord: string * string -> order
   234   val prod_ord: ('a * 'b -> order) -> ('c * 'd -> order) -> ('a * 'c) * ('b * 'd) -> order
   235   val dict_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   236   val list_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   237   val sort: ('a * 'a -> order) -> 'a list -> 'a list
   238   val sort_strings: string list -> string list
   239   val sort_wrt: ('a -> string) -> 'a list -> 'a list
   240   val unique_strings: string list -> string list
   241 
   242   (*random numbers*)
   243   exception RANDOM
   244   val random: unit -> real
   245   val random_range: int -> int -> int
   246   val one_of: 'a list -> 'a
   247   val frequency: (int * 'a) list -> 'a
   248 
   249   (*current directory*)
   250   val cd: string -> unit
   251   val pwd: unit -> string
   252 
   253   (*misc*)
   254   val make_keylist: ('a -> 'b) -> 'a list -> ('a * 'b) list
   255   val keyfilter: ('a * ''b) list -> ''b -> 'a list
   256   val partition_eq: ('a * 'a -> bool) -> 'a list -> 'a list list
   257   val partition_list: (int -> 'a -> bool) -> int -> int -> 'a list -> 'a list list
   258   val gensym: string -> string
   259   val scanwords: (string -> bool) -> string list -> string list
   260   type stamp
   261   val stamp: unit -> stamp
   262   type serial
   263   val serial: unit -> serial
   264 end;
   265 
   266 signature LIBRARY =
   267 sig
   268   include BASIC_LIBRARY
   269   val foldl: ('a * 'b -> 'a) -> 'a * 'b list -> 'a
   270   val foldr: ('a * 'b -> 'b) -> 'a list * 'b -> 'b
   271   val take: int * 'a list -> 'a list
   272   val drop: int * 'a list -> 'a list
   273   val nth_elem: int * 'a list -> 'a
   274   val last_elem: 'a list -> 'a
   275   val flat: 'a list list -> 'a list
   276   val seq: ('a -> unit) -> 'a list -> unit
   277   val partition: ('a -> bool) -> 'a list -> 'a list * 'a list
   278   val mapfilter: ('a -> 'b option) -> 'a list -> 'b list
   279 end;
   280 
   281 structure Library: LIBRARY =
   282 struct
   283 
   284 
   285 (** functions **)
   286 
   287 (*handy combinators*)
   288 fun curry f x y = f (x, y);
   289 fun uncurry f (x, y) = f x y;
   290 fun I x = x;
   291 fun K x y = x;
   292 
   293 (*reverse apply*)
   294 fun (x |> f) = f x;
   295 fun ((x, y) |>> f) = (f x, y);
   296 fun ((x, y) |>>> f) = let val (x', z) = f x in (x', (y, z)) end;
   297 
   298 (*application of (infix) operator to its left or right argument*)
   299 fun apl (x, f) y = f (x, y);
   300 fun apr (f, y) x = f (x, y);
   301 
   302 (*function exponentiation: f(...(f x)...) with n applications of f*)
   303 fun funpow n f x =
   304   let fun rep (0, x) = x
   305         | rep (n, x) = rep (n - 1, f x)
   306   in rep (n, x) end;
   307 
   308 (*concatenation: 2 and 3 args*)
   309 fun (f oo g) x y = f (g x y);
   310 fun (f ooo g) x y z = f (g x y z);
   311 fun (f oooo g) x y z w = f (g x y z w);
   312 
   313 
   314 
   315 (** options **)
   316 
   317 (*invalidate former constructors to prevent accidental use as match-all patterns!*)
   318 datatype invalid = None of invalid;
   319 exception OPTION of invalid;
   320 
   321 val the = Option.valOf;
   322 
   323 (*strict!*)
   324 fun if_none NONE y = y
   325   | if_none (SOME x) _ = x;
   326 
   327 fun is_some (SOME _) = true
   328   | is_some NONE = false;
   329 
   330 fun is_none (SOME _) = false
   331   | is_none NONE = true;
   332 
   333 
   334 (* exception handling *)
   335 
   336 exception ERROR;
   337 
   338 fun try f x = SOME (f x)
   339   handle Interrupt => raise Interrupt | ERROR => raise ERROR | _ => NONE;
   340 
   341 fun can f x = is_some (try f x);
   342 
   343 
   344 datatype 'a result =
   345   Result of 'a |
   346   Exn of exn;
   347 
   348 fun capture f x = Result (f x) handle e => Exn e;
   349 
   350 fun release (Result y) = y
   351   | release (Exn e) = raise e;
   352 
   353 fun get_result (Result x) = SOME x
   354   | get_result _ = NONE;
   355 
   356 fun get_exn (Exn exn) = SOME exn
   357   | get_exn _ = NONE;
   358 
   359 
   360 
   361 (** pairs **)
   362 
   363 fun pair x y = (x, y);
   364 fun rpair x y = (y, x);
   365 
   366 fun fst (x, y) = x;
   367 fun snd (x, y) = y;
   368 
   369 fun eq_fst ((x1, _), (x2, _)) = x1 = x2;
   370 fun eq_snd ((_, y1), (_, y2)) = y1 = y2;
   371 
   372 fun swap (x, y) = (y, x);
   373 
   374 (*apply function to components*)
   375 fun apfst f (x, y) = (f x, y);
   376 fun apsnd f (x, y) = (x, f y);
   377 fun pairself f (x, y) = (f x, f y);
   378 
   379 
   380 
   381 (** booleans **)
   382 
   383 (* equality *)
   384 
   385 fun equal x y = x = y;
   386 fun not_equal x y = x <> y;
   387 
   388 
   389 (* operators for combining predicates *)
   390 
   391 fun (p orf q) = fn x => p x orelse q x;
   392 fun (p andf q) = fn x => p x andalso q x;
   393 
   394 
   395 (* predicates on lists *)
   396 
   397 (*exists pred [x1, ..., xn] ===> pred x1 orelse ... orelse pred xn*)
   398 fun exists (pred: 'a -> bool) : 'a list -> bool =
   399   let fun boolf [] = false
   400         | boolf (x :: xs) = pred x orelse boolf xs
   401   in boolf end;
   402 
   403 (*forall pred [x1, ..., xn] ===> pred x1 andalso ... andalso pred xn*)
   404 fun forall (pred: 'a -> bool) : 'a list -> bool =
   405   let fun boolf [] = true
   406         | boolf (x :: xs) = pred x andalso boolf xs
   407   in boolf end;
   408 
   409 
   410 (* flags *)
   411 
   412 fun set flag = (flag := true; true);
   413 fun reset flag = (flag := false; false);
   414 fun toggle flag = (flag := not (! flag); ! flag);
   415 
   416 fun change r f = r := f (! r);
   417 
   418 (*temporarily set flag, handling exceptions*)
   419 fun setmp flag value f x =
   420   let
   421     val orig_value = ! flag;
   422     fun return y = (flag := orig_value; y);
   423   in
   424     flag := value;
   425     return (f x handle exn => (return (); raise exn))
   426   end;
   427 
   428 
   429 (* conditional execution *)
   430 
   431 fun conditional b f = if b then f () else ();
   432 
   433 
   434 
   435 (** lists **)
   436 
   437 exception UnequalLengths;
   438 
   439 fun cons x xs = x :: xs;
   440 fun single x = [x];
   441 
   442 fun append xs ys = xs @ ys;
   443 
   444 fun apply [] x = x
   445   | apply (f :: fs) x = apply fs (f x);
   446 
   447 
   448 (* fold *)
   449 
   450 fun fold _ [] y = y
   451   | fold f (x :: xs) y = fold f xs (f x y);
   452 
   453 fun fold_rev _ [] y = y
   454   | fold_rev f (x :: xs) y = f x (fold_rev f xs y);
   455 
   456 fun foldl_map _ (x, []) = (x, [])
   457   | foldl_map f (x, y :: ys) =
   458       let
   459         val (x', y') = f (x, y);
   460         val (x'', ys') = foldl_map f (x', ys);
   461       in (x'', y' :: ys') end;
   462 
   463 (*the following versions of fold are designed to fit nicely with infixes*)
   464 
   465 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   466     for operators that associate to the left (TAIL RECURSIVE)*)
   467 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   468   let fun itl (e, [])  = e
   469         | itl (e, a::l) = itl (f(e, a), l)
   470   in  itl end;
   471 
   472 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   473     for operators that associate to the right (not tail recursive)*)
   474 fun foldr f (l, e) =
   475   let fun itr [] = e
   476         | itr (a::l) = f(a, itr l)
   477   in  itr l  end;
   478 
   479 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   480     for n > 0, operators that associate to the right (not tail recursive)*)
   481 fun foldr1 f l =
   482   let fun itr [x] = x
   483         | itr (x::l) = f(x, itr l)
   484   in  itr l  end;
   485 
   486 fun foldln f xs e = fst (foldl (fn ((e,i), x) => (f (x,i) e, i+1)) ((e,1),xs));
   487 
   488 
   489 (* basic list functions *)
   490 
   491 (*take the first n elements from a list*)
   492 fun take (n, []) = []
   493   | take (n, x :: xs) =
   494       if n > 0 then x :: take (n - 1, xs) else [];
   495 
   496 (*drop the first n elements from a list*)
   497 fun drop (n, []) = []
   498   | drop (n, x :: xs) =
   499       if n > 0 then drop (n - 1, xs) else x :: xs;
   500 
   501 fun splitAt(n,[]) = ([],[])
   502   | splitAt(n,xs as x::ys) =
   503       if n>0 then let val (ps,qs) = splitAt(n-1,ys) in (x::ps,qs) end
   504       else ([],xs)
   505 
   506 fun dropwhile P [] = []
   507   | dropwhile P (ys as x::xs) = if P x then dropwhile P xs else ys;
   508 
   509 (*return nth element of a list, where 0 designates the first element;
   510   raise EXCEPTION if list too short*)
   511 fun nth_elem (i,xs) = List.nth(xs,i);
   512 
   513 fun map_nth_elem 0 f (x :: xs) = f x :: xs
   514   | map_nth_elem n f (x :: xs) = x :: map_nth_elem (n - 1) f xs
   515   | map_nth_elem _ _ [] = raise Subscript;
   516 
   517 (*last element of a list*)
   518 val last_elem = List.last;
   519 
   520 (*rear decomposition*)
   521 fun split_last [] = raise Empty
   522   | split_last [x] = ([], x)
   523   | split_last (x :: xs) = apfst (cons x) (split_last xs);
   524 
   525 (*update nth element*)
   526 fun nth_update x n_xs =
   527     (case splitAt n_xs of
   528       (_,[]) => raise Subscript
   529     | (prfx, _ :: sffx') => prfx @ (x :: sffx'))
   530 
   531 (*find the position of an element in a list*)
   532 fun find_index pred =
   533   let fun find _ [] = ~1
   534         | find n (x :: xs) = if pred x then n else find (n + 1) xs;
   535   in find 0 end;
   536 
   537 fun find_index_eq x = find_index (equal x);
   538 
   539 (*find first element satisfying predicate*)
   540 fun find_first _ [] = NONE
   541   | find_first pred (x :: xs) =
   542       if pred x then SOME x else find_first pred xs;
   543 
   544 (*get first element by lookup function*)
   545 fun get_first _ [] = NONE
   546   | get_first f (x :: xs) =
   547       (case f x of
   548         NONE => get_first f xs
   549       | some => some);
   550 
   551 (*flatten a list of lists to a list*)
   552 val flat = List.concat;
   553 
   554 fun unflat (xs :: xss) ys =
   555       let val (ps,qs) = splitAt(length xs,ys)
   556       in ps :: unflat xss qs end
   557   | unflat [] [] = []
   558   | unflat _ _ = raise UnequalLengths;
   559 
   560 (*like Lisp's MAPC -- seq proc [x1, ..., xn] evaluates
   561   (proc x1; ...; proc xn) for side effects*)
   562 val seq = List.app;
   563 
   564 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   565 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   566   | separate _ xs = xs;
   567 
   568 (*make the list [x, x, ..., x] of length n*)
   569 fun replicate n (x: 'a) : 'a list =
   570   let fun rep (0, xs) = xs
   571         | rep (n, xs) = rep (n - 1, x :: xs)
   572   in
   573     if n < 0 then raise Subscript
   574     else rep (n, [])
   575   end;
   576 
   577 fun translate_string f = String.translate (f o String.str);
   578 
   579 (*multiply [a, b, c, ...] * [xs, ys, zs, ...]*)
   580 fun multiply ([], _) = []
   581   | multiply (x :: xs, yss) = map (cons x) yss @ multiply (xs, yss);
   582 
   583 (*direct product*)
   584 fun product _ [] = []
   585   | product [] _ = []
   586   | product (x :: xs) ys = map (pair x) ys @ product xs ys;
   587 
   588 
   589 (* filter *)
   590 
   591 (*copy the list preserving elements that satisfy the predicate*)
   592 val filter = List.filter;
   593 fun filter_out f = filter (not o f);
   594 val mapfilter = List.mapPartial;
   595 
   596 
   597 (* lists of pairs *)
   598 
   599 exception UnequalLengths;
   600 
   601 fun map2 _ ([], []) = []
   602   | map2 f (x :: xs, y :: ys) = (f (x, y) :: map2 f (xs, ys))
   603   | map2 _ _ = raise UnequalLengths;
   604 
   605 fun exists2 _ ([], []) = false
   606   | exists2 pred (x :: xs, y :: ys) = pred (x, y) orelse exists2 pred (xs, ys)
   607   | exists2 _ _ = raise UnequalLengths;
   608 
   609 fun forall2 _ ([], []) = true
   610   | forall2 pred (x :: xs, y :: ys) = pred (x, y) andalso forall2 pred (xs, ys)
   611   | forall2 _ _ = raise UnequalLengths;
   612 
   613 fun seq2 _ ([], []) = ()
   614   | seq2 f (x :: xs, y :: ys) = (f (x, y); seq2 f (xs, ys))
   615   | seq2 _ _ = raise UnequalLengths;
   616 
   617 (*combine two lists forming a list of pairs:
   618   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   619 fun [] ~~ [] = []
   620   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   621   | _ ~~ _ = raise UnequalLengths;
   622 
   623 (*inverse of ~~; the old 'split':
   624   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   625 val split_list = ListPair.unzip;
   626 
   627 fun equal_lists eq (xs, ys) = length xs = length ys andalso forall2 eq (xs, ys);
   628 
   629 
   630 (* prefixes, suffixes *)
   631 
   632 fun [] prefix _ = true
   633   | (x :: xs) prefix (y :: ys) = x = y andalso (xs prefix ys)
   634   | _ prefix _ = false;
   635 
   636 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   637    where xi is the first element that does not satisfy the predicate*)
   638 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   639   let fun take (rxs, []) = (rev rxs, [])
   640         | take (rxs, x :: xs) =
   641             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   642   in  take([], xs)  end;
   643 
   644 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   645    where xi is the last element that does not satisfy the predicate*)
   646 fun take_suffix _ [] = ([], [])
   647   | take_suffix pred (x :: xs) =
   648       (case take_suffix pred xs of
   649         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   650       | (prfx, sffx) => (x :: prfx, sffx));
   651 
   652 fun prefixes1 [] = []
   653   | prefixes1 (x :: xs) = map (cons x) ([] :: prefixes1 xs);
   654 
   655 fun suffixes1 xs = map rev (prefixes1 (rev xs));
   656 
   657 
   658 
   659 (** integers **)
   660 
   661 fun gcd (x, y) =
   662   let fun gxd x y : IntInf.int =
   663     if y = 0 then x else gxd y (x mod y)
   664   in if x < y then gxd y x else gxd x y end;
   665 
   666 fun lcm (x, y) = (x * y) div gcd (x, y);
   667 
   668 fun inc i = (i := ! i + 1; ! i);
   669 fun dec i = (i := ! i - 1; ! i);
   670 
   671 
   672 (* lists of integers *)
   673 
   674 (*make the list [from, from + 1, ..., to]*)
   675 fun (from upto to) =
   676   if from > to then [] else from :: ((from + 1) upto to);
   677 
   678 (*make the list [from, from - 1, ..., to]*)
   679 fun (from downto to) =
   680   if from < to then [] else from :: ((from - 1) downto to);
   681 
   682 (*predicate: downto0 (is, n) <=> is = [n, n - 1, ..., 0]*)
   683 fun downto0 (i :: is, n) = i = n andalso downto0 (is, n - 1)
   684   | downto0 ([], n) = n = ~1;
   685 
   686 
   687 (* convert integers to strings *)
   688 
   689 (*expand the number in the given base;
   690   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   691 fun radixpand (base, num) : int list =
   692   let
   693     fun radix (n, tail) =
   694       if n < base then n :: tail
   695       else radix (n div base, (n mod base) :: tail)
   696   in radix (num, []) end;
   697 
   698 (*expands a number into a string of characters starting from "zerochar";
   699   example: radixstring (2, "0", 8) gives "1000"*)
   700 fun radixstring (base, zerochar, num) =
   701   let val offset = ord zerochar;
   702       fun chrof n = chr (offset + n)
   703   in implode (map chrof (radixpand (base, num))) end;
   704 
   705 
   706 val string_of_int = Int.toString;
   707 
   708 fun string_of_indexname (a,0) = a
   709   | string_of_indexname (a,i) = a ^ "_" ^ Int.toString i;
   710 
   711 
   712 (* read integers *)
   713 
   714 fun read_radixint (radix: int, cs) : int * string list =
   715   let val zero = ord"0"
   716       val limit = zero+radix
   717       fun scan (num,[]) = (num,[])
   718         | scan (num, c::cs) =
   719               if  zero <= ord c  andalso  ord c < limit
   720               then scan(radix*num + ord c - zero, cs)
   721               else (num, c::cs)
   722   in  scan(0,cs)  end;
   723 
   724 fun read_int cs = read_radixint (10, cs);
   725 
   726 fun oct_char s = chr (#1 (read_radixint (8, explode s)));
   727 
   728 
   729 
   730 (** strings **)
   731 
   732 (* functions tuned for strings, avoiding explode *)
   733 
   734 fun nth_elem_string (i, str) =
   735   (case try String.substring (str, i, 1) of
   736     SOME s => s
   737   | NONE => raise Subscript);
   738 
   739 fun fold_string f str x0 =
   740   let
   741     val n = size str;
   742     fun iter (x, i) =
   743       if i < n then iter (f (String.substring (str, i, 1)) x, i + 1) else x;
   744   in iter (x0, 0) end;
   745 
   746 fun exists_string pred str =
   747   let
   748     val n = size str;
   749     fun ex i = i < n andalso (pred (String.substring (str, i, 1)) orelse ex (i + 1));
   750   in ex 0 end;
   751 
   752 fun forall_string pred = not o exists_string (not o pred);
   753 
   754 (*enclose in brackets*)
   755 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   756 fun unenclose str = String.substring (str, 1, size str - 2);
   757 
   758 (*simple quoting (does not escape special chars)*)
   759 val quote = enclose "\"" "\"";
   760 
   761 (*space_implode "..." (explode "hello") = "h...e...l...l...o"*)
   762 fun space_implode a bs = implode (separate a bs);
   763 
   764 val commas = space_implode ", ";
   765 val commas_quote = commas o map quote;
   766 
   767 (*concatenate messages, one per line, into a string*)
   768 val cat_lines = space_implode "\n";
   769 
   770 (*space_explode "." "h.e..l.lo" = ["h", "e", "", "l", "lo"]*)
   771 fun space_explode _ "" = []
   772   | space_explode sep str =
   773       let
   774         fun expl chs =
   775           (case take_prefix (not_equal sep) chs of
   776             (cs, []) => [implode cs]
   777           | (cs, _ :: cs') => implode cs :: expl cs');
   778       in expl (explode str) end;
   779 
   780 val split_lines = space_explode "\n";
   781 
   782 fun prefix_lines "" txt = txt
   783   | prefix_lines prfx txt = txt |> split_lines |> map (fn s => prfx ^ s) |> cat_lines;
   784 
   785 fun untabify chs =
   786   let
   787     val tab_width = 8;
   788 
   789     fun untab (_, "\n") = (0, ["\n"])
   790       | untab (pos, "\t") =
   791           let val d = tab_width - (pos mod tab_width) in (pos + d, replicate d " ") end
   792       | untab (pos, c) = (pos + 1, [c]);
   793   in
   794     if not (exists (equal "\t") chs) then chs
   795     else flat (#2 (foldl_map untab (0, chs)))
   796   end;
   797 
   798 fun suffix sffx s = s ^ sffx;
   799 
   800 fun unsuffix sffx s =
   801   let val m = size sffx; val n = size s - m in
   802     if n >= 0 andalso String.substring (s, n, m) = sffx then String.substring (s, 0, n)
   803     else raise Fail "unsuffix"
   804   end;
   805 
   806 fun unprefix prfx s =
   807   let val m = size prfx; val n = size s - m in
   808     if String.isPrefix prfx s then String.substring (s, m, n)
   809     else raise Fail "unprefix"
   810   end;
   811 
   812 fun replicate_string 0 _ = ""
   813   | replicate_string 1 a = a
   814   | replicate_string k a =
   815       if k mod 2 = 0 then replicate_string (k div 2) (a ^ a)
   816       else replicate_string (k div 2) (a ^ a) ^ a;
   817 
   818 
   819 
   820 (** lists as sets **)
   821 
   822 (*membership in a list*)
   823 fun x mem [] = false
   824   | x mem (y :: ys) = x = y orelse x mem ys;
   825 
   826 (*membership in a list, optimized version for ints*)
   827 fun (x:int) mem_int [] = false
   828   | x mem_int (y :: ys) = x = y orelse x mem_int ys;
   829 
   830 (*membership in a list, optimized version for strings*)
   831 fun (x:string) mem_string [] = false
   832   | x mem_string (y :: ys) = x = y orelse x mem_string ys;
   833 
   834 (*generalized membership test*)
   835 fun gen_mem eq (x, []) = false
   836   | gen_mem eq (x, y :: ys) = eq (x, y) orelse gen_mem eq (x, ys);
   837 
   838 (*insert and remove*)
   839 fun insert eq x xs = if gen_mem eq (x, xs) then xs else x :: xs;
   840 fun remove eq x xs = if gen_mem eq (x, xs) then filter_out (fn y => eq (x, y)) xs else xs;
   841 
   842 (*insertion into list if not already there*)
   843 fun (x ins xs) = if x mem xs then xs else x :: xs;
   844 
   845 (*insertion into list, optimized version for ints*)
   846 fun (x ins_int xs) = if x mem_int xs then xs else x :: xs;
   847 
   848 (*insertion into list, optimized version for strings*)
   849 fun (x ins_string xs) = if x mem_string xs then xs else x :: xs;
   850 
   851 (*generalized insertion*)
   852 fun gen_ins eq (x, xs) = insert eq x xs;
   853 
   854 (*union of sets represented as lists: no repetitions*)
   855 fun xs union [] = xs
   856   | [] union ys = ys
   857   | (x :: xs) union ys = xs union (x ins ys);
   858 
   859 (*union of sets, optimized version for ints*)
   860 fun (xs:int list) union_int [] = xs
   861   | [] union_int ys = ys
   862   | (x :: xs) union_int ys = xs union_int (x ins_int ys);
   863 
   864 (*union of sets, optimized version for strings*)
   865 fun (xs:string list) union_string [] = xs
   866   | [] union_string ys = ys
   867   | (x :: xs) union_string ys = xs union_string (x ins_string ys);
   868 
   869 (*generalized union*)
   870 fun gen_union eq (xs, []) = xs
   871   | gen_union eq ([], ys) = ys
   872   | gen_union eq (x :: xs, ys) = gen_union eq (xs, gen_ins eq (x, ys));
   873 
   874 
   875 (*intersection*)
   876 fun [] inter ys = []
   877   | (x :: xs) inter ys =
   878       if x mem ys then x :: (xs inter ys) else xs inter ys;
   879 
   880 (*intersection, optimized version for ints*)
   881 fun ([]:int list) inter_int ys = []
   882   | (x :: xs) inter_int ys =
   883       if x mem_int ys then x :: (xs inter_int ys) else xs inter_int ys;
   884 
   885 (*intersection, optimized version for strings *)
   886 fun ([]:string list) inter_string ys = []
   887   | (x :: xs) inter_string ys =
   888       if x mem_string ys then x :: (xs inter_string ys) else xs inter_string ys;
   889 
   890 (*generalized intersection*)
   891 fun gen_inter eq ([], ys) = []
   892   | gen_inter eq (x::xs, ys) =
   893       if gen_mem eq (x,ys) then x :: gen_inter eq (xs, ys)
   894                            else      gen_inter eq (xs, ys);
   895 
   896 
   897 (*subset*)
   898 fun [] subset ys = true
   899   | (x :: xs) subset ys = x mem ys andalso xs subset ys;
   900 
   901 (*subset, optimized version for ints*)
   902 fun ([]: int list) subset_int ys = true
   903   | (x :: xs) subset_int ys = x mem_int ys andalso xs subset_int ys;
   904 
   905 (*subset, optimized version for strings*)
   906 fun ([]: string list) subset_string ys = true
   907   | (x :: xs) subset_string ys = x mem_string ys andalso xs subset_string ys;
   908 
   909 (*set equality*)
   910 fun eq_set (xs, ys) =
   911   xs = ys orelse (xs subset ys andalso ys subset xs);
   912 
   913 (*set equality for strings*)
   914 fun eq_set_string ((xs: string list), ys) =
   915   xs = ys orelse (xs subset_string ys andalso ys subset_string xs);
   916 
   917 fun gen_subset eq (xs, ys) = forall (fn x => gen_mem eq (x, ys)) xs;
   918 
   919 
   920 (*removing an element from a list WITHOUT duplicates*)
   921 fun (y :: ys) \ x = if x = y then ys else y :: (ys \ x)
   922   | [] \ x = [];
   923 
   924 fun ys \\ xs = foldl (op \) (ys,xs);
   925 
   926 (*removing an element from a list -- possibly WITH duplicates*)
   927 fun gen_rem eq (xs, y) = filter_out (fn x => eq (x, y)) xs;
   928 fun gen_rems eq (xs, ys) = filter_out (fn x => gen_mem eq (x, ys)) xs;
   929 
   930 (*makes a list of the distinct members of the input; preserves order, takes
   931   first of equal elements*)
   932 fun gen_distinct eq lst =
   933   let
   934     val memb = gen_mem eq;
   935 
   936     fun dist (rev_seen, []) = rev rev_seen
   937       | dist (rev_seen, x :: xs) =
   938           if memb (x, rev_seen) then dist (rev_seen, xs)
   939           else dist (x :: rev_seen, xs);
   940   in
   941     dist ([], lst)
   942   end;
   943 
   944 fun distinct l = gen_distinct (op =) l;
   945 
   946 
   947 (*returns the tail beginning with the first repeated element, or []*)
   948 fun findrep [] = []
   949   | findrep (x :: xs) = if x mem xs then x :: xs else findrep xs;
   950 
   951 
   952 (*returns a list containing all repeated elements exactly once; preserves
   953   order, takes first of equal elements*)
   954 fun gen_duplicates eq lst =
   955   let
   956     val memb = gen_mem eq;
   957 
   958     fun dups (rev_dups, []) = rev rev_dups
   959       | dups (rev_dups, x :: xs) =
   960           if memb (x, rev_dups) orelse not (memb (x, xs)) then
   961             dups (rev_dups, xs)
   962           else dups (x :: rev_dups, xs);
   963   in
   964     dups ([], lst)
   965   end;
   966 
   967 fun duplicates l = gen_duplicates (op =) l;
   968 
   969 
   970 
   971 (** association lists **)
   972 
   973 (*association list lookup*)
   974 fun assoc ([], key) = NONE
   975   | assoc ((keyi, xi) :: pairs, key) =
   976       if key = keyi then SOME xi else assoc (pairs, key);
   977 
   978 (*association list lookup, optimized version for ints*)
   979 fun assoc_int ([], (key:int)) = NONE
   980   | assoc_int ((keyi, xi) :: pairs, key) =
   981       if key = keyi then SOME xi else assoc_int (pairs, key);
   982 
   983 (*association list lookup, optimized version for strings*)
   984 fun assoc_string ([], (key:string)) = NONE
   985   | assoc_string ((keyi, xi) :: pairs, key) =
   986       if key = keyi then SOME xi else assoc_string (pairs, key);
   987 
   988 (*association list lookup, optimized version for string*ints*)
   989 fun assoc_string_int ([], (key:string*int)) = NONE
   990   | assoc_string_int ((keyi, xi) :: pairs, key) =
   991       if key = keyi then SOME xi else assoc_string_int (pairs, key);
   992 
   993 fun assocs ps x =
   994   (case assoc (ps, x) of
   995     NONE => []
   996   | SOME ys => ys);
   997 
   998 (*two-fold association list lookup*)
   999 fun assoc2 (aal, (key1, key2)) =
  1000   (case assoc (aal, key1) of
  1001     SOME al => assoc (al, key2)
  1002   | NONE => NONE);
  1003 
  1004 (*generalized association list lookup*)
  1005 fun gen_assoc eq ([], key) = NONE
  1006   | gen_assoc eq ((keyi, xi) :: pairs, key) =
  1007       if eq (key, keyi) then SOME xi else gen_assoc eq (pairs, key);
  1008 
  1009 (*association list update*)
  1010 fun overwrite (al, p as (key, _)) =
  1011   let fun over ((q as (keyi, _)) :: pairs) =
  1012             if keyi = key then p :: pairs else q :: (over pairs)
  1013         | over [] = [p]
  1014   in over al end;
  1015 
  1016 fun gen_overwrite eq (al, p as (key, _)) =
  1017   let fun over ((q as (keyi, _)) :: pairs) =
  1018             if eq (keyi, key) then p :: pairs else q :: (over pairs)
  1019         | over [] = [p]
  1020   in over al end;
  1021 
  1022 
  1023 (* lists as tables *)
  1024 
  1025 fun gen_merge_lists _ xs [] = xs
  1026   | gen_merge_lists _ [] ys = ys
  1027   | gen_merge_lists eq xs ys = xs @ gen_rems eq (ys, xs);
  1028 
  1029 fun gen_merge_lists' _ xs [] = xs
  1030   | gen_merge_lists' _ [] ys = ys
  1031   | gen_merge_lists' eq xs ys = gen_rems eq (ys, xs) @ xs;
  1032 
  1033 fun merge_lists xs ys = gen_merge_lists (op =) xs ys;
  1034 fun merge_lists' xs ys = gen_merge_lists' (op =) xs ys;
  1035 fun merge_alists al = gen_merge_lists eq_fst al;
  1036 fun merge_alists' al = gen_merge_lists' eq_fst al;
  1037 
  1038 
  1039 
  1040 (** balanced trees **)
  1041 
  1042 exception Balance;      (*indicates non-positive argument to balancing fun*)
  1043 
  1044 (*balanced folding; avoids deep nesting*)
  1045 fun fold_bal f [x] = x
  1046   | fold_bal f [] = raise Balance
  1047   | fold_bal f xs =
  1048       let val (ps,qs) = splitAt(length xs div 2, xs)
  1049       in  f (fold_bal f ps, fold_bal f qs)  end;
  1050 
  1051 (*construct something of the form f(...g(...(x)...)) for balanced access*)
  1052 fun access_bal (f, g, x) n i =
  1053   let fun acc n i =     (*1<=i<=n*)
  1054           if n=1 then x else
  1055           let val n2 = n div 2
  1056           in  if i<=n2 then f (acc n2 i)
  1057                        else g (acc (n-n2) (i-n2))
  1058           end
  1059   in  if 1<=i andalso i<=n then acc n i else raise Balance  end;
  1060 
  1061 (*construct ALL such accesses; could try harder to share recursive calls!*)
  1062 fun accesses_bal (f, g, x) n =
  1063   let fun acc n =
  1064           if n=1 then [x] else
  1065           let val n2 = n div 2
  1066               val acc2 = acc n2
  1067           in  if n-n2=n2 then map f acc2 @ map g acc2
  1068                          else map f acc2 @ map g (acc (n-n2)) end
  1069   in  if 1<=n then acc n else raise Balance  end;
  1070 
  1071 
  1072 
  1073 (** orders **)
  1074 
  1075 fun rev_order LESS = GREATER
  1076   | rev_order EQUAL = EQUAL
  1077   | rev_order GREATER = LESS;
  1078 
  1079 (*assume rel is a linear strict order*)
  1080 fun make_ord rel (x, y) =
  1081   if rel (x, y) then LESS
  1082   else if rel (y, x) then GREATER
  1083   else EQUAL;
  1084 
  1085 val int_ord = Int.compare;
  1086 val string_ord = String.compare;
  1087 
  1088 (*lexicographic product*)
  1089 fun prod_ord a_ord b_ord ((x, y), (x', y')) =
  1090   (case a_ord (x, x') of EQUAL => b_ord (y, y') | ord => ord);
  1091 
  1092 (*dictionary order -- in general NOT well-founded!*)
  1093 fun dict_ord _ ([], []) = EQUAL
  1094   | dict_ord _ ([], _ :: _) = LESS
  1095   | dict_ord _ (_ :: _, []) = GREATER
  1096   | dict_ord elem_ord (x :: xs, y :: ys) =
  1097       (case elem_ord (x, y) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
  1098 
  1099 (*lexicographic product of lists*)
  1100 fun list_ord elem_ord (xs, ys) =
  1101   prod_ord int_ord (dict_ord elem_ord) ((length xs, xs), (length ys, ys));
  1102 
  1103 
  1104 (* sorting *)
  1105 
  1106 (*quicksort (stable, i.e. does not reorder equal elements)*)
  1107 fun sort ord =
  1108   let
  1109     fun qsort xs =
  1110       let val len = length xs in
  1111         if len <= 1 then xs
  1112         else
  1113           let val (lts, eqs, gts) = part (nth_elem (len div 2, xs)) xs in
  1114             qsort lts @ eqs @ qsort gts
  1115           end
  1116       end
  1117     and part _ [] = ([], [], [])
  1118       | part pivot (x :: xs) = add (ord (x, pivot)) x (part pivot xs)
  1119     and add LESS x (lts, eqs, gts) = (x :: lts, eqs, gts)
  1120       | add EQUAL x (lts, eqs, gts) = (lts, x :: eqs, gts)
  1121       | add GREATER x (lts, eqs, gts) = (lts, eqs, x :: gts);
  1122   in qsort end;
  1123 
  1124 (*sort strings*)
  1125 val sort_strings = sort string_ord;
  1126 fun sort_wrt sel xs = sort (string_ord o pairself sel) xs;
  1127 
  1128 fun unique_strings ([]: string list) = []
  1129   | unique_strings [x] = [x]
  1130   | unique_strings (x :: y :: ys) =
  1131       if x = y then unique_strings (y :: ys)
  1132       else x :: unique_strings (y :: ys);
  1133 
  1134 
  1135 (** random numbers **)
  1136 
  1137 exception RANDOM;
  1138 
  1139 fun rmod x y = x - y * Real.realFloor (x / y);
  1140 
  1141 local
  1142   val a = 16807.0;
  1143   val m = 2147483647.0;
  1144   val random_seed = ref 1.0;
  1145 in
  1146 
  1147 fun random () =
  1148   let val r = rmod (a * !random_seed) m
  1149   in (random_seed := r; r) end;
  1150 
  1151 end;
  1152 
  1153 fun random_range l h =
  1154   if h < l orelse l < 0 then raise RANDOM
  1155   else l + Real.floor (rmod (random ()) (real (h - l + 1)));
  1156 
  1157 fun one_of xs = nth_elem (random_range 0 (length xs - 1), xs);
  1158 
  1159 fun frequency xs =
  1160   let
  1161     val sum = foldl op + (0, map fst xs);
  1162     fun pick n ((k, x) :: xs) =
  1163       if n <= k then x else pick (n - k) xs
  1164   in pick (random_range 1 sum) xs end;
  1165 
  1166 
  1167 (** current directory **)
  1168 
  1169 val cd = OS.FileSys.chDir;
  1170 val pwd = OS.FileSys.getDir;
  1171 
  1172 
  1173 
  1174 (** rational numbers **)
  1175 
  1176 datatype rat = Rat of bool * IntInf.int * IntInf.int
  1177 
  1178 exception RAT of string;
  1179 
  1180 fun rep_rat(Rat(a,p,q)) = (if a then p else ~p,q)
  1181 
  1182 fun ratnorm(a,p,q) = if p=0 then Rat(a,0,1) else
  1183   let val absp = abs p
  1184       val m = gcd(absp,q)
  1185   in Rat(a = (0 <= p), absp div m, q div m) end;
  1186 
  1187 fun ratadd(Rat(a,p,q),Rat(b,r,s)) =
  1188   let val den = lcm(q,s)
  1189       val p = p*(den div q) and r = r*(den div s)
  1190       val num = (if a then p else ~p) + (if b then r else ~r)
  1191   in ratnorm(true,num,den) end;
  1192 
  1193 fun ratmul(Rat(a,p,q),Rat(b,r,s)) = ratnorm(a=b,p*r,q*s)
  1194 
  1195 fun ratinv(Rat(a,p,q)) = if p=0 then raise RAT "ratinv" else Rat(a,q,p)
  1196 
  1197 fun int_ratdiv(p,q) =
  1198   if q=0 then raise RAT "int_ratdiv" else ratnorm(0<=q, p, abs q)
  1199 
  1200 fun ratneg(Rat(b,p,q)) = Rat(not b,p,q);
  1201 
  1202 fun rat_of_intinf i = if i < 0 then Rat(false,abs i,1) else Rat(true,i,1);
  1203 
  1204 fun rat_of_int i = rat_of_intinf (IntInf.fromInt i);
  1205 
  1206 
  1207 (** misc **)
  1208 
  1209 (*use the keyfun to make a list of (x, key) pairs*)
  1210 fun make_keylist (keyfun: 'a->'b) : 'a list -> ('a * 'b) list =
  1211   let fun keypair x = (x, keyfun x)
  1212   in map keypair end;
  1213 
  1214 (*given a list of (x, key) pairs and a searchkey
  1215   return the list of xs from each pair whose key equals searchkey*)
  1216 fun keyfilter [] searchkey = []
  1217   | keyfilter ((x, key) :: pairs) searchkey =
  1218       if key = searchkey then x :: keyfilter pairs searchkey
  1219       else keyfilter pairs searchkey;
  1220 
  1221 
  1222 (*Partition list into elements that satisfy predicate and those that don't.
  1223   Preserves order of elements in both lists.*)
  1224 val partition = List.partition;
  1225 
  1226 
  1227 fun partition_eq (eq:'a * 'a -> bool) =
  1228     let fun part [] = []
  1229           | part (x::ys) = let val (xs, xs') = partition (apl(x, eq)) ys
  1230                            in (x::xs)::(part xs') end
  1231     in part end;
  1232 
  1233 
  1234 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
  1235    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
  1236 fun partition_list p i j =
  1237   let fun part k xs =
  1238             if k>j then
  1239               (case xs of [] => []
  1240                          | _ => raise Fail "partition_list")
  1241             else
  1242             let val (ns, rest) = partition (p k) xs;
  1243             in  ns :: part(k+1)rest  end
  1244   in  part i end;
  1245 
  1246 
  1247 (* generating identifiers *)
  1248 
  1249 (** Freshly generated identifiers; supplied prefix MUST start with a letter **)
  1250 local
  1251 (*Maps 0-63 to A-Z, a-z, 0-9 or _ or ' for generating random identifiers*)
  1252 fun char i =      if i<26 then chr (ord "A" + i)
  1253              else if i<52 then chr (ord "a" + i - 26)
  1254              else if i<62 then chr (ord"0" + i - 52)
  1255              else if i=62 then "_"
  1256              else  (*i=63*)    "'";
  1257 
  1258 val charVec = Vector.tabulate (64, char);
  1259 
  1260 fun newid n =
  1261   let
  1262   in  implode (map (fn i => Vector.sub(charVec,i)) (radixpand (64,n)))  end;
  1263 
  1264 val seedr = ref 0;
  1265 
  1266 in
  1267 
  1268 fun gensym pre = pre ^ (#1(newid (!seedr), inc seedr));
  1269 
  1270 end;
  1271 
  1272 
  1273 (* lexical scanning *)
  1274 
  1275 (*scan a list of characters into "words" composed of "letters" (recognized by
  1276   is_let) and separated by any number of non-"letters"*)
  1277 fun scanwords is_let cs =
  1278   let fun scan1 [] = []
  1279         | scan1 cs =
  1280             let val (lets, rest) = take_prefix is_let cs
  1281             in implode lets :: scanwords is_let rest end;
  1282   in scan1 (#2 (take_prefix (not o is_let) cs)) end;
  1283 
  1284 
  1285 (* stamps and serial numbers *)
  1286 
  1287 type stamp = unit ref;
  1288 val stamp: unit -> stamp = ref;
  1289 
  1290 type serial = int;
  1291 local val count = ref 0
  1292 in fun serial () = inc count end;
  1293 
  1294 end;
  1295 
  1296 structure BasicLibrary: BASIC_LIBRARY = Library;
  1297 open BasicLibrary;