src/HOL/Complete_Lattices.thy
author blanchet
Wed Feb 12 08:35:57 2014 +0100 (2014-02-12)
changeset 55415 05f5fdb8d093
parent 54414 72949fae4f81
child 56015 57e2cfba9c6e
permissions -rw-r--r--
renamed 'nat_{case,rec}' to '{case,rec}_nat'
     1  (*  Author:     Tobias Nipkow, Lawrence C Paulson and Markus Wenzel; Florian Haftmann, TU Muenchen *)
     2 
     3 header {* Complete lattices *}
     4 
     5 theory Complete_Lattices
     6 imports Set
     7 begin
     8 
     9 notation
    10   less_eq (infix "\<sqsubseteq>" 50) and
    11   less (infix "\<sqsubset>" 50)
    12 
    13 
    14 subsection {* Syntactic infimum and supremum operations *}
    15 
    16 class Inf =
    17   fixes Inf :: "'a set \<Rightarrow> 'a" ("\<Sqinter>_" [900] 900)
    18 begin
    19 
    20 definition INFI :: "'b set \<Rightarrow> ('b \<Rightarrow> 'a) \<Rightarrow> 'a" where
    21   INF_def: "INFI A f = \<Sqinter>(f ` A)"
    22 
    23 lemma INF_image [simp]: "INFI (f`A) g = INFI A (\<lambda>x. g (f x))"
    24   by (simp add: INF_def image_image)
    25 
    26 lemma INF_cong: "A = B \<Longrightarrow> (\<And>x. x \<in> B \<Longrightarrow> C x = D x) \<Longrightarrow> INFI A C = INFI B D"
    27   by (simp add: INF_def image_def)
    28 
    29 end
    30 
    31 class Sup =
    32   fixes Sup :: "'a set \<Rightarrow> 'a" ("\<Squnion>_" [900] 900)
    33 begin
    34 
    35 definition SUPR :: "'b set \<Rightarrow> ('b \<Rightarrow> 'a) \<Rightarrow> 'a" where
    36   SUP_def: "SUPR A f = \<Squnion>(f ` A)"
    37 
    38 lemma SUP_image [simp]: "SUPR (f`A) g = SUPR A (%x. g (f x))"
    39   by (simp add: SUP_def image_image)
    40 
    41 lemma SUP_cong: "A = B \<Longrightarrow> (\<And>x. x \<in> B \<Longrightarrow> C x = D x) \<Longrightarrow> SUPR A C = SUPR B D"
    42   by (simp add: SUP_def image_def)
    43 
    44 end
    45 
    46 text {*
    47   Note: must use names @{const INFI} and @{const SUPR} here instead of
    48   @{text INF} and @{text SUP} to allow the following syntax coexist
    49   with the plain constant names.
    50 *}
    51 
    52 syntax
    53   "_INF1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3INF _./ _)" [0, 10] 10)
    54   "_INF"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3INF _:_./ _)" [0, 0, 10] 10)
    55   "_SUP1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3SUP _./ _)" [0, 10] 10)
    56   "_SUP"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3SUP _:_./ _)" [0, 0, 10] 10)
    57 
    58 syntax (xsymbols)
    59   "_INF1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3\<Sqinter>_./ _)" [0, 10] 10)
    60   "_INF"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3\<Sqinter>_\<in>_./ _)" [0, 0, 10] 10)
    61   "_SUP1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3\<Squnion>_./ _)" [0, 10] 10)
    62   "_SUP"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3\<Squnion>_\<in>_./ _)" [0, 0, 10] 10)
    63 
    64 translations
    65   "INF x y. B"   == "INF x. INF y. B"
    66   "INF x. B"     == "CONST INFI CONST UNIV (%x. B)"
    67   "INF x. B"     == "INF x:CONST UNIV. B"
    68   "INF x:A. B"   == "CONST INFI A (%x. B)"
    69   "SUP x y. B"   == "SUP x. SUP y. B"
    70   "SUP x. B"     == "CONST SUPR CONST UNIV (%x. B)"
    71   "SUP x. B"     == "SUP x:CONST UNIV. B"
    72   "SUP x:A. B"   == "CONST SUPR A (%x. B)"
    73 
    74 print_translation {*
    75   [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax INFI} @{syntax_const "_INF"},
    76     Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax SUPR} @{syntax_const "_SUP"}]
    77 *} -- {* to avoid eta-contraction of body *}
    78 
    79 subsection {* Abstract complete lattices *}
    80 
    81 text {* A complete lattice always has a bottom and a top,
    82 so we include them into the following type class,
    83 along with assumptions that define bottom and top
    84 in terms of infimum and supremum. *}
    85 
    86 class complete_lattice = lattice + Inf + Sup + bot + top +
    87   assumes Inf_lower: "x \<in> A \<Longrightarrow> \<Sqinter>A \<sqsubseteq> x"
    88      and Inf_greatest: "(\<And>x. x \<in> A \<Longrightarrow> z \<sqsubseteq> x) \<Longrightarrow> z \<sqsubseteq> \<Sqinter>A"
    89   assumes Sup_upper: "x \<in> A \<Longrightarrow> x \<sqsubseteq> \<Squnion>A"
    90      and Sup_least: "(\<And>x. x \<in> A \<Longrightarrow> x \<sqsubseteq> z) \<Longrightarrow> \<Squnion>A \<sqsubseteq> z"
    91   assumes Inf_empty [simp]: "\<Sqinter>{} = \<top>"
    92   assumes Sup_empty [simp]: "\<Squnion>{} = \<bottom>"
    93 begin
    94 
    95 subclass bounded_lattice
    96 proof
    97   fix a
    98   show "\<bottom> \<le> a" by (auto intro: Sup_least simp only: Sup_empty [symmetric])
    99   show "a \<le> \<top>" by (auto intro: Inf_greatest simp only: Inf_empty [symmetric])
   100 qed
   101 
   102 lemma dual_complete_lattice:
   103   "class.complete_lattice Sup Inf sup (op \<ge>) (op >) inf \<top> \<bottom>"
   104   by (auto intro!: class.complete_lattice.intro dual_lattice)
   105     (unfold_locales, (fact Inf_empty Sup_empty
   106         Sup_upper Sup_least Inf_lower Inf_greatest)+)
   107 
   108 end
   109 
   110 context complete_lattice
   111 begin
   112 
   113 lemma INF_foundation_dual:
   114   "Sup.SUPR Inf = INFI"
   115   by (simp add: fun_eq_iff INF_def Sup.SUP_def)
   116 
   117 lemma SUP_foundation_dual:
   118   "Inf.INFI Sup = SUPR" by (simp add: fun_eq_iff SUP_def Inf.INF_def)
   119 
   120 lemma Sup_eqI:
   121   "(\<And>y. y \<in> A \<Longrightarrow> y \<le> x) \<Longrightarrow> (\<And>y. (\<And>z. z \<in> A \<Longrightarrow> z \<le> y) \<Longrightarrow> x \<le> y) \<Longrightarrow> \<Squnion>A = x"
   122   by (blast intro: antisym Sup_least Sup_upper)
   123 
   124 lemma Inf_eqI:
   125   "(\<And>i. i \<in> A \<Longrightarrow> x \<le> i) \<Longrightarrow> (\<And>y. (\<And>i. i \<in> A \<Longrightarrow> y \<le> i) \<Longrightarrow> y \<le> x) \<Longrightarrow> \<Sqinter>A = x"
   126   by (blast intro: antisym Inf_greatest Inf_lower)
   127 
   128 lemma SUP_eqI:
   129   "(\<And>i. i \<in> A \<Longrightarrow> f i \<le> x) \<Longrightarrow> (\<And>y. (\<And>i. i \<in> A \<Longrightarrow> f i \<le> y) \<Longrightarrow> x \<le> y) \<Longrightarrow> (\<Squnion>i\<in>A. f i) = x"
   130   unfolding SUP_def by (rule Sup_eqI) auto
   131 
   132 lemma INF_eqI:
   133   "(\<And>i. i \<in> A \<Longrightarrow> x \<le> f i) \<Longrightarrow> (\<And>y. (\<And>i. i \<in> A \<Longrightarrow> f i \<ge> y) \<Longrightarrow> x \<ge> y) \<Longrightarrow> (\<Sqinter>i\<in>A. f i) = x"
   134   unfolding INF_def by (rule Inf_eqI) auto
   135 
   136 lemma INF_lower: "i \<in> A \<Longrightarrow> (\<Sqinter>i\<in>A. f i) \<sqsubseteq> f i"
   137   by (auto simp add: INF_def intro: Inf_lower)
   138 
   139 lemma INF_greatest: "(\<And>i. i \<in> A \<Longrightarrow> u \<sqsubseteq> f i) \<Longrightarrow> u \<sqsubseteq> (\<Sqinter>i\<in>A. f i)"
   140   by (auto simp add: INF_def intro: Inf_greatest)
   141 
   142 lemma SUP_upper: "i \<in> A \<Longrightarrow> f i \<sqsubseteq> (\<Squnion>i\<in>A. f i)"
   143   by (auto simp add: SUP_def intro: Sup_upper)
   144 
   145 lemma SUP_least: "(\<And>i. i \<in> A \<Longrightarrow> f i \<sqsubseteq> u) \<Longrightarrow> (\<Squnion>i\<in>A. f i) \<sqsubseteq> u"
   146   by (auto simp add: SUP_def intro: Sup_least)
   147 
   148 lemma Inf_lower2: "u \<in> A \<Longrightarrow> u \<sqsubseteq> v \<Longrightarrow> \<Sqinter>A \<sqsubseteq> v"
   149   using Inf_lower [of u A] by auto
   150 
   151 lemma INF_lower2: "i \<in> A \<Longrightarrow> f i \<sqsubseteq> u \<Longrightarrow> (\<Sqinter>i\<in>A. f i) \<sqsubseteq> u"
   152   using INF_lower [of i A f] by auto
   153 
   154 lemma Sup_upper2: "u \<in> A \<Longrightarrow> v \<sqsubseteq> u \<Longrightarrow> v \<sqsubseteq> \<Squnion>A"
   155   using Sup_upper [of u A] by auto
   156 
   157 lemma SUP_upper2: "i \<in> A \<Longrightarrow> u \<sqsubseteq> f i \<Longrightarrow> u \<sqsubseteq> (\<Squnion>i\<in>A. f i)"
   158   using SUP_upper [of i A f] by auto
   159 
   160 lemma le_Inf_iff: "b \<sqsubseteq> \<Sqinter>A \<longleftrightarrow> (\<forall>a\<in>A. b \<sqsubseteq> a)"
   161   by (auto intro: Inf_greatest dest: Inf_lower)
   162 
   163 lemma le_INF_iff: "u \<sqsubseteq> (\<Sqinter>i\<in>A. f i) \<longleftrightarrow> (\<forall>i\<in>A. u \<sqsubseteq> f i)"
   164   by (auto simp add: INF_def le_Inf_iff)
   165 
   166 lemma Sup_le_iff: "\<Squnion>A \<sqsubseteq> b \<longleftrightarrow> (\<forall>a\<in>A. a \<sqsubseteq> b)"
   167   by (auto intro: Sup_least dest: Sup_upper)
   168 
   169 lemma SUP_le_iff: "(\<Squnion>i\<in>A. f i) \<sqsubseteq> u \<longleftrightarrow> (\<forall>i\<in>A. f i \<sqsubseteq> u)"
   170   by (auto simp add: SUP_def Sup_le_iff)
   171 
   172 lemma Inf_insert [simp]: "\<Sqinter>insert a A = a \<sqinter> \<Sqinter>A"
   173   by (auto intro: le_infI le_infI1 le_infI2 antisym Inf_greatest Inf_lower)
   174 
   175 lemma INF_insert: "(\<Sqinter>x\<in>insert a A. f x) = f a \<sqinter> INFI A f"
   176   by (simp add: INF_def)
   177 
   178 lemma Sup_insert [simp]: "\<Squnion>insert a A = a \<squnion> \<Squnion>A"
   179   by (auto intro: le_supI le_supI1 le_supI2 antisym Sup_least Sup_upper)
   180 
   181 lemma SUP_insert: "(\<Squnion>x\<in>insert a A. f x) = f a \<squnion> SUPR A f"
   182   by (simp add: SUP_def)
   183 
   184 lemma INF_empty [simp]: "(\<Sqinter>x\<in>{}. f x) = \<top>"
   185   by (simp add: INF_def)
   186 
   187 lemma SUP_empty [simp]: "(\<Squnion>x\<in>{}. f x) = \<bottom>"
   188   by (simp add: SUP_def)
   189 
   190 lemma Inf_UNIV [simp]:
   191   "\<Sqinter>UNIV = \<bottom>"
   192   by (auto intro!: antisym Inf_lower)
   193 
   194 lemma Sup_UNIV [simp]:
   195   "\<Squnion>UNIV = \<top>"
   196   by (auto intro!: antisym Sup_upper)
   197 
   198 lemma Inf_Sup: "\<Sqinter>A = \<Squnion>{b. \<forall>a \<in> A. b \<sqsubseteq> a}"
   199   by (auto intro: antisym Inf_lower Inf_greatest Sup_upper Sup_least)
   200 
   201 lemma Sup_Inf:  "\<Squnion>A = \<Sqinter>{b. \<forall>a \<in> A. a \<sqsubseteq> b}"
   202   by (auto intro: antisym Inf_lower Inf_greatest Sup_upper Sup_least)
   203 
   204 lemma Inf_superset_mono: "B \<subseteq> A \<Longrightarrow> \<Sqinter>A \<sqsubseteq> \<Sqinter>B"
   205   by (auto intro: Inf_greatest Inf_lower)
   206 
   207 lemma Sup_subset_mono: "A \<subseteq> B \<Longrightarrow> \<Squnion>A \<sqsubseteq> \<Squnion>B"
   208   by (auto intro: Sup_least Sup_upper)
   209 
   210 lemma Inf_mono:
   211   assumes "\<And>b. b \<in> B \<Longrightarrow> \<exists>a\<in>A. a \<sqsubseteq> b"
   212   shows "\<Sqinter>A \<sqsubseteq> \<Sqinter>B"
   213 proof (rule Inf_greatest)
   214   fix b assume "b \<in> B"
   215   with assms obtain a where "a \<in> A" and "a \<sqsubseteq> b" by blast
   216   from `a \<in> A` have "\<Sqinter>A \<sqsubseteq> a" by (rule Inf_lower)
   217   with `a \<sqsubseteq> b` show "\<Sqinter>A \<sqsubseteq> b" by auto
   218 qed
   219 
   220 lemma INF_mono:
   221   "(\<And>m. m \<in> B \<Longrightarrow> \<exists>n\<in>A. f n \<sqsubseteq> g m) \<Longrightarrow> (\<Sqinter>n\<in>A. f n) \<sqsubseteq> (\<Sqinter>n\<in>B. g n)"
   222   unfolding INF_def by (rule Inf_mono) fast
   223 
   224 lemma Sup_mono:
   225   assumes "\<And>a. a \<in> A \<Longrightarrow> \<exists>b\<in>B. a \<sqsubseteq> b"
   226   shows "\<Squnion>A \<sqsubseteq> \<Squnion>B"
   227 proof (rule Sup_least)
   228   fix a assume "a \<in> A"
   229   with assms obtain b where "b \<in> B" and "a \<sqsubseteq> b" by blast
   230   from `b \<in> B` have "b \<sqsubseteq> \<Squnion>B" by (rule Sup_upper)
   231   with `a \<sqsubseteq> b` show "a \<sqsubseteq> \<Squnion>B" by auto
   232 qed
   233 
   234 lemma SUP_mono:
   235   "(\<And>n. n \<in> A \<Longrightarrow> \<exists>m\<in>B. f n \<sqsubseteq> g m) \<Longrightarrow> (\<Squnion>n\<in>A. f n) \<sqsubseteq> (\<Squnion>n\<in>B. g n)"
   236   unfolding SUP_def by (rule Sup_mono) fast
   237 
   238 lemma INF_superset_mono:
   239   "B \<subseteq> A \<Longrightarrow> (\<And>x. x \<in> B \<Longrightarrow> f x \<sqsubseteq> g x) \<Longrightarrow> (\<Sqinter>x\<in>A. f x) \<sqsubseteq> (\<Sqinter>x\<in>B. g x)"
   240   -- {* The last inclusion is POSITIVE! *}
   241   by (blast intro: INF_mono dest: subsetD)
   242 
   243 lemma SUP_subset_mono:
   244   "A \<subseteq> B \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> f x \<sqsubseteq> g x) \<Longrightarrow> (\<Squnion>x\<in>A. f x) \<sqsubseteq> (\<Squnion>x\<in>B. g x)"
   245   by (blast intro: SUP_mono dest: subsetD)
   246 
   247 lemma Inf_less_eq:
   248   assumes "\<And>v. v \<in> A \<Longrightarrow> v \<sqsubseteq> u"
   249     and "A \<noteq> {}"
   250   shows "\<Sqinter>A \<sqsubseteq> u"
   251 proof -
   252   from `A \<noteq> {}` obtain v where "v \<in> A" by blast
   253   moreover from `v \<in> A` assms(1) have "v \<sqsubseteq> u" by blast
   254   ultimately show ?thesis by (rule Inf_lower2)
   255 qed
   256 
   257 lemma less_eq_Sup:
   258   assumes "\<And>v. v \<in> A \<Longrightarrow> u \<sqsubseteq> v"
   259     and "A \<noteq> {}"
   260   shows "u \<sqsubseteq> \<Squnion>A"
   261 proof -
   262   from `A \<noteq> {}` obtain v where "v \<in> A" by blast
   263   moreover from `v \<in> A` assms(1) have "u \<sqsubseteq> v" by blast
   264   ultimately show ?thesis by (rule Sup_upper2)
   265 qed
   266 
   267 lemma SUPR_eq:
   268   assumes "\<And>i. i \<in> A \<Longrightarrow> \<exists>j\<in>B. f i \<le> g j"
   269   assumes "\<And>j. j \<in> B \<Longrightarrow> \<exists>i\<in>A. g j \<le> f i"
   270   shows "(SUP i:A. f i) = (SUP j:B. g j)"
   271   by (intro antisym SUP_least) (blast intro: SUP_upper2 dest: assms)+
   272 
   273 lemma INFI_eq:
   274   assumes "\<And>i. i \<in> A \<Longrightarrow> \<exists>j\<in>B. f i \<ge> g j"
   275   assumes "\<And>j. j \<in> B \<Longrightarrow> \<exists>i\<in>A. g j \<ge> f i"
   276   shows "(INF i:A. f i) = (INF j:B. g j)"
   277   by (intro antisym INF_greatest) (blast intro: INF_lower2 dest: assms)+
   278 
   279 lemma less_eq_Inf_inter: "\<Sqinter>A \<squnion> \<Sqinter>B \<sqsubseteq> \<Sqinter>(A \<inter> B)"
   280   by (auto intro: Inf_greatest Inf_lower)
   281 
   282 lemma Sup_inter_less_eq: "\<Squnion>(A \<inter> B) \<sqsubseteq> \<Squnion>A \<sqinter> \<Squnion>B "
   283   by (auto intro: Sup_least Sup_upper)
   284 
   285 lemma Inf_union_distrib: "\<Sqinter>(A \<union> B) = \<Sqinter>A \<sqinter> \<Sqinter>B"
   286   by (rule antisym) (auto intro: Inf_greatest Inf_lower le_infI1 le_infI2)
   287 
   288 lemma INF_union:
   289   "(\<Sqinter>i \<in> A \<union> B. M i) = (\<Sqinter>i \<in> A. M i) \<sqinter> (\<Sqinter>i\<in>B. M i)"
   290   by (auto intro!: antisym INF_mono intro: le_infI1 le_infI2 INF_greatest INF_lower)
   291 
   292 lemma Sup_union_distrib: "\<Squnion>(A \<union> B) = \<Squnion>A \<squnion> \<Squnion>B"
   293   by (rule antisym) (auto intro: Sup_least Sup_upper le_supI1 le_supI2)
   294 
   295 lemma SUP_union:
   296   "(\<Squnion>i \<in> A \<union> B. M i) = (\<Squnion>i \<in> A. M i) \<squnion> (\<Squnion>i\<in>B. M i)"
   297   by (auto intro!: antisym SUP_mono intro: le_supI1 le_supI2 SUP_least SUP_upper)
   298 
   299 lemma INF_inf_distrib: "(\<Sqinter>a\<in>A. f a) \<sqinter> (\<Sqinter>a\<in>A. g a) = (\<Sqinter>a\<in>A. f a \<sqinter> g a)"
   300   by (rule antisym) (rule INF_greatest, auto intro: le_infI1 le_infI2 INF_lower INF_mono)
   301 
   302 lemma SUP_sup_distrib: "(\<Squnion>a\<in>A. f a) \<squnion> (\<Squnion>a\<in>A. g a) = (\<Squnion>a\<in>A. f a \<squnion> g a)" (is "?L = ?R")
   303 proof (rule antisym)
   304   show "?L \<le> ?R" by (auto intro: le_supI1 le_supI2 SUP_upper SUP_mono)
   305 next
   306   show "?R \<le> ?L" by (rule SUP_least) (auto intro: le_supI1 le_supI2 SUP_upper)
   307 qed
   308 
   309 lemma Inf_top_conv [simp]:
   310   "\<Sqinter>A = \<top> \<longleftrightarrow> (\<forall>x\<in>A. x = \<top>)"
   311   "\<top> = \<Sqinter>A \<longleftrightarrow> (\<forall>x\<in>A. x = \<top>)"
   312 proof -
   313   show "\<Sqinter>A = \<top> \<longleftrightarrow> (\<forall>x\<in>A. x = \<top>)"
   314   proof
   315     assume "\<forall>x\<in>A. x = \<top>"
   316     then have "A = {} \<or> A = {\<top>}" by auto
   317     then show "\<Sqinter>A = \<top>" by auto
   318   next
   319     assume "\<Sqinter>A = \<top>"
   320     show "\<forall>x\<in>A. x = \<top>"
   321     proof (rule ccontr)
   322       assume "\<not> (\<forall>x\<in>A. x = \<top>)"
   323       then obtain x where "x \<in> A" and "x \<noteq> \<top>" by blast
   324       then obtain B where "A = insert x B" by blast
   325       with `\<Sqinter>A = \<top>` `x \<noteq> \<top>` show False by simp
   326     qed
   327   qed
   328   then show "\<top> = \<Sqinter>A \<longleftrightarrow> (\<forall>x\<in>A. x = \<top>)" by auto
   329 qed
   330 
   331 lemma INF_top_conv [simp]:
   332  "(\<Sqinter>x\<in>A. B x) = \<top> \<longleftrightarrow> (\<forall>x\<in>A. B x = \<top>)"
   333  "\<top> = (\<Sqinter>x\<in>A. B x) \<longleftrightarrow> (\<forall>x\<in>A. B x = \<top>)"
   334   by (auto simp add: INF_def)
   335 
   336 lemma Sup_bot_conv [simp]:
   337   "\<Squnion>A = \<bottom> \<longleftrightarrow> (\<forall>x\<in>A. x = \<bottom>)" (is ?P)
   338   "\<bottom> = \<Squnion>A \<longleftrightarrow> (\<forall>x\<in>A. x = \<bottom>)" (is ?Q)
   339   using dual_complete_lattice
   340   by (rule complete_lattice.Inf_top_conv)+
   341 
   342 lemma SUP_bot_conv [simp]:
   343  "(\<Squnion>x\<in>A. B x) = \<bottom> \<longleftrightarrow> (\<forall>x\<in>A. B x = \<bottom>)"
   344  "\<bottom> = (\<Squnion>x\<in>A. B x) \<longleftrightarrow> (\<forall>x\<in>A. B x = \<bottom>)"
   345   by (auto simp add: SUP_def)
   346 
   347 lemma INF_const [simp]: "A \<noteq> {} \<Longrightarrow> (\<Sqinter>i\<in>A. f) = f"
   348   by (auto intro: antisym INF_lower INF_greatest)
   349 
   350 lemma SUP_const [simp]: "A \<noteq> {} \<Longrightarrow> (\<Squnion>i\<in>A. f) = f"
   351   by (auto intro: antisym SUP_upper SUP_least)
   352 
   353 lemma INF_top [simp]: "(\<Sqinter>x\<in>A. \<top>) = \<top>"
   354   by (cases "A = {}") simp_all
   355 
   356 lemma SUP_bot [simp]: "(\<Squnion>x\<in>A. \<bottom>) = \<bottom>"
   357   by (cases "A = {}") simp_all
   358 
   359 lemma INF_commute: "(\<Sqinter>i\<in>A. \<Sqinter>j\<in>B. f i j) = (\<Sqinter>j\<in>B. \<Sqinter>i\<in>A. f i j)"
   360   by (iprover intro: INF_lower INF_greatest order_trans antisym)
   361 
   362 lemma SUP_commute: "(\<Squnion>i\<in>A. \<Squnion>j\<in>B. f i j) = (\<Squnion>j\<in>B. \<Squnion>i\<in>A. f i j)"
   363   by (iprover intro: SUP_upper SUP_least order_trans antisym)
   364 
   365 lemma INF_absorb:
   366   assumes "k \<in> I"
   367   shows "A k \<sqinter> (\<Sqinter>i\<in>I. A i) = (\<Sqinter>i\<in>I. A i)"
   368 proof -
   369   from assms obtain J where "I = insert k J" by blast
   370   then show ?thesis by (simp add: INF_insert)
   371 qed
   372 
   373 lemma SUP_absorb:
   374   assumes "k \<in> I"
   375   shows "A k \<squnion> (\<Squnion>i\<in>I. A i) = (\<Squnion>i\<in>I. A i)"
   376 proof -
   377   from assms obtain J where "I = insert k J" by blast
   378   then show ?thesis by (simp add: SUP_insert)
   379 qed
   380 
   381 lemma INF_constant:
   382   "(\<Sqinter>y\<in>A. c) = (if A = {} then \<top> else c)"
   383   by simp
   384 
   385 lemma SUP_constant:
   386   "(\<Squnion>y\<in>A. c) = (if A = {} then \<bottom> else c)"
   387   by simp
   388 
   389 lemma less_INF_D:
   390   assumes "y < (\<Sqinter>i\<in>A. f i)" "i \<in> A" shows "y < f i"
   391 proof -
   392   note `y < (\<Sqinter>i\<in>A. f i)`
   393   also have "(\<Sqinter>i\<in>A. f i) \<le> f i" using `i \<in> A`
   394     by (rule INF_lower)
   395   finally show "y < f i" .
   396 qed
   397 
   398 lemma SUP_lessD:
   399   assumes "(\<Squnion>i\<in>A. f i) < y" "i \<in> A" shows "f i < y"
   400 proof -
   401   have "f i \<le> (\<Squnion>i\<in>A. f i)" using `i \<in> A`
   402     by (rule SUP_upper)
   403   also note `(\<Squnion>i\<in>A. f i) < y`
   404   finally show "f i < y" .
   405 qed
   406 
   407 lemma INF_UNIV_bool_expand:
   408   "(\<Sqinter>b. A b) = A True \<sqinter> A False"
   409   by (simp add: UNIV_bool INF_insert inf_commute)
   410 
   411 lemma SUP_UNIV_bool_expand:
   412   "(\<Squnion>b. A b) = A True \<squnion> A False"
   413   by (simp add: UNIV_bool SUP_insert sup_commute)
   414 
   415 lemma Inf_le_Sup: "A \<noteq> {} \<Longrightarrow> Inf A \<le> Sup A"
   416   by (blast intro: Sup_upper2 Inf_lower ex_in_conv)
   417 
   418 lemma INF_le_SUP: "A \<noteq> {} \<Longrightarrow> INFI A f \<le> SUPR A f"
   419   unfolding INF_def SUP_def by (rule Inf_le_Sup) auto
   420 
   421 lemma SUP_eq_const:
   422   "I \<noteq> {} \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> f i = x) \<Longrightarrow> SUPR I f = x"
   423   by (auto intro: SUP_eqI)
   424 
   425 lemma INF_eq_const:
   426   "I \<noteq> {} \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> f i = x) \<Longrightarrow> INFI I f = x"
   427   by (auto intro: INF_eqI)
   428 
   429 lemma SUP_eq_iff:
   430   "I \<noteq> {} \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> c \<le> f i) \<Longrightarrow> (SUPR I f = c) \<longleftrightarrow> (\<forall>i\<in>I. f i = c)"
   431   using SUP_eq_const[of I f c] SUP_upper[of _ I f] by (auto intro: antisym)
   432 
   433 lemma INF_eq_iff:
   434   "I \<noteq> {} \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> f i \<le> c) \<Longrightarrow> (INFI I f = c) \<longleftrightarrow> (\<forall>i\<in>I. f i = c)"
   435   using INF_eq_const[of I f c] INF_lower[of _ I f] by (auto intro: antisym)
   436 
   437 end
   438 
   439 class complete_distrib_lattice = complete_lattice +
   440   assumes sup_Inf: "a \<squnion> \<Sqinter>B = (\<Sqinter>b\<in>B. a \<squnion> b)"
   441   assumes inf_Sup: "a \<sqinter> \<Squnion>B = (\<Squnion>b\<in>B. a \<sqinter> b)"
   442 begin
   443 
   444 lemma sup_INF:
   445   "a \<squnion> (\<Sqinter>b\<in>B. f b) = (\<Sqinter>b\<in>B. a \<squnion> f b)"
   446   by (simp add: INF_def sup_Inf image_image)
   447 
   448 lemma inf_SUP:
   449   "a \<sqinter> (\<Squnion>b\<in>B. f b) = (\<Squnion>b\<in>B. a \<sqinter> f b)"
   450   by (simp add: SUP_def inf_Sup image_image)
   451 
   452 lemma dual_complete_distrib_lattice:
   453   "class.complete_distrib_lattice Sup Inf sup (op \<ge>) (op >) inf \<top> \<bottom>"
   454   apply (rule class.complete_distrib_lattice.intro)
   455   apply (fact dual_complete_lattice)
   456   apply (rule class.complete_distrib_lattice_axioms.intro)
   457   apply (simp_all only: INF_foundation_dual SUP_foundation_dual inf_Sup sup_Inf)
   458   done
   459 
   460 subclass distrib_lattice proof
   461   fix a b c
   462   from sup_Inf have "a \<squnion> \<Sqinter>{b, c} = (\<Sqinter>d\<in>{b, c}. a \<squnion> d)" .
   463   then show "a \<squnion> b \<sqinter> c = (a \<squnion> b) \<sqinter> (a \<squnion> c)" by (simp add: INF_def)
   464 qed
   465 
   466 lemma Inf_sup:
   467   "\<Sqinter>B \<squnion> a = (\<Sqinter>b\<in>B. b \<squnion> a)"
   468   by (simp add: sup_Inf sup_commute)
   469 
   470 lemma Sup_inf:
   471   "\<Squnion>B \<sqinter> a = (\<Squnion>b\<in>B. b \<sqinter> a)"
   472   by (simp add: inf_Sup inf_commute)
   473 
   474 lemma INF_sup: 
   475   "(\<Sqinter>b\<in>B. f b) \<squnion> a = (\<Sqinter>b\<in>B. f b \<squnion> a)"
   476   by (simp add: sup_INF sup_commute)
   477 
   478 lemma SUP_inf:
   479   "(\<Squnion>b\<in>B. f b) \<sqinter> a = (\<Squnion>b\<in>B. f b \<sqinter> a)"
   480   by (simp add: inf_SUP inf_commute)
   481 
   482 lemma Inf_sup_eq_top_iff:
   483   "(\<Sqinter>B \<squnion> a = \<top>) \<longleftrightarrow> (\<forall>b\<in>B. b \<squnion> a = \<top>)"
   484   by (simp only: Inf_sup INF_top_conv)
   485 
   486 lemma Sup_inf_eq_bot_iff:
   487   "(\<Squnion>B \<sqinter> a = \<bottom>) \<longleftrightarrow> (\<forall>b\<in>B. b \<sqinter> a = \<bottom>)"
   488   by (simp only: Sup_inf SUP_bot_conv)
   489 
   490 lemma INF_sup_distrib2:
   491   "(\<Sqinter>a\<in>A. f a) \<squnion> (\<Sqinter>b\<in>B. g b) = (\<Sqinter>a\<in>A. \<Sqinter>b\<in>B. f a \<squnion> g b)"
   492   by (subst INF_commute) (simp add: sup_INF INF_sup)
   493 
   494 lemma SUP_inf_distrib2:
   495   "(\<Squnion>a\<in>A. f a) \<sqinter> (\<Squnion>b\<in>B. g b) = (\<Squnion>a\<in>A. \<Squnion>b\<in>B. f a \<sqinter> g b)"
   496   by (subst SUP_commute) (simp add: inf_SUP SUP_inf)
   497 
   498 end
   499 
   500 class complete_boolean_algebra = boolean_algebra + complete_distrib_lattice
   501 begin
   502 
   503 lemma dual_complete_boolean_algebra:
   504   "class.complete_boolean_algebra Sup Inf sup (op \<ge>) (op >) inf \<top> \<bottom> (\<lambda>x y. x \<squnion> - y) uminus"
   505   by (rule class.complete_boolean_algebra.intro, rule dual_complete_distrib_lattice, rule dual_boolean_algebra)
   506 
   507 lemma uminus_Inf:
   508   "- (\<Sqinter>A) = \<Squnion>(uminus ` A)"
   509 proof (rule antisym)
   510   show "- \<Sqinter>A \<le> \<Squnion>(uminus ` A)"
   511     by (rule compl_le_swap2, rule Inf_greatest, rule compl_le_swap2, rule Sup_upper) simp
   512   show "\<Squnion>(uminus ` A) \<le> - \<Sqinter>A"
   513     by (rule Sup_least, rule compl_le_swap1, rule Inf_lower) auto
   514 qed
   515 
   516 lemma uminus_INF: "- (\<Sqinter>x\<in>A. B x) = (\<Squnion>x\<in>A. - B x)"
   517   by (simp add: INF_def SUP_def uminus_Inf image_image)
   518 
   519 lemma uminus_Sup:
   520   "- (\<Squnion>A) = \<Sqinter>(uminus ` A)"
   521 proof -
   522   have "\<Squnion>A = - \<Sqinter>(uminus ` A)" by (simp add: image_image uminus_Inf)
   523   then show ?thesis by simp
   524 qed
   525   
   526 lemma uminus_SUP: "- (\<Squnion>x\<in>A. B x) = (\<Sqinter>x\<in>A. - B x)"
   527   by (simp add: INF_def SUP_def uminus_Sup image_image)
   528 
   529 end
   530 
   531 class complete_linorder = linorder + complete_lattice
   532 begin
   533 
   534 lemma dual_complete_linorder:
   535   "class.complete_linorder Sup Inf sup (op \<ge>) (op >) inf \<top> \<bottom>"
   536   by (rule class.complete_linorder.intro, rule dual_complete_lattice, rule dual_linorder)
   537 
   538 lemma complete_linorder_inf_min: "inf = min"
   539   by (auto intro: antisym simp add: min_def fun_eq_iff)
   540 
   541 lemma complete_linorder_sup_max: "sup = max"
   542   by (auto intro: antisym simp add: max_def fun_eq_iff)
   543 
   544 lemma Inf_less_iff:
   545   "\<Sqinter>S \<sqsubset> a \<longleftrightarrow> (\<exists>x\<in>S. x \<sqsubset> a)"
   546   unfolding not_le [symmetric] le_Inf_iff by auto
   547 
   548 lemma INF_less_iff:
   549   "(\<Sqinter>i\<in>A. f i) \<sqsubset> a \<longleftrightarrow> (\<exists>x\<in>A. f x \<sqsubset> a)"
   550   unfolding INF_def Inf_less_iff by auto
   551 
   552 lemma less_Sup_iff:
   553   "a \<sqsubset> \<Squnion>S \<longleftrightarrow> (\<exists>x\<in>S. a \<sqsubset> x)"
   554   unfolding not_le [symmetric] Sup_le_iff by auto
   555 
   556 lemma less_SUP_iff:
   557   "a \<sqsubset> (\<Squnion>i\<in>A. f i) \<longleftrightarrow> (\<exists>x\<in>A. a \<sqsubset> f x)"
   558   unfolding SUP_def less_Sup_iff by auto
   559 
   560 lemma Sup_eq_top_iff [simp]:
   561   "\<Squnion>A = \<top> \<longleftrightarrow> (\<forall>x<\<top>. \<exists>i\<in>A. x < i)"
   562 proof
   563   assume *: "\<Squnion>A = \<top>"
   564   show "(\<forall>x<\<top>. \<exists>i\<in>A. x < i)" unfolding * [symmetric]
   565   proof (intro allI impI)
   566     fix x assume "x < \<Squnion>A" then show "\<exists>i\<in>A. x < i"
   567       unfolding less_Sup_iff by auto
   568   qed
   569 next
   570   assume *: "\<forall>x<\<top>. \<exists>i\<in>A. x < i"
   571   show "\<Squnion>A = \<top>"
   572   proof (rule ccontr)
   573     assume "\<Squnion>A \<noteq> \<top>"
   574     with top_greatest [of "\<Squnion>A"]
   575     have "\<Squnion>A < \<top>" unfolding le_less by auto
   576     then have "\<Squnion>A < \<Squnion>A"
   577       using * unfolding less_Sup_iff by auto
   578     then show False by auto
   579   qed
   580 qed
   581 
   582 lemma SUP_eq_top_iff [simp]:
   583   "(\<Squnion>i\<in>A. f i) = \<top> \<longleftrightarrow> (\<forall>x<\<top>. \<exists>i\<in>A. x < f i)"
   584   unfolding SUP_def by auto
   585 
   586 lemma Inf_eq_bot_iff [simp]:
   587   "\<Sqinter>A = \<bottom> \<longleftrightarrow> (\<forall>x>\<bottom>. \<exists>i\<in>A. i < x)"
   588   using dual_complete_linorder
   589   by (rule complete_linorder.Sup_eq_top_iff)
   590 
   591 lemma INF_eq_bot_iff [simp]:
   592   "(\<Sqinter>i\<in>A. f i) = \<bottom> \<longleftrightarrow> (\<forall>x>\<bottom>. \<exists>i\<in>A. f i < x)"
   593   unfolding INF_def by auto
   594 
   595 lemma le_Sup_iff: "x \<le> \<Squnion>A \<longleftrightarrow> (\<forall>y<x. \<exists>a\<in>A. y < a)"
   596 proof safe
   597   fix y assume "x \<le> \<Squnion>A" "y < x"
   598   then have "y < \<Squnion>A" by auto
   599   then show "\<exists>a\<in>A. y < a"
   600     unfolding less_Sup_iff .
   601 qed (auto elim!: allE[of _ "\<Squnion>A"] simp add: not_le[symmetric] Sup_upper)
   602 
   603 lemma le_SUP_iff: "x \<le> SUPR A f \<longleftrightarrow> (\<forall>y<x. \<exists>i\<in>A. y < f i)"
   604   unfolding le_Sup_iff SUP_def by simp
   605 
   606 lemma Inf_le_iff: "\<Sqinter>A \<le> x \<longleftrightarrow> (\<forall>y>x. \<exists>a\<in>A. y > a)"
   607 proof safe
   608   fix y assume "x \<ge> \<Sqinter>A" "y > x"
   609   then have "y > \<Sqinter>A" by auto
   610   then show "\<exists>a\<in>A. y > a"
   611     unfolding Inf_less_iff .
   612 qed (auto elim!: allE[of _ "\<Sqinter>A"] simp add: not_le[symmetric] Inf_lower)
   613 
   614 lemma INF_le_iff:
   615   "INFI A f \<le> x \<longleftrightarrow> (\<forall>y>x. \<exists>i\<in>A. y > f i)"
   616   unfolding Inf_le_iff INF_def by simp
   617 
   618 subclass complete_distrib_lattice
   619 proof
   620   fix a and B
   621   show "a \<squnion> \<Sqinter>B = (\<Sqinter>b\<in>B. a \<squnion> b)" and "a \<sqinter> \<Squnion>B = (\<Squnion>b\<in>B. a \<sqinter> b)"
   622     by (safe intro!: INF_eqI [symmetric] sup_mono Inf_lower SUP_eqI [symmetric] inf_mono Sup_upper)
   623       (auto simp: not_less [symmetric] Inf_less_iff less_Sup_iff
   624         le_max_iff_disj complete_linorder_sup_max min_le_iff_disj complete_linorder_inf_min)
   625 qed
   626 
   627 end
   628 
   629 
   630 subsection {* Complete lattice on @{typ bool} *}
   631 
   632 instantiation bool :: complete_lattice
   633 begin
   634 
   635 definition
   636   [simp, code]: "\<Sqinter>A \<longleftrightarrow> False \<notin> A"
   637 
   638 definition
   639   [simp, code]: "\<Squnion>A \<longleftrightarrow> True \<in> A"
   640 
   641 instance proof
   642 qed (auto intro: bool_induct)
   643 
   644 end
   645 
   646 lemma not_False_in_image_Ball [simp]:
   647   "False \<notin> P ` A \<longleftrightarrow> Ball A P"
   648   by auto
   649 
   650 lemma True_in_image_Bex [simp]:
   651   "True \<in> P ` A \<longleftrightarrow> Bex A P"
   652   by auto
   653 
   654 lemma INF_bool_eq [simp]:
   655   "INFI = Ball"
   656   by (simp add: fun_eq_iff INF_def)
   657 
   658 lemma SUP_bool_eq [simp]:
   659   "SUPR = Bex"
   660   by (simp add: fun_eq_iff SUP_def)
   661 
   662 instance bool :: complete_boolean_algebra proof
   663 qed (auto intro: bool_induct)
   664 
   665 
   666 subsection {* Complete lattice on @{typ "_ \<Rightarrow> _"} *}
   667 
   668 instantiation "fun" :: (type, complete_lattice) complete_lattice
   669 begin
   670 
   671 definition
   672   "\<Sqinter>A = (\<lambda>x. \<Sqinter>f\<in>A. f x)"
   673 
   674 lemma Inf_apply [simp, code]:
   675   "(\<Sqinter>A) x = (\<Sqinter>f\<in>A. f x)"
   676   by (simp add: Inf_fun_def)
   677 
   678 definition
   679   "\<Squnion>A = (\<lambda>x. \<Squnion>f\<in>A. f x)"
   680 
   681 lemma Sup_apply [simp, code]:
   682   "(\<Squnion>A) x = (\<Squnion>f\<in>A. f x)"
   683   by (simp add: Sup_fun_def)
   684 
   685 instance proof
   686 qed (auto simp add: le_fun_def intro: INF_lower INF_greatest SUP_upper SUP_least)
   687 
   688 end
   689 
   690 lemma INF_apply [simp]:
   691   "(\<Sqinter>y\<in>A. f y) x = (\<Sqinter>y\<in>A. f y x)"
   692   by (auto intro: arg_cong [of _ _ Inf] simp add: INF_def)
   693 
   694 lemma SUP_apply [simp]:
   695   "(\<Squnion>y\<in>A. f y) x = (\<Squnion>y\<in>A. f y x)"
   696   by (auto intro: arg_cong [of _ _ Sup] simp add: SUP_def)
   697 
   698 instance "fun" :: (type, complete_distrib_lattice) complete_distrib_lattice proof
   699 qed (auto simp add: INF_def SUP_def inf_Sup sup_Inf image_image)
   700 
   701 instance "fun" :: (type, complete_boolean_algebra) complete_boolean_algebra ..
   702 
   703 
   704 subsection {* Complete lattice on unary and binary predicates *}
   705 
   706 lemma INF1_iff: "(\<Sqinter>x\<in>A. B x) b = (\<forall>x\<in>A. B x b)"
   707   by simp
   708 
   709 lemma INF2_iff: "(\<Sqinter>x\<in>A. B x) b c = (\<forall>x\<in>A. B x b c)"
   710   by simp
   711 
   712 lemma INF1_I: "(\<And>x. x \<in> A \<Longrightarrow> B x b) \<Longrightarrow> (\<Sqinter>x\<in>A. B x) b"
   713   by auto
   714 
   715 lemma INF2_I: "(\<And>x. x \<in> A \<Longrightarrow> B x b c) \<Longrightarrow> (\<Sqinter>x\<in>A. B x) b c"
   716   by auto
   717 
   718 lemma INF1_D: "(\<Sqinter>x\<in>A. B x) b \<Longrightarrow> a \<in> A \<Longrightarrow> B a b"
   719   by auto
   720 
   721 lemma INF2_D: "(\<Sqinter>x\<in>A. B x) b c \<Longrightarrow> a \<in> A \<Longrightarrow> B a b c"
   722   by auto
   723 
   724 lemma INF1_E: "(\<Sqinter>x\<in>A. B x) b \<Longrightarrow> (B a b \<Longrightarrow> R) \<Longrightarrow> (a \<notin> A \<Longrightarrow> R) \<Longrightarrow> R"
   725   by auto
   726 
   727 lemma INF2_E: "(\<Sqinter>x\<in>A. B x) b c \<Longrightarrow> (B a b c \<Longrightarrow> R) \<Longrightarrow> (a \<notin> A \<Longrightarrow> R) \<Longrightarrow> R"
   728   by auto
   729 
   730 lemma SUP1_iff: "(\<Squnion>x\<in>A. B x) b = (\<exists>x\<in>A. B x b)"
   731   by simp
   732 
   733 lemma SUP2_iff: "(\<Squnion>x\<in>A. B x) b c = (\<exists>x\<in>A. B x b c)"
   734   by simp
   735 
   736 lemma SUP1_I: "a \<in> A \<Longrightarrow> B a b \<Longrightarrow> (\<Squnion>x\<in>A. B x) b"
   737   by auto
   738 
   739 lemma SUP2_I: "a \<in> A \<Longrightarrow> B a b c \<Longrightarrow> (\<Squnion>x\<in>A. B x) b c"
   740   by auto
   741 
   742 lemma SUP1_E: "(\<Squnion>x\<in>A. B x) b \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> B x b \<Longrightarrow> R) \<Longrightarrow> R"
   743   by auto
   744 
   745 lemma SUP2_E: "(\<Squnion>x\<in>A. B x) b c \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> B x b c \<Longrightarrow> R) \<Longrightarrow> R"
   746   by auto
   747 
   748 
   749 subsection {* Complete lattice on @{typ "_ set"} *}
   750 
   751 instantiation "set" :: (type) complete_lattice
   752 begin
   753 
   754 definition
   755   "\<Sqinter>A = {x. \<Sqinter>((\<lambda>B. x \<in> B) ` A)}"
   756 
   757 definition
   758   "\<Squnion>A = {x. \<Squnion>((\<lambda>B. x \<in> B) ` A)}"
   759 
   760 instance proof
   761 qed (auto simp add: less_eq_set_def Inf_set_def Sup_set_def le_fun_def)
   762 
   763 end
   764 
   765 instance "set" :: (type) complete_boolean_algebra
   766 proof
   767 qed (auto simp add: INF_def SUP_def Inf_set_def Sup_set_def image_def)
   768   
   769 
   770 subsubsection {* Inter *}
   771 
   772 abbreviation Inter :: "'a set set \<Rightarrow> 'a set" where
   773   "Inter S \<equiv> \<Sqinter>S"
   774   
   775 notation (xsymbols)
   776   Inter  ("\<Inter>_" [900] 900)
   777 
   778 lemma Inter_eq:
   779   "\<Inter>A = {x. \<forall>B \<in> A. x \<in> B}"
   780 proof (rule set_eqI)
   781   fix x
   782   have "(\<forall>Q\<in>{P. \<exists>B\<in>A. P \<longleftrightarrow> x \<in> B}. Q) \<longleftrightarrow> (\<forall>B\<in>A. x \<in> B)"
   783     by auto
   784   then show "x \<in> \<Inter>A \<longleftrightarrow> x \<in> {x. \<forall>B \<in> A. x \<in> B}"
   785     by (simp add: Inf_set_def image_def)
   786 qed
   787 
   788 lemma Inter_iff [simp]: "A \<in> \<Inter>C \<longleftrightarrow> (\<forall>X\<in>C. A \<in> X)"
   789   by (unfold Inter_eq) blast
   790 
   791 lemma InterI [intro!]: "(\<And>X. X \<in> C \<Longrightarrow> A \<in> X) \<Longrightarrow> A \<in> \<Inter>C"
   792   by (simp add: Inter_eq)
   793 
   794 text {*
   795   \medskip A ``destruct'' rule -- every @{term X} in @{term C}
   796   contains @{term A} as an element, but @{prop "A \<in> X"} can hold when
   797   @{prop "X \<in> C"} does not!  This rule is analogous to @{text spec}.
   798 *}
   799 
   800 lemma InterD [elim, Pure.elim]: "A \<in> \<Inter>C \<Longrightarrow> X \<in> C \<Longrightarrow> A \<in> X"
   801   by auto
   802 
   803 lemma InterE [elim]: "A \<in> \<Inter>C \<Longrightarrow> (X \<notin> C \<Longrightarrow> R) \<Longrightarrow> (A \<in> X \<Longrightarrow> R) \<Longrightarrow> R"
   804   -- {* ``Classical'' elimination rule -- does not require proving
   805     @{prop "X \<in> C"}. *}
   806   by (unfold Inter_eq) blast
   807 
   808 lemma Inter_lower: "B \<in> A \<Longrightarrow> \<Inter>A \<subseteq> B"
   809   by (fact Inf_lower)
   810 
   811 lemma Inter_subset:
   812   "(\<And>X. X \<in> A \<Longrightarrow> X \<subseteq> B) \<Longrightarrow> A \<noteq> {} \<Longrightarrow> \<Inter>A \<subseteq> B"
   813   by (fact Inf_less_eq)
   814 
   815 lemma Inter_greatest: "(\<And>X. X \<in> A \<Longrightarrow> C \<subseteq> X) \<Longrightarrow> C \<subseteq> Inter A"
   816   by (fact Inf_greatest)
   817 
   818 lemma Inter_empty: "\<Inter>{} = UNIV"
   819   by (fact Inf_empty) (* already simp *)
   820 
   821 lemma Inter_UNIV: "\<Inter>UNIV = {}"
   822   by (fact Inf_UNIV) (* already simp *)
   823 
   824 lemma Inter_insert: "\<Inter>(insert a B) = a \<inter> \<Inter>B"
   825   by (fact Inf_insert) (* already simp *)
   826 
   827 lemma Inter_Un_subset: "\<Inter>A \<union> \<Inter>B \<subseteq> \<Inter>(A \<inter> B)"
   828   by (fact less_eq_Inf_inter)
   829 
   830 lemma Inter_Un_distrib: "\<Inter>(A \<union> B) = \<Inter>A \<inter> \<Inter>B"
   831   by (fact Inf_union_distrib)
   832 
   833 lemma Inter_UNIV_conv [simp]:
   834   "\<Inter>A = UNIV \<longleftrightarrow> (\<forall>x\<in>A. x = UNIV)"
   835   "UNIV = \<Inter>A \<longleftrightarrow> (\<forall>x\<in>A. x = UNIV)"
   836   by (fact Inf_top_conv)+
   837 
   838 lemma Inter_anti_mono: "B \<subseteq> A \<Longrightarrow> \<Inter>A \<subseteq> \<Inter>B"
   839   by (fact Inf_superset_mono)
   840 
   841 
   842 subsubsection {* Intersections of families *}
   843 
   844 abbreviation INTER :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> 'b set" where
   845   "INTER \<equiv> INFI"
   846 
   847 text {*
   848   Note: must use name @{const INTER} here instead of @{text INT}
   849   to allow the following syntax coexist with the plain constant name.
   850 *}
   851 
   852 syntax
   853   "_INTER1"     :: "pttrns => 'b set => 'b set"           ("(3INT _./ _)" [0, 10] 10)
   854   "_INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3INT _:_./ _)" [0, 0, 10] 10)
   855 
   856 syntax (xsymbols)
   857   "_INTER1"     :: "pttrns => 'b set => 'b set"           ("(3\<Inter>_./ _)" [0, 10] 10)
   858   "_INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Inter>_\<in>_./ _)" [0, 0, 10] 10)
   859 
   860 syntax (latex output)
   861   "_INTER1"     :: "pttrns => 'b set => 'b set"           ("(3\<Inter>(00\<^bsub>_\<^esub>)/ _)" [0, 10] 10)
   862   "_INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Inter>(00\<^bsub>_\<in>_\<^esub>)/ _)" [0, 0, 10] 10)
   863 
   864 translations
   865   "INT x y. B"  == "INT x. INT y. B"
   866   "INT x. B"    == "CONST INTER CONST UNIV (%x. B)"
   867   "INT x. B"    == "INT x:CONST UNIV. B"
   868   "INT x:A. B"  == "CONST INTER A (%x. B)"
   869 
   870 print_translation {*
   871   [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax INTER} @{syntax_const "_INTER"}]
   872 *} -- {* to avoid eta-contraction of body *}
   873 
   874 lemma INTER_eq:
   875   "(\<Inter>x\<in>A. B x) = {y. \<forall>x\<in>A. y \<in> B x}"
   876   by (auto simp add: INF_def)
   877 
   878 lemma Inter_image_eq [simp]:
   879   "\<Inter>(B`A) = (\<Inter>x\<in>A. B x)"
   880   by (rule sym) (fact INF_def)
   881 
   882 lemma INT_iff [simp]: "b \<in> (\<Inter>x\<in>A. B x) \<longleftrightarrow> (\<forall>x\<in>A. b \<in> B x)"
   883   by (auto simp add: INF_def image_def)
   884 
   885 lemma INT_I [intro!]: "(\<And>x. x \<in> A \<Longrightarrow> b \<in> B x) \<Longrightarrow> b \<in> (\<Inter>x\<in>A. B x)"
   886   by (auto simp add: INF_def image_def)
   887 
   888 lemma INT_D [elim, Pure.elim]: "b \<in> (\<Inter>x\<in>A. B x) \<Longrightarrow> a \<in> A \<Longrightarrow> b \<in> B a"
   889   by auto
   890 
   891 lemma INT_E [elim]: "b \<in> (\<Inter>x\<in>A. B x) \<Longrightarrow> (b \<in> B a \<Longrightarrow> R) \<Longrightarrow> (a \<notin> A \<Longrightarrow> R) \<Longrightarrow> R"
   892   -- {* "Classical" elimination -- by the Excluded Middle on @{prop "a\<in>A"}. *}
   893   by (auto simp add: INF_def image_def)
   894 
   895 lemma INT_cong [cong]:
   896   "A = B \<Longrightarrow> (\<And>x. x \<in> B \<Longrightarrow> C x = D x) \<Longrightarrow> (\<Inter>x\<in>A. C x) = (\<Inter>x\<in>B. D x)"
   897   by (fact INF_cong)
   898 
   899 lemma Collect_ball_eq: "{x. \<forall>y\<in>A. P x y} = (\<Inter>y\<in>A. {x. P x y})"
   900   by blast
   901 
   902 lemma Collect_all_eq: "{x. \<forall>y. P x y} = (\<Inter>y. {x. P x y})"
   903   by blast
   904 
   905 lemma INT_lower: "a \<in> A \<Longrightarrow> (\<Inter>x\<in>A. B x) \<subseteq> B a"
   906   by (fact INF_lower)
   907 
   908 lemma INT_greatest: "(\<And>x. x \<in> A \<Longrightarrow> C \<subseteq> B x) \<Longrightarrow> C \<subseteq> (\<Inter>x\<in>A. B x)"
   909   by (fact INF_greatest)
   910 
   911 lemma INT_empty: "(\<Inter>x\<in>{}. B x) = UNIV"
   912   by (fact INF_empty)
   913 
   914 lemma INT_absorb: "k \<in> I \<Longrightarrow> A k \<inter> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. A i)"
   915   by (fact INF_absorb)
   916 
   917 lemma INT_subset_iff: "B \<subseteq> (\<Inter>i\<in>I. A i) \<longleftrightarrow> (\<forall>i\<in>I. B \<subseteq> A i)"
   918   by (fact le_INF_iff)
   919 
   920 lemma INT_insert [simp]: "(\<Inter>x \<in> insert a A. B x) = B a \<inter> INTER A B"
   921   by (fact INF_insert)
   922 
   923 lemma INT_Un: "(\<Inter>i \<in> A \<union> B. M i) = (\<Inter>i \<in> A. M i) \<inter> (\<Inter>i\<in>B. M i)"
   924   by (fact INF_union)
   925 
   926 lemma INT_insert_distrib:
   927   "u \<in> A \<Longrightarrow> (\<Inter>x\<in>A. insert a (B x)) = insert a (\<Inter>x\<in>A. B x)"
   928   by blast
   929 
   930 lemma INT_constant [simp]: "(\<Inter>y\<in>A. c) = (if A = {} then UNIV else c)"
   931   by (fact INF_constant)
   932 
   933 lemma INTER_UNIV_conv:
   934  "(UNIV = (\<Inter>x\<in>A. B x)) = (\<forall>x\<in>A. B x = UNIV)"
   935  "((\<Inter>x\<in>A. B x) = UNIV) = (\<forall>x\<in>A. B x = UNIV)"
   936   by (fact INF_top_conv)+ (* already simp *)
   937 
   938 lemma INT_bool_eq: "(\<Inter>b. A b) = A True \<inter> A False"
   939   by (fact INF_UNIV_bool_expand)
   940 
   941 lemma INT_anti_mono:
   942   "A \<subseteq> B \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> f x \<subseteq> g x) \<Longrightarrow> (\<Inter>x\<in>B. f x) \<subseteq> (\<Inter>x\<in>A. g x)"
   943   -- {* The last inclusion is POSITIVE! *}
   944   by (fact INF_superset_mono)
   945 
   946 lemma Pow_INT_eq: "Pow (\<Inter>x\<in>A. B x) = (\<Inter>x\<in>A. Pow (B x))"
   947   by blast
   948 
   949 lemma vimage_INT: "f -` (\<Inter>x\<in>A. B x) = (\<Inter>x\<in>A. f -` B x)"
   950   by blast
   951 
   952 
   953 subsubsection {* Union *}
   954 
   955 abbreviation Union :: "'a set set \<Rightarrow> 'a set" where
   956   "Union S \<equiv> \<Squnion>S"
   957 
   958 notation (xsymbols)
   959   Union  ("\<Union>_" [900] 900)
   960 
   961 lemma Union_eq:
   962   "\<Union>A = {x. \<exists>B \<in> A. x \<in> B}"
   963 proof (rule set_eqI)
   964   fix x
   965   have "(\<exists>Q\<in>{P. \<exists>B\<in>A. P \<longleftrightarrow> x \<in> B}. Q) \<longleftrightarrow> (\<exists>B\<in>A. x \<in> B)"
   966     by auto
   967   then show "x \<in> \<Union>A \<longleftrightarrow> x \<in> {x. \<exists>B\<in>A. x \<in> B}"
   968     by (simp add: Sup_set_def image_def)
   969 qed
   970 
   971 lemma Union_iff [simp]:
   972   "A \<in> \<Union>C \<longleftrightarrow> (\<exists>X\<in>C. A\<in>X)"
   973   by (unfold Union_eq) blast
   974 
   975 lemma UnionI [intro]:
   976   "X \<in> C \<Longrightarrow> A \<in> X \<Longrightarrow> A \<in> \<Union>C"
   977   -- {* The order of the premises presupposes that @{term C} is rigid;
   978     @{term A} may be flexible. *}
   979   by auto
   980 
   981 lemma UnionE [elim!]:
   982   "A \<in> \<Union>C \<Longrightarrow> (\<And>X. A \<in> X \<Longrightarrow> X \<in> C \<Longrightarrow> R) \<Longrightarrow> R"
   983   by auto
   984 
   985 lemma Union_upper: "B \<in> A \<Longrightarrow> B \<subseteq> \<Union>A"
   986   by (fact Sup_upper)
   987 
   988 lemma Union_least: "(\<And>X. X \<in> A \<Longrightarrow> X \<subseteq> C) \<Longrightarrow> \<Union>A \<subseteq> C"
   989   by (fact Sup_least)
   990 
   991 lemma Union_empty: "\<Union>{} = {}"
   992   by (fact Sup_empty) (* already simp *)
   993 
   994 lemma Union_UNIV: "\<Union>UNIV = UNIV"
   995   by (fact Sup_UNIV) (* already simp *)
   996 
   997 lemma Union_insert: "\<Union>insert a B = a \<union> \<Union>B"
   998   by (fact Sup_insert) (* already simp *)
   999 
  1000 lemma Union_Un_distrib [simp]: "\<Union>(A \<union> B) = \<Union>A \<union> \<Union>B"
  1001   by (fact Sup_union_distrib)
  1002 
  1003 lemma Union_Int_subset: "\<Union>(A \<inter> B) \<subseteq> \<Union>A \<inter> \<Union>B"
  1004   by (fact Sup_inter_less_eq)
  1005 
  1006 lemma Union_empty_conv: "(\<Union>A = {}) \<longleftrightarrow> (\<forall>x\<in>A. x = {})"
  1007   by (fact Sup_bot_conv) (* already simp *)
  1008 
  1009 lemma empty_Union_conv: "({} = \<Union>A) \<longleftrightarrow> (\<forall>x\<in>A. x = {})"
  1010   by (fact Sup_bot_conv) (* already simp *)
  1011 
  1012 lemma subset_Pow_Union: "A \<subseteq> Pow (\<Union>A)"
  1013   by blast
  1014 
  1015 lemma Union_Pow_eq [simp]: "\<Union>(Pow A) = A"
  1016   by blast
  1017 
  1018 lemma Union_mono: "A \<subseteq> B \<Longrightarrow> \<Union>A \<subseteq> \<Union>B"
  1019   by (fact Sup_subset_mono)
  1020 
  1021 
  1022 subsubsection {* Unions of families *}
  1023 
  1024 abbreviation UNION :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> 'b set" where
  1025   "UNION \<equiv> SUPR"
  1026 
  1027 text {*
  1028   Note: must use name @{const UNION} here instead of @{text UN}
  1029   to allow the following syntax coexist with the plain constant name.
  1030 *}
  1031 
  1032 syntax
  1033   "_UNION1"     :: "pttrns => 'b set => 'b set"           ("(3UN _./ _)" [0, 10] 10)
  1034   "_UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3UN _:_./ _)" [0, 0, 10] 10)
  1035 
  1036 syntax (xsymbols)
  1037   "_UNION1"     :: "pttrns => 'b set => 'b set"           ("(3\<Union>_./ _)" [0, 10] 10)
  1038   "_UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Union>_\<in>_./ _)" [0, 0, 10] 10)
  1039 
  1040 syntax (latex output)
  1041   "_UNION1"     :: "pttrns => 'b set => 'b set"           ("(3\<Union>(00\<^bsub>_\<^esub>)/ _)" [0, 10] 10)
  1042   "_UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Union>(00\<^bsub>_\<in>_\<^esub>)/ _)" [0, 0, 10] 10)
  1043 
  1044 translations
  1045   "UN x y. B"   == "UN x. UN y. B"
  1046   "UN x. B"     == "CONST UNION CONST UNIV (%x. B)"
  1047   "UN x. B"     == "UN x:CONST UNIV. B"
  1048   "UN x:A. B"   == "CONST UNION A (%x. B)"
  1049 
  1050 text {*
  1051   Note the difference between ordinary xsymbol syntax of indexed
  1052   unions and intersections (e.g.\ @{text"\<Union>a\<^sub>1\<in>A\<^sub>1. B"})
  1053   and their \LaTeX\ rendition: @{term"\<Union>a\<^sub>1\<in>A\<^sub>1. B"}. The
  1054   former does not make the index expression a subscript of the
  1055   union/intersection symbol because this leads to problems with nested
  1056   subscripts in Proof General.
  1057 *}
  1058 
  1059 print_translation {*
  1060   [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax UNION} @{syntax_const "_UNION"}]
  1061 *} -- {* to avoid eta-contraction of body *}
  1062 
  1063 lemma UNION_eq:
  1064   "(\<Union>x\<in>A. B x) = {y. \<exists>x\<in>A. y \<in> B x}"
  1065   by (auto simp add: SUP_def)
  1066 
  1067 lemma bind_UNION [code]:
  1068   "Set.bind A f = UNION A f"
  1069   by (simp add: bind_def UNION_eq)
  1070 
  1071 lemma member_bind [simp]:
  1072   "x \<in> Set.bind P f \<longleftrightarrow> x \<in> UNION P f "
  1073   by (simp add: bind_UNION)
  1074 
  1075 lemma Union_image_eq [simp]:
  1076   "\<Union>(B ` A) = (\<Union>x\<in>A. B x)"
  1077   by (rule sym) (fact SUP_def)
  1078 
  1079 lemma UN_iff [simp]: "b \<in> (\<Union>x\<in>A. B x) \<longleftrightarrow> (\<exists>x\<in>A. b \<in> B x)"
  1080   by (auto simp add: SUP_def image_def)
  1081 
  1082 lemma UN_I [intro]: "a \<in> A \<Longrightarrow> b \<in> B a \<Longrightarrow> b \<in> (\<Union>x\<in>A. B x)"
  1083   -- {* The order of the premises presupposes that @{term A} is rigid;
  1084     @{term b} may be flexible. *}
  1085   by auto
  1086 
  1087 lemma UN_E [elim!]: "b \<in> (\<Union>x\<in>A. B x) \<Longrightarrow> (\<And>x. x\<in>A \<Longrightarrow> b \<in> B x \<Longrightarrow> R) \<Longrightarrow> R"
  1088   by (auto simp add: SUP_def image_def)
  1089 
  1090 lemma UN_cong [cong]:
  1091   "A = B \<Longrightarrow> (\<And>x. x \<in> B \<Longrightarrow> C x = D x) \<Longrightarrow> (\<Union>x\<in>A. C x) = (\<Union>x\<in>B. D x)"
  1092   by (fact SUP_cong)
  1093 
  1094 lemma strong_UN_cong:
  1095   "A = B \<Longrightarrow> (\<And>x. x \<in> B =simp=> C x = D x) \<Longrightarrow> (\<Union>x\<in>A. C x) = (\<Union>x\<in>B. D x)"
  1096   by (unfold simp_implies_def) (fact UN_cong)
  1097 
  1098 lemma image_eq_UN: "f ` A = (\<Union>x\<in>A. {f x})"
  1099   by blast
  1100 
  1101 lemma UN_upper: "a \<in> A \<Longrightarrow> B a \<subseteq> (\<Union>x\<in>A. B x)"
  1102   by (fact SUP_upper)
  1103 
  1104 lemma UN_least: "(\<And>x. x \<in> A \<Longrightarrow> B x \<subseteq> C) \<Longrightarrow> (\<Union>x\<in>A. B x) \<subseteq> C"
  1105   by (fact SUP_least)
  1106 
  1107 lemma Collect_bex_eq: "{x. \<exists>y\<in>A. P x y} = (\<Union>y\<in>A. {x. P x y})"
  1108   by blast
  1109 
  1110 lemma UN_insert_distrib: "u \<in> A \<Longrightarrow> (\<Union>x\<in>A. insert a (B x)) = insert a (\<Union>x\<in>A. B x)"
  1111   by blast
  1112 
  1113 lemma UN_empty: "(\<Union>x\<in>{}. B x) = {}"
  1114   by (fact SUP_empty)
  1115 
  1116 lemma UN_empty2: "(\<Union>x\<in>A. {}) = {}"
  1117   by (fact SUP_bot) (* already simp *)
  1118 
  1119 lemma UN_absorb: "k \<in> I \<Longrightarrow> A k \<union> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. A i)"
  1120   by (fact SUP_absorb)
  1121 
  1122 lemma UN_insert [simp]: "(\<Union>x\<in>insert a A. B x) = B a \<union> UNION A B"
  1123   by (fact SUP_insert)
  1124 
  1125 lemma UN_Un [simp]: "(\<Union>i \<in> A \<union> B. M i) = (\<Union>i\<in>A. M i) \<union> (\<Union>i\<in>B. M i)"
  1126   by (fact SUP_union)
  1127 
  1128 lemma UN_UN_flatten: "(\<Union>x \<in> (\<Union>y\<in>A. B y). C x) = (\<Union>y\<in>A. \<Union>x\<in>B y. C x)"
  1129   by blast
  1130 
  1131 lemma UN_subset_iff: "((\<Union>i\<in>I. A i) \<subseteq> B) = (\<forall>i\<in>I. A i \<subseteq> B)"
  1132   by (fact SUP_le_iff)
  1133 
  1134 lemma UN_constant [simp]: "(\<Union>y\<in>A. c) = (if A = {} then {} else c)"
  1135   by (fact SUP_constant)
  1136 
  1137 lemma image_Union: "f ` \<Union>S = (\<Union>x\<in>S. f ` x)"
  1138   by blast
  1139 
  1140 lemma UNION_empty_conv:
  1141   "{} = (\<Union>x\<in>A. B x) \<longleftrightarrow> (\<forall>x\<in>A. B x = {})"
  1142   "(\<Union>x\<in>A. B x) = {} \<longleftrightarrow> (\<forall>x\<in>A. B x = {})"
  1143   by (fact SUP_bot_conv)+ (* already simp *)
  1144 
  1145 lemma Collect_ex_eq: "{x. \<exists>y. P x y} = (\<Union>y. {x. P x y})"
  1146   by blast
  1147 
  1148 lemma ball_UN: "(\<forall>z \<in> UNION A B. P z) \<longleftrightarrow> (\<forall>x\<in>A. \<forall>z \<in> B x. P z)"
  1149   by blast
  1150 
  1151 lemma bex_UN: "(\<exists>z \<in> UNION A B. P z) \<longleftrightarrow> (\<exists>x\<in>A. \<exists>z\<in>B x. P z)"
  1152   by blast
  1153 
  1154 lemma Un_eq_UN: "A \<union> B = (\<Union>b. if b then A else B)"
  1155   by (auto simp add: split_if_mem2)
  1156 
  1157 lemma UN_bool_eq: "(\<Union>b. A b) = (A True \<union> A False)"
  1158   by (fact SUP_UNIV_bool_expand)
  1159 
  1160 lemma UN_Pow_subset: "(\<Union>x\<in>A. Pow (B x)) \<subseteq> Pow (\<Union>x\<in>A. B x)"
  1161   by blast
  1162 
  1163 lemma UN_mono:
  1164   "A \<subseteq> B \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> f x \<subseteq> g x) \<Longrightarrow>
  1165     (\<Union>x\<in>A. f x) \<subseteq> (\<Union>x\<in>B. g x)"
  1166   by (fact SUP_subset_mono)
  1167 
  1168 lemma vimage_Union: "f -` (\<Union>A) = (\<Union>X\<in>A. f -` X)"
  1169   by blast
  1170 
  1171 lemma vimage_UN: "f -` (\<Union>x\<in>A. B x) = (\<Union>x\<in>A. f -` B x)"
  1172   by blast
  1173 
  1174 lemma vimage_eq_UN: "f -` B = (\<Union>y\<in>B. f -` {y})"
  1175   -- {* NOT suitable for rewriting *}
  1176   by blast
  1177 
  1178 lemma image_UN: "f ` UNION A B = (\<Union>x\<in>A. f ` B x)"
  1179   by blast
  1180 
  1181 lemma UN_singleton [simp]: "(\<Union>x\<in>A. {x}) = A"
  1182   by blast
  1183 
  1184 
  1185 subsubsection {* Distributive laws *}
  1186 
  1187 lemma Int_Union: "A \<inter> \<Union>B = (\<Union>C\<in>B. A \<inter> C)"
  1188   by (fact inf_Sup)
  1189 
  1190 lemma Un_Inter: "A \<union> \<Inter>B = (\<Inter>C\<in>B. A \<union> C)"
  1191   by (fact sup_Inf)
  1192 
  1193 lemma Int_Union2: "\<Union>B \<inter> A = (\<Union>C\<in>B. C \<inter> A)"
  1194   by (fact Sup_inf)
  1195 
  1196 lemma INT_Int_distrib: "(\<Inter>i\<in>I. A i \<inter> B i) = (\<Inter>i\<in>I. A i) \<inter> (\<Inter>i\<in>I. B i)"
  1197   by (rule sym) (rule INF_inf_distrib)
  1198 
  1199 lemma UN_Un_distrib: "(\<Union>i\<in>I. A i \<union> B i) = (\<Union>i\<in>I. A i) \<union> (\<Union>i\<in>I. B i)"
  1200   by (rule sym) (rule SUP_sup_distrib)
  1201 
  1202 lemma Int_Inter_image: "(\<Inter>x\<in>C. A x \<inter> B x) = \<Inter>(A ` C) \<inter> \<Inter>(B ` C)"
  1203   by (simp only: INT_Int_distrib INF_def)
  1204 
  1205 lemma Un_Union_image: "(\<Union>x\<in>C. A x \<union> B x) = \<Union>(A ` C) \<union> \<Union>(B ` C)"
  1206   -- {* Devlin, Fundamentals of Contemporary Set Theory, page 12, exercise 5: *}
  1207   -- {* Union of a family of unions *}
  1208   by (simp only: UN_Un_distrib SUP_def)
  1209 
  1210 lemma Un_INT_distrib: "B \<union> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. B \<union> A i)"
  1211   by (fact sup_INF)
  1212 
  1213 lemma Int_UN_distrib: "B \<inter> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. B \<inter> A i)"
  1214   -- {* Halmos, Naive Set Theory, page 35. *}
  1215   by (fact inf_SUP)
  1216 
  1217 lemma Int_UN_distrib2: "(\<Union>i\<in>I. A i) \<inter> (\<Union>j\<in>J. B j) = (\<Union>i\<in>I. \<Union>j\<in>J. A i \<inter> B j)"
  1218   by (fact SUP_inf_distrib2)
  1219 
  1220 lemma Un_INT_distrib2: "(\<Inter>i\<in>I. A i) \<union> (\<Inter>j\<in>J. B j) = (\<Inter>i\<in>I. \<Inter>j\<in>J. A i \<union> B j)"
  1221   by (fact INF_sup_distrib2)
  1222 
  1223 lemma Union_disjoint: "(\<Union>C \<inter> A = {}) \<longleftrightarrow> (\<forall>B\<in>C. B \<inter> A = {})"
  1224   by (fact Sup_inf_eq_bot_iff)
  1225 
  1226 
  1227 subsubsection {* Complement *}
  1228 
  1229 lemma Compl_INT [simp]: "- (\<Inter>x\<in>A. B x) = (\<Union>x\<in>A. -B x)"
  1230   by (fact uminus_INF)
  1231 
  1232 lemma Compl_UN [simp]: "- (\<Union>x\<in>A. B x) = (\<Inter>x\<in>A. -B x)"
  1233   by (fact uminus_SUP)
  1234 
  1235 
  1236 subsubsection {* Miniscoping and maxiscoping *}
  1237 
  1238 text {* \medskip Miniscoping: pushing in quantifiers and big Unions
  1239            and Intersections. *}
  1240 
  1241 lemma UN_simps [simp]:
  1242   "\<And>a B C. (\<Union>x\<in>C. insert a (B x)) = (if C={} then {} else insert a (\<Union>x\<in>C. B x))"
  1243   "\<And>A B C. (\<Union>x\<in>C. A x \<union> B) = ((if C={} then {} else (\<Union>x\<in>C. A x) \<union> B))"
  1244   "\<And>A B C. (\<Union>x\<in>C. A \<union> B x) = ((if C={} then {} else A \<union> (\<Union>x\<in>C. B x)))"
  1245   "\<And>A B C. (\<Union>x\<in>C. A x \<inter> B) = ((\<Union>x\<in>C. A x) \<inter> B)"
  1246   "\<And>A B C. (\<Union>x\<in>C. A \<inter> B x) = (A \<inter>(\<Union>x\<in>C. B x))"
  1247   "\<And>A B C. (\<Union>x\<in>C. A x - B) = ((\<Union>x\<in>C. A x) - B)"
  1248   "\<And>A B C. (\<Union>x\<in>C. A - B x) = (A - (\<Inter>x\<in>C. B x))"
  1249   "\<And>A B. (\<Union>x\<in>\<Union>A. B x) = (\<Union>y\<in>A. \<Union>x\<in>y. B x)"
  1250   "\<And>A B C. (\<Union>z\<in>UNION A B. C z) = (\<Union>x\<in>A. \<Union>z\<in>B x. C z)"
  1251   "\<And>A B f. (\<Union>x\<in>f`A. B x) = (\<Union>a\<in>A. B (f a))"
  1252   by auto
  1253 
  1254 lemma INT_simps [simp]:
  1255   "\<And>A B C. (\<Inter>x\<in>C. A x \<inter> B) = (if C={} then UNIV else (\<Inter>x\<in>C. A x) \<inter> B)"
  1256   "\<And>A B C. (\<Inter>x\<in>C. A \<inter> B x) = (if C={} then UNIV else A \<inter>(\<Inter>x\<in>C. B x))"
  1257   "\<And>A B C. (\<Inter>x\<in>C. A x - B) = (if C={} then UNIV else (\<Inter>x\<in>C. A x) - B)"
  1258   "\<And>A B C. (\<Inter>x\<in>C. A - B x) = (if C={} then UNIV else A - (\<Union>x\<in>C. B x))"
  1259   "\<And>a B C. (\<Inter>x\<in>C. insert a (B x)) = insert a (\<Inter>x\<in>C. B x)"
  1260   "\<And>A B C. (\<Inter>x\<in>C. A x \<union> B) = ((\<Inter>x\<in>C. A x) \<union> B)"
  1261   "\<And>A B C. (\<Inter>x\<in>C. A \<union> B x) = (A \<union> (\<Inter>x\<in>C. B x))"
  1262   "\<And>A B. (\<Inter>x\<in>\<Union>A. B x) = (\<Inter>y\<in>A. \<Inter>x\<in>y. B x)"
  1263   "\<And>A B C. (\<Inter>z\<in>UNION A B. C z) = (\<Inter>x\<in>A. \<Inter>z\<in>B x. C z)"
  1264   "\<And>A B f. (\<Inter>x\<in>f`A. B x) = (\<Inter>a\<in>A. B (f a))"
  1265   by auto
  1266 
  1267 lemma UN_ball_bex_simps [simp]:
  1268   "\<And>A P. (\<forall>x\<in>\<Union>A. P x) \<longleftrightarrow> (\<forall>y\<in>A. \<forall>x\<in>y. P x)"
  1269   "\<And>A B P. (\<forall>x\<in>UNION A B. P x) = (\<forall>a\<in>A. \<forall>x\<in> B a. P x)"
  1270   "\<And>A P. (\<exists>x\<in>\<Union>A. P x) \<longleftrightarrow> (\<exists>y\<in>A. \<exists>x\<in>y. P x)"
  1271   "\<And>A B P. (\<exists>x\<in>UNION A B. P x) \<longleftrightarrow> (\<exists>a\<in>A. \<exists>x\<in>B a. P x)"
  1272   by auto
  1273 
  1274 
  1275 text {* \medskip Maxiscoping: pulling out big Unions and Intersections. *}
  1276 
  1277 lemma UN_extend_simps:
  1278   "\<And>a B C. insert a (\<Union>x\<in>C. B x) = (if C={} then {a} else (\<Union>x\<in>C. insert a (B x)))"
  1279   "\<And>A B C. (\<Union>x\<in>C. A x) \<union> B = (if C={} then B else (\<Union>x\<in>C. A x \<union> B))"
  1280   "\<And>A B C. A \<union> (\<Union>x\<in>C. B x) = (if C={} then A else (\<Union>x\<in>C. A \<union> B x))"
  1281   "\<And>A B C. ((\<Union>x\<in>C. A x) \<inter> B) = (\<Union>x\<in>C. A x \<inter> B)"
  1282   "\<And>A B C. (A \<inter> (\<Union>x\<in>C. B x)) = (\<Union>x\<in>C. A \<inter> B x)"
  1283   "\<And>A B C. ((\<Union>x\<in>C. A x) - B) = (\<Union>x\<in>C. A x - B)"
  1284   "\<And>A B C. (A - (\<Inter>x\<in>C. B x)) = (\<Union>x\<in>C. A - B x)"
  1285   "\<And>A B. (\<Union>y\<in>A. \<Union>x\<in>y. B x) = (\<Union>x\<in>\<Union>A. B x)"
  1286   "\<And>A B C. (\<Union>x\<in>A. \<Union>z\<in>B x. C z) = (\<Union>z\<in>UNION A B. C z)"
  1287   "\<And>A B f. (\<Union>a\<in>A. B (f a)) = (\<Union>x\<in>f`A. B x)"
  1288   by auto
  1289 
  1290 lemma INT_extend_simps:
  1291   "\<And>A B C. (\<Inter>x\<in>C. A x) \<inter> B = (if C={} then B else (\<Inter>x\<in>C. A x \<inter> B))"
  1292   "\<And>A B C. A \<inter> (\<Inter>x\<in>C. B x) = (if C={} then A else (\<Inter>x\<in>C. A \<inter> B x))"
  1293   "\<And>A B C. (\<Inter>x\<in>C. A x) - B = (if C={} then UNIV - B else (\<Inter>x\<in>C. A x - B))"
  1294   "\<And>A B C. A - (\<Union>x\<in>C. B x) = (if C={} then A else (\<Inter>x\<in>C. A - B x))"
  1295   "\<And>a B C. insert a (\<Inter>x\<in>C. B x) = (\<Inter>x\<in>C. insert a (B x))"
  1296   "\<And>A B C. ((\<Inter>x\<in>C. A x) \<union> B) = (\<Inter>x\<in>C. A x \<union> B)"
  1297   "\<And>A B C. A \<union> (\<Inter>x\<in>C. B x) = (\<Inter>x\<in>C. A \<union> B x)"
  1298   "\<And>A B. (\<Inter>y\<in>A. \<Inter>x\<in>y. B x) = (\<Inter>x\<in>\<Union>A. B x)"
  1299   "\<And>A B C. (\<Inter>x\<in>A. \<Inter>z\<in>B x. C z) = (\<Inter>z\<in>UNION A B. C z)"
  1300   "\<And>A B f. (\<Inter>a\<in>A. B (f a)) = (\<Inter>x\<in>f`A. B x)"
  1301   by auto
  1302 
  1303 text {* Finally *}
  1304 
  1305 no_notation
  1306   less_eq (infix "\<sqsubseteq>" 50) and
  1307   less (infix "\<sqsubset>" 50)
  1308 
  1309 lemmas mem_simps =
  1310   insert_iff empty_iff Un_iff Int_iff Compl_iff Diff_iff
  1311   mem_Collect_eq UN_iff Union_iff INT_iff Inter_iff
  1312   -- {* Each of these has ALREADY been added @{text "[simp]"} above. *}
  1313 
  1314 end
  1315