src/Pure/variable.ML
author wenzelm
Wed Nov 07 16:42:57 2007 +0100 (2007-11-07)
changeset 25325 0659c05cc107
parent 25316 17c183417f93
child 25573 a0e695567236
permissions -rw-r--r--
refined notion of consts within the local scope;
     1 (*  Title:      Pure/variable.ML
     2     ID:         $Id$
     3     Author:     Makarius
     4 
     5 Fixed type/term variables and polymorphic term abbreviations.
     6 *)
     7 
     8 signature VARIABLE =
     9 sig
    10   val is_body: Proof.context -> bool
    11   val set_body: bool -> Proof.context -> Proof.context
    12   val restore_body: Proof.context -> Proof.context -> Proof.context
    13   val names_of: Proof.context -> Name.context
    14   val fixes_of: Proof.context -> (string * string) list
    15   val binds_of: Proof.context -> (typ * term) Vartab.table
    16   val maxidx_of: Proof.context -> int
    17   val constraints_of: Proof.context -> typ Vartab.table * sort Vartab.table
    18   val is_declared: Proof.context -> string -> bool
    19   val is_fixed: Proof.context -> string -> bool
    20   val newly_fixed: Proof.context -> Proof.context -> string -> bool
    21   val add_fixed: Proof.context -> term -> (string * typ) list -> (string * typ) list
    22   val default_type: Proof.context -> string -> typ option
    23   val def_type: Proof.context -> bool -> indexname -> typ option
    24   val def_sort: Proof.context -> indexname -> sort option
    25   val declare_constraints: term -> Proof.context -> Proof.context
    26   val declare_internal: term -> Proof.context -> Proof.context
    27   val declare_term: term -> Proof.context -> Proof.context
    28   val declare_prf: Proofterm.proof -> Proof.context -> Proof.context
    29   val declare_thm: thm -> Proof.context -> Proof.context
    30   val thm_context: thm -> Proof.context
    31   val variant_frees: Proof.context -> term list -> (string * 'a) list -> (string * 'a) list
    32   val add_binds: (indexname * term option) list -> Proof.context -> Proof.context
    33   val expand_binds: Proof.context -> term -> term
    34   val lookup_const: Proof.context -> string -> string option
    35   val is_const: Proof.context -> string -> bool
    36   val declare_const: string * string -> Proof.context -> Proof.context
    37   val add_fixes: string list -> Proof.context -> string list * Proof.context
    38   val add_fixes_direct: string list -> Proof.context -> Proof.context
    39   val auto_fixes: term -> Proof.context -> Proof.context
    40   val variant_fixes: string list -> Proof.context -> string list * Proof.context
    41   val invent_types: sort list -> Proof.context -> (string * sort) list * Proof.context
    42   val export_terms: Proof.context -> Proof.context -> term list -> term list
    43   val exportT_terms: Proof.context -> Proof.context -> term list -> term list
    44   val exportT: Proof.context -> Proof.context -> thm list -> thm list
    45   val export_prf: Proof.context -> Proof.context -> Proofterm.proof -> Proofterm.proof
    46   val export: Proof.context -> Proof.context -> thm list -> thm list
    47   val export_morphism: Proof.context -> Proof.context -> morphism
    48   val importT_inst: term list -> Proof.context -> ((indexname * sort) * typ) list * Proof.context
    49   val import_inst: bool -> term list -> Proof.context ->
    50     (((indexname * sort) * typ) list * ((indexname * typ) * term) list) * Proof.context
    51   val importT_terms: term list -> Proof.context -> term list * Proof.context
    52   val import_terms: bool -> term list -> Proof.context -> term list * Proof.context
    53   val importT_thms: thm list -> Proof.context -> (ctyp list * thm list) * Proof.context
    54   val import_prf: bool -> Proofterm.proof -> Proof.context -> Proofterm.proof * Proof.context
    55   val import_thms: bool -> thm list -> Proof.context ->
    56     ((ctyp list * cterm list) * thm list) * Proof.context
    57   val tradeT: (Proof.context -> thm list -> thm list) -> Proof.context -> thm list -> thm list
    58   val trade: (Proof.context -> thm list -> thm list) -> Proof.context -> thm list -> thm list
    59   val focus: cterm -> Proof.context -> (cterm list * cterm) * Proof.context
    60   val focus_subgoal: int -> thm -> Proof.context -> (cterm list * cterm) * Proof.context
    61   val warn_extra_tfrees: Proof.context -> Proof.context -> unit
    62   val polymorphic_types: Proof.context -> term list -> (indexname * sort) list * term list
    63   val polymorphic: Proof.context -> term list -> term list
    64 end;
    65 
    66 structure Variable: VARIABLE =
    67 struct
    68 
    69 (** local context data **)
    70 
    71 datatype data = Data of
    72  {is_body: bool,                        (*inner body mode*)
    73   names: Name.context,                  (*type/term variable names*)
    74   consts: string Symtab.table,          (*consts within the local scope*)
    75   fixes: (string * string) list,        (*term fixes -- extern/intern*)
    76   binds: (typ * term) Vartab.table,     (*term bindings*)
    77   type_occs: string list Symtab.table,  (*type variables -- possibly within term variables*)
    78   maxidx: int,                          (*maximum var index*)
    79   constraints:
    80     typ Vartab.table *                  (*type constraints*)
    81     sort Vartab.table};                 (*default sorts*)
    82 
    83 fun make_data (is_body, names, consts, fixes, binds, type_occs, maxidx, constraints) =
    84   Data {is_body = is_body, names = names, consts = consts, fixes = fixes, binds = binds,
    85     type_occs = type_occs, maxidx = maxidx, constraints = constraints};
    86 
    87 structure Data = ProofDataFun
    88 (
    89   type T = data;
    90   fun init thy =
    91     make_data (false, Name.context, Symtab.empty, [], Vartab.empty, Symtab.empty,
    92       ~1, (Vartab.empty, Vartab.empty));
    93 );
    94 
    95 fun map_data f =
    96   Data.map (fn Data {is_body, names, consts, fixes, binds, type_occs, maxidx, constraints} =>
    97     make_data (f (is_body, names, consts, fixes, binds, type_occs, maxidx, constraints)));
    98 
    99 fun map_names f =
   100   map_data (fn (is_body, names, consts, fixes, binds, type_occs, maxidx, constraints) =>
   101     (is_body, f names, consts, fixes, binds, type_occs, maxidx, constraints));
   102 
   103 fun map_consts f =
   104   map_data (fn (is_body, names, consts, fixes, binds, type_occs, maxidx, constraints) =>
   105     (is_body, names, f consts, fixes, binds, type_occs, maxidx, constraints));
   106 
   107 fun map_fixes f =
   108   map_data (fn (is_body, names, consts, fixes, binds, type_occs, maxidx, constraints) =>
   109     (is_body, names, consts, f fixes, binds, type_occs, maxidx, constraints));
   110 
   111 fun map_binds f =
   112   map_data (fn (is_body, names, consts, fixes, binds, type_occs, maxidx, constraints) =>
   113     (is_body, names, consts, fixes, f binds, type_occs, maxidx, constraints));
   114 
   115 fun map_type_occs f =
   116   map_data (fn (is_body, names, consts, fixes, binds, type_occs, maxidx, constraints) =>
   117     (is_body, names, consts, fixes, binds, f type_occs, maxidx, constraints));
   118 
   119 fun map_maxidx f =
   120   map_data (fn (is_body, names, consts, fixes, binds, type_occs, maxidx, constraints) =>
   121     (is_body, names, consts, fixes, binds, type_occs, f maxidx, constraints));
   122 
   123 fun map_constraints f =
   124   map_data (fn (is_body, names, consts, fixes, binds, type_occs, maxidx, constraints) =>
   125     (is_body, names, consts, fixes, binds, type_occs, maxidx, f constraints));
   126 
   127 fun rep_data ctxt = Data.get ctxt |> (fn Data args => args);
   128 
   129 val is_body = #is_body o rep_data;
   130 
   131 fun set_body b = map_data (fn (_, names, consts, fixes, binds, type_occs, maxidx, constraints) =>
   132   (b, names, consts, fixes, binds, type_occs, maxidx, constraints));
   133 
   134 fun restore_body ctxt = set_body (is_body ctxt);
   135 
   136 val names_of = #names o rep_data;
   137 val fixes_of = #fixes o rep_data;
   138 val binds_of = #binds o rep_data;
   139 val type_occs_of = #type_occs o rep_data;
   140 val maxidx_of = #maxidx o rep_data;
   141 val constraints_of = #constraints o rep_data;
   142 
   143 val is_declared = Name.is_declared o names_of;
   144 fun is_fixed ctxt x = exists (fn (_, y) => x = y) (fixes_of ctxt);
   145 fun newly_fixed inner outer x = is_fixed inner x andalso not (is_fixed outer x);
   146 
   147 fun add_fixed ctxt = Term.fold_aterms
   148   (fn Free (x, T) => if is_fixed ctxt x then insert (op =) (x, T) else I | _ => I);
   149 
   150 
   151 
   152 (** declarations **)
   153 
   154 (* default sorts and types *)
   155 
   156 fun default_type ctxt x = Vartab.lookup (#1 (constraints_of ctxt)) (x, ~1);
   157 
   158 fun def_type ctxt pattern xi =
   159   let val {binds, constraints = (types, _), ...} = rep_data ctxt in
   160     (case Vartab.lookup types xi of
   161       NONE =>
   162         if pattern then NONE
   163         else Vartab.lookup binds xi |> Option.map (TypeInfer.polymorphicT o #1)
   164     | some => some)
   165   end;
   166 
   167 val def_sort = Vartab.lookup o #2 o constraints_of;
   168 
   169 
   170 (* names *)
   171 
   172 fun declare_type_names t =
   173   map_names (fold_types (fold_atyps (fn TFree (a, _) => Name.declare a | _ => I)) t) #>
   174   map_maxidx (fold_types Term.maxidx_typ t);
   175 
   176 fun declare_names t =
   177   declare_type_names t #>
   178   map_names (fold_aterms (fn Free (x, _) => Name.declare x | _ => I) t) #>
   179   map_maxidx (Term.maxidx_term t);
   180 
   181 
   182 (* type occurrences *)
   183 
   184 fun decl_type_occsT T = fold_atyps (fn TFree (a, _) => Symtab.default (a, []) | _ => I) T;
   185 
   186 val decl_type_occs = fold_term_types
   187   (fn Free (x, _) => fold_atyps (fn TFree (a, _) => Symtab.insert_list (op =) (a, x) | _ => I)
   188     | _ => decl_type_occsT);
   189 
   190 val declare_type_occsT = map_type_occs o fold_types decl_type_occsT;
   191 val declare_type_occs = map_type_occs o decl_type_occs;
   192 
   193 
   194 (* constraints *)
   195 
   196 fun constrain_tvar (xi, S) =
   197   if S = dummyS then Vartab.delete_safe xi else Vartab.update (xi, S);
   198 
   199 fun declare_constraints t = map_constraints (fn (types, sorts) =>
   200   let
   201     val types' = fold_aterms
   202       (fn Free (x, T) => Vartab.update ((x, ~1), T)
   203         | Var v => Vartab.update v
   204         | _ => I) t types;
   205     val sorts' = fold_types (fold_atyps
   206       (fn TFree (x, S) => constrain_tvar ((x, ~1), S)
   207         | TVar v => constrain_tvar v
   208         | _ => I)) t sorts;
   209   in (types', sorts') end)
   210   #> declare_type_occsT t
   211   #> declare_type_names t;
   212 
   213 
   214 (* common declarations *)
   215 
   216 fun declare_internal t =
   217   declare_names t #>
   218   declare_type_occs t;
   219 
   220 fun declare_term t =
   221   declare_internal t #>
   222   declare_constraints t;
   223 
   224 val declare_prf = Proofterm.fold_proof_terms declare_internal (declare_internal o Logic.mk_type);
   225 
   226 val declare_thm = Thm.fold_terms declare_internal;
   227 fun thm_context th = declare_thm th (ProofContext.init (Thm.theory_of_thm th));
   228 
   229 
   230 (* renaming term/type frees *)
   231 
   232 fun variant_frees ctxt ts frees =
   233   let
   234     val names = names_of (fold declare_names ts ctxt);
   235     val xs = fst (Name.variants (map #1 frees) names);
   236   in xs ~~ map snd frees end;
   237 
   238 
   239 
   240 (** term bindings **)
   241 
   242 fun add_bind (xi, NONE) = map_binds (Vartab.delete_safe xi)
   243   | add_bind ((x, i), SOME t) =
   244       let
   245         val u = Term.close_schematic_term t;
   246         val U = Term.fastype_of u;
   247       in declare_term u #> map_binds (Vartab.update ((x, i), (U, u))) end;
   248 
   249 val add_binds = fold add_bind;
   250 
   251 fun expand_binds ctxt =
   252   let
   253     val binds = binds_of ctxt;
   254     val get = fn Var (xi, _) => Vartab.lookup binds xi | _ => NONE;
   255   in Envir.beta_norm o Envir.expand_term get end;
   256 
   257 
   258 
   259 (** consts **)
   260 
   261 val lookup_const = Symtab.lookup o #consts o rep_data;
   262 val is_const = is_some oo lookup_const;
   263 
   264 val declare_fixed = map_consts o Symtab.delete_safe;
   265 val declare_const = map_consts o Symtab.update;
   266 
   267 
   268 
   269 (** fixes **)
   270 
   271 local
   272 
   273 fun no_dups [] = ()
   274   | no_dups dups = error ("Duplicate fixed variable(s): " ^ commas_quote dups);
   275 
   276 fun new_fixes names' xs xs' =
   277   map_names (K names') #>
   278   fold declare_fixed xs #>
   279   map_fixes (fn fixes => (rev (xs ~~ xs') @ fixes)) #>
   280   fold (declare_constraints o Syntax.free) xs' #>
   281   pair xs';
   282 
   283 in
   284 
   285 fun add_fixes xs ctxt =
   286   let
   287     val _ =
   288       (case filter (can Name.dest_skolem) xs of [] => ()
   289       | bads => error ("Illegal internal Skolem constant(s): " ^ commas_quote bads));
   290     val _ = no_dups (duplicates (op =) xs);
   291     val (ys, zs) = split_list (fixes_of ctxt);
   292     val names = names_of ctxt;
   293     val (xs', names') =
   294       if is_body ctxt then Name.variants xs names |>> map Name.skolem
   295       else (no_dups (xs inter_string ys); no_dups (xs inter_string zs);
   296         (xs, fold Name.declare xs names));
   297   in ctxt |> new_fixes names' xs xs' end;
   298 
   299 fun variant_fixes raw_xs ctxt =
   300   let
   301     val names = names_of ctxt;
   302     val xs = map Name.clean raw_xs;
   303     val (xs', names') = Name.variants xs names |>> map Name.skolem;
   304   in ctxt |> new_fixes names' xs xs' end;
   305 
   306 end;
   307 
   308 
   309 fun add_fixes_direct xs ctxt = ctxt
   310   |> set_body false
   311   |> (snd o add_fixes xs)
   312   |> restore_body ctxt;
   313 
   314 fun fix_frees t ctxt = ctxt
   315   |> add_fixes_direct
   316       (rev (fold_aterms (fn Free (x, _) =>
   317         if is_fixed ctxt x then I else insert (op =) x | _ => I) t []));
   318 
   319 fun auto_fixes t ctxt =
   320   (if is_body ctxt then ctxt else fix_frees t ctxt)
   321   |> declare_term t;
   322 
   323 fun invent_types Ss ctxt =
   324   let
   325     val tfrees = Name.invents (names_of ctxt) Name.aT (length Ss) ~~ Ss;
   326     val ctxt' = fold (declare_constraints o Logic.mk_type o TFree) tfrees ctxt;
   327   in (tfrees, ctxt') end;
   328 
   329 
   330 
   331 (** export -- generalize type/term variables (beware of closure sizes) **)
   332 
   333 fun export_inst inner outer =
   334   let
   335     val declared_outer = is_declared outer;
   336     val fixes_inner = fixes_of inner;
   337     val fixes_outer = fixes_of outer;
   338 
   339     val gen_fixes = map #2 (Library.take (length fixes_inner - length fixes_outer, fixes_inner));
   340     val still_fixed = not o member (op =) gen_fixes;
   341 
   342     val type_occs_inner = type_occs_of inner;
   343     fun gen_fixesT ts =
   344       Symtab.fold (fn (a, xs) =>
   345         if declared_outer a orelse exists still_fixed xs
   346         then I else cons a) (fold decl_type_occs ts type_occs_inner) [];
   347   in (gen_fixesT, gen_fixes) end;
   348 
   349 fun exportT_inst inner outer = #1 (export_inst inner outer);
   350 
   351 fun exportT_terms inner outer =
   352   let val mk_tfrees = exportT_inst inner outer in
   353     fn ts => ts |> map
   354       (TermSubst.generalize (mk_tfrees ts, [])
   355         (fold (Term.fold_types Term.maxidx_typ) ts ~1 + 1))
   356   end;
   357 
   358 fun export_terms inner outer =
   359   let val (mk_tfrees, tfrees) = export_inst inner outer in
   360     fn ts => ts |> map
   361       (TermSubst.generalize (mk_tfrees ts, tfrees)
   362         (fold Term.maxidx_term ts ~1 + 1))
   363   end;
   364 
   365 fun export_prf inner outer prf =
   366   let
   367     val (mk_tfrees, frees) = export_inst (declare_prf prf inner) outer;
   368     val tfrees = mk_tfrees [];
   369     val idx = Proofterm.maxidx_proof prf ~1 + 1;
   370     val gen_term = TermSubst.generalize_option (tfrees, frees) idx;
   371     val gen_typ = TermSubst.generalizeT_option tfrees idx;
   372   in Proofterm.map_proof_terms_option gen_term gen_typ prf end;
   373 
   374 
   375 fun gen_export (mk_tfrees, frees) ths =
   376   let
   377     val tfrees = mk_tfrees (map Thm.full_prop_of ths);
   378     val maxidx = fold Thm.maxidx_thm ths ~1;
   379   in map (Thm.generalize (tfrees, frees) (maxidx + 1)) ths end;
   380 
   381 fun exportT inner outer = gen_export (exportT_inst inner outer, []);
   382 fun export inner outer = gen_export (export_inst inner outer);
   383 
   384 fun export_morphism inner outer =
   385   let
   386     val fact = export inner outer;
   387     val term = singleton (export_terms inner outer);
   388     val typ = Logic.type_map term;
   389   in Morphism.morphism {name = I, var = I, typ = typ, term = term, fact = fact} end;
   390 
   391 
   392 
   393 (** import -- fix schematic type/term variables **)
   394 
   395 fun importT_inst ts ctxt =
   396   let
   397     val tvars = rev (fold Term.add_tvars ts []);
   398     val (tfrees, ctxt') = invent_types (map #2 tvars) ctxt;
   399   in (tvars ~~ map TFree tfrees, ctxt') end;
   400 
   401 fun import_inst is_open ts ctxt =
   402   let
   403     val ren = if is_open then I else Name.internal;
   404     val (instT, ctxt') = importT_inst ts ctxt;
   405     val vars = map (apsnd (TermSubst.instantiateT instT)) (rev (fold Term.add_vars ts []));
   406     val (xs, ctxt'') = variant_fixes (map (ren o #1 o #1) vars) ctxt';
   407     val inst = vars ~~ map Free (xs ~~ map #2 vars);
   408   in ((instT, inst), ctxt'') end;
   409 
   410 fun importT_terms ts ctxt =
   411   let val (instT, ctxt') = importT_inst ts ctxt
   412   in (map (TermSubst.instantiate (instT, [])) ts, ctxt') end;
   413 
   414 fun import_terms is_open ts ctxt =
   415   let val (inst, ctxt') = import_inst is_open ts ctxt
   416   in (map (TermSubst.instantiate inst) ts, ctxt') end;
   417 
   418 fun importT_thms ths ctxt =
   419   let
   420     val thy = ProofContext.theory_of ctxt;
   421     val certT = Thm.ctyp_of thy;
   422     val (instT, ctxt') = importT_inst (map Thm.full_prop_of ths) ctxt;
   423     val instT' = map (fn (v, T) => (certT (TVar v), certT T)) instT;
   424     val ths' = map (Thm.instantiate (instT', [])) ths;
   425   in ((map #2 instT', ths'), ctxt') end;
   426 
   427 fun import_prf is_open prf ctxt =
   428   let
   429     val ts = rev (Proofterm.fold_proof_terms cons (cons o Logic.mk_type) prf []);
   430     val (insts, ctxt') = import_inst is_open ts ctxt;
   431   in (Proofterm.instantiate insts prf, ctxt') end;
   432 
   433 fun import_thms is_open ths ctxt =
   434   let
   435     val thy = ProofContext.theory_of ctxt;
   436     val cert = Thm.cterm_of thy;
   437     val certT = Thm.ctyp_of thy;
   438     val ((instT, inst), ctxt') = import_inst is_open (map Thm.full_prop_of ths) ctxt;
   439     val instT' = map (fn (v, T) => (certT (TVar v), certT T)) instT;
   440     val inst' = map (fn (v, t) => (cert (Var v), cert t)) inst;
   441     val ths' = map (Thm.instantiate (instT', inst')) ths;
   442   in (((map #2 instT', map #2 inst'), ths'), ctxt') end;
   443 
   444 
   445 (* import/export *)
   446 
   447 fun gen_trade imp exp f ctxt ths =
   448   let val ((_, ths'), ctxt') = imp ths ctxt
   449   in exp ctxt' ctxt (f ctxt' ths') end;
   450 
   451 val tradeT = gen_trade importT_thms exportT;
   452 val trade = gen_trade (import_thms true) export;
   453 
   454 
   455 (* focus on outermost parameters *)
   456 
   457 fun forall_elim_prop t prop =
   458   Thm.beta_conversion false (Thm.capply (Thm.dest_arg prop) t)
   459   |> Thm.cprop_of |> Thm.dest_arg;
   460 
   461 fun focus goal ctxt =
   462   let
   463     val cert = Thm.cterm_of (Thm.theory_of_cterm goal);
   464     val t = Thm.term_of goal;
   465     val ps = Term.variant_frees t (Term.strip_all_vars t);   (*as they are printed :-*)
   466     val (xs, Ts) = split_list ps;
   467     val (xs', ctxt') = variant_fixes xs ctxt;
   468     val ps' = ListPair.map (cert o Free) (xs', Ts);
   469     val goal' = fold forall_elim_prop ps' goal;
   470   in ((ps', goal'), ctxt') end;
   471 
   472 fun focus_subgoal i st =
   473   let
   474     val all_vars = Thm.fold_terms Term.add_vars st [];
   475     val no_binds = map (fn (xi, _) => (xi, NONE)) all_vars;
   476   in
   477     add_binds no_binds #>
   478     fold (declare_constraints o Var) all_vars #>
   479     focus (Thm.cprem_of st i)
   480   end;
   481 
   482 
   483 
   484 (** implicit polymorphism **)
   485 
   486 (* warn_extra_tfrees *)
   487 
   488 fun warn_extra_tfrees ctxt1 ctxt2 =
   489   let
   490     fun occs_typ a = Term.exists_subtype (fn TFree (b, _) => a = b | _ => false);
   491     fun occs_free a x =
   492       (case def_type ctxt1 false (x, ~1) of
   493         SOME T => if occs_typ a T then I else cons (a, x)
   494       | NONE => cons (a, x));
   495 
   496     val occs1 = type_occs_of ctxt1;
   497     val occs2 = type_occs_of ctxt2;
   498     val extras = Symtab.fold (fn (a, xs) =>
   499       if Symtab.defined occs1 a then I else fold (occs_free a) xs) occs2 [];
   500     val tfrees = map #1 extras |> sort_distinct string_ord;
   501     val frees = map #2 extras |> sort_distinct string_ord;
   502   in
   503     if null extras then ()
   504     else warning ("Introduced fixed type variable(s): " ^ commas tfrees ^ " in " ^
   505       space_implode " or " (map quote frees))
   506   end;
   507 
   508 
   509 (* polymorphic terms *)
   510 
   511 fun polymorphic_types ctxt ts =
   512   let
   513     val ctxt' = fold declare_term ts ctxt;
   514     val occs = type_occs_of ctxt;
   515     val occs' = type_occs_of ctxt';
   516     val types = Symtab.fold (fn (a, _) => if Symtab.defined occs a then I else cons a) occs' [];
   517     val idx = maxidx_of ctxt' + 1;
   518     val Ts' = (fold o fold_types o fold_atyps)
   519       (fn T as TFree _ =>
   520           (case TermSubst.generalizeT types idx T of TVar v => insert (op =) v | _ => I)
   521         | _ => I) ts [];
   522     val ts' = map (TermSubst.generalize (types, []) idx) ts;
   523   in (rev Ts', ts') end;
   524 
   525 fun polymorphic ctxt ts = snd (polymorphic_types ctxt ts);
   526 
   527 end;