src/HOL/Probability/Independent_Family.thy
author hoelzl
Mon Apr 23 12:14:35 2012 +0200 (2012-04-23)
changeset 47694 05663f75964c
parent 46731 5302e932d1e5
child 49772 75660d89c339
permissions -rw-r--r--
reworked Probability theory
     1 (*  Title:      HOL/Probability/Independent_Family.thy
     2     Author:     Johannes Hölzl, TU München
     3 *)
     4 
     5 header {* Independent families of events, event sets, and random variables *}
     6 
     7 theory Independent_Family
     8   imports Probability_Measure Infinite_Product_Measure
     9 begin
    10 
    11 lemma INT_decseq_offset:
    12   assumes "decseq F"
    13   shows "(\<Inter>i. F i) = (\<Inter>i\<in>{n..}. F i)"
    14 proof safe
    15   fix x i assume x: "x \<in> (\<Inter>i\<in>{n..}. F i)"
    16   show "x \<in> F i"
    17   proof cases
    18     from x have "x \<in> F n" by auto
    19     also assume "i \<le> n" with `decseq F` have "F n \<subseteq> F i"
    20       unfolding decseq_def by simp
    21     finally show ?thesis .
    22   qed (insert x, simp)
    23 qed auto
    24 
    25 definition (in prob_space)
    26   "indep_events A I \<longleftrightarrow> (A`I \<subseteq> events) \<and>
    27     (\<forall>J\<subseteq>I. J \<noteq> {} \<longrightarrow> finite J \<longrightarrow> prob (\<Inter>j\<in>J. A j) = (\<Prod>j\<in>J. prob (A j)))"
    28 
    29 definition (in prob_space)
    30   "indep_event A B \<longleftrightarrow> indep_events (bool_case A B) UNIV"
    31 
    32 definition (in prob_space)
    33   "indep_sets F I \<longleftrightarrow> (\<forall>i\<in>I. F i \<subseteq> events) \<and>
    34     (\<forall>J\<subseteq>I. J \<noteq> {} \<longrightarrow> finite J \<longrightarrow> (\<forall>A\<in>Pi J F. prob (\<Inter>j\<in>J. A j) = (\<Prod>j\<in>J. prob (A j))))"
    35 
    36 definition (in prob_space)
    37   "indep_set A B \<longleftrightarrow> indep_sets (bool_case A B) UNIV"
    38 
    39 definition (in prob_space)
    40   "indep_vars M' X I \<longleftrightarrow>
    41     (\<forall>i\<in>I. random_variable (M' i) (X i)) \<and>
    42     indep_sets (\<lambda>i. sigma_sets (space M) { X i -` A \<inter> space M | A. A \<in> sets (M' i)}) I"
    43 
    44 definition (in prob_space)
    45   "indep_var Ma A Mb B \<longleftrightarrow> indep_vars (bool_case Ma Mb) (bool_case A B) UNIV"
    46 
    47 lemma (in prob_space) indep_sets_cong:
    48   "I = J \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> F i = G i) \<Longrightarrow> indep_sets F I \<longleftrightarrow> indep_sets G J"
    49   by (simp add: indep_sets_def, intro conj_cong all_cong imp_cong ball_cong) blast+
    50 
    51 lemma (in prob_space) indep_sets_singleton_iff_indep_events:
    52   "indep_sets (\<lambda>i. {F i}) I \<longleftrightarrow> indep_events F I"
    53   unfolding indep_sets_def indep_events_def
    54   by (simp, intro conj_cong ball_cong all_cong imp_cong) (auto simp: Pi_iff)
    55 
    56 lemma (in prob_space) indep_events_finite_index_events:
    57   "indep_events F I \<longleftrightarrow> (\<forall>J\<subseteq>I. J \<noteq> {} \<longrightarrow> finite J \<longrightarrow> indep_events F J)"
    58   by (auto simp: indep_events_def)
    59 
    60 lemma (in prob_space) indep_sets_finite_index_sets:
    61   "indep_sets F I \<longleftrightarrow> (\<forall>J\<subseteq>I. J \<noteq> {} \<longrightarrow> finite J \<longrightarrow> indep_sets F J)"
    62 proof (intro iffI allI impI)
    63   assume *: "\<forall>J\<subseteq>I. J \<noteq> {} \<longrightarrow> finite J \<longrightarrow> indep_sets F J"
    64   show "indep_sets F I" unfolding indep_sets_def
    65   proof (intro conjI ballI allI impI)
    66     fix i assume "i \<in> I"
    67     with *[THEN spec, of "{i}"] show "F i \<subseteq> events"
    68       by (auto simp: indep_sets_def)
    69   qed (insert *, auto simp: indep_sets_def)
    70 qed (auto simp: indep_sets_def)
    71 
    72 lemma (in prob_space) indep_sets_mono_index:
    73   "J \<subseteq> I \<Longrightarrow> indep_sets F I \<Longrightarrow> indep_sets F J"
    74   unfolding indep_sets_def by auto
    75 
    76 lemma (in prob_space) indep_sets_mono_sets:
    77   assumes indep: "indep_sets F I"
    78   assumes mono: "\<And>i. i\<in>I \<Longrightarrow> G i \<subseteq> F i"
    79   shows "indep_sets G I"
    80 proof -
    81   have "(\<forall>i\<in>I. F i \<subseteq> events) \<Longrightarrow> (\<forall>i\<in>I. G i \<subseteq> events)"
    82     using mono by auto
    83   moreover have "\<And>A J. J \<subseteq> I \<Longrightarrow> A \<in> (\<Pi> j\<in>J. G j) \<Longrightarrow> A \<in> (\<Pi> j\<in>J. F j)"
    84     using mono by (auto simp: Pi_iff)
    85   ultimately show ?thesis
    86     using indep by (auto simp: indep_sets_def)
    87 qed
    88 
    89 lemma (in prob_space) indep_setsI:
    90   assumes "\<And>i. i \<in> I \<Longrightarrow> F i \<subseteq> events"
    91     and "\<And>A J. J \<noteq> {} \<Longrightarrow> J \<subseteq> I \<Longrightarrow> finite J \<Longrightarrow> (\<forall>j\<in>J. A j \<in> F j) \<Longrightarrow> prob (\<Inter>j\<in>J. A j) = (\<Prod>j\<in>J. prob (A j))"
    92   shows "indep_sets F I"
    93   using assms unfolding indep_sets_def by (auto simp: Pi_iff)
    94 
    95 lemma (in prob_space) indep_setsD:
    96   assumes "indep_sets F I" and "J \<subseteq> I" "J \<noteq> {}" "finite J" "\<forall>j\<in>J. A j \<in> F j"
    97   shows "prob (\<Inter>j\<in>J. A j) = (\<Prod>j\<in>J. prob (A j))"
    98   using assms unfolding indep_sets_def by auto
    99 
   100 lemma (in prob_space) indep_setI:
   101   assumes ev: "A \<subseteq> events" "B \<subseteq> events"
   102     and indep: "\<And>a b. a \<in> A \<Longrightarrow> b \<in> B \<Longrightarrow> prob (a \<inter> b) = prob a * prob b"
   103   shows "indep_set A B"
   104   unfolding indep_set_def
   105 proof (rule indep_setsI)
   106   fix F J assume "J \<noteq> {}" "J \<subseteq> UNIV"
   107     and F: "\<forall>j\<in>J. F j \<in> (case j of True \<Rightarrow> A | False \<Rightarrow> B)"
   108   have "J \<in> Pow UNIV" by auto
   109   with F `J \<noteq> {}` indep[of "F True" "F False"]
   110   show "prob (\<Inter>j\<in>J. F j) = (\<Prod>j\<in>J. prob (F j))"
   111     unfolding UNIV_bool Pow_insert by (auto simp: ac_simps)
   112 qed (auto split: bool.split simp: ev)
   113 
   114 lemma (in prob_space) indep_setD:
   115   assumes indep: "indep_set A B" and ev: "a \<in> A" "b \<in> B"
   116   shows "prob (a \<inter> b) = prob a * prob b"
   117   using indep[unfolded indep_set_def, THEN indep_setsD, of UNIV "bool_case a b"] ev
   118   by (simp add: ac_simps UNIV_bool)
   119 
   120 lemma (in prob_space) indep_var_eq:
   121   "indep_var S X T Y \<longleftrightarrow>
   122     (random_variable S X \<and> random_variable T Y) \<and>
   123     indep_set
   124       (sigma_sets (space M) { X -` A \<inter> space M | A. A \<in> sets S})
   125       (sigma_sets (space M) { Y -` A \<inter> space M | A. A \<in> sets T})"
   126   unfolding indep_var_def indep_vars_def indep_set_def UNIV_bool
   127   by (intro arg_cong2[where f="op \<and>"] arg_cong2[where f=indep_sets] ext)
   128      (auto split: bool.split)
   129 
   130 lemma (in prob_space)
   131   assumes indep: "indep_set A B"
   132   shows indep_setD_ev1: "A \<subseteq> events"
   133     and indep_setD_ev2: "B \<subseteq> events"
   134   using indep unfolding indep_set_def indep_sets_def UNIV_bool by auto
   135 
   136 lemma (in prob_space) indep_sets_dynkin:
   137   assumes indep: "indep_sets F I"
   138   shows "indep_sets (\<lambda>i. dynkin (space M) (F i)) I"
   139     (is "indep_sets ?F I")
   140 proof (subst indep_sets_finite_index_sets, intro allI impI ballI)
   141   fix J assume "finite J" "J \<subseteq> I" "J \<noteq> {}"
   142   with indep have "indep_sets F J"
   143     by (subst (asm) indep_sets_finite_index_sets) auto
   144   { fix J K assume "indep_sets F K"
   145     let ?G = "\<lambda>S i. if i \<in> S then ?F i else F i"
   146     assume "finite J" "J \<subseteq> K"
   147     then have "indep_sets (?G J) K"
   148     proof induct
   149       case (insert j J)
   150       moreover def G \<equiv> "?G J"
   151       ultimately have G: "indep_sets G K" "\<And>i. i \<in> K \<Longrightarrow> G i \<subseteq> events" and "j \<in> K"
   152         by (auto simp: indep_sets_def)
   153       let ?D = "{E\<in>events. indep_sets (G(j := {E})) K }"
   154       { fix X assume X: "X \<in> events"
   155         assume indep: "\<And>J A. J \<noteq> {} \<Longrightarrow> J \<subseteq> K \<Longrightarrow> finite J \<Longrightarrow> j \<notin> J \<Longrightarrow> (\<forall>i\<in>J. A i \<in> G i)
   156           \<Longrightarrow> prob ((\<Inter>i\<in>J. A i) \<inter> X) = prob X * (\<Prod>i\<in>J. prob (A i))"
   157         have "indep_sets (G(j := {X})) K"
   158         proof (rule indep_setsI)
   159           fix i assume "i \<in> K" then show "(G(j:={X})) i \<subseteq> events"
   160             using G X by auto
   161         next
   162           fix A J assume J: "J \<noteq> {}" "J \<subseteq> K" "finite J" "\<forall>i\<in>J. A i \<in> (G(j := {X})) i"
   163           show "prob (\<Inter>j\<in>J. A j) = (\<Prod>j\<in>J. prob (A j))"
   164           proof cases
   165             assume "j \<in> J"
   166             with J have "A j = X" by auto
   167             show ?thesis
   168             proof cases
   169               assume "J = {j}" then show ?thesis by simp
   170             next
   171               assume "J \<noteq> {j}"
   172               have "prob (\<Inter>i\<in>J. A i) = prob ((\<Inter>i\<in>J-{j}. A i) \<inter> X)"
   173                 using `j \<in> J` `A j = X` by (auto intro!: arg_cong[where f=prob] split: split_if_asm)
   174               also have "\<dots> = prob X * (\<Prod>i\<in>J-{j}. prob (A i))"
   175               proof (rule indep)
   176                 show "J - {j} \<noteq> {}" "J - {j} \<subseteq> K" "finite (J - {j})" "j \<notin> J - {j}"
   177                   using J `J \<noteq> {j}` `j \<in> J` by auto
   178                 show "\<forall>i\<in>J - {j}. A i \<in> G i"
   179                   using J by auto
   180               qed
   181               also have "\<dots> = prob (A j) * (\<Prod>i\<in>J-{j}. prob (A i))"
   182                 using `A j = X` by simp
   183               also have "\<dots> = (\<Prod>i\<in>J. prob (A i))"
   184                 unfolding setprod.insert_remove[OF `finite J`, symmetric, of "\<lambda>i. prob  (A i)"]
   185                 using `j \<in> J` by (simp add: insert_absorb)
   186               finally show ?thesis .
   187             qed
   188           next
   189             assume "j \<notin> J"
   190             with J have "\<forall>i\<in>J. A i \<in> G i" by (auto split: split_if_asm)
   191             with J show ?thesis
   192               by (intro indep_setsD[OF G(1)]) auto
   193           qed
   194         qed }
   195       note indep_sets_insert = this
   196       have "dynkin_system (space M) ?D"
   197       proof (rule dynkin_systemI', simp_all cong del: indep_sets_cong, safe)
   198         show "indep_sets (G(j := {{}})) K"
   199           by (rule indep_sets_insert) auto
   200       next
   201         fix X assume X: "X \<in> events" and G': "indep_sets (G(j := {X})) K"
   202         show "indep_sets (G(j := {space M - X})) K"
   203         proof (rule indep_sets_insert)
   204           fix J A assume J: "J \<noteq> {}" "J \<subseteq> K" "finite J" "j \<notin> J" and A: "\<forall>i\<in>J. A i \<in> G i"
   205           then have A_sets: "\<And>i. i\<in>J \<Longrightarrow> A i \<in> events"
   206             using G by auto
   207           have "prob ((\<Inter>j\<in>J. A j) \<inter> (space M - X)) =
   208               prob ((\<Inter>j\<in>J. A j) - (\<Inter>i\<in>insert j J. (A(j := X)) i))"
   209             using A_sets sets_into_space[of _ M] X `J \<noteq> {}`
   210             by (auto intro!: arg_cong[where f=prob] split: split_if_asm)
   211           also have "\<dots> = prob (\<Inter>j\<in>J. A j) - prob (\<Inter>i\<in>insert j J. (A(j := X)) i)"
   212             using J `J \<noteq> {}` `j \<notin> J` A_sets X sets_into_space
   213             by (auto intro!: finite_measure_Diff finite_INT split: split_if_asm)
   214           finally have "prob ((\<Inter>j\<in>J. A j) \<inter> (space M - X)) =
   215               prob (\<Inter>j\<in>J. A j) - prob (\<Inter>i\<in>insert j J. (A(j := X)) i)" .
   216           moreover {
   217             have "prob (\<Inter>j\<in>J. A j) = (\<Prod>j\<in>J. prob (A j))"
   218               using J A `finite J` by (intro indep_setsD[OF G(1)]) auto
   219             then have "prob (\<Inter>j\<in>J. A j) = prob (space M) * (\<Prod>i\<in>J. prob (A i))"
   220               using prob_space by simp }
   221           moreover {
   222             have "prob (\<Inter>i\<in>insert j J. (A(j := X)) i) = (\<Prod>i\<in>insert j J. prob ((A(j := X)) i))"
   223               using J A `j \<in> K` by (intro indep_setsD[OF G']) auto
   224             then have "prob (\<Inter>i\<in>insert j J. (A(j := X)) i) = prob X * (\<Prod>i\<in>J. prob (A i))"
   225               using `finite J` `j \<notin> J` by (auto intro!: setprod_cong) }
   226           ultimately have "prob ((\<Inter>j\<in>J. A j) \<inter> (space M - X)) = (prob (space M) - prob X) * (\<Prod>i\<in>J. prob (A i))"
   227             by (simp add: field_simps)
   228           also have "\<dots> = prob (space M - X) * (\<Prod>i\<in>J. prob (A i))"
   229             using X A by (simp add: finite_measure_compl)
   230           finally show "prob ((\<Inter>j\<in>J. A j) \<inter> (space M - X)) = prob (space M - X) * (\<Prod>i\<in>J. prob (A i))" .
   231         qed (insert X, auto)
   232       next
   233         fix F :: "nat \<Rightarrow> 'a set" assume disj: "disjoint_family F" and "range F \<subseteq> ?D"
   234         then have F: "\<And>i. F i \<in> events" "\<And>i. indep_sets (G(j:={F i})) K" by auto
   235         show "indep_sets (G(j := {\<Union>k. F k})) K"
   236         proof (rule indep_sets_insert)
   237           fix J A assume J: "j \<notin> J" "J \<noteq> {}" "J \<subseteq> K" "finite J" and A: "\<forall>i\<in>J. A i \<in> G i"
   238           then have A_sets: "\<And>i. i\<in>J \<Longrightarrow> A i \<in> events"
   239             using G by auto
   240           have "prob ((\<Inter>j\<in>J. A j) \<inter> (\<Union>k. F k)) = prob (\<Union>k. (\<Inter>i\<in>insert j J. (A(j := F k)) i))"
   241             using `J \<noteq> {}` `j \<notin> J` `j \<in> K` by (auto intro!: arg_cong[where f=prob] split: split_if_asm)
   242           moreover have "(\<lambda>k. prob (\<Inter>i\<in>insert j J. (A(j := F k)) i)) sums prob (\<Union>k. (\<Inter>i\<in>insert j J. (A(j := F k)) i))"
   243           proof (rule finite_measure_UNION)
   244             show "disjoint_family (\<lambda>k. \<Inter>i\<in>insert j J. (A(j := F k)) i)"
   245               using disj by (rule disjoint_family_on_bisimulation) auto
   246             show "range (\<lambda>k. \<Inter>i\<in>insert j J. (A(j := F k)) i) \<subseteq> events"
   247               using A_sets F `finite J` `J \<noteq> {}` `j \<notin> J` by (auto intro!: Int)
   248           qed
   249           moreover { fix k
   250             from J A `j \<in> K` have "prob (\<Inter>i\<in>insert j J. (A(j := F k)) i) = prob (F k) * (\<Prod>i\<in>J. prob (A i))"
   251               by (subst indep_setsD[OF F(2)]) (auto intro!: setprod_cong split: split_if_asm)
   252             also have "\<dots> = prob (F k) * prob (\<Inter>i\<in>J. A i)"
   253               using J A `j \<in> K` by (subst indep_setsD[OF G(1)]) auto
   254             finally have "prob (\<Inter>i\<in>insert j J. (A(j := F k)) i) = prob (F k) * prob (\<Inter>i\<in>J. A i)" . }
   255           ultimately have "(\<lambda>k. prob (F k) * prob (\<Inter>i\<in>J. A i)) sums (prob ((\<Inter>j\<in>J. A j) \<inter> (\<Union>k. F k)))"
   256             by simp
   257           moreover
   258           have "(\<lambda>k. prob (F k) * prob (\<Inter>i\<in>J. A i)) sums (prob (\<Union>k. F k) * prob (\<Inter>i\<in>J. A i))"
   259             using disj F(1) by (intro finite_measure_UNION sums_mult2) auto
   260           then have "(\<lambda>k. prob (F k) * prob (\<Inter>i\<in>J. A i)) sums (prob (\<Union>k. F k) * (\<Prod>i\<in>J. prob (A i)))"
   261             using J A `j \<in> K` by (subst indep_setsD[OF G(1), symmetric]) auto
   262           ultimately
   263           show "prob ((\<Inter>j\<in>J. A j) \<inter> (\<Union>k. F k)) = prob (\<Union>k. F k) * (\<Prod>j\<in>J. prob (A j))"
   264             by (auto dest!: sums_unique)
   265         qed (insert F, auto)
   266       qed (insert sets_into_space, auto)
   267       then have mono: "dynkin (space M) (G j) \<subseteq> {E \<in> events. indep_sets (G(j := {E})) K}"
   268       proof (rule dynkin_system.dynkin_subset, safe)
   269         fix X assume "X \<in> G j"
   270         then show "X \<in> events" using G `j \<in> K` by auto
   271         from `indep_sets G K`
   272         show "indep_sets (G(j := {X})) K"
   273           by (rule indep_sets_mono_sets) (insert `X \<in> G j`, auto)
   274       qed
   275       have "indep_sets (G(j:=?D)) K"
   276       proof (rule indep_setsI)
   277         fix i assume "i \<in> K" then show "(G(j := ?D)) i \<subseteq> events"
   278           using G(2) by auto
   279       next
   280         fix A J assume J: "J\<noteq>{}" "J \<subseteq> K" "finite J" and A: "\<forall>i\<in>J. A i \<in> (G(j := ?D)) i"
   281         show "prob (\<Inter>j\<in>J. A j) = (\<Prod>j\<in>J. prob (A j))"
   282         proof cases
   283           assume "j \<in> J"
   284           with A have indep: "indep_sets (G(j := {A j})) K" by auto
   285           from J A show ?thesis
   286             by (intro indep_setsD[OF indep]) auto
   287         next
   288           assume "j \<notin> J"
   289           with J A have "\<forall>i\<in>J. A i \<in> G i" by (auto split: split_if_asm)
   290           with J show ?thesis
   291             by (intro indep_setsD[OF G(1)]) auto
   292         qed
   293       qed
   294       then have "indep_sets (G(j := dynkin (space M) (G j))) K"
   295         by (rule indep_sets_mono_sets) (insert mono, auto)
   296       then show ?case
   297         by (rule indep_sets_mono_sets) (insert `j \<in> K` `j \<notin> J`, auto simp: G_def)
   298     qed (insert `indep_sets F K`, simp) }
   299   from this[OF `indep_sets F J` `finite J` subset_refl]
   300   show "indep_sets ?F J"
   301     by (rule indep_sets_mono_sets) auto
   302 qed
   303 
   304 lemma (in prob_space) indep_sets_sigma:
   305   assumes indep: "indep_sets F I"
   306   assumes stable: "\<And>i. i \<in> I \<Longrightarrow> Int_stable (F i)"
   307   shows "indep_sets (\<lambda>i. sigma_sets (space M) (F i)) I"
   308 proof -
   309   from indep_sets_dynkin[OF indep]
   310   show ?thesis
   311   proof (rule indep_sets_mono_sets, subst sigma_eq_dynkin, simp_all add: stable)
   312     fix i assume "i \<in> I"
   313     with indep have "F i \<subseteq> events" by (auto simp: indep_sets_def)
   314     with sets_into_space show "F i \<subseteq> Pow (space M)" by auto
   315   qed
   316 qed
   317 
   318 lemma (in prob_space) indep_sets_sigma_sets_iff:
   319   assumes "\<And>i. i \<in> I \<Longrightarrow> Int_stable (F i)"
   320   shows "indep_sets (\<lambda>i. sigma_sets (space M) (F i)) I \<longleftrightarrow> indep_sets F I"
   321 proof
   322   assume "indep_sets F I" then show "indep_sets (\<lambda>i. sigma_sets (space M) (F i)) I"
   323     by (rule indep_sets_sigma) fact
   324 next
   325   assume "indep_sets (\<lambda>i. sigma_sets (space M) (F i)) I" then show "indep_sets F I"
   326     by (rule indep_sets_mono_sets) (intro subsetI sigma_sets.Basic)
   327 qed
   328 
   329 lemma (in prob_space) indep_sets2_eq:
   330   "indep_set A B \<longleftrightarrow> A \<subseteq> events \<and> B \<subseteq> events \<and> (\<forall>a\<in>A. \<forall>b\<in>B. prob (a \<inter> b) = prob a * prob b)"
   331   unfolding indep_set_def
   332 proof (intro iffI ballI conjI)
   333   assume indep: "indep_sets (bool_case A B) UNIV"
   334   { fix a b assume "a \<in> A" "b \<in> B"
   335     with indep_setsD[OF indep, of UNIV "bool_case a b"]
   336     show "prob (a \<inter> b) = prob a * prob b"
   337       unfolding UNIV_bool by (simp add: ac_simps) }
   338   from indep show "A \<subseteq> events" "B \<subseteq> events"
   339     unfolding indep_sets_def UNIV_bool by auto
   340 next
   341   assume *: "A \<subseteq> events \<and> B \<subseteq> events \<and> (\<forall>a\<in>A. \<forall>b\<in>B. prob (a \<inter> b) = prob a * prob b)"
   342   show "indep_sets (bool_case A B) UNIV"
   343   proof (rule indep_setsI)
   344     fix i show "(case i of True \<Rightarrow> A | False \<Rightarrow> B) \<subseteq> events"
   345       using * by (auto split: bool.split)
   346   next
   347     fix J X assume "J \<noteq> {}" "J \<subseteq> UNIV" and X: "\<forall>j\<in>J. X j \<in> (case j of True \<Rightarrow> A | False \<Rightarrow> B)"
   348     then have "J = {True} \<or> J = {False} \<or> J = {True,False}"
   349       by (auto simp: UNIV_bool)
   350     then show "prob (\<Inter>j\<in>J. X j) = (\<Prod>j\<in>J. prob (X j))"
   351       using X * by auto
   352   qed
   353 qed
   354 
   355 lemma (in prob_space) indep_set_sigma_sets:
   356   assumes "indep_set A B"
   357   assumes A: "Int_stable A" and B: "Int_stable B"
   358   shows "indep_set (sigma_sets (space M) A) (sigma_sets (space M) B)"
   359 proof -
   360   have "indep_sets (\<lambda>i. sigma_sets (space M) (case i of True \<Rightarrow> A | False \<Rightarrow> B)) UNIV"
   361   proof (rule indep_sets_sigma)
   362     show "indep_sets (bool_case A B) UNIV"
   363       by (rule `indep_set A B`[unfolded indep_set_def])
   364     fix i show "Int_stable (case i of True \<Rightarrow> A | False \<Rightarrow> B)"
   365       using A B by (cases i) auto
   366   qed
   367   then show ?thesis
   368     unfolding indep_set_def
   369     by (rule indep_sets_mono_sets) (auto split: bool.split)
   370 qed
   371 
   372 lemma (in prob_space) indep_sets_collect_sigma:
   373   fixes I :: "'j \<Rightarrow> 'i set" and J :: "'j set" and E :: "'i \<Rightarrow> 'a set set"
   374   assumes indep: "indep_sets E (\<Union>j\<in>J. I j)"
   375   assumes Int_stable: "\<And>i j. j \<in> J \<Longrightarrow> i \<in> I j \<Longrightarrow> Int_stable (E i)"
   376   assumes disjoint: "disjoint_family_on I J"
   377   shows "indep_sets (\<lambda>j. sigma_sets (space M) (\<Union>i\<in>I j. E i)) J"
   378 proof -
   379   let ?E = "\<lambda>j. {\<Inter>k\<in>K. E' k| E' K. finite K \<and> K \<noteq> {} \<and> K \<subseteq> I j \<and> (\<forall>k\<in>K. E' k \<in> E k) }"
   380 
   381   from indep have E: "\<And>j i. j \<in> J \<Longrightarrow> i \<in> I j \<Longrightarrow> E i \<subseteq> events"
   382     unfolding indep_sets_def by auto
   383   { fix j
   384     let ?S = "sigma_sets (space M) (\<Union>i\<in>I j. E i)"
   385     assume "j \<in> J"
   386     from E[OF this] interpret S: sigma_algebra "space M" ?S
   387       using sets_into_space[of _ M] by (intro sigma_algebra_sigma_sets) auto
   388 
   389     have "sigma_sets (space M) (\<Union>i\<in>I j. E i) = sigma_sets (space M) (?E j)"
   390     proof (rule sigma_sets_eqI)
   391       fix A assume "A \<in> (\<Union>i\<in>I j. E i)"
   392       then guess i ..
   393       then show "A \<in> sigma_sets (space M) (?E j)"
   394         by (auto intro!: sigma_sets.intros(2-) exI[of _ "{i}"] exI[of _ "\<lambda>i. A"])
   395     next
   396       fix A assume "A \<in> ?E j"
   397       then obtain E' K where "finite K" "K \<noteq> {}" "K \<subseteq> I j" "\<And>k. k \<in> K \<Longrightarrow> E' k \<in> E k"
   398         and A: "A = (\<Inter>k\<in>K. E' k)"
   399         by auto
   400       then have "A \<in> ?S" unfolding A
   401         by (safe intro!: S.finite_INT) auto
   402       then show "A \<in> sigma_sets (space M) (\<Union>i\<in>I j. E i)"
   403         by simp
   404     qed }
   405   moreover have "indep_sets (\<lambda>j. sigma_sets (space M) (?E j)) J"
   406   proof (rule indep_sets_sigma)
   407     show "indep_sets ?E J"
   408     proof (intro indep_setsI)
   409       fix j assume "j \<in> J" with E show "?E j \<subseteq> events" by (force  intro!: finite_INT)
   410     next
   411       fix K A assume K: "K \<noteq> {}" "K \<subseteq> J" "finite K"
   412         and "\<forall>j\<in>K. A j \<in> ?E j"
   413       then have "\<forall>j\<in>K. \<exists>E' L. A j = (\<Inter>l\<in>L. E' l) \<and> finite L \<and> L \<noteq> {} \<and> L \<subseteq> I j \<and> (\<forall>l\<in>L. E' l \<in> E l)"
   414         by simp
   415       from bchoice[OF this] guess E' ..
   416       from bchoice[OF this] obtain L
   417         where A: "\<And>j. j\<in>K \<Longrightarrow> A j = (\<Inter>l\<in>L j. E' j l)"
   418         and L: "\<And>j. j\<in>K \<Longrightarrow> finite (L j)" "\<And>j. j\<in>K \<Longrightarrow> L j \<noteq> {}" "\<And>j. j\<in>K \<Longrightarrow> L j \<subseteq> I j"
   419         and E': "\<And>j l. j\<in>K \<Longrightarrow> l \<in> L j \<Longrightarrow> E' j l \<in> E l"
   420         by auto
   421 
   422       { fix k l j assume "k \<in> K" "j \<in> K" "l \<in> L j" "l \<in> L k"
   423         have "k = j"
   424         proof (rule ccontr)
   425           assume "k \<noteq> j"
   426           with disjoint `K \<subseteq> J` `k \<in> K` `j \<in> K` have "I k \<inter> I j = {}"
   427             unfolding disjoint_family_on_def by auto
   428           with L(2,3)[OF `j \<in> K`] L(2,3)[OF `k \<in> K`]
   429           show False using `l \<in> L k` `l \<in> L j` by auto
   430         qed }
   431       note L_inj = this
   432 
   433       def k \<equiv> "\<lambda>l. (SOME k. k \<in> K \<and> l \<in> L k)"
   434       { fix x j l assume *: "j \<in> K" "l \<in> L j"
   435         have "k l = j" unfolding k_def
   436         proof (rule some_equality)
   437           fix k assume "k \<in> K \<and> l \<in> L k"
   438           with * L_inj show "k = j" by auto
   439         qed (insert *, simp) }
   440       note k_simp[simp] = this
   441       let ?E' = "\<lambda>l. E' (k l) l"
   442       have "prob (\<Inter>j\<in>K. A j) = prob (\<Inter>l\<in>(\<Union>k\<in>K. L k). ?E' l)"
   443         by (auto simp: A intro!: arg_cong[where f=prob])
   444       also have "\<dots> = (\<Prod>l\<in>(\<Union>k\<in>K. L k). prob (?E' l))"
   445         using L K E' by (intro indep_setsD[OF indep]) (simp_all add: UN_mono)
   446       also have "\<dots> = (\<Prod>j\<in>K. \<Prod>l\<in>L j. prob (E' j l))"
   447         using K L L_inj by (subst setprod_UN_disjoint) auto
   448       also have "\<dots> = (\<Prod>j\<in>K. prob (A j))"
   449         using K L E' by (auto simp add: A intro!: setprod_cong indep_setsD[OF indep, symmetric]) blast
   450       finally show "prob (\<Inter>j\<in>K. A j) = (\<Prod>j\<in>K. prob (A j))" .
   451     qed
   452   next
   453     fix j assume "j \<in> J"
   454     show "Int_stable (?E j)"
   455     proof (rule Int_stableI)
   456       fix a assume "a \<in> ?E j" then obtain Ka Ea
   457         where a: "a = (\<Inter>k\<in>Ka. Ea k)" "finite Ka" "Ka \<noteq> {}" "Ka \<subseteq> I j" "\<And>k. k\<in>Ka \<Longrightarrow> Ea k \<in> E k" by auto
   458       fix b assume "b \<in> ?E j" then obtain Kb Eb
   459         where b: "b = (\<Inter>k\<in>Kb. Eb k)" "finite Kb" "Kb \<noteq> {}" "Kb \<subseteq> I j" "\<And>k. k\<in>Kb \<Longrightarrow> Eb k \<in> E k" by auto
   460       let ?A = "\<lambda>k. (if k \<in> Ka \<inter> Kb then Ea k \<inter> Eb k else if k \<in> Kb then Eb k else if k \<in> Ka then Ea k else {})"
   461       have "a \<inter> b = INTER (Ka \<union> Kb) ?A"
   462         by (simp add: a b set_eq_iff) auto
   463       with a b `j \<in> J` Int_stableD[OF Int_stable] show "a \<inter> b \<in> ?E j"
   464         by (intro CollectI exI[of _ "Ka \<union> Kb"] exI[of _ ?A]) auto
   465     qed
   466   qed
   467   ultimately show ?thesis
   468     by (simp cong: indep_sets_cong)
   469 qed
   470 
   471 definition (in prob_space) terminal_events where
   472   "terminal_events A = (\<Inter>n. sigma_sets (space M) (UNION {n..} A))"
   473 
   474 lemma (in prob_space) terminal_events_sets:
   475   assumes A: "\<And>i. A i \<subseteq> events"
   476   assumes "\<And>i::nat. sigma_algebra (space M) (A i)"
   477   assumes X: "X \<in> terminal_events A"
   478   shows "X \<in> events"
   479 proof -
   480   let ?A = "(\<Inter>n. sigma_sets (space M) (UNION {n..} A))"
   481   interpret A: sigma_algebra "space M" "A i" for i by fact
   482   from X have "\<And>n. X \<in> sigma_sets (space M) (UNION {n..} A)" by (auto simp: terminal_events_def)
   483   from this[of 0] have "X \<in> sigma_sets (space M) (UNION UNIV A)" by simp
   484   then show "X \<in> events"
   485     by induct (insert A, auto)
   486 qed
   487 
   488 lemma (in prob_space) sigma_algebra_terminal_events:
   489   assumes "\<And>i::nat. sigma_algebra (space M) (A i)"
   490   shows "sigma_algebra (space M) (terminal_events A)"
   491   unfolding terminal_events_def
   492 proof (simp add: sigma_algebra_iff2, safe)
   493   let ?A = "(\<Inter>n. sigma_sets (space M) (UNION {n..} A))"
   494   interpret A: sigma_algebra "space M" "A i" for i by fact
   495   { fix X x assume "X \<in> ?A" "x \<in> X"
   496     then have "\<And>n. X \<in> sigma_sets (space M) (UNION {n..} A)" by auto
   497     from this[of 0] have "X \<in> sigma_sets (space M) (UNION UNIV A)" by simp
   498     then have "X \<subseteq> space M"
   499       by induct (insert A.sets_into_space, auto)
   500     with `x \<in> X` show "x \<in> space M" by auto }
   501   { fix F :: "nat \<Rightarrow> 'a set" and n assume "range F \<subseteq> ?A"
   502     then show "(UNION UNIV F) \<in> sigma_sets (space M) (UNION {n..} A)"
   503       by (intro sigma_sets.Union) auto }
   504 qed (auto intro!: sigma_sets.Compl sigma_sets.Empty)
   505 
   506 lemma (in prob_space) kolmogorov_0_1_law:
   507   fixes A :: "nat \<Rightarrow> 'a set set"
   508   assumes A: "\<And>i. A i \<subseteq> events"
   509   assumes "\<And>i::nat. sigma_algebra (space M) (A i)"
   510   assumes indep: "indep_sets A UNIV"
   511   and X: "X \<in> terminal_events A"
   512   shows "prob X = 0 \<or> prob X = 1"
   513 proof -
   514   let ?D = "{D \<in> events. prob (X \<inter> D) = prob X * prob D}"
   515   interpret A: sigma_algebra "space M" "A i" for i by fact
   516   interpret T: sigma_algebra "space M" "terminal_events A"
   517     by (rule sigma_algebra_terminal_events) fact
   518   have "X \<subseteq> space M" using T.space_closed X by auto
   519 
   520   have X_in: "X \<in> events"
   521     by (rule terminal_events_sets) fact+
   522 
   523   interpret D: dynkin_system "space M" ?D
   524   proof (rule dynkin_systemI)
   525     fix D assume "D \<in> ?D" then show "D \<subseteq> space M"
   526       using sets_into_space by auto
   527   next
   528     show "space M \<in> ?D"
   529       using prob_space `X \<subseteq> space M` by (simp add: Int_absorb2)
   530   next
   531     fix A assume A: "A \<in> ?D"
   532     have "prob (X \<inter> (space M - A)) = prob (X - (X \<inter> A))"
   533       using `X \<subseteq> space M` by (auto intro!: arg_cong[where f=prob])
   534     also have "\<dots> = prob X - prob (X \<inter> A)"
   535       using X_in A by (intro finite_measure_Diff) auto
   536     also have "\<dots> = prob X * prob (space M) - prob X * prob A"
   537       using A prob_space by auto
   538     also have "\<dots> = prob X * prob (space M - A)"
   539       using X_in A sets_into_space
   540       by (subst finite_measure_Diff) (auto simp: field_simps)
   541     finally show "space M - A \<in> ?D"
   542       using A `X \<subseteq> space M` by auto
   543   next
   544     fix F :: "nat \<Rightarrow> 'a set" assume dis: "disjoint_family F" and "range F \<subseteq> ?D"
   545     then have F: "range F \<subseteq> events" "\<And>i. prob (X \<inter> F i) = prob X * prob (F i)"
   546       by auto
   547     have "(\<lambda>i. prob (X \<inter> F i)) sums prob (\<Union>i. X \<inter> F i)"
   548     proof (rule finite_measure_UNION)
   549       show "range (\<lambda>i. X \<inter> F i) \<subseteq> events"
   550         using F X_in by auto
   551       show "disjoint_family (\<lambda>i. X \<inter> F i)"
   552         using dis by (rule disjoint_family_on_bisimulation) auto
   553     qed
   554     with F have "(\<lambda>i. prob X * prob (F i)) sums prob (X \<inter> (\<Union>i. F i))"
   555       by simp
   556     moreover have "(\<lambda>i. prob X * prob (F i)) sums (prob X * prob (\<Union>i. F i))"
   557       by (intro sums_mult finite_measure_UNION F dis)
   558     ultimately have "prob (X \<inter> (\<Union>i. F i)) = prob X * prob (\<Union>i. F i)"
   559       by (auto dest!: sums_unique)
   560     with F show "(\<Union>i. F i) \<in> ?D"
   561       by auto
   562   qed
   563 
   564   { fix n
   565     have "indep_sets (\<lambda>b. sigma_sets (space M) (\<Union>m\<in>bool_case {..n} {Suc n..} b. A m)) UNIV"
   566     proof (rule indep_sets_collect_sigma)
   567       have *: "(\<Union>b. case b of True \<Rightarrow> {..n} | False \<Rightarrow> {Suc n..}) = UNIV" (is "?U = _")
   568         by (simp split: bool.split add: set_eq_iff) (metis not_less_eq_eq)
   569       with indep show "indep_sets A ?U" by simp
   570       show "disjoint_family (bool_case {..n} {Suc n..})"
   571         unfolding disjoint_family_on_def by (auto split: bool.split)
   572       fix m
   573       show "Int_stable (A m)"
   574         unfolding Int_stable_def using A.Int by auto
   575     qed
   576     also have "(\<lambda>b. sigma_sets (space M) (\<Union>m\<in>bool_case {..n} {Suc n..} b. A m)) =
   577       bool_case (sigma_sets (space M) (\<Union>m\<in>{..n}. A m)) (sigma_sets (space M) (\<Union>m\<in>{Suc n..}. A m))"
   578       by (auto intro!: ext split: bool.split)
   579     finally have indep: "indep_set (sigma_sets (space M) (\<Union>m\<in>{..n}. A m)) (sigma_sets (space M) (\<Union>m\<in>{Suc n..}. A m))"
   580       unfolding indep_set_def by simp
   581 
   582     have "sigma_sets (space M) (\<Union>m\<in>{..n}. A m) \<subseteq> ?D"
   583     proof (simp add: subset_eq, rule)
   584       fix D assume D: "D \<in> sigma_sets (space M) (\<Union>m\<in>{..n}. A m)"
   585       have "X \<in> sigma_sets (space M) (\<Union>m\<in>{Suc n..}. A m)"
   586         using X unfolding terminal_events_def by simp
   587       from indep_setD[OF indep D this] indep_setD_ev1[OF indep] D
   588       show "D \<in> events \<and> prob (X \<inter> D) = prob X * prob D"
   589         by (auto simp add: ac_simps)
   590     qed }
   591   then have "(\<Union>n. sigma_sets (space M) (\<Union>m\<in>{..n}. A m)) \<subseteq> ?D" (is "?A \<subseteq> _")
   592     by auto
   593 
   594   note `X \<in> terminal_events A`
   595   also {
   596     have "\<And>n. sigma_sets (space M) (\<Union>i\<in>{n..}. A i) \<subseteq> sigma_sets (space M) ?A"
   597       by (intro sigma_sets_subseteq UN_mono) auto
   598    then have "terminal_events A \<subseteq> sigma_sets (space M) ?A"
   599       unfolding terminal_events_def by auto }
   600   also have "sigma_sets (space M) ?A = dynkin (space M) ?A"
   601   proof (rule sigma_eq_dynkin)
   602     { fix B n assume "B \<in> sigma_sets (space M) (\<Union>m\<in>{..n}. A m)"
   603       then have "B \<subseteq> space M"
   604         by induct (insert A sets_into_space[of _ M], auto) }
   605     then show "?A \<subseteq> Pow (space M)" by auto
   606     show "Int_stable ?A"
   607     proof (rule Int_stableI)
   608       fix a assume "a \<in> ?A" then guess n .. note a = this
   609       fix b assume "b \<in> ?A" then guess m .. note b = this
   610       interpret Amn: sigma_algebra "space M" "sigma_sets (space M) (\<Union>i\<in>{..max m n}. A i)"
   611         using A sets_into_space[of _ M] by (intro sigma_algebra_sigma_sets) auto
   612       have "sigma_sets (space M) (\<Union>i\<in>{..n}. A i) \<subseteq> sigma_sets (space M) (\<Union>i\<in>{..max m n}. A i)"
   613         by (intro sigma_sets_subseteq UN_mono) auto
   614       with a have "a \<in> sigma_sets (space M) (\<Union>i\<in>{..max m n}. A i)" by auto
   615       moreover
   616       have "sigma_sets (space M) (\<Union>i\<in>{..m}. A i) \<subseteq> sigma_sets (space M) (\<Union>i\<in>{..max m n}. A i)"
   617         by (intro sigma_sets_subseteq UN_mono) auto
   618       with b have "b \<in> sigma_sets (space M) (\<Union>i\<in>{..max m n}. A i)" by auto
   619       ultimately have "a \<inter> b \<in> sigma_sets (space M) (\<Union>i\<in>{..max m n}. A i)"
   620         using Amn.Int[of a b] by simp
   621       then show "a \<inter> b \<in> (\<Union>n. sigma_sets (space M) (\<Union>i\<in>{..n}. A i))" by auto
   622     qed
   623   qed
   624   also have "dynkin (space M) ?A \<subseteq> ?D"
   625     using `?A \<subseteq> ?D` by (auto intro!: D.dynkin_subset)
   626   finally show ?thesis by auto
   627 qed
   628 
   629 lemma (in prob_space) borel_0_1_law:
   630   fixes F :: "nat \<Rightarrow> 'a set"
   631   assumes F: "range F \<subseteq> events" "indep_events F UNIV"
   632   shows "prob (\<Inter>n. \<Union>m\<in>{n..}. F m) = 0 \<or> prob (\<Inter>n. \<Union>m\<in>{n..}. F m) = 1"
   633 proof (rule kolmogorov_0_1_law[of "\<lambda>i. sigma_sets (space M) { F i }"])
   634   show "\<And>i. sigma_sets (space M) {F i} \<subseteq> events"
   635     using F(1) sets_into_space
   636     by (subst sigma_sets_singleton) auto
   637   { fix i show "sigma_algebra (space M) (sigma_sets (space M) {F i})"
   638       using sigma_algebra_sigma_sets[of "{F i}" "space M"] F sets_into_space
   639       by auto }
   640   show "indep_sets (\<lambda>i. sigma_sets (space M) {F i}) UNIV"
   641   proof (rule indep_sets_sigma)
   642     show "indep_sets (\<lambda>i. {F i}) UNIV"
   643       unfolding indep_sets_singleton_iff_indep_events by fact
   644     fix i show "Int_stable {F i}"
   645       unfolding Int_stable_def by simp
   646   qed
   647   let ?Q = "\<lambda>n. \<Union>i\<in>{n..}. F i"
   648   show "(\<Inter>n. \<Union>m\<in>{n..}. F m) \<in> terminal_events (\<lambda>i. sigma_sets (space M) {F i})"
   649     unfolding terminal_events_def
   650   proof
   651     fix j
   652     interpret S: sigma_algebra "space M" "sigma_sets (space M) (\<Union>i\<in>{j..}. sigma_sets (space M) {F i})"
   653       using order_trans[OF F(1) space_closed]
   654       by (intro sigma_algebra_sigma_sets) (simp add: sigma_sets_singleton subset_eq)
   655     have "(\<Inter>n. ?Q n) = (\<Inter>n\<in>{j..}. ?Q n)"
   656       by (intro decseq_SucI INT_decseq_offset UN_mono) auto
   657     also have "\<dots> \<in> sigma_sets (space M) (\<Union>i\<in>{j..}. sigma_sets (space M) {F i})"
   658       using order_trans[OF F(1) space_closed]
   659       by (safe intro!: S.countable_INT S.countable_UN)
   660          (auto simp: sigma_sets_singleton intro!: sigma_sets.Basic bexI)
   661     finally show "(\<Inter>n. ?Q n) \<in> sigma_sets (space M) (\<Union>i\<in>{j..}. sigma_sets (space M) {F i})"
   662       by simp
   663   qed
   664 qed
   665 
   666 lemma (in prob_space) indep_sets_finite:
   667   assumes I: "I \<noteq> {}" "finite I"
   668     and F: "\<And>i. i \<in> I \<Longrightarrow> F i \<subseteq> events" "\<And>i. i \<in> I \<Longrightarrow> space M \<in> F i"
   669   shows "indep_sets F I \<longleftrightarrow> (\<forall>A\<in>Pi I F. prob (\<Inter>j\<in>I. A j) = (\<Prod>j\<in>I. prob (A j)))"
   670 proof
   671   assume *: "indep_sets F I"
   672   from I show "\<forall>A\<in>Pi I F. prob (\<Inter>j\<in>I. A j) = (\<Prod>j\<in>I. prob (A j))"
   673     by (intro indep_setsD[OF *] ballI) auto
   674 next
   675   assume indep: "\<forall>A\<in>Pi I F. prob (\<Inter>j\<in>I. A j) = (\<Prod>j\<in>I. prob (A j))"
   676   show "indep_sets F I"
   677   proof (rule indep_setsI[OF F(1)])
   678     fix A J assume J: "J \<noteq> {}" "J \<subseteq> I" "finite J"
   679     assume A: "\<forall>j\<in>J. A j \<in> F j"
   680     let ?A = "\<lambda>j. if j \<in> J then A j else space M"
   681     have "prob (\<Inter>j\<in>I. ?A j) = prob (\<Inter>j\<in>J. A j)"
   682       using subset_trans[OF F(1) space_closed] J A
   683       by (auto intro!: arg_cong[where f=prob] split: split_if_asm) blast
   684     also
   685     from A F have "(\<lambda>j. if j \<in> J then A j else space M) \<in> Pi I F" (is "?A \<in> _")
   686       by (auto split: split_if_asm)
   687     with indep have "prob (\<Inter>j\<in>I. ?A j) = (\<Prod>j\<in>I. prob (?A j))"
   688       by auto
   689     also have "\<dots> = (\<Prod>j\<in>J. prob (A j))"
   690       unfolding if_distrib setprod.If_cases[OF `finite I`]
   691       using prob_space `J \<subseteq> I` by (simp add: Int_absorb1 setprod_1)
   692     finally show "prob (\<Inter>j\<in>J. A j) = (\<Prod>j\<in>J. prob (A j))" ..
   693   qed
   694 qed
   695 
   696 lemma (in prob_space) indep_vars_finite:
   697   fixes I :: "'i set"
   698   assumes I: "I \<noteq> {}" "finite I"
   699     and M': "\<And>i. i \<in> I \<Longrightarrow> sets (M' i) = sigma_sets (space (M' i)) (E i)"
   700     and rv: "\<And>i. i \<in> I \<Longrightarrow> random_variable (M' i) (X i)"
   701     and Int_stable: "\<And>i. i \<in> I \<Longrightarrow> Int_stable (E i)"
   702     and space: "\<And>i. i \<in> I \<Longrightarrow> space (M' i) \<in> E i" and closed: "\<And>i. i \<in> I \<Longrightarrow> E i \<subseteq> Pow (space (M' i))"
   703   shows "indep_vars M' X I \<longleftrightarrow>
   704     (\<forall>A\<in>(\<Pi> i\<in>I. E i). prob (\<Inter>j\<in>I. X j -` A j \<inter> space M) = (\<Prod>j\<in>I. prob (X j -` A j \<inter> space M)))"
   705 proof -
   706   from rv have X: "\<And>i. i \<in> I \<Longrightarrow> X i \<in> space M \<rightarrow> space (M' i)"
   707     unfolding measurable_def by simp
   708 
   709   { fix i assume "i\<in>I"
   710     from closed[OF `i \<in> I`]
   711     have "sigma_sets (space M) {X i -` A \<inter> space M |A. A \<in> sets (M' i)}
   712       = sigma_sets (space M) {X i -` A \<inter> space M |A. A \<in> E i}"
   713       unfolding sigma_sets_vimage_commute[OF X, OF `i \<in> I`, symmetric] M'[OF `i \<in> I`]
   714       by (subst sigma_sets_sigma_sets_eq) auto }
   715   note sigma_sets_X = this
   716 
   717   { fix i assume "i\<in>I"
   718     have "Int_stable {X i -` A \<inter> space M |A. A \<in> E i}"
   719     proof (rule Int_stableI)
   720       fix a assume "a \<in> {X i -` A \<inter> space M |A. A \<in> E i}"
   721       then obtain A where "a = X i -` A \<inter> space M" "A \<in> E i" by auto
   722       moreover
   723       fix b assume "b \<in> {X i -` A \<inter> space M |A. A \<in> E i}"
   724       then obtain B where "b = X i -` B \<inter> space M" "B \<in> E i" by auto
   725       moreover
   726       have "(X i -` A \<inter> space M) \<inter> (X i -` B \<inter> space M) = X i -` (A \<inter> B) \<inter> space M" by auto
   727       moreover note Int_stable[OF `i \<in> I`]
   728       ultimately
   729       show "a \<inter> b \<in> {X i -` A \<inter> space M |A. A \<in> E i}"
   730         by (auto simp del: vimage_Int intro!: exI[of _ "A \<inter> B"] dest: Int_stableD)
   731     qed }
   732   note indep_sets_X = indep_sets_sigma_sets_iff[OF this]
   733 
   734   { fix i assume "i \<in> I"
   735     { fix A assume "A \<in> E i"
   736       with M'[OF `i \<in> I`] have "A \<in> sets (M' i)" by auto
   737       moreover
   738       from rv[OF `i\<in>I`] have "X i \<in> measurable M (M' i)" by auto
   739       ultimately
   740       have "X i -` A \<inter> space M \<in> sets M" by (auto intro: measurable_sets) }
   741     with X[OF `i\<in>I`] space[OF `i\<in>I`]
   742     have "{X i -` A \<inter> space M |A. A \<in> E i} \<subseteq> events"
   743       "space M \<in> {X i -` A \<inter> space M |A. A \<in> E i}"
   744       by (auto intro!: exI[of _ "space (M' i)"]) }
   745   note indep_sets_finite_X = indep_sets_finite[OF I this]
   746 
   747   have "(\<forall>A\<in>\<Pi> i\<in>I. {X i -` A \<inter> space M |A. A \<in> E i}. prob (INTER I A) = (\<Prod>j\<in>I. prob (A j))) =
   748     (\<forall>A\<in>\<Pi> i\<in>I. E i. prob ((\<Inter>j\<in>I. X j -` A j) \<inter> space M) = (\<Prod>x\<in>I. prob (X x -` A x \<inter> space M)))"
   749     (is "?L = ?R")
   750   proof safe
   751     fix A assume ?L and A: "A \<in> (\<Pi> i\<in>I. E i)"
   752     from `?L`[THEN bspec, of "\<lambda>i. X i -` A i \<inter> space M"] A `I \<noteq> {}`
   753     show "prob ((\<Inter>j\<in>I. X j -` A j) \<inter> space M) = (\<Prod>x\<in>I. prob (X x -` A x \<inter> space M))"
   754       by (auto simp add: Pi_iff)
   755   next
   756     fix A assume ?R and A: "A \<in> (\<Pi> i\<in>I. {X i -` A \<inter> space M |A. A \<in> E i})"
   757     from A have "\<forall>i\<in>I. \<exists>B. A i = X i -` B \<inter> space M \<and> B \<in> E i" by auto
   758     from bchoice[OF this] obtain B where B: "\<forall>i\<in>I. A i = X i -` B i \<inter> space M"
   759       "B \<in> (\<Pi> i\<in>I. E i)" by auto
   760     from `?R`[THEN bspec, OF B(2)] B(1) `I \<noteq> {}`
   761     show "prob (INTER I A) = (\<Prod>j\<in>I. prob (A j))"
   762       by simp
   763   qed
   764   then show ?thesis using `I \<noteq> {}`
   765     by (simp add: rv indep_vars_def indep_sets_X sigma_sets_X indep_sets_finite_X cong: indep_sets_cong)
   766 qed
   767 
   768 lemma (in prob_space) indep_vars_compose:
   769   assumes "indep_vars M' X I"
   770   assumes rv: "\<And>i. i \<in> I \<Longrightarrow> Y i \<in> measurable (M' i) (N i)"
   771   shows "indep_vars N (\<lambda>i. Y i \<circ> X i) I"
   772   unfolding indep_vars_def
   773 proof
   774   from rv `indep_vars M' X I`
   775   show "\<forall>i\<in>I. random_variable (N i) (Y i \<circ> X i)"
   776     by (auto simp: indep_vars_def)
   777 
   778   have "indep_sets (\<lambda>i. sigma_sets (space M) {X i -` A \<inter> space M |A. A \<in> sets (M' i)}) I"
   779     using `indep_vars M' X I` by (simp add: indep_vars_def)
   780   then show "indep_sets (\<lambda>i. sigma_sets (space M) {(Y i \<circ> X i) -` A \<inter> space M |A. A \<in> sets (N i)}) I"
   781   proof (rule indep_sets_mono_sets)
   782     fix i assume "i \<in> I"
   783     with `indep_vars M' X I` have X: "X i \<in> space M \<rightarrow> space (M' i)"
   784       unfolding indep_vars_def measurable_def by auto
   785     { fix A assume "A \<in> sets (N i)"
   786       then have "\<exists>B. (Y i \<circ> X i) -` A \<inter> space M = X i -` B \<inter> space M \<and> B \<in> sets (M' i)"
   787         by (intro exI[of _ "Y i -` A \<inter> space (M' i)"])
   788            (auto simp: vimage_compose intro!: measurable_sets rv `i \<in> I` funcset_mem[OF X]) }
   789     then show "sigma_sets (space M) {(Y i \<circ> X i) -` A \<inter> space M |A. A \<in> sets (N i)} \<subseteq>
   790       sigma_sets (space M) {X i -` A \<inter> space M |A. A \<in> sets (M' i)}"
   791       by (intro sigma_sets_subseteq) (auto simp: vimage_compose)
   792   qed
   793 qed
   794 
   795 lemma (in prob_space) indep_varsD_finite:
   796   assumes X: "indep_vars M' X I"
   797   assumes I: "I \<noteq> {}" "finite I" "\<And>i. i \<in> I \<Longrightarrow> A i \<in> sets (M' i)"
   798   shows "prob (\<Inter>i\<in>I. X i -` A i \<inter> space M) = (\<Prod>i\<in>I. prob (X i -` A i \<inter> space M))"
   799 proof (rule indep_setsD)
   800   show "indep_sets (\<lambda>i. sigma_sets (space M) {X i -` A \<inter> space M |A. A \<in> sets (M' i)}) I"
   801     using X by (auto simp: indep_vars_def)
   802   show "I \<subseteq> I" "I \<noteq> {}" "finite I" using I by auto
   803   show "\<forall>i\<in>I. X i -` A i \<inter> space M \<in> sigma_sets (space M) {X i -` A \<inter> space M |A. A \<in> sets (M' i)}"
   804     using I by auto
   805 qed
   806 
   807 lemma (in prob_space) indep_varsD:
   808   assumes X: "indep_vars M' X I"
   809   assumes I: "J \<noteq> {}" "finite J" "J \<subseteq> I" "\<And>i. i \<in> J \<Longrightarrow> A i \<in> sets (M' i)"
   810   shows "prob (\<Inter>i\<in>J. X i -` A i \<inter> space M) = (\<Prod>i\<in>J. prob (X i -` A i \<inter> space M))"
   811 proof (rule indep_setsD)
   812   show "indep_sets (\<lambda>i. sigma_sets (space M) {X i -` A \<inter> space M |A. A \<in> sets (M' i)}) I"
   813     using X by (auto simp: indep_vars_def)
   814   show "\<forall>i\<in>J. X i -` A i \<inter> space M \<in> sigma_sets (space M) {X i -` A \<inter> space M |A. A \<in> sets (M' i)}"
   815     using I by auto
   816 qed fact+
   817 
   818 lemma prod_algebra_cong:
   819   assumes "I = J" and sets: "(\<And>i. i \<in> I \<Longrightarrow> sets (M i) = sets (N i))"
   820   shows "prod_algebra I M = prod_algebra J N"
   821 proof -
   822   have space: "\<And>i. i \<in> I \<Longrightarrow> space (M i) = space (N i)"
   823     using sets_eq_imp_space_eq[OF sets] by auto
   824   with sets show ?thesis unfolding `I = J`
   825     by (intro antisym prod_algebra_mono) auto
   826 qed
   827 
   828 lemma space_in_prod_algebra:
   829   "(\<Pi>\<^isub>E i\<in>I. space (M i)) \<in> prod_algebra I M"
   830 proof cases
   831   assume "I = {}" then show ?thesis
   832     by (auto simp add: prod_algebra_def image_iff prod_emb_def)
   833 next
   834   assume "I \<noteq> {}"
   835   then obtain i where "i \<in> I" by auto
   836   then have "(\<Pi>\<^isub>E i\<in>I. space (M i)) = prod_emb I M {i} (\<Pi>\<^isub>E i\<in>{i}. space (M i))"
   837     by (auto simp: prod_emb_def Pi_iff)
   838   also have "\<dots> \<in> prod_algebra I M"
   839     using `i \<in> I` by (intro prod_algebraI) auto
   840   finally show ?thesis .
   841 qed
   842 
   843 lemma (in prob_space) indep_vars_iff_distr_eq_PiM:
   844   fixes I :: "'i set" and X :: "'i \<Rightarrow> 'a \<Rightarrow> 'b"
   845   assumes "I \<noteq> {}"
   846   assumes rv: "\<And>i. random_variable (M' i) (X i)"
   847   shows "indep_vars M' X I \<longleftrightarrow>
   848     distr M (\<Pi>\<^isub>M i\<in>I. M' i) (\<lambda>x. \<lambda>i\<in>I. X i x) = (\<Pi>\<^isub>M i\<in>I. distr M (M' i) (X i))"
   849 proof -
   850   let ?P = "\<Pi>\<^isub>M i\<in>I. M' i"
   851   let ?X = "\<lambda>x. \<lambda>i\<in>I. X i x"
   852   let ?D = "distr M ?P ?X"
   853   have X: "random_variable ?P ?X" by (intro measurable_restrict rv)
   854   interpret D: prob_space ?D by (intro prob_space_distr X)
   855 
   856   let ?D' = "\<lambda>i. distr M (M' i) (X i)"
   857   let ?P' = "\<Pi>\<^isub>M i\<in>I. distr M (M' i) (X i)"
   858   interpret D': prob_space "?D' i" for i by (intro prob_space_distr rv)
   859   interpret P: product_prob_space ?D' I ..
   860     
   861   show ?thesis
   862   proof
   863     assume "indep_vars M' X I"
   864     show "?D = ?P'"
   865     proof (rule measure_eqI_generator_eq)
   866       show "Int_stable (prod_algebra I M')"
   867         by (rule Int_stable_prod_algebra)
   868       show "prod_algebra I M' \<subseteq> Pow (space ?P)"
   869         using prod_algebra_sets_into_space by (simp add: space_PiM)
   870       show "sets ?D = sigma_sets (space ?P) (prod_algebra I M')"
   871         by (simp add: sets_PiM space_PiM)
   872       show "sets ?P' = sigma_sets (space ?P) (prod_algebra I M')"
   873         by (simp add: sets_PiM space_PiM cong: prod_algebra_cong)
   874       let ?A = "\<lambda>i. \<Pi>\<^isub>E i\<in>I. space (M' i)"
   875       show "range ?A \<subseteq> prod_algebra I M'" "incseq ?A" "(\<Union>i. ?A i) = space (Pi\<^isub>M I M')"
   876         by (auto simp: space_PiM intro!: space_in_prod_algebra cong: prod_algebra_cong)
   877       { fix i show "emeasure ?D (\<Pi>\<^isub>E i\<in>I. space (M' i)) \<noteq> \<infinity>" by auto }
   878     next
   879       fix E assume E: "E \<in> prod_algebra I M'"
   880       from prod_algebraE[OF E] guess J Y . note J = this
   881 
   882       from E have "E \<in> sets ?P" by (auto simp: sets_PiM)
   883       then have "emeasure ?D E = emeasure M (?X -` E \<inter> space M)"
   884         by (simp add: emeasure_distr X)
   885       also have "?X -` E \<inter> space M = (\<Inter>i\<in>J. X i -` Y i \<inter> space M)"
   886         using J `I \<noteq> {}` measurable_space[OF rv] by (auto simp: prod_emb_def Pi_iff split: split_if_asm)
   887       also have "emeasure M (\<Inter>i\<in>J. X i -` Y i \<inter> space M) = (\<Prod> i\<in>J. emeasure M (X i -` Y i \<inter> space M))"
   888         using `indep_vars M' X I` J `I \<noteq> {}` using indep_varsD[of M' X I J]
   889         by (auto simp: emeasure_eq_measure setprod_ereal)
   890       also have "\<dots> = (\<Prod> i\<in>J. emeasure (?D' i) (Y i))"
   891         using rv J by (simp add: emeasure_distr)
   892       also have "\<dots> = emeasure ?P' E"
   893         using P.emeasure_PiM_emb[of J Y] J by (simp add: prod_emb_def)
   894       finally show "emeasure ?D E = emeasure ?P' E" .
   895     qed
   896   next
   897     assume "?D = ?P'"
   898     show "indep_vars M' X I" unfolding indep_vars_def
   899     proof (intro conjI indep_setsI ballI rv)
   900       fix i show "sigma_sets (space M) {X i -` A \<inter> space M |A. A \<in> sets (M' i)} \<subseteq> events"
   901         by (auto intro!: sigma_sets_subset measurable_sets rv)
   902     next
   903       fix J Y' assume J: "J \<noteq> {}" "J \<subseteq> I" "finite J"
   904       assume Y': "\<forall>j\<in>J. Y' j \<in> sigma_sets (space M) {X j -` A \<inter> space M |A. A \<in> sets (M' j)}"
   905       have "\<forall>j\<in>J. \<exists>Y. Y' j = X j -` Y \<inter> space M \<and> Y \<in> sets (M' j)"
   906       proof
   907         fix j assume "j \<in> J"
   908         from Y'[rule_format, OF this] rv[of j]
   909         show "\<exists>Y. Y' j = X j -` Y \<inter> space M \<and> Y \<in> sets (M' j)"
   910           by (subst (asm) sigma_sets_vimage_commute[symmetric, of _ _ "space (M' j)"])
   911              (auto dest: measurable_space simp: sigma_sets_eq)
   912       qed
   913       from bchoice[OF this] obtain Y where
   914         Y: "\<And>j. j \<in> J \<Longrightarrow> Y' j = X j -` Y j \<inter> space M" "\<And>j. j \<in> J \<Longrightarrow> Y j \<in> sets (M' j)" by auto
   915       let ?E = "prod_emb I M' J (Pi\<^isub>E J Y)"
   916       from Y have "(\<Inter>j\<in>J. Y' j) = ?X -` ?E \<inter> space M"
   917         using J `I \<noteq> {}` measurable_space[OF rv] by (auto simp: prod_emb_def Pi_iff split: split_if_asm)
   918       then have "emeasure M (\<Inter>j\<in>J. Y' j) = emeasure M (?X -` ?E \<inter> space M)"
   919         by simp
   920       also have "\<dots> = emeasure ?D ?E"
   921         using Y  J by (intro emeasure_distr[symmetric] X sets_PiM_I) auto
   922       also have "\<dots> = emeasure ?P' ?E"
   923         using `?D = ?P'` by simp
   924       also have "\<dots> = (\<Prod> i\<in>J. emeasure (?D' i) (Y i))"
   925         using P.emeasure_PiM_emb[of J Y] J Y by (simp add: prod_emb_def)
   926       also have "\<dots> = (\<Prod> i\<in>J. emeasure M (Y' i))"
   927         using rv J Y by (simp add: emeasure_distr)
   928       finally have "emeasure M (\<Inter>j\<in>J. Y' j) = (\<Prod> i\<in>J. emeasure M (Y' i))" .
   929       then show "prob (\<Inter>j\<in>J. Y' j) = (\<Prod> i\<in>J. prob (Y' i))"
   930         by (auto simp: emeasure_eq_measure setprod_ereal)
   931     qed
   932   qed
   933 qed
   934 
   935 lemma (in prob_space) indep_varD:
   936   assumes indep: "indep_var Ma A Mb B"
   937   assumes sets: "Xa \<in> sets Ma" "Xb \<in> sets Mb"
   938   shows "prob ((\<lambda>x. (A x, B x)) -` (Xa \<times> Xb) \<inter> space M) =
   939     prob (A -` Xa \<inter> space M) * prob (B -` Xb \<inter> space M)"
   940 proof -
   941   have "prob ((\<lambda>x. (A x, B x)) -` (Xa \<times> Xb) \<inter> space M) =
   942     prob (\<Inter>i\<in>UNIV. (bool_case A B i -` bool_case Xa Xb i \<inter> space M))"
   943     by (auto intro!: arg_cong[where f=prob] simp: UNIV_bool)
   944   also have "\<dots> = (\<Prod>i\<in>UNIV. prob (bool_case A B i -` bool_case Xa Xb i \<inter> space M))"
   945     using indep unfolding indep_var_def
   946     by (rule indep_varsD) (auto split: bool.split intro: sets)
   947   also have "\<dots> = prob (A -` Xa \<inter> space M) * prob (B -` Xb \<inter> space M)"
   948     unfolding UNIV_bool by simp
   949   finally show ?thesis .
   950 qed
   951 
   952 lemma (in prob_space)
   953   assumes "indep_var S X T Y"
   954   shows indep_var_rv1: "random_variable S X"
   955     and indep_var_rv2: "random_variable T Y"
   956 proof -
   957   have "\<forall>i\<in>UNIV. random_variable (bool_case S T i) (bool_case X Y i)"
   958     using assms unfolding indep_var_def indep_vars_def by auto
   959   then show "random_variable S X" "random_variable T Y"
   960     unfolding UNIV_bool by auto
   961 qed
   962 
   963 lemma measurable_bool_case[simp, intro]:
   964   "(\<lambda>(x, y). bool_case x y) \<in> measurable (M \<Otimes>\<^isub>M N) (Pi\<^isub>M UNIV (bool_case M N))"
   965     (is "?f \<in> measurable ?B ?P")
   966 proof (rule measurable_PiM_single)
   967   show "?f \<in> space ?B \<rightarrow> (\<Pi>\<^isub>E i\<in>UNIV. space (bool_case M N i))"
   968     by (auto simp: space_pair_measure extensional_def split: bool.split)
   969   fix i A assume "A \<in> sets (case i of True \<Rightarrow> M | False \<Rightarrow> N)"
   970   moreover then have "{\<omega> \<in> space (M \<Otimes>\<^isub>M N). prod_case bool_case \<omega> i \<in> A}
   971     = (case i of True \<Rightarrow> A \<times> space N | False \<Rightarrow> space M \<times> A)" 
   972     by (auto simp: space_pair_measure split: bool.split dest!: sets_into_space)
   973   ultimately show "{\<omega> \<in> space (M \<Otimes>\<^isub>M N). prod_case bool_case \<omega> i \<in> A} \<in> sets ?B"
   974     by (auto split: bool.split)
   975 qed
   976 
   977 lemma borel_measurable_indicator':
   978   "A \<in> sets N \<Longrightarrow> f \<in> measurable M N \<Longrightarrow> (\<lambda>x. indicator A (f x)) \<in> borel_measurable M"
   979   using measurable_comp[OF _ borel_measurable_indicator, of f M N A] by (auto simp add: comp_def)
   980 
   981 lemma (in product_sigma_finite) distr_component:
   982   "distr (M i) (Pi\<^isub>M {i} M) (\<lambda>x. \<lambda>i\<in>{i}. x) = Pi\<^isub>M {i} M" (is "?D = ?P")
   983 proof (intro measure_eqI[symmetric])
   984   interpret I: finite_product_sigma_finite M "{i}" by default simp
   985 
   986   have eq: "\<And>x. x \<in> extensional {i} \<Longrightarrow> (\<lambda>j\<in>{i}. x i) = x"
   987     by (auto simp: extensional_def restrict_def)
   988 
   989   fix A assume A: "A \<in> sets ?P"
   990   then have "emeasure ?P A = (\<integral>\<^isup>+x. indicator A x \<partial>?P)" 
   991     by simp
   992   also have "\<dots> = (\<integral>\<^isup>+x. indicator ((\<lambda>x. \<lambda>i\<in>{i}. x) -` A \<inter> space (M i)) x \<partial>M i)" 
   993     apply (subst product_positive_integral_singleton[symmetric])
   994     apply (force intro!: measurable_restrict measurable_sets A)
   995     apply (auto intro!: positive_integral_cong simp: space_PiM indicator_def simp: eq)
   996     done
   997   also have "\<dots> = emeasure (M i) ((\<lambda>x. \<lambda>i\<in>{i}. x) -` A \<inter> space (M i))"
   998     by (force intro!: measurable_restrict measurable_sets A positive_integral_indicator)
   999   also have "\<dots> = emeasure ?D A"
  1000     using A by (auto intro!: emeasure_distr[symmetric] measurable_restrict) 
  1001   finally show "emeasure (Pi\<^isub>M {i} M) A = emeasure ?D A" .
  1002 qed simp
  1003 
  1004 lemma pair_measure_eqI:
  1005   assumes "sigma_finite_measure M1" "sigma_finite_measure M2"
  1006   assumes sets: "sets (M1 \<Otimes>\<^isub>M M2) = sets M"
  1007   assumes emeasure: "\<And>A B. A \<in> sets M1 \<Longrightarrow> B \<in> sets M2 \<Longrightarrow> emeasure M1 A * emeasure M2 B = emeasure M (A \<times> B)"
  1008   shows "M1 \<Otimes>\<^isub>M M2 = M"
  1009 proof -
  1010   interpret M1: sigma_finite_measure M1 by fact
  1011   interpret M2: sigma_finite_measure M2 by fact
  1012   interpret pair_sigma_finite M1 M2 by default
  1013   from sigma_finite_up_in_pair_measure_generator guess F :: "nat \<Rightarrow> ('a \<times> 'b) set" .. note F = this
  1014   let ?E = "{a \<times> b |a b. a \<in> sets M1 \<and> b \<in> sets M2}"
  1015   let ?P = "M1 \<Otimes>\<^isub>M M2"
  1016   show ?thesis
  1017   proof (rule measure_eqI_generator_eq[OF Int_stable_pair_measure_generator[of M1 M2]])
  1018     show "?E \<subseteq> Pow (space ?P)"
  1019       using space_closed[of M1] space_closed[of M2] by (auto simp: space_pair_measure)
  1020     show "sets ?P = sigma_sets (space ?P) ?E"
  1021       by (simp add: sets_pair_measure space_pair_measure)
  1022     then show "sets M = sigma_sets (space ?P) ?E"
  1023       using sets[symmetric] by simp
  1024   next
  1025     show "range F \<subseteq> ?E" "incseq F" "(\<Union>i. F i) = space ?P" "\<And>i. emeasure ?P (F i) \<noteq> \<infinity>"
  1026       using F by (auto simp: space_pair_measure)
  1027   next
  1028     fix X assume "X \<in> ?E"
  1029     then obtain A B where X[simp]: "X = A \<times> B" and A: "A \<in> sets M1" and B: "B \<in> sets M2" by auto
  1030     then have "emeasure ?P X = emeasure M1 A * emeasure M2 B"
  1031        by (simp add: emeasure_pair_measure_Times)
  1032     also have "\<dots> = emeasure M (A \<times> B)"
  1033       using A B emeasure by auto
  1034     finally show "emeasure ?P X = emeasure M X"
  1035       by simp
  1036   qed
  1037 qed
  1038 
  1039 lemma pair_measure_eq_distr_PiM:
  1040   fixes M1 :: "'a measure" and M2 :: "'a measure"
  1041   assumes "sigma_finite_measure M1" "sigma_finite_measure M2"
  1042   shows "(M1 \<Otimes>\<^isub>M M2) = distr (Pi\<^isub>M UNIV (bool_case M1 M2)) (M1 \<Otimes>\<^isub>M M2) (\<lambda>x. (x True, x False))"
  1043     (is "?P = ?D")
  1044 proof (rule pair_measure_eqI[OF assms])
  1045   interpret B: product_sigma_finite "bool_case M1 M2"
  1046     unfolding product_sigma_finite_def using assms by (auto split: bool.split)
  1047   let ?B = "Pi\<^isub>M UNIV (bool_case M1 M2)"
  1048 
  1049   have [simp]: "fst \<circ> (\<lambda>x. (x True, x False)) = (\<lambda>x. x True)" "snd \<circ> (\<lambda>x. (x True, x False)) = (\<lambda>x. x False)"
  1050     by auto
  1051   fix A B assume A: "A \<in> sets M1" and B: "B \<in> sets M2"
  1052   have "emeasure M1 A * emeasure M2 B = (\<Prod> i\<in>UNIV. emeasure (bool_case M1 M2 i) (bool_case A B i))"
  1053     by (simp add: UNIV_bool ac_simps)
  1054   also have "\<dots> = emeasure ?B (Pi\<^isub>E UNIV (bool_case A B))"
  1055     using A B by (subst B.emeasure_PiM) (auto split: bool.split)
  1056   also have "Pi\<^isub>E UNIV (bool_case A B) = (\<lambda>x. (x True, x False)) -` (A \<times> B) \<inter> space ?B"
  1057     using A[THEN sets_into_space] B[THEN sets_into_space]
  1058     by (auto simp: Pi_iff all_bool_eq space_PiM split: bool.split)
  1059   finally show "emeasure M1 A * emeasure M2 B = emeasure ?D (A \<times> B)"
  1060     using A B
  1061       measurable_component_singleton[of True UNIV "bool_case M1 M2"]
  1062       measurable_component_singleton[of False UNIV "bool_case M1 M2"]
  1063     by (subst emeasure_distr) (auto simp: measurable_pair_iff)
  1064 qed simp
  1065 
  1066 lemma measurable_Pair:
  1067   assumes rvs: "X \<in> measurable M S" "Y \<in> measurable M T"
  1068   shows "(\<lambda>x. (X x, Y x)) \<in> measurable M (S \<Otimes>\<^isub>M T)"
  1069 proof -
  1070   have [simp]: "fst \<circ> (\<lambda>x. (X x, Y x)) = (\<lambda>x. X x)" "snd \<circ> (\<lambda>x. (X x, Y x)) = (\<lambda>x. Y x)"
  1071     by auto
  1072   show " (\<lambda>x. (X x, Y x)) \<in> measurable M (S \<Otimes>\<^isub>M T)"
  1073     by (auto simp: measurable_pair_iff rvs)
  1074 qed
  1075 
  1076 lemma (in prob_space) indep_var_distribution_eq:
  1077   "indep_var S X T Y \<longleftrightarrow> random_variable S X \<and> random_variable T Y \<and>
  1078     distr M S X \<Otimes>\<^isub>M distr M T Y = distr M (S \<Otimes>\<^isub>M T) (\<lambda>x. (X x, Y x))" (is "_ \<longleftrightarrow> _ \<and> _ \<and> ?S \<Otimes>\<^isub>M ?T = ?J")
  1079 proof safe
  1080   assume "indep_var S X T Y"
  1081   then show rvs: "random_variable S X" "random_variable T Y"
  1082     by (blast dest: indep_var_rv1 indep_var_rv2)+
  1083   then have XY: "random_variable (S \<Otimes>\<^isub>M T) (\<lambda>x. (X x, Y x))"
  1084     by (rule measurable_Pair)
  1085 
  1086   interpret X: prob_space ?S by (rule prob_space_distr) fact
  1087   interpret Y: prob_space ?T by (rule prob_space_distr) fact
  1088   interpret XY: pair_prob_space ?S ?T ..
  1089   show "?S \<Otimes>\<^isub>M ?T = ?J"
  1090   proof (rule pair_measure_eqI)
  1091     show "sigma_finite_measure ?S" ..
  1092     show "sigma_finite_measure ?T" ..
  1093 
  1094     fix A B assume A: "A \<in> sets ?S" and B: "B \<in> sets ?T"
  1095     have "emeasure ?J (A \<times> B) = emeasure M ((\<lambda>x. (X x, Y x)) -` (A \<times> B) \<inter> space M)"
  1096       using A B by (intro emeasure_distr[OF XY]) auto
  1097     also have "\<dots> = emeasure M (X -` A \<inter> space M) * emeasure M (Y -` B \<inter> space M)"
  1098       using indep_varD[OF `indep_var S X T Y`, of A B] A B by (simp add: emeasure_eq_measure)
  1099     also have "\<dots> = emeasure ?S A * emeasure ?T B"
  1100       using rvs A B by (simp add: emeasure_distr)
  1101     finally show "emeasure ?S A * emeasure ?T B = emeasure ?J (A \<times> B)" by simp
  1102   qed simp
  1103 next
  1104   assume rvs: "random_variable S X" "random_variable T Y"
  1105   then have XY: "random_variable (S \<Otimes>\<^isub>M T) (\<lambda>x. (X x, Y x))"
  1106     by (rule measurable_Pair)
  1107 
  1108   let ?S = "distr M S X" and ?T = "distr M T Y"
  1109   interpret X: prob_space ?S by (rule prob_space_distr) fact
  1110   interpret Y: prob_space ?T by (rule prob_space_distr) fact
  1111   interpret XY: pair_prob_space ?S ?T ..
  1112 
  1113   assume "?S \<Otimes>\<^isub>M ?T = ?J"
  1114 
  1115   { fix S and X
  1116     have "Int_stable {X -` A \<inter> space M |A. A \<in> sets S}"
  1117     proof (safe intro!: Int_stableI)
  1118       fix A B assume "A \<in> sets S" "B \<in> sets S"
  1119       then show "\<exists>C. (X -` A \<inter> space M) \<inter> (X -` B \<inter> space M) = (X -` C \<inter> space M) \<and> C \<in> sets S"
  1120         by (intro exI[of _ "A \<inter> B"]) auto
  1121     qed }
  1122   note Int_stable = this
  1123 
  1124   show "indep_var S X T Y" unfolding indep_var_eq
  1125   proof (intro conjI indep_set_sigma_sets Int_stable rvs)
  1126     show "indep_set {X -` A \<inter> space M |A. A \<in> sets S} {Y -` A \<inter> space M |A. A \<in> sets T}"
  1127     proof (safe intro!: indep_setI)
  1128       { fix A assume "A \<in> sets S" then show "X -` A \<inter> space M \<in> sets M"
  1129         using `X \<in> measurable M S` by (auto intro: measurable_sets) }
  1130       { fix A assume "A \<in> sets T" then show "Y -` A \<inter> space M \<in> sets M"
  1131         using `Y \<in> measurable M T` by (auto intro: measurable_sets) }
  1132     next
  1133       fix A B assume ab: "A \<in> sets S" "B \<in> sets T"
  1134       then have "ereal (prob ((X -` A \<inter> space M) \<inter> (Y -` B \<inter> space M))) = emeasure ?J (A \<times> B)"
  1135         using XY by (auto simp add: emeasure_distr emeasure_eq_measure intro!: arg_cong[where f="prob"])
  1136       also have "\<dots> = emeasure (?S \<Otimes>\<^isub>M ?T) (A \<times> B)"
  1137         unfolding `?S \<Otimes>\<^isub>M ?T = ?J` ..
  1138       also have "\<dots> = emeasure ?S A * emeasure ?T B"
  1139         using ab by (simp add: XY.emeasure_pair_measure_Times)
  1140       finally show "prob ((X -` A \<inter> space M) \<inter> (Y -` B \<inter> space M)) =
  1141         prob (X -` A \<inter> space M) * prob (Y -` B \<inter> space M)"
  1142         using rvs ab by (simp add: emeasure_eq_measure emeasure_distr)
  1143     qed
  1144   qed
  1145 qed
  1146 
  1147 end