src/HOL/Real_Vector_Spaces.thy
author blanchet
Wed Feb 12 08:35:57 2014 +0100 (2014-02-12)
changeset 55415 05f5fdb8d093
parent 54890 cb892d835803
child 55719 cdddd073bff8
permissions -rw-r--r--
renamed 'nat_{case,rec}' to '{case,rec}_nat'
     1 (*  Title:      HOL/Real_Vector_Spaces.thy
     2     Author:     Brian Huffman
     3     Author:     Johannes Hölzl
     4 *)
     5 
     6 header {* Vector Spaces and Algebras over the Reals *}
     7 
     8 theory Real_Vector_Spaces
     9 imports Real Topological_Spaces
    10 begin
    11 
    12 subsection {* Locale for additive functions *}
    13 
    14 locale additive =
    15   fixes f :: "'a::ab_group_add \<Rightarrow> 'b::ab_group_add"
    16   assumes add: "f (x + y) = f x + f y"
    17 begin
    18 
    19 lemma zero: "f 0 = 0"
    20 proof -
    21   have "f 0 = f (0 + 0)" by simp
    22   also have "\<dots> = f 0 + f 0" by (rule add)
    23   finally show "f 0 = 0" by simp
    24 qed
    25 
    26 lemma minus: "f (- x) = - f x"
    27 proof -
    28   have "f (- x) + f x = f (- x + x)" by (rule add [symmetric])
    29   also have "\<dots> = - f x + f x" by (simp add: zero)
    30   finally show "f (- x) = - f x" by (rule add_right_imp_eq)
    31 qed
    32 
    33 lemma diff: "f (x - y) = f x - f y"
    34   using add [of x "- y"] by (simp add: minus)
    35 
    36 lemma setsum: "f (setsum g A) = (\<Sum>x\<in>A. f (g x))"
    37 apply (cases "finite A")
    38 apply (induct set: finite)
    39 apply (simp add: zero)
    40 apply (simp add: add)
    41 apply (simp add: zero)
    42 done
    43 
    44 end
    45 
    46 subsection {* Vector spaces *}
    47 
    48 locale vector_space =
    49   fixes scale :: "'a::field \<Rightarrow> 'b::ab_group_add \<Rightarrow> 'b"
    50   assumes scale_right_distrib [algebra_simps]:
    51     "scale a (x + y) = scale a x + scale a y"
    52   and scale_left_distrib [algebra_simps]:
    53     "scale (a + b) x = scale a x + scale b x"
    54   and scale_scale [simp]: "scale a (scale b x) = scale (a * b) x"
    55   and scale_one [simp]: "scale 1 x = x"
    56 begin
    57 
    58 lemma scale_left_commute:
    59   "scale a (scale b x) = scale b (scale a x)"
    60 by (simp add: mult_commute)
    61 
    62 lemma scale_zero_left [simp]: "scale 0 x = 0"
    63   and scale_minus_left [simp]: "scale (- a) x = - (scale a x)"
    64   and scale_left_diff_distrib [algebra_simps]:
    65         "scale (a - b) x = scale a x - scale b x"
    66   and scale_setsum_left: "scale (setsum f A) x = (\<Sum>a\<in>A. scale (f a) x)"
    67 proof -
    68   interpret s: additive "\<lambda>a. scale a x"
    69     proof qed (rule scale_left_distrib)
    70   show "scale 0 x = 0" by (rule s.zero)
    71   show "scale (- a) x = - (scale a x)" by (rule s.minus)
    72   show "scale (a - b) x = scale a x - scale b x" by (rule s.diff)
    73   show "scale (setsum f A) x = (\<Sum>a\<in>A. scale (f a) x)" by (rule s.setsum)
    74 qed
    75 
    76 lemma scale_zero_right [simp]: "scale a 0 = 0"
    77   and scale_minus_right [simp]: "scale a (- x) = - (scale a x)"
    78   and scale_right_diff_distrib [algebra_simps]:
    79         "scale a (x - y) = scale a x - scale a y"
    80   and scale_setsum_right: "scale a (setsum f A) = (\<Sum>x\<in>A. scale a (f x))"
    81 proof -
    82   interpret s: additive "\<lambda>x. scale a x"
    83     proof qed (rule scale_right_distrib)
    84   show "scale a 0 = 0" by (rule s.zero)
    85   show "scale a (- x) = - (scale a x)" by (rule s.minus)
    86   show "scale a (x - y) = scale a x - scale a y" by (rule s.diff)
    87   show "scale a (setsum f A) = (\<Sum>x\<in>A. scale a (f x))" by (rule s.setsum)
    88 qed
    89 
    90 lemma scale_eq_0_iff [simp]:
    91   "scale a x = 0 \<longleftrightarrow> a = 0 \<or> x = 0"
    92 proof cases
    93   assume "a = 0" thus ?thesis by simp
    94 next
    95   assume anz [simp]: "a \<noteq> 0"
    96   { assume "scale a x = 0"
    97     hence "scale (inverse a) (scale a x) = 0" by simp
    98     hence "x = 0" by simp }
    99   thus ?thesis by force
   100 qed
   101 
   102 lemma scale_left_imp_eq:
   103   "\<lbrakk>a \<noteq> 0; scale a x = scale a y\<rbrakk> \<Longrightarrow> x = y"
   104 proof -
   105   assume nonzero: "a \<noteq> 0"
   106   assume "scale a x = scale a y"
   107   hence "scale a (x - y) = 0"
   108      by (simp add: scale_right_diff_distrib)
   109   hence "x - y = 0" by (simp add: nonzero)
   110   thus "x = y" by (simp only: right_minus_eq)
   111 qed
   112 
   113 lemma scale_right_imp_eq:
   114   "\<lbrakk>x \<noteq> 0; scale a x = scale b x\<rbrakk> \<Longrightarrow> a = b"
   115 proof -
   116   assume nonzero: "x \<noteq> 0"
   117   assume "scale a x = scale b x"
   118   hence "scale (a - b) x = 0"
   119      by (simp add: scale_left_diff_distrib)
   120   hence "a - b = 0" by (simp add: nonzero)
   121   thus "a = b" by (simp only: right_minus_eq)
   122 qed
   123 
   124 lemma scale_cancel_left [simp]:
   125   "scale a x = scale a y \<longleftrightarrow> x = y \<or> a = 0"
   126 by (auto intro: scale_left_imp_eq)
   127 
   128 lemma scale_cancel_right [simp]:
   129   "scale a x = scale b x \<longleftrightarrow> a = b \<or> x = 0"
   130 by (auto intro: scale_right_imp_eq)
   131 
   132 end
   133 
   134 subsection {* Real vector spaces *}
   135 
   136 class scaleR =
   137   fixes scaleR :: "real \<Rightarrow> 'a \<Rightarrow> 'a" (infixr "*\<^sub>R" 75)
   138 begin
   139 
   140 abbreviation
   141   divideR :: "'a \<Rightarrow> real \<Rightarrow> 'a" (infixl "'/\<^sub>R" 70)
   142 where
   143   "x /\<^sub>R r == scaleR (inverse r) x"
   144 
   145 end
   146 
   147 class real_vector = scaleR + ab_group_add +
   148   assumes scaleR_add_right: "scaleR a (x + y) = scaleR a x + scaleR a y"
   149   and scaleR_add_left: "scaleR (a + b) x = scaleR a x + scaleR b x"
   150   and scaleR_scaleR: "scaleR a (scaleR b x) = scaleR (a * b) x"
   151   and scaleR_one: "scaleR 1 x = x"
   152 
   153 interpretation real_vector:
   154   vector_space "scaleR :: real \<Rightarrow> 'a \<Rightarrow> 'a::real_vector"
   155 apply unfold_locales
   156 apply (rule scaleR_add_right)
   157 apply (rule scaleR_add_left)
   158 apply (rule scaleR_scaleR)
   159 apply (rule scaleR_one)
   160 done
   161 
   162 text {* Recover original theorem names *}
   163 
   164 lemmas scaleR_left_commute = real_vector.scale_left_commute
   165 lemmas scaleR_zero_left = real_vector.scale_zero_left
   166 lemmas scaleR_minus_left = real_vector.scale_minus_left
   167 lemmas scaleR_diff_left = real_vector.scale_left_diff_distrib
   168 lemmas scaleR_setsum_left = real_vector.scale_setsum_left
   169 lemmas scaleR_zero_right = real_vector.scale_zero_right
   170 lemmas scaleR_minus_right = real_vector.scale_minus_right
   171 lemmas scaleR_diff_right = real_vector.scale_right_diff_distrib
   172 lemmas scaleR_setsum_right = real_vector.scale_setsum_right
   173 lemmas scaleR_eq_0_iff = real_vector.scale_eq_0_iff
   174 lemmas scaleR_left_imp_eq = real_vector.scale_left_imp_eq
   175 lemmas scaleR_right_imp_eq = real_vector.scale_right_imp_eq
   176 lemmas scaleR_cancel_left = real_vector.scale_cancel_left
   177 lemmas scaleR_cancel_right = real_vector.scale_cancel_right
   178 
   179 text {* Legacy names *}
   180 
   181 lemmas scaleR_left_distrib = scaleR_add_left
   182 lemmas scaleR_right_distrib = scaleR_add_right
   183 lemmas scaleR_left_diff_distrib = scaleR_diff_left
   184 lemmas scaleR_right_diff_distrib = scaleR_diff_right
   185 
   186 lemma scaleR_minus1_left [simp]:
   187   fixes x :: "'a::real_vector"
   188   shows "scaleR (-1) x = - x"
   189   using scaleR_minus_left [of 1 x] by simp
   190 
   191 class real_algebra = real_vector + ring +
   192   assumes mult_scaleR_left [simp]: "scaleR a x * y = scaleR a (x * y)"
   193   and mult_scaleR_right [simp]: "x * scaleR a y = scaleR a (x * y)"
   194 
   195 class real_algebra_1 = real_algebra + ring_1
   196 
   197 class real_div_algebra = real_algebra_1 + division_ring
   198 
   199 class real_field = real_div_algebra + field
   200 
   201 instantiation real :: real_field
   202 begin
   203 
   204 definition
   205   real_scaleR_def [simp]: "scaleR a x = a * x"
   206 
   207 instance proof
   208 qed (simp_all add: algebra_simps)
   209 
   210 end
   211 
   212 interpretation scaleR_left: additive "(\<lambda>a. scaleR a x::'a::real_vector)"
   213 proof qed (rule scaleR_left_distrib)
   214 
   215 interpretation scaleR_right: additive "(\<lambda>x. scaleR a x::'a::real_vector)"
   216 proof qed (rule scaleR_right_distrib)
   217 
   218 lemma nonzero_inverse_scaleR_distrib:
   219   fixes x :: "'a::real_div_algebra" shows
   220   "\<lbrakk>a \<noteq> 0; x \<noteq> 0\<rbrakk> \<Longrightarrow> inverse (scaleR a x) = scaleR (inverse a) (inverse x)"
   221 by (rule inverse_unique, simp)
   222 
   223 lemma inverse_scaleR_distrib:
   224   fixes x :: "'a::{real_div_algebra, division_ring_inverse_zero}"
   225   shows "inverse (scaleR a x) = scaleR (inverse a) (inverse x)"
   226 apply (case_tac "a = 0", simp)
   227 apply (case_tac "x = 0", simp)
   228 apply (erule (1) nonzero_inverse_scaleR_distrib)
   229 done
   230 
   231 
   232 subsection {* Embedding of the Reals into any @{text real_algebra_1}:
   233 @{term of_real} *}
   234 
   235 definition
   236   of_real :: "real \<Rightarrow> 'a::real_algebra_1" where
   237   "of_real r = scaleR r 1"
   238 
   239 lemma scaleR_conv_of_real: "scaleR r x = of_real r * x"
   240 by (simp add: of_real_def)
   241 
   242 lemma of_real_0 [simp]: "of_real 0 = 0"
   243 by (simp add: of_real_def)
   244 
   245 lemma of_real_1 [simp]: "of_real 1 = 1"
   246 by (simp add: of_real_def)
   247 
   248 lemma of_real_add [simp]: "of_real (x + y) = of_real x + of_real y"
   249 by (simp add: of_real_def scaleR_left_distrib)
   250 
   251 lemma of_real_minus [simp]: "of_real (- x) = - of_real x"
   252 by (simp add: of_real_def)
   253 
   254 lemma of_real_diff [simp]: "of_real (x - y) = of_real x - of_real y"
   255 by (simp add: of_real_def scaleR_left_diff_distrib)
   256 
   257 lemma of_real_mult [simp]: "of_real (x * y) = of_real x * of_real y"
   258 by (simp add: of_real_def mult_commute)
   259 
   260 lemma nonzero_of_real_inverse:
   261   "x \<noteq> 0 \<Longrightarrow> of_real (inverse x) =
   262    inverse (of_real x :: 'a::real_div_algebra)"
   263 by (simp add: of_real_def nonzero_inverse_scaleR_distrib)
   264 
   265 lemma of_real_inverse [simp]:
   266   "of_real (inverse x) =
   267    inverse (of_real x :: 'a::{real_div_algebra, division_ring_inverse_zero})"
   268 by (simp add: of_real_def inverse_scaleR_distrib)
   269 
   270 lemma nonzero_of_real_divide:
   271   "y \<noteq> 0 \<Longrightarrow> of_real (x / y) =
   272    (of_real x / of_real y :: 'a::real_field)"
   273 by (simp add: divide_inverse nonzero_of_real_inverse)
   274 
   275 lemma of_real_divide [simp]:
   276   "of_real (x / y) =
   277    (of_real x / of_real y :: 'a::{real_field, field_inverse_zero})"
   278 by (simp add: divide_inverse)
   279 
   280 lemma of_real_power [simp]:
   281   "of_real (x ^ n) = (of_real x :: 'a::{real_algebra_1}) ^ n"
   282 by (induct n) simp_all
   283 
   284 lemma of_real_eq_iff [simp]: "(of_real x = of_real y) = (x = y)"
   285 by (simp add: of_real_def)
   286 
   287 lemma inj_of_real:
   288   "inj of_real"
   289   by (auto intro: injI)
   290 
   291 lemmas of_real_eq_0_iff [simp] = of_real_eq_iff [of _ 0, simplified]
   292 
   293 lemma of_real_eq_id [simp]: "of_real = (id :: real \<Rightarrow> real)"
   294 proof
   295   fix r
   296   show "of_real r = id r"
   297     by (simp add: of_real_def)
   298 qed
   299 
   300 text{*Collapse nested embeddings*}
   301 lemma of_real_of_nat_eq [simp]: "of_real (of_nat n) = of_nat n"
   302 by (induct n) auto
   303 
   304 lemma of_real_of_int_eq [simp]: "of_real (of_int z) = of_int z"
   305 by (cases z rule: int_diff_cases, simp)
   306 
   307 lemma of_real_numeral: "of_real (numeral w) = numeral w"
   308 using of_real_of_int_eq [of "numeral w"] by simp
   309 
   310 lemma of_real_neg_numeral: "of_real (- numeral w) = - numeral w"
   311 using of_real_of_int_eq [of "- numeral w"] by simp
   312 
   313 text{*Every real algebra has characteristic zero*}
   314 
   315 instance real_algebra_1 < ring_char_0
   316 proof
   317   from inj_of_real inj_of_nat have "inj (of_real \<circ> of_nat)" by (rule inj_comp)
   318   then show "inj (of_nat :: nat \<Rightarrow> 'a)" by (simp add: comp_def)
   319 qed
   320 
   321 instance real_field < field_char_0 ..
   322 
   323 
   324 subsection {* The Set of Real Numbers *}
   325 
   326 definition Reals :: "'a::real_algebra_1 set" where
   327   "Reals = range of_real"
   328 
   329 notation (xsymbols)
   330   Reals  ("\<real>")
   331 
   332 lemma Reals_of_real [simp]: "of_real r \<in> Reals"
   333 by (simp add: Reals_def)
   334 
   335 lemma Reals_of_int [simp]: "of_int z \<in> Reals"
   336 by (subst of_real_of_int_eq [symmetric], rule Reals_of_real)
   337 
   338 lemma Reals_of_nat [simp]: "of_nat n \<in> Reals"
   339 by (subst of_real_of_nat_eq [symmetric], rule Reals_of_real)
   340 
   341 lemma Reals_numeral [simp]: "numeral w \<in> Reals"
   342 by (subst of_real_numeral [symmetric], rule Reals_of_real)
   343 
   344 lemma Reals_0 [simp]: "0 \<in> Reals"
   345 apply (unfold Reals_def)
   346 apply (rule range_eqI)
   347 apply (rule of_real_0 [symmetric])
   348 done
   349 
   350 lemma Reals_1 [simp]: "1 \<in> Reals"
   351 apply (unfold Reals_def)
   352 apply (rule range_eqI)
   353 apply (rule of_real_1 [symmetric])
   354 done
   355 
   356 lemma Reals_add [simp]: "\<lbrakk>a \<in> Reals; b \<in> Reals\<rbrakk> \<Longrightarrow> a + b \<in> Reals"
   357 apply (auto simp add: Reals_def)
   358 apply (rule range_eqI)
   359 apply (rule of_real_add [symmetric])
   360 done
   361 
   362 lemma Reals_minus [simp]: "a \<in> Reals \<Longrightarrow> - a \<in> Reals"
   363 apply (auto simp add: Reals_def)
   364 apply (rule range_eqI)
   365 apply (rule of_real_minus [symmetric])
   366 done
   367 
   368 lemma Reals_diff [simp]: "\<lbrakk>a \<in> Reals; b \<in> Reals\<rbrakk> \<Longrightarrow> a - b \<in> Reals"
   369 apply (auto simp add: Reals_def)
   370 apply (rule range_eqI)
   371 apply (rule of_real_diff [symmetric])
   372 done
   373 
   374 lemma Reals_mult [simp]: "\<lbrakk>a \<in> Reals; b \<in> Reals\<rbrakk> \<Longrightarrow> a * b \<in> Reals"
   375 apply (auto simp add: Reals_def)
   376 apply (rule range_eqI)
   377 apply (rule of_real_mult [symmetric])
   378 done
   379 
   380 lemma nonzero_Reals_inverse:
   381   fixes a :: "'a::real_div_algebra"
   382   shows "\<lbrakk>a \<in> Reals; a \<noteq> 0\<rbrakk> \<Longrightarrow> inverse a \<in> Reals"
   383 apply (auto simp add: Reals_def)
   384 apply (rule range_eqI)
   385 apply (erule nonzero_of_real_inverse [symmetric])
   386 done
   387 
   388 lemma Reals_inverse [simp]:
   389   fixes a :: "'a::{real_div_algebra, division_ring_inverse_zero}"
   390   shows "a \<in> Reals \<Longrightarrow> inverse a \<in> Reals"
   391 apply (auto simp add: Reals_def)
   392 apply (rule range_eqI)
   393 apply (rule of_real_inverse [symmetric])
   394 done
   395 
   396 lemma nonzero_Reals_divide:
   397   fixes a b :: "'a::real_field"
   398   shows "\<lbrakk>a \<in> Reals; b \<in> Reals; b \<noteq> 0\<rbrakk> \<Longrightarrow> a / b \<in> Reals"
   399 apply (auto simp add: Reals_def)
   400 apply (rule range_eqI)
   401 apply (erule nonzero_of_real_divide [symmetric])
   402 done
   403 
   404 lemma Reals_divide [simp]:
   405   fixes a b :: "'a::{real_field, field_inverse_zero}"
   406   shows "\<lbrakk>a \<in> Reals; b \<in> Reals\<rbrakk> \<Longrightarrow> a / b \<in> Reals"
   407 apply (auto simp add: Reals_def)
   408 apply (rule range_eqI)
   409 apply (rule of_real_divide [symmetric])
   410 done
   411 
   412 lemma Reals_power [simp]:
   413   fixes a :: "'a::{real_algebra_1}"
   414   shows "a \<in> Reals \<Longrightarrow> a ^ n \<in> Reals"
   415 apply (auto simp add: Reals_def)
   416 apply (rule range_eqI)
   417 apply (rule of_real_power [symmetric])
   418 done
   419 
   420 lemma Reals_cases [cases set: Reals]:
   421   assumes "q \<in> \<real>"
   422   obtains (of_real) r where "q = of_real r"
   423   unfolding Reals_def
   424 proof -
   425   from `q \<in> \<real>` have "q \<in> range of_real" unfolding Reals_def .
   426   then obtain r where "q = of_real r" ..
   427   then show thesis ..
   428 qed
   429 
   430 lemma Reals_induct [case_names of_real, induct set: Reals]:
   431   "q \<in> \<real> \<Longrightarrow> (\<And>r. P (of_real r)) \<Longrightarrow> P q"
   432   by (rule Reals_cases) auto
   433 
   434 subsection {* Ordered real vector spaces *}
   435 
   436 class ordered_real_vector = real_vector + ordered_ab_group_add +
   437   assumes scaleR_left_mono: "x \<le> y \<Longrightarrow> 0 \<le> a \<Longrightarrow> a *\<^sub>R x \<le> a *\<^sub>R y"
   438   assumes scaleR_right_mono: "a \<le> b \<Longrightarrow> 0 \<le> x \<Longrightarrow> a *\<^sub>R x \<le> b *\<^sub>R x"
   439 begin
   440 
   441 lemma scaleR_mono:
   442   "a \<le> b \<Longrightarrow> x \<le> y \<Longrightarrow> 0 \<le> b \<Longrightarrow> 0 \<le> x \<Longrightarrow> a *\<^sub>R x \<le> b *\<^sub>R y"
   443 apply (erule scaleR_right_mono [THEN order_trans], assumption)
   444 apply (erule scaleR_left_mono, assumption)
   445 done
   446 
   447 lemma scaleR_mono':
   448   "a \<le> b \<Longrightarrow> c \<le> d \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 \<le> c \<Longrightarrow> a *\<^sub>R c \<le> b *\<^sub>R d"
   449   by (rule scaleR_mono) (auto intro: order.trans)
   450 
   451 lemma pos_le_divideRI:
   452   assumes "0 < c"
   453   assumes "c *\<^sub>R a \<le> b"
   454   shows "a \<le> b /\<^sub>R c"
   455 proof -
   456   from scaleR_left_mono[OF assms(2)] assms(1)
   457   have "c *\<^sub>R a /\<^sub>R c \<le> b /\<^sub>R c"
   458     by simp
   459   with assms show ?thesis
   460     by (simp add: scaleR_one scaleR_scaleR inverse_eq_divide)
   461 qed
   462 
   463 lemma pos_le_divideR_eq:
   464   assumes "0 < c"
   465   shows "a \<le> b /\<^sub>R c \<longleftrightarrow> c *\<^sub>R a \<le> b"
   466 proof rule
   467   assume "a \<le> b /\<^sub>R c"
   468   from scaleR_left_mono[OF this] assms
   469   have "c *\<^sub>R a \<le> c *\<^sub>R (b /\<^sub>R c)"
   470     by simp
   471   with assms show "c *\<^sub>R a \<le> b"
   472     by (simp add: scaleR_one scaleR_scaleR inverse_eq_divide)
   473 qed (rule pos_le_divideRI[OF assms])
   474 
   475 lemma scaleR_image_atLeastAtMost:
   476   "c > 0 \<Longrightarrow> scaleR c ` {x..y} = {c *\<^sub>R x..c *\<^sub>R y}"
   477   apply (auto intro!: scaleR_left_mono)
   478   apply (rule_tac x = "inverse c *\<^sub>R xa" in image_eqI)
   479   apply (simp_all add: pos_le_divideR_eq[symmetric] scaleR_scaleR scaleR_one)
   480   done
   481 
   482 end
   483 
   484 lemma scaleR_nonneg_nonneg: "0 \<le> a \<Longrightarrow> 0 \<le> (x::'a::ordered_real_vector) \<Longrightarrow> 0 \<le> a *\<^sub>R x"
   485   using scaleR_left_mono [of 0 x a]
   486   by simp
   487 
   488 lemma scaleR_nonneg_nonpos: "0 \<le> a \<Longrightarrow> (x::'a::ordered_real_vector) \<le> 0 \<Longrightarrow> a *\<^sub>R x \<le> 0"
   489   using scaleR_left_mono [of x 0 a] by simp
   490 
   491 lemma scaleR_nonpos_nonneg: "a \<le> 0 \<Longrightarrow> 0 \<le> (x::'a::ordered_real_vector) \<Longrightarrow> a *\<^sub>R x \<le> 0"
   492   using scaleR_right_mono [of a 0 x] by simp
   493 
   494 lemma split_scaleR_neg_le: "(0 \<le> a & x \<le> 0) | (a \<le> 0 & 0 \<le> x) \<Longrightarrow>
   495   a *\<^sub>R (x::'a::ordered_real_vector) \<le> 0"
   496   by (auto simp add: scaleR_nonneg_nonpos scaleR_nonpos_nonneg)
   497 
   498 lemma le_add_iff1:
   499   fixes c d e::"'a::ordered_real_vector"
   500   shows "a *\<^sub>R e + c \<le> b *\<^sub>R e + d \<longleftrightarrow> (a - b) *\<^sub>R e + c \<le> d"
   501   by (simp add: algebra_simps)
   502 
   503 lemma le_add_iff2:
   504   fixes c d e::"'a::ordered_real_vector"
   505   shows "a *\<^sub>R e + c \<le> b *\<^sub>R e + d \<longleftrightarrow> c \<le> (b - a) *\<^sub>R e + d"
   506   by (simp add: algebra_simps)
   507 
   508 lemma scaleR_left_mono_neg:
   509   fixes a b::"'a::ordered_real_vector"
   510   shows "b \<le> a \<Longrightarrow> c \<le> 0 \<Longrightarrow> c *\<^sub>R a \<le> c *\<^sub>R b"
   511   apply (drule scaleR_left_mono [of _ _ "- c"])
   512   apply simp_all
   513   done
   514 
   515 lemma scaleR_right_mono_neg:
   516   fixes c::"'a::ordered_real_vector"
   517   shows "b \<le> a \<Longrightarrow> c \<le> 0 \<Longrightarrow> a *\<^sub>R c \<le> b *\<^sub>R c"
   518   apply (drule scaleR_right_mono [of _ _ "- c"])
   519   apply simp_all
   520   done
   521 
   522 lemma scaleR_nonpos_nonpos: "a \<le> 0 \<Longrightarrow> (b::'a::ordered_real_vector) \<le> 0 \<Longrightarrow> 0 \<le> a *\<^sub>R b"
   523 using scaleR_right_mono_neg [of a 0 b] by simp
   524 
   525 lemma split_scaleR_pos_le:
   526   fixes b::"'a::ordered_real_vector"
   527   shows "(0 \<le> a \<and> 0 \<le> b) \<or> (a \<le> 0 \<and> b \<le> 0) \<Longrightarrow> 0 \<le> a *\<^sub>R b"
   528   by (auto simp add: scaleR_nonneg_nonneg scaleR_nonpos_nonpos)
   529 
   530 lemma zero_le_scaleR_iff:
   531   fixes b::"'a::ordered_real_vector"
   532   shows "0 \<le> a *\<^sub>R b \<longleftrightarrow> 0 < a \<and> 0 \<le> b \<or> a < 0 \<and> b \<le> 0 \<or> a = 0" (is "?lhs = ?rhs")
   533 proof cases
   534   assume "a \<noteq> 0"
   535   show ?thesis
   536   proof
   537     assume lhs: ?lhs
   538     {
   539       assume "0 < a"
   540       with lhs have "inverse a *\<^sub>R 0 \<le> inverse a *\<^sub>R (a *\<^sub>R b)"
   541         by (intro scaleR_mono) auto
   542       hence ?rhs using `0 < a`
   543         by simp
   544     } moreover {
   545       assume "0 > a"
   546       with lhs have "- inverse a *\<^sub>R 0 \<le> - inverse a *\<^sub>R (a *\<^sub>R b)"
   547         by (intro scaleR_mono) auto
   548       hence ?rhs using `0 > a`
   549         by simp
   550     } ultimately show ?rhs using `a \<noteq> 0` by arith
   551   qed (auto simp: not_le `a \<noteq> 0` intro!: split_scaleR_pos_le)
   552 qed simp
   553 
   554 lemma scaleR_le_0_iff:
   555   fixes b::"'a::ordered_real_vector"
   556   shows "a *\<^sub>R b \<le> 0 \<longleftrightarrow> 0 < a \<and> b \<le> 0 \<or> a < 0 \<and> 0 \<le> b \<or> a = 0"
   557   by (insert zero_le_scaleR_iff [of "-a" b]) force
   558 
   559 lemma scaleR_le_cancel_left:
   560   fixes b::"'a::ordered_real_vector"
   561   shows "c *\<^sub>R a \<le> c *\<^sub>R b \<longleftrightarrow> (0 < c \<longrightarrow> a \<le> b) \<and> (c < 0 \<longrightarrow> b \<le> a)"
   562   by (auto simp add: neq_iff scaleR_left_mono scaleR_left_mono_neg
   563     dest: scaleR_left_mono[where a="inverse c"] scaleR_left_mono_neg[where c="inverse c"])
   564 
   565 lemma scaleR_le_cancel_left_pos:
   566   fixes b::"'a::ordered_real_vector"
   567   shows "0 < c \<Longrightarrow> c *\<^sub>R a \<le> c *\<^sub>R b \<longleftrightarrow> a \<le> b"
   568   by (auto simp: scaleR_le_cancel_left)
   569 
   570 lemma scaleR_le_cancel_left_neg:
   571   fixes b::"'a::ordered_real_vector"
   572   shows "c < 0 \<Longrightarrow> c *\<^sub>R a \<le> c *\<^sub>R b \<longleftrightarrow> b \<le> a"
   573   by (auto simp: scaleR_le_cancel_left)
   574 
   575 lemma scaleR_left_le_one_le:
   576   fixes x::"'a::ordered_real_vector" and a::real
   577   shows "0 \<le> x \<Longrightarrow> a \<le> 1 \<Longrightarrow> a *\<^sub>R x \<le> x"
   578   using scaleR_right_mono[of a 1 x] by simp
   579 
   580 
   581 subsection {* Real normed vector spaces *}
   582 
   583 class dist =
   584   fixes dist :: "'a \<Rightarrow> 'a \<Rightarrow> real"
   585 
   586 class norm =
   587   fixes norm :: "'a \<Rightarrow> real"
   588 
   589 class sgn_div_norm = scaleR + norm + sgn +
   590   assumes sgn_div_norm: "sgn x = x /\<^sub>R norm x"
   591 
   592 class dist_norm = dist + norm + minus +
   593   assumes dist_norm: "dist x y = norm (x - y)"
   594 
   595 class open_dist = "open" + dist +
   596   assumes open_dist: "open S \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"
   597 
   598 class real_normed_vector = real_vector + sgn_div_norm + dist_norm + open_dist +
   599   assumes norm_eq_zero [simp]: "norm x = 0 \<longleftrightarrow> x = 0"
   600   and norm_triangle_ineq: "norm (x + y) \<le> norm x + norm y"
   601   and norm_scaleR [simp]: "norm (scaleR a x) = \<bar>a\<bar> * norm x"
   602 begin
   603 
   604 lemma norm_ge_zero [simp]: "0 \<le> norm x"
   605 proof -
   606   have "0 = norm (x + -1 *\<^sub>R x)" 
   607     using scaleR_add_left[of 1 "-1" x] norm_scaleR[of 0 x] by (simp add: scaleR_one)
   608   also have "\<dots> \<le> norm x + norm (-1 *\<^sub>R x)" by (rule norm_triangle_ineq)
   609   finally show ?thesis by simp
   610 qed
   611 
   612 end
   613 
   614 class real_normed_algebra = real_algebra + real_normed_vector +
   615   assumes norm_mult_ineq: "norm (x * y) \<le> norm x * norm y"
   616 
   617 class real_normed_algebra_1 = real_algebra_1 + real_normed_algebra +
   618   assumes norm_one [simp]: "norm 1 = 1"
   619 
   620 class real_normed_div_algebra = real_div_algebra + real_normed_vector +
   621   assumes norm_mult: "norm (x * y) = norm x * norm y"
   622 
   623 class real_normed_field = real_field + real_normed_div_algebra
   624 
   625 instance real_normed_div_algebra < real_normed_algebra_1
   626 proof
   627   fix x y :: 'a
   628   show "norm (x * y) \<le> norm x * norm y"
   629     by (simp add: norm_mult)
   630 next
   631   have "norm (1 * 1::'a) = norm (1::'a) * norm (1::'a)"
   632     by (rule norm_mult)
   633   thus "norm (1::'a) = 1" by simp
   634 qed
   635 
   636 lemma norm_zero [simp]: "norm (0::'a::real_normed_vector) = 0"
   637 by simp
   638 
   639 lemma zero_less_norm_iff [simp]:
   640   fixes x :: "'a::real_normed_vector"
   641   shows "(0 < norm x) = (x \<noteq> 0)"
   642 by (simp add: order_less_le)
   643 
   644 lemma norm_not_less_zero [simp]:
   645   fixes x :: "'a::real_normed_vector"
   646   shows "\<not> norm x < 0"
   647 by (simp add: linorder_not_less)
   648 
   649 lemma norm_le_zero_iff [simp]:
   650   fixes x :: "'a::real_normed_vector"
   651   shows "(norm x \<le> 0) = (x = 0)"
   652 by (simp add: order_le_less)
   653 
   654 lemma norm_minus_cancel [simp]:
   655   fixes x :: "'a::real_normed_vector"
   656   shows "norm (- x) = norm x"
   657 proof -
   658   have "norm (- x) = norm (scaleR (- 1) x)"
   659     by (simp only: scaleR_minus_left scaleR_one)
   660   also have "\<dots> = \<bar>- 1\<bar> * norm x"
   661     by (rule norm_scaleR)
   662   finally show ?thesis by simp
   663 qed
   664 
   665 lemma norm_minus_commute:
   666   fixes a b :: "'a::real_normed_vector"
   667   shows "norm (a - b) = norm (b - a)"
   668 proof -
   669   have "norm (- (b - a)) = norm (b - a)"
   670     by (rule norm_minus_cancel)
   671   thus ?thesis by simp
   672 qed
   673 
   674 lemma norm_triangle_ineq2:
   675   fixes a b :: "'a::real_normed_vector"
   676   shows "norm a - norm b \<le> norm (a - b)"
   677 proof -
   678   have "norm (a - b + b) \<le> norm (a - b) + norm b"
   679     by (rule norm_triangle_ineq)
   680   thus ?thesis by simp
   681 qed
   682 
   683 lemma norm_triangle_ineq3:
   684   fixes a b :: "'a::real_normed_vector"
   685   shows "\<bar>norm a - norm b\<bar> \<le> norm (a - b)"
   686 apply (subst abs_le_iff)
   687 apply auto
   688 apply (rule norm_triangle_ineq2)
   689 apply (subst norm_minus_commute)
   690 apply (rule norm_triangle_ineq2)
   691 done
   692 
   693 lemma norm_triangle_ineq4:
   694   fixes a b :: "'a::real_normed_vector"
   695   shows "norm (a - b) \<le> norm a + norm b"
   696 proof -
   697   have "norm (a + - b) \<le> norm a + norm (- b)"
   698     by (rule norm_triangle_ineq)
   699   then show ?thesis by simp
   700 qed
   701 
   702 lemma norm_diff_ineq:
   703   fixes a b :: "'a::real_normed_vector"
   704   shows "norm a - norm b \<le> norm (a + b)"
   705 proof -
   706   have "norm a - norm (- b) \<le> norm (a - - b)"
   707     by (rule norm_triangle_ineq2)
   708   thus ?thesis by simp
   709 qed
   710 
   711 lemma norm_diff_triangle_ineq:
   712   fixes a b c d :: "'a::real_normed_vector"
   713   shows "norm ((a + b) - (c + d)) \<le> norm (a - c) + norm (b - d)"
   714 proof -
   715   have "norm ((a + b) - (c + d)) = norm ((a - c) + (b - d))"
   716     by (simp add: algebra_simps)
   717   also have "\<dots> \<le> norm (a - c) + norm (b - d)"
   718     by (rule norm_triangle_ineq)
   719   finally show ?thesis .
   720 qed
   721 
   722 lemma abs_norm_cancel [simp]:
   723   fixes a :: "'a::real_normed_vector"
   724   shows "\<bar>norm a\<bar> = norm a"
   725 by (rule abs_of_nonneg [OF norm_ge_zero])
   726 
   727 lemma norm_add_less:
   728   fixes x y :: "'a::real_normed_vector"
   729   shows "\<lbrakk>norm x < r; norm y < s\<rbrakk> \<Longrightarrow> norm (x + y) < r + s"
   730 by (rule order_le_less_trans [OF norm_triangle_ineq add_strict_mono])
   731 
   732 lemma norm_mult_less:
   733   fixes x y :: "'a::real_normed_algebra"
   734   shows "\<lbrakk>norm x < r; norm y < s\<rbrakk> \<Longrightarrow> norm (x * y) < r * s"
   735 apply (rule order_le_less_trans [OF norm_mult_ineq])
   736 apply (simp add: mult_strict_mono')
   737 done
   738 
   739 lemma norm_of_real [simp]:
   740   "norm (of_real r :: 'a::real_normed_algebra_1) = \<bar>r\<bar>"
   741 unfolding of_real_def by simp
   742 
   743 lemma norm_numeral [simp]:
   744   "norm (numeral w::'a::real_normed_algebra_1) = numeral w"
   745 by (subst of_real_numeral [symmetric], subst norm_of_real, simp)
   746 
   747 lemma norm_neg_numeral [simp]:
   748   "norm (- numeral w::'a::real_normed_algebra_1) = numeral w"
   749 by (subst of_real_neg_numeral [symmetric], subst norm_of_real, simp)
   750 
   751 lemma norm_of_int [simp]:
   752   "norm (of_int z::'a::real_normed_algebra_1) = \<bar>of_int z\<bar>"
   753 by (subst of_real_of_int_eq [symmetric], rule norm_of_real)
   754 
   755 lemma norm_of_nat [simp]:
   756   "norm (of_nat n::'a::real_normed_algebra_1) = of_nat n"
   757 apply (subst of_real_of_nat_eq [symmetric])
   758 apply (subst norm_of_real, simp)
   759 done
   760 
   761 lemma nonzero_norm_inverse:
   762   fixes a :: "'a::real_normed_div_algebra"
   763   shows "a \<noteq> 0 \<Longrightarrow> norm (inverse a) = inverse (norm a)"
   764 apply (rule inverse_unique [symmetric])
   765 apply (simp add: norm_mult [symmetric])
   766 done
   767 
   768 lemma norm_inverse:
   769   fixes a :: "'a::{real_normed_div_algebra, division_ring_inverse_zero}"
   770   shows "norm (inverse a) = inverse (norm a)"
   771 apply (case_tac "a = 0", simp)
   772 apply (erule nonzero_norm_inverse)
   773 done
   774 
   775 lemma nonzero_norm_divide:
   776   fixes a b :: "'a::real_normed_field"
   777   shows "b \<noteq> 0 \<Longrightarrow> norm (a / b) = norm a / norm b"
   778 by (simp add: divide_inverse norm_mult nonzero_norm_inverse)
   779 
   780 lemma norm_divide:
   781   fixes a b :: "'a::{real_normed_field, field_inverse_zero}"
   782   shows "norm (a / b) = norm a / norm b"
   783 by (simp add: divide_inverse norm_mult norm_inverse)
   784 
   785 lemma norm_power_ineq:
   786   fixes x :: "'a::{real_normed_algebra_1}"
   787   shows "norm (x ^ n) \<le> norm x ^ n"
   788 proof (induct n)
   789   case 0 show "norm (x ^ 0) \<le> norm x ^ 0" by simp
   790 next
   791   case (Suc n)
   792   have "norm (x * x ^ n) \<le> norm x * norm (x ^ n)"
   793     by (rule norm_mult_ineq)
   794   also from Suc have "\<dots> \<le> norm x * norm x ^ n"
   795     using norm_ge_zero by (rule mult_left_mono)
   796   finally show "norm (x ^ Suc n) \<le> norm x ^ Suc n"
   797     by simp
   798 qed
   799 
   800 lemma norm_power:
   801   fixes x :: "'a::{real_normed_div_algebra}"
   802   shows "norm (x ^ n) = norm x ^ n"
   803 by (induct n) (simp_all add: norm_mult)
   804 
   805 
   806 subsection {* Metric spaces *}
   807 
   808 class metric_space = open_dist +
   809   assumes dist_eq_0_iff [simp]: "dist x y = 0 \<longleftrightarrow> x = y"
   810   assumes dist_triangle2: "dist x y \<le> dist x z + dist y z"
   811 begin
   812 
   813 lemma dist_self [simp]: "dist x x = 0"
   814 by simp
   815 
   816 lemma zero_le_dist [simp]: "0 \<le> dist x y"
   817 using dist_triangle2 [of x x y] by simp
   818 
   819 lemma zero_less_dist_iff: "0 < dist x y \<longleftrightarrow> x \<noteq> y"
   820 by (simp add: less_le)
   821 
   822 lemma dist_not_less_zero [simp]: "\<not> dist x y < 0"
   823 by (simp add: not_less)
   824 
   825 lemma dist_le_zero_iff [simp]: "dist x y \<le> 0 \<longleftrightarrow> x = y"
   826 by (simp add: le_less)
   827 
   828 lemma dist_commute: "dist x y = dist y x"
   829 proof (rule order_antisym)
   830   show "dist x y \<le> dist y x"
   831     using dist_triangle2 [of x y x] by simp
   832   show "dist y x \<le> dist x y"
   833     using dist_triangle2 [of y x y] by simp
   834 qed
   835 
   836 lemma dist_triangle: "dist x z \<le> dist x y + dist y z"
   837 using dist_triangle2 [of x z y] by (simp add: dist_commute)
   838 
   839 lemma dist_triangle3: "dist x y \<le> dist a x + dist a y"
   840 using dist_triangle2 [of x y a] by (simp add: dist_commute)
   841 
   842 lemma dist_triangle_alt:
   843   shows "dist y z <= dist x y + dist x z"
   844 by (rule dist_triangle3)
   845 
   846 lemma dist_pos_lt:
   847   shows "x \<noteq> y ==> 0 < dist x y"
   848 by (simp add: zero_less_dist_iff)
   849 
   850 lemma dist_nz:
   851   shows "x \<noteq> y \<longleftrightarrow> 0 < dist x y"
   852 by (simp add: zero_less_dist_iff)
   853 
   854 lemma dist_triangle_le:
   855   shows "dist x z + dist y z <= e \<Longrightarrow> dist x y <= e"
   856 by (rule order_trans [OF dist_triangle2])
   857 
   858 lemma dist_triangle_lt:
   859   shows "dist x z + dist y z < e ==> dist x y < e"
   860 by (rule le_less_trans [OF dist_triangle2])
   861 
   862 lemma dist_triangle_half_l:
   863   shows "dist x1 y < e / 2 \<Longrightarrow> dist x2 y < e / 2 \<Longrightarrow> dist x1 x2 < e"
   864 by (rule dist_triangle_lt [where z=y], simp)
   865 
   866 lemma dist_triangle_half_r:
   867   shows "dist y x1 < e / 2 \<Longrightarrow> dist y x2 < e / 2 \<Longrightarrow> dist x1 x2 < e"
   868 by (rule dist_triangle_half_l, simp_all add: dist_commute)
   869 
   870 subclass topological_space
   871 proof
   872   have "\<exists>e::real. 0 < e"
   873     by (fast intro: zero_less_one)
   874   then show "open UNIV"
   875     unfolding open_dist by simp
   876 next
   877   fix S T assume "open S" "open T"
   878   then show "open (S \<inter> T)"
   879     unfolding open_dist
   880     apply clarify
   881     apply (drule (1) bspec)+
   882     apply (clarify, rename_tac r s)
   883     apply (rule_tac x="min r s" in exI, simp)
   884     done
   885 next
   886   fix K assume "\<forall>S\<in>K. open S" thus "open (\<Union>K)"
   887     unfolding open_dist by fast
   888 qed
   889 
   890 lemma open_ball: "open {y. dist x y < d}"
   891 proof (unfold open_dist, intro ballI)
   892   fix y assume *: "y \<in> {y. dist x y < d}"
   893   then show "\<exists>e>0. \<forall>z. dist z y < e \<longrightarrow> z \<in> {y. dist x y < d}"
   894     by (auto intro!: exI[of _ "d - dist x y"] simp: field_simps dist_triangle_lt)
   895 qed
   896 
   897 subclass first_countable_topology
   898 proof
   899   fix x 
   900   show "\<exists>A::nat \<Rightarrow> 'a set. (\<forall>i. x \<in> A i \<and> open (A i)) \<and> (\<forall>S. open S \<and> x \<in> S \<longrightarrow> (\<exists>i. A i \<subseteq> S))"
   901   proof (safe intro!: exI[of _ "\<lambda>n. {y. dist x y < inverse (Suc n)}"])
   902     fix S assume "open S" "x \<in> S"
   903     then obtain e where e: "0 < e" and "{y. dist x y < e} \<subseteq> S"
   904       by (auto simp: open_dist subset_eq dist_commute)
   905     moreover
   906     from e obtain i where "inverse (Suc i) < e"
   907       by (auto dest!: reals_Archimedean)
   908     then have "{y. dist x y < inverse (Suc i)} \<subseteq> {y. dist x y < e}"
   909       by auto
   910     ultimately show "\<exists>i. {y. dist x y < inverse (Suc i)} \<subseteq> S"
   911       by blast
   912   qed (auto intro: open_ball)
   913 qed
   914 
   915 end
   916 
   917 instance metric_space \<subseteq> t2_space
   918 proof
   919   fix x y :: "'a::metric_space"
   920   assume xy: "x \<noteq> y"
   921   let ?U = "{y'. dist x y' < dist x y / 2}"
   922   let ?V = "{x'. dist y x' < dist x y / 2}"
   923   have th0: "\<And>d x y z. (d x z :: real) \<le> d x y + d y z \<Longrightarrow> d y z = d z y
   924                \<Longrightarrow> \<not>(d x y * 2 < d x z \<and> d z y * 2 < d x z)" by arith
   925   have "open ?U \<and> open ?V \<and> x \<in> ?U \<and> y \<in> ?V \<and> ?U \<inter> ?V = {}"
   926     using dist_pos_lt[OF xy] th0[of dist, OF dist_triangle dist_commute]
   927     using open_ball[of _ "dist x y / 2"] by auto
   928   then show "\<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {}"
   929     by blast
   930 qed
   931 
   932 text {* Every normed vector space is a metric space. *}
   933 
   934 instance real_normed_vector < metric_space
   935 proof
   936   fix x y :: 'a show "dist x y = 0 \<longleftrightarrow> x = y"
   937     unfolding dist_norm by simp
   938 next
   939   fix x y z :: 'a show "dist x y \<le> dist x z + dist y z"
   940     unfolding dist_norm
   941     using norm_triangle_ineq4 [of "x - z" "y - z"] by simp
   942 qed
   943 
   944 subsection {* Class instances for real numbers *}
   945 
   946 instantiation real :: real_normed_field
   947 begin
   948 
   949 definition dist_real_def:
   950   "dist x y = \<bar>x - y\<bar>"
   951 
   952 definition open_real_def [code del]:
   953   "open (S :: real set) \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"
   954 
   955 definition real_norm_def [simp]:
   956   "norm r = \<bar>r\<bar>"
   957 
   958 instance
   959 apply (intro_classes, unfold real_norm_def real_scaleR_def)
   960 apply (rule dist_real_def)
   961 apply (rule open_real_def)
   962 apply (simp add: sgn_real_def)
   963 apply (rule abs_eq_0)
   964 apply (rule abs_triangle_ineq)
   965 apply (rule abs_mult)
   966 apply (rule abs_mult)
   967 done
   968 
   969 end
   970 
   971 declare [[code abort: "open :: real set \<Rightarrow> bool"]]
   972 
   973 instance real :: linorder_topology
   974 proof
   975   show "(open :: real set \<Rightarrow> bool) = generate_topology (range lessThan \<union> range greaterThan)"
   976   proof (rule ext, safe)
   977     fix S :: "real set" assume "open S"
   978     then obtain f where "\<forall>x\<in>S. 0 < f x \<and> (\<forall>y. dist y x < f x \<longrightarrow> y \<in> S)"
   979       unfolding open_real_def bchoice_iff ..
   980     then have *: "S = (\<Union>x\<in>S. {x - f x <..} \<inter> {..< x + f x})"
   981       by (fastforce simp: dist_real_def)
   982     show "generate_topology (range lessThan \<union> range greaterThan) S"
   983       apply (subst *)
   984       apply (intro generate_topology_Union generate_topology.Int)
   985       apply (auto intro: generate_topology.Basis)
   986       done
   987   next
   988     fix S :: "real set" assume "generate_topology (range lessThan \<union> range greaterThan) S"
   989     moreover have "\<And>a::real. open {..<a}"
   990       unfolding open_real_def dist_real_def
   991     proof clarify
   992       fix x a :: real assume "x < a"
   993       hence "0 < a - x \<and> (\<forall>y. \<bar>y - x\<bar> < a - x \<longrightarrow> y \<in> {..<a})" by auto
   994       thus "\<exists>e>0. \<forall>y. \<bar>y - x\<bar> < e \<longrightarrow> y \<in> {..<a}" ..
   995     qed
   996     moreover have "\<And>a::real. open {a <..}"
   997       unfolding open_real_def dist_real_def
   998     proof clarify
   999       fix x a :: real assume "a < x"
  1000       hence "0 < x - a \<and> (\<forall>y. \<bar>y - x\<bar> < x - a \<longrightarrow> y \<in> {a<..})" by auto
  1001       thus "\<exists>e>0. \<forall>y. \<bar>y - x\<bar> < e \<longrightarrow> y \<in> {a<..}" ..
  1002     qed
  1003     ultimately show "open S"
  1004       by induct auto
  1005   qed
  1006 qed
  1007 
  1008 instance real :: linear_continuum_topology ..
  1009 
  1010 lemmas open_real_greaterThan = open_greaterThan[where 'a=real]
  1011 lemmas open_real_lessThan = open_lessThan[where 'a=real]
  1012 lemmas open_real_greaterThanLessThan = open_greaterThanLessThan[where 'a=real]
  1013 lemmas closed_real_atMost = closed_atMost[where 'a=real]
  1014 lemmas closed_real_atLeast = closed_atLeast[where 'a=real]
  1015 lemmas closed_real_atLeastAtMost = closed_atLeastAtMost[where 'a=real]
  1016 
  1017 subsection {* Extra type constraints *}
  1018 
  1019 text {* Only allow @{term "open"} in class @{text topological_space}. *}
  1020 
  1021 setup {* Sign.add_const_constraint
  1022   (@{const_name "open"}, SOME @{typ "'a::topological_space set \<Rightarrow> bool"}) *}
  1023 
  1024 text {* Only allow @{term dist} in class @{text metric_space}. *}
  1025 
  1026 setup {* Sign.add_const_constraint
  1027   (@{const_name dist}, SOME @{typ "'a::metric_space \<Rightarrow> 'a \<Rightarrow> real"}) *}
  1028 
  1029 text {* Only allow @{term norm} in class @{text real_normed_vector}. *}
  1030 
  1031 setup {* Sign.add_const_constraint
  1032   (@{const_name norm}, SOME @{typ "'a::real_normed_vector \<Rightarrow> real"}) *}
  1033 
  1034 subsection {* Sign function *}
  1035 
  1036 lemma norm_sgn:
  1037   "norm (sgn(x::'a::real_normed_vector)) = (if x = 0 then 0 else 1)"
  1038 by (simp add: sgn_div_norm)
  1039 
  1040 lemma sgn_zero [simp]: "sgn(0::'a::real_normed_vector) = 0"
  1041 by (simp add: sgn_div_norm)
  1042 
  1043 lemma sgn_zero_iff: "(sgn(x::'a::real_normed_vector) = 0) = (x = 0)"
  1044 by (simp add: sgn_div_norm)
  1045 
  1046 lemma sgn_minus: "sgn (- x) = - sgn(x::'a::real_normed_vector)"
  1047 by (simp add: sgn_div_norm)
  1048 
  1049 lemma sgn_scaleR:
  1050   "sgn (scaleR r x) = scaleR (sgn r) (sgn(x::'a::real_normed_vector))"
  1051 by (simp add: sgn_div_norm mult_ac)
  1052 
  1053 lemma sgn_one [simp]: "sgn (1::'a::real_normed_algebra_1) = 1"
  1054 by (simp add: sgn_div_norm)
  1055 
  1056 lemma sgn_of_real:
  1057   "sgn (of_real r::'a::real_normed_algebra_1) = of_real (sgn r)"
  1058 unfolding of_real_def by (simp only: sgn_scaleR sgn_one)
  1059 
  1060 lemma sgn_mult:
  1061   fixes x y :: "'a::real_normed_div_algebra"
  1062   shows "sgn (x * y) = sgn x * sgn y"
  1063 by (simp add: sgn_div_norm norm_mult mult_commute)
  1064 
  1065 lemma real_sgn_eq: "sgn (x::real) = x / \<bar>x\<bar>"
  1066 by (simp add: sgn_div_norm divide_inverse)
  1067 
  1068 lemma real_sgn_pos: "0 < (x::real) \<Longrightarrow> sgn x = 1"
  1069 unfolding real_sgn_eq by simp
  1070 
  1071 lemma real_sgn_neg: "(x::real) < 0 \<Longrightarrow> sgn x = -1"
  1072 unfolding real_sgn_eq by simp
  1073 
  1074 lemma norm_conv_dist: "norm x = dist x 0"
  1075   unfolding dist_norm by simp
  1076 
  1077 subsection {* Bounded Linear and Bilinear Operators *}
  1078 
  1079 locale linear = additive f for f :: "'a::real_vector \<Rightarrow> 'b::real_vector" +
  1080   assumes scaleR: "f (scaleR r x) = scaleR r (f x)"
  1081 
  1082 lemma linearI:
  1083   assumes "\<And>x y. f (x + y) = f x + f y"
  1084   assumes "\<And>c x. f (c *\<^sub>R x) = c *\<^sub>R f x"
  1085   shows "linear f"
  1086   by default (rule assms)+
  1087 
  1088 locale bounded_linear = linear f for f :: "'a::real_normed_vector \<Rightarrow> 'b::real_normed_vector" +
  1089   assumes bounded: "\<exists>K. \<forall>x. norm (f x) \<le> norm x * K"
  1090 begin
  1091 
  1092 lemma pos_bounded:
  1093   "\<exists>K>0. \<forall>x. norm (f x) \<le> norm x * K"
  1094 proof -
  1095   obtain K where K: "\<And>x. norm (f x) \<le> norm x * K"
  1096     using bounded by fast
  1097   show ?thesis
  1098   proof (intro exI impI conjI allI)
  1099     show "0 < max 1 K"
  1100       by (rule order_less_le_trans [OF zero_less_one max.cobounded1])
  1101   next
  1102     fix x
  1103     have "norm (f x) \<le> norm x * K" using K .
  1104     also have "\<dots> \<le> norm x * max 1 K"
  1105       by (rule mult_left_mono [OF max.cobounded2 norm_ge_zero])
  1106     finally show "norm (f x) \<le> norm x * max 1 K" .
  1107   qed
  1108 qed
  1109 
  1110 lemma nonneg_bounded:
  1111   "\<exists>K\<ge>0. \<forall>x. norm (f x) \<le> norm x * K"
  1112 proof -
  1113   from pos_bounded
  1114   show ?thesis by (auto intro: order_less_imp_le)
  1115 qed
  1116 
  1117 end
  1118 
  1119 lemma bounded_linear_intro:
  1120   assumes "\<And>x y. f (x + y) = f x + f y"
  1121   assumes "\<And>r x. f (scaleR r x) = scaleR r (f x)"
  1122   assumes "\<And>x. norm (f x) \<le> norm x * K"
  1123   shows "bounded_linear f"
  1124   by default (fast intro: assms)+
  1125 
  1126 locale bounded_bilinear =
  1127   fixes prod :: "['a::real_normed_vector, 'b::real_normed_vector]
  1128                  \<Rightarrow> 'c::real_normed_vector"
  1129     (infixl "**" 70)
  1130   assumes add_left: "prod (a + a') b = prod a b + prod a' b"
  1131   assumes add_right: "prod a (b + b') = prod a b + prod a b'"
  1132   assumes scaleR_left: "prod (scaleR r a) b = scaleR r (prod a b)"
  1133   assumes scaleR_right: "prod a (scaleR r b) = scaleR r (prod a b)"
  1134   assumes bounded: "\<exists>K. \<forall>a b. norm (prod a b) \<le> norm a * norm b * K"
  1135 begin
  1136 
  1137 lemma pos_bounded:
  1138   "\<exists>K>0. \<forall>a b. norm (a ** b) \<le> norm a * norm b * K"
  1139 apply (cut_tac bounded, erule exE)
  1140 apply (rule_tac x="max 1 K" in exI, safe)
  1141 apply (rule order_less_le_trans [OF zero_less_one max.cobounded1])
  1142 apply (drule spec, drule spec, erule order_trans)
  1143 apply (rule mult_left_mono [OF max.cobounded2])
  1144 apply (intro mult_nonneg_nonneg norm_ge_zero)
  1145 done
  1146 
  1147 lemma nonneg_bounded:
  1148   "\<exists>K\<ge>0. \<forall>a b. norm (a ** b) \<le> norm a * norm b * K"
  1149 proof -
  1150   from pos_bounded
  1151   show ?thesis by (auto intro: order_less_imp_le)
  1152 qed
  1153 
  1154 lemma additive_right: "additive (\<lambda>b. prod a b)"
  1155 by (rule additive.intro, rule add_right)
  1156 
  1157 lemma additive_left: "additive (\<lambda>a. prod a b)"
  1158 by (rule additive.intro, rule add_left)
  1159 
  1160 lemma zero_left: "prod 0 b = 0"
  1161 by (rule additive.zero [OF additive_left])
  1162 
  1163 lemma zero_right: "prod a 0 = 0"
  1164 by (rule additive.zero [OF additive_right])
  1165 
  1166 lemma minus_left: "prod (- a) b = - prod a b"
  1167 by (rule additive.minus [OF additive_left])
  1168 
  1169 lemma minus_right: "prod a (- b) = - prod a b"
  1170 by (rule additive.minus [OF additive_right])
  1171 
  1172 lemma diff_left:
  1173   "prod (a - a') b = prod a b - prod a' b"
  1174 by (rule additive.diff [OF additive_left])
  1175 
  1176 lemma diff_right:
  1177   "prod a (b - b') = prod a b - prod a b'"
  1178 by (rule additive.diff [OF additive_right])
  1179 
  1180 lemma bounded_linear_left:
  1181   "bounded_linear (\<lambda>a. a ** b)"
  1182 apply (cut_tac bounded, safe)
  1183 apply (rule_tac K="norm b * K" in bounded_linear_intro)
  1184 apply (rule add_left)
  1185 apply (rule scaleR_left)
  1186 apply (simp add: mult_ac)
  1187 done
  1188 
  1189 lemma bounded_linear_right:
  1190   "bounded_linear (\<lambda>b. a ** b)"
  1191 apply (cut_tac bounded, safe)
  1192 apply (rule_tac K="norm a * K" in bounded_linear_intro)
  1193 apply (rule add_right)
  1194 apply (rule scaleR_right)
  1195 apply (simp add: mult_ac)
  1196 done
  1197 
  1198 lemma prod_diff_prod:
  1199   "(x ** y - a ** b) = (x - a) ** (y - b) + (x - a) ** b + a ** (y - b)"
  1200 by (simp add: diff_left diff_right)
  1201 
  1202 end
  1203 
  1204 lemma bounded_linear_ident[simp]: "bounded_linear (\<lambda>x. x)"
  1205   by default (auto intro!: exI[of _ 1])
  1206 
  1207 lemma bounded_linear_zero[simp]: "bounded_linear (\<lambda>x. 0)"
  1208   by default (auto intro!: exI[of _ 1])
  1209 
  1210 lemma bounded_linear_add:
  1211   assumes "bounded_linear f"
  1212   assumes "bounded_linear g"
  1213   shows "bounded_linear (\<lambda>x. f x + g x)"
  1214 proof -
  1215   interpret f: bounded_linear f by fact
  1216   interpret g: bounded_linear g by fact
  1217   show ?thesis
  1218   proof
  1219     from f.bounded obtain Kf where Kf: "\<And>x. norm (f x) \<le> norm x * Kf" by blast
  1220     from g.bounded obtain Kg where Kg: "\<And>x. norm (g x) \<le> norm x * Kg" by blast
  1221     show "\<exists>K. \<forall>x. norm (f x + g x) \<le> norm x * K"
  1222       using add_mono[OF Kf Kg]
  1223       by (intro exI[of _ "Kf + Kg"]) (auto simp: field_simps intro: norm_triangle_ineq order_trans)
  1224   qed (simp_all add: f.add g.add f.scaleR g.scaleR scaleR_right_distrib)
  1225 qed
  1226 
  1227 lemma bounded_linear_minus:
  1228   assumes "bounded_linear f"
  1229   shows "bounded_linear (\<lambda>x. - f x)"
  1230 proof -
  1231   interpret f: bounded_linear f by fact
  1232   show ?thesis apply (unfold_locales)
  1233     apply (simp add: f.add)
  1234     apply (simp add: f.scaleR)
  1235     apply (simp add: f.bounded)
  1236     done
  1237 qed
  1238 
  1239 lemma bounded_linear_compose:
  1240   assumes "bounded_linear f"
  1241   assumes "bounded_linear g"
  1242   shows "bounded_linear (\<lambda>x. f (g x))"
  1243 proof -
  1244   interpret f: bounded_linear f by fact
  1245   interpret g: bounded_linear g by fact
  1246   show ?thesis proof (unfold_locales)
  1247     fix x y show "f (g (x + y)) = f (g x) + f (g y)"
  1248       by (simp only: f.add g.add)
  1249   next
  1250     fix r x show "f (g (scaleR r x)) = scaleR r (f (g x))"
  1251       by (simp only: f.scaleR g.scaleR)
  1252   next
  1253     from f.pos_bounded
  1254     obtain Kf where f: "\<And>x. norm (f x) \<le> norm x * Kf" and Kf: "0 < Kf" by fast
  1255     from g.pos_bounded
  1256     obtain Kg where g: "\<And>x. norm (g x) \<le> norm x * Kg" by fast
  1257     show "\<exists>K. \<forall>x. norm (f (g x)) \<le> norm x * K"
  1258     proof (intro exI allI)
  1259       fix x
  1260       have "norm (f (g x)) \<le> norm (g x) * Kf"
  1261         using f .
  1262       also have "\<dots> \<le> (norm x * Kg) * Kf"
  1263         using g Kf [THEN order_less_imp_le] by (rule mult_right_mono)
  1264       also have "(norm x * Kg) * Kf = norm x * (Kg * Kf)"
  1265         by (rule mult_assoc)
  1266       finally show "norm (f (g x)) \<le> norm x * (Kg * Kf)" .
  1267     qed
  1268   qed
  1269 qed
  1270 
  1271 lemma bounded_bilinear_mult:
  1272   "bounded_bilinear (op * :: 'a \<Rightarrow> 'a \<Rightarrow> 'a::real_normed_algebra)"
  1273 apply (rule bounded_bilinear.intro)
  1274 apply (rule distrib_right)
  1275 apply (rule distrib_left)
  1276 apply (rule mult_scaleR_left)
  1277 apply (rule mult_scaleR_right)
  1278 apply (rule_tac x="1" in exI)
  1279 apply (simp add: norm_mult_ineq)
  1280 done
  1281 
  1282 lemma bounded_linear_mult_left:
  1283   "bounded_linear (\<lambda>x::'a::real_normed_algebra. x * y)"
  1284   using bounded_bilinear_mult
  1285   by (rule bounded_bilinear.bounded_linear_left)
  1286 
  1287 lemma bounded_linear_mult_right:
  1288   "bounded_linear (\<lambda>y::'a::real_normed_algebra. x * y)"
  1289   using bounded_bilinear_mult
  1290   by (rule bounded_bilinear.bounded_linear_right)
  1291 
  1292 lemmas bounded_linear_mult_const =
  1293   bounded_linear_mult_left [THEN bounded_linear_compose]
  1294 
  1295 lemmas bounded_linear_const_mult =
  1296   bounded_linear_mult_right [THEN bounded_linear_compose]
  1297 
  1298 lemma bounded_linear_divide:
  1299   "bounded_linear (\<lambda>x::'a::real_normed_field. x / y)"
  1300   unfolding divide_inverse by (rule bounded_linear_mult_left)
  1301 
  1302 lemma bounded_bilinear_scaleR: "bounded_bilinear scaleR"
  1303 apply (rule bounded_bilinear.intro)
  1304 apply (rule scaleR_left_distrib)
  1305 apply (rule scaleR_right_distrib)
  1306 apply simp
  1307 apply (rule scaleR_left_commute)
  1308 apply (rule_tac x="1" in exI, simp)
  1309 done
  1310 
  1311 lemma bounded_linear_scaleR_left: "bounded_linear (\<lambda>r. scaleR r x)"
  1312   using bounded_bilinear_scaleR
  1313   by (rule bounded_bilinear.bounded_linear_left)
  1314 
  1315 lemma bounded_linear_scaleR_right: "bounded_linear (\<lambda>x. scaleR r x)"
  1316   using bounded_bilinear_scaleR
  1317   by (rule bounded_bilinear.bounded_linear_right)
  1318 
  1319 lemma bounded_linear_of_real: "bounded_linear (\<lambda>r. of_real r)"
  1320   unfolding of_real_def by (rule bounded_linear_scaleR_left)
  1321 
  1322 lemma real_bounded_linear:
  1323   fixes f :: "real \<Rightarrow> real"
  1324   shows "bounded_linear f \<longleftrightarrow> (\<exists>c::real. f = (\<lambda>x. x * c))"
  1325 proof -
  1326   { fix x assume "bounded_linear f"
  1327     then interpret bounded_linear f .
  1328     from scaleR[of x 1] have "f x = x * f 1"
  1329       by simp }
  1330   then show ?thesis
  1331     by (auto intro: exI[of _ "f 1"] bounded_linear_mult_left)
  1332 qed
  1333 
  1334 instance real_normed_algebra_1 \<subseteq> perfect_space
  1335 proof
  1336   fix x::'a
  1337   show "\<not> open {x}"
  1338     unfolding open_dist dist_norm
  1339     by (clarsimp, rule_tac x="x + of_real (e/2)" in exI, simp)
  1340 qed
  1341 
  1342 subsection {* Filters and Limits on Metric Space *}
  1343 
  1344 lemma eventually_nhds_metric:
  1345   fixes a :: "'a :: metric_space"
  1346   shows "eventually P (nhds a) \<longleftrightarrow> (\<exists>d>0. \<forall>x. dist x a < d \<longrightarrow> P x)"
  1347 unfolding eventually_nhds open_dist
  1348 apply safe
  1349 apply fast
  1350 apply (rule_tac x="{x. dist x a < d}" in exI, simp)
  1351 apply clarsimp
  1352 apply (rule_tac x="d - dist x a" in exI, clarsimp)
  1353 apply (simp only: less_diff_eq)
  1354 apply (erule le_less_trans [OF dist_triangle])
  1355 done
  1356 
  1357 lemma eventually_at:
  1358   fixes a :: "'a :: metric_space"
  1359   shows "eventually P (at a within S) \<longleftrightarrow> (\<exists>d>0. \<forall>x\<in>S. x \<noteq> a \<and> dist x a < d \<longrightarrow> P x)"
  1360   unfolding eventually_at_filter eventually_nhds_metric by (auto simp: dist_nz)
  1361 
  1362 lemma eventually_at_le:
  1363   fixes a :: "'a::metric_space"
  1364   shows "eventually P (at a within S) \<longleftrightarrow> (\<exists>d>0. \<forall>x\<in>S. x \<noteq> a \<and> dist x a \<le> d \<longrightarrow> P x)"
  1365   unfolding eventually_at_filter eventually_nhds_metric
  1366   apply auto
  1367   apply (rule_tac x="d / 2" in exI)
  1368   apply auto
  1369   done
  1370 
  1371 lemma tendstoI:
  1372   fixes l :: "'a :: metric_space"
  1373   assumes "\<And>e. 0 < e \<Longrightarrow> eventually (\<lambda>x. dist (f x) l < e) F"
  1374   shows "(f ---> l) F"
  1375   apply (rule topological_tendstoI)
  1376   apply (simp add: open_dist)
  1377   apply (drule (1) bspec, clarify)
  1378   apply (drule assms)
  1379   apply (erule eventually_elim1, simp)
  1380   done
  1381 
  1382 lemma tendstoD:
  1383   fixes l :: "'a :: metric_space"
  1384   shows "(f ---> l) F \<Longrightarrow> 0 < e \<Longrightarrow> eventually (\<lambda>x. dist (f x) l < e) F"
  1385   apply (drule_tac S="{x. dist x l < e}" in topological_tendstoD)
  1386   apply (clarsimp simp add: open_dist)
  1387   apply (rule_tac x="e - dist x l" in exI, clarsimp)
  1388   apply (simp only: less_diff_eq)
  1389   apply (erule le_less_trans [OF dist_triangle])
  1390   apply simp
  1391   apply simp
  1392   done
  1393 
  1394 lemma tendsto_iff:
  1395   fixes l :: "'a :: metric_space"
  1396   shows "(f ---> l) F \<longleftrightarrow> (\<forall>e>0. eventually (\<lambda>x. dist (f x) l < e) F)"
  1397   using tendstoI tendstoD by fast
  1398 
  1399 lemma metric_tendsto_imp_tendsto:
  1400   fixes a :: "'a :: metric_space" and b :: "'b :: metric_space"
  1401   assumes f: "(f ---> a) F"
  1402   assumes le: "eventually (\<lambda>x. dist (g x) b \<le> dist (f x) a) F"
  1403   shows "(g ---> b) F"
  1404 proof (rule tendstoI)
  1405   fix e :: real assume "0 < e"
  1406   with f have "eventually (\<lambda>x. dist (f x) a < e) F" by (rule tendstoD)
  1407   with le show "eventually (\<lambda>x. dist (g x) b < e) F"
  1408     using le_less_trans by (rule eventually_elim2)
  1409 qed
  1410 
  1411 lemma filterlim_real_sequentially: "LIM x sequentially. real x :> at_top"
  1412   unfolding filterlim_at_top
  1413   apply (intro allI)
  1414   apply (rule_tac c="natceiling (Z + 1)" in eventually_sequentiallyI)
  1415   apply (auto simp: natceiling_le_eq)
  1416   done
  1417 
  1418 subsubsection {* Limits of Sequences *}
  1419 
  1420 lemma LIMSEQ_def: "X ----> (L::'a::metric_space) \<longleftrightarrow> (\<forall>r>0. \<exists>no. \<forall>n\<ge>no. dist (X n) L < r)"
  1421   unfolding tendsto_iff eventually_sequentially ..
  1422 
  1423 lemma LIMSEQ_iff_nz: "X ----> (L::'a::metric_space) = (\<forall>r>0. \<exists>no>0. \<forall>n\<ge>no. dist (X n) L < r)"
  1424   unfolding LIMSEQ_def by (metis Suc_leD zero_less_Suc)
  1425 
  1426 lemma metric_LIMSEQ_I:
  1427   "(\<And>r. 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. dist (X n) L < r) \<Longrightarrow> X ----> (L::'a::metric_space)"
  1428 by (simp add: LIMSEQ_def)
  1429 
  1430 lemma metric_LIMSEQ_D:
  1431   "\<lbrakk>X ----> (L::'a::metric_space); 0 < r\<rbrakk> \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. dist (X n) L < r"
  1432 by (simp add: LIMSEQ_def)
  1433 
  1434 
  1435 subsubsection {* Limits of Functions *}
  1436 
  1437 lemma LIM_def: "f -- (a::'a::metric_space) --> (L::'b::metric_space) =
  1438      (\<forall>r > 0. \<exists>s > 0. \<forall>x. x \<noteq> a & dist x a < s
  1439         --> dist (f x) L < r)"
  1440   unfolding tendsto_iff eventually_at by simp
  1441 
  1442 lemma metric_LIM_I:
  1443   "(\<And>r. 0 < r \<Longrightarrow> \<exists>s>0. \<forall>x. x \<noteq> a \<and> dist x a < s \<longrightarrow> dist (f x) L < r)
  1444     \<Longrightarrow> f -- (a::'a::metric_space) --> (L::'b::metric_space)"
  1445 by (simp add: LIM_def)
  1446 
  1447 lemma metric_LIM_D:
  1448   "\<lbrakk>f -- (a::'a::metric_space) --> (L::'b::metric_space); 0 < r\<rbrakk>
  1449     \<Longrightarrow> \<exists>s>0. \<forall>x. x \<noteq> a \<and> dist x a < s \<longrightarrow> dist (f x) L < r"
  1450 by (simp add: LIM_def)
  1451 
  1452 lemma metric_LIM_imp_LIM:
  1453   assumes f: "f -- a --> (l::'a::metric_space)"
  1454   assumes le: "\<And>x. x \<noteq> a \<Longrightarrow> dist (g x) m \<le> dist (f x) l"
  1455   shows "g -- a --> (m::'b::metric_space)"
  1456   by (rule metric_tendsto_imp_tendsto [OF f]) (auto simp add: eventually_at_topological le)
  1457 
  1458 lemma metric_LIM_equal2:
  1459   assumes 1: "0 < R"
  1460   assumes 2: "\<And>x. \<lbrakk>x \<noteq> a; dist x a < R\<rbrakk> \<Longrightarrow> f x = g x"
  1461   shows "g -- a --> l \<Longrightarrow> f -- (a::'a::metric_space) --> l"
  1462 apply (rule topological_tendstoI)
  1463 apply (drule (2) topological_tendstoD)
  1464 apply (simp add: eventually_at, safe)
  1465 apply (rule_tac x="min d R" in exI, safe)
  1466 apply (simp add: 1)
  1467 apply (simp add: 2)
  1468 done
  1469 
  1470 lemma metric_LIM_compose2:
  1471   assumes f: "f -- (a::'a::metric_space) --> b"
  1472   assumes g: "g -- b --> c"
  1473   assumes inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> dist x a < d \<longrightarrow> f x \<noteq> b"
  1474   shows "(\<lambda>x. g (f x)) -- a --> c"
  1475   using inj
  1476   by (intro tendsto_compose_eventually[OF g f]) (auto simp: eventually_at)
  1477 
  1478 lemma metric_isCont_LIM_compose2:
  1479   fixes f :: "'a :: metric_space \<Rightarrow> _"
  1480   assumes f [unfolded isCont_def]: "isCont f a"
  1481   assumes g: "g -- f a --> l"
  1482   assumes inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> dist x a < d \<longrightarrow> f x \<noteq> f a"
  1483   shows "(\<lambda>x. g (f x)) -- a --> l"
  1484 by (rule metric_LIM_compose2 [OF f g inj])
  1485 
  1486 subsection {* Complete metric spaces *}
  1487 
  1488 subsection {* Cauchy sequences *}
  1489 
  1490 definition (in metric_space) Cauchy :: "(nat \<Rightarrow> 'a) \<Rightarrow> bool" where
  1491   "Cauchy X = (\<forall>e>0. \<exists>M. \<forall>m \<ge> M. \<forall>n \<ge> M. dist (X m) (X n) < e)"
  1492 
  1493 subsection {* Cauchy Sequences *}
  1494 
  1495 lemma metric_CauchyI:
  1496   "(\<And>e. 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < e) \<Longrightarrow> Cauchy X"
  1497   by (simp add: Cauchy_def)
  1498 
  1499 lemma metric_CauchyD:
  1500   "Cauchy X \<Longrightarrow> 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < e"
  1501   by (simp add: Cauchy_def)
  1502 
  1503 lemma metric_Cauchy_iff2:
  1504   "Cauchy X = (\<forall>j. (\<exists>M. \<forall>m \<ge> M. \<forall>n \<ge> M. dist (X m) (X n) < inverse(real (Suc j))))"
  1505 apply (simp add: Cauchy_def, auto)
  1506 apply (drule reals_Archimedean, safe)
  1507 apply (drule_tac x = n in spec, auto)
  1508 apply (rule_tac x = M in exI, auto)
  1509 apply (drule_tac x = m in spec, simp)
  1510 apply (drule_tac x = na in spec, auto)
  1511 done
  1512 
  1513 lemma Cauchy_iff2:
  1514   "Cauchy X = (\<forall>j. (\<exists>M. \<forall>m \<ge> M. \<forall>n \<ge> M. \<bar>X m - X n\<bar> < inverse(real (Suc j))))"
  1515   unfolding metric_Cauchy_iff2 dist_real_def ..
  1516 
  1517 lemma Cauchy_subseq_Cauchy:
  1518   "\<lbrakk> Cauchy X; subseq f \<rbrakk> \<Longrightarrow> Cauchy (X o f)"
  1519 apply (auto simp add: Cauchy_def)
  1520 apply (drule_tac x=e in spec, clarify)
  1521 apply (rule_tac x=M in exI, clarify)
  1522 apply (blast intro: le_trans [OF _ seq_suble] dest!: spec)
  1523 done
  1524 
  1525 theorem LIMSEQ_imp_Cauchy:
  1526   assumes X: "X ----> a" shows "Cauchy X"
  1527 proof (rule metric_CauchyI)
  1528   fix e::real assume "0 < e"
  1529   hence "0 < e/2" by simp
  1530   with X have "\<exists>N. \<forall>n\<ge>N. dist (X n) a < e/2" by (rule metric_LIMSEQ_D)
  1531   then obtain N where N: "\<forall>n\<ge>N. dist (X n) a < e/2" ..
  1532   show "\<exists>N. \<forall>m\<ge>N. \<forall>n\<ge>N. dist (X m) (X n) < e"
  1533   proof (intro exI allI impI)
  1534     fix m assume "N \<le> m"
  1535     hence m: "dist (X m) a < e/2" using N by fast
  1536     fix n assume "N \<le> n"
  1537     hence n: "dist (X n) a < e/2" using N by fast
  1538     have "dist (X m) (X n) \<le> dist (X m) a + dist (X n) a"
  1539       by (rule dist_triangle2)
  1540     also from m n have "\<dots> < e" by simp
  1541     finally show "dist (X m) (X n) < e" .
  1542   qed
  1543 qed
  1544 
  1545 lemma convergent_Cauchy: "convergent X \<Longrightarrow> Cauchy X"
  1546 unfolding convergent_def
  1547 by (erule exE, erule LIMSEQ_imp_Cauchy)
  1548 
  1549 subsubsection {* Cauchy Sequences are Convergent *}
  1550 
  1551 class complete_space = metric_space +
  1552   assumes Cauchy_convergent: "Cauchy X \<Longrightarrow> convergent X"
  1553 
  1554 lemma Cauchy_convergent_iff:
  1555   fixes X :: "nat \<Rightarrow> 'a::complete_space"
  1556   shows "Cauchy X = convergent X"
  1557 by (fast intro: Cauchy_convergent convergent_Cauchy)
  1558 
  1559 subsection {* The set of real numbers is a complete metric space *}
  1560 
  1561 text {*
  1562 Proof that Cauchy sequences converge based on the one from
  1563 @{url "http://pirate.shu.edu/~wachsmut/ira/numseq/proofs/cauconv.html"}
  1564 *}
  1565 
  1566 text {*
  1567   If sequence @{term "X"} is Cauchy, then its limit is the lub of
  1568   @{term "{r::real. \<exists>N. \<forall>n\<ge>N. r < X n}"}
  1569 *}
  1570 
  1571 lemma increasing_LIMSEQ:
  1572   fixes f :: "nat \<Rightarrow> real"
  1573   assumes inc: "\<And>n. f n \<le> f (Suc n)"
  1574       and bdd: "\<And>n. f n \<le> l"
  1575       and en: "\<And>e. 0 < e \<Longrightarrow> \<exists>n. l \<le> f n + e"
  1576   shows "f ----> l"
  1577 proof (rule increasing_tendsto)
  1578   fix x assume "x < l"
  1579   with dense[of 0 "l - x"] obtain e where "0 < e" "e < l - x"
  1580     by auto
  1581   from en[OF `0 < e`] obtain n where "l - e \<le> f n"
  1582     by (auto simp: field_simps)
  1583   with `e < l - x` `0 < e` have "x < f n" by simp
  1584   with incseq_SucI[of f, OF inc] show "eventually (\<lambda>n. x < f n) sequentially"
  1585     by (auto simp: eventually_sequentially incseq_def intro: less_le_trans)
  1586 qed (insert bdd, auto)
  1587 
  1588 lemma real_Cauchy_convergent:
  1589   fixes X :: "nat \<Rightarrow> real"
  1590   assumes X: "Cauchy X"
  1591   shows "convergent X"
  1592 proof -
  1593   def S \<equiv> "{x::real. \<exists>N. \<forall>n\<ge>N. x < X n}"
  1594   then have mem_S: "\<And>N x. \<forall>n\<ge>N. x < X n \<Longrightarrow> x \<in> S" by auto
  1595 
  1596   { fix N x assume N: "\<forall>n\<ge>N. X n < x"
  1597   fix y::real assume "y \<in> S"
  1598   hence "\<exists>M. \<forall>n\<ge>M. y < X n"
  1599     by (simp add: S_def)
  1600   then obtain M where "\<forall>n\<ge>M. y < X n" ..
  1601   hence "y < X (max M N)" by simp
  1602   also have "\<dots> < x" using N by simp
  1603   finally have "y \<le> x"
  1604     by (rule order_less_imp_le) }
  1605   note bound_isUb = this 
  1606 
  1607   obtain N where "\<forall>m\<ge>N. \<forall>n\<ge>N. dist (X m) (X n) < 1"
  1608     using X[THEN metric_CauchyD, OF zero_less_one] by auto
  1609   hence N: "\<forall>n\<ge>N. dist (X n) (X N) < 1" by simp
  1610   have [simp]: "S \<noteq> {}"
  1611   proof (intro exI ex_in_conv[THEN iffD1])
  1612     from N have "\<forall>n\<ge>N. X N - 1 < X n"
  1613       by (simp add: abs_diff_less_iff dist_real_def)
  1614     thus "X N - 1 \<in> S" by (rule mem_S)
  1615   qed
  1616   have [simp]: "bdd_above S"
  1617   proof
  1618     from N have "\<forall>n\<ge>N. X n < X N + 1"
  1619       by (simp add: abs_diff_less_iff dist_real_def)
  1620     thus "\<And>s. s \<in> S \<Longrightarrow>  s \<le> X N + 1"
  1621       by (rule bound_isUb)
  1622   qed
  1623   have "X ----> Sup S"
  1624   proof (rule metric_LIMSEQ_I)
  1625   fix r::real assume "0 < r"
  1626   hence r: "0 < r/2" by simp
  1627   obtain N where "\<forall>n\<ge>N. \<forall>m\<ge>N. dist (X n) (X m) < r/2"
  1628     using metric_CauchyD [OF X r] by auto
  1629   hence "\<forall>n\<ge>N. dist (X n) (X N) < r/2" by simp
  1630   hence N: "\<forall>n\<ge>N. X N - r/2 < X n \<and> X n < X N + r/2"
  1631     by (simp only: dist_real_def abs_diff_less_iff)
  1632 
  1633   from N have "\<forall>n\<ge>N. X N - r/2 < X n" by fast
  1634   hence "X N - r/2 \<in> S" by (rule mem_S)
  1635   hence 1: "X N - r/2 \<le> Sup S" by (simp add: cSup_upper)
  1636 
  1637   from N have "\<forall>n\<ge>N. X n < X N + r/2" by fast
  1638   from bound_isUb[OF this]
  1639   have 2: "Sup S \<le> X N + r/2"
  1640     by (intro cSup_least) simp_all
  1641 
  1642   show "\<exists>N. \<forall>n\<ge>N. dist (X n) (Sup S) < r"
  1643   proof (intro exI allI impI)
  1644     fix n assume n: "N \<le> n"
  1645     from N n have "X n < X N + r/2" and "X N - r/2 < X n" by simp+
  1646     thus "dist (X n) (Sup S) < r" using 1 2
  1647       by (simp add: abs_diff_less_iff dist_real_def)
  1648   qed
  1649   qed
  1650   then show ?thesis unfolding convergent_def by auto
  1651 qed
  1652 
  1653 instance real :: complete_space
  1654   by intro_classes (rule real_Cauchy_convergent)
  1655 
  1656 class banach = real_normed_vector + complete_space
  1657 
  1658 instance real :: banach by default
  1659 
  1660 lemma tendsto_at_topI_sequentially:
  1661   fixes f :: "real \<Rightarrow> real"
  1662   assumes mono: "mono f"
  1663   assumes limseq: "(\<lambda>n. f (real n)) ----> y"
  1664   shows "(f ---> y) at_top"
  1665 proof (rule tendstoI)
  1666   fix e :: real assume "0 < e"
  1667   with limseq obtain N :: nat where N: "\<And>n. N \<le> n \<Longrightarrow> \<bar>f (real n) - y\<bar> < e"
  1668     by (auto simp: LIMSEQ_def dist_real_def)
  1669   { fix x :: real
  1670     obtain n where "x \<le> real_of_nat n"
  1671       using ex_le_of_nat[of x] ..
  1672     note monoD[OF mono this]
  1673     also have "f (real_of_nat n) \<le> y"
  1674       by (rule LIMSEQ_le_const[OF limseq])
  1675          (auto intro: exI[of _ n] monoD[OF mono] simp: real_eq_of_nat[symmetric])
  1676     finally have "f x \<le> y" . }
  1677   note le = this
  1678   have "eventually (\<lambda>x. real N \<le> x) at_top"
  1679     by (rule eventually_ge_at_top)
  1680   then show "eventually (\<lambda>x. dist (f x) y < e) at_top"
  1681   proof eventually_elim
  1682     fix x assume N': "real N \<le> x"
  1683     with N[of N] le have "y - f (real N) < e" by auto
  1684     moreover note monoD[OF mono N']
  1685     ultimately show "dist (f x) y < e"
  1686       using le[of x] by (auto simp: dist_real_def field_simps)
  1687   qed
  1688 qed
  1689 
  1690 end