src/HOL/Transcendental.thy
author nipkow
Wed Jun 24 09:41:14 2009 +0200 (2009-06-24)
changeset 31790 05c92381363c
parent 31338 d41a8ba25b67
child 31880 6fb86c61747c
permissions -rw-r--r--
corrected and unified thm names
     1 (*  Title       : Transcendental.thy
     2     Author      : Jacques D. Fleuriot
     3     Copyright   : 1998,1999 University of Cambridge
     4                   1999,2001 University of Edinburgh
     5     Conversion to Isar and new proofs by Lawrence C Paulson, 2004
     6 *)
     7 
     8 header{*Power Series, Transcendental Functions etc.*}
     9 
    10 theory Transcendental
    11 imports Fact Series Deriv NthRoot
    12 begin
    13 
    14 subsection {* Properties of Power Series *}
    15 
    16 lemma lemma_realpow_diff:
    17   fixes y :: "'a::monoid_mult"
    18   shows "p \<le> n \<Longrightarrow> y ^ (Suc n - p) = (y ^ (n - p)) * y"
    19 proof -
    20   assume "p \<le> n"
    21   hence "Suc n - p = Suc (n - p)" by (rule Suc_diff_le)
    22   thus ?thesis by (simp add: power_commutes)
    23 qed
    24 
    25 lemma lemma_realpow_diff_sumr:
    26   fixes y :: "'a::{comm_semiring_0,monoid_mult}" shows
    27      "(\<Sum>p=0..<Suc n. (x ^ p) * y ^ (Suc n - p)) =  
    28       y * (\<Sum>p=0..<Suc n. (x ^ p) * y ^ (n - p))"
    29 by (simp add: setsum_right_distrib lemma_realpow_diff mult_ac
    30          del: setsum_op_ivl_Suc cong: strong_setsum_cong)
    31 
    32 lemma lemma_realpow_diff_sumr2:
    33   fixes y :: "'a::{comm_ring,monoid_mult}" shows
    34      "x ^ (Suc n) - y ^ (Suc n) =  
    35       (x - y) * (\<Sum>p=0..<Suc n. (x ^ p) * y ^ (n - p))"
    36 apply (induct n, simp)
    37 apply (simp del: setsum_op_ivl_Suc)
    38 apply (subst setsum_op_ivl_Suc)
    39 apply (subst lemma_realpow_diff_sumr)
    40 apply (simp add: right_distrib del: setsum_op_ivl_Suc)
    41 apply (subst mult_left_commute [where a="x - y"])
    42 apply (erule subst)
    43 apply (simp add: algebra_simps)
    44 done
    45 
    46 lemma lemma_realpow_rev_sumr:
    47      "(\<Sum>p=0..<Suc n. (x ^ p) * (y ^ (n - p))) =  
    48       (\<Sum>p=0..<Suc n. (x ^ (n - p)) * (y ^ p))"
    49 apply (rule setsum_reindex_cong [where f="\<lambda>i. n - i"])
    50 apply (rule inj_onI, simp)
    51 apply auto
    52 apply (rule_tac x="n - x" in image_eqI, simp, simp)
    53 done
    54 
    55 text{*Power series has a `circle` of convergence, i.e. if it sums for @{term
    56 x}, then it sums absolutely for @{term z} with @{term "\<bar>z\<bar> < \<bar>x\<bar>"}.*}
    57 
    58 lemma powser_insidea:
    59   fixes x z :: "'a::{real_normed_field,banach}"
    60   assumes 1: "summable (\<lambda>n. f n * x ^ n)"
    61   assumes 2: "norm z < norm x"
    62   shows "summable (\<lambda>n. norm (f n * z ^ n))"
    63 proof -
    64   from 2 have x_neq_0: "x \<noteq> 0" by clarsimp
    65   from 1 have "(\<lambda>n. f n * x ^ n) ----> 0"
    66     by (rule summable_LIMSEQ_zero)
    67   hence "convergent (\<lambda>n. f n * x ^ n)"
    68     by (rule convergentI)
    69   hence "Cauchy (\<lambda>n. f n * x ^ n)"
    70     by (simp add: Cauchy_convergent_iff)
    71   hence "Bseq (\<lambda>n. f n * x ^ n)"
    72     by (rule Cauchy_Bseq)
    73   then obtain K where 3: "0 < K" and 4: "\<forall>n. norm (f n * x ^ n) \<le> K"
    74     by (simp add: Bseq_def, safe)
    75   have "\<exists>N. \<forall>n\<ge>N. norm (norm (f n * z ^ n)) \<le>
    76                    K * norm (z ^ n) * inverse (norm (x ^ n))"
    77   proof (intro exI allI impI)
    78     fix n::nat assume "0 \<le> n"
    79     have "norm (norm (f n * z ^ n)) * norm (x ^ n) =
    80           norm (f n * x ^ n) * norm (z ^ n)"
    81       by (simp add: norm_mult abs_mult)
    82     also have "\<dots> \<le> K * norm (z ^ n)"
    83       by (simp only: mult_right_mono 4 norm_ge_zero)
    84     also have "\<dots> = K * norm (z ^ n) * (inverse (norm (x ^ n)) * norm (x ^ n))"
    85       by (simp add: x_neq_0)
    86     also have "\<dots> = K * norm (z ^ n) * inverse (norm (x ^ n)) * norm (x ^ n)"
    87       by (simp only: mult_assoc)
    88     finally show "norm (norm (f n * z ^ n)) \<le>
    89                   K * norm (z ^ n) * inverse (norm (x ^ n))"
    90       by (simp add: mult_le_cancel_right x_neq_0)
    91   qed
    92   moreover have "summable (\<lambda>n. K * norm (z ^ n) * inverse (norm (x ^ n)))"
    93   proof -
    94     from 2 have "norm (norm (z * inverse x)) < 1"
    95       using x_neq_0
    96       by (simp add: nonzero_norm_divide divide_inverse [symmetric])
    97     hence "summable (\<lambda>n. norm (z * inverse x) ^ n)"
    98       by (rule summable_geometric)
    99     hence "summable (\<lambda>n. K * norm (z * inverse x) ^ n)"
   100       by (rule summable_mult)
   101     thus "summable (\<lambda>n. K * norm (z ^ n) * inverse (norm (x ^ n)))"
   102       using x_neq_0
   103       by (simp add: norm_mult nonzero_norm_inverse power_mult_distrib
   104                     power_inverse norm_power mult_assoc)
   105   qed
   106   ultimately show "summable (\<lambda>n. norm (f n * z ^ n))"
   107     by (rule summable_comparison_test)
   108 qed
   109 
   110 lemma powser_inside:
   111   fixes f :: "nat \<Rightarrow> 'a::{real_normed_field,banach}" shows
   112      "[| summable (%n. f(n) * (x ^ n)); norm z < norm x |]  
   113       ==> summable (%n. f(n) * (z ^ n))"
   114 by (rule powser_insidea [THEN summable_norm_cancel])
   115 
   116 lemma sum_split_even_odd: fixes f :: "nat \<Rightarrow> real" shows
   117   "(\<Sum> i = 0 ..< 2 * n. if even i then f i else g i) = 
   118    (\<Sum> i = 0 ..< n. f (2 * i)) + (\<Sum> i = 0 ..< n. g (2 * i + 1))"
   119 proof (induct n)
   120   case (Suc n)
   121   have "(\<Sum> i = 0 ..< 2 * Suc n. if even i then f i else g i) = 
   122         (\<Sum> i = 0 ..< n. f (2 * i)) + (\<Sum> i = 0 ..< n. g (2 * i + 1)) + (f (2 * n) + g (2 * n + 1))"
   123     using Suc.hyps unfolding One_nat_def by auto
   124   also have "\<dots> = (\<Sum> i = 0 ..< Suc n. f (2 * i)) + (\<Sum> i = 0 ..< Suc n. g (2 * i + 1))" by auto
   125   finally show ?case .
   126 qed auto
   127 
   128 lemma sums_if': fixes g :: "nat \<Rightarrow> real" assumes "g sums x"
   129   shows "(\<lambda> n. if even n then 0 else g ((n - 1) div 2)) sums x"
   130   unfolding sums_def
   131 proof (rule LIMSEQ_I)
   132   fix r :: real assume "0 < r"
   133   from `g sums x`[unfolded sums_def, THEN LIMSEQ_D, OF this]
   134   obtain no where no_eq: "\<And> n. n \<ge> no \<Longrightarrow> (norm (setsum g { 0..<n } - x) < r)" by blast
   135 
   136   let ?SUM = "\<lambda> m. \<Sum> i = 0 ..< m. if even i then 0 else g ((i - 1) div 2)"
   137   { fix m assume "m \<ge> 2 * no" hence "m div 2 \<ge> no" by auto
   138     have sum_eq: "?SUM (2 * (m div 2)) = setsum g { 0 ..< m div 2 }" 
   139       using sum_split_even_odd by auto
   140     hence "(norm (?SUM (2 * (m div 2)) - x) < r)" using no_eq unfolding sum_eq using `m div 2 \<ge> no` by auto
   141     moreover
   142     have "?SUM (2 * (m div 2)) = ?SUM m"
   143     proof (cases "even m")
   144       case True show ?thesis unfolding even_nat_div_two_times_two[OF True, unfolded numeral_2_eq_2[symmetric]] ..
   145     next
   146       case False hence "even (Suc m)" by auto
   147       from even_nat_div_two_times_two[OF this, unfolded numeral_2_eq_2[symmetric]] odd_nat_plus_one_div_two[OF False, unfolded numeral_2_eq_2[symmetric]]
   148       have eq: "Suc (2 * (m div 2)) = m" by auto
   149       hence "even (2 * (m div 2))" using `odd m` by auto
   150       have "?SUM m = ?SUM (Suc (2 * (m div 2)))" unfolding eq ..
   151       also have "\<dots> = ?SUM (2 * (m div 2))" using `even (2 * (m div 2))` by auto
   152       finally show ?thesis by auto
   153     qed
   154     ultimately have "(norm (?SUM m - x) < r)" by auto
   155   }
   156   thus "\<exists> no. \<forall> m \<ge> no. norm (?SUM m - x) < r" by blast
   157 qed
   158 
   159 lemma sums_if: fixes g :: "nat \<Rightarrow> real" assumes "g sums x" and "f sums y"
   160   shows "(\<lambda> n. if even n then f (n div 2) else g ((n - 1) div 2)) sums (x + y)"
   161 proof -
   162   let ?s = "\<lambda> n. if even n then 0 else f ((n - 1) div 2)"
   163   { fix B T E have "(if B then (0 :: real) else E) + (if B then T else 0) = (if B then T else E)"
   164       by (cases B) auto } note if_sum = this
   165   have g_sums: "(\<lambda> n. if even n then 0 else g ((n - 1) div 2)) sums x" using sums_if'[OF `g sums x`] .
   166   { 
   167     have "?s 0 = 0" by auto
   168     have Suc_m1: "\<And> n. Suc n - 1 = n" by auto
   169     { fix B T E have "(if \<not> B then T else E) = (if B then E else T)" by auto } note if_eq = this
   170 
   171     have "?s sums y" using sums_if'[OF `f sums y`] .
   172     from this[unfolded sums_def, THEN LIMSEQ_Suc] 
   173     have "(\<lambda> n. if even n then f (n div 2) else 0) sums y"
   174       unfolding sums_def setsum_shift_lb_Suc0_0_upt[where f="?s", OF `?s 0 = 0`, symmetric]
   175                 image_Suc_atLeastLessThan[symmetric] setsum_reindex[OF inj_Suc, unfolded comp_def]
   176                 even_Suc Suc_m1 if_eq .
   177   } from sums_add[OF g_sums this]
   178   show ?thesis unfolding if_sum .
   179 qed
   180 
   181 subsection {* Alternating series test / Leibniz formula *}
   182 
   183 lemma sums_alternating_upper_lower:
   184   fixes a :: "nat \<Rightarrow> real"
   185   assumes mono: "\<And>n. a (Suc n) \<le> a n" and a_pos: "\<And>n. 0 \<le> a n" and "a ----> 0"
   186   shows "\<exists>l. ((\<forall>n. (\<Sum>i=0..<2*n. -1^i*a i) \<le> l) \<and> (\<lambda> n. \<Sum>i=0..<2*n. -1^i*a i) ----> l) \<and> 
   187              ((\<forall>n. l \<le> (\<Sum>i=0..<2*n + 1. -1^i*a i)) \<and> (\<lambda> n. \<Sum>i=0..<2*n + 1. -1^i*a i) ----> l)"
   188   (is "\<exists>l. ((\<forall>n. ?f n \<le> l) \<and> _) \<and> ((\<forall>n. l \<le> ?g n) \<and> _)")
   189 proof -
   190   have fg_diff: "\<And>n. ?f n - ?g n = - a (2 * n)" unfolding One_nat_def by auto
   191 
   192   have "\<forall> n. ?f n \<le> ?f (Suc n)"
   193   proof fix n show "?f n \<le> ?f (Suc n)" using mono[of "2*n"] by auto qed
   194   moreover
   195   have "\<forall> n. ?g (Suc n) \<le> ?g n"
   196   proof fix n show "?g (Suc n) \<le> ?g n" using mono[of "Suc (2*n)"]
   197     unfolding One_nat_def by auto qed
   198   moreover
   199   have "\<forall> n. ?f n \<le> ?g n" 
   200   proof fix n show "?f n \<le> ?g n" using fg_diff a_pos
   201     unfolding One_nat_def by auto qed
   202   moreover
   203   have "(\<lambda> n. ?f n - ?g n) ----> 0" unfolding fg_diff
   204   proof (rule LIMSEQ_I)
   205     fix r :: real assume "0 < r"
   206     with `a ----> 0`[THEN LIMSEQ_D] 
   207     obtain N where "\<And> n. n \<ge> N \<Longrightarrow> norm (a n - 0) < r" by auto
   208     hence "\<forall> n \<ge> N. norm (- a (2 * n) - 0) < r" by auto
   209     thus "\<exists> N. \<forall> n \<ge> N. norm (- a (2 * n) - 0) < r" by auto
   210   qed
   211   ultimately
   212   show ?thesis by (rule lemma_nest_unique)
   213 qed 
   214 
   215 lemma summable_Leibniz': fixes a :: "nat \<Rightarrow> real"
   216   assumes a_zero: "a ----> 0" and a_pos: "\<And> n. 0 \<le> a n"
   217   and a_monotone: "\<And> n. a (Suc n) \<le> a n"
   218   shows summable: "summable (\<lambda> n. (-1)^n * a n)"
   219   and "\<And>n. (\<Sum>i=0..<2*n. (-1)^i*a i) \<le> (\<Sum>i. (-1)^i*a i)"
   220   and "(\<lambda>n. \<Sum>i=0..<2*n. (-1)^i*a i) ----> (\<Sum>i. (-1)^i*a i)"
   221   and "\<And>n. (\<Sum>i. (-1)^i*a i) \<le> (\<Sum>i=0..<2*n+1. (-1)^i*a i)"
   222   and "(\<lambda>n. \<Sum>i=0..<2*n+1. (-1)^i*a i) ----> (\<Sum>i. (-1)^i*a i)"
   223 proof -
   224   let "?S n" = "(-1)^n * a n"
   225   let "?P n" = "\<Sum>i=0..<n. ?S i"
   226   let "?f n" = "?P (2 * n)"
   227   let "?g n" = "?P (2 * n + 1)"
   228   obtain l :: real where below_l: "\<forall> n. ?f n \<le> l" and "?f ----> l" and above_l: "\<forall> n. l \<le> ?g n" and "?g ----> l"
   229     using sums_alternating_upper_lower[OF a_monotone a_pos a_zero] by blast
   230   
   231   let ?Sa = "\<lambda> m. \<Sum> n = 0..<m. ?S n"
   232   have "?Sa ----> l"
   233   proof (rule LIMSEQ_I)
   234     fix r :: real assume "0 < r"
   235 
   236     with `?f ----> l`[THEN LIMSEQ_D] 
   237     obtain f_no where f: "\<And> n. n \<ge> f_no \<Longrightarrow> norm (?f n - l) < r" by auto
   238 
   239     from `0 < r` `?g ----> l`[THEN LIMSEQ_D] 
   240     obtain g_no where g: "\<And> n. n \<ge> g_no \<Longrightarrow> norm (?g n - l) < r" by auto
   241 
   242     { fix n :: nat
   243       assume "n \<ge> (max (2 * f_no) (2 * g_no))" hence "n \<ge> 2 * f_no" and "n \<ge> 2 * g_no" by auto
   244       have "norm (?Sa n - l) < r"
   245       proof (cases "even n")
   246 	case True from even_nat_div_two_times_two[OF this]
   247 	have n_eq: "2 * (n div 2) = n" unfolding numeral_2_eq_2[symmetric] by auto
   248 	with `n \<ge> 2 * f_no` have "n div 2 \<ge> f_no" by auto
   249 	from f[OF this]
   250 	show ?thesis unfolding n_eq atLeastLessThanSuc_atLeastAtMost .
   251       next
   252 	case False hence "even (n - 1)" using even_num_iff odd_pos by auto 
   253 	from even_nat_div_two_times_two[OF this]
   254 	have n_eq: "2 * ((n - 1) div 2) = n - 1" unfolding numeral_2_eq_2[symmetric] by auto
   255 	hence range_eq: "n - 1 + 1 = n" using odd_pos[OF False] by auto
   256 
   257 	from n_eq `n \<ge> 2 * g_no` have "(n - 1) div 2 \<ge> g_no" by auto
   258 	from g[OF this]
   259 	show ?thesis unfolding n_eq atLeastLessThanSuc_atLeastAtMost range_eq .
   260       qed
   261     }
   262     thus "\<exists> no. \<forall> n \<ge> no. norm (?Sa n - l) < r" by blast
   263   qed
   264   hence sums_l: "(\<lambda>i. (-1)^i * a i) sums l" unfolding sums_def atLeastLessThanSuc_atLeastAtMost[symmetric] .
   265   thus "summable ?S" using summable_def by auto
   266 
   267   have "l = suminf ?S" using sums_unique[OF sums_l] .
   268 
   269   { fix n show "suminf ?S \<le> ?g n" unfolding sums_unique[OF sums_l, symmetric] using above_l by auto }
   270   { fix n show "?f n \<le> suminf ?S" unfolding sums_unique[OF sums_l, symmetric] using below_l by auto }
   271   show "?g ----> suminf ?S" using `?g ----> l` `l = suminf ?S` by auto
   272   show "?f ----> suminf ?S" using `?f ----> l` `l = suminf ?S` by auto
   273 qed
   274 
   275 theorem summable_Leibniz: fixes a :: "nat \<Rightarrow> real"
   276   assumes a_zero: "a ----> 0" and "monoseq a"
   277   shows "summable (\<lambda> n. (-1)^n * a n)" (is "?summable")
   278   and "0 < a 0 \<longrightarrow> (\<forall>n. (\<Sum>i. -1^i*a i) \<in> { \<Sum>i=0..<2*n. -1^i * a i .. \<Sum>i=0..<2*n+1. -1^i * a i})" (is "?pos")
   279   and "a 0 < 0 \<longrightarrow> (\<forall>n. (\<Sum>i. -1^i*a i) \<in> { \<Sum>i=0..<2*n+1. -1^i * a i .. \<Sum>i=0..<2*n. -1^i * a i})" (is "?neg")
   280   and "(\<lambda>n. \<Sum>i=0..<2*n. -1^i*a i) ----> (\<Sum>i. -1^i*a i)" (is "?f")
   281   and "(\<lambda>n. \<Sum>i=0..<2*n+1. -1^i*a i) ----> (\<Sum>i. -1^i*a i)" (is "?g")
   282 proof -
   283   have "?summable \<and> ?pos \<and> ?neg \<and> ?f \<and> ?g"
   284   proof (cases "(\<forall> n. 0 \<le> a n) \<and> (\<forall>m. \<forall>n\<ge>m. a n \<le> a m)")
   285     case True
   286     hence ord: "\<And>n m. m \<le> n \<Longrightarrow> a n \<le> a m" and ge0: "\<And> n. 0 \<le> a n" by auto
   287     { fix n have "a (Suc n) \<le> a n" using ord[where n="Suc n" and m=n] by auto }
   288     note leibniz = summable_Leibniz'[OF `a ----> 0` ge0] and mono = this
   289     from leibniz[OF mono]
   290     show ?thesis using `0 \<le> a 0` by auto
   291   next
   292     let ?a = "\<lambda> n. - a n"
   293     case False
   294     with monoseq_le[OF `monoseq a` `a ----> 0`]
   295     have "(\<forall> n. a n \<le> 0) \<and> (\<forall>m. \<forall>n\<ge>m. a m \<le> a n)" by auto
   296     hence ord: "\<And>n m. m \<le> n \<Longrightarrow> ?a n \<le> ?a m" and ge0: "\<And> n. 0 \<le> ?a n" by auto
   297     { fix n have "?a (Suc n) \<le> ?a n" using ord[where n="Suc n" and m=n] by auto }
   298     note monotone = this
   299     note leibniz = summable_Leibniz'[OF _ ge0, of "\<lambda>x. x", OF LIMSEQ_minus[OF `a ----> 0`, unfolded minus_zero] monotone]
   300     have "summable (\<lambda> n. (-1)^n * ?a n)" using leibniz(1) by auto
   301     then obtain l where "(\<lambda> n. (-1)^n * ?a n) sums l" unfolding summable_def by auto
   302     from this[THEN sums_minus]
   303     have "(\<lambda> n. (-1)^n * a n) sums -l" by auto
   304     hence ?summable unfolding summable_def by auto
   305     moreover
   306     have "\<And> a b :: real. \<bar> - a - - b \<bar> = \<bar>a - b\<bar>" unfolding minus_diff_minus by auto
   307     
   308     from suminf_minus[OF leibniz(1), unfolded mult_minus_right minus_minus]
   309     have move_minus: "(\<Sum>n. - (-1 ^ n * a n)) = - (\<Sum>n. -1 ^ n * a n)" by auto
   310 
   311     have ?pos using `0 \<le> ?a 0` by auto
   312     moreover have ?neg using leibniz(2,4) unfolding mult_minus_right setsum_negf move_minus neg_le_iff_le by auto
   313     moreover have ?f and ?g using leibniz(3,5)[unfolded mult_minus_right setsum_negf move_minus, THEN LIMSEQ_minus_cancel] by auto
   314     ultimately show ?thesis by auto
   315   qed
   316   from this[THEN conjunct1] this[THEN conjunct2, THEN conjunct1] this[THEN conjunct2, THEN conjunct2, THEN conjunct1] this[THEN conjunct2, THEN conjunct2, THEN conjunct2, THEN conjunct1]
   317        this[THEN conjunct2, THEN conjunct2, THEN conjunct2, THEN conjunct2]
   318   show ?summable and ?pos and ?neg and ?f and ?g .
   319 qed
   320 
   321 subsection {* Term-by-Term Differentiability of Power Series *}
   322 
   323 definition
   324   diffs :: "(nat => 'a::ring_1) => nat => 'a" where
   325   "diffs c = (%n. of_nat (Suc n) * c(Suc n))"
   326 
   327 text{*Lemma about distributing negation over it*}
   328 lemma diffs_minus: "diffs (%n. - c n) = (%n. - diffs c n)"
   329 by (simp add: diffs_def)
   330 
   331 lemma sums_Suc_imp:
   332   assumes f: "f 0 = 0"
   333   shows "(\<lambda>n. f (Suc n)) sums s \<Longrightarrow> (\<lambda>n. f n) sums s"
   334 unfolding sums_def
   335 apply (rule LIMSEQ_imp_Suc)
   336 apply (subst setsum_shift_lb_Suc0_0_upt [where f=f, OF f, symmetric])
   337 apply (simp only: setsum_shift_bounds_Suc_ivl)
   338 done
   339 
   340 lemma diffs_equiv:
   341      "summable (%n. (diffs c)(n) * (x ^ n)) ==>  
   342       (%n. of_nat n * c(n) * (x ^ (n - Suc 0))) sums  
   343          (\<Sum>n. (diffs c)(n) * (x ^ n))"
   344 unfolding diffs_def
   345 apply (drule summable_sums)
   346 apply (rule sums_Suc_imp, simp_all)
   347 done
   348 
   349 lemma lemma_termdiff1:
   350   fixes z :: "'a :: {monoid_mult,comm_ring}" shows
   351   "(\<Sum>p=0..<m. (((z + h) ^ (m - p)) * (z ^ p)) - (z ^ m)) =  
   352    (\<Sum>p=0..<m. (z ^ p) * (((z + h) ^ (m - p)) - (z ^ (m - p))))"
   353 by(auto simp add: algebra_simps power_add [symmetric] cong: strong_setsum_cong)
   354 
   355 lemma sumr_diff_mult_const2:
   356   "setsum f {0..<n} - of_nat n * (r::'a::ring_1) = (\<Sum>i = 0..<n. f i - r)"
   357 by (simp add: setsum_subtractf)
   358 
   359 lemma lemma_termdiff2:
   360   fixes h :: "'a :: {field}"
   361   assumes h: "h \<noteq> 0" shows
   362   "((z + h) ^ n - z ^ n) / h - of_nat n * z ^ (n - Suc 0) =
   363    h * (\<Sum>p=0..< n - Suc 0. \<Sum>q=0..< n - Suc 0 - p.
   364         (z + h) ^ q * z ^ (n - 2 - q))" (is "?lhs = ?rhs")
   365 apply (subgoal_tac "h * ?lhs = h * ?rhs", simp add: h)
   366 apply (simp add: right_diff_distrib diff_divide_distrib h)
   367 apply (simp add: mult_assoc [symmetric])
   368 apply (cases "n", simp)
   369 apply (simp add: lemma_realpow_diff_sumr2 h
   370                  right_diff_distrib [symmetric] mult_assoc
   371             del: power_Suc setsum_op_ivl_Suc of_nat_Suc)
   372 apply (subst lemma_realpow_rev_sumr)
   373 apply (subst sumr_diff_mult_const2)
   374 apply simp
   375 apply (simp only: lemma_termdiff1 setsum_right_distrib)
   376 apply (rule setsum_cong [OF refl])
   377 apply (simp add: diff_minus [symmetric] less_iff_Suc_add)
   378 apply (clarify)
   379 apply (simp add: setsum_right_distrib lemma_realpow_diff_sumr2 mult_ac
   380             del: setsum_op_ivl_Suc power_Suc)
   381 apply (subst mult_assoc [symmetric], subst power_add [symmetric])
   382 apply (simp add: mult_ac)
   383 done
   384 
   385 lemma real_setsum_nat_ivl_bounded2:
   386   fixes K :: "'a::ordered_semidom"
   387   assumes f: "\<And>p::nat. p < n \<Longrightarrow> f p \<le> K"
   388   assumes K: "0 \<le> K"
   389   shows "setsum f {0..<n-k} \<le> of_nat n * K"
   390 apply (rule order_trans [OF setsum_mono])
   391 apply (rule f, simp)
   392 apply (simp add: mult_right_mono K)
   393 done
   394 
   395 lemma lemma_termdiff3:
   396   fixes h z :: "'a::{real_normed_field}"
   397   assumes 1: "h \<noteq> 0"
   398   assumes 2: "norm z \<le> K"
   399   assumes 3: "norm (z + h) \<le> K"
   400   shows "norm (((z + h) ^ n - z ^ n) / h - of_nat n * z ^ (n - Suc 0))
   401           \<le> of_nat n * of_nat (n - Suc 0) * K ^ (n - 2) * norm h"
   402 proof -
   403   have "norm (((z + h) ^ n - z ^ n) / h - of_nat n * z ^ (n - Suc 0)) =
   404         norm (\<Sum>p = 0..<n - Suc 0. \<Sum>q = 0..<n - Suc 0 - p.
   405           (z + h) ^ q * z ^ (n - 2 - q)) * norm h"
   406     apply (subst lemma_termdiff2 [OF 1])
   407     apply (subst norm_mult)
   408     apply (rule mult_commute)
   409     done
   410   also have "\<dots> \<le> of_nat n * (of_nat (n - Suc 0) * K ^ (n - 2)) * norm h"
   411   proof (rule mult_right_mono [OF _ norm_ge_zero])
   412     from norm_ge_zero 2 have K: "0 \<le> K" by (rule order_trans)
   413     have le_Kn: "\<And>i j n. i + j = n \<Longrightarrow> norm ((z + h) ^ i * z ^ j) \<le> K ^ n"
   414       apply (erule subst)
   415       apply (simp only: norm_mult norm_power power_add)
   416       apply (intro mult_mono power_mono 2 3 norm_ge_zero zero_le_power K)
   417       done
   418     show "norm (\<Sum>p = 0..<n - Suc 0. \<Sum>q = 0..<n - Suc 0 - p.
   419               (z + h) ^ q * z ^ (n - 2 - q))
   420           \<le> of_nat n * (of_nat (n - Suc 0) * K ^ (n - 2))"
   421       apply (intro
   422          order_trans [OF norm_setsum]
   423          real_setsum_nat_ivl_bounded2
   424          mult_nonneg_nonneg
   425          zero_le_imp_of_nat
   426          zero_le_power K)
   427       apply (rule le_Kn, simp)
   428       done
   429   qed
   430   also have "\<dots> = of_nat n * of_nat (n - Suc 0) * K ^ (n - 2) * norm h"
   431     by (simp only: mult_assoc)
   432   finally show ?thesis .
   433 qed
   434 
   435 lemma lemma_termdiff4:
   436   fixes f :: "'a::{real_normed_field} \<Rightarrow>
   437               'b::real_normed_vector"
   438   assumes k: "0 < (k::real)"
   439   assumes le: "\<And>h. \<lbrakk>h \<noteq> 0; norm h < k\<rbrakk> \<Longrightarrow> norm (f h) \<le> K * norm h"
   440   shows "f -- 0 --> 0"
   441 unfolding LIM_eq diff_0_right
   442 proof (safe)
   443   let ?h = "of_real (k / 2)::'a"
   444   have "?h \<noteq> 0" and "norm ?h < k" using k by simp_all
   445   hence "norm (f ?h) \<le> K * norm ?h" by (rule le)
   446   hence "0 \<le> K * norm ?h" by (rule order_trans [OF norm_ge_zero])
   447   hence zero_le_K: "0 \<le> K" using k by (simp add: zero_le_mult_iff)
   448 
   449   fix r::real assume r: "0 < r"
   450   show "\<exists>s. 0 < s \<and> (\<forall>x. x \<noteq> 0 \<and> norm x < s \<longrightarrow> norm (f x) < r)"
   451   proof (cases)
   452     assume "K = 0"
   453     with k r le have "0 < k \<and> (\<forall>x. x \<noteq> 0 \<and> norm x < k \<longrightarrow> norm (f x) < r)"
   454       by simp
   455     thus "\<exists>s. 0 < s \<and> (\<forall>x. x \<noteq> 0 \<and> norm x < s \<longrightarrow> norm (f x) < r)" ..
   456   next
   457     assume K_neq_zero: "K \<noteq> 0"
   458     with zero_le_K have K: "0 < K" by simp
   459     show "\<exists>s. 0 < s \<and> (\<forall>x. x \<noteq> 0 \<and> norm x < s \<longrightarrow> norm (f x) < r)"
   460     proof (rule exI, safe)
   461       from k r K show "0 < min k (r * inverse K / 2)"
   462         by (simp add: mult_pos_pos positive_imp_inverse_positive)
   463     next
   464       fix x::'a
   465       assume x1: "x \<noteq> 0" and x2: "norm x < min k (r * inverse K / 2)"
   466       from x2 have x3: "norm x < k" and x4: "norm x < r * inverse K / 2"
   467         by simp_all
   468       from x1 x3 le have "norm (f x) \<le> K * norm x" by simp
   469       also from x4 K have "K * norm x < K * (r * inverse K / 2)"
   470         by (rule mult_strict_left_mono)
   471       also have "\<dots> = r / 2"
   472         using K_neq_zero by simp
   473       also have "r / 2 < r"
   474         using r by simp
   475       finally show "norm (f x) < r" .
   476     qed
   477   qed
   478 qed
   479 
   480 lemma lemma_termdiff5:
   481   fixes g :: "'a::{real_normed_field} \<Rightarrow>
   482               nat \<Rightarrow> 'b::banach"
   483   assumes k: "0 < (k::real)"
   484   assumes f: "summable f"
   485   assumes le: "\<And>h n. \<lbrakk>h \<noteq> 0; norm h < k\<rbrakk> \<Longrightarrow> norm (g h n) \<le> f n * norm h"
   486   shows "(\<lambda>h. suminf (g h)) -- 0 --> 0"
   487 proof (rule lemma_termdiff4 [OF k])
   488   fix h::'a assume "h \<noteq> 0" and "norm h < k"
   489   hence A: "\<forall>n. norm (g h n) \<le> f n * norm h"
   490     by (simp add: le)
   491   hence "\<exists>N. \<forall>n\<ge>N. norm (norm (g h n)) \<le> f n * norm h"
   492     by simp
   493   moreover from f have B: "summable (\<lambda>n. f n * norm h)"
   494     by (rule summable_mult2)
   495   ultimately have C: "summable (\<lambda>n. norm (g h n))"
   496     by (rule summable_comparison_test)
   497   hence "norm (suminf (g h)) \<le> (\<Sum>n. norm (g h n))"
   498     by (rule summable_norm)
   499   also from A C B have "(\<Sum>n. norm (g h n)) \<le> (\<Sum>n. f n * norm h)"
   500     by (rule summable_le)
   501   also from f have "(\<Sum>n. f n * norm h) = suminf f * norm h"
   502     by (rule suminf_mult2 [symmetric])
   503   finally show "norm (suminf (g h)) \<le> suminf f * norm h" .
   504 qed
   505 
   506 
   507 text{* FIXME: Long proofs*}
   508 
   509 lemma termdiffs_aux:
   510   fixes x :: "'a::{real_normed_field,banach}"
   511   assumes 1: "summable (\<lambda>n. diffs (diffs c) n * K ^ n)"
   512   assumes 2: "norm x < norm K"
   513   shows "(\<lambda>h. \<Sum>n. c n * (((x + h) ^ n - x ^ n) / h
   514              - of_nat n * x ^ (n - Suc 0))) -- 0 --> 0"
   515 proof -
   516   from dense [OF 2]
   517   obtain r where r1: "norm x < r" and r2: "r < norm K" by fast
   518   from norm_ge_zero r1 have r: "0 < r"
   519     by (rule order_le_less_trans)
   520   hence r_neq_0: "r \<noteq> 0" by simp
   521   show ?thesis
   522   proof (rule lemma_termdiff5)
   523     show "0 < r - norm x" using r1 by simp
   524   next
   525     from r r2 have "norm (of_real r::'a) < norm K"
   526       by simp
   527     with 1 have "summable (\<lambda>n. norm (diffs (diffs c) n * (of_real r ^ n)))"
   528       by (rule powser_insidea)
   529     hence "summable (\<lambda>n. diffs (diffs (\<lambda>n. norm (c n))) n * r ^ n)"
   530       using r
   531       by (simp add: diffs_def norm_mult norm_power del: of_nat_Suc)
   532     hence "summable (\<lambda>n. of_nat n * diffs (\<lambda>n. norm (c n)) n * r ^ (n - Suc 0))"
   533       by (rule diffs_equiv [THEN sums_summable])
   534     also have "(\<lambda>n. of_nat n * diffs (\<lambda>n. norm (c n)) n * r ^ (n - Suc 0))
   535       = (\<lambda>n. diffs (%m. of_nat (m - Suc 0) * norm (c m) * inverse r) n * (r ^ n))"
   536       apply (rule ext)
   537       apply (simp add: diffs_def)
   538       apply (case_tac n, simp_all add: r_neq_0)
   539       done
   540     finally have "summable 
   541       (\<lambda>n. of_nat n * (of_nat (n - Suc 0) * norm (c n) * inverse r) * r ^ (n - Suc 0))"
   542       by (rule diffs_equiv [THEN sums_summable])
   543     also have
   544       "(\<lambda>n. of_nat n * (of_nat (n - Suc 0) * norm (c n) * inverse r) *
   545            r ^ (n - Suc 0)) =
   546        (\<lambda>n. norm (c n) * of_nat n * of_nat (n - Suc 0) * r ^ (n - 2))"
   547       apply (rule ext)
   548       apply (case_tac "n", simp)
   549       apply (case_tac "nat", simp)
   550       apply (simp add: r_neq_0)
   551       done
   552     finally show
   553       "summable (\<lambda>n. norm (c n) * of_nat n * of_nat (n - Suc 0) * r ^ (n - 2))" .
   554   next
   555     fix h::'a and n::nat
   556     assume h: "h \<noteq> 0"
   557     assume "norm h < r - norm x"
   558     hence "norm x + norm h < r" by simp
   559     with norm_triangle_ineq have xh: "norm (x + h) < r"
   560       by (rule order_le_less_trans)
   561     show "norm (c n * (((x + h) ^ n - x ^ n) / h - of_nat n * x ^ (n - Suc 0)))
   562           \<le> norm (c n) * of_nat n * of_nat (n - Suc 0) * r ^ (n - 2) * norm h"
   563       apply (simp only: norm_mult mult_assoc)
   564       apply (rule mult_left_mono [OF _ norm_ge_zero])
   565       apply (simp (no_asm) add: mult_assoc [symmetric])
   566       apply (rule lemma_termdiff3)
   567       apply (rule h)
   568       apply (rule r1 [THEN order_less_imp_le])
   569       apply (rule xh [THEN order_less_imp_le])
   570       done
   571   qed
   572 qed
   573 
   574 lemma termdiffs:
   575   fixes K x :: "'a::{real_normed_field,banach}"
   576   assumes 1: "summable (\<lambda>n. c n * K ^ n)"
   577   assumes 2: "summable (\<lambda>n. (diffs c) n * K ^ n)"
   578   assumes 3: "summable (\<lambda>n. (diffs (diffs c)) n * K ^ n)"
   579   assumes 4: "norm x < norm K"
   580   shows "DERIV (\<lambda>x. \<Sum>n. c n * x ^ n) x :> (\<Sum>n. (diffs c) n * x ^ n)"
   581 unfolding deriv_def
   582 proof (rule LIM_zero_cancel)
   583   show "(\<lambda>h. (suminf (\<lambda>n. c n * (x + h) ^ n) - suminf (\<lambda>n. c n * x ^ n)) / h
   584             - suminf (\<lambda>n. diffs c n * x ^ n)) -- 0 --> 0"
   585   proof (rule LIM_equal2)
   586     show "0 < norm K - norm x" using 4 by (simp add: less_diff_eq)
   587   next
   588     fix h :: 'a
   589     assume "h \<noteq> 0"
   590     assume "norm (h - 0) < norm K - norm x"
   591     hence "norm x + norm h < norm K" by simp
   592     hence 5: "norm (x + h) < norm K"
   593       by (rule norm_triangle_ineq [THEN order_le_less_trans])
   594     have A: "summable (\<lambda>n. c n * x ^ n)"
   595       by (rule powser_inside [OF 1 4])
   596     have B: "summable (\<lambda>n. c n * (x + h) ^ n)"
   597       by (rule powser_inside [OF 1 5])
   598     have C: "summable (\<lambda>n. diffs c n * x ^ n)"
   599       by (rule powser_inside [OF 2 4])
   600     show "((\<Sum>n. c n * (x + h) ^ n) - (\<Sum>n. c n * x ^ n)) / h
   601              - (\<Sum>n. diffs c n * x ^ n) = 
   602           (\<Sum>n. c n * (((x + h) ^ n - x ^ n) / h - of_nat n * x ^ (n - Suc 0)))"
   603       apply (subst sums_unique [OF diffs_equiv [OF C]])
   604       apply (subst suminf_diff [OF B A])
   605       apply (subst suminf_divide [symmetric])
   606       apply (rule summable_diff [OF B A])
   607       apply (subst suminf_diff)
   608       apply (rule summable_divide)
   609       apply (rule summable_diff [OF B A])
   610       apply (rule sums_summable [OF diffs_equiv [OF C]])
   611       apply (rule arg_cong [where f="suminf"], rule ext)
   612       apply (simp add: algebra_simps)
   613       done
   614   next
   615     show "(\<lambda>h. \<Sum>n. c n * (((x + h) ^ n - x ^ n) / h -
   616                of_nat n * x ^ (n - Suc 0))) -- 0 --> 0"
   617         by (rule termdiffs_aux [OF 3 4])
   618   qed
   619 qed
   620 
   621 
   622 subsection{* Some properties of factorials *}
   623 
   624 lemma real_of_nat_fact_not_zero [simp]: "real (fact n) \<noteq> 0"
   625 by auto
   626 
   627 lemma real_of_nat_fact_gt_zero [simp]: "0 < real(fact n)"
   628 by auto
   629 
   630 lemma real_of_nat_fact_ge_zero [simp]: "0 \<le> real(fact n)"
   631 by simp
   632 
   633 lemma inv_real_of_nat_fact_gt_zero [simp]: "0 < inverse (real (fact n))"
   634 by (auto simp add: positive_imp_inverse_positive)
   635 
   636 lemma inv_real_of_nat_fact_ge_zero [simp]: "0 \<le> inverse (real (fact n))"
   637 by (auto intro: order_less_imp_le)
   638 
   639 subsection {* Derivability of power series *}
   640 
   641 lemma DERIV_series': fixes f :: "real \<Rightarrow> nat \<Rightarrow> real"
   642   assumes DERIV_f: "\<And> n. DERIV (\<lambda> x. f x n) x0 :> (f' x0 n)"
   643   and allf_summable: "\<And> x. x \<in> {a <..< b} \<Longrightarrow> summable (f x)" and x0_in_I: "x0 \<in> {a <..< b}"
   644   and "summable (f' x0)"
   645   and "summable L" and L_def: "\<And> n x y. \<lbrakk> x \<in> { a <..< b} ; y \<in> { a <..< b} \<rbrakk> \<Longrightarrow> \<bar> f x n - f y n \<bar> \<le> L n * \<bar> x - y \<bar>"
   646   shows "DERIV (\<lambda> x. suminf (f x)) x0 :> (suminf (f' x0))"
   647   unfolding deriv_def
   648 proof (rule LIM_I)
   649   fix r :: real assume "0 < r" hence "0 < r/3" by auto
   650 
   651   obtain N_L where N_L: "\<And> n. N_L \<le> n \<Longrightarrow> \<bar> \<Sum> i. L (i + n) \<bar> < r/3" 
   652     using suminf_exist_split[OF `0 < r/3` `summable L`] by auto
   653 
   654   obtain N_f' where N_f': "\<And> n. N_f' \<le> n \<Longrightarrow> \<bar> \<Sum> i. f' x0 (i + n) \<bar> < r/3" 
   655     using suminf_exist_split[OF `0 < r/3` `summable (f' x0)`] by auto
   656 
   657   let ?N = "Suc (max N_L N_f')"
   658   have "\<bar> \<Sum> i. f' x0 (i + ?N) \<bar> < r/3" (is "?f'_part < r/3") and
   659     L_estimate: "\<bar> \<Sum> i. L (i + ?N) \<bar> < r/3" using N_L[of "?N"] and N_f' [of "?N"] by auto
   660 
   661   let "?diff i x" = "(f (x0 + x) i - f x0 i) / x"
   662 
   663   let ?r = "r / (3 * real ?N)"
   664   have "0 < 3 * real ?N" by auto
   665   from divide_pos_pos[OF `0 < r` this]
   666   have "0 < ?r" .
   667 
   668   let "?s n" = "SOME s. 0 < s \<and> (\<forall> x. x \<noteq> 0 \<and> \<bar> x \<bar> < s \<longrightarrow> \<bar> ?diff n x - f' x0 n \<bar> < ?r)"
   669   def S' \<equiv> "Min (?s ` { 0 ..< ?N })"
   670 
   671   have "0 < S'" unfolding S'_def
   672   proof (rule iffD2[OF Min_gr_iff])
   673     show "\<forall> x \<in> (?s ` { 0 ..< ?N }). 0 < x"
   674     proof (rule ballI)
   675       fix x assume "x \<in> ?s ` {0..<?N}"
   676       then obtain n where "x = ?s n" and "n \<in> {0..<?N}" using image_iff[THEN iffD1] by blast
   677       from DERIV_D[OF DERIV_f[where n=n], THEN LIM_D, OF `0 < ?r`, unfolded real_norm_def] 
   678       obtain s where s_bound: "0 < s \<and> (\<forall>x. x \<noteq> 0 \<and> \<bar>x\<bar> < s \<longrightarrow> \<bar>?diff n x - f' x0 n\<bar> < ?r)" by auto
   679       have "0 < ?s n" by (rule someI2[where a=s], auto simp add: s_bound)
   680       thus "0 < x" unfolding `x = ?s n` .
   681     qed
   682   qed auto
   683 
   684   def S \<equiv> "min (min (x0 - a) (b - x0)) S'"
   685   hence "0 < S" and S_a: "S \<le> x0 - a" and S_b: "S \<le> b - x0" and "S \<le> S'" using x0_in_I and `0 < S'`
   686     by auto
   687 
   688   { fix x assume "x \<noteq> 0" and "\<bar> x \<bar> < S"
   689     hence x_in_I: "x0 + x \<in> { a <..< b }" using S_a S_b by auto
   690     
   691     note diff_smbl = summable_diff[OF allf_summable[OF x_in_I] allf_summable[OF x0_in_I]]
   692     note div_smbl = summable_divide[OF diff_smbl]
   693     note all_smbl = summable_diff[OF div_smbl `summable (f' x0)`]
   694     note ign = summable_ignore_initial_segment[where k="?N"]
   695     note diff_shft_smbl = summable_diff[OF ign[OF allf_summable[OF x_in_I]] ign[OF allf_summable[OF x0_in_I]]]
   696     note div_shft_smbl = summable_divide[OF diff_shft_smbl]
   697     note all_shft_smbl = summable_diff[OF div_smbl ign[OF `summable (f' x0)`]]
   698 
   699     { fix n
   700       have "\<bar> ?diff (n + ?N) x \<bar> \<le> L (n + ?N) * \<bar> (x0 + x) - x0 \<bar> / \<bar> x \<bar>" 
   701 	using divide_right_mono[OF L_def[OF x_in_I x0_in_I] abs_ge_zero] unfolding abs_divide .
   702       hence "\<bar> ( \<bar> ?diff (n + ?N) x \<bar>) \<bar> \<le> L (n + ?N)" using `x \<noteq> 0` by auto
   703     } note L_ge = summable_le2[OF allI[OF this] ign[OF `summable L`]]
   704     from order_trans[OF summable_rabs[OF conjunct1[OF L_ge]] L_ge[THEN conjunct2]]
   705     have "\<bar> \<Sum> i. ?diff (i + ?N) x \<bar> \<le> (\<Sum> i. L (i + ?N))" .
   706     hence "\<bar> \<Sum> i. ?diff (i + ?N) x \<bar> \<le> r / 3" (is "?L_part \<le> r/3") using L_estimate by auto
   707 
   708     have "\<bar>\<Sum>n \<in> { 0 ..< ?N}. ?diff n x - f' x0 n \<bar> \<le> (\<Sum>n \<in> { 0 ..< ?N}. \<bar>?diff n x - f' x0 n \<bar>)" ..
   709     also have "\<dots> < (\<Sum>n \<in> { 0 ..< ?N}. ?r)"
   710     proof (rule setsum_strict_mono)
   711       fix n assume "n \<in> { 0 ..< ?N}"
   712       have "\<bar> x \<bar> < S" using `\<bar> x \<bar> < S` .
   713       also have "S \<le> S'" using `S \<le> S'` .
   714       also have "S' \<le> ?s n" unfolding S'_def 
   715       proof (rule Min_le_iff[THEN iffD2])
   716 	have "?s n \<in> (?s ` {0..<?N}) \<and> ?s n \<le> ?s n" using `n \<in> { 0 ..< ?N}` by auto
   717 	thus "\<exists> a \<in> (?s ` {0..<?N}). a \<le> ?s n" by blast
   718       qed auto
   719       finally have "\<bar> x \<bar> < ?s n" .
   720 
   721       from DERIV_D[OF DERIV_f[where n=n], THEN LIM_D, OF `0 < ?r`, unfolded real_norm_def diff_0_right, unfolded some_eq_ex[symmetric], THEN conjunct2]
   722       have "\<forall>x. x \<noteq> 0 \<and> \<bar>x\<bar> < ?s n \<longrightarrow> \<bar>?diff n x - f' x0 n\<bar> < ?r" .
   723       with `x \<noteq> 0` and `\<bar>x\<bar> < ?s n`
   724       show "\<bar>?diff n x - f' x0 n\<bar> < ?r" by blast
   725     qed auto
   726     also have "\<dots> = of_nat (card {0 ..< ?N}) * ?r" by (rule setsum_constant)
   727     also have "\<dots> = real ?N * ?r" unfolding real_eq_of_nat by auto
   728     also have "\<dots> = r/3" by auto
   729     finally have "\<bar>\<Sum>n \<in> { 0 ..< ?N}. ?diff n x - f' x0 n \<bar> < r / 3" (is "?diff_part < r / 3") .
   730 
   731     from suminf_diff[OF allf_summable[OF x_in_I] allf_summable[OF x0_in_I]]
   732     have "\<bar> (suminf (f (x0 + x)) - (suminf (f x0))) / x - suminf (f' x0) \<bar> = 
   733                     \<bar> \<Sum>n. ?diff n x - f' x0 n \<bar>" unfolding suminf_diff[OF div_smbl `summable (f' x0)`, symmetric] using suminf_divide[OF diff_smbl, symmetric] by auto
   734     also have "\<dots> \<le> ?diff_part + \<bar> (\<Sum>n. ?diff (n + ?N) x) - (\<Sum> n. f' x0 (n + ?N)) \<bar>" unfolding suminf_split_initial_segment[OF all_smbl, where k="?N"] unfolding suminf_diff[OF div_shft_smbl ign[OF `summable (f' x0)`]] by (rule abs_triangle_ineq)
   735     also have "\<dots> \<le> ?diff_part + ?L_part + ?f'_part" using abs_triangle_ineq4 by auto
   736     also have "\<dots> < r /3 + r/3 + r/3" 
   737       using `?diff_part < r/3` `?L_part \<le> r/3` and `?f'_part < r/3` by auto
   738     finally have "\<bar> (suminf (f (x0 + x)) - (suminf (f x0))) / x - suminf (f' x0) \<bar> < r"
   739       by auto
   740   } thus "\<exists> s > 0. \<forall> x. x \<noteq> 0 \<and> norm (x - 0) < s \<longrightarrow> 
   741       norm (((\<Sum>n. f (x0 + x) n) - (\<Sum>n. f x0 n)) / x - (\<Sum>n. f' x0 n)) < r" using `0 < S`
   742     unfolding real_norm_def diff_0_right by blast
   743 qed
   744 
   745 lemma DERIV_power_series': fixes f :: "nat \<Rightarrow> real"
   746   assumes converges: "\<And> x. x \<in> {-R <..< R} \<Longrightarrow> summable (\<lambda> n. f n * real (Suc n) * x^n)"
   747   and x0_in_I: "x0 \<in> {-R <..< R}" and "0 < R"
   748   shows "DERIV (\<lambda> x. (\<Sum> n. f n * x^(Suc n))) x0 :> (\<Sum> n. f n * real (Suc n) * x0^n)"
   749   (is "DERIV (\<lambda> x. (suminf (?f x))) x0 :> (suminf (?f' x0))")
   750 proof -
   751   { fix R' assume "0 < R'" and "R' < R" and "-R' < x0" and "x0 < R'"
   752     hence "x0 \<in> {-R' <..< R'}" and "R' \<in> {-R <..< R}" and "x0 \<in> {-R <..< R}" by auto
   753     have "DERIV (\<lambda> x. (suminf (?f x))) x0 :> (suminf (?f' x0))"
   754     proof (rule DERIV_series')
   755       show "summable (\<lambda> n. \<bar>f n * real (Suc n) * R'^n\<bar>)"
   756       proof -
   757 	have "(R' + R) / 2 < R" and "0 < (R' + R) / 2" using `0 < R'` `0 < R` `R' < R` by auto
   758 	hence in_Rball: "(R' + R) / 2 \<in> {-R <..< R}" using `R' < R` by auto
   759 	have "norm R' < norm ((R' + R) / 2)" using `0 < R'` `0 < R` `R' < R` by auto
   760 	from powser_insidea[OF converges[OF in_Rball] this] show ?thesis by auto
   761       qed
   762       { fix n x y assume "x \<in> {-R' <..< R'}" and "y \<in> {-R' <..< R'}"
   763 	show "\<bar>?f x n - ?f y n\<bar> \<le> \<bar>f n * real (Suc n) * R'^n\<bar> * \<bar>x-y\<bar>"
   764 	proof -
   765 	  have "\<bar>f n * x ^ (Suc n) - f n * y ^ (Suc n)\<bar> = (\<bar>f n\<bar> * \<bar>x-y\<bar>) * \<bar>\<Sum>p = 0..<Suc n. x ^ p * y ^ (n - p)\<bar>" 
   766 	    unfolding right_diff_distrib[symmetric] lemma_realpow_diff_sumr2 abs_mult by auto
   767 	  also have "\<dots> \<le> (\<bar>f n\<bar> * \<bar>x-y\<bar>) * (\<bar>real (Suc n)\<bar> * \<bar>R' ^ n\<bar>)" 
   768 	  proof (rule mult_left_mono)
   769 	    have "\<bar>\<Sum>p = 0..<Suc n. x ^ p * y ^ (n - p)\<bar> \<le> (\<Sum>p = 0..<Suc n. \<bar>x ^ p * y ^ (n - p)\<bar>)" by (rule setsum_abs)
   770 	    also have "\<dots> \<le> (\<Sum>p = 0..<Suc n. R' ^ n)"
   771 	    proof (rule setsum_mono)
   772 	      fix p assume "p \<in> {0..<Suc n}" hence "p \<le> n" by auto
   773 	      { fix n fix x :: real assume "x \<in> {-R'<..<R'}"
   774 		hence "\<bar>x\<bar> \<le> R'"  by auto
   775 		hence "\<bar>x^n\<bar> \<le> R'^n" unfolding power_abs by (rule power_mono, auto)
   776 	      } from mult_mono[OF this[OF `x \<in> {-R'<..<R'}`, of p] this[OF `y \<in> {-R'<..<R'}`, of "n-p"]] `0 < R'`
   777 	      have "\<bar>x^p * y^(n-p)\<bar> \<le> R'^p * R'^(n-p)" unfolding abs_mult by auto
   778 	      thus "\<bar>x^p * y^(n-p)\<bar> \<le> R'^n" unfolding power_add[symmetric] using `p \<le> n` by auto
   779 	    qed
   780 	    also have "\<dots> = real (Suc n) * R' ^ n" unfolding setsum_constant card_atLeastLessThan real_of_nat_def by auto
   781 	    finally show "\<bar>\<Sum>p = 0..<Suc n. x ^ p * y ^ (n - p)\<bar> \<le> \<bar>real (Suc n)\<bar> * \<bar>R' ^ n\<bar>" unfolding abs_real_of_nat_cancel abs_of_nonneg[OF zero_le_power[OF less_imp_le[OF `0 < R'`]]] .
   782 	    show "0 \<le> \<bar>f n\<bar> * \<bar>x - y\<bar>" unfolding abs_mult[symmetric] by auto
   783 	  qed
   784 	  also have "\<dots> = \<bar>f n * real (Suc n) * R' ^ n\<bar> * \<bar>x - y\<bar>" unfolding abs_mult real_mult_assoc[symmetric] by algebra
   785 	  finally show ?thesis .
   786 	qed }
   787       { fix n
   788 	from DERIV_pow[of "Suc n" x0, THEN DERIV_cmult[where c="f n"]]
   789 	show "DERIV (\<lambda> x. ?f x n) x0 :> (?f' x0 n)" unfolding real_mult_assoc by auto }
   790       { fix x assume "x \<in> {-R' <..< R'}" hence "R' \<in> {-R <..< R}" and "norm x < norm R'" using assms `R' < R` by auto
   791 	have "summable (\<lambda> n. f n * x^n)"
   792 	proof (rule summable_le2[THEN conjunct1, OF _ powser_insidea[OF converges[OF `R' \<in> {-R <..< R}`] `norm x < norm R'`]], rule allI)
   793 	  fix n
   794 	  have le: "\<bar>f n\<bar> * 1 \<le> \<bar>f n\<bar> * real (Suc n)" by (rule mult_left_mono, auto)
   795 	  show "\<bar>f n * x ^ n\<bar> \<le> norm (f n * real (Suc n) * x ^ n)" unfolding real_norm_def abs_mult
   796 	    by (rule mult_right_mono, auto simp add: le[unfolded mult_1_right])
   797 	qed
   798 	from this[THEN summable_mult2[where c=x], unfolded real_mult_assoc, unfolded real_mult_commute]
   799 	show "summable (?f x)" by auto }
   800       show "summable (?f' x0)" using converges[OF `x0 \<in> {-R <..< R}`] .
   801       show "x0 \<in> {-R' <..< R'}" using `x0 \<in> {-R' <..< R'}` .
   802     qed
   803   } note for_subinterval = this
   804   let ?R = "(R + \<bar>x0\<bar>) / 2"
   805   have "\<bar>x0\<bar> < ?R" using assms by auto
   806   hence "- ?R < x0"
   807   proof (cases "x0 < 0")
   808     case True
   809     hence "- x0 < ?R" using `\<bar>x0\<bar> < ?R` by auto
   810     thus ?thesis unfolding neg_less_iff_less[symmetric, of "- x0"] by auto
   811   next
   812     case False
   813     have "- ?R < 0" using assms by auto
   814     also have "\<dots> \<le> x0" using False by auto 
   815     finally show ?thesis .
   816   qed
   817   hence "0 < ?R" "?R < R" "- ?R < x0" and "x0 < ?R" using assms by auto
   818   from for_subinterval[OF this]
   819   show ?thesis .
   820 qed
   821 
   822 subsection {* Exponential Function *}
   823 
   824 definition
   825   exp :: "'a \<Rightarrow> 'a::{real_normed_field,banach}" where
   826   "exp x = (\<Sum>n. x ^ n /\<^sub>R real (fact n))"
   827 
   828 lemma summable_exp_generic:
   829   fixes x :: "'a::{real_normed_algebra_1,banach}"
   830   defines S_def: "S \<equiv> \<lambda>n. x ^ n /\<^sub>R real (fact n)"
   831   shows "summable S"
   832 proof -
   833   have S_Suc: "\<And>n. S (Suc n) = (x * S n) /\<^sub>R real (Suc n)"
   834     unfolding S_def by (simp del: mult_Suc)
   835   obtain r :: real where r0: "0 < r" and r1: "r < 1"
   836     using dense [OF zero_less_one] by fast
   837   obtain N :: nat where N: "norm x < real N * r"
   838     using reals_Archimedean3 [OF r0] by fast
   839   from r1 show ?thesis
   840   proof (rule ratio_test [rule_format])
   841     fix n :: nat
   842     assume n: "N \<le> n"
   843     have "norm x \<le> real N * r"
   844       using N by (rule order_less_imp_le)
   845     also have "real N * r \<le> real (Suc n) * r"
   846       using r0 n by (simp add: mult_right_mono)
   847     finally have "norm x * norm (S n) \<le> real (Suc n) * r * norm (S n)"
   848       using norm_ge_zero by (rule mult_right_mono)
   849     hence "norm (x * S n) \<le> real (Suc n) * r * norm (S n)"
   850       by (rule order_trans [OF norm_mult_ineq])
   851     hence "norm (x * S n) / real (Suc n) \<le> r * norm (S n)"
   852       by (simp add: pos_divide_le_eq mult_ac)
   853     thus "norm (S (Suc n)) \<le> r * norm (S n)"
   854       by (simp add: S_Suc norm_scaleR inverse_eq_divide)
   855   qed
   856 qed
   857 
   858 lemma summable_norm_exp:
   859   fixes x :: "'a::{real_normed_algebra_1,banach}"
   860   shows "summable (\<lambda>n. norm (x ^ n /\<^sub>R real (fact n)))"
   861 proof (rule summable_norm_comparison_test [OF exI, rule_format])
   862   show "summable (\<lambda>n. norm x ^ n /\<^sub>R real (fact n))"
   863     by (rule summable_exp_generic)
   864 next
   865   fix n show "norm (x ^ n /\<^sub>R real (fact n)) \<le> norm x ^ n /\<^sub>R real (fact n)"
   866     by (simp add: norm_scaleR norm_power_ineq)
   867 qed
   868 
   869 lemma summable_exp: "summable (%n. inverse (real (fact n)) * x ^ n)"
   870 by (insert summable_exp_generic [where x=x], simp)
   871 
   872 lemma exp_converges: "(\<lambda>n. x ^ n /\<^sub>R real (fact n)) sums exp x"
   873 unfolding exp_def by (rule summable_exp_generic [THEN summable_sums])
   874 
   875 
   876 lemma exp_fdiffs: 
   877       "diffs (%n. inverse(real (fact n))) = (%n. inverse(real (fact n)))"
   878 by (simp add: diffs_def mult_assoc [symmetric] real_of_nat_def of_nat_mult
   879          del: mult_Suc of_nat_Suc)
   880 
   881 lemma diffs_of_real: "diffs (\<lambda>n. of_real (f n)) = (\<lambda>n. of_real (diffs f n))"
   882 by (simp add: diffs_def)
   883 
   884 lemma lemma_exp_ext: "exp = (\<lambda>x. \<Sum>n. x ^ n /\<^sub>R real (fact n))"
   885 by (auto intro!: ext simp add: exp_def)
   886 
   887 lemma DERIV_exp [simp]: "DERIV exp x :> exp(x)"
   888 apply (simp add: exp_def)
   889 apply (subst lemma_exp_ext)
   890 apply (subgoal_tac "DERIV (\<lambda>u. \<Sum>n. of_real (inverse (real (fact n))) * u ^ n) x :> (\<Sum>n. diffs (\<lambda>n. of_real (inverse (real (fact n)))) n * x ^ n)")
   891 apply (rule_tac [2] K = "of_real (1 + norm x)" in termdiffs)
   892 apply (simp_all only: diffs_of_real scaleR_conv_of_real exp_fdiffs)
   893 apply (rule exp_converges [THEN sums_summable, unfolded scaleR_conv_of_real])+
   894 apply (simp del: of_real_add)
   895 done
   896 
   897 lemma isCont_exp [simp]: "isCont exp x"
   898 by (rule DERIV_exp [THEN DERIV_isCont])
   899 
   900 
   901 subsubsection {* Properties of the Exponential Function *}
   902 
   903 lemma powser_zero:
   904   fixes f :: "nat \<Rightarrow> 'a::{real_normed_algebra_1}"
   905   shows "(\<Sum>n. f n * 0 ^ n) = f 0"
   906 proof -
   907   have "(\<Sum>n = 0..<1. f n * 0 ^ n) = (\<Sum>n. f n * 0 ^ n)"
   908     by (rule sums_unique [OF series_zero], simp add: power_0_left)
   909   thus ?thesis unfolding One_nat_def by simp
   910 qed
   911 
   912 lemma exp_zero [simp]: "exp 0 = 1"
   913 unfolding exp_def by (simp add: scaleR_conv_of_real powser_zero)
   914 
   915 lemma setsum_cl_ivl_Suc2:
   916   "(\<Sum>i=m..Suc n. f i) = (if Suc n < m then 0 else f m + (\<Sum>i=m..n. f (Suc i)))"
   917 by (simp add: setsum_head_Suc setsum_shift_bounds_cl_Suc_ivl
   918          del: setsum_cl_ivl_Suc)
   919 
   920 lemma exp_series_add:
   921   fixes x y :: "'a::{real_field}"
   922   defines S_def: "S \<equiv> \<lambda>x n. x ^ n /\<^sub>R real (fact n)"
   923   shows "S (x + y) n = (\<Sum>i=0..n. S x i * S y (n - i))"
   924 proof (induct n)
   925   case 0
   926   show ?case
   927     unfolding S_def by simp
   928 next
   929   case (Suc n)
   930   have S_Suc: "\<And>x n. S x (Suc n) = (x * S x n) /\<^sub>R real (Suc n)"
   931     unfolding S_def by (simp del: mult_Suc)
   932   hence times_S: "\<And>x n. x * S x n = real (Suc n) *\<^sub>R S x (Suc n)"
   933     by simp
   934 
   935   have "real (Suc n) *\<^sub>R S (x + y) (Suc n) = (x + y) * S (x + y) n"
   936     by (simp only: times_S)
   937   also have "\<dots> = (x + y) * (\<Sum>i=0..n. S x i * S y (n-i))"
   938     by (simp only: Suc)
   939   also have "\<dots> = x * (\<Sum>i=0..n. S x i * S y (n-i))
   940                 + y * (\<Sum>i=0..n. S x i * S y (n-i))"
   941     by (rule left_distrib)
   942   also have "\<dots> = (\<Sum>i=0..n. (x * S x i) * S y (n-i))
   943                 + (\<Sum>i=0..n. S x i * (y * S y (n-i)))"
   944     by (simp only: setsum_right_distrib mult_ac)
   945   also have "\<dots> = (\<Sum>i=0..n. real (Suc i) *\<^sub>R (S x (Suc i) * S y (n-i)))
   946                 + (\<Sum>i=0..n. real (Suc n-i) *\<^sub>R (S x i * S y (Suc n-i)))"
   947     by (simp add: times_S Suc_diff_le)
   948   also have "(\<Sum>i=0..n. real (Suc i) *\<^sub>R (S x (Suc i) * S y (n-i))) =
   949              (\<Sum>i=0..Suc n. real i *\<^sub>R (S x i * S y (Suc n-i)))"
   950     by (subst setsum_cl_ivl_Suc2, simp)
   951   also have "(\<Sum>i=0..n. real (Suc n-i) *\<^sub>R (S x i * S y (Suc n-i))) =
   952              (\<Sum>i=0..Suc n. real (Suc n-i) *\<^sub>R (S x i * S y (Suc n-i)))"
   953     by (subst setsum_cl_ivl_Suc, simp)
   954   also have "(\<Sum>i=0..Suc n. real i *\<^sub>R (S x i * S y (Suc n-i))) +
   955              (\<Sum>i=0..Suc n. real (Suc n-i) *\<^sub>R (S x i * S y (Suc n-i))) =
   956              (\<Sum>i=0..Suc n. real (Suc n) *\<^sub>R (S x i * S y (Suc n-i)))"
   957     by (simp only: setsum_addf [symmetric] scaleR_left_distrib [symmetric]
   958               real_of_nat_add [symmetric], simp)
   959   also have "\<dots> = real (Suc n) *\<^sub>R (\<Sum>i=0..Suc n. S x i * S y (Suc n-i))"
   960     by (simp only: scaleR_right.setsum)
   961   finally show
   962     "S (x + y) (Suc n) = (\<Sum>i=0..Suc n. S x i * S y (Suc n - i))"
   963     by (simp add: scaleR_cancel_left del: setsum_cl_ivl_Suc)
   964 qed
   965 
   966 lemma exp_add: "exp (x + y) = exp x * exp y"
   967 unfolding exp_def
   968 by (simp only: Cauchy_product summable_norm_exp exp_series_add)
   969 
   970 lemma mult_exp_exp: "exp x * exp y = exp (x + y)"
   971 by (rule exp_add [symmetric])
   972 
   973 lemma exp_of_real: "exp (of_real x) = of_real (exp x)"
   974 unfolding exp_def
   975 apply (subst of_real.suminf)
   976 apply (rule summable_exp_generic)
   977 apply (simp add: scaleR_conv_of_real)
   978 done
   979 
   980 lemma exp_not_eq_zero [simp]: "exp x \<noteq> 0"
   981 proof
   982   have "exp x * exp (- x) = 1" by (simp add: mult_exp_exp)
   983   also assume "exp x = 0"
   984   finally show "False" by simp
   985 qed
   986 
   987 lemma exp_minus: "exp (- x) = inverse (exp x)"
   988 by (rule inverse_unique [symmetric], simp add: mult_exp_exp)
   989 
   990 lemma exp_diff: "exp (x - y) = exp x / exp y"
   991   unfolding diff_minus divide_inverse
   992   by (simp add: exp_add exp_minus)
   993 
   994 
   995 subsubsection {* Properties of the Exponential Function on Reals *}
   996 
   997 text {* Comparisons of @{term "exp x"} with zero. *}
   998 
   999 text{*Proof: because every exponential can be seen as a square.*}
  1000 lemma exp_ge_zero [simp]: "0 \<le> exp (x::real)"
  1001 proof -
  1002   have "0 \<le> exp (x/2) * exp (x/2)" by simp
  1003   thus ?thesis by (simp add: exp_add [symmetric])
  1004 qed
  1005 
  1006 lemma exp_gt_zero [simp]: "0 < exp (x::real)"
  1007 by (simp add: order_less_le)
  1008 
  1009 lemma not_exp_less_zero [simp]: "\<not> exp (x::real) < 0"
  1010 by (simp add: not_less)
  1011 
  1012 lemma not_exp_le_zero [simp]: "\<not> exp (x::real) \<le> 0"
  1013 by (simp add: not_le)
  1014 
  1015 lemma abs_exp_cancel [simp]: "\<bar>exp x::real\<bar> = exp x"
  1016 by simp
  1017 
  1018 lemma exp_real_of_nat_mult: "exp(real n * x) = exp(x) ^ n"
  1019 apply (induct "n")
  1020 apply (auto simp add: real_of_nat_Suc right_distrib exp_add mult_commute)
  1021 done
  1022 
  1023 text {* Strict monotonicity of exponential. *}
  1024 
  1025 lemma exp_ge_add_one_self_aux: "0 \<le> (x::real) ==> (1 + x) \<le> exp(x)"
  1026 apply (drule order_le_imp_less_or_eq, auto)
  1027 apply (simp add: exp_def)
  1028 apply (rule real_le_trans)
  1029 apply (rule_tac [2] n = 2 and f = "(%n. inverse (real (fact n)) * x ^ n)" in series_pos_le)
  1030 apply (auto intro: summable_exp simp add: numeral_2_eq_2 zero_le_mult_iff)
  1031 done
  1032 
  1033 lemma exp_gt_one: "0 < (x::real) \<Longrightarrow> 1 < exp x"
  1034 proof -
  1035   assume x: "0 < x"
  1036   hence "1 < 1 + x" by simp
  1037   also from x have "1 + x \<le> exp x"
  1038     by (simp add: exp_ge_add_one_self_aux)
  1039   finally show ?thesis .
  1040 qed
  1041 
  1042 lemma exp_less_mono:
  1043   fixes x y :: real
  1044   assumes "x < y" shows "exp x < exp y"
  1045 proof -
  1046   from `x < y` have "0 < y - x" by simp
  1047   hence "1 < exp (y - x)" by (rule exp_gt_one)
  1048   hence "1 < exp y / exp x" by (simp only: exp_diff)
  1049   thus "exp x < exp y" by simp
  1050 qed
  1051 
  1052 lemma exp_less_cancel: "exp (x::real) < exp y ==> x < y"
  1053 apply (simp add: linorder_not_le [symmetric])
  1054 apply (auto simp add: order_le_less exp_less_mono)
  1055 done
  1056 
  1057 lemma exp_less_cancel_iff [iff]: "exp (x::real) < exp y \<longleftrightarrow> x < y"
  1058 by (auto intro: exp_less_mono exp_less_cancel)
  1059 
  1060 lemma exp_le_cancel_iff [iff]: "exp (x::real) \<le> exp y \<longleftrightarrow> x \<le> y"
  1061 by (auto simp add: linorder_not_less [symmetric])
  1062 
  1063 lemma exp_inj_iff [iff]: "exp (x::real) = exp y \<longleftrightarrow> x = y"
  1064 by (simp add: order_eq_iff)
  1065 
  1066 text {* Comparisons of @{term "exp x"} with one. *}
  1067 
  1068 lemma one_less_exp_iff [simp]: "1 < exp (x::real) \<longleftrightarrow> 0 < x"
  1069   using exp_less_cancel_iff [where x=0 and y=x] by simp
  1070 
  1071 lemma exp_less_one_iff [simp]: "exp (x::real) < 1 \<longleftrightarrow> x < 0"
  1072   using exp_less_cancel_iff [where x=x and y=0] by simp
  1073 
  1074 lemma one_le_exp_iff [simp]: "1 \<le> exp (x::real) \<longleftrightarrow> 0 \<le> x"
  1075   using exp_le_cancel_iff [where x=0 and y=x] by simp
  1076 
  1077 lemma exp_le_one_iff [simp]: "exp (x::real) \<le> 1 \<longleftrightarrow> x \<le> 0"
  1078   using exp_le_cancel_iff [where x=x and y=0] by simp
  1079 
  1080 lemma exp_eq_one_iff [simp]: "exp (x::real) = 1 \<longleftrightarrow> x = 0"
  1081   using exp_inj_iff [where x=x and y=0] by simp
  1082 
  1083 lemma lemma_exp_total: "1 \<le> y ==> \<exists>x. 0 \<le> x & x \<le> y - 1 & exp(x::real) = y"
  1084 apply (rule IVT)
  1085 apply (auto intro: isCont_exp simp add: le_diff_eq)
  1086 apply (subgoal_tac "1 + (y - 1) \<le> exp (y - 1)") 
  1087 apply simp
  1088 apply (rule exp_ge_add_one_self_aux, simp)
  1089 done
  1090 
  1091 lemma exp_total: "0 < (y::real) ==> \<exists>x. exp x = y"
  1092 apply (rule_tac x = 1 and y = y in linorder_cases)
  1093 apply (drule order_less_imp_le [THEN lemma_exp_total])
  1094 apply (rule_tac [2] x = 0 in exI)
  1095 apply (frule_tac [3] real_inverse_gt_one)
  1096 apply (drule_tac [4] order_less_imp_le [THEN lemma_exp_total], auto)
  1097 apply (rule_tac x = "-x" in exI)
  1098 apply (simp add: exp_minus)
  1099 done
  1100 
  1101 
  1102 subsection {* Natural Logarithm *}
  1103 
  1104 definition
  1105   ln :: "real => real" where
  1106   "ln x = (THE u. exp u = x)"
  1107 
  1108 lemma ln_exp [simp]: "ln (exp x) = x"
  1109 by (simp add: ln_def)
  1110 
  1111 lemma exp_ln [simp]: "0 < x \<Longrightarrow> exp (ln x) = x"
  1112 by (auto dest: exp_total)
  1113 
  1114 lemma exp_ln_iff [simp]: "exp (ln x) = x \<longleftrightarrow> 0 < x"
  1115 apply (rule iffI)
  1116 apply (erule subst, rule exp_gt_zero)
  1117 apply (erule exp_ln)
  1118 done
  1119 
  1120 lemma ln_unique: "exp y = x \<Longrightarrow> ln x = y"
  1121 by (erule subst, rule ln_exp)
  1122 
  1123 lemma ln_one [simp]: "ln 1 = 0"
  1124 by (rule ln_unique, simp)
  1125 
  1126 lemma ln_mult: "\<lbrakk>0 < x; 0 < y\<rbrakk> \<Longrightarrow> ln (x * y) = ln x + ln y"
  1127 by (rule ln_unique, simp add: exp_add)
  1128 
  1129 lemma ln_inverse: "0 < x \<Longrightarrow> ln (inverse x) = - ln x"
  1130 by (rule ln_unique, simp add: exp_minus)
  1131 
  1132 lemma ln_div: "\<lbrakk>0 < x; 0 < y\<rbrakk> \<Longrightarrow> ln (x / y) = ln x - ln y"
  1133 by (rule ln_unique, simp add: exp_diff)
  1134 
  1135 lemma ln_realpow: "0 < x \<Longrightarrow> ln (x ^ n) = real n * ln x"
  1136 by (rule ln_unique, simp add: exp_real_of_nat_mult)
  1137 
  1138 lemma ln_less_cancel_iff [simp]: "\<lbrakk>0 < x; 0 < y\<rbrakk> \<Longrightarrow> ln x < ln y \<longleftrightarrow> x < y"
  1139 by (subst exp_less_cancel_iff [symmetric], simp)
  1140 
  1141 lemma ln_le_cancel_iff [simp]: "\<lbrakk>0 < x; 0 < y\<rbrakk> \<Longrightarrow> ln x \<le> ln y \<longleftrightarrow> x \<le> y"
  1142 by (simp add: linorder_not_less [symmetric])
  1143 
  1144 lemma ln_inj_iff [simp]: "\<lbrakk>0 < x; 0 < y\<rbrakk> \<Longrightarrow> ln x = ln y \<longleftrightarrow> x = y"
  1145 by (simp add: order_eq_iff)
  1146 
  1147 lemma ln_add_one_self_le_self [simp]: "0 \<le> x \<Longrightarrow> ln (1 + x) \<le> x"
  1148 apply (rule exp_le_cancel_iff [THEN iffD1])
  1149 apply (simp add: exp_ge_add_one_self_aux)
  1150 done
  1151 
  1152 lemma ln_less_self [simp]: "0 < x \<Longrightarrow> ln x < x"
  1153 by (rule order_less_le_trans [where y="ln (1 + x)"]) simp_all
  1154 
  1155 lemma ln_ge_zero [simp]:
  1156   assumes x: "1 \<le> x" shows "0 \<le> ln x"
  1157 proof -
  1158   have "0 < x" using x by arith
  1159   hence "exp 0 \<le> exp (ln x)"
  1160     by (simp add: x)
  1161   thus ?thesis by (simp only: exp_le_cancel_iff)
  1162 qed
  1163 
  1164 lemma ln_ge_zero_imp_ge_one:
  1165   assumes ln: "0 \<le> ln x" 
  1166       and x:  "0 < x"
  1167   shows "1 \<le> x"
  1168 proof -
  1169   from ln have "ln 1 \<le> ln x" by simp
  1170   thus ?thesis by (simp add: x del: ln_one) 
  1171 qed
  1172 
  1173 lemma ln_ge_zero_iff [simp]: "0 < x ==> (0 \<le> ln x) = (1 \<le> x)"
  1174 by (blast intro: ln_ge_zero ln_ge_zero_imp_ge_one)
  1175 
  1176 lemma ln_less_zero_iff [simp]: "0 < x ==> (ln x < 0) = (x < 1)"
  1177 by (insert ln_ge_zero_iff [of x], arith)
  1178 
  1179 lemma ln_gt_zero:
  1180   assumes x: "1 < x" shows "0 < ln x"
  1181 proof -
  1182   have "0 < x" using x by arith
  1183   hence "exp 0 < exp (ln x)" by (simp add: x)
  1184   thus ?thesis  by (simp only: exp_less_cancel_iff)
  1185 qed
  1186 
  1187 lemma ln_gt_zero_imp_gt_one:
  1188   assumes ln: "0 < ln x" 
  1189       and x:  "0 < x"
  1190   shows "1 < x"
  1191 proof -
  1192   from ln have "ln 1 < ln x" by simp
  1193   thus ?thesis by (simp add: x del: ln_one) 
  1194 qed
  1195 
  1196 lemma ln_gt_zero_iff [simp]: "0 < x ==> (0 < ln x) = (1 < x)"
  1197 by (blast intro: ln_gt_zero ln_gt_zero_imp_gt_one)
  1198 
  1199 lemma ln_eq_zero_iff [simp]: "0 < x ==> (ln x = 0) = (x = 1)"
  1200 by (insert ln_less_zero_iff [of x] ln_gt_zero_iff [of x], arith)
  1201 
  1202 lemma ln_less_zero: "[| 0 < x; x < 1 |] ==> ln x < 0"
  1203 by simp
  1204 
  1205 lemma exp_ln_eq: "exp u = x ==> ln x = u"
  1206 by auto
  1207 
  1208 lemma isCont_ln: "0 < x \<Longrightarrow> isCont ln x"
  1209 apply (subgoal_tac "isCont ln (exp (ln x))", simp)
  1210 apply (rule isCont_inverse_function [where f=exp], simp_all)
  1211 done
  1212 
  1213 lemma DERIV_ln: "0 < x \<Longrightarrow> DERIV ln x :> inverse x"
  1214 apply (rule DERIV_inverse_function [where f=exp and a=0 and b="x+1"])
  1215 apply (erule lemma_DERIV_subst [OF DERIV_exp exp_ln])
  1216 apply (simp_all add: abs_if isCont_ln)
  1217 done
  1218 
  1219 lemma ln_series: assumes "0 < x" and "x < 2"
  1220   shows "ln x = (\<Sum> n. (-1)^n * (1 / real (n + 1)) * (x - 1)^(Suc n))" (is "ln x = suminf (?f (x - 1))")
  1221 proof -
  1222   let "?f' x n" = "(-1)^n * (x - 1)^n"
  1223 
  1224   have "ln x - suminf (?f (x - 1)) = ln 1 - suminf (?f (1 - 1))"
  1225   proof (rule DERIV_isconst3[where x=x])
  1226     fix x :: real assume "x \<in> {0 <..< 2}" hence "0 < x" and "x < 2" by auto
  1227     have "norm (1 - x) < 1" using `0 < x` and `x < 2` by auto
  1228     have "1 / x = 1 / (1 - (1 - x))" by auto
  1229     also have "\<dots> = (\<Sum> n. (1 - x)^n)" using geometric_sums[OF `norm (1 - x) < 1`] by (rule sums_unique)
  1230     also have "\<dots> = suminf (?f' x)" unfolding power_mult_distrib[symmetric] by (rule arg_cong[where f=suminf], rule arg_cong[where f="op ^"], auto)
  1231     finally have "DERIV ln x :> suminf (?f' x)" using DERIV_ln[OF `0 < x`] unfolding real_divide_def by auto
  1232     moreover
  1233     have repos: "\<And> h x :: real. h - 1 + x = h + x - 1" by auto
  1234     have "DERIV (\<lambda>x. suminf (?f x)) (x - 1) :> (\<Sum>n. (-1)^n * (1 / real (n + 1)) * real (Suc n) * (x - 1) ^ n)"
  1235     proof (rule DERIV_power_series')
  1236       show "x - 1 \<in> {- 1<..<1}" and "(0 :: real) < 1" using `0 < x` `x < 2` by auto
  1237       { fix x :: real assume "x \<in> {- 1<..<1}" hence "norm (-x) < 1" by auto
  1238 	show "summable (\<lambda>n. -1 ^ n * (1 / real (n + 1)) * real (Suc n) * x ^ n)"
  1239           unfolding One_nat_def
  1240 	  by (auto simp del: power_mult_distrib simp add: power_mult_distrib[symmetric] summable_geometric[OF `norm (-x) < 1`])
  1241       }
  1242     qed
  1243     hence "DERIV (\<lambda>x. suminf (?f x)) (x - 1) :> suminf (?f' x)" unfolding One_nat_def by auto
  1244     hence "DERIV (\<lambda>x. suminf (?f (x - 1))) x :> suminf (?f' x)" unfolding DERIV_iff repos .
  1245     ultimately have "DERIV (\<lambda>x. ln x - suminf (?f (x - 1))) x :> (suminf (?f' x) - suminf (?f' x))"
  1246       by (rule DERIV_diff)
  1247     thus "DERIV (\<lambda>x. ln x - suminf (?f (x - 1))) x :> 0" by auto
  1248   qed (auto simp add: assms)
  1249   thus ?thesis by (auto simp add: suminf_zero)
  1250 qed
  1251 
  1252 subsection {* Sine and Cosine *}
  1253 
  1254 definition
  1255   sin_coeff :: "nat \<Rightarrow> real" where
  1256   "sin_coeff = (\<lambda>n. if even n then 0 else -1 ^ ((n - Suc 0) div 2) / real (fact n))"
  1257 
  1258 definition
  1259   cos_coeff :: "nat \<Rightarrow> real" where
  1260   "cos_coeff = (\<lambda>n. if even n then (-1 ^ (n div 2)) / real (fact n) else 0)"
  1261 
  1262 definition
  1263   sin :: "real => real" where
  1264   "sin x = (\<Sum>n. sin_coeff n * x ^ n)"
  1265 
  1266 definition
  1267   cos :: "real => real" where
  1268   "cos x = (\<Sum>n. cos_coeff n * x ^ n)"
  1269 
  1270 lemma summable_sin: "summable (\<lambda>n. sin_coeff n * x ^ n)"
  1271 unfolding sin_coeff_def
  1272 apply (rule_tac g = "(%n. inverse (real (fact n)) * \<bar>x\<bar> ^ n)" in summable_comparison_test)
  1273 apply (rule_tac [2] summable_exp)
  1274 apply (rule_tac x = 0 in exI)
  1275 apply (auto simp add: divide_inverse abs_mult power_abs [symmetric] zero_le_mult_iff)
  1276 done
  1277 
  1278 lemma summable_cos: "summable (\<lambda>n. cos_coeff n * x ^ n)"
  1279 unfolding cos_coeff_def
  1280 apply (rule_tac g = "(%n. inverse (real (fact n)) * \<bar>x\<bar> ^ n)" in summable_comparison_test)
  1281 apply (rule_tac [2] summable_exp)
  1282 apply (rule_tac x = 0 in exI)
  1283 apply (auto simp add: divide_inverse abs_mult power_abs [symmetric] zero_le_mult_iff)
  1284 done
  1285 
  1286 lemma lemma_STAR_sin:
  1287      "(if even n then 0  
  1288        else -1 ^ ((n - Suc 0) div 2)/(real (fact n))) * 0 ^ n = 0"
  1289 by (induct "n", auto)
  1290 
  1291 lemma lemma_STAR_cos:
  1292      "0 < n -->  
  1293       -1 ^ (n div 2)/(real (fact n)) * 0 ^ n = 0"
  1294 by (induct "n", auto)
  1295 
  1296 lemma lemma_STAR_cos1:
  1297      "0 < n -->  
  1298       (-1) ^ (n div 2)/(real (fact n)) * 0 ^ n = 0"
  1299 by (induct "n", auto)
  1300 
  1301 lemma lemma_STAR_cos2:
  1302   "(\<Sum>n=1..<n. if even n then -1 ^ (n div 2)/(real (fact n)) *  0 ^ n 
  1303                          else 0) = 0"
  1304 apply (induct "n")
  1305 apply (case_tac [2] "n", auto)
  1306 done
  1307 
  1308 lemma sin_converges: "(\<lambda>n. sin_coeff n * x ^ n) sums sin(x)"
  1309 unfolding sin_def by (rule summable_sin [THEN summable_sums])
  1310 
  1311 lemma cos_converges: "(\<lambda>n. cos_coeff n * x ^ n) sums cos(x)"
  1312 unfolding cos_def by (rule summable_cos [THEN summable_sums])
  1313 
  1314 lemma sin_fdiffs: "diffs sin_coeff = cos_coeff"
  1315 unfolding sin_coeff_def cos_coeff_def
  1316 by (auto intro!: ext 
  1317          simp add: diffs_def divide_inverse real_of_nat_def of_nat_mult
  1318          simp del: mult_Suc of_nat_Suc)
  1319 
  1320 lemma sin_fdiffs2: "diffs sin_coeff n = cos_coeff n"
  1321 by (simp only: sin_fdiffs)
  1322 
  1323 lemma cos_fdiffs: "diffs cos_coeff = (\<lambda>n. - sin_coeff n)"
  1324 unfolding sin_coeff_def cos_coeff_def
  1325 by (auto intro!: ext 
  1326          simp add: diffs_def divide_inverse odd_Suc_mult_two_ex real_of_nat_def of_nat_mult
  1327          simp del: mult_Suc of_nat_Suc)
  1328 
  1329 lemma cos_fdiffs2: "diffs cos_coeff n = - sin_coeff n"
  1330 by (simp only: cos_fdiffs)
  1331 
  1332 text{*Now at last we can get the derivatives of exp, sin and cos*}
  1333 
  1334 lemma lemma_sin_minus: "- sin x = (\<Sum>n. - (sin_coeff n * x ^ n))"
  1335 by (auto intro!: sums_unique sums_minus sin_converges)
  1336 
  1337 lemma lemma_sin_ext: "sin = (\<lambda>x. \<Sum>n. sin_coeff n * x ^ n)"
  1338 by (auto intro!: ext simp add: sin_def)
  1339 
  1340 lemma lemma_cos_ext: "cos = (\<lambda>x. \<Sum>n. cos_coeff n * x ^ n)"
  1341 by (auto intro!: ext simp add: cos_def)
  1342 
  1343 lemma DERIV_sin [simp]: "DERIV sin x :> cos(x)"
  1344 apply (simp add: cos_def)
  1345 apply (subst lemma_sin_ext)
  1346 apply (auto simp add: sin_fdiffs2 [symmetric])
  1347 apply (rule_tac K = "1 + \<bar>x\<bar>" in termdiffs)
  1348 apply (auto intro: sin_converges cos_converges sums_summable intro!: sums_minus [THEN sums_summable] simp add: cos_fdiffs sin_fdiffs)
  1349 done
  1350 
  1351 lemma DERIV_cos [simp]: "DERIV cos x :> -sin(x)"
  1352 apply (subst lemma_cos_ext)
  1353 apply (auto simp add: lemma_sin_minus cos_fdiffs2 [symmetric] minus_mult_left)
  1354 apply (rule_tac K = "1 + \<bar>x\<bar>" in termdiffs)
  1355 apply (auto intro: sin_converges cos_converges sums_summable intro!: sums_minus [THEN sums_summable] simp add: cos_fdiffs sin_fdiffs diffs_minus)
  1356 done
  1357 
  1358 lemma isCont_sin [simp]: "isCont sin x"
  1359 by (rule DERIV_sin [THEN DERIV_isCont])
  1360 
  1361 lemma isCont_cos [simp]: "isCont cos x"
  1362 by (rule DERIV_cos [THEN DERIV_isCont])
  1363 
  1364 
  1365 subsection {* Properties of Sine and Cosine *}
  1366 
  1367 lemma sin_zero [simp]: "sin 0 = 0"
  1368 unfolding sin_def sin_coeff_def by (simp add: powser_zero)
  1369 
  1370 lemma cos_zero [simp]: "cos 0 = 1"
  1371 unfolding cos_def cos_coeff_def by (simp add: powser_zero)
  1372 
  1373 lemma DERIV_sin_sin_mult [simp]:
  1374      "DERIV (%x. sin(x)*sin(x)) x :> cos(x) * sin(x) + cos(x) * sin(x)"
  1375 by (rule DERIV_mult, auto)
  1376 
  1377 lemma DERIV_sin_sin_mult2 [simp]:
  1378      "DERIV (%x. sin(x)*sin(x)) x :> 2 * cos(x) * sin(x)"
  1379 apply (cut_tac x = x in DERIV_sin_sin_mult)
  1380 apply (auto simp add: mult_assoc)
  1381 done
  1382 
  1383 lemma DERIV_sin_realpow2 [simp]:
  1384      "DERIV (%x. (sin x)\<twosuperior>) x :> cos(x) * sin(x) + cos(x) * sin(x)"
  1385 by (auto simp add: numeral_2_eq_2 real_mult_assoc [symmetric])
  1386 
  1387 lemma DERIV_sin_realpow2a [simp]:
  1388      "DERIV (%x. (sin x)\<twosuperior>) x :> 2 * cos(x) * sin(x)"
  1389 by (auto simp add: numeral_2_eq_2)
  1390 
  1391 lemma DERIV_cos_cos_mult [simp]:
  1392      "DERIV (%x. cos(x)*cos(x)) x :> -sin(x) * cos(x) + -sin(x) * cos(x)"
  1393 by (rule DERIV_mult, auto)
  1394 
  1395 lemma DERIV_cos_cos_mult2 [simp]:
  1396      "DERIV (%x. cos(x)*cos(x)) x :> -2 * cos(x) * sin(x)"
  1397 apply (cut_tac x = x in DERIV_cos_cos_mult)
  1398 apply (auto simp add: mult_ac)
  1399 done
  1400 
  1401 lemma DERIV_cos_realpow2 [simp]:
  1402      "DERIV (%x. (cos x)\<twosuperior>) x :> -sin(x) * cos(x) + -sin(x) * cos(x)"
  1403 by (auto simp add: numeral_2_eq_2 real_mult_assoc [symmetric])
  1404 
  1405 lemma DERIV_cos_realpow2a [simp]:
  1406      "DERIV (%x. (cos x)\<twosuperior>) x :> -2 * cos(x) * sin(x)"
  1407 by (auto simp add: numeral_2_eq_2)
  1408 
  1409 lemma lemma_DERIV_subst: "[| DERIV f x :> D; D = E |] ==> DERIV f x :> E"
  1410 by auto
  1411 
  1412 lemma DERIV_cos_realpow2b: "DERIV (%x. (cos x)\<twosuperior>) x :> -(2 * cos(x) * sin(x))"
  1413 apply (rule lemma_DERIV_subst)
  1414 apply (rule DERIV_cos_realpow2a, auto)
  1415 done
  1416 
  1417 (* most useful *)
  1418 lemma DERIV_cos_cos_mult3 [simp]:
  1419      "DERIV (%x. cos(x)*cos(x)) x :> -(2 * cos(x) * sin(x))"
  1420 apply (rule lemma_DERIV_subst)
  1421 apply (rule DERIV_cos_cos_mult2, auto)
  1422 done
  1423 
  1424 lemma DERIV_sin_circle_all: 
  1425      "\<forall>x. DERIV (%x. (sin x)\<twosuperior> + (cos x)\<twosuperior>) x :>  
  1426              (2*cos(x)*sin(x) - 2*cos(x)*sin(x))"
  1427 apply (simp only: diff_minus, safe)
  1428 apply (rule DERIV_add) 
  1429 apply (auto simp add: numeral_2_eq_2)
  1430 done
  1431 
  1432 lemma DERIV_sin_circle_all_zero [simp]:
  1433      "\<forall>x. DERIV (%x. (sin x)\<twosuperior> + (cos x)\<twosuperior>) x :> 0"
  1434 by (cut_tac DERIV_sin_circle_all, auto)
  1435 
  1436 lemma sin_cos_squared_add [simp]: "((sin x)\<twosuperior>) + ((cos x)\<twosuperior>) = 1"
  1437 apply (cut_tac x = x and y = 0 in DERIV_sin_circle_all_zero [THEN DERIV_isconst_all])
  1438 apply (auto simp add: numeral_2_eq_2)
  1439 done
  1440 
  1441 lemma sin_cos_squared_add2 [simp]: "((cos x)\<twosuperior>) + ((sin x)\<twosuperior>) = 1"
  1442 apply (subst add_commute)
  1443 apply (rule sin_cos_squared_add)
  1444 done
  1445 
  1446 lemma sin_cos_squared_add3 [simp]: "cos x * cos x + sin x * sin x = 1"
  1447 apply (cut_tac x = x in sin_cos_squared_add2)
  1448 apply (simp add: power2_eq_square)
  1449 done
  1450 
  1451 lemma sin_squared_eq: "(sin x)\<twosuperior> = 1 - (cos x)\<twosuperior>"
  1452 apply (rule_tac a1 = "(cos x)\<twosuperior>" in add_right_cancel [THEN iffD1])
  1453 apply simp
  1454 done
  1455 
  1456 lemma cos_squared_eq: "(cos x)\<twosuperior> = 1 - (sin x)\<twosuperior>"
  1457 apply (rule_tac a1 = "(sin x)\<twosuperior>" in add_right_cancel [THEN iffD1])
  1458 apply simp
  1459 done
  1460 
  1461 lemma abs_sin_le_one [simp]: "\<bar>sin x\<bar> \<le> 1"
  1462 by (rule power2_le_imp_le, simp_all add: sin_squared_eq)
  1463 
  1464 lemma sin_ge_minus_one [simp]: "-1 \<le> sin x"
  1465 apply (insert abs_sin_le_one [of x]) 
  1466 apply (simp add: abs_le_iff del: abs_sin_le_one) 
  1467 done
  1468 
  1469 lemma sin_le_one [simp]: "sin x \<le> 1"
  1470 apply (insert abs_sin_le_one [of x]) 
  1471 apply (simp add: abs_le_iff del: abs_sin_le_one) 
  1472 done
  1473 
  1474 lemma abs_cos_le_one [simp]: "\<bar>cos x\<bar> \<le> 1"
  1475 by (rule power2_le_imp_le, simp_all add: cos_squared_eq)
  1476 
  1477 lemma cos_ge_minus_one [simp]: "-1 \<le> cos x"
  1478 apply (insert abs_cos_le_one [of x]) 
  1479 apply (simp add: abs_le_iff del: abs_cos_le_one) 
  1480 done
  1481 
  1482 lemma cos_le_one [simp]: "cos x \<le> 1"
  1483 apply (insert abs_cos_le_one [of x]) 
  1484 apply (simp add: abs_le_iff del: abs_cos_le_one)
  1485 done
  1486 
  1487 lemma DERIV_fun_pow: "DERIV g x :> m ==>  
  1488       DERIV (%x. (g x) ^ n) x :> real n * (g x) ^ (n - 1) * m"
  1489 unfolding One_nat_def
  1490 apply (rule lemma_DERIV_subst)
  1491 apply (rule_tac f = "(%x. x ^ n)" in DERIV_chain2)
  1492 apply (rule DERIV_pow, auto)
  1493 done
  1494 
  1495 lemma DERIV_fun_exp:
  1496      "DERIV g x :> m ==> DERIV (%x. exp(g x)) x :> exp(g x) * m"
  1497 apply (rule lemma_DERIV_subst)
  1498 apply (rule_tac f = exp in DERIV_chain2)
  1499 apply (rule DERIV_exp, auto)
  1500 done
  1501 
  1502 lemma DERIV_fun_sin:
  1503      "DERIV g x :> m ==> DERIV (%x. sin(g x)) x :> cos(g x) * m"
  1504 apply (rule lemma_DERIV_subst)
  1505 apply (rule_tac f = sin in DERIV_chain2)
  1506 apply (rule DERIV_sin, auto)
  1507 done
  1508 
  1509 lemma DERIV_fun_cos:
  1510      "DERIV g x :> m ==> DERIV (%x. cos(g x)) x :> -sin(g x) * m"
  1511 apply (rule lemma_DERIV_subst)
  1512 apply (rule_tac f = cos in DERIV_chain2)
  1513 apply (rule DERIV_cos, auto)
  1514 done
  1515 
  1516 lemmas DERIV_intros = DERIV_ident DERIV_const DERIV_cos DERIV_cmult 
  1517                     DERIV_sin  DERIV_exp  DERIV_inverse DERIV_pow 
  1518                     DERIV_add  DERIV_diff  DERIV_mult  DERIV_minus 
  1519                     DERIV_inverse_fun DERIV_quotient DERIV_fun_pow 
  1520                     DERIV_fun_exp DERIV_fun_sin DERIV_fun_cos 
  1521 
  1522 (* lemma *)
  1523 lemma lemma_DERIV_sin_cos_add:
  1524      "\<forall>x.  
  1525          DERIV (%x. (sin (x + y) - (sin x * cos y + cos x * sin y)) ^ 2 +  
  1526                (cos (x + y) - (cos x * cos y - sin x * sin y)) ^ 2) x :> 0"
  1527 apply (safe, rule lemma_DERIV_subst)
  1528 apply (best intro!: DERIV_intros intro: DERIV_chain2) 
  1529   --{*replaces the old @{text DERIV_tac}*}
  1530 apply (auto simp add: algebra_simps)
  1531 done
  1532 
  1533 lemma sin_cos_add [simp]:
  1534      "(sin (x + y) - (sin x * cos y + cos x * sin y)) ^ 2 +  
  1535       (cos (x + y) - (cos x * cos y - sin x * sin y)) ^ 2 = 0"
  1536 apply (cut_tac y = 0 and x = x and y7 = y 
  1537        in lemma_DERIV_sin_cos_add [THEN DERIV_isconst_all])
  1538 apply (auto simp add: numeral_2_eq_2)
  1539 done
  1540 
  1541 lemma sin_add: "sin (x + y) = sin x * cos y + cos x * sin y"
  1542 apply (cut_tac x = x and y = y in sin_cos_add)
  1543 apply (simp del: sin_cos_add)
  1544 done
  1545 
  1546 lemma cos_add: "cos (x + y) = cos x * cos y - sin x * sin y"
  1547 apply (cut_tac x = x and y = y in sin_cos_add)
  1548 apply (simp del: sin_cos_add)
  1549 done
  1550 
  1551 lemma lemma_DERIV_sin_cos_minus:
  1552     "\<forall>x. DERIV (%x. (sin(-x) + (sin x)) ^ 2 + (cos(-x) - (cos x)) ^ 2) x :> 0"
  1553 apply (safe, rule lemma_DERIV_subst)
  1554 apply (best intro!: DERIV_intros intro: DERIV_chain2)
  1555 apply (simp add: algebra_simps)
  1556 done
  1557 
  1558 lemma sin_cos_minus: 
  1559     "(sin(-x) + (sin x)) ^ 2 + (cos(-x) - (cos x)) ^ 2 = 0"
  1560 apply (cut_tac y = 0 and x = x 
  1561        in lemma_DERIV_sin_cos_minus [THEN DERIV_isconst_all])
  1562 apply simp
  1563 done
  1564 
  1565 lemma sin_minus [simp]: "sin (-x) = -sin(x)"
  1566   using sin_cos_minus [where x=x] by simp
  1567 
  1568 lemma cos_minus [simp]: "cos (-x) = cos(x)"
  1569   using sin_cos_minus [where x=x] by simp
  1570 
  1571 lemma sin_diff: "sin (x - y) = sin x * cos y - cos x * sin y"
  1572 by (simp add: diff_minus sin_add)
  1573 
  1574 lemma sin_diff2: "sin (x - y) = cos y * sin x - sin y * cos x"
  1575 by (simp add: sin_diff mult_commute)
  1576 
  1577 lemma cos_diff: "cos (x - y) = cos x * cos y + sin x * sin y"
  1578 by (simp add: diff_minus cos_add)
  1579 
  1580 lemma cos_diff2: "cos (x - y) = cos y * cos x + sin y * sin x"
  1581 by (simp add: cos_diff mult_commute)
  1582 
  1583 lemma sin_double [simp]: "sin(2 * x) = 2* sin x * cos x"
  1584   using sin_add [where x=x and y=x] by simp
  1585 
  1586 lemma cos_double: "cos(2* x) = ((cos x)\<twosuperior>) - ((sin x)\<twosuperior>)"
  1587   using cos_add [where x=x and y=x]
  1588   by (simp add: power2_eq_square)
  1589 
  1590 
  1591 subsection {* The Constant Pi *}
  1592 
  1593 definition
  1594   pi :: "real" where
  1595   "pi = 2 * (THE x. 0 \<le> (x::real) & x \<le> 2 & cos x = 0)"
  1596 
  1597 text{*Show that there's a least positive @{term x} with @{term "cos(x) = 0"}; 
  1598    hence define pi.*}
  1599 
  1600 lemma sin_paired:
  1601      "(%n. -1 ^ n /(real (fact (2 * n + 1))) * x ^ (2 * n + 1)) 
  1602       sums  sin x"
  1603 proof -
  1604   have "(\<lambda>n. \<Sum>k = n * 2..<n * 2 + 2. sin_coeff k * x ^ k) sums sin x"
  1605     unfolding sin_def
  1606     by (rule sin_converges [THEN sums_summable, THEN sums_group], simp) 
  1607   thus ?thesis unfolding One_nat_def sin_coeff_def by (simp add: mult_ac)
  1608 qed
  1609 
  1610 text {* FIXME: This is a long, ugly proof! *}
  1611 lemma sin_gt_zero: "[|0 < x; x < 2 |] ==> 0 < sin x"
  1612 apply (subgoal_tac 
  1613        "(\<lambda>n. \<Sum>k = n * 2..<n * 2 + 2.
  1614               -1 ^ k / real (fact (2 * k + 1)) * x ^ (2 * k + 1)) 
  1615      sums (\<Sum>n. -1 ^ n / real (fact (2 * n + 1)) * x ^ (2 * n + 1))")
  1616  prefer 2
  1617  apply (rule sin_paired [THEN sums_summable, THEN sums_group], simp) 
  1618 apply (rotate_tac 2)
  1619 apply (drule sin_paired [THEN sums_unique, THEN ssubst])
  1620 unfolding One_nat_def
  1621 apply (auto simp del: fact_Suc)
  1622 apply (frule sums_unique)
  1623 apply (auto simp del: fact_Suc)
  1624 apply (rule_tac n1 = 0 in series_pos_less [THEN [2] order_le_less_trans])
  1625 apply (auto simp del: fact_Suc)
  1626 apply (erule sums_summable)
  1627 apply (case_tac "m=0")
  1628 apply (simp (no_asm_simp))
  1629 apply (subgoal_tac "6 * (x * (x * x) / real (Suc (Suc (Suc (Suc (Suc (Suc 0))))))) < 6 * x") 
  1630 apply (simp only: mult_less_cancel_left, simp)  
  1631 apply (simp (no_asm_simp) add: numeral_2_eq_2 [symmetric] mult_assoc [symmetric])
  1632 apply (subgoal_tac "x*x < 2*3", simp) 
  1633 apply (rule mult_strict_mono)
  1634 apply (auto simp add: real_0_less_add_iff real_of_nat_Suc simp del: fact_Suc)
  1635 apply (subst fact_Suc)
  1636 apply (subst fact_Suc)
  1637 apply (subst fact_Suc)
  1638 apply (subst fact_Suc)
  1639 apply (subst real_of_nat_mult)
  1640 apply (subst real_of_nat_mult)
  1641 apply (subst real_of_nat_mult)
  1642 apply (subst real_of_nat_mult)
  1643 apply (simp (no_asm) add: divide_inverse del: fact_Suc)
  1644 apply (auto simp add: mult_assoc [symmetric] simp del: fact_Suc)
  1645 apply (rule_tac c="real (Suc (Suc (4*m)))" in mult_less_imp_less_right) 
  1646 apply (auto simp add: mult_assoc simp del: fact_Suc)
  1647 apply (rule_tac c="real (Suc (Suc (Suc (4*m))))" in mult_less_imp_less_right) 
  1648 apply (auto simp add: mult_assoc mult_less_cancel_left simp del: fact_Suc)
  1649 apply (subgoal_tac "x * (x * x ^ (4*m)) = (x ^ (4*m)) * (x * x)") 
  1650 apply (erule ssubst)+
  1651 apply (auto simp del: fact_Suc)
  1652 apply (subgoal_tac "0 < x ^ (4 * m) ")
  1653  prefer 2 apply (simp only: zero_less_power) 
  1654 apply (simp (no_asm_simp) add: mult_less_cancel_left)
  1655 apply (rule mult_strict_mono)
  1656 apply (simp_all (no_asm_simp))
  1657 done
  1658 
  1659 lemma sin_gt_zero1: "[|0 < x; x < 2 |] ==> 0 < sin x"
  1660 by (auto intro: sin_gt_zero)
  1661 
  1662 lemma cos_double_less_one: "[| 0 < x; x < 2 |] ==> cos (2 * x) < 1"
  1663 apply (cut_tac x = x in sin_gt_zero1)
  1664 apply (auto simp add: cos_squared_eq cos_double)
  1665 done
  1666 
  1667 lemma cos_paired:
  1668      "(%n. -1 ^ n /(real (fact (2 * n))) * x ^ (2 * n)) sums cos x"
  1669 proof -
  1670   have "(\<lambda>n. \<Sum>k = n * 2..<n * 2 + 2. cos_coeff k * x ^ k) sums cos x"
  1671     unfolding cos_def
  1672     by (rule cos_converges [THEN sums_summable, THEN sums_group], simp) 
  1673   thus ?thesis unfolding cos_coeff_def by (simp add: mult_ac)
  1674 qed
  1675 
  1676 lemma fact_lemma: "real (n::nat) * 4 = real (4 * n)"
  1677 by simp
  1678 
  1679 lemma cos_two_less_zero [simp]: "cos (2) < 0"
  1680 apply (cut_tac x = 2 in cos_paired)
  1681 apply (drule sums_minus)
  1682 apply (rule neg_less_iff_less [THEN iffD1]) 
  1683 apply (frule sums_unique, auto)
  1684 apply (rule_tac y =
  1685  "\<Sum>n=0..< Suc(Suc(Suc 0)). - (-1 ^ n / (real(fact (2*n))) * 2 ^ (2*n))"
  1686        in order_less_trans)
  1687 apply (simp (no_asm) add: fact_num_eq_if realpow_num_eq_if del: fact_Suc)
  1688 apply (simp (no_asm) add: mult_assoc del: setsum_op_ivl_Suc)
  1689 apply (rule sumr_pos_lt_pair)
  1690 apply (erule sums_summable, safe)
  1691 unfolding One_nat_def
  1692 apply (simp (no_asm) add: divide_inverse real_0_less_add_iff mult_assoc [symmetric] 
  1693             del: fact_Suc)
  1694 apply (rule real_mult_inverse_cancel2)
  1695 apply (rule real_of_nat_fact_gt_zero)+
  1696 apply (simp (no_asm) add: mult_assoc [symmetric] del: fact_Suc)
  1697 apply (subst fact_lemma) 
  1698 apply (subst fact_Suc [of "Suc (Suc (Suc (Suc (Suc (Suc (Suc (4 * d)))))))"])
  1699 apply (simp only: real_of_nat_mult)
  1700 apply (rule mult_strict_mono, force)
  1701   apply (rule_tac [3] real_of_nat_ge_zero)
  1702  prefer 2 apply force
  1703 apply (rule real_of_nat_less_iff [THEN iffD2])
  1704 apply (rule fact_less_mono, auto)
  1705 done
  1706 
  1707 lemmas cos_two_neq_zero [simp] = cos_two_less_zero [THEN less_imp_neq]
  1708 lemmas cos_two_le_zero [simp] = cos_two_less_zero [THEN order_less_imp_le]
  1709 
  1710 lemma cos_is_zero: "EX! x. 0 \<le> x & x \<le> 2 & cos x = 0"
  1711 apply (subgoal_tac "\<exists>x. 0 \<le> x & x \<le> 2 & cos x = 0")
  1712 apply (rule_tac [2] IVT2)
  1713 apply (auto intro: DERIV_isCont DERIV_cos)
  1714 apply (cut_tac x = xa and y = y in linorder_less_linear)
  1715 apply (rule ccontr)
  1716 apply (subgoal_tac " (\<forall>x. cos differentiable x) & (\<forall>x. isCont cos x) ")
  1717 apply (auto intro: DERIV_cos DERIV_isCont simp add: differentiable_def)
  1718 apply (drule_tac f = cos in Rolle)
  1719 apply (drule_tac [5] f = cos in Rolle)
  1720 apply (auto dest!: DERIV_cos [THEN DERIV_unique] simp add: differentiable_def)
  1721 apply (drule_tac y1 = xa in order_le_less_trans [THEN sin_gt_zero])
  1722 apply (assumption, rule_tac y=y in order_less_le_trans, simp_all) 
  1723 apply (drule_tac y1 = y in order_le_less_trans [THEN sin_gt_zero], assumption, simp_all) 
  1724 done
  1725     
  1726 lemma pi_half: "pi/2 = (THE x. 0 \<le> x & x \<le> 2 & cos x = 0)"
  1727 by (simp add: pi_def)
  1728 
  1729 lemma cos_pi_half [simp]: "cos (pi / 2) = 0"
  1730 by (simp add: pi_half cos_is_zero [THEN theI'])
  1731 
  1732 lemma pi_half_gt_zero [simp]: "0 < pi / 2"
  1733 apply (rule order_le_neq_trans)
  1734 apply (simp add: pi_half cos_is_zero [THEN theI'])
  1735 apply (rule notI, drule arg_cong [where f=cos], simp)
  1736 done
  1737 
  1738 lemmas pi_half_neq_zero [simp] = pi_half_gt_zero [THEN less_imp_neq, symmetric]
  1739 lemmas pi_half_ge_zero [simp] = pi_half_gt_zero [THEN order_less_imp_le]
  1740 
  1741 lemma pi_half_less_two [simp]: "pi / 2 < 2"
  1742 apply (rule order_le_neq_trans)
  1743 apply (simp add: pi_half cos_is_zero [THEN theI'])
  1744 apply (rule notI, drule arg_cong [where f=cos], simp)
  1745 done
  1746 
  1747 lemmas pi_half_neq_two [simp] = pi_half_less_two [THEN less_imp_neq]
  1748 lemmas pi_half_le_two [simp] =  pi_half_less_two [THEN order_less_imp_le]
  1749 
  1750 lemma pi_gt_zero [simp]: "0 < pi"
  1751 by (insert pi_half_gt_zero, simp)
  1752 
  1753 lemma pi_ge_zero [simp]: "0 \<le> pi"
  1754 by (rule pi_gt_zero [THEN order_less_imp_le])
  1755 
  1756 lemma pi_neq_zero [simp]: "pi \<noteq> 0"
  1757 by (rule pi_gt_zero [THEN less_imp_neq, THEN not_sym])
  1758 
  1759 lemma pi_not_less_zero [simp]: "\<not> pi < 0"
  1760 by (simp add: linorder_not_less)
  1761 
  1762 lemma minus_pi_half_less_zero: "-(pi/2) < 0"
  1763 by simp
  1764 
  1765 lemma m2pi_less_pi: "- (2 * pi) < pi"
  1766 proof -
  1767   have "- (2 * pi) < 0" and "0 < pi" by auto
  1768   from order_less_trans[OF this] show ?thesis .
  1769 qed
  1770 
  1771 lemma sin_pi_half [simp]: "sin(pi/2) = 1"
  1772 apply (cut_tac x = "pi/2" in sin_cos_squared_add2)
  1773 apply (cut_tac sin_gt_zero [OF pi_half_gt_zero pi_half_less_two])
  1774 apply (simp add: power2_eq_square)
  1775 done
  1776 
  1777 lemma cos_pi [simp]: "cos pi = -1"
  1778 by (cut_tac x = "pi/2" and y = "pi/2" in cos_add, simp)
  1779 
  1780 lemma sin_pi [simp]: "sin pi = 0"
  1781 by (cut_tac x = "pi/2" and y = "pi/2" in sin_add, simp)
  1782 
  1783 lemma sin_cos_eq: "sin x = cos (pi/2 - x)"
  1784 by (simp add: diff_minus cos_add)
  1785 declare sin_cos_eq [symmetric, simp]
  1786 
  1787 lemma minus_sin_cos_eq: "-sin x = cos (x + pi/2)"
  1788 by (simp add: cos_add)
  1789 declare minus_sin_cos_eq [symmetric, simp]
  1790 
  1791 lemma cos_sin_eq: "cos x = sin (pi/2 - x)"
  1792 by (simp add: diff_minus sin_add)
  1793 declare cos_sin_eq [symmetric, simp]
  1794 
  1795 lemma sin_periodic_pi [simp]: "sin (x + pi) = - sin x"
  1796 by (simp add: sin_add)
  1797 
  1798 lemma sin_periodic_pi2 [simp]: "sin (pi + x) = - sin x"
  1799 by (simp add: sin_add)
  1800 
  1801 lemma cos_periodic_pi [simp]: "cos (x + pi) = - cos x"
  1802 by (simp add: cos_add)
  1803 
  1804 lemma sin_periodic [simp]: "sin (x + 2*pi) = sin x"
  1805 by (simp add: sin_add cos_double)
  1806 
  1807 lemma cos_periodic [simp]: "cos (x + 2*pi) = cos x"
  1808 by (simp add: cos_add cos_double)
  1809 
  1810 lemma cos_npi [simp]: "cos (real n * pi) = -1 ^ n"
  1811 apply (induct "n")
  1812 apply (auto simp add: real_of_nat_Suc left_distrib)
  1813 done
  1814 
  1815 lemma cos_npi2 [simp]: "cos (pi * real n) = -1 ^ n"
  1816 proof -
  1817   have "cos (pi * real n) = cos (real n * pi)" by (simp only: mult_commute)
  1818   also have "... = -1 ^ n" by (rule cos_npi) 
  1819   finally show ?thesis .
  1820 qed
  1821 
  1822 lemma sin_npi [simp]: "sin (real (n::nat) * pi) = 0"
  1823 apply (induct "n")
  1824 apply (auto simp add: real_of_nat_Suc left_distrib)
  1825 done
  1826 
  1827 lemma sin_npi2 [simp]: "sin (pi * real (n::nat)) = 0"
  1828 by (simp add: mult_commute [of pi]) 
  1829 
  1830 lemma cos_two_pi [simp]: "cos (2 * pi) = 1"
  1831 by (simp add: cos_double)
  1832 
  1833 lemma sin_two_pi [simp]: "sin (2 * pi) = 0"
  1834 by simp
  1835 
  1836 lemma sin_gt_zero2: "[| 0 < x; x < pi/2 |] ==> 0 < sin x"
  1837 apply (rule sin_gt_zero, assumption)
  1838 apply (rule order_less_trans, assumption)
  1839 apply (rule pi_half_less_two)
  1840 done
  1841 
  1842 lemma sin_less_zero: 
  1843   assumes lb: "- pi/2 < x" and "x < 0" shows "sin x < 0"
  1844 proof -
  1845   have "0 < sin (- x)" using prems by (simp only: sin_gt_zero2) 
  1846   thus ?thesis by simp
  1847 qed
  1848 
  1849 lemma pi_less_4: "pi < 4"
  1850 by (cut_tac pi_half_less_two, auto)
  1851 
  1852 lemma cos_gt_zero: "[| 0 < x; x < pi/2 |] ==> 0 < cos x"
  1853 apply (cut_tac pi_less_4)
  1854 apply (cut_tac f = cos and a = 0 and b = x and y = 0 in IVT2_objl, safe, simp_all)
  1855 apply (cut_tac cos_is_zero, safe)
  1856 apply (rename_tac y z)
  1857 apply (drule_tac x = y in spec)
  1858 apply (drule_tac x = "pi/2" in spec, simp) 
  1859 done
  1860 
  1861 lemma cos_gt_zero_pi: "[| -(pi/2) < x; x < pi/2 |] ==> 0 < cos x"
  1862 apply (rule_tac x = x and y = 0 in linorder_cases)
  1863 apply (rule cos_minus [THEN subst])
  1864 apply (rule cos_gt_zero)
  1865 apply (auto intro: cos_gt_zero)
  1866 done
  1867  
  1868 lemma cos_ge_zero: "[| -(pi/2) \<le> x; x \<le> pi/2 |] ==> 0 \<le> cos x"
  1869 apply (auto simp add: order_le_less cos_gt_zero_pi)
  1870 apply (subgoal_tac "x = pi/2", auto) 
  1871 done
  1872 
  1873 lemma sin_gt_zero_pi: "[| 0 < x; x < pi  |] ==> 0 < sin x"
  1874 apply (subst sin_cos_eq)
  1875 apply (rotate_tac 1)
  1876 apply (drule real_sum_of_halves [THEN ssubst])
  1877 apply (auto intro!: cos_gt_zero_pi simp del: sin_cos_eq [symmetric])
  1878 done
  1879 
  1880 
  1881 lemma pi_ge_two: "2 \<le> pi"
  1882 proof (rule ccontr)
  1883   assume "\<not> 2 \<le> pi" hence "pi < 2" by auto
  1884   have "\<exists>y > pi. y < 2 \<and> y < 2 * pi"
  1885   proof (cases "2 < 2 * pi")
  1886     case True with dense[OF `pi < 2`] show ?thesis by auto
  1887   next
  1888     case False have "pi < 2 * pi" by auto
  1889     from dense[OF this] and False show ?thesis by auto
  1890   qed
  1891   then obtain y where "pi < y" and "y < 2" and "y < 2 * pi" by blast
  1892   hence "0 < sin y" using sin_gt_zero by auto
  1893   moreover 
  1894   have "sin y < 0" using sin_gt_zero_pi[of "y - pi"] `pi < y` and `y < 2 * pi` sin_periodic_pi[of "y - pi"] by auto
  1895   ultimately show False by auto
  1896 qed
  1897 
  1898 lemma sin_ge_zero: "[| 0 \<le> x; x \<le> pi |] ==> 0 \<le> sin x"
  1899 by (auto simp add: order_le_less sin_gt_zero_pi)
  1900 
  1901 lemma cos_total: "[| -1 \<le> y; y \<le> 1 |] ==> EX! x. 0 \<le> x & x \<le> pi & (cos x = y)"
  1902 apply (subgoal_tac "\<exists>x. 0 \<le> x & x \<le> pi & cos x = y")
  1903 apply (rule_tac [2] IVT2)
  1904 apply (auto intro: order_less_imp_le DERIV_isCont DERIV_cos)
  1905 apply (cut_tac x = xa and y = y in linorder_less_linear)
  1906 apply (rule ccontr, auto)
  1907 apply (drule_tac f = cos in Rolle)
  1908 apply (drule_tac [5] f = cos in Rolle)
  1909 apply (auto intro: order_less_imp_le DERIV_isCont DERIV_cos
  1910             dest!: DERIV_cos [THEN DERIV_unique] 
  1911             simp add: differentiable_def)
  1912 apply (auto dest: sin_gt_zero_pi [OF order_le_less_trans order_less_le_trans])
  1913 done
  1914 
  1915 lemma sin_total:
  1916      "[| -1 \<le> y; y \<le> 1 |] ==> EX! x. -(pi/2) \<le> x & x \<le> pi/2 & (sin x = y)"
  1917 apply (rule ccontr)
  1918 apply (subgoal_tac "\<forall>x. (- (pi/2) \<le> x & x \<le> pi/2 & (sin x = y)) = (0 \<le> (x + pi/2) & (x + pi/2) \<le> pi & (cos (x + pi/2) = -y))")
  1919 apply (erule contrapos_np)
  1920 apply (simp del: minus_sin_cos_eq [symmetric])
  1921 apply (cut_tac y="-y" in cos_total, simp) apply simp 
  1922 apply (erule ex1E)
  1923 apply (rule_tac a = "x - (pi/2)" in ex1I)
  1924 apply (simp (no_asm) add: add_assoc)
  1925 apply (rotate_tac 3)
  1926 apply (drule_tac x = "xa + pi/2" in spec, safe, simp_all) 
  1927 done
  1928 
  1929 lemma reals_Archimedean4:
  1930      "[| 0 < y; 0 \<le> x |] ==> \<exists>n. real n * y \<le> x & x < real (Suc n) * y"
  1931 apply (auto dest!: reals_Archimedean3)
  1932 apply (drule_tac x = x in spec, clarify) 
  1933 apply (subgoal_tac "x < real(LEAST m::nat. x < real m * y) * y")
  1934  prefer 2 apply (erule LeastI) 
  1935 apply (case_tac "LEAST m::nat. x < real m * y", simp) 
  1936 apply (subgoal_tac "~ x < real nat * y")
  1937  prefer 2 apply (rule not_less_Least, simp, force)  
  1938 done
  1939 
  1940 (* Pre Isabelle99-2 proof was simpler- numerals arithmetic 
  1941    now causes some unwanted re-arrangements of literals!   *)
  1942 lemma cos_zero_lemma:
  1943      "[| 0 \<le> x; cos x = 0 |] ==>  
  1944       \<exists>n::nat. ~even n & x = real n * (pi/2)"
  1945 apply (drule pi_gt_zero [THEN reals_Archimedean4], safe)
  1946 apply (subgoal_tac "0 \<le> x - real n * pi & 
  1947                     (x - real n * pi) \<le> pi & (cos (x - real n * pi) = 0) ")
  1948 apply (auto simp add: algebra_simps real_of_nat_Suc)
  1949  prefer 2 apply (simp add: cos_diff)
  1950 apply (simp add: cos_diff)
  1951 apply (subgoal_tac "EX! x. 0 \<le> x & x \<le> pi & cos x = 0")
  1952 apply (rule_tac [2] cos_total, safe)
  1953 apply (drule_tac x = "x - real n * pi" in spec)
  1954 apply (drule_tac x = "pi/2" in spec)
  1955 apply (simp add: cos_diff)
  1956 apply (rule_tac x = "Suc (2 * n)" in exI)
  1957 apply (simp add: real_of_nat_Suc algebra_simps, auto)
  1958 done
  1959 
  1960 lemma sin_zero_lemma:
  1961      "[| 0 \<le> x; sin x = 0 |] ==>  
  1962       \<exists>n::nat. even n & x = real n * (pi/2)"
  1963 apply (subgoal_tac "\<exists>n::nat. ~ even n & x + pi/2 = real n * (pi/2) ")
  1964  apply (clarify, rule_tac x = "n - 1" in exI)
  1965  apply (force simp add: odd_Suc_mult_two_ex real_of_nat_Suc left_distrib)
  1966 apply (rule cos_zero_lemma)
  1967 apply (simp_all add: add_increasing)  
  1968 done
  1969 
  1970 
  1971 lemma cos_zero_iff:
  1972      "(cos x = 0) =  
  1973       ((\<exists>n::nat. ~even n & (x = real n * (pi/2))) |    
  1974        (\<exists>n::nat. ~even n & (x = -(real n * (pi/2)))))"
  1975 apply (rule iffI)
  1976 apply (cut_tac linorder_linear [of 0 x], safe)
  1977 apply (drule cos_zero_lemma, assumption+)
  1978 apply (cut_tac x="-x" in cos_zero_lemma, simp, simp) 
  1979 apply (force simp add: minus_equation_iff [of x]) 
  1980 apply (auto simp only: odd_Suc_mult_two_ex real_of_nat_Suc left_distrib) 
  1981 apply (auto simp add: cos_add)
  1982 done
  1983 
  1984 (* ditto: but to a lesser extent *)
  1985 lemma sin_zero_iff:
  1986      "(sin x = 0) =  
  1987       ((\<exists>n::nat. even n & (x = real n * (pi/2))) |    
  1988        (\<exists>n::nat. even n & (x = -(real n * (pi/2)))))"
  1989 apply (rule iffI)
  1990 apply (cut_tac linorder_linear [of 0 x], safe)
  1991 apply (drule sin_zero_lemma, assumption+)
  1992 apply (cut_tac x="-x" in sin_zero_lemma, simp, simp, safe)
  1993 apply (force simp add: minus_equation_iff [of x]) 
  1994 apply (auto simp add: even_mult_two_ex)
  1995 done
  1996 
  1997 lemma cos_monotone_0_pi: assumes "0 \<le> y" and "y < x" and "x \<le> pi"
  1998   shows "cos x < cos y"
  1999 proof -
  2000   have "- (x - y) < 0" by (auto!)
  2001 
  2002   from MVT2[OF `y < x` DERIV_cos[THEN impI, THEN allI]]
  2003   obtain z where "y < z" and "z < x" and cos_diff: "cos x - cos y = (x - y) * - sin z" by auto
  2004   hence "0 < z" and "z < pi" by (auto!)
  2005   hence "0 < sin z" using sin_gt_zero_pi by auto
  2006   hence "cos x - cos y < 0" unfolding cos_diff minus_mult_commute[symmetric] using `- (x - y) < 0` by (rule mult_pos_neg2)
  2007   thus ?thesis by auto
  2008 qed
  2009 
  2010 lemma cos_monotone_0_pi': assumes "0 \<le> y" and "y \<le> x" and "x \<le> pi" shows "cos x \<le> cos y"
  2011 proof (cases "y < x")
  2012   case True show ?thesis using cos_monotone_0_pi[OF `0 \<le> y` True `x \<le> pi`] by auto
  2013 next
  2014   case False hence "y = x" using `y \<le> x` by auto
  2015   thus ?thesis by auto
  2016 qed
  2017 
  2018 lemma cos_monotone_minus_pi_0: assumes "-pi \<le> y" and "y < x" and "x \<le> 0"
  2019   shows "cos y < cos x"
  2020 proof -
  2021   have "0 \<le> -x" and "-x < -y" and "-y \<le> pi" by (auto!)
  2022   from cos_monotone_0_pi[OF this]
  2023   show ?thesis unfolding cos_minus .
  2024 qed
  2025 
  2026 lemma cos_monotone_minus_pi_0': assumes "-pi \<le> y" and "y \<le> x" and "x \<le> 0" shows "cos y \<le> cos x"
  2027 proof (cases "y < x")
  2028   case True show ?thesis using cos_monotone_minus_pi_0[OF `-pi \<le> y` True `x \<le> 0`] by auto
  2029 next
  2030   case False hence "y = x" using `y \<le> x` by auto
  2031   thus ?thesis by auto
  2032 qed
  2033 
  2034 lemma sin_monotone_2pi': assumes "- (pi / 2) \<le> y" and "y \<le> x" and "x \<le> pi / 2" shows "sin y \<le> sin x"
  2035 proof -
  2036   have "0 \<le> y + pi / 2" and "y + pi / 2 \<le> x + pi / 2" and "x + pi /2 \<le> pi" using pi_ge_two by (auto!)
  2037   from cos_monotone_0_pi'[OF this] show ?thesis unfolding minus_sin_cos_eq[symmetric] by auto
  2038 qed
  2039 
  2040 subsection {* Tangent *}
  2041 
  2042 definition
  2043   tan :: "real => real" where
  2044   "tan x = (sin x)/(cos x)"
  2045 
  2046 lemma tan_zero [simp]: "tan 0 = 0"
  2047 by (simp add: tan_def)
  2048 
  2049 lemma tan_pi [simp]: "tan pi = 0"
  2050 by (simp add: tan_def)
  2051 
  2052 lemma tan_npi [simp]: "tan (real (n::nat) * pi) = 0"
  2053 by (simp add: tan_def)
  2054 
  2055 lemma tan_minus [simp]: "tan (-x) = - tan x"
  2056 by (simp add: tan_def minus_mult_left)
  2057 
  2058 lemma tan_periodic [simp]: "tan (x + 2*pi) = tan x"
  2059 by (simp add: tan_def)
  2060 
  2061 lemma lemma_tan_add1: 
  2062       "[| cos x \<noteq> 0; cos y \<noteq> 0 |]  
  2063         ==> 1 - tan(x)*tan(y) = cos (x + y)/(cos x * cos y)"
  2064 apply (simp add: tan_def divide_inverse)
  2065 apply (auto simp del: inverse_mult_distrib 
  2066             simp add: inverse_mult_distrib [symmetric] mult_ac)
  2067 apply (rule_tac c1 = "cos x * cos y" in real_mult_right_cancel [THEN subst])
  2068 apply (auto simp del: inverse_mult_distrib 
  2069             simp add: mult_assoc left_diff_distrib cos_add)
  2070 done
  2071 
  2072 lemma add_tan_eq: 
  2073       "[| cos x \<noteq> 0; cos y \<noteq> 0 |]  
  2074        ==> tan x + tan y = sin(x + y)/(cos x * cos y)"
  2075 apply (simp add: tan_def)
  2076 apply (rule_tac c1 = "cos x * cos y" in real_mult_right_cancel [THEN subst])
  2077 apply (auto simp add: mult_assoc left_distrib)
  2078 apply (simp add: sin_add)
  2079 done
  2080 
  2081 lemma tan_add:
  2082      "[| cos x \<noteq> 0; cos y \<noteq> 0; cos (x + y) \<noteq> 0 |]  
  2083       ==> tan(x + y) = (tan(x) + tan(y))/(1 - tan(x) * tan(y))"
  2084 apply (simp (no_asm_simp) add: add_tan_eq lemma_tan_add1)
  2085 apply (simp add: tan_def)
  2086 done
  2087 
  2088 lemma tan_double:
  2089      "[| cos x \<noteq> 0; cos (2 * x) \<noteq> 0 |]  
  2090       ==> tan (2 * x) = (2 * tan x)/(1 - (tan(x) ^ 2))"
  2091 apply (insert tan_add [of x x]) 
  2092 apply (simp add: mult_2 [symmetric])  
  2093 apply (auto simp add: numeral_2_eq_2)
  2094 done
  2095 
  2096 lemma tan_gt_zero: "[| 0 < x; x < pi/2 |] ==> 0 < tan x"
  2097 by (simp add: tan_def zero_less_divide_iff sin_gt_zero2 cos_gt_zero_pi) 
  2098 
  2099 lemma tan_less_zero: 
  2100   assumes lb: "- pi/2 < x" and "x < 0" shows "tan x < 0"
  2101 proof -
  2102   have "0 < tan (- x)" using prems by (simp only: tan_gt_zero) 
  2103   thus ?thesis by simp
  2104 qed
  2105 
  2106 lemma tan_half: fixes x :: real assumes "- (pi / 2) < x" and "x < pi / 2"
  2107   shows "tan x = sin (2 * x) / (cos (2 * x) + 1)"
  2108 proof -
  2109   from cos_gt_zero_pi[OF `- (pi / 2) < x` `x < pi / 2`]
  2110   have "cos x \<noteq> 0" by auto
  2111 
  2112   have minus_cos_2x: "\<And>X. X - cos (2*x) = X - (cos x) ^ 2 + (sin x) ^ 2" unfolding cos_double by algebra
  2113 
  2114   have "tan x = (tan x + tan x) / 2" by auto
  2115   also have "\<dots> = sin (x + x) / (cos x * cos x) / 2" unfolding add_tan_eq[OF `cos x \<noteq> 0` `cos x \<noteq> 0`] ..
  2116   also have "\<dots> = sin (2 * x) / ((cos x) ^ 2 + (cos x) ^ 2 + cos (2*x) - cos (2*x))" unfolding divide_divide_eq_left numeral_2_eq_2 by auto
  2117   also have "\<dots> = sin (2 * x) / ((cos x) ^ 2 + cos (2*x) + (sin x)^2)" unfolding minus_cos_2x by auto
  2118   also have "\<dots> = sin (2 * x) / (cos (2*x) + 1)" by auto
  2119   finally show ?thesis .
  2120 qed
  2121 
  2122 lemma lemma_DERIV_tan:
  2123      "cos x \<noteq> 0 ==> DERIV (%x. sin(x)/cos(x)) x :> inverse((cos x)\<twosuperior>)"
  2124 apply (rule lemma_DERIV_subst)
  2125 apply (best intro!: DERIV_intros intro: DERIV_chain2) 
  2126 apply (auto simp add: divide_inverse numeral_2_eq_2)
  2127 done
  2128 
  2129 lemma DERIV_tan [simp]: "cos x \<noteq> 0 ==> DERIV tan x :> inverse((cos x)\<twosuperior>)"
  2130 by (auto dest: lemma_DERIV_tan simp add: tan_def [symmetric])
  2131 
  2132 lemma isCont_tan [simp]: "cos x \<noteq> 0 ==> isCont tan x"
  2133 by (rule DERIV_tan [THEN DERIV_isCont])
  2134 
  2135 lemma LIM_cos_div_sin [simp]: "(%x. cos(x)/sin(x)) -- pi/2 --> 0"
  2136 apply (subgoal_tac "(\<lambda>x. cos x * inverse (sin x)) -- pi * inverse 2 --> 0*1")
  2137 apply (simp add: divide_inverse [symmetric])
  2138 apply (rule LIM_mult)
  2139 apply (rule_tac [2] inverse_1 [THEN subst])
  2140 apply (rule_tac [2] LIM_inverse)
  2141 apply (simp_all add: divide_inverse [symmetric]) 
  2142 apply (simp_all only: isCont_def [symmetric] cos_pi_half [symmetric] sin_pi_half [symmetric]) 
  2143 apply (blast intro!: DERIV_isCont DERIV_sin DERIV_cos)+
  2144 done
  2145 
  2146 lemma lemma_tan_total: "0 < y ==> \<exists>x. 0 < x & x < pi/2 & y < tan x"
  2147 apply (cut_tac LIM_cos_div_sin)
  2148 apply (simp only: LIM_eq)
  2149 apply (drule_tac x = "inverse y" in spec, safe, force)
  2150 apply (drule_tac ?d1.0 = s in pi_half_gt_zero [THEN [2] real_lbound_gt_zero], safe)
  2151 apply (rule_tac x = "(pi/2) - e" in exI)
  2152 apply (simp (no_asm_simp))
  2153 apply (drule_tac x = "(pi/2) - e" in spec)
  2154 apply (auto simp add: tan_def)
  2155 apply (rule inverse_less_iff_less [THEN iffD1])
  2156 apply (auto simp add: divide_inverse)
  2157 apply (rule real_mult_order) 
  2158 apply (subgoal_tac [3] "0 < sin e & 0 < cos e")
  2159 apply (auto intro: cos_gt_zero sin_gt_zero2 simp add: mult_commute) 
  2160 done
  2161 
  2162 lemma tan_total_pos: "0 \<le> y ==> \<exists>x. 0 \<le> x & x < pi/2 & tan x = y"
  2163 apply (frule order_le_imp_less_or_eq, safe)
  2164  prefer 2 apply force
  2165 apply (drule lemma_tan_total, safe)
  2166 apply (cut_tac f = tan and a = 0 and b = x and y = y in IVT_objl)
  2167 apply (auto intro!: DERIV_tan [THEN DERIV_isCont])
  2168 apply (drule_tac y = xa in order_le_imp_less_or_eq)
  2169 apply (auto dest: cos_gt_zero)
  2170 done
  2171 
  2172 lemma lemma_tan_total1: "\<exists>x. -(pi/2) < x & x < (pi/2) & tan x = y"
  2173 apply (cut_tac linorder_linear [of 0 y], safe)
  2174 apply (drule tan_total_pos)
  2175 apply (cut_tac [2] y="-y" in tan_total_pos, safe)
  2176 apply (rule_tac [3] x = "-x" in exI)
  2177 apply (auto intro!: exI)
  2178 done
  2179 
  2180 lemma tan_total: "EX! x. -(pi/2) < x & x < (pi/2) & tan x = y"
  2181 apply (cut_tac y = y in lemma_tan_total1, auto)
  2182 apply (cut_tac x = xa and y = y in linorder_less_linear, auto)
  2183 apply (subgoal_tac [2] "\<exists>z. y < z & z < xa & DERIV tan z :> 0")
  2184 apply (subgoal_tac "\<exists>z. xa < z & z < y & DERIV tan z :> 0")
  2185 apply (rule_tac [4] Rolle)
  2186 apply (rule_tac [2] Rolle)
  2187 apply (auto intro!: DERIV_tan DERIV_isCont exI 
  2188             simp add: differentiable_def)
  2189 txt{*Now, simulate TRYALL*}
  2190 apply (rule_tac [!] DERIV_tan asm_rl)
  2191 apply (auto dest!: DERIV_unique [OF _ DERIV_tan]
  2192 	    simp add: cos_gt_zero_pi [THEN less_imp_neq, THEN not_sym]) 
  2193 done
  2194 
  2195 lemma tan_monotone: assumes "- (pi / 2) < y" and "y < x" and "x < pi / 2"
  2196   shows "tan y < tan x"
  2197 proof -
  2198   have "\<forall> x'. y \<le> x' \<and> x' \<le> x \<longrightarrow> DERIV tan x' :> inverse (cos x'^2)"
  2199   proof (rule allI, rule impI)
  2200     fix x' :: real assume "y \<le> x' \<and> x' \<le> x"
  2201     hence "-(pi/2) < x'" and "x' < pi/2" by (auto!)
  2202     from cos_gt_zero_pi[OF this]
  2203     have "cos x' \<noteq> 0" by auto
  2204     thus "DERIV tan x' :> inverse (cos x'^2)" by (rule DERIV_tan)
  2205   qed
  2206   from MVT2[OF `y < x` this] 
  2207   obtain z where "y < z" and "z < x" and tan_diff: "tan x - tan y = (x - y) * inverse ((cos z)\<twosuperior>)" by auto
  2208   hence "- (pi / 2) < z" and "z < pi / 2" by (auto!)
  2209   hence "0 < cos z" using cos_gt_zero_pi by auto
  2210   hence inv_pos: "0 < inverse ((cos z)\<twosuperior>)" by auto
  2211   have "0 < x - y" using `y < x` by auto
  2212   from real_mult_order[OF this inv_pos]
  2213   have "0 < tan x - tan y" unfolding tan_diff by auto
  2214   thus ?thesis by auto
  2215 qed
  2216 
  2217 lemma tan_monotone': assumes "- (pi / 2) < y" and "y < pi / 2" and "- (pi / 2) < x" and "x < pi / 2"
  2218   shows "(y < x) = (tan y < tan x)"
  2219 proof
  2220   assume "y < x" thus "tan y < tan x" using tan_monotone and `- (pi / 2) < y` and `x < pi / 2` by auto
  2221 next
  2222   assume "tan y < tan x"
  2223   show "y < x"
  2224   proof (rule ccontr)
  2225     assume "\<not> y < x" hence "x \<le> y" by auto
  2226     hence "tan x \<le> tan y" 
  2227     proof (cases "x = y")
  2228       case True thus ?thesis by auto
  2229     next
  2230       case False hence "x < y" using `x \<le> y` by auto
  2231       from tan_monotone[OF `- (pi/2) < x` this `y < pi / 2`] show ?thesis by auto
  2232     qed
  2233     thus False using `tan y < tan x` by auto
  2234   qed
  2235 qed
  2236 
  2237 lemma tan_inverse: "1 / (tan y) = tan (pi / 2 - y)" unfolding tan_def sin_cos_eq[of y] cos_sin_eq[of y] by auto
  2238 
  2239 lemma tan_periodic_pi[simp]: "tan (x + pi) = tan x" 
  2240   by (simp add: tan_def)
  2241 
  2242 lemma tan_periodic_nat[simp]: fixes n :: nat shows "tan (x + real n * pi) = tan x" 
  2243 proof (induct n arbitrary: x)
  2244   case (Suc n)
  2245   have split_pi_off: "x + real (Suc n) * pi = (x + real n * pi) + pi" unfolding Suc_eq_plus1 real_of_nat_add real_of_one real_add_mult_distrib by auto
  2246   show ?case unfolding split_pi_off using Suc by auto
  2247 qed auto
  2248 
  2249 lemma tan_periodic_int[simp]: fixes i :: int shows "tan (x + real i * pi) = tan x"
  2250 proof (cases "0 \<le> i")
  2251   case True hence i_nat: "real i = real (nat i)" by auto
  2252   show ?thesis unfolding i_nat by auto
  2253 next
  2254   case False hence i_nat: "real i = - real (nat (-i))" by auto
  2255   have "tan x = tan (x + real i * pi - real i * pi)" by auto
  2256   also have "\<dots> = tan (x + real i * pi)" unfolding i_nat mult_minus_left diff_minus_eq_add by (rule tan_periodic_nat)
  2257   finally show ?thesis by auto
  2258 qed
  2259 
  2260 lemma tan_periodic_n[simp]: "tan (x + number_of n * pi) = tan x"
  2261   using tan_periodic_int[of _ "number_of n" ] unfolding real_number_of .
  2262 
  2263 subsection {* Inverse Trigonometric Functions *}
  2264 
  2265 definition
  2266   arcsin :: "real => real" where
  2267   "arcsin y = (THE x. -(pi/2) \<le> x & x \<le> pi/2 & sin x = y)"
  2268 
  2269 definition
  2270   arccos :: "real => real" where
  2271   "arccos y = (THE x. 0 \<le> x & x \<le> pi & cos x = y)"
  2272 
  2273 definition     
  2274   arctan :: "real => real" where
  2275   "arctan y = (THE x. -(pi/2) < x & x < pi/2 & tan x = y)"
  2276 
  2277 lemma arcsin:
  2278      "[| -1 \<le> y; y \<le> 1 |]  
  2279       ==> -(pi/2) \<le> arcsin y &  
  2280            arcsin y \<le> pi/2 & sin(arcsin y) = y"
  2281 unfolding arcsin_def by (rule theI' [OF sin_total])
  2282 
  2283 lemma arcsin_pi:
  2284      "[| -1 \<le> y; y \<le> 1 |]  
  2285       ==> -(pi/2) \<le> arcsin y & arcsin y \<le> pi & sin(arcsin y) = y"
  2286 apply (drule (1) arcsin)
  2287 apply (force intro: order_trans)
  2288 done
  2289 
  2290 lemma sin_arcsin [simp]: "[| -1 \<le> y; y \<le> 1 |] ==> sin(arcsin y) = y"
  2291 by (blast dest: arcsin)
  2292       
  2293 lemma arcsin_bounded:
  2294      "[| -1 \<le> y; y \<le> 1 |] ==> -(pi/2) \<le> arcsin y & arcsin y \<le> pi/2"
  2295 by (blast dest: arcsin)
  2296 
  2297 lemma arcsin_lbound: "[| -1 \<le> y; y \<le> 1 |] ==> -(pi/2) \<le> arcsin y"
  2298 by (blast dest: arcsin)
  2299 
  2300 lemma arcsin_ubound: "[| -1 \<le> y; y \<le> 1 |] ==> arcsin y \<le> pi/2"
  2301 by (blast dest: arcsin)
  2302 
  2303 lemma arcsin_lt_bounded:
  2304      "[| -1 < y; y < 1 |] ==> -(pi/2) < arcsin y & arcsin y < pi/2"
  2305 apply (frule order_less_imp_le)
  2306 apply (frule_tac y = y in order_less_imp_le)
  2307 apply (frule arcsin_bounded)
  2308 apply (safe, simp)
  2309 apply (drule_tac y = "arcsin y" in order_le_imp_less_or_eq)
  2310 apply (drule_tac [2] y = "pi/2" in order_le_imp_less_or_eq, safe)
  2311 apply (drule_tac [!] f = sin in arg_cong, auto)
  2312 done
  2313 
  2314 lemma arcsin_sin: "[|-(pi/2) \<le> x; x \<le> pi/2 |] ==> arcsin(sin x) = x"
  2315 apply (unfold arcsin_def)
  2316 apply (rule the1_equality)
  2317 apply (rule sin_total, auto)
  2318 done
  2319 
  2320 lemma arccos:
  2321      "[| -1 \<le> y; y \<le> 1 |]  
  2322       ==> 0 \<le> arccos y & arccos y \<le> pi & cos(arccos y) = y"
  2323 unfolding arccos_def by (rule theI' [OF cos_total])
  2324 
  2325 lemma cos_arccos [simp]: "[| -1 \<le> y; y \<le> 1 |] ==> cos(arccos y) = y"
  2326 by (blast dest: arccos)
  2327       
  2328 lemma arccos_bounded: "[| -1 \<le> y; y \<le> 1 |] ==> 0 \<le> arccos y & arccos y \<le> pi"
  2329 by (blast dest: arccos)
  2330 
  2331 lemma arccos_lbound: "[| -1 \<le> y; y \<le> 1 |] ==> 0 \<le> arccos y"
  2332 by (blast dest: arccos)
  2333 
  2334 lemma arccos_ubound: "[| -1 \<le> y; y \<le> 1 |] ==> arccos y \<le> pi"
  2335 by (blast dest: arccos)
  2336 
  2337 lemma arccos_lt_bounded:
  2338      "[| -1 < y; y < 1 |]  
  2339       ==> 0 < arccos y & arccos y < pi"
  2340 apply (frule order_less_imp_le)
  2341 apply (frule_tac y = y in order_less_imp_le)
  2342 apply (frule arccos_bounded, auto)
  2343 apply (drule_tac y = "arccos y" in order_le_imp_less_or_eq)
  2344 apply (drule_tac [2] y = pi in order_le_imp_less_or_eq, auto)
  2345 apply (drule_tac [!] f = cos in arg_cong, auto)
  2346 done
  2347 
  2348 lemma arccos_cos: "[|0 \<le> x; x \<le> pi |] ==> arccos(cos x) = x"
  2349 apply (simp add: arccos_def)
  2350 apply (auto intro!: the1_equality cos_total)
  2351 done
  2352 
  2353 lemma arccos_cos2: "[|x \<le> 0; -pi \<le> x |] ==> arccos(cos x) = -x"
  2354 apply (simp add: arccos_def)
  2355 apply (auto intro!: the1_equality cos_total)
  2356 done
  2357 
  2358 lemma cos_arcsin: "\<lbrakk>-1 \<le> x; x \<le> 1\<rbrakk> \<Longrightarrow> cos (arcsin x) = sqrt (1 - x\<twosuperior>)"
  2359 apply (subgoal_tac "x\<twosuperior> \<le> 1")
  2360 apply (rule power2_eq_imp_eq)
  2361 apply (simp add: cos_squared_eq)
  2362 apply (rule cos_ge_zero)
  2363 apply (erule (1) arcsin_lbound)
  2364 apply (erule (1) arcsin_ubound)
  2365 apply simp
  2366 apply (subgoal_tac "\<bar>x\<bar>\<twosuperior> \<le> 1\<twosuperior>", simp)
  2367 apply (rule power_mono, simp, simp)
  2368 done
  2369 
  2370 lemma sin_arccos: "\<lbrakk>-1 \<le> x; x \<le> 1\<rbrakk> \<Longrightarrow> sin (arccos x) = sqrt (1 - x\<twosuperior>)"
  2371 apply (subgoal_tac "x\<twosuperior> \<le> 1")
  2372 apply (rule power2_eq_imp_eq)
  2373 apply (simp add: sin_squared_eq)
  2374 apply (rule sin_ge_zero)
  2375 apply (erule (1) arccos_lbound)
  2376 apply (erule (1) arccos_ubound)
  2377 apply simp
  2378 apply (subgoal_tac "\<bar>x\<bar>\<twosuperior> \<le> 1\<twosuperior>", simp)
  2379 apply (rule power_mono, simp, simp)
  2380 done
  2381 
  2382 lemma arctan [simp]:
  2383      "- (pi/2) < arctan y  & arctan y < pi/2 & tan (arctan y) = y"
  2384 unfolding arctan_def by (rule theI' [OF tan_total])
  2385 
  2386 lemma tan_arctan: "tan(arctan y) = y"
  2387 by auto
  2388 
  2389 lemma arctan_bounded: "- (pi/2) < arctan y  & arctan y < pi/2"
  2390 by (auto simp only: arctan)
  2391 
  2392 lemma arctan_lbound: "- (pi/2) < arctan y"
  2393 by auto
  2394 
  2395 lemma arctan_ubound: "arctan y < pi/2"
  2396 by (auto simp only: arctan)
  2397 
  2398 lemma arctan_tan: 
  2399       "[|-(pi/2) < x; x < pi/2 |] ==> arctan(tan x) = x"
  2400 apply (unfold arctan_def)
  2401 apply (rule the1_equality)
  2402 apply (rule tan_total, auto)
  2403 done
  2404 
  2405 lemma arctan_zero_zero [simp]: "arctan 0 = 0"
  2406 by (insert arctan_tan [of 0], simp)
  2407 
  2408 lemma cos_arctan_not_zero [simp]: "cos(arctan x) \<noteq> 0"
  2409 apply (auto simp add: cos_zero_iff)
  2410 apply (case_tac "n")
  2411 apply (case_tac [3] "n")
  2412 apply (cut_tac [2] y = x in arctan_ubound)
  2413 apply (cut_tac [4] y = x in arctan_lbound) 
  2414 apply (auto simp add: real_of_nat_Suc left_distrib mult_less_0_iff)
  2415 done
  2416 
  2417 lemma tan_sec: "cos x \<noteq> 0 ==> 1 + tan(x) ^ 2 = inverse(cos x) ^ 2"
  2418 apply (rule power_inverse [THEN subst])
  2419 apply (rule_tac c1 = "(cos x)\<twosuperior>" in real_mult_right_cancel [THEN iffD1])
  2420 apply (auto dest: field_power_not_zero
  2421         simp add: power_mult_distrib left_distrib power_divide tan_def 
  2422                   mult_assoc power_inverse [symmetric])
  2423 done
  2424 
  2425 lemma isCont_inverse_function2:
  2426   fixes f g :: "real \<Rightarrow> real" shows
  2427   "\<lbrakk>a < x; x < b;
  2428     \<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> g (f z) = z;
  2429     \<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> isCont f z\<rbrakk>
  2430    \<Longrightarrow> isCont g (f x)"
  2431 apply (rule isCont_inverse_function
  2432        [where f=f and d="min (x - a) (b - x)"])
  2433 apply (simp_all add: abs_le_iff)
  2434 done
  2435 
  2436 lemma isCont_arcsin: "\<lbrakk>-1 < x; x < 1\<rbrakk> \<Longrightarrow> isCont arcsin x"
  2437 apply (subgoal_tac "isCont arcsin (sin (arcsin x))", simp)
  2438 apply (rule isCont_inverse_function2 [where f=sin])
  2439 apply (erule (1) arcsin_lt_bounded [THEN conjunct1])
  2440 apply (erule (1) arcsin_lt_bounded [THEN conjunct2])
  2441 apply (fast intro: arcsin_sin, simp)
  2442 done
  2443 
  2444 lemma isCont_arccos: "\<lbrakk>-1 < x; x < 1\<rbrakk> \<Longrightarrow> isCont arccos x"
  2445 apply (subgoal_tac "isCont arccos (cos (arccos x))", simp)
  2446 apply (rule isCont_inverse_function2 [where f=cos])
  2447 apply (erule (1) arccos_lt_bounded [THEN conjunct1])
  2448 apply (erule (1) arccos_lt_bounded [THEN conjunct2])
  2449 apply (fast intro: arccos_cos, simp)
  2450 done
  2451 
  2452 lemma isCont_arctan: "isCont arctan x"
  2453 apply (rule arctan_lbound [of x, THEN dense, THEN exE], clarify)
  2454 apply (rule arctan_ubound [of x, THEN dense, THEN exE], clarify)
  2455 apply (subgoal_tac "isCont arctan (tan (arctan x))", simp)
  2456 apply (erule (1) isCont_inverse_function2 [where f=tan])
  2457 apply (clarify, rule arctan_tan)
  2458 apply (erule (1) order_less_le_trans)
  2459 apply (erule (1) order_le_less_trans)
  2460 apply (clarify, rule isCont_tan)
  2461 apply (rule less_imp_neq [symmetric])
  2462 apply (rule cos_gt_zero_pi)
  2463 apply (erule (1) order_less_le_trans)
  2464 apply (erule (1) order_le_less_trans)
  2465 done
  2466 
  2467 lemma DERIV_arcsin:
  2468   "\<lbrakk>-1 < x; x < 1\<rbrakk> \<Longrightarrow> DERIV arcsin x :> inverse (sqrt (1 - x\<twosuperior>))"
  2469 apply (rule DERIV_inverse_function [where f=sin and a="-1" and b="1"])
  2470 apply (rule lemma_DERIV_subst [OF DERIV_sin])
  2471 apply (simp add: cos_arcsin)
  2472 apply (subgoal_tac "\<bar>x\<bar>\<twosuperior> < 1\<twosuperior>", simp)
  2473 apply (rule power_strict_mono, simp, simp, simp)
  2474 apply assumption
  2475 apply assumption
  2476 apply simp
  2477 apply (erule (1) isCont_arcsin)
  2478 done
  2479 
  2480 lemma DERIV_arccos:
  2481   "\<lbrakk>-1 < x; x < 1\<rbrakk> \<Longrightarrow> DERIV arccos x :> inverse (- sqrt (1 - x\<twosuperior>))"
  2482 apply (rule DERIV_inverse_function [where f=cos and a="-1" and b="1"])
  2483 apply (rule lemma_DERIV_subst [OF DERIV_cos])
  2484 apply (simp add: sin_arccos)
  2485 apply (subgoal_tac "\<bar>x\<bar>\<twosuperior> < 1\<twosuperior>", simp)
  2486 apply (rule power_strict_mono, simp, simp, simp)
  2487 apply assumption
  2488 apply assumption
  2489 apply simp
  2490 apply (erule (1) isCont_arccos)
  2491 done
  2492 
  2493 lemma DERIV_arctan: "DERIV arctan x :> inverse (1 + x\<twosuperior>)"
  2494 apply (rule DERIV_inverse_function [where f=tan and a="x - 1" and b="x + 1"])
  2495 apply (rule lemma_DERIV_subst [OF DERIV_tan])
  2496 apply (rule cos_arctan_not_zero)
  2497 apply (simp add: power_inverse tan_sec [symmetric])
  2498 apply (subgoal_tac "0 < 1 + x\<twosuperior>", simp)
  2499 apply (simp add: add_pos_nonneg)
  2500 apply (simp, simp, simp, rule isCont_arctan)
  2501 done
  2502 
  2503 subsection {* More Theorems about Sin and Cos *}
  2504 
  2505 lemma cos_45: "cos (pi / 4) = sqrt 2 / 2"
  2506 proof -
  2507   let ?c = "cos (pi / 4)" and ?s = "sin (pi / 4)"
  2508   have nonneg: "0 \<le> ?c"
  2509     by (rule cos_ge_zero, rule order_trans [where y=0], simp_all)
  2510   have "0 = cos (pi / 4 + pi / 4)"
  2511     by simp
  2512   also have "cos (pi / 4 + pi / 4) = ?c\<twosuperior> - ?s\<twosuperior>"
  2513     by (simp only: cos_add power2_eq_square)
  2514   also have "\<dots> = 2 * ?c\<twosuperior> - 1"
  2515     by (simp add: sin_squared_eq)
  2516   finally have "?c\<twosuperior> = (sqrt 2 / 2)\<twosuperior>"
  2517     by (simp add: power_divide)
  2518   thus ?thesis
  2519     using nonneg by (rule power2_eq_imp_eq) simp
  2520 qed
  2521 
  2522 lemma cos_30: "cos (pi / 6) = sqrt 3 / 2"
  2523 proof -
  2524   let ?c = "cos (pi / 6)" and ?s = "sin (pi / 6)"
  2525   have pos_c: "0 < ?c"
  2526     by (rule cos_gt_zero, simp, simp)
  2527   have "0 = cos (pi / 6 + pi / 6 + pi / 6)"
  2528     by simp
  2529   also have "\<dots> = (?c * ?c - ?s * ?s) * ?c - (?s * ?c + ?c * ?s) * ?s"
  2530     by (simp only: cos_add sin_add)
  2531   also have "\<dots> = ?c * (?c\<twosuperior> - 3 * ?s\<twosuperior>)"
  2532     by (simp add: algebra_simps power2_eq_square)
  2533   finally have "?c\<twosuperior> = (sqrt 3 / 2)\<twosuperior>"
  2534     using pos_c by (simp add: sin_squared_eq power_divide)
  2535   thus ?thesis
  2536     using pos_c [THEN order_less_imp_le]
  2537     by (rule power2_eq_imp_eq) simp
  2538 qed
  2539 
  2540 lemma sin_45: "sin (pi / 4) = sqrt 2 / 2"
  2541 proof -
  2542   have "sin (pi / 4) = cos (pi / 2 - pi / 4)" by (rule sin_cos_eq)
  2543   also have "pi / 2 - pi / 4 = pi / 4" by simp
  2544   also have "cos (pi / 4) = sqrt 2 / 2" by (rule cos_45)
  2545   finally show ?thesis .
  2546 qed
  2547 
  2548 lemma sin_60: "sin (pi / 3) = sqrt 3 / 2"
  2549 proof -
  2550   have "sin (pi / 3) = cos (pi / 2 - pi / 3)" by (rule sin_cos_eq)
  2551   also have "pi / 2 - pi / 3 = pi / 6" by simp
  2552   also have "cos (pi / 6) = sqrt 3 / 2" by (rule cos_30)
  2553   finally show ?thesis .
  2554 qed
  2555 
  2556 lemma cos_60: "cos (pi / 3) = 1 / 2"
  2557 apply (rule power2_eq_imp_eq)
  2558 apply (simp add: cos_squared_eq sin_60 power_divide)
  2559 apply (rule cos_ge_zero, rule order_trans [where y=0], simp_all)
  2560 done
  2561 
  2562 lemma sin_30: "sin (pi / 6) = 1 / 2"
  2563 proof -
  2564   have "sin (pi / 6) = cos (pi / 2 - pi / 6)" by (rule sin_cos_eq)
  2565   also have "pi / 2 - pi / 6 = pi / 3" by simp
  2566   also have "cos (pi / 3) = 1 / 2" by (rule cos_60)
  2567   finally show ?thesis .
  2568 qed
  2569 
  2570 lemma tan_30: "tan (pi / 6) = 1 / sqrt 3"
  2571 unfolding tan_def by (simp add: sin_30 cos_30)
  2572 
  2573 lemma tan_45: "tan (pi / 4) = 1"
  2574 unfolding tan_def by (simp add: sin_45 cos_45)
  2575 
  2576 lemma tan_60: "tan (pi / 3) = sqrt 3"
  2577 unfolding tan_def by (simp add: sin_60 cos_60)
  2578 
  2579 text{*NEEDED??*}
  2580 lemma [simp]:
  2581      "sin (x + 1 / 2 * real (Suc m) * pi) =  
  2582       cos (x + 1 / 2 * real  (m) * pi)"
  2583 by (simp only: cos_add sin_add real_of_nat_Suc left_distrib right_distrib, auto)
  2584 
  2585 text{*NEEDED??*}
  2586 lemma [simp]:
  2587      "sin (x + real (Suc m) * pi / 2) =  
  2588       cos (x + real (m) * pi / 2)"
  2589 by (simp only: cos_add sin_add real_of_nat_Suc add_divide_distrib left_distrib, auto)
  2590 
  2591 lemma DERIV_sin_add [simp]: "DERIV (%x. sin (x + k)) xa :> cos (xa + k)"
  2592 apply (rule lemma_DERIV_subst)
  2593 apply (rule_tac f = sin and g = "%x. x + k" in DERIV_chain2)
  2594 apply (best intro!: DERIV_intros intro: DERIV_chain2)+
  2595 apply (simp (no_asm))
  2596 done
  2597 
  2598 lemma sin_cos_npi [simp]: "sin (real (Suc (2 * n)) * pi / 2) = (-1) ^ n"
  2599 proof -
  2600   have "sin ((real n + 1/2) * pi) = cos (real n * pi)"
  2601     by (auto simp add: algebra_simps sin_add)
  2602   thus ?thesis
  2603     by (simp add: real_of_nat_Suc left_distrib add_divide_distrib 
  2604                   mult_commute [of pi])
  2605 qed
  2606 
  2607 lemma cos_2npi [simp]: "cos (2 * real (n::nat) * pi) = 1"
  2608 by (simp add: cos_double mult_assoc power_add [symmetric] numeral_2_eq_2)
  2609 
  2610 lemma cos_3over2_pi [simp]: "cos (3 / 2 * pi) = 0"
  2611 apply (subgoal_tac "cos (pi + pi/2) = 0", simp)
  2612 apply (subst cos_add, simp)
  2613 done
  2614 
  2615 lemma sin_2npi [simp]: "sin (2 * real (n::nat) * pi) = 0"
  2616 by (auto simp add: mult_assoc)
  2617 
  2618 lemma sin_3over2_pi [simp]: "sin (3 / 2 * pi) = - 1"
  2619 apply (subgoal_tac "sin (pi + pi/2) = - 1", simp)
  2620 apply (subst sin_add, simp)
  2621 done
  2622 
  2623 (*NEEDED??*)
  2624 lemma [simp]:
  2625      "cos(x + 1 / 2 * real(Suc m) * pi) = -sin (x + 1 / 2 * real m * pi)"
  2626 apply (simp only: cos_add sin_add real_of_nat_Suc right_distrib left_distrib minus_mult_right, auto)
  2627 done
  2628 
  2629 (*NEEDED??*)
  2630 lemma [simp]: "cos (x + real(Suc m) * pi / 2) = -sin (x + real m * pi / 2)"
  2631 by (simp only: cos_add sin_add real_of_nat_Suc left_distrib add_divide_distrib, auto)
  2632 
  2633 lemma cos_pi_eq_zero [simp]: "cos (pi * real (Suc (2 * m)) / 2) = 0"
  2634 by (simp only: cos_add sin_add real_of_nat_Suc left_distrib right_distrib add_divide_distrib, auto)
  2635 
  2636 lemma DERIV_cos_add [simp]: "DERIV (%x. cos (x + k)) xa :> - sin (xa + k)"
  2637 apply (rule lemma_DERIV_subst)
  2638 apply (rule_tac f = cos and g = "%x. x + k" in DERIV_chain2)
  2639 apply (best intro!: DERIV_intros intro: DERIV_chain2)+
  2640 apply (simp (no_asm))
  2641 done
  2642 
  2643 lemma sin_zero_abs_cos_one: "sin x = 0 ==> \<bar>cos x\<bar> = 1"
  2644 by (auto simp add: sin_zero_iff even_mult_two_ex)
  2645 
  2646 lemma cos_one_sin_zero: "cos x = 1 ==> sin x = 0"
  2647 by (cut_tac x = x in sin_cos_squared_add3, auto)
  2648 
  2649 subsection {* Machins formula *}
  2650 
  2651 lemma tan_total_pi4: assumes "\<bar>x\<bar> < 1"
  2652   shows "\<exists> z. - (pi / 4) < z \<and> z < pi / 4 \<and> tan z = x"
  2653 proof -
  2654   obtain z where "- (pi / 2) < z" and "z < pi / 2" and "tan z = x" using tan_total by blast
  2655   have "tan (pi / 4) = 1" and "tan (- (pi / 4)) = - 1" using tan_45 tan_minus by auto
  2656   have "z \<noteq> pi / 4" 
  2657   proof (rule ccontr)
  2658     assume "\<not> (z \<noteq> pi / 4)" hence "z = pi / 4" by auto
  2659     have "tan z = 1" unfolding `z = pi / 4` `tan (pi / 4) = 1` ..
  2660     thus False unfolding `tan z = x` using `\<bar>x\<bar> < 1` by auto
  2661   qed
  2662   have "z \<noteq> - (pi / 4)"
  2663   proof (rule ccontr)
  2664     assume "\<not> (z \<noteq> - (pi / 4))" hence "z = - (pi / 4)" by auto
  2665     have "tan z = - 1" unfolding `z = - (pi / 4)` `tan (- (pi / 4)) = - 1` ..
  2666     thus False unfolding `tan z = x` using `\<bar>x\<bar> < 1` by auto
  2667   qed
  2668 
  2669   have "z < pi / 4"
  2670   proof (rule ccontr)
  2671     assume "\<not> (z < pi / 4)" hence "pi / 4 < z" using `z \<noteq> pi / 4` by auto
  2672     have "- (pi / 2) < pi / 4" using m2pi_less_pi by auto
  2673     from tan_monotone[OF this `pi / 4 < z` `z < pi / 2`] 
  2674     have "1 < x" unfolding `tan z = x` `tan (pi / 4) = 1` .
  2675     thus False using `\<bar>x\<bar> < 1` by auto
  2676   qed
  2677   moreover 
  2678   have "-(pi / 4) < z"
  2679   proof (rule ccontr)
  2680     assume "\<not> (-(pi / 4) < z)" hence "z < - (pi / 4)" using `z \<noteq> - (pi / 4)` by auto
  2681     have "-(pi / 4) < pi / 2" using m2pi_less_pi by auto
  2682     from tan_monotone[OF `-(pi / 2) < z` `z < -(pi / 4)` this]
  2683     have "x < - 1" unfolding `tan z = x` `tan (-(pi / 4)) = - 1` .
  2684     thus False using `\<bar>x\<bar> < 1` by auto
  2685   qed
  2686   ultimately show ?thesis using `tan z = x` by auto
  2687 qed
  2688 
  2689 lemma arctan_add: assumes "\<bar>x\<bar> \<le> 1" and "\<bar>y\<bar> < 1"
  2690   shows "arctan x + arctan y = arctan ((x + y) / (1 - x * y))"
  2691 proof -
  2692   obtain y' where "-(pi/4) < y'" and "y' < pi/4" and "tan y' = y" using tan_total_pi4[OF `\<bar>y\<bar> < 1`] by blast
  2693 
  2694   have "pi / 4 < pi / 2" by auto
  2695 
  2696   have "\<exists> x'. -(pi/4) \<le> x' \<and> x' \<le> pi/4 \<and> tan x' = x"
  2697   proof (cases "\<bar>x\<bar> < 1")
  2698     case True from tan_total_pi4[OF this] obtain x' where "-(pi/4) < x'" and "x' < pi/4" and "tan x' = x" by blast
  2699     hence "-(pi/4) \<le> x'" and "x' \<le> pi/4" and "tan x' = x" by auto
  2700     thus ?thesis by auto
  2701   next
  2702     case False
  2703     show ?thesis
  2704     proof (cases "x = 1")
  2705       case True hence "tan (pi/4) = x" using tan_45 by auto
  2706       moreover 
  2707       have "- pi \<le> pi" unfolding minus_le_self_iff by auto
  2708       hence "-(pi/4) \<le> pi/4" and "pi/4 \<le> pi/4" by auto
  2709       ultimately show ?thesis by blast
  2710     next
  2711       case False hence "x = -1" using `\<not> \<bar>x\<bar> < 1` and `\<bar>x\<bar> \<le> 1` by auto
  2712       hence "tan (-(pi/4)) = x" using tan_45 tan_minus by auto
  2713       moreover 
  2714       have "- pi \<le> pi" unfolding minus_le_self_iff by auto
  2715       hence "-(pi/4) \<le> pi/4" and "-(pi/4) \<le> -(pi/4)" by auto
  2716       ultimately show ?thesis by blast
  2717     qed
  2718   qed
  2719   then obtain x' where "-(pi/4) \<le> x'" and "x' \<le> pi/4" and "tan x' = x" by blast
  2720   hence "-(pi/2) < x'" and "x' < pi/2" using order_le_less_trans[OF `x' \<le> pi/4` `pi / 4 < pi / 2`] by auto
  2721 
  2722   have "cos x' \<noteq> 0" using cos_gt_zero_pi[THEN less_imp_neq] and `-(pi/2) < x'` and `x' < pi/2` by auto
  2723   moreover have "cos y' \<noteq> 0" using cos_gt_zero_pi[THEN less_imp_neq] and `-(pi/4) < y'` and `y' < pi/4` by auto
  2724   ultimately have "cos x' * cos y' \<noteq> 0" by auto
  2725 
  2726   have divide_nonzero_divide: "\<And> A B C :: real. C \<noteq> 0 \<Longrightarrow> (A / C) / (B / C) = A / B" by auto
  2727   have divide_mult_commute: "\<And> A B C D :: real. A * B / (C * D) = (A / C) * (B / D)" by auto
  2728 
  2729   have "tan (x' + y') = sin (x' + y') / (cos x' * cos y' - sin x' * sin y')" unfolding tan_def cos_add ..
  2730   also have "\<dots> = (tan x' + tan y') / ((cos x' * cos y' - sin x' * sin y') / (cos x' * cos y'))" unfolding add_tan_eq[OF `cos x' \<noteq> 0` `cos y' \<noteq> 0`] divide_nonzero_divide[OF `cos x' * cos y' \<noteq> 0`] ..
  2731   also have "\<dots> = (tan x' + tan y') / (1 - tan x' * tan y')" unfolding tan_def diff_divide_distrib divide_self[OF `cos x' * cos y' \<noteq> 0`] unfolding divide_mult_commute ..
  2732   finally have tan_eq: "tan (x' + y') = (x + y) / (1 - x * y)" unfolding `tan y' = y` `tan x' = x` .
  2733 
  2734   have "arctan (tan (x' + y')) = x' + y'" using `-(pi/4) < y'` `-(pi/4) \<le> x'` `y' < pi/4` and `x' \<le> pi/4` by (auto intro!: arctan_tan)
  2735   moreover have "arctan (tan (x')) = x'" using `-(pi/2) < x'` and `x' < pi/2` by (auto intro!: arctan_tan)
  2736   moreover have "arctan (tan (y')) = y'" using `-(pi/4) < y'` and `y' < pi/4` by (auto intro!: arctan_tan)
  2737   ultimately have "arctan x + arctan y = arctan (tan (x' + y'))" unfolding `tan y' = y` [symmetric] `tan x' = x`[symmetric] by auto
  2738   thus "arctan x + arctan y = arctan ((x + y) / (1 - x * y))" unfolding tan_eq .
  2739 qed
  2740 
  2741 lemma arctan1_eq_pi4: "arctan 1 = pi / 4" unfolding tan_45[symmetric] by (rule arctan_tan, auto simp add: m2pi_less_pi)
  2742 
  2743 theorem machin: "pi / 4 = 4 * arctan (1/5) - arctan (1 / 239)"
  2744 proof -
  2745   have "\<bar>1 / 5\<bar> < (1 :: real)" by auto
  2746   from arctan_add[OF less_imp_le[OF this] this]
  2747   have "2 * arctan (1 / 5) = arctan (5 / 12)" by auto
  2748   moreover
  2749   have "\<bar>5 / 12\<bar> < (1 :: real)" by auto
  2750   from arctan_add[OF less_imp_le[OF this] this]
  2751   have "2 * arctan (5 / 12) = arctan (120 / 119)" by auto
  2752   moreover 
  2753   have "\<bar>1\<bar> \<le> (1::real)" and "\<bar>1 / 239\<bar> < (1::real)" by auto
  2754   from arctan_add[OF this]
  2755   have "arctan 1 + arctan (1 / 239) = arctan (120 / 119)" by auto
  2756   ultimately have "arctan 1 + arctan (1 / 239) = 4 * arctan (1 / 5)" by auto
  2757   thus ?thesis unfolding arctan1_eq_pi4 by algebra
  2758 qed
  2759 subsection {* Introducing the arcus tangens power series *}
  2760 
  2761 lemma monoseq_arctan_series: fixes x :: real
  2762   assumes "\<bar>x\<bar> \<le> 1" shows "monoseq (\<lambda> n. 1 / real (n*2+1) * x^(n*2+1))" (is "monoseq ?a")
  2763 proof (cases "x = 0") case True thus ?thesis unfolding monoseq_def One_nat_def by auto
  2764 next
  2765   case False
  2766   have "norm x \<le> 1" and "x \<le> 1" and "-1 \<le> x" using assms by auto
  2767   show "monoseq ?a"
  2768   proof -
  2769     { fix n fix x :: real assume "0 \<le> x" and "x \<le> 1"
  2770       have "1 / real (Suc (Suc n * 2)) * x ^ Suc (Suc n * 2) \<le> 1 / real (Suc (n * 2)) * x ^ Suc (n * 2)"
  2771       proof (rule mult_mono)
  2772 	show "1 / real (Suc (Suc n * 2)) \<le> 1 / real (Suc (n * 2))" by (rule frac_le) simp_all
  2773 	show "0 \<le> 1 / real (Suc (n * 2))" by auto
  2774 	show "x ^ Suc (Suc n * 2) \<le> x ^ Suc (n * 2)" by (rule power_decreasing) (simp_all add: `0 \<le> x` `x \<le> 1`)
  2775 	show "0 \<le> x ^ Suc (Suc n * 2)" by (rule zero_le_power) (simp add: `0 \<le> x`)
  2776       qed
  2777     } note mono = this
  2778     
  2779     show ?thesis
  2780     proof (cases "0 \<le> x")
  2781       case True from mono[OF this `x \<le> 1`, THEN allI]
  2782       show ?thesis unfolding Suc_eq_plus1[symmetric] by (rule mono_SucI2)
  2783     next
  2784       case False hence "0 \<le> -x" and "-x \<le> 1" using `-1 \<le> x` by auto
  2785       from mono[OF this]
  2786       have "\<And>n. 1 / real (Suc (Suc n * 2)) * x ^ Suc (Suc n * 2) \<ge> 1 / real (Suc (n * 2)) * x ^ Suc (n * 2)" using `0 \<le> -x` by auto
  2787       thus ?thesis unfolding Suc_eq_plus1[symmetric] by (rule mono_SucI1[OF allI])
  2788     qed
  2789   qed
  2790 qed
  2791 
  2792 lemma zeroseq_arctan_series: fixes x :: real
  2793   assumes "\<bar>x\<bar> \<le> 1" shows "(\<lambda> n. 1 / real (n*2+1) * x^(n*2+1)) ----> 0" (is "?a ----> 0")
  2794 proof (cases "x = 0") case True thus ?thesis unfolding One_nat_def by (auto simp add: LIMSEQ_const)
  2795 next
  2796   case False
  2797   have "norm x \<le> 1" and "x \<le> 1" and "-1 \<le> x" using assms by auto
  2798   show "?a ----> 0"
  2799   proof (cases "\<bar>x\<bar> < 1")
  2800     case True hence "norm x < 1" by auto
  2801     from LIMSEQ_mult[OF LIMSEQ_inverse_real_of_nat LIMSEQ_power_zero[OF `norm x < 1`, THEN LIMSEQ_Suc]]
  2802     have "(\<lambda>n. 1 / real (n + 1) * x ^ (n + 1)) ----> 0"
  2803       unfolding inverse_eq_divide Suc_eq_plus1 by simp
  2804     then show ?thesis using pos2 by (rule LIMSEQ_linear)
  2805   next
  2806     case False hence "x = -1 \<or> x = 1" using `\<bar>x\<bar> \<le> 1` by auto
  2807     hence n_eq: "\<And> n. x ^ (n * 2 + 1) = x" unfolding One_nat_def by auto
  2808     from LIMSEQ_mult[OF LIMSEQ_inverse_real_of_nat[THEN LIMSEQ_linear, OF pos2, unfolded inverse_eq_divide] LIMSEQ_const[of x]]
  2809     show ?thesis unfolding n_eq Suc_eq_plus1 by auto
  2810   qed
  2811 qed
  2812 
  2813 lemma summable_arctan_series: fixes x :: real and n :: nat
  2814   assumes "\<bar>x\<bar> \<le> 1" shows "summable (\<lambda> k. (-1)^k * (1 / real (k*2+1) * x ^ (k*2+1)))" (is "summable (?c x)")
  2815   by (rule summable_Leibniz(1), rule zeroseq_arctan_series[OF assms], rule monoseq_arctan_series[OF assms])
  2816 
  2817 lemma less_one_imp_sqr_less_one: fixes x :: real assumes "\<bar>x\<bar> < 1" shows "x^2 < 1"
  2818 proof -
  2819   from mult_mono1[OF less_imp_le[OF `\<bar>x\<bar> < 1`] abs_ge_zero[of x]]
  2820   have "\<bar> x^2 \<bar> < 1" using `\<bar> x \<bar> < 1` unfolding numeral_2_eq_2 power_Suc2 by auto
  2821   thus ?thesis using zero_le_power2 by auto
  2822 qed 
  2823 
  2824 lemma DERIV_arctan_series: assumes "\<bar> x \<bar> < 1"
  2825   shows "DERIV (\<lambda> x'. \<Sum> k. (-1)^k * (1 / real (k*2+1) * x' ^ (k*2+1))) x :> (\<Sum> k. (-1)^k * x^(k*2))" (is "DERIV ?arctan _ :> ?Int")
  2826 proof -
  2827   let "?f n" = "if even n then (-1)^(n div 2) * 1 / real (Suc n) else 0"
  2828 
  2829   { fix n :: nat assume "even n" hence "2 * (n div 2) = n" by presburger } note n_even=this
  2830   have if_eq: "\<And> n x'. ?f n * real (Suc n) * x'^n = (if even n then (-1)^(n div 2) * x'^(2 * (n div 2)) else 0)" using n_even by auto
  2831 
  2832   { fix x :: real assume "\<bar>x\<bar> < 1" hence "x^2 < 1" by (rule less_one_imp_sqr_less_one)
  2833     have "summable (\<lambda> n. -1 ^ n * (x^2) ^n)"
  2834       by (rule summable_Leibniz(1), auto intro!: LIMSEQ_realpow_zero monoseq_realpow `x^2 < 1` order_less_imp_le[OF `x^2 < 1`])
  2835     hence "summable (\<lambda> n. -1 ^ n * x^(2*n))" unfolding power_mult .
  2836   } note summable_Integral = this
  2837 
  2838   { fix f :: "nat \<Rightarrow> real"
  2839     have "\<And> x. f sums x = (\<lambda> n. if even n then f (n div 2) else 0) sums x"
  2840     proof
  2841       fix x :: real assume "f sums x" 
  2842       from sums_if[OF sums_zero this]
  2843       show "(\<lambda> n. if even n then f (n div 2) else 0) sums x" by auto
  2844     next
  2845       fix x :: real assume "(\<lambda> n. if even n then f (n div 2) else 0) sums x"
  2846       from LIMSEQ_linear[OF this[unfolded sums_def] pos2, unfolded sum_split_even_odd[unfolded mult_commute]]
  2847       show "f sums x" unfolding sums_def by auto
  2848     qed
  2849     hence "op sums f = op sums (\<lambda> n. if even n then f (n div 2) else 0)" ..
  2850   } note sums_even = this
  2851 
  2852   have Int_eq: "(\<Sum> n. ?f n * real (Suc n) * x^n) = ?Int" unfolding if_eq mult_commute[of _ 2] suminf_def sums_even[of "\<lambda> n. -1 ^ n * x ^ (2 * n)", symmetric]
  2853     by auto
  2854 
  2855   { fix x :: real
  2856     have if_eq': "\<And> n. (if even n then -1 ^ (n div 2) * 1 / real (Suc n) else 0) * x ^ Suc n = 
  2857       (if even n then -1 ^ (n div 2) * (1 / real (Suc (2 * (n div 2))) * x ^ Suc (2 * (n div 2))) else 0)"
  2858       using n_even by auto
  2859     have idx_eq: "\<And> n. n * 2 + 1 = Suc (2 * n)" by auto 
  2860     have "(\<Sum> n. ?f n * x^(Suc n)) = ?arctan x" unfolding if_eq' idx_eq suminf_def sums_even[of "\<lambda> n. -1 ^ n * (1 / real (Suc (2 * n)) * x ^ Suc (2 * n))", symmetric]
  2861       by auto
  2862   } note arctan_eq = this
  2863 
  2864   have "DERIV (\<lambda> x. \<Sum> n. ?f n * x^(Suc n)) x :> (\<Sum> n. ?f n * real (Suc n) * x^n)"
  2865   proof (rule DERIV_power_series')
  2866     show "x \<in> {- 1 <..< 1}" using `\<bar> x \<bar> < 1` by auto
  2867     { fix x' :: real assume x'_bounds: "x' \<in> {- 1 <..< 1}"
  2868       hence "\<bar>x'\<bar> < 1" by auto
  2869 
  2870       let ?S = "\<Sum> n. (-1)^n * x'^(2 * n)"
  2871       show "summable (\<lambda> n. ?f n * real (Suc n) * x'^n)" unfolding if_eq
  2872 	by (rule sums_summable[where l="0 + ?S"], rule sums_if, rule sums_zero, rule summable_sums, rule summable_Integral[OF `\<bar>x'\<bar> < 1`])
  2873     }
  2874   qed auto
  2875   thus ?thesis unfolding Int_eq arctan_eq .
  2876 qed
  2877 
  2878 lemma arctan_series: assumes "\<bar> x \<bar> \<le> 1"
  2879   shows "arctan x = (\<Sum> k. (-1)^k * (1 / real (k*2+1) * x ^ (k*2+1)))" (is "_ = suminf (\<lambda> n. ?c x n)")
  2880 proof -
  2881   let "?c' x n" = "(-1)^n * x^(n*2)"
  2882 
  2883   { fix r x :: real assume "0 < r" and "r < 1" and "\<bar> x \<bar> < r"
  2884     have "\<bar>x\<bar> < 1" using `r < 1` and `\<bar>x\<bar> < r` by auto
  2885     from DERIV_arctan_series[OF this]
  2886     have "DERIV (\<lambda> x. suminf (?c x)) x :> (suminf (?c' x))" .
  2887   } note DERIV_arctan_suminf = this
  2888 
  2889   { fix x :: real assume "\<bar>x\<bar> \<le> 1" note summable_Leibniz[OF zeroseq_arctan_series[OF this] monoseq_arctan_series[OF this]] }
  2890   note arctan_series_borders = this
  2891 
  2892   { fix x :: real assume "\<bar>x\<bar> < 1" have "arctan x = (\<Sum> k. ?c x k)"
  2893   proof -
  2894     obtain r where "\<bar>x\<bar> < r" and "r < 1" using dense[OF `\<bar>x\<bar> < 1`] by blast
  2895     hence "0 < r" and "-r < x" and "x < r" by auto
  2896 
  2897     have suminf_eq_arctan_bounded: "\<And> x a b. \<lbrakk> -r < a ; b < r ; a < b ; a \<le> x ; x \<le> b \<rbrakk> \<Longrightarrow> suminf (?c x) - arctan x = suminf (?c a) - arctan a"
  2898     proof -
  2899       fix x a b assume "-r < a" and "b < r" and "a < b" and "a \<le> x" and "x \<le> b"
  2900       hence "\<bar>x\<bar> < r" by auto
  2901       show "suminf (?c x) - arctan x = suminf (?c a) - arctan a"
  2902       proof (rule DERIV_isconst2[of "a" "b"])
  2903 	show "a < b" and "a \<le> x" and "x \<le> b" using `a < b` `a \<le> x` `x \<le> b` by auto
  2904 	have "\<forall> x. -r < x \<and> x < r \<longrightarrow> DERIV (\<lambda> x. suminf (?c x) - arctan x) x :> 0"
  2905 	proof (rule allI, rule impI)
  2906 	  fix x assume "-r < x \<and> x < r" hence "\<bar>x\<bar> < r" by auto
  2907 	  hence "\<bar>x\<bar> < 1" using `r < 1` by auto
  2908 	  have "\<bar> - (x^2) \<bar> < 1" using less_one_imp_sqr_less_one[OF `\<bar>x\<bar> < 1`] by auto
  2909 	  hence "(\<lambda> n. (- (x^2)) ^ n) sums (1 / (1 - (- (x^2))))" unfolding real_norm_def[symmetric] by (rule geometric_sums)
  2910 	  hence "(?c' x) sums (1 / (1 - (- (x^2))))" unfolding power_mult_distrib[symmetric] power_mult nat_mult_commute[of _ 2] by auto
  2911 	  hence suminf_c'_eq_geom: "inverse (1 + x^2) = suminf (?c' x)" using sums_unique unfolding inverse_eq_divide by auto
  2912 	  have "DERIV (\<lambda> x. suminf (?c x)) x :> (inverse (1 + x^2))" unfolding suminf_c'_eq_geom
  2913 	    by (rule DERIV_arctan_suminf[OF `0 < r` `r < 1` `\<bar>x\<bar> < r`])
  2914 	  from DERIV_add_minus[OF this DERIV_arctan]
  2915 	  show "DERIV (\<lambda> x. suminf (?c x) - arctan x) x :> 0" unfolding diff_minus by auto
  2916 	qed
  2917 	hence DERIV_in_rball: "\<forall> y. a \<le> y \<and> y \<le> b \<longrightarrow> DERIV (\<lambda> x. suminf (?c x) - arctan x) y :> 0" using `-r < a` `b < r` by auto
  2918 	thus "\<forall> y. a < y \<and> y < b \<longrightarrow> DERIV (\<lambda> x. suminf (?c x) - arctan x) y :> 0" using `\<bar>x\<bar> < r` by auto
  2919 	show "\<forall> y. a \<le> y \<and> y \<le> b \<longrightarrow> isCont (\<lambda> x. suminf (?c x) - arctan x) y" using DERIV_in_rball DERIV_isCont by auto
  2920       qed
  2921     qed
  2922     
  2923     have suminf_arctan_zero: "suminf (?c 0) - arctan 0 = 0"
  2924       unfolding Suc_eq_plus1[symmetric] power_Suc2 mult_zero_right arctan_zero_zero suminf_zero by auto
  2925     
  2926     have "suminf (?c x) - arctan x = 0"
  2927     proof (cases "x = 0")
  2928       case True thus ?thesis using suminf_arctan_zero by auto
  2929     next
  2930       case False hence "0 < \<bar>x\<bar>" and "- \<bar>x\<bar> < \<bar>x\<bar>" by auto
  2931       have "suminf (?c (-\<bar>x\<bar>)) - arctan (-\<bar>x\<bar>) = suminf (?c 0) - arctan 0"
  2932 	by (rule suminf_eq_arctan_bounded[where x="0" and a="-\<bar>x\<bar>" and b="\<bar>x\<bar>", symmetric], auto simp add: `\<bar>x\<bar> < r` `-\<bar>x\<bar> < \<bar>x\<bar>`)
  2933       moreover
  2934       have "suminf (?c x) - arctan x = suminf (?c (-\<bar>x\<bar>)) - arctan (-\<bar>x\<bar>)"
  2935 	by (rule suminf_eq_arctan_bounded[where x="x" and a="-\<bar>x\<bar>" and b="\<bar>x\<bar>"], auto simp add: `\<bar>x\<bar> < r` `-\<bar>x\<bar> < \<bar>x\<bar>`)
  2936       ultimately 
  2937       show ?thesis using suminf_arctan_zero by auto
  2938     qed
  2939     thus ?thesis by auto
  2940   qed } note when_less_one = this
  2941 
  2942   show "arctan x = suminf (\<lambda> n. ?c x n)"
  2943   proof (cases "\<bar>x\<bar> < 1")
  2944     case True thus ?thesis by (rule when_less_one)
  2945   next case False hence "\<bar>x\<bar> = 1" using `\<bar>x\<bar> \<le> 1` by auto
  2946     let "?a x n" = "\<bar>1 / real (n*2+1) * x^(n*2+1)\<bar>"
  2947     let "?diff x n" = "\<bar> arctan x - (\<Sum> i = 0..<n. ?c x i)\<bar>"
  2948     { fix n :: nat
  2949       have "0 < (1 :: real)" by auto
  2950       moreover
  2951       { fix x :: real assume "0 < x" and "x < 1" hence "\<bar>x\<bar> \<le> 1" and "\<bar>x\<bar> < 1" by auto
  2952 	from `0 < x` have "0 < 1 / real (0 * 2 + (1::nat)) * x ^ (0 * 2 + 1)" by auto
  2953 	note bounds = mp[OF arctan_series_borders(2)[OF `\<bar>x\<bar> \<le> 1`] this, unfolded when_less_one[OF `\<bar>x\<bar> < 1`, symmetric], THEN spec]
  2954 	have "0 < 1 / real (n*2+1) * x^(n*2+1)" by (rule mult_pos_pos, auto simp only: zero_less_power[OF `0 < x`], auto)
  2955 	hence a_pos: "?a x n = 1 / real (n*2+1) * x^(n*2+1)" by (rule abs_of_pos)
  2956         have "?diff x n \<le> ?a x n"
  2957 	proof (cases "even n")
  2958 	  case True hence sgn_pos: "(-1)^n = (1::real)" by auto
  2959 	  from `even n` obtain m where "2 * m = n" unfolding even_mult_two_ex by auto
  2960 	  from bounds[of m, unfolded this atLeastAtMost_iff]
  2961 	  have "\<bar>arctan x - (\<Sum>i = 0..<n. (?c x i))\<bar> \<le> (\<Sum>i = 0..<n + 1. (?c x i)) - (\<Sum>i = 0..<n. (?c x i))" by auto
  2962 	  also have "\<dots> = ?c x n" unfolding One_nat_def by auto
  2963 	  also have "\<dots> = ?a x n" unfolding sgn_pos a_pos by auto
  2964 	  finally show ?thesis .
  2965 	next
  2966 	  case False hence sgn_neg: "(-1)^n = (-1::real)" by auto
  2967 	  from `odd n` obtain m where m_def: "2 * m + 1 = n" unfolding odd_Suc_mult_two_ex by auto
  2968 	  hence m_plus: "2 * (m + 1) = n + 1" by auto
  2969 	  from bounds[of "m + 1", unfolded this atLeastAtMost_iff, THEN conjunct1] bounds[of m, unfolded m_def atLeastAtMost_iff, THEN conjunct2]
  2970 	  have "\<bar>arctan x - (\<Sum>i = 0..<n. (?c x i))\<bar> \<le> (\<Sum>i = 0..<n. (?c x i)) - (\<Sum>i = 0..<n+1. (?c x i))" by auto
  2971 	  also have "\<dots> = - ?c x n" unfolding One_nat_def by auto
  2972 	  also have "\<dots> = ?a x n" unfolding sgn_neg a_pos by auto
  2973 	  finally show ?thesis .
  2974 	qed
  2975         hence "0 \<le> ?a x n - ?diff x n" by auto
  2976       }
  2977       hence "\<forall> x \<in> { 0 <..< 1 }. 0 \<le> ?a x n - ?diff x n" by auto
  2978       moreover have "\<And>x. isCont (\<lambda> x. ?a x n - ?diff x n) x"
  2979 	unfolding real_diff_def divide_inverse
  2980 	by (auto intro!: isCont_add isCont_rabs isCont_ident isCont_minus isCont_arctan isCont_inverse isCont_mult isCont_power isCont_const isCont_setsum)
  2981       ultimately have "0 \<le> ?a 1 n - ?diff 1 n" by (rule LIM_less_bound)
  2982       hence "?diff 1 n \<le> ?a 1 n" by auto
  2983     }
  2984     have "?a 1 ----> 0"
  2985       unfolding LIMSEQ_rabs_zero power_one divide_inverse One_nat_def
  2986       by (auto intro!: LIMSEQ_mult LIMSEQ_linear LIMSEQ_inverse_real_of_nat)
  2987     have "?diff 1 ----> 0"
  2988     proof (rule LIMSEQ_I)
  2989       fix r :: real assume "0 < r"
  2990       obtain N :: nat where N_I: "\<And> n. N \<le> n \<Longrightarrow> ?a 1 n < r" using LIMSEQ_D[OF `?a 1 ----> 0` `0 < r`] by auto
  2991       { fix n assume "N \<le> n" from `?diff 1 n \<le> ?a 1 n` N_I[OF this]
  2992 	have "norm (?diff 1 n - 0) < r" by auto }
  2993       thus "\<exists> N. \<forall> n \<ge> N. norm (?diff 1 n - 0) < r" by blast
  2994     qed
  2995     from this[unfolded LIMSEQ_rabs_zero real_diff_def add_commute[of "arctan 1"], THEN LIMSEQ_add_const, of "- arctan 1", THEN LIMSEQ_minus]
  2996     have "(?c 1) sums (arctan 1)" unfolding sums_def by auto
  2997     hence "arctan 1 = (\<Sum> i. ?c 1 i)" by (rule sums_unique)
  2998     
  2999     show ?thesis
  3000     proof (cases "x = 1", simp add: `arctan 1 = (\<Sum> i. ?c 1 i)`)
  3001       assume "x \<noteq> 1" hence "x = -1" using `\<bar>x\<bar> = 1` by auto
  3002       
  3003       have "- (pi / 2) < 0" using pi_gt_zero by auto
  3004       have "- (2 * pi) < 0" using pi_gt_zero by auto
  3005       
  3006       have c_minus_minus: "\<And> i. ?c (- 1) i = - ?c 1 i" unfolding One_nat_def by auto
  3007     
  3008       have "arctan (- 1) = arctan (tan (-(pi / 4)))" unfolding tan_45 tan_minus ..
  3009       also have "\<dots> = - (pi / 4)" by (rule arctan_tan, auto simp add: order_less_trans[OF `- (pi / 2) < 0` pi_gt_zero])
  3010       also have "\<dots> = - (arctan (tan (pi / 4)))" unfolding neg_equal_iff_equal by (rule arctan_tan[symmetric], auto simp add: order_less_trans[OF `- (2 * pi) < 0` pi_gt_zero])
  3011       also have "\<dots> = - (arctan 1)" unfolding tan_45 ..
  3012       also have "\<dots> = - (\<Sum> i. ?c 1 i)" using `arctan 1 = (\<Sum> i. ?c 1 i)` by auto
  3013       also have "\<dots> = (\<Sum> i. ?c (- 1) i)" using suminf_minus[OF sums_summable[OF `(?c 1) sums (arctan 1)`]] unfolding c_minus_minus by auto
  3014       finally show ?thesis using `x = -1` by auto
  3015     qed
  3016   qed
  3017 qed
  3018 
  3019 lemma arctan_half: fixes x :: real
  3020   shows "arctan x = 2 * arctan (x / (1 + sqrt(1 + x^2)))"
  3021 proof -
  3022   obtain y where low: "- (pi / 2) < y" and high: "y < pi / 2" and y_eq: "tan y = x" using tan_total by blast
  3023   hence low2: "- (pi / 2) < y / 2" and high2: "y / 2 < pi / 2" by auto
  3024 
  3025   have divide_nonzero_divide: "\<And> A B C :: real. C \<noteq> 0 \<Longrightarrow> A / B = (A / C) / (B / C)" by auto
  3026   
  3027   have "0 < cos y" using cos_gt_zero_pi[OF low high] .
  3028   hence "cos y \<noteq> 0" and cos_sqrt: "sqrt ((cos y) ^ 2) = cos y" by auto
  3029 
  3030   have "1 + (tan y)^2 = 1 + sin y^2 / cos y^2" unfolding tan_def power_divide ..
  3031   also have "\<dots> = cos y^2 / cos y^2 + sin y^2 / cos y^2" using `cos y \<noteq> 0` by auto
  3032   also have "\<dots> = 1 / cos y^2" unfolding add_divide_distrib[symmetric] sin_cos_squared_add2 ..
  3033   finally have "1 + (tan y)^2 = 1 / cos y^2" .
  3034 
  3035   have "sin y / (cos y + 1) = tan y / ((cos y + 1) / cos y)" unfolding tan_def divide_nonzero_divide[OF `cos y \<noteq> 0`, symmetric] ..
  3036   also have "\<dots> = tan y / (1 + 1 / cos y)" using `cos y \<noteq> 0` unfolding add_divide_distrib by auto
  3037   also have "\<dots> = tan y / (1 + 1 / sqrt(cos y^2))" unfolding cos_sqrt ..
  3038   also have "\<dots> = tan y / (1 + sqrt(1 / cos y^2))" unfolding real_sqrt_divide by auto
  3039   finally have eq: "sin y / (cos y + 1) = tan y / (1 + sqrt(1 + (tan y)^2))" unfolding `1 + (tan y)^2 = 1 / cos y^2` .
  3040 
  3041   have "arctan x = y" using arctan_tan low high y_eq by auto
  3042   also have "\<dots> = 2 * (arctan (tan (y/2)))" using arctan_tan[OF low2 high2] by auto
  3043   also have "\<dots> = 2 * (arctan (sin y / (cos y + 1)))" unfolding tan_half[OF low2 high2] by auto
  3044   finally show ?thesis unfolding eq `tan y = x` .
  3045 qed
  3046 
  3047 lemma arctan_monotone: assumes "x < y"
  3048   shows "arctan x < arctan y"
  3049 proof -
  3050   obtain z where "-(pi / 2) < z" and "z < pi / 2" and "tan z = x" using tan_total by blast
  3051   obtain w where "-(pi / 2) < w" and "w < pi / 2" and "tan w = y" using tan_total by blast
  3052   have "z < w" unfolding tan_monotone'[OF `-(pi / 2) < z` `z < pi / 2` `-(pi / 2) < w` `w < pi / 2`] `tan z = x` `tan w = y` using `x < y` .
  3053   thus ?thesis
  3054     unfolding `tan z = x`[symmetric] arctan_tan[OF `-(pi / 2) < z` `z < pi / 2`]
  3055     unfolding `tan w = y`[symmetric] arctan_tan[OF `-(pi / 2) < w` `w < pi / 2`] .
  3056 qed
  3057 
  3058 lemma arctan_monotone': assumes "x \<le> y" shows "arctan x \<le> arctan y"
  3059 proof (cases "x = y") 
  3060   case False hence "x < y" using `x \<le> y` by auto from arctan_monotone[OF this] show ?thesis by auto
  3061 qed auto
  3062 
  3063 lemma arctan_minus: "arctan (- x) = - arctan x" 
  3064 proof -
  3065   obtain y where "- (pi / 2) < y" and "y < pi / 2" and "tan y = x" using tan_total by blast
  3066   thus ?thesis unfolding `tan y = x`[symmetric] tan_minus[symmetric] using arctan_tan[of y] arctan_tan[of "-y"] by auto 
  3067 qed
  3068 
  3069 lemma arctan_inverse: assumes "x \<noteq> 0" shows "arctan (1 / x) = sgn x * pi / 2 - arctan x"
  3070 proof -
  3071   obtain y where "- (pi / 2) < y" and "y < pi / 2" and "tan y = x" using tan_total by blast
  3072   hence "y = arctan x" unfolding `tan y = x`[symmetric] using arctan_tan by auto
  3073 
  3074   { fix y x :: real assume "0 < y" and "y < pi /2" and "y = arctan x" and "tan y = x" hence "- (pi / 2) < y" by auto
  3075     have "tan y > 0" using tan_monotone'[OF _ _ `- (pi / 2) < y` `y < pi / 2`, of 0] tan_zero `0 < y` by auto
  3076     hence "x > 0" using `tan y = x` by auto
  3077 
  3078     have "- (pi / 2) < pi / 2 - y" using `y > 0` `y < pi / 2` by auto
  3079     moreover have "pi / 2 - y < pi / 2" using `y > 0` `y < pi / 2` by auto
  3080     ultimately have "arctan (1 / x) = pi / 2 - y" unfolding `tan y = x`[symmetric] tan_inverse using arctan_tan by auto
  3081     hence "arctan (1 / x) = sgn x * pi / 2 - arctan x" unfolding `y = arctan x` real_sgn_pos[OF `x > 0`] by auto
  3082   } note pos_y = this
  3083 
  3084   show ?thesis
  3085   proof (cases "y > 0")
  3086     case True from pos_y[OF this `y < pi / 2` `y = arctan x` `tan y = x`] show ?thesis .
  3087   next
  3088     case False hence "y \<le> 0" by auto
  3089     moreover have "y \<noteq> 0" 
  3090     proof (rule ccontr)
  3091       assume "\<not> y \<noteq> 0" hence "y = 0" by auto
  3092       have "x = 0" unfolding `tan y = x`[symmetric] `y = 0` tan_zero ..
  3093       thus False using `x \<noteq> 0` by auto
  3094     qed
  3095     ultimately have "y < 0" by auto
  3096     hence "0 < - y" and "-y < pi / 2" using `- (pi / 2) < y` by auto
  3097     moreover have "-y = arctan (-x)" unfolding arctan_minus `y = arctan x` ..
  3098     moreover have "tan (-y) = -x" unfolding tan_minus `tan y = x` ..
  3099     ultimately have "arctan (1 / -x) = sgn (-x) * pi / 2 - arctan (-x)" using pos_y by blast
  3100     hence "arctan (- (1 / x)) = - (sgn x * pi / 2 - arctan x)" unfolding arctan_minus[of x] divide_minus_right sgn_minus by auto
  3101     thus ?thesis unfolding arctan_minus neg_equal_iff_equal .
  3102   qed
  3103 qed
  3104 
  3105 theorem pi_series: "pi / 4 = (\<Sum> k. (-1)^k * 1 / real (k*2+1))" (is "_ = ?SUM")
  3106 proof -
  3107   have "pi / 4 = arctan 1" using arctan1_eq_pi4 by auto
  3108   also have "\<dots> = ?SUM" using arctan_series[of 1] by auto
  3109   finally show ?thesis by auto
  3110 qed
  3111 
  3112 subsection {* Existence of Polar Coordinates *}
  3113 
  3114 lemma cos_x_y_le_one: "\<bar>x / sqrt (x\<twosuperior> + y\<twosuperior>)\<bar> \<le> 1"
  3115 apply (rule power2_le_imp_le [OF _ zero_le_one])
  3116 apply (simp add: abs_divide power_divide divide_le_eq not_sum_power2_lt_zero)
  3117 done
  3118 
  3119 lemma cos_arccos_abs: "\<bar>y\<bar> \<le> 1 \<Longrightarrow> cos (arccos y) = y"
  3120 by (simp add: abs_le_iff)
  3121 
  3122 lemma sin_arccos_abs: "\<bar>y\<bar> \<le> 1 \<Longrightarrow> sin (arccos y) = sqrt (1 - y\<twosuperior>)"
  3123 by (simp add: sin_arccos abs_le_iff)
  3124 
  3125 lemmas cos_arccos_lemma1 = cos_arccos_abs [OF cos_x_y_le_one]
  3126 
  3127 lemmas sin_arccos_lemma1 = sin_arccos_abs [OF cos_x_y_le_one]
  3128 
  3129 lemma polar_ex1:
  3130      "0 < y ==> \<exists>r a. x = r * cos a & y = r * sin a"
  3131 apply (rule_tac x = "sqrt (x\<twosuperior> + y\<twosuperior>)" in exI)
  3132 apply (rule_tac x = "arccos (x / sqrt (x\<twosuperior> + y\<twosuperior>))" in exI)
  3133 apply (simp add: cos_arccos_lemma1)
  3134 apply (simp add: sin_arccos_lemma1)
  3135 apply (simp add: power_divide)
  3136 apply (simp add: real_sqrt_mult [symmetric])
  3137 apply (simp add: right_diff_distrib)
  3138 done
  3139 
  3140 lemma polar_ex2:
  3141      "y < 0 ==> \<exists>r a. x = r * cos a & y = r * sin a"
  3142 apply (insert polar_ex1 [where x=x and y="-y"], simp, clarify)
  3143 apply (rule_tac x = r in exI)
  3144 apply (rule_tac x = "-a" in exI, simp)
  3145 done
  3146 
  3147 lemma polar_Ex: "\<exists>r a. x = r * cos a & y = r * sin a"
  3148 apply (rule_tac x=0 and y=y in linorder_cases)
  3149 apply (erule polar_ex1)
  3150 apply (rule_tac x=x in exI, rule_tac x=0 in exI, simp)
  3151 apply (erule polar_ex2)
  3152 done
  3153 
  3154 end