src/HOL/Probability/Lebesgue_Measure.thy
author hoelzl
Mon Apr 23 12:14:35 2012 +0200 (2012-04-23)
changeset 47694 05663f75964c
parent 46905 6b1c0a80a57a
child 47757 5e6fe71e2390
permissions -rw-r--r--
reworked Probability theory
     1 (*  Title:      HOL/Probability/Lebesgue_Measure.thy
     2     Author:     Johannes Hölzl, TU München
     3     Author:     Robert Himmelmann, TU München
     4 *)
     5 
     6 header {* Lebsegue measure *}
     7 
     8 theory Lebesgue_Measure
     9   imports Finite_Product_Measure
    10 begin
    11 
    12 lemma borel_measurable_sets:
    13   assumes "f \<in> measurable borel M" "A \<in> sets M"
    14   shows "f -` A \<in> sets borel"
    15   using measurable_sets[OF assms] by simp
    16 
    17 lemma measurable_identity[intro,simp]:
    18   "(\<lambda>x. x) \<in> measurable M M"
    19   unfolding measurable_def by auto
    20 
    21 subsection {* Standard Cubes *}
    22 
    23 definition cube :: "nat \<Rightarrow> 'a::ordered_euclidean_space set" where
    24   "cube n \<equiv> {\<chi>\<chi> i. - real n .. \<chi>\<chi> i. real n}"
    25 
    26 lemma cube_closed[intro]: "closed (cube n)"
    27   unfolding cube_def by auto
    28 
    29 lemma cube_subset[intro]: "n \<le> N \<Longrightarrow> cube n \<subseteq> cube N"
    30   by (fastforce simp: eucl_le[where 'a='a] cube_def)
    31 
    32 lemma cube_subset_iff:
    33   "cube n \<subseteq> cube N \<longleftrightarrow> n \<le> N"
    34 proof
    35   assume subset: "cube n \<subseteq> (cube N::'a set)"
    36   then have "((\<chi>\<chi> i. real n)::'a) \<in> cube N"
    37     using DIM_positive[where 'a='a]
    38     by (fastforce simp: cube_def eucl_le[where 'a='a])
    39   then show "n \<le> N"
    40     by (fastforce simp: cube_def eucl_le[where 'a='a])
    41 next
    42   assume "n \<le> N" then show "cube n \<subseteq> (cube N::'a set)" by (rule cube_subset)
    43 qed
    44 
    45 lemma ball_subset_cube:"ball (0::'a::ordered_euclidean_space) (real n) \<subseteq> cube n"
    46   unfolding cube_def subset_eq mem_interval apply safe unfolding euclidean_lambda_beta'
    47 proof- fix x::'a and i assume as:"x\<in>ball 0 (real n)" "i<DIM('a)"
    48   thus "- real n \<le> x $$ i" "real n \<ge> x $$ i"
    49     using component_le_norm[of x i] by(auto simp: dist_norm)
    50 qed
    51 
    52 lemma mem_big_cube: obtains n where "x \<in> cube n"
    53 proof- from reals_Archimedean2[of "norm x"] guess n ..
    54   thus ?thesis apply-apply(rule that[where n=n])
    55     apply(rule ball_subset_cube[unfolded subset_eq,rule_format])
    56     by (auto simp add:dist_norm)
    57 qed
    58 
    59 lemma cube_subset_Suc[intro]: "cube n \<subseteq> cube (Suc n)"
    60   unfolding cube_def subset_eq apply safe unfolding mem_interval apply auto done
    61 
    62 subsection {* Lebesgue measure *} 
    63 
    64 definition lebesgue :: "'a::ordered_euclidean_space measure" where
    65   "lebesgue = measure_of UNIV {A. \<forall>n. (indicator A :: 'a \<Rightarrow> real) integrable_on cube n}
    66     (\<lambda>A. SUP n. ereal (integral (cube n) (indicator A)))"
    67 
    68 lemma space_lebesgue[simp]: "space lebesgue = UNIV"
    69   unfolding lebesgue_def by simp
    70 
    71 lemma lebesgueI: "(\<And>n. (indicator A :: _ \<Rightarrow> real) integrable_on cube n) \<Longrightarrow> A \<in> sets lebesgue"
    72   unfolding lebesgue_def by simp
    73 
    74 lemma absolutely_integrable_on_indicator[simp]:
    75   fixes A :: "'a::ordered_euclidean_space set"
    76   shows "((indicator A :: _ \<Rightarrow> real) absolutely_integrable_on X) \<longleftrightarrow>
    77     (indicator A :: _ \<Rightarrow> real) integrable_on X"
    78   unfolding absolutely_integrable_on_def by simp
    79 
    80 lemma LIMSEQ_indicator_UN:
    81   "(\<lambda>k. indicator (\<Union> i<k. A i) x) ----> (indicator (\<Union>i. A i) x :: real)"
    82 proof cases
    83   assume "\<exists>i. x \<in> A i" then guess i .. note i = this
    84   then have *: "\<And>n. (indicator (\<Union> i<n + Suc i. A i) x :: real) = 1"
    85     "(indicator (\<Union> i. A i) x :: real) = 1" by (auto simp: indicator_def)
    86   show ?thesis
    87     apply (rule LIMSEQ_offset[of _ "Suc i"]) unfolding * by auto
    88 qed (auto simp: indicator_def)
    89 
    90 lemma indicator_add:
    91   "A \<inter> B = {} \<Longrightarrow> (indicator A x::_::monoid_add) + indicator B x = indicator (A \<union> B) x"
    92   unfolding indicator_def by auto
    93 
    94 lemma sigma_algebra_lebesgue:
    95   defines "leb \<equiv> {A. \<forall>n. (indicator A :: 'a::ordered_euclidean_space \<Rightarrow> real) integrable_on cube n}"
    96   shows "sigma_algebra UNIV leb"
    97 proof (safe intro!: sigma_algebra_iff2[THEN iffD2])
    98   fix A assume A: "A \<in> leb"
    99   moreover have "indicator (UNIV - A) = (\<lambda>x. 1 - indicator A x :: real)"
   100     by (auto simp: fun_eq_iff indicator_def)
   101   ultimately show "UNIV - A \<in> leb"
   102     using A by (auto intro!: integrable_sub simp: cube_def leb_def)
   103 next
   104   fix n show "{} \<in> leb"
   105     by (auto simp: cube_def indicator_def[abs_def] leb_def)
   106 next
   107   fix A :: "nat \<Rightarrow> _" assume A: "range A \<subseteq> leb"
   108   have "\<forall>n. (indicator (\<Union>i. A i) :: _ \<Rightarrow> real) integrable_on cube n" (is "\<forall>n. ?g integrable_on _")
   109   proof (intro dominated_convergence[where g="?g"] ballI allI)
   110     fix k n show "(indicator (\<Union>i<k. A i) :: _ \<Rightarrow> real) integrable_on cube n"
   111     proof (induct k)
   112       case (Suc k)
   113       have *: "(\<Union> i<Suc k. A i) = (\<Union> i<k. A i) \<union> A k"
   114         unfolding lessThan_Suc UN_insert by auto
   115       have *: "(\<lambda>x. max (indicator (\<Union> i<k. A i) x) (indicator (A k) x) :: real) =
   116           indicator (\<Union> i<Suc k. A i)" (is "(\<lambda>x. max (?f x) (?g x)) = _")
   117         by (auto simp: fun_eq_iff * indicator_def)
   118       show ?case
   119         using absolutely_integrable_max[of ?f "cube n" ?g] A Suc
   120         by (simp add: * leb_def subset_eq)
   121     qed auto
   122   qed (auto intro: LIMSEQ_indicator_UN simp: cube_def)
   123   then show "(\<Union>i. A i) \<in> leb" by (auto simp: leb_def)
   124 qed simp
   125 
   126 lemma sets_lebesgue: "sets lebesgue = {A. \<forall>n. (indicator A :: _ \<Rightarrow> real) integrable_on cube n}"
   127   unfolding lebesgue_def sigma_algebra.sets_measure_of_eq[OF sigma_algebra_lebesgue] ..
   128 
   129 lemma lebesgueD: "A \<in> sets lebesgue \<Longrightarrow> (indicator A :: _ \<Rightarrow> real) integrable_on cube n"
   130   unfolding sets_lebesgue by simp
   131 
   132 lemma emeasure_lebesgue: 
   133   assumes "A \<in> sets lebesgue"
   134   shows "emeasure lebesgue A = (SUP n. ereal (integral (cube n) (indicator A)))"
   135     (is "_ = ?\<mu> A")
   136 proof (rule emeasure_measure_of[OF lebesgue_def])
   137   have *: "indicator {} = (\<lambda>x. 0 :: real)" by (simp add: fun_eq_iff)
   138   show "positive (sets lebesgue) ?\<mu>"
   139   proof (unfold positive_def, intro conjI ballI)
   140     show "?\<mu> {} = 0" by (simp add: integral_0 *)
   141     fix A :: "'a set" assume "A \<in> sets lebesgue" then show "0 \<le> ?\<mu> A"
   142       by (auto intro!: SUP_upper2 Integration.integral_nonneg simp: sets_lebesgue)
   143   qed
   144 next
   145   show "countably_additive (sets lebesgue) ?\<mu>"
   146   proof (intro countably_additive_def[THEN iffD2] allI impI)
   147     fix A :: "nat \<Rightarrow> 'a set" assume rA: "range A \<subseteq> sets lebesgue" "disjoint_family A"
   148     then have A[simp, intro]: "\<And>i n. (indicator (A i) :: _ \<Rightarrow> real) integrable_on cube n"
   149       by (auto dest: lebesgueD)
   150     let ?m = "\<lambda>n i. integral (cube n) (indicator (A i) :: _\<Rightarrow>real)"
   151     let ?M = "\<lambda>n I. integral (cube n) (indicator (\<Union>i\<in>I. A i) :: _\<Rightarrow>real)"
   152     have nn[simp, intro]: "\<And>i n. 0 \<le> ?m n i" by (auto intro!: Integration.integral_nonneg)
   153     assume "(\<Union>i. A i) \<in> sets lebesgue"
   154     then have UN_A[simp, intro]: "\<And>i n. (indicator (\<Union>i. A i) :: _ \<Rightarrow> real) integrable_on cube n"
   155       by (auto simp: sets_lebesgue)
   156     show "(\<Sum>n. ?\<mu> (A n)) = ?\<mu> (\<Union>i. A i)"
   157     proof (subst suminf_SUP_eq, safe intro!: incseq_SucI)
   158       fix i n show "ereal (?m n i) \<le> ereal (?m (Suc n) i)"
   159         using cube_subset[of n "Suc n"] by (auto intro!: integral_subset_le incseq_SucI)
   160     next
   161       fix i n show "0 \<le> ereal (?m n i)"
   162         using rA unfolding lebesgue_def
   163         by (auto intro!: SUP_upper2 integral_nonneg)
   164     next
   165       show "(SUP n. \<Sum>i. ereal (?m n i)) = (SUP n. ereal (?M n UNIV))"
   166       proof (intro arg_cong[where f="SUPR UNIV"] ext sums_unique[symmetric] sums_ereal[THEN iffD2] sums_def[THEN iffD2])
   167         fix n
   168         have "\<And>m. (UNION {..<m} A) \<in> sets lebesgue" using rA by auto
   169         from lebesgueD[OF this]
   170         have "(\<lambda>m. ?M n {..< m}) ----> ?M n UNIV"
   171           (is "(\<lambda>m. integral _ (?A m)) ----> ?I")
   172           by (intro dominated_convergence(2)[where f="?A" and h="\<lambda>x. 1::real"])
   173              (auto intro: LIMSEQ_indicator_UN simp: cube_def)
   174         moreover
   175         { fix m have *: "(\<Sum>x<m. ?m n x) = ?M n {..< m}"
   176           proof (induct m)
   177             case (Suc m)
   178             have "(\<Union>i<m. A i) \<in> sets lebesgue" using rA by auto
   179             then have "(indicator (\<Union>i<m. A i) :: _\<Rightarrow>real) integrable_on (cube n)"
   180               by (auto dest!: lebesgueD)
   181             moreover
   182             have "(\<Union>i<m. A i) \<inter> A m = {}"
   183               using rA(2)[unfolded disjoint_family_on_def, THEN bspec, of m]
   184               by auto
   185             then have "\<And>x. indicator (\<Union>i<Suc m. A i) x =
   186               indicator (\<Union>i<m. A i) x + (indicator (A m) x :: real)"
   187               by (auto simp: indicator_add lessThan_Suc ac_simps)
   188             ultimately show ?case
   189               using Suc A by (simp add: Integration.integral_add[symmetric])
   190           qed auto }
   191         ultimately show "(\<lambda>m. \<Sum>x = 0..<m. ?m n x) ----> ?M n UNIV"
   192           by (simp add: atLeast0LessThan)
   193       qed
   194     qed
   195   qed
   196 next
   197 qed (auto, fact)
   198 
   199 lemma has_integral_interval_cube:
   200   fixes a b :: "'a::ordered_euclidean_space"
   201   shows "(indicator {a .. b} has_integral
   202     content ({\<chi>\<chi> i. max (- real n) (a $$ i) .. \<chi>\<chi> i. min (real n) (b $$ i)} :: 'a set)) (cube n)"
   203     (is "(?I has_integral content ?R) (cube n)")
   204 proof -
   205   let "{?N .. ?P}" = ?R
   206   have [simp]: "(\<lambda>x. if x \<in> cube n then ?I x else 0) = indicator ?R"
   207     by (auto simp: indicator_def cube_def fun_eq_iff eucl_le[where 'a='a])
   208   have "(?I has_integral content ?R) (cube n) \<longleftrightarrow> (indicator ?R has_integral content ?R) UNIV"
   209     unfolding has_integral_restrict_univ[where s="cube n", symmetric] by simp
   210   also have "\<dots> \<longleftrightarrow> ((\<lambda>x. 1) has_integral content ?R) ?R"
   211     unfolding indicator_def [abs_def] has_integral_restrict_univ ..
   212   finally show ?thesis
   213     using has_integral_const[of "1::real" "?N" "?P"] by simp
   214 qed
   215 
   216 lemma lebesgueI_borel[intro, simp]:
   217   fixes s::"'a::ordered_euclidean_space set"
   218   assumes "s \<in> sets borel" shows "s \<in> sets lebesgue"
   219 proof -
   220   have "s \<in> sigma_sets (space lebesgue) (range (\<lambda>(a, b). {a .. (b :: 'a\<Colon>ordered_euclidean_space)}))"
   221     using assms by (simp add: borel_eq_atLeastAtMost)
   222   also have "\<dots> \<subseteq> sets lebesgue"
   223   proof (safe intro!: sigma_sets_subset lebesgueI)
   224     fix n :: nat and a b :: 'a
   225     let ?N = "\<chi>\<chi> i. max (- real n) (a $$ i)"
   226     let ?P = "\<chi>\<chi> i. min (real n) (b $$ i)"
   227     show "(indicator {a..b} :: 'a\<Rightarrow>real) integrable_on cube n"
   228       unfolding integrable_on_def
   229       using has_integral_interval_cube[of a b] by auto
   230   qed
   231   finally show ?thesis .
   232 qed
   233 
   234 lemma lebesgueI_negligible[dest]: fixes s::"'a::ordered_euclidean_space set"
   235   assumes "negligible s" shows "s \<in> sets lebesgue"
   236   using assms by (force simp: cube_def integrable_on_def negligible_def intro!: lebesgueI)
   237 
   238 lemma lmeasure_eq_0:
   239   fixes S :: "'a::ordered_euclidean_space set"
   240   assumes "negligible S" shows "emeasure lebesgue S = 0"
   241 proof -
   242   have "\<And>n. integral (cube n) (indicator S :: 'a\<Rightarrow>real) = 0"
   243     unfolding lebesgue_integral_def using assms
   244     by (intro integral_unique some1_equality ex_ex1I)
   245        (auto simp: cube_def negligible_def)
   246   then show ?thesis
   247     using assms by (simp add: emeasure_lebesgue lebesgueI_negligible)
   248 qed
   249 
   250 lemma lmeasure_iff_LIMSEQ:
   251   assumes A: "A \<in> sets lebesgue" and "0 \<le> m"
   252   shows "emeasure lebesgue A = ereal m \<longleftrightarrow> (\<lambda>n. integral (cube n) (indicator A :: _ \<Rightarrow> real)) ----> m"
   253 proof (subst emeasure_lebesgue[OF A], intro SUP_eq_LIMSEQ)
   254   show "mono (\<lambda>n. integral (cube n) (indicator A::_=>real))"
   255     using cube_subset assms by (intro monoI integral_subset_le) (auto dest!: lebesgueD)
   256 qed
   257 
   258 lemma has_integral_indicator_UNIV:
   259   fixes s A :: "'a::ordered_euclidean_space set" and x :: real
   260   shows "((indicator (s \<inter> A) :: 'a\<Rightarrow>real) has_integral x) UNIV = ((indicator s :: _\<Rightarrow>real) has_integral x) A"
   261 proof -
   262   have "(\<lambda>x. if x \<in> A then indicator s x else 0) = (indicator (s \<inter> A) :: _\<Rightarrow>real)"
   263     by (auto simp: fun_eq_iff indicator_def)
   264   then show ?thesis
   265     unfolding has_integral_restrict_univ[where s=A, symmetric] by simp
   266 qed
   267 
   268 lemma
   269   fixes s a :: "'a::ordered_euclidean_space set"
   270   shows integral_indicator_UNIV:
   271     "integral UNIV (indicator (s \<inter> A) :: 'a\<Rightarrow>real) = integral A (indicator s :: _\<Rightarrow>real)"
   272   and integrable_indicator_UNIV:
   273     "(indicator (s \<inter> A) :: 'a\<Rightarrow>real) integrable_on UNIV \<longleftrightarrow> (indicator s :: 'a\<Rightarrow>real) integrable_on A"
   274   unfolding integral_def integrable_on_def has_integral_indicator_UNIV by auto
   275 
   276 lemma lmeasure_finite_has_integral:
   277   fixes s :: "'a::ordered_euclidean_space set"
   278   assumes "s \<in> sets lebesgue" "emeasure lebesgue s = ereal m" "0 \<le> m"
   279   shows "(indicator s has_integral m) UNIV"
   280 proof -
   281   let ?I = "indicator :: 'a set \<Rightarrow> 'a \<Rightarrow> real"
   282   have **: "(?I s) integrable_on UNIV \<and> (\<lambda>k. integral UNIV (?I (s \<inter> cube k))) ----> integral UNIV (?I s)"
   283   proof (intro monotone_convergence_increasing allI ballI)
   284     have LIMSEQ: "(\<lambda>n. integral (cube n) (?I s)) ----> m"
   285       using assms(2) unfolding lmeasure_iff_LIMSEQ[OF assms(1, 3)] .
   286     { fix n have "integral (cube n) (?I s) \<le> m"
   287         using cube_subset assms
   288         by (intro incseq_le[where L=m] LIMSEQ incseq_def[THEN iffD2] integral_subset_le allI impI)
   289            (auto dest!: lebesgueD) }
   290     moreover
   291     { fix n have "0 \<le> integral (cube n) (?I s)"
   292       using assms by (auto dest!: lebesgueD intro!: Integration.integral_nonneg) }
   293     ultimately
   294     show "bounded {integral UNIV (?I (s \<inter> cube k)) |k. True}"
   295       unfolding bounded_def
   296       apply (rule_tac exI[of _ 0])
   297       apply (rule_tac exI[of _ m])
   298       by (auto simp: dist_real_def integral_indicator_UNIV)
   299     fix k show "?I (s \<inter> cube k) integrable_on UNIV"
   300       unfolding integrable_indicator_UNIV using assms by (auto dest!: lebesgueD)
   301     fix x show "?I (s \<inter> cube k) x \<le> ?I (s \<inter> cube (Suc k)) x"
   302       using cube_subset[of k "Suc k"] by (auto simp: indicator_def)
   303   next
   304     fix x :: 'a
   305     from mem_big_cube obtain k where k: "x \<in> cube k" .
   306     { fix n have "?I (s \<inter> cube (n + k)) x = ?I s x"
   307       using k cube_subset[of k "n + k"] by (auto simp: indicator_def) }
   308     note * = this
   309     show "(\<lambda>k. ?I (s \<inter> cube k) x) ----> ?I s x"
   310       by (rule LIMSEQ_offset[where k=k]) (auto simp: *)
   311   qed
   312   note ** = conjunctD2[OF this]
   313   have m: "m = integral UNIV (?I s)"
   314     apply (intro LIMSEQ_unique[OF _ **(2)])
   315     using assms(2) unfolding lmeasure_iff_LIMSEQ[OF assms(1,3)] integral_indicator_UNIV .
   316   show ?thesis
   317     unfolding m by (intro integrable_integral **)
   318 qed
   319 
   320 lemma lmeasure_finite_integrable: assumes s: "s \<in> sets lebesgue" and "emeasure lebesgue s \<noteq> \<infinity>"
   321   shows "(indicator s :: _ \<Rightarrow> real) integrable_on UNIV"
   322 proof (cases "emeasure lebesgue s")
   323   case (real m)
   324   with lmeasure_finite_has_integral[OF `s \<in> sets lebesgue` this] emeasure_nonneg[of lebesgue s]
   325   show ?thesis unfolding integrable_on_def by auto
   326 qed (insert assms emeasure_nonneg[of lebesgue s], auto)
   327 
   328 lemma has_integral_lebesgue: assumes "((indicator s :: _\<Rightarrow>real) has_integral m) UNIV"
   329   shows "s \<in> sets lebesgue"
   330 proof (intro lebesgueI)
   331   let ?I = "indicator :: 'a set \<Rightarrow> 'a \<Rightarrow> real"
   332   fix n show "(?I s) integrable_on cube n" unfolding cube_def
   333   proof (intro integrable_on_subinterval)
   334     show "(?I s) integrable_on UNIV"
   335       unfolding integrable_on_def using assms by auto
   336   qed auto
   337 qed
   338 
   339 lemma has_integral_lmeasure: assumes "((indicator s :: _\<Rightarrow>real) has_integral m) UNIV"
   340   shows "emeasure lebesgue s = ereal m"
   341 proof (intro lmeasure_iff_LIMSEQ[THEN iffD2])
   342   let ?I = "indicator :: 'a set \<Rightarrow> 'a \<Rightarrow> real"
   343   show "s \<in> sets lebesgue" using has_integral_lebesgue[OF assms] .
   344   show "0 \<le> m" using assms by (rule has_integral_nonneg) auto
   345   have "(\<lambda>n. integral UNIV (?I (s \<inter> cube n))) ----> integral UNIV (?I s)"
   346   proof (intro dominated_convergence(2) ballI)
   347     show "(?I s) integrable_on UNIV" unfolding integrable_on_def using assms by auto
   348     fix n show "?I (s \<inter> cube n) integrable_on UNIV"
   349       unfolding integrable_indicator_UNIV using `s \<in> sets lebesgue` by (auto dest: lebesgueD)
   350     fix x show "norm (?I (s \<inter> cube n) x) \<le> ?I s x" by (auto simp: indicator_def)
   351   next
   352     fix x :: 'a
   353     from mem_big_cube obtain k where k: "x \<in> cube k" .
   354     { fix n have "?I (s \<inter> cube (n + k)) x = ?I s x"
   355       using k cube_subset[of k "n + k"] by (auto simp: indicator_def) }
   356     note * = this
   357     show "(\<lambda>k. ?I (s \<inter> cube k) x) ----> ?I s x"
   358       by (rule LIMSEQ_offset[where k=k]) (auto simp: *)
   359   qed
   360   then show "(\<lambda>n. integral (cube n) (?I s)) ----> m"
   361     unfolding integral_unique[OF assms] integral_indicator_UNIV by simp
   362 qed
   363 
   364 lemma has_integral_iff_lmeasure:
   365   "(indicator A has_integral m) UNIV \<longleftrightarrow> (A \<in> sets lebesgue \<and> 0 \<le> m \<and> emeasure lebesgue A = ereal m)"
   366 proof
   367   assume "(indicator A has_integral m) UNIV"
   368   with has_integral_lmeasure[OF this] has_integral_lebesgue[OF this]
   369   show "A \<in> sets lebesgue \<and> 0 \<le> m \<and> emeasure lebesgue A = ereal m"
   370     by (auto intro: has_integral_nonneg)
   371 next
   372   assume "A \<in> sets lebesgue \<and> 0 \<le> m \<and> emeasure lebesgue A = ereal m"
   373   then show "(indicator A has_integral m) UNIV" by (intro lmeasure_finite_has_integral) auto
   374 qed
   375 
   376 lemma lmeasure_eq_integral: assumes "(indicator s::_\<Rightarrow>real) integrable_on UNIV"
   377   shows "emeasure lebesgue s = ereal (integral UNIV (indicator s))"
   378   using assms unfolding integrable_on_def
   379 proof safe
   380   fix y :: real assume "(indicator s has_integral y) UNIV"
   381   from this[unfolded has_integral_iff_lmeasure] integral_unique[OF this]
   382   show "emeasure lebesgue s = ereal (integral UNIV (indicator s))" by simp
   383 qed
   384 
   385 lemma lebesgue_simple_function_indicator:
   386   fixes f::"'a::ordered_euclidean_space \<Rightarrow> ereal"
   387   assumes f:"simple_function lebesgue f"
   388   shows "f = (\<lambda>x. (\<Sum>y \<in> f ` UNIV. y * indicator (f -` {y}) x))"
   389   by (rule, subst simple_function_indicator_representation[OF f]) auto
   390 
   391 lemma integral_eq_lmeasure:
   392   "(indicator s::_\<Rightarrow>real) integrable_on UNIV \<Longrightarrow> integral UNIV (indicator s) = real (emeasure lebesgue s)"
   393   by (subst lmeasure_eq_integral) (auto intro!: integral_nonneg)
   394 
   395 lemma lmeasure_finite: assumes "(indicator s::_\<Rightarrow>real) integrable_on UNIV" shows "emeasure lebesgue s \<noteq> \<infinity>"
   396   using lmeasure_eq_integral[OF assms] by auto
   397 
   398 lemma negligible_iff_lebesgue_null_sets:
   399   "negligible A \<longleftrightarrow> A \<in> null_sets lebesgue"
   400 proof
   401   assume "negligible A"
   402   from this[THEN lebesgueI_negligible] this[THEN lmeasure_eq_0]
   403   show "A \<in> null_sets lebesgue" by auto
   404 next
   405   assume A: "A \<in> null_sets lebesgue"
   406   then have *:"((indicator A) has_integral (0::real)) UNIV" using lmeasure_finite_has_integral[of A]
   407     by (auto simp: null_sets_def)
   408   show "negligible A" unfolding negligible_def
   409   proof (intro allI)
   410     fix a b :: 'a
   411     have integrable: "(indicator A :: _\<Rightarrow>real) integrable_on {a..b}"
   412       by (intro integrable_on_subinterval has_integral_integrable) (auto intro: *)
   413     then have "integral {a..b} (indicator A) \<le> (integral UNIV (indicator A) :: real)"
   414       using * by (auto intro!: integral_subset_le)
   415     moreover have "(0::real) \<le> integral {a..b} (indicator A)"
   416       using integrable by (auto intro!: integral_nonneg)
   417     ultimately have "integral {a..b} (indicator A) = (0::real)"
   418       using integral_unique[OF *] by auto
   419     then show "(indicator A has_integral (0::real)) {a..b}"
   420       using integrable_integral[OF integrable] by simp
   421   qed
   422 qed
   423 
   424 lemma integral_const[simp]:
   425   fixes a b :: "'a::ordered_euclidean_space"
   426   shows "integral {a .. b} (\<lambda>x. c) = content {a .. b} *\<^sub>R c"
   427   by (rule integral_unique) (rule has_integral_const)
   428 
   429 lemma lmeasure_UNIV[intro]: "emeasure lebesgue (UNIV::'a::ordered_euclidean_space set) = \<infinity>"
   430 proof (simp add: emeasure_lebesgue, intro SUP_PInfty bexI)
   431   fix n :: nat
   432   have "indicator UNIV = (\<lambda>x::'a. 1 :: real)" by auto
   433   moreover
   434   { have "real n \<le> (2 * real n) ^ DIM('a)"
   435     proof (cases n)
   436       case 0 then show ?thesis by auto
   437     next
   438       case (Suc n')
   439       have "real n \<le> (2 * real n)^1" by auto
   440       also have "(2 * real n)^1 \<le> (2 * real n) ^ DIM('a)"
   441         using Suc DIM_positive[where 'a='a] by (intro power_increasing) (auto simp: real_of_nat_Suc)
   442       finally show ?thesis .
   443     qed }
   444   ultimately show "ereal (real n) \<le> ereal (integral (cube n) (indicator UNIV::'a\<Rightarrow>real))"
   445     using integral_const DIM_positive[where 'a='a]
   446     by (auto simp: cube_def content_closed_interval_cases setprod_constant)
   447 qed simp
   448 
   449 lemma
   450   fixes a b ::"'a::ordered_euclidean_space"
   451   shows lmeasure_atLeastAtMost[simp]: "emeasure lebesgue {a..b} = ereal (content {a..b})"
   452 proof -
   453   have "(indicator (UNIV \<inter> {a..b})::_\<Rightarrow>real) integrable_on UNIV"
   454     unfolding integrable_indicator_UNIV by (simp add: integrable_const indicator_def [abs_def])
   455   from lmeasure_eq_integral[OF this] show ?thesis unfolding integral_indicator_UNIV
   456     by (simp add: indicator_def [abs_def])
   457 qed
   458 
   459 lemma atLeastAtMost_singleton_euclidean[simp]:
   460   fixes a :: "'a::ordered_euclidean_space" shows "{a .. a} = {a}"
   461   by (force simp: eucl_le[where 'a='a] euclidean_eq[where 'a='a])
   462 
   463 lemma content_singleton[simp]: "content {a} = 0"
   464 proof -
   465   have "content {a .. a} = 0"
   466     by (subst content_closed_interval) auto
   467   then show ?thesis by simp
   468 qed
   469 
   470 lemma lmeasure_singleton[simp]:
   471   fixes a :: "'a::ordered_euclidean_space" shows "emeasure lebesgue {a} = 0"
   472   using lmeasure_atLeastAtMost[of a a] by simp
   473 
   474 declare content_real[simp]
   475 
   476 lemma
   477   fixes a b :: real
   478   shows lmeasure_real_greaterThanAtMost[simp]:
   479     "emeasure lebesgue {a <.. b} = ereal (if a \<le> b then b - a else 0)"
   480 proof cases
   481   assume "a < b"
   482   then have "emeasure lebesgue {a <.. b} = emeasure lebesgue {a .. b} - emeasure lebesgue {a}"
   483     by (subst emeasure_Diff[symmetric])
   484        (auto intro!: arg_cong[where f="emeasure lebesgue"])
   485   then show ?thesis by auto
   486 qed auto
   487 
   488 lemma
   489   fixes a b :: real
   490   shows lmeasure_real_atLeastLessThan[simp]:
   491     "emeasure lebesgue {a ..< b} = ereal (if a \<le> b then b - a else 0)"
   492 proof cases
   493   assume "a < b"
   494   then have "emeasure lebesgue {a ..< b} = emeasure lebesgue {a .. b} - emeasure lebesgue {b}"
   495     by (subst emeasure_Diff[symmetric])
   496        (auto intro!: arg_cong[where f="emeasure lebesgue"])
   497   then show ?thesis by auto
   498 qed auto
   499 
   500 lemma
   501   fixes a b :: real
   502   shows lmeasure_real_greaterThanLessThan[simp]:
   503     "emeasure lebesgue {a <..< b} = ereal (if a \<le> b then b - a else 0)"
   504 proof cases
   505   assume "a < b"
   506   then have "emeasure lebesgue {a <..< b} = emeasure lebesgue {a <.. b} - emeasure lebesgue {b}"
   507     by (subst emeasure_Diff[symmetric])
   508        (auto intro!: arg_cong[where f="emeasure lebesgue"])
   509   then show ?thesis by auto
   510 qed auto
   511 
   512 subsection {* Lebesgue-Borel measure *}
   513 
   514 definition "lborel = measure_of UNIV (sets borel) (emeasure lebesgue)"
   515 
   516 lemma
   517   shows space_lborel[simp]: "space lborel = UNIV"
   518   and sets_lborel[simp]: "sets lborel = sets borel"
   519   and measurable_lborel1[simp]: "measurable lborel = measurable borel"
   520   and measurable_lborel2[simp]: "measurable A lborel = measurable A borel"
   521   using sigma_sets_eq[of borel]
   522   by (auto simp add: lborel_def measurable_def[abs_def])
   523 
   524 lemma emeasure_lborel[simp]: "A \<in> sets borel \<Longrightarrow> emeasure lborel A = emeasure lebesgue A"
   525   by (rule emeasure_measure_of[OF lborel_def])
   526      (auto simp: positive_def emeasure_nonneg countably_additive_def intro!: suminf_emeasure)
   527 
   528 interpretation lborel: sigma_finite_measure lborel
   529 proof (default, intro conjI exI[of _ "\<lambda>n. cube n"])
   530   show "range cube \<subseteq> sets lborel" by (auto intro: borel_closed)
   531   { fix x :: 'a have "\<exists>n. x\<in>cube n" using mem_big_cube by auto }
   532   then show "(\<Union>i. cube i) = (space lborel :: 'a set)" using mem_big_cube by auto
   533   show "\<forall>i. emeasure lborel (cube i) \<noteq> \<infinity>" by (simp add: cube_def)
   534 qed
   535 
   536 interpretation lebesgue: sigma_finite_measure lebesgue
   537 proof
   538   from lborel.sigma_finite guess A :: "nat \<Rightarrow> 'a set" ..
   539   then show "\<exists>A::nat \<Rightarrow> 'a set. range A \<subseteq> sets lebesgue \<and> (\<Union>i. A i) = space lebesgue \<and> (\<forall>i. emeasure lebesgue (A i) \<noteq> \<infinity>)"
   540     by (intro exI[of _ A]) (auto simp: subset_eq)
   541 qed
   542 
   543 subsection {* Lebesgue integrable implies Gauge integrable *}
   544 
   545 lemma has_integral_cmult_real:
   546   fixes c :: real
   547   assumes "c \<noteq> 0 \<Longrightarrow> (f has_integral x) A"
   548   shows "((\<lambda>x. c * f x) has_integral c * x) A"
   549 proof cases
   550   assume "c \<noteq> 0"
   551   from has_integral_cmul[OF assms[OF this], of c] show ?thesis
   552     unfolding real_scaleR_def .
   553 qed simp
   554 
   555 lemma simple_function_has_integral:
   556   fixes f::"'a::ordered_euclidean_space \<Rightarrow> ereal"
   557   assumes f:"simple_function lebesgue f"
   558   and f':"range f \<subseteq> {0..<\<infinity>}"
   559   and om:"\<And>x. x \<in> range f \<Longrightarrow> emeasure lebesgue (f -` {x} \<inter> UNIV) = \<infinity> \<Longrightarrow> x = 0"
   560   shows "((\<lambda>x. real (f x)) has_integral (real (integral\<^isup>S lebesgue f))) UNIV"
   561   unfolding simple_integral_def space_lebesgue
   562 proof (subst lebesgue_simple_function_indicator)
   563   let ?M = "\<lambda>x. emeasure lebesgue (f -` {x} \<inter> UNIV)"
   564   let ?F = "\<lambda>x. indicator (f -` {x})"
   565   { fix x y assume "y \<in> range f"
   566     from subsetD[OF f' this] have "y * ?F y x = ereal (real y * ?F y x)"
   567       by (cases rule: ereal2_cases[of y "?F y x"])
   568          (auto simp: indicator_def one_ereal_def split: split_if_asm) }
   569   moreover
   570   { fix x assume x: "x\<in>range f"
   571     have "x * ?M x = real x * real (?M x)"
   572     proof cases
   573       assume "x \<noteq> 0" with om[OF x] have "?M x \<noteq> \<infinity>" by auto
   574       with subsetD[OF f' x] f[THEN simple_functionD(2)] show ?thesis
   575         by (cases rule: ereal2_cases[of x "?M x"]) auto
   576     qed simp }
   577   ultimately
   578   have "((\<lambda>x. real (\<Sum>y\<in>range f. y * ?F y x)) has_integral real (\<Sum>x\<in>range f. x * ?M x)) UNIV \<longleftrightarrow>
   579     ((\<lambda>x. \<Sum>y\<in>range f. real y * ?F y x) has_integral (\<Sum>x\<in>range f. real x * real (?M x))) UNIV"
   580     by simp
   581   also have \<dots>
   582   proof (intro has_integral_setsum has_integral_cmult_real lmeasure_finite_has_integral
   583                real_of_ereal_pos emeasure_nonneg ballI)
   584     show *: "finite (range f)" "\<And>y. f -` {y} \<in> sets lebesgue"
   585       using simple_functionD[OF f] by auto
   586     fix y assume "real y \<noteq> 0" "y \<in> range f"
   587     with * om[OF this(2)] show "emeasure lebesgue (f -` {y}) = ereal (real (?M y))"
   588       by (auto simp: ereal_real)
   589   qed
   590   finally show "((\<lambda>x. real (\<Sum>y\<in>range f. y * ?F y x)) has_integral real (\<Sum>x\<in>range f. x * ?M x)) UNIV" .
   591 qed fact
   592 
   593 lemma bounded_realI: assumes "\<forall>x\<in>s. abs (x::real) \<le> B" shows "bounded s"
   594   unfolding bounded_def dist_real_def apply(rule_tac x=0 in exI)
   595   using assms by auto
   596 
   597 lemma simple_function_has_integral':
   598   fixes f::"'a::ordered_euclidean_space \<Rightarrow> ereal"
   599   assumes f: "simple_function lebesgue f" "\<And>x. 0 \<le> f x"
   600   and i: "integral\<^isup>S lebesgue f \<noteq> \<infinity>"
   601   shows "((\<lambda>x. real (f x)) has_integral (real (integral\<^isup>S lebesgue f))) UNIV"
   602 proof -
   603   let ?f = "\<lambda>x. if x \<in> f -` {\<infinity>} then 0 else f x"
   604   note f(1)[THEN simple_functionD(2)]
   605   then have [simp, intro]: "\<And>X. f -` X \<in> sets lebesgue" by auto
   606   have f': "simple_function lebesgue ?f"
   607     using f by (intro simple_function_If_set) auto
   608   have rng: "range ?f \<subseteq> {0..<\<infinity>}" using f by auto
   609   have "AE x in lebesgue. f x = ?f x"
   610     using simple_integral_PInf[OF f i]
   611     by (intro AE_I[where N="f -` {\<infinity>} \<inter> space lebesgue"]) auto
   612   from f(1) f' this have eq: "integral\<^isup>S lebesgue f = integral\<^isup>S lebesgue ?f"
   613     by (rule simple_integral_cong_AE)
   614   have real_eq: "\<And>x. real (f x) = real (?f x)" by auto
   615 
   616   show ?thesis
   617     unfolding eq real_eq
   618   proof (rule simple_function_has_integral[OF f' rng])
   619     fix x assume x: "x \<in> range ?f" and inf: "emeasure lebesgue (?f -` {x} \<inter> UNIV) = \<infinity>"
   620     have "x * emeasure lebesgue (?f -` {x} \<inter> UNIV) = (\<integral>\<^isup>S y. x * indicator (?f -` {x}) y \<partial>lebesgue)"
   621       using f'[THEN simple_functionD(2)]
   622       by (simp add: simple_integral_cmult_indicator)
   623     also have "\<dots> \<le> integral\<^isup>S lebesgue f"
   624       using f'[THEN simple_functionD(2)] f
   625       by (intro simple_integral_mono simple_function_mult simple_function_indicator)
   626          (auto split: split_indicator)
   627     finally show "x = 0" unfolding inf using i subsetD[OF rng x] by (auto split: split_if_asm)
   628   qed
   629 qed
   630 
   631 lemma positive_integral_has_integral:
   632   fixes f :: "'a::ordered_euclidean_space \<Rightarrow> ereal"
   633   assumes f: "f \<in> borel_measurable lebesgue" "range f \<subseteq> {0..<\<infinity>}" "integral\<^isup>P lebesgue f \<noteq> \<infinity>"
   634   shows "((\<lambda>x. real (f x)) has_integral (real (integral\<^isup>P lebesgue f))) UNIV"
   635 proof -
   636   from borel_measurable_implies_simple_function_sequence'[OF f(1)]
   637   guess u . note u = this
   638   have SUP_eq: "\<And>x. (SUP i. u i x) = f x"
   639     using u(4) f(2)[THEN subsetD] by (auto split: split_max)
   640   let ?u = "\<lambda>i x. real (u i x)"
   641   note u_eq = positive_integral_eq_simple_integral[OF u(1,5), symmetric]
   642   { fix i
   643     note u_eq
   644     also have "integral\<^isup>P lebesgue (u i) \<le> (\<integral>\<^isup>+x. max 0 (f x) \<partial>lebesgue)"
   645       by (intro positive_integral_mono) (auto intro: SUP_upper simp: u(4)[symmetric])
   646     finally have "integral\<^isup>S lebesgue (u i) \<noteq> \<infinity>"
   647       unfolding positive_integral_max_0 using f by auto }
   648   note u_fin = this
   649   then have u_int: "\<And>i. (?u i has_integral real (integral\<^isup>S lebesgue (u i))) UNIV"
   650     by (rule simple_function_has_integral'[OF u(1,5)])
   651   have "\<forall>x. \<exists>r\<ge>0. f x = ereal r"
   652   proof
   653     fix x from f(2) have "0 \<le> f x" "f x \<noteq> \<infinity>" by (auto simp: subset_eq)
   654     then show "\<exists>r\<ge>0. f x = ereal r" by (cases "f x") auto
   655   qed
   656   from choice[OF this] obtain f' where f': "f = (\<lambda>x. ereal (f' x))" "\<And>x. 0 \<le> f' x" by auto
   657 
   658   have "\<forall>i. \<exists>r. \<forall>x. 0 \<le> r x \<and> u i x = ereal (r x)"
   659   proof
   660     fix i show "\<exists>r. \<forall>x. 0 \<le> r x \<and> u i x = ereal (r x)"
   661     proof (intro choice allI)
   662       fix i x have "u i x \<noteq> \<infinity>" using u(3)[of i] by (auto simp: image_iff) metis
   663       then show "\<exists>r\<ge>0. u i x = ereal r" using u(5)[of i x] by (cases "u i x") auto
   664     qed
   665   qed
   666   from choice[OF this] obtain u' where
   667       u': "u = (\<lambda>i x. ereal (u' i x))" "\<And>i x. 0 \<le> u' i x" by (auto simp: fun_eq_iff)
   668 
   669   have convergent: "f' integrable_on UNIV \<and>
   670     (\<lambda>k. integral UNIV (u' k)) ----> integral UNIV f'"
   671   proof (intro monotone_convergence_increasing allI ballI)
   672     show int: "\<And>k. (u' k) integrable_on UNIV"
   673       using u_int unfolding integrable_on_def u' by auto
   674     show "\<And>k x. u' k x \<le> u' (Suc k) x" using u(2,3,5)
   675       by (auto simp: incseq_Suc_iff le_fun_def image_iff u' intro!: real_of_ereal_positive_mono)
   676     show "\<And>x. (\<lambda>k. u' k x) ----> f' x"
   677       using SUP_eq u(2)
   678       by (intro SUP_eq_LIMSEQ[THEN iffD1]) (auto simp: u' f' incseq_mono incseq_Suc_iff le_fun_def)
   679     show "bounded {integral UNIV (u' k)|k. True}"
   680     proof (safe intro!: bounded_realI)
   681       fix k
   682       have "\<bar>integral UNIV (u' k)\<bar> = integral UNIV (u' k)"
   683         by (intro abs_of_nonneg integral_nonneg int ballI u')
   684       also have "\<dots> = real (integral\<^isup>S lebesgue (u k))"
   685         using u_int[THEN integral_unique] by (simp add: u')
   686       also have "\<dots> = real (integral\<^isup>P lebesgue (u k))"
   687         using positive_integral_eq_simple_integral[OF u(1,5)] by simp
   688       also have "\<dots> \<le> real (integral\<^isup>P lebesgue f)" using f
   689         by (auto intro!: real_of_ereal_positive_mono positive_integral_positive
   690              positive_integral_mono SUP_upper simp: SUP_eq[symmetric])
   691       finally show "\<bar>integral UNIV (u' k)\<bar> \<le> real (integral\<^isup>P lebesgue f)" .
   692     qed
   693   qed
   694 
   695   have "integral\<^isup>P lebesgue f = ereal (integral UNIV f')"
   696   proof (rule tendsto_unique[OF trivial_limit_sequentially])
   697     have "(\<lambda>i. integral\<^isup>S lebesgue (u i)) ----> (SUP i. integral\<^isup>P lebesgue (u i))"
   698       unfolding u_eq by (intro LIMSEQ_ereal_SUPR incseq_positive_integral u)
   699     also note positive_integral_monotone_convergence_SUP
   700       [OF u(2)  borel_measurable_simple_function[OF u(1)] u(5), symmetric]
   701     finally show "(\<lambda>k. integral\<^isup>S lebesgue (u k)) ----> integral\<^isup>P lebesgue f"
   702       unfolding SUP_eq .
   703 
   704     { fix k
   705       have "0 \<le> integral\<^isup>S lebesgue (u k)"
   706         using u by (auto intro!: simple_integral_positive)
   707       then have "integral\<^isup>S lebesgue (u k) = ereal (real (integral\<^isup>S lebesgue (u k)))"
   708         using u_fin by (auto simp: ereal_real) }
   709     note * = this
   710     show "(\<lambda>k. integral\<^isup>S lebesgue (u k)) ----> ereal (integral UNIV f')"
   711       using convergent using u_int[THEN integral_unique, symmetric]
   712       by (subst *) (simp add: u')
   713   qed
   714   then show ?thesis using convergent by (simp add: f' integrable_integral)
   715 qed
   716 
   717 lemma lebesgue_integral_has_integral:
   718   fixes f :: "'a::ordered_euclidean_space \<Rightarrow> real"
   719   assumes f: "integrable lebesgue f"
   720   shows "(f has_integral (integral\<^isup>L lebesgue f)) UNIV"
   721 proof -
   722   let ?n = "\<lambda>x. real (ereal (max 0 (- f x)))" and ?p = "\<lambda>x. real (ereal (max 0 (f x)))"
   723   have *: "f = (\<lambda>x. ?p x - ?n x)" by (auto simp del: ereal_max)
   724   { fix f :: "'a \<Rightarrow> real" have "(\<integral>\<^isup>+ x. ereal (f x) \<partial>lebesgue) = (\<integral>\<^isup>+ x. ereal (max 0 (f x)) \<partial>lebesgue)"
   725       by (intro positive_integral_cong_pos) (auto split: split_max) }
   726   note eq = this
   727   show ?thesis
   728     unfolding lebesgue_integral_def
   729     apply (subst *)
   730     apply (rule has_integral_sub)
   731     unfolding eq[of f] eq[of "\<lambda>x. - f x"]
   732     apply (safe intro!: positive_integral_has_integral)
   733     using integrableD[OF f]
   734     by (auto simp: zero_ereal_def[symmetric] positive_integral_max_0  split: split_max
   735              intro!: measurable_If)
   736 qed
   737 
   738 lemma lebesgue_positive_integral_eq_borel:
   739   assumes f: "f \<in> borel_measurable borel"
   740   shows "integral\<^isup>P lebesgue f = integral\<^isup>P lborel f"
   741 proof -
   742   from f have "integral\<^isup>P lebesgue (\<lambda>x. max 0 (f x)) = integral\<^isup>P lborel (\<lambda>x. max 0 (f x))"
   743     by (auto intro!: positive_integral_subalgebra[symmetric])
   744   then show ?thesis unfolding positive_integral_max_0 .
   745 qed
   746 
   747 lemma lebesgue_integral_eq_borel:
   748   assumes "f \<in> borel_measurable borel"
   749   shows "integrable lebesgue f \<longleftrightarrow> integrable lborel f" (is ?P)
   750     and "integral\<^isup>L lebesgue f = integral\<^isup>L lborel f" (is ?I)
   751 proof -
   752   have "sets lborel \<subseteq> sets lebesgue" by auto
   753   from integral_subalgebra[of f lborel, OF _ this _ _] assms
   754   show ?P ?I by auto
   755 qed
   756 
   757 lemma borel_integral_has_integral:
   758   fixes f::"'a::ordered_euclidean_space => real"
   759   assumes f:"integrable lborel f"
   760   shows "(f has_integral (integral\<^isup>L lborel f)) UNIV"
   761 proof -
   762   have borel: "f \<in> borel_measurable borel"
   763     using f unfolding integrable_def by auto
   764   from f show ?thesis
   765     using lebesgue_integral_has_integral[of f]
   766     unfolding lebesgue_integral_eq_borel[OF borel] by simp
   767 qed
   768 
   769 subsection {* Equivalence between product spaces and euclidean spaces *}
   770 
   771 definition e2p :: "'a::ordered_euclidean_space \<Rightarrow> (nat \<Rightarrow> real)" where
   772   "e2p x = (\<lambda>i\<in>{..<DIM('a)}. x$$i)"
   773 
   774 definition p2e :: "(nat \<Rightarrow> real) \<Rightarrow> 'a::ordered_euclidean_space" where
   775   "p2e x = (\<chi>\<chi> i. x i)"
   776 
   777 lemma e2p_p2e[simp]:
   778   "x \<in> extensional {..<DIM('a)} \<Longrightarrow> e2p (p2e x::'a::ordered_euclidean_space) = x"
   779   by (auto simp: fun_eq_iff extensional_def p2e_def e2p_def)
   780 
   781 lemma p2e_e2p[simp]:
   782   "p2e (e2p x) = (x::'a::ordered_euclidean_space)"
   783   by (auto simp: euclidean_eq[where 'a='a] p2e_def e2p_def)
   784 
   785 interpretation lborel_product: product_sigma_finite "\<lambda>x. lborel::real measure"
   786   by default
   787 
   788 interpretation lborel_space: finite_product_sigma_finite "\<lambda>x. lborel::real measure" "{..<n}" for n :: nat
   789   by default auto
   790 
   791 lemma bchoice_iff: "(\<forall>x\<in>A. \<exists>y. P x y) \<longleftrightarrow> (\<exists>f. \<forall>x\<in>A. P x (f x))"
   792   by metis
   793 
   794 lemma sets_product_borel:
   795   assumes I: "finite I"
   796   shows "sets (\<Pi>\<^isub>M i\<in>I. lborel) = sigma_sets (\<Pi>\<^isub>E i\<in>I. UNIV) { \<Pi>\<^isub>E i\<in>I. {..< x i :: real} | x. True}" (is "_ = ?G")
   797 proof (subst sigma_prod_algebra_sigma_eq[where S="\<lambda>_ i::nat. {..<real i}" and E="\<lambda>_. range lessThan", OF I])
   798   show "sigma_sets (space (Pi\<^isub>M I (\<lambda>i. lborel))) {Pi\<^isub>E I F |F. \<forall>i\<in>I. F i \<in> range lessThan} = ?G"
   799     by (intro arg_cong2[where f=sigma_sets]) (auto simp: space_PiM image_iff bchoice_iff)
   800 qed (auto simp: borel_eq_lessThan incseq_def reals_Archimedean2 image_iff intro: real_natceiling_ge)
   801 
   802 lemma measurable_e2p:
   803   "e2p \<in> measurable (borel::'a::ordered_euclidean_space measure) (\<Pi>\<^isub>M i\<in>{..<DIM('a)}. (lborel :: real measure))"
   804 proof (rule measurable_sigma_sets[OF sets_product_borel])
   805   fix A :: "(nat \<Rightarrow> real) set" assume "A \<in> {\<Pi>\<^isub>E i\<in>{..<DIM('a)}. {..<x i} |x. True} "
   806   then obtain x where  "A = (\<Pi>\<^isub>E i\<in>{..<DIM('a)}. {..<x i})" by auto
   807   then have "e2p -` A = {..< (\<chi>\<chi> i. x i) :: 'a}"
   808     using DIM_positive by (auto simp add: Pi_iff set_eq_iff e2p_def
   809       euclidean_eq[where 'a='a] eucl_less[where 'a='a])
   810   then show "e2p -` A \<inter> space (borel::'a measure) \<in> sets borel" by simp
   811 qed (auto simp: e2p_def)
   812 
   813 lemma measurable_p2e:
   814   "p2e \<in> measurable (\<Pi>\<^isub>M i\<in>{..<DIM('a)}. (lborel :: real measure))
   815     (borel :: 'a::ordered_euclidean_space measure)"
   816   (is "p2e \<in> measurable ?P _")
   817 proof (safe intro!: borel_measurable_iff_halfspace_le[THEN iffD2])
   818   fix x i
   819   let ?A = "{w \<in> space ?P. (p2e w :: 'a) $$ i \<le> x}"
   820   assume "i < DIM('a)"
   821   then have "?A = (\<Pi>\<^isub>E j\<in>{..<DIM('a)}. if i = j then {.. x} else UNIV)"
   822     using DIM_positive by (auto simp: space_PiM p2e_def split: split_if_asm)
   823   then show "?A \<in> sets ?P"
   824     by auto
   825 qed
   826 
   827 lemma Int_stable_atLeastAtMost:
   828   fixes x::"'a::ordered_euclidean_space"
   829   shows "Int_stable (range (\<lambda>(a, b::'a). {a..b}))"
   830   by (auto simp: inter_interval Int_stable_def)
   831 
   832 lemma lborel_eqI:
   833   fixes M :: "'a::ordered_euclidean_space measure"
   834   assumes emeasure_eq: "\<And>a b. emeasure M {a .. b} = content {a .. b}"
   835   assumes sets_eq: "sets M = sets borel"
   836   shows "lborel = M"
   837 proof (rule measure_eqI_generator_eq[OF Int_stable_atLeastAtMost])
   838   let ?P = "\<Pi>\<^isub>M i\<in>{..<DIM('a::ordered_euclidean_space)}. lborel"
   839   let ?E = "range (\<lambda>(a, b). {a..b} :: 'a set)"
   840   show "?E \<subseteq> Pow UNIV" "sets lborel = sigma_sets UNIV ?E" "sets M = sigma_sets UNIV ?E"
   841     by (simp_all add: borel_eq_atLeastAtMost sets_eq)
   842   
   843   show "range cube \<subseteq> ?E" unfolding cube_def [abs_def] by auto
   844   show "incseq cube" using cube_subset_Suc by (auto intro!: incseq_SucI)
   845   { fix x :: 'a have "\<exists>n. x \<in> cube n" using mem_big_cube[of x] by fastforce }
   846   then show "(\<Union>i. cube i :: 'a set) = UNIV" by auto
   847 
   848   { fix i show "emeasure lborel (cube i) \<noteq> \<infinity>" unfolding cube_def by auto }
   849   { fix X assume "X \<in> ?E" then show "emeasure lborel X = emeasure M X"
   850       by (auto simp: emeasure_eq) }
   851 qed
   852 
   853 lemma lborel_eq_lborel_space:
   854   "(lborel :: 'a measure) = distr (\<Pi>\<^isub>M i\<in>{..<DIM('a::ordered_euclidean_space)}. lborel) lborel p2e"
   855   (is "?B = ?D")
   856 proof (rule lborel_eqI)
   857   show "sets ?D = sets borel" by simp
   858   let ?P = "(\<Pi>\<^isub>M i\<in>{..<DIM('a::ordered_euclidean_space)}. lborel)"
   859   fix a b :: 'a
   860   have *: "p2e -` {a .. b} \<inter> space ?P = (\<Pi>\<^isub>E i\<in>{..<DIM('a)}. {a $$ i .. b $$ i})"
   861     by (auto simp: Pi_iff eucl_le[where 'a='a] p2e_def space_PiM)
   862   have "emeasure ?P (p2e -` {a..b} \<inter> space ?P) = content {a..b}"
   863   proof cases
   864     assume "{a..b} \<noteq> {}"
   865     then have "a \<le> b"
   866       by (simp add: interval_ne_empty eucl_le[where 'a='a])
   867     then have "emeasure lborel {a..b} = (\<Prod>x<DIM('a). emeasure lborel {a $$ x .. b $$ x})"
   868       by (auto simp: content_closed_interval eucl_le[where 'a='a]
   869                intro!: setprod_ereal[symmetric])
   870     also have "\<dots> = emeasure ?P (p2e -` {a..b} \<inter> space ?P)"
   871       unfolding * by (subst lborel_space.measure_times) auto
   872     finally show ?thesis by simp
   873   qed simp
   874   then show "emeasure ?D {a .. b} = content {a .. b}"
   875     by (simp add: emeasure_distr measurable_p2e)
   876 qed
   877 
   878 lemma borel_fubini_positiv_integral:
   879   fixes f :: "'a::ordered_euclidean_space \<Rightarrow> ereal"
   880   assumes f: "f \<in> borel_measurable borel"
   881   shows "integral\<^isup>P lborel f = \<integral>\<^isup>+x. f (p2e x) \<partial>(\<Pi>\<^isub>M i\<in>{..<DIM('a)}. lborel)"
   882   by (subst lborel_eq_lborel_space) (simp add: positive_integral_distr measurable_p2e f)
   883 
   884 lemma borel_fubini_integrable:
   885   fixes f :: "'a::ordered_euclidean_space \<Rightarrow> real"
   886   shows "integrable lborel f \<longleftrightarrow>
   887     integrable (\<Pi>\<^isub>M i\<in>{..<DIM('a)}. lborel) (\<lambda>x. f (p2e x))"
   888     (is "_ \<longleftrightarrow> integrable ?B ?f")
   889 proof
   890   assume "integrable lborel f"
   891   moreover then have f: "f \<in> borel_measurable borel"
   892     by auto
   893   moreover with measurable_p2e
   894   have "f \<circ> p2e \<in> borel_measurable ?B"
   895     by (rule measurable_comp)
   896   ultimately show "integrable ?B ?f"
   897     by (simp add: comp_def borel_fubini_positiv_integral integrable_def)
   898 next
   899   assume "integrable ?B ?f"
   900   moreover
   901   then have "?f \<circ> e2p \<in> borel_measurable (borel::'a measure)"
   902     by (auto intro!: measurable_e2p)
   903   then have "f \<in> borel_measurable borel"
   904     by (simp cong: measurable_cong)
   905   ultimately show "integrable lborel f"
   906     by (simp add: borel_fubini_positiv_integral integrable_def)
   907 qed
   908 
   909 lemma borel_fubini:
   910   fixes f :: "'a::ordered_euclidean_space \<Rightarrow> real"
   911   assumes f: "f \<in> borel_measurable borel"
   912   shows "integral\<^isup>L lborel f = \<integral>x. f (p2e x) \<partial>((\<Pi>\<^isub>M i\<in>{..<DIM('a)}. lborel))"
   913   using f by (simp add: borel_fubini_positiv_integral lebesgue_integral_def)
   914 
   915 lemma borel_measurable_indicator':
   916   "A \<in> sets borel \<Longrightarrow> f \<in> borel_measurable M \<Longrightarrow> (\<lambda>x. indicator A (f x)) \<in> borel_measurable M"
   917   using measurable_comp[OF _ borel_measurable_indicator, of f M borel A] by (auto simp add: comp_def)
   918 
   919 lemma lebesgue_real_affine:
   920   fixes c :: real assumes "c \<noteq> 0"
   921   shows "lborel = density (distr lborel borel (\<lambda>x. t + c * x)) (\<lambda>_. \<bar>c\<bar>)" (is "_ = ?D")
   922 proof (rule lborel_eqI)
   923   fix a b show "emeasure ?D {a..b} = content {a .. b}"
   924   proof cases
   925     assume "0 < c"
   926     then have "(\<lambda>x. t + c * x) -` {a..b} = {(a - t) / c .. (b - t) / c}"
   927       by (auto simp: field_simps)
   928     with `0 < c` show ?thesis
   929       by (cases "a \<le> b")
   930          (auto simp: field_simps emeasure_density positive_integral_distr positive_integral_cmult
   931                      borel_measurable_indicator' emeasure_distr)
   932   next
   933     assume "\<not> 0 < c" with `c \<noteq> 0` have "c < 0" by auto
   934     then have *: "(\<lambda>x. t + c * x) -` {a..b} = {(b - t) / c .. (a - t) / c}"
   935       by (auto simp: field_simps)
   936     with `c < 0` show ?thesis
   937       by (cases "a \<le> b")
   938          (auto simp: field_simps emeasure_density positive_integral_distr
   939                      positive_integral_cmult borel_measurable_indicator' emeasure_distr)
   940   qed
   941 qed simp
   942 
   943 end