src/HOL/Hilbert_Choice.thy
 author blanchet Wed Feb 12 08:35:57 2014 +0100 (2014-02-12) changeset 55415 05f5fdb8d093 parent 55088 57c82e01022b child 55811 aa1acc25126b permissions -rw-r--r--
renamed 'nat_{case,rec}' to '{case,rec}_nat'
1 (*  Title:      HOL/Hilbert_Choice.thy
2     Author:     Lawrence C Paulson, Tobias Nipkow
3     Copyright   2001  University of Cambridge
4 *)
6 header {* Hilbert's Epsilon-Operator and the Axiom of Choice *}
8 theory Hilbert_Choice
9 imports Nat Wellfounded Metis
10 keywords "specification" "ax_specification" :: thy_goal
11 begin
13 subsection {* Hilbert's epsilon *}
15 axiomatization Eps :: "('a => bool) => 'a" where
16   someI: "P x ==> P (Eps P)"
18 syntax (epsilon)
19   "_Eps"        :: "[pttrn, bool] => 'a"    ("(3\<some>_./ _)" [0, 10] 10)
20 syntax (HOL)
21   "_Eps"        :: "[pttrn, bool] => 'a"    ("(3@ _./ _)" [0, 10] 10)
22 syntax
23   "_Eps"        :: "[pttrn, bool] => 'a"    ("(3SOME _./ _)" [0, 10] 10)
24 translations
25   "SOME x. P" == "CONST Eps (%x. P)"
27 print_translation {*
28   [(@{const_syntax Eps}, fn _ => fn [Abs abs] =>
29       let val (x, t) = Syntax_Trans.atomic_abs_tr' abs
30       in Syntax.const @{syntax_const "_Eps"} \$ x \$ t end)]
31 *} -- {* to avoid eta-contraction of body *}
33 definition inv_into :: "'a set => ('a => 'b) => ('b => 'a)" where
34 "inv_into A f == %x. SOME y. y : A & f y = x"
36 abbreviation inv :: "('a => 'b) => ('b => 'a)" where
37 "inv == inv_into UNIV"
40 subsection {*Hilbert's Epsilon-operator*}
42 text{*Easier to apply than @{text someI} if the witness comes from an
43 existential formula*}
44 lemma someI_ex [elim?]: "\<exists>x. P x ==> P (SOME x. P x)"
45 apply (erule exE)
46 apply (erule someI)
47 done
49 text{*Easier to apply than @{text someI} because the conclusion has only one
50 occurrence of @{term P}.*}
51 lemma someI2: "[| P a;  !!x. P x ==> Q x |] ==> Q (SOME x. P x)"
52 by (blast intro: someI)
54 text{*Easier to apply than @{text someI2} if the witness comes from an
55 existential formula*}
56 lemma someI2_ex: "[| \<exists>a. P a; !!x. P x ==> Q x |] ==> Q (SOME x. P x)"
57 by (blast intro: someI2)
59 lemma some_equality [intro]:
60      "[| P a;  !!x. P x ==> x=a |] ==> (SOME x. P x) = a"
61 by (blast intro: someI2)
63 lemma some1_equality: "[| EX!x. P x; P a |] ==> (SOME x. P x) = a"
64 by blast
66 lemma some_eq_ex: "P (SOME x. P x) =  (\<exists>x. P x)"
67 by (blast intro: someI)
69 lemma some_eq_trivial [simp]: "(SOME y. y=x) = x"
70 apply (rule some_equality)
71 apply (rule refl, assumption)
72 done
74 lemma some_sym_eq_trivial [simp]: "(SOME y. x=y) = x"
75 apply (rule some_equality)
76 apply (rule refl)
77 apply (erule sym)
78 done
81 subsection{*Axiom of Choice, Proved Using the Description Operator*}
83 lemma choice: "\<forall>x. \<exists>y. Q x y ==> \<exists>f. \<forall>x. Q x (f x)"
84 by (fast elim: someI)
86 lemma bchoice: "\<forall>x\<in>S. \<exists>y. Q x y ==> \<exists>f. \<forall>x\<in>S. Q x (f x)"
87 by (fast elim: someI)
89 lemma choice_iff: "(\<forall>x. \<exists>y. Q x y) \<longleftrightarrow> (\<exists>f. \<forall>x. Q x (f x))"
90 by (fast elim: someI)
92 lemma choice_iff': "(\<forall>x. P x \<longrightarrow> (\<exists>y. Q x y)) \<longleftrightarrow> (\<exists>f. \<forall>x. P x \<longrightarrow> Q x (f x))"
93 by (fast elim: someI)
95 lemma bchoice_iff: "(\<forall>x\<in>S. \<exists>y. Q x y) \<longleftrightarrow> (\<exists>f. \<forall>x\<in>S. Q x (f x))"
96 by (fast elim: someI)
98 lemma bchoice_iff': "(\<forall>x\<in>S. P x \<longrightarrow> (\<exists>y. Q x y)) \<longleftrightarrow> (\<exists>f. \<forall>x\<in>S. P x \<longrightarrow> Q x (f x))"
99 by (fast elim: someI)
101 subsection {*Function Inverse*}
103 lemma inv_def: "inv f = (%y. SOME x. f x = y)"
104 by(simp add: inv_into_def)
106 lemma inv_into_into: "x : f ` A ==> inv_into A f x : A"
107 apply (simp add: inv_into_def)
108 apply (fast intro: someI2)
109 done
111 lemma inv_id [simp]: "inv id = id"
112 by (simp add: inv_into_def id_def)
114 lemma inv_into_f_f [simp]:
115   "[| inj_on f A;  x : A |] ==> inv_into A f (f x) = x"
116 apply (simp add: inv_into_def inj_on_def)
117 apply (blast intro: someI2)
118 done
120 lemma inv_f_f: "inj f ==> inv f (f x) = x"
121 by simp
123 lemma f_inv_into_f: "y : f`A  ==> f (inv_into A f y) = y"
124 apply (simp add: inv_into_def)
125 apply (fast intro: someI2)
126 done
128 lemma inv_into_f_eq: "[| inj_on f A; x : A; f x = y |] ==> inv_into A f y = x"
129 apply (erule subst)
130 apply (fast intro: inv_into_f_f)
131 done
133 lemma inv_f_eq: "[| inj f; f x = y |] ==> inv f y = x"
134 by (simp add:inv_into_f_eq)
136 lemma inj_imp_inv_eq: "[| inj f; ALL x. f(g x) = x |] ==> inv f = g"
137   by (blast intro: inv_into_f_eq)
139 text{*But is it useful?*}
140 lemma inj_transfer:
141   assumes injf: "inj f" and minor: "!!y. y \<in> range(f) ==> P(inv f y)"
142   shows "P x"
143 proof -
144   have "f x \<in> range f" by auto
145   hence "P(inv f (f x))" by (rule minor)
146   thus "P x" by (simp add: inv_into_f_f [OF injf])
147 qed
149 lemma inj_iff: "(inj f) = (inv f o f = id)"
150 apply (simp add: o_def fun_eq_iff)
151 apply (blast intro: inj_on_inverseI inv_into_f_f)
152 done
154 lemma inv_o_cancel[simp]: "inj f ==> inv f o f = id"
155 by (simp add: inj_iff)
157 lemma o_inv_o_cancel[simp]: "inj f ==> g o inv f o f = g"
158 by (simp add: comp_assoc)
160 lemma inv_into_image_cancel[simp]:
161   "inj_on f A ==> S <= A ==> inv_into A f ` f ` S = S"
162 by(fastforce simp: image_def)
164 lemma inj_imp_surj_inv: "inj f ==> surj (inv f)"
165 by (blast intro!: surjI inv_into_f_f)
167 lemma surj_f_inv_f: "surj f ==> f(inv f y) = y"
168 by (simp add: f_inv_into_f)
170 lemma inv_into_injective:
171   assumes eq: "inv_into A f x = inv_into A f y"
172       and x: "x: f`A"
173       and y: "y: f`A"
174   shows "x=y"
175 proof -
176   have "f (inv_into A f x) = f (inv_into A f y)" using eq by simp
177   thus ?thesis by (simp add: f_inv_into_f x y)
178 qed
180 lemma inj_on_inv_into: "B <= f`A ==> inj_on (inv_into A f) B"
181 by (blast intro: inj_onI dest: inv_into_injective injD)
183 lemma bij_betw_inv_into: "bij_betw f A B ==> bij_betw (inv_into A f) B A"
184 by (auto simp add: bij_betw_def inj_on_inv_into)
186 lemma surj_imp_inj_inv: "surj f ==> inj (inv f)"
187 by (simp add: inj_on_inv_into)
189 lemma surj_iff: "(surj f) = (f o inv f = id)"
190 by (auto intro!: surjI simp: surj_f_inv_f fun_eq_iff[where 'b='a])
192 lemma surj_iff_all: "surj f \<longleftrightarrow> (\<forall>x. f (inv f x) = x)"
193   unfolding surj_iff by (simp add: o_def fun_eq_iff)
195 lemma surj_imp_inv_eq: "[| surj f; \<forall>x. g(f x) = x |] ==> inv f = g"
196 apply (rule ext)
197 apply (drule_tac x = "inv f x" in spec)
198 apply (simp add: surj_f_inv_f)
199 done
201 lemma bij_imp_bij_inv: "bij f ==> bij (inv f)"
202 by (simp add: bij_def inj_imp_surj_inv surj_imp_inj_inv)
204 lemma inv_equality: "[| !!x. g (f x) = x;  !!y. f (g y) = y |] ==> inv f = g"
205 apply (rule ext)
206 apply (auto simp add: inv_into_def)
207 done
209 lemma inv_inv_eq: "bij f ==> inv (inv f) = f"
210 apply (rule inv_equality)
211 apply (auto simp add: bij_def surj_f_inv_f)
212 done
214 (** bij(inv f) implies little about f.  Consider f::bool=>bool such that
215     f(True)=f(False)=True.  Then it's consistent with axiom someI that
216     inv f could be any function at all, including the identity function.
217     If inv f=id then inv f is a bijection, but inj f, surj(f) and
218     inv(inv f)=f all fail.
219 **)
221 lemma inv_into_comp:
222   "[| inj_on f (g ` A); inj_on g A; x : f ` g ` A |] ==>
223   inv_into A (f o g) x = (inv_into A g o inv_into (g ` A) f) x"
224 apply (rule inv_into_f_eq)
225   apply (fast intro: comp_inj_on)
226  apply (simp add: inv_into_into)
227 apply (simp add: f_inv_into_f inv_into_into)
228 done
230 lemma o_inv_distrib: "[| bij f; bij g |] ==> inv (f o g) = inv g o inv f"
231 apply (rule inv_equality)
232 apply (auto simp add: bij_def surj_f_inv_f)
233 done
235 lemma image_surj_f_inv_f: "surj f ==> f ` (inv f ` A) = A"
236 by (simp add: image_eq_UN surj_f_inv_f)
238 lemma image_inv_f_f: "inj f ==> (inv f) ` (f ` A) = A"
239 by (simp add: image_eq_UN)
241 lemma inv_image_comp: "inj f ==> inv f ` (f`X) = X"
242 by (auto simp add: image_def)
244 lemma bij_image_Collect_eq: "bij f ==> f ` Collect P = {y. P (inv f y)}"
245 apply auto
246 apply (force simp add: bij_is_inj)
247 apply (blast intro: bij_is_surj [THEN surj_f_inv_f, symmetric])
248 done
250 lemma bij_vimage_eq_inv_image: "bij f ==> f -` A = inv f ` A"
251 apply (auto simp add: bij_is_surj [THEN surj_f_inv_f])
252 apply (blast intro: bij_is_inj [THEN inv_into_f_f, symmetric])
253 done
255 lemma finite_fun_UNIVD1:
256   assumes fin: "finite (UNIV :: ('a \<Rightarrow> 'b) set)"
257   and card: "card (UNIV :: 'b set) \<noteq> Suc 0"
258   shows "finite (UNIV :: 'a set)"
259 proof -
260   from fin have finb: "finite (UNIV :: 'b set)" by (rule finite_fun_UNIVD2)
261   with card have "card (UNIV :: 'b set) \<ge> Suc (Suc 0)"
262     by (cases "card (UNIV :: 'b set)") (auto simp add: card_eq_0_iff)
263   then obtain n where "card (UNIV :: 'b set) = Suc (Suc n)" "n = card (UNIV :: 'b set) - Suc (Suc 0)" by auto
264   then obtain b1 b2 where b1b2: "(b1 :: 'b) \<noteq> (b2 :: 'b)" by (auto simp add: card_Suc_eq)
265   from fin have "finite (range (\<lambda>f :: 'a \<Rightarrow> 'b. inv f b1))" by (rule finite_imageI)
266   moreover have "UNIV = range (\<lambda>f :: 'a \<Rightarrow> 'b. inv f b1)"
267   proof (rule UNIV_eq_I)
268     fix x :: 'a
269     from b1b2 have "x = inv (\<lambda>y. if y = x then b1 else b2) b1" by (simp add: inv_into_def)
270     thus "x \<in> range (\<lambda>f\<Colon>'a \<Rightarrow> 'b. inv f b1)" by blast
271   qed
272   ultimately show "finite (UNIV :: 'a set)" by simp
273 qed
275 text {*
276   Every infinite set contains a countable subset. More precisely we
277   show that a set @{text S} is infinite if and only if there exists an
278   injective function from the naturals into @{text S}.
280   The ``only if'' direction is harder because it requires the
281   construction of a sequence of pairwise different elements of an
282   infinite set @{text S}. The idea is to construct a sequence of
283   non-empty and infinite subsets of @{text S} obtained by successively
284   removing elements of @{text S}.
285 *}
287 lemma infinite_countable_subset:
288   assumes inf: "\<not> finite (S::'a set)"
289   shows "\<exists>f. inj (f::nat \<Rightarrow> 'a) \<and> range f \<subseteq> S"
290   -- {* Courtesy of Stephan Merz *}
291 proof -
292   def Sseq \<equiv> "rec_nat S (\<lambda>n T. T - {SOME e. e \<in> T})"
293   def pick \<equiv> "\<lambda>n. (SOME e. e \<in> Sseq n)"
294   { fix n have "Sseq n \<subseteq> S" "\<not> finite (Sseq n)" by (induct n) (auto simp add: Sseq_def inf) }
295   moreover then have *: "\<And>n. pick n \<in> Sseq n" by (metis someI_ex pick_def ex_in_conv finite.simps)
296   ultimately have "range pick \<subseteq> S" by auto
297   moreover
298   { fix n m
299     have "pick n \<notin> Sseq (n + Suc m)" by (induct m) (auto simp add: Sseq_def pick_def)
300     hence "pick n \<noteq> pick (n + Suc m)" by (metis *)
301   }
302   then have "inj pick" by (intro linorder_injI) (auto simp add: less_iff_Suc_add)
303   ultimately show ?thesis by blast
304 qed
306 lemma infinite_iff_countable_subset: "\<not> finite S \<longleftrightarrow> (\<exists>f. inj (f::nat \<Rightarrow> 'a) \<and> range f \<subseteq> S)"
307   -- {* Courtesy of Stephan Merz *}
308   by (metis finite_imageD finite_subset infinite_UNIV_char_0 infinite_countable_subset)
310 lemma image_inv_into_cancel:
311   assumes SURJ: "f`A=A'" and SUB: "B' \<le> A'"
312   shows "f `((inv_into A f)`B') = B'"
313   using assms
314 proof (auto simp add: f_inv_into_f)
315   let ?f' = "(inv_into A f)"
316   fix a' assume *: "a' \<in> B'"
317   then have "a' \<in> A'" using SUB by auto
318   then have "a' = f (?f' a')"
319     using SURJ by (auto simp add: f_inv_into_f)
320   then show "a' \<in> f ` (?f' ` B')" using * by blast
321 qed
323 lemma inv_into_inv_into_eq:
324   assumes "bij_betw f A A'" "a \<in> A"
325   shows "inv_into A' (inv_into A f) a = f a"
326 proof -
327   let ?f' = "inv_into A f"   let ?f'' = "inv_into A' ?f'"
328   have 1: "bij_betw ?f' A' A" using assms
329   by (auto simp add: bij_betw_inv_into)
330   obtain a' where 2: "a' \<in> A'" and 3: "?f' a' = a"
331     using 1 `a \<in> A` unfolding bij_betw_def by force
332   hence "?f'' a = a'"
333     using `a \<in> A` 1 3 by (auto simp add: f_inv_into_f bij_betw_def)
334   moreover have "f a = a'" using assms 2 3
335     by (auto simp add: bij_betw_def)
336   ultimately show "?f'' a = f a" by simp
337 qed
339 lemma inj_on_iff_surj:
340   assumes "A \<noteq> {}"
341   shows "(\<exists>f. inj_on f A \<and> f ` A \<le> A') \<longleftrightarrow> (\<exists>g. g ` A' = A)"
342 proof safe
343   fix f assume INJ: "inj_on f A" and INCL: "f ` A \<le> A'"
344   let ?phi = "\<lambda>a' a. a \<in> A \<and> f a = a'"  let ?csi = "\<lambda>a. a \<in> A"
345   let ?g = "\<lambda>a'. if a' \<in> f ` A then (SOME a. ?phi a' a) else (SOME a. ?csi a)"
346   have "?g ` A' = A"
347   proof
348     show "?g ` A' \<le> A"
349     proof clarify
350       fix a' assume *: "a' \<in> A'"
351       show "?g a' \<in> A"
352       proof cases
353         assume Case1: "a' \<in> f ` A"
354         then obtain a where "?phi a' a" by blast
355         hence "?phi a' (SOME a. ?phi a' a)" using someI[of "?phi a'" a] by blast
356         with Case1 show ?thesis by auto
357       next
358         assume Case2: "a' \<notin> f ` A"
359         hence "?csi (SOME a. ?csi a)" using assms someI_ex[of ?csi] by blast
360         with Case2 show ?thesis by auto
361       qed
362     qed
363   next
364     show "A \<le> ?g ` A'"
365     proof-
366       {fix a assume *: "a \<in> A"
367        let ?b = "SOME aa. ?phi (f a) aa"
368        have "?phi (f a) a" using * by auto
369        hence 1: "?phi (f a) ?b" using someI[of "?phi(f a)" a] by blast
370        hence "?g(f a) = ?b" using * by auto
371        moreover have "a = ?b" using 1 INJ * by (auto simp add: inj_on_def)
372        ultimately have "?g(f a) = a" by simp
373        with INCL * have "?g(f a) = a \<and> f a \<in> A'" by auto
374       }
375       thus ?thesis by force
376     qed
377   qed
378   thus "\<exists>g. g ` A' = A" by blast
379 next
380   fix g  let ?f = "inv_into A' g"
381   have "inj_on ?f (g ` A')"
382     by (auto simp add: inj_on_inv_into)
383   moreover
384   {fix a' assume *: "a' \<in> A'"
385    let ?phi = "\<lambda> b'. b' \<in> A' \<and> g b' = g a'"
386    have "?phi a'" using * by auto
387    hence "?phi(SOME b'. ?phi b')" using someI[of ?phi] by blast
388    hence "?f(g a') \<in> A'" unfolding inv_into_def by auto
389   }
390   ultimately show "\<exists>f. inj_on f (g ` A') \<and> f ` g ` A' \<subseteq> A'" by auto
391 qed
393 lemma Ex_inj_on_UNION_Sigma:
394   "\<exists>f. (inj_on f (\<Union> i \<in> I. A i) \<and> f ` (\<Union> i \<in> I. A i) \<le> (SIGMA i : I. A i))"
395 proof
396   let ?phi = "\<lambda> a i. i \<in> I \<and> a \<in> A i"
397   let ?sm = "\<lambda> a. SOME i. ?phi a i"
398   let ?f = "\<lambda>a. (?sm a, a)"
399   have "inj_on ?f (\<Union> i \<in> I. A i)" unfolding inj_on_def by auto
400   moreover
401   { { fix i a assume "i \<in> I" and "a \<in> A i"
402       hence "?sm a \<in> I \<and> a \<in> A(?sm a)" using someI[of "?phi a" i] by auto
403     }
404     hence "?f ` (\<Union> i \<in> I. A i) \<le> (SIGMA i : I. A i)" by auto
405   }
406   ultimately
407   show "inj_on ?f (\<Union> i \<in> I. A i) \<and> ?f ` (\<Union> i \<in> I. A i) \<le> (SIGMA i : I. A i)"
408   by auto
409 qed
411 subsection {* The Cantor-Bernstein Theorem *}
413 lemma Cantor_Bernstein_aux:
414   shows "\<exists>A' h. A' \<le> A \<and>
415                 (\<forall>a \<in> A'. a \<notin> g`(B - f ` A')) \<and>
416                 (\<forall>a \<in> A'. h a = f a) \<and>
417                 (\<forall>a \<in> A - A'. h a \<in> B - (f ` A') \<and> a = g(h a))"
418 proof-
419   obtain H where H_def: "H = (\<lambda> A'. A - (g`(B - (f ` A'))))" by blast
420   have 0: "mono H" unfolding mono_def H_def by blast
421   then obtain A' where 1: "H A' = A'" using lfp_unfold by blast
422   hence 2: "A' = A - (g`(B - (f ` A')))" unfolding H_def by simp
423   hence 3: "A' \<le> A" by blast
424   have 4: "\<forall>a \<in> A'.  a \<notin> g`(B - f ` A')"
425   using 2 by blast
426   have 5: "\<forall>a \<in> A - A'. \<exists>b \<in> B - (f ` A'). a = g b"
427   using 2 by blast
428   (*  *)
429   obtain h where h_def:
430   "h = (\<lambda> a. if a \<in> A' then f a else (SOME b. b \<in> B - (f ` A') \<and> a = g b))" by blast
431   hence "\<forall>a \<in> A'. h a = f a" by auto
432   moreover
433   have "\<forall>a \<in> A - A'. h a \<in> B - (f ` A') \<and> a = g(h a)"
434   proof
435     fix a assume *: "a \<in> A - A'"
436     let ?phi = "\<lambda> b. b \<in> B - (f ` A') \<and> a = g b"
437     have "h a = (SOME b. ?phi b)" using h_def * by auto
438     moreover have "\<exists>b. ?phi b" using 5 *  by auto
439     ultimately show  "?phi (h a)" using someI_ex[of ?phi] by auto
440   qed
441   ultimately show ?thesis using 3 4 by blast
442 qed
444 theorem Cantor_Bernstein:
445   assumes INJ1: "inj_on f A" and SUB1: "f ` A \<le> B" and
446           INJ2: "inj_on g B" and SUB2: "g ` B \<le> A"
447   shows "\<exists>h. bij_betw h A B"
448 proof-
449   obtain A' and h where 0: "A' \<le> A" and
450   1: "\<forall>a \<in> A'. a \<notin> g`(B - f ` A')" and
451   2: "\<forall>a \<in> A'. h a = f a" and
452   3: "\<forall>a \<in> A - A'. h a \<in> B - (f ` A') \<and> a = g(h a)"
453   using Cantor_Bernstein_aux[of A g B f] by blast
454   have "inj_on h A"
455   proof (intro inj_onI)
456     fix a1 a2
457     assume 4: "a1 \<in> A" and 5: "a2 \<in> A" and 6: "h a1 = h a2"
458     show "a1 = a2"
459     proof(cases "a1 \<in> A'")
460       assume Case1: "a1 \<in> A'"
461       show ?thesis
462       proof(cases "a2 \<in> A'")
463         assume Case11: "a2 \<in> A'"
464         hence "f a1 = f a2" using Case1 2 6 by auto
465         thus ?thesis using INJ1 Case1 Case11 0
466         unfolding inj_on_def by blast
467       next
468         assume Case12: "a2 \<notin> A'"
469         hence False using 3 5 2 6 Case1 by force
470         thus ?thesis by simp
471       qed
472     next
473     assume Case2: "a1 \<notin> A'"
474       show ?thesis
475       proof(cases "a2 \<in> A'")
476         assume Case21: "a2 \<in> A'"
477         hence False using 3 4 2 6 Case2 by auto
478         thus ?thesis by simp
479       next
480         assume Case22: "a2 \<notin> A'"
481         hence "a1 = g(h a1) \<and> a2 = g(h a2)" using Case2 4 5 3 by auto
482         thus ?thesis using 6 by simp
483       qed
484     qed
485   qed
486   (*  *)
487   moreover
488   have "h ` A = B"
489   proof safe
490     fix a assume "a \<in> A"
491     thus "h a \<in> B" using SUB1 2 3 by (cases "a \<in> A'") auto
492   next
493     fix b assume *: "b \<in> B"
494     show "b \<in> h ` A"
495     proof(cases "b \<in> f ` A'")
496       assume Case1: "b \<in> f ` A'"
497       then obtain a where "a \<in> A' \<and> b = f a" by blast
498       thus ?thesis using 2 0 by force
499     next
500       assume Case2: "b \<notin> f ` A'"
501       hence "g b \<notin> A'" using 1 * by auto
502       hence 4: "g b \<in> A - A'" using * SUB2 by auto
503       hence "h(g b) \<in> B \<and> g(h(g b)) = g b"
504       using 3 by auto
505       hence "h(g b) = b" using * INJ2 unfolding inj_on_def by auto
506       thus ?thesis using 4 by force
507     qed
508   qed
509   (*  *)
510   ultimately show ?thesis unfolding bij_betw_def by auto
511 qed
513 subsection {*Other Consequences of Hilbert's Epsilon*}
515 text {*Hilbert's Epsilon and the @{term split} Operator*}
517 text{*Looping simprule*}
518 lemma split_paired_Eps: "(SOME x. P x) = (SOME (a,b). P(a,b))"
519   by simp
521 lemma Eps_split: "Eps (split P) = (SOME xy. P (fst xy) (snd xy))"
522   by (simp add: split_def)
524 lemma Eps_split_eq [simp]: "(@(x',y'). x = x' & y = y') = (x,y)"
525   by blast
528 text{*A relation is wellfounded iff it has no infinite descending chain*}
529 lemma wf_iff_no_infinite_down_chain:
530   "wf r = (~(\<exists>f. \<forall>i. (f(Suc i),f i) \<in> r))"
531 apply (simp only: wf_eq_minimal)
532 apply (rule iffI)
533  apply (rule notI)
534  apply (erule exE)
535  apply (erule_tac x = "{w. \<exists>i. w=f i}" in allE, blast)
536 apply (erule contrapos_np, simp, clarify)
537 apply (subgoal_tac "\<forall>n. rec_nat x (%i y. @z. z:Q & (z,y) :r) n \<in> Q")
538  apply (rule_tac x = "rec_nat x (%i y. @z. z:Q & (z,y) :r)" in exI)
539  apply (rule allI, simp)
540  apply (rule someI2_ex, blast, blast)
541 apply (rule allI)
542 apply (induct_tac "n", simp_all)
543 apply (rule someI2_ex, blast+)
544 done
546 lemma wf_no_infinite_down_chainE:
547   assumes "wf r" obtains k where "(f (Suc k), f k) \<notin> r"
548 using `wf r` wf_iff_no_infinite_down_chain[of r] by blast
551 text{*A dynamically-scoped fact for TFL *}
552 lemma tfl_some: "\<forall>P x. P x --> P (Eps P)"
553   by (blast intro: someI)
556 subsection {* Least value operator *}
558 definition
559   LeastM :: "['a => 'b::ord, 'a => bool] => 'a" where
560   "LeastM m P == SOME x. P x & (\<forall>y. P y --> m x <= m y)"
562 syntax
563   "_LeastM" :: "[pttrn, 'a => 'b::ord, bool] => 'a"    ("LEAST _ WRT _. _" [0, 4, 10] 10)
564 translations
565   "LEAST x WRT m. P" == "CONST LeastM m (%x. P)"
567 lemma LeastMI2:
568   "P x ==> (!!y. P y ==> m x <= m y)
569     ==> (!!x. P x ==> \<forall>y. P y --> m x \<le> m y ==> Q x)
570     ==> Q (LeastM m P)"
571   apply (simp add: LeastM_def)
572   apply (rule someI2_ex, blast, blast)
573   done
575 lemma LeastM_equality:
576   "P k ==> (!!x. P x ==> m k <= m x)
577     ==> m (LEAST x WRT m. P x) = (m k::'a::order)"
578   apply (rule LeastMI2, assumption, blast)
579   apply (blast intro!: order_antisym)
580   done
582 lemma wf_linord_ex_has_least:
583   "wf r ==> \<forall>x y. ((x,y):r^+) = ((y,x)~:r^*) ==> P k
584     ==> \<exists>x. P x & (!y. P y --> (m x,m y):r^*)"
585   apply (drule wf_trancl [THEN wf_eq_minimal [THEN iffD1]])
586   apply (drule_tac x = "m`Collect P" in spec, force)
587   done
589 lemma ex_has_least_nat:
590     "P k ==> \<exists>x. P x & (\<forall>y. P y --> m x <= (m y::nat))"
591   apply (simp only: pred_nat_trancl_eq_le [symmetric])
592   apply (rule wf_pred_nat [THEN wf_linord_ex_has_least])
593    apply (simp add: less_eq linorder_not_le pred_nat_trancl_eq_le, assumption)
594   done
596 lemma LeastM_nat_lemma:
597     "P k ==> P (LeastM m P) & (\<forall>y. P y --> m (LeastM m P) <= (m y::nat))"
598   apply (simp add: LeastM_def)
599   apply (rule someI_ex)
600   apply (erule ex_has_least_nat)
601   done
603 lemmas LeastM_natI = LeastM_nat_lemma [THEN conjunct1]
605 lemma LeastM_nat_le: "P x ==> m (LeastM m P) <= (m x::nat)"
606 by (rule LeastM_nat_lemma [THEN conjunct2, THEN spec, THEN mp], assumption, assumption)
609 subsection {* Greatest value operator *}
611 definition
612   GreatestM :: "['a => 'b::ord, 'a => bool] => 'a" where
613   "GreatestM m P == SOME x. P x & (\<forall>y. P y --> m y <= m x)"
615 definition
616   Greatest :: "('a::ord => bool) => 'a" (binder "GREATEST " 10) where
617   "Greatest == GreatestM (%x. x)"
619 syntax
620   "_GreatestM" :: "[pttrn, 'a => 'b::ord, bool] => 'a"
621       ("GREATEST _ WRT _. _" [0, 4, 10] 10)
622 translations
623   "GREATEST x WRT m. P" == "CONST GreatestM m (%x. P)"
625 lemma GreatestMI2:
626   "P x ==> (!!y. P y ==> m y <= m x)
627     ==> (!!x. P x ==> \<forall>y. P y --> m y \<le> m x ==> Q x)
628     ==> Q (GreatestM m P)"
629   apply (simp add: GreatestM_def)
630   apply (rule someI2_ex, blast, blast)
631   done
633 lemma GreatestM_equality:
634  "P k ==> (!!x. P x ==> m x <= m k)
635     ==> m (GREATEST x WRT m. P x) = (m k::'a::order)"
636   apply (rule_tac m = m in GreatestMI2, assumption, blast)
637   apply (blast intro!: order_antisym)
638   done
640 lemma Greatest_equality:
641   "P (k::'a::order) ==> (!!x. P x ==> x <= k) ==> (GREATEST x. P x) = k"
642   apply (simp add: Greatest_def)
643   apply (erule GreatestM_equality, blast)
644   done
646 lemma ex_has_greatest_nat_lemma:
647   "P k ==> \<forall>x. P x --> (\<exists>y. P y & ~ ((m y::nat) <= m x))
648     ==> \<exists>y. P y & ~ (m y < m k + n)"
649   apply (induct n, force)
650   apply (force simp add: le_Suc_eq)
651   done
653 lemma ex_has_greatest_nat:
654   "P k ==> \<forall>y. P y --> m y < b
655     ==> \<exists>x. P x & (\<forall>y. P y --> (m y::nat) <= m x)"
656   apply (rule ccontr)
657   apply (cut_tac P = P and n = "b - m k" in ex_has_greatest_nat_lemma)
658     apply (subgoal_tac  "m k <= b", auto)
659   done
661 lemma GreatestM_nat_lemma:
662   "P k ==> \<forall>y. P y --> m y < b
663     ==> P (GreatestM m P) & (\<forall>y. P y --> (m y::nat) <= m (GreatestM m P))"
664   apply (simp add: GreatestM_def)
665   apply (rule someI_ex)
666   apply (erule ex_has_greatest_nat, assumption)
667   done
669 lemmas GreatestM_natI = GreatestM_nat_lemma [THEN conjunct1]
671 lemma GreatestM_nat_le:
672   "P x ==> \<forall>y. P y --> m y < b
673     ==> (m x::nat) <= m (GreatestM m P)"
674   apply (blast dest: GreatestM_nat_lemma [THEN conjunct2, THEN spec, of P])
675   done
678 text {* \medskip Specialization to @{text GREATEST}. *}
680 lemma GreatestI: "P (k::nat) ==> \<forall>y. P y --> y < b ==> P (GREATEST x. P x)"
681   apply (simp add: Greatest_def)
682   apply (rule GreatestM_natI, auto)
683   done
685 lemma Greatest_le:
686     "P x ==> \<forall>y. P y --> y < b ==> (x::nat) <= (GREATEST x. P x)"
687   apply (simp add: Greatest_def)
688   apply (rule GreatestM_nat_le, auto)
689   done
692 subsection {* An aside: bounded accessible part *}
694 text {* Finite monotone eventually stable sequences *}
696 lemma finite_mono_remains_stable_implies_strict_prefix:
697   fixes f :: "nat \<Rightarrow> 'a::order"
698   assumes S: "finite (range f)" "mono f" and eq: "\<forall>n. f n = f (Suc n) \<longrightarrow> f (Suc n) = f (Suc (Suc n))"
699   shows "\<exists>N. (\<forall>n\<le>N. \<forall>m\<le>N. m < n \<longrightarrow> f m < f n) \<and> (\<forall>n\<ge>N. f N = f n)"
700   using assms
701 proof -
702   have "\<exists>n. f n = f (Suc n)"
703   proof (rule ccontr)
704     assume "\<not> ?thesis"
705     then have "\<And>n. f n \<noteq> f (Suc n)" by auto
706     then have "\<And>n. f n < f (Suc n)"
707       using  `mono f` by (auto simp: le_less mono_iff_le_Suc)
708     with lift_Suc_mono_less_iff[of f]
709     have "\<And>n m. n < m \<Longrightarrow> f n < f m" by auto
710     then have "inj f"
711       by (auto simp: inj_on_def) (metis linorder_less_linear order_less_imp_not_eq)
712     with `finite (range f)` have "finite (UNIV::nat set)"
713       by (rule finite_imageD)
714     then show False by simp
715   qed
716   then obtain n where n: "f n = f (Suc n)" ..
717   def N \<equiv> "LEAST n. f n = f (Suc n)"
718   have N: "f N = f (Suc N)"
719     unfolding N_def using n by (rule LeastI)
720   show ?thesis
721   proof (intro exI[of _ N] conjI allI impI)
722     fix n assume "N \<le> n"
723     then have "\<And>m. N \<le> m \<Longrightarrow> m \<le> n \<Longrightarrow> f m = f N"
724     proof (induct rule: dec_induct)
725       case (step n) then show ?case
726         using eq[rule_format, of "n - 1"] N
727         by (cases n) (auto simp add: le_Suc_eq)
728     qed simp
729     from this[of n] `N \<le> n` show "f N = f n" by auto
730   next
731     fix n m :: nat assume "m < n" "n \<le> N"
732     then show "f m < f n"
733     proof (induct rule: less_Suc_induct[consumes 1])
734       case (1 i)
735       then have "i < N" by simp
736       then have "f i \<noteq> f (Suc i)"
737         unfolding N_def by (rule not_less_Least)
738       with `mono f` show ?case by (simp add: mono_iff_le_Suc less_le)
739     qed auto
740   qed
741 qed
743 lemma finite_mono_strict_prefix_implies_finite_fixpoint:
744   fixes f :: "nat \<Rightarrow> 'a set"
745   assumes S: "\<And>i. f i \<subseteq> S" "finite S"
746     and inj: "\<exists>N. (\<forall>n\<le>N. \<forall>m\<le>N. m < n \<longrightarrow> f m \<subset> f n) \<and> (\<forall>n\<ge>N. f N = f n)"
747   shows "f (card S) = (\<Union>n. f n)"
748 proof -
749   from inj obtain N where inj: "(\<forall>n\<le>N. \<forall>m\<le>N. m < n \<longrightarrow> f m \<subset> f n)" and eq: "(\<forall>n\<ge>N. f N = f n)" by auto
751   { fix i have "i \<le> N \<Longrightarrow> i \<le> card (f i)"
752     proof (induct i)
753       case 0 then show ?case by simp
754     next
755       case (Suc i)
756       with inj[rule_format, of "Suc i" i]
757       have "(f i) \<subset> (f (Suc i))" by auto
758       moreover have "finite (f (Suc i))" using S by (rule finite_subset)
759       ultimately have "card (f i) < card (f (Suc i))" by (intro psubset_card_mono)
760       with Suc show ?case using inj by auto
761     qed
762   }
763   then have "N \<le> card (f N)" by simp
764   also have "\<dots> \<le> card S" using S by (intro card_mono)
765   finally have "f (card S) = f N" using eq by auto
766   then show ?thesis using eq inj[rule_format, of N]
767     apply auto
768     apply (case_tac "n < N")
769     apply (auto simp: not_less)
770     done
771 qed
774 subsection {* More on injections, bijections, and inverses *}
776 lemma infinite_imp_bij_betw:
777 assumes INF: "\<not> finite A"
778 shows "\<exists>h. bij_betw h A (A - {a})"
779 proof(cases "a \<in> A")
780   assume Case1: "a \<notin> A"  hence "A - {a} = A" by blast
781   thus ?thesis using bij_betw_id[of A] by auto
782 next
783   assume Case2: "a \<in> A"
784 find_theorems "\<not> finite _"
785   have "\<not> finite (A - {a})" using INF by auto
786   with infinite_iff_countable_subset[of "A - {a}"] obtain f::"nat \<Rightarrow> 'a"
787   where 1: "inj f" and 2: "f ` UNIV \<le> A - {a}" by blast
788   obtain g where g_def: "g = (\<lambda> n. if n = 0 then a else f (Suc n))" by blast
789   obtain A' where A'_def: "A' = g ` UNIV" by blast
790   have temp: "\<forall>y. f y \<noteq> a" using 2 by blast
791   have 3: "inj_on g UNIV \<and> g ` UNIV \<le> A \<and> a \<in> g ` UNIV"
792   proof(auto simp add: Case2 g_def, unfold inj_on_def, intro ballI impI,
793         case_tac "x = 0", auto simp add: 2)
794     fix y  assume "a = (if y = 0 then a else f (Suc y))"
795     thus "y = 0" using temp by (case_tac "y = 0", auto)
796   next
797     fix x y
798     assume "f (Suc x) = (if y = 0 then a else f (Suc y))"
799     thus "x = y" using 1 temp unfolding inj_on_def by (case_tac "y = 0", auto)
800   next
801     fix n show "f (Suc n) \<in> A" using 2 by blast
802   qed
803   hence 4: "bij_betw g UNIV A' \<and> a \<in> A' \<and> A' \<le> A"
804   using inj_on_imp_bij_betw[of g] unfolding A'_def by auto
805   hence 5: "bij_betw (inv g) A' UNIV"
806   by (auto simp add: bij_betw_inv_into)
807   (*  *)
808   obtain n where "g n = a" using 3 by auto
809   hence 6: "bij_betw g (UNIV - {n}) (A' - {a})"
810   using 3 4 unfolding A'_def
811   by clarify (rule bij_betw_subset, auto simp: image_set_diff)
812   (*  *)
813   obtain v where v_def: "v = (\<lambda> m. if m < n then m else Suc m)" by blast
814   have 7: "bij_betw v UNIV (UNIV - {n})"
815   proof(unfold bij_betw_def inj_on_def, intro conjI, clarify)
816     fix m1 m2 assume "v m1 = v m2"
817     thus "m1 = m2"
818     by(case_tac "m1 < n", case_tac "m2 < n",
819        auto simp add: inj_on_def v_def, case_tac "m2 < n", auto)
820   next
821     show "v ` UNIV = UNIV - {n}"
822     proof(auto simp add: v_def)
823       fix m assume *: "m \<noteq> n" and **: "m \<notin> Suc ` {m'. \<not> m' < n}"
824       {assume "n \<le> m" with * have 71: "Suc n \<le> m" by auto
825        then obtain m' where 72: "m = Suc m'" using Suc_le_D by auto
826        with 71 have "n \<le> m'" by auto
827        with 72 ** have False by auto
828       }
829       thus "m < n" by force
830     qed
831   qed
832   (*  *)
833   obtain h' where h'_def: "h' = g o v o (inv g)" by blast
834   hence 8: "bij_betw h' A' (A' - {a})" using 5 7 6
835   by (auto simp add: bij_betw_trans)
836   (*  *)
837   obtain h where h_def: "h = (\<lambda> b. if b \<in> A' then h' b else b)" by blast
838   have "\<forall>b \<in> A'. h b = h' b" unfolding h_def by auto
839   hence "bij_betw h  A' (A' - {a})" using 8 bij_betw_cong[of A' h] by auto
840   moreover
841   {have "\<forall>b \<in> A - A'. h b = b" unfolding h_def by auto
842    hence "bij_betw h  (A - A') (A - A')"
843    using bij_betw_cong[of "A - A'" h id] bij_betw_id[of "A - A'"] by auto
844   }
845   moreover
846   have "(A' Int (A - A') = {} \<and> A' \<union> (A - A') = A) \<and>
847         ((A' - {a}) Int (A - A') = {} \<and> (A' - {a}) \<union> (A - A') = A - {a})"
848   using 4 by blast
849   ultimately have "bij_betw h A (A - {a})"
850   using bij_betw_combine[of h A' "A' - {a}" "A - A'" "A - A'"] by simp
851   thus ?thesis by blast
852 qed
854 lemma infinite_imp_bij_betw2:
855 assumes INF: "\<not> finite A"
856 shows "\<exists>h. bij_betw h A (A \<union> {a})"
857 proof(cases "a \<in> A")
858   assume Case1: "a \<in> A"  hence "A \<union> {a} = A" by blast
859   thus ?thesis using bij_betw_id[of A] by auto
860 next
861   let ?A' = "A \<union> {a}"
862   assume Case2: "a \<notin> A" hence "A = ?A' - {a}" by blast
863   moreover have "\<not> finite ?A'" using INF by auto
864   ultimately obtain f where "bij_betw f ?A' A"
865   using infinite_imp_bij_betw[of ?A' a] by auto
866   hence "bij_betw(inv_into ?A' f) A ?A'" using bij_betw_inv_into by blast
867   thus ?thesis by auto
868 qed
870 lemma bij_betw_inv_into_left:
871 assumes BIJ: "bij_betw f A A'" and IN: "a \<in> A"
872 shows "(inv_into A f) (f a) = a"
873 using assms unfolding bij_betw_def
874 by clarify (rule inv_into_f_f)
876 lemma bij_betw_inv_into_right:
877 assumes "bij_betw f A A'" "a' \<in> A'"
878 shows "f(inv_into A f a') = a'"
879 using assms unfolding bij_betw_def using f_inv_into_f by force
881 lemma bij_betw_inv_into_subset:
882 assumes BIJ: "bij_betw f A A'" and
883         SUB: "B \<le> A" and IM: "f ` B = B'"
884 shows "bij_betw (inv_into A f) B' B"
885 using assms unfolding bij_betw_def
886 by (auto intro: inj_on_inv_into)
889 subsection {* Specification package -- Hilbertized version *}
891 lemma exE_some: "[| Ex P ; c == Eps P |] ==> P c"
892   by (simp only: someI_ex)
894 ML_file "Tools/choice_specification.ML"
896 end