src/Pure/Thy/export_theory.ML
author wenzelm
Sun Sep 30 12:26:14 2018 +0200 (12 months ago)
changeset 69087 06017b2c4552
parent 69086 2859dcdbc849
child 69784 24bbc4e30e5b
permissions -rw-r--r--
suppress aux. locales from command 'experiment' -- avoid crash of theory Dict_Construction.Test_Dict_Construction (AFP);
     1 (*  Title:      Pure/Thy/export_theory.ML
     2     Author:     Makarius
     3 
     4 Export foundational theory content and locale/class structure.
     5 *)
     6 
     7 signature EXPORT_THEORY =
     8 sig
     9   val setup_presentation: (Thy_Info.presentation_context -> theory -> unit) -> unit
    10   val export_body: theory -> string -> XML.body -> unit
    11 end;
    12 
    13 structure Export_Theory: EXPORT_THEORY =
    14 struct
    15 
    16 (* approximative syntax *)
    17 
    18 val get_syntax = Syntax.get_approx o Proof_Context.syn_of;
    19 fun get_syntax_type ctxt = get_syntax ctxt o Lexicon.mark_type;
    20 fun get_syntax_const ctxt = get_syntax ctxt o Lexicon.mark_const;
    21 fun get_syntax_fixed ctxt = get_syntax ctxt o Lexicon.mark_fixed;
    22 
    23 fun get_syntax_param ctxt loc x =
    24   let val thy = Proof_Context.theory_of ctxt in
    25     if Class.is_class thy loc then
    26       (case AList.lookup (op =) (Class.these_params thy [loc]) x of
    27         NONE => NONE
    28       | SOME (_, (c, _)) => get_syntax_const ctxt c)
    29     else get_syntax_fixed ctxt x
    30   end;
    31 
    32 val encode_syntax =
    33   XML.Encode.variant
    34    [fn NONE => ([], []),
    35     fn SOME (Syntax.Prefix delim) => ([delim], []),
    36     fn SOME (Syntax.Infix {assoc, delim, pri}) =>
    37       let
    38         val ass =
    39           (case assoc of
    40             Printer.No_Assoc => 0
    41           | Printer.Left_Assoc => 1
    42           | Printer.Right_Assoc => 2);
    43         open XML.Encode Term_XML.Encode;
    44       in ([], triple int string int (ass, delim, pri)) end];
    45 
    46 
    47 (* standardization of variables: only frees and named bounds *)
    48 
    49 local
    50 
    51 fun declare_names (Abs (_, _, b)) = declare_names b
    52   | declare_names (t $ u) = declare_names t #> declare_names u
    53   | declare_names (Const (c, _)) = Name.declare (Long_Name.base_name c)
    54   | declare_names (Free (x, _)) = Name.declare x
    55   | declare_names _ = I;
    56 
    57 fun variant_abs bs (Abs (x, T, t)) =
    58       let
    59         val names = fold Name.declare bs (declare_names t Name.context);
    60         val x' = #1 (Name.variant x names);
    61         val t' = variant_abs (x' :: bs) t;
    62       in Abs (x', T, t') end
    63   | variant_abs bs (t $ u) = variant_abs bs t $ variant_abs bs u
    64   | variant_abs _ t = t;
    65 
    66 in
    67 
    68 fun standard_vars used =
    69   let
    70     fun zero_var_indexes tm =
    71       Term_Subst.instantiate (Term_Subst.zero_var_indexes_inst used [tm]) tm;
    72 
    73     fun unvarifyT ty = ty |> Term.map_atyps
    74       (fn TVar ((a, _), S) => TFree (a, S)
    75         | T as TFree (a, _) =>
    76             if Name.is_declared used a then T
    77             else raise TYPE (Logic.bad_fixed a, [ty], []));
    78 
    79     fun unvarify tm = tm |> Term.map_aterms
    80       (fn Var ((x, _), T) => Free (x, T)
    81         | t as Free (x, _) =>
    82             if Name.is_declared used x then t
    83             else raise TERM (Logic.bad_fixed x, [tm])
    84         | t => t);
    85 
    86   in zero_var_indexes #> map_types unvarifyT #> unvarify #> variant_abs [] end;
    87 
    88 val standard_vars_global = standard_vars Name.context;
    89 
    90 end;
    91 
    92 
    93 (* free variables: not declared in the context *)
    94 
    95 val is_free = not oo Name.is_declared;
    96 
    97 fun add_frees used =
    98   fold_aterms (fn Free (x, T) => is_free used x ? insert (op =) (x, T) | _ => I);
    99 
   100 fun add_tfrees used =
   101   (fold_types o fold_atyps) (fn TFree (a, S) => is_free used a ? insert (op =) (a, S) | _ => I);
   102 
   103 
   104 (* locales content *)
   105 
   106 fun locale_content thy loc =
   107   let
   108     val ctxt = Locale.init loc thy;
   109     val args =
   110       Locale.params_of thy loc
   111       |> map (fn ((x, T), _) => ((x, T), get_syntax_param ctxt loc x));
   112     val axioms =
   113       let
   114         val (asm, defs) = Locale.specification_of thy loc;
   115         val cprops = map (Thm.cterm_of ctxt) (the_list asm @ defs);
   116         val (intro1, intro2) = Locale.intros_of thy loc;
   117         val intros_tac = Method.try_intros_tac ctxt (the_list intro1 @ the_list intro2) [];
   118         val res =
   119           Goal.init (Conjunction.mk_conjunction_balanced cprops)
   120           |> (ALLGOALS Goal.conjunction_tac THEN intros_tac)
   121           |> try Seq.hd;
   122       in
   123         (case res of
   124           SOME goal => Thm.prems_of goal
   125         | NONE => raise Fail ("Cannot unfold locale " ^ quote loc))
   126       end;
   127     val typargs = rev (fold Term.add_tfrees (map (Free o #1) args @ axioms) []);
   128   in {typargs = typargs, args = args, axioms = axioms} end;
   129 
   130 fun get_locales thy =
   131   Locale.get_locales thy |> map_filter (fn loc =>
   132     if Experiment.is_experiment thy loc then NONE else SOME (loc, ()));
   133 
   134 fun get_dependencies prev_thys thy =
   135   Locale.dest_dependencies prev_thys thy |> map_filter (fn dep =>
   136     if Experiment.is_experiment thy (#source dep) orelse
   137       Experiment.is_experiment thy (#target dep) then NONE
   138     else
   139       let
   140         val (type_params, params) = Locale.parameters_of thy (#source dep);
   141         val typargs = fold (Term.add_tfreesT o #2 o #1) params type_params;
   142         val substT =
   143           typargs |> map_filter (fn v =>
   144             let
   145               val T = TFree v;
   146               val T' = Morphism.typ (#morphism dep) T;
   147             in if T = T' then NONE else SOME (v, T') end);
   148         val subst =
   149           params |> map_filter (fn (v, _) =>
   150             let
   151               val t = Free v;
   152               val t' = Morphism.term (#morphism dep) t;
   153             in if t aconv t' then NONE else SOME (v, t') end);
   154       in SOME (dep, (substT, subst)) end);
   155 
   156 
   157 (* general setup *)
   158 
   159 fun setup_presentation f =
   160   Theory.setup (Thy_Info.add_presentation (fn context => fn thy =>
   161     if Options.bool (#options context) "export_theory" then f context thy else ()));
   162 
   163 fun export_body thy name body =
   164   Export.export thy ("theory/" ^ name) (Buffer.chunks (YXML.buffer_body body Buffer.empty));
   165 
   166 
   167 (* presentation *)
   168 
   169 val _ = setup_presentation (fn {adjust_pos, ...} => fn thy =>
   170   let
   171     val parents = Theory.parents_of thy;
   172     val rep_tsig = Type.rep_tsig (Sign.tsig_of thy);
   173 
   174     val thy_ctxt = Proof_Context.init_global thy;
   175 
   176 
   177     (* entities *)
   178 
   179     fun make_entity_markup name xname pos serial =
   180       let
   181         val props =
   182           Position.offset_properties_of (adjust_pos pos) @
   183           Position.id_properties_of pos @
   184           Markup.serial_properties serial;
   185       in (Markup.entityN, (Markup.nameN, name) :: (Markup.xnameN, xname) :: props) end;
   186 
   187     fun entity_markup space name =
   188       let
   189         val xname = Name_Space.extern_shortest thy_ctxt space name;
   190         val {serial, pos, ...} = Name_Space.the_entry space name;
   191       in make_entity_markup name xname pos serial end;
   192 
   193     fun export_entities export_name export get_space decls =
   194       let val elems =
   195         let
   196           val parent_spaces = map get_space parents;
   197           val space = get_space thy;
   198         in
   199           (decls, []) |-> fold (fn (name, decl) =>
   200             if exists (fn space => Name_Space.declared space name) parent_spaces then I
   201             else
   202               (case export name decl of
   203                 NONE => I
   204               | SOME body =>
   205                   cons (#serial (Name_Space.the_entry space name),
   206                     XML.Elem (entity_markup space name, body))))
   207           |> sort (int_ord o apply2 #1) |> map #2
   208         end;
   209       in if null elems then () else export_body thy export_name elems end;
   210 
   211 
   212     (* types *)
   213 
   214     val encode_type =
   215       let open XML.Encode Term_XML.Encode
   216       in triple encode_syntax (list string) (option typ) end;
   217 
   218     fun export_type c (Type.LogicalType n) =
   219           SOME (encode_type (get_syntax_type thy_ctxt c, Name.invent Name.context Name.aT n, NONE))
   220       | export_type c (Type.Abbreviation (args, U, false)) =
   221           SOME (encode_type (get_syntax_type thy_ctxt c, args, SOME U))
   222       | export_type _ _ = NONE;
   223 
   224     val _ =
   225       export_entities "types" export_type Sign.type_space
   226         (Name_Space.dest_table (#types rep_tsig));
   227 
   228 
   229     (* consts *)
   230 
   231     val encode_const =
   232       let open XML.Encode Term_XML.Encode
   233       in pair encode_syntax (pair (list string) (pair typ (option term))) end;
   234 
   235     fun export_const c (T, abbrev) =
   236       let
   237         val syntax = get_syntax_const thy_ctxt c;
   238         val T' = T |> Logic.unvarifyT_global |> Type.strip_sorts;
   239         val abbrev' = abbrev |> Option.map (standard_vars_global #> map_types Type.strip_sorts);
   240         val args = map (#1 o dest_TFree) (Consts.typargs (Sign.consts_of thy) (c, T'));
   241       in encode_const (syntax, (args, (T', abbrev'))) end;
   242 
   243     val _ =
   244       export_entities "consts" (SOME oo export_const) Sign.const_space
   245         (#constants (Consts.dest (Sign.consts_of thy)));
   246 
   247 
   248     (* axioms and facts *)
   249 
   250     fun prop_of raw_thm =
   251       let
   252         val thm = raw_thm
   253           |> Thm.transfer thy
   254           |> Thm.check_hyps (Context.Theory thy)
   255           |> Thm.strip_shyps;
   256         val prop = thm
   257           |> Thm.full_prop_of;
   258       in (Thm.extra_shyps thm, prop) end;
   259 
   260     fun encode_prop used (Ss, raw_prop) =
   261       let
   262         val prop = standard_vars used raw_prop;
   263         val args = rev (add_frees used prop []);
   264         val typargs = rev (add_tfrees used prop []);
   265         val used' = fold (Name.declare o #1) typargs used;
   266         val sorts = Name.invent used' Name.aT (length Ss) ~~ Ss;
   267       in
   268         (sorts @ typargs, args, prop) |>
   269           let open XML.Encode Term_XML.Encode
   270           in triple (list (pair string sort)) (list (pair string typ)) term end
   271       end;
   272 
   273     fun encode_axiom used t = encode_prop used ([], t);
   274 
   275     val encode_fact_single = encode_prop Name.context o prop_of;
   276     val encode_fact_multi = XML.Encode.list (encode_prop Name.context) o map prop_of;
   277 
   278     val _ =
   279       export_entities "axioms" (fn _ => fn t => SOME (encode_axiom Name.context t))
   280         Theory.axiom_space (Theory.axioms_of thy);
   281     val _ =
   282       export_entities "facts" (K (SOME o encode_fact_multi))
   283         (Facts.space_of o Global_Theory.facts_of)
   284         (Facts.dest_static true [] (Global_Theory.facts_of thy));
   285 
   286 
   287     (* type classes *)
   288 
   289     val encode_class =
   290       let open XML.Encode Term_XML.Encode
   291       in pair (list (pair string typ)) (list encode_fact_single) end;
   292 
   293     fun export_class name =
   294       (case try (Axclass.get_info thy) name of
   295         NONE => ([], [])
   296       | SOME {params, axioms, ...} => (params, axioms))
   297       |> encode_class |> SOME;
   298 
   299     val _ =
   300       export_entities "classes" (fn name => fn () => export_class name)
   301         Sign.class_space (map (rpair ()) (Graph.keys (Sorts.classes_of (#2 (#classes rep_tsig)))));
   302 
   303 
   304     (* sort algebra *)
   305 
   306     val {classrel, arities} =
   307       Sorts.dest_algebra (map (#2 o #classes o Type.rep_tsig o Sign.tsig_of) parents)
   308         (#2 (#classes rep_tsig));
   309 
   310     val encode_classrel =
   311       let open XML.Encode
   312       in list (pair string (list string)) end;
   313 
   314     val encode_arities =
   315       let open XML.Encode Term_XML.Encode
   316       in list (triple string (list sort) string) end;
   317 
   318     val _ = if null classrel then () else export_body thy "classrel" (encode_classrel classrel);
   319     val _ = if null arities then () else export_body thy "arities" (encode_arities arities);
   320 
   321 
   322     (* locales *)
   323 
   324     fun encode_locale used =
   325       let open XML.Encode Term_XML.Encode in
   326         triple (list (pair string sort)) (list (pair (pair string typ) encode_syntax))
   327           (list (encode_axiom used))
   328       end;
   329 
   330     fun export_locale loc =
   331       let
   332         val {typargs, args, axioms} = locale_content thy loc;
   333         val used = fold Name.declare (map #1 typargs @ map (#1 o #1) args) Name.context;
   334       in encode_locale used (typargs, args, axioms) end
   335       handle ERROR msg =>
   336         cat_error msg ("The error(s) above occurred in locale " ^
   337           quote (Locale.markup_name thy_ctxt loc));
   338 
   339     val _ =
   340       export_entities "locales" (fn loc => fn () => SOME (export_locale loc))
   341         Locale.locale_space (get_locales thy);
   342 
   343 
   344     (* locale dependencies *)
   345 
   346     fun encode_locale_dependency (dep: Locale.locale_dependency, subst) =
   347       (#source dep, (#target dep, (#prefix dep, subst))) |>
   348         let
   349           open XML.Encode Term_XML.Encode;
   350           val encode_subst =
   351             pair (list (pair (pair string sort) typ)) (list (pair (pair string typ) term));
   352         in pair string (pair string (pair (list (pair string bool)) encode_subst)) end;
   353 
   354     val _ =
   355       (case get_dependencies parents thy of
   356         [] => ()
   357       | deps =>
   358           deps |> map_index (fn (i, dep) =>
   359             let
   360               val xname = string_of_int (i + 1);
   361               val name = Long_Name.implode [Context.theory_name thy, xname];
   362               val markup = make_entity_markup name xname (#pos (#1 dep)) (#serial (#1 dep));
   363               val body = encode_locale_dependency dep;
   364             in XML.Elem (markup, body) end)
   365           |> export_body thy "locale_dependencies");
   366 
   367 
   368     (* parents *)
   369 
   370     val _ =
   371       export_body thy "parents"
   372         (XML.Encode.string (cat_lines (map Context.theory_long_name parents)));
   373 
   374   in () end);
   375 
   376 end;