src/HOL/Library/List_Prefix.thy
author wenzelm
Thu Nov 08 20:52:27 2007 +0100 (2007-11-08)
changeset 25356 059c03630d6e
parent 25355 69c0a39ba028
child 25564 4ca31a3706a4
permissions -rw-r--r--
tuned presentation;
     1 (*  Title:      HOL/Library/List_Prefix.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow and Markus Wenzel, TU Muenchen
     4 *)
     5 
     6 header {* List prefixes and postfixes *}
     7 
     8 theory List_Prefix
     9 imports Main
    10 begin
    11 
    12 subsection {* Prefix order on lists *}
    13 
    14 instance list :: (type) ord ..
    15 
    16 defs (overloaded)
    17   prefix_def: "xs \<le> ys == \<exists>zs. ys = xs @ zs"
    18   strict_prefix_def: "xs < ys == xs \<le> ys \<and> xs \<noteq> (ys::'a list)"
    19 
    20 instance list :: (type) order
    21   by intro_classes (auto simp add: prefix_def strict_prefix_def)
    22 
    23 lemma prefixI [intro?]: "ys = xs @ zs ==> xs \<le> ys"
    24   unfolding prefix_def by blast
    25 
    26 lemma prefixE [elim?]:
    27   assumes "xs \<le> ys"
    28   obtains zs where "ys = xs @ zs"
    29   using assms unfolding prefix_def by blast
    30 
    31 lemma strict_prefixI' [intro?]: "ys = xs @ z # zs ==> xs < ys"
    32   unfolding strict_prefix_def prefix_def by blast
    33 
    34 lemma strict_prefixE' [elim?]:
    35   assumes "xs < ys"
    36   obtains z zs where "ys = xs @ z # zs"
    37 proof -
    38   from `xs < ys` obtain us where "ys = xs @ us" and "xs \<noteq> ys"
    39     unfolding strict_prefix_def prefix_def by blast
    40   with that show ?thesis by (auto simp add: neq_Nil_conv)
    41 qed
    42 
    43 lemma strict_prefixI [intro?]: "xs \<le> ys ==> xs \<noteq> ys ==> xs < (ys::'a list)"
    44   unfolding strict_prefix_def by blast
    45 
    46 lemma strict_prefixE [elim?]:
    47   fixes xs ys :: "'a list"
    48   assumes "xs < ys"
    49   obtains "xs \<le> ys" and "xs \<noteq> ys"
    50   using assms unfolding strict_prefix_def by blast
    51 
    52 
    53 subsection {* Basic properties of prefixes *}
    54 
    55 theorem Nil_prefix [iff]: "[] \<le> xs"
    56   by (simp add: prefix_def)
    57 
    58 theorem prefix_Nil [simp]: "(xs \<le> []) = (xs = [])"
    59   by (induct xs) (simp_all add: prefix_def)
    60 
    61 lemma prefix_snoc [simp]: "(xs \<le> ys @ [y]) = (xs = ys @ [y] \<or> xs \<le> ys)"
    62 proof
    63   assume "xs \<le> ys @ [y]"
    64   then obtain zs where zs: "ys @ [y] = xs @ zs" ..
    65   show "xs = ys @ [y] \<or> xs \<le> ys"
    66   proof (cases zs rule: rev_cases)
    67     assume "zs = []"
    68     with zs have "xs = ys @ [y]" by simp
    69     then show ?thesis ..
    70   next
    71     fix z zs' assume "zs = zs' @ [z]"
    72     with zs have "ys = xs @ zs'" by simp
    73     then have "xs \<le> ys" ..
    74     then show ?thesis ..
    75   qed
    76 next
    77   assume "xs = ys @ [y] \<or> xs \<le> ys"
    78   then show "xs \<le> ys @ [y]"
    79   proof
    80     assume "xs = ys @ [y]"
    81     then show ?thesis by simp
    82   next
    83     assume "xs \<le> ys"
    84     then obtain zs where "ys = xs @ zs" ..
    85     then have "ys @ [y] = xs @ (zs @ [y])" by simp
    86     then show ?thesis ..
    87   qed
    88 qed
    89 
    90 lemma Cons_prefix_Cons [simp]: "(x # xs \<le> y # ys) = (x = y \<and> xs \<le> ys)"
    91   by (auto simp add: prefix_def)
    92 
    93 lemma same_prefix_prefix [simp]: "(xs @ ys \<le> xs @ zs) = (ys \<le> zs)"
    94   by (induct xs) simp_all
    95 
    96 lemma same_prefix_nil [iff]: "(xs @ ys \<le> xs) = (ys = [])"
    97 proof -
    98   have "(xs @ ys \<le> xs @ []) = (ys \<le> [])" by (rule same_prefix_prefix)
    99   then show ?thesis by simp
   100 qed
   101 
   102 lemma prefix_prefix [simp]: "xs \<le> ys ==> xs \<le> ys @ zs"
   103 proof -
   104   assume "xs \<le> ys"
   105   then obtain us where "ys = xs @ us" ..
   106   then have "ys @ zs = xs @ (us @ zs)" by simp
   107   then show ?thesis ..
   108 qed
   109 
   110 lemma append_prefixD: "xs @ ys \<le> zs \<Longrightarrow> xs \<le> zs"
   111   by (auto simp add: prefix_def)
   112 
   113 theorem prefix_Cons: "(xs \<le> y # ys) = (xs = [] \<or> (\<exists>zs. xs = y # zs \<and> zs \<le> ys))"
   114   by (cases xs) (auto simp add: prefix_def)
   115 
   116 theorem prefix_append:
   117     "(xs \<le> ys @ zs) = (xs \<le> ys \<or> (\<exists>us. xs = ys @ us \<and> us \<le> zs))"
   118   apply (induct zs rule: rev_induct)
   119    apply force
   120   apply (simp del: append_assoc add: append_assoc [symmetric])
   121   apply simp
   122   apply blast
   123   done
   124 
   125 lemma append_one_prefix:
   126     "xs \<le> ys ==> length xs < length ys ==> xs @ [ys ! length xs] \<le> ys"
   127   apply (unfold prefix_def)
   128   apply (auto simp add: nth_append)
   129   apply (case_tac zs)
   130    apply auto
   131   done
   132 
   133 theorem prefix_length_le: "xs \<le> ys ==> length xs \<le> length ys"
   134   by (auto simp add: prefix_def)
   135 
   136 lemma prefix_same_cases:
   137     "(xs\<^isub>1::'a list) \<le> ys \<Longrightarrow> xs\<^isub>2 \<le> ys \<Longrightarrow> xs\<^isub>1 \<le> xs\<^isub>2 \<or> xs\<^isub>2 \<le> xs\<^isub>1"
   138   apply (simp add: prefix_def)
   139   apply (erule exE)+
   140   apply (simp add: append_eq_append_conv_if split: if_splits)
   141    apply (rule disjI2)
   142    apply (rule_tac x = "drop (size xs\<^isub>2) xs\<^isub>1" in exI)
   143    apply clarify
   144    apply (drule sym)
   145    apply (insert append_take_drop_id [of "length xs\<^isub>2" xs\<^isub>1])
   146    apply simp
   147   apply (rule disjI1)
   148   apply (rule_tac x = "drop (size xs\<^isub>1) xs\<^isub>2" in exI)
   149   apply clarify
   150   apply (insert append_take_drop_id [of "length xs\<^isub>1" xs\<^isub>2])
   151   apply simp
   152   done
   153 
   154 lemma set_mono_prefix:
   155     "xs \<le> ys \<Longrightarrow> set xs \<subseteq> set ys"
   156   by (auto simp add: prefix_def)
   157 
   158 lemma take_is_prefix:
   159   "take n xs \<le> xs"
   160   apply (simp add: prefix_def)
   161   apply (rule_tac x="drop n xs" in exI)
   162   apply simp
   163   done
   164 
   165 lemma map_prefixI:
   166   "xs \<le> ys \<Longrightarrow> map f xs \<le> map f ys"
   167   by (clarsimp simp: prefix_def)
   168 
   169 lemma prefix_length_less:
   170   "xs < ys \<Longrightarrow> length xs < length ys"
   171   apply (clarsimp simp: strict_prefix_def)
   172   apply (frule prefix_length_le)
   173   apply (rule ccontr, simp)
   174   apply (clarsimp simp: prefix_def)
   175   done
   176 
   177 lemma strict_prefix_simps [simp]:
   178   "xs < [] = False"
   179   "[] < (x # xs) = True"
   180   "(x # xs) < (y # ys) = (x = y \<and> xs < ys)"
   181   by (simp_all add: strict_prefix_def cong: conj_cong)
   182 
   183 lemma take_strict_prefix:
   184   "xs < ys \<Longrightarrow> take n xs < ys"
   185   apply (induct n arbitrary: xs ys)
   186    apply (case_tac ys, simp_all)[1]
   187   apply (case_tac xs, simp)
   188   apply (case_tac ys, simp_all)
   189   done
   190 
   191 lemma not_prefix_cases:
   192   assumes pfx: "\<not> ps \<le> ls"
   193   obtains
   194     (c1) "ps \<noteq> []" and "ls = []"
   195   | (c2) a as x xs where "ps = a#as" and "ls = x#xs" and "x = a" and "\<not> as \<le> xs"
   196   | (c3) a as x xs where "ps = a#as" and "ls = x#xs" and "x \<noteq> a"
   197 proof (cases ps)
   198   case Nil
   199   then show ?thesis using pfx by simp
   200 next
   201   case (Cons a as)
   202   then have c: "ps = a#as" .
   203 
   204   show ?thesis
   205   proof (cases ls)
   206     case Nil
   207     have "ps \<noteq> []" by (simp add: Nil Cons)
   208     from this and Nil show ?thesis by (rule c1)
   209   next
   210     case (Cons x xs)
   211     show ?thesis
   212     proof (cases "x = a")
   213       case True
   214       have "\<not> as \<le> xs" using pfx c Cons True by simp
   215       with c Cons True show ?thesis by (rule c2)
   216     next
   217       case False
   218       with c Cons show ?thesis by (rule c3)
   219     qed
   220   qed
   221 qed
   222 
   223 lemma not_prefix_induct [consumes 1, case_names Nil Neq Eq]:
   224   assumes np: "\<not> ps \<le> ls"
   225     and base: "\<And>x xs. P (x#xs) []"
   226     and r1: "\<And>x xs y ys. x \<noteq> y \<Longrightarrow> P (x#xs) (y#ys)"
   227     and r2: "\<And>x xs y ys. \<lbrakk> x = y; \<not> xs \<le> ys; P xs ys \<rbrakk> \<Longrightarrow> P (x#xs) (y#ys)"
   228   shows "P ps ls" using np
   229 proof (induct ls arbitrary: ps)
   230   case Nil then show ?case
   231     by (auto simp: neq_Nil_conv elim!: not_prefix_cases intro!: base)
   232 next
   233   case (Cons y ys)
   234   then have npfx: "\<not> ps \<le> (y # ys)" by simp
   235   then obtain x xs where pv: "ps = x # xs"
   236     by (rule not_prefix_cases) auto
   237 
   238   from Cons
   239   have ih: "\<And>ps. \<not>ps \<le> ys \<Longrightarrow> P ps ys" by simp
   240 
   241   show ?case using npfx
   242     by (simp only: pv) (erule not_prefix_cases, auto intro: r1 r2 ih)
   243 qed
   244 
   245 
   246 subsection {* Parallel lists *}
   247 
   248 definition
   249   parallel :: "'a list => 'a list => bool"  (infixl "\<parallel>" 50) where
   250   "(xs \<parallel> ys) = (\<not> xs \<le> ys \<and> \<not> ys \<le> xs)"
   251 
   252 lemma parallelI [intro]: "\<not> xs \<le> ys ==> \<not> ys \<le> xs ==> xs \<parallel> ys"
   253   unfolding parallel_def by blast
   254 
   255 lemma parallelE [elim]:
   256   assumes "xs \<parallel> ys"
   257   obtains "\<not> xs \<le> ys \<and> \<not> ys \<le> xs"
   258   using assms unfolding parallel_def by blast
   259 
   260 theorem prefix_cases:
   261   obtains "xs \<le> ys" | "ys < xs" | "xs \<parallel> ys"
   262   unfolding parallel_def strict_prefix_def by blast
   263 
   264 theorem parallel_decomp:
   265   "xs \<parallel> ys ==> \<exists>as b bs c cs. b \<noteq> c \<and> xs = as @ b # bs \<and> ys = as @ c # cs"
   266 proof (induct xs rule: rev_induct)
   267   case Nil
   268   then have False by auto
   269   then show ?case ..
   270 next
   271   case (snoc x xs)
   272   show ?case
   273   proof (rule prefix_cases)
   274     assume le: "xs \<le> ys"
   275     then obtain ys' where ys: "ys = xs @ ys'" ..
   276     show ?thesis
   277     proof (cases ys')
   278       assume "ys' = []" with ys have "xs = ys" by simp
   279       with snoc have "[x] \<parallel> []" by auto
   280       then have False by blast
   281       then show ?thesis ..
   282     next
   283       fix c cs assume ys': "ys' = c # cs"
   284       with snoc ys have "xs @ [x] \<parallel> xs @ c # cs" by (simp only:)
   285       then have "x \<noteq> c" by auto
   286       moreover have "xs @ [x] = xs @ x # []" by simp
   287       moreover from ys ys' have "ys = xs @ c # cs" by (simp only:)
   288       ultimately show ?thesis by blast
   289     qed
   290   next
   291     assume "ys < xs" then have "ys \<le> xs @ [x]" by (simp add: strict_prefix_def)
   292     with snoc have False by blast
   293     then show ?thesis ..
   294   next
   295     assume "xs \<parallel> ys"
   296     with snoc obtain as b bs c cs where neq: "(b::'a) \<noteq> c"
   297       and xs: "xs = as @ b # bs" and ys: "ys = as @ c # cs"
   298       by blast
   299     from xs have "xs @ [x] = as @ b # (bs @ [x])" by simp
   300     with neq ys show ?thesis by blast
   301   qed
   302 qed
   303 
   304 lemma parallel_append:
   305   "a \<parallel> b \<Longrightarrow> a @ c \<parallel> b @ d"
   306   by (rule parallelI)
   307      (erule parallelE, erule conjE,
   308             induct rule: not_prefix_induct, simp+)+
   309 
   310 lemma parallel_appendI:
   311   "\<lbrakk> xs \<parallel> ys; x = xs @ xs' ; y = ys @ ys' \<rbrakk> \<Longrightarrow> x \<parallel> y"
   312   by simp (rule parallel_append)
   313 
   314 lemma parallel_commute: "(a \<parallel> b) = (b \<parallel> a)"
   315   unfolding parallel_def by auto
   316 
   317 
   318 subsection {* Postfix order on lists *}
   319 
   320 definition
   321   postfix :: "'a list => 'a list => bool"  ("(_/ >>= _)" [51, 50] 50) where
   322   "(xs >>= ys) = (\<exists>zs. xs = zs @ ys)"
   323 
   324 lemma postfixI [intro?]: "xs = zs @ ys ==> xs >>= ys"
   325   unfolding postfix_def by blast
   326 
   327 lemma postfixE [elim?]:
   328   assumes "xs >>= ys"
   329   obtains zs where "xs = zs @ ys"
   330   using assms unfolding postfix_def by blast
   331 
   332 lemma postfix_refl [iff]: "xs >>= xs"
   333   by (auto simp add: postfix_def)
   334 lemma postfix_trans: "\<lbrakk>xs >>= ys; ys >>= zs\<rbrakk> \<Longrightarrow> xs >>= zs"
   335   by (auto simp add: postfix_def)
   336 lemma postfix_antisym: "\<lbrakk>xs >>= ys; ys >>= xs\<rbrakk> \<Longrightarrow> xs = ys"
   337   by (auto simp add: postfix_def)
   338 
   339 lemma Nil_postfix [iff]: "xs >>= []"
   340   by (simp add: postfix_def)
   341 lemma postfix_Nil [simp]: "([] >>= xs) = (xs = [])"
   342   by (auto simp add: postfix_def)
   343 
   344 lemma postfix_ConsI: "xs >>= ys \<Longrightarrow> x#xs >>= ys"
   345   by (auto simp add: postfix_def)
   346 lemma postfix_ConsD: "xs >>= y#ys \<Longrightarrow> xs >>= ys"
   347   by (auto simp add: postfix_def)
   348 
   349 lemma postfix_appendI: "xs >>= ys \<Longrightarrow> zs @ xs >>= ys"
   350   by (auto simp add: postfix_def)
   351 lemma postfix_appendD: "xs >>= zs @ ys \<Longrightarrow> xs >>= ys"
   352   by (auto simp add: postfix_def)
   353 
   354 lemma postfix_is_subset: "xs >>= ys ==> set ys \<subseteq> set xs"
   355 proof -
   356   assume "xs >>= ys"
   357   then obtain zs where "xs = zs @ ys" ..
   358   then show ?thesis by (induct zs) auto
   359 qed
   360 
   361 lemma postfix_ConsD2: "x#xs >>= y#ys ==> xs >>= ys"
   362 proof -
   363   assume "x#xs >>= y#ys"
   364   then obtain zs where "x#xs = zs @ y#ys" ..
   365   then show ?thesis
   366     by (induct zs) (auto intro!: postfix_appendI postfix_ConsI)
   367 qed
   368 
   369 lemma postfix_to_prefix: "xs >>= ys \<longleftrightarrow> rev ys \<le> rev xs"
   370 proof
   371   assume "xs >>= ys"
   372   then obtain zs where "xs = zs @ ys" ..
   373   then have "rev xs = rev ys @ rev zs" by simp
   374   then show "rev ys <= rev xs" ..
   375 next
   376   assume "rev ys <= rev xs"
   377   then obtain zs where "rev xs = rev ys @ zs" ..
   378   then have "rev (rev xs) = rev zs @ rev (rev ys)" by simp
   379   then have "xs = rev zs @ ys" by simp
   380   then show "xs >>= ys" ..
   381 qed
   382 
   383 lemma distinct_postfix:
   384   assumes "distinct xs"
   385     and "xs >>= ys"
   386   shows "distinct ys"
   387   using assms by (clarsimp elim!: postfixE)
   388 
   389 lemma postfix_map:
   390   assumes "xs >>= ys"
   391   shows "map f xs >>= map f ys"
   392   using assms by (auto elim!: postfixE intro: postfixI)
   393 
   394 lemma postfix_drop: "as >>= drop n as"
   395   unfolding postfix_def
   396   by (rule exI [where x = "take n as"]) simp
   397 
   398 lemma postfix_take:
   399     "xs >>= ys \<Longrightarrow> xs = take (length xs - length ys) xs @ ys"
   400   by (clarsimp elim!: postfixE)
   401 
   402 lemma parallelD1: "x \<parallel> y \<Longrightarrow> \<not> x \<le> y"
   403   by blast
   404 
   405 lemma parallelD2: "x \<parallel> y \<Longrightarrow> \<not> y \<le> x"
   406   by blast
   407 
   408 lemma parallel_Nil1 [simp]: "\<not> x \<parallel> []"
   409   unfolding parallel_def by simp
   410 
   411 lemma parallel_Nil2 [simp]: "\<not> [] \<parallel> x"
   412   unfolding parallel_def by simp
   413 
   414 lemma Cons_parallelI1:
   415   "a \<noteq> b \<Longrightarrow> a # as \<parallel> b # bs" by auto
   416 
   417 lemma Cons_parallelI2:
   418   "\<lbrakk> a = b; as \<parallel> bs \<rbrakk> \<Longrightarrow> a # as \<parallel> b # bs"
   419   apply simp
   420   apply (rule parallelI)
   421    apply simp
   422    apply (erule parallelD1)
   423   apply simp
   424   apply (erule parallelD2)
   425  done
   426 
   427 lemma not_equal_is_parallel:
   428   assumes neq: "xs \<noteq> ys"
   429     and len: "length xs = length ys"
   430   shows "xs \<parallel> ys"
   431   using len neq
   432 proof (induct rule: list_induct2)
   433   case 1
   434   then show ?case by simp
   435 next
   436   case (2 a as b bs)
   437   have ih: "as \<noteq> bs \<Longrightarrow> as \<parallel> bs" by fact
   438 
   439   show ?case
   440   proof (cases "a = b")
   441     case True
   442     then have "as \<noteq> bs" using 2 by simp
   443     then show ?thesis by (rule Cons_parallelI2 [OF True ih])
   444   next
   445     case False
   446     then show ?thesis by (rule Cons_parallelI1)
   447   qed
   448 qed
   449 
   450 
   451 subsection {* Executable code *}
   452 
   453 lemma less_eq_code [code func]:
   454     "([]\<Colon>'a\<Colon>{eq, ord} list) \<le> xs \<longleftrightarrow> True"
   455     "(x\<Colon>'a\<Colon>{eq, ord}) # xs \<le> [] \<longleftrightarrow> False"
   456     "(x\<Colon>'a\<Colon>{eq, ord}) # xs \<le> y # ys \<longleftrightarrow> x = y \<and> xs \<le> ys"
   457   by simp_all
   458 
   459 lemma less_code [code func]:
   460     "xs < ([]\<Colon>'a\<Colon>{eq, ord} list) \<longleftrightarrow> False"
   461     "[] < (x\<Colon>'a\<Colon>{eq, ord})# xs \<longleftrightarrow> True"
   462     "(x\<Colon>'a\<Colon>{eq, ord}) # xs < y # ys \<longleftrightarrow> x = y \<and> xs < ys"
   463   unfolding strict_prefix_def by auto
   464 
   465 lemmas [code func] = postfix_to_prefix
   466 
   467 end