src/Pure/library.ML
author haftmann
Fri Oct 01 10:25:36 2010 +0200 (2010-10-01)
changeset 39811 0659e84bdc5f
parent 39809 dac3c3106746
child 40291 012ed4426fda
permissions -rw-r--r--
chop_while replace drop_while and take_while
     1 (*  Title:      Pure/library.ML
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 Basic library: functions, pairs, booleans, lists, integers,
     6 strings, lists as sets, orders, current directory, misc.
     7 
     8 See also General/basics.ML for the most fundamental concepts.
     9 *)
    10 
    11 infix 2 ?
    12 infix 3 o oo ooo oooo
    13 infix 4 ~~ upto downto
    14 infix orf andf
    15 
    16 signature BASIC_LIBRARY =
    17 sig
    18   (*functions*)
    19   val undefined: 'a -> 'b
    20   val I: 'a -> 'a
    21   val K: 'a -> 'b -> 'a
    22   val curry: ('a * 'b -> 'c) -> 'a -> 'b -> 'c
    23   val uncurry: ('a -> 'b -> 'c) -> 'a * 'b -> 'c
    24   val ? : bool * ('a -> 'a) -> 'a -> 'a
    25   val oo: ('a -> 'b) * ('c -> 'd -> 'a) -> 'c -> 'd -> 'b
    26   val ooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'a) -> 'c -> 'd -> 'e -> 'b
    27   val oooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'f -> 'a) -> 'c -> 'd -> 'e -> 'f -> 'b
    28   val funpow: int -> ('a -> 'a) -> 'a -> 'a
    29   val funpow_yield: int -> ('a -> 'b * 'a) -> 'a -> 'b list * 'a
    30 
    31   (*errors*)
    32   exception SYS_ERROR of string
    33   val sys_error: string -> 'a
    34   exception ERROR of string
    35   val error: string -> 'a
    36   val cat_error: string -> string -> 'a
    37   val assert_all: ('a -> bool) -> 'a list -> ('a -> string) -> unit
    38 
    39   (*pairs*)
    40   val pair: 'a -> 'b -> 'a * 'b
    41   val rpair: 'a -> 'b -> 'b * 'a
    42   val fst: 'a * 'b -> 'a
    43   val snd: 'a * 'b -> 'b
    44   val eq_fst: ('a * 'c -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    45   val eq_snd: ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    46   val eq_pair: ('a * 'c -> bool) -> ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    47   val swap: 'a * 'b -> 'b * 'a
    48   val apfst: ('a -> 'b) -> 'a * 'c -> 'b * 'c
    49   val apsnd: ('a -> 'b) -> 'c * 'a -> 'c * 'b
    50   val pairself: ('a -> 'b) -> 'a * 'a -> 'b * 'b
    51 
    52   (*booleans*)
    53   val equal: ''a -> ''a -> bool
    54   val not_equal: ''a -> ''a -> bool
    55   val orf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    56   val andf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    57   val exists: ('a -> bool) -> 'a list -> bool
    58   val forall: ('a -> bool) -> 'a list -> bool
    59   val setmp_CRITICAL: 'a Unsynchronized.ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    60   val setmp_thread_data: 'a Universal.tag -> 'a -> 'a -> ('b -> 'c) -> 'b -> 'c
    61 
    62   (*lists*)
    63   exception UnequalLengths
    64   val single: 'a -> 'a list
    65   val the_single: 'a list -> 'a
    66   val singleton: ('a list -> 'b list) -> 'a -> 'b
    67   val yield_singleton: ('a list -> 'c -> 'b list * 'c) -> 'a -> 'c -> 'b * 'c
    68   val apply: ('a -> 'a) list -> 'a -> 'a
    69   val perhaps_apply: ('a -> 'a option) list -> 'a -> 'a option
    70   val perhaps_loop: ('a -> 'a option) -> 'a -> 'a option
    71   val foldl1: ('a * 'a -> 'a) -> 'a list -> 'a
    72   val foldr1: ('a * 'a -> 'a) -> 'a list -> 'a
    73   val flat: 'a list list -> 'a list
    74   val unflat: 'a list list -> 'b list -> 'b list list
    75   val burrow: ('a list -> 'b list) -> 'a list list -> 'b list list
    76   val burrow_options: ('a list -> 'b list) -> 'a option list -> 'b option list
    77   val burrow_fst: ('a list -> 'b list) -> ('a * 'c) list -> ('b * 'c) list
    78   val fold_burrow: ('a list -> 'c -> 'b list * 'd) -> 'a list list -> 'c -> 'b list list * 'd
    79   val maps: ('a -> 'b list) -> 'a list -> 'b list
    80   val filter: ('a -> bool) -> 'a list -> 'a list
    81   val filter_out: ('a -> bool) -> 'a list -> 'a list
    82   val map_filter: ('a -> 'b option) -> 'a list -> 'b list
    83   val take: int -> 'a list -> 'a list
    84   val drop: int -> 'a list -> 'a list
    85   val chop: int -> 'a list -> 'a list * 'a list
    86   val chop_while: ('a -> bool) -> 'a list -> 'a list * 'a list
    87   val nth: 'a list -> int -> 'a
    88   val nth_map: int -> ('a -> 'a) -> 'a list -> 'a list
    89   val nth_drop: int -> 'a list -> 'a list
    90   val nth_list: 'a list list -> int -> 'a list
    91   val map_index: (int * 'a -> 'b) -> 'a list -> 'b list
    92   val fold_index: (int * 'a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    93   val map_range: (int -> 'a) -> int -> 'a list
    94   val split_last: 'a list -> 'a list * 'a
    95   val find_index: ('a -> bool) -> 'a list -> int
    96   val find_first: ('a -> bool) -> 'a list -> 'a option
    97   val get_index: ('a -> 'b option) -> 'a list -> (int * 'b) option
    98   val get_first: ('a -> 'b option) -> 'a list -> 'b option
    99   val eq_list: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   100   val map2: ('a -> 'b -> 'c) -> 'a list -> 'b list -> 'c list
   101   val fold2: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
   102   val zip_options: 'a list -> 'b option list -> ('a * 'b) list
   103   val ~~ : 'a list * 'b list -> ('a * 'b) list
   104   val map_split: ('a -> 'b * 'c) -> 'a list -> 'b list * 'c list
   105   val split_list: ('a * 'b) list -> 'a list * 'b list
   106   val map_product: ('a -> 'b -> 'c) -> 'a list -> 'b list -> 'c list
   107   val fold_product: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
   108   val map_transpose: ('a list -> 'b) -> 'a list list -> 'b list
   109   val separate: 'a -> 'a list -> 'a list
   110   val surround: 'a -> 'a list -> 'a list
   111   val replicate: int -> 'a -> 'a list
   112   val is_prefix: ('a * 'a -> bool) -> 'a list -> 'a list -> bool
   113   val take_prefix: ('a -> bool) -> 'a list -> 'a list * 'a list
   114   val chop_prefix: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list * ('a list * 'b list)
   115   val take_suffix: ('a -> bool) -> 'a list -> 'a list * 'a list
   116   val prefixes1: 'a list -> 'a list list
   117   val prefixes: 'a list -> 'a list list
   118   val suffixes1: 'a list -> 'a list list
   119   val suffixes: 'a list -> 'a list list
   120 
   121   (*integers*)
   122   val upto: int * int -> int list
   123   val downto: int * int -> int list
   124   val radixpand: int * int -> int list
   125   val radixstring: int * string * int -> string
   126   val string_of_int: int -> string
   127   val signed_string_of_int: int -> string
   128   val string_of_indexname: string * int -> string
   129   val read_radix_int: int -> string list -> int * string list
   130   val read_int: string list -> int * string list
   131   val oct_char: string -> string
   132 
   133   (*strings*)
   134   val nth_string: string -> int -> string
   135   val fold_string: (string -> 'a -> 'a) -> string -> 'a -> 'a
   136   val exists_string: (string -> bool) -> string -> bool
   137   val forall_string: (string -> bool) -> string -> bool
   138   val first_field: string -> string -> (string * string) option
   139   val enclose: string -> string -> string -> string
   140   val unenclose: string -> string
   141   val quote: string -> string
   142   val space_implode: string -> string list -> string
   143   val commas: string list -> string
   144   val commas_quote: string list -> string
   145   val cat_lines: string list -> string
   146   val space_explode: string -> string -> string list
   147   val split_lines: string -> string list
   148   val prefix_lines: string -> string -> string
   149   val prefix: string -> string -> string
   150   val suffix: string -> string -> string
   151   val unprefix: string -> string -> string
   152   val unsuffix: string -> string -> string
   153   val replicate_string: int -> string -> string
   154   val translate_string: (string -> string) -> string -> string
   155   val match_string: string -> string -> bool
   156 
   157   (*lists as sets -- see also Pure/General/ord_list.ML*)
   158   val member: ('b * 'a -> bool) -> 'a list -> 'b -> bool
   159   val insert: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   160   val remove: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   161   val update: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   162   val union: ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   163   val subtract: ('b * 'a -> bool) -> 'b list -> 'a list -> 'a list
   164   val inter: ('a * 'b -> bool) -> 'b list -> 'a list -> 'a list
   165   val merge: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   166   val subset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   167   val eq_set: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   168   val distinct: ('a * 'a -> bool) -> 'a list -> 'a list
   169   val duplicates: ('a * 'a -> bool) -> 'a list -> 'a list
   170   val has_duplicates: ('a * 'a -> bool) -> 'a list -> bool
   171 
   172   (*lists as multisets*)
   173   val remove1: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   174   val combine: ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   175   val submultiset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   176 
   177   (*orders*)
   178   val is_equal: order -> bool
   179   val rev_order: order -> order
   180   val make_ord: ('a * 'a -> bool) -> 'a * 'a -> order
   181   val bool_ord: bool * bool -> order
   182   val int_ord: int * int -> order
   183   val string_ord: string * string -> order
   184   val fast_string_ord: string * string -> order
   185   val option_ord: ('a * 'b -> order) -> 'a option * 'b option -> order
   186   val prod_ord: ('a * 'b -> order) -> ('c * 'd -> order) -> ('a * 'c) * ('b * 'd) -> order
   187   val dict_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   188   val list_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   189   val sort: ('a * 'a -> order) -> 'a list -> 'a list
   190   val sort_distinct: ('a * 'a -> order) -> 'a list -> 'a list
   191   val sort_strings: string list -> string list
   192   val sort_wrt: ('a -> string) -> 'a list -> 'a list
   193   val tag_list: int -> 'a list -> (int * 'a) list
   194   val untag_list: (int * 'a) list -> 'a list
   195   val order_list: (int * 'a) list -> 'a list
   196 
   197   (*random numbers*)
   198   exception RANDOM
   199   val random: unit -> real
   200   val random_range: int -> int -> int
   201   val one_of: 'a list -> 'a
   202   val frequency: (int * 'a) list -> 'a
   203 
   204   (*misc*)
   205   val divide_and_conquer: ('a -> 'a list * ('b list -> 'b)) -> 'a -> 'b
   206   val divide_and_conquer': ('a -> 'b -> ('a list * ('c list * 'b -> 'c * 'b)) * 'b) ->
   207     'a -> 'b -> 'c * 'b
   208   val partition_eq: ('a * 'a -> bool) -> 'a list -> 'a list list
   209   val partition_list: (int -> 'a -> bool) -> int -> int -> 'a list -> 'a list list
   210   val gensym: string -> string
   211   type stamp
   212   val stamp: unit -> stamp
   213   type serial
   214   val serial: unit -> serial
   215   val serial_string: unit -> string
   216   structure Object: sig type T end
   217 end;
   218 
   219 signature LIBRARY =
   220 sig
   221   include BASIC_LIBRARY
   222   val foldl: ('a * 'b -> 'a) -> 'a * 'b list -> 'a
   223   val foldr: ('a * 'b -> 'b) -> 'a list * 'b -> 'b
   224   val foldl_map: ('a * 'b -> 'a * 'c) -> 'a * 'b list -> 'a * 'c list
   225   val last_elem: 'a list -> 'a
   226 end;
   227 
   228 structure Library: LIBRARY =
   229 struct
   230 
   231 (* functions *)
   232 
   233 fun undefined _ = raise Match;
   234 
   235 fun I x = x;
   236 fun K x = fn _ => x;
   237 fun curry f x y = f (x, y);
   238 fun uncurry f (x, y) = f x y;
   239 
   240 (*conditional application*)
   241 fun b ? f = fn x => if b then f x else x;
   242 
   243 (*composition with multiple args*)
   244 fun (f oo g) x y = f (g x y);
   245 fun (f ooo g) x y z = f (g x y z);
   246 fun (f oooo g) x y z w = f (g x y z w);
   247 
   248 (*function exponentiation: f (... (f x) ...) with n applications of f*)
   249 fun funpow (0 : int) _ = I
   250   | funpow n f = f #> funpow (n - 1) f;
   251 
   252 fun funpow_yield (0 : int) _ x = ([], x)
   253   | funpow_yield n f x = x |> f ||>> funpow_yield (n - 1) f |>> op ::;
   254 
   255 (* errors *)
   256 
   257 exception SYS_ERROR of string;
   258 fun sys_error msg = raise SYS_ERROR msg;
   259 
   260 exception ERROR of string;
   261 fun error msg = raise ERROR msg;
   262 
   263 fun cat_error "" msg = error msg
   264   | cat_error msg1 msg2 = error (msg1 ^ "\n" ^ msg2);
   265 
   266 fun assert_all pred list msg =
   267   let
   268     fun ass [] = ()
   269       | ass (x :: xs) = if pred x then ass xs else error (msg x);
   270   in ass list end;
   271 
   272 
   273 (* pairs *)
   274 
   275 fun pair x y = (x, y);
   276 fun rpair x y = (y, x);
   277 
   278 fun fst (x, y) = x;
   279 fun snd (x, y) = y;
   280 
   281 fun eq_fst eq ((x1, _), (x2, _)) = eq (x1, x2);
   282 fun eq_snd eq ((_, y1), (_, y2)) = eq (y1, y2);
   283 fun eq_pair eqx eqy ((x1, y1), (x2, y2)) = eqx (x1, x2) andalso eqy (y1, y2);
   284 
   285 fun swap (x, y) = (y, x);
   286 
   287 fun apfst f (x, y) = (f x, y);
   288 fun apsnd f (x, y) = (x, f y);
   289 fun pairself f (x, y) = (f x, f y);
   290 
   291 
   292 (* booleans *)
   293 
   294 (*polymorphic equality*)
   295 fun equal x y = x = y;
   296 fun not_equal x y = x <> y;
   297 
   298 (*combining predicates*)
   299 fun p orf q = fn x => p x orelse q x;
   300 fun p andf q = fn x => p x andalso q x;
   301 
   302 val exists = List.exists;
   303 val forall = List.all;
   304 
   305 
   306 (* flags *)
   307 
   308 fun setmp_CRITICAL flag value f x =
   309   NAMED_CRITICAL "setmp" (fn () => Unsynchronized.setmp flag value f x);
   310 
   311 fun setmp_thread_data tag orig_data data f x =
   312   uninterruptible (fn restore_attributes => fn () =>
   313     let
   314       val _ = Thread.setLocal (tag, data);
   315       val result = Exn.capture (restore_attributes f) x;
   316       val _ = Thread.setLocal (tag, orig_data);
   317     in Exn.release result end) ();
   318 
   319 
   320 
   321 (** lists **)
   322 
   323 exception UnequalLengths;
   324 
   325 fun single x = [x];
   326 
   327 fun the_single [x] = x
   328   | the_single _ = raise Empty;
   329 
   330 fun singleton f x = the_single (f [x]);
   331 
   332 fun yield_singleton f x = f [x] #>> the_single;
   333 
   334 fun apply [] x = x
   335   | apply (f :: fs) x = apply fs (f x);
   336 
   337 fun perhaps_apply funs arg =
   338   let
   339     fun app [] res = res
   340       | app (f :: fs) (changed, x) =
   341           (case f x of
   342             NONE => app fs (changed, x)
   343           | SOME x' => app fs (true, x'));
   344   in (case app funs (false, arg) of (false, _) => NONE | (true, arg') => SOME arg') end;
   345 
   346 fun perhaps_loop f arg =
   347   let
   348     fun loop (changed, x) =
   349       (case f x of
   350         NONE => (changed, x)
   351       | SOME x' => loop (true, x'));
   352   in (case loop (false, arg) of (false, _) => NONE | (true, arg') => SOME arg') end;
   353 
   354 
   355 (* fold -- old versions *)
   356 
   357 (*the following versions of fold are designed to fit nicely with infixes*)
   358 
   359 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   360     for operators that associate to the left (TAIL RECURSIVE)*)
   361 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   362   let fun itl (e, [])  = e
   363         | itl (e, a::l) = itl (f(e, a), l)
   364   in  itl end;
   365 
   366 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   367     for operators that associate to the right (not tail recursive)*)
   368 fun foldr f (l, e) =
   369   let fun itr [] = e
   370         | itr (a::l) = f(a, itr l)
   371   in  itr l  end;
   372 
   373 (*  (op @) [x1, ..., xn]  ===>  ((x1 @ x2) @ x3) ... @ xn
   374     for operators that associate to the left (TAIL RECURSIVE)*)
   375 fun foldl1 f [] = raise Empty
   376   | foldl1 f (x :: xs) = foldl f (x, xs);
   377 
   378 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   379     for n > 0, operators that associate to the right (not tail recursive)*)
   380 fun foldr1 f [] = raise Empty
   381   | foldr1 f l =
   382       let fun itr [x] = x
   383             | itr (x::l) = f(x, itr l)
   384       in  itr l  end;
   385 
   386 fun foldl_map f =
   387   let
   388     fun fold_aux (x, []) = (x, [])
   389       | fold_aux (x, y :: ys) =
   390           let
   391             val (x', y') = f (x, y);
   392             val (x'', ys') = fold_aux (x', ys);
   393           in (x'', y' :: ys') end;
   394   in fold_aux end;
   395 
   396 
   397 (* basic list functions *)
   398 
   399 fun eq_list eq (list1, list2) =
   400   let
   401     fun eq_lst (x :: xs, y :: ys) = eq (x, y) andalso eq_lst (xs, ys)
   402       | eq_lst _ = true;
   403   in length list1 = length list2 andalso eq_lst (list1, list2) end;
   404 
   405 fun maps f [] = []
   406   | maps f (x :: xs) = f x @ maps f xs;
   407 
   408 val filter = List.filter;
   409 fun filter_out f = filter (not o f);
   410 val map_filter = List.mapPartial;
   411 
   412 fun take (0: int) xs = []
   413   | take _ [] = []
   414   | take n (x :: xs) = x :: take (n - 1) xs;
   415 
   416 fun drop (0: int) xs = xs
   417   | drop _ [] = []
   418   | drop n (x :: xs) = drop (n - 1) xs;
   419 
   420 fun chop (0: int) xs = ([], xs)
   421   | chop _ [] = ([], [])
   422   | chop n (x :: xs) = chop (n - 1) xs |>> cons x;
   423 
   424 fun chop_while P [] = ([], [])
   425   | chop_while P (ys as x :: xs) =
   426       if P x then chop_while P xs |>> cons x else ([], ys);
   427 
   428 (*return nth element of a list, where 0 designates the first element;
   429   raise Subscript if list too short*)
   430 fun nth xs i = List.nth (xs, i);
   431 
   432 fun nth_list xss i = nth xss i handle Subscript => [];
   433 
   434 fun nth_map 0 f (x :: xs) = f x :: xs
   435   | nth_map n f (x :: xs) = x :: nth_map (n - 1) f xs
   436   | nth_map (_: int) _ [] = raise Subscript;
   437 
   438 fun nth_drop n xs =
   439   List.take (xs, n) @ List.drop (xs, n + 1);
   440 
   441 fun map_index f =
   442   let
   443     fun mapp (_: int) [] = []
   444       | mapp i (x :: xs) = f (i, x) :: mapp (i + 1) xs
   445   in mapp 0 end;
   446 
   447 fun fold_index f =
   448   let
   449     fun fold_aux (_: int) [] y = y
   450       | fold_aux i (x :: xs) y = fold_aux (i + 1) xs (f (i, x) y);
   451   in fold_aux 0 end;
   452 
   453 fun map_range f i =
   454   let
   455     fun mapp (k: int) =
   456       if k < i then f k :: mapp (k + 1) else [];
   457   in mapp 0 end;
   458 
   459 val last_elem = List.last;
   460 
   461 (*rear decomposition*)
   462 fun split_last [] = raise Empty
   463   | split_last [x] = ([], x)
   464   | split_last (x :: xs) = apfst (cons x) (split_last xs);
   465 
   466 (*find position of first element satisfying a predicate*)
   467 fun find_index pred =
   468   let fun find (_: int) [] = ~1
   469         | find n (x :: xs) = if pred x then n else find (n + 1) xs;
   470   in find 0 end;
   471 
   472 (*find first element satisfying predicate*)
   473 val find_first = List.find;
   474 
   475 (*get first element by lookup function*)
   476 fun get_first _ [] = NONE
   477   | get_first f (x :: xs) =
   478       (case f x of
   479         NONE => get_first f xs
   480       | some => some);
   481 
   482 fun get_index f =
   483   let
   484     fun get (_: int) [] = NONE
   485       | get i (x :: xs) =
   486           case f x
   487            of NONE => get (i + 1) xs
   488             | SOME y => SOME (i, y)
   489   in get 0 end;
   490 
   491 val flat = List.concat;
   492 
   493 fun unflat (xs :: xss) ys =
   494       let val (ps, qs) = chop (length xs) ys
   495       in ps :: unflat xss qs end
   496   | unflat [] [] = []
   497   | unflat _ _ = raise UnequalLengths;
   498 
   499 fun burrow f xss = unflat xss (f (flat xss));
   500 
   501 fun burrow_options f os = map (try hd) (burrow f (map the_list os));
   502 
   503 fun fold_burrow f xss s =
   504   apfst (unflat xss) (f (flat xss) s);
   505 
   506 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   507 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   508   | separate _ xs = xs;
   509 
   510 fun surround s (x :: xs) = s :: x :: surround s xs
   511   | surround s [] = [s];
   512 
   513 (*make the list [x, x, ..., x] of length n*)
   514 fun replicate (n: int) x =
   515   let fun rep (0, xs) = xs
   516         | rep (n, xs) = rep (n - 1, x :: xs)
   517   in
   518     if n < 0 then raise Subscript
   519     else rep (n, [])
   520   end;
   521 
   522 
   523 (* direct product *)
   524 
   525 fun map_product f _ [] = []
   526   | map_product f [] _ = []
   527   | map_product f (x :: xs) ys = map (f x) ys @ map_product f xs ys;
   528 
   529 fun fold_product f _ [] z = z
   530   | fold_product f [] _ z = z
   531   | fold_product f (x :: xs) ys z = z |> fold (f x) ys |> fold_product f xs ys;
   532 
   533 
   534 (* lists of pairs *)
   535 
   536 exception UnequalLengths;
   537 
   538 fun map2 _ [] [] = []
   539   | map2 f (x :: xs) (y :: ys) = f x y :: map2 f xs ys
   540   | map2 _ _ _ = raise UnequalLengths;
   541 
   542 fun fold2 f [] [] z = z
   543   | fold2 f (x :: xs) (y :: ys) z = fold2 f xs ys (f x y z)
   544   | fold2 f _ _ _ = raise UnequalLengths;
   545 
   546 fun map_split f [] = ([], [])
   547   | map_split f (x :: xs) =
   548       let
   549         val (y, w) = f x;
   550         val (ys, ws) = map_split f xs;
   551       in (y :: ys, w :: ws) end;
   552 
   553 fun zip_options (x :: xs) (SOME y :: ys) = (x, y) :: zip_options xs ys
   554   | zip_options (_ :: xs) (NONE :: ys) = zip_options xs ys
   555   | zip_options _ [] = []
   556   | zip_options [] _ = raise UnequalLengths;
   557 
   558 (*combine two lists forming a list of pairs:
   559   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   560 fun [] ~~ [] = []
   561   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   562   | _ ~~ _ = raise UnequalLengths;
   563 
   564 (*inverse of ~~; the old 'split':
   565   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   566 val split_list = ListPair.unzip;
   567 
   568 fun burrow_fst f xs = split_list xs |>> f |> op ~~;
   569 
   570 
   571 (* prefixes, suffixes *)
   572 
   573 fun is_prefix _ [] _ = true
   574   | is_prefix eq (x :: xs) (y :: ys) = eq (x, y) andalso is_prefix eq xs ys
   575   | is_prefix eq _ _ = false;
   576 
   577 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   578    where xi is the first element that does not satisfy the predicate*)
   579 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   580   let fun take (rxs, []) = (rev rxs, [])
   581         | take (rxs, x :: xs) =
   582             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   583   in  take([], xs)  end;
   584 
   585 fun chop_prefix eq ([], ys) = ([], ([], ys))
   586   | chop_prefix eq (xs, []) = ([], (xs, []))
   587   | chop_prefix eq (xs as x :: xs', ys as y :: ys') =
   588       if eq (x, y) then
   589         let val (ps', xys'') = chop_prefix eq (xs', ys')
   590         in (x :: ps', xys'') end
   591       else ([], (xs, ys));
   592 
   593 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   594    where xi is the last element that does not satisfy the predicate*)
   595 fun take_suffix _ [] = ([], [])
   596   | take_suffix pred (x :: xs) =
   597       (case take_suffix pred xs of
   598         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   599       | (prfx, sffx) => (x :: prfx, sffx));
   600 
   601 fun prefixes1 [] = []
   602   | prefixes1 (x :: xs) = map (cons x) ([] :: prefixes1 xs);
   603 
   604 fun prefixes xs = [] :: prefixes1 xs;
   605 
   606 fun suffixes1 xs = map rev (prefixes1 (rev xs));
   607 fun suffixes xs = [] :: suffixes1 xs;
   608 
   609 
   610 
   611 (** integers **)
   612 
   613 (* lists of integers *)
   614 
   615 (*make the list [from, from + 1, ..., to]*)
   616 fun ((i: int) upto j) =
   617   if i > j then [] else i :: (i + 1 upto j);
   618 
   619 (*make the list [from, from - 1, ..., to]*)
   620 fun ((i: int) downto j) =
   621   if i < j then [] else i :: (i - 1 downto j);
   622 
   623 
   624 (* convert integers to strings *)
   625 
   626 (*expand the number in the given base;
   627   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   628 fun radixpand (base, num) : int list =
   629   let
   630     fun radix (n, tail) =
   631       if n < base then n :: tail
   632       else radix (n div base, (n mod base) :: tail)
   633   in radix (num, []) end;
   634 
   635 (*expands a number into a string of characters starting from "zerochar";
   636   example: radixstring (2, "0", 8) gives "1000"*)
   637 fun radixstring (base, zerochar, num) =
   638   let val offset = ord zerochar;
   639       fun chrof n = chr (offset + n)
   640   in implode (map chrof (radixpand (base, num))) end;
   641 
   642 
   643 val string_of_int = Int.toString;
   644 
   645 fun signed_string_of_int i =
   646   if i < 0 then "-" ^ string_of_int (~ i) else string_of_int i;
   647 
   648 fun string_of_indexname (a, 0) = a
   649   | string_of_indexname (a, i) = a ^ "_" ^ string_of_int i;
   650 
   651 
   652 (* read integers *)
   653 
   654 fun read_radix_int radix cs =
   655   let
   656     val zero = ord "0";
   657     val limit = zero + radix;
   658     fun scan (num, []) = (num, [])
   659       | scan (num, c :: cs) =
   660         if zero <= ord c andalso ord c < limit then
   661           scan (radix * num + (ord c - zero), cs)
   662         else (num, c :: cs);
   663   in scan (0, cs) end;
   664 
   665 val read_int = read_radix_int 10;
   666 
   667 fun oct_char s = chr (#1 (read_radix_int 8 (explode s)));
   668 
   669 
   670 
   671 (** strings **)
   672 
   673 (* functions tuned for strings, avoiding explode *)
   674 
   675 fun nth_string str i =
   676   (case try String.substring (str, i, 1) of
   677     SOME s => s
   678   | NONE => raise Subscript);
   679 
   680 fun fold_string f str x0 =
   681   let
   682     val n = size str;
   683     fun iter (x, i) =
   684       if i < n then iter (f (String.substring (str, i, 1)) x, i + 1) else x;
   685   in iter (x0, 0) end;
   686 
   687 fun exists_string pred str =
   688   let
   689     val n = size str;
   690     fun ex i = i < n andalso (pred (String.substring (str, i, 1)) orelse ex (i + 1));
   691   in ex 0 end;
   692 
   693 fun forall_string pred = not o exists_string (not o pred);
   694 
   695 fun first_field sep str =
   696   let
   697     val n = size sep;
   698     val len = size str;
   699     fun find i =
   700       if i + n > len then NONE
   701       else if String.substring (str, i, n) = sep then SOME i
   702       else find (i + 1);
   703   in
   704     (case find 0 of
   705       NONE => NONE
   706     | SOME i => SOME (String.substring (str, 0, i), String.extract (str, i + n, NONE)))
   707   end;
   708 
   709 (*enclose in brackets*)
   710 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   711 fun unenclose str = String.substring (str, 1, size str - 2);
   712 
   713 (*simple quoting (does not escape special chars)*)
   714 val quote = enclose "\"" "\"";
   715 
   716 (*space_implode "..." (explode "hello") = "h...e...l...l...o"*)
   717 fun space_implode a bs = implode (separate a bs);
   718 
   719 val commas = space_implode ", ";
   720 val commas_quote = commas o map quote;
   721 
   722 (*concatenate messages, one per line, into a string*)
   723 val cat_lines = space_implode "\n";
   724 
   725 (*space_explode "." "h.e..l.lo" = ["h", "e", "", "l", "lo"]*)
   726 fun space_explode _ "" = []
   727   | space_explode sep s = String.fields (fn c => str c = sep) s;
   728 
   729 val split_lines = space_explode "\n";
   730 
   731 fun prefix_lines "" txt = txt
   732   | prefix_lines prfx txt = txt |> split_lines |> map (fn s => prfx ^ s) |> cat_lines;
   733 
   734 fun prefix prfx s = prfx ^ s;
   735 fun suffix sffx s = s ^ sffx;
   736 
   737 fun unprefix prfx s =
   738   if String.isPrefix prfx s then String.substring (s, size prfx, size s - size prfx)
   739   else raise Fail "unprefix";
   740 
   741 fun unsuffix sffx s =
   742   if String.isSuffix sffx s then String.substring (s, 0, size s - size sffx)
   743   else raise Fail "unsuffix";
   744 
   745 fun replicate_string (0: int) _ = ""
   746   | replicate_string 1 a = a
   747   | replicate_string k a =
   748       if k mod 2 = 0 then replicate_string (k div 2) (a ^ a)
   749       else replicate_string (k div 2) (a ^ a) ^ a;
   750 
   751 fun translate_string f = String.translate (f o String.str);
   752 
   753 (*crude matching of str against simple glob pat*)
   754 fun match_string pat str =
   755   let
   756     fun match [] _ = true
   757       | match (p :: ps) s =
   758           size p <= size s andalso
   759             (case try (unprefix p) s of
   760               SOME s' => match ps s'
   761             | NONE => match (p :: ps) (String.substring (s, 1, size s - 1)));
   762   in match (space_explode "*" pat) str end;
   763 
   764 
   765 
   766 (** lists as sets -- see also Pure/General/ord_list.ML **)
   767 
   768 (* canonical operations *)
   769 
   770 fun member eq list x =
   771   let
   772     fun memb [] = false
   773       | memb (y :: ys) = eq (x, y) orelse memb ys;
   774   in memb list end;
   775 
   776 fun insert eq x xs = if member eq xs x then xs else x :: xs;
   777 fun remove eq x xs = if member eq xs x then filter_out (fn y => eq (x, y)) xs else xs;
   778 fun update eq x xs = cons x (remove eq x xs);
   779 
   780 fun inter eq xs = filter (member eq xs);
   781 
   782 fun union eq = fold (insert eq);
   783 fun subtract eq = fold (remove eq);
   784 
   785 fun merge eq (xs, ys) =
   786   if pointer_eq (xs, ys) then xs
   787   else if null xs then ys
   788   else fold_rev (insert eq) ys xs;
   789 
   790 
   791 (* subset and set equality *)
   792 
   793 fun subset eq (xs, ys) = forall (member eq ys) xs;
   794 
   795 fun eq_set eq (xs, ys) =
   796   eq_list eq (xs, ys) orelse
   797     (subset eq (xs, ys) andalso subset (eq o swap) (ys, xs));
   798 
   799 
   800 (*makes a list of the distinct members of the input; preserves order, takes
   801   first of equal elements*)
   802 fun distinct eq lst =
   803   let
   804     fun dist (rev_seen, []) = rev rev_seen
   805       | dist (rev_seen, x :: xs) =
   806           if member eq rev_seen x then dist (rev_seen, xs)
   807           else dist (x :: rev_seen, xs);
   808   in dist ([], lst) end;
   809 
   810 (*returns a list containing all repeated elements exactly once; preserves
   811   order, takes first of equal elements*)
   812 fun duplicates eq lst =
   813   let
   814     fun dups (rev_dups, []) = rev rev_dups
   815       | dups (rev_dups, x :: xs) =
   816           if member eq rev_dups x orelse not (member eq xs x) then
   817             dups (rev_dups, xs)
   818           else dups (x :: rev_dups, xs);
   819   in dups ([], lst) end;
   820 
   821 fun has_duplicates eq =
   822   let
   823     fun dups [] = false
   824       | dups (x :: xs) = member eq xs x orelse dups xs;
   825   in dups end;
   826 
   827 
   828 (* matrices *)
   829 
   830 fun map_transpose f xss =
   831   let
   832     val n = case distinct (op =) (map length xss)
   833      of [] => 0
   834       | [n] => n
   835       | _ => raise UnequalLengths;
   836   in map_range (fn m => f (map (fn xs => nth xs m) xss)) n end;
   837 
   838 
   839 
   840 (** lists as multisets **)
   841 
   842 fun remove1 eq x [] = []
   843   | remove1 eq x (y :: ys) = if eq (x, y) then ys else y :: remove1 eq x ys;
   844 
   845 fun combine eq xs ys = fold (remove1 eq) ys xs @ ys;
   846 
   847 fun submultiset _ ([], _)  = true
   848   | submultiset eq (x :: xs, ys) = member eq ys x andalso submultiset eq (xs, remove1 eq x ys);
   849 
   850 
   851 
   852 (** orders **)
   853 
   854 fun is_equal EQUAL = true
   855   | is_equal _ = false;
   856 
   857 fun rev_order LESS = GREATER
   858   | rev_order EQUAL = EQUAL
   859   | rev_order GREATER = LESS;
   860 
   861 (*assume rel is a linear strict order*)
   862 fun make_ord rel (x, y) =
   863   if rel (x, y) then LESS
   864   else if rel (y, x) then GREATER
   865   else EQUAL;
   866 
   867 fun bool_ord (false, true) = LESS
   868   | bool_ord (true, false) = GREATER
   869   | bool_ord _ = EQUAL;
   870 
   871 val int_ord = Int.compare;
   872 val string_ord = String.compare;
   873 
   874 fun fast_string_ord (s1, s2) =
   875   (case int_ord (size s1, size s2) of EQUAL => string_ord (s1, s2) | ord => ord);
   876 
   877 fun option_ord ord (SOME x, SOME y) = ord (x, y)
   878   | option_ord _ (NONE, NONE) = EQUAL
   879   | option_ord _ (NONE, SOME _) = LESS
   880   | option_ord _ (SOME _, NONE) = GREATER;
   881 
   882 (*lexicographic product*)
   883 fun prod_ord a_ord b_ord ((x, y), (x', y')) =
   884   (case a_ord (x, x') of EQUAL => b_ord (y, y') | ord => ord);
   885 
   886 (*dictionary order -- in general NOT well-founded!*)
   887 fun dict_ord elem_ord (x :: xs, y :: ys) =
   888       (case elem_ord (x, y) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord)
   889   | dict_ord _ ([], []) = EQUAL
   890   | dict_ord _ ([], _ :: _) = LESS
   891   | dict_ord _ (_ :: _, []) = GREATER;
   892 
   893 (*lexicographic product of lists*)
   894 fun list_ord elem_ord (xs, ys) =
   895   (case int_ord (length xs, length ys) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
   896 
   897 
   898 (* sorting *)
   899 
   900 (*quicksort -- stable, i.e. does not reorder equal elements*)
   901 fun quicksort unique ord =
   902   let
   903     fun qsort [] = []
   904       | qsort (xs as [_]) = xs
   905       | qsort (xs as [x, y]) =
   906           (case ord (x, y) of
   907             LESS => xs
   908           | EQUAL => if unique then [x] else xs
   909           | GREATER => [y, x])
   910       | qsort xs =
   911           let val (lts, eqs, gts) = part (nth xs (length xs div 2)) xs
   912           in qsort lts @ eqs @ qsort gts end
   913     and part _ [] = ([], [], [])
   914       | part pivot (x :: xs) = add (ord (x, pivot)) x (part pivot xs)
   915     and add LESS x (lts, eqs, gts) = (x :: lts, eqs, gts)
   916       | add EQUAL x (lts, [], gts) = (lts, [x], gts)
   917       | add EQUAL x (res as (lts, eqs, gts)) = if unique then res else (lts, x :: eqs, gts)
   918       | add GREATER x (lts, eqs, gts) = (lts, eqs, x :: gts);
   919   in qsort end;
   920 
   921 fun sort ord = quicksort false ord;
   922 fun sort_distinct ord = quicksort true ord;
   923 
   924 val sort_strings = sort string_ord;
   925 fun sort_wrt sel xs = sort (string_ord o pairself sel) xs;
   926 
   927 
   928 (* items tagged by integer index *)
   929 
   930 (*insert tags*)
   931 fun tag_list k [] = []
   932   | tag_list k (x :: xs) = (k:int, x) :: tag_list (k + 1) xs;
   933 
   934 (*remove tags and suppress duplicates -- list is assumed sorted!*)
   935 fun untag_list [] = []
   936   | untag_list [(k: int, x)] = [x]
   937   | untag_list ((k, x) :: (rest as (k', x') :: _)) =
   938       if k = k' then untag_list rest
   939       else x :: untag_list rest;
   940 
   941 (*return list elements in original order*)
   942 fun order_list list = untag_list (sort (int_ord o pairself fst) list);
   943 
   944 
   945 
   946 (** random numbers **)
   947 
   948 exception RANDOM;
   949 
   950 fun rmod x y = x - y * Real.realFloor (x / y);
   951 
   952 local
   953   val a = 16807.0;
   954   val m = 2147483647.0;
   955   val random_seed = Unsynchronized.ref 1.0;
   956 in
   957 
   958 fun random () = CRITICAL (fn () =>
   959   let val r = rmod (a * ! random_seed) m
   960   in (random_seed := r; r) end);
   961 
   962 end;
   963 
   964 fun random_range l h =
   965   if h < l orelse l < 0 then raise RANDOM
   966   else l + Real.floor (rmod (random ()) (real (h - l + 1)));
   967 
   968 fun one_of xs = nth xs (random_range 0 (length xs - 1));
   969 
   970 fun frequency xs =
   971   let
   972     val sum = foldl op + (0, map fst xs);
   973     fun pick n ((k: int, x) :: xs) =
   974       if n <= k then x else pick (n - k) xs
   975   in pick (random_range 1 sum) xs end;
   976 
   977 
   978 
   979 (** misc **)
   980 
   981 fun divide_and_conquer decomp x =
   982   let val (ys, recomb) = decomp x
   983   in recomb (map (divide_and_conquer decomp) ys) end;
   984 
   985 fun divide_and_conquer' decomp x s =
   986   let val ((ys, recomb), s') = decomp x s
   987   in recomb (fold_map (divide_and_conquer' decomp) ys s') end;
   988 
   989 
   990 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
   991    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
   992 fun partition_list p i j =
   993   let
   994     fun part (k: int) xs =
   995       if k > j then
   996         (case xs of
   997           [] => []
   998         | _ => raise Fail "partition_list")
   999       else
  1000         let val (ns, rest) = List.partition (p k) xs
  1001         in ns :: part (k + 1) rest end;
  1002   in part (i: int) end;
  1003 
  1004 fun partition_eq (eq: 'a * 'a -> bool) =
  1005   let
  1006     fun part [] = []
  1007       | part (x :: ys) =
  1008           let val (xs, xs') = List.partition (fn y => eq (x, y)) ys
  1009           in (x :: xs) :: part xs' end;
  1010   in part end;
  1011 
  1012 
  1013 
  1014 (* generating identifiers *)
  1015 
  1016 (** Freshly generated identifiers; supplied prefix MUST start with a letter **)
  1017 local
  1018 (*Maps 0-61 to A-Z, a-z, 0-9; exclude _ or ' to avoid clash with internal/unusual indentifiers*)
  1019 fun gensym_char i =
  1020   if i<26 then chr (ord "A" + i)
  1021   else if i<52 then chr (ord "a" + i - 26)
  1022   else chr (ord "0" + i - 52);
  1023 
  1024 val char_vec = Vector.tabulate (62, gensym_char);
  1025 fun newid n = implode (map (fn i => Vector.sub (char_vec, i)) (radixpand (62, n)));
  1026 
  1027 val gensym_seed = Unsynchronized.ref (0: int);
  1028 
  1029 in
  1030   fun gensym pre =
  1031     pre ^ newid (NAMED_CRITICAL "gensym" (fn () => Unsynchronized.inc gensym_seed));
  1032 end;
  1033 
  1034 
  1035 (* stamps and serial numbers *)
  1036 
  1037 type stamp = unit Unsynchronized.ref;
  1038 val stamp: unit -> stamp = Unsynchronized.ref;
  1039 
  1040 type serial = int;
  1041 val serial = Multithreading.serial;
  1042 val serial_string = string_of_int o serial;
  1043 
  1044 
  1045 (* generic objects *)
  1046 
  1047 (*note that the builtin exception datatype may be extended by new
  1048   constructors at any time*)
  1049 structure Object = struct type T = exn end;
  1050 
  1051 end;
  1052 
  1053 structure Basic_Library: BASIC_LIBRARY = Library;
  1054 open Basic_Library;