src/HOL/Library/Formal_Power_Series.thy
author nipkow
Wed Jun 24 09:41:14 2009 +0200 (2009-06-24)
changeset 31790 05c92381363c
parent 31776 151c3f5f28f9
child 31968 0314441a53a6
permissions -rw-r--r--
corrected and unified thm names
     1 (*  Title:      Formal_Power_Series.thy
     2     Author:     Amine Chaieb, University of Cambridge
     3 *)
     4 
     5 header{* A formalization of formal power series *}
     6 
     7 theory Formal_Power_Series
     8 imports Main Fact Parity Rational
     9 begin
    10 
    11 subsection {* The type of formal power series*}
    12 
    13 typedef (open) 'a fps = "{f :: nat \<Rightarrow> 'a. True}"
    14   morphisms fps_nth Abs_fps
    15   by simp
    16 
    17 notation fps_nth (infixl "$" 75)
    18 
    19 lemma expand_fps_eq: "p = q \<longleftrightarrow> (\<forall>n. p $ n = q $ n)"
    20   by (simp add: fps_nth_inject [symmetric] expand_fun_eq)
    21 
    22 lemma fps_ext: "(\<And>n. p $ n = q $ n) \<Longrightarrow> p = q"
    23   by (simp add: expand_fps_eq)
    24 
    25 lemma fps_nth_Abs_fps [simp]: "Abs_fps f $ n = f n"
    26   by (simp add: Abs_fps_inverse)
    27 
    28 text{* Definition of the basic elements 0 and 1 and the basic operations of addition, negation and multiplication *}
    29 
    30 instantiation fps :: (zero)  zero
    31 begin
    32 
    33 definition fps_zero_def:
    34   "0 = Abs_fps (\<lambda>n. 0)"
    35 
    36 instance ..
    37 end
    38 
    39 lemma fps_zero_nth [simp]: "0 $ n = 0"
    40   unfolding fps_zero_def by simp
    41 
    42 instantiation fps :: ("{one,zero}")  one
    43 begin
    44 
    45 definition fps_one_def:
    46   "1 = Abs_fps (\<lambda>n. if n = 0 then 1 else 0)"
    47 
    48 instance ..
    49 end
    50 
    51 lemma fps_one_nth [simp]: "1 $ n = (if n = 0 then 1 else 0)"
    52   unfolding fps_one_def by simp
    53 
    54 instantiation fps :: (plus)  plus
    55 begin
    56 
    57 definition fps_plus_def:
    58   "op + = (\<lambda>f g. Abs_fps (\<lambda>n. f $ n + g $ n))"
    59 
    60 instance ..
    61 end
    62 
    63 lemma fps_add_nth [simp]: "(f + g) $ n = f $ n + g $ n"
    64   unfolding fps_plus_def by simp
    65 
    66 instantiation fps :: (minus) minus
    67 begin
    68 
    69 definition fps_minus_def:
    70   "op - = (\<lambda>f g. Abs_fps (\<lambda>n. f $ n - g $ n))"
    71 
    72 instance ..
    73 end
    74 
    75 lemma fps_sub_nth [simp]: "(f - g) $ n = f $ n - g $ n"
    76   unfolding fps_minus_def by simp
    77 
    78 instantiation fps :: (uminus) uminus
    79 begin
    80 
    81 definition fps_uminus_def:
    82   "uminus = (\<lambda>f. Abs_fps (\<lambda>n. - (f $ n)))"
    83 
    84 instance ..
    85 end
    86 
    87 lemma fps_neg_nth [simp]: "(- f) $ n = - (f $ n)"
    88   unfolding fps_uminus_def by simp
    89 
    90 instantiation fps :: ("{comm_monoid_add, times}")  times
    91 begin
    92 
    93 definition fps_times_def:
    94   "op * = (\<lambda>f g. Abs_fps (\<lambda>n. \<Sum>i=0..n. f $ i * g $ (n - i)))"
    95 
    96 instance ..
    97 end
    98 
    99 lemma fps_mult_nth: "(f * g) $ n = (\<Sum>i=0..n. f$i * g$(n - i))"
   100   unfolding fps_times_def by simp
   101 
   102 declare atLeastAtMost_iff[presburger]
   103 declare Bex_def[presburger]
   104 declare Ball_def[presburger]
   105 
   106 lemma mult_delta_left:
   107   fixes x y :: "'a::mult_zero"
   108   shows "(if b then x else 0) * y = (if b then x * y else 0)"
   109   by simp
   110 
   111 lemma mult_delta_right:
   112   fixes x y :: "'a::mult_zero"
   113   shows "x * (if b then y else 0) = (if b then x * y else 0)"
   114   by simp
   115 
   116 lemma cond_value_iff: "f (if b then x else y) = (if b then f x else f y)"
   117   by auto
   118 lemma cond_application_beta: "(if b then f else g) x = (if b then f x else g x)"
   119   by auto
   120 
   121 subsection{* Formal power series form a commutative ring with unity, if the range of sequences
   122   they represent is a commutative ring with unity*}
   123 
   124 instance fps :: (semigroup_add) semigroup_add
   125 proof
   126   fix a b c :: "'a fps" show "a + b + c = a + (b + c)"
   127     by (simp add: fps_ext add_assoc)
   128 qed
   129 
   130 instance fps :: (ab_semigroup_add) ab_semigroup_add
   131 proof
   132   fix a b :: "'a fps" show "a + b = b + a"
   133     by (simp add: fps_ext add_commute)
   134 qed
   135 
   136 lemma fps_mult_assoc_lemma:
   137   fixes k :: nat and f :: "nat \<Rightarrow> nat \<Rightarrow> nat \<Rightarrow> 'a::comm_monoid_add"
   138   shows "(\<Sum>j=0..k. \<Sum>i=0..j. f i (j - i) (n - j)) =
   139          (\<Sum>j=0..k. \<Sum>i=0..k - j. f j i (n - j - i))"
   140 proof (induct k)
   141   case 0 show ?case by simp
   142 next
   143   case (Suc k) thus ?case
   144     by (simp add: Suc_diff_le setsum_addf add_assoc
   145              cong: strong_setsum_cong)
   146 qed
   147 
   148 instance fps :: (semiring_0) semigroup_mult
   149 proof
   150   fix a b c :: "'a fps"
   151   show "(a * b) * c = a * (b * c)"
   152   proof (rule fps_ext)
   153     fix n :: nat
   154     have "(\<Sum>j=0..n. \<Sum>i=0..j. a$i * b$(j - i) * c$(n - j)) =
   155           (\<Sum>j=0..n. \<Sum>i=0..n - j. a$j * b$i * c$(n - j - i))"
   156       by (rule fps_mult_assoc_lemma)
   157     thus "((a * b) * c) $ n = (a * (b * c)) $ n"
   158       by (simp add: fps_mult_nth setsum_right_distrib
   159                     setsum_left_distrib mult_assoc)
   160   qed
   161 qed
   162 
   163 lemma fps_mult_commute_lemma:
   164   fixes n :: nat and f :: "nat \<Rightarrow> nat \<Rightarrow> 'a::comm_monoid_add"
   165   shows "(\<Sum>i=0..n. f i (n - i)) = (\<Sum>i=0..n. f (n - i) i)"
   166 proof (rule setsum_reindex_cong)
   167   show "inj_on (\<lambda>i. n - i) {0..n}"
   168     by (rule inj_onI) simp
   169   show "{0..n} = (\<lambda>i. n - i) ` {0..n}"
   170     by (auto, rule_tac x="n - x" in image_eqI, simp_all)
   171 next
   172   fix i assume "i \<in> {0..n}"
   173   hence "n - (n - i) = i" by simp
   174   thus "f (n - i) i = f (n - i) (n - (n - i))" by simp
   175 qed
   176 
   177 instance fps :: (comm_semiring_0) ab_semigroup_mult
   178 proof
   179   fix a b :: "'a fps"
   180   show "a * b = b * a"
   181   proof (rule fps_ext)
   182     fix n :: nat
   183     have "(\<Sum>i=0..n. a$i * b$(n - i)) = (\<Sum>i=0..n. a$(n - i) * b$i)"
   184       by (rule fps_mult_commute_lemma)
   185     thus "(a * b) $ n = (b * a) $ n"
   186       by (simp add: fps_mult_nth mult_commute)
   187   qed
   188 qed
   189 
   190 instance fps :: (monoid_add) monoid_add
   191 proof
   192   fix a :: "'a fps" show "0 + a = a "
   193     by (simp add: fps_ext)
   194 next
   195   fix a :: "'a fps" show "a + 0 = a "
   196     by (simp add: fps_ext)
   197 qed
   198 
   199 instance fps :: (comm_monoid_add) comm_monoid_add
   200 proof
   201   fix a :: "'a fps" show "0 + a = a "
   202     by (simp add: fps_ext)
   203 qed
   204 
   205 instance fps :: (semiring_1) monoid_mult
   206 proof
   207   fix a :: "'a fps" show "1 * a = a"
   208     by (simp add: fps_ext fps_mult_nth mult_delta_left setsum_delta)
   209 next
   210   fix a :: "'a fps" show "a * 1 = a"
   211     by (simp add: fps_ext fps_mult_nth mult_delta_right setsum_delta')
   212 qed
   213 
   214 instance fps :: (cancel_semigroup_add) cancel_semigroup_add
   215 proof
   216   fix a b c :: "'a fps"
   217   assume "a + b = a + c" then show "b = c"
   218     by (simp add: expand_fps_eq)
   219 next
   220   fix a b c :: "'a fps"
   221   assume "b + a = c + a" then show "b = c"
   222     by (simp add: expand_fps_eq)
   223 qed
   224 
   225 instance fps :: (cancel_ab_semigroup_add) cancel_ab_semigroup_add
   226 proof
   227   fix a b c :: "'a fps"
   228   assume "a + b = a + c" then show "b = c"
   229     by (simp add: expand_fps_eq)
   230 qed
   231 
   232 instance fps :: (cancel_comm_monoid_add) cancel_comm_monoid_add ..
   233 
   234 instance fps :: (group_add) group_add
   235 proof
   236   fix a :: "'a fps" show "- a + a = 0"
   237     by (simp add: fps_ext)
   238 next
   239   fix a b :: "'a fps" show "a - b = a + - b"
   240     by (simp add: fps_ext diff_minus)
   241 qed
   242 
   243 instance fps :: (ab_group_add) ab_group_add
   244 proof
   245   fix a :: "'a fps"
   246   show "- a + a = 0"
   247     by (simp add: fps_ext)
   248 next
   249   fix a b :: "'a fps"
   250   show "a - b = a + - b"
   251     by (simp add: fps_ext)
   252 qed
   253 
   254 instance fps :: (zero_neq_one) zero_neq_one
   255   by default (simp add: expand_fps_eq)
   256 
   257 instance fps :: (semiring_0) semiring
   258 proof
   259   fix a b c :: "'a fps"
   260   show "(a + b) * c = a * c + b * c"
   261     by (simp add: expand_fps_eq fps_mult_nth left_distrib setsum_addf)
   262 next
   263   fix a b c :: "'a fps"
   264   show "a * (b + c) = a * b + a * c"
   265     by (simp add: expand_fps_eq fps_mult_nth right_distrib setsum_addf)
   266 qed
   267 
   268 instance fps :: (semiring_0) semiring_0
   269 proof
   270   fix a:: "'a fps" show "0 * a = 0"
   271     by (simp add: fps_ext fps_mult_nth)
   272 next
   273   fix a:: "'a fps" show "a * 0 = 0"
   274     by (simp add: fps_ext fps_mult_nth)
   275 qed
   276 
   277 instance fps :: (semiring_0_cancel) semiring_0_cancel ..
   278 
   279 subsection {* Selection of the nth power of the implicit variable in the infinite sum*}
   280 
   281 lemma fps_nonzero_nth: "f \<noteq> 0 \<longleftrightarrow> (\<exists> n. f $n \<noteq> 0)"
   282   by (simp add: expand_fps_eq)
   283 
   284 lemma fps_nonzero_nth_minimal:
   285   "f \<noteq> 0 \<longleftrightarrow> (\<exists>n. f $ n \<noteq> 0 \<and> (\<forall>m<n. f $ m = 0))"
   286 proof
   287   let ?n = "LEAST n. f $ n \<noteq> 0"
   288   assume "f \<noteq> 0"
   289   then have "\<exists>n. f $ n \<noteq> 0"
   290     by (simp add: fps_nonzero_nth)
   291   then have "f $ ?n \<noteq> 0"
   292     by (rule LeastI_ex)
   293   moreover have "\<forall>m<?n. f $ m = 0"
   294     by (auto dest: not_less_Least)
   295   ultimately have "f $ ?n \<noteq> 0 \<and> (\<forall>m<?n. f $ m = 0)" ..
   296   then show "\<exists>n. f $ n \<noteq> 0 \<and> (\<forall>m<n. f $ m = 0)" ..
   297 next
   298   assume "\<exists>n. f $ n \<noteq> 0 \<and> (\<forall>m<n. f $ m = 0)"
   299   then show "f \<noteq> 0" by (auto simp add: expand_fps_eq)
   300 qed
   301 
   302 lemma fps_eq_iff: "f = g \<longleftrightarrow> (\<forall>n. f $ n = g $n)"
   303   by (rule expand_fps_eq)
   304 
   305 lemma fps_setsum_nth: "(setsum f S) $ n = setsum (\<lambda>k. (f k) $ n) S"
   306 proof (cases "finite S")
   307   assume "\<not> finite S" then show ?thesis by simp
   308 next
   309   assume "finite S"
   310   then show ?thesis by (induct set: finite) auto
   311 qed
   312 
   313 subsection{* Injection of the basic ring elements and multiplication by scalars *}
   314 
   315 definition
   316   "fps_const c = Abs_fps (\<lambda>n. if n = 0 then c else 0)"
   317 
   318 lemma fps_nth_fps_const [simp]: "fps_const c $ n = (if n = 0 then c else 0)"
   319   unfolding fps_const_def by simp
   320 
   321 lemma fps_const_0_eq_0 [simp]: "fps_const 0 = 0"
   322   by (simp add: fps_ext)
   323 
   324 lemma fps_const_1_eq_1 [simp]: "fps_const 1 = 1"
   325   by (simp add: fps_ext)
   326 
   327 lemma fps_const_neg [simp]: "- (fps_const (c::'a::ring)) = fps_const (- c)"
   328   by (simp add: fps_ext)
   329 
   330 lemma fps_const_add [simp]: "fps_const (c::'a\<Colon>monoid_add) + fps_const d = fps_const (c + d)"
   331   by (simp add: fps_ext)
   332 lemma fps_const_sub [simp]: "fps_const (c::'a\<Colon>group_add) - fps_const d = fps_const (c - d)"
   333   by (simp add: fps_ext)
   334 lemma fps_const_mult[simp]: "fps_const (c::'a\<Colon>ring) * fps_const d = fps_const (c * d)"
   335   by (simp add: fps_eq_iff fps_mult_nth setsum_0')
   336 
   337 lemma fps_const_add_left: "fps_const (c::'a\<Colon>monoid_add) + f = Abs_fps (\<lambda>n. if n = 0 then c + f$0 else f$n)"
   338   by (simp add: fps_ext)
   339 
   340 lemma fps_const_add_right: "f + fps_const (c::'a\<Colon>monoid_add) = Abs_fps (\<lambda>n. if n = 0 then f$0 + c else f$n)"
   341   by (simp add: fps_ext)
   342 
   343 lemma fps_const_mult_left: "fps_const (c::'a\<Colon>semiring_0) * f = Abs_fps (\<lambda>n. c * f$n)"
   344   unfolding fps_eq_iff fps_mult_nth
   345   by (simp add: fps_const_def mult_delta_left setsum_delta)
   346 
   347 lemma fps_const_mult_right: "f * fps_const (c::'a\<Colon>semiring_0) = Abs_fps (\<lambda>n. f$n * c)"
   348   unfolding fps_eq_iff fps_mult_nth
   349   by (simp add: fps_const_def mult_delta_right setsum_delta')
   350 
   351 lemma fps_mult_left_const_nth [simp]: "(fps_const (c::'a::semiring_1) * f)$n = c* f$n"
   352   by (simp add: fps_mult_nth mult_delta_left setsum_delta)
   353 
   354 lemma fps_mult_right_const_nth [simp]: "(f * fps_const (c::'a::semiring_1))$n = f$n * c"
   355   by (simp add: fps_mult_nth mult_delta_right setsum_delta')
   356 
   357 subsection {* Formal power series form an integral domain*}
   358 
   359 instance fps :: (ring) ring ..
   360 
   361 instance fps :: (ring_1) ring_1
   362   by (intro_classes, auto simp add: diff_minus left_distrib)
   363 
   364 instance fps :: (comm_ring_1) comm_ring_1
   365   by (intro_classes, auto simp add: diff_minus left_distrib)
   366 
   367 instance fps :: (ring_no_zero_divisors) ring_no_zero_divisors
   368 proof
   369   fix a b :: "'a fps"
   370   assume a0: "a \<noteq> 0" and b0: "b \<noteq> 0"
   371   then obtain i j where i: "a$i\<noteq>0" "\<forall>k<i. a$k=0"
   372     and j: "b$j \<noteq>0" "\<forall>k<j. b$k =0" unfolding fps_nonzero_nth_minimal
   373     by blast+
   374   have "(a * b) $ (i+j) = (\<Sum>k=0..i+j. a$k * b$(i+j-k))"
   375     by (rule fps_mult_nth)
   376   also have "\<dots> = (a$i * b$(i+j-i)) + (\<Sum>k\<in>{0..i+j}-{i}. a$k * b$(i+j-k))"
   377     by (rule setsum_diff1') simp_all
   378   also have "(\<Sum>k\<in>{0..i+j}-{i}. a$k * b$(i+j-k)) = 0"
   379     proof (rule setsum_0' [rule_format])
   380       fix k assume "k \<in> {0..i+j} - {i}"
   381       then have "k < i \<or> i+j-k < j" by auto
   382       then show "a$k * b$(i+j-k) = 0" using i j by auto
   383     qed
   384   also have "a$i * b$(i+j-i) + 0 = a$i * b$j" by simp
   385   also have "a$i * b$j \<noteq> 0" using i j by simp
   386   finally have "(a*b) $ (i+j) \<noteq> 0" .
   387   then show "a*b \<noteq> 0" unfolding fps_nonzero_nth by blast
   388 qed
   389 
   390 instance fps :: (idom) idom ..
   391 
   392 instantiation fps :: (comm_ring_1) number_ring
   393 begin
   394 definition number_of_fps_def: "(number_of k::'a fps) = of_int k"
   395 
   396 instance proof
   397 qed (rule number_of_fps_def)
   398 end
   399 
   400 lemma number_of_fps_const: "(number_of k::('a::comm_ring_1) fps) = fps_const (of_int k)"
   401   
   402 proof(induct k rule: int_induct[where k=0])
   403   case base thus ?case unfolding number_of_fps_def of_int_0 by simp
   404 next
   405   case (step1 i) thus ?case unfolding number_of_fps_def 
   406     by (simp add: fps_const_add[symmetric] del: fps_const_add)
   407 next
   408   case (step2 i) thus ?case unfolding number_of_fps_def 
   409     by (simp add: fps_const_sub[symmetric] del: fps_const_sub)
   410 qed
   411   
   412 subsection{* Inverses of formal power series *}
   413 
   414 declare setsum_cong[fundef_cong]
   415 
   416 
   417 instantiation fps :: ("{comm_monoid_add,inverse, times, uminus}") inverse
   418 begin
   419 
   420 fun natfun_inverse:: "'a fps \<Rightarrow> nat \<Rightarrow> 'a" where
   421   "natfun_inverse f 0 = inverse (f$0)"
   422 | "natfun_inverse f n = - inverse (f$0) * setsum (\<lambda>i. f$i * natfun_inverse f (n - i)) {1..n}"
   423 
   424 definition fps_inverse_def:
   425   "inverse f = (if f$0 = 0 then 0 else Abs_fps (natfun_inverse f))"
   426 definition fps_divide_def: "divide = (\<lambda>(f::'a fps) g. f * inverse g)"
   427 instance ..
   428 end
   429 
   430 lemma fps_inverse_zero[simp]:
   431   "inverse (0 :: 'a::{comm_monoid_add,inverse, times, uminus} fps) = 0"
   432   by (simp add: fps_ext fps_inverse_def)
   433 
   434 lemma fps_inverse_one[simp]: "inverse (1 :: 'a::{division_ring,zero_neq_one} fps) = 1"
   435   apply (auto simp add: expand_fps_eq fps_inverse_def)
   436   by (case_tac n, auto)
   437 
   438 instance fps :: ("{comm_monoid_add,inverse, times, uminus}")  division_by_zero
   439   by default (rule fps_inverse_zero)
   440 
   441 lemma inverse_mult_eq_1[intro]: assumes f0: "f$0 \<noteq> (0::'a::field)"
   442   shows "inverse f * f = 1"
   443 proof-
   444   have c: "inverse f * f = f * inverse f" by (simp add: mult_commute)
   445   from f0 have ifn: "\<And>n. inverse f $ n = natfun_inverse f n"
   446     by (simp add: fps_inverse_def)
   447   from f0 have th0: "(inverse f * f) $ 0 = 1"
   448     by (simp add: fps_mult_nth fps_inverse_def)
   449   {fix n::nat assume np: "n >0 "
   450     from np have eq: "{0..n} = {0} \<union> {1 .. n}" by auto
   451     have d: "{0} \<inter> {1 .. n} = {}" by auto
   452     have f: "finite {0::nat}" "finite {1..n}" by auto
   453     from f0 np have th0: "- (inverse f$n) =
   454       (setsum (\<lambda>i. f$i * natfun_inverse f (n - i)) {1..n}) / (f$0)"
   455       by (cases n, simp, simp add: divide_inverse fps_inverse_def)
   456     from th0[symmetric, unfolded nonzero_divide_eq_eq[OF f0]]
   457     have th1: "setsum (\<lambda>i. f$i * natfun_inverse f (n - i)) {1..n} =
   458       - (f$0) * (inverse f)$n"
   459       by (simp add: ring_simps)
   460     have "(f * inverse f) $ n = (\<Sum>i = 0..n. f $i * natfun_inverse f (n - i))"
   461       unfolding fps_mult_nth ifn ..
   462     also have "\<dots> = f$0 * natfun_inverse f n
   463       + (\<Sum>i = 1..n. f$i * natfun_inverse f (n-i))"
   464       unfolding setsum_Un_disjoint[OF f d, unfolded eq[symmetric]]
   465       by simp
   466     also have "\<dots> = 0" unfolding th1 ifn by simp
   467     finally have "(inverse f * f)$n = 0" unfolding c . }
   468   with th0 show ?thesis by (simp add: fps_eq_iff)
   469 qed
   470 
   471 lemma fps_inverse_0_iff[simp]: "(inverse f)$0 = (0::'a::division_ring) \<longleftrightarrow> f$0 = 0"
   472   by (simp add: fps_inverse_def nonzero_imp_inverse_nonzero)
   473 
   474 lemma fps_inverse_eq_0_iff[simp]: "inverse f = (0:: ('a::field) fps) \<longleftrightarrow> f $0 = 0"
   475 proof-
   476   {assume "f$0 = 0" hence "inverse f = 0" by (simp add: fps_inverse_def)}
   477   moreover
   478   {assume h: "inverse f = 0" and c: "f $0 \<noteq> 0"
   479     from inverse_mult_eq_1[OF c] h have False by simp}
   480   ultimately show ?thesis by blast
   481 qed
   482 
   483 lemma fps_inverse_idempotent[intro]: assumes f0: "f$0 \<noteq> (0::'a::field)"
   484   shows "inverse (inverse f) = f"
   485 proof-
   486   from f0 have if0: "inverse f $ 0 \<noteq> 0" by simp
   487   from inverse_mult_eq_1[OF f0] inverse_mult_eq_1[OF if0]
   488   have th0: "inverse f * f = inverse f * inverse (inverse f)"   by (simp add: mult_ac)
   489   then show ?thesis using f0 unfolding mult_cancel_left by simp
   490 qed
   491 
   492 lemma fps_inverse_unique: assumes f0: "f$0 \<noteq> (0::'a::field)" and fg: "f*g = 1"
   493   shows "inverse f = g"
   494 proof-
   495   from inverse_mult_eq_1[OF f0] fg
   496   have th0: "inverse f * f = g * f" by (simp add: mult_ac)
   497   then show ?thesis using f0  unfolding mult_cancel_right
   498     by (auto simp add: expand_fps_eq)
   499 qed
   500 
   501 lemma fps_inverse_gp: "inverse (Abs_fps(\<lambda>n. (1::'a::field)))
   502   = Abs_fps (\<lambda>n. if n= 0 then 1 else if n=1 then - 1 else 0)"
   503   apply (rule fps_inverse_unique)
   504   apply simp
   505   apply (simp add: fps_eq_iff fps_mult_nth)
   506 proof(clarsimp)
   507   fix n::nat assume n: "n > 0"
   508   let ?f = "\<lambda>i. if n = i then (1\<Colon>'a) else if n - i = 1 then - 1 else 0"
   509   let ?g = "\<lambda>i. if i = n then 1 else if i=n - 1 then - 1 else 0"
   510   let ?h = "\<lambda>i. if i=n - 1 then - 1 else 0"
   511   have th1: "setsum ?f {0..n} = setsum ?g {0..n}"
   512     by (rule setsum_cong2) auto
   513   have th2: "setsum ?g {0..n - 1} = setsum ?h {0..n - 1}"
   514     using n apply - by (rule setsum_cong2) auto
   515   have eq: "{0 .. n} = {0.. n - 1} \<union> {n}" by auto
   516   from n have d: "{0.. n - 1} \<inter> {n} = {}" by auto
   517   have f: "finite {0.. n - 1}" "finite {n}" by auto
   518   show "setsum ?f {0..n} = 0"
   519     unfolding th1
   520     apply (simp add: setsum_Un_disjoint[OF f d, unfolded eq[symmetric]] del: One_nat_def)
   521     unfolding th2
   522     by(simp add: setsum_delta)
   523 qed
   524 
   525 subsection{* Formal Derivatives, and the MacLaurin theorem around 0*}
   526 
   527 definition "fps_deriv f = Abs_fps (\<lambda>n. of_nat (n + 1) * f $ (n + 1))"
   528 
   529 lemma fps_deriv_nth[simp]: "fps_deriv f $ n = of_nat (n +1) * f $ (n+1)" by (simp add: fps_deriv_def)
   530 
   531 lemma fps_deriv_linear[simp]: "fps_deriv (fps_const (a::'a::comm_semiring_1) * f + fps_const b * g) = fps_const a * fps_deriv f + fps_const b * fps_deriv g"
   532   unfolding fps_eq_iff fps_add_nth  fps_const_mult_left fps_deriv_nth by (simp add: ring_simps)
   533 
   534 lemma fps_deriv_mult[simp]:
   535   fixes f :: "('a :: comm_ring_1) fps"
   536   shows "fps_deriv (f * g) = f * fps_deriv g + fps_deriv f * g"
   537 proof-
   538   let ?D = "fps_deriv"
   539   {fix n::nat
   540     let ?Zn = "{0 ..n}"
   541     let ?Zn1 = "{0 .. n + 1}"
   542     let ?f = "\<lambda>i. i + 1"
   543     have fi: "inj_on ?f {0..n}" by (simp add: inj_on_def)
   544     have eq: "{1.. n+1} = ?f ` {0..n}" by auto
   545     let ?g = "\<lambda>i. of_nat (i+1) * g $ (i+1) * f $ (n - i) +
   546         of_nat (i+1)* f $ (i+1) * g $ (n - i)"
   547     let ?h = "\<lambda>i. of_nat i * g $ i * f $ ((n+1) - i) +
   548         of_nat i* f $ i * g $ ((n + 1) - i)"
   549     {fix k assume k: "k \<in> {0..n}"
   550       have "?h (k + 1) = ?g k" using k by auto}
   551     note th0 = this
   552     have eq': "{0..n +1}- {1 .. n+1} = {0}" by auto
   553     have s0: "setsum (\<lambda>i. of_nat i * f $ i * g $ (n + 1 - i)) ?Zn1 = setsum (\<lambda>i. of_nat (n + 1 - i) * f $ (n + 1 - i) * g $ i) ?Zn1"
   554       apply (rule setsum_reindex_cong[where f="\<lambda>i. n + 1 - i"])
   555       apply (simp add: inj_on_def Ball_def)
   556       apply presburger
   557       apply (rule set_ext)
   558       apply (presburger add: image_iff)
   559       by simp
   560     have s1: "setsum (\<lambda>i. f $ i * g $ (n + 1 - i)) ?Zn1 = setsum (\<lambda>i. f $ (n + 1 - i) * g $ i) ?Zn1"
   561       apply (rule setsum_reindex_cong[where f="\<lambda>i. n + 1 - i"])
   562       apply (simp add: inj_on_def Ball_def)
   563       apply presburger
   564       apply (rule set_ext)
   565       apply (presburger add: image_iff)
   566       by simp
   567     have "(f * ?D g + ?D f * g)$n = (?D g * f + ?D f * g)$n" by (simp only: mult_commute)
   568     also have "\<dots> = (\<Sum>i = 0..n. ?g i)"
   569       by (simp add: fps_mult_nth setsum_addf[symmetric])
   570     also have "\<dots> = setsum ?h {1..n+1}"
   571       using th0 setsum_reindex_cong[OF fi eq, of "?g" "?h"] by auto
   572     also have "\<dots> = setsum ?h {0..n+1}"
   573       apply (rule setsum_mono_zero_left)
   574       apply simp
   575       apply (simp add: subset_eq)
   576       unfolding eq'
   577       by simp
   578     also have "\<dots> = (fps_deriv (f * g)) $ n"
   579       apply (simp only: fps_deriv_nth fps_mult_nth setsum_addf)
   580       unfolding s0 s1
   581       unfolding setsum_addf[symmetric] setsum_right_distrib
   582       apply (rule setsum_cong2)
   583       by (auto simp add: of_nat_diff ring_simps)
   584     finally have "(f * ?D g + ?D f * g) $ n = ?D (f*g) $ n" .}
   585   then show ?thesis unfolding fps_eq_iff by auto
   586 qed
   587 
   588 lemma fps_deriv_neg[simp]: "fps_deriv (- (f:: ('a:: comm_ring_1) fps)) = - (fps_deriv f)"
   589   by (simp add: fps_eq_iff fps_deriv_def)
   590 lemma fps_deriv_add[simp]: "fps_deriv ((f:: ('a::comm_ring_1) fps) + g) = fps_deriv f + fps_deriv g"
   591   using fps_deriv_linear[of 1 f 1 g] by simp
   592 
   593 lemma fps_deriv_sub[simp]: "fps_deriv ((f:: ('a::comm_ring_1) fps) - g) = fps_deriv f - fps_deriv g"
   594   unfolding diff_minus by simp
   595 
   596 lemma fps_deriv_const[simp]: "fps_deriv (fps_const c) = 0"
   597   by (simp add: fps_ext fps_deriv_def fps_const_def)
   598 
   599 lemma fps_deriv_mult_const_left[simp]: "fps_deriv (fps_const (c::'a::comm_ring_1) * f) = fps_const c * fps_deriv f"
   600   by simp
   601 
   602 lemma fps_deriv_0[simp]: "fps_deriv 0 = 0"
   603   by (simp add: fps_deriv_def fps_eq_iff)
   604 
   605 lemma fps_deriv_1[simp]: "fps_deriv 1 = 0"
   606   by (simp add: fps_deriv_def fps_eq_iff )
   607 
   608 lemma fps_deriv_mult_const_right[simp]: "fps_deriv (f * fps_const (c::'a::comm_ring_1)) = fps_deriv f * fps_const c"
   609   by simp
   610 
   611 lemma fps_deriv_setsum: "fps_deriv (setsum f S) = setsum (\<lambda>i. fps_deriv (f i :: ('a::comm_ring_1) fps)) S"
   612 proof-
   613   {assume "\<not> finite S" hence ?thesis by simp}
   614   moreover
   615   {assume fS: "finite S"
   616     have ?thesis  by (induct rule: finite_induct[OF fS], simp_all)}
   617   ultimately show ?thesis by blast
   618 qed
   619 
   620 lemma fps_deriv_eq_0_iff[simp]: "fps_deriv f = 0 \<longleftrightarrow> (f = fps_const (f$0 :: 'a::{idom,semiring_char_0}))"
   621 proof-
   622   {assume "f= fps_const (f$0)" hence "fps_deriv f = fps_deriv (fps_const (f$0))" by simp
   623     hence "fps_deriv f = 0" by simp }
   624   moreover
   625   {assume z: "fps_deriv f = 0"
   626     hence "\<forall>n. (fps_deriv f)$n = 0" by simp
   627     hence "\<forall>n. f$(n+1) = 0" by (simp del: of_nat_Suc of_nat_add One_nat_def)
   628     hence "f = fps_const (f$0)"
   629       apply (clarsimp simp add: fps_eq_iff fps_const_def)
   630       apply (erule_tac x="n - 1" in allE)
   631       by simp}
   632   ultimately show ?thesis by blast
   633 qed
   634 
   635 lemma fps_deriv_eq_iff:
   636   fixes f:: "('a::{idom,semiring_char_0}) fps"
   637   shows "fps_deriv f = fps_deriv g \<longleftrightarrow> (f = fps_const(f$0 - g$0) + g)"
   638 proof-
   639   have "fps_deriv f = fps_deriv g \<longleftrightarrow> fps_deriv (f - g) = 0" by simp
   640   also have "\<dots> \<longleftrightarrow> f - g = fps_const ((f-g)$0)" unfolding fps_deriv_eq_0_iff ..
   641   finally show ?thesis by (simp add: ring_simps)
   642 qed
   643 
   644 lemma fps_deriv_eq_iff_ex: "(fps_deriv f = fps_deriv g) \<longleftrightarrow> (\<exists>(c::'a::{idom,semiring_char_0}). f = fps_const c + g)"
   645   apply auto unfolding fps_deriv_eq_iff by blast
   646 
   647 
   648 fun fps_nth_deriv :: "nat \<Rightarrow> ('a::semiring_1) fps \<Rightarrow> 'a fps" where
   649   "fps_nth_deriv 0 f = f"
   650 | "fps_nth_deriv (Suc n) f = fps_nth_deriv n (fps_deriv f)"
   651 
   652 lemma fps_nth_deriv_commute: "fps_nth_deriv (Suc n) f = fps_deriv (fps_nth_deriv n f)"
   653   by (induct n arbitrary: f, auto)
   654 
   655 lemma fps_nth_deriv_linear[simp]: "fps_nth_deriv n (fps_const (a::'a::comm_semiring_1) * f + fps_const b * g) = fps_const a * fps_nth_deriv n f + fps_const b * fps_nth_deriv n g"
   656   by (induct n arbitrary: f g, auto simp add: fps_nth_deriv_commute)
   657 
   658 lemma fps_nth_deriv_neg[simp]: "fps_nth_deriv n (- (f:: ('a:: comm_ring_1) fps)) = - (fps_nth_deriv n f)"
   659   by (induct n arbitrary: f, simp_all)
   660 
   661 lemma fps_nth_deriv_add[simp]: "fps_nth_deriv n ((f:: ('a::comm_ring_1) fps) + g) = fps_nth_deriv n f + fps_nth_deriv n g"
   662   using fps_nth_deriv_linear[of n 1 f 1 g] by simp
   663 
   664 lemma fps_nth_deriv_sub[simp]: "fps_nth_deriv n ((f:: ('a::comm_ring_1) fps) - g) = fps_nth_deriv n f - fps_nth_deriv n g"
   665   unfolding diff_minus fps_nth_deriv_add by simp
   666 
   667 lemma fps_nth_deriv_0[simp]: "fps_nth_deriv n 0 = 0"
   668   by (induct n, simp_all )
   669 
   670 lemma fps_nth_deriv_1[simp]: "fps_nth_deriv n 1 = (if n = 0 then 1 else 0)"
   671   by (induct n, simp_all )
   672 
   673 lemma fps_nth_deriv_const[simp]: "fps_nth_deriv n (fps_const c) = (if n = 0 then fps_const c else 0)"
   674   by (cases n, simp_all)
   675 
   676 lemma fps_nth_deriv_mult_const_left[simp]: "fps_nth_deriv n (fps_const (c::'a::comm_ring_1) * f) = fps_const c * fps_nth_deriv n f"
   677   using fps_nth_deriv_linear[of n "c" f 0 0 ] by simp
   678 
   679 lemma fps_nth_deriv_mult_const_right[simp]: "fps_nth_deriv n (f * fps_const (c::'a::comm_ring_1)) = fps_nth_deriv n f * fps_const c"
   680   using fps_nth_deriv_linear[of n "c" f 0 0] by (simp add: mult_commute)
   681 
   682 lemma fps_nth_deriv_setsum: "fps_nth_deriv n (setsum f S) = setsum (\<lambda>i. fps_nth_deriv n (f i :: ('a::comm_ring_1) fps)) S"
   683 proof-
   684   {assume "\<not> finite S" hence ?thesis by simp}
   685   moreover
   686   {assume fS: "finite S"
   687     have ?thesis  by (induct rule: finite_induct[OF fS], simp_all)}
   688   ultimately show ?thesis by blast
   689 qed
   690 
   691 lemma fps_deriv_maclauren_0: "(fps_nth_deriv k (f:: ('a::comm_semiring_1) fps)) $ 0 = of_nat (fact k) * f$(k)"
   692   by (induct k arbitrary: f) (auto simp add: ring_simps of_nat_mult)
   693 
   694 subsection {* Powers*}
   695 
   696 lemma fps_power_zeroth_eq_one: "a$0 =1 \<Longrightarrow> a^n $ 0 = (1::'a::semiring_1)"
   697   by (induct n, auto simp add: expand_fps_eq fps_mult_nth)
   698 
   699 lemma fps_power_first_eq: "(a:: 'a::comm_ring_1 fps)$0 =1 \<Longrightarrow> a^n $ 1 = of_nat n * a$1"
   700 proof(induct n)
   701   case 0 thus ?case by simp
   702 next
   703   case (Suc n)
   704   note h = Suc.hyps[OF `a$0 = 1`]
   705   show ?case unfolding power_Suc fps_mult_nth
   706     using h `a$0 = 1`  fps_power_zeroth_eq_one[OF `a$0=1`] by (simp add: ring_simps)
   707 qed
   708 
   709 lemma startsby_one_power:"a $ 0 = (1::'a::comm_ring_1) \<Longrightarrow> a^n $ 0 = 1"
   710   by (induct n, auto simp add: fps_mult_nth)
   711 
   712 lemma startsby_zero_power:"a $0 = (0::'a::comm_ring_1) \<Longrightarrow> n > 0 \<Longrightarrow> a^n $0 = 0"
   713   by (induct n, auto simp add: fps_mult_nth)
   714 
   715 lemma startsby_power:"a $0 = (v::'a::{comm_ring_1}) \<Longrightarrow> a^n $0 = v^n"
   716   by (induct n, auto simp add: fps_mult_nth power_Suc)
   717 
   718 lemma startsby_zero_power_iff[simp]:
   719   "a^n $0 = (0::'a::{idom}) \<longleftrightarrow> (n \<noteq> 0 \<and> a$0 = 0)"
   720 apply (rule iffI)
   721 apply (induct n, auto simp add: power_Suc fps_mult_nth)
   722 by (rule startsby_zero_power, simp_all)
   723 
   724 lemma startsby_zero_power_prefix:
   725   assumes a0: "a $0 = (0::'a::idom)"
   726   shows "\<forall>n < k. a ^ k $ n = 0"
   727   using a0
   728 proof(induct k rule: nat_less_induct)
   729   fix k assume H: "\<forall>m<k. a $0 =  0 \<longrightarrow> (\<forall>n<m. a ^ m $ n = 0)" and a0: "a $0 = (0\<Colon>'a)"
   730   let ?ths = "\<forall>m<k. a ^ k $ m = 0"
   731   {assume "k = 0" then have ?ths by simp}
   732   moreover
   733   {fix l assume k: "k = Suc l"
   734     {fix m assume mk: "m < k"
   735       {assume "m=0" hence "a^k $ m = 0" using startsby_zero_power[of a k] k a0
   736 	  by simp}
   737       moreover
   738       {assume m0: "m \<noteq> 0"
   739 	have "a ^k $ m = (a^l * a) $m" by (simp add: k power_Suc mult_commute)
   740 	also have "\<dots> = (\<Sum>i = 0..m. a ^ l $ i * a $ (m - i))" by (simp add: fps_mult_nth)
   741 	also have "\<dots> = 0" apply (rule setsum_0')
   742 	  apply auto
   743 	  apply (case_tac "aa = m")
   744 	  using a0
   745 	  apply simp
   746 	  apply (rule H[rule_format])
   747 	  using a0 k mk by auto
   748 	finally have "a^k $ m = 0" .}
   749     ultimately have "a^k $ m = 0" by blast}
   750     hence ?ths by blast}
   751   ultimately show ?ths by (cases k, auto)
   752 qed
   753 
   754 lemma startsby_zero_setsum_depends:
   755   assumes a0: "a $0 = (0::'a::idom)" and kn: "n \<ge> k"
   756   shows "setsum (\<lambda>i. (a ^ i)$k) {0 .. n} = setsum (\<lambda>i. (a ^ i)$k) {0 .. k}"
   757   apply (rule setsum_mono_zero_right)
   758   using kn apply auto
   759   apply (rule startsby_zero_power_prefix[rule_format, OF a0])
   760   by arith
   761 
   762 lemma startsby_zero_power_nth_same: assumes a0: "a$0 = (0::'a::{idom})"
   763   shows "a^n $ n = (a$1) ^ n"
   764 proof(induct n)
   765   case 0 thus ?case by (simp add: power_0)
   766 next
   767   case (Suc n)
   768   have "a ^ Suc n $ (Suc n) = (a^n * a)$(Suc n)" by (simp add: ring_simps power_Suc)
   769   also have "\<dots> = setsum (\<lambda>i. a^n$i * a $ (Suc n - i)) {0.. Suc n}" by (simp add: fps_mult_nth)
   770   also have "\<dots> = setsum (\<lambda>i. a^n$i * a $ (Suc n - i)) {n .. Suc n}"
   771     apply (rule setsum_mono_zero_right)
   772     apply simp
   773     apply clarsimp
   774     apply clarsimp
   775     apply (rule startsby_zero_power_prefix[rule_format, OF a0])
   776     apply arith
   777     done
   778   also have "\<dots> = a^n $ n * a$1" using a0 by simp
   779   finally show ?case using Suc.hyps by (simp add: power_Suc)
   780 qed
   781 
   782 lemma fps_inverse_power:
   783   fixes a :: "('a::{field}) fps"
   784   shows "inverse (a^n) = inverse a ^ n"
   785 proof-
   786   {assume a0: "a$0 = 0"
   787     hence eq: "inverse a = 0" by (simp add: fps_inverse_def)
   788     {assume "n = 0" hence ?thesis by simp}
   789     moreover
   790     {assume n: "n > 0"
   791       from startsby_zero_power[OF a0 n] eq a0 n have ?thesis
   792 	by (simp add: fps_inverse_def)}
   793     ultimately have ?thesis by blast}
   794   moreover
   795   {assume a0: "a$0 \<noteq> 0"
   796     have ?thesis
   797       apply (rule fps_inverse_unique)
   798       apply (simp add: a0)
   799       unfolding power_mult_distrib[symmetric]
   800       apply (rule ssubst[where t = "a * inverse a" and s= 1])
   801       apply simp_all
   802       apply (subst mult_commute)
   803       by (rule inverse_mult_eq_1[OF a0])}
   804   ultimately show ?thesis by blast
   805 qed
   806 
   807 lemma fps_deriv_power: "fps_deriv (a ^ n) = fps_const (of_nat n :: 'a:: comm_ring_1) * fps_deriv a * a ^ (n - 1)"
   808   apply (induct n, auto simp add: power_Suc ring_simps fps_const_add[symmetric] simp del: fps_const_add)
   809   by (case_tac n, auto simp add: power_Suc ring_simps)
   810 
   811 lemma fps_inverse_deriv:
   812   fixes a:: "('a :: field) fps"
   813   assumes a0: "a$0 \<noteq> 0"
   814   shows "fps_deriv (inverse a) = - fps_deriv a * inverse a ^ 2"
   815 proof-
   816   from inverse_mult_eq_1[OF a0]
   817   have "fps_deriv (inverse a * a) = 0" by simp
   818   hence "inverse a * fps_deriv a + fps_deriv (inverse a) * a = 0" by simp
   819   hence "inverse a * (inverse a * fps_deriv a + fps_deriv (inverse a) * a) = 0"  by simp
   820   with inverse_mult_eq_1[OF a0]
   821   have "inverse a ^ 2 * fps_deriv a + fps_deriv (inverse a) = 0"
   822     unfolding power2_eq_square
   823     apply (simp add: ring_simps)
   824     by (simp add: mult_assoc[symmetric])
   825   hence "inverse a ^ 2 * fps_deriv a + fps_deriv (inverse a) - fps_deriv a * inverse a ^ 2 = 0 - fps_deriv a * inverse a ^ 2"
   826     by simp
   827   then show "fps_deriv (inverse a) = - fps_deriv a * inverse a ^ 2" by (simp add: ring_simps)
   828 qed
   829 
   830 lemma fps_inverse_mult:
   831   fixes a::"('a :: field) fps"
   832   shows "inverse (a * b) = inverse a * inverse b"
   833 proof-
   834   {assume a0: "a$0 = 0" hence ab0: "(a*b)$0 = 0" by (simp add: fps_mult_nth)
   835     from a0 ab0 have th: "inverse a = 0" "inverse (a*b) = 0" by simp_all
   836     have ?thesis unfolding th by simp}
   837   moreover
   838   {assume b0: "b$0 = 0" hence ab0: "(a*b)$0 = 0" by (simp add: fps_mult_nth)
   839     from b0 ab0 have th: "inverse b = 0" "inverse (a*b) = 0" by simp_all
   840     have ?thesis unfolding th by simp}
   841   moreover
   842   {assume a0: "a$0 \<noteq> 0" and b0: "b$0 \<noteq> 0"
   843     from a0 b0 have ab0:"(a*b) $ 0 \<noteq> 0" by (simp  add: fps_mult_nth)
   844     from inverse_mult_eq_1[OF ab0]
   845     have "inverse (a*b) * (a*b) * inverse a * inverse b = 1 * inverse a * inverse b" by simp
   846     then have "inverse (a*b) * (inverse a * a) * (inverse b * b) = inverse a * inverse b"
   847       by (simp add: ring_simps)
   848     then have ?thesis using inverse_mult_eq_1[OF a0] inverse_mult_eq_1[OF b0] by simp}
   849 ultimately show ?thesis by blast
   850 qed
   851 
   852 lemma fps_inverse_deriv':
   853   fixes a:: "('a :: field) fps"
   854   assumes a0: "a$0 \<noteq> 0"
   855   shows "fps_deriv (inverse a) = - fps_deriv a / a ^ 2"
   856   using fps_inverse_deriv[OF a0]
   857   unfolding power2_eq_square fps_divide_def
   858     fps_inverse_mult by simp
   859 
   860 lemma inverse_mult_eq_1': assumes f0: "f$0 \<noteq> (0::'a::field)"
   861   shows "f * inverse f= 1"
   862   by (metis mult_commute inverse_mult_eq_1 f0)
   863 
   864 lemma fps_divide_deriv:   fixes a:: "('a :: field) fps"
   865   assumes a0: "b$0 \<noteq> 0"
   866   shows "fps_deriv (a / b) = (fps_deriv a * b - a * fps_deriv b) / b ^ 2"
   867   using fps_inverse_deriv[OF a0]
   868   by (simp add: fps_divide_def ring_simps power2_eq_square fps_inverse_mult inverse_mult_eq_1'[OF a0])
   869 
   870 subsection{* The eXtractor series X*}
   871 
   872 lemma minus_one_power_iff: "(- (1::'a :: {comm_ring_1})) ^ n = (if even n then 1 else - 1)"
   873   by (induct n, auto)
   874 
   875 definition "X = Abs_fps (\<lambda>n. if n = 1 then 1 else 0)"
   876 
   877 lemma fps_inverse_gp': "inverse (Abs_fps(\<lambda>n. (1::'a::field)))
   878   = 1 - X"
   879   by (simp add: fps_inverse_gp fps_eq_iff X_def)
   880 
   881 lemma X_mult_nth[simp]: "(X * (f :: ('a::semiring_1) fps)) $n = (if n = 0 then 0 else f $ (n - 1))"
   882 proof-
   883   {assume n: "n \<noteq> 0"
   884     have fN: "finite {0 .. n}" by simp
   885     have "(X * f) $n = (\<Sum>i = 0..n. X $ i * f $ (n - i))" by (simp add: fps_mult_nth)
   886     also have "\<dots> = f $ (n - 1)"
   887       using n by (simp add: X_def mult_delta_left setsum_delta [OF fN])
   888   finally have ?thesis using n by simp }
   889   moreover
   890   {assume n: "n=0" hence ?thesis by (simp add: fps_mult_nth X_def)}
   891   ultimately show ?thesis by blast
   892 qed
   893 
   894 lemma X_mult_right_nth[simp]: "((f :: ('a::comm_semiring_1) fps) * X) $n = (if n = 0 then 0 else f $ (n - 1))"
   895   by (metis X_mult_nth mult_commute)
   896 
   897 lemma X_power_iff: "X^k = Abs_fps (\<lambda>n. if n = k then (1::'a::comm_ring_1) else 0)"
   898 proof(induct k)
   899   case 0 thus ?case by (simp add: X_def fps_eq_iff)
   900 next
   901   case (Suc k)
   902   {fix m
   903     have "(X^Suc k) $ m = (if m = 0 then (0::'a) else (X^k) $ (m - 1))"
   904       by (simp add: power_Suc del: One_nat_def)
   905     then     have "(X^Suc k) $ m = (if m = Suc k then (1::'a) else 0)"
   906       using Suc.hyps by (auto cong del: if_weak_cong)}
   907   then show ?case by (simp add: fps_eq_iff)
   908 qed
   909 
   910 lemma X_power_mult_nth: "(X^k * (f :: ('a::comm_ring_1) fps)) $n = (if n < k then 0 else f $ (n - k))"
   911   apply (induct k arbitrary: n)
   912   apply (simp)
   913   unfolding power_Suc mult_assoc
   914   by (case_tac n, auto)
   915 
   916 lemma X_power_mult_right_nth: "((f :: ('a::comm_ring_1) fps) * X^k) $n = (if n < k then 0 else f $ (n - k))"
   917   by (metis X_power_mult_nth mult_commute)
   918 lemma fps_deriv_X[simp]: "fps_deriv X = 1"
   919   by (simp add: fps_deriv_def X_def fps_eq_iff)
   920 
   921 lemma fps_nth_deriv_X[simp]: "fps_nth_deriv n X = (if n = 0 then X else if n=1 then 1 else 0)"
   922   by (cases "n", simp_all)
   923 
   924 lemma X_nth[simp]: "X$n = (if n = 1 then 1 else 0)" by (simp add: X_def)
   925 lemma X_power_nth[simp]: "(X^k) $n = (if n = k then 1 else (0::'a::comm_ring_1))"
   926   by (simp add: X_power_iff)
   927 
   928 lemma fps_inverse_X_plus1:
   929   "inverse (1 + X) = Abs_fps (\<lambda>n. (- (1::'a::{field})) ^ n)" (is "_ = ?r")
   930 proof-
   931   have eq: "(1 + X) * ?r = 1"
   932     unfolding minus_one_power_iff
   933     by (auto simp add: ring_simps fps_eq_iff)
   934   show ?thesis by (auto simp add: eq intro: fps_inverse_unique)
   935 qed
   936 
   937 
   938 subsection{* Integration *}
   939 
   940 definition
   941   fps_integral :: "'a::field_char_0 fps \<Rightarrow> 'a \<Rightarrow> 'a fps" where
   942   "fps_integral a a0 = Abs_fps (\<lambda>n. if n = 0 then a0 else (a$(n - 1) / of_nat n))"
   943 
   944 lemma fps_deriv_fps_integral: "fps_deriv (fps_integral a a0) = a"
   945   unfolding fps_integral_def fps_deriv_def
   946   by (simp add: fps_eq_iff del: of_nat_Suc)
   947 
   948 lemma fps_integral_linear:
   949   "fps_integral (fps_const a * f + fps_const b * g) (a*a0 + b*b0) =
   950     fps_const a * fps_integral f a0 + fps_const b * fps_integral g b0"
   951   (is "?l = ?r")
   952 proof-
   953   have "fps_deriv ?l = fps_deriv ?r" by (simp add: fps_deriv_fps_integral)
   954   moreover have "?l$0 = ?r$0" by (simp add: fps_integral_def)
   955   ultimately show ?thesis
   956     unfolding fps_deriv_eq_iff by auto
   957 qed
   958 
   959 subsection {* Composition of FPSs *}
   960 definition fps_compose :: "('a::semiring_1) fps \<Rightarrow> 'a fps \<Rightarrow> 'a fps" (infixl "oo" 55) where
   961   fps_compose_def: "a oo b = Abs_fps (\<lambda>n. setsum (\<lambda>i. a$i * (b^i$n)) {0..n})"
   962 
   963 lemma fps_compose_nth: "(a oo b)$n = setsum (\<lambda>i. a$i * (b^i$n)) {0..n}" by (simp add: fps_compose_def)
   964 
   965 lemma fps_compose_X[simp]: "a oo X = (a :: ('a :: comm_ring_1) fps)"
   966   by (simp add: fps_ext fps_compose_def mult_delta_right setsum_delta')
   967 
   968 lemma fps_const_compose[simp]:
   969   "fps_const (a::'a::{comm_ring_1}) oo b = fps_const (a)"
   970   by (simp add: fps_eq_iff fps_compose_nth mult_delta_left setsum_delta)
   971 
   972 lemma number_of_compose[simp]: "(number_of k::('a::{comm_ring_1}) fps) oo b = number_of k"
   973   unfolding number_of_fps_const by simp
   974 
   975 lemma X_fps_compose_startby0[simp]: "a$0 = 0 \<Longrightarrow> X oo a = (a :: ('a :: comm_ring_1) fps)"
   976   by (simp add: fps_eq_iff fps_compose_def mult_delta_left setsum_delta
   977                 power_Suc not_le)
   978 
   979 
   980 subsection {* Rules from Herbert Wilf's Generatingfunctionology*}
   981 
   982 subsubsection {* Rule 1 *}
   983   (* {a_{n+k}}_0^infty Corresponds to (f - setsum (\<lambda>i. a_i * x^i))/x^h, for h>0*)
   984 
   985 lemma fps_power_mult_eq_shift:
   986   "X^Suc k * Abs_fps (\<lambda>n. a (n + Suc k)) = Abs_fps a - setsum (\<lambda>i. fps_const (a i :: 'a:: comm_ring_1) * X^i) {0 .. k}" (is "?lhs = ?rhs")
   987 proof-
   988   {fix n:: nat
   989     have "?lhs $ n = (if n < Suc k then 0 else a n)"
   990       unfolding X_power_mult_nth by auto
   991     also have "\<dots> = ?rhs $ n"
   992     proof(induct k)
   993       case 0 thus ?case by (simp add: fps_setsum_nth power_Suc)
   994     next
   995       case (Suc k)
   996       note th = Suc.hyps[symmetric]
   997       have "(Abs_fps a - setsum (\<lambda>i. fps_const (a i :: 'a) * X^i) {0 .. Suc k})$n = (Abs_fps a - setsum (\<lambda>i. fps_const (a i :: 'a) * X^i) {0 .. k} - fps_const (a (Suc k)) * X^ Suc k) $ n" by (simp add: ring_simps)
   998       also  have "\<dots> = (if n < Suc k then 0 else a n) - (fps_const (a (Suc k)) * X^ Suc k)$n"
   999 	using th
  1000 	unfolding fps_sub_nth by simp
  1001       also have "\<dots> = (if n < Suc (Suc k) then 0 else a n)"
  1002 	unfolding X_power_mult_right_nth
  1003 	apply (auto simp add: not_less fps_const_def)
  1004 	apply (rule cong[of a a, OF refl])
  1005 	by arith
  1006       finally show ?case by simp
  1007     qed
  1008     finally have "?lhs $ n = ?rhs $ n"  .}
  1009   then show ?thesis by (simp add: fps_eq_iff)
  1010 qed
  1011 
  1012 subsubsection{* Rule 2*}
  1013 
  1014   (* We can not reach the form of Wilf, but still near to it using rewrite rules*)
  1015   (* If f reprents {a_n} and P is a polynomial, then
  1016         P(xD) f represents {P(n) a_n}*)
  1017 
  1018 definition "XD = op * X o fps_deriv"
  1019 
  1020 lemma XD_add[simp]:"XD (a + b) = XD a + XD (b :: ('a::comm_ring_1) fps)"
  1021   by (simp add: XD_def ring_simps)
  1022 
  1023 lemma XD_mult_const[simp]:"XD (fps_const (c::'a::comm_ring_1) * a) = fps_const c * XD a"
  1024   by (simp add: XD_def ring_simps)
  1025 
  1026 lemma XD_linear[simp]: "XD (fps_const c * a + fps_const d * b) = fps_const c * XD a + fps_const d * XD (b :: ('a::comm_ring_1) fps)"
  1027   by simp
  1028 
  1029 lemma XDN_linear:
  1030   "(XD ^^ n) (fps_const c * a + fps_const d * b) = fps_const c * (XD ^^ n) a + fps_const d * (XD ^^ n) (b :: ('a::comm_ring_1) fps)"
  1031   by (induct n, simp_all)
  1032 
  1033 lemma fps_mult_X_deriv_shift: "X* fps_deriv a = Abs_fps (\<lambda>n. of_nat n* a$n)" by (simp add: fps_eq_iff)
  1034 
  1035 
  1036 lemma fps_mult_XD_shift:
  1037   "(XD ^^ k) (a:: ('a::{comm_ring_1}) fps) = Abs_fps (\<lambda>n. (of_nat n ^ k) * a$n)"
  1038   by (induct k arbitrary: a) (simp_all add: power_Suc XD_def fps_eq_iff ring_simps del: One_nat_def)
  1039 
  1040 subsubsection{* Rule 3 is trivial and is given by @{text fps_times_def}*}
  1041 subsubsection{* Rule 5 --- summation and "division" by (1 - X)*}
  1042 
  1043 lemma fps_divide_X_minus1_setsum_lemma:
  1044   "a = ((1::('a::comm_ring_1) fps) - X) * Abs_fps (\<lambda>n. setsum (\<lambda>i. a $ i) {0..n})"
  1045 proof-
  1046   let ?X = "X::('a::comm_ring_1) fps"
  1047   let ?sa = "Abs_fps (\<lambda>n. setsum (\<lambda>i. a $ i) {0..n})"
  1048   have th0: "\<And>i. (1 - (X::'a fps)) $ i = (if i = 0 then 1 else if i = 1 then - 1 else 0)" by simp
  1049   {fix n:: nat
  1050     {assume "n=0" hence "a$n = ((1 - ?X) * ?sa) $ n"
  1051 	by (simp add: fps_mult_nth)}
  1052     moreover
  1053     {assume n0: "n \<noteq> 0"
  1054       then have u: "{0} \<union> ({1} \<union> {2..n}) = {0..n}" "{1}\<union>{2..n} = {1..n}"
  1055 	"{0..n - 1}\<union>{n} = {0..n}"
  1056 	apply (simp_all add: expand_set_eq) by presburger+
  1057       have d: "{0} \<inter> ({1} \<union> {2..n}) = {}" "{1} \<inter> {2..n} = {}"
  1058 	"{0..n - 1}\<inter>{n} ={}" using n0
  1059 	by (simp_all add: expand_set_eq, presburger+)
  1060       have f: "finite {0}" "finite {1}" "finite {2 .. n}"
  1061 	"finite {0 .. n - 1}" "finite {n}" by simp_all
  1062     have "((1 - ?X) * ?sa) $ n = setsum (\<lambda>i. (1 - ?X)$ i * ?sa $ (n - i)) {0 .. n}"
  1063       by (simp add: fps_mult_nth)
  1064     also have "\<dots> = a$n" unfolding th0
  1065       unfolding setsum_Un_disjoint[OF f(1) finite_UnI[OF f(2,3)] d(1), unfolded u(1)]
  1066       unfolding setsum_Un_disjoint[OF f(2) f(3) d(2)]
  1067       apply (simp)
  1068       unfolding setsum_Un_disjoint[OF f(4,5) d(3), unfolded u(3)]
  1069       by simp
  1070     finally have "a$n = ((1 - ?X) * ?sa) $ n" by simp}
  1071   ultimately have "a$n = ((1 - ?X) * ?sa) $ n" by blast}
  1072 then show ?thesis
  1073   unfolding fps_eq_iff by blast
  1074 qed
  1075 
  1076 lemma fps_divide_X_minus1_setsum:
  1077   "a /((1::('a::field) fps) - X)  = Abs_fps (\<lambda>n. setsum (\<lambda>i. a $ i) {0..n})"
  1078 proof-
  1079   let ?X = "1 - (X::('a::field) fps)"
  1080   have th0: "?X $ 0 \<noteq> 0" by simp
  1081   have "a /?X = ?X *  Abs_fps (\<lambda>n\<Colon>nat. setsum (op $ a) {0..n}) * inverse ?X"
  1082     using fps_divide_X_minus1_setsum_lemma[of a, symmetric] th0
  1083     by (simp add: fps_divide_def mult_assoc)
  1084   also have "\<dots> = (inverse ?X * ?X) * Abs_fps (\<lambda>n\<Colon>nat. setsum (op $ a) {0..n}) "
  1085     by (simp add: mult_ac)
  1086   finally show ?thesis by (simp add: inverse_mult_eq_1[OF th0])
  1087 qed
  1088 
  1089 subsubsection{* Rule 4 in its more general form: generalizes Rule 3 for an arbitrary
  1090   finite product of FPS, also the relvant instance of powers of a FPS*}
  1091 
  1092 definition "natpermute n k = {l:: nat list. length l = k \<and> foldl op + 0 l = n}"
  1093 
  1094 lemma natlist_trivial_1: "natpermute n 1 = {[n]}"
  1095   apply (auto simp add: natpermute_def)
  1096   apply (case_tac x, auto)
  1097   done
  1098 
  1099 lemma foldl_add_start0:
  1100   "foldl op + x xs = x + foldl op + (0::nat) xs"
  1101   apply (induct xs arbitrary: x)
  1102   apply simp
  1103   unfolding foldl.simps
  1104   apply atomize
  1105   apply (subgoal_tac "\<forall>x\<Colon>nat. foldl op + x xs = x + foldl op + (0\<Colon>nat) xs")
  1106   apply (erule_tac x="x + a" in allE)
  1107   apply (erule_tac x="a" in allE)
  1108   apply simp
  1109   apply assumption
  1110   done
  1111 
  1112 lemma foldl_add_append: "foldl op + (x::nat) (xs@ys) = foldl op + x xs + foldl op + 0 ys"
  1113   apply (induct ys arbitrary: x xs)
  1114   apply auto
  1115   apply (subst (2) foldl_add_start0)
  1116   apply simp
  1117   apply (subst (2) foldl_add_start0)
  1118   by simp
  1119 
  1120 lemma foldl_add_setsum: "foldl op + (x::nat) xs = x + setsum (nth xs) {0..<length xs}"
  1121 proof(induct xs arbitrary: x)
  1122   case Nil thus ?case by simp
  1123 next
  1124   case (Cons a as x)
  1125   have eq: "setsum (op ! (a#as)) {1..<length (a#as)} = setsum (op ! as) {0..<length as}"
  1126     apply (rule setsum_reindex_cong [where f=Suc])
  1127     by (simp_all add: inj_on_def)
  1128   have f: "finite {0}" "finite {1 ..< length (a#as)}" by simp_all
  1129   have d: "{0} \<inter> {1..<length (a#as)} = {}" by simp
  1130   have seq: "{0} \<union> {1..<length(a#as)} = {0 ..<length (a#as)}" by auto
  1131   have "foldl op + x (a#as) = x + foldl op + a as "
  1132     apply (subst foldl_add_start0)    by simp
  1133   also have "\<dots> = x + a + setsum (op ! as) {0..<length as}" unfolding Cons.hyps by simp
  1134   also have "\<dots> = x + setsum (op ! (a#as)) {0..<length (a#as)}"
  1135     unfolding eq[symmetric]
  1136     unfolding setsum_Un_disjoint[OF f d, unfolded seq]
  1137     by simp
  1138   finally show ?case  .
  1139 qed
  1140 
  1141 
  1142 lemma append_natpermute_less_eq:
  1143   assumes h: "xs@ys \<in> natpermute n k" shows "foldl op + 0 xs \<le> n" and "foldl op + 0 ys \<le> n"
  1144 proof-
  1145   {from h have "foldl op + 0 (xs@ ys) = n" by (simp add: natpermute_def)
  1146     hence "foldl op + 0 xs + foldl op + 0 ys = n" unfolding foldl_add_append .}
  1147   note th = this
  1148   {from th show "foldl op + 0 xs \<le> n" by simp}
  1149   {from th show "foldl op + 0 ys \<le> n" by simp}
  1150 qed
  1151 
  1152 lemma natpermute_split:
  1153   assumes mn: "h \<le> k"
  1154   shows "natpermute n k = (\<Union>m \<in>{0..n}. {l1 @ l2 |l1 l2. l1 \<in> natpermute m h \<and> l2 \<in> natpermute (n - m) (k - h)})" (is "?L = ?R" is "?L = (\<Union>m \<in>{0..n}. ?S m)")
  1155 proof-
  1156   {fix l assume l: "l \<in> ?R"
  1157     from l obtain m xs ys where h: "m \<in> {0..n}" and xs: "xs \<in> natpermute m h" and ys: "ys \<in> natpermute (n - m) (k - h)"  and leq: "l = xs@ys" by blast
  1158     from xs have xs': "foldl op + 0 xs = m" by (simp add: natpermute_def)
  1159     from ys have ys': "foldl op + 0 ys = n - m" by (simp add: natpermute_def)
  1160     have "l \<in> ?L" using leq xs ys h
  1161       apply simp
  1162       apply (clarsimp simp add: natpermute_def simp del: foldl_append)
  1163       apply (simp add: foldl_add_append[unfolded foldl_append])
  1164       unfolding xs' ys'
  1165       using mn xs ys
  1166       unfolding natpermute_def by simp}
  1167   moreover
  1168   {fix l assume l: "l \<in> natpermute n k"
  1169     let ?xs = "take h l"
  1170     let ?ys = "drop h l"
  1171     let ?m = "foldl op + 0 ?xs"
  1172     from l have ls: "foldl op + 0 (?xs @ ?ys) = n" by (simp add: natpermute_def)
  1173     have xs: "?xs \<in> natpermute ?m h" using l mn by (simp add: natpermute_def)
  1174     have ys: "?ys \<in> natpermute (n - ?m) (k - h)" using l mn ls[unfolded foldl_add_append]
  1175       by (simp add: natpermute_def)
  1176     from ls have m: "?m \<in> {0..n}"  unfolding foldl_add_append by simp
  1177     from xs ys ls have "l \<in> ?R"
  1178       apply auto
  1179       apply (rule bexI[where x = "?m"])
  1180       apply (rule exI[where x = "?xs"])
  1181       apply (rule exI[where x = "?ys"])
  1182       using ls l unfolding foldl_add_append
  1183       by (auto simp add: natpermute_def)}
  1184   ultimately show ?thesis by blast
  1185 qed
  1186 
  1187 lemma natpermute_0: "natpermute n 0 = (if n = 0 then {[]} else {})"
  1188   by (auto simp add: natpermute_def)
  1189 lemma natpermute_0'[simp]: "natpermute 0 k = (if k = 0 then {[]} else {replicate k 0})"
  1190   apply (auto simp add: set_replicate_conv_if natpermute_def)
  1191   apply (rule nth_equalityI)
  1192   by simp_all
  1193 
  1194 lemma natpermute_finite: "finite (natpermute n k)"
  1195 proof(induct k arbitrary: n)
  1196   case 0 thus ?case
  1197     apply (subst natpermute_split[of 0 0, simplified])
  1198     by (simp add: natpermute_0)
  1199 next
  1200   case (Suc k)
  1201   then show ?case unfolding natpermute_split[of k "Suc k", simplified]
  1202     apply -
  1203     apply (rule finite_UN_I)
  1204     apply simp
  1205     unfolding One_nat_def[symmetric] natlist_trivial_1
  1206     apply simp
  1207     done
  1208 qed
  1209 
  1210 lemma natpermute_contain_maximal:
  1211   "{xs \<in> natpermute n (k+1). n \<in> set xs} = UNION {0 .. k} (\<lambda>i. {(replicate (k+1) 0) [i:=n]})"
  1212   (is "?A = ?B")
  1213 proof-
  1214   {fix xs assume H: "xs \<in> natpermute n (k+1)" and n: "n \<in> set xs"
  1215     from n obtain i where i: "i \<in> {0.. k}" "xs!i = n" using H
  1216       unfolding in_set_conv_nth by (auto simp add: less_Suc_eq_le natpermute_def)
  1217     have eqs: "({0..k} - {i}) \<union> {i} = {0..k}" using i by auto
  1218     have f: "finite({0..k} - {i})" "finite {i}" by auto
  1219     have d: "({0..k} - {i}) \<inter> {i} = {}" using i by auto
  1220     from H have "n = setsum (nth xs) {0..k}" apply (simp add: natpermute_def)
  1221       unfolding foldl_add_setsum by (auto simp add: atLeastLessThanSuc_atLeastAtMost)
  1222     also have "\<dots> = n + setsum (nth xs) ({0..k} - {i})"
  1223       unfolding setsum_Un_disjoint[OF f d, unfolded eqs] using i by simp
  1224     finally have zxs: "\<forall> j\<in> {0..k} - {i}. xs!j = 0" by auto
  1225     from H have xsl: "length xs = k+1" by (simp add: natpermute_def)
  1226     from i have i': "i < length (replicate (k+1) 0)"   "i < k+1"
  1227       unfolding length_replicate  by arith+
  1228     have "xs = replicate (k+1) 0 [i := n]"
  1229       apply (rule nth_equalityI)
  1230       unfolding xsl length_list_update length_replicate
  1231       apply simp
  1232       apply clarify
  1233       unfolding nth_list_update[OF i'(1)]
  1234       using i zxs
  1235       by (case_tac "ia=i", auto simp del: replicate.simps)
  1236     then have "xs \<in> ?B" using i by blast}
  1237   moreover
  1238   {fix i assume i: "i \<in> {0..k}"
  1239     let ?xs = "replicate (k+1) 0 [i:=n]"
  1240     have nxs: "n \<in> set ?xs"
  1241       apply (rule set_update_memI) using i by simp
  1242     have xsl: "length ?xs = k+1" by (simp only: length_replicate length_list_update)
  1243     have "foldl op + 0 ?xs = setsum (nth ?xs) {0..<k+1}"
  1244       unfolding foldl_add_setsum add_0 length_replicate length_list_update ..
  1245     also have "\<dots> = setsum (\<lambda>j. if j = i then n else 0) {0..< k+1}"
  1246       apply (rule setsum_cong2) by (simp del: replicate.simps)
  1247     also have "\<dots> = n" using i by (simp add: setsum_delta)
  1248     finally
  1249     have "?xs \<in> natpermute n (k+1)" using xsl unfolding natpermute_def Collect_def mem_def
  1250       by blast
  1251     then have "?xs \<in> ?A"  using nxs  by blast}
  1252   ultimately show ?thesis by auto
  1253 qed
  1254 
  1255     (* The general form *)
  1256 lemma fps_setprod_nth:
  1257   fixes m :: nat and a :: "nat \<Rightarrow> ('a::comm_ring_1) fps"
  1258   shows "(setprod a {0 .. m})$n = setsum (\<lambda>v. setprod (\<lambda>j. (a j) $ (v!j)) {0..m}) (natpermute n (m+1))"
  1259   (is "?P m n")
  1260 proof(induct m arbitrary: n rule: nat_less_induct)
  1261   fix m n assume H: "\<forall>m' < m. \<forall>n. ?P m' n"
  1262   {assume m0: "m = 0"
  1263     hence "?P m n" apply simp
  1264       unfolding natlist_trivial_1[where n = n, unfolded One_nat_def] by simp}
  1265   moreover
  1266   {fix k assume k: "m = Suc k"
  1267     have km: "k < m" using k by arith
  1268     have u0: "{0 .. k} \<union> {m} = {0..m}" using k apply (simp add: expand_set_eq) by presburger
  1269     have f0: "finite {0 .. k}" "finite {m}" by auto
  1270     have d0: "{0 .. k} \<inter> {m} = {}" using k by auto
  1271     have "(setprod a {0 .. m}) $ n = (setprod a {0 .. k} * a m) $ n"
  1272       unfolding setprod_Un_disjoint[OF f0 d0, unfolded u0] by simp
  1273     also have "\<dots> = (\<Sum>i = 0..n. (\<Sum>v\<in>natpermute i (k + 1). \<Prod>j\<in>{0..k}. a j $ v ! j) * a m $ (n - i))"
  1274       unfolding fps_mult_nth H[rule_format, OF km] ..
  1275     also have "\<dots> = (\<Sum>v\<in>natpermute n (m + 1). \<Prod>j\<in>{0..m}. a j $ v ! j)"
  1276       apply (simp add: k)
  1277       unfolding natpermute_split[of m "m + 1", simplified, of n, unfolded natlist_trivial_1[unfolded One_nat_def] k]
  1278       apply (subst setsum_UN_disjoint)
  1279       apply simp
  1280       apply simp
  1281       unfolding image_Collect[symmetric]
  1282       apply clarsimp
  1283       apply (rule finite_imageI)
  1284       apply (rule natpermute_finite)
  1285       apply (clarsimp simp add: expand_set_eq)
  1286       apply auto
  1287       apply (rule setsum_cong2)
  1288       unfolding setsum_left_distrib
  1289       apply (rule sym)
  1290       apply (rule_tac f="\<lambda>xs. xs @[n - x]" in  setsum_reindex_cong)
  1291       apply (simp add: inj_on_def)
  1292       apply auto
  1293       unfolding setprod_Un_disjoint[OF f0 d0, unfolded u0, unfolded k]
  1294       apply (clarsimp simp add: natpermute_def nth_append)
  1295       done
  1296     finally have "?P m n" .}
  1297   ultimately show "?P m n " by (cases m, auto)
  1298 qed
  1299 
  1300 text{* The special form for powers *}
  1301 lemma fps_power_nth_Suc:
  1302   fixes m :: nat and a :: "('a::comm_ring_1) fps"
  1303   shows "(a ^ Suc m)$n = setsum (\<lambda>v. setprod (\<lambda>j. a $ (v!j)) {0..m}) (natpermute n (m+1))"
  1304 proof-
  1305   have f: "finite {0 ..m}" by simp
  1306   have th0: "a^Suc m = setprod (\<lambda>i. a) {0..m}" unfolding setprod_constant[OF f, of a] by simp
  1307   show ?thesis unfolding th0 fps_setprod_nth ..
  1308 qed
  1309 lemma fps_power_nth:
  1310   fixes m :: nat and a :: "('a::comm_ring_1) fps"
  1311   shows "(a ^m)$n = (if m=0 then 1$n else setsum (\<lambda>v. setprod (\<lambda>j. a $ (v!j)) {0..m - 1}) (natpermute n m))"
  1312   by (cases m, simp_all add: fps_power_nth_Suc del: power_Suc)
  1313 
  1314 lemma fps_nth_power_0:
  1315   fixes m :: nat and a :: "('a::{comm_ring_1}) fps"
  1316   shows "(a ^m)$0 = (a$0) ^ m"
  1317 proof-
  1318   {assume "m=0" hence ?thesis by simp}
  1319   moreover
  1320   {fix n assume m: "m = Suc n"
  1321     have c: "m = card {0..n}" using m by simp
  1322    have "(a ^m)$0 = setprod (\<lambda>i. a$0) {0..n}"
  1323      by (simp add: m fps_power_nth del: replicate.simps power_Suc)
  1324    also have "\<dots> = (a$0) ^ m"
  1325      unfolding c by (rule setprod_constant, simp)
  1326    finally have ?thesis .}
  1327  ultimately show ?thesis by (cases m, auto)
  1328 qed
  1329 
  1330 lemma fps_compose_inj_right:
  1331   assumes a0: "a$0 = (0::'a::{idom})"
  1332   and a1: "a$1 \<noteq> 0"
  1333   shows "(b oo a = c oo a) \<longleftrightarrow> b = c" (is "?lhs \<longleftrightarrow>?rhs")
  1334 proof-
  1335   {assume ?rhs then have "?lhs" by simp}
  1336   moreover
  1337   {assume h: ?lhs
  1338     {fix n have "b$n = c$n"
  1339       proof(induct n rule: nat_less_induct)
  1340 	fix n assume H: "\<forall>m<n. b$m = c$m"
  1341 	{assume n0: "n=0"
  1342 	  from h have "(b oo a)$n = (c oo a)$n" by simp
  1343 	  hence "b$n = c$n" using n0 by (simp add: fps_compose_nth)}
  1344 	moreover
  1345 	{fix n1 assume n1: "n = Suc n1"
  1346 	  have f: "finite {0 .. n1}" "finite {n}" by simp_all
  1347 	  have eq: "{0 .. n1} \<union> {n} = {0 .. n}" using n1 by auto
  1348 	  have d: "{0 .. n1} \<inter> {n} = {}" using n1 by auto
  1349 	  have seq: "(\<Sum>i = 0..n1. b $ i * a ^ i $ n) = (\<Sum>i = 0..n1. c $ i * a ^ i $ n)"
  1350 	    apply (rule setsum_cong2)
  1351 	    using H n1 by auto
  1352 	  have th0: "(b oo a) $n = (\<Sum>i = 0..n1. c $ i * a ^ i $ n) + b$n * (a$1)^n"
  1353 	    unfolding fps_compose_nth setsum_Un_disjoint[OF f d, unfolded eq] seq
  1354 	    using startsby_zero_power_nth_same[OF a0]
  1355 	    by simp
  1356 	  have th1: "(c oo a) $n = (\<Sum>i = 0..n1. c $ i * a ^ i $ n) + c$n * (a$1)^n"
  1357 	    unfolding fps_compose_nth setsum_Un_disjoint[OF f d, unfolded eq]
  1358 	    using startsby_zero_power_nth_same[OF a0]
  1359 	    by simp
  1360 	  from h[unfolded fps_eq_iff, rule_format, of n] th0 th1 a1
  1361 	  have "b$n = c$n" by auto}
  1362 	ultimately show "b$n = c$n" by (cases n, auto)
  1363       qed}
  1364     then have ?rhs by (simp add: fps_eq_iff)}
  1365   ultimately show ?thesis by blast
  1366 qed
  1367 
  1368 
  1369 subsection {* Radicals *}
  1370 
  1371 declare setprod_cong[fundef_cong]
  1372 function radical :: "(nat \<Rightarrow> 'a \<Rightarrow> 'a) \<Rightarrow> nat \<Rightarrow> ('a::{field}) fps \<Rightarrow> nat \<Rightarrow> 'a" where
  1373   "radical r 0 a 0 = 1"
  1374 | "radical r 0 a (Suc n) = 0"
  1375 | "radical r (Suc k) a 0 = r (Suc k) (a$0)"
  1376 | "radical r (Suc k) a (Suc n) = (a$ Suc n - setsum (\<lambda>xs. setprod (\<lambda>j. radical r (Suc k) a (xs ! j)) {0..k}) {xs. xs \<in> natpermute (Suc n) (Suc k) \<and> Suc n \<notin> set xs}) / (of_nat (Suc k) * (radical r (Suc k) a 0)^k)"
  1377 by pat_completeness auto
  1378 
  1379 termination radical
  1380 proof
  1381   let ?R = "measure (\<lambda>(r, k, a, n). n)"
  1382   {
  1383     show "wf ?R" by auto}
  1384   {fix r k a n xs i
  1385     assume xs: "xs \<in> {xs \<in> natpermute (Suc n) (Suc k). Suc n \<notin> set xs}" and i: "i \<in> {0..k}"
  1386     {assume c: "Suc n \<le> xs ! i"
  1387       from xs i have "xs !i \<noteq> Suc n" by (auto simp add: in_set_conv_nth natpermute_def)
  1388       with c have c': "Suc n < xs!i" by arith
  1389       have fths: "finite {0 ..< i}" "finite {i}" "finite {i+1..<Suc k}" by simp_all
  1390       have d: "{0 ..< i} \<inter> ({i} \<union> {i+1 ..< Suc k}) = {}" "{i} \<inter> {i+1..< Suc k} = {}" by auto
  1391       have eqs: "{0..<Suc k} = {0 ..< i} \<union> ({i} \<union> {i+1 ..< Suc k})" using i by auto
  1392       from xs have "Suc n = foldl op + 0 xs" by (simp add: natpermute_def)
  1393       also have "\<dots> = setsum (nth xs) {0..<Suc k}" unfolding foldl_add_setsum using xs
  1394 	by (simp add: natpermute_def)
  1395       also have "\<dots> = xs!i + setsum (nth xs) {0..<i} + setsum (nth xs) {i+1..<Suc k}"
  1396 	unfolding eqs  setsum_Un_disjoint[OF fths(1) finite_UnI[OF fths(2,3)] d(1)]
  1397 	unfolding setsum_Un_disjoint[OF fths(2) fths(3) d(2)]
  1398 	by simp
  1399       finally have False using c' by simp}
  1400     then show "((r,Suc k,a,xs!i), r, Suc k, a, Suc n) \<in> ?R"
  1401       apply auto by (metis not_less)}
  1402   {fix r k a n
  1403     show "((r,Suc k, a, 0),r, Suc k, a, Suc n) \<in> ?R" by simp}
  1404 qed
  1405 
  1406 definition "fps_radical r n a = Abs_fps (radical r n a)"
  1407 
  1408 lemma fps_radical0[simp]: "fps_radical r 0 a = 1"
  1409   apply (auto simp add: fps_eq_iff fps_radical_def)  by (case_tac n, auto)
  1410 
  1411 lemma fps_radical_nth_0[simp]: "fps_radical r n a $ 0 = (if n=0 then 1 else r n (a$0))"
  1412   by (cases n, simp_all add: fps_radical_def)
  1413 
  1414 lemma fps_radical_power_nth[simp]:
  1415   assumes r: "(r k (a$0)) ^ k = a$0"
  1416   shows "fps_radical r k a ^ k $ 0 = (if k = 0 then 1 else a$0)"
  1417 proof-
  1418   {assume "k=0" hence ?thesis by simp }
  1419   moreover
  1420   {fix h assume h: "k = Suc h"
  1421     have fh: "finite {0..h}" by simp
  1422     have eq1: "fps_radical r k a ^ k $ 0 = (\<Prod>j\<in>{0..h}. fps_radical r k a $ (replicate k 0) ! j)"
  1423       unfolding fps_power_nth h by simp
  1424     also have "\<dots> = (\<Prod>j\<in>{0..h}. r k (a$0))"
  1425       apply (rule setprod_cong)
  1426       apply simp
  1427       using h
  1428       apply (subgoal_tac "replicate k (0::nat) ! x = 0")
  1429       by (auto intro: nth_replicate simp del: replicate.simps)
  1430     also have "\<dots> = a$0"
  1431       unfolding setprod_constant[OF fh] using r by (simp add: h)
  1432     finally have ?thesis using h by simp}
  1433   ultimately show ?thesis by (cases k, auto)
  1434 qed
  1435 
  1436 lemma natpermute_max_card: assumes n0: "n\<noteq>0"
  1437   shows "card {xs \<in> natpermute n (k+1). n \<in> set xs} = k+1"
  1438   unfolding natpermute_contain_maximal
  1439 proof-
  1440   let ?A= "\<lambda>i. {replicate (k + 1) 0[i := n]}"
  1441   let ?K = "{0 ..k}"
  1442   have fK: "finite ?K" by simp
  1443   have fAK: "\<forall>i\<in>?K. finite (?A i)" by auto
  1444   have d: "\<forall>i\<in> ?K. \<forall>j\<in> ?K. i \<noteq> j \<longrightarrow> {replicate (k + 1) 0[i := n]} \<inter> {replicate (k + 1) 0[j := n]} = {}"
  1445   proof(clarify)
  1446     fix i j assume i: "i \<in> ?K" and j: "j\<in> ?K" and ij: "i\<noteq>j"
  1447     {assume eq: "replicate (k+1) 0 [i:=n] = replicate (k+1) 0 [j:= n]"
  1448       have "(replicate (k+1) 0 [i:=n] ! i) = n" using i by (simp del: replicate.simps)
  1449       moreover
  1450       have "(replicate (k+1) 0 [j:=n] ! i) = 0" using i ij by (simp del: replicate.simps)
  1451       ultimately have False using eq n0 by (simp del: replicate.simps)}
  1452     then show "{replicate (k + 1) 0[i := n]} \<inter> {replicate (k + 1) 0[j := n]} = {}"
  1453       by auto
  1454   qed
  1455   from card_UN_disjoint[OF fK fAK d]
  1456   show "card (\<Union>i\<in>{0..k}. {replicate (k + 1) 0[i := n]}) = k+1" by simp
  1457 qed
  1458 
  1459 lemma power_radical:
  1460   fixes a:: "'a::field_char_0 fps"
  1461   assumes a0: "a$0 \<noteq> 0"
  1462   shows "(r (Suc k) (a$0)) ^ Suc k = a$0 \<longleftrightarrow> (fps_radical r (Suc k) a) ^ (Suc k) = a"
  1463 proof-
  1464   let ?r = "fps_radical r (Suc k) a"
  1465   {assume r0: "(r (Suc k) (a$0)) ^ Suc k = a$0"
  1466     from a0 r0 have r00: "r (Suc k) (a$0) \<noteq> 0" by auto
  1467     {fix z have "?r ^ Suc k $ z = a$z"
  1468       proof(induct z rule: nat_less_induct)
  1469 	fix n assume H: "\<forall>m<n. ?r ^ Suc k $ m = a$m"
  1470 	{assume "n = 0" hence "?r ^ Suc k $ n = a $n"
  1471 	    using fps_radical_power_nth[of r "Suc k" a, OF r0] by simp}
  1472 	moreover
  1473 	{fix n1 assume n1: "n = Suc n1"
  1474 	  have fK: "finite {0..k}" by simp
  1475 	  have nz: "n \<noteq> 0" using n1 by arith
  1476 	  let ?Pnk = "natpermute n (k + 1)"
  1477 	  let ?Pnkn = "{xs \<in> ?Pnk. n \<in> set xs}"
  1478 	  let ?Pnknn = "{xs \<in> ?Pnk. n \<notin> set xs}"
  1479 	  have eq: "?Pnkn \<union> ?Pnknn = ?Pnk" by blast
  1480 	  have d: "?Pnkn \<inter> ?Pnknn = {}" by blast
  1481 	  have f: "finite ?Pnkn" "finite ?Pnknn"
  1482 	    using finite_Un[of ?Pnkn ?Pnknn, unfolded eq]
  1483 	    by (metis natpermute_finite)+
  1484 	  let ?f = "\<lambda>v. \<Prod>j\<in>{0..k}. ?r $ v ! j"
  1485 	  have "setsum ?f ?Pnkn = setsum (\<lambda>v. ?r $ n * r (Suc k) (a $ 0) ^ k) ?Pnkn"
  1486 	  proof(rule setsum_cong2)
  1487 	    fix v assume v: "v \<in> {xs \<in> natpermute n (k + 1). n \<in> set xs}"
  1488 	    let ?ths = "(\<Prod>j\<in>{0..k}. fps_radical r (Suc k) a $ v ! j) = fps_radical r (Suc k) a $ n * r (Suc k) (a $ 0) ^ k"
  1489 	  from v obtain i where i: "i \<in> {0..k}" "v = replicate (k+1) 0 [i:= n]"
  1490 	    unfolding natpermute_contain_maximal by auto
  1491 	  have "(\<Prod>j\<in>{0..k}. fps_radical r (Suc k) a $ v ! j) = (\<Prod>j\<in>{0..k}. if j = i then fps_radical r (Suc k) a $ n else r (Suc k) (a$0))"
  1492 	    apply (rule setprod_cong, simp)
  1493 	    using i r0 by (simp del: replicate.simps)
  1494 	  also have "\<dots> = (fps_radical r (Suc k) a $ n) * r (Suc k) (a$0) ^ k"
  1495 	    unfolding setprod_gen_delta[OF fK] using i r0 by simp
  1496 	  finally show ?ths .
  1497 	qed
  1498 	then have "setsum ?f ?Pnkn = of_nat (k+1) * ?r $ n * r (Suc k) (a $ 0) ^ k"
  1499 	  by (simp add: natpermute_max_card[OF nz, simplified])
  1500 	also have "\<dots> = a$n - setsum ?f ?Pnknn"
  1501 	  unfolding n1 using r00 a0 by (simp add: field_simps fps_radical_def del: of_nat_Suc )
  1502 	finally have fn: "setsum ?f ?Pnkn = a$n - setsum ?f ?Pnknn" .
  1503 	have "(?r ^ Suc k)$n = setsum ?f ?Pnkn + setsum ?f ?Pnknn"
  1504 	  unfolding fps_power_nth_Suc setsum_Un_disjoint[OF f d, unfolded eq] ..
  1505 	also have "\<dots> = a$n" unfolding fn by simp
  1506 	finally have "?r ^ Suc k $ n = a $n" .}
  1507       ultimately  show "?r ^ Suc k $ n = a $n" by (cases n, auto)
  1508     qed }
  1509   then have ?thesis using r0 by (simp add: fps_eq_iff)}
  1510 moreover 
  1511 { assume h: "(fps_radical r (Suc k) a) ^ (Suc k) = a"
  1512   hence "((fps_radical r (Suc k) a) ^ (Suc k))$0 = a$0" by simp
  1513   then have "(r (Suc k) (a$0)) ^ Suc k = a$0"
  1514     unfolding fps_power_nth_Suc
  1515     by (simp add: setprod_constant del: replicate.simps)}
  1516 ultimately show ?thesis by blast
  1517 qed
  1518 
  1519 (*
  1520 lemma power_radical:
  1521   fixes a:: "'a::field_char_0 fps"
  1522   assumes r0: "(r (Suc k) (a$0)) ^ Suc k = a$0" and a0: "a$0 \<noteq> 0"
  1523   shows "(fps_radical r (Suc k) a) ^ (Suc k) = a"
  1524 proof-
  1525   let ?r = "fps_radical r (Suc k) a"
  1526   from a0 r0 have r00: "r (Suc k) (a$0) \<noteq> 0" by auto
  1527   {fix z have "?r ^ Suc k $ z = a$z"
  1528     proof(induct z rule: nat_less_induct)
  1529       fix n assume H: "\<forall>m<n. ?r ^ Suc k $ m = a$m"
  1530       {assume "n = 0" hence "?r ^ Suc k $ n = a $n"
  1531 	  using fps_radical_power_nth[of r "Suc k" a, OF r0] by simp}
  1532       moreover
  1533       {fix n1 assume n1: "n = Suc n1"
  1534 	have fK: "finite {0..k}" by simp
  1535 	have nz: "n \<noteq> 0" using n1 by arith
  1536 	let ?Pnk = "natpermute n (k + 1)"
  1537 	let ?Pnkn = "{xs \<in> ?Pnk. n \<in> set xs}"
  1538 	let ?Pnknn = "{xs \<in> ?Pnk. n \<notin> set xs}"
  1539 	have eq: "?Pnkn \<union> ?Pnknn = ?Pnk" by blast
  1540 	have d: "?Pnkn \<inter> ?Pnknn = {}" by blast
  1541 	have f: "finite ?Pnkn" "finite ?Pnknn"
  1542 	  using finite_Un[of ?Pnkn ?Pnknn, unfolded eq]
  1543 	  by (metis natpermute_finite)+
  1544 	let ?f = "\<lambda>v. \<Prod>j\<in>{0..k}. ?r $ v ! j"
  1545 	have "setsum ?f ?Pnkn = setsum (\<lambda>v. ?r $ n * r (Suc k) (a $ 0) ^ k) ?Pnkn"
  1546 	proof(rule setsum_cong2)
  1547 	  fix v assume v: "v \<in> {xs \<in> natpermute n (k + 1). n \<in> set xs}"
  1548 	  let ?ths = "(\<Prod>j\<in>{0..k}. fps_radical r (Suc k) a $ v ! j) = fps_radical r (Suc k) a $ n * r (Suc k) (a $ 0) ^ k"
  1549 	  from v obtain i where i: "i \<in> {0..k}" "v = replicate (k+1) 0 [i:= n]"
  1550 	    unfolding natpermute_contain_maximal by auto
  1551 	  have "(\<Prod>j\<in>{0..k}. fps_radical r (Suc k) a $ v ! j) = (\<Prod>j\<in>{0..k}. if j = i then fps_radical r (Suc k) a $ n else r (Suc k) (a$0))"
  1552 	    apply (rule setprod_cong, simp)
  1553 	    using i r0 by (simp del: replicate.simps)
  1554 	  also have "\<dots> = (fps_radical r (Suc k) a $ n) * r (Suc k) (a$0) ^ k"
  1555 	    unfolding setprod_gen_delta[OF fK] using i r0 by simp
  1556 	  finally show ?ths .
  1557 	qed
  1558 	then have "setsum ?f ?Pnkn = of_nat (k+1) * ?r $ n * r (Suc k) (a $ 0) ^ k"
  1559 	  by (simp add: natpermute_max_card[OF nz, simplified])
  1560 	also have "\<dots> = a$n - setsum ?f ?Pnknn"
  1561 	  unfolding n1 using r00 a0 by (simp add: field_simps fps_radical_def del: of_nat_Suc )
  1562 	finally have fn: "setsum ?f ?Pnkn = a$n - setsum ?f ?Pnknn" .
  1563 	have "(?r ^ Suc k)$n = setsum ?f ?Pnkn + setsum ?f ?Pnknn"
  1564 	  unfolding fps_power_nth_Suc setsum_Un_disjoint[OF f d, unfolded eq] ..
  1565 	also have "\<dots> = a$n" unfolding fn by simp
  1566 	finally have "?r ^ Suc k $ n = a $n" .}
  1567       ultimately  show "?r ^ Suc k $ n = a $n" by (cases n, auto)
  1568   qed }
  1569   then show ?thesis by (simp add: fps_eq_iff)
  1570 qed
  1571 
  1572 *)
  1573 lemma eq_divide_imp': assumes c0: "(c::'a::field) ~= 0" and eq: "a * c = b"
  1574   shows "a = b / c"
  1575 proof-
  1576   from eq have "a * c * inverse c = b * inverse c" by simp
  1577   hence "a * (inverse c * c) = b/c" by (simp only: field_simps divide_inverse)
  1578   then show "a = b/c" unfolding  field_inverse[OF c0] by simp
  1579 qed
  1580 
  1581 lemma radical_unique:
  1582   assumes r0: "(r (Suc k) (b$0)) ^ Suc k = b$0"
  1583   and a0: "r (Suc k) (b$0 ::'a::field_char_0) = a$0" and b0: "b$0 \<noteq> 0"
  1584   shows "a^(Suc k) = b \<longleftrightarrow> a = fps_radical r (Suc k) b"
  1585 proof-
  1586   let ?r = "fps_radical r (Suc k) b"
  1587   have r00: "r (Suc k) (b$0) \<noteq> 0" using b0 r0 by auto
  1588   {assume H: "a = ?r"
  1589     from H have "a^Suc k = b" using power_radical[OF b0, of r k, unfolded r0] by simp}
  1590   moreover
  1591   {assume H: "a^Suc k = b"
  1592     have ceq: "card {0..k} = Suc k" by simp
  1593     have fk: "finite {0..k}" by simp
  1594     from a0 have a0r0: "a$0 = ?r$0" by simp
  1595     {fix n have "a $ n = ?r $ n"
  1596       proof(induct n rule: nat_less_induct)
  1597 	fix n assume h: "\<forall>m<n. a$m = ?r $m"
  1598 	{assume "n = 0" hence "a$n = ?r $n" using a0 by simp }
  1599 	moreover
  1600 	{fix n1 assume n1: "n = Suc n1"
  1601 	  have fK: "finite {0..k}" by simp
  1602 	have nz: "n \<noteq> 0" using n1 by arith
  1603 	let ?Pnk = "natpermute n (Suc k)"
  1604 	let ?Pnkn = "{xs \<in> ?Pnk. n \<in> set xs}"
  1605 	let ?Pnknn = "{xs \<in> ?Pnk. n \<notin> set xs}"
  1606 	have eq: "?Pnkn \<union> ?Pnknn = ?Pnk" by blast
  1607 	have d: "?Pnkn \<inter> ?Pnknn = {}" by blast
  1608 	have f: "finite ?Pnkn" "finite ?Pnknn"
  1609 	  using finite_Un[of ?Pnkn ?Pnknn, unfolded eq]
  1610 	  by (metis natpermute_finite)+
  1611 	let ?f = "\<lambda>v. \<Prod>j\<in>{0..k}. ?r $ v ! j"
  1612 	let ?g = "\<lambda>v. \<Prod>j\<in>{0..k}. a $ v ! j"
  1613 	have "setsum ?g ?Pnkn = setsum (\<lambda>v. a $ n * (?r$0)^k) ?Pnkn"
  1614 	proof(rule setsum_cong2)
  1615 	  fix v assume v: "v \<in> {xs \<in> natpermute n (Suc k). n \<in> set xs}"
  1616 	  let ?ths = "(\<Prod>j\<in>{0..k}. a $ v ! j) = a $ n * (?r$0)^k"
  1617 	  from v obtain i where i: "i \<in> {0..k}" "v = replicate (k+1) 0 [i:= n]"
  1618 	    unfolding Suc_eq_plus1 natpermute_contain_maximal by (auto simp del: replicate.simps)
  1619 	  have "(\<Prod>j\<in>{0..k}. a $ v ! j) = (\<Prod>j\<in>{0..k}. if j = i then a $ n else r (Suc k) (b$0))"
  1620 	    apply (rule setprod_cong, simp)
  1621 	    using i a0 by (simp del: replicate.simps)
  1622 	  also have "\<dots> = a $ n * (?r $ 0)^k"
  1623 	    unfolding  setprod_gen_delta[OF fK] using i by simp
  1624 	  finally show ?ths .
  1625 	qed
  1626 	then have th0: "setsum ?g ?Pnkn = of_nat (k+1) * a $ n * (?r $ 0)^k"
  1627 	  by (simp add: natpermute_max_card[OF nz, simplified])
  1628 	have th1: "setsum ?g ?Pnknn = setsum ?f ?Pnknn"
  1629 	proof (rule setsum_cong2, rule setprod_cong, simp)
  1630 	  fix xs i assume xs: "xs \<in> ?Pnknn" and i: "i \<in> {0..k}"
  1631 	  {assume c: "n \<le> xs ! i"
  1632 	    from xs i have "xs !i \<noteq> n" by (auto simp add: in_set_conv_nth natpermute_def)
  1633 	    with c have c': "n < xs!i" by arith
  1634 	    have fths: "finite {0 ..< i}" "finite {i}" "finite {i+1..<Suc k}" by simp_all
  1635 	    have d: "{0 ..< i} \<inter> ({i} \<union> {i+1 ..< Suc k}) = {}" "{i} \<inter> {i+1..< Suc k} = {}" by auto
  1636 	    have eqs: "{0..<Suc k} = {0 ..< i} \<union> ({i} \<union> {i+1 ..< Suc k})" using i by auto
  1637 	    from xs have "n = foldl op + 0 xs" by (simp add: natpermute_def)
  1638 	    also have "\<dots> = setsum (nth xs) {0..<Suc k}" unfolding foldl_add_setsum using xs
  1639 	      by (simp add: natpermute_def)
  1640 	    also have "\<dots> = xs!i + setsum (nth xs) {0..<i} + setsum (nth xs) {i+1..<Suc k}"
  1641 	      unfolding eqs  setsum_Un_disjoint[OF fths(1) finite_UnI[OF fths(2,3)] d(1)]
  1642 	      unfolding setsum_Un_disjoint[OF fths(2) fths(3) d(2)]
  1643 	      by simp
  1644 	    finally have False using c' by simp}
  1645 	  then have thn: "xs!i < n" by arith
  1646 	  from h[rule_format, OF thn]
  1647 	  show "a$(xs !i) = ?r$(xs!i)" .
  1648 	qed
  1649 	have th00: "\<And>(x::'a). of_nat (Suc k) * (x * inverse (of_nat (Suc k))) = x"
  1650 	  by (simp add: field_simps del: of_nat_Suc)
  1651 	from H have "b$n = a^Suc k $ n" by (simp add: fps_eq_iff)
  1652 	also have "a ^ Suc k$n = setsum ?g ?Pnkn + setsum ?g ?Pnknn"
  1653 	  unfolding fps_power_nth_Suc
  1654 	  using setsum_Un_disjoint[OF f d, unfolded Suc_eq_plus1[symmetric],
  1655 	    unfolded eq, of ?g] by simp
  1656 	also have "\<dots> = of_nat (k+1) * a $ n * (?r $ 0)^k + setsum ?f ?Pnknn" unfolding th0 th1 ..
  1657 	finally have "of_nat (k+1) * a $ n * (?r $ 0)^k = b$n - setsum ?f ?Pnknn" by simp
  1658 	then have "a$n = (b$n - setsum ?f ?Pnknn) / (of_nat (k+1) * (?r $ 0)^k)"
  1659 	  apply -
  1660 	  apply (rule eq_divide_imp')
  1661 	  using r00
  1662 	  apply (simp del: of_nat_Suc)
  1663 	  by (simp add: mult_ac)
  1664 	then have "a$n = ?r $n"
  1665 	  apply (simp del: of_nat_Suc)
  1666 	  unfolding fps_radical_def n1
  1667 	  by (simp add: field_simps n1 th00 del: of_nat_Suc)}
  1668 	ultimately show "a$n = ?r $ n" by (cases n, auto)
  1669       qed}
  1670     then have "a = ?r" by (simp add: fps_eq_iff)}
  1671   ultimately show ?thesis by blast
  1672 qed
  1673 
  1674 
  1675 lemma radical_power:
  1676   assumes r0: "r (Suc k) ((a$0) ^ Suc k) = a$0"
  1677   and a0: "(a$0 ::'a::field_char_0) \<noteq> 0"
  1678   shows "(fps_radical r (Suc k) (a ^ Suc k)) = a"
  1679 proof-
  1680   let ?ak = "a^ Suc k"
  1681   have ak0: "?ak $ 0 = (a$0) ^ Suc k" by (simp add: fps_nth_power_0 del: power_Suc)
  1682   from r0 have th0: "r (Suc k) (a ^ Suc k $ 0) ^ Suc k = a ^ Suc k $ 0" using ak0 by auto
  1683   from r0 ak0 have th1: "r (Suc k) (a ^ Suc k $ 0) = a $ 0" by auto
  1684   from ak0 a0 have ak00: "?ak $ 0 \<noteq>0 " by auto
  1685   from radical_unique[of r k ?ak a, OF th0 th1 ak00] show ?thesis by metis
  1686 qed
  1687 
  1688 lemma fps_deriv_radical:
  1689   fixes a:: "'a::field_char_0 fps"
  1690   assumes r0: "(r (Suc k) (a$0)) ^ Suc k = a$0" and a0: "a$0 \<noteq> 0"
  1691   shows "fps_deriv (fps_radical r (Suc k) a) = fps_deriv a / (fps_const (of_nat (Suc k)) * (fps_radical r (Suc k) a) ^ k)"
  1692 proof-
  1693   let ?r= "fps_radical r (Suc k) a"
  1694   let ?w = "(fps_const (of_nat (Suc k)) * ?r ^ k)"
  1695   from a0 r0 have r0': "r (Suc k) (a$0) \<noteq> 0" by auto
  1696   from r0' have w0: "?w $ 0 \<noteq> 0" by (simp del: of_nat_Suc)
  1697   note th0 = inverse_mult_eq_1[OF w0]
  1698   let ?iw = "inverse ?w"
  1699   from iffD1[OF power_radical[of a r], OF a0 r0]
  1700   have "fps_deriv (?r ^ Suc k) = fps_deriv a" by simp
  1701   hence "fps_deriv ?r * ?w = fps_deriv a"
  1702     by (simp add: fps_deriv_power mult_ac del: power_Suc)
  1703   hence "?iw * fps_deriv ?r * ?w = ?iw * fps_deriv a" by simp
  1704   hence "fps_deriv ?r * (?iw * ?w) = fps_deriv a / ?w"
  1705     by (simp add: fps_divide_def)
  1706   then show ?thesis unfolding th0 by simp
  1707 qed
  1708 
  1709 lemma radical_mult_distrib:
  1710   fixes a:: "'a::field_char_0 fps"
  1711   assumes
  1712   k: "k > 0"
  1713   and ra0: "r k (a $ 0) ^ k = a $ 0"
  1714   and rb0: "r k (b $ 0) ^ k = b $ 0"
  1715   and a0: "a$0 \<noteq> 0"
  1716   and b0: "b$0 \<noteq> 0"
  1717   shows "r k ((a * b) $ 0) = r k (a $ 0) * r k (b $ 0) \<longleftrightarrow> fps_radical r (k) (a*b) = fps_radical r (k) a * fps_radical r (k) (b)"
  1718 proof-
  1719   {assume  r0': "r k ((a * b) $ 0) = r k (a $ 0) * r k (b $ 0)"
  1720   from r0' have r0: "(r (k) ((a*b)$0)) ^ k = (a*b)$0"
  1721     by (simp add: fps_mult_nth ra0 rb0 power_mult_distrib)
  1722   {assume "k=0" hence ?thesis using r0' by simp}
  1723   moreover
  1724   {fix h assume k: "k = Suc h"
  1725   let ?ra = "fps_radical r (Suc h) a"
  1726   let ?rb = "fps_radical r (Suc h) b"
  1727   have th0: "r (Suc h) ((a * b) $ 0) = (fps_radical r (Suc h) a * fps_radical r (Suc h) b) $ 0"
  1728     using r0' k by (simp add: fps_mult_nth)
  1729   have ab0: "(a*b) $ 0 \<noteq> 0" using a0 b0 by (simp add: fps_mult_nth)
  1730   from radical_unique[of r h "a*b" "fps_radical r (Suc h) a * fps_radical r (Suc h) b", OF r0[unfolded k] th0 ab0, symmetric]
  1731     iffD1[OF power_radical[of _ r], OF a0 ra0[unfolded k]] iffD1[OF power_radical[of _ r], OF b0 rb0[unfolded k]] k r0'
  1732   have ?thesis by (auto simp add: power_mult_distrib simp del: power_Suc)}
  1733 ultimately have ?thesis by (cases k, auto)}
  1734 moreover
  1735 {assume h: "fps_radical r k (a*b) = fps_radical r k a * fps_radical r k b"
  1736   hence "(fps_radical r k (a*b))$0 = (fps_radical r k a * fps_radical r k b)$0" by simp
  1737   then have "r k ((a * b) $ 0) = r k (a $ 0) * r k (b $ 0)"
  1738     using k by (simp add: fps_mult_nth)}
  1739 ultimately show ?thesis by blast
  1740 qed
  1741 
  1742 (*
  1743 lemma radical_mult_distrib:
  1744   fixes a:: "'a::field_char_0 fps"
  1745   assumes
  1746   ra0: "r k (a $ 0) ^ k = a $ 0"
  1747   and rb0: "r k (b $ 0) ^ k = b $ 0"
  1748   and r0': "r k ((a * b) $ 0) = r k (a $ 0) * r k (b $ 0)"
  1749   and a0: "a$0 \<noteq> 0"
  1750   and b0: "b$0 \<noteq> 0"
  1751   shows "fps_radical r (k) (a*b) = fps_radical r (k) a * fps_radical r (k) (b)"
  1752 proof-
  1753   from r0' have r0: "(r (k) ((a*b)$0)) ^ k = (a*b)$0"
  1754     by (simp add: fps_mult_nth ra0 rb0 power_mult_distrib)
  1755   {assume "k=0" hence ?thesis by simp}
  1756   moreover
  1757   {fix h assume k: "k = Suc h"
  1758   let ?ra = "fps_radical r (Suc h) a"
  1759   let ?rb = "fps_radical r (Suc h) b"
  1760   have th0: "r (Suc h) ((a * b) $ 0) = (fps_radical r (Suc h) a * fps_radical r (Suc h) b) $ 0"
  1761     using r0' k by (simp add: fps_mult_nth)
  1762   have ab0: "(a*b) $ 0 \<noteq> 0" using a0 b0 by (simp add: fps_mult_nth)
  1763   from radical_unique[of r h "a*b" "fps_radical r (Suc h) a * fps_radical r (Suc h) b", OF r0[unfolded k] th0 ab0, symmetric]
  1764     power_radical[of r, OF ra0[unfolded k] a0] power_radical[of r, OF rb0[unfolded k] b0] k
  1765   have ?thesis by (auto simp add: power_mult_distrib simp del: power_Suc)}
  1766 ultimately show ?thesis by (cases k, auto)
  1767 qed
  1768 *)
  1769 
  1770 lemma fps_divide_1[simp]: "(a:: ('a::field) fps) / 1 = a"
  1771   by (simp add: fps_divide_def)
  1772 
  1773 lemma radical_divide:
  1774   fixes a :: "'a::field_char_0 fps"
  1775   assumes
  1776   kp: "k>0"
  1777   and ra0: "(r k (a $ 0)) ^ k = a $ 0"
  1778   and rb0: "(r k (b $ 0)) ^ k = b $ 0"
  1779   and a0: "a$0 \<noteq> 0"
  1780   and b0: "b$0 \<noteq> 0"
  1781   shows "r k ((a $ 0) / (b$0)) = r k (a$0) / r k (b $ 0) \<longleftrightarrow> fps_radical r k (a/b) = fps_radical r k a / fps_radical r k b" (is "?lhs = ?rhs")
  1782 proof-
  1783   let ?r = "fps_radical r k"
  1784   from kp obtain h where k: "k = Suc h" by (cases k, auto)
  1785   have ra0': "r k (a$0) \<noteq> 0" using a0 ra0 k by auto
  1786   have rb0': "r k (b$0) \<noteq> 0" using b0 rb0 k by auto
  1787 
  1788   {assume ?rhs
  1789     then have "?r (a/b) $ 0 = (?r a / ?r b)$0" by simp
  1790     then have ?lhs using k a0 b0 rb0' 
  1791       by (simp add: fps_divide_def fps_mult_nth fps_inverse_def divide_inverse) }
  1792   moreover
  1793   {assume h: ?lhs
  1794     from a0 b0 have ab0[simp]: "(a/b)$0 = a$0 / b$0" 
  1795       by (simp add: fps_divide_def fps_mult_nth divide_inverse fps_inverse_def)
  1796     have th0: "r k ((a/b)$0) ^ k = (a/b)$0"
  1797       by (simp add: h nonzero_power_divide[OF rb0'] ra0 rb0 del: k)
  1798     from a0 b0 ra0' rb0' kp h 
  1799     have th1: "r k ((a / b) $ 0) = (fps_radical r k a / fps_radical r k b) $ 0"
  1800       by (simp add: fps_divide_def fps_mult_nth fps_inverse_def divide_inverse del: k)
  1801     from a0 b0 ra0' rb0' kp have ab0': "(a / b) $ 0 \<noteq> 0"
  1802       by (simp add: fps_divide_def fps_mult_nth fps_inverse_def nonzero_imp_inverse_nonzero)
  1803     note tha[simp] = iffD1[OF power_radical[where r=r and k=h], OF a0 ra0[unfolded k], unfolded k[symmetric]]
  1804     note thb[simp] = iffD1[OF power_radical[where r=r and k=h], OF b0 rb0[unfolded k], unfolded k[symmetric]]
  1805     have th2: "(?r a / ?r b)^k = a/b"
  1806       by (simp add: fps_divide_def power_mult_distrib fps_inverse_power[symmetric])
  1807     from iffD1[OF radical_unique[where r=r and a="?r a / ?r b" and b="a/b" and k=h], symmetric, unfolded k[symmetric], OF th0 th1 ab0' th2] have ?rhs .}
  1808   ultimately show ?thesis by blast
  1809 qed
  1810 
  1811 lemma radical_inverse:
  1812   fixes a :: "'a::field_char_0 fps"
  1813   assumes
  1814   k: "k>0"
  1815   and ra0: "r k (a $ 0) ^ k = a $ 0"
  1816   and r1: "(r k 1)^k = 1"
  1817   and a0: "a$0 \<noteq> 0"
  1818   shows "r k (inverse (a $ 0)) = r k 1 / (r k (a $ 0)) \<longleftrightarrow> fps_radical r k (inverse a) = fps_radical r k 1 / fps_radical r k a"
  1819   using radical_divide[where k=k and r=r and a=1 and b=a, OF k ] ra0 r1 a0
  1820   by (simp add: divide_inverse fps_divide_def)
  1821 
  1822 subsection{* Derivative of composition *}
  1823 
  1824 lemma fps_compose_deriv:
  1825   fixes a:: "('a::idom) fps"
  1826   assumes b0: "b$0 = 0"
  1827   shows "fps_deriv (a oo b) = ((fps_deriv a) oo b) * (fps_deriv b)"
  1828 proof-
  1829   {fix n
  1830     have "(fps_deriv (a oo b))$n = setsum (\<lambda>i. a $ i * (fps_deriv (b^i))$n) {0.. Suc n}"
  1831       by (simp add: fps_compose_def ring_simps setsum_right_distrib del: of_nat_Suc)
  1832     also have "\<dots> = setsum (\<lambda>i. a$i * ((fps_const (of_nat i)) * (fps_deriv b * (b^(i - 1))))$n) {0.. Suc n}"
  1833       by (simp add: ring_simps fps_deriv_power del: fps_mult_left_const_nth of_nat_Suc)
  1834   also have "\<dots> = setsum (\<lambda>i. of_nat i * a$i * (((b^(i - 1)) * fps_deriv b))$n) {0.. Suc n}"
  1835     unfolding fps_mult_left_const_nth  by (simp add: ring_simps)
  1836   also have "\<dots> = setsum (\<lambda>i. of_nat i * a$i * (setsum (\<lambda>j. (b^ (i - 1))$j * (fps_deriv b)$(n - j)) {0..n})) {0.. Suc n}"
  1837     unfolding fps_mult_nth ..
  1838   also have "\<dots> = setsum (\<lambda>i. of_nat i * a$i * (setsum (\<lambda>j. (b^ (i - 1))$j * (fps_deriv b)$(n - j)) {0..n})) {1.. Suc n}"
  1839     apply (rule setsum_mono_zero_right)
  1840     apply (auto simp add: mult_delta_left setsum_delta not_le)
  1841     done
  1842   also have "\<dots> = setsum (\<lambda>i. of_nat (i + 1) * a$(i+1) * (setsum (\<lambda>j. (b^ i)$j * of_nat (n - j + 1) * b$(n - j + 1)) {0..n})) {0.. n}"
  1843     unfolding fps_deriv_nth
  1844     apply (rule setsum_reindex_cong[where f="Suc"])
  1845     by (auto simp add: mult_assoc)
  1846   finally have th0: "(fps_deriv (a oo b))$n = setsum (\<lambda>i. of_nat (i + 1) * a$(i+1) * (setsum (\<lambda>j. (b^ i)$j * of_nat (n - j + 1) * b$(n - j + 1)) {0..n})) {0.. n}" .
  1847 
  1848   have "(((fps_deriv a) oo b) * (fps_deriv b))$n = setsum (\<lambda>i. (fps_deriv b)$ (n - i) * ((fps_deriv a) oo b)$i) {0..n}"
  1849     unfolding fps_mult_nth by (simp add: mult_ac)
  1850   also have "\<dots> = setsum (\<lambda>i. setsum (\<lambda>j. of_nat (n - i +1) * b$(n - i + 1) * of_nat (j + 1) * a$(j+1) * (b^j)$i) {0..n}) {0..n}"
  1851     unfolding fps_deriv_nth fps_compose_nth setsum_right_distrib mult_assoc
  1852     apply (rule setsum_cong2)
  1853     apply (rule setsum_mono_zero_left)
  1854     apply (simp_all add: subset_eq)
  1855     apply clarify
  1856     apply (subgoal_tac "b^i$x = 0")
  1857     apply simp
  1858     apply (rule startsby_zero_power_prefix[OF b0, rule_format])
  1859     by simp
  1860   also have "\<dots> = setsum (\<lambda>i. of_nat (i + 1) * a$(i+1) * (setsum (\<lambda>j. (b^ i)$j * of_nat (n - j + 1) * b$(n - j + 1)) {0..n})) {0.. n}"
  1861     unfolding setsum_right_distrib
  1862     apply (subst setsum_commute)
  1863     by ((rule setsum_cong2)+) simp
  1864   finally have "(fps_deriv (a oo b))$n = (((fps_deriv a) oo b) * (fps_deriv b)) $n"
  1865     unfolding th0 by simp}
  1866 then show ?thesis by (simp add: fps_eq_iff)
  1867 qed
  1868 
  1869 lemma fps_mult_X_plus_1_nth:
  1870   "((1+X)*a) $n = (if n = 0 then (a$n :: 'a::comm_ring_1) else a$n + a$(n - 1))"
  1871 proof-
  1872   {assume "n = 0" hence ?thesis by (simp add: fps_mult_nth )}
  1873   moreover
  1874   {fix m assume m: "n = Suc m"
  1875     have "((1+X)*a) $n = setsum (\<lambda>i. (1+X)$i * a$(n-i)) {0..n}"
  1876       by (simp add: fps_mult_nth)
  1877     also have "\<dots> = setsum (\<lambda>i. (1+X)$i * a$(n-i)) {0.. 1}"
  1878       unfolding m
  1879       apply (rule setsum_mono_zero_right)
  1880       by (auto simp add: )
  1881     also have "\<dots> = (if n = 0 then (a$n :: 'a::comm_ring_1) else a$n + a$(n - 1))"
  1882       unfolding m
  1883       by (simp add: )
  1884     finally have ?thesis .}
  1885   ultimately show ?thesis by (cases n, auto)
  1886 qed
  1887 
  1888 subsection{* Finite FPS (i.e. polynomials) and X *}
  1889 lemma fps_poly_sum_X:
  1890   assumes z: "\<forall>i > n. a$i = (0::'a::comm_ring_1)"
  1891   shows "a = setsum (\<lambda>i. fps_const (a$i) * X^i) {0..n}" (is "a = ?r")
  1892 proof-
  1893   {fix i
  1894     have "a$i = ?r$i"
  1895       unfolding fps_setsum_nth fps_mult_left_const_nth X_power_nth
  1896       by (simp add: mult_delta_right setsum_delta' z)
  1897   }
  1898   then show ?thesis unfolding fps_eq_iff by blast
  1899 qed
  1900 
  1901 subsection{* Compositional inverses *}
  1902 
  1903 
  1904 fun compinv :: "'a fps \<Rightarrow> nat \<Rightarrow> 'a::{field}" where
  1905   "compinv a 0 = X$0"
  1906 | "compinv a (Suc n) = (X$ Suc n - setsum (\<lambda>i. (compinv a i) * (a^i)$Suc n) {0 .. n}) / (a$1) ^ Suc n"
  1907 
  1908 definition "fps_inv a = Abs_fps (compinv a)"
  1909 
  1910 lemma fps_inv: assumes a0: "a$0 = 0" and a1: "a$1 \<noteq> 0"
  1911   shows "fps_inv a oo a = X"
  1912 proof-
  1913   let ?i = "fps_inv a oo a"
  1914   {fix n
  1915     have "?i $n = X$n"
  1916     proof(induct n rule: nat_less_induct)
  1917       fix n assume h: "\<forall>m<n. ?i$m = X$m"
  1918       {assume "n=0" hence "?i $n = X$n" using a0
  1919 	  by (simp add: fps_compose_nth fps_inv_def)}
  1920       moreover
  1921       {fix n1 assume n1: "n = Suc n1"
  1922 	have "?i $ n = setsum (\<lambda>i. (fps_inv a $ i) * (a^i)$n) {0 .. n1} + fps_inv a $ Suc n1 * (a $ 1)^ Suc n1"
  1923 	  by (simp add: fps_compose_nth n1 startsby_zero_power_nth_same[OF a0]
  1924                    del: power_Suc)
  1925 	also have "\<dots> = setsum (\<lambda>i. (fps_inv a $ i) * (a^i)$n) {0 .. n1} + (X$ Suc n1 - setsum (\<lambda>i. (fps_inv a $ i) * (a^i)$n) {0 .. n1})"
  1926 	  using a0 a1 n1 by (simp add: fps_inv_def)
  1927 	also have "\<dots> = X$n" using n1 by simp
  1928 	finally have "?i $ n = X$n" .}
  1929       ultimately show "?i $ n = X$n" by (cases n, auto)
  1930     qed}
  1931   then show ?thesis by (simp add: fps_eq_iff)
  1932 qed
  1933 
  1934 
  1935 fun gcompinv :: "'a fps \<Rightarrow> 'a fps \<Rightarrow> nat \<Rightarrow> 'a::{field}" where
  1936   "gcompinv b a 0 = b$0"
  1937 | "gcompinv b a (Suc n) = (b$ Suc n - setsum (\<lambda>i. (gcompinv b a i) * (a^i)$Suc n) {0 .. n}) / (a$1) ^ Suc n"
  1938 
  1939 definition "fps_ginv b a = Abs_fps (gcompinv b a)"
  1940 
  1941 lemma fps_ginv: assumes a0: "a$0 = 0" and a1: "a$1 \<noteq> 0"
  1942   shows "fps_ginv b a oo a = b"
  1943 proof-
  1944   let ?i = "fps_ginv b a oo a"
  1945   {fix n
  1946     have "?i $n = b$n"
  1947     proof(induct n rule: nat_less_induct)
  1948       fix n assume h: "\<forall>m<n. ?i$m = b$m"
  1949       {assume "n=0" hence "?i $n = b$n" using a0
  1950 	  by (simp add: fps_compose_nth fps_ginv_def)}
  1951       moreover
  1952       {fix n1 assume n1: "n = Suc n1"
  1953 	have "?i $ n = setsum (\<lambda>i. (fps_ginv b a $ i) * (a^i)$n) {0 .. n1} + fps_ginv b a $ Suc n1 * (a $ 1)^ Suc n1"
  1954 	  by (simp add: fps_compose_nth n1 startsby_zero_power_nth_same[OF a0]
  1955                    del: power_Suc)
  1956 	also have "\<dots> = setsum (\<lambda>i. (fps_ginv b a $ i) * (a^i)$n) {0 .. n1} + (b$ Suc n1 - setsum (\<lambda>i. (fps_ginv b a $ i) * (a^i)$n) {0 .. n1})"
  1957 	  using a0 a1 n1 by (simp add: fps_ginv_def)
  1958 	also have "\<dots> = b$n" using n1 by simp
  1959 	finally have "?i $ n = b$n" .}
  1960       ultimately show "?i $ n = b$n" by (cases n, auto)
  1961     qed}
  1962   then show ?thesis by (simp add: fps_eq_iff)
  1963 qed
  1964 
  1965 lemma fps_inv_ginv: "fps_inv = fps_ginv X"
  1966   apply (auto simp add: expand_fun_eq fps_eq_iff fps_inv_def fps_ginv_def)
  1967   apply (induct_tac n rule: nat_less_induct, auto)
  1968   apply (case_tac na)
  1969   apply simp
  1970   apply simp
  1971   done
  1972 
  1973 lemma fps_compose_1[simp]: "1 oo a = 1"
  1974   by (simp add: fps_eq_iff fps_compose_nth mult_delta_left setsum_delta)
  1975 
  1976 lemma fps_compose_0[simp]: "0 oo a = 0"
  1977   by (simp add: fps_eq_iff fps_compose_nth)
  1978 
  1979 lemma fps_compose_0_right[simp]: "a oo 0 = fps_const (a$0)"
  1980   by (auto simp add: fps_eq_iff fps_compose_nth power_0_left setsum_0')
  1981 
  1982 lemma fps_compose_add_distrib: "(a + b) oo c = (a oo c) + (b oo c)"
  1983   by (simp add: fps_eq_iff fps_compose_nth ring_simps setsum_addf)
  1984 
  1985 lemma fps_compose_setsum_distrib: "(setsum f S) oo a = setsum (\<lambda>i. f i oo a) S"
  1986 proof-
  1987   {assume "\<not> finite S" hence ?thesis by simp}
  1988   moreover
  1989   {assume fS: "finite S"
  1990     have ?thesis
  1991     proof(rule finite_induct[OF fS])
  1992       show "setsum f {} oo a = (\<Sum>i\<in>{}. f i oo a)" by simp
  1993     next
  1994       fix x F assume fF: "finite F" and xF: "x \<notin> F" and h: "setsum f F oo a = setsum (\<lambda>i. f i oo a) F"
  1995       show "setsum f (insert x F) oo a  = setsum (\<lambda>i. f i oo a) (insert x F)"
  1996 	using fF xF h by (simp add: fps_compose_add_distrib)
  1997     qed}
  1998   ultimately show ?thesis by blast
  1999 qed
  2000 
  2001 lemma convolution_eq:
  2002   "setsum (%i. a (i :: nat) * b (n - i)) {0 .. n} = setsum (%(i,j). a i * b j) {(i,j). i <= n \<and> j \<le> n \<and> i + j = n}"
  2003   apply (rule setsum_reindex_cong[where f=fst])
  2004   apply (clarsimp simp add: inj_on_def)
  2005   apply (auto simp add: expand_set_eq image_iff)
  2006   apply (rule_tac x= "x" in exI)
  2007   apply clarsimp
  2008   apply (rule_tac x="n - x" in exI)
  2009   apply arith
  2010   done
  2011 
  2012 lemma product_composition_lemma:
  2013   assumes c0: "c$0 = (0::'a::idom)" and d0: "d$0 = 0"
  2014   shows "((a oo c) * (b oo d))$n = setsum (%(k,m). a$k * b$m * (c^k * d^m) $ n) {(k,m). k + m \<le> n}" (is "?l = ?r")
  2015 proof-
  2016   let ?S = "{(k\<Colon>nat, m\<Colon>nat). k + m \<le> n}"
  2017   have s: "?S \<subseteq> {0..n} <*> {0..n}" by (auto simp add: subset_eq)
  2018   have f: "finite {(k\<Colon>nat, m\<Colon>nat). k + m \<le> n}"
  2019     apply (rule finite_subset[OF s])
  2020     by auto
  2021   have "?r =  setsum (%i. setsum (%(k,m). a$k * (c^k)$i * b$m * (d^m) $ (n - i)) {(k,m). k + m \<le> n}) {0..n}"
  2022     apply (simp add: fps_mult_nth setsum_right_distrib)
  2023     apply (subst setsum_commute)
  2024     apply (rule setsum_cong2)
  2025     by (auto simp add: ring_simps)
  2026   also have "\<dots> = ?l"
  2027     apply (simp add: fps_mult_nth fps_compose_nth setsum_product)
  2028     apply (rule setsum_cong2)
  2029     apply (simp add: setsum_cartesian_product mult_assoc)
  2030     apply (rule setsum_mono_zero_right[OF f])
  2031     apply (simp add: subset_eq) apply presburger
  2032     apply clarsimp
  2033     apply (rule ccontr)
  2034     apply (clarsimp simp add: not_le)
  2035     apply (case_tac "x < aa")
  2036     apply simp
  2037     apply (frule_tac startsby_zero_power_prefix[rule_format, OF c0])
  2038     apply blast
  2039     apply simp
  2040     apply (frule_tac startsby_zero_power_prefix[rule_format, OF d0])
  2041     apply blast
  2042     done
  2043   finally show ?thesis by simp
  2044 qed
  2045 
  2046 lemma product_composition_lemma':
  2047   assumes c0: "c$0 = (0::'a::idom)" and d0: "d$0 = 0"
  2048   shows "((a oo c) * (b oo d))$n = setsum (%k. setsum (%m. a$k * b$m * (c^k * d^m) $ n) {0..n}) {0..n}" (is "?l = ?r")
  2049   unfolding product_composition_lemma[OF c0 d0]
  2050   unfolding setsum_cartesian_product
  2051   apply (rule setsum_mono_zero_left)
  2052   apply simp
  2053   apply (clarsimp simp add: subset_eq)
  2054   apply clarsimp
  2055   apply (rule ccontr)
  2056   apply (subgoal_tac "(c^aa * d^ba) $ n = 0")
  2057   apply simp
  2058   unfolding fps_mult_nth
  2059   apply (rule setsum_0')
  2060   apply (clarsimp simp add: not_le)
  2061   apply (case_tac "aaa < aa")
  2062   apply (rule startsby_zero_power_prefix[OF c0, rule_format])
  2063   apply simp
  2064   apply (subgoal_tac "n - aaa < ba")
  2065   apply (frule_tac k = "ba" in startsby_zero_power_prefix[OF d0, rule_format])
  2066   apply simp
  2067   apply arith
  2068   done
  2069 
  2070 
  2071 lemma setsum_pair_less_iff:
  2072   "setsum (%((k::nat),m). a k * b m * c (k + m)) {(k,m). k + m \<le> n} = setsum (%s. setsum (%i. a i * b (s - i) * c s) {0..s}) {0..n}" (is "?l = ?r")
  2073 proof-
  2074   let ?KM=  "{(k,m). k + m \<le> n}"
  2075   let ?f = "%s. UNION {(0::nat)..s} (%i. {(i,s - i)})"
  2076   have th0: "?KM = UNION {0..n} ?f"
  2077     apply (simp add: expand_set_eq)
  2078     apply arith (* FIXME: VERY slow! *)
  2079     done
  2080   show "?l = ?r "
  2081     unfolding th0
  2082     apply (subst setsum_UN_disjoint)
  2083     apply auto
  2084     apply (subst setsum_UN_disjoint)
  2085     apply auto
  2086     done
  2087 qed
  2088 
  2089 lemma fps_compose_mult_distrib_lemma:
  2090   assumes c0: "c$0 = (0::'a::idom)"
  2091   shows "((a oo c) * (b oo c))$n = setsum (%s. setsum (%i. a$i * b$(s - i) * (c^s) $ n) {0..s}) {0..n}" (is "?l = ?r")
  2092   unfolding product_composition_lemma[OF c0 c0] power_add[symmetric]
  2093   unfolding setsum_pair_less_iff[where a = "%k. a$k" and b="%m. b$m" and c="%s. (c ^ s)$n" and n = n] ..
  2094 
  2095 
  2096 lemma fps_compose_mult_distrib:
  2097   assumes c0: "c$0 = (0::'a::idom)"
  2098   shows "(a * b) oo c = (a oo c) * (b oo c)" (is "?l = ?r")
  2099   apply (simp add: fps_eq_iff fps_compose_mult_distrib_lemma[OF c0])
  2100   by (simp add: fps_compose_nth fps_mult_nth setsum_left_distrib)
  2101 lemma fps_compose_setprod_distrib:
  2102   assumes c0: "c$0 = (0::'a::idom)"
  2103   shows "(setprod a S) oo c = setprod (%k. a k oo c) S" (is "?l = ?r")
  2104   apply (cases "finite S")
  2105   apply simp_all
  2106   apply (induct S rule: finite_induct)
  2107   apply simp
  2108   apply (simp add: fps_compose_mult_distrib[OF c0])
  2109   done
  2110 
  2111 lemma fps_compose_power:   assumes c0: "c$0 = (0::'a::idom)"
  2112   shows "(a oo c)^n = a^n oo c" (is "?l = ?r")
  2113 proof-
  2114   {assume "n=0" then have ?thesis by simp}
  2115   moreover
  2116   {fix m assume m: "n = Suc m"
  2117     have th0: "a^n = setprod (%k. a) {0..m}" "(a oo c) ^ n = setprod (%k. a oo c) {0..m}"
  2118       by (simp_all add: setprod_constant m)
  2119     then have ?thesis
  2120       by (simp add: fps_compose_setprod_distrib[OF c0])}
  2121   ultimately show ?thesis by (cases n, auto)
  2122 qed
  2123 
  2124 lemma fps_compose_uminus: "- (a::'a::ring_1 fps) oo c = - (a oo c)"
  2125   by (simp add: fps_eq_iff fps_compose_nth ring_simps setsum_negf[symmetric])
  2126 
  2127 lemma fps_compose_sub_distrib:
  2128   shows "(a - b) oo (c::'a::ring_1 fps) = (a oo c) - (b oo c)"
  2129   unfolding diff_minus fps_compose_uminus fps_compose_add_distrib ..
  2130 
  2131 lemma X_fps_compose:"X oo a = Abs_fps (\<lambda>n. if n = 0 then (0::'a::comm_ring_1) else a$n)"
  2132   by (simp add: fps_eq_iff fps_compose_nth mult_delta_left setsum_delta power_Suc)
  2133 
  2134 lemma fps_inverse_compose:
  2135   assumes b0: "(b$0 :: 'a::field) = 0" and a0: "a$0 \<noteq> 0"
  2136   shows "inverse a oo b = inverse (a oo b)"
  2137 proof-
  2138   let ?ia = "inverse a"
  2139   let ?ab = "a oo b"
  2140   let ?iab = "inverse ?ab"
  2141 
  2142 from a0 have ia0: "?ia $ 0 \<noteq> 0" by (simp )
  2143 from a0 have ab0: "?ab $ 0 \<noteq> 0" by (simp add: fps_compose_def)
  2144 thm inverse_mult_eq_1[OF ab0]
  2145 have "(?ia oo b) *  (a oo b) = 1"
  2146 unfolding fps_compose_mult_distrib[OF b0, symmetric]
  2147 unfolding inverse_mult_eq_1[OF a0]
  2148 fps_compose_1 ..
  2149 
  2150 then have "(?ia oo b) *  (a oo b) * ?iab  = 1 * ?iab" by simp
  2151 then have "(?ia oo b) *  (?iab * (a oo b))  = ?iab" by simp
  2152 then show ?thesis 
  2153   unfolding inverse_mult_eq_1[OF ab0] by simp
  2154 qed
  2155 
  2156 lemma fps_divide_compose:
  2157   assumes c0: "(c$0 :: 'a::field) = 0" and b0: "b$0 \<noteq> 0"
  2158   shows "(a/b) oo c = (a oo c) / (b oo c)"
  2159     unfolding fps_divide_def fps_compose_mult_distrib[OF c0]
  2160     fps_inverse_compose[OF c0 b0] ..
  2161 
  2162 lemma gp: assumes a0: "a$0 = (0::'a::field)"
  2163   shows "(Abs_fps (\<lambda>n. 1)) oo a = 1/(1 - a)" (is "?one oo a = _")
  2164 proof-
  2165   have o0: "?one $ 0 \<noteq> 0" by simp
  2166   have th0: "(1 - X) $ 0 \<noteq> (0::'a)" by simp  
  2167   from fps_inverse_gp[where ?'a = 'a]
  2168   have "inverse ?one = 1 - X" by (simp add: fps_eq_iff)
  2169   hence "inverse (inverse ?one) = inverse (1 - X)" by simp
  2170   hence th: "?one = 1/(1 - X)" unfolding fps_inverse_idempotent[OF o0] 
  2171     by (simp add: fps_divide_def)
  2172   show ?thesis unfolding th
  2173     unfolding fps_divide_compose[OF a0 th0]
  2174     fps_compose_1 fps_compose_sub_distrib X_fps_compose_startby0[OF a0] ..
  2175 qed
  2176 
  2177 lemma fps_const_power[simp]: "fps_const (c::'a::ring_1) ^ n = fps_const (c^n)"
  2178 by (induct n, auto)
  2179 
  2180 lemma fps_compose_radical:
  2181   assumes b0: "b$0 = (0::'a::field_char_0)"
  2182   and ra0: "r (Suc k) (a$0) ^ Suc k = a$0"
  2183   and a0: "a$0 \<noteq> 0"
  2184   shows "fps_radical r (Suc k)  a oo b = fps_radical r (Suc k) (a oo b)"
  2185 proof-
  2186   let ?r = "fps_radical r (Suc k)"
  2187   let ?ab = "a oo b"
  2188   have ab0: "?ab $ 0 = a$0" by (simp add: fps_compose_def)
  2189   from ab0 a0 ra0 have rab0: "?ab $ 0 \<noteq> 0" "r (Suc k) (?ab $ 0) ^ Suc k = ?ab $ 0" by simp_all
  2190   have th00: "r (Suc k) ((a oo b) $ 0) = (fps_radical r (Suc k) a oo b) $ 0"
  2191     by (simp add: ab0 fps_compose_def)
  2192   have th0: "(?r a oo b) ^ (Suc k) = a  oo b"
  2193     unfolding fps_compose_power[OF b0]
  2194     unfolding iffD1[OF power_radical[of a r k], OF a0 ra0]  .. 
  2195   from iffD1[OF radical_unique[where r=r and k=k and b= ?ab and a = "?r a oo b", OF rab0(2) th00 rab0(1)], OF th0] show ?thesis  . 
  2196 qed
  2197 
  2198 lemma fps_const_mult_apply_left:
  2199   "fps_const c * (a oo b) = (fps_const c * a) oo b"
  2200   by (simp add: fps_eq_iff fps_compose_nth setsum_right_distrib mult_assoc)
  2201 
  2202 lemma fps_const_mult_apply_right:
  2203   "(a oo b) * fps_const (c::'a::comm_semiring_1) = (fps_const c * a) oo b"
  2204   by (auto simp add: fps_const_mult_apply_left mult_commute)
  2205 
  2206 lemma fps_compose_assoc:
  2207   assumes c0: "c$0 = (0::'a::idom)" and b0: "b$0 = 0"
  2208   shows "a oo (b oo c) = a oo b oo c" (is "?l = ?r")
  2209 proof-
  2210   {fix n
  2211     have "?l$n = (setsum (\<lambda>i. (fps_const (a$i) * b^i) oo c) {0..n})$n"
  2212       by (simp add: fps_compose_nth fps_compose_power[OF c0] fps_const_mult_apply_left setsum_right_distrib mult_assoc fps_setsum_nth)
  2213     also have "\<dots> = ((setsum (\<lambda>i. fps_const (a$i) * b^i) {0..n}) oo c)$n"
  2214       by (simp add: fps_compose_setsum_distrib)
  2215     also have "\<dots> = ?r$n"
  2216       apply (simp add: fps_compose_nth fps_setsum_nth setsum_left_distrib mult_assoc)
  2217       apply (rule setsum_cong2)
  2218       apply (rule setsum_mono_zero_right)
  2219       apply (auto simp add: not_le)
  2220       by (erule startsby_zero_power_prefix[OF b0, rule_format])
  2221     finally have "?l$n = ?r$n" .}
  2222   then show ?thesis by (simp add: fps_eq_iff)
  2223 qed
  2224 
  2225 
  2226 lemma fps_X_power_compose:
  2227   assumes a0: "a$0=0" shows "X^k oo a = (a::('a::idom fps))^k" (is "?l = ?r")
  2228 proof-
  2229   {assume "k=0" hence ?thesis by simp}
  2230   moreover
  2231   {fix h assume h: "k = Suc h"
  2232     {fix n
  2233       {assume kn: "k>n" hence "?l $ n = ?r $n" using a0 startsby_zero_power_prefix[OF a0] h
  2234 	  by (simp add: fps_compose_nth del: power_Suc)}
  2235       moreover
  2236       {assume kn: "k \<le> n"
  2237 	hence "?l$n = ?r$n"
  2238           by (simp add: fps_compose_nth mult_delta_left setsum_delta)}
  2239       moreover have "k >n \<or> k\<le> n"  by arith
  2240       ultimately have "?l$n = ?r$n"  by blast}
  2241     then have ?thesis unfolding fps_eq_iff by blast}
  2242   ultimately show ?thesis by (cases k, auto)
  2243 qed
  2244 
  2245 lemma fps_inv_right: assumes a0: "a$0 = 0" and a1: "a$1 \<noteq> 0"
  2246   shows "a oo fps_inv a = X"
  2247 proof-
  2248   let ?ia = "fps_inv a"
  2249   let ?iaa = "a oo fps_inv a"
  2250   have th0: "?ia $ 0 = 0" by (simp add: fps_inv_def)
  2251   have th1: "?iaa $ 0 = 0" using a0 a1
  2252     by (simp add: fps_inv_def fps_compose_nth)
  2253   have th2: "X$0 = 0" by simp
  2254   from fps_inv[OF a0 a1] have "a oo (fps_inv a oo a) = a oo X" by simp
  2255   then have "(a oo fps_inv a) oo a = X oo a"
  2256     by (simp add: fps_compose_assoc[OF a0 th0] X_fps_compose_startby0[OF a0])
  2257   with fps_compose_inj_right[OF a0 a1]
  2258   show ?thesis by simp
  2259 qed
  2260 
  2261 lemma fps_inv_deriv:
  2262   assumes a0:"a$0 = (0::'a::{field})" and a1: "a$1 \<noteq> 0"
  2263   shows "fps_deriv (fps_inv a) = inverse (fps_deriv a oo fps_inv a)"
  2264 proof-
  2265   let ?ia = "fps_inv a"
  2266   let ?d = "fps_deriv a oo ?ia"
  2267   let ?dia = "fps_deriv ?ia"
  2268   have ia0: "?ia$0 = 0" by (simp add: fps_inv_def)
  2269   have th0: "?d$0 \<noteq> 0" using a1 by (simp add: fps_compose_nth fps_deriv_nth)
  2270   from fps_inv_right[OF a0 a1] have "?d * ?dia = 1"
  2271     by (simp add: fps_compose_deriv[OF ia0, of a, symmetric] )
  2272   hence "inverse ?d * ?d * ?dia = inverse ?d * 1" by simp
  2273   with inverse_mult_eq_1[OF th0]
  2274   show "?dia = inverse ?d" by simp
  2275 qed
  2276 
  2277 lemma fps_inv_idempotent: 
  2278   assumes a0: "a$0 = 0" and a1: "a$1 \<noteq> 0"
  2279   shows "fps_inv (fps_inv a) = a"
  2280 proof-
  2281   let ?r = "fps_inv"
  2282   have ra0: "?r a $ 0 = 0" by (simp add: fps_inv_def)
  2283   from a1 have ra1: "?r a $ 1 \<noteq> 0" by (simp add: fps_inv_def field_simps)
  2284   have X0: "X$0 = 0" by simp
  2285   from fps_inv[OF ra0 ra1] have "?r (?r a) oo ?r a = X" .
  2286   then have "?r (?r a) oo ?r a oo a = X oo a" by simp
  2287   then have "?r (?r a) oo (?r a oo a) = a" 
  2288     unfolding X_fps_compose_startby0[OF a0]
  2289     unfolding fps_compose_assoc[OF a0 ra0, symmetric] .
  2290   then show ?thesis unfolding fps_inv[OF a0 a1] by simp
  2291 qed
  2292 
  2293 lemma fps_ginv_ginv:
  2294   assumes a0: "a$0 = 0" and a1: "a$1 \<noteq> 0"
  2295   and c0: "c$0 = 0" and  c1: "c$1 \<noteq> 0"
  2296   shows "fps_ginv b (fps_ginv c a) = b oo a oo fps_inv c"
  2297 proof-
  2298   let ?r = "fps_ginv"
  2299   from c0 have rca0: "?r c a $0 = 0" by (simp add: fps_ginv_def)
  2300   from a1 c1 have rca1: "?r c a $ 1 \<noteq> 0" by (simp add: fps_ginv_def field_simps)
  2301   from fps_ginv[OF rca0 rca1] 
  2302   have "?r b (?r c a) oo ?r c a = b" .
  2303   then have "?r b (?r c a) oo ?r c a oo a = b oo a" by simp
  2304   then have "?r b (?r c a) oo (?r c a oo a) = b oo a"
  2305     apply (subst fps_compose_assoc)
  2306     using a0 c0 by (auto simp add: fps_ginv_def)
  2307   then have "?r b (?r c a) oo c = b oo a"
  2308     unfolding fps_ginv[OF a0 a1] .
  2309   then have "?r b (?r c a) oo c oo fps_inv c= b oo a oo fps_inv c" by simp
  2310   then have "?r b (?r c a) oo (c oo fps_inv c) = b oo a oo fps_inv c"
  2311     apply (subst fps_compose_assoc)
  2312     using a0 c0 by (auto simp add: fps_inv_def)
  2313   then show ?thesis unfolding fps_inv_right[OF c0 c1] by simp
  2314 qed
  2315 
  2316 subsection{* Elementary series *}
  2317 
  2318 subsubsection{* Exponential series *}
  2319 definition "E x = Abs_fps (\<lambda>n. x^n / of_nat (fact n))"
  2320 
  2321 lemma E_deriv[simp]: "fps_deriv (E a) = fps_const (a::'a::field_char_0) * E a" (is "?l = ?r")
  2322 proof-
  2323   {fix n
  2324     have "?l$n = ?r $ n"
  2325   apply (auto simp add: E_def field_simps power_Suc[symmetric]simp del: fact_Suc of_nat_Suc power_Suc)
  2326   by (simp add: of_nat_mult ring_simps)}
  2327 then show ?thesis by (simp add: fps_eq_iff)
  2328 qed
  2329 
  2330 lemma E_unique_ODE:
  2331   "fps_deriv a = fps_const c * a \<longleftrightarrow> a = fps_const (a$0) * E (c :: 'a::field_char_0)"
  2332   (is "?lhs \<longleftrightarrow> ?rhs")
  2333 proof-
  2334   {assume d: ?lhs
  2335   from d have th: "\<And>n. a $ Suc n = c * a$n / of_nat (Suc n)"
  2336     by (simp add: fps_deriv_def fps_eq_iff field_simps del: of_nat_Suc)
  2337   {fix n have "a$n = a$0 * c ^ n/ (of_nat (fact n))"
  2338       apply (induct n)
  2339       apply simp
  2340       unfolding th
  2341       using fact_gt_zero
  2342       apply (simp add: field_simps del: of_nat_Suc fact.simps)
  2343       apply (drule sym)
  2344       by (simp add: ring_simps of_nat_mult power_Suc)}
  2345   note th' = this
  2346   have ?rhs
  2347     by (auto simp add: fps_eq_iff fps_const_mult_left E_def intro : th')}
  2348 moreover
  2349 {assume h: ?rhs
  2350   have ?lhs
  2351     apply (subst h)
  2352     apply simp
  2353     apply (simp only: h[symmetric])
  2354   by simp}
  2355 ultimately show ?thesis by blast
  2356 qed
  2357 
  2358 lemma E_add_mult: "E (a + b) = E (a::'a::field_char_0) * E b" (is "?l = ?r")
  2359 proof-
  2360   have "fps_deriv (?r) = fps_const (a+b) * ?r"
  2361     by (simp add: fps_const_add[symmetric] ring_simps del: fps_const_add)
  2362   then have "?r = ?l" apply (simp only: E_unique_ODE)
  2363     by (simp add: fps_mult_nth E_def)
  2364   then show ?thesis ..
  2365 qed
  2366 
  2367 lemma E_nth[simp]: "E a $ n = a^n / of_nat (fact n)"
  2368   by (simp add: E_def)
  2369 
  2370 lemma E0[simp]: "E (0::'a::{field}) = 1"
  2371   by (simp add: fps_eq_iff power_0_left)
  2372 
  2373 lemma E_neg: "E (- a) = inverse (E (a::'a::field_char_0))"
  2374 proof-
  2375   from E_add_mult[of a "- a"] have th0: "E a * E (- a) = 1"
  2376     by (simp )
  2377   have th1: "E a $ 0 \<noteq> 0" by simp
  2378   from fps_inverse_unique[OF th1 th0] show ?thesis by simp
  2379 qed
  2380 
  2381 lemma E_nth_deriv[simp]: "fps_nth_deriv n (E (a::'a::field_char_0)) = (fps_const a)^n * (E a)"
  2382   by (induct n, auto simp add: power_Suc)
  2383 
  2384 lemma X_compose_E[simp]: "X oo E (a::'a::{field}) = E a - 1"
  2385   by (simp add: fps_eq_iff X_fps_compose)
  2386 
  2387 lemma LE_compose:
  2388   assumes a: "a\<noteq>0"
  2389   shows "fps_inv (E a - 1) oo (E a - 1) = X"
  2390   and "(E a - 1) oo fps_inv (E a - 1) = X"
  2391 proof-
  2392   let ?b = "E a - 1"
  2393   have b0: "?b $ 0 = 0" by simp
  2394   have b1: "?b $ 1 \<noteq> 0" by (simp add: a)
  2395   from fps_inv[OF b0 b1] show "fps_inv (E a - 1) oo (E a - 1) = X" .
  2396   from fps_inv_right[OF b0 b1] show "(E a - 1) oo fps_inv (E a - 1) = X" .
  2397 qed
  2398 
  2399 
  2400 lemma fps_const_inverse:
  2401   "a \<noteq> 0 \<Longrightarrow> inverse (fps_const (a::'a::field)) = fps_const (inverse a)"
  2402   apply (auto simp add: fps_eq_iff fps_inverse_def) by (case_tac "n", auto)
  2403 
  2404 lemma inverse_one_plus_X:
  2405   "inverse (1 + X) = Abs_fps (\<lambda>n. (- 1 ::'a::{field})^n)"
  2406   (is "inverse ?l = ?r")
  2407 proof-
  2408   have th: "?l * ?r = 1"
  2409     by (auto simp add: ring_simps fps_eq_iff minus_one_power_iff)
  2410   have th': "?l $ 0 \<noteq> 0" by (simp add: )
  2411   from fps_inverse_unique[OF th' th] show ?thesis .
  2412 qed
  2413 
  2414 lemma E_power_mult: "(E (c::'a::field_char_0))^n = E (of_nat n * c)"
  2415   by (induct n, auto simp add: ring_simps E_add_mult power_Suc)
  2416 
  2417 lemma assumes r: "r (Suc k) 1 = 1" 
  2418   shows "fps_radical r (Suc k) (E (c::'a::{field_char_0})) = E (c / of_nat (Suc k))"
  2419 proof-
  2420   let ?ck = "(c / of_nat (Suc k))"
  2421   let ?r = "fps_radical r (Suc k)"
  2422   have eq0[simp]: "?ck * of_nat (Suc k) = c" "of_nat (Suc k) * ?ck = c"
  2423     by (simp_all del: of_nat_Suc)
  2424   have th0: "E ?ck ^ (Suc k) = E c" unfolding E_power_mult eq0 ..
  2425   have th: "r (Suc k) (E c $0) ^ Suc k = E c $ 0"
  2426     "r (Suc k) (E c $ 0) = E ?ck $ 0" "E c $ 0 \<noteq> 0" using r by simp_all
  2427   from th0 radical_unique[where r=r and k=k, OF th]
  2428   show ?thesis by auto 
  2429 qed
  2430 
  2431 lemma Ec_E1_eq: 
  2432   "E (1::'a::{field_char_0}) oo (fps_const c * X) = E c"
  2433   apply (auto simp add: fps_eq_iff E_def fps_compose_def power_mult_distrib)
  2434   by (simp add: cond_value_iff cond_application_beta setsum_delta' cong del: if_weak_cong)
  2435 
  2436 subsubsection{* Logarithmic series *}
  2437 
  2438 lemma Abs_fps_if_0: 
  2439   "Abs_fps(%n. if n=0 then (v::'a::ring_1) else f n) = fps_const v + X * Abs_fps (%n. f (Suc n))"
  2440   by (auto simp add: fps_eq_iff)
  2441 
  2442 definition L:: "'a::{field_char_0} \<Rightarrow> 'a fps" where 
  2443   "L c \<equiv> fps_const (1/c) * Abs_fps (\<lambda>n. if n = 0 then 0 else (- 1) ^ (n - 1) / of_nat n)"
  2444 
  2445 lemma fps_deriv_L: "fps_deriv (L c) = fps_const (1/c) * inverse (1 + X)"
  2446   unfolding inverse_one_plus_X
  2447   by (simp add: L_def fps_eq_iff del: of_nat_Suc)
  2448 
  2449 lemma L_nth: "L c $ n = (if n=0 then 0 else 1/c * ((- 1) ^ (n - 1) / of_nat n))"
  2450   by (simp add: L_def field_simps)
  2451 
  2452 lemma L_0[simp]: "L c $ 0 = 0" by (simp add: L_def)
  2453 lemma L_E_inv:
  2454   assumes a: "a\<noteq> (0::'a::{field_char_0})"
  2455   shows "L a = fps_inv (E a - 1)" (is "?l = ?r")
  2456 proof-
  2457   let ?b = "E a - 1"
  2458   have b0: "?b $ 0 = 0" by simp
  2459   have b1: "?b $ 1 \<noteq> 0" by (simp add: a)
  2460   have "fps_deriv (E a - 1) oo fps_inv (E a - 1) = (fps_const a * (E a - 1) + fps_const a) oo fps_inv (E a - 1)"
  2461     by (simp add: ring_simps)
  2462   also have "\<dots> = fps_const a * (X + 1)" apply (simp add: fps_compose_add_distrib fps_const_mult_apply_left[symmetric] fps_inv_right[OF b0 b1])
  2463     by (simp add: ring_simps)
  2464   finally have eq: "fps_deriv (E a - 1) oo fps_inv (E a - 1) = fps_const a * (X + 1)" .
  2465   from fps_inv_deriv[OF b0 b1, unfolded eq]
  2466   have "fps_deriv (fps_inv ?b) = fps_const (inverse a) / (X + 1)"
  2467     using a 
  2468     by (simp add: fps_const_inverse eq fps_divide_def fps_inverse_mult)
  2469   hence "fps_deriv ?l = fps_deriv ?r"
  2470     by (simp add: fps_deriv_L add_commute fps_divide_def divide_inverse)
  2471   then show ?thesis unfolding fps_deriv_eq_iff
  2472     by (simp add: L_nth fps_inv_def)
  2473 qed
  2474 
  2475 lemma L_mult_add: 
  2476   assumes c0: "c\<noteq>0" and d0: "d\<noteq>0"
  2477   shows "L c + L d = fps_const (c+d) * L (c*d)"
  2478   (is "?r = ?l")
  2479 proof-
  2480   from c0 d0 have eq: "1/c + 1/d = (c+d)/(c*d)" by (simp add: field_simps)
  2481   have "fps_deriv ?r = fps_const (1/c + 1/d) * inverse (1 + X)"
  2482     by (simp add: fps_deriv_L fps_const_add[symmetric] algebra_simps del: fps_const_add)
  2483   also have "\<dots> = fps_deriv ?l"
  2484     apply (simp add: fps_deriv_L)
  2485     by (simp add: fps_eq_iff eq)
  2486   finally show ?thesis
  2487     unfolding fps_deriv_eq_iff by simp
  2488 qed
  2489 
  2490 subsubsection{* Formal trigonometric functions  *}
  2491 
  2492 definition "fps_sin (c::'a::field_char_0) =
  2493   Abs_fps (\<lambda>n. if even n then 0 else (- 1) ^((n - 1) div 2) * c^n /(of_nat (fact n)))"
  2494 
  2495 definition "fps_cos (c::'a::field_char_0) =
  2496   Abs_fps (\<lambda>n. if even n then (- 1) ^ (n div 2) * c^n / (of_nat (fact n)) else 0)"
  2497 
  2498 lemma fps_sin_deriv:
  2499   "fps_deriv (fps_sin c) = fps_const c * fps_cos c"
  2500   (is "?lhs = ?rhs")
  2501 proof (rule fps_ext)
  2502   fix n::nat
  2503     {assume en: "even n"
  2504       have "?lhs$n = of_nat (n+1) * (fps_sin c $ (n+1))" by simp
  2505       also have "\<dots> = of_nat (n+1) * ((- 1)^(n div 2) * c^Suc n / of_nat (fact (Suc n)))"
  2506 	using en by (simp add: fps_sin_def)
  2507       also have "\<dots> = (- 1)^(n div 2) * c^Suc n * (of_nat (n+1) / (of_nat (Suc n) * of_nat (fact n)))"
  2508 	unfolding fact_Suc of_nat_mult
  2509 	by (simp add: field_simps del: of_nat_add of_nat_Suc)
  2510       also have "\<dots> = (- 1)^(n div 2) *c^Suc n / of_nat (fact n)"
  2511 	by (simp add: field_simps del: of_nat_add of_nat_Suc)
  2512       finally have "?lhs $n = ?rhs$n" using en
  2513 	by (simp add: fps_cos_def ring_simps power_Suc )}
  2514     then show "?lhs $ n = ?rhs $ n"
  2515       by (cases "even n", simp_all add: fps_deriv_def fps_sin_def fps_cos_def)
  2516 qed
  2517 
  2518 lemma fps_cos_deriv:
  2519   "fps_deriv (fps_cos c) = fps_const (- c)* (fps_sin c)"
  2520   (is "?lhs = ?rhs")
  2521 proof (rule fps_ext)
  2522   have th0: "\<And>n. - ((- 1::'a) ^ n) = (- 1)^Suc n" by (simp add: power_Suc)
  2523   have th1: "\<And>n. odd n \<Longrightarrow> Suc ((n - 1) div 2) = Suc n div 2"
  2524     by (case_tac n, simp_all)
  2525   fix n::nat
  2526     {assume en: "odd n"
  2527       from en have n0: "n \<noteq>0 " by presburger
  2528       have "?lhs$n = of_nat (n+1) * (fps_cos c $ (n+1))" by simp
  2529       also have "\<dots> = of_nat (n+1) * ((- 1)^((n + 1) div 2) * c^Suc n / of_nat (fact (Suc n)))"
  2530 	using en by (simp add: fps_cos_def)
  2531       also have "\<dots> = (- 1)^((n + 1) div 2)*c^Suc n * (of_nat (n+1) / (of_nat (Suc n) * of_nat (fact n)))"
  2532 	unfolding fact_Suc of_nat_mult
  2533 	by (simp add: field_simps del: of_nat_add of_nat_Suc)
  2534       also have "\<dots> = (- 1)^((n + 1) div 2) * c^Suc n / of_nat (fact n)"
  2535 	by (simp add: field_simps del: of_nat_add of_nat_Suc)
  2536       also have "\<dots> = (- ((- 1)^((n - 1) div 2))) * c^Suc n / of_nat (fact n)"
  2537 	unfolding th0 unfolding th1[OF en] by simp
  2538       finally have "?lhs $n = ?rhs$n" using en
  2539 	by (simp add: fps_sin_def ring_simps power_Suc)}
  2540     then show "?lhs $ n = ?rhs $ n"
  2541       by (cases "even n", simp_all add: fps_deriv_def fps_sin_def
  2542 	fps_cos_def)
  2543 qed
  2544 
  2545 lemma fps_sin_cos_sum_of_squares:
  2546   "fps_cos c ^ 2 + fps_sin c ^ 2 = 1" (is "?lhs = 1")
  2547 proof-
  2548   have "fps_deriv ?lhs = 0"
  2549     apply (simp add:  fps_deriv_power fps_sin_deriv fps_cos_deriv power_Suc)
  2550     by (simp add: ring_simps fps_const_neg[symmetric] del: fps_const_neg)
  2551   then have "?lhs = fps_const (?lhs $ 0)"
  2552     unfolding fps_deriv_eq_0_iff .
  2553   also have "\<dots> = 1"
  2554     by (auto simp add: fps_eq_iff numeral_2_eq_2 fps_mult_nth fps_cos_def fps_sin_def)
  2555   finally show ?thesis .
  2556 qed
  2557 
  2558 lemma fact_1 [simp]: "fact 1 = 1"
  2559 unfolding One_nat_def fact_Suc by simp
  2560 
  2561 lemma divide_eq_iff: "a \<noteq> (0::'a::field) \<Longrightarrow> x / a = y \<longleftrightarrow> x = y * a"
  2562 by auto
  2563 
  2564 lemma eq_divide_iff: "a \<noteq> (0::'a::field) \<Longrightarrow> x = y / a \<longleftrightarrow> x * a = y"
  2565 by auto
  2566 
  2567 lemma fps_sin_nth_0 [simp]: "fps_sin c $ 0 = 0"
  2568 unfolding fps_sin_def by simp
  2569 
  2570 lemma fps_sin_nth_1 [simp]: "fps_sin c $ 1 = c"
  2571 unfolding fps_sin_def by simp
  2572 
  2573 lemma fps_sin_nth_add_2:
  2574   "fps_sin c $ (n + 2) = - (c * c * fps_sin c $ n / (of_nat(n+1) * of_nat(n+2)))"
  2575 unfolding fps_sin_def
  2576 apply (cases n, simp)
  2577 apply (simp add: divide_eq_iff eq_divide_iff del: of_nat_Suc fact_Suc)
  2578 apply (simp add: of_nat_mult del: of_nat_Suc mult_Suc)
  2579 done
  2580 
  2581 lemma fps_cos_nth_0 [simp]: "fps_cos c $ 0 = 1"
  2582 unfolding fps_cos_def by simp
  2583 
  2584 lemma fps_cos_nth_1 [simp]: "fps_cos c $ 1 = 0"
  2585 unfolding fps_cos_def by simp
  2586 
  2587 lemma fps_cos_nth_add_2:
  2588   "fps_cos c $ (n + 2) = - (c * c * fps_cos c $ n / (of_nat(n+1) * of_nat(n+2)))"
  2589 unfolding fps_cos_def
  2590 apply (simp add: divide_eq_iff eq_divide_iff del: of_nat_Suc fact_Suc)
  2591 apply (simp add: of_nat_mult del: of_nat_Suc mult_Suc)
  2592 done
  2593 
  2594 lemma nat_induct2:
  2595   "\<lbrakk>P 0; P 1; \<And>n. P n \<Longrightarrow> P (n + 2)\<rbrakk> \<Longrightarrow> P (n::nat)"
  2596 unfolding One_nat_def numeral_2_eq_2
  2597 apply (induct n rule: nat_less_induct)
  2598 apply (case_tac n, simp)
  2599 apply (rename_tac m, case_tac m, simp)
  2600 apply (rename_tac k, case_tac k, simp_all)
  2601 done
  2602 
  2603 lemma nat_add_1_add_1: "(n::nat) + 1 + 1 = n + 2"
  2604 by simp
  2605 
  2606 lemma eq_fps_sin:
  2607   assumes 0: "a $ 0 = 0" and 1: "a $ 1 = c"
  2608   and 2: "fps_deriv (fps_deriv a) = - (fps_const c * fps_const c * a)"
  2609   shows "a = fps_sin c"
  2610 apply (rule fps_ext)
  2611 apply (induct_tac n rule: nat_induct2)
  2612 apply (simp add: fps_sin_nth_0 0)
  2613 apply (simp add: fps_sin_nth_1 1 del: One_nat_def)
  2614 apply (rename_tac m, cut_tac f="\<lambda>a. a $ m" in arg_cong [OF 2])
  2615 apply (simp add: nat_add_1_add_1 fps_sin_nth_add_2
  2616             del: One_nat_def of_nat_Suc of_nat_add add_2_eq_Suc')
  2617 apply (subst minus_divide_left)
  2618 apply (subst eq_divide_iff)
  2619 apply (simp del: of_nat_add of_nat_Suc)
  2620 apply (simp only: mult_ac)
  2621 done
  2622 
  2623 lemma eq_fps_cos:
  2624   assumes 0: "a $ 0 = 1" and 1: "a $ 1 = 0"
  2625   and 2: "fps_deriv (fps_deriv a) = - (fps_const c * fps_const c * a)"
  2626   shows "a = fps_cos c"
  2627 apply (rule fps_ext)
  2628 apply (induct_tac n rule: nat_induct2)
  2629 apply (simp add: fps_cos_nth_0 0)
  2630 apply (simp add: fps_cos_nth_1 1 del: One_nat_def)
  2631 apply (rename_tac m, cut_tac f="\<lambda>a. a $ m" in arg_cong [OF 2])
  2632 apply (simp add: nat_add_1_add_1 fps_cos_nth_add_2
  2633             del: One_nat_def of_nat_Suc of_nat_add add_2_eq_Suc')
  2634 apply (subst minus_divide_left)
  2635 apply (subst eq_divide_iff)
  2636 apply (simp del: of_nat_add of_nat_Suc)
  2637 apply (simp only: mult_ac)
  2638 done
  2639 
  2640 lemma mult_nth_0 [simp]: "(a * b) $ 0 = a $ 0 * b $ 0"
  2641 by (simp add: fps_mult_nth)
  2642 
  2643 lemma mult_nth_1 [simp]: "(a * b) $ 1 = a $ 0 * b $ 1 + a $ 1 * b $ 0"
  2644 by (simp add: fps_mult_nth)
  2645 
  2646 lemma fps_sin_add:
  2647   "fps_sin (a + b) = fps_sin a * fps_cos b + fps_cos a * fps_sin b"
  2648 apply (rule eq_fps_sin [symmetric], simp, simp del: One_nat_def)
  2649 apply (simp del: fps_const_neg fps_const_add fps_const_mult
  2650             add: fps_const_add [symmetric] fps_const_neg [symmetric]
  2651                  fps_sin_deriv fps_cos_deriv algebra_simps)
  2652 done
  2653 
  2654 lemma fps_cos_add:
  2655   "fps_cos (a + b) = fps_cos a * fps_cos b - fps_sin a * fps_sin b"
  2656 apply (rule eq_fps_cos [symmetric], simp, simp del: One_nat_def)
  2657 apply (simp del: fps_const_neg fps_const_add fps_const_mult
  2658             add: fps_const_add [symmetric] fps_const_neg [symmetric]
  2659                  fps_sin_deriv fps_cos_deriv algebra_simps)
  2660 done
  2661 
  2662 definition "fps_tan c = fps_sin c / fps_cos c"
  2663 
  2664 lemma fps_tan_deriv: "fps_deriv(fps_tan c) = fps_const c/ (fps_cos c ^ 2)"
  2665 proof-
  2666   have th0: "fps_cos c $ 0 \<noteq> 0" by (simp add: fps_cos_def)
  2667   show ?thesis
  2668     using fps_sin_cos_sum_of_squares[of c]
  2669     apply (simp add: fps_tan_def fps_divide_deriv[OF th0] fps_sin_deriv fps_cos_deriv add: fps_const_neg[symmetric] ring_simps power2_eq_square del: fps_const_neg)
  2670     unfolding right_distrib[symmetric]
  2671     by simp
  2672 qed
  2673 
  2674 end