src/HOL/Number_Theory/Residues.thy
author haftmann
Wed Apr 12 09:27:43 2017 +0200 (2017-04-12)
changeset 65465 067210a08a22
parent 65416 f707dbcf11e3
child 65726 f5d64d094efe
permissions -rw-r--r--
more fundamental euler's totient function on nat rather than int;
avoid generic name phi;
separate theory for euler's totient function
     1 (*  Title:      HOL/Number_Theory/Residues.thy
     2     Author:     Jeremy Avigad
     3 
     4 An algebraic treatment of residue rings, and resulting proofs of
     5 Euler's theorem and Wilson's theorem.
     6 *)
     7 
     8 section \<open>Residue rings\<close>
     9 
    10 theory Residues
    11 imports
    12   Cong
    13   "~~/src/HOL/Algebra/More_Group"
    14   "~~/src/HOL/Algebra/More_Ring"
    15   "~~/src/HOL/Algebra/More_Finite_Product"
    16   "~~/src/HOL/Algebra/Multiplicative_Group"
    17   Totient
    18 begin
    19 
    20 definition QuadRes :: "int \<Rightarrow> int \<Rightarrow> bool" where
    21   "QuadRes p a = (\<exists>y. ([y^2 = a] (mod p)))"
    22 
    23 definition Legendre :: "int \<Rightarrow> int \<Rightarrow> int" where
    24   "Legendre a p = (if ([a = 0] (mod p)) then 0
    25     else if QuadRes p a then 1
    26     else -1)"
    27 
    28 subsection \<open>A locale for residue rings\<close>
    29 
    30 definition residue_ring :: "int \<Rightarrow> int ring"
    31 where
    32   "residue_ring m =
    33     \<lparr>carrier = {0..m - 1},
    34      mult = \<lambda>x y. (x * y) mod m,
    35      one = 1,
    36      zero = 0,
    37      add = \<lambda>x y. (x + y) mod m\<rparr>"
    38 
    39 locale residues =
    40   fixes m :: int and R (structure)
    41   assumes m_gt_one: "m > 1"
    42   defines "R \<equiv> residue_ring m"
    43 begin
    44 
    45 lemma abelian_group: "abelian_group R"
    46 proof -
    47   have "\<exists>y\<in>{0..m - 1}. (x + y) mod m = 0" if "0 \<le> x" "x < m" for x
    48   proof (cases "x = 0")
    49     case True
    50     with m_gt_one show ?thesis by simp
    51   next
    52     case False
    53     then have "(x + (m - x)) mod m = 0"
    54       by simp
    55     with m_gt_one that show ?thesis
    56       by (metis False atLeastAtMost_iff diff_ge_0_iff_ge diff_left_mono int_one_le_iff_zero_less less_le)
    57   qed
    58   with m_gt_one show ?thesis
    59     by (fastforce simp add: R_def residue_ring_def mod_add_right_eq ac_simps  intro!: abelian_groupI)
    60 qed    
    61 
    62 lemma comm_monoid: "comm_monoid R"
    63   unfolding R_def residue_ring_def
    64   apply (rule comm_monoidI)
    65     using m_gt_one  apply auto
    66   apply (metis mod_mult_right_eq mult.assoc mult.commute)
    67   apply (metis mult.commute)
    68   done
    69 
    70 lemma cring: "cring R"
    71   apply (intro cringI abelian_group comm_monoid)
    72   unfolding R_def residue_ring_def
    73   apply (auto simp add: comm_semiring_class.distrib mod_add_eq mod_mult_left_eq)
    74   done
    75 
    76 end
    77 
    78 sublocale residues < cring
    79   by (rule cring)
    80 
    81 
    82 context residues
    83 begin
    84 
    85 text \<open>
    86   These lemmas translate back and forth between internal and
    87   external concepts.
    88 \<close>
    89 
    90 lemma res_carrier_eq: "carrier R = {0..m - 1}"
    91   unfolding R_def residue_ring_def by auto
    92 
    93 lemma res_add_eq: "x \<oplus> y = (x + y) mod m"
    94   unfolding R_def residue_ring_def by auto
    95 
    96 lemma res_mult_eq: "x \<otimes> y = (x * y) mod m"
    97   unfolding R_def residue_ring_def by auto
    98 
    99 lemma res_zero_eq: "\<zero> = 0"
   100   unfolding R_def residue_ring_def by auto
   101 
   102 lemma res_one_eq: "\<one> = 1"
   103   unfolding R_def residue_ring_def units_of_def by auto
   104 
   105 lemma res_units_eq: "Units R = {x. 0 < x \<and> x < m \<and> coprime x m}"
   106   using m_gt_one
   107   unfolding Units_def R_def residue_ring_def
   108   apply auto
   109   apply (subgoal_tac "x \<noteq> 0")
   110   apply auto
   111   apply (metis invertible_coprime_int)
   112   apply (subst (asm) coprime_iff_invertible'_int)
   113   apply (auto simp add: cong_int_def mult.commute)
   114   done
   115 
   116 lemma res_neg_eq: "\<ominus> x = (- x) mod m"
   117   using m_gt_one unfolding R_def a_inv_def m_inv_def residue_ring_def
   118   apply simp
   119   apply (rule the_equality)
   120   apply (simp add: mod_add_right_eq)
   121   apply (simp add: add.commute mod_add_right_eq)
   122   apply (metis add.right_neutral minus_add_cancel mod_add_right_eq mod_pos_pos_trivial)
   123   done
   124 
   125 lemma finite [iff]: "finite (carrier R)"
   126   by (simp add: res_carrier_eq)
   127 
   128 lemma finite_Units [iff]: "finite (Units R)"
   129   by (simp add: finite_ring_finite_units)
   130 
   131 text \<open>
   132   The function \<open>a \<mapsto> a mod m\<close> maps the integers to the
   133   residue classes. The following lemmas show that this mapping
   134   respects addition and multiplication on the integers.
   135 \<close>
   136 
   137 lemma mod_in_carrier [iff]: "a mod m \<in> carrier R"
   138   unfolding res_carrier_eq
   139   using insert m_gt_one by auto
   140 
   141 lemma add_cong: "(x mod m) \<oplus> (y mod m) = (x + y) mod m"
   142   unfolding R_def residue_ring_def
   143   by (auto simp add: mod_simps)
   144 
   145 lemma mult_cong: "(x mod m) \<otimes> (y mod m) = (x * y) mod m"
   146   unfolding R_def residue_ring_def
   147   by (auto simp add: mod_simps)
   148 
   149 lemma zero_cong: "\<zero> = 0"
   150   unfolding R_def residue_ring_def by auto
   151 
   152 lemma one_cong: "\<one> = 1 mod m"
   153   using m_gt_one unfolding R_def residue_ring_def by auto
   154 
   155 (* FIXME revise algebra library to use 1? *)
   156 lemma pow_cong: "(x mod m) (^) n = x^n mod m"
   157   using m_gt_one
   158   apply (induct n)
   159   apply (auto simp add: nat_pow_def one_cong)
   160   apply (metis mult.commute mult_cong)
   161   done
   162 
   163 lemma neg_cong: "\<ominus> (x mod m) = (- x) mod m"
   164   by (metis mod_minus_eq res_neg_eq)
   165 
   166 lemma (in residues) prod_cong: "finite A \<Longrightarrow> (\<Otimes>i\<in>A. (f i) mod m) = (\<Prod>i\<in>A. f i) mod m"
   167   by (induct set: finite) (auto simp: one_cong mult_cong)
   168 
   169 lemma (in residues) sum_cong: "finite A \<Longrightarrow> (\<Oplus>i\<in>A. (f i) mod m) = (\<Sum>i\<in>A. f i) mod m"
   170   by (induct set: finite) (auto simp: zero_cong add_cong)
   171 
   172 lemma mod_in_res_units [simp]:
   173   assumes "1 < m" and "coprime a m"
   174   shows "a mod m \<in> Units R"
   175 proof (cases "a mod m = 0")
   176   case True with assms show ?thesis
   177     by (auto simp add: res_units_eq gcd_red_int [symmetric])
   178 next
   179   case False
   180   from assms have "0 < m" by simp
   181   with pos_mod_sign [of m a] have "0 \<le> a mod m" .
   182   with False have "0 < a mod m" by simp
   183   with assms show ?thesis
   184     by (auto simp add: res_units_eq gcd_red_int [symmetric] ac_simps)
   185 qed
   186 
   187 lemma res_eq_to_cong: "(a mod m) = (b mod m) \<longleftrightarrow> [a = b] (mod m)"
   188   unfolding cong_int_def by auto
   189 
   190 
   191 text \<open>Simplifying with these will translate a ring equation in R to a congruence.\<close>
   192 lemmas res_to_cong_simps = add_cong mult_cong pow_cong one_cong
   193     prod_cong sum_cong neg_cong res_eq_to_cong
   194 
   195 text \<open>Other useful facts about the residue ring.\<close>
   196 lemma one_eq_neg_one: "\<one> = \<ominus> \<one> \<Longrightarrow> m = 2"
   197   apply (simp add: res_one_eq res_neg_eq)
   198   apply (metis add.commute add_diff_cancel mod_mod_trivial one_add_one uminus_add_conv_diff
   199     zero_neq_one zmod_zminus1_eq_if)
   200   done
   201 
   202 end
   203 
   204 
   205 subsection \<open>Prime residues\<close>
   206 
   207 locale residues_prime =
   208   fixes p :: nat and R (structure)
   209   assumes p_prime [intro]: "prime p"
   210   defines "R \<equiv> residue_ring (int p)"
   211 
   212 sublocale residues_prime < residues p
   213   unfolding R_def residues_def
   214   using p_prime apply auto
   215   apply (metis (full_types) of_nat_1 of_nat_less_iff prime_gt_1_nat)
   216   done
   217 
   218 context residues_prime
   219 begin
   220 
   221 lemma is_field: "field R"
   222 proof -
   223   have "\<And>x. \<lbrakk>gcd x (int p) \<noteq> 1; 0 \<le> x; x < int p\<rbrakk> \<Longrightarrow> x = 0"
   224     by (metis dual_order.order_iff_strict gcd.commute less_le_not_le p_prime prime_imp_coprime prime_nat_int_transfer zdvd_imp_le)
   225   then show ?thesis
   226   apply (intro cring.field_intro2 cring)
   227   apply (auto simp add: res_carrier_eq res_one_eq res_zero_eq res_units_eq)
   228     done
   229 qed
   230 
   231 lemma res_prime_units_eq: "Units R = {1..p - 1}"
   232   apply (subst res_units_eq)
   233   apply auto
   234   apply (subst gcd.commute)
   235   apply (auto simp add: p_prime prime_imp_coprime_int zdvd_not_zless)
   236   done
   237 
   238 end
   239 
   240 sublocale residues_prime < field
   241   by (rule is_field)
   242 
   243 
   244 section \<open>Test cases: Euler's theorem and Wilson's theorem\<close>
   245 
   246 subsection \<open>Euler's theorem\<close>
   247 
   248 lemma (in residues) totient_eq:
   249   "totient (nat m) = card (Units R)"
   250 proof -
   251   have *: "inj_on nat (Units R)"
   252     by (rule inj_onI) (auto simp add: res_units_eq)
   253   have "totatives (nat m) = nat ` Units R"
   254     by (auto simp add: res_units_eq totatives_def transfer_nat_int_gcd(1))
   255       (smt One_nat_def image_def mem_Collect_eq nat_0 nat_eq_iff nat_less_iff of_nat_1 transfer_int_nat_gcd(1))
   256   then have "card (totatives (nat m)) = card (nat ` Units R)"
   257     by simp
   258   also have "\<dots> = card (Units R)"
   259     using * card_image [of nat "Units R"] by auto
   260   finally show ?thesis
   261     by simp
   262 qed
   263 
   264 lemma (in residues_prime) totient_eq: "totient p = p - 1"
   265   using totient_eq by (simp add: res_prime_units_eq)
   266 
   267 lemma (in residues) euler_theorem:
   268   assumes "coprime a m"
   269   shows "[a ^ totient (nat m) = 1] (mod m)"
   270 proof -
   271   have "a ^ totient (nat m) mod m = 1 mod m"
   272     by (metis assms finite_Units m_gt_one mod_in_res_units one_cong totient_eq pow_cong units_power_order_eq_one)
   273   then show ?thesis
   274     using res_eq_to_cong by blast
   275 qed
   276 
   277 lemma euler_theorem:
   278   fixes a m :: nat
   279   assumes "coprime a m"
   280   shows "[a ^ totient m = 1] (mod m)"
   281 proof (cases "m = 0 | m = 1")
   282   case True
   283   then show ?thesis by auto
   284 next
   285   case False
   286   with assms show ?thesis
   287     using residues.euler_theorem [of "int m" "int a"] transfer_int_nat_cong
   288     by (auto simp add: residues_def transfer_int_nat_gcd(1)) force
   289 qed
   290 
   291 lemma fermat_theorem:
   292   fixes p a :: nat
   293   assumes "prime p" and "\<not> p dvd a"
   294   shows "[a ^ (p - 1) = 1] (mod p)"
   295 proof -
   296   from assms prime_imp_coprime [of p a] have "coprime a p"
   297     by (auto simp add: ac_simps)
   298   then have "[a ^ totient p = 1] (mod p)"
   299      by (rule euler_theorem)
   300   also have "totient p = p - 1"
   301     by (rule prime_totient) (rule assms)
   302   finally show ?thesis .
   303 qed
   304 
   305 
   306 subsection \<open>Wilson's theorem\<close>
   307 
   308 lemma (in field) inv_pair_lemma: "x \<in> Units R \<Longrightarrow> y \<in> Units R \<Longrightarrow>
   309     {x, inv x} \<noteq> {y, inv y} \<Longrightarrow> {x, inv x} \<inter> {y, inv y} = {}"
   310   apply auto
   311   apply (metis Units_inv_inv)+
   312   done
   313 
   314 lemma (in residues_prime) wilson_theorem1:
   315   assumes a: "p > 2"
   316   shows "[fact (p - 1) = (-1::int)] (mod p)"
   317 proof -
   318   let ?Inverse_Pairs = "{{x, inv x}| x. x \<in> Units R - {\<one>, \<ominus> \<one>}}"
   319   have UR: "Units R = {\<one>, \<ominus> \<one>} \<union> \<Union>?Inverse_Pairs"
   320     by auto
   321   have "(\<Otimes>i\<in>Units R. i) = (\<Otimes>i\<in>{\<one>, \<ominus> \<one>}. i) \<otimes> (\<Otimes>i\<in>\<Union>?Inverse_Pairs. i)"
   322     apply (subst UR)
   323     apply (subst finprod_Un_disjoint)
   324     apply (auto intro: funcsetI)
   325     using inv_one apply auto[1]
   326     using inv_eq_neg_one_eq apply auto
   327     done
   328   also have "(\<Otimes>i\<in>{\<one>, \<ominus> \<one>}. i) = \<ominus> \<one>"
   329     apply (subst finprod_insert)
   330     apply auto
   331     apply (frule one_eq_neg_one)
   332     using a apply force
   333     done
   334   also have "(\<Otimes>i\<in>(\<Union>?Inverse_Pairs). i) = (\<Otimes>A\<in>?Inverse_Pairs. (\<Otimes>y\<in>A. y))"
   335     apply (subst finprod_Union_disjoint)
   336     apply auto
   337     apply (metis Units_inv_inv)+
   338     done
   339   also have "\<dots> = \<one>"
   340     apply (rule finprod_one)
   341     apply auto
   342     apply (subst finprod_insert)
   343     apply auto
   344     apply (metis inv_eq_self)
   345     done
   346   finally have "(\<Otimes>i\<in>Units R. i) = \<ominus> \<one>"
   347     by simp
   348   also have "(\<Otimes>i\<in>Units R. i) = (\<Otimes>i\<in>Units R. i mod p)"
   349     by (rule finprod_cong') (auto simp: res_units_eq)
   350   also have "\<dots> = (\<Prod>i\<in>Units R. i) mod p"
   351     by (rule prod_cong) auto
   352   also have "\<dots> = fact (p - 1) mod p"
   353     apply (simp add: fact_prod)
   354     using assms
   355     apply (subst res_prime_units_eq)
   356     apply (simp add: int_prod zmod_int prod_int_eq)
   357     done
   358   finally have "fact (p - 1) mod p = \<ominus> \<one>" .
   359   then show ?thesis
   360     by (metis of_nat_fact Divides.transfer_int_nat_functions(2)
   361       cong_int_def res_neg_eq res_one_eq)
   362 qed
   363 
   364 lemma wilson_theorem:
   365   assumes "prime p"
   366   shows "[fact (p - 1) = - 1] (mod p)"
   367 proof (cases "p = 2")
   368   case True
   369   then show ?thesis
   370     by (simp add: cong_int_def fact_prod)
   371 next
   372   case False
   373   then show ?thesis
   374     using assms prime_ge_2_nat
   375     by (metis residues_prime.wilson_theorem1 residues_prime.intro le_eq_less_or_eq)
   376 qed
   377 
   378 text {*
   379   This result can be transferred to the multiplicative group of
   380   $\mathbb{Z}/p\mathbb{Z}$ for $p$ prime. *}
   381 
   382 lemma mod_nat_int_pow_eq:
   383   fixes n :: nat and p a :: int
   384   assumes "a \<ge> 0" "p \<ge> 0"
   385   shows "(nat a ^ n) mod (nat p) = nat ((a ^ n) mod p)"
   386   using assms
   387   by (simp add: int_one_le_iff_zero_less nat_mod_distrib order_less_imp_le nat_power_eq[symmetric])
   388 
   389 theorem residue_prime_mult_group_has_gen :
   390  fixes p :: nat
   391  assumes prime_p : "prime p"
   392  shows "\<exists>a \<in> {1 .. p - 1}. {1 .. p - 1} = {a^i mod p|i . i \<in> UNIV}"
   393 proof -
   394   have "p\<ge>2" using prime_gt_1_nat[OF prime_p] by simp
   395   interpret R:residues_prime "p" "residue_ring p" unfolding residues_prime_def
   396     by (simp add: prime_p)
   397   have car: "carrier (residue_ring (int p)) - {\<zero>\<^bsub>residue_ring (int p)\<^esub>} =  {1 .. int p - 1}"
   398     by (auto simp add: R.zero_cong R.res_carrier_eq)
   399   obtain a where a:"a \<in> {1 .. int p - 1}"
   400          and a_gen:"{1 .. int p - 1} = {a(^)\<^bsub>residue_ring (int p)\<^esub>i|i::nat . i \<in> UNIV}"
   401     apply atomize_elim using field.finite_field_mult_group_has_gen[OF R.is_field]
   402     by (auto simp add: car[symmetric] carrier_mult_of)
   403   { fix x fix i :: nat assume x: "x \<in> {1 .. int p - 1}"
   404     hence "x (^)\<^bsub>residue_ring (int p)\<^esub> i = x ^ i mod (int p)" using R.pow_cong[of x i] by auto}
   405   note * = this
   406   have **:"nat ` {1 .. int p - 1} = {1 .. p - 1}" (is "?L = ?R")
   407   proof
   408     { fix n assume n: "n \<in> ?L"
   409       then have "n \<in> ?R" using `p\<ge>2` by force
   410     } thus "?L \<subseteq> ?R" by blast
   411     { fix n assume n: "n \<in> ?R"
   412       then have "n \<in> ?L" using `p\<ge>2` Set_Interval.transfer_nat_int_set_functions(2) by fastforce
   413     } thus "?R \<subseteq> ?L" by blast
   414   qed
   415   have "nat ` {a^i mod (int p) | i::nat. i \<in> UNIV} = {nat a^i mod p | i . i \<in> UNIV}" (is "?L = ?R")
   416   proof
   417     { fix x assume x: "x \<in> ?L"
   418       then obtain i where i:"x = nat (a^i mod (int p))" by blast
   419       hence "x = nat a ^ i mod p" using mod_nat_int_pow_eq[of a "int p" i] a `p\<ge>2` by auto
   420       hence "x \<in> ?R" using i by blast
   421     } thus "?L \<subseteq> ?R" by blast
   422     { fix x assume x: "x \<in> ?R"
   423       then obtain i where i:"x = nat a^i mod p" by blast
   424       hence "x \<in> ?L" using mod_nat_int_pow_eq[of a "int p" i] a `p\<ge>2` by auto
   425     } thus "?R \<subseteq> ?L" by blast
   426   qed
   427   hence "{1 .. p - 1} = {nat a^i mod p | i. i \<in> UNIV}"
   428     using * a a_gen ** by presburger
   429   moreover
   430   have "nat a \<in> {1 .. p - 1}" using a by force
   431   ultimately show ?thesis ..
   432 qed
   433 
   434 end