src/HOL/Map.thy
author haftmann
Fri Jan 25 14:54:41 2008 +0100 (2008-01-25)
changeset 25965 05df64f786a4
parent 25670 497474b69c86
child 26443 cae9fa186541
permissions -rw-r--r--
improved code theorem setup
     1 (*  Title:      HOL/Map.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, based on a theory by David von Oheimb
     4     Copyright   1997-2003 TU Muenchen
     5 
     6 The datatype of `maps' (written ~=>); strongly resembles maps in VDM.
     7 *)
     8 
     9 header {* Maps *}
    10 
    11 theory Map
    12 imports List
    13 begin
    14 
    15 types ('a,'b) "~=>" = "'a => 'b option"  (infixr 0)
    16 translations (type) "a ~=> b " <= (type) "a => b option"
    17 
    18 syntax (xsymbols)
    19   "~=>" :: "[type, type] => type"  (infixr "\<rightharpoonup>" 0)
    20 
    21 abbreviation
    22   empty :: "'a ~=> 'b" where
    23   "empty == %x. None"
    24 
    25 definition
    26   map_comp :: "('b ~=> 'c) => ('a ~=> 'b) => ('a ~=> 'c)"  (infixl "o'_m" 55) where
    27   "f o_m g = (\<lambda>k. case g k of None \<Rightarrow> None | Some v \<Rightarrow> f v)"
    28 
    29 notation (xsymbols)
    30   map_comp  (infixl "\<circ>\<^sub>m" 55)
    31 
    32 definition
    33   map_add :: "('a ~=> 'b) => ('a ~=> 'b) => ('a ~=> 'b)"  (infixl "++" 100) where
    34   "m1 ++ m2 = (\<lambda>x. case m2 x of None => m1 x | Some y => Some y)"
    35 
    36 definition
    37   restrict_map :: "('a ~=> 'b) => 'a set => ('a ~=> 'b)"  (infixl "|`"  110) where
    38   "m|`A = (\<lambda>x. if x : A then m x else None)"
    39 
    40 notation (latex output)
    41   restrict_map  ("_\<restriction>\<^bsub>_\<^esub>" [111,110] 110)
    42 
    43 definition
    44   dom :: "('a ~=> 'b) => 'a set" where
    45   "dom m = {a. m a ~= None}"
    46 
    47 definition
    48   ran :: "('a ~=> 'b) => 'b set" where
    49   "ran m = {b. EX a. m a = Some b}"
    50 
    51 definition
    52   map_le :: "('a ~=> 'b) => ('a ~=> 'b) => bool"  (infix "\<subseteq>\<^sub>m" 50) where
    53   "(m\<^isub>1 \<subseteq>\<^sub>m m\<^isub>2) = (\<forall>a \<in> dom m\<^isub>1. m\<^isub>1 a = m\<^isub>2 a)"
    54 
    55 consts
    56   map_of :: "('a * 'b) list => 'a ~=> 'b"
    57   map_upds :: "('a ~=> 'b) => 'a list => 'b list => ('a ~=> 'b)"
    58 
    59 nonterminals
    60   maplets maplet
    61 
    62 syntax
    63   "_maplet"  :: "['a, 'a] => maplet"             ("_ /|->/ _")
    64   "_maplets" :: "['a, 'a] => maplet"             ("_ /[|->]/ _")
    65   ""         :: "maplet => maplets"             ("_")
    66   "_Maplets" :: "[maplet, maplets] => maplets" ("_,/ _")
    67   "_MapUpd"  :: "['a ~=> 'b, maplets] => 'a ~=> 'b" ("_/'(_')" [900,0]900)
    68   "_Map"     :: "maplets => 'a ~=> 'b"            ("(1[_])")
    69 
    70 syntax (xsymbols)
    71   "_maplet"  :: "['a, 'a] => maplet"             ("_ /\<mapsto>/ _")
    72   "_maplets" :: "['a, 'a] => maplet"             ("_ /[\<mapsto>]/ _")
    73 
    74 translations
    75   "_MapUpd m (_Maplets xy ms)"  == "_MapUpd (_MapUpd m xy) ms"
    76   "_MapUpd m (_maplet  x y)"    == "m(x:=Some y)"
    77   "_MapUpd m (_maplets x y)"    == "map_upds m x y"
    78   "_Map ms"                     == "_MapUpd (CONST empty) ms"
    79   "_Map (_Maplets ms1 ms2)"     <= "_MapUpd (_Map ms1) ms2"
    80   "_Maplets ms1 (_Maplets ms2 ms3)" <= "_Maplets (_Maplets ms1 ms2) ms3"
    81 
    82 primrec
    83   "map_of [] = empty"
    84   "map_of (p#ps) = (map_of ps)(fst p |-> snd p)"
    85 
    86 declare map_of.simps [code del]
    87 
    88 lemma map_of_Cons_code [code]: 
    89   "map_of [] k = None"
    90   "map_of ((l, v) # ps) k = (if l = k then Some v else map_of ps k)"
    91   by simp_all
    92 
    93 defs
    94   map_upds_def [code func]: "m(xs [|->] ys) == m ++ map_of (rev(zip xs ys))"
    95 
    96 
    97 subsection {* @{term [source] empty} *}
    98 
    99 lemma empty_upd_none [simp]: "empty(x := None) = empty"
   100 by (rule ext) simp
   101 
   102 
   103 subsection {* @{term [source] map_upd} *}
   104 
   105 lemma map_upd_triv: "t k = Some x ==> t(k|->x) = t"
   106 by (rule ext) simp
   107 
   108 lemma map_upd_nonempty [simp]: "t(k|->x) ~= empty"
   109 proof
   110   assume "t(k \<mapsto> x) = empty"
   111   then have "(t(k \<mapsto> x)) k = None" by simp
   112   then show False by simp
   113 qed
   114 
   115 lemma map_upd_eqD1:
   116   assumes "m(a\<mapsto>x) = n(a\<mapsto>y)"
   117   shows "x = y"
   118 proof -
   119   from prems have "(m(a\<mapsto>x)) a = (n(a\<mapsto>y)) a" by simp
   120   then show ?thesis by simp
   121 qed
   122 
   123 lemma map_upd_Some_unfold:
   124   "((m(a|->b)) x = Some y) = (x = a \<and> b = y \<or> x \<noteq> a \<and> m x = Some y)"
   125 by auto
   126 
   127 lemma image_map_upd [simp]: "x \<notin> A \<Longrightarrow> m(x \<mapsto> y) ` A = m ` A"
   128 by auto
   129 
   130 lemma finite_range_updI: "finite (range f) ==> finite (range (f(a|->b)))"
   131 unfolding image_def
   132 apply (simp (no_asm_use) add:full_SetCompr_eq)
   133 apply (rule finite_subset)
   134  prefer 2 apply assumption
   135 apply (auto)
   136 done
   137 
   138 
   139 subsection {* @{term [source] map_of} *}
   140 
   141 lemma map_of_eq_None_iff:
   142   "(map_of xys x = None) = (x \<notin> fst ` (set xys))"
   143 by (induct xys) simp_all
   144 
   145 lemma map_of_is_SomeD: "map_of xys x = Some y \<Longrightarrow> (x,y) \<in> set xys"
   146 apply (induct xys)
   147  apply simp
   148 apply (clarsimp split: if_splits)
   149 done
   150 
   151 lemma map_of_eq_Some_iff [simp]:
   152   "distinct(map fst xys) \<Longrightarrow> (map_of xys x = Some y) = ((x,y) \<in> set xys)"
   153 apply (induct xys)
   154  apply simp
   155 apply (auto simp: map_of_eq_None_iff [symmetric])
   156 done
   157 
   158 lemma Some_eq_map_of_iff [simp]:
   159   "distinct(map fst xys) \<Longrightarrow> (Some y = map_of xys x) = ((x,y) \<in> set xys)"
   160 by (auto simp del:map_of_eq_Some_iff simp add: map_of_eq_Some_iff [symmetric])
   161 
   162 lemma map_of_is_SomeI [simp]: "\<lbrakk> distinct(map fst xys); (x,y) \<in> set xys \<rbrakk>
   163     \<Longrightarrow> map_of xys x = Some y"
   164 apply (induct xys)
   165  apply simp
   166 apply force
   167 done
   168 
   169 lemma map_of_zip_is_None [simp]:
   170   "length xs = length ys \<Longrightarrow> (map_of (zip xs ys) x = None) = (x \<notin> set xs)"
   171 by (induct rule: list_induct2) simp_all
   172 
   173 lemma finite_range_map_of: "finite (range (map_of xys))"
   174 apply (induct xys)
   175  apply (simp_all add: image_constant)
   176 apply (rule finite_subset)
   177  prefer 2 apply assumption
   178 apply auto
   179 done
   180 
   181 lemma map_of_SomeD: "map_of xs k = Some y \<Longrightarrow> (k, y) \<in> set xs"
   182 by (induct xs) (simp, atomize (full), auto)
   183 
   184 lemma map_of_mapk_SomeI:
   185   "inj f ==> map_of t k = Some x ==>
   186    map_of (map (split (%k. Pair (f k))) t) (f k) = Some x"
   187 by (induct t) (auto simp add: inj_eq)
   188 
   189 lemma weak_map_of_SomeI: "(k, x) : set l ==> \<exists>x. map_of l k = Some x"
   190 by (induct l) auto
   191 
   192 lemma map_of_filter_in:
   193   "map_of xs k = Some z \<Longrightarrow> P k z \<Longrightarrow> map_of (filter (split P) xs) k = Some z"
   194 by (induct xs) auto
   195 
   196 lemma map_of_map: "map_of (map (%(a,b). (a,f b)) xs) x = option_map f (map_of xs x)"
   197 by (induct xs) auto
   198 
   199 
   200 subsection {* @{term [source] option_map} related *}
   201 
   202 lemma option_map_o_empty [simp]: "option_map f o empty = empty"
   203 by (rule ext) simp
   204 
   205 lemma option_map_o_map_upd [simp]:
   206   "option_map f o m(a|->b) = (option_map f o m)(a|->f b)"
   207 by (rule ext) simp
   208 
   209 
   210 subsection {* @{term [source] map_comp} related *}
   211 
   212 lemma map_comp_empty [simp]:
   213   "m \<circ>\<^sub>m empty = empty"
   214   "empty \<circ>\<^sub>m m = empty"
   215 by (auto simp add: map_comp_def intro: ext split: option.splits)
   216 
   217 lemma map_comp_simps [simp]:
   218   "m2 k = None \<Longrightarrow> (m1 \<circ>\<^sub>m m2) k = None"
   219   "m2 k = Some k' \<Longrightarrow> (m1 \<circ>\<^sub>m m2) k = m1 k'"
   220 by (auto simp add: map_comp_def)
   221 
   222 lemma map_comp_Some_iff:
   223   "((m1 \<circ>\<^sub>m m2) k = Some v) = (\<exists>k'. m2 k = Some k' \<and> m1 k' = Some v)"
   224 by (auto simp add: map_comp_def split: option.splits)
   225 
   226 lemma map_comp_None_iff:
   227   "((m1 \<circ>\<^sub>m m2) k = None) = (m2 k = None \<or> (\<exists>k'. m2 k = Some k' \<and> m1 k' = None)) "
   228 by (auto simp add: map_comp_def split: option.splits)
   229 
   230 
   231 subsection {* @{text "++"} *}
   232 
   233 lemma map_add_empty[simp]: "m ++ empty = m"
   234 by(simp add: map_add_def)
   235 
   236 lemma empty_map_add[simp]: "empty ++ m = m"
   237 by (rule ext) (simp add: map_add_def split: option.split)
   238 
   239 lemma map_add_assoc[simp]: "m1 ++ (m2 ++ m3) = (m1 ++ m2) ++ m3"
   240 by (rule ext) (simp add: map_add_def split: option.split)
   241 
   242 lemma map_add_Some_iff:
   243   "((m ++ n) k = Some x) = (n k = Some x | n k = None & m k = Some x)"
   244 by (simp add: map_add_def split: option.split)
   245 
   246 lemma map_add_SomeD [dest!]:
   247   "(m ++ n) k = Some x \<Longrightarrow> n k = Some x \<or> n k = None \<and> m k = Some x"
   248 by (rule map_add_Some_iff [THEN iffD1])
   249 
   250 lemma map_add_find_right [simp]: "!!xx. n k = Some xx ==> (m ++ n) k = Some xx"
   251 by (subst map_add_Some_iff) fast
   252 
   253 lemma map_add_None [iff]: "((m ++ n) k = None) = (n k = None & m k = None)"
   254 by (simp add: map_add_def split: option.split)
   255 
   256 lemma map_add_upd[simp]: "f ++ g(x|->y) = (f ++ g)(x|->y)"
   257 by (rule ext) (simp add: map_add_def)
   258 
   259 lemma map_add_upds[simp]: "m1 ++ (m2(xs[\<mapsto>]ys)) = (m1++m2)(xs[\<mapsto>]ys)"
   260 by (simp add: map_upds_def)
   261 
   262 lemma map_of_append[simp]: "map_of (xs @ ys) = map_of ys ++ map_of xs"
   263 unfolding map_add_def
   264 apply (induct xs)
   265  apply simp
   266 apply (rule ext)
   267 apply (simp split add: option.split)
   268 done
   269 
   270 lemma finite_range_map_of_map_add:
   271   "finite (range f) ==> finite (range (f ++ map_of l))"
   272 apply (induct l)
   273  apply (auto simp del: fun_upd_apply)
   274 apply (erule finite_range_updI)
   275 done
   276 
   277 lemma inj_on_map_add_dom [iff]:
   278   "inj_on (m ++ m') (dom m') = inj_on m' (dom m')"
   279 by (fastsimp simp: map_add_def dom_def inj_on_def split: option.splits)
   280 
   281 
   282 subsection {* @{term [source] restrict_map} *}
   283 
   284 lemma restrict_map_to_empty [simp]: "m|`{} = empty"
   285 by (simp add: restrict_map_def)
   286 
   287 lemma restrict_map_empty [simp]: "empty|`D = empty"
   288 by (simp add: restrict_map_def)
   289 
   290 lemma restrict_in [simp]: "x \<in> A \<Longrightarrow> (m|`A) x = m x"
   291 by (simp add: restrict_map_def)
   292 
   293 lemma restrict_out [simp]: "x \<notin> A \<Longrightarrow> (m|`A) x = None"
   294 by (simp add: restrict_map_def)
   295 
   296 lemma ran_restrictD: "y \<in> ran (m|`A) \<Longrightarrow> \<exists>x\<in>A. m x = Some y"
   297 by (auto simp: restrict_map_def ran_def split: split_if_asm)
   298 
   299 lemma dom_restrict [simp]: "dom (m|`A) = dom m \<inter> A"
   300 by (auto simp: restrict_map_def dom_def split: split_if_asm)
   301 
   302 lemma restrict_upd_same [simp]: "m(x\<mapsto>y)|`(-{x}) = m|`(-{x})"
   303 by (rule ext) (auto simp: restrict_map_def)
   304 
   305 lemma restrict_restrict [simp]: "m|`A|`B = m|`(A\<inter>B)"
   306 by (rule ext) (auto simp: restrict_map_def)
   307 
   308 lemma restrict_fun_upd [simp]:
   309   "m(x := y)|`D = (if x \<in> D then (m|`(D-{x}))(x := y) else m|`D)"
   310 by (simp add: restrict_map_def expand_fun_eq)
   311 
   312 lemma fun_upd_None_restrict [simp]:
   313   "(m|`D)(x := None) = (if x:D then m|`(D - {x}) else m|`D)"
   314 by (simp add: restrict_map_def expand_fun_eq)
   315 
   316 lemma fun_upd_restrict: "(m|`D)(x := y) = (m|`(D-{x}))(x := y)"
   317 by (simp add: restrict_map_def expand_fun_eq)
   318 
   319 lemma fun_upd_restrict_conv [simp]:
   320   "x \<in> D \<Longrightarrow> (m|`D)(x := y) = (m|`(D-{x}))(x := y)"
   321 by (simp add: restrict_map_def expand_fun_eq)
   322 
   323 
   324 subsection {* @{term [source] map_upds} *}
   325 
   326 lemma map_upds_Nil1 [simp]: "m([] [|->] bs) = m"
   327 by (simp add: map_upds_def)
   328 
   329 lemma map_upds_Nil2 [simp]: "m(as [|->] []) = m"
   330 by (simp add:map_upds_def)
   331 
   332 lemma map_upds_Cons [simp]: "m(a#as [|->] b#bs) = (m(a|->b))(as[|->]bs)"
   333 by (simp add:map_upds_def)
   334 
   335 lemma map_upds_append1 [simp]: "\<And>ys m. size xs < size ys \<Longrightarrow>
   336   m(xs@[x] [\<mapsto>] ys) = m(xs [\<mapsto>] ys)(x \<mapsto> ys!size xs)"
   337 apply(induct xs)
   338  apply (clarsimp simp add: neq_Nil_conv)
   339 apply (case_tac ys)
   340  apply simp
   341 apply simp
   342 done
   343 
   344 lemma map_upds_list_update2_drop [simp]:
   345   "\<lbrakk>size xs \<le> i; i < size ys\<rbrakk>
   346     \<Longrightarrow> m(xs[\<mapsto>]ys[i:=y]) = m(xs[\<mapsto>]ys)"
   347 apply (induct xs arbitrary: m ys i)
   348  apply simp
   349 apply (case_tac ys)
   350  apply simp
   351 apply (simp split: nat.split)
   352 done
   353 
   354 lemma map_upd_upds_conv_if:
   355   "(f(x|->y))(xs [|->] ys) =
   356    (if x : set(take (length ys) xs) then f(xs [|->] ys)
   357                                     else (f(xs [|->] ys))(x|->y))"
   358 apply (induct xs arbitrary: x y ys f)
   359  apply simp
   360 apply (case_tac ys)
   361  apply (auto split: split_if simp: fun_upd_twist)
   362 done
   363 
   364 lemma map_upds_twist [simp]:
   365   "a ~: set as ==> m(a|->b)(as[|->]bs) = m(as[|->]bs)(a|->b)"
   366 using set_take_subset by (fastsimp simp add: map_upd_upds_conv_if)
   367 
   368 lemma map_upds_apply_nontin [simp]:
   369   "x ~: set xs ==> (f(xs[|->]ys)) x = f x"
   370 apply (induct xs arbitrary: ys)
   371  apply simp
   372 apply (case_tac ys)
   373  apply (auto simp: map_upd_upds_conv_if)
   374 done
   375 
   376 lemma fun_upds_append_drop [simp]:
   377   "size xs = size ys \<Longrightarrow> m(xs@zs[\<mapsto>]ys) = m(xs[\<mapsto>]ys)"
   378 apply (induct xs arbitrary: m ys)
   379  apply simp
   380 apply (case_tac ys)
   381  apply simp_all
   382 done
   383 
   384 lemma fun_upds_append2_drop [simp]:
   385   "size xs = size ys \<Longrightarrow> m(xs[\<mapsto>]ys@zs) = m(xs[\<mapsto>]ys)"
   386 apply (induct xs arbitrary: m ys)
   387  apply simp
   388 apply (case_tac ys)
   389  apply simp_all
   390 done
   391 
   392 
   393 lemma restrict_map_upds[simp]:
   394   "\<lbrakk> length xs = length ys; set xs \<subseteq> D \<rbrakk>
   395     \<Longrightarrow> m(xs [\<mapsto>] ys)|`D = (m|`(D - set xs))(xs [\<mapsto>] ys)"
   396 apply (induct xs arbitrary: m ys)
   397  apply simp
   398 apply (case_tac ys)
   399  apply simp
   400 apply (simp add: Diff_insert [symmetric] insert_absorb)
   401 apply (simp add: map_upd_upds_conv_if)
   402 done
   403 
   404 
   405 subsection {* @{term [source] dom} *}
   406 
   407 lemma domI: "m a = Some b ==> a : dom m"
   408 by(simp add:dom_def)
   409 (* declare domI [intro]? *)
   410 
   411 lemma domD: "a : dom m ==> \<exists>b. m a = Some b"
   412 by (cases "m a") (auto simp add: dom_def)
   413 
   414 lemma domIff [iff, simp del]: "(a : dom m) = (m a ~= None)"
   415 by(simp add:dom_def)
   416 
   417 lemma dom_empty [simp]: "dom empty = {}"
   418 by(simp add:dom_def)
   419 
   420 lemma dom_fun_upd [simp]:
   421   "dom(f(x := y)) = (if y=None then dom f - {x} else insert x (dom f))"
   422 by(auto simp add:dom_def)
   423 
   424 lemma dom_map_of: "dom(map_of xys) = {x. \<exists>y. (x,y) : set xys}"
   425 by (induct xys) (auto simp del: fun_upd_apply)
   426 
   427 lemma dom_map_of_conv_image_fst:
   428   "dom(map_of xys) = fst ` (set xys)"
   429 by(force simp: dom_map_of)
   430 
   431 lemma dom_map_of_zip [simp]: "[| length xs = length ys; distinct xs |] ==>
   432   dom(map_of(zip xs ys)) = set xs"
   433 by (induct rule: list_induct2) simp_all
   434 
   435 lemma finite_dom_map_of: "finite (dom (map_of l))"
   436 by (induct l) (auto simp add: dom_def insert_Collect [symmetric])
   437 
   438 lemma dom_map_upds [simp]:
   439   "dom(m(xs[|->]ys)) = set(take (length ys) xs) Un dom m"
   440 apply (induct xs arbitrary: m ys)
   441  apply simp
   442 apply (case_tac ys)
   443  apply auto
   444 done
   445 
   446 lemma dom_map_add [simp]: "dom(m++n) = dom n Un dom m"
   447 by(auto simp:dom_def)
   448 
   449 lemma dom_override_on [simp]:
   450   "dom(override_on f g A) =
   451     (dom f  - {a. a : A - dom g}) Un {a. a : A Int dom g}"
   452 by(auto simp: dom_def override_on_def)
   453 
   454 lemma map_add_comm: "dom m1 \<inter> dom m2 = {} \<Longrightarrow> m1++m2 = m2++m1"
   455 by (rule ext) (force simp: map_add_def dom_def split: option.split)
   456 
   457 (* Due to John Matthews - could be rephrased with dom *)
   458 lemma finite_map_freshness:
   459   "finite (dom (f :: 'a \<rightharpoonup> 'b)) \<Longrightarrow> \<not> finite (UNIV :: 'a set) \<Longrightarrow>
   460    \<exists>x. f x = None"
   461 by(bestsimp dest:ex_new_if_finite)
   462 
   463 subsection {* @{term [source] ran} *}
   464 
   465 lemma ranI: "m a = Some b ==> b : ran m"
   466 by(auto simp: ran_def)
   467 (* declare ranI [intro]? *)
   468 
   469 lemma ran_empty [simp]: "ran empty = {}"
   470 by(auto simp: ran_def)
   471 
   472 lemma ran_map_upd [simp]: "m a = None ==> ran(m(a|->b)) = insert b (ran m)"
   473 unfolding ran_def
   474 apply auto
   475 apply (subgoal_tac "aa ~= a")
   476  apply auto
   477 done
   478 
   479 
   480 subsection {* @{text "map_le"} *}
   481 
   482 lemma map_le_empty [simp]: "empty \<subseteq>\<^sub>m g"
   483 by (simp add: map_le_def)
   484 
   485 lemma upd_None_map_le [simp]: "f(x := None) \<subseteq>\<^sub>m f"
   486 by (force simp add: map_le_def)
   487 
   488 lemma map_le_upd[simp]: "f \<subseteq>\<^sub>m g ==> f(a := b) \<subseteq>\<^sub>m g(a := b)"
   489 by (fastsimp simp add: map_le_def)
   490 
   491 lemma map_le_imp_upd_le [simp]: "m1 \<subseteq>\<^sub>m m2 \<Longrightarrow> m1(x := None) \<subseteq>\<^sub>m m2(x \<mapsto> y)"
   492 by (force simp add: map_le_def)
   493 
   494 lemma map_le_upds [simp]:
   495   "f \<subseteq>\<^sub>m g ==> f(as [|->] bs) \<subseteq>\<^sub>m g(as [|->] bs)"
   496 apply (induct as arbitrary: f g bs)
   497  apply simp
   498 apply (case_tac bs)
   499  apply auto
   500 done
   501 
   502 lemma map_le_implies_dom_le: "(f \<subseteq>\<^sub>m g) \<Longrightarrow> (dom f \<subseteq> dom g)"
   503 by (fastsimp simp add: map_le_def dom_def)
   504 
   505 lemma map_le_refl [simp]: "f \<subseteq>\<^sub>m f"
   506 by (simp add: map_le_def)
   507 
   508 lemma map_le_trans[trans]: "\<lbrakk> m1 \<subseteq>\<^sub>m m2; m2 \<subseteq>\<^sub>m m3\<rbrakk> \<Longrightarrow> m1 \<subseteq>\<^sub>m m3"
   509 by (auto simp add: map_le_def dom_def)
   510 
   511 lemma map_le_antisym: "\<lbrakk> f \<subseteq>\<^sub>m g; g \<subseteq>\<^sub>m f \<rbrakk> \<Longrightarrow> f = g"
   512 unfolding map_le_def
   513 apply (rule ext)
   514 apply (case_tac "x \<in> dom f", simp)
   515 apply (case_tac "x \<in> dom g", simp, fastsimp)
   516 done
   517 
   518 lemma map_le_map_add [simp]: "f \<subseteq>\<^sub>m (g ++ f)"
   519 by (fastsimp simp add: map_le_def)
   520 
   521 lemma map_le_iff_map_add_commute: "(f \<subseteq>\<^sub>m f ++ g) = (f++g = g++f)"
   522 by(fastsimp simp: map_add_def map_le_def expand_fun_eq split: option.splits)
   523 
   524 lemma map_add_le_mapE: "f++g \<subseteq>\<^sub>m h \<Longrightarrow> g \<subseteq>\<^sub>m h"
   525 by (fastsimp simp add: map_le_def map_add_def dom_def)
   526 
   527 lemma map_add_le_mapI: "\<lbrakk> f \<subseteq>\<^sub>m h; g \<subseteq>\<^sub>m h; f \<subseteq>\<^sub>m f++g \<rbrakk> \<Longrightarrow> f++g \<subseteq>\<^sub>m h"
   528 by (clarsimp simp add: map_le_def map_add_def dom_def split: option.splits)
   529 
   530 end