src/Pure/Thy/present.ML
author wenzelm
Wed Feb 27 12:45:19 2013 +0100 (2013-02-27)
changeset 51293 05b1bbae748d
parent 50707 5b2bf7611662
child 51398 c3d02b3518c2
permissions -rw-r--r--
discontinued obsolete 'uses' within theory header;
     1 (*  Title:      Pure/Thy/present.ML
     2     Author:     Markus Wenzel and Stefan Berghofer, TU Muenchen
     3 
     4 Theory presentation: HTML, graph files, (PDF)LaTeX documents.
     5 *)
     6 
     7 signature BASIC_PRESENT =
     8 sig
     9   val no_document: ('a -> 'b) -> 'a -> 'b  (*not thread-safe!*)
    10 end;
    11 
    12 signature PRESENT =
    13 sig
    14   include BASIC_PRESENT
    15   val session_name: theory -> string
    16   val read_variant: string -> string * string
    17   val init: bool -> bool -> string -> string -> bool -> string -> (string * string) list ->
    18     string list -> string -> bool * string -> Url.T option * bool -> bool ->
    19     theory list -> unit  (*not thread-safe!*)
    20   val finish: unit -> unit  (*not thread-safe!*)
    21   val init_theory: string -> unit
    22   val theory_source: string -> (unit -> HTML.text) -> unit
    23   val theory_output: string -> string -> unit
    24   val begin_theory: int -> Path.T -> theory -> theory
    25   val drafts: string -> Path.T list -> Path.T
    26 end;
    27 
    28 structure Present: PRESENT =
    29 struct
    30 
    31 
    32 (** paths **)
    33 
    34 val tex_ext = Path.ext "tex";
    35 val tex_path = tex_ext o Path.basic;
    36 val html_ext = Path.ext "html";
    37 val html_path = html_ext o Path.basic;
    38 val index_path = Path.basic "index.html";
    39 val readme_html_path = Path.basic "README.html";
    40 val readme_path = Path.basic "README";
    41 val documentN = "document";
    42 val document_path = Path.basic documentN;
    43 val doc_indexN = "session";
    44 val graph_path = Path.basic "session.graph";
    45 val graph_pdf_path = Path.basic "session_graph.pdf";
    46 val graph_eps_path = Path.basic "session_graph.eps";
    47 
    48 val session_path = Path.basic ".session";
    49 val session_entries_path = Path.explode ".session/entries";
    50 val pre_index_path = Path.explode ".session/pre-index";
    51 
    52 fun mk_rel_path [] ys = Path.make ys
    53   | mk_rel_path xs [] = Path.appends (replicate (length xs) Path.parent)
    54   | mk_rel_path (ps as x :: xs) (qs as y :: ys) = if x = y then mk_rel_path xs ys else
    55       Path.appends (replicate (length ps) Path.parent @ [Path.make qs]);
    56 
    57 fun show_path path = Path.implode (Path.append (File.pwd ()) path);
    58 
    59 
    60 
    61 (** additional theory data **)
    62 
    63 structure Browser_Info = Theory_Data
    64 (
    65   type T = {name: string, session: string list, is_local: bool};
    66   val empty = {name = "", session = [], is_local = false}: T;
    67   fun extend _ = empty;
    68   fun merge _ = empty;
    69 );
    70 
    71 val put_info = Browser_Info.put;
    72 val get_info = Browser_Info.get;
    73 val session_name = #name o get_info;
    74 
    75 
    76 
    77 (** graphs **)
    78 
    79 fun ID_of sess s = space_implode "/" (sess @ [s]);
    80 fun ID_of_thy thy = ID_of (#session (get_info thy)) (Context.theory_name thy);
    81 
    82 
    83 (*retrieve graph data from initial collection of theories*)
    84 fun init_graph remote_path curr_sess = rev o map (fn thy =>
    85   let
    86     val name = Context.theory_name thy;
    87     val {name = sess_name, session, is_local} = get_info thy;
    88     val entry =
    89      {name = name, ID = ID_of session name, dir = sess_name,
    90       path =
    91         if null session then "" else
    92         if is_some remote_path andalso not is_local then
    93           Url.implode (Url.append (the remote_path) (Url.File
    94             (Path.append (Path.make session) (html_path name))))
    95         else Path.implode (Path.append (mk_rel_path curr_sess session) (html_path name)),
    96       unfold = false,
    97       parents = map ID_of_thy (Theory.parents_of thy),
    98       content = []};
    99   in (0, entry) end);
   100 
   101 fun ins_graph_entry (i, entry as {ID, ...}) (gr: (int * Graph_Display.node) list) =
   102   (i, entry) :: filter_out (fn (_, entry') => #ID entry' = ID) gr;
   103 
   104 
   105 
   106 (** global browser info state **)
   107 
   108 (* type theory_info *)
   109 
   110 type theory_info = {tex_source: Buffer.T, html_source: Buffer.T, html: Buffer.T};
   111 
   112 fun make_theory_info (tex_source, html_source, html) =
   113   {tex_source = tex_source, html_source = html_source, html = html}: theory_info;
   114 
   115 val empty_theory_info = make_theory_info (Buffer.empty, Buffer.empty, Buffer.empty);
   116 
   117 fun map_theory_info f {tex_source, html_source, html} =
   118   make_theory_info (f (tex_source, html_source, html));
   119 
   120 
   121 (* type browser_info *)
   122 
   123 type browser_info = {theories: theory_info Symtab.table, files: (Path.T * string) list,
   124   tex_index: (int * string) list, html_index: (int * string) list,
   125   graph: (int * Graph_Display.node) list};
   126 
   127 fun make_browser_info (theories, files, tex_index, html_index, graph) =
   128   {theories = theories, files = files, tex_index = tex_index, html_index = html_index,
   129     graph = graph}: browser_info;
   130 
   131 val empty_browser_info = make_browser_info (Symtab.empty, [], [], [], []);
   132 
   133 fun init_browser_info remote_path curr_sess thys = make_browser_info
   134   (Symtab.empty, [], [], [], init_graph remote_path curr_sess thys);
   135 
   136 fun map_browser_info f {theories, files, tex_index, html_index, graph} =
   137   make_browser_info (f (theories, files, tex_index, html_index, graph));
   138 
   139 
   140 (* state *)
   141 
   142 val browser_info = Unsynchronized.ref empty_browser_info;
   143 fun change_browser_info f =
   144   CRITICAL (fn () => Unsynchronized.change browser_info (map_browser_info f));
   145 
   146 val suppress_tex_source = Unsynchronized.ref false;
   147 fun no_document f x = Unsynchronized.setmp suppress_tex_source true f x;
   148 
   149 fun init_theory_info name info =
   150   change_browser_info (fn (theories, files, tex_index, html_index, graph) =>
   151     (Symtab.update (name, info) theories, files, tex_index, html_index, graph));
   152 
   153 fun change_theory_info name f =
   154   change_browser_info (fn (theories, files, tex_index, html_index, graph) =>
   155     (case Symtab.lookup theories name of
   156       NONE => error ("Browser info: cannot access theory document " ^ quote name)
   157     | SOME info => (Symtab.update (name, map_theory_info f info) theories, files,
   158         tex_index, html_index, graph)));
   159 
   160 
   161 fun add_file file =
   162   change_browser_info (fn (theories, files, tex_index, html_index, graph) =>
   163     (theories, file :: files, tex_index, html_index, graph));
   164 
   165 fun add_tex_index txt =
   166   change_browser_info (fn (theories, files, tex_index, html_index, graph) =>
   167     (theories, files, txt :: tex_index, html_index, graph));
   168 
   169 fun add_html_index txt =
   170   change_browser_info (fn (theories, files, tex_index, html_index, graph) =>
   171     (theories, files, tex_index, txt :: html_index, graph));
   172 
   173 fun add_graph_entry entry =
   174   change_browser_info (fn (theories, files, tex_index, html_index, graph) =>
   175     (theories, files, tex_index, html_index, ins_graph_entry entry graph));
   176 
   177 fun add_tex_source name txt =
   178   if ! suppress_tex_source then ()
   179   else change_theory_info name (fn (tex_source, html_source, html) =>
   180     (Buffer.add txt tex_source, html_source, html));
   181 
   182 fun add_html_source name txt = change_theory_info name (fn (tex_source, html_source, html) =>
   183   (tex_source, Buffer.add txt html_source, html));
   184 
   185 
   186 
   187 (** global session state **)
   188 
   189 (* session_info *)
   190 
   191 type session_info =
   192   {name: string, parent: string, session: string, path: string list, html_prefix: Path.T,
   193     info: bool, doc_format: string, doc_graph: bool, doc_output: Path.T option,
   194     documents: (string * string) list, doc_dump: (bool * string), remote_path: Url.T option,
   195     verbose: bool, readme: Path.T option};
   196 
   197 fun make_session_info
   198   (name, parent, session, path, html_prefix, info, doc_format, doc_graph, doc_output,
   199     documents, doc_dump, remote_path, verbose, readme) =
   200   {name = name, parent = parent, session = session, path = path, html_prefix = html_prefix,
   201     info = info, doc_format = doc_format, doc_graph = doc_graph, doc_output = doc_output,
   202     documents = documents, doc_dump = doc_dump, remote_path = remote_path,
   203     verbose = verbose, readme = readme}: session_info;
   204 
   205 
   206 (* state *)
   207 
   208 val session_info = Unsynchronized.ref (NONE: session_info option);
   209 
   210 fun session_default x f = (case ! session_info of NONE => x | SOME info => f info);
   211 
   212 
   213 
   214 (** document preparation **)
   215 
   216 (* maintain session index *)
   217 
   218 val session_entries =
   219   HTML.session_entries o
   220     map (fn name => (Url.File (Path.append (Path.basic name) index_path), name));
   221 
   222 fun get_entries dir =
   223   split_lines (File.read (Path.append dir session_entries_path));
   224 
   225 fun put_entries entries dir =
   226   File.write (Path.append dir session_entries_path) (cat_lines entries);
   227 
   228 
   229 fun create_index dir =
   230   File.read (Path.append dir pre_index_path) ^
   231     session_entries (get_entries dir) ^ HTML.end_document
   232   |> File.write (Path.append dir index_path);
   233 
   234 fun update_index dir name =
   235   (case try get_entries dir of
   236     NONE => warning ("Browser info: cannot access session index of " ^ Path.print dir)
   237   | SOME es => (put_entries ((remove (op =) name es) @ [name]) dir; create_index dir));
   238 
   239 
   240 (* document variants *)
   241 
   242 fun read_variant str =
   243   (case space_explode "=" str of
   244     [name] => (name, "")
   245   | [name, tags] => (name, tags)
   246   | _ => error ("Malformed document variant specification: " ^ quote str));
   247 
   248 
   249 (* init session *)
   250 
   251 fun name_of_session elems = space_implode "/" ("Isabelle" :: elems);
   252 
   253 fun init build info info_path doc doc_graph document_output doc_variants path name
   254     (doc_dump as (_, dump_prefix)) (remote_path, first_time) verbose thys =
   255   if not build andalso not info andalso doc = "" andalso dump_prefix = "" then
   256     (browser_info := empty_browser_info; session_info := NONE)
   257   else
   258     let
   259       val parent_name = name_of_session (take (length path - 1) path);
   260       val session_name = name_of_session path;
   261       val sess_prefix = Path.make path;
   262       val html_prefix = Path.append (Path.expand (Path.explode info_path)) sess_prefix;
   263       val doc_output = if document_output = "" then NONE else SOME (Path.explode document_output);
   264 
   265       val documents =
   266         if doc = "" then []
   267         else if not (can File.check_dir document_path) then
   268           (if verbose then Output.physical_stderr "Warning: missing document directory\n"
   269            else (); [])
   270         else doc_variants;
   271 
   272       val parent_index_path = Path.append Path.parent index_path;
   273       val index_up_lnk =
   274         if first_time then
   275           Url.append (the remote_path) (Url.File (Path.append sess_prefix parent_index_path))
   276         else Url.File parent_index_path;
   277       val readme =
   278         if File.exists readme_html_path then SOME readme_html_path
   279         else if File.exists readme_path then SOME readme_path
   280         else NONE;
   281 
   282       val docs =
   283         (case readme of NONE => [] | SOME p => [(Url.File p, "README")]) @
   284           map (fn (name, _) => (Url.File (Path.ext doc (Path.basic name)), name)) documents;
   285       val index_text = HTML.begin_index (index_up_lnk, parent_name)
   286         (Url.File index_path, session_name) docs (Url.explode "medium.html");
   287     in
   288       session_info :=
   289         SOME (make_session_info (name, parent_name, session_name, path, html_prefix, info, doc,
   290           doc_graph, doc_output, documents, doc_dump, remote_path, verbose, readme));
   291       browser_info := init_browser_info remote_path path thys;
   292       add_html_index (0, index_text)
   293     end;
   294 
   295 
   296 (* isabelle tool wrappers *)
   297 
   298 fun isabelle_document {verbose, purge} format name tags dir =
   299   let
   300     val s = "\"$ISABELLE_TOOL\" document" ^ (if purge then " -c" else "") ^ " -o '" ^ format ^ "' \
   301       \-n '" ^ name ^ "' -t '" ^ tags ^ "' " ^ File.shell_path dir ^ " 2>&1";
   302     val doc_path = Path.appends [dir, Path.parent, Path.basic name |> Path.ext format];
   303     val _ = if verbose then writeln s else ();
   304     val (out, rc) = Isabelle_System.bash_output s;
   305     val _ =
   306       if not (File.exists doc_path) orelse rc <> 0 then
   307         cat_error out ("Failed to build document " ^ quote (show_path doc_path))
   308       else if verbose then writeln out
   309       else ();
   310   in doc_path end;
   311 
   312 fun isabelle_browser graph = Isabelle_System.with_tmp_dir "browser" (fn dir =>
   313   let
   314     val pdf_path = Path.append dir graph_pdf_path;
   315     val eps_path = Path.append dir graph_eps_path;
   316     val graph_path = Path.append dir graph_path;
   317     val _ = Graph_Display.write_graph_browser graph_path graph;
   318     val args = "-o " ^ File.shell_path pdf_path ^ " " ^ File.shell_path graph_path;
   319   in
   320     if Isabelle_System.isabelle_tool "browser" args = 0 andalso
   321       File.exists pdf_path andalso File.exists eps_path
   322     then (File.read pdf_path, File.read eps_path)
   323     else error "Failed to prepare dependency graph"
   324   end);
   325 
   326 
   327 (* finish session -- output all generated text *)
   328 
   329 fun sorted_index index = map snd (sort (int_ord o pairself fst) (rev index));
   330 fun index_buffer index = Buffer.add (implode (sorted_index index)) Buffer.empty;
   331 
   332 fun write_tex src name path =
   333   File.write_buffer (Path.append path (tex_path name)) src;
   334 
   335 fun write_tex_index tex_index path =
   336   write_tex (index_buffer tex_index |> Buffer.add Latex.tex_trailer) doc_indexN path;
   337 
   338 
   339 fun finish () =
   340   session_default () (fn {name, info, html_prefix, doc_format, doc_graph, doc_output,
   341     documents, doc_dump = (dump_copy, dump_prefix), path, verbose, readme, ...} =>
   342   let
   343     val {theories, files, tex_index, html_index, graph} = ! browser_info;
   344     val thys = Symtab.dest theories;
   345     val parent_html_prefix = Path.append html_prefix Path.parent;
   346 
   347     fun finish_html (a, {html, ...}: theory_info) =
   348       File.write_buffer (Path.append html_prefix (html_path a)) (Buffer.add HTML.end_document html);
   349 
   350     val sorted_graph = sorted_index graph;
   351     val opt_graphs =
   352       if doc_graph andalso (not (null documents) orelse dump_prefix <> "") then
   353         SOME (isabelle_browser sorted_graph)
   354       else NONE;
   355 
   356     val _ =
   357       if info then
   358        (Isabelle_System.mkdirs (Path.append html_prefix session_path);
   359         File.write_buffer (Path.append html_prefix pre_index_path) (index_buffer html_index);
   360         File.write (Path.append html_prefix session_entries_path) "";
   361         create_index html_prefix;
   362         if length path > 1 then update_index parent_html_prefix name else ();
   363         (case readme of NONE => () | SOME path => File.copy path html_prefix);
   364         Graph_Display.write_graph_browser (Path.append html_prefix graph_path) sorted_graph;
   365         Isabelle_System.isabelle_tool "browser" "-b";
   366         File.copy (Path.explode "~~/lib/browser/GraphBrowser.jar") html_prefix;
   367         List.app (fn (a, txt) => File.write (Path.append html_prefix (Path.basic a)) txt)
   368           (HTML.applet_pages name (Url.File index_path, name));
   369         File.copy (Path.explode "~~/etc/isabelle.css") html_prefix;
   370         List.app finish_html thys;
   371         List.app (uncurry File.write) files;
   372         if verbose then Output.physical_stderr ("Browser info at " ^ show_path html_prefix ^ "\n")
   373         else ())
   374       else ();
   375 
   376     fun prepare_sources doc_copy doc_dir =
   377      (Isabelle_System.mkdirs doc_dir;
   378       if doc_copy then Isabelle_System.copy_dir document_path doc_dir else ();
   379       Isabelle_System.isabelle_tool "latex"
   380         ("-o sty " ^ File.shell_path (Path.append doc_dir (Path.basic "root.tex")));
   381       (case opt_graphs of NONE => () | SOME (pdf, eps) =>
   382         (File.write (Path.append doc_dir graph_pdf_path) pdf;
   383           File.write (Path.append doc_dir graph_eps_path) eps));
   384       write_tex_index tex_index doc_dir;
   385       List.app (fn (a, {tex_source, ...}) => write_tex tex_source a doc_dir) thys);
   386 
   387     val _ =
   388       if dump_prefix = "" then ()
   389       else
   390         let
   391           val path = Path.explode dump_prefix;
   392           val _ = prepare_sources dump_copy path;
   393         in
   394           if verbose then
   395             Output.physical_stderr ("Document sources at " ^ show_path path ^ "\n")
   396           else ()
   397         end;
   398 
   399     fun document_job doc_prefix backdrop (name, tags) =
   400       let
   401         val _ =
   402           File.eq (document_path, doc_prefix) andalso
   403             error ("Overlap of document input and output directory " ^ Path.print doc_prefix);
   404         val dir = Path.append doc_prefix (Path.basic name);
   405         val copy = not (File.eq (document_path, dir));
   406         val _ = prepare_sources copy dir;
   407         fun inform doc =
   408           if verbose orelse not backdrop then
   409             Output.physical_stderr ("Document at " ^ show_path doc ^ "\n")
   410           else ();
   411       in
   412         fn () =>
   413           (isabelle_document {verbose = true, purge = backdrop} doc_format name tags dir, inform)
   414       end;
   415 
   416     val jobs =
   417       (if info orelse is_none doc_output then
   418         map (document_job html_prefix true) documents
   419        else []) @
   420       (case doc_output of
   421         NONE => []
   422       | SOME path => map (document_job path false) documents);
   423 
   424     val _ = jobs |> Par_List.map (fn job => job ()) |> List.app (op |>);
   425   in
   426     browser_info := empty_browser_info;
   427     session_info := NONE
   428   end);
   429 
   430 
   431 (* theory elements *)
   432 
   433 fun init_theory name = session_default () (fn _ => init_theory_info name empty_theory_info);
   434 
   435 fun theory_source name mk_text =
   436   session_default () (fn _ => add_html_source name (HTML.theory_source (mk_text ())));
   437 
   438 fun theory_output name s =
   439   session_default () (fn _ => add_tex_source name (Latex.isabelle_file name s));
   440 
   441 
   442 fun parent_link remote_path curr_session thy =
   443   let
   444     val {name = _, session, is_local} = get_info thy;
   445     val name = Context.theory_name thy;
   446     val link =
   447       if null session then NONE
   448       else SOME
   449        (if is_some remote_path andalso not is_local then
   450          Url.append (the remote_path) (Url.File (Path.append (Path.make session) (html_path name)))
   451         else Url.File (Path.append (mk_rel_path curr_session session) (html_path name)));
   452   in (link, name) end;
   453 
   454 fun begin_theory update_time dir thy =
   455     session_default thy (fn {name = sess_name, session, path, html_prefix, remote_path, ...} =>
   456   let
   457     val name = Context.theory_name thy;
   458     val parents = Theory.parents_of thy;
   459     val parent_specs = map (parent_link remote_path path) parents;
   460 
   461     val files = [];  (* FIXME *)
   462     val files_html = files |> map (fn (raw_path, loadit) =>
   463       let
   464         val path = File.check_file (File.full_path dir raw_path);
   465         val base = Path.base path;
   466         val base_html = html_ext base;
   467         val _ = add_file (Path.append html_prefix base_html,
   468           HTML.external_file (Url.File base) (File.read path));
   469       in (Url.File base_html, Url.File raw_path, loadit) end);
   470 
   471     fun prep_html_source (tex_source, html_source, html) =
   472       let
   473         val txt = HTML.begin_theory (Url.File index_path, session)
   474           name parent_specs files_html (Buffer.content html_source)
   475       in (tex_source, Buffer.empty, Buffer.add txt html) end;
   476 
   477     val entry =
   478      {name = name, ID = ID_of path name, dir = sess_name, unfold = true,
   479       path = Path.implode (html_path name),
   480       parents = map ID_of_thy parents,
   481       content = []};
   482   in
   483     change_theory_info name prep_html_source;
   484     add_graph_entry (update_time, entry);
   485     add_html_index (update_time, HTML.theory_entry (Url.File (html_path name), name));
   486     add_tex_index (update_time, Latex.theory_entry name);
   487     put_info {name = sess_name, session = path, is_local = is_some remote_path} thy
   488   end);
   489 
   490 
   491 
   492 (** draft document output **)
   493 
   494 fun drafts doc_format src_paths = Isabelle_System.with_tmp_dir "drafts" (fn dir =>
   495   let
   496     fun prep_draft path i =
   497       let
   498         val base = Path.base path;
   499         val name =
   500           (case Path.implode (#1 (Path.split_ext base)) of
   501             "" => "DUMMY"
   502           | s => s)  ^ serial_string ();
   503       in
   504         if File.exists path then
   505           (((name, base, File.read path), (i, Latex.theory_entry name)), i + 1)
   506         else error ("Bad file: " ^ Path.print path)
   507       end;
   508     val (srcs, tex_index) = split_list (fst (fold_map prep_draft src_paths 0));
   509 
   510     val doc_path = Path.append dir document_path;
   511     val _ = Isabelle_System.mkdirs doc_path;
   512     val root_path = Path.append doc_path (Path.basic "root.tex");
   513     val _ = File.copy (Path.explode "~~/lib/texinputs/draft.tex") root_path;
   514     val _ = Isabelle_System.isabelle_tool "latex" ("-o sty " ^ File.shell_path root_path);
   515     val _ = Isabelle_System.isabelle_tool "latex" ("-o syms " ^ File.shell_path root_path);
   516 
   517     fun known name =
   518       let val ss = split_lines (File.read (Path.append doc_path (Path.basic name)))
   519       in member (op =) ss end;
   520     val known_syms = known "syms.lst";
   521     val known_ctrls = known "ctrls.lst";
   522 
   523     val _ = srcs |> List.app (fn (name, base, txt) =>
   524       Symbol.explode txt
   525       |> Latex.symbol_source (known_syms, known_ctrls) (Path.implode base)
   526       |> File.write (Path.append doc_path (tex_path name)));
   527     val _ = write_tex_index tex_index doc_path;
   528 
   529     val result =
   530       isabelle_document {verbose = false, purge = true} doc_format documentN "" doc_path;
   531     val result' = Isabelle_System.create_tmp_path documentN doc_format;
   532     val _ = File.copy result result';
   533   in result' end);
   534 
   535 end;
   536 
   537 structure Basic_Present: BASIC_PRESENT = Present;
   538 open Basic_Present;